lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 use Cwd ();
 516
 517 my $_initial_cwd;
 518
 519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 520
 521 BEGIN {
 522     require feature;
 523     $^V =~ /^v(\d+\.\d+)/;
 524     feature->import(":$1");
 525     $_initial_cwd = Cwd::getcwd();
 526 }
 527
 528 # Debugger for Perl 5.00x; perl5db.pl patch level:
 529 use vars qw($VERSION $header);
 530
 531 $VERSION = '1.49_04';
 532
 533 $header = "perl5db.pl version $VERSION";
 534
 535 =head1 DEBUGGER ROUTINES
 536
 537 =head2 C<DB::eval()>
 538
 539 This function replaces straight C<eval()> inside the debugger; it simplifies
 540 the process of evaluating code in the user's context.
 541
 542 The code to be evaluated is passed via the package global variable
 543 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 544
 545 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 546 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 547 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 548 user's current package, grabbed when C<DB::DB> got control.  This causes the
 549 proper context to be used when the eval is actually done.  Afterward, we
 550 restore C<$trace>, C<$single>, and C<$^D>.
 551
 552 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 553 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 554 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 555 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 556 considered sane by the debugger. If there was an C<eval()> error, we print
 557 it on the debugger's output. If C<$onetimedump> is defined, we call
 558 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 559 'methods'. Setting it to something else causes the debugger to do the eval
 560 but not print the result - handy if you want to do something else with it
 561 (the "watch expressions" code does this to get the value of the watch
 562 expression but not show it unless it matters).
 563
 564 In any case, we then return the list of output from C<eval> to the caller,
 565 and unwinding restores the former version of C<$@> in C<@saved> as well
 566 (the localization of C<$saved[0]> goes away at the end of this scope).
 567
 568 =head3 Parameters and variables influencing execution of DB::eval()
 569
 570 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 571 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 572 The variables listed below influence C<DB::eval()>'s execution directly.
 573
 574 =over 4
 575
 576 =item C<$evalarg> - the thing to actually be eval'ed
 577
 578 =item C<$trace> - Current state of execution tracing
 579
 580 =item C<$single> - Current state of single-stepping
 581
 582 =item C<$onetimeDump> - what is to be displayed after the evaluation
 583
 584 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 585
 586 =back
 587
 588 The following variables are altered by C<DB::eval()> during its execution. They
 589 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 590
 591 =over 4
 592
 593 =item C<@res> - used to capture output from actual C<eval>.
 594
 595 =item C<$otrace> - saved value of C<$trace>.
 596
 597 =item C<$osingle> - saved value of C<$single>.
 598
 599 =item C<$od> - saved value of C<$^D>.
 600
 601 =item C<$saved[0]> - saved value of C<$@>.
 602
 603 =item $\ - for output of C<$@> if there is an evaluation error.
 604
 605 =back
 606
 607 =head3 The problem of lexicals
 608
 609 The context of C<DB::eval()> presents us with some problems. Obviously,
 610 we want to be 'sandboxed' away from the debugger's internals when we do
 611 the eval, but we need some way to control how punctuation variables and
 612 debugger globals are used.
 613
 614 We can't use local, because the code inside C<DB::eval> can see localized
 615 variables; and we can't use C<my> either for the same reason. The code
 616 in this routine compromises and uses C<my>.
 617
 618 After this routine is over, we don't have user code executing in the debugger's
 619 context, so we can use C<my> freely.
 620
 621 =cut
 622
 623 ############################################## Begin lexical danger zone
 624
 625 # 'my' variables used here could leak into (that is, be visible in)
 626 # the context that the code being evaluated is executing in. This means that
 627 # the code could modify the debugger's variables.
 628 #
 629 # Fiddling with the debugger's context could be Bad. We insulate things as
 630 # much as we can.
 631
 632 use vars qw(
 633     @args
 634     %break_on_load
 635     $CommandSet
 636     $CreateTTY
 637     $DBGR
 638     @dbline
 639     $dbline
 640     %dbline
 641     $dieLevel
 642     $filename
 643     $histfile
 644     $histsize
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $maxtrace
 650     $od
 651     @options
 652     $osingle
 653     $otrace
 654     $pager
 655     $post
 656     %postponed
 657     $prc
 658     $pre
 659     $pretype
 660     $psh
 661     @RememberOnROptions
 662     $remoteport
 663     @res
 664     $rl
 665     @saved
 666     $signalLevel
 667     $sub
 668     $term
 669     $usercontext
 670     $warnLevel
 671 );
 672
 673 our (
 674     @cmdfhs,
 675     $evalarg,
 676     $frame,
 677     $hist,
 678     $ImmediateStop,
 679     $line,
 680     $onetimeDump,
 681     $onetimedumpDepth,
 682     %option,
 683     $OUT,
 684     $packname,
 685     $signal,
 686     $single,
 687     $start,
 688     %sub,
 689     $subname,
 690     $trace,
 691     $window,
 692 );
 693
 694 # Used to save @ARGV and extract any debugger-related flags.
 695 use vars qw(@ARGS);
 696
 697 # Used to prevent multiple entries to diesignal()
 698 # (if for instance diesignal() itself dies)
 699 use vars qw($panic);
 700
 701 # Used to prevent the debugger from running nonstop
 702 # after a restart
 703 our ($second_time);
 704
 705 sub _calc_usercontext {
 706     my ($package) = @_;
 707
 708     # Cancel strict completely for the evaluated code, so the code
 709     # the user evaluates won't be affected by it. (Shlomi Fish)
 710     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 711     . "package $package;";    # this won't let them modify, alas
 712 }
 713
 714 sub eval {
 715
 716     # 'my' would make it visible from user code
 717     #    but so does local! --tchrist
 718     # Remember: this localizes @DB::res, not @main::res.
 719     local @res;
 720     {
 721
 722         # Try to keep the user code from messing  with us. Save these so that
 723         # even if the eval'ed code changes them, we can put them back again.
 724         # Needed because the user could refer directly to the debugger's
 725         # package globals (and any 'my' variables in this containing scope)
 726         # inside the eval(), and we want to try to stay safe.
 727         local $otrace  = $trace;
 728         local $osingle = $single;
 729         local $od      = $^D;
 730
 731         # Untaint the incoming eval() argument.
 732         { ($evalarg) = $evalarg =~ /(.*)/s; }
 733
 734         # $usercontext built in DB::DB near the comment
 735         # "set up the context for DB::eval ..."
 736         # Evaluate and save any results.
 737         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 738
 739         # Restore those old values.
 740         $trace  = $otrace;
 741         $single = $osingle;
 742         $^D     = $od;
 743     }
 744
 745     # Save the current value of $@, and preserve it in the debugger's copy
 746     # of the saved precious globals.
 747     my $at = $@;
 748
 749     # Since we're only saving $@, we only have to localize the array element
 750     # that it will be stored in.
 751     local $saved[0];    # Preserve the old value of $@
 752     eval { &DB::save };
 753
 754     # Now see whether we need to report an error back to the user.
 755     if ($at) {
 756         local $\ = '';
 757         print $OUT $at;
 758     }
 759
 760     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 761     # are package globals.
 762     elsif ($onetimeDump) {
 763         if ( $onetimeDump eq 'dump' ) {
 764             local $option{dumpDepth} = $onetimedumpDepth
 765               if defined $onetimedumpDepth;
 766             dumpit( $OUT, \@res );
 767         }
 768         elsif ( $onetimeDump eq 'methods' ) {
 769             methods( $res[0] );
 770         }
 771     } ## end elsif ($onetimeDump)
 772     @res;
 773 } ## end sub eval
 774
 775 ############################################## End lexical danger zone
 776
 777 # After this point it is safe to introduce lexicals.
 778 # The code being debugged will be executing in its own context, and
 779 # can't see the inside of the debugger.
 780 #
 781 # However, one should not overdo it: leave as much control from outside as
 782 # possible. If you make something a lexical, it's not going to be addressable
 783 # from outside the debugger even if you know its name.
 784
 785 # This file is automatically included if you do perl -d.
 786 # It's probably not useful to include this yourself.
 787 #
 788 # Before venturing further into these twisty passages, it is
 789 # wise to read the perldebguts man page or risk the ire of dragons.
 790 #
 791 # (It should be noted that perldebguts will tell you a lot about
 792 # the underlying mechanics of how the debugger interfaces into the
 793 # Perl interpreter, but not a lot about the debugger itself. The new
 794 # comments in this code try to address this problem.)
 795
 796 # Note that no subroutine call is possible until &DB::sub is defined
 797 # (for subroutines defined outside of the package DB). In fact the same is
 798 # true if $deep is not defined.
 799
 800 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 801
 802 # modified Perl debugger, to be run from Emacs in perldb-mode
 803 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 804 # Johan Vromans -- upgrade to 4.0 pl 10
 805 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 806 ########################################################################
 807
 808 =head1 DEBUGGER INITIALIZATION
 809
 810 The debugger starts up in phases.
 811
 812 =head2 BASIC SETUP
 813
 814 First, it initializes the environment it wants to run in: turning off
 815 warnings during its own compilation, defining variables which it will need
 816 to avoid warnings later, setting itself up to not exit when the program
 817 terminates, and defaulting to printing return values for the C<r> command.
 818
 819 =cut
 820
 821 # Needed for the statement after exec():
 822 #
 823 # This BEGIN block is simply used to switch off warnings during debugger
 824 # compilation. Probably it would be better practice to fix the warnings,
 825 # but this is how it's done at the moment.
 826
 827 BEGIN {
 828     $ini_warn = $^W;
 829     $^W       = 0;
 830 }    # Switch compilation warnings off until another BEGIN.
 831
 832 local ($^W) = 0;    # Switch run-time warnings off during init.
 833
 834 =head2 THREADS SUPPORT
 835
 836 If we are running under a threaded Perl, we require threads and threads::shared
 837 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 838 threaded debugger control.  C<-dt> can also be used to set this.
 839
 840 Each new thread will be announced and the debugger prompt will always inform
 841 you of each new thread created.  It will also indicate the thread id in which
 842 we are currently running within the prompt like this:
 843
 844     [tid] DB<$i>
 845
 846 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 847 command prompt.  The prompt will show: C<[0]> when running under threads, but
 848 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 849
 850 While running under threads, when you set or delete a breakpoint (etc.), this
 851 will apply to all threads, not just the currently running one.  When you are
 852 in a currently executing thread, you will stay there until it completes.  With
 853 the current implementation it is not currently possible to hop from one thread
 854 to another.
 855
 856 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 857
 858 Note that threading support was built into the debugger as of Perl version
 859 C<5.8.6> and debugger version C<1.2.8>.
 860
 861 =cut
 862
 863 BEGIN {
 864     # ensure we can share our non-threaded variables or no-op
 865     if ($ENV{PERL5DB_THREADED}) {
 866         require threads;
 867         require threads::shared;
 868         import threads::shared qw(share);
 869         $DBGR;
 870         share(\$DBGR);
 871         lock($DBGR);
 872         print "Threads support enabled\n";
 873     } else {
 874         *lock = sub(*) {};
 875         *share = sub(\[$@%]) {};
 876     }
 877 }
 878
 879 # These variables control the execution of 'dumpvar.pl'.
 880 {
 881     package dumpvar;
 882     use vars qw(
 883     $hashDepth
 884     $arrayDepth
 885     $dumpDBFiles
 886     $dumpPackages
 887     $quoteHighBit
 888     $printUndef
 889     $globPrint
 890     $usageOnly
 891     );
 892 }
 893
 894 # used to control die() reporting in diesignal()
 895 {
 896     package Carp;
 897     use vars qw($CarpLevel);
 898 }
 899
 900 # without threads, $filename is not defined until DB::DB is called
 901 share($main::{'_<'.$filename}) if defined $filename;
 902
 903 # Command-line + PERLLIB:
 904 # Save the contents of @INC before they are modified elsewhere.
 905 @ini_INC = @INC;
 906
 907 # This was an attempt to clear out the previous values of various
 908 # trapped errors. Apparently it didn't help. XXX More info needed!
 909 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 910
 911 # We set these variables to safe values. We don't want to blindly turn
 912 # off warnings, because other packages may still want them.
 913 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 914                                    # (local $^W cannot help - other packages!).
 915
 916 # Default to not exiting when program finishes; print the return
 917 # value when the 'r' command is used to return from a subroutine.
 918 $inhibit_exit = $option{PrintRet} = 1;
 919
 920 use vars qw($trace_to_depth);
 921
 922 # Default to 1E9 so it won't be limited to a certain recursion depth.
 923 $trace_to_depth = 1E9;
 924
 925 =head1 OPTION PROCESSING
 926
 927 The debugger's options are actually spread out over the debugger itself and
 928 C<dumpvar.pl>; some of these are variables to be set, while others are
 929 subs to be called with a value. To try to make this a little easier to
 930 manage, the debugger uses a few data structures to define what options
 931 are legal and how they are to be processed.
 932
 933 First, the C<@options> array defines the I<names> of all the options that
 934 are to be accepted.
 935
 936 =cut
 937
 938 @options = qw(
 939   CommandSet   HistFile      HistSize
 940   hashDepth    arrayDepth    dumpDepth
 941   DumpDBFiles  DumpPackages  DumpReused
 942   compactDump  veryCompact   quote
 943   HighBit      undefPrint    globPrint
 944   PrintRet     UsageOnly     frame
 945   AutoTrace    TTY           noTTY
 946   ReadLine     NonStop       LineInfo
 947   maxTraceLen  recallCommand ShellBang
 948   pager        tkRunning     ornaments
 949   signalLevel  warnLevel     dieLevel
 950   inhibit_exit ImmediateStop bareStringify
 951   CreateTTY    RemotePort    windowSize
 952   DollarCaretP
 953 );
 954
 955 @RememberOnROptions = qw(DollarCaretP);
 956
 957 =pod
 958
 959 Second, C<optionVars> lists the variables that each option uses to save its
 960 state.
 961
 962 =cut
 963
 964 use vars qw(%optionVars);
 965
 966 %optionVars = (
 967     hashDepth     => \$dumpvar::hashDepth,
 968     arrayDepth    => \$dumpvar::arrayDepth,
 969     CommandSet    => \$CommandSet,
 970     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 971     DumpPackages  => \$dumpvar::dumpPackages,
 972     DumpReused    => \$dumpvar::dumpReused,
 973     HighBit       => \$dumpvar::quoteHighBit,
 974     undefPrint    => \$dumpvar::printUndef,
 975     globPrint     => \$dumpvar::globPrint,
 976     UsageOnly     => \$dumpvar::usageOnly,
 977     CreateTTY     => \$CreateTTY,
 978     bareStringify => \$dumpvar::bareStringify,
 979     frame         => \$frame,
 980     AutoTrace     => \$trace,
 981     inhibit_exit  => \$inhibit_exit,
 982     maxTraceLen   => \$maxtrace,
 983     ImmediateStop => \$ImmediateStop,
 984     RemotePort    => \$remoteport,
 985     windowSize    => \$window,
 986     HistFile      => \$histfile,
 987     HistSize      => \$histsize,
 988 );
 989
 990 =pod
 991
 992 Third, C<%optionAction> defines the subroutine to be called to process each
 993 option.
 994
 995 =cut
 996
 997 use vars qw(%optionAction);
 998
 999 %optionAction = (
1000     compactDump   => \&dumpvar::compactDump,
1001     veryCompact   => \&dumpvar::veryCompact,
1002     quote         => \&dumpvar::quote,
1003     TTY           => \&TTY,
1004     noTTY         => \&noTTY,
1005     ReadLine      => \&ReadLine,
1006     NonStop       => \&NonStop,
1007     LineInfo      => \&LineInfo,
1008     recallCommand => \&recallCommand,
1009     ShellBang     => \&shellBang,
1010     pager         => \&pager,
1011     signalLevel   => \&signalLevel,
1012     warnLevel     => \&warnLevel,
1013     dieLevel      => \&dieLevel,
1014     tkRunning     => \&tkRunning,
1015     ornaments     => \&ornaments,
1016     RemotePort    => \&RemotePort,
1017     DollarCaretP  => \&DollarCaretP,
1018 );
1019
1020 =pod
1021
1022 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1023 option is used.
1024
1025 =cut
1026
1027 # Note that this list is not complete: several options not listed here
1028 # actually require that dumpvar.pl be loaded for them to work, but are
1029 # not in the table. A subsequent patch will correct this problem; for
1030 # the moment, we're just recommenting, and we are NOT going to change
1031 # function.
1032 use vars qw(%optionRequire);
1033
1034 %optionRequire = (
1035     compactDump => 'dumpvar.pl',
1036     veryCompact => 'dumpvar.pl',
1037     quote       => 'dumpvar.pl',
1038 );
1039
1040 =pod
1041
1042 There are a number of initialization-related variables which can be set
1043 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1044 variable. These are:
1045
1046 =over 4
1047
1048 =item C<$rl> - readline control XXX needs more explanation
1049
1050 =item C<$warnLevel> - whether or not debugger takes over warning handling
1051
1052 =item C<$dieLevel> - whether or not debugger takes over die handling
1053
1054 =item C<$signalLevel> - whether or not debugger takes over signal handling
1055
1056 =item C<$pre> - preprompt actions (array reference)
1057
1058 =item C<$post> - postprompt actions (array reference)
1059
1060 =item C<$pretype>
1061
1062 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1063
1064 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1065
1066 =back
1067
1068 =cut
1069
1070 # These guys may be defined in $ENV{PERL5DB} :
1071 $rl          = 1     unless defined $rl;
1072 $warnLevel   = 1     unless defined $warnLevel;
1073 $dieLevel    = 1     unless defined $dieLevel;
1074 $signalLevel = 1     unless defined $signalLevel;
1075 $pre         = []    unless defined $pre;
1076 $post        = []    unless defined $post;
1077 $pretype     = []    unless defined $pretype;
1078 $CreateTTY   = 3     unless defined $CreateTTY;
1079 $CommandSet  = '580' unless defined $CommandSet;
1080
1081 share($rl);
1082 share($warnLevel);
1083 share($dieLevel);
1084 share($signalLevel);
1085 share($pre);
1086 share($post);
1087 share($pretype);
1088 share($rl);
1089 share($CreateTTY);
1090 share($CommandSet);
1091
1092 =pod
1093
1094 The default C<die>, C<warn>, and C<signal> handlers are set up.
1095
1096 =cut
1097
1098 warnLevel($warnLevel);
1099 dieLevel($dieLevel);
1100 signalLevel($signalLevel);
1101
1102 =pod
1103
1104 The pager to be used is needed next. We try to get it from the
1105 environment first.  If it's not defined there, we try to find it in
1106 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1107 then call the C<pager()> function to save the pager name.
1108
1109 =cut
1110
1111 # This routine makes sure $pager is set up so that '|' can use it.
1112 pager(
1113
1114     # If PAGER is defined in the environment, use it.
1115     defined $ENV{PAGER}
1116     ? $ENV{PAGER}
1117
1118       # If not, see if Config.pm defines it.
1119     : eval { require Config }
1120       && defined $Config::Config{pager}
1121     ? $Config::Config{pager}
1122
1123       # If not, fall back to 'more'.
1124     : 'more'
1125   )
1126   unless defined $pager;
1127
1128 =pod
1129
1130 We set up the command to be used to access the man pages, the command
1131 recall character (C<!> unless otherwise defined) and the shell escape
1132 character (C<!> unless otherwise defined). Yes, these do conflict, and
1133 neither works in the debugger at the moment.
1134
1135 =cut
1136
1137 setman();
1138
1139 # Set up defaults for command recall and shell escape (note:
1140 # these currently don't work in linemode debugging).
1141 recallCommand("!") unless defined $prc;
1142 shellBang("!")     unless defined $psh;
1143
1144 =pod
1145
1146 We then set up the gigantic string containing the debugger help.
1147 We also set the limit on the number of arguments we'll display during a
1148 trace.
1149
1150 =cut
1151
1152 sethelp();
1153
1154 # If we didn't get a default for the length of eval/stack trace args,
1155 # set it here.
1156 $maxtrace = 400 unless defined $maxtrace;
1157
1158 =head2 SETTING UP THE DEBUGGER GREETING
1159
1160 The debugger I<greeting> helps to inform the user how many debuggers are
1161 running, and whether the current debugger is the primary or a child.
1162
1163 If we are the primary, we just hang onto our pid so we'll have it when
1164 or if we start a child debugger. If we are a child, we'll set things up
1165 so we'll have a unique greeting and so the parent will give us our own
1166 TTY later.
1167
1168 We save the current contents of the C<PERLDB_PIDS> environment variable
1169 because we mess around with it. We'll also need to hang onto it because
1170 we'll need it if we restart.
1171
1172 Child debuggers make a label out of the current PID structure recorded in
1173 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1174 yet so the parent will give them one later via C<resetterm()>.
1175
1176 =cut
1177
1178 # Save the current contents of the environment; we're about to
1179 # much with it. We'll need this if we have to restart.
1180 use vars qw($ini_pids);
1181 $ini_pids = $ENV{PERLDB_PIDS};
1182
1183 use vars qw ($pids $term_pid);
1184
1185 if ( defined $ENV{PERLDB_PIDS} ) {
1186
1187     # We're a child. Make us a label out of the current PID structure
1188     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1189     # a term yet so the parent will give us one later via resetterm().
1190
1191     my $env_pids = $ENV{PERLDB_PIDS};
1192     $pids = "[$env_pids]";
1193
1194     # Unless we are on OpenVMS, all programs under the DCL shell run under
1195     # the same PID.
1196
1197     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1198         $term_pid         = $$;
1199     }
1200     else {
1201         $ENV{PERLDB_PIDS} .= "->$$";
1202         $term_pid = -1;
1203     }
1204
1205 } ## end if (defined $ENV{PERLDB_PIDS...
1206 else {
1207
1208     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1209     # child debugger, and mark us as the parent, so we'll know to set up
1210     # more TTY's is we have to.
1211     $ENV{PERLDB_PIDS} = "$$";
1212     $pids             = "[pid=$$]";
1213     $term_pid         = $$;
1214 }
1215
1216 use vars qw($pidprompt);
1217 $pidprompt = '';
1218
1219 # Sets up $emacs as a synonym for $slave_editor.
1220 our ($slave_editor);
1221 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1222
1223 =head2 READING THE RC FILE
1224
1225 The debugger will read a file of initialization options if supplied. If
1226 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1227
1228 =cut
1229
1230 # As noted, this test really doesn't check accurately that the debugger
1231 # is running at a terminal or not.
1232
1233 use vars qw($rcfile);
1234 {
1235     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1236     # this is the wrong metric!
1237     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1238 }
1239
1240 =pod
1241
1242 The debugger does a safety test of the file to be read. It must be owned
1243 either by the current user or root, and must only be writable by the owner.
1244
1245 =cut
1246
1247 # This wraps a safety test around "do" to read and evaluate the init file.
1248 #
1249 # This isn't really safe, because there's a race
1250 # between checking and opening.  The solution is to
1251 # open and fstat the handle, but then you have to read and
1252 # eval the contents.  But then the silly thing gets
1253 # your lexical scope, which is unfortunate at best.
1254 sub safe_do {
1255     my $file = shift;
1256
1257     # Just exactly what part of the word "CORE::" don't you understand?
1258     local $SIG{__WARN__};
1259     local $SIG{__DIE__};
1260
1261     unless ( is_safe_file($file) ) {
1262         CORE::warn <<EO_GRIPE;
1263 perldb: Must not source insecure rcfile $file.
1264         You or the superuser must be the owner, and it must not
1265         be writable by anyone but its owner.
1266 EO_GRIPE
1267         return;
1268     } ## end unless (is_safe_file($file...
1269
1270     do $file;
1271     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1272 } ## end sub safe_do
1273
1274 # This is the safety test itself.
1275 #
1276 # Verifies that owner is either real user or superuser and that no
1277 # one but owner may write to it.  This function is of limited use
1278 # when called on a path instead of upon a handle, because there are
1279 # no guarantees that filename (by dirent) whose file (by ino) is
1280 # eventually accessed is the same as the one tested.
1281 # Assumes that the file's existence is not in doubt.
1282 sub is_safe_file {
1283     my $path = shift;
1284     stat($path) || return;    # mysteriously vaporized
1285     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1286
1287     return 0 if $uid != 0 && $uid != $<;
1288     return 0 if $mode & 022;
1289     return 1;
1290 } ## end sub is_safe_file
1291
1292 # If the rcfile (whichever one we decided was the right one to read)
1293 # exists, we safely do it.
1294 if ( -f $rcfile ) {
1295     safe_do("./$rcfile");
1296 }
1297
1298 # If there isn't one here, try the user's home directory.
1299 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1300     safe_do("$ENV{HOME}/$rcfile");
1301 }
1302
1303 # Else try the login directory.
1304 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1305     safe_do("$ENV{LOGDIR}/$rcfile");
1306 }
1307
1308 # If the PERLDB_OPTS variable has options in it, parse those out next.
1309 if ( defined $ENV{PERLDB_OPTS} ) {
1310     parse_options( $ENV{PERLDB_OPTS} );
1311 }
1312
1313 =pod
1314
1315 The last thing we do during initialization is determine which subroutine is
1316 to be used to obtain a new terminal when a new debugger is started. Right now,
1317 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1318 (darwin).
1319
1320 =cut
1321
1322 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1323 # Works if you're running an xterm or xterm-like window, or you're on
1324 # OS/2, or on Mac OS X. This may need some expansion.
1325
1326 if (not defined &get_fork_TTY)       # only if no routine exists
1327 {
1328     if ( defined $remoteport ) {
1329                                                  # Expect an inetd-like server
1330         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1331     }
1332     elsif (defined $ENV{TERM}                    # If we know what kind
1333                                                  # of terminal this is,
1334         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1335         and defined $ENV{DISPLAY}                # and what display it's on,
1336       )
1337     {
1338         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1339     }
1340     elsif ( $ENV{TMUX} ) {
1341         *get_fork_TTY = \&tmux_get_fork_TTY;
1342     }
1343     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1344         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1345     }
1346     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1347             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1348             and $ENV{TERM_PROGRAM}
1349                 eq 'Apple_Terminal'              # Terminal.app
1350             )
1351     {
1352         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1353     }
1354 } ## end if (not defined &get_fork_TTY...
1355
1356 # untaint $^O, which may have been tainted by the last statement.
1357 # see bug [perl #24674]
1358 $^O =~ m/^(.*)\z/;
1359 $^O = $1;
1360
1361 # Here begin the unreadable code.  It needs fixing.
1362
1363 =head2 RESTART PROCESSING
1364
1365 This section handles the restart command. When the C<R> command is invoked, it
1366 tries to capture all of the state it can into environment variables, and
1367 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1368 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1369 the R command stuffed into the environment variables.
1370
1371   PERLDB_RESTART   - flag only, contains no restart data itself.
1372   PERLDB_HIST      - command history, if it's available
1373   PERLDB_ON_LOAD   - breakpoints set by the rc file
1374   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1375                      and have actions
1376   PERLDB_VISITED   - files that had breakpoints
1377   PERLDB_FILE_...  - breakpoints for a file
1378   PERLDB_OPT       - active options
1379   PERLDB_INC       - the original @INC
1380   PERLDB_PRETYPE   - preprompt debugger actions
1381   PERLDB_PRE       - preprompt Perl code
1382   PERLDB_POST      - post-prompt Perl code
1383   PERLDB_TYPEAHEAD - typeahead captured by readline()
1384
1385 We chug through all these variables and plug the values saved in them
1386 back into the appropriate spots in the debugger.
1387
1388 =cut
1389
1390 use vars qw(%postponed_file @typeahead);
1391
1392 our (@hist, @truehist);
1393
1394 sub _restore_shared_globals_after_restart
1395 {
1396     @hist          = get_list('PERLDB_HIST');
1397     %break_on_load = get_list("PERLDB_ON_LOAD");
1398     %postponed     = get_list("PERLDB_POSTPONE");
1399
1400     share(@hist);
1401     share(@truehist);
1402     share(%break_on_load);
1403     share(%postponed);
1404 }
1405
1406 sub _restore_breakpoints_and_actions {
1407
1408     my @had_breakpoints = get_list("PERLDB_VISITED");
1409
1410     for my $file_idx ( 0 .. $#had_breakpoints ) {
1411         my $filename = $had_breakpoints[$file_idx];
1412         my %pf = get_list("PERLDB_FILE_$file_idx");
1413         $postponed_file{ $filename } = \%pf if %pf;
1414         my @lines = sort {$a <=> $b} keys(%pf);
1415         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1416         for my $line_idx (0 .. $#lines) {
1417             _set_breakpoint_enabled_status(
1418                 $filename,
1419                 $lines[$line_idx],
1420                 ($enabled_statuses[$line_idx] ? 1 : ''),
1421             );
1422         }
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_options_after_restart
1429 {
1430     my %options_map = get_list("PERLDB_OPT");
1431
1432     while ( my ( $opt, $val ) = each %options_map ) {
1433         $val =~ s/[\\\']/\\$1/g;
1434         parse_options("$opt'$val'");
1435     }
1436
1437     return;
1438 }
1439
1440 sub _restore_globals_after_restart
1441 {
1442     # restore original @INC
1443     @INC     = get_list("PERLDB_INC");
1444     @ini_INC = @INC;
1445
1446     # return pre/postprompt actions and typeahead buffer
1447     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1448     $pre       = [ get_list("PERLDB_PRE") ];
1449     $post      = [ get_list("PERLDB_POST") ];
1450     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1451
1452     return;
1453 }
1454
1455
1456 if ( exists $ENV{PERLDB_RESTART} ) {
1457
1458     # We're restarting, so we don't need the flag that says to restart anymore.
1459     delete $ENV{PERLDB_RESTART};
1460
1461     # $restart = 1;
1462     _restore_shared_globals_after_restart();
1463
1464     _restore_breakpoints_and_actions();
1465
1466     # restore options
1467     _restore_options_after_restart();
1468
1469     _restore_globals_after_restart();
1470 } ## end if (exists $ENV{PERLDB_RESTART...
1471
1472 =head2 SETTING UP THE TERMINAL
1473
1474 Now, we'll decide how the debugger is going to interact with the user.
1475 If there's no TTY, we set the debugger to run non-stop; there's not going
1476 to be anyone there to enter commands.
1477
1478 =cut
1479
1480 use vars qw($notty $console $tty $LINEINFO);
1481 use vars qw($lineinfo $doccmd);
1482
1483 our ($runnonstop);
1484
1485 # Local autoflush to avoid rt#116769,
1486 # as calling IO::File methods causes an unresolvable loop
1487 # that results in debugger failure.
1488 sub _autoflush {
1489     my $o = select($_[0]);
1490     $|++;
1491     select($o);
1492 }
1493
1494 if ($notty) {
1495     $runnonstop = 1;
1496     share($runnonstop);
1497 }
1498
1499 =pod
1500
1501 If there is a TTY, we have to determine who it belongs to before we can
1502 proceed. If this is a slave editor or graphical debugger (denoted by
1503 the first command-line switch being '-emacs'), we shift this off and
1504 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1505
1506 =cut
1507
1508 else {
1509
1510     # Is Perl being run from a slave editor or graphical debugger?
1511     # If so, don't use readline, and set $slave_editor = 1.
1512     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1513         $rl = 0;
1514         shift(@main::ARGV);
1515     }
1516
1517     #require Term::ReadLine;
1518
1519 =pod
1520
1521 We then determine what the console should be on various systems:
1522
1523 =over 4
1524
1525 =item * Cygwin - We use C<stdin> instead of a separate device.
1526
1527 =cut
1528
1529     if ( $^O eq 'cygwin' ) {
1530
1531         # /dev/tty is binary. use stdin for textmode
1532         undef $console;
1533     }
1534
1535 =item * Unix - use F</dev/tty>.
1536
1537 =cut
1538
1539     elsif ( -e "/dev/tty" ) {
1540         $console = "/dev/tty";
1541     }
1542
1543 =item * Windows or MSDOS - use C<con>.
1544
1545 =cut
1546
1547     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1548         $console = "con";
1549     }
1550
1551 =item * AmigaOS - use C<CONSOLE:>.
1552
1553 =cut
1554
1555     elsif ( $^O eq 'amigaos' ) {
1556         $console = "CONSOLE:";
1557     }
1558
1559 =item * VMS - use C<sys$command>.
1560
1561 =cut
1562
1563     elsif ($^O eq 'VMS') {
1564         $console = 'sys$command';
1565     }
1566
1567 # Keep this last.
1568
1569     else {
1570         _db_warn("Can't figure out your console, using stdin");
1571         undef $console;
1572     }
1573
1574 =pod
1575
1576 =back
1577
1578 Several other systems don't use a specific console. We C<undef $console>
1579 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1580 with a slave editor).
1581
1582 =cut
1583
1584     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1585
1586         # /dev/tty is binary. use stdin for textmode
1587         $console = undef;
1588     }
1589
1590     if ( $^O eq 'NetWare' ) {
1591
1592         # /dev/tty is binary. use stdin for textmode
1593         $console = undef;
1594     }
1595
1596     # In OS/2, we need to use STDIN to get textmode too, even though
1597     # it pretty much looks like Unix otherwise.
1598     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1599     {    # In OS/2
1600         $console = undef;
1601     }
1602
1603 =pod
1604
1605 If there is a TTY hanging around from a parent, we use that as the console.
1606
1607 =cut
1608
1609     $console = $tty if defined $tty;
1610
1611 =head2 SOCKET HANDLING
1612
1613 The debugger is capable of opening a socket and carrying out a debugging
1614 session over the socket.
1615
1616 If C<RemotePort> was defined in the options, the debugger assumes that it
1617 should try to start a debugging session on that port. It builds the socket
1618 and then tries to connect the input and output filehandles to it.
1619
1620 =cut
1621
1622     # Handle socket stuff.
1623
1624     if ( defined $remoteport ) {
1625
1626         # If RemotePort was defined in the options, connect input and output
1627         # to the socket.
1628         $IN = $OUT = connect_remoteport();
1629     } ## end if (defined $remoteport)
1630
1631 =pod
1632
1633 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1634 this is probably a situation where multiple debuggers are running (for example,
1635 a backticked command that starts up another debugger). We create a new IN and
1636 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1637 and if we can.
1638
1639 =cut
1640
1641     # Non-socket.
1642     else {
1643
1644         # Two debuggers running (probably a system or a backtick that invokes
1645         # the debugger itself under the running one). create a new IN and OUT
1646         # filehandle, and do the necessary mojo to create a new tty if we
1647         # know how, and we can.
1648         create_IN_OUT(4) if $CreateTTY & 4;
1649         if ($console) {
1650
1651             # If we have a console, check to see if there are separate ins and
1652             # outs to open. (They are assumed identical if not.)
1653
1654             my ( $i, $o ) = split /,/, $console;
1655             $o = $i unless defined $o;
1656
1657             # read/write on in, or just read, or read on STDIN.
1658             open( IN,      "+<$i" )
1659               || open( IN, "<$i" )
1660               || open( IN, "<&STDIN" );
1661
1662             # read/write/create/clobber out, or write/create/clobber out,
1663             # or merge with STDERR, or merge with STDOUT.
1664                  open( OUT, "+>$o" )
1665               || open( OUT, ">$o" )
1666               || open( OUT, ">&STDERR" )
1667               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1668
1669         } ## end if ($console)
1670         elsif ( not defined $console ) {
1671
1672             # No console. Open STDIN.
1673             open( IN, "<&STDIN" );
1674
1675             # merge with STDERR, or with STDOUT.
1676             open( OUT,      ">&STDERR" )
1677               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1678             $console = 'STDIN/OUT';
1679         } ## end elsif (not defined $console)
1680
1681         # Keep copies of the filehandles so that when the pager runs, it
1682         # can close standard input without clobbering ours.
1683         if ($console or (not defined($console))) {
1684             $IN = \*IN;
1685             $OUT = \*OUT;
1686         }
1687     } ## end elsif (from if(defined $remoteport))
1688
1689     # Unbuffer DB::OUT. We need to see responses right away.
1690     _autoflush($OUT);
1691
1692     # Line info goes to debugger output unless pointed elsewhere.
1693     # Pointing elsewhere makes it possible for slave editors to
1694     # keep track of file and position. We have both a filehandle
1695     # and a I/O description to keep track of.
1696     $LINEINFO = $OUT     unless defined $LINEINFO;
1697     $lineinfo = $console unless defined $lineinfo;
1698     # share($LINEINFO); # <- unable to share globs
1699     share($lineinfo);   #
1700
1701 =pod
1702
1703 To finish initialization, we show the debugger greeting,
1704 and then call the C<afterinit()> subroutine if there is one.
1705
1706 =cut
1707
1708     # Show the debugger greeting.
1709     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1710     unless ($runnonstop) {
1711         local $\ = '';
1712         local $, = '';
1713         if ( $term_pid eq '-1' ) {
1714             print $OUT "\nDaughter DB session started...\n";
1715         }
1716         else {
1717             print $OUT "\nLoading DB routines from $header\n";
1718             print $OUT (
1719                 "Editor support ",
1720                 $slave_editor ? "enabled" : "available", ".\n"
1721             );
1722             print $OUT
1723 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1724         } ## end else [ if ($term_pid eq '-1')
1725     } ## end unless ($runnonstop)
1726 } ## end else [ if ($notty)
1727
1728 # XXX This looks like a bug to me.
1729 # Why copy to @ARGS and then futz with @args?
1730 @ARGS = @ARGV;
1731 # for (@args) {
1732     # Make sure backslashes before single quotes are stripped out, and
1733     # keep args unless they are numeric (XXX why?)
1734     # s/\'/\\\'/g;                      # removed while not justified understandably
1735     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1736 # }
1737
1738 # If there was an afterinit() sub defined, call it. It will get
1739 # executed in our scope, so it can fiddle with debugger globals.
1740 if ( defined &afterinit ) {    # May be defined in $rcfile
1741     afterinit();
1742 }
1743
1744 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1745 use vars qw($I_m_init);
1746
1747 $I_m_init = 1;
1748
1749 ############################################################ Subroutines
1750
1751 =head1 SUBROUTINES
1752
1753 =head2 DB
1754
1755 This gigantic subroutine is the heart of the debugger. Called before every
1756 statement, its job is to determine if a breakpoint has been reached, and
1757 stop if so; read commands from the user, parse them, and execute
1758 them, and then send execution off to the next statement.
1759
1760 Note that the order in which the commands are processed is very important;
1761 some commands earlier in the loop will actually alter the C<$cmd> variable
1762 to create other commands to be executed later. This is all highly I<optimized>
1763 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1764 see what's happening in any given command.
1765
1766 =cut
1767
1768 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1769
1770 use vars qw(
1771     $action
1772     $cmd
1773     $file
1774     $filename_ini
1775     $finished
1776     %had_breakpoints
1777     $level
1778     $max
1779     $package
1780     $try
1781 );
1782
1783 our (
1784     %alias,
1785     $doret,
1786     $end,
1787     $fall_off_end,
1788     $incr,
1789     $laststep,
1790     $rc,
1791     $sh,
1792     $stack_depth,
1793     @stack,
1794     @to_watch,
1795     @old_watch,
1796 );
1797
1798 sub _DB__determine_if_we_should_break
1799 {
1800     # if we have something here, see if we should break.
1801     # $stop is lexical and local to this block - $action on the other hand
1802     # is global.
1803     my $stop;
1804
1805     if ( $dbline{$line}
1806         && _is_breakpoint_enabled($filename, $line)
1807         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1808     {
1809
1810         # Stop if the stop criterion says to just stop.
1811         if ( $stop eq '1' ) {
1812             $signal |= 1;
1813         }
1814
1815         # It's a conditional stop; eval it in the user's context and
1816         # see if we should stop. If so, remove the one-time sigil.
1817         elsif ($stop) {
1818             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1819             # The &-call is here to ascertain the mutability of @_.
1820             &DB::eval;
1821             # If the breakpoint is temporary, then delete its enabled status.
1822             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1823                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1824             }
1825         }
1826     } ## end if ($dbline{$line} && ...
1827 }
1828
1829 sub _DB__is_finished {
1830     if ($finished and $level <= 1) {
1831         end_report();
1832         return 1;
1833     }
1834     else {
1835         return;
1836     }
1837 }
1838
1839 sub _DB__read_next_cmd
1840 {
1841     my ($tid) = @_;
1842
1843     # We have a terminal, or can get one ...
1844     if (!$term) {
1845         setterm();
1846     }
1847
1848     # ... and it belongs to this PID or we get one for this PID ...
1849     if ($term_pid != $$) {
1850         resetterm(1);
1851     }
1852
1853     # ... and we got a line of command input ...
1854     $cmd = DB::readline(
1855         "$pidprompt $tid DB"
1856         . ( '<' x $level )
1857         . ( $#hist + 1 )
1858         . ( '>' x $level ) . " "
1859     );
1860
1861     return defined($cmd);
1862 }
1863
1864 sub _DB__trim_command_and_return_first_component {
1865     my ($obj) = @_;
1866
1867     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1868     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1869
1870     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1871
1872     $obj->cmd_verb($verb);
1873     $obj->cmd_args($args);
1874
1875     return;
1876 }
1877
1878 sub _DB__handle_f_command {
1879     my ($obj) = @_;
1880
1881     if ($file = $obj->cmd_args) {
1882         # help for no arguments (old-style was return from sub).
1883         if ( !$file ) {
1884             print $OUT
1885             "The old f command is now the r command.\n";    # hint
1886             print $OUT "The new f command switches filenames.\n";
1887             next CMD;
1888         } ## end if (!$file)
1889
1890         # if not in magic file list, try a close match.
1891         if ( !defined $main::{ '_<' . $file } ) {
1892             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1893                 {
1894                     $try = substr( $try, 2 );
1895                     print $OUT "Choosing $try matching '$file':\n";
1896                     $file = $try;
1897                 }
1898             } ## end if (($try) = grep(m#^_<.*$file#...
1899         } ## end if (!defined $main::{ ...
1900
1901         # If not successfully switched now, we failed.
1902         if ( !defined $main::{ '_<' . $file } ) {
1903             print $OUT "No file matching '$file' is loaded.\n";
1904             next CMD;
1905         }
1906
1907         # We switched, so switch the debugger internals around.
1908         elsif ( $file ne $filename ) {
1909             *dbline   = $main::{ '_<' . $file };
1910             $max      = $#dbline;
1911             $filename = $file;
1912             $start    = 1;
1913             $cmd      = "l";
1914         } ## end elsif ($file ne $filename)
1915
1916         # We didn't switch; say we didn't.
1917         else {
1918             print $OUT "Already in $file.\n";
1919             next CMD;
1920         }
1921     }
1922
1923     return;
1924 }
1925
1926 sub _DB__handle_dot_command {
1927     my ($obj) = @_;
1928
1929     # . command.
1930     if ($obj->_is_full('.')) {
1931         $incr = -1;    # stay at current line
1932
1933         # Reset everything to the old location.
1934         $start    = $line;
1935         $filename = $filename_ini;
1936         *dbline   = $main::{ '_<' . $filename };
1937         $max      = $#dbline;
1938
1939         # Now where are we?
1940         print_lineinfo($obj->position());
1941         next CMD;
1942     }
1943
1944     return;
1945 }
1946
1947 sub _DB__handle_y_command {
1948     my ($obj) = @_;
1949
1950     if (my ($match_level, $match_vars)
1951         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1952
1953         # See if we've got the necessary support.
1954         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1955             my $Err = $@;
1956             _db_warn(
1957                 $Err =~ /locate/
1958                 ? "PadWalker module not found - please install\n"
1959                 : $Err
1960             );
1961             next CMD;
1962         }
1963
1964         # Load up dumpvar if we don't have it. If we can, that is.
1965         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1966         defined &main::dumpvar
1967             or print $OUT "dumpvar.pl not available.\n"
1968             and next CMD;
1969
1970         # Got all the modules we need. Find them and print them.
1971         my @vars = split( ' ', $match_vars || '' );
1972
1973         # Find the pad.
1974         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1975
1976         # Oops. Can't find it.
1977         if (my $Err = $@) {
1978             $Err =~ s/ at .*//;
1979             _db_warn($Err);
1980             next CMD;
1981         }
1982
1983         # Show the desired vars with dumplex().
1984         my $savout = select($OUT);
1985
1986         # Have dumplex dump the lexicals.
1987         foreach my $key (sort keys %$h) {
1988             dumpvar::dumplex( $key, $h->{$key},
1989                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1990                 @vars );
1991         }
1992         select($savout);
1993         next CMD;
1994     }
1995 }
1996
1997 sub _DB__handle_c_command {
1998     my ($obj) = @_;
1999
2000     my $i = $obj->cmd_args;
2001
2002     if ($i =~ m#\A[\w:]*\z#) {
2003
2004         # Hey, show's over. The debugged program finished
2005         # executing already.
2006         next CMD if _DB__is_finished();
2007
2008         # Capture the place to put a one-time break.
2009         $subname = $i;
2010
2011         #  Probably not needed, since we finish an interactive
2012         #  sub-session anyway...
2013         # local $filename = $filename;
2014         # local *dbline = *dbline; # XXX Would this work?!
2015         #
2016         # The above question wonders if localizing the alias
2017         # to the magic array works or not. Since it's commented
2018         # out, we'll just leave that to speculation for now.
2019
2020         # If the "subname" isn't all digits, we'll assume it
2021         # is a subroutine name, and try to find it.
2022         if ( $subname =~ /\D/ ) {    # subroutine name
2023             # Qualify it to the current package unless it's
2024             # already qualified.
2025             $subname = $package . "::" . $subname
2026             unless $subname =~ /::/;
2027
2028             # find_sub will return "file:line_number" corresponding
2029             # to where the subroutine is defined; we call find_sub,
2030             # break up the return value, and assign it in one
2031             # operation.
2032             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2033
2034             # Force the line number to be numeric.
2035             $i = $i + 0;
2036
2037             # If we got a line number, we found the sub.
2038             if ($i) {
2039
2040                 # Switch all the debugger's internals around so
2041                 # we're actually working with that file.
2042                 $filename = $file;
2043                 *dbline   = $main::{ '_<' . $filename };
2044
2045                 # Mark that there's a breakpoint in this file.
2046                 $had_breakpoints{$filename} |= 1;
2047
2048                 # Scan forward to the first executable line
2049                 # after the 'sub whatever' line.
2050                 $max = $#dbline;
2051                 my $_line_num = $i;
2052                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2053                 {
2054                     $_line_num++;
2055                 }
2056                 $i = $_line_num;
2057             } ## end if ($i)
2058
2059             # We didn't find a sub by that name.
2060             else {
2061                 print $OUT "Subroutine $subname not found.\n";
2062                 next CMD;
2063             }
2064         } ## end if ($subname =~ /\D/)
2065
2066         # At this point, either the subname was all digits (an
2067         # absolute line-break request) or we've scanned through
2068         # the code following the definition of the sub, looking
2069         # for an executable, which we may or may not have found.
2070         #
2071         # If $i (which we set $subname from) is non-zero, we
2072         # got a request to break at some line somewhere. On
2073         # one hand, if there wasn't any real subroutine name
2074         # involved, this will be a request to break in the current
2075         # file at the specified line, so we have to check to make
2076         # sure that the line specified really is breakable.
2077         #
2078         # On the other hand, if there was a subname supplied, the
2079         # preceding block has moved us to the proper file and
2080         # location within that file, and then scanned forward
2081         # looking for the next executable line. We have to make
2082         # sure that one was found.
2083         #
2084         # On the gripping hand, we can't do anything unless the
2085         # current value of $i points to a valid breakable line.
2086         # Check that.
2087         if ($i) {
2088
2089             # Breakable?
2090             if ( $dbline[$i] == 0 ) {
2091                 print $OUT "Line $i not breakable.\n";
2092                 next CMD;
2093             }
2094
2095             # Yes. Set up the one-time-break sigil.
2096             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2097             _enable_breakpoint_temp_enabled_status($filename, $i);
2098         } ## end if ($i)
2099
2100         # Turn off stack tracing from here up.
2101         for my $j (0 .. $stack_depth) {
2102             $stack[ $j ] &= ~1;
2103         }
2104         last CMD;
2105     }
2106
2107     return;
2108 }
2109
2110 sub _DB__handle_forward_slash_command {
2111     my ($obj) = @_;
2112
2113     # The pattern as a string.
2114     use vars qw($inpat);
2115
2116     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2117
2118         # Remove the final slash.
2119         $inpat =~ s:([^\\])/$:$1:;
2120
2121         # If the pattern isn't null ...
2122         if ( $inpat ne "" ) {
2123
2124             # Turn off warn and die processing for a bit.
2125             local $SIG{__DIE__};
2126             local $SIG{__WARN__};
2127
2128             # Create the pattern.
2129             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2130             if ( $@ ne "" ) {
2131
2132                 # Oops. Bad pattern. No biscuit.
2133                 # Print the eval error and go back for more
2134                 # commands.
2135                 print {$OUT} "$@";
2136                 next CMD;
2137             }
2138             $obj->pat($inpat);
2139         } ## end if ($inpat ne "")
2140
2141         # Set up to stop on wrap-around.
2142         $end = $start;
2143
2144         # Don't move off the current line.
2145         $incr = -1;
2146
2147         my $pat = $obj->pat;
2148
2149         # Done in eval so nothing breaks if the pattern
2150         # does something weird.
2151         eval
2152         {
2153             no strict q/vars/;
2154             for (;;) {
2155                 # Move ahead one line.
2156                 ++$start;
2157
2158                 # Wrap if we pass the last line.
2159                 if ($start > $max) {
2160                     $start = 1;
2161                 }
2162
2163                 # Stop if we have gotten back to this line again,
2164                 last if ($start == $end);
2165
2166                 # A hit! (Note, though, that we are doing
2167                 # case-insensitive matching. Maybe a qr//
2168                 # expression would be better, so the user could
2169                 # do case-sensitive matching if desired.
2170                 if ($dbline[$start] =~ m/$pat/i) {
2171                     if ($slave_editor) {
2172                         # Handle proper escaping in the slave.
2173                         print {$OUT} "\032\032$filename:$start:0\n";
2174                     }
2175                     else {
2176                         # Just print the line normally.
2177                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2178                     }
2179                     # And quit since we found something.
2180                     last;
2181                 }
2182             }
2183         };
2184
2185         if ($@) {
2186             warn $@;
2187         }
2188
2189         # If we wrapped, there never was a match.
2190         if ( $start == $end ) {
2191             print {$OUT} "/$pat/: not found\n";
2192         }
2193         next CMD;
2194     }
2195
2196     return;
2197 }
2198
2199 sub _DB__handle_question_mark_command {
2200     my ($obj) = @_;
2201
2202     # ? - backward pattern search.
2203     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2204
2205         # Get the pattern, remove trailing question mark.
2206         $inpat =~ s:([^\\])\?$:$1:;
2207
2208         # If we've got one ...
2209         if ( $inpat ne "" ) {
2210
2211             # Turn off die & warn handlers.
2212             local $SIG{__DIE__};
2213             local $SIG{__WARN__};
2214             eval '$inpat =~ m' . "\a$inpat\a";
2215
2216             if ( $@ ne "" ) {
2217
2218                 # Ouch. Not good. Print the error.
2219                 print $OUT $@;
2220                 next CMD;
2221             }
2222             $obj->pat($inpat);
2223         } ## end if ($inpat ne "")
2224
2225         # Where we are now is where to stop after wraparound.
2226         $end = $start;
2227
2228         # Don't move away from this line.
2229         $incr = -1;
2230
2231         my $pat = $obj->pat;
2232         # Search inside the eval to prevent pattern badness
2233         # from killing us.
2234         eval {
2235             no strict q/vars/;
2236             for (;;) {
2237                 # Back up a line.
2238                 --$start;
2239
2240                 # Wrap if we pass the first line.
2241
2242                 $start = $max if ($start <= 0);
2243
2244                 # Quit if we get back where we started,
2245                 last if ($start == $end);
2246
2247                 # Match?
2248                 if ($dbline[$start] =~ m/$pat/i) {
2249                     if ($slave_editor) {
2250                         # Yep, follow slave editor requirements.
2251                         print $OUT "\032\032$filename:$start:0\n";
2252                     }
2253                     else {
2254                         # Yep, just print normally.
2255                         print $OUT "$start:\t",$dbline[$start],"\n";
2256                     }
2257
2258                     # Found, so done.
2259                     last;
2260                 }
2261             }
2262         };
2263
2264         # Say we failed if the loop never found anything,
2265         if ( $start == $end ) {
2266             print {$OUT} "?$pat?: not found\n";
2267         }
2268         next CMD;
2269     }
2270
2271     return;
2272 }
2273
2274 sub _DB__handle_restart_and_rerun_commands {
2275     my ($obj) = @_;
2276
2277     my $cmd_cmd = $obj->cmd_verb;
2278     my $cmd_params = $obj->cmd_args;
2279     # R - restart execution.
2280     # rerun - controlled restart execution.
2281     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2282
2283         # Change directory to the initial current working directory on
2284         # the script startup, so if the debugged program changed the
2285         # directory, then we will still be able to find the path to the
2286         # the program. (perl 5 RT #121509 ).
2287         chdir ($_initial_cwd);
2288
2289         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2290
2291         # Close all non-system fds for a clean restart.  A more
2292         # correct method would be to close all fds that were not
2293         # open when the process started, but this seems to be
2294         # hard.  See "debugger 'R'estart and open database
2295         # connections" on p5p.
2296
2297         my $max_fd = 1024; # default if POSIX can't be loaded
2298         if (eval { require POSIX }) {
2299             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2300         }
2301
2302         if (defined $max_fd) {
2303             foreach ($^F+1 .. $max_fd-1) {
2304                 next unless open FD_TO_CLOSE, "<&=$_";
2305                 close(FD_TO_CLOSE);
2306             }
2307         }
2308
2309         # And run Perl again.  We use exec() to keep the
2310         # PID stable (and that way $ini_pids is still valid).
2311         exec(@args) or print {$OUT} "exec failed: $!\n";
2312
2313         last CMD;
2314     }
2315
2316     return;
2317 }
2318
2319 sub _DB__handle_run_command_in_pager_command {
2320     my ($obj) = @_;
2321
2322     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2323         if ( $pager =~ /^\|/ ) {
2324
2325             # Default pager is into a pipe. Redirect I/O.
2326             open( SAVEOUT, ">&STDOUT" )
2327             || _db_warn("Can't save STDOUT");
2328             open( STDOUT, ">&OUT" )
2329             || _db_warn("Can't redirect STDOUT");
2330         } ## end if ($pager =~ /^\|/)
2331         else {
2332
2333             # Not into a pipe. STDOUT is safe.
2334             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2335         }
2336
2337         # Fix up environment to record we have less if so.
2338         fix_less();
2339
2340         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2341
2342             # Couldn't open pipe to pager.
2343             _db_warn("Can't pipe output to '$pager'");
2344             if ( $pager =~ /^\|/ ) {
2345
2346                 # Redirect I/O back again.
2347                 open( OUT, ">&STDOUT" )    # XXX: lost message
2348                 || _db_warn("Can't restore DB::OUT");
2349                 open( STDOUT, ">&SAVEOUT" )
2350                 || _db_warn("Can't restore STDOUT");
2351                 close(SAVEOUT);
2352             } ## end if ($pager =~ /^\|/)
2353             else {
2354
2355                 # Redirect I/O. STDOUT already safe.
2356                 open( OUT, ">&STDOUT" )    # XXX: lost message
2357                 || _db_warn("Can't restore DB::OUT");
2358             }
2359             next CMD;
2360         } ## end unless ($piped = open(OUT,...
2361
2362         # Set up broken-pipe handler if necessary.
2363         $SIG{PIPE} = \&DB::catch
2364         if $pager =~ /^\|/
2365         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2366
2367         _autoflush(\*OUT);
2368         # Save current filehandle, and put it back.
2369         $obj->selected(scalar( select(OUT) ));
2370         # Don't put it back if pager was a pipe.
2371         if ($cmd !~ /\A\|\|/)
2372         {
2373             select($obj->selected());
2374             $obj->selected("");
2375         }
2376
2377         # Trim off the pipe symbols and run the command now.
2378         $cmd =~ s#\A\|+\s*##;
2379         redo PIPE;
2380     }
2381
2382     return;
2383 }
2384
2385 sub _DB__handle_m_command {
2386     my ($obj) = @_;
2387
2388     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2389         methods($1);
2390         next CMD;
2391     }
2392
2393     # m expr - set up DB::eval to do the work
2394     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2395         $onetimeDump = 'methods';   #  method output gets used there
2396     }
2397
2398     return;
2399 }
2400
2401 sub _DB__at_end_of_every_command {
2402     my ($obj) = @_;
2403
2404     # At the end of every command:
2405     if ($obj->piped) {
2406
2407         # Unhook the pipe mechanism now.
2408         if ( $pager =~ /^\|/ ) {
2409
2410             # No error from the child.
2411             $? = 0;
2412
2413             # we cannot warn here: the handle is missing --tchrist
2414             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2415
2416             # most of the $? crud was coping with broken cshisms
2417             # $? is explicitly set to 0, so this never runs.
2418             if ($?) {
2419                 print SAVEOUT "Pager '$pager' failed: ";
2420                 if ( $? == -1 ) {
2421                     print SAVEOUT "shell returned -1\n";
2422                 }
2423                 elsif ( $? >> 8 ) {
2424                     print SAVEOUT ( $? & 127 )
2425                     ? " (SIG#" . ( $? & 127 ) . ")"
2426                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2427                 }
2428                 else {
2429                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2430                 }
2431             } ## end if ($?)
2432
2433             # Reopen filehandle for our output (if we can) and
2434             # restore STDOUT (if we can).
2435             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2436             open( STDOUT, ">&SAVEOUT" )
2437             || _db_warn("Can't restore STDOUT");
2438
2439             # Turn off pipe exception handler if necessary.
2440             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2441
2442             # Will stop ignoring SIGPIPE if done like nohup(1)
2443             # does SIGINT but Perl doesn't give us a choice.
2444         } ## end if ($pager =~ /^\|/)
2445         else {
2446
2447             # Non-piped "pager". Just restore STDOUT.
2448             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2449         }
2450
2451         # Let Readline know about the new filehandles.
2452         reset_IN_OUT( \*IN, \*OUT );
2453
2454         # Close filehandle pager was using, restore the normal one
2455         # if necessary,
2456         close(SAVEOUT);
2457
2458         if ($obj->selected() ne "") {
2459             select($obj->selected);
2460             $obj->selected("");
2461         }
2462
2463         # No pipes now.
2464         $obj->piped("");
2465     } ## end if ($piped)
2466
2467     return;
2468 }
2469
2470 sub _DB__handle_watch_expressions
2471 {
2472     my $self = shift;
2473
2474     if ( $DB::trace & 2 ) {
2475         for my $n (0 .. $#DB::to_watch) {
2476             $DB::evalarg = $DB::to_watch[$n];
2477             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2478
2479             # Fix context DB::eval() wants to return an array, but
2480             # we need a scalar here.
2481             my ($val) = join( "', '", DB::eval(@_) );
2482             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2483
2484             # Did it change?
2485             if ( $val ne $DB::old_watch[$n] ) {
2486
2487                 # Yep! Show the difference, and fake an interrupt.
2488                 $DB::signal = 1;
2489                 print {$DB::OUT} <<EOP;
2490 Watchpoint $n:\t$DB::to_watch[$n] changed:
2491     old value:\t$DB::old_watch[$n]
2492     new value:\t$val
2493 EOP
2494                 $DB::old_watch[$n] = $val;
2495             } ## end if ($val ne $old_watch...
2496         } ## end for my $n (0 ..
2497     } ## end if ($trace & 2)
2498
2499     return;
2500 }
2501
2502 # 't' is type.
2503 # 'm' is method.
2504 # 'v' is the value (i.e: method name or subroutine ref).
2505 # 's' is subroutine.
2506 my %cmd_lookup;
2507
2508 BEGIN
2509 {
2510     %cmd_lookup =
2511 (
2512     '-' => { t => 'm', v => '_handle_dash_command', },
2513     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2514     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2515     'H' => { t => 'm', v => '_handle_H_command', },
2516     'S' => { t => 'm', v => '_handle_S_command', },
2517     'T' => { t => 'm', v => '_handle_T_command', },
2518     'W' => { t => 'm', v => '_handle_W_command', },
2519     'c' => { t => 's', v => \&_DB__handle_c_command, },
2520     'f' => { t => 's', v => \&_DB__handle_f_command, },
2521     'm' => { t => 's', v => \&_DB__handle_m_command, },
2522     'n' => { t => 'm', v => '_handle_n_command', },
2523     'p' => { t => 'm', v => '_handle_p_command', },
2524     'q' => { t => 'm', v => '_handle_q_command', },
2525     'r' => { t => 'm', v => '_handle_r_command', },
2526     's' => { t => 'm', v => '_handle_s_command', },
2527     'save' => { t => 'm', v => '_handle_save_command', },
2528     'source' => { t => 'm', v => '_handle_source_command', },
2529     't' => { t => 'm', v => '_handle_t_command', },
2530     'w' => { t => 'm', v => '_handle_w_command', },
2531     'x' => { t => 'm', v => '_handle_x_command', },
2532     'y' => { t => 's', v => \&_DB__handle_y_command, },
2533     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2534         ('X', 'V')),
2535     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2536         qw(enable disable)),
2537     (map { $_ =>
2538         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2539         } qw(R rerun)),
2540     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2541         qw(a A b B e E h i l L M o O v w W)),
2542 );
2543 };
2544
2545 sub DB {
2546
2547     # lock the debugger and get the thread id for the prompt
2548     lock($DBGR);
2549     my $tid;
2550     my $position;
2551     my ($prefix, $after, $infix);
2552     my $pat;
2553     my $explicit_stop;
2554     my $piped;
2555     my $selected;
2556
2557     if ($ENV{PERL5DB_THREADED}) {
2558         $tid = eval { "[".threads->tid."]" };
2559     }
2560
2561     my $cmd_verb;
2562     my $cmd_args;
2563
2564     my $obj = DB::Obj->new(
2565         {
2566             position => \$position,
2567             prefix => \$prefix,
2568             after => \$after,
2569             explicit_stop => \$explicit_stop,
2570             infix => \$infix,
2571             cmd_args => \$cmd_args,
2572             cmd_verb => \$cmd_verb,
2573             pat => \$pat,
2574             piped => \$piped,
2575             selected => \$selected,
2576         },
2577     );
2578
2579     $obj->_DB_on_init__initialize_globals(@_);
2580
2581     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2582     # The code being debugged may have altered them.
2583     DB::save();
2584
2585     # Since DB::DB gets called after every line, we can use caller() to
2586     # figure out where we last were executing. Sneaky, eh? This works because
2587     # caller is returning all the extra information when called from the
2588     # debugger.
2589     local ( $package, $filename, $line ) = caller;
2590     $filename_ini = $filename;
2591
2592     # set up the context for DB::eval, so it can properly execute
2593     # code on behalf of the user. We add the package in so that the
2594     # code is eval'ed in the proper package (not in the debugger!).
2595     local $usercontext = _calc_usercontext($package);
2596
2597     # Create an alias to the active file magical array to simplify
2598     # the code here.
2599     local (*dbline) = $main::{ '_<' . $filename };
2600
2601     # Last line in the program.
2602     $max = $#dbline;
2603
2604     # The &-call is here to ascertain the mutability of @_.
2605     &_DB__determine_if_we_should_break;
2606
2607     # Preserve the current stop-or-not, and see if any of the W
2608     # (watch expressions) has changed.
2609     my $was_signal = $signal;
2610
2611     # If we have any watch expressions ...
2612     _DB__handle_watch_expressions($obj);
2613
2614 =head2 C<watchfunction()>
2615
2616 C<watchfunction()> is a function that can be defined by the user; it is a
2617 function which will be run on each entry to C<DB::DB>; it gets the
2618 current package, filename, and line as its parameters.
2619
2620 The watchfunction can do anything it likes; it is executing in the
2621 debugger's context, so it has access to all of the debugger's internal
2622 data structures and functions.
2623
2624 C<watchfunction()> can control the debugger's actions. Any of the following
2625 will cause the debugger to return control to the user's program after
2626 C<watchfunction()> executes:
2627
2628 =over 4
2629
2630 =item *
2631
2632 Returning a false value from the C<watchfunction()> itself.
2633
2634 =item *
2635
2636 Altering C<$single> to a false value.
2637
2638 =item *
2639
2640 Altering C<$signal> to a false value.
2641
2642 =item *
2643
2644 Turning off the C<4> bit in C<$trace> (this also disables the
2645 check for C<watchfunction()>. This can be done with
2646
2647     $trace &= ~4;
2648
2649 =back
2650
2651 =cut
2652
2653     # If there's a user-defined DB::watchfunction, call it with the
2654     # current package, filename, and line. The function executes in
2655     # the DB:: package.
2656     if ( $trace & 4 ) {    # User-installed watch
2657         return
2658           if watchfunction( $package, $filename, $line )
2659           and not $single
2660           and not $was_signal
2661           and not( $trace & ~4 );
2662     } ## end if ($trace & 4)
2663
2664     # Pick up any alteration to $signal in the watchfunction, and
2665     # turn off the signal now.
2666     $was_signal = $signal;
2667     $signal     = 0;
2668
2669 =head2 GETTING READY TO EXECUTE COMMANDS
2670
2671 The debugger decides to take control if single-step mode is on, the
2672 C<t> command was entered, or the user generated a signal. If the program
2673 has fallen off the end, we set things up so that entering further commands
2674 won't cause trouble, and we say that the program is over.
2675
2676 =cut
2677
2678     # Make sure that we always print if asked for explicitly regardless
2679     # of $trace_to_depth .
2680     $explicit_stop = ($single || $was_signal);
2681
2682     # Check to see if we should grab control ($single true,
2683     # trace set appropriately, or we got a signal).
2684     if ( $explicit_stop || ( $trace & 1 ) ) {
2685         $obj->_DB__grab_control(@_);
2686     } ## end if ($single || ($trace...
2687
2688 =pod
2689
2690 If there's an action to be executed for the line we stopped at, execute it.
2691 If there are any preprompt actions, execute those as well.
2692
2693 =cut
2694
2695     # If there's an action, do it now.
2696     if ($action) {
2697         $evalarg = $action;
2698         # The &-call is here to ascertain the mutability of @_.
2699         &DB::eval;
2700     }
2701
2702     # Are we nested another level (e.g., did we evaluate a function
2703     # that had a breakpoint in it at the debugger prompt)?
2704     if ( $single || $was_signal ) {
2705
2706         # Yes, go down a level.
2707         local $level = $level + 1;
2708
2709         # Do any pre-prompt actions.
2710         foreach $evalarg (@$pre) {
2711             # The &-call is here to ascertain the mutability of @_.
2712             &DB::eval;
2713         }
2714
2715         # Complain about too much recursion if we passed the limit.
2716         if ($single & 4) {
2717             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2718         }
2719
2720         # The line we're currently on. Set $incr to -1 to stay here
2721         # until we get a command that tells us to advance.
2722         $start = $line;
2723         $incr  = -1;      # for backward motion.
2724
2725         # Tack preprompt debugger actions ahead of any actual input.
2726         @typeahead = ( @$pretype, @typeahead );
2727
2728 =head2 WHERE ARE WE?
2729
2730 XXX Relocate this section?
2731
2732 The debugger normally shows the line corresponding to the current line of
2733 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2734 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2735
2736 C<$incr> controls by how many lines the I<current> line should move forward
2737 after a command is executed. If set to -1, this indicates that the I<current>
2738 line shouldn't change.
2739
2740 C<$start> is the I<current> line. It is used for things like knowing where to
2741 move forwards or backwards from when doing an C<L> or C<-> command.
2742
2743 C<$max> tells the debugger where the last line of the current file is. It's
2744 used to terminate loops most often.
2745
2746 =head2 THE COMMAND LOOP
2747
2748 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2749 in two parts:
2750
2751 =over 4
2752
2753 =item *
2754
2755 The outer part of the loop, starting at the C<CMD> label. This loop
2756 reads a command and then executes it.
2757
2758 =item *
2759
2760 The inner part of the loop, starting at the C<PIPE> label. This part
2761 is wholly contained inside the C<CMD> block and only executes a command.
2762 Used to handle commands running inside a pager.
2763
2764 =back
2765
2766 So why have two labels to restart the loop? Because sometimes, it's easier to
2767 have a command I<generate> another command and then re-execute the loop to do
2768 the new command. This is faster, but perhaps a bit more convoluted.
2769
2770 =cut
2771
2772         # The big command dispatch loop. It keeps running until the
2773         # user yields up control again.
2774         #
2775         # If we have a terminal for input, and we get something back
2776         # from readline(), keep on processing.
2777
2778       CMD:
2779         while (_DB__read_next_cmd($tid))
2780         {
2781
2782             share($cmd);
2783             # ... try to execute the input as debugger commands.
2784
2785             # Don't stop running.
2786             $single = 0;
2787
2788             # No signal is active.
2789             $signal = 0;
2790
2791             # Handle continued commands (ending with \):
2792             if ($cmd =~ s/\\\z/\n/) {
2793                 $cmd .= DB::readline("  cont: ");
2794                 redo CMD;
2795             }
2796
2797 =head4 The null command
2798
2799 A newline entered by itself means I<re-execute the last command>. We grab the
2800 command out of C<$laststep> (where it was recorded previously), and copy it
2801 back into C<$cmd> to be executed below. If there wasn't any previous command,
2802 we'll do nothing below (no command will match). If there was, we also save it
2803 in the command history and fall through to allow the command parsing to pick
2804 it up.
2805
2806 =cut
2807
2808             # Empty input means repeat the last command.
2809             if ($cmd eq '') {
2810                 $cmd = $laststep;
2811             }
2812             chomp($cmd);    # get rid of the annoying extra newline
2813             if (length($cmd) >= 2) {
2814                 push( @hist, $cmd );
2815             }
2816             push( @truehist, $cmd );
2817             share(@hist);
2818             share(@truehist);
2819
2820             # This is a restart point for commands that didn't arrive
2821             # via direct user input. It allows us to 'redo PIPE' to
2822             # re-execute command processing without reading a new command.
2823           PIPE: {
2824                 _DB__trim_command_and_return_first_component($obj);
2825
2826 =head3 COMMAND ALIASES
2827
2828 The debugger can create aliases for commands (these are stored in the
2829 C<%alias> hash). Before a command is executed, the command loop looks it up
2830 in the alias hash and substitutes the contents of the alias for the command,
2831 completely replacing it.
2832
2833 =cut
2834
2835                 # See if there's an alias for the command, and set it up if so.
2836                 if ( $alias{$cmd_verb} ) {
2837
2838                     # Squelch signal handling; we want to keep control here
2839                     # if something goes loco during the alias eval.
2840                     local $SIG{__DIE__};
2841                     local $SIG{__WARN__};
2842
2843                     # This is a command, so we eval it in the DEBUGGER's
2844                     # scope! Otherwise, we can't see the special debugger
2845                     # variables, or get to the debugger's subs. (Well, we
2846                     # _could_, but why make it even more complicated?)
2847                     eval "\$cmd =~ $alias{$cmd_verb}";
2848                     if ($@) {
2849                         local $\ = '';
2850                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2851                         next CMD;
2852                     }
2853                     _DB__trim_command_and_return_first_component($obj);
2854                 } ## end if ($alias{$cmd_verb})
2855
2856 =head3 MAIN-LINE COMMANDS
2857
2858 All of these commands work up to and after the program being debugged has
2859 terminated.
2860
2861 =head4 C<q> - quit
2862
2863 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2864 try to execute further, cleaning any restart-related stuff out of the
2865 environment, and executing with the last value of C<$?>.
2866
2867 =cut
2868
2869                 # All of these commands were remapped in perl 5.8.0;
2870                 # we send them off to the secondary dispatcher (see below).
2871                 $obj->_handle_special_char_cmd_wrapper_commands;
2872                 _DB__trim_command_and_return_first_component($obj);
2873
2874                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2875                     my $type = $cmd_rec->{t};
2876                     my $val = $cmd_rec->{v};
2877                     if ($type eq 'm') {
2878                         $obj->$val();
2879                     }
2880                     elsif ($type eq 's') {
2881                         $val->($obj);
2882                     }
2883                 }
2884
2885 =head4 C<t> - trace [n]
2886
2887 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2888 If level is specified, set C<$trace_to_depth>.
2889
2890 =head4 C<S> - list subroutines matching/not matching a pattern
2891
2892 Walks through C<%sub>, checking to see whether or not to print the name.
2893
2894 =head4 C<X> - list variables in current package
2895
2896 Since the C<V> command actually processes this, just change this to the
2897 appropriate C<V> command and fall through.
2898
2899 =head4 C<V> - list variables
2900
2901 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2902
2903 =head4 C<x> - evaluate and print an expression
2904
2905 Hands the expression off to C<DB::eval>, setting it up to print the value
2906 via C<dumpvar.pl> instead of just printing it directly.
2907
2908 =head4 C<m> - print methods
2909
2910 Just uses C<DB::methods> to determine what methods are available.
2911
2912 =head4 C<f> - switch files
2913
2914 Switch to a different filename.
2915
2916 =head4 C<.> - return to last-executed line.
2917
2918 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2919 and then we look up the line in the magical C<%dbline> hash.
2920
2921 =head4 C<-> - back one window
2922
2923 We change C<$start> to be one window back; if we go back past the first line,
2924 we set it to be the first line. We ser C<$incr> to put us back at the
2925 currently-executing line, and then put a C<l $start +> (list one window from
2926 C<$start>) in C<$cmd> to be executed later.
2927
2928 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2929
2930 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2931 problems, most notably that the default case of several commands destroying
2932 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2933 retain the old commands for those who were used to using them or who preferred
2934 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2935 deal with them instead of processing them in-line.
2936
2937 =head4 C<y> - List lexicals in higher scope
2938
2939 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2940 above the current one and then displays then using C<dumpvar.pl>.
2941
2942 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2943
2944 All of the commands below this point don't work after the program being
2945 debugged has ended. All of them check to see if the program has ended; this
2946 allows the commands to be relocated without worrying about a 'line of
2947 demarcation' above which commands can be entered anytime, and below which
2948 they can't.
2949
2950 =head4 C<n> - single step, but don't trace down into subs
2951
2952 Done by setting C<$single> to 2, which forces subs to execute straight through
2953 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2954 so a null command knows what to re-execute.
2955
2956 =head4 C<s> - single-step, entering subs
2957
2958 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2959 subs. Also saves C<s> as C<$lastcmd>.
2960
2961 =head4 C<c> - run continuously, setting an optional breakpoint
2962
2963 Most of the code for this command is taken up with locating the optional
2964 breakpoint, which is either a subroutine name or a line number. We set
2965 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2966 in this and all call levels above this one.
2967
2968 =head4 C<r> - return from a subroutine
2969
2970 For C<r> to work properly, the debugger has to stop execution again
2971 immediately after the return is executed. This is done by forcing
2972 single-stepping to be on in the call level above the current one. If
2973 we are printing return values when a C<r> is executed, set C<$doret>
2974 appropriately, and force us out of the command loop.
2975
2976 =head4 C<T> - stack trace
2977
2978 Just calls C<DB::print_trace>.
2979
2980 =head4 C<w> - List window around current line.
2981
2982 Just calls C<DB::cmd_w>.
2983
2984 =head4 C<W> - watch-expression processing.
2985
2986 Just calls C<DB::cmd_W>.
2987
2988 =head4 C</> - search forward for a string in the source
2989
2990 We take the argument and treat it as a pattern. If it turns out to be a
2991 bad one, we return the error we got from trying to C<eval> it and exit.
2992 If not, we create some code to do the search and C<eval> it so it can't
2993 mess us up.
2994
2995 =cut
2996
2997                 _DB__handle_forward_slash_command($obj);
2998
2999 =head4 C<?> - search backward for a string in the source
3000
3001 Same as for C</>, except the loop runs backwards.
3002
3003 =cut
3004
3005                 _DB__handle_question_mark_command($obj);
3006
3007 =head4 C<$rc> - Recall command
3008
3009 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3010 that the terminal supports history). It finds the command required, puts it
3011 into C<$cmd>, and redoes the loop to execute it.
3012
3013 =cut
3014
3015                 # $rc - recall command.
3016                 $obj->_handle_rc_recall_command;
3017
3018 =head4 C<$sh$sh> - C<system()> command
3019
3020 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3021 C<STDOUT> from getting messed up.
3022
3023 =cut
3024
3025                 $obj->_handle_sh_command;
3026
3027 =head4 C<$rc I<pattern> $rc> - Search command history
3028
3029 Another command to manipulate C<@hist>: this one searches it with a pattern.
3030 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3031
3032 =cut
3033
3034                 $obj->_handle_rc_search_history_command;
3035
3036 =head4 C<$sh> - Invoke a shell
3037
3038 Uses C<_db_system()> to invoke a shell.
3039
3040 =cut
3041
3042 =head4 C<$sh I<command>> - Force execution of a command in a shell
3043
3044 Like the above, but the command is passed to the shell. Again, we use
3045 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3046
3047 =head4 C<H> - display commands in history
3048
3049 Prints the contents of C<@hist> (if any).
3050
3051 =head4 C<man, doc, perldoc> - look up documentation
3052
3053 Just calls C<runman()> to print the appropriate document.
3054
3055 =cut
3056
3057                 $obj->_handle_doc_command;
3058
3059 =head4 C<p> - print
3060
3061 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3062 the bottom of the loop.
3063
3064 =head4 C<=> - define command alias
3065
3066 Manipulates C<%alias> to add or list command aliases.
3067
3068 =head4 C<source> - read commands from a file.
3069
3070 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3071 pick it up.
3072
3073 =head4 C<enable> C<disable> - enable or disable breakpoints
3074
3075 This enables or disables breakpoints.
3076
3077 =head4 C<save> - send current history to a file
3078
3079 Takes the complete history, (not the shrunken version you see with C<H>),
3080 and saves it to the given filename, so it can be replayed using C<source>.
3081
3082 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3083
3084 =head4 C<R> - restart
3085
3086 Restart the debugger session.
3087
3088 =head4 C<rerun> - rerun the current session
3089
3090 Return to any given position in the B<true>-history list
3091
3092 =head4 C<|, ||> - pipe output through the pager.
3093
3094 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3095 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3096 pipe to the pager (restoring the output filehandles if this fails). If this
3097 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3098 set C<$signal>, sending us back into the debugger.
3099
3100 We then trim off the pipe symbols and C<redo> the command loop at the
3101 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3102 reading another.
3103
3104 =cut
3105
3106                 # || - run command in the pager, with output to DB::OUT.
3107                 _DB__handle_run_command_in_pager_command($obj);
3108
3109 =head3 END OF COMMAND PARSING
3110
3111 Anything left in C<$cmd> at this point is a Perl expression that we want to
3112 evaluate. We'll always evaluate in the user's context, and fully qualify
3113 any variables we might want to address in the C<DB> package.
3114
3115 =cut
3116
3117             }    # PIPE:
3118
3119             # trace an expression
3120             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3121
3122             # Make sure the flag that says "the debugger's running" is
3123             # still on, to make sure we get control again.
3124             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3125
3126             # Run *our* eval that executes in the caller's context.
3127             # The &-call is here to ascertain the mutability of @_.
3128             &DB::eval;
3129
3130             # Turn off the one-time-dump stuff now.
3131             if ($onetimeDump) {
3132                 $onetimeDump      = undef;
3133                 $onetimedumpDepth = undef;
3134             }
3135             elsif ( $term_pid == $$ ) {
3136                 eval { # May run under miniperl, when not available...
3137                     STDOUT->flush();
3138                     STDERR->flush();
3139                 };
3140
3141                 # XXX If this is the master pid, print a newline.
3142                 print {$OUT} "\n";
3143             }
3144         } ## end while (($term || &setterm...
3145
3146 =head3 POST-COMMAND PROCESSING
3147
3148 After each command, we check to see if the command output was piped anywhere.
3149 If so, we go through the necessary code to unhook the pipe and go back to
3150 our standard filehandles for input and output.
3151
3152 =cut
3153
3154         continue {    # CMD:
3155             _DB__at_end_of_every_command($obj);
3156         }    # CMD:
3157
3158 =head3 COMMAND LOOP TERMINATION
3159
3160 When commands have finished executing, we come here. If the user closed the
3161 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3162 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3163 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3164 The interpreter will then execute the next line and then return control to us
3165 again.
3166
3167 =cut
3168
3169         # No more commands? Quit.
3170         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3171
3172         # Evaluate post-prompt commands.
3173         foreach $evalarg (@$post) {
3174             # The &-call is here to ascertain the mutability of @_.
3175             &DB::eval;
3176         }
3177     }    # if ($single || $signal)
3178
3179     # Put the user's globals back where you found them.
3180     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3181     ();
3182 } ## end sub DB
3183
3184 # Because DB::Obj is used above,
3185 #
3186 #   my $obj = DB::Obj->new(
3187 #
3188 # The following package declaration must come before that,
3189 # or else runtime errors will occur with
3190 #
3191 #   PERLDB_OPTS="autotrace nonstop"
3192 #
3193 # ( rt#116771 )
3194 BEGIN {
3195
3196 package DB::Obj;
3197
3198 sub new {
3199     my $class = shift;
3200
3201     my $self = bless {}, $class;
3202
3203     $self->_init(@_);
3204
3205     return $self;
3206 }
3207
3208 sub _init {
3209     my ($self, $args) = @_;
3210
3211     %{$self} = (%$self, %$args);
3212
3213     return;
3214 }
3215
3216 {
3217     no strict 'refs';
3218     foreach my $slot_name (qw(
3219         after explicit_stop infix pat piped position prefix selected cmd_verb
3220         cmd_args
3221         )) {
3222         my $slot = $slot_name;
3223         *{$slot} = sub {
3224             my $self = shift;
3225
3226             if (@_) {
3227                 ${ $self->{$slot} } = shift;
3228             }
3229
3230             return ${ $self->{$slot} };
3231         };
3232
3233         *{"append_to_$slot"} = sub {
3234             my $self = shift;
3235             my $s = shift;
3236
3237             return $self->$slot($self->$slot . $s);
3238         };
3239     }
3240 }
3241
3242 sub _DB_on_init__initialize_globals
3243 {
3244     my $self = shift;
3245
3246     # Check for whether we should be running continuously or not.
3247     # _After_ the perl program is compiled, $single is set to 1:
3248     if ( $single and not $second_time++ ) {
3249
3250         # Options say run non-stop. Run until we get an interrupt.
3251         if ($runnonstop) {    # Disable until signal
3252                 # If there's any call stack in place, turn off single
3253                 # stepping into subs throughout the stack.
3254             for my $i (0 .. $stack_depth) {
3255                 $stack[ $i ] &= ~1;
3256             }
3257
3258             # And we are now no longer in single-step mode.
3259             $single = 0;
3260
3261             # If we simply returned at this point, we wouldn't get
3262             # the trace info. Fall on through.
3263             # return;
3264         } ## end if ($runnonstop)
3265
3266         elsif ($ImmediateStop) {
3267
3268             # We are supposed to stop here; XXX probably a break.
3269             $ImmediateStop = 0;    # We've processed it; turn it off
3270             $signal        = 1;    # Simulate an interrupt to force
3271                                    # us into the command loop
3272         }
3273     } ## end if ($single and not $second_time...
3274
3275     # If we're in single-step mode, or an interrupt (real or fake)
3276     # has occurred, turn off non-stop mode.
3277     $runnonstop = 0 if $single or $signal;
3278
3279     return;
3280 }
3281
3282 sub _my_print_lineinfo
3283 {
3284     my ($self, $i, $incr_pos) = @_;
3285
3286     if ($frame) {
3287         # Print it indented if tracing is on.
3288         DB::print_lineinfo( ' ' x $stack_depth,
3289             "$i:\t$DB::dbline[$i]" . $self->after );
3290     }
3291     else {
3292         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3293     }
3294 }
3295
3296 sub _curr_line {
3297     return $DB::dbline[$line];
3298 }
3299
3300 sub _is_full {
3301     my ($self, $letter) = @_;
3302
3303     return ($DB::cmd eq $letter);
3304 }
3305
3306 sub _DB__grab_control
3307 {
3308     my $self = shift;
3309
3310     # Yes, grab control.
3311     if ($slave_editor) {
3312
3313         # Tell the editor to update its position.
3314         $self->position("\032\032${DB::filename}:$line:0\n");
3315         DB::print_lineinfo($self->position());
3316     }
3317
3318 =pod
3319
3320 Special check: if we're in package C<DB::fake>, we've gone through the
3321 C<END> block at least once. We set up everything so that we can continue
3322 to enter commands and have a valid context to be in.
3323
3324 =cut
3325
3326     elsif ( $DB::package eq 'DB::fake' ) {
3327
3328         # Fallen off the end already.
3329         if (!$DB::term) {
3330             DB::setterm();
3331         }
3332
3333         DB::print_help(<<EOP);
3334 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3335 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3336 B<h q>, B<h R> or B<h o> to get additional info.
3337 EOP
3338
3339         # Set the DB::eval context appropriately.
3340         # At program termination disable any user actions.
3341         $DB::action = undef;
3342
3343         $DB::package     = 'main';
3344         $DB::usercontext = DB::_calc_usercontext($DB::package);
3345     } ## end elsif ($package eq 'DB::fake')
3346
3347 =pod
3348
3349 If the program hasn't finished executing, we scan forward to the
3350 next executable line, print that out, build the prompt from the file and line
3351 number information, and print that.
3352
3353 =cut
3354
3355     else {
3356
3357
3358         # Still somewhere in the midst of execution. Set up the
3359         #  debugger prompt.
3360         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3361                              # Perl 5 ones (sorry, we don't print Klingon
3362                              #module names)
3363
3364         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3365         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3366         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3367
3368         # Break up the prompt if it's really long.
3369         if ( length($self->prefix()) > 30 ) {
3370             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3371             $self->prefix("");
3372             $self->infix(":\t");
3373         }
3374         else {
3375             $self->infix("):\t");
3376             $self->position(
3377                 $self->prefix . $line. $self->infix
3378                 . $self->_curr_line . $self->after
3379             );
3380         }
3381
3382         # Print current line info, indenting if necessary.
3383         $self->_my_print_lineinfo($line, $self->position);
3384
3385         my $i;
3386         my $line_i = sub { return $DB::dbline[$i]; };
3387
3388         # Scan forward, stopping at either the end or the next
3389         # unbreakable line.
3390         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3391         {    #{ vi
3392
3393             # Drop out on null statements, block closers, and comments.
3394             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3395
3396             # Drop out if the user interrupted us.
3397             last if $signal;
3398
3399             # Append a newline if the line doesn't have one. Can happen
3400             # in eval'ed text, for instance.
3401             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3402
3403             # Next executable line.
3404             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3405                 . $self->after;
3406             $self->append_to_position($incr_pos);
3407             $self->_my_print_lineinfo($i, $incr_pos);
3408         } ## end for ($i = $line + 1 ; $i...
3409     } ## end else [ if ($slave_editor)
3410
3411     return;
3412 }
3413
3414 sub _handle_t_command {
3415     my $self = shift;
3416
3417     my $levels = $self->cmd_args();
3418
3419     if ((!length($levels)) or ($levels !~ /\D/)) {
3420         $trace ^= 1;
3421         local $\ = '';
3422         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3423         print {$OUT} "Trace = "
3424         . ( ( $trace & 1 )
3425             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3426             : "off" ) . "\n";
3427         next CMD;
3428     }
3429
3430     return;
3431 }
3432
3433
3434 sub _handle_S_command {
3435     my $self = shift;
3436
3437     if (my ($print_all_subs, $should_reverse, $Spatt)
3438         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3439         # $Spatt is the pattern (if any) to use.
3440         # Reverse scan?
3441         my $Srev     = defined $should_reverse;
3442         # No args - print all subs.
3443         my $Snocheck = !defined $print_all_subs;
3444
3445         # Need to make these sane here.
3446         local $\ = '';
3447         local $, = '';
3448
3449         # Search through the debugger's magical hash of subs.
3450         # If $nocheck is true, just print the sub name.
3451         # Otherwise, check it against the pattern. We then use
3452         # the XOR trick to reverse the condition as required.
3453         foreach $subname ( sort( keys %sub ) ) {
3454             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3455                 print $OUT $subname, "\n";
3456             }
3457         }
3458         next CMD;
3459     }
3460
3461     return;
3462 }
3463
3464 sub _handle_V_command_and_X_command {
3465     my $self = shift;
3466
3467     $DB::cmd =~ s/^X\b/V $DB::package/;
3468
3469     # Bare V commands get the currently-being-debugged package
3470     # added.
3471     if ($self->_is_full('V')) {
3472         $DB::cmd = "V $DB::package";
3473     }
3474
3475     # V - show variables in package.
3476     if (my ($new_packname, $new_vars_str) =
3477         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3478
3479         # Save the currently selected filehandle and
3480         # force output to debugger's filehandle (dumpvar
3481         # just does "print" for output).
3482         my $savout = select($OUT);
3483
3484         # Grab package name and variables to dump.
3485         $packname = $new_packname;
3486         my @vars     = split( ' ', $new_vars_str );
3487
3488         # If main::dumpvar isn't here, get it.
3489         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3490         if ( defined &main::dumpvar ) {
3491
3492             # We got it. Turn off subroutine entry/exit messages
3493             # for the moment, along with return values.
3494             local $frame = 0;
3495             local $doret = -2;
3496
3497             # must detect sigpipe failures  - not catching
3498             # then will cause the debugger to die.
3499             eval {
3500                 main::dumpvar(
3501                     $packname,
3502                     defined $option{dumpDepth}
3503                     ? $option{dumpDepth}
3504                     : -1,    # assume -1 unless specified
3505                     @vars
3506                 );
3507             };
3508
3509             # The die doesn't need to include the $@, because
3510             # it will automatically get propagated for us.
3511             if ($@) {
3512                 die unless $@ =~ /dumpvar print failed/;
3513             }
3514         } ## end if (defined &main::dumpvar)
3515         else {
3516
3517             # Couldn't load dumpvar.
3518             print $OUT "dumpvar.pl not available.\n";
3519         }
3520
3521         # Restore the output filehandle, and go round again.
3522         select($savout);
3523         next CMD;
3524     }
3525
3526     return;
3527 }
3528
3529 sub _handle_dash_command {
3530     my $self = shift;
3531
3532     if ($self->_is_full('-')) {
3533
3534         # back up by a window; go to 1 if back too far.
3535         $start -= $incr + $window + 1;
3536         $start = 1 if $start <= 0;
3537         $incr  = $window - 1;
3538
3539         # Generate and execute a "l +" command (handled below).
3540         $DB::cmd = 'l ' . ($start) . '+';
3541         redo CMD;
3542     }
3543     return;
3544 }
3545
3546 sub _n_or_s_commands_generic {
3547     my ($self, $new_val) = @_;
3548     # n - next
3549     next CMD if DB::_DB__is_finished();
3550
3551     # Single step, but don't enter subs.
3552     $single = $new_val;
3553
3554     # Save for empty command (repeat last).
3555     $laststep = $DB::cmd;
3556     last CMD;
3557 }
3558
3559 sub _n_or_s {
3560     my ($self, $letter, $new_val) = @_;
3561
3562     if ($self->_is_full($letter)) {
3563         $self->_n_or_s_commands_generic($new_val);
3564     }
3565     else {
3566         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3567     }
3568
3569     return;
3570 }
3571
3572 sub _handle_n_command {
3573     my $self = shift;
3574
3575     return $self->_n_or_s('n', 2);
3576 }
3577
3578 sub _handle_s_command {
3579     my $self = shift;
3580
3581     return $self->_n_or_s('s', 1);
3582 }
3583
3584 sub _handle_r_command {
3585     my $self = shift;
3586
3587     # r - return from the current subroutine.
3588     if ($self->_is_full('r')) {
3589
3590         # Can't do anything if the program's over.
3591         next CMD if DB::_DB__is_finished();
3592
3593         # Turn on stack trace.
3594         $stack[$stack_depth] |= 1;
3595
3596         # Print return value unless the stack is empty.
3597         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3598         last CMD;
3599     }
3600
3601     return;
3602 }
3603
3604 sub _handle_T_command {
3605     my $self = shift;
3606
3607     if ($self->_is_full('T')) {
3608         DB::print_trace( $OUT, 1 );    # skip DB
3609         next CMD;
3610     }
3611
3612     return;
3613 }
3614
3615 sub _handle_w_command {
3616     my $self = shift;
3617
3618     DB::cmd_w( 'w', $self->cmd_args() );
3619     next CMD;
3620
3621     return;
3622 }
3623
3624 sub _handle_W_command {
3625     my $self = shift;
3626
3627     if (my $arg = $self->cmd_args) {
3628         DB::cmd_W( 'W', $arg );
3629         next CMD;
3630     }
3631
3632     return;
3633 }
3634
3635 sub _handle_rc_recall_command {
3636     my $self = shift;
3637
3638     # $rc - recall command.
3639     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3640
3641         # No arguments, take one thing off history.
3642         pop(@hist) if length($DB::cmd) > 1;
3643
3644         # Relative (- found)?
3645         #  Y - index back from most recent (by 1 if bare minus)
3646         #  N - go to that particular command slot or the last
3647         #      thing if nothing following.
3648
3649         $self->cmd_verb(
3650             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3651         );
3652
3653         # Pick out the command desired.
3654         $DB::cmd = $hist[$self->cmd_verb];
3655
3656         # Print the command to be executed and restart the loop
3657         # with that command in the buffer.
3658         print {$OUT} $DB::cmd, "\n";
3659         redo CMD;
3660     }
3661
3662     return;
3663 }
3664
3665 sub _handle_rc_search_history_command {
3666     my $self = shift;
3667
3668     # $rc pattern $rc - find a command in the history.
3669     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3670
3671         # Create the pattern to use.
3672         my $pat = "^$arg";
3673         $self->pat($pat);
3674
3675         # Toss off last entry if length is >1 (and it always is).
3676         pop(@hist) if length($DB::cmd) > 1;
3677
3678         my $i;
3679
3680         # Look backward through the history.
3681         SEARCH_HIST:
3682         for ( $i = $#hist ; $i ; --$i ) {
3683             # Stop if we find it.
3684             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3685         }
3686
3687         if ( !$i ) {
3688
3689             # Never found it.
3690             print $OUT "No such command!\n\n";
3691             next CMD;
3692         }
3693
3694         # Found it. Put it in the buffer, print it, and process it.
3695         $DB::cmd = $hist[$i];
3696         print $OUT $DB::cmd, "\n";
3697         redo CMD;
3698     }
3699
3700     return;
3701 }
3702
3703 sub _handle_H_command {
3704     my $self = shift;
3705
3706     if ($self->cmd_args =~ m#\A\*#) {
3707         @hist = @truehist = ();
3708         print $OUT "History cleansed\n";
3709         next CMD;
3710     }
3711
3712     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3713
3714         # Anything other than negative numbers is ignored by
3715         # the (incorrect) pattern, so this test does nothing.
3716         $end = $num ? ( $#hist - $num ) : 0;
3717
3718         # Set to the minimum if less than zero.
3719         $hist = 0 if $hist < 0;
3720
3721         # Start at the end of the array.
3722         # Stay in while we're still above the ending value.
3723         # Tick back by one each time around the loop.
3724         my $i;
3725
3726         for ( $i = $#hist ; $i > $end ; $i-- ) {
3727
3728             # Print the command  unless it has no arguments.
3729             print $OUT "$i: ", $hist[$i], "\n"
3730             unless $hist[$i] =~ /^.?$/;
3731         }
3732
3733         next CMD;
3734     }
3735
3736     return;
3737 }
3738
3739 sub _handle_doc_command {
3740     my $self = shift;
3741
3742     # man, perldoc, doc - show manual pages.
3743     if (my ($man_page)
3744         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3745         DB::runman($man_page);
3746         next CMD;
3747     }
3748
3749     return;
3750 }
3751
3752 sub _handle_p_command {
3753     my $self = shift;
3754
3755     my $print_cmd = 'print {$DB::OUT} ';
3756     # p - print (no args): print $_.
3757     if ($self->_is_full('p')) {
3758         $DB::cmd = $print_cmd . '$_';
3759     }
3760     else {
3761         # p - print the given expression.
3762         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3763     }
3764
3765     return;
3766 }
3767
3768 sub _handle_equal_sign_command {
3769     my $self = shift;
3770
3771     if ($DB::cmd =~ s/\A=\s*//) {
3772         my @keys;
3773         if ( length $DB::cmd == 0 ) {
3774
3775             # No args, get current aliases.
3776             @keys = sort keys %alias;
3777         }
3778         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3779
3780             # Creating a new alias. $k is alias name, $v is
3781             # alias value.
3782
3783             # can't use $_ or kill //g state
3784             for my $x ( $k, $v ) {
3785
3786                 # Escape "alarm" characters.
3787                 $x =~ s/\a/\\a/g;
3788             }
3789
3790             # Substitute key for value, using alarm chars
3791             # as separators (which is why we escaped them in
3792             # the command).
3793             $alias{$k} = "s\a$k\a$v\a";
3794
3795             # Turn off standard warn and die behavior.
3796             local $SIG{__DIE__};
3797             local $SIG{__WARN__};
3798
3799             # Is it valid Perl?
3800             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3801
3802                 # Nope. Bad alias. Say so and get out.
3803                 print $OUT "Can't alias $k to $v: $@\n";
3804                 delete $alias{$k};
3805                 next CMD;
3806             }
3807
3808             # We'll only list the new one.
3809             @keys = ($k);
3810         } ## end elsif (my ($k, $v) = ($DB::cmd...
3811
3812         # The argument is the alias to list.
3813         else {
3814             @keys = ($DB::cmd);
3815         }
3816
3817         # List aliases.
3818         for my $k (@keys) {
3819
3820             # Messy metaquoting: Trim the substitution code off.
3821             # We use control-G as the delimiter because it's not
3822             # likely to appear in the alias.
3823             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3824
3825                 # Print the alias.
3826                 print $OUT "$k\t= $1\n";
3827             }
3828             elsif ( defined $alias{$k} ) {
3829
3830                 # Couldn't trim it off; just print the alias code.
3831                 print $OUT "$k\t$alias{$k}\n";
3832             }
3833             else {
3834
3835                 # No such, dude.
3836                 print "No alias for $k\n";
3837             }
3838         } ## end for my $k (@keys)
3839         next CMD;
3840     }
3841
3842     return;
3843 }
3844
3845 sub _handle_source_command {
3846     my $self = shift;
3847
3848     # source - read commands from a file (or pipe!) and execute.
3849     if (my $sourced_fn = $self->cmd_args) {
3850         if ( open my $fh, $sourced_fn ) {
3851
3852             # Opened OK; stick it in the list of file handles.
3853             push @cmdfhs, $fh;
3854         }
3855         else {
3856
3857             # Couldn't open it.
3858             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3859         }
3860         next CMD;
3861     }
3862
3863     return;
3864 }
3865
3866 sub _handle_enable_disable_commands {
3867     my $self = shift;
3868
3869     my $which_cmd = $self->cmd_verb;
3870     my $position = $self->cmd_args;
3871
3872     if ($position !~ /\s/) {
3873         my ($fn, $line_num);
3874         if ($position =~ m{\A\d+\z})
3875         {
3876             $fn = $DB::filename;
3877             $line_num = $position;
3878         }
3879         elsif (my ($new_fn, $new_line_num)
3880             = $position =~ m{\A(.*):(\d+)\z}) {
3881             ($fn, $line_num) = ($new_fn, $new_line_num);
3882         }
3883         else
3884         {
3885             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3886         }
3887
3888         if (defined($fn)) {
3889             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3890                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3891                     ($which_cmd eq 'enable' ? 1 : '')
3892                 );
3893             }
3894             else {
3895                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3896             }
3897         }
3898
3899         next CMD;
3900     }
3901
3902     return;
3903 }
3904
3905 sub _handle_save_command {
3906     my $self = shift;
3907
3908     if (my $new_fn = $self->cmd_args) {
3909         my $filename = $new_fn || '.perl5dbrc';    # default?
3910         if ( open my $fh, '>', $filename ) {
3911
3912             # chomp to remove extraneous newlines from source'd files
3913             chomp( my @truelist =
3914                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3915                 @truehist );
3916             print {$fh} join( "\n", @truelist );
3917             print "commands saved in $filename\n";
3918         }
3919         else {
3920             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3921         }
3922         next CMD;
3923     }
3924
3925     return;
3926 }
3927
3928 sub _n_or_s_and_arg_commands_generic {
3929     my ($self, $letter, $new_val) = @_;
3930
3931     # s - single-step. Remember the last command was 's'.
3932     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3933         $laststep = $letter;
3934     }
3935
3936     return;
3937 }
3938
3939 sub _handle_sh_command {
3940     my $self = shift;
3941
3942     # $sh$sh - run a shell command (if it's all ASCII).
3943     # Can't run shell commands with Unicode in the debugger, hmm.
3944     my $my_cmd = $DB::cmd;
3945     if ($my_cmd =~ m#\A$sh#gms) {
3946
3947         if ($my_cmd =~ m#\G\z#cgms) {
3948             # Run the user's shell. If none defined, run Bourne.
3949             # We resume execution when the shell terminates.
3950             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3951             next CMD;
3952         }
3953         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3954             # System it.
3955             DB::_db_system($1);
3956             next CMD;
3957         }
3958         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3959             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3960             next CMD;
3961         }
3962     }
3963 }
3964
3965 sub _handle_x_command {
3966     my $self = shift;
3967
3968     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3969         $onetimeDump = 'dump';    # main::dumpvar shows the output
3970
3971         # handle special  "x 3 blah" syntax XXX propagate
3972         # doc back to special variables.
3973         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3974             $onetimedumpDepth = $1;
3975         }
3976     }
3977
3978     return;
3979 }
3980
3981 sub _handle_q_command {
3982     my $self = shift;
3983
3984     if ($self->_is_full('q')) {
3985         $fall_off_end = 1;
3986         DB::clean_ENV();
3987         exit $?;
3988     }
3989
3990     return;
3991 }
3992
3993 sub _handle_cmd_wrapper_commands {
3994     my $self = shift;
3995
3996     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3997     next CMD;
3998 }
3999
4000 sub _handle_special_char_cmd_wrapper_commands {
4001     my $self = shift;
4002
4003     # All of these commands were remapped in perl 5.8.0;
4004     # we send them off to the secondary dispatcher (see below).
4005     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4006         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4007         next CMD;
4008     }
4009
4010     return;
4011 }
4012
4013 } ## end DB::Obj
4014
4015 package DB;
4016
4017 # The following code may be executed now:
4018 # BEGIN {warn 4}
4019
4020 =head2 sub
4021
4022 C<sub> is called whenever a subroutine call happens in the program being
4023 debugged. The variable C<$DB::sub> contains the name of the subroutine
4024 being called.
4025
4026 The core function of this subroutine is to actually call the sub in the proper
4027 context, capturing its output. This of course causes C<DB::DB> to get called
4028 again, repeating until the subroutine ends and returns control to C<DB::sub>
4029 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4030 return value, and returns its captured copy of the return value as its own
4031 return value. The value then feeds back into the program being debugged as if
4032 C<DB::sub> hadn't been there at all.
4033
4034 C<sub> does all the work of printing the subroutine entry and exit messages
4035 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4036 and also prints the return value if needed (for the C<r> command and if
4037 the 16 bit is set in C<$frame>).
4038
4039 It also tracks the subroutine call depth by saving the current setting of
4040 C<$single> in the C<@stack> package global; if this exceeds the value in
4041 C<$deep>, C<sub> automatically turns on printing of the current depth by
4042 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4043 of stop/don't stop on entry to subs set as it currently is set.
4044
4045 =head3 C<caller()> support
4046
4047 If C<caller()> is called from the package C<DB>, it provides some
4048 additional data, in the following order:
4049
4050 =over 4
4051
4052 =item * C<$package>
4053
4054 The package name the sub was in
4055
4056 =item * C<$filename>
4057
4058 The filename it was defined in
4059
4060 =item * C<$line>
4061
4062 The line number it was defined on
4063
4064 =item * C<$subroutine>
4065
4066 The subroutine name; C<(eval)> if an C<eval>().
4067
4068 =item * C<$hasargs>
4069
4070 1 if it has arguments, 0 if not
4071
4072 =item * C<$wantarray>
4073
4074 1 if array context, 0 if scalar context
4075
4076 =item * C<$evaltext>
4077
4078 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4079
4080 =item * C<$is_require>
4081
4082 frame was created by a C<use> or C<require> statement
4083
4084 =item * C<$hints>
4085
4086 pragma information; subject to change between versions
4087
4088 =item * C<$bitmask>
4089
4090 pragma information; subject to change between versions
4091
4092 =item * C<@DB::args>
4093
4094 arguments with which the subroutine was invoked
4095
4096 =back
4097
4098 =cut
4099
4100 use vars qw($deep);
4101
4102 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4103 # happy. -- Shlomi Fish
4104
4105 sub _indent_print_line_info {
4106     my ($offset, $str) = @_;
4107
4108     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4109
4110     return;
4111 }
4112
4113 sub _print_frame_message {
4114     my ($al) = @_;
4115
4116     if ($frame) {
4117         if ($frame & 4) {   # Extended frame entry message
4118             _indent_print_line_info(-1, "in  ");
4119
4120             # Why -1? But it works! :-(
4121             # Because print_trace will call add 1 to it and then call
4122             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4123             # in dump_trace.
4124             #
4125             # Now it's 0 because we extracted a function.
4126             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4127         }
4128         else {
4129             _indent_print_line_info(-1, "entering $sub$al\n" );
4130         }
4131     }
4132
4133     return;
4134 }
4135
4136 sub DB::sub {
4137     # lock ourselves under threads
4138     lock($DBGR);
4139
4140     # Whether or not the autoloader was running, a scalar to put the
4141     # sub's return value in (if needed), and an array to put the sub's
4142     # return value in (if needed).
4143     my ( $al, $ret, @ret ) = "";
4144     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4145         print "creating new thread\n";
4146     }
4147
4148     # If the last ten characters are '::AUTOLOAD', note we've traced
4149     # into AUTOLOAD for $sub.
4150     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4151         no strict 'refs';
4152         $al = " for $$sub" if defined $$sub;
4153     }
4154
4155     # We stack the stack pointer and then increment it to protect us
4156     # from a situation that might unwind a whole bunch of call frames
4157     # at once. Localizing the stack pointer means that it will automatically
4158     # unwind the same amount when multiple stack frames are unwound.
4159     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4160
4161     # Expand @stack.
4162     $#stack = $stack_depth;
4163
4164     # Save current single-step setting.
4165     $stack[-1] = $single;
4166
4167     # Turn off all flags except single-stepping.
4168     $single &= 1;
4169
4170     # If we've gotten really deeply recursed, turn on the flag that will
4171     # make us stop with the 'deep recursion' message.
4172     $single |= 4 if $stack_depth == $deep;
4173
4174     # If frame messages are on ...
4175
4176     _print_frame_message($al);
4177     # standard frame entry message
4178
4179     my $print_exit_msg = sub {
4180         # Check for exit trace messages...
4181         if ($frame & 2)
4182         {
4183             if ($frame & 4)    # Extended exit message
4184             {
4185                 _indent_print_line_info(0, "out ");
4186                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4187             }
4188             else
4189             {
4190                 _indent_print_line_info(0, "exited $sub$al\n" );
4191             }
4192         }
4193         return;
4194     };
4195
4196     # Determine the sub's return type, and capture appropriately.
4197     if (wantarray) {
4198
4199         # Called in array context. call sub and capture output.
4200         # DB::DB will recursively get control again if appropriate; we'll come
4201         # back here when the sub is finished.
4202         {
4203             no strict 'refs';
4204             @ret = &$sub;
4205         }
4206
4207         # Pop the single-step value back off the stack.
4208         $single |= $stack[ $stack_depth-- ];
4209
4210         $print_exit_msg->();
4211
4212         # Print the return info if we need to.
4213         if ( $doret eq $stack_depth or $frame & 16 ) {
4214
4215             # Turn off output record separator.
4216             local $\ = '';
4217             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4218
4219             # Indent if we're printing because of $frame tracing.
4220             if ($frame & 16)
4221             {
4222                 print {$fh} ' ' x $stack_depth;
4223             }
4224
4225             # Print the return value.
4226             print {$fh} "list context return from $sub:\n";
4227             dumpit( $fh, \@ret );
4228
4229             # And don't print it again.
4230             $doret = -2;
4231         } ## end if ($doret eq $stack_depth...
4232             # And we have to return the return value now.
4233         @ret;
4234     } ## end if (wantarray)
4235
4236     # Scalar context.
4237     else {
4238         if ( defined wantarray ) {
4239             no strict 'refs';
4240             # Save the value if it's wanted at all.
4241             $ret = &$sub;
4242         }
4243         else {
4244             no strict 'refs';
4245             # Void return, explicitly.
4246             &$sub;
4247             undef $ret;
4248         }
4249
4250         # Pop the single-step value off the stack.
4251         $single |= $stack[ $stack_depth-- ];
4252
4253         # If we're doing exit messages...
4254         $print_exit_msg->();
4255
4256         # If we are supposed to show the return value... same as before.
4257         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4258             local $\ = '';
4259             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4260             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4261             print $fh (
4262                 defined wantarray
4263                 ? "scalar context return from $sub: "
4264                 : "void context return from $sub\n"
4265             );
4266             dumpit( $fh, $ret ) if defined wantarray;
4267             $doret = -2;
4268         } ## end if ($doret eq $stack_depth...
4269
4270         # Return the appropriate scalar value.
4271         $ret;
4272     } ## end else [ if (wantarray)
4273 } ## end sub _sub
4274
4275 sub lsub : lvalue {
4276
4277     no strict 'refs';
4278
4279     # lock ourselves under threads
4280     lock($DBGR);
4281
4282     # Whether or not the autoloader was running, a scalar to put the
4283     # sub's return value in (if needed), and an array to put the sub's
4284     # return value in (if needed).
4285     my ( $al, $ret, @ret ) = "";
4286     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4287         print "creating new thread\n";
4288     }
4289
4290     # If the last ten characters are C'::AUTOLOAD', note we've traced
4291     # into AUTOLOAD for $sub.
4292     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4293         $al = " for $$sub";
4294     }
4295
4296     # We stack the stack pointer and then increment it to protect us
4297     # from a situation that might unwind a whole bunch of call frames
4298     # at once. Localizing the stack pointer means that it will automatically
4299     # unwind the same amount when multiple stack frames are unwound.
4300     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4301
4302     # Expand @stack.
4303     $#stack = $stack_depth;
4304
4305     # Save current single-step setting.
4306     $stack[-1] = $single;
4307
4308     # Turn off all flags except single-stepping.
4309     # Use local so the single-step value is popped back off the
4310     # stack for us.
4311     local $single = $single & 1;
4312
4313     # If we've gotten really deeply recursed, turn on the flag that will
4314     # make us stop with the 'deep recursion' message.
4315     $single |= 4 if $stack_depth == $deep;
4316
4317     # If frame messages are on ...
4318     _print_frame_message($al);
4319
4320     # call the original lvalue sub.
4321     &$sub;
4322 }
4323
4324 # Abstracting common code from multiple places elsewhere:
4325 sub depth_print_lineinfo {
4326     my $always_print = shift;
4327
4328     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4329 }
4330
4331 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4332
4333 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4334 Most of the changes were to systematize the command structure and to eliminate
4335 commands that threw away user input without checking.
4336
4337 The following sections describe the code added to make it easy to support
4338 multiple command sets with conflicting command names. This section is a start
4339 at unifying all command processing to make it simpler to develop commands.
4340
4341 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4342 number, and C<$dbline> (the current line) as arguments.
4343
4344 Support functions in this section which have multiple modes of failure C<die>
4345 on error; the rest simply return a false value.
4346
4347 The user-interface functions (all of the C<cmd_*> functions) just output
4348 error messages.
4349
4350 =head2 C<%set>
4351
4352 The C<%set> hash defines the mapping from command letter to subroutine
4353 name suffix.
4354
4355 C<%set> is a two-level hash, indexed by set name and then by command name.
4356 Note that trying to set the CommandSet to C<foobar> simply results in the
4357 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4358
4359 =cut
4360
4361 ### The API section
4362
4363 my %set = (    #
4364     'pre580' => {
4365         'a' => 'pre580_a',
4366         'A' => 'pre580_null',
4367         'b' => 'pre580_b',
4368         'B' => 'pre580_null',
4369         'd' => 'pre580_null',
4370         'D' => 'pre580_D',
4371         'h' => 'pre580_h',
4372         'M' => 'pre580_null',
4373         'O' => 'o',
4374         'o' => 'pre580_null',
4375         'v' => 'M',
4376         'w' => 'v',
4377         'W' => 'pre580_W',
4378     },
4379     'pre590' => {
4380         '<'  => 'pre590_prepost',
4381         '<<' => 'pre590_prepost',
4382         '>'  => 'pre590_prepost',
4383         '>>' => 'pre590_prepost',
4384         '{'  => 'pre590_prepost',
4385         '{{' => 'pre590_prepost',
4386     },
4387 );
4388
4389 my %breakpoints_data;
4390
4391 sub _has_breakpoint_data_ref {
4392     my ($filename, $line) = @_;
4393
4394     return (
4395         exists( $breakpoints_data{$filename} )
4396             and
4397         exists( $breakpoints_data{$filename}{$line} )
4398     );
4399 }
4400
4401 sub _get_breakpoint_data_ref {
4402     my ($filename, $line) = @_;
4403
4404     return ($breakpoints_data{$filename}{$line} ||= +{});
4405 }
4406
4407 sub _delete_breakpoint_data_ref {
4408     my ($filename, $line) = @_;
4409
4410     delete($breakpoints_data{$filename}{$line});
4411     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4412         delete($breakpoints_data{$filename});
4413     }
4414
4415     return;
4416 }
4417
4418 sub _set_breakpoint_enabled_status {
4419     my ($filename, $line, $status) = @_;
4420
4421     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4422         ($status ? 1 : '')
4423         ;
4424
4425     return;
4426 }
4427
4428 sub _enable_breakpoint_temp_enabled_status {
4429     my ($filename, $line) = @_;
4430
4431     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4432
4433     return;
4434 }
4435
4436 sub _cancel_breakpoint_temp_enabled_status {
4437     my ($filename, $line) = @_;
4438
4439     my $ref = _get_breakpoint_data_ref($filename, $line);
4440
4441     delete ($ref->{'temp_enabled'});
4442
4443     if (! %$ref) {
4444         _delete_breakpoint_data_ref($filename, $line);
4445     }
4446
4447     return;
4448 }
4449
4450 sub _is_breakpoint_enabled {
4451     my ($filename, $line) = @_;
4452
4453     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4454     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4455 }
4456
4457 =head2 C<cmd_wrapper()> (API)
4458
4459 C<cmd_wrapper()> allows the debugger to switch command sets
4460 depending on the value of the C<CommandSet> option.
4461
4462 It tries to look up the command in the C<%set> package-level I<lexical>
4463 (which means external entities can't fiddle with it) and create the name of
4464 the sub to call based on the value found in the hash (if it's there). I<All>
4465 of the commands to be handled in a set have to be added to C<%set>; if they
4466 aren't found, the 5.8.0 equivalent is called (if there is one).
4467
4468 This code uses symbolic references.
4469
4470 =cut
4471
4472 sub cmd_wrapper {
4473     my $cmd      = shift;
4474     my $line     = shift;
4475     my $dblineno = shift;
4476
4477     # Assemble the command subroutine's name by looking up the
4478     # command set and command name in %set. If we can't find it,
4479     # default to the older version of the command.
4480     my $call = 'cmd_'
4481       . ( $set{$CommandSet}{$cmd}
4482           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4483
4484     # Call the command subroutine, call it by name.
4485     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4486 } ## end sub cmd_wrapper
4487
4488 =head3 C<cmd_a> (command)
4489
4490 The C<a> command handles pre-execution actions. These are associated with a
4491 particular line, so they're stored in C<%dbline>. We default to the current
4492 line if none is specified.
4493
4494 =cut
4495
4496 sub cmd_a {
4497     my $cmd    = shift;
4498     my $line   = shift || '';    # [.|line] expr
4499     my $dbline = shift;
4500
4501     # If it's dot (here), or not all digits,  use the current line.
4502     $line =~ s/\A\./$dbline/;
4503
4504     # Should be a line number followed by an expression.
4505     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4506
4507         if (! length($lineno)) {
4508             $lineno = $dbline;
4509         }
4510
4511         # If we have an expression ...
4512         if ( length $expr ) {
4513
4514             # ... but the line isn't breakable, complain.
4515             if ( $dbline[$lineno] == 0 ) {
4516                 print $OUT
4517                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4518             }
4519             else {
4520
4521                 # It's executable. Record that the line has an action.
4522                 $had_breakpoints{$filename} |= 2;
4523
4524                 # Remove any action, temp breakpoint, etc.
4525                 $dbline{$lineno} =~ s/\0[^\0]*//;
4526
4527                 # Add the action to the line.
4528                 $dbline{$lineno} .= "\0" . action($expr);
4529
4530                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4531             }
4532         } ## end if (length $expr)
4533     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4534     else {
4535
4536         # Syntax wrong.
4537         print $OUT
4538           "Adding an action requires an optional lineno and an expression\n"
4539           ;    # hint
4540     }
4541 } ## end sub cmd_a
4542
4543 =head3 C<cmd_A> (command)
4544
4545 Delete actions. Similar to above, except the delete code is in a separate
4546 subroutine, C<delete_action>.
4547
4548 =cut
4549
4550 sub cmd_A {
4551     my $cmd    = shift;
4552     my $line   = shift || '';
4553     my $dbline = shift;
4554
4555     # Dot is this line.
4556     $line =~ s/^\./$dbline/;
4557
4558     # Call delete_action with a null param to delete them all.
4559     # The '1' forces the eval to be true. It'll be false only
4560     # if delete_action blows up for some reason, in which case
4561     # we print $@ and get out.
4562     if ( $line eq '*' ) {
4563         if (! eval { _delete_all_actions(); 1 }) {
4564             print {$OUT} $@;
4565             return;
4566         }
4567     }
4568
4569     # There's a real line  number. Pass it to delete_action.
4570     # Error trapping is as above.
4571     elsif ( $line =~ /^(\S.*)/ ) {
4572         if (! eval { delete_action($1); 1 }) {
4573             print {$OUT} $@;
4574             return;
4575         }
4576     }
4577
4578     # Swing and a miss. Bad syntax.
4579     else {
4580         print $OUT
4581           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4582     }
4583 } ## end sub cmd_A
4584
4585 =head3 C<delete_action> (API)
4586
4587 C<delete_action> accepts either a line number or C<undef>. If a line number
4588 is specified, we check for the line being executable (if it's not, it
4589 couldn't have had an  action). If it is, we just take the action off (this
4590 will get any kind of an action, including breakpoints).
4591
4592 =cut
4593
4594 sub _remove_action_from_dbline {
4595     my $i = shift;
4596
4597     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4598     delete $dbline{$i} if $dbline{$i} eq '';
4599
4600     return;
4601 }
4602
4603 sub _delete_all_actions {
4604     print {$OUT} "Deleting all actions...\n";
4605
4606     for my $file ( keys %had_breakpoints ) {
4607         local *dbline = $main::{ '_<' . $file };
4608         $max = $#dbline;
4609         my $was;
4610         for my $i (1 .. $max) {
4611             if ( defined $dbline{$i} ) {
4612                 _remove_action_from_dbline($i);
4613             }
4614         }
4615
4616         unless ( $had_breakpoints{$file} &= ~2 ) {
4617             delete $had_breakpoints{$file};
4618         }
4619     }
4620
4621     return;
4622 }
4623
4624 sub delete_action {
4625     my $i = shift;
4626
4627     if ( defined($i) ) {
4628         # Can there be one?
4629         die "Line $i has no action .\n" if $dbline[$i] == 0;
4630
4631         # Nuke whatever's there.
4632         _remove_action_from_dbline($i);
4633     }
4634     else {
4635         _delete_all_actions();
4636     }
4637 }
4638
4639 =head3 C<cmd_b> (command)
4640
4641 Set breakpoints. Since breakpoints can be set in so many places, in so many
4642 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4643 we try to parse the command type, and then shuttle it off to an appropriate
4644 subroutine to actually do the work of setting the breakpoint in the right
4645 place.
4646
4647 =cut
4648
4649 sub cmd_b {
4650     my $cmd    = shift;
4651     my $line   = shift;    # [.|line] [cond]
4652     my $dbline = shift;
4653
4654     my $default_cond = sub {
4655         my $cond = shift;
4656         return length($cond) ? $cond : '1';
4657     };
4658
4659     # Make . the current line number if it's there..
4660     $line =~ s/^\.(\s|\z)/$dbline$1/;
4661
4662     # No line number, no condition. Simple break on current line.
4663     if ( $line =~ /^\s*$/ ) {
4664         cmd_b_line( $dbline, 1 );
4665     }
4666
4667     # Break on load for a file.
4668     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4669         $file =~ s/\s+\z//;
4670         cmd_b_load($file);
4671     }
4672
4673     # b compile|postpone <some sub> [<condition>]
4674     # The interpreter actually traps this one for us; we just put the
4675     # necessary condition in the %postponed hash.
4676     elsif ( my ($action, $subname, $cond)
4677         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4678
4679         # De-Perl4-ify the name - ' separators to ::.
4680         $subname =~ s/'/::/g;
4681
4682         # Qualify it into the current package unless it's already qualified.
4683         $subname = "${package}::" . $subname unless $subname =~ /::/;
4684
4685         # Add main if it starts with ::.
4686         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4687
4688         # Save the break type for this sub.
4689         $postponed{$subname} = (($action eq 'postpone')
4690             ? ( "break +0 if " . $default_cond->($cond) )
4691             : "compile");
4692     } ## end elsif ($line =~ ...
4693     # b <filename>:<line> [<condition>]
4694     elsif (my ($filename, $line_num, $cond)
4695         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4696         cmd_b_filename_line(
4697             $filename,
4698             $line_num,
4699             (length($cond) ? $cond : '1'),
4700         );
4701     }
4702     # b <sub name> [<condition>]
4703     elsif ( my ($new_subname, $new_cond) =
4704         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4705
4706         #
4707         $subname = $new_subname;
4708         cmd_b_sub( $subname, $default_cond->($new_cond) );
4709     }
4710
4711     # b <line> [<condition>].
4712     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4713
4714         # Capture the line. If none, it's the current line.
4715         $line = $line_n || $dbline;
4716
4717         # Break on line.
4718         cmd_b_line( $line, $default_cond->($cond) );
4719     }
4720
4721     # Line didn't make sense.
4722     else {
4723         print "confused by line($line)?\n";
4724     }
4725
4726     return;
4727 } ## end sub cmd_b
4728
4729 =head3 C<break_on_load> (API)
4730
4731 We want to break when this file is loaded. Mark this file in the
4732 C<%break_on_load> hash, and note that it has a breakpoint in
4733 C<%had_breakpoints>.
4734
4735 =cut
4736
4737 sub break_on_load {
4738     my $file = shift;
4739     $break_on_load{$file} = 1;
4740     $had_breakpoints{$file} |= 1;
4741 }
4742
4743 =head3 C<report_break_on_load> (API)
4744
4745 Gives us an array of filenames that are set to break on load. Note that
4746 only files with break-on-load are in here, so simply showing the keys
4747 suffices.
4748
4749 =cut
4750
4751 sub report_break_on_load {
4752     sort keys %break_on_load;
4753 }
4754
4755 =head3 C<cmd_b_load> (command)
4756
4757 We take the file passed in and try to find it in C<%INC> (which maps modules
4758 to files they came from). We mark those files for break-on-load via
4759 C<break_on_load> and then report that it was done.
4760
4761 =cut
4762
4763 sub cmd_b_load {
4764     my $file = shift;
4765     my @files;
4766
4767     # This is a block because that way we can use a redo inside it
4768     # even without there being any looping structure at all outside it.
4769     {
4770
4771         # Save short name and full path if found.
4772         push @files, $file;
4773         push @files, $::INC{$file} if $::INC{$file};
4774
4775         # Tack on .pm and do it again unless there was a '.' in the name
4776         # already.
4777         $file .= '.pm', redo unless $file =~ /\./;
4778     }
4779
4780     # Do the real work here.
4781     break_on_load($_) for @files;
4782
4783     # All the files that have break-on-load breakpoints.
4784     @files = report_break_on_load;
4785
4786     # Normalize for the purposes of our printing this.
4787     local $\ = '';
4788     local $" = ' ';
4789     print $OUT "Will stop on load of '@files'.\n";
4790 } ## end sub cmd_b_load
4791
4792 =head3 C<$filename_error> (API package global)
4793
4794 Several of the functions we need to implement in the API need to work both
4795 on the current file and on other files. We don't want to duplicate code, so
4796 C<$filename_error> is used to contain the name of the file that's being
4797 worked on (if it's not the current one).
4798
4799 We can now build functions in pairs: the basic function works on the current
4800 file, and uses C<$filename_error> as part of its error message. Since this is
4801 initialized to C<"">, no filename will appear when we are working on the
4802 current file.
4803
4804 The second function is a wrapper which does the following:
4805
4806 =over 4
4807
4808 =item *
4809
4810 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4811
4812 =item *
4813
4814 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4815
4816 =item *
4817
4818 Calls the first function.
4819
4820 The first function works on the I<current> file (i.e., the one we changed to),
4821 and prints C<$filename_error> in the error message (the name of the other file)
4822 if it needs to. When the functions return, C<*dbline> is restored to point
4823 to the actual current file (the one we're executing in) and
4824 C<$filename_error> is restored to C<"">. This restores everything to
4825 the way it was before the second function was called at all.
4826
4827 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4828 details.
4829
4830 =back
4831
4832 =cut
4833
4834 use vars qw($filename_error);
4835 $filename_error = '';
4836
4837 =head3 breakable_line(from, to) (API)
4838
4839 The subroutine decides whether or not a line in the current file is breakable.
4840 It walks through C<@dbline> within the range of lines specified, looking for
4841 the first line that is breakable.
4842
4843 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4844 first line I<after> C<$to> that's breakable, if there is one.
4845
4846 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4847 first line I<before> C<$to> that's breakable, if there is one.
4848
4849 =cut
4850
4851 sub breakable_line {
4852
4853     my ( $from, $to ) = @_;
4854
4855     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4856     my $i = $from;
4857
4858     # If there are at least 2 arguments, we're trying to search a range.
4859     if ( @_ >= 2 ) {
4860
4861         # $delta is positive for a forward search, negative for a backward one.
4862         my $delta = $from < $to ? +1 : -1;
4863
4864         # Keep us from running off the ends of the file.
4865         my $limit = $delta > 0 ? $#dbline : 1;
4866
4867         # Clever test. If you're a mathematician, it's obvious why this
4868         # test works. If not:
4869         # If $delta is positive (going forward), $limit will be $#dbline.
4870         #    If $to is less than $limit, ($limit - $to) will be positive, times
4871         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4872         #    as the stopping point.
4873         #
4874         #    If $to is greater than $limit, ($limit - $to) is negative,
4875         #    times $delta of 1 (positive), so the result is < 0 and we should
4876         #    use $limit ($#dbline) as the stopping point.
4877         #
4878         # If $delta is negative (going backward), $limit will be 1.
4879         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4880         #    (negative) so the result is > 0, and we use $to as the stopping
4881         #    point.
4882         #
4883         #    If $to is less than zero, ($limit - $to) will be positive,
4884         #    times $delta of -1 (negative), so the result is not > 0, and
4885         #    we use $limit (1) as the stopping point.
4886         #
4887         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4888         #    (negative), still giving zero; the result is not > 0, and
4889         #    we use $limit (1) as the stopping point.
4890         #
4891         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4892         #    (negative), giving a positive (>0) value, so we'll set $limit to
4893         #    $to.
4894
4895         $limit = $to if ( $limit - $to ) * $delta > 0;
4896
4897         # The real search loop.
4898         # $i starts at $from (the point we want to start searching from).
4899         # We move through @dbline in the appropriate direction (determined
4900         # by $delta: either -1 (back) or +1 (ahead).
4901         # We stay in as long as we haven't hit an executable line
4902         # ($dbline[$i] == 0 means not executable) and we haven't reached
4903         # the limit yet (test similar to the above).
4904         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4905
4906     } ## end if (@_ >= 2)
4907
4908     # If $i points to a line that is executable, return that.
4909     return $i unless $dbline[$i] == 0;
4910
4911     # Format the message and print it: no breakable lines in range.
4912     my ( $pl, $upto ) = ( '', '' );
4913     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4914
4915     # If there's a filename in filename_error, we'll see it.
4916     # If not, not.
4917     die "Line$pl $from$upto$filename_error not breakable\n";
4918 } ## end sub breakable_line
4919
4920 =head3 breakable_line_in_filename(file, from, to) (API)
4921
4922 Like C<breakable_line>, but look in another file.
4923
4924 =cut
4925
4926 sub breakable_line_in_filename {
4927
4928     # Capture the file name.
4929     my ($f) = shift;
4930
4931     # Swap the magic line array over there temporarily.
4932     local *dbline = $main::{ '_<' . $f };
4933
4934     # If there's an error, it's in this other file.
4935     local $filename_error = " of '$f'";
4936
4937     # Find the breakable line.
4938     breakable_line(@_);
4939
4940     # *dbline and $filename_error get restored when this block ends.
4941
4942 } ## end sub breakable_line_in_filename
4943
4944 =head3 break_on_line(lineno, [condition]) (API)
4945
4946 Adds a breakpoint with the specified condition (or 1 if no condition was
4947 specified) to the specified line. Dies if it can't.
4948
4949 =cut
4950
4951 sub break_on_line {
4952     my $i = shift;
4953     my $cond = @_ ? shift(@_) : 1;
4954
4955     my $inii  = $i;
4956     my $after = '';
4957     my $pl    = '';
4958
4959     # Woops, not a breakable line. $filename_error allows us to say
4960     # if it was in a different file.
4961     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4962
4963     # Mark this file as having breakpoints in it.
4964     $had_breakpoints{$filename} |= 1;
4965
4966     # If there is an action or condition here already ...
4967     if ( $dbline{$i} ) {
4968
4969         # ... swap this condition for the existing one.
4970         $dbline{$i} =~ s/^[^\0]*/$cond/;
4971     }
4972     else {
4973
4974         # Nothing here - just add the condition.
4975         $dbline{$i} = $cond;
4976
4977         _set_breakpoint_enabled_status($filename, $i, 1);
4978     }
4979
4980     return;
4981 } ## end sub break_on_line
4982
4983 =head3 cmd_b_line(line, [condition]) (command)
4984
4985 Wrapper for C<break_on_line>. Prints the failure message if it
4986 doesn't work.
4987
4988 =cut
4989
4990 sub cmd_b_line {
4991     if (not eval { break_on_line(@_); 1 }) {
4992         local $\ = '';
4993         print $OUT $@ and return;
4994     }
4995
4996     return;
4997 } ## end sub cmd_b_line
4998
4999 =head3 cmd_b_filename_line(line, [condition]) (command)
5000
5001 Wrapper for C<break_on_filename_line>. Prints the failure message if it
5002 doesn't work.
5003
5004 =cut
5005
5006 sub cmd_b_filename_line {
5007     if (not eval { break_on_filename_line(@_); 1 }) {
5008         local $\ = '';
5009         print $OUT $@ and return;
5010     }
5011
5012     return;
5013 }
5014
5015 =head3 break_on_filename_line(file, line, [condition]) (API)
5016
5017 Switches to the file specified and then calls C<break_on_line> to set
5018 the breakpoint.
5019
5020 =cut
5021
5022 sub break_on_filename_line {
5023     my $f = shift;
5024     my $i = shift;
5025     my $cond = @_ ? shift(@_) : 1;
5026
5027     # Switch the magical hash temporarily.
5028     local *dbline = $main::{ '_<' . $f };
5029
5030     # Localize the variables that break_on_line uses to make its message.
5031     local $filename_error = " of '$f'";
5032     local $filename       = $f;
5033
5034     # Add the breakpoint.
5035     break_on_line( $i, $cond );
5036
5037     return;
5038 } ## end sub break_on_filename_line
5039
5040 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
5041
5042 Switch to another file, search the range of lines specified for an
5043 executable one, and put a breakpoint on the first one you find.
5044
5045 =cut
5046
5047 sub break_on_filename_line_range {
5048     my $f = shift;
5049     my $from = shift;
5050     my $to = shift;
5051     my $cond = @_ ? shift(@_) : 1;
5052
5053     # Find a breakable line if there is one.
5054     my $i = breakable_line_in_filename( $f, $from, $to );
5055
5056     # Add the breakpoint.
5057     break_on_filename_line( $f, $i, $cond );
5058
5059     return;
5060 } ## end sub break_on_filename_line_range
5061
5062 =head3 subroutine_filename_lines(subname, [condition]) (API)
5063
5064 Search for a subroutine within a given file. The condition is ignored.
5065 Uses C<find_sub> to locate the desired subroutine.
5066
5067 =cut
5068
5069 sub subroutine_filename_lines {
5070     my ( $subname ) = @_;
5071
5072     # Returned value from find_sub() is fullpathname:startline-endline.
5073     # The match creates the list (fullpathname, start, end).
5074     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5075 } ## end sub subroutine_filename_lines
5076
5077 =head3 break_subroutine(subname) (API)
5078
5079 Places a break on the first line possible in the specified subroutine. Uses
5080 C<subroutine_filename_lines> to find the subroutine, and
5081 C<break_on_filename_line_range> to place the break.
5082
5083 =cut
5084
5085 sub break_subroutine {
5086     my $subname = shift;
5087
5088     # Get filename, start, and end.
5089     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5090       or die "Subroutine $subname not found.\n";
5091
5092
5093     # Null condition changes to '1' (always true).
5094     my $cond = @_ ? shift(@_) : 1;
5095
5096     # Put a break the first place possible in the range of lines
5097     # that make up this subroutine.
5098     break_on_filename_line_range( $file, $s, $e, $cond );
5099
5100     return;
5101 } ## end sub break_subroutine
5102
5103 =head3 cmd_b_sub(subname, [condition]) (command)
5104
5105 We take the incoming subroutine name and fully-qualify it as best we can.
5106
5107 =over 4
5108
5109 =item 1. If it's already fully-qualified, leave it alone.
5110
5111 =item 2. Try putting it in the current package.
5112
5113 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5114
5115 =item 4. If it starts with '::', put it in 'main::'.
5116
5117 =back
5118
5119 After all this cleanup, we call C<break_subroutine> to try to set the
5120 breakpoint.
5121
5122 =cut
5123
5124 sub cmd_b_sub {
5125     my $subname = shift;
5126     my $cond = @_ ? shift : 1;
5127
5128     # If the subname isn't a code reference, qualify it so that
5129     # break_subroutine() will work right.
5130     if ( ref($subname) ne 'CODE' ) {
5131
5132         # Not Perl 4.
5133         $subname =~ s/'/::/g;
5134         my $s = $subname;
5135
5136         # Put it in this package unless it's already qualified.
5137         if ($subname !~ /::/)
5138         {
5139             $subname = $package . '::' . $subname;
5140         };
5141
5142         # Requalify it into CORE::GLOBAL if qualifying it into this
5143         # package resulted in its not being defined, but only do so
5144         # if it really is in CORE::GLOBAL.
5145         my $core_name = "CORE::GLOBAL::$s";
5146         if ((!defined(&$subname))
5147                 and ($s !~ /::/)
5148                 and (defined &{$core_name}))
5149         {
5150             $subname = $core_name;
5151         }
5152
5153         # Put it in package 'main' if it has a leading ::.
5154         if ($subname =~ /\A::/)
5155         {
5156             $subname = "main" . $subname;
5157         }
5158     } ## end if ( ref($subname) ne 'CODE' ) {
5159
5160     # Try to set the breakpoint.
5161     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5162         local $\ = '';
5163         print {$OUT} $@;
5164         return;
5165     }
5166
5167     return;
5168 } ## end sub cmd_b_sub
5169
5170 =head3 C<cmd_B> - delete breakpoint(s) (command)
5171
5172 The command mostly parses the command line and tries to turn the argument
5173 into a line spec. If it can't, it uses the current line. It then calls
5174 C<delete_breakpoint> to actually do the work.
5175
5176 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5177 thereby deleting all the breakpoints.
5178
5179 =cut
5180
5181 sub cmd_B {
5182     my $cmd = shift;
5183
5184     # No line spec? Use dbline.
5185     # If there is one, use it if it's non-zero, or wipe it out if it is.
5186     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5187     my $dbline = shift;
5188
5189     # If the line was dot, make the line the current one.
5190     $line =~ s/^\./$dbline/;
5191
5192     # If it's * we're deleting all the breakpoints.
5193     if ( $line eq '*' ) {
5194         if (not eval { delete_breakpoint(); 1 }) {
5195             print {$OUT} $@;
5196         }
5197     }
5198
5199     # If there is a line spec, delete the breakpoint on that line.
5200     elsif ( $line =~ /\A(\S.*)/ ) {
5201         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5202             local $\ = '';
5203             print {$OUT} $@;
5204         }
5205     } ## end elsif ($line =~ /^(\S.*)/)
5206
5207     # No line spec.
5208     else {
5209         print {$OUT}
5210           "Deleting a breakpoint requires a line number, or '*' for all\n"
5211           ;    # hint
5212     }
5213
5214     return;
5215 } ## end sub cmd_B
5216
5217 =head3 delete_breakpoint([line]) (API)
5218
5219 This actually does the work of deleting either a single breakpoint, or all
5220 of them.
5221
5222 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5223 just drop out with a message saying so. If it is, we remove the condition
5224 part of the 'condition\0action' that says there's a breakpoint here. If,
5225 after we've done that, there's nothing left, we delete the corresponding
5226 line in C<%dbline> to signal that no action needs to be taken for this line.
5227
5228 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5229 which lists all currently-loaded files which have breakpoints. We then look
5230 at each line in each of these files, temporarily switching the C<%dbline>
5231 and C<@dbline> structures to point to the files in question, and do what
5232 we did in the single line case: delete the condition in C<@dbline>, and
5233 delete the key in C<%dbline> if nothing's left.
5234
5235 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5236 C<%break_on_load>, because these structures contain breakpoints for files
5237 and code that haven't been loaded yet. We can just kill these off because there
5238 are no magical debugger structures associated with them.
5239
5240 =cut
5241
5242 sub _remove_breakpoint_entry {
5243     my ($fn, $i) = @_;
5244
5245     delete $dbline{$i};
5246     _delete_breakpoint_data_ref($fn, $i);
5247
5248     return;
5249 }
5250
5251 sub _delete_all_breakpoints {
5252     print {$OUT} "Deleting all breakpoints...\n";
5253
5254     # %had_breakpoints lists every file that had at least one
5255     # breakpoint in it.
5256     for my $fn ( keys %had_breakpoints ) {
5257
5258         # Switch to the desired file temporarily.
5259         local *dbline = $main::{ '_<' . $fn };
5260
5261         $max = $#dbline;
5262
5263         # For all lines in this file ...
5264         for my $i (1 .. $max) {
5265
5266             # If there's a breakpoint or action on this line ...
5267             if ( defined $dbline{$i} ) {
5268
5269                 # ... remove the breakpoint.
5270                 $dbline{$i} =~ s/\A[^\0]+//;
5271                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5272                     # Remove the entry altogether if no action is there.
5273                     _remove_breakpoint_entry($fn, $i);
5274                 }
5275             } ## end if (defined $dbline{$i...
5276         } ## end for $i (1 .. $max)
5277
5278         # If, after we turn off the "there were breakpoints in this file"
5279         # bit, the entry in %had_breakpoints for this file is zero,
5280         # we should remove this file from the hash.
5281         if ( not $had_breakpoints{$fn} &= (~1) ) {
5282             delete $had_breakpoints{$fn};
5283         }
5284     } ## end for my $fn (keys %had_breakpoints)
5285
5286     # Kill off all the other breakpoints that are waiting for files that
5287     # haven't been loaded yet.
5288     undef %postponed;
5289     undef %postponed_file;
5290     undef %break_on_load;
5291
5292     return;
5293 }
5294
5295 sub _delete_breakpoint_from_line {
5296     my ($i) = @_;
5297
5298     # Woops. This line wasn't breakable at all.
5299     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5300
5301     # Kill the condition, but leave any action.
5302     $dbline{$i} =~ s/\A[^\0]*//;
5303
5304     # Remove the entry entirely if there's no action left.
5305     if ($dbline{$i} eq '') {
5306         _remove_breakpoint_entry($filename, $i);
5307     }
5308
5309     return;
5310 }
5311
5312 sub delete_breakpoint {
5313     my $i = shift;
5314
5315     # If we got a line, delete just that one.
5316     if ( defined($i) ) {
5317         _delete_breakpoint_from_line($i);
5318     }
5319     # No line; delete them all.
5320     else {
5321         _delete_all_breakpoints();
5322     }
5323
5324     return;
5325 }
5326
5327 =head3 cmd_stop (command)
5328
5329 This is meant to be part of the new command API, but it isn't called or used
5330 anywhere else in the debugger. XXX It is probably meant for use in development
5331 of new commands.
5332
5333 =cut
5334
5335 sub cmd_stop {    # As on ^C, but not signal-safy.
5336     $signal = 1;
5337 }
5338
5339 =head3 C<cmd_e> - threads
5340
5341 Display the current thread id:
5342
5343     e
5344
5345 This could be how (when implemented) to send commands to this thread id (e cmd)
5346 or that thread id (e tid cmd).
5347
5348 =cut
5349
5350 sub cmd_e {
5351     my $cmd  = shift;
5352     my $line = shift;
5353     unless (exists($INC{'threads.pm'})) {
5354         print "threads not loaded($ENV{PERL5DB_THREADED})
5355         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5356     } else {
5357         my $tid = threads->tid;
5358         print "thread id: $tid\n";
5359     }
5360 } ## end sub cmd_e
5361
5362 =head3 C<cmd_E> - list of thread ids
5363
5364 Display the list of available thread ids:
5365
5366     E
5367
5368 This could be used (when implemented) to send commands to all threads (E cmd).
5369
5370 =cut
5371
5372 sub cmd_E {
5373     my $cmd  = shift;
5374     my $line = shift;
5375     unless (exists($INC{'threads.pm'})) {
5376         print "threads not loaded($ENV{PERL5DB_THREADED})
5377         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5378     } else {
5379         my $tid = threads->tid;
5380         print "thread ids: ".join(', ',
5381             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5382         )."\n";
5383     }
5384 } ## end sub cmd_E
5385
5386 =head3 C<cmd_h> - help command (command)
5387
5388 Does the work of either
5389
5390 =over 4
5391
5392 =item *
5393
5394 Showing all the debugger help
5395
5396 =item *
5397
5398 Showing help for a specific command
5399
5400 =back
5401
5402 =cut
5403
5404 use vars qw($help);
5405 use vars qw($summary);
5406
5407 sub cmd_h {
5408     my $cmd = shift;
5409
5410     # If we have no operand, assume null.
5411     my $line = shift || '';
5412
5413     # 'h h'. Print the long-format help.
5414     if ( $line =~ /\Ah\s*\z/ ) {
5415         print_help($help);
5416     }
5417
5418     # 'h <something>'. Search for the command and print only its help.
5419     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5420
5421         # support long commands; otherwise bogus errors
5422         # happen when you ask for h on <CR> for example
5423         my $qasked = quotemeta($asked);    # for searching; we don't
5424                                            # want to use it as a pattern.
5425                                            # XXX: finds CR but not <CR>
5426
5427         # Search the help string for the command.
5428         if (
5429             $help =~ /^                    # Start of a line
5430                       <?                   # Optional '<'
5431                       (?:[IB]<)            # Optional markup
5432                       $qasked              # The requested command
5433                      /mx
5434           )
5435         {
5436
5437             # It's there; pull it out and print it.
5438             while (
5439                 $help =~ /^
5440                               (<?            # Optional '<'
5441                                  (?:[IB]<)   # Optional markup
5442                                  $qasked     # The command
5443                                  ([\s\S]*?)  # Description line(s)
5444                               \n)            # End of last description line
5445                               (?!\s)         # Next line not starting with
5446                                              # whitespace
5447                              /mgx
5448               )
5449             {
5450                 print_help($1);
5451             }
5452         }
5453
5454         # Not found; not a debugger command.
5455         else {
5456             print_help("B<$asked> is not a debugger command.\n");
5457         }
5458     } ## end elsif ($line =~ /^(\S.*)$/)
5459
5460     # 'h' - print the summary help.
5461     else {
5462         print_help($summary);
5463     }
5464 } ## end sub cmd_h
5465
5466 =head3 C<cmd_i> - inheritance display
5467
5468 Display the (nested) parentage of the module or object given.
5469
5470 =cut
5471
5472 sub cmd_i {
5473     my $cmd  = shift;
5474     my $line = shift;
5475     foreach my $isa ( split( /\s+/, $line ) ) {
5476         $evalarg = $isa;
5477         # The &-call is here to ascertain the mutability of @_.
5478         ($isa) = &DB::eval;
5479         no strict 'refs';
5480         print join(
5481             ', ',
5482             map {
5483                 "$_"
5484                   . (
5485                     defined( ${"$_\::VERSION"} )
5486                     ? ' ' . ${"$_\::VERSION"}
5487                     : undef )
5488               } @{mro::get_linear_isa(ref($isa) || $isa)}
5489         );
5490         print "\n";
5491     }
5492 } ## end sub cmd_i
5493
5494 =head3 C<cmd_l> - list lines (command)
5495
5496 Most of the command is taken up with transforming all the different line
5497 specification syntaxes into 'start-stop'. After that is done, the command
5498 runs a loop over C<@dbline> for the specified range of lines. It handles
5499 the printing of each line and any markers (C<==E<gt>> for current line,
5500 C<b> for break on this line, C<a> for action on this line, C<:> for this
5501 line breakable).
5502
5503 We save the last line listed in the C<$start> global for further listing
5504 later.
5505
5506 =cut
5507
5508 sub _min {
5509     my $min = shift;
5510     foreach my $v (@_) {
5511         if ($min > $v) {
5512             $min = $v;
5513         }
5514     }
5515     return $min;
5516 }
5517
5518 sub _max {
5519     my $max = shift;
5520     foreach my $v (@_) {
5521         if ($max < $v) {
5522             $max = $v;
5523         }
5524     }
5525     return $max;
5526 }
5527
5528 sub _minify_to_max {
5529     my $ref = shift;
5530
5531     $$ref = _min($$ref, $max);
5532
5533     return;
5534 }
5535
5536 sub _cmd_l_handle_var_name {
5537     my $var_name = shift;
5538
5539     $evalarg = $var_name;
5540
5541     my ($s) = DB::eval();
5542
5543     # Ooops. Bad scalar.
5544     if ($@) {
5545         print {$OUT} "Error: $@\n";
5546         next CMD;
5547     }
5548
5549     # Good scalar. If it's a reference, find what it points to.
5550     $s = CvGV_name($s);
5551     print {$OUT} "Interpreted as: $1 $s\n";
5552     $line = "$1 $s";
5553
5554     # Call self recursively to really do the command.
5555     return _cmd_l_main( $s );
5556 }
5557
5558 sub _cmd_l_handle_subname {
5559
5560     my $s = $subname;
5561
5562     # De-Perl4.
5563     $subname =~ s/\'/::/;
5564
5565     # Put it in this package unless it starts with ::.
5566     $subname = $package . "::" . $subname unless $subname =~ /::/;
5567
5568     # Put it in CORE::GLOBAL if t doesn't start with :: and
5569     # it doesn't live in this package and it lives in CORE::GLOBAL.
5570     $subname = "CORE::GLOBAL::$s"
5571     if not defined &$subname
5572         and $s !~ /::/
5573         and defined &{"CORE::GLOBAL::$s"};
5574
5575     # Put leading '::' names into 'main::'.
5576     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5577
5578     # Get name:start-stop from find_sub, and break this up at
5579     # colons.
5580     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5581
5582     # Pull off start-stop.
5583     my $subrange = pop @pieces;
5584
5585     # If the name contained colons, the split broke it up.
5586     # Put it back together.
5587     $file = join( ':', @pieces );
5588
5589     # If we're not in that file, switch over to it.
5590     if ( $file ne $filename ) {
5591         if (! $slave_editor) {
5592             print {$OUT} "Switching to file '$file'.\n";
5593         }
5594
5595         # Switch debugger's magic structures.
5596         *dbline   = $main::{ '_<' . $file };
5597         $max      = $#dbline;
5598         $filename = $file;
5599     } ## end if ($file ne $filename)
5600
5601     # Subrange is 'start-stop'. If this is less than a window full,
5602     # swap it to 'start+', which will list a window from the start point.
5603     if ($subrange) {
5604         if ( eval($subrange) < -$window ) {
5605             $subrange =~ s/-.*/+/;
5606         }
5607
5608         # Call self recursively to list the range.
5609         return _cmd_l_main( $subrange );
5610     } ## end if ($subrange)
5611
5612     # Couldn't find it.
5613     else {
5614         print {$OUT} "Subroutine $subname not found.\n";
5615         return;
5616     }
5617 }
5618
5619 sub _cmd_l_empty {
5620     # Compute new range to list.
5621     $incr = $window - 1;
5622
5623     # Recurse to do it.
5624     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5625 }
5626
5627 sub _cmd_l_plus {
5628     my ($new_start, $new_incr) = @_;
5629
5630     # Don't reset start for 'l +nnn'.
5631     $start = $new_start if $new_start;
5632
5633     # Increment for list. Use window size if not specified.
5634     # (Allows 'l +' to work.)
5635     $incr = $new_incr || ($window - 1);
5636
5637     # Create a line range we'll understand, and recurse to do it.
5638     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5639 }
5640
5641 sub _cmd_l_calc_initial_end_and_i {
5642     my ($spec, $start_match, $end_match) = @_;
5643
5644     # Determine end point; use end of file if not specified.
5645     my $end = ( !defined $start_match ) ? $max :
5646     ( $end_match ? $end_match : $start_match );
5647
5648     # Go on to the end, and then stop.
5649     _minify_to_max(\$end);
5650
5651     # Determine start line.
5652     my $i = $start_match;
5653
5654     if ($i eq '.') {
5655         $i = $spec;
5656     }
5657
5658     $i = _max($i, 1);
5659
5660     $incr = $end - $i;
5661
5662     return ($end, $i);
5663 }
5664
5665 sub _cmd_l_range {
5666     my ($spec, $current_line, $start_match, $end_match) = @_;
5667
5668     my ($end, $i) =
5669         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5670
5671     # If we're running under a slave editor, force it to show the lines.
5672     if ($slave_editor) {
5673         print {$OUT} "\032\032$filename:$i:0\n";
5674         $i = $end;
5675     }
5676     # We're doing it ourselves. We want to show the line and special
5677     # markers for:
5678     # - the current line in execution
5679     # - whether a line is breakable or not
5680     # - whether a line has a break or not
5681     # - whether a line has an action or not
5682     else {
5683         I_TO_END:
5684         for ( ; $i <= $end ; $i++ ) {
5685
5686             # Check for breakpoints and actions.
5687             my ( $stop, $action );
5688             if ($dbline{$i}) {
5689                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5690             }
5691
5692             # ==> if this is the current line in execution,
5693             # : if it's breakable.
5694             my $arrow =
5695             ( $i == $current_line and $filename eq $filename_ini )
5696             ? '==>'
5697             : ( $dbline[$i] + 0 ? ':' : ' ' );
5698
5699             # Add break and action indicators.
5700             $arrow .= 'b' if $stop;
5701             $arrow .= 'a' if $action;
5702
5703             # Print the line.
5704             print {$OUT} "$i$arrow\t", $dbline[$i];
5705
5706             # Move on to the next line. Drop out on an interrupt.
5707             if ($signal) {
5708                 $i++;
5709                 last I_TO_END;
5710             }
5711         } ## end for (; $i <= $end ; $i++)
5712
5713         # Line the prompt up; print a newline if the last line listed
5714         # didn't have a newline.
5715         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5716             print {$OUT} "\n";
5717         }
5718     } ## end else [ if ($slave_editor)
5719
5720     # Save the point we last listed to in case another relative 'l'
5721     # command is desired. Don't let it run off the end.
5722     $start = $i;
5723     _minify_to_max(\$start);
5724
5725     return;
5726 }
5727
5728 sub _cmd_l_main {
5729     my $spec = shift;
5730
5731     # If this is '-something', delete any spaces after the dash.
5732     $spec =~ s/\A-\s*\z/-/;
5733
5734     # If the line is '$something', assume this is a scalar containing a
5735     # line number.
5736     # Set up for DB::eval() - evaluate in *user* context.
5737     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5738         return _cmd_l_handle_var_name($var_name);
5739     }
5740     # l name. Try to find a sub by that name.
5741     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5742         return _cmd_l_handle_subname();
5743     }
5744     # Bare 'l' command.
5745     elsif ( $spec !~ /\S/ ) {
5746         return _cmd_l_empty();
5747     }
5748     # l [start]+number_of_lines
5749     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5750         return _cmd_l_plus($new_start, $new_incr);
5751     }
5752     # l start-stop or l start,stop
5753     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5754         return _cmd_l_range($spec, $line, $s, $e);
5755     }
5756
5757     return;
5758 } ## end sub cmd_l
5759
5760 sub cmd_l {
5761     my (undef, $line) = @_;
5762
5763     return _cmd_l_main($line);
5764 }
5765
5766 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5767
5768 To list breakpoints, the command has to look determine where all of them are
5769 first. It starts a C<%had_breakpoints>, which tells us what all files have
5770 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5771 magic source and breakpoint data structures) to the file, and then look
5772 through C<%dbline> for lines with breakpoints and/or actions, listing them
5773 out. We look through C<%postponed> not-yet-compiled subroutines that have
5774 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5775 that have breakpoints.
5776
5777 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5778
5779 =cut
5780
5781 sub _cmd_L_calc_arg {
5782     # If no argument, list everything. Pre-5.8.0 version always lists
5783     # everything
5784     my $arg = shift || 'abw';
5785     if ($CommandSet ne '580')
5786     {
5787         $arg = 'abw';
5788     }
5789
5790     return $arg;
5791 }
5792
5793 sub _cmd_L_calc_wanted_flags {
5794     my $arg = _cmd_L_calc_arg(shift);
5795
5796     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5797 }
5798
5799
5800 sub _cmd_L_handle_breakpoints {
5801     my ($handle_db_line) = @_;
5802
5803     BREAKPOINTS_SCAN:
5804     # Look in all the files with breakpoints...
5805     for my $file ( keys %had_breakpoints ) {
5806
5807         # Temporary switch to this file.
5808         local *dbline = $main::{ '_<' . $file };
5809
5810         # Set up to look through the whole file.
5811         $max = $#dbline;
5812         my $was;    # Flag: did we print something
5813         # in this file?
5814
5815         # For each line in the file ...
5816         for my $i (1 .. $max) {
5817
5818             # We've got something on this line.
5819             if ( defined $dbline{$i} ) {
5820
5821                 # Print the header if we haven't.
5822                 if (not $was++) {
5823                     print {$OUT} "$file:\n";
5824                 }
5825
5826                 # Print the line.
5827                 print {$OUT} " $i:\t", $dbline[$i];
5828
5829                 $handle_db_line->($dbline{$i});
5830
5831                 # Quit if the user hit interrupt.
5832                 if ($signal) {
5833                     last BREAKPOINTS_SCAN;
5834                 }
5835             } ## end if (defined $dbline{$i...
5836         } ## end for my $i (1 .. $max)
5837     } ## end for my $file (keys %had_breakpoints)
5838
5839     return;
5840 }
5841
5842 sub _cmd_L_handle_postponed_breakpoints {
5843     my ($handle_db_line) = @_;
5844
5845     print {$OUT} "Postponed breakpoints in files:\n";
5846
5847     POSTPONED_SCANS:
5848     for my $file ( keys %postponed_file ) {
5849         my $db = $postponed_file{$file};
5850         print {$OUT} " $file:\n";
5851         for my $line ( sort { $a <=> $b } keys %$db ) {
5852             print {$OUT} "  $line:\n";
5853
5854             $handle_db_line->($db->{$line});
5855
5856             if ($signal) {
5857                 last POSTPONED_SCANS;
5858             }
5859         }
5860         if ($signal) {
5861             last POSTPONED_SCANS;
5862         }
5863     }
5864
5865     return;
5866 }
5867
5868
5869 sub cmd_L {
5870     my $cmd = shift;
5871
5872     my ($action_wanted, $break_wanted, $watch_wanted) =
5873         _cmd_L_calc_wanted_flags(shift);
5874
5875     my $handle_db_line = sub {
5876         my ($l) = @_;
5877
5878         my ( $stop, $action ) = split( /\0/, $l );
5879
5880         if ($stop and $break_wanted) {
5881             print {$OUT} "    break if (", $stop, ")\n"
5882         }
5883
5884         if ($action && $action_wanted) {
5885             print {$OUT} "    action:  ", $action, "\n"
5886         }
5887
5888         return;
5889     };
5890
5891     # Breaks and actions are found together, so we look in the same place
5892     # for both.
5893     if ( $break_wanted or $action_wanted ) {
5894         _cmd_L_handle_breakpoints($handle_db_line);
5895     }
5896
5897     # Look for breaks in not-yet-compiled subs:
5898     if ( %postponed and $break_wanted ) {
5899         print {$OUT} "Postponed breakpoints in subroutines:\n";
5900         my $subname;
5901         SUBS_SCAN:
5902         for $subname ( keys %postponed ) {
5903             print {$OUT} " $subname\t$postponed{$subname}\n";
5904             if ($signal) {
5905                 last SUBS_SCAN;
5906             }
5907         }
5908     } ## end if (%postponed and $break_wanted)
5909
5910     # Find files that have not-yet-loaded breaks:
5911     my @have = map {    # Combined keys
5912         keys %{ $postponed_file{$_} }
5913     } keys %postponed_file;
5914
5915     # If there are any, list them.
5916     if ( @have and ( $break_wanted or $action_wanted ) ) {
5917         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5918     } ## end if (@have and ($break_wanted...
5919
5920     if ( %break_on_load and $break_wanted ) {
5921         print {$OUT} "Breakpoints on load:\n";
5922         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5923             print {$OUT} " $filename\n";
5924             last BREAK_ON_LOAD if $signal;
5925         }
5926     } ## end if (%break_on_load and...
5927
5928     if ($watch_wanted and ( $trace & 2 )) {
5929         print {$OUT} "Watch-expressions:\n" if @to_watch;
5930         TO_WATCH: for my $expr (@to_watch) {
5931             print {$OUT} " $expr\n";
5932             last TO_WATCH if $signal;
5933         }
5934     }
5935
5936     return;
5937 } ## end sub cmd_L
5938
5939 =head3 C<cmd_M> - list modules (command)
5940
5941 Just call C<list_modules>.
5942
5943 =cut
5944
5945 sub cmd_M {
5946     list_modules();
5947
5948     return;
5949 }
5950
5951 =head3 C<cmd_o> - options (command)
5952
5953 If this is just C<o> by itself, we list the current settings via
5954 C<dump_option>. If there's a nonblank value following it, we pass that on to
5955 C<parse_options> for processing.
5956
5957 =cut
5958
5959 sub cmd_o {
5960     my $cmd = shift;
5961     my $opt = shift || '';    # opt[=val]
5962
5963     # Nonblank. Try to parse and process.
5964     if ( $opt =~ /^(\S.*)/ ) {
5965         parse_options($1);
5966     }
5967
5968     # Blank. List the current option settings.
5969     else {
5970         for (@options) {
5971             dump_option($_);
5972         }
5973     }
5974 } ## end sub cmd_o
5975
5976 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5977
5978 Advises the user that the O command has been renamed.
5979
5980 =cut
5981
5982 sub cmd_O {
5983     print $OUT "The old O command is now the o command.\n";             # hint
5984     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5985     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5986 }
5987
5988 =head3 C<cmd_v> - view window (command)
5989
5990 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5991 move back a few lines to list the selected line in context. Uses C<cmd_l>
5992 to do the actual listing after figuring out the range of line to request.
5993
5994 =cut
5995
5996 use vars qw($preview);
5997
5998 sub cmd_v {
5999     my $cmd  = shift;
6000     my $line = shift;
6001
6002     # Extract the line to list around. (Astute readers will have noted that
6003     # this pattern will match whether or not a numeric line is specified,
6004     # which means that we'll always enter this loop (though a non-numeric
6005     # argument results in no action at all)).
6006     if ( $line =~ /^(\d*)$/ ) {
6007
6008         # Total number of lines to list (a windowful).
6009         $incr = $window - 1;
6010
6011         # Set the start to the argument given (if there was one).
6012         $start = $1 if $1;
6013
6014         # Back up by the context amount.
6015         $start -= $preview;
6016
6017         # Put together a linespec that cmd_l will like.
6018         $line = $start . '-' . ( $start + $incr );
6019
6020         # List the lines.
6021         cmd_l( 'l', $line );
6022     } ## end if ($line =~ /^(\d*)$/)
6023 } ## end sub cmd_v
6024
6025 =head3 C<cmd_w> - add a watch expression (command)
6026
6027 The 5.8 version of this command adds a watch expression if one is specified;
6028 it does nothing if entered with no operands.
6029
6030 We extract the expression, save it, evaluate it in the user's context, and
6031 save the value. We'll re-evaluate it each time the debugger passes a line,
6032 and will stop (see the code at the top of the command loop) if the value
6033 of any of the expressions changes.
6034
6035 =cut
6036
6037 sub _add_watch_expr {
6038     my $expr = shift;
6039
6040     # ... save it.
6041     push @to_watch, $expr;
6042
6043     # Parameterize DB::eval and call it to get the expression's value
6044     # in the user's context. This version can handle expressions which
6045     # return a list value.
6046     $evalarg = $expr;
6047     # The &-call is here to ascertain the mutability of @_.
6048     my ($val) = join( ' ', &DB::eval);
6049     $val = ( defined $val ) ? "'$val'" : 'undef';
6050
6051     # Save the current value of the expression.
6052     push @old_watch, $val;
6053
6054     # We are now watching expressions.
6055     $trace |= 2;
6056
6057     return;
6058 }
6059
6060 sub cmd_w {
6061     my $cmd = shift;
6062
6063     # Null expression if no arguments.
6064     my $expr = shift || '';
6065
6066     # If expression is not null ...
6067     if ( $expr =~ /\A\S/ ) {
6068         _add_watch_expr($expr);
6069     } ## end if ($expr =~ /^(\S.*)/)
6070
6071     # You have to give one to get one.
6072     else {
6073         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6074     }
6075
6076     return;
6077 }
6078
6079 =head3 C<cmd_W> - delete watch expressions (command)
6080
6081 This command accepts either a watch expression to be removed from the list
6082 of watch expressions, or C<*> to delete them all.
6083
6084 If C<*> is specified, we simply empty the watch expression list and the
6085 watch expression value list. We also turn off the bit that says we've got
6086 watch expressions.
6087
6088 If an expression (or partial expression) is specified, we pattern-match
6089 through the expressions and remove the ones that match. We also discard
6090 the corresponding values. If no watch expressions are left, we turn off
6091 the I<watching expressions> bit.
6092
6093 =cut
6094
6095 sub cmd_W {
6096     my $cmd  = shift;
6097     my $expr = shift || '';
6098
6099     # Delete them all.
6100     if ( $expr eq '*' ) {
6101
6102         # Not watching now.
6103         $trace &= ~2;
6104
6105         print $OUT "Deleting all watch expressions ...\n";
6106
6107         # And all gone.
6108         @to_watch = @old_watch = ();
6109     }
6110
6111     # Delete one of them.
6112     elsif ( $expr =~ /^(\S.*)/ ) {
6113
6114         # Where we are in the list.
6115         my $i_cnt = 0;
6116
6117         # For each expression ...
6118         foreach (@to_watch) {
6119             my $val = $to_watch[$i_cnt];
6120
6121             # Does this one match the command argument?
6122             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6123                                       # Yes. Turn it off, and its value too.
6124                 splice( @to_watch,  $i_cnt, 1 );
6125                 splice( @old_watch, $i_cnt, 1 );
6126             }
6127             $i_cnt++;
6128         } ## end foreach (@to_watch)
6129
6130         # We don't bother to turn watching off because
6131         #  a) we don't want to stop calling watchfunction() if it exists
6132         #  b) foreach over a null list doesn't do anything anyway
6133
6134     } ## end elsif ($expr =~ /^(\S.*)/)
6135
6136     # No command arguments entered.
6137     else {
6138         print $OUT
6139           "Deleting a watch-expression requires an expression, or '*' for all\n"
6140           ;    # hint
6141     }
6142 } ## end sub cmd_W
6143
6144 ### END of the API section
6145
6146 =head1 SUPPORT ROUTINES
6147
6148 These are general support routines that are used in a number of places
6149 throughout the debugger.
6150
6151 =head2 save
6152
6153 save() saves the user's versions of globals that would mess us up in C<@saved>,
6154 and installs the versions we like better.
6155
6156 =cut
6157
6158 sub save {
6159
6160     # Save eval failure, command failure, extended OS error, output field
6161     # separator, input record separator, output record separator and
6162     # the warning setting.
6163     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6164
6165     $,  = "";      # output field separator is null string
6166     $/  = "\n";    # input record separator is newline
6167     $\  = "";      # output record separator is null string
6168     $^W = 0;       # warnings are off
6169 } ## end sub save
6170
6171 =head2 C<print_lineinfo> - show where we are now
6172
6173 print_lineinfo prints whatever it is that it is handed; it prints it to the
6174 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6175 us to feed line information to a slave editor without messing up the
6176 debugger output.
6177
6178 =cut
6179
6180 sub print_lineinfo {
6181
6182     # Make the terminal sensible if we're not the primary debugger.
6183     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6184     local $\ = '';
6185     local $, = '';
6186     # $LINEINFO may be undef if $noTTY is set or some other issue.
6187     if ($LINEINFO)
6188     {
6189         print {$LINEINFO} @_;
6190     }
6191 } ## end sub print_lineinfo
6192
6193 =head2 C<postponed_sub>
6194
6195 Handles setting postponed breakpoints in subroutines once they're compiled.
6196 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6197 range for the subroutine, then mark the file as having a breakpoint,
6198 temporarily switch the C<*dbline> glob over to the source file, and then
6199 search the given range of lines to find a breakable line. If we find one,
6200 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6201
6202 =cut
6203
6204 # The following takes its argument via $evalarg to preserve current @_
6205
6206 sub postponed_sub {
6207
6208     # Get the subroutine name.
6209     my $subname = shift;
6210
6211     # If this is a 'break +<n> if <condition>' ...
6212     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6213
6214         # If there's no offset, use '+0'.
6215         my $offset = $1 || 0;
6216
6217         # find_sub's value is 'fullpath-filename:start-stop'. It's
6218         # possible that the filename might have colons in it too.
6219         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6220         if ($i) {
6221
6222             # We got the start line. Add the offset '+<n>' from
6223             # $postponed{subname}.
6224             $i += $offset;
6225
6226             # Switch to the file this sub is in, temporarily.
6227             local *dbline = $main::{ '_<' . $file };
6228
6229             # No warnings, please.
6230             local $^W = 0;    # != 0 is magical below
6231
6232             # This file's got a breakpoint in it.
6233             $had_breakpoints{$file} |= 1;
6234
6235             # Last line in file.
6236             $max = $#dbline;
6237
6238             # Search forward until we hit a breakable line or get to
6239             # the end of the file.
6240             ++$i until $dbline[$i] != 0 or $i >= $max;
6241
6242             # Copy the breakpoint in and delete it from %postponed.
6243             $dbline{$i} = delete $postponed{$subname};
6244         } ## end if ($i)
6245
6246         # find_sub didn't find the sub.
6247         else {
6248             local $\ = '';
6249             print $OUT "Subroutine $subname not found.\n";
6250         }
6251         return;
6252     } ## end if ($postponed{$subname...
6253     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6254
6255     #print $OUT "In postponed_sub for '$subname'.\n";
6256 } ## end sub postponed_sub
6257
6258 =head2 C<postponed>
6259
6260 Called after each required file is compiled, but before it is executed;
6261 also called if the name of a just-compiled subroutine is a key of
6262 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6263 etc.) into the just-compiled code.
6264
6265 If this is a C<require>'d file, the incoming parameter is the glob
6266 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6267
6268 If it's a subroutine, the incoming parameter is the subroutine name.
6269
6270 =cut
6271
6272 sub postponed {
6273
6274     # If there's a break, process it.
6275     if ($ImmediateStop) {
6276
6277         # Right, we've stopped. Turn it off.
6278         $ImmediateStop = 0;
6279
6280         # Enter the command loop when DB::DB gets called.
6281         $signal = 1;
6282     }
6283
6284     # If this is a subroutine, let postponed_sub() deal with it.
6285     if (ref(\$_[0]) ne 'GLOB') {
6286         return postponed_sub(@_);
6287     }
6288
6289     # Not a subroutine. Deal with the file.
6290     local *dbline = shift;
6291     my $filename = $dbline;
6292     $filename =~ s/^_<//;
6293     local $\ = '';
6294     $signal = 1, print $OUT "'$filename' loaded...\n"
6295       if $break_on_load{$filename};
6296     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6297
6298     # Do we have any breakpoints to put in this file?
6299     return unless $postponed_file{$filename};
6300
6301     # Yes. Mark this file as having breakpoints.
6302     $had_breakpoints{$filename} |= 1;
6303
6304     # "Cannot be done: insufficient magic" - we can't just put the
6305     # breakpoints saved in %postponed_file into %dbline by assigning
6306     # the whole hash; we have to do it one item at a time for the
6307     # breakpoints to be set properly.
6308     #%dbline = %{$postponed_file{$filename}};
6309
6310     # Set the breakpoints, one at a time.
6311     my $key;
6312
6313     for $key ( keys %{ $postponed_file{$filename} } ) {
6314
6315         # Stash the saved breakpoint into the current file's magic line array.
6316         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6317     }
6318
6319     # This file's been compiled; discard the stored breakpoints.
6320     delete $postponed_file{$filename};
6321
6322 } ## end sub postponed
6323
6324 =head2 C<dumpit>
6325
6326 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6327
6328 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6329 a reference to a variable (the thing to be dumped) as its input.
6330
6331 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6332 the currently-selected filehandle, thank you very much). The current
6333 values of the package globals C<$single> and C<$trace> are backed up in
6334 lexicals, and they are turned off (this keeps the debugger from trying
6335 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6336 preserve its current value and it is set to zero to prevent entry/exit
6337 messages from printing, and C<$doret> is localized as well and set to -2 to
6338 prevent return values from being shown.
6339
6340 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6341 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6342 installed version in C<@INC>, yours will be used instead. Possible security
6343 problem?).
6344
6345 It then checks to see if the subroutine C<main::dumpValue> is now defined
6346 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6347 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6348 is called, and picks up the variable to be dumped from the parameter list.
6349
6350 It checks the package global C<%options> to see if there's a C<dumpDepth>
6351 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6352 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6353 structure: -1 means dump everything.
6354
6355 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6356 warning.
6357
6358 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6359 and we then return to the caller.
6360
6361 =cut
6362
6363 sub dumpit {
6364
6365     # Save the current output filehandle and switch to the one
6366     # passed in as the first parameter.
6367     my $savout = select(shift);
6368
6369     # Save current settings of $single and $trace, and then turn them off.
6370     my $osingle = $single;
6371     my $otrace  = $trace;
6372     $single = $trace = 0;
6373
6374     # XXX Okay, what do $frame and $doret do, again?
6375     local $frame = 0;
6376     local $doret = -2;
6377
6378     # Load dumpvar.pl unless we've already got the sub we need from it.
6379     unless ( defined &main::dumpValue ) {
6380         do 'dumpvar.pl' or die $@;
6381     }
6382
6383     # If the load succeeded (or we already had dumpvalue()), go ahead
6384     # and dump things.
6385     if ( defined &main::dumpValue ) {
6386         local $\ = '';
6387         local $, = '';
6388         local $" = ' ';
6389         my $v = shift;
6390         my $maxdepth = shift || $option{dumpDepth};
6391         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6392         main::dumpValue( $v, $maxdepth );
6393     } ## end if (defined &main::dumpValue)
6394
6395     # Oops, couldn't load dumpvar.pl.
6396     else {
6397         local $\ = '';
6398         print $OUT "dumpvar.pl not available.\n";
6399     }
6400
6401     # Reset $single and $trace to their old values.
6402     $single = $osingle;
6403     $trace  = $otrace;
6404
6405     # Restore the old filehandle.
6406     select($savout);
6407 } ## end sub dumpit
6408
6409 =head2 C<print_trace>
6410
6411 C<print_trace>'s job is to print a stack trace. It does this via the
6412 C<dump_trace> routine, which actually does all the ferreting-out of the
6413 stack trace data. C<print_trace> takes care of formatting it nicely and
6414 printing it to the proper filehandle.
6415
6416 Parameters:
6417
6418 =over 4
6419
6420 =item *
6421
6422 The filehandle to print to.
6423
6424 =item *
6425
6426 How many frames to skip before starting trace.
6427
6428 =item *
6429
6430 How many frames to print.
6431
6432 =item *
6433
6434 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6435
6436 =back
6437
6438 The original comment below seems to be noting that the traceback may not be
6439 correct if this routine is called in a tied method.
6440
6441 =cut
6442
6443 # Tied method do not create a context, so may get wrong message:
6444
6445 sub print_trace {
6446     local $\ = '';
6447     my $fh = shift;
6448
6449     # If this is going to a slave editor, but we're not the primary
6450     # debugger, reset it first.
6451     resetterm(1)
6452       if $fh        eq $LINEINFO    # slave editor
6453       and $LINEINFO eq $OUT         # normal output
6454       and $term_pid != $$;          # not the primary
6455
6456     # Collect the actual trace information to be formatted.
6457     # This is an array of hashes of subroutine call info.
6458     my @sub = dump_trace( $_[0] + 1, $_[1] );
6459
6460     # Grab the "short report" flag from @_.
6461     my $short = $_[2];              # Print short report, next one for sub name
6462
6463     # Run through the traceback info, format it, and print it.
6464     my $s;
6465     for my $i (0 .. $#sub) {
6466
6467         # Drop out if the user has lost interest and hit control-C.
6468         last if $signal;
6469
6470         # Set the separator so arrays print nice.
6471         local $" = ', ';
6472
6473         # Grab and stringify the arguments if they are there.
6474         my $args =
6475           defined $sub[$i]{args}
6476           ? "(@{ $sub[$i]{args} })"
6477           : '';
6478
6479         # Shorten them up if $maxtrace says they're too long.
6480         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6481           if length $args > $maxtrace;
6482
6483         # Get the file name.
6484         my $file = $sub[$i]{file};
6485
6486         # Put in a filename header if short is off.
6487         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6488
6489         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6490         $s = $sub[$i]{'sub'};
6491         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6492
6493         # Short report uses trimmed file and sub names.
6494         if ($short) {
6495             my $sub = @_ >= 4 ? $_[3] : $s;
6496             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6497         } ## end if ($short)
6498
6499         # Non-short report includes full names.
6500         else {
6501             print $fh "$sub[$i]{context} = $s$args"
6502               . " called from $file"
6503               . " line $sub[$i]{line}\n";
6504         }
6505     } ## end for my $i (0 .. $#sub)
6506 } ## end sub print_trace
6507
6508 =head2 dump_trace(skip[,count])
6509
6510 Actually collect the traceback information available via C<caller()>. It does
6511 some filtering and cleanup of the data, but mostly it just collects it to
6512 make C<print_trace()>'s job easier.
6513
6514 C<skip> defines the number of stack frames to be skipped, working backwards
6515 from the most current. C<count> determines the total number of frames to
6516 be returned; all of them (well, the first 10^9) are returned if C<count>
6517 is omitted.
6518
6519 This routine returns a list of hashes, from most-recent to least-recent
6520 stack frame. Each has the following keys and values:
6521
6522 =over 4
6523
6524 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6525
6526 =item * C<sub> - subroutine name, or C<eval> information
6527
6528 =item * C<args> - undef, or a reference to an array of arguments
6529
6530 =item * C<file> - the file in which this item was defined (if any)
6531
6532 =item * C<line> - the line on which it was defined
6533
6534 =back
6535
6536 =cut
6537
6538 sub _dump_trace_calc_saved_single_arg
6539 {
6540     my ($nothard, $arg) = @_;
6541
6542     my $type;
6543     if ( not defined $arg ) {    # undefined parameter
6544         return "undef";
6545     }
6546
6547     elsif ( $nothard and tied $arg ) {    # tied parameter
6548         return "tied";
6549     }
6550     elsif ( $nothard and $type = ref $arg ) {    # reference
6551         return "ref($type)";
6552     }
6553     else {                                       # can be stringified
6554         local $_ =
6555         "$arg";    # Safe to stringify now - should not call f().
6556
6557         # Backslash any single-quotes or backslashes.
6558         s/([\'\\])/\\$1/g;
6559
6560         # Single-quote it unless it's a number or a colon-separated
6561         # name.
6562         s/(.*)/'$1'/s
6563         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6564
6565         # Turn high-bit characters into meta-whatever, and controls into like
6566         # '^D'.
6567         require 'meta_notation.pm';
6568         $_ = _meta_notation($_) if /[[:^print:]]/a;
6569
6570         return $_;
6571     }
6572 }
6573
6574 sub _dump_trace_calc_save_args {
6575     my ($nothard) = @_;
6576
6577     return [
6578         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6579     ];
6580 }
6581
6582 sub dump_trace {
6583
6584     # How many levels to skip.
6585     my $skip = shift;
6586
6587     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6588     # it's unlikely that we'll have more than a billion stack frames. If you
6589     # do, you've got an awfully big machine...)
6590     my $count = shift || 1e9;
6591
6592     # We increment skip because caller(1) is the first level *back* from
6593     # the current one.  Add $skip to the count of frames so we have a
6594     # simple stop criterion, counting from $skip to $count+$skip.
6595     $skip++;
6596     $count += $skip;
6597
6598     # These variables are used to capture output from caller();
6599     my ( $p, $file, $line, $sub, $h, $context );
6600
6601     my ( $e, $r, @sub, $args );
6602
6603     # XXX Okay... why'd we do that?
6604     my $nothard = not $frame & 8;
6605     local $frame = 0;
6606
6607     # Do not want to trace this.
6608     my $otrace = $trace;
6609     $trace = 0;
6610
6611     # Start out at the skip count.
6612     # If we haven't reached the number of frames requested, and caller() is
6613     # still returning something, stay in the loop. (If we pass the requested
6614     # number of stack frames, or we run out - caller() returns nothing - we
6615     # quit.
6616     # Up the stack frame index to go back one more level each time.
6617     for (
6618         my $i = $skip ;
6619         $i < $count
6620         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6621         $i++
6622     )
6623     {
6624
6625         # Go through the arguments and save them for later.
6626         my $save_args = _dump_trace_calc_save_args($nothard);
6627
6628         # If context is true, this is array (@)context.
6629         # If context is false, this is scalar ($) context.
6630         # If neither, context isn't defined. (This is apparently a 'can't
6631         # happen' trap.)
6632         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6633
6634         # if the sub has args ($h true), make an anonymous array of the
6635         # dumped args.
6636         $args = $h ? $save_args : undef;
6637
6638         # remove trailing newline-whitespace-semicolon-end of line sequence
6639         # from the eval text, if any.
6640         $e =~ s/\n\s*\;\s*\Z// if $e;
6641
6642         # Escape backslashed single-quotes again if necessary.
6643         $e =~ s/([\\\'])/\\$1/g if $e;
6644
6645         # if the require flag is true, the eval text is from a require.
6646         if ($r) {
6647             $sub = "require '$e'";
6648         }
6649
6650         # if it's false, the eval text is really from an eval.
6651         elsif ( defined $r ) {
6652             $sub = "eval '$e'";
6653         }
6654
6655         # If the sub is '(eval)', this is a block eval, meaning we don't
6656         # know what the eval'ed text actually was.
6657         elsif ( $sub eq '(eval)' ) {
6658             $sub = "eval {...}";
6659         }
6660
6661         # Stick the collected information into @sub as an anonymous hash.
6662         push(
6663             @sub,
6664             {
6665                 context => $context,
6666                 sub     => $sub,
6667                 args    => $args,
6668                 file    => $file,
6669                 line    => $line
6670             }
6671         );
6672
6673         # Stop processing frames if the user hit control-C.
6674         last if $signal;
6675     } ## end for ($i = $skip ; $i < ...
6676
6677     # Restore the trace value again.
6678     $trace = $otrace;
6679     @sub;
6680 } ## end sub dump_trace
6681
6682 =head2 C<action()>
6683
6684 C<action()> takes input provided as the argument to an add-action command,
6685 either pre- or post-, and makes sure it's a complete command. It doesn't do
6686 any fancy parsing; it just keeps reading input until it gets a string
6687 without a trailing backslash.
6688
6689 =cut
6690
6691 sub action {
6692     my $action = shift;
6693
6694     while ( $action =~ s/\\$// ) {
6695
6696         # We have a backslash on the end. Read more.
6697         $action .= gets();
6698     } ## end while ($action =~ s/\\$//)
6699
6700     # Return the assembled action.
6701     $action;
6702 } ## end sub action
6703
6704 =head2 unbalanced
6705
6706 This routine mostly just packages up a regular expression to be used
6707 to check that the thing it's being matched against has properly-matched
6708 curly braces.
6709
6710 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6711 speeds things up by only creating the qr//'ed expression once; if it's
6712 already defined, we don't try to define it again. A speed hack.
6713
6714 =cut
6715
6716 use vars qw($balanced_brace_re);
6717
6718 sub unbalanced {
6719
6720     # I hate using globals!
6721     $balanced_brace_re ||= qr{
6722         ^ \{
6723              (?:
6724                  (?> [^{}] + )              # Non-parens without backtracking
6725                 |
6726                  (??{ $balanced_brace_re }) # Group with matching parens
6727               ) *
6728           \} $
6729    }x;
6730     return $_[0] !~ m/$balanced_brace_re/;
6731 } ## end sub unbalanced
6732
6733 =head2 C<gets()>
6734
6735 C<gets()> is a primitive (very primitive) routine to read continuations.
6736 It was devised for reading continuations for actions.
6737 it just reads more input with C<readline()> and returns it.
6738
6739 =cut
6740
6741 sub gets {
6742     return DB::readline("cont: ");
6743 }
6744
6745 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6746
6747 The C<system()> function assumes that it can just go ahead and use STDIN and
6748 STDOUT, but under the debugger, we want it to use the debugger's input and
6749 outout filehandles.
6750
6751 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6752 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6753 and then puts everything back again.
6754
6755 =cut
6756
6757 sub _db_system {
6758
6759     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6760     # some non-Unix systems can do system() but have problems with fork().
6761     open( SAVEIN,  "<&STDIN" )  || _db_warn("Can't save STDIN");
6762     open( SAVEOUT, ">&STDOUT" ) || _db_warn("Can't save STDOUT");
6763     open( STDIN,   "<&IN" )     || _db_warn("Can't redirect STDIN");
6764     open( STDOUT,  ">&OUT" )    || _db_warn("Can't redirect STDOUT");
6765
6766     # XXX: using csh or tcsh destroys sigint retvals!
6767     system(@_);
6768     open( STDIN,  "<&SAVEIN" )  || _db_warn("Can't restore STDIN");
6769     open( STDOUT, ">&SAVEOUT" ) || _db_warn("Can't restore STDOUT");
6770     close(SAVEIN);
6771     close(SAVEOUT);
6772
6773     # most of the $? crud was coping with broken cshisms
6774     if ( $? >> 8 ) {
6775         _db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6776     }
6777     elsif ($?) {
6778         _db_warn(
6779             "(Command died of SIG#",
6780             ( $? & 127 ),
6781             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6782             ")", "\n"
6783         );
6784     } ## end elsif ($?)
6785
6786     return $?;
6787
6788 } ## end sub system
6789
6790 *system = \&_db_system;
6791
6792 =head1 TTY MANAGEMENT
6793
6794 The subs here do some of the terminal management for multiple debuggers.
6795
6796 =head2 setterm
6797
6798 Top-level function called when we want to set up a new terminal for use
6799 by the debugger.
6800
6801 If the C<noTTY> debugger option was set, we'll either use the terminal
6802 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6803 to find one. If we're a forked debugger, we call C<resetterm> to try to
6804 get a whole new terminal if we can.
6805
6806 In either case, we set up the terminal next. If the C<ReadLine> option was
6807 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6808 the appropriate attributes. We then
6809
6810 =cut
6811
6812 use vars qw($ornaments);
6813 use vars qw($rl_attribs);
6814
6815 sub setterm {
6816
6817     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6818     local $frame = 0;
6819     local $doret = -2;
6820     require Term::ReadLine;
6821
6822     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6823     if ($notty) {
6824         if ($tty) {
6825             my ( $i, $o ) = split $tty, /,/;
6826             $o = $i unless defined $o;
6827             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6828             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6829             $IN  = \*IN;
6830             $OUT = \*OUT;
6831             _autoflush($OUT);
6832         } ## end if ($tty)
6833
6834         # We don't have a TTY - try to find one via Term::Rendezvous.
6835         else {
6836             require Term::Rendezvous;
6837
6838             # See if we have anything to pass to Term::Rendezvous.
6839             # Use $HOME/.perldbtty$$ if not.
6840             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6841
6842             # Rendezvous and get the filehandles.
6843             my $term_rv = Term::Rendezvous->new( $rv );
6844             $IN  = $term_rv->IN;
6845             $OUT = $term_rv->OUT;
6846         } ## end else [ if ($tty)
6847     } ## end if ($notty)
6848
6849     # We're a daughter debugger. Try to fork off another TTY.
6850     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6851         resetterm(2);
6852     }
6853
6854     # If we shouldn't use Term::ReadLine, don't.
6855     if ( !$rl ) {
6856         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6857     }
6858
6859     # We're using Term::ReadLine. Get all the attributes for this terminal.
6860     else {
6861         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6862
6863         $rl_attribs = $term->Attribs;
6864         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6865           if defined $rl_attribs->{basic_word_break_characters}
6866           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6867         $rl_attribs->{special_prefixes} = '$@&%';
6868         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6869         $rl_attribs->{completion_function} = \&db_complete;
6870     } ## end else [ if (!$rl)
6871
6872     # Set up the LINEINFO filehandle.
6873     $LINEINFO = $OUT     unless defined $LINEINFO;
6874     $lineinfo = $console unless defined $lineinfo;
6875
6876     $term->MinLine(2);
6877
6878     load_hist();
6879
6880     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6881         $term->SetHistory(@hist);
6882     }
6883
6884     # XXX Ornaments are turned on unconditionally, which is not
6885     # always a good thing.
6886     ornaments($ornaments) if defined $ornaments;
6887     $term_pid = $$;
6888 } ## end sub setterm
6889
6890 sub load_hist {
6891     $histfile //= option_val("HistFile", undef);
6892     return unless defined $histfile;
6893     open my $fh, "<", $histfile or return;
6894     local $/ = "\n";
6895     @hist = ();
6896     while (<$fh>) {
6897         chomp;
6898         push @hist, $_;
6899     }
6900     close $fh;
6901 }
6902
6903 sub save_hist {
6904     return unless defined $histfile;
6905     eval { require File::Path } or return;
6906     eval { require File::Basename } or return;
6907     File::Path::mkpath(File::Basename::dirname($histfile));
6908     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6909     $histsize //= option_val("HistSize",100);
6910     my @copy = grep { $_ ne '?' } @hist;
6911     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6912     for ($start .. $#copy) {
6913         print $fh "$copy[$_]\n";
6914     }
6915     close $fh or die "Could not write '$histfile': $!";
6916 }
6917
6918 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6919
6920 When the process being debugged forks, or the process invokes a command
6921 via C<system()> which starts a new debugger, we need to be able to get a new
6922 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6923 fight over the terminal, and you can never quite be sure who's going to get the
6924 input you're typing.
6925
6926 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6927 is tasked with doing all the necessary operating system mojo to get a new
6928 TTY (and probably another window) and to direct the new debugger to read and
6929 write there.
6930
6931 The debugger provides C<get_fork_TTY> functions which work for TCP
6932 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6933 supported. You are encouraged to write C<get_fork_TTY> functions which
6934 work for I<your> platform and contribute them.
6935
6936 =head3 C<socket_get_fork_TTY>
6937
6938 =cut
6939
6940 sub connect_remoteport {
6941     require IO::Socket;
6942
6943     my $socket = IO::Socket::INET->new(
6944         Timeout  => '10',
6945         PeerAddr => $remoteport,
6946         Proto    => 'tcp',
6947     );
6948     if ( ! $socket ) {
6949         die "Unable to connect to remote host: $remoteport\n";
6950     }
6951     return $socket;
6952 }
6953
6954 sub socket_get_fork_TTY {
6955     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6956
6957     # Do I need to worry about setting $term?
6958
6959     reset_IN_OUT( $IN, $OUT );
6960     return '';
6961 }
6962
6963 =head3 C<xterm_get_fork_TTY>
6964
6965 This function provides the C<get_fork_TTY> function for X11. If a
6966 program running under the debugger forks, a new <xterm> window is opened and
6967 the subsidiary debugger is directed there.
6968
6969 The C<open()> call is of particular note here. We have the new C<xterm>
6970 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6971 command (which prints the device name of the TTY we'll want to use for input
6972 and output to STDOUT, then C<sleep> for a very long time, routing this output
6973 to file number 3. This way we can simply read from the <XT> filehandle (which
6974 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6975
6976 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6977 properly set up.
6978
6979 =cut
6980
6981 sub xterm_get_fork_TTY {
6982     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6983     open XT,
6984 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6985  sleep 10000000' |];
6986
6987     # Get the output from 'tty' and clean it up a little.
6988     my $tty = <XT>;
6989     chomp $tty;
6990
6991     $pidprompt = '';    # Shown anyway in titlebar
6992
6993     # We need $term defined or we can not switch to the newly created xterm
6994     if ($tty ne '' && !defined $term) {
6995         require Term::ReadLine;
6996         if ( !$rl ) {
6997             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6998         }
6999         else {
7000             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7001         }
7002     }
7003     # There's our new TTY.
7004     return $tty;
7005 } ## end sub xterm_get_fork_TTY
7006
7007 =head3 C<os2_get_fork_TTY>
7008
7009 XXX It behooves an OS/2 expert to write the necessary documentation for this!
7010
7011 =cut
7012
7013 # This example function resets $IN, $OUT itself
7014 my $c_pipe = 0;
7015 sub os2_get_fork_TTY { # A simplification of the following (and works without):
7016     local $\  = '';
7017     ( my $name = $0 ) =~ s,^.*[/\\],,s;
7018     my %opt = ( title => "Daughter Perl debugger $pids $name",
7019         ($rl ? (read_by_key => 1) : ()) );
7020     require OS2::Process;
7021     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
7022       or return;
7023     $pidprompt = '';    # Shown anyway in titlebar
7024     reset_IN_OUT($in, $out);
7025     $tty = '*reset*';
7026     return '';          # Indicate that reset_IN_OUT is called
7027 } ## end sub os2_get_fork_TTY
7028
7029 =head3 C<macosx_get_fork_TTY>
7030
7031 The Mac OS X version uses AppleScript to tell Terminal.app to create
7032 a new window.
7033
7034 =cut
7035
7036 # Notes about Terminal.app's AppleScript support,
7037 # (aka things that might break in future OS versions).
7038 #
7039 # The "do script" command doesn't return a reference to the new window
7040 # it creates, but since it appears frontmost and windows are enumerated
7041 # front to back, we can use "first window" === "window 1".
7042 #
7043 # Since "do script" is implemented by supplying the argument (plus a
7044 # return character) as terminal input, there's a potential race condition
7045 # where the debugger could beat the shell to reading the command.
7046 # To prevent this, we wait for the screen to clear before proceeding.
7047 #
7048 # 10.3 and 10.4:
7049 # There's no direct accessor for the tty device name, so we fiddle
7050 # with the window title options until it says what we want.
7051 #
7052 # 10.5:
7053 # There _is_ a direct accessor for the tty device name, _and_ there's
7054 # a new possible component of the window title (the name of the settings
7055 # set).  A separate version is needed.
7056
7057 my @script_versions=
7058
7059     ([237, <<'__LEOPARD__'],
7060 tell application "Terminal"
7061     do script "clear;exec sleep 100000"
7062     tell first tab of first window
7063         copy tty to thetty
7064         set custom title to "forked perl debugger"
7065         set title displays custom title to true
7066         repeat while (length of first paragraph of (get contents)) > 0
7067             delay 0.1
7068         end repeat
7069     end tell
7070 end tell
7071 thetty
7072 __LEOPARD__
7073
7074      [100, <<'__JAGUAR_TIGER__'],
7075 tell application "Terminal"
7076     do script "clear;exec sleep 100000"
7077     tell first window
7078         set title displays shell path to false
7079         set title displays window size to false
7080         set title displays file name to false
7081         set title displays device name to true
7082         set title displays custom title to true
7083         set custom title to ""
7084         copy "/dev/" & name to thetty
7085         set custom title to "forked perl debugger"
7086         repeat while (length of first paragraph of (get contents)) > 0
7087             delay 0.1
7088         end repeat
7089     end tell
7090 end tell
7091 thetty
7092 __JAGUAR_TIGER__
7093
7094 );
7095
7096 sub macosx_get_fork_TTY
7097 {
7098     my($version,$script,$pipe,$tty);
7099
7100     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7101     foreach my $entry (@script_versions) {
7102         if ($version>=$entry->[0]) {
7103             $script=$entry->[1];
7104             last;
7105         }
7106     }
7107     return unless defined($script);
7108     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7109     $tty=readline($pipe);
7110     close($pipe);
7111     return unless defined($tty) && $tty =~ m(^/dev/);
7112     chomp $tty;
7113     return $tty;
7114 }
7115
7116 =head3 C<tmux_get_fork_TTY>
7117
7118 Creates a split window for subprocesses when a process running under the
7119 perl debugger in Tmux forks.
7120
7121 =cut
7122
7123 sub tmux_get_fork_TTY {
7124     return unless $ENV{TMUX};
7125
7126     my $pipe;
7127
7128     my $status = open $pipe, '-|', 'tmux', 'split-window',
7129         '-P', '-F', '#{pane_tty}', 'sleep 100000';
7130
7131     if ( !$status ) {
7132         return;
7133     }
7134
7135     my $tty = <$pipe>;
7136     close $pipe;
7137
7138     if ( $tty ) {
7139         chomp $tty;
7140
7141         if ( !defined $term ) {
7142             require Term::ReadLine;
7143             if ( !$rl ) {
7144                 $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7145             }
7146             else {
7147                 $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7148             }
7149         }
7150     }
7151
7152     return $tty;
7153 }
7154
7155 =head2 C<create_IN_OUT($flags)>
7156
7157 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7158 try to diagnose why.
7159
7160 Flags are:
7161
7162 =over 4
7163
7164 =item * 1 - Don't know how to create a new TTY.
7165
7166 =item * 2 - Debugger has forked, but we can't get a new TTY.
7167
7168 =item * 4 - standard debugger startup is happening.
7169
7170 =back
7171
7172 =cut
7173
7174 use vars qw($fork_TTY);
7175
7176 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7177
7178     # If we know how to get a new TTY, do it! $in will have
7179     # the TTY name if get_fork_TTY works.
7180     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7181
7182     # It used to be that
7183     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7184
7185     if ( not defined $in ) {
7186         my $why = shift;
7187
7188         # We don't know how.
7189         print_help(<<EOP) if $why == 1;
7190 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7191 EOP
7192
7193         # Forked debugger.
7194         print_help(<<EOP) if $why == 2;
7195 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7196   This may be an asynchronous session, so the parent debugger may be active.
7197 EOP
7198
7199         # Note that both debuggers are fighting over the same input.
7200         print_help(<<EOP) if $why != 4;
7201   Since two debuggers fight for the same TTY, input is severely entangled.
7202
7203 EOP
7204         print_help(<<EOP);
7205   I know how to switch the output to a different window in xterms, OS/2
7206   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7207   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7208   B<DB::get_fork_TTY()> returning this.
7209
7210   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7211   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7212
7213 EOP
7214     } ## end if (not defined $in)
7215     elsif ( $in ne '' ) {
7216         TTY($in);
7217     }
7218     else {
7219         $console = '';    # Indicate no need to open-from-the-console
7220     }
7221     undef $fork_TTY;
7222 } ## end sub create_IN_OUT
7223
7224 =head2 C<resetterm>
7225
7226 Handles rejiggering the prompt when we've forked off a new debugger.
7227
7228 If the new debugger happened because of a C<system()> that invoked a
7229 program under the debugger, the arrow between the old pid and the new
7230 in the prompt has I<two> dashes instead of one.
7231
7232 We take the current list of pids and add this one to the end. If there
7233 isn't any list yet, we make one up out of the initial pid associated with
7234 the terminal and our new pid, sticking an arrow (either one-dashed or
7235 two dashed) in between them.
7236
7237 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7238 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7239 and try to do that.
7240
7241 =cut
7242
7243 sub resetterm {    # We forked, so we need a different TTY
7244
7245     # Needs to be passed to create_IN_OUT() as well.
7246     my $in = shift;
7247
7248     # resetterm(2): got in here because of a system() starting a debugger.
7249     # resetterm(1): just forked.
7250     my $systemed = $in > 1 ? '-' : '';
7251
7252     # If there's already a list of pids, add this to the end.
7253     if ($pids) {
7254         $pids =~ s/\]/$systemed->$$]/;
7255     }
7256
7257     # No pid list. Time to make one.
7258     else {
7259         $pids = "[$term_pid->$$]";
7260     }
7261
7262     # The prompt we're going to be using for this debugger.
7263     $pidprompt = $pids;
7264
7265     # We now 0wnz this terminal.
7266     $term_pid = $$;
7267
7268     # Just return if we're not supposed to try to create a new TTY.
7269     return unless $CreateTTY & $in;
7270
7271     # Try to create a new IN/OUT pair.
7272     create_IN_OUT($in);
7273 } ## end sub resetterm
7274
7275 =head2 C<readline>
7276
7277 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7278 the next line, print a message saying we got it, add it to the terminal
7279 history (if possible), and return it.
7280
7281 If there's nothing in the typeahead buffer, check the command filehandle stack.
7282 If there are any filehandles there, read from the last one, and return the line
7283 if we got one. If not, we pop the filehandle off and close it, and try the
7284 next one up the stack.
7285
7286 If we've emptied the filehandle stack, we check to see if we've got a socket
7287 open, and we read that and return it if we do. If we don't, we just call the
7288 core C<readline()> and return its value.
7289
7290 =cut
7291
7292 sub readline {
7293
7294     # Localize to prevent it from being smashed in the program being debugged.
7295     local $.;
7296
7297     # If there are stacked filehandles to read from ...
7298     # (Handle it before the typeahead, because we may call source/etc. from
7299     # the typeahead.)
7300     while (@cmdfhs) {
7301
7302         # Read from the last one in the stack.
7303         my $line = CORE::readline( $cmdfhs[-1] );
7304
7305         # If we got a line ...
7306         defined $line
7307           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7308           : close pop @cmdfhs;                            # Pop and close
7309     } ## end while (@cmdfhs)
7310
7311     # Pull a line out of the typeahead if there's stuff there.
7312     if (@typeahead) {
7313
7314         # How many lines left.
7315         my $left = @typeahead;
7316
7317         # Get the next line.
7318         my $got = shift @typeahead;
7319
7320         # Print a message saying we got input from the typeahead.
7321         local $\ = '';
7322         print $OUT "auto(-$left)", shift, $got, "\n";
7323
7324         # Add it to the terminal history (if possible).
7325         $term->AddHistory($got)
7326           if length($got) > 1
7327           and defined $term->Features->{addHistory};
7328         return $got;
7329     } ## end if (@typeahead)
7330
7331     # We really need to read some input. Turn off entry/exit trace and
7332     # return value printing.
7333     local $frame = 0;
7334     local $doret = -2;
7335
7336     # Nothing on the filehandle stack. Socket?
7337     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7338
7339         # Send anything we have to send.
7340         $OUT->write( join( '', @_ ) );
7341
7342         # Receive anything there is to receive.
7343         my $stuff = '';
7344         my $buf;
7345         my $first_time = 1;
7346
7347         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7348         {
7349             $first_time = 0;
7350             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7351                                             # XXX Don't know. You tell me.
7352         }
7353
7354         # What we got.
7355         return $stuff;
7356     } ## end if (ref $OUT and UNIVERSAL::isa...
7357
7358     # No socket. Just read from the terminal.
7359     else {
7360         return $term->readline(@_);
7361     }
7362 } ## end sub readline
7363
7364 =head1 OPTIONS SUPPORT ROUTINES
7365
7366 These routines handle listing and setting option values.
7367
7368 =head2 C<dump_option> - list the current value of an option setting
7369
7370 This routine uses C<option_val> to look up the value for an option.
7371 It cleans up escaped single-quotes and then displays the option and
7372 its value.
7373
7374 =cut
7375
7376 sub dump_option {
7377     my ( $opt, $val ) = @_;
7378     $val = option_val( $opt, 'N/A' );
7379     $val =~ s/([\\\'])/\\$1/g;
7380     printf $OUT "%20s = '%s'\n", $opt, $val;
7381 } ## end sub dump_option
7382
7383 sub options2remember {
7384     foreach my $k (@RememberOnROptions) {
7385         $option{$k} = option_val( $k, 'N/A' );
7386     }
7387     return %option;
7388 }
7389
7390 =head2 C<option_val> - find the current value of an option
7391
7392 This can't just be a simple hash lookup because of the indirect way that
7393 the option values are stored. Some are retrieved by calling a subroutine,
7394 some are just variables.
7395
7396 You must supply a default value to be used in case the option isn't set.
7397
7398 =cut
7399
7400 sub option_val {
7401     my ( $opt, $default ) = @_;
7402     my $val;
7403
7404     # Does this option exist, and is it a variable?
7405     # If so, retrieve the value via the value in %optionVars.
7406     if (    defined $optionVars{$opt}
7407         and defined ${ $optionVars{$opt} } )
7408     {
7409         $val = ${ $optionVars{$opt} };
7410     }
7411
7412     # Does this option exist, and it's a subroutine?
7413     # If so, call the subroutine via the ref in %optionAction
7414     # and capture the value.
7415     elsif ( defined $optionAction{$opt}
7416         and defined &{ $optionAction{$opt} } )
7417     {
7418         $val = &{ $optionAction{$opt} }();
7419     }
7420
7421     # If there's an action or variable for the supplied option,
7422     # but no value was set, use the default.
7423     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7424         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7425     {
7426         $val = $default;
7427     }
7428
7429     # Otherwise, do the simple hash lookup.
7430     else {
7431         $val = $option{$opt};
7432     }
7433
7434     # If the value isn't defined, use the default.
7435     # Then return whatever the value is.
7436     $val = $default unless defined $val;
7437     $val;
7438 } ## end sub option_val
7439
7440 =head2 C<parse_options>
7441
7442 Handles the parsing and execution of option setting/displaying commands.
7443
7444 An option entered by itself is assumed to be I<set me to 1> (the default value)
7445 if the option is a boolean one. If not, the user is prompted to enter a valid
7446 value or to query the current value (via C<option? >).
7447
7448 If C<option=value> is entered, we try to extract a quoted string from the
7449 value (if it is quoted). If it's not, we just use the whole value as-is.
7450
7451 We load any modules required to service this option, and then we set it: if
7452 it just gets stuck in a variable, we do that; if there's a subroutine to
7453 handle setting the option, we call that.
7454
7455 Finally, if we're running in interactive mode, we display the effect of the
7456 user's command back to the terminal, skipping this if we're setting things
7457 during initialization.
7458
7459 =cut
7460
7461 sub parse_options {
7462     my ($s) = @_;
7463     local $\ = '';
7464
7465     my $option;
7466
7467     # These options need a value. Don't allow them to be clobbered by accident.
7468     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7469       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7470       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7471     };
7472
7473     while (length($s)) {
7474         my $val_defaulted;
7475
7476         # Clean off excess leading whitespace.
7477         $s =~ s/^\s+// && next;
7478
7479         # Options are always all word characters, followed by a non-word
7480         # separator.
7481         if ($s !~ s/^(\w+)(\W?)//) {
7482             print {$OUT} "Invalid option '$s'\n";
7483             last;
7484         }
7485         my ( $opt, $sep ) = ( $1, $2 );
7486
7487         # Make sure that such an option exists.
7488         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7489           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7490
7491         unless ($matches) {
7492             print {$OUT} "Unknown option '$opt'\n";
7493             next;
7494         }
7495         if ($matches > 1) {
7496             print {$OUT} "Ambiguous option '$opt'\n";
7497             next;
7498         }
7499         my $val;
7500
7501         # '?' as separator means query, but must have whitespace after it.
7502         if ( "?" eq $sep ) {
7503             if ($s =~ /\A\S/) {
7504                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7505
7506                 last;
7507             }
7508
7509             #&dump_option($opt);
7510         } ## end if ("?" eq $sep)
7511
7512         # Separator is whitespace (or just a carriage return).
7513         # They're going for a default, which we assume is 1.
7514         elsif ( $sep !~ /\S/ ) {
7515             $val_defaulted = 1;
7516             $val           = "1";   #  this is an evil default; make 'em set it!
7517         }
7518
7519         # Separator is =. Trying to set a value.
7520         elsif ( $sep eq "=" ) {
7521
7522             # If quoted, extract a quoted string.
7523             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7524                 my $quote = $1;
7525                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7526             }
7527
7528             # Not quoted. Use the whole thing. Warn about 'option='.
7529             else {
7530                 $s =~ s/^(\S*)//;
7531                 $val = $1;
7532                 print OUT qq(Option better cleared using $opt=""\n)
7533                   unless length $val;
7534             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7535
7536         } ## end elsif ($sep eq "=")
7537
7538         # "Quoted" with [], <>, or {}.
7539         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7540             my ($end) =
7541               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7542             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7543               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7544             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7545         } ## end else [ if ("?" eq $sep)
7546
7547         # Exclude non-booleans from getting set to 1 by default.
7548         if ( $opt_needs_val{$option} && $val_defaulted ) {
7549             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7550             print {$OUT}
7551 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7552             next;
7553         } ## end if ($opt_needs_val{$option...
7554
7555         # Save the option value.
7556         $option{$option} = $val if defined $val;
7557
7558         # Load any module that this option requires.
7559         if ( defined($optionRequire{$option}) && defined($val) ) {
7560             eval qq{
7561             local \$frame = 0;
7562             local \$doret = -2;
7563             require '$optionRequire{$option}';
7564             1;
7565             } || die $@   # XXX: shouldn't happen
7566         }
7567
7568         # Set it.
7569         # Stick it in the proper variable if it goes in a variable.
7570         if (defined($optionVars{$option}) && defined($val)) {
7571             ${ $optionVars{$option} } = $val;
7572         }
7573
7574         # Call the appropriate sub if it gets set via sub.
7575         if (defined($optionAction{$option})
7576           && defined (&{ $optionAction{$option} })
7577           && defined ($val))
7578         {
7579           &{ $optionAction{$option} }($val);
7580         }
7581
7582         # Not initialization - echo the value we set it to.
7583         dump_option($option) if ($OUT ne \*STDERR);
7584     } ## end while (length)
7585 } ## end sub parse_options
7586
7587 =head1 RESTART SUPPORT
7588
7589 These routines are used to store (and restore) lists of items in environment
7590 variables during a restart.
7591
7592 =head2 set_list
7593
7594 Set_list packages up items to be stored in a set of environment variables
7595 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7596 the values). Values outside the standard ASCII charset are stored by encoding
7597 them as hexadecimal values.
7598
7599 =cut
7600
7601 sub set_list {
7602     my ( $stem, @list ) = @_;
7603     my $val;
7604
7605     # VAR_n: how many we have. Scalar assignment gets the number of items.
7606     $ENV{"${stem}_n"} = @list;
7607
7608     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7609     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7610     for my $i ( 0 .. $#list ) {
7611         $val = $list[$i];
7612         $val =~ s/\\/\\\\/g;
7613         no warnings 'experimental::regex_sets';
7614         $val =~ s/ ( (?[ [\000-\xFF] & [:^print:] ]) ) /
7615                                                 "\\0x" . unpack('H2',$1)/xaeg;
7616         $ENV{"${stem}_$i"} = $val;
7617     } ## end for $i (0 .. $#list)
7618 } ## end sub set_list
7619
7620 =head2 get_list
7621
7622 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7623 back, and then pull VAR_0, VAR_1. etc. back out.
7624
7625 =cut
7626
7627 sub get_list {
7628     my $stem = shift;
7629     my @list;
7630     my $n = delete $ENV{"${stem}_n"};
7631     my $val;
7632     for my $i ( 0 .. $n - 1 ) {
7633         $val = delete $ENV{"${stem}_$i"};
7634         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7635         push @list, $val;
7636     }
7637     @list;
7638 } ## end sub get_list
7639
7640 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7641
7642 =head2 catch()
7643
7644 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7645 set an already-existing global scalar variable to a constant value. This
7646 avoids allocating any memory possibly in the middle of something that will
7647 get all confused if we do, particularly under I<unsafe signals>.
7648
7649 =cut
7650
7651 sub catch {
7652     $signal = 1;
7653     return;    # Put nothing on the stack - malloc/free land!
7654 }
7655
7656 =head2 C<warn()>
7657
7658 C<warn> emits a warning, by joining together its arguments and printing
7659 them, with couple of fillips.
7660
7661 If the composited message I<doesn't> end with a newline, we automatically
7662 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7663 to be set to the filehandle to be used to output warnings; it makes no
7664 assumptions about what filehandles are available.
7665
7666 =cut
7667
7668 sub _db_warn {
7669     my ($msg) = join( "", @_ );
7670     $msg .= ": $!\n" unless $msg =~ /\n$/;
7671     local $\ = '';
7672     print $OUT $msg;
7673 } ## end sub warn
7674
7675 *warn = \&_db_warn;
7676
7677 =head1 INITIALIZATION TTY SUPPORT
7678
7679 =head2 C<reset_IN_OUT>
7680
7681 This routine handles restoring the debugger's input and output filehandles
7682 after we've tried and failed to move them elsewhere.  In addition, it assigns
7683 the debugger's output filehandle to $LINEINFO if it was already open there.
7684
7685 =cut
7686
7687 sub reset_IN_OUT {
7688     my $switch_li = $LINEINFO eq $OUT;
7689
7690     # If there's a term and it's able to get a new tty, try to get one.
7691     if ( $term and $term->Features->{newTTY} ) {
7692         ( $IN, $OUT ) = ( shift, shift );
7693         $term->newTTY( $IN, $OUT );
7694     }
7695
7696     # This term can't get a new tty now. Better luck later.
7697     elsif ($term) {
7698         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7699     }
7700
7701     # Set the filehndles up as they were.
7702     else {
7703         ( $IN, $OUT ) = ( shift, shift );
7704     }
7705
7706     # Unbuffer the output filehandle.
7707     _autoflush($OUT);
7708
7709     # Point LINEINFO to the same output filehandle if it was there before.
7710     $LINEINFO = $OUT if $switch_li;
7711 } ## end sub reset_IN_OUT
7712
7713 =head1 OPTION SUPPORT ROUTINES
7714
7715 The following routines are used to process some of the more complicated
7716 debugger options.
7717
7718 =head2 C<TTY>
7719
7720 Sets the input and output filehandles to the specified files or pipes.
7721 If the terminal supports switching, we go ahead and do it. If not, and
7722 there's already a terminal in place, we save the information to take effect
7723 on restart.
7724
7725 If there's no terminal yet (for instance, during debugger initialization),
7726 we go ahead and set C<$console> and C<$tty> to the file indicated.
7727
7728 =cut
7729
7730 sub TTY {
7731
7732     if ( @_ and $term and $term->Features->{newTTY} ) {
7733
7734         # This terminal supports switching to a new TTY.
7735         # Can be a list of two files, or on string containing both names,
7736         # comma-separated.
7737         # XXX Should this perhaps be an assignment from @_?
7738         my ( $in, $out ) = shift;
7739         if ( $in =~ /,/ ) {
7740
7741             # Split list apart if supplied.
7742             ( $in, $out ) = split /,/, $in, 2;
7743         }
7744         else {
7745
7746             # Use the same file for both input and output.
7747             $out = $in;
7748         }
7749
7750         # Open file onto the debugger's filehandles, if you can.
7751         open IN,  $in     or die "cannot open '$in' for read: $!";
7752         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7753
7754         # Swap to the new filehandles.
7755         reset_IN_OUT( \*IN, \*OUT );
7756
7757         # Save the setting for later.
7758         return $tty = $in;
7759     } ## end if (@_ and $term and $term...
7760
7761     # Terminal doesn't support new TTY, or doesn't support readline.
7762     # Can't do it now, try restarting.
7763     if ($term and @_) {
7764         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7765     }
7766
7767     # Useful if done through PERLDB_OPTS:
7768     $console = $tty = shift if @_;
7769
7770     # Return whatever the TTY is.
7771     $tty or $console;
7772 } ## end sub TTY
7773
7774 =head2 C<noTTY>
7775
7776 Sets the C<$notty> global, controlling whether or not the debugger tries to
7777 get a terminal to read from. If called after a terminal is already in place,
7778 we save the value to use it if we're restarted.
7779
7780 =cut
7781
7782 sub noTTY {
7783     if ($term) {
7784         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7785     }
7786     $notty = shift if @_;
7787     $notty;
7788 } ## end sub noTTY
7789
7790 =head2 C<ReadLine>
7791
7792 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7793 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7794 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7795 the value in case a restart is done so we can change it then.
7796
7797 =cut
7798
7799 sub ReadLine {
7800     if ($term) {
7801         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7802     }
7803     $rl = shift if @_;
7804     $rl;
7805 } ## end sub ReadLine
7806
7807 =head2 C<RemotePort>
7808
7809 Sets the port that the debugger will try to connect to when starting up.
7810 If the terminal's already been set up, we can't do it, but we remember the
7811 setting in case the user does a restart.
7812
7813 =cut
7814
7815 sub RemotePort {
7816     if ($term) {
7817         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7818     }
7819     $remoteport = shift if @_;
7820     $remoteport;
7821 } ## end sub RemotePort
7822
7823 =head2 C<tkRunning>
7824
7825 Checks with the terminal to see if C<Tk> is running, and returns true or
7826 false. Returns false if the current terminal doesn't support C<readline>.
7827
7828 =cut
7829
7830 sub tkRunning {
7831     if ( ${ $term->Features }{tkRunning} ) {
7832         return $term->tkRunning(@_);
7833     }
7834     else {
7835         local $\ = '';
7836         print $OUT "tkRunning not supported by current ReadLine package.\n";
7837         0;
7838     }
7839 } ## end sub tkRunning
7840
7841 =head2 C<NonStop>
7842
7843 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7844 debugger remembers the setting in case you restart, though.
7845
7846 =cut
7847
7848 sub NonStop {
7849     if ($term) {
7850         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7851           if @_;
7852     }
7853     $runnonstop = shift if @_;
7854     $runnonstop;
7855 } ## end sub NonStop
7856
7857 sub DollarCaretP {
7858     if ($term) {
7859         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7860           if @_;
7861     }
7862     $^P = parse_DollarCaretP_flags(shift) if @_;
7863     expand_DollarCaretP_flags($^P);
7864 }
7865
7866 =head2 C<pager>
7867
7868 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7869 there already.
7870
7871 =cut
7872
7873 sub pager {
7874     if (@_) {
7875         $pager = shift;
7876         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7877     }
7878     $pager;
7879 } ## end sub pager
7880
7881 =head2 C<shellBang>
7882
7883 Sets the shell escape command, and generates a printable copy to be used
7884 in the help.
7885
7886 =cut
7887
7888 sub shellBang {
7889
7890     # If we got an argument, meta-quote it, and add '\b' if it
7891     # ends in a word character.
7892     if (@_) {
7893         $sh = quotemeta shift;
7894         $sh .= "\\b" if $sh =~ /\w$/;
7895     }
7896
7897     # Generate the printable version for the help:
7898     $psh = $sh;    # copy it
7899     $psh =~ s/\\b$//;        # Take off trailing \b if any
7900     $psh =~ s/\\(.)/$1/g;    # De-escape
7901     $psh;                    # return the printable version
7902 } ## end sub shellBang
7903
7904 =head2 C<ornaments>
7905
7906 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7907 was passed as the argument. (This means you can't override the terminal's
7908 ornaments.)
7909
7910 =cut
7911
7912 sub ornaments {
7913     if ( defined $term ) {
7914
7915         # We don't want to show warning backtraces, but we do want die() ones.
7916         local $warnLevel = 0;
7917         local $dieLevel = 1;
7918
7919         # No ornaments if the terminal doesn't support them.
7920         if (not $term->Features->{ornaments}) {
7921             return '';
7922         }
7923
7924         return (eval { $term->ornaments(@_) } || '');
7925     }
7926
7927     # Use what was passed in if we can't determine it ourselves.
7928     else {
7929         $ornaments = shift;
7930
7931         return $ornaments;
7932     }
7933
7934 } ## end sub ornaments
7935
7936 =head2 C<recallCommand>
7937
7938 Sets the recall command, and builds a printable version which will appear in
7939 the help text.
7940
7941 =cut
7942
7943 sub recallCommand {
7944
7945     # If there is input, metaquote it. Add '\b' if it ends with a word
7946     # character.
7947     if (@_) {
7948         $rc = quotemeta shift;
7949         $rc .= "\\b" if $rc =~ /\w$/;
7950     }
7951
7952     # Build it into a printable version.
7953     $prc = $rc;              # Copy it
7954     $prc =~ s/\\b$//;        # Remove trailing \b
7955     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7956     return $prc;             # Return the printable version
7957 } ## end sub recallCommand
7958
7959 =head2 C<LineInfo> - where the line number information goes
7960
7961 Called with no arguments, returns the file or pipe that line info should go to.
7962
7963 Called with an argument (a file or a pipe), it opens that onto the
7964 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7965 file or pipe again to the caller.
7966
7967 =cut
7968
7969 sub LineInfo {
7970     if (@_) {
7971         $lineinfo = shift;
7972
7973         #  If this is a valid "thing to be opened for output", tack a
7974         # '>' onto the front.
7975         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7976
7977         # If this is a pipe, the stream points to a slave editor.
7978         $slave_editor = ( $stream =~ /^\|/ );
7979
7980         my $new_lineinfo_fh;
7981         # Open it up and unbuffer it.
7982         open ($new_lineinfo_fh , $stream )
7983             or _db_warn("Cannot open '$stream' for write");
7984         $LINEINFO = $new_lineinfo_fh;
7985         _autoflush($LINEINFO);
7986     }
7987
7988     return $lineinfo;
7989 } ## end sub LineInfo
7990
7991 =head1 COMMAND SUPPORT ROUTINES
7992
7993 These subroutines provide functionality for various commands.
7994
7995 =head2 C<list_modules>
7996
7997 For the C<M> command: list modules loaded and their versions.
7998 Essentially just runs through the keys in %INC, picks each package's
7999 C<$VERSION> variable, gets the file name, and formats the information
8000 for output.
8001
8002 =cut
8003
8004 sub list_modules {    # versions
8005     my %version;
8006     my $file;
8007
8008     # keys are the "as-loaded" name, values are the fully-qualified path
8009     # to the file itself.
8010     for ( keys %INC ) {
8011         $file = $_;                                # get the module name
8012         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
8013         s,/,::,g;                                  # change '/' to '::'
8014         s/^perl5db$/DB/;                           # Special case: debugger
8015                                                    # moves to package DB
8016         s/^Term::ReadLine::readline$/readline/;    # simplify readline
8017
8018         # If the package has a $VERSION package global (as all good packages
8019         # should!) decode it and save as partial message.
8020         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
8021         if ( defined $pkg_version ) {
8022             $version{$file} = "$pkg_version from ";
8023         }
8024
8025         # Finish up the message with the file the package came from.
8026         $version{$file} .= $INC{$file};
8027     } ## end for (keys %INC)
8028
8029     # Hey, dumpit() formats a hash nicely, so why not use it?
8030     dumpit( $OUT, \%version );
8031 } ## end sub list_modules
8032
8033 =head2 C<sethelp()>
8034
8035 Sets up the monster string used to format and print the help.
8036
8037 =head3 HELP MESSAGE FORMAT
8038
8039 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
8040 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
8041 easy to parse and portable, but which still allows the help to be a little
8042 nicer than just plain text.
8043
8044 Essentially, you define the command name (usually marked up with C<< B<> >>
8045 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
8046 newline. The descriptive text can also be marked up in the same way. If you
8047 need to continue the descriptive text to another line, start that line with
8048 just tabs and then enter the marked-up text.
8049
8050 If you are modifying the help text, I<be careful>. The help-string parser is
8051 not very sophisticated, and if you don't follow these rules it will mangle the
8052 help beyond hope until you fix the string.
8053
8054 =cut
8055
8056 use vars qw($pre580_help);
8057 use vars qw($pre580_summary);
8058
8059 sub sethelp {
8060
8061     # XXX: make sure there are tabs between the command and explanation,
8062     #      or print_help will screw up your formatting if you have
8063     #      eeevil ornaments enabled.  This is an insane mess.
8064
8065     $help = "
8066 Help is currently only available for the new 5.8 command set.
8067 No help is available for the old command set.
8068 We assume you know what you're doing if you switch to it.
8069
8070 B<T>        Stack trace.
8071 B<s> [I<expr>]    Single step [in I<expr>].
8072 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8073 <B<CR>>        Repeat last B<n> or B<s> command.
8074 B<r>        Return from current subroutine.
8075 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8076         at the specified position.
8077 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8078 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8079 B<l> I<line>        List single I<line>.
8080 B<l> I<subname>    List first window of lines from subroutine.
8081 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8082 B<l>        List next window of lines.
8083 B<->        List previous window of lines.
8084 B<v> [I<line>]    View window around I<line>.
8085 B<.>        Return to the executed line.
8086 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8087         I<filename> may be either the full name of the file, or a regular
8088         expression matching the full file name:
8089         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8090         Evals (with saved bodies) are considered to be filenames:
8091         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8092         (in the order of execution).
8093 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8094 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8095 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8096 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8097 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8098 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8099 B<b>        Sets breakpoint on current line)
8100 B<b> [I<line>] [I<condition>]
8101         Set breakpoint; I<line> defaults to the current execution line;
8102         I<condition> breaks if it evaluates to true, defaults to '1'.
8103 B<b> I<subname> [I<condition>]
8104         Set breakpoint at first line of subroutine.
8105 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8106 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8107 B<b> B<postpone> I<subname> [I<condition>]
8108         Set breakpoint at first line of subroutine after
8109         it is compiled.
8110 B<b> B<compile> I<subname>
8111         Stop after the subroutine is compiled.
8112 B<B> [I<line>]    Delete the breakpoint for I<line>.
8113 B<B> I<*>             Delete all breakpoints.
8114 B<a> [I<line>] I<command>
8115         Set an action to be done before the I<line> is executed;
8116         I<line> defaults to the current execution line.
8117         Sequence is: check for breakpoint/watchpoint, print line
8118         if necessary, do action, prompt user if necessary,
8119         execute line.
8120 B<a>        Does nothing
8121 B<A> [I<line>]    Delete the action for I<line>.
8122 B<A> I<*>             Delete all actions.
8123 B<w> I<expr>        Add a global watch-expression.
8124 B<w>             Does nothing
8125 B<W> I<expr>        Delete a global watch-expression.
8126 B<W> I<*>             Delete all watch-expressions.
8127 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8128         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8129 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8130 B<x> I<expr>        Evals expression in list context, dumps the result.
8131 B<m> I<expr>        Evals expression in list context, prints methods callable
8132         on the first element of the result.
8133 B<m> I<class>        Prints methods callable via the given class.
8134 B<M>        Show versions of loaded modules.
8135 B<i> I<class>       Prints nested parents of given class.
8136 B<e>         Display current thread id.
8137 B<E>         Display all thread ids the current one will be identified: <n>.
8138 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8139
8140 B<<> ?            List Perl commands to run before each prompt.
8141 B<<> I<expr>        Define Perl command to run before each prompt.
8142 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8143 B<< *>                Delete the list of perl commands to run before each prompt.
8144 B<>> ?            List Perl commands to run after each prompt.
8145 B<>> I<expr>        Define Perl command to run after each prompt.
8146 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8147 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8148 B<{> I<db_command>    Define debugger command to run before each prompt.
8149 B<{> ?            List debugger commands to run before each prompt.
8150 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8151 B<{ *>             Delete the list of debugger commands to run before each prompt.
8152 B<$prc> I<number>    Redo a previous command (default previous command).
8153 B<$prc> I<-number>    Redo number'th-to-last command.
8154 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8155         See 'B<O> I<recallCommand>' too.
8156 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8157       . (
8158         $rc eq $sh
8159         ? ""
8160         : "
8161 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8162       ) . "
8163         See 'B<O> I<shellBang>' too.
8164 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8165 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8166 B<rerun>           Rerun session to current position.
8167 B<rerun> I<n>         Rerun session to numbered command.
8168 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8169 B<H> I<-number>    Display last number commands (default all).
8170 B<H> I<*>          Delete complete history.
8171 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8172 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8173 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8174 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8175 I<command>        Execute as a perl statement in current package.
8176 B<R>        Pure-man-restart of debugger, some of debugger state
8177         and command-line options may be lost.
8178         Currently the following settings are preserved:
8179         history, breakpoints and actions, debugger B<O>ptions
8180         and the following command-line options: I<-w>, I<-I>, I<-e>.
8181
8182 B<o> [I<opt>] ...    Set boolean option to true
8183 B<o> [I<opt>B<?>]    Query options
8184 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8185         Set options.  Use quotes if spaces in value.
8186     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8187     I<pager>            program for output of \"|cmd\";
8188     I<tkRunning>            run Tk while prompting (with ReadLine);
8189     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8190     I<inhibit_exit>        Allows stepping off the end of the script.
8191     I<ImmediateStop>        Debugger should stop as early as possible.
8192     I<RemotePort>            Remote hostname:port for remote debugging
8193   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8194     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8195     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8196     I<globPrint>             whether to print contents of globs;
8197     I<DumpDBFiles>         dump arrays holding debugged files;
8198     I<DumpPackages>         dump symbol tables of packages;
8199     I<DumpReused>             dump contents of \"reused\" addresses;
8200     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8201     I<bareStringify>         Do not print the overload-stringified value;
8202   Other options include:
8203     I<PrintRet>        affects printing of return value after B<r> command,
8204     I<frame>        affects printing messages on subroutine entry/exit.
8205     I<AutoTrace>    affects printing messages on possible breaking points.
8206     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8207     I<ornaments>     affects screen appearance of the command line.
8208     I<CreateTTY>     bits control attempts to create a new TTY on events:
8209             1: on fork()    2: debugger is started inside debugger
8210             4: on startup
8211     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8212     You can put additional initialization options I<TTY>, I<noTTY>,
8213     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8214     B<R> after you set them).
8215
8216 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8217 B<h>        Summary of debugger commands.
8218 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8219 B<h h>        Long help for debugger commands
8220 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8221         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8222         Set B<\$DB::doccmd> to change viewer.
8223
8224 Type '|h h' for a paged display if this was too hard to read.
8225
8226 ";    # Fix balance of vi % matching: }}}}
8227
8228     #  note: tabs in the following section are not-so-helpful
8229     $summary = <<"END_SUM";
8230 I<List/search source lines:>               I<Control script execution:>
8231   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8232   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8233   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8234   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8235   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8236   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8237 I<Debugger controls:>                        B<L>           List break/watch/actions
8238   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8239   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8240   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8241   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8242   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8243   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8244   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8245   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8246   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8247 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8248   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8249   B<p> I<expr>         Print expression (uses script's current package).
8250   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8251   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8252   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8253   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8254   B<e>     Display thread id     B<E> Display all thread ids.
8255 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8256 END_SUM
8257
8258     # ')}}; # Fix balance of vi % matching
8259
8260     # and this is really numb...
8261     $pre580_help = "
8262 B<T>        Stack trace.
8263 B<s> [I<expr>]    Single step [in I<expr>].
8264 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8265 B<CR>>        Repeat last B<n> or B<s> command.
8266 B<r>        Return from current subroutine.
8267 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8268         at the specified position.
8269 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8270 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8271 B<l> I<line>        List single I<line>.
8272 B<l> I<subname>    List first window of lines from subroutine.
8273 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8274 B<l>        List next window of lines.
8275 B<->        List previous window of lines.
8276 B<w> [I<line>]    List window around I<line>.
8277 B<.>        Return to the executed line.
8278 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8279         I<filename> may be either the full name of the file, or a regular
8280         expression matching the full file name:
8281         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8282         Evals (with saved bodies) are considered to be filenames:
8283         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8284         (in the order of execution).
8285 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8286 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8287 B<L>        List all breakpoints and actions.
8288 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8289 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8290 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8291 B<b> [I<line>] [I<condition>]
8292         Set breakpoint; I<line> defaults to the current execution line;
8293         I<condition> breaks if it evaluates to true, defaults to '1'.
8294 B<b> I<subname> [I<condition>]
8295         Set breakpoint at first line of subroutine.
8296 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8297 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8298 B<b> B<postpone> I<subname> [I<condition>]
8299         Set breakpoint at first line of subroutine after
8300         it is compiled.
8301 B<b> B<compile> I<subname>
8302         Stop after the subroutine is compiled.
8303 B<d> [I<line>]    Delete the breakpoint for I<line>.
8304 B<D>        Delete all breakpoints.
8305 B<a> [I<line>] I<command>
8306         Set an action to be done before the I<line> is executed;
8307         I<line> defaults to the current execution line.
8308         Sequence is: check for breakpoint/watchpoint, print line
8309         if necessary, do action, prompt user if necessary,
8310         execute line.
8311 B<a> [I<line>]    Delete the action for I<line>.
8312 B<A>        Delete all actions.
8313 B<W> I<expr>        Add a global watch-expression.
8314 B<W>        Delete all watch-expressions.
8315 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8316         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8317 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8318 B<x> I<expr>        Evals expression in list context, dumps the result.
8319 B<m> I<expr>        Evals expression in list context, prints methods callable
8320         on the first element of the result.
8321 B<m> I<class>        Prints methods callable via the given class.
8322
8323 B<<> ?            List Perl commands to run before each prompt.
8324 B<<> I<expr>        Define Perl command to run before each prompt.
8325 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8326 B<>> ?            List Perl commands to run after each prompt.
8327 B<>> I<expr>        Define Perl command to run after each prompt.
8328 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8329 B<{> I<db_command>    Define debugger command to run before each prompt.
8330 B<{> ?            List debugger commands to run before each prompt.
8331 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8332 B<$prc> I<number>    Redo a previous command (default previous command).
8333 B<$prc> I<-number>    Redo number'th-to-last command.
8334 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8335         See 'B<O> I<recallCommand>' too.
8336 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8337       . (
8338         $rc eq $sh
8339         ? ""
8340         : "
8341 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8342       ) . "
8343         See 'B<O> I<shellBang>' too.
8344 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8345 B<H> I<-number>    Display last number commands (default all).
8346 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8347 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8348 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8349 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8350 I<command>        Execute as a perl statement in current package.
8351 B<v>        Show versions of loaded modules.
8352 B<R>        Pure-man-restart of debugger, some of debugger state
8353         and command-line options may be lost.
8354         Currently the following settings are preserved:
8355         history, breakpoints and actions, debugger B<O>ptions
8356         and the following command-line options: I<-w>, I<-I>, I<-e>.
8357
8358 B<O> [I<opt>] ...    Set boolean option to true
8359 B<O> [I<opt>B<?>]    Query options
8360 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8361         Set options.  Use quotes if spaces in value.
8362     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8363     I<pager>            program for output of \"|cmd\";
8364     I<tkRunning>            run Tk while prompting (with ReadLine);
8365     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8366     I<inhibit_exit>        Allows stepping off the end of the script.
8367     I<ImmediateStop>        Debugger should stop as early as possible.
8368     I<RemotePort>            Remote hostname:port for remote debugging
8369   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8370     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8371     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8372     I<globPrint>             whether to print contents of globs;
8373     I<DumpDBFiles>         dump arrays holding debugged files;
8374     I<DumpPackages>         dump symbol tables of packages;
8375     I<DumpReused>             dump contents of \"reused\" addresses;
8376     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8377     I<bareStringify>         Do not print the overload-stringified value;
8378   Other options include:
8379     I<PrintRet>        affects printing of return value after B<r> command,
8380     I<frame>        affects printing messages on subroutine entry/exit.
8381     I<AutoTrace>    affects printing messages on possible breaking points.
8382     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8383     I<ornaments>     affects screen appearance of the command line.
8384     I<CreateTTY>     bits control attempts to create a new TTY on events:
8385             1: on fork()    2: debugger is started inside debugger
8386             4: on startup
8387     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8388     You can put additional initialization options I<TTY>, I<noTTY>,
8389     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8390     B<R> after you set them).
8391
8392 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8393 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8394 B<h h>        Summary of debugger commands.
8395 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8396         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8397         Set B<\$DB::doccmd> to change viewer.
8398
8399 Type '|h' for a paged display if this was too hard to read.
8400
8401 ";    # Fix balance of vi % matching: }}}}
8402
8403     #  note: tabs in the following section are not-so-helpful
8404     $pre580_summary = <<"END_SUM";
8405 I<List/search source lines:>               I<Control script execution:>
8406   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8407   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8408   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8409   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8410   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8411   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8412 I<Debugger controls:>                        B<L>           List break/watch/actions
8413   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8414   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8415   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8416   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8417   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8418   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8419   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8420   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8421 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8422   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8423   B<p> I<expr>         Print expression (uses script's current package).
8424   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8425   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8426   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8427   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8428 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8429 END_SUM
8430
8431     # ')}}; # Fix balance of vi % matching
8432
8433 } ## end sub sethelp
8434
8435 =head2 C<print_help()>
8436
8437 Most of what C<print_help> does is just text formatting. It finds the
8438 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8439 terminal control characters to simulate them (courtesy of
8440 C<Term::ReadLine::TermCap>).
8441
8442 =cut
8443
8444 sub print_help {
8445     my $help_str = shift;
8446
8447     # Restore proper alignment destroyed by eeevil I<> and B<>
8448     # ornaments: A pox on both their houses!
8449     #
8450     # A help command will have everything up to and including
8451     # the first tab sequence padded into a field 16 (or if indented 20)
8452     # wide.  If it's wider than that, an extra space will be added.
8453     $help_str =~ s{
8454         ^                       # only matters at start of line
8455           ( \ {4} | \t )*       # some subcommands are indented
8456           ( < ?                 # so <CR> works
8457             [BI] < [^\t\n] + )  # find an eeevil ornament
8458           ( \t+ )               # original separation, discarded
8459           ( .* )                # this will now start (no earlier) than
8460                                 # column 16
8461     } {
8462         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8463         my $clean = $command;
8464         $clean =~ s/[BI]<([^>]*)>/$1/g;
8465
8466         # replace with this whole string:
8467         ($leadwhite ? " " x 4 : "")
8468       . $command
8469       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8470       . $text;
8471
8472     }mgex;
8473
8474     $help_str =~ s{                          # handle bold ornaments
8475        B < ( [^>] + | > ) >
8476     } {
8477           $Term::ReadLine::TermCap::rl_term_set[2]
8478         . $1
8479         . $Term::ReadLine::TermCap::rl_term_set[3]
8480     }gex;
8481
8482     $help_str =~ s{                         # handle italic ornaments
8483        I < ( [^>] + | > ) >
8484     } {
8485           $Term::ReadLine::TermCap::rl_term_set[0]
8486         . $1
8487         . $Term::ReadLine::TermCap::rl_term_set[1]
8488     }gex;
8489
8490     local $\ = '';
8491     print {$OUT} $help_str;
8492
8493     return;
8494 } ## end sub print_help
8495
8496 =head2 C<fix_less>
8497
8498 This routine does a lot of gyrations to be sure that the pager is C<less>.
8499 It checks for C<less> masquerading as C<more> and records the result in
8500 C<$fixed_less> so we don't have to go through doing the stats again.
8501
8502 =cut
8503
8504 use vars qw($fixed_less);
8505
8506 sub _calc_is_less {
8507     if ($pager =~ /\bless\b/)
8508     {
8509         return 1;
8510     }
8511     elsif ($pager =~ /\bmore\b/)
8512     {
8513         # Nope, set to more. See what's out there.
8514         my @st_more = stat('/usr/bin/more');
8515         my @st_less = stat('/usr/bin/less');
8516
8517         # is it really less, pretending to be more?
8518         return (
8519             @st_more
8520             && @st_less
8521             && $st_more[0] == $st_less[0]
8522             && $st_more[1] == $st_less[1]
8523         );
8524     }
8525     else {
8526         return;
8527     }
8528 }
8529
8530 sub fix_less {
8531
8532     # We already know if this is set.
8533     return if $fixed_less;
8534
8535     # changes environment!
8536     # 'r' added so we don't do (slow) stats again.
8537     $fixed_less = 1 if _calc_is_less();
8538
8539     return;
8540 } ## end sub fix_less
8541
8542 =head1 DIE AND WARN MANAGEMENT
8543
8544 =head2 C<diesignal>
8545
8546 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8547 to debug a debugger problem.
8548
8549 It does its best to report the error that occurred, and then forces the
8550 program, debugger, and everything to die.
8551
8552 =cut
8553
8554 sub diesignal {
8555
8556     # No entry/exit messages.
8557     local $frame = 0;
8558
8559     # No return value prints.
8560     local $doret = -2;
8561
8562     # set the abort signal handling to the default (just terminate).
8563     $SIG{'ABRT'} = 'DEFAULT';
8564
8565     # If we enter the signal handler recursively, kill myself with an
8566     # abort signal (so we just terminate).
8567     kill 'ABRT', $$ if $panic++;
8568
8569     # If we can show detailed info, do so.
8570     if ( defined &Carp::longmess ) {
8571
8572         # Don't recursively enter the warn handler, since we're carping.
8573         local $SIG{__WARN__} = '';
8574
8575         # Skip two levels before reporting traceback: we're skipping
8576         # mydie and confess.
8577         local $Carp::CarpLevel = 2;    # mydie + confess
8578
8579         # Tell us all about it.
8580         _db_warn( Carp::longmess("Signal @_") );
8581     }
8582
8583     # No Carp. Tell us about the signal as best we can.
8584     else {
8585         local $\ = '';
8586         print $DB::OUT "Got signal @_\n";
8587     }
8588
8589     # Drop dead.
8590     kill 'ABRT', $$;
8591 } ## end sub diesignal
8592
8593 =head2 C<dbwarn>
8594
8595 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8596 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8597
8598 =cut
8599
8600 sub dbwarn {
8601
8602     # No entry/exit trace.
8603     local $frame = 0;
8604
8605     # No return value printing.
8606     local $doret = -2;
8607
8608     # Turn off warn and die handling to prevent recursive entries to this
8609     # routine.
8610     local $SIG{__WARN__} = '';
8611     local $SIG{__DIE__}  = '';
8612
8613     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8614     # done yet), we may not be able to do a require.
8615     eval { require Carp }
8616       if defined $^S;    # If error/warning during compilation,
8617                          # require may be broken.
8618
8619     # Use the core warn() unless Carp loaded OK.
8620     CORE::warn( @_,
8621         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8622       return
8623       unless defined &Carp::longmess;
8624
8625     # Save the current values of $single and $trace, and then turn them off.
8626     my ( $mysingle, $mytrace ) = ( $single, $trace );
8627     $single = 0;
8628     $trace  = 0;
8629
8630     # We can call Carp::longmess without its being "debugged" (which we
8631     # don't want - we just want to use it!). Capture this for later.
8632     my $mess = Carp::longmess(@_);
8633
8634     # Restore $single and $trace to their original values.
8635     ( $single, $trace ) = ( $mysingle, $mytrace );
8636
8637     # Use the debugger's own special way of printing warnings to print
8638     # the stack trace message.
8639     _db_warn($mess);
8640 } ## end sub dbwarn
8641
8642 =head2 C<dbdie>
8643
8644 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8645 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8646 single stepping and tracing during the call to C<Carp::longmess> to avoid
8647 debugging it - we just want to use it.
8648
8649 If C<dieLevel> is zero, we let the program being debugged handle the
8650 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8651 the debugger takes over all exception handling, printing a backtrace and
8652 displaying the exception via its C<dbwarn()> routine.
8653
8654 =cut
8655
8656 sub dbdie {
8657     local $frame         = 0;
8658     local $doret         = -2;
8659     local $SIG{__DIE__}  = '';
8660     local $SIG{__WARN__} = '';
8661     if ( $dieLevel > 2 ) {
8662         local $SIG{__WARN__} = \&dbwarn;
8663         _db_warn(@_);    # Yell no matter what
8664         return;
8665     }
8666     if ( $dieLevel < 2 ) {
8667         die @_ if $^S;    # in eval propagate
8668     }
8669
8670     # The code used to check $^S to see if compilation of the current thing
8671     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8672     eval { require Carp };
8673
8674     die( @_,
8675         "\nCannot print stack trace, load with -MCarp option to see stack" )
8676       unless defined &Carp::longmess;
8677
8678     # We do not want to debug this chunk (automatic disabling works
8679     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8680     # get the stack trace from Carp::longmess (if possible), restore $signal
8681     # and $trace, and then die with the stack trace.
8682     my ( $mysingle, $mytrace ) = ( $single, $trace );
8683     $single = 0;
8684     $trace  = 0;
8685     my $mess = "@_";
8686     {
8687
8688         package Carp;    # Do not include us in the list
8689         eval { $mess = Carp::longmess(@_); };
8690     }
8691     ( $single, $trace ) = ( $mysingle, $mytrace );
8692     die $mess;
8693 } ## end sub dbdie
8694
8695 =head2 C<warnlevel()>
8696
8697 Set the C<$DB::warnLevel> variable that stores the value of the
8698 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8699 results in the debugger taking over all warning handlers. Setting
8700 C<warnLevel> to zero leaves any warning handlers set up by the program
8701 being debugged in place.
8702
8703 =cut
8704
8705 sub warnLevel {
8706     if (@_) {
8707         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8708         $warnLevel = shift;
8709         if ($warnLevel) {
8710             $SIG{__WARN__} = \&DB::dbwarn;
8711         }
8712         elsif ($prevwarn) {
8713             $SIG{__WARN__} = $prevwarn;
8714         } else {
8715             undef $SIG{__WARN__};
8716         }
8717     } ## end if (@_)
8718     $warnLevel;
8719 } ## end sub warnLevel
8720
8721 =head2 C<dielevel>
8722
8723 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8724 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8725 zero lets you use your own C<die()> handler.
8726
8727 =cut
8728
8729 sub dieLevel {
8730     local $\ = '';
8731     if (@_) {
8732         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8733         $dieLevel = shift;
8734         if ($dieLevel) {
8735
8736             # Always set it to dbdie() for non-zero values.
8737             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8738
8739             # No longer exists, so don't try  to use it.
8740             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8741
8742             # If we've finished initialization, mention that stack dumps
8743             # are enabled, If dieLevel is 1, we won't stack dump if we die
8744             # in an eval().
8745             print $OUT "Stack dump during die enabled",
8746               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8747               if $I_m_init;
8748
8749             # XXX This is probably obsolete, given that diehard() is gone.
8750             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8751         } ## end if ($dieLevel)
8752
8753         # Put the old one back if there was one.
8754         elsif ($prevdie) {
8755             $SIG{__DIE__} = $prevdie;
8756             print $OUT "Default die handler restored.\n";
8757         } else {
8758             undef $SIG{__DIE__};
8759             print $OUT "Die handler removed.\n";
8760         }
8761     } ## end if (@_)
8762     $dieLevel;
8763 } ## end sub dieLevel
8764
8765 =head2 C<signalLevel>
8766
8767 Number three in a series: set C<signalLevel> to zero to keep your own
8768 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8769 takes over and handles them with C<DB::diesignal()>.
8770
8771 =cut
8772
8773 sub signalLevel {
8774     if (@_) {
8775         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8776         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8777         $signalLevel = shift;
8778         if ($signalLevel) {
8779             $SIG{SEGV} = \&DB::diesignal;
8780             $SIG{BUS}  = \&DB::diesignal;
8781         }
8782         else {
8783             $SIG{SEGV} = $prevsegv;
8784             $SIG{BUS}  = $prevbus;
8785         }
8786     } ## end if (@_)
8787     $signalLevel;
8788 } ## end sub signalLevel
8789
8790 =head1 SUBROUTINE DECODING SUPPORT
8791
8792 These subroutines are used during the C<x> and C<X> commands to try to
8793 produce as much information as possible about a code reference. They use
8794 L<Devel::Peek> to try to find the glob in which this code reference lives
8795 (if it does) - this allows us to actually code references which correspond
8796 to named subroutines (including those aliased via glob assignment).
8797
8798 =head2 C<CvGV_name()>
8799
8800 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8801 via that routine. If this fails, return the reference again (when the
8802 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8803
8804 =cut
8805
8806 sub CvGV_name {
8807     my $in   = shift;
8808     my $name = CvGV_name_or_bust($in);
8809     defined $name ? $name : $in;
8810 }
8811
8812 =head2 C<CvGV_name_or_bust> I<coderef>
8813
8814 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8815 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8816 find a glob for this ref.
8817
8818 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8819
8820 =cut
8821
8822 use vars qw($skipCvGV);
8823
8824 sub CvGV_name_or_bust {
8825     my $in = shift;
8826     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8827     return unless ref $in;
8828     $in = \&$in;            # Hard reference...
8829     eval { require Devel::Peek; 1 } or return;
8830     my $gv = Devel::Peek::CvGV($in) or return;
8831     *$gv{PACKAGE} . '::' . *$gv{NAME};
8832 } ## end sub CvGV_name_or_bust
8833
8834 =head2 C<find_sub>
8835
8836 A utility routine used in various places; finds the file where a subroutine
8837 was defined, and returns that filename and a line-number range.
8838
8839 Tries to use C<@sub> first; if it can't find it there, it tries building a
8840 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8841 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8842 this way, it brute-force searches C<%sub>, checking for identical references.
8843
8844 =cut
8845
8846 sub _find_sub_helper {
8847     my $subr = shift;
8848
8849     return unless defined &$subr;
8850     my $name = CvGV_name_or_bust($subr);
8851     my $data;
8852     $data = $sub{$name} if defined $name;
8853     return $data if defined $data;
8854
8855     # Old stupid way...
8856     $subr = \&$subr;    # Hard reference
8857     my $s;
8858     for ( keys %sub ) {
8859         $s = $_, last if $subr eq \&$_;
8860     }
8861     if ($s)
8862     {
8863         return $sub{$s};
8864     }
8865     else
8866     {
8867         return;
8868     }
8869
8870 }
8871
8872 sub find_sub {
8873     my $subr = shift;
8874     return ( $sub{$subr} || _find_sub_helper($subr) );
8875 } ## end sub find_sub
8876
8877 =head2 C<methods>
8878
8879 A subroutine that uses the utility function C<methods_via> to find all the
8880 methods in the class corresponding to the current reference and in
8881 C<UNIVERSAL>.
8882
8883 =cut
8884
8885 use vars qw(%seen);
8886
8887 sub methods {
8888
8889     # Figure out the class - either this is the class or it's a reference
8890     # to something blessed into that class.
8891     my $class = shift;
8892     $class = ref $class if ref $class;
8893
8894     local %seen;
8895
8896     # Show the methods that this class has.
8897     methods_via( $class, '', 1 );
8898
8899     # Show the methods that UNIVERSAL has.
8900     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8901 } ## end sub methods
8902
8903 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8904
8905 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8906 all the parent class methods. C<$class> is the name of the next class to
8907 try; C<$prefix> is the message prefix, which gets built up as we go up the
8908 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8909 higher in the C<@ISA> tree, 0 if we should stop.
8910
8911 =cut
8912
8913 sub methods_via {
8914
8915     # If we've processed this class already, just quit.
8916     my $class = shift;
8917     return if $seen{$class}++;
8918
8919     # This is a package that is contributing the methods we're about to print.
8920     my $prefix  = shift;
8921     my $prepend = $prefix ? "via $prefix: " : '';
8922     my @to_print;
8923
8924     # Extract from all the symbols in this class.
8925     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8926     while (my ($name, $glob) = each %$class_ref) {
8927         # references directly in the symbol table are Proxy Constant
8928         # Subroutines, and are by their very nature defined
8929         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8930         # to a subroutine reference, which can be tested by defined.
8931         # $glob might also be the value -1  (from sub foo;)
8932         # or (say) '$$' (from sub foo ($$);)
8933         # \$glob will be SCALAR in both cases.
8934         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8935             && !$seen{$name}++) {
8936             push @to_print, "$prepend$name\n";
8937         }
8938     }
8939
8940     {
8941         local $\ = '';
8942         local $, = '';
8943         print $DB::OUT $_ foreach sort @to_print;
8944     }
8945
8946     # If the $crawl_upward argument is false, just quit here.
8947     return unless shift;
8948
8949     # $crawl_upward true: keep going up the tree.
8950     # Find all the classes this one is a subclass of.
8951     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8952     for my $name ( @$class_ISA_ref ) {
8953
8954         # Set up the new prefix.
8955         $prepend = $prefix ? $prefix . " -> $name" : $name;
8956
8957         # Crawl up the tree and keep trying to crawl up.
8958         methods_via( $name, $prepend, 1 );
8959     }
8960 } ## end sub methods_via
8961
8962 =head2 C<setman> - figure out which command to use to show documentation
8963
8964 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8965
8966 =cut
8967
8968 sub setman {
8969     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8970       ? "man"         # O Happy Day!
8971       : "perldoc";    # Alas, poor unfortunates
8972 } ## end sub setman
8973
8974 =head2 C<runman> - run the appropriate command to show documentation
8975
8976 Accepts a man page name; runs the appropriate command to display it (set up
8977 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8978 program's STDIN and STDOUT.
8979
8980 =cut
8981
8982 sub runman {
8983     my $page = shift;
8984     unless ($page) {
8985         _db_system("$doccmd $doccmd");
8986         return;
8987     }
8988
8989     # this way user can override, like with $doccmd="man -Mwhatever"
8990     # or even just "man " to disable the path check.
8991     if ( $doccmd ne 'man' ) {
8992         _db_system("$doccmd $page");
8993         return;
8994     }
8995
8996     $page = 'perl' if lc($page) eq 'help';
8997
8998     require Config;
8999     my $man1dir = $Config::Config{man1direxp};
9000     my $man3dir = $Config::Config{man3direxp};
9001     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
9002     my $manpath = '';
9003     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
9004     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
9005     chop $manpath if $manpath;
9006
9007     # harmless if missing, I figure
9008     local $ENV{MANPATH} = $manpath if $manpath;
9009     my $nopathopt = $^O =~ /dunno what goes here/;
9010     if (
9011         CORE::system(
9012             $doccmd,
9013
9014             # I just *know* there are men without -M
9015             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9016             split ' ', $page
9017         )
9018       )
9019     {
9020         unless ( $page =~ /^perl\w/ ) {
9021             # Previously the debugger contained a list which it slurped in,
9022             # listing the known "perl" manpages. However, it was out of date,
9023             # with errors both of omission and inclusion. This approach is
9024             # considerably less complex. The failure mode on a butchered
9025             # install is simply that the user has to run man or perldoc
9026             # "manually" with the full manpage name.
9027
9028             # There is a list of $^O values in installperl to determine whether
9029             # the directory is 'pods' or 'pod'. However, we can avoid tight
9030             # coupling to that by simply checking the "non-standard" 'pods'
9031             # first.
9032             my $pods = "$Config::Config{privlibexp}/pods";
9033             $pods = "$Config::Config{privlibexp}/pod"
9034                 unless -d $pods;
9035             if (-f "$pods/perl$page.pod") {
9036                 CORE::system( $doccmd,
9037                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9038                     "perl$page" );
9039             }
9040         }
9041     } ## end if (CORE::system($doccmd...
9042 } ## end sub runman
9043
9044 #use Carp;                          # This did break, left for debugging
9045
9046 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
9047
9048 Because of the way the debugger interface to the Perl core is designed, any
9049 debugger package globals that C<DB::sub()> requires have to be defined before
9050 any subroutines can be called. These are defined in the second C<BEGIN> block.
9051
9052 This block sets things up so that (basically) the world is sane
9053 before the debugger starts executing. We set up various variables that the
9054 debugger has to have set up before the Perl core starts running:
9055
9056 =over 4
9057
9058 =item *
9059
9060 The debugger's own filehandles (copies of STD and STDOUT for now).
9061
9062 =item *
9063
9064 Characters for shell escapes, the recall command, and the history command.
9065
9066 =item *
9067
9068 The maximum recursion depth.
9069
9070 =item *
9071
9072 The size of a C<w> command's window.
9073
9074 =item *
9075
9076 The before-this-line context to be printed in a C<v> (view a window around this line) command.
9077
9078 =item *
9079
9080 The fact that we're not in a sub at all right now.
9081
9082 =item *
9083
9084 The default SIGINT handler for the debugger.
9085
9086 =item *
9087
9088 The appropriate value of the flag in C<$^D> that says the debugger is running
9089
9090 =item *
9091
9092 The current debugger recursion level
9093
9094 =item *
9095
9096 The list of postponed items and the C<$single> stack (XXX define this)
9097
9098 =item *
9099
9100 That we want no return values and no subroutine entry/exit trace.
9101
9102 =back
9103
9104 =cut
9105
9106 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9107
9108 use vars qw($db_stop);
9109
9110 BEGIN {    # This does not compile, alas. (XXX eh?)
9111     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9112     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9113
9114     # Define characters used by command parsing.
9115     $sh       = '!';      # Shell escape (does not work)
9116     $rc       = ',';      # Recall command (does not work)
9117     @hist     = ('?');    # Show history (does not work)
9118     @truehist = ();       # Can be saved for replay (per session)
9119
9120     # This defines the point at which you get the 'deep recursion'
9121     # warning. It MUST be defined or the debugger will not load.
9122     $deep = 1000;
9123
9124     # Number of lines around the current one that are shown in the
9125     # 'w' command.
9126     $window = 10;
9127
9128     # How much before-the-current-line context the 'v' command should
9129     # use in calculating the start of the window it will display.
9130     $preview = 3;
9131
9132     # We're not in any sub yet, but we need this to be a defined value.
9133     $sub = '';
9134
9135     # Set up the debugger's interrupt handler. It simply sets a flag
9136     # ($signal) that DB::DB() will check before each command is executed.
9137     $SIG{INT} = \&DB::catch;
9138
9139     # The following lines supposedly, if uncommented, allow the debugger to
9140     # debug itself. Perhaps we can try that someday.
9141     # This may be enabled to debug debugger:
9142     #$warnLevel = 1 unless defined $warnLevel;
9143     #$dieLevel = 1 unless defined $dieLevel;
9144     #$signalLevel = 1 unless defined $signalLevel;
9145
9146     # This is the flag that says "a debugger is running, please call
9147     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9148     # execute anything in the user's context, because we always want to
9149     # get control back.
9150     $db_stop = 0;          # Compiler warning ...
9151     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9152
9153     # This variable records how many levels we're nested in debugging. Used
9154     # Used in the debugger prompt, and in determining whether it's all over or
9155     # not.
9156     $level = 0;            # Level of recursive debugging
9157
9158     # "Triggers bug (?) in perl if we postpone this until runtime."
9159     # XXX No details on this yet, or whether we should fix the bug instead
9160     # of work around it. Stay tuned.
9161     @stack = (0);
9162
9163     # Used to track the current stack depth using the auto-stacked-variable
9164     # trick.
9165     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9166
9167     # Don't print return values on exiting a subroutine.
9168     $doret = -2;
9169
9170     # No extry/exit tracing.
9171     $frame = 0;
9172
9173 } ## end BEGIN
9174
9175 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9176
9177 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9178
9179 =head2 db_complete
9180
9181 C<readline> support - adds command completion to basic C<readline>.
9182
9183 Returns a list of possible completions to C<readline> when invoked. C<readline>
9184 will print the longest common substring following the text already entered.
9185
9186 If there is only a single possible completion, C<readline> will use it in full.
9187
9188 This code uses C<map> and C<grep> heavily to create lists of possible
9189 completion. Think LISP in this section.
9190
9191 =cut
9192
9193 sub db_complete {
9194
9195     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9196     # $text is the text to be completed.
9197     # $line is the incoming line typed by the user.
9198     # $start is the start of the text to be completed in the incoming line.
9199     my ( $text, $line, $start ) = @_;
9200
9201     # Save the initial text.
9202     # The search pattern is current package, ::, extract the next qualifier
9203     # Prefix and pack are set to undef.
9204     my ( $itext, $search, $prefix, $pack ) =
9205       ( $text, "^\Q${package}::\E([^:]+)\$" );
9206
9207 =head3 C<b postpone|compile>
9208
9209 =over 4
9210
9211 =item *
9212
9213 Find all the subroutines that might match in this package
9214
9215 =item *
9216
9217 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9218
9219 =item *
9220
9221 Include all the rest of the subs that are known
9222
9223 =item *
9224
9225 C<grep> out the ones that match the text we have so far
9226
9227 =item *
9228
9229 Return this as the list of possible completions
9230
9231 =back
9232
9233 =cut
9234
9235     return sort grep /^\Q$text/, ( keys %sub ),
9236       qw(postpone load compile),    # subroutines
9237       ( map { /$search/ ? ($1) : () } keys %sub )
9238       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9239
9240 =head3 C<b load>
9241
9242 Get all the possible files from C<@INC> as it currently stands and
9243 select the ones that match the text so far.
9244
9245 =cut
9246
9247     return sort grep /^\Q$text/, values %INC    # files
9248       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9249
9250 =head3  C<V> (list variable) and C<m> (list modules)
9251
9252 There are two entry points for these commands:
9253
9254 =head4 Unqualified package names
9255
9256 Get the top-level packages and grab everything that matches the text
9257 so far. For each match, recursively complete the partial packages to
9258 get all possible matching packages. Return this sorted list.
9259
9260 =cut
9261
9262     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9263       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9264       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9265
9266 =head4 Qualified package names
9267
9268 Take a partially-qualified package and find all subpackages for it
9269 by getting all the subpackages for the package so far, matching all
9270 the subpackages against the text, and discarding all of them which
9271 start with 'main::'. Return this list.
9272
9273 =cut
9274
9275     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9276       grep !/^main::/, grep /^\Q$text/,
9277       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9278       do { no strict 'refs'; keys %{ $prefix . '::' } }
9279       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9280       and $text =~ /^(.*[^:])::?(\w*)$/
9281       and $prefix = $1;
9282
9283 =head3 C<f> - switch files
9284
9285 Here, we want to get a fully-qualified filename for the C<f> command.
9286 Possibilities are:
9287
9288 =over 4
9289
9290 =item 1. The original source file itself
9291
9292 =item 2. A file from C<@INC>
9293
9294 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9295
9296 =back
9297
9298 =cut
9299
9300     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9301            # We might possibly want to switch to an eval (which has a "filename"
9302            # like '(eval 9)'), so we may need to clean up the completion text
9303            # before proceeding.
9304         $prefix = length($1) - length($text);
9305         $text   = $1;
9306
9307 =pod
9308
9309 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9310 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9311 out of C<%main::>, add the initial source file, and extract the ones that
9312 match the completion text so far.
9313
9314 =cut
9315
9316         return sort
9317           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9318           $0;
9319     } ## end if ($line =~ /^\|*f\s+(.*)/)
9320
9321 =head3 Subroutine name completion
9322
9323 We look through all of the defined subs (the keys of C<%sub>) and
9324 return both all the possible matches to the subroutine name plus
9325 all the matches qualified to the current package.
9326
9327 =cut
9328
9329     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9330         $text = substr $text, 1;
9331         $prefix = "&";
9332         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9333           (
9334             map { /$search/ ? ($1) : () }
9335               keys %sub
9336           );
9337     } ## end if ((substr $text, 0, ...
9338
9339 =head3  Scalar, array, and hash completion: partially qualified package
9340
9341 Much like the above, except we have to do a little more cleanup:
9342
9343 =cut
9344
9345     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9346
9347 =pod
9348
9349 =over 4
9350
9351 =item *
9352
9353 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9354
9355 =cut
9356
9357         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9358
9359 =pod
9360
9361 =item *
9362
9363 Figure out the prefix vs. what needs completing.
9364
9365 =cut
9366
9367         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9368         $text   = $2;
9369
9370 =pod
9371
9372 =item *
9373
9374 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9375
9376 =cut
9377
9378         my @out = do {
9379             no strict 'refs';
9380             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9381             keys %$pack;
9382         };
9383
9384 =pod
9385
9386 =item *
9387
9388 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9389
9390 =cut
9391
9392         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9393             return db_complete( $out[0], $line, $start );
9394         }
9395
9396         # Return the list of possibles.
9397         return sort @out;
9398
9399     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9400
9401 =pod
9402
9403 =back
9404
9405 =head3 Symbol completion: current package or package C<main>.
9406
9407 =cut
9408
9409     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9410 =pod
9411
9412 =over 4
9413
9414 =item *
9415
9416 If it's C<main>, delete main to just get C<::> leading.
9417
9418 =cut
9419
9420         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9421
9422 =pod
9423
9424 =item *
9425
9426 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9427
9428 =cut
9429
9430         $prefix = substr $text, 0, 1;
9431         $text   = substr $text, 1;
9432
9433         my @out;
9434
9435 =pod
9436
9437 =item *
9438
9439 We look for the lexical scope above DB::DB and auto-complete lexical variables
9440 if PadWalker could be loaded.
9441
9442 =cut
9443
9444         if (not $text =~ /::/ and eval { require PadWalker } ) {
9445             my $level = 1;
9446             while (1) {
9447                 my @info = caller($level);
9448                 $level++;
9449                 $level = -1, last
9450                   if not @info;
9451                 last if $info[3] eq 'DB::DB';
9452             }
9453             if ($level > 0) {
9454                 my $lexicals = PadWalker::peek_my($level);
9455                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9456             }
9457         }
9458
9459 =pod
9460
9461 =item *
9462
9463 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9464
9465 =cut
9466
9467         push @out, map "$prefix$_", grep /^\Q$text/,
9468           ( grep /^_?[a-zA-Z]/, do { no strict 'refs'; keys %$pack } ),
9469           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9470
9471 =item *
9472
9473 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9474
9475 =back
9476
9477 =cut
9478
9479         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9480             return db_complete( $out[0], $line, $start );
9481         }
9482
9483         # Return the list of possibles.
9484         return sort @out;
9485     } ## end if ($text =~ /^[\$@%]/)
9486
9487 =head3 Options
9488
9489 We use C<option_val()> to look up the current value of the option. If there's
9490 only a single value, we complete the command in such a way that it is a
9491 complete command for setting the option in question. If there are multiple
9492 possible values, we generate a command consisting of the option plus a trailing
9493 question mark, which, if executed, will list the current value of the option.
9494
9495 =cut
9496
9497     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9498     {    # Options after space
9499            # We look for the text to be matched in the list of possible options,
9500            # and fetch the current value.
9501         my @out = grep /^\Q$text/, @options;
9502         my $val = option_val( $out[0], undef );
9503
9504         # Set up a 'query option's value' command.
9505         my $out = '? ';
9506         if ( not defined $val or $val =~ /[\n\r]/ ) {
9507
9508             # There's really nothing else we can do.
9509         }
9510
9511         # We have a value. Create a proper option-setting command.
9512         elsif ( $val =~ /\s/ ) {
9513
9514             # XXX This may be an extraneous variable.
9515             my $found;
9516
9517             # We'll want to quote the string (because of the embedded
9518             # whtespace), but we want to make sure we don't end up with
9519             # mismatched quote characters. We try several possibilities.
9520             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9521
9522                 # If we didn't find this quote character in the value,
9523                 # quote it using this quote character.
9524                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9525             }
9526         } ## end elsif ($val =~ /\s/)
9527
9528         # Don't need any quotes.
9529         else {
9530             $out = "=$val ";
9531         }
9532
9533         # If there were multiple possible values, return '? ', which
9534         # makes the command into a query command. If there was just one,
9535         # have readline append that.
9536         $rl_attribs->{completer_terminator_character} =
9537           ( @out == 1 ? $out : '? ' );
9538
9539         # Return list of possibilities.
9540         return sort @out;
9541     } ## end if ((substr $line, 0, ...
9542
9543 =head3 Filename completion
9544
9545 For entering filenames. We simply call C<readline>'s C<filename_list()>
9546 method with the completion text to get the possible completions.
9547
9548 =cut
9549
9550     return $term->filename_list($text);    # filenames
9551
9552 } ## end sub db_complete
9553
9554 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9555
9556 Functions that possibly ought to be somewhere else.
9557
9558 =head2 end_report
9559
9560 Say we're done.
9561
9562 =cut
9563
9564 sub end_report {
9565     local $\ = '';
9566     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9567 }
9568
9569 =head2 clean_ENV
9570
9571 If we have $ini_pids, save it in the environment; else remove it from the
9572 environment. Used by the C<R> (restart) command.
9573
9574 =cut
9575
9576 sub clean_ENV {
9577     if ( defined($ini_pids) ) {
9578         $ENV{PERLDB_PIDS} = $ini_pids;
9579     }
9580     else {
9581         delete( $ENV{PERLDB_PIDS} );
9582     }
9583 } ## end sub clean_ENV
9584
9585 # PERLDBf_... flag names from perl.h
9586 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9587
9588 BEGIN {
9589     %DollarCaretP_flags = (
9590         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9591         PERLDBf_LINE      => 0x02,     # Keep line #
9592         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9593         PERLDBf_INTER     => 0x08,     # Preserve more data
9594         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9595         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9596         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9597         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9598         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9599         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9600         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9601         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9602     );
9603     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9604     # doesn't need to set it. It's provided for the benefit of profilers and
9605     # other code analysers.
9606
9607     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9608 }
9609
9610 sub parse_DollarCaretP_flags {
9611     my $flags = shift;
9612     $flags =~ s/^\s+//;
9613     $flags =~ s/\s+$//;
9614     my $acu = 0;
9615     foreach my $f ( split /\s*\|\s*/, $flags ) {
9616         my $value;
9617         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9618             $value = hex $1;
9619         }
9620         elsif ( $f =~ /^(\d+)$/ ) {
9621             $value = int $1;
9622         }
9623         elsif ( $f =~ /^DEFAULT$/i ) {
9624             $value = $DollarCaretP_flags{PERLDB_ALL};
9625         }
9626         else {
9627             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9628             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9629             unless ( defined $value ) {
9630                 print $OUT (
9631                     "Unrecognized \$^P flag '$f'!\n",
9632                     "Acceptable flags are: "
9633                       . join( ', ', sort keys %DollarCaretP_flags ),
9634                     ", and hexadecimal and decimal numbers.\n"
9635                 );
9636                 return undef;
9637             }
9638         }
9639         $acu |= $value;
9640     }
9641     $acu;
9642 }
9643
9644 sub expand_DollarCaretP_flags {
9645     my $DollarCaretP = shift;
9646     my @bits         = (
9647         map {
9648             my $n = ( 1 << $_ );
9649             ( $DollarCaretP & $n )
9650               ? ( $DollarCaretP_flags_r{$n}
9651                   || sprintf( '0x%x', $n ) )
9652               : ()
9653           } 0 .. 31
9654     );
9655     return @bits ? join( '|', @bits ) : 0;
9656 }
9657
9658 =over 4
9659
9660 =item rerun
9661
9662 Rerun the current session to:
9663
9664     rerun        current position
9665
9666     rerun 4      command number 4
9667
9668     rerun -4     current command minus 4 (go back 4 steps)
9669
9670 Whether this always makes sense, in the current context is unknowable, and is
9671 in part left as a useful exercise for the reader.  This sub returns the
9672 appropriate arguments to rerun the current session.
9673
9674 =cut
9675
9676 sub rerun {
9677     my $i = shift;
9678     my @args;
9679     pop(@truehist);                      # strim
9680     unless (defined $truehist[$i]) {
9681         print "Unable to return to non-existent command: $i\n";
9682     } else {
9683         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9684         my @temp = @truehist;            # store
9685         push(@DB::typeahead, @truehist); # saved
9686         @truehist = @hist = ();          # flush
9687         @args = restart();              # setup
9688         get_list("PERLDB_HIST");        # clean
9689         set_list("PERLDB_HIST", @temp); # reset
9690     }
9691     return @args;
9692 }
9693
9694 =item restart
9695
9696 Restarting the debugger is a complex operation that occurs in several phases.
9697 First, we try to reconstruct the command line that was used to invoke Perl
9698 and the debugger.
9699
9700 =cut
9701
9702 sub restart {
9703     # I may not be able to resurrect you, but here goes ...
9704     print $OUT
9705 "Warning: some settings and command-line options may be lost!\n";
9706     my ( @script, @flags, $cl );
9707
9708     # If warn was on before, turn it on again.
9709     push @flags, '-w' if $ini_warn;
9710
9711     # Rebuild the -I flags that were on the initial
9712     # command line.
9713     for (@ini_INC) {
9714         push @flags, '-I', $_;
9715     }
9716
9717     # Turn on taint if it was on before.
9718     push @flags, '-T' if ${^TAINT};
9719
9720     # Arrange for setting the old INC:
9721     # Save the current @init_INC in the environment.
9722     set_list( "PERLDB_INC", @ini_INC );
9723
9724     # If this was a perl one-liner, go to the "file"
9725     # corresponding to the one-liner read all the lines
9726     # out of it (except for the first one, which is going
9727     # to be added back on again when 'perl -d' runs: that's
9728     # the 'require perl5db.pl;' line), and add them back on
9729     # to the command line to be executed.
9730     if ( $0 eq '-e' ) {
9731         my $lines = *{$main::{'_<-e'}}{ARRAY};
9732         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9733             chomp( $cl = $lines->[$_] );
9734             push @script, '-e', $cl;
9735         }
9736     } ## end if ($0 eq '-e')
9737
9738     # Otherwise we just reuse the original name we had
9739     # before.
9740     else {
9741         @script = $0;
9742     }
9743
9744 =pod
9745
9746 After the command line  has been reconstructed, the next step is to save
9747 the debugger's status in environment variables. The C<DB::set_list> routine
9748 is used to save aggregate variables (both hashes and arrays); scalars are
9749 just popped into environment variables directly.
9750
9751 =cut
9752
9753     # If the terminal supported history, grab it and
9754     # save that in the environment.
9755     set_list( "PERLDB_HIST",
9756           $term->Features->{getHistory}
9757         ? $term->GetHistory
9758         : @hist );
9759
9760     # Find all the files that were visited during this
9761     # session (i.e., the debugger had magic hashes
9762     # corresponding to them) and stick them in the environment.
9763     my @had_breakpoints = keys %had_breakpoints;
9764     set_list( "PERLDB_VISITED", @had_breakpoints );
9765
9766     # Save the debugger options we chose.
9767     set_list( "PERLDB_OPT", %option );
9768     # set_list( "PERLDB_OPT", options2remember() );
9769
9770     # Save the break-on-loads.
9771     set_list( "PERLDB_ON_LOAD", %break_on_load );
9772
9773 =pod
9774
9775 The most complex part of this is the saving of all of the breakpoints. They
9776 can live in an awful lot of places, and we have to go through all of them,
9777 find the breakpoints, and then save them in the appropriate environment
9778 variable via C<DB::set_list>.
9779
9780 =cut
9781
9782     # Go through all the breakpoints and make sure they're
9783     # still valid.
9784     my @hard;
9785     for ( 0 .. $#had_breakpoints ) {
9786
9787         # We were in this file.
9788         my $file = $had_breakpoints[$_];
9789
9790         # Grab that file's magic line hash.
9791         *dbline = $main::{ '_<' . $file };
9792
9793         # Skip out if it doesn't exist, or if the breakpoint
9794         # is in a postponed file (we'll do postponed ones
9795         # later).
9796         next unless %dbline or $postponed_file{$file};
9797
9798         # In an eval. This is a little harder, so we'll
9799         # do more processing on that below.
9800         ( push @hard, $file ), next
9801           if $file =~ /^\(\w*eval/;
9802
9803         # XXX I have no idea what this is doing. Yet.
9804         my @add;
9805         @add = %{ $postponed_file{$file} }
9806           if $postponed_file{$file};
9807
9808         # Save the list of all the breakpoints for this file.
9809         set_list( "PERLDB_FILE_$_", %dbline, @add );
9810
9811         # Serialize the extra data %breakpoints_data hash.
9812         # That's a bug fix.
9813         set_list( "PERLDB_FILE_ENABLED_$_",
9814             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9815             sort { $a <=> $b } keys(%dbline)
9816         )
9817     } ## end for (0 .. $#had_breakpoints)
9818
9819     # The breakpoint was inside an eval. This is a little
9820     # more difficult. XXX and I don't understand it.
9821     foreach my $hard_file (@hard) {
9822         # Get over to the eval in question.
9823         *dbline = $main::{ '_<' . $hard_file };
9824         my $quoted = quotemeta $hard_file;
9825         my %subs;
9826         for my $sub ( keys %sub ) {
9827             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9828                 $subs{$sub} = [ $n1, $n2 ];
9829             }
9830         }
9831         unless (%subs) {
9832             print {$OUT}
9833             "No subroutines in $hard_file, ignoring breakpoints.\n";
9834             next;
9835         }
9836         LINES: foreach my $line ( keys %dbline ) {
9837
9838             # One breakpoint per sub only:
9839             my ( $offset, $found );
9840             SUBS: foreach my $sub ( keys %subs ) {
9841                 if (
9842                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9843                     and (
9844                         not defined $offset    # Not caught
9845                             or $offset < 0
9846                     )
9847                 )
9848                 {                              # or badly caught
9849                     $found  = $sub;
9850                     $offset = $line - $subs{$sub}->[0];
9851                     if ($offset >= 0) {
9852                         $offset = "+$offset";
9853                         last SUBS;
9854                     }
9855                 } ## end if ($subs{$sub}->[1] >=...
9856             } ## end for $sub (keys %subs)
9857             if ( defined $offset ) {
9858                 $postponed{$found} =
9859                 "break $offset if $dbline{$line}";
9860             }
9861             else {
9862                 print {$OUT}
9863                 ("Breakpoint in ${hard_file}:$line ignored:"
9864                 . " after all the subroutines.\n");
9865             }
9866         } ## end for $line (keys %dbline)
9867     } ## end for (@hard)
9868
9869     # Save the other things that don't need to be
9870     # processed.
9871     set_list( "PERLDB_POSTPONE",  %postponed );
9872     set_list( "PERLDB_PRETYPE",   @$pretype );
9873     set_list( "PERLDB_PRE",       @$pre );
9874     set_list( "PERLDB_POST",      @$post );
9875     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9876
9877     # We are officially restarting.
9878     $ENV{PERLDB_RESTART} = 1;
9879
9880     # We are junking all child debuggers.
9881     delete $ENV{PERLDB_PIDS};    # Restore ini state
9882
9883     # Set this back to the initial pid.
9884     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9885
9886 =pod
9887
9888 After all the debugger status has been saved, we take the command we built up
9889 and then return it, so we can C<exec()> it. The debugger will spot the
9890 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9891 from the environment.
9892
9893 =cut
9894
9895     # And run Perl again. Add the "-d" flag, all the
9896     # flags we built up, the script (whether a one-liner
9897     # or a file), add on the -emacs flag for a slave editor,
9898     # and then the old arguments.
9899
9900     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9901
9902 };  # end restart
9903
9904 =back
9905
9906 =head1 END PROCESSING - THE C<END> BLOCK
9907
9908 Come here at the very end of processing. We want to go into a
9909 loop where we allow the user to enter commands and interact with the
9910 debugger, but we don't want anything else to execute.
9911
9912 First we set the C<$finished> variable, so that some commands that
9913 shouldn't be run after the end of program quit working.
9914
9915 We then figure out whether we're truly done (as in the user entered a C<q>
9916 command, or we finished execution while running nonstop). If we aren't,
9917 we set C<$single> to 1 (causing the debugger to get control again).
9918
9919 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9920 message and returns control to the debugger. Repeat.
9921
9922 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9923 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9924 break, run to completion.).
9925
9926 =cut
9927
9928 END {
9929     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9930     $fall_off_end = 1 unless $inhibit_exit;
9931
9932     # Do not stop in at_exit() and destructors on exit:
9933     if ($fall_off_end or $runnonstop) {
9934         save_hist();
9935     } else {
9936         $DB::single = 1;
9937         DB::fake::at_exit();
9938     }
9939 } ## end END
9940
9941 =head1 PRE-5.8 COMMANDS
9942
9943 Some of the commands changed function quite a bit in the 5.8 command
9944 realignment, so much so that the old code had to be replaced completely.
9945 Because we wanted to retain the option of being able to go back to the
9946 former command set, we moved the old code off to this section.
9947
9948 There's an awful lot of duplicated code here. We've duplicated the
9949 comments to keep things clear.
9950
9951 =head2 Null command
9952
9953 Does nothing. Used to I<turn off> commands.
9954
9955 =cut
9956
9957 sub cmd_pre580_null {
9958
9959     # do nothing...
9960 }
9961
9962 =head2 Old C<a> command.
9963
9964 This version added actions if you supplied them, and deleted them
9965 if you didn't.
9966
9967 =cut
9968
9969 sub cmd_pre580_a {
9970     my $xcmd = shift;
9971     my $cmd  = shift;
9972
9973     # Argument supplied. Add the action.
9974     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9975
9976         # If the line isn't there, use the current line.
9977         my $i = $1 || $line;
9978         my $j = $2;
9979
9980         # If there is an action ...
9981         if ( length $j ) {
9982
9983             # ... but the line isn't breakable, skip it.
9984             if ( $dbline[$i] == 0 ) {
9985                 print $OUT "Line $i may not have an action.\n";
9986             }
9987             else {
9988
9989                 # ... and the line is breakable:
9990                 # Mark that there's an action in this file.
9991                 $had_breakpoints{$filename} |= 2;
9992
9993                 # Delete any current action.
9994                 $dbline{$i} =~ s/\0[^\0]*//;
9995
9996                 # Add the new action, continuing the line as needed.
9997                 $dbline{$i} .= "\0" . action($j);
9998             }
9999         } ## end if (length $j)
10000
10001         # No action supplied.
10002         else {
10003
10004             # Delete the action.
10005             $dbline{$i} =~ s/\0[^\0]*//;
10006
10007             # Mark as having no break or action if nothing's left.
10008             delete $dbline{$i} if $dbline{$i} eq '';
10009         }
10010     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
10011 } ## end sub cmd_pre580_a
10012
10013 =head2 Old C<b> command
10014
10015 Add breakpoints.
10016
10017 =cut
10018
10019 sub cmd_pre580_b {
10020     my $xcmd   = shift;
10021     my $cmd    = shift;
10022     my $dbline = shift;
10023
10024     # Break on load.
10025     if ( $cmd =~ /^load\b\s*(.*)/ ) {
10026         my $file = $1;
10027         $file =~ s/\s+$//;
10028         cmd_b_load($file);
10029     }
10030
10031     # b compile|postpone <some sub> [<condition>]
10032     # The interpreter actually traps this one for us; we just put the
10033     # necessary condition in the %postponed hash.
10034     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
10035
10036         # Capture the condition if there is one. Make it true if none.
10037         my $cond = length $3 ? $3 : '1';
10038
10039         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
10040         # if it was 'compile'.
10041         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
10042
10043         # De-Perl4-ify the name - ' separators to ::.
10044         $subname =~ s/\'/::/g;
10045
10046         # Qualify it into the current package unless it's already qualified.
10047         $subname = "${package}::" . $subname
10048           unless $subname =~ /::/;
10049
10050         # Add main if it starts with ::.
10051         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
10052
10053         # Save the break type for this sub.
10054         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
10055     } ## end elsif ($cmd =~ ...
10056
10057     # b <sub name> [<condition>]
10058     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
10059         my $subname = $1;
10060         my $cond = length $2 ? $2 : '1';
10061         cmd_b_sub( $subname, $cond );
10062     }
10063     # b <line> [<condition>].
10064     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
10065         my $i = $1 || $dbline;
10066         my $cond = length $2 ? $2 : '1';
10067         cmd_b_line( $i, $cond );
10068     }
10069 } ## end sub cmd_pre580_b
10070
10071 =head2 Old C<D> command.
10072
10073 Delete all breakpoints unconditionally.
10074
10075 =cut
10076
10077 sub cmd_pre580_D {
10078     my $xcmd = shift;
10079     my $cmd  = shift;
10080     if ( $cmd =~ /^\s*$/ ) {
10081         print $OUT "Deleting all breakpoints...\n";
10082
10083         # %had_breakpoints lists every file that had at least one
10084         # breakpoint in it.
10085         my $file;
10086         for $file ( keys %had_breakpoints ) {
10087
10088             # Switch to the desired file temporarily.
10089             local *dbline = $main::{ '_<' . $file };
10090
10091             $max = $#dbline;
10092             my $was;
10093
10094             # For all lines in this file ...
10095             for my $i (1 .. $max) {
10096
10097                 # If there's a breakpoint or action on this line ...
10098                 if ( defined $dbline{$i} ) {
10099
10100                     # ... remove the breakpoint.
10101                     $dbline{$i} =~ s/^[^\0]+//;
10102                     if ( $dbline{$i} =~ s/^\0?$// ) {
10103
10104                         # Remove the entry altogether if no action is there.
10105                         delete $dbline{$i};
10106                     }
10107                 } ## end if (defined $dbline{$i...
10108             } ## end for my $i (1 .. $max)
10109
10110             # If, after we turn off the "there were breakpoints in this file"
10111             # bit, the entry in %had_breakpoints for this file is zero,
10112             # we should remove this file from the hash.
10113             if ( not $had_breakpoints{$file} &= ~1 ) {
10114                 delete $had_breakpoints{$file};
10115             }
10116         } ## end for $file (keys %had_breakpoints)
10117
10118         # Kill off all the other breakpoints that are waiting for files that
10119         # haven't been loaded yet.
10120         undef %postponed;
10121         undef %postponed_file;
10122         undef %break_on_load;
10123     } ## end if ($cmd =~ /^\s*$/)
10124 } ## end sub cmd_pre580_D
10125
10126 =head2 Old C<h> command
10127
10128 Print help. Defaults to printing the long-form help; the 5.8 version
10129 prints the summary by default.
10130
10131 =cut
10132
10133 sub cmd_pre580_h {
10134     my $xcmd = shift;
10135     my $cmd  = shift;
10136
10137     # Print the *right* help, long format.
10138     if ( $cmd =~ /^\s*$/ ) {
10139         print_help($pre580_help);
10140     }
10141
10142     # 'h h' - explicitly-requested summary.
10143     elsif ( $cmd =~ /^h\s*/ ) {
10144         print_help($pre580_summary);
10145     }
10146
10147     # Find and print a command's help.
10148     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10149         my $asked  = $1;                   # for proper errmsg
10150         my $qasked = quotemeta($asked);    # for searching
10151                                            # XXX: finds CR but not <CR>
10152         if (
10153             $pre580_help =~ /^
10154                               <?           # Optional '<'
10155                               (?:[IB]<)    # Optional markup
10156                               $qasked      # The command name
10157                             /mx
10158           )
10159         {
10160
10161             while (
10162                 $pre580_help =~ /^
10163                                   (             # The command help:
10164                                    <?           # Optional '<'
10165                                    (?:[IB]<)    # Optional markup
10166                                    $qasked      # The command name
10167                                    ([\s\S]*?)   # Lines starting with tabs
10168                                    \n           # Final newline
10169                                   )
10170                                   (?!\s)/mgx
10171               )    # Line not starting with space
10172                    # (Next command's help)
10173             {
10174                 print_help($1);
10175             }
10176         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10177
10178         # Help not found.
10179         else {
10180             print_help("B<$asked> is not a debugger command.\n");
10181         }
10182     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10183 } ## end sub cmd_pre580_h
10184
10185 =head2 Old C<W> command
10186
10187 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10188
10189 =cut
10190
10191 sub cmd_pre580_W {
10192     my $xcmd = shift;
10193     my $cmd  = shift;
10194
10195     # Delete all watch expressions.
10196     if ( $cmd =~ /^$/ ) {
10197
10198         # No watching is going on.
10199         $trace &= ~2;
10200
10201         # Kill all the watch expressions and values.
10202         @to_watch = @old_watch = ();
10203     }
10204
10205     # Add a watch expression.
10206     elsif ( $cmd =~ /^(.*)/s ) {
10207
10208         # add it to the list to be watched.
10209         push @to_watch, $1;
10210
10211         # Get the current value of the expression.
10212         # Doesn't handle expressions returning list values!
10213         $evalarg = $1;
10214         # The &-call is here to ascertain the mutability of @_.
10215         my ($val) = &DB::eval;
10216         $val = ( defined $val ) ? "'$val'" : 'undef';
10217
10218         # Save it.
10219         push @old_watch, $val;
10220
10221         # We're watching stuff.
10222         $trace |= 2;
10223
10224     } ## end elsif ($cmd =~ /^(.*)/s)
10225 } ## end sub cmd_pre580_W
10226
10227 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10228
10229 The debugger used to have a bunch of nearly-identical code to handle
10230 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10231 C<cmd_prepost> unify all this into one set of code to handle the
10232 appropriate actions.
10233
10234 =head2 C<cmd_pre590_prepost>
10235
10236 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10237 do something destructive. In pre 5.8 debuggers, the default action was to
10238 delete all the actions.
10239
10240 =cut
10241
10242 sub cmd_pre590_prepost {
10243     my $cmd    = shift;
10244     my $line   = shift || '*';
10245     my $dbline = shift;
10246
10247     return cmd_prepost( $cmd, $line, $dbline );
10248 } ## end sub cmd_pre590_prepost
10249
10250 =head2 C<cmd_prepost>
10251
10252 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10253 Since the lists of actions are all held in arrays that are pointed to by
10254 references anyway, all we have to do is pick the right array reference and
10255 then use generic code to all, delete, or list actions.
10256
10257 =cut
10258
10259 sub cmd_prepost {
10260     my $cmd = shift;
10261
10262     # No action supplied defaults to 'list'.
10263     my $line = shift || '?';
10264
10265     # Figure out what to put in the prompt.
10266     my $which = '';
10267
10268     # Make sure we have some array or another to address later.
10269     # This means that if for some reason the tests fail, we won't be
10270     # trying to stash actions or delete them from the wrong place.
10271     my $aref = [];
10272
10273     # < - Perl code to run before prompt.
10274     if ( $cmd =~ /^\</o ) {
10275         $which = 'pre-perl';
10276         $aref  = $pre;
10277     }
10278
10279     # > - Perl code to run after prompt.
10280     elsif ( $cmd =~ /^\>/o ) {
10281         $which = 'post-perl';
10282         $aref  = $post;
10283     }
10284
10285     # { - first check for properly-balanced braces.
10286     elsif ( $cmd =~ /^\{/o ) {
10287         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10288             print $OUT
10289 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10290         }
10291
10292         # Properly balanced. Pre-prompt debugger actions.
10293         else {
10294             $which = 'pre-debugger';
10295             $aref  = $pretype;
10296         }
10297     } ## end elsif ( $cmd =~ /^\{/o )
10298
10299     # Did we find something that makes sense?
10300     unless ($which) {
10301         print $OUT "Confused by command: $cmd\n";
10302     }
10303
10304     # Yes.
10305     else {
10306
10307         # List actions.
10308         if ( $line =~ /^\s*\?\s*$/o ) {
10309             unless (@$aref) {
10310
10311                 # Nothing there. Complain.
10312                 print $OUT "No $which actions.\n";
10313             }
10314             else {
10315
10316                 # List the actions in the selected list.
10317                 print $OUT "$which commands:\n";
10318                 foreach my $action (@$aref) {
10319                     print $OUT "\t$cmd -- $action\n";
10320                 }
10321             } ## end else
10322         } ## end if ( $line =~ /^\s*\?\s*$/o)
10323
10324         # Might be a delete.
10325         else {
10326             if ( length($cmd) == 1 ) {
10327                 if ( $line =~ /^\s*\*\s*$/o ) {
10328
10329                     # It's a delete. Get rid of the old actions in the
10330                     # selected list..
10331                     @$aref = ();
10332                     print $OUT "All $cmd actions cleared.\n";
10333                 }
10334                 else {
10335
10336                     # Replace all the actions. (This is a <, >, or {).
10337                     @$aref = action($line);
10338                 }
10339             } ## end if ( length($cmd) == 1)
10340             elsif ( length($cmd) == 2 ) {
10341
10342                 # Add the action to the line. (This is a <<, >>, or {{).
10343                 push @$aref, action($line);
10344             }
10345             else {
10346
10347                 # <<<, >>>>, {{{{{{ ... something not a command.
10348                 print $OUT
10349                   "Confused by strange length of $which command($cmd)...\n";
10350             }
10351         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10352     } ## end else
10353 } ## end sub cmd_prepost
10354
10355 =head1 C<DB::fake>
10356
10357 Contains the C<at_exit> routine that the debugger uses to issue the
10358 C<Debugged program terminated ...> message after the program completes. See
10359 the C<END> block documentation for more details.
10360
10361 =cut
10362
10363 package DB::fake;
10364
10365 sub at_exit {
10366     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10367 }
10368
10369 package DB;    # Do not trace this 1; below!
10370
10371 1;
10372
10373