win32/FindExt.pm

   1 package FindExt;
   2
   3 our $VERSION = '1.03';
   4
   5 use strict;
   6 use warnings;
   7
   8 my $no = join('|',qw(Amiga.* GDBM_File ODBM_File NDBM_File DB_File
   9                      VMS.* Sys-Syslog IPC-SysV I18N-Langinfo));
  10 $no = qr/^(?:$no)$/i;
  11
  12 sub apply_config {
  13     my ($config) = @_;
  14     my @no;
  15
  16     push @no, 'Sys-Syslog' if $^O eq 'MSWin32';
  17
  18     # duplicates logic from Configure (mostly)
  19     push @no, "DB_File" unless $config->{i_db};
  20     push @no, "GDBM_File" unless $config->{i_gdbm};
  21     push @no, "I18N-Langinfo" unless $config->{i_langinfo} && $config->{d_nl_langinfo};
  22     push @no, "IPC-SysV" unless $config->{d_msg} || $config->{d_sem} || $config->{d_shm};
  23     push @no, "NDBM_File" unless $config->{d_ndbm};
  24     push @no, "ODBM_File"
  25       unless ($config->{i_dbm} || $config->{i_rpcsvcdbm}) && !$config->{d_cplusplus};
  26     push @no, "Amiga.*" unless $^O eq "amigaos";
  27     push @no, "VMS.*" unless $^O eq "VMS";
  28     push @no, "Win32.*" unless $^O eq "MSWin32" || $^O eq "cygwin";
  29
  30     $no = join('|', @no);
  31     $no = qr/^(?:$no)$/i;
  32 }
  33
  34 my %ext;
  35 my %static;
  36
  37 sub set_static_extensions {
  38     # adjust results of scan_ext, and also save
  39     # statics in case scan_ext hasn't been called yet.
  40     # if '*' is passed then all XS extensions are static
  41     # (with possible exclusions)
  42     %static = ();
  43     my @list = @_;
  44     if (@_ and $_[0] eq '*') {
  45         my %excl = map {$_=>1} map {m/^!(.*)$/} @_[1 .. $#_];
  46         @list = grep {!exists $excl{$_}} keys %ext;
  47     }
  48     for (@list) {
  49         $static{$_} = 1;
  50         $ext{$_} = 'static' if $ext{$_} && $ext{$_} eq 'dynamic';
  51     }
  52
  53     # Encode is a special case.  If we are building Encode as a static
  54     # extension, we need to explicitly list its subextensions as well.
  55     # For other nested extensions, this is handled automatically by
  56     # the appropriate Makefile.PL.
  57     if ($ext{Encode} && $ext{Encode} eq 'static') {
  58         require File::Find;
  59         File::Find::find({
  60                           no_chdir => 1,
  61                           wanted => sub {
  62                               return unless m!\b(Encode/.+)/Makefile\.PL!;
  63                               $static{$1} = 1;
  64                               $ext{$1} = 'static';
  65                           },
  66                          }, "../cpan/Encode");
  67     }
  68 }
  69
  70 sub _ext_eq {
  71     my $key = shift;
  72     sub {
  73         sort grep $ext{$_} eq $key, keys %ext;
  74     }
  75 }
  76
  77 *dynamic_ext = _ext_eq('dynamic');
  78 *static_ext = _ext_eq('static');
  79 *nonxs_ext = _ext_eq('nonxs');
  80
  81 sub extensions {
  82     sort grep $ext{$_} ne 'known', keys %ext;
  83 }
  84
  85 sub known_extensions {
  86     sort keys %ext;
  87 }
  88
  89 sub is_static
  90 {
  91  return $ext{$_[0]} eq 'static'
  92 }
  93
  94 sub has_xs_or_c {
  95     my $dir = shift;
  96     opendir my $dh, $dir or die "opendir $dir: $!";
  97     while (defined (my $item = readdir $dh)) {
  98         return 1 if $item =~ /\.xs$/;
  99         return 1 if $item =~ /\.c$/;
 100     }
 101     return 0;
 102 }
 103
 104 # Function to find available extensions, ignoring DynaLoader
 105 sub scan_ext
 106 {
 107     my $ext_dir = shift;
 108     opendir my $dh, "$ext_dir";
 109     while (defined (my $item = readdir $dh)) {
 110         next if $item =~ /^\.\.?$/;
 111         next if $item eq "DynaLoader";
 112         next unless -d "$ext_dir/$item";
 113         my $this_ext = $item;
 114         my $leaf = $item;
 115
 116         $this_ext =~ s!-!/!g;
 117         $leaf =~ s/.*-//;
 118
 119         # List/Util.xs lives in Scalar-List-Utils, Cwd.xs lives in PathTools
 120         $this_ext = 'List/Util' if $this_ext eq 'Scalar/List/Utils';
 121         $this_ext = 'Cwd'       if $this_ext eq 'PathTools';
 122
 123         # Temporary hack to cope with smokers that are not clearing directories:
 124         next if $ext{$this_ext};
 125
 126         if (has_xs_or_c("$ext_dir/$item")) {
 127             $ext{$this_ext} = $static{$this_ext} ? 'static' : 'dynamic';
 128         } else {
 129             $ext{$this_ext} = 'nonxs';
 130         }
 131         $ext{$this_ext} = 'known' if $item =~ $no;
 132     }
 133 }
 134
 135 1;
 136 # ex: set ts=8 sts=4 sw=4 et: