cpan/Encode/Encode.pm

   1 #
   2 # $Id: Encode.pm,v 2.75 2015/06/30 09:57:15 dankogai Exp $
   3 #
   4 package Encode;
   5 use strict;
   6 use warnings;
   7 our $VERSION = sprintf "%d.%02d", q$Revision: 2.75 $ =~ /(\d+)/g;
   8 use constant DEBUG => !!$ENV{PERL_ENCODE_DEBUG};
   9 use XSLoader ();
  10 XSLoader::load( __PACKAGE__, $VERSION );
  11
  12 use Exporter 5.57 'import';
  13
  14 # Public, encouraged API is exported by default
  15
  16 our @EXPORT = qw(
  17   decode  decode_utf8  encode  encode_utf8 str2bytes bytes2str
  18   encodings  find_encoding clone_encoding
  19 );
  20 our @FB_FLAGS = qw(
  21   DIE_ON_ERR WARN_ON_ERR RETURN_ON_ERR LEAVE_SRC
  22   PERLQQ HTMLCREF XMLCREF STOP_AT_PARTIAL
  23 );
  24 our @FB_CONSTS = qw(
  25   FB_DEFAULT FB_CROAK FB_QUIET FB_WARN
  26   FB_PERLQQ FB_HTMLCREF FB_XMLCREF
  27 );
  28 our @EXPORT_OK = (
  29     qw(
  30       _utf8_off _utf8_on define_encoding from_to is_16bit is_8bit
  31       is_utf8 perlio_ok resolve_alias utf8_downgrade utf8_upgrade
  32       ),
  33     @FB_FLAGS, @FB_CONSTS,
  34 );
  35
  36 our %EXPORT_TAGS = (
  37     all          => [ @EXPORT,    @EXPORT_OK ],
  38     default      => [ @EXPORT ],
  39     fallbacks    => [ @FB_CONSTS ],
  40     fallback_all => [ @FB_CONSTS, @FB_FLAGS ],
  41 );
  42
  43 # Documentation moved after __END__ for speed - NI-S
  44
  45 our $ON_EBCDIC = ( ord("A") == 193 );
  46
  47 use Encode::Alias;
  48
  49 # Make a %Encoding package variable to allow a certain amount of cheating
  50 our %Encoding;
  51 our %ExtModule;
  52 require Encode::Config;
  53 #  See
  54 #  https://bugzilla.redhat.com/show_bug.cgi?id=435505#c2
  55 #  to find why sig handlers inside eval{} are disabled.
  56 eval {
  57     local $SIG{__DIE__};
  58     local $SIG{__WARN__};
  59     require Encode::ConfigLocal;
  60 };
  61
  62 sub encodings {
  63     my %enc;
  64     my $arg  = $_[1] || '';
  65     if ( $arg eq ":all" ) {
  66         %enc = ( %Encoding, %ExtModule );
  67     }
  68     else {
  69         %enc = %Encoding;
  70         for my $mod ( map { m/::/ ? $_ : "Encode::$_" } @_ ) {
  71             DEBUG and warn $mod;
  72             for my $enc ( keys %ExtModule ) {
  73                 $ExtModule{$enc} eq $mod and $enc{$enc} = $mod;
  74             }
  75         }
  76     }
  77     return sort { lc $a cmp lc $b }
  78       grep      { !/^(?:Internal|Unicode|Guess)$/o } keys %enc;
  79 }
  80
  81 sub perlio_ok {
  82     my $obj = ref( $_[0] ) ? $_[0] : find_encoding( $_[0] );
  83     $obj->can("perlio_ok") and return $obj->perlio_ok();
  84     return 0;    # safety net
  85 }
  86
  87 sub define_encoding {
  88     my $obj  = shift;
  89     my $name = shift;
  90     $Encoding{$name} = $obj;
  91     my $lc = lc($name);
  92     define_alias( $lc => $obj ) unless $lc eq $name;
  93     while (@_) {
  94         my $alias = shift;
  95         define_alias( $alias, $obj );
  96     }
  97     return $obj;
  98 }
  99
 100 sub getEncoding {
 101     my ( $class, $name, $skip_external ) = @_;
 102
 103     $name =~ s/\s+//g; # https://rt.cpan.org/Ticket/Display.html?id=65796
 104
 105     ref($name) && $name->can('renew') and return $name;
 106     exists $Encoding{$name} and return $Encoding{$name};
 107     my $lc = lc $name;
 108     exists $Encoding{$lc} and return $Encoding{$lc};
 109
 110     my $oc = $class->find_alias($name);
 111     defined($oc) and return $oc;
 112     $lc ne $name and $oc = $class->find_alias($lc);
 113     defined($oc) and return $oc;
 114
 115     unless ($skip_external) {
 116         if ( my $mod = $ExtModule{$name} || $ExtModule{$lc} ) {
 117             $mod =~ s,::,/,g;
 118             $mod .= '.pm';
 119             eval { require $mod; };
 120             exists $Encoding{$name} and return $Encoding{$name};
 121         }
 122     }
 123     return;
 124 }
 125
 126 sub find_encoding($;$) {
 127     my ( $name, $skip_external ) = @_;
 128     return __PACKAGE__->getEncoding( $name, $skip_external );
 129 }
 130
 131 sub resolve_alias($) {
 132     my $obj = find_encoding(shift);
 133     defined $obj and return $obj->name;
 134     return;
 135 }
 136
 137 sub clone_encoding($) {
 138     my $obj = find_encoding(shift);
 139     ref $obj or return;
 140     eval { require Storable };
 141     $@ and return;
 142     return Storable::dclone($obj);
 143 }
 144
 145 sub encode($$;$) {
 146     my ( $name, $string, $check ) = @_;
 147     return undef unless defined $string;
 148     $string .= '';    # stringify;
 149     $check ||= 0;
 150     unless ( defined $name ) {
 151         require Carp;
 152         Carp::croak("Encoding name should not be undef");
 153     }
 154     my $enc = find_encoding($name);
 155     unless ( defined $enc ) {
 156         require Carp;
 157         Carp::croak("Unknown encoding '$name'");
 158     }
 159     # For Unicode, warnings need to be caught and re-issued at this level
 160     # so that callers can disable utf8 warnings lexically.
 161     my $octets;
 162     if ( ref($enc) eq 'Encode::Unicode' ) {
 163         my $warn = '';
 164         {
 165             local $SIG{__WARN__} = sub { $warn = shift };
 166             $octets = $enc->encode( $string, $check );
 167         }
 168         warnings::warnif('utf8', $warn) if length $warn;
 169     }
 170     else {
 171         $octets = $enc->encode( $string, $check );
 172     }
 173     $_[1] = $string if $check and !ref $check and !( $check & LEAVE_SRC() );
 174     return $octets;
 175 }
 176 *str2bytes = \&encode;
 177
 178 sub decode($$;$) {
 179     my ( $name, $octets, $check ) = @_;
 180     return undef unless defined $octets;
 181     $octets .= '';
 182     $check ||= 0;
 183     my $enc = find_encoding($name);
 184     unless ( defined $enc ) {
 185         require Carp;
 186         Carp::croak("Unknown encoding '$name'");
 187     }
 188     # For Unicode, warnings need to be caught and re-issued at this level
 189     # so that callers can disable utf8 warnings lexically.
 190     my $string;
 191     if ( ref($enc) eq 'Encode::Unicode' ) {
 192         my $warn = '';
 193         {
 194             local $SIG{__WARN__} = sub { $warn = shift };
 195             $string = $enc->decode( $octets, $check );
 196         }
 197         warnings::warnif('utf8', $warn) if length $warn;
 198     }
 199     else {
 200         $string = $enc->decode( $octets, $check );
 201     }
 202     $_[1] = $octets if $check and !ref $check and !( $check & LEAVE_SRC() );
 203     return $string;
 204 }
 205 *bytes2str = \&decode;
 206
 207 sub from_to($$$;$) {
 208     my ( $string, $from, $to, $check ) = @_;
 209     return undef unless defined $string;
 210     $check ||= 0;
 211     my $f = find_encoding($from);
 212     unless ( defined $f ) {
 213         require Carp;
 214         Carp::croak("Unknown encoding '$from'");
 215     }
 216     my $t = find_encoding($to);
 217     unless ( defined $t ) {
 218         require Carp;
 219         Carp::croak("Unknown encoding '$to'");
 220     }
 221     my $uni = $f->decode($string);
 222     $_[0] = $string = $t->encode( $uni, $check );
 223     return undef if ( $check && length($uni) );
 224     return defined( $_[0] ) ? length($string) : undef;
 225 }
 226
 227 sub encode_utf8($) {
 228     my ($str) = @_;
 229     utf8::encode($str);
 230     return $str;
 231 }
 232
 233 my $utf8enc;
 234
 235 sub decode_utf8($;$) {
 236     my ( $octets, $check ) = @_;
 237     return undef unless defined $octets;
 238     $octets .= '';
 239     $check   ||= 0;
 240     $utf8enc ||= find_encoding('utf8');
 241     my $string = $utf8enc->decode( $octets, $check );
 242     $_[0] = $octets if $check and !ref $check and !( $check & LEAVE_SRC() );
 243     return $string;
 244 }
 245
 246 # sub decode_utf8($;$) {
 247 #     my ( $str, $check ) = @_;
 248 #     return $str if is_utf8($str);
 249 #     if ($check) {
 250 #         return decode( "utf8", $str, $check );
 251 #     }
 252 #     else {
 253 #         return decode( "utf8", $str );
 254 #         return $str;
 255 #     }
 256 # }
 257
 258 predefine_encodings(1);
 259
 260 #
 261 # This is to restore %Encoding if really needed;
 262 #
 263
 264 sub predefine_encodings {
 265     require Encode::Encoding;
 266     no warnings 'redefine';
 267     my $use_xs = shift;
 268     if ($ON_EBCDIC) {
 269
 270         # was in Encode::UTF_EBCDIC
 271         package Encode::UTF_EBCDIC;
 272         push @Encode::UTF_EBCDIC::ISA, 'Encode::Encoding';
 273         *decode = sub {
 274             my ( undef, $str, $chk ) = @_;
 275             my $res = '';
 276             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 277                 $res .=
 278                   chr(
 279                     utf8::unicode_to_native( ord( substr( $str, $i, 1 ) ) )
 280                   );
 281             }
 282             $_[1] = '' if $chk;
 283             return $res;
 284         };
 285         *encode = sub {
 286             my ( undef, $str, $chk ) = @_;
 287             my $res = '';
 288             for ( my $i = 0 ; $i < length($str) ; $i++ ) {
 289                 $res .=
 290                   chr(
 291                     utf8::native_to_unicode( ord( substr( $str, $i, 1 ) ) )
 292                   );
 293             }
 294             $_[1] = '' if $chk;
 295             return $res;
 296         };
 297         $Encode::Encoding{Unicode} =
 298           bless { Name => "UTF_EBCDIC" } => "Encode::UTF_EBCDIC";
 299     }
 300     else {
 301
 302         package Encode::Internal;
 303         push @Encode::Internal::ISA, 'Encode::Encoding';
 304         *decode = sub {
 305             my ( undef, $str, $chk ) = @_;
 306             utf8::upgrade($str);
 307             $_[1] = '' if $chk;
 308             return $str;
 309         };
 310         *encode = \&decode;
 311         $Encode::Encoding{Unicode} =
 312           bless { Name => "Internal" } => "Encode::Internal";
 313     }
 314     {
 315         # https://rt.cpan.org/Public/Bug/Display.html?id=103253
 316         package Encode::XS;
 317         push @Encode::XS::ISA, 'Encode::Encoding';
 318     }
 319     {
 320
 321         # was in Encode::utf8
 322         package Encode::utf8;
 323         push @Encode::utf8::ISA, 'Encode::Encoding';
 324
 325         #
 326         if ($use_xs) {
 327             Encode::DEBUG and warn __PACKAGE__, " XS on";
 328             *decode = \&decode_xs;
 329             *encode = \&encode_xs;
 330         }
 331         else {
 332             Encode::DEBUG and warn __PACKAGE__, " XS off";
 333             *decode = sub {
 334                 my ( undef, $octets, $chk ) = @_;
 335                 my $str = Encode::decode_utf8($octets);
 336                 if ( defined $str ) {
 337                     $_[1] = '' if $chk;
 338                     return $str;
 339                 }
 340                 return undef;
 341             };
 342             *encode = sub {
 343                 my ( undef, $string, $chk ) = @_;
 344                 my $octets = Encode::encode_utf8($string);
 345                 $_[1] = '' if $chk;
 346                 return $octets;
 347             };
 348         }
 349         *cat_decode = sub {    # ($obj, $dst, $src, $pos, $trm, $chk)
 350                                # currently ignores $chk
 351             my ( undef, undef, undef, $pos, $trm ) = @_;
 352             my ( $rdst, $rsrc, $rpos ) = \@_[ 1, 2, 3 ];
 353             use bytes;
 354             if ( ( my $npos = index( $$rsrc, $trm, $pos ) ) >= 0 ) {
 355                 $$rdst .=
 356                   substr( $$rsrc, $pos, $npos - $pos + length($trm) );
 357                 $$rpos = $npos + length($trm);
 358                 return 1;
 359             }
 360             $$rdst .= substr( $$rsrc, $pos );
 361             $$rpos = length($$rsrc);
 362             return '';
 363         };
 364         $Encode::Encoding{utf8} =
 365           bless { Name => "utf8" } => "Encode::utf8";
 366         $Encode::Encoding{"utf-8-strict"} =
 367           bless { Name => "utf-8-strict", strict_utf8 => 1 }
 368             => "Encode::utf8";
 369     }
 370 }
 371
 372 1;
 373
 374 __END__
 375
 376 =head1 NAME
 377
 378 Encode - character encodings in Perl
 379
 380 =head1 SYNOPSIS
 381
 382     use Encode qw(decode encode);
 383     $characters = decode('UTF-8', $octets,     Encode::FB_CROAK);
 384     $octets     = encode('UTF-8', $characters, Encode::FB_CROAK);
 385
 386 =head2 Table of Contents
 387
 388 Encode consists of a collection of modules whose details are too extensive
 389 to fit in one document.  This one itself explains the top-level APIs
 390 and general topics at a glance.  For other topics and more details,
 391 see the documentation for these modules:
 392
 393 =over 2
 394
 395 =item L<Encode::Alias> - Alias definitions to encodings
 396
 397 =item L<Encode::Encoding> - Encode Implementation Base Class
 398
 399 =item L<Encode::Supported> - List of Supported Encodings
 400
 401 =item L<Encode::CN> - Simplified Chinese Encodings
 402
 403 =item L<Encode::JP> - Japanese Encodings
 404
 405 =item L<Encode::KR> - Korean Encodings
 406
 407 =item L<Encode::TW> - Traditional Chinese Encodings
 408
 409 =back
 410
 411 =head1 DESCRIPTION
 412
 413 The C<Encode> module provides the interface between Perl strings
 414 and the rest of the system.  Perl strings are sequences of
 415 I<characters>.
 416
 417 The repertoire of characters that Perl can represent is a superset of those
 418 defined by the Unicode Consortium. On most platforms the ordinal
 419 values of a character as returned by C<ord(I<S>)> is the I<Unicode
 420 codepoint> for that character. The exceptions are platforms where
 421 the legacy encoding is some variant of EBCDIC rather than a superset
 422 of ASCII; see L<perlebcdic>.
 423
 424 During recent history, data is moved around a computer in 8-bit chunks,
 425 often called "bytes" but also known as "octets" in standards documents.
 426 Perl is widely used to manipulate data of many types: not only strings of
 427 characters representing human or computer languages, but also "binary"
 428 data, being the machine's representation of numbers, pixels in an image, or
 429 just about anything.
 430
 431 When Perl is processing "binary data", the programmer wants Perl to
 432 process "sequences of bytes". This is not a problem for Perl: because a
 433 byte has 256 possible values, it easily fits in Perl's much larger
 434 "logical character".
 435
 436 This document mostly explains the I<how>. L<perlunitut> and L<perlunifaq>
 437 explain the I<why>.
 438
 439 =head2 TERMINOLOGY
 440
 441 =head3 character
 442
 443 A character in the range 0 .. 2**32-1 (or more);
 444 what Perl's strings are made of.
 445
 446 =head3 byte
 447
 448 A character in the range 0..255;
 449 a special case of a Perl character.
 450
 451 =head3 octet
 452
 453 8 bits of data, with ordinal values 0..255;
 454 term for bytes passed to or from a non-Perl context, such as a disk file,
 455 standard I/O stream, database, command-line argument, environment variable,
 456 socket etc.
 457
 458 =head1 THE PERL ENCODING API
 459
 460 =head2 Basic methods
 461
 462 =head3 encode
 463
 464   $octets  = encode(ENCODING, STRING[, CHECK])
 465
 466 Encodes the scalar value I<STRING> from Perl's internal form into
 467 I<ENCODING> and returns a sequence of octets.  I<ENCODING> can be either a
 468 canonical name or an alias.  For encoding names and aliases, see
 469 L</"Defining Aliases">.  For CHECK, see L</"Handling Malformed Data">.
 470
 471 For example, to convert a string from Perl's internal format into
 472 ISO-8859-1, also known as Latin1:
 473
 474   $octets = encode("iso-8859-1", $string);
 475
 476 B<CAVEAT>: When you run C<$octets = encode("utf8", $string)>, then
 477 $octets I<might not be equal to> $string.  Though both contain the
 478 same data, the UTF8 flag for $octets is I<always> off.  When you
 479 encode anything, the UTF8 flag on the result is always off, even when it
 480 contains a completely valid utf8 string. See L</"The UTF8 flag"> below.
 481
 482 If the $string is C<undef>, then C<undef> is returned.
 483
 484 =head3 decode
 485
 486   $string = decode(ENCODING, OCTETS[, CHECK])
 487
 488 This function returns the string that results from decoding the scalar
 489 value I<OCTETS>, assumed to be a sequence of octets in I<ENCODING>, into
 490 Perl's internal form.  As with encode(),
 491 I<ENCODING> can be either a canonical name or an alias. For encoding names
 492 and aliases, see L</"Defining Aliases">; for I<CHECK>, see L</"Handling
 493 Malformed Data">.
 494
 495 For example, to convert ISO-8859-1 data into a string in Perl's
 496 internal format:
 497
 498   $string = decode("iso-8859-1", $octets);
 499
 500 B<CAVEAT>: When you run C<$string = decode("utf8", $octets)>, then $string
 501 I<might not be equal to> $octets.  Though both contain the same data, the
 502 UTF8 flag for $string is on.  See L</"The UTF8 flag">
 503 below.
 504
 505 If the $string is C<undef>, then C<undef> is returned.
 506
 507 =head3 find_encoding
 508
 509   [$obj =] find_encoding(ENCODING)
 510
 511 Returns the I<encoding object> corresponding to I<ENCODING>.  Returns
 512 C<undef> if no matching I<ENCODING> is find.  The returned object is
 513 what does the actual encoding or decoding.
 514
 515   $utf8 = decode($name, $bytes);
 516
 517 is in fact
 518
 519     $utf8 = do {
 520         $obj = find_encoding($name);
 521         croak qq(encoding "$name" not found) unless ref $obj;
 522         $obj->decode($bytes);
 523     };
 524
 525 with more error checking.
 526
 527 You can therefore save time by reusing this object as follows;
 528
 529     my $enc = find_encoding("iso-8859-1");
 530     while(<>) {
 531         my $utf8 = $enc->decode($_);
 532         ... # now do something with $utf8;
 533     }
 534
 535 Besides L</decode> and L</encode>, other methods are
 536 available as well.  For instance, C<name()> returns the canonical
 537 name of the encoding object.
 538
 539   find_encoding("latin1")->name; # iso-8859-1
 540
 541 See L<Encode::Encoding> for details.
 542
 543 =head3 from_to
 544
 545   [$length =] from_to($octets, FROM_ENC, TO_ENC [, CHECK])
 546
 547 Converts I<in-place> data between two encodings. The data in $octets
 548 must be encoded as octets and I<not> as characters in Perl's internal
 549 format. For example, to convert ISO-8859-1 data into Microsoft's CP1250
 550 encoding:
 551
 552   from_to($octets, "iso-8859-1", "cp1250");
 553
 554 and to convert it back:
 555
 556   from_to($octets, "cp1250", "iso-8859-1");
 557
 558 Because the conversion happens in place, the data to be
 559 converted cannot be a string constant: it must be a scalar variable.
 560
 561 C<from_to()> returns the length of the converted string in octets on success,
 562 and C<undef> on error.
 563
 564 B<CAVEAT>: The following operations may look the same, but are not:
 565
 566   from_to($data, "iso-8859-1", "utf8"); #1
 567   $data = decode("iso-8859-1", $data);  #2
 568
 569 Both #1 and #2 make $data consist of a completely valid UTF-8 string,
 570 but only #2 turns the UTF8 flag on.  #1 is equivalent to:
 571
 572   $data = encode("utf8", decode("iso-8859-1", $data));
 573
 574 See L</"The UTF8 flag"> below.
 575
 576 Also note that:
 577
 578   from_to($octets, $from, $to, $check);
 579
 580 is equivalent to:
 581
 582   $octets = encode($to, decode($from, $octets), $check);
 583
 584 Yes, it does I<not> respect the $check during decoding.  It is
 585 deliberately done that way.  If you need minute control, use C<decode>
 586 followed by C<encode> as follows:
 587
 588   $octets = encode($to, decode($from, $octets, $check_from), $check_to);
 589
 590 =head3 encode_utf8
 591
 592   $octets = encode_utf8($string);
 593
 594 Equivalent to C<$octets = encode("utf8", $string)>.  The characters in
 595 $string are encoded in Perl's internal format, and the result is returned
 596 as a sequence of octets.  Because all possible characters in Perl have a
 597 (loose, not strict) UTF-8 representation, this function cannot fail.
 598
 599 =head3 decode_utf8
 600
 601   $string = decode_utf8($octets [, CHECK]);
 602
 603 Equivalent to C<$string = decode("utf8", $octets [, CHECK])>.
 604 The sequence of octets represented by $octets is decoded
 605 from UTF-8 into a sequence of logical characters.
 606 Because not all sequences of octets are valid UTF-8,
 607 it is quite possible for this function to fail.
 608 For CHECK, see L</"Handling Malformed Data">.
 609
 610 =head2 Listing available encodings
 611
 612   use Encode;
 613   @list = Encode->encodings();
 614
 615 Returns a list of canonical names of available encodings that have already
 616 been loaded.  To get a list of all available encodings including those that
 617 have not yet been loaded, say:
 618
 619   @all_encodings = Encode->encodings(":all");
 620
 621 Or you can give the name of a specific module:
 622
 623   @with_jp = Encode->encodings("Encode::JP");
 624
 625 When "C<::>" is not in the name, "C<Encode::>" is assumed.
 626
 627   @ebcdic = Encode->encodings("EBCDIC");
 628
 629 To find out in detail which encodings are supported by this package,
 630 see L<Encode::Supported>.
 631
 632 =head2 Defining Aliases
 633
 634 To add a new alias to a given encoding, use:
 635
 636   use Encode;
 637   use Encode::Alias;
 638   define_alias(NEWNAME => ENCODING);
 639
 640 After that, I<NEWNAME> can be used as an alias for I<ENCODING>.
 641 I<ENCODING> may be either the name of an encoding or an
 642 I<encoding object>.
 643
 644 Before you do that, first make sure the alias is nonexistent using
 645 C<resolve_alias()>, which returns the canonical name thereof.
 646 For example:
 647
 648   Encode::resolve_alias("latin1") eq "iso-8859-1" # true
 649   Encode::resolve_alias("iso-8859-12")   # false; nonexistent
 650   Encode::resolve_alias($name) eq $name  # true if $name is canonical
 651
 652 C<resolve_alias()> does not need C<use Encode::Alias>; it can be
 653 imported via C<use Encode qw(resolve_alias)>.
 654
 655 See L<Encode::Alias> for details.
 656
 657 =head2 Finding IANA Character Set Registry names
 658
 659 The canonical name of a given encoding does not necessarily agree with
 660 IANA Character Set Registry, commonly seen as C<< Content-Type:
 661 text/plain; charset=I<WHATEVER> >>.  For most cases, the canonical name
 662 works, but sometimes it does not, most notably with "utf-8-strict".
 663
 664 As of C<Encode> version 2.21, a new method C<mime_name()> is therefore added.
 665
 666   use Encode;
 667   my $enc = find_encoding("UTF-8");
 668   warn $enc->name;      # utf-8-strict
 669   warn $enc->mime_name; # UTF-8
 670
 671 See also:  L<Encode::Encoding>
 672
 673 =head1 Encoding via PerlIO
 674
 675 If your perl supports C<PerlIO> (which is the default), you can use a
 676 C<PerlIO> layer to decode and encode directly via a filehandle.  The
 677 following two examples are fully identical in functionality:
 678
 679   ### Version 1 via PerlIO
 680     open(INPUT,  "< :encoding(shiftjis)", $infile)
 681         || die "Can't open < $infile for reading: $!";
 682     open(OUTPUT, "> :encoding(euc-jp)",  $outfile)
 683         || die "Can't open > $output for writing: $!";
 684     while (<INPUT>) {   # auto decodes $_
 685         print OUTPUT;   # auto encodes $_
 686     }
 687     close(INPUT)   || die "can't close $infile: $!";
 688     close(OUTPUT)  || die "can't close $outfile: $!";
 689
 690   ### Version 2 via from_to()
 691     open(INPUT,  "< :raw", $infile)
 692         || die "Can't open < $infile for reading: $!";
 693     open(OUTPUT, "> :raw",  $outfile)
 694         || die "Can't open > $output for writing: $!";
 695
 696     while (<INPUT>) {
 697         from_to($_, "shiftjis", "euc-jp", 1);  # switch encoding
 698         print OUTPUT;   # emit raw (but properly encoded) data
 699     }
 700     close(INPUT)   || die "can't close $infile: $!";
 701     close(OUTPUT)  || die "can't close $outfile: $!";
 702
 703 In the first version above, you let the appropriate encoding layer
 704 handle the conversion.  In the second, you explicitly translate
 705 from one encoding to the other.
 706
 707 Unfortunately, it may be that encodings are not C<PerlIO>-savvy.  You can check
 708 to see whether your encoding is supported by C<PerlIO> by invoking the
 709 C<perlio_ok> method on it:
 710
 711   Encode::perlio_ok("hz");             # false
 712   find_encoding("euc-cn")->perlio_ok;  # true wherever PerlIO is available
 713
 714   use Encode qw(perlio_ok);            # imported upon request
 715   perlio_ok("euc-jp")
 716
 717 Fortunately, all encodings that come with C<Encode> core are C<PerlIO>-savvy
 718 except for C<hz> and C<ISO-2022-kr>.  For the gory details, see
 719 L<Encode::Encoding> and L<Encode::PerlIO>.
 720
 721 =head1 Handling Malformed Data
 722
 723 The optional I<CHECK> argument tells C<Encode> what to do when
 724 encountering malformed data.  Without I<CHECK>, C<Encode::FB_DEFAULT>
 725 (== 0) is assumed.
 726
 727 As of version 2.12, C<Encode> supports coderef values for C<CHECK>;
 728 see below.
 729
 730 B<NOTE:> Not all encodings support this feature.
 731 Some encodings ignore the I<CHECK> argument.  For example,
 732 L<Encode::Unicode> ignores I<CHECK> and it always croaks on error.
 733
 734 =head2 List of I<CHECK> values
 735
 736 =head3 FB_DEFAULT
 737
 738   I<CHECK> = Encode::FB_DEFAULT ( == 0)
 739
 740 If I<CHECK> is 0, encoding and decoding replace any malformed character
 741 with a I<substitution character>.  When you encode, I<SUBCHAR> is used.
 742 When you decode, the Unicode REPLACEMENT CHARACTER, code point U+FFFD, is
 743 used.  If the data is supposed to be UTF-8, an optional lexical warning of
 744 warning category C<"utf8"> is given.
 745
 746 =head3 FB_CROAK
 747
 748   I<CHECK> = Encode::FB_CROAK ( == 1)
 749
 750 If I<CHECK> is 1, methods immediately die with an error
 751 message.  Therefore, when I<CHECK> is 1, you should trap
 752 exceptions with C<eval{}>, unless you really want to let it C<die>.
 753
 754 =head3 FB_QUIET
 755
 756   I<CHECK> = Encode::FB_QUIET
 757
 758 If I<CHECK> is set to C<Encode::FB_QUIET>, encoding and decoding immediately
 759 return the portion of the data that has been processed so far when an
 760 error occurs. The data argument is overwritten with everything
 761 after that point; that is, the unprocessed portion of the data.  This is
 762 handy when you have to call C<decode> repeatedly in the case where your
 763 source data may contain partial multi-byte character sequences,
 764 (that is, you are reading with a fixed-width buffer). Here's some sample
 765 code to do exactly that:
 766
 767     my($buffer, $string) = ("", "");
 768     while (read($fh, $buffer, 256, length($buffer))) {
 769         $string .= decode($encoding, $buffer, Encode::FB_QUIET);
 770         # $buffer now contains the unprocessed partial character
 771     }
 772
 773 =head3 FB_WARN
 774
 775   I<CHECK> = Encode::FB_WARN
 776
 777 This is the same as C<FB_QUIET> above, except that instead of being silent
 778 on errors, it issues a warning.  This is handy for when you are debugging.
 779
 780 =head3 FB_PERLQQ FB_HTMLCREF FB_XMLCREF
 781
 782 =over 2
 783
 784 =item perlqq mode (I<CHECK> = Encode::FB_PERLQQ)
 785
 786 =item HTML charref mode (I<CHECK> = Encode::FB_HTMLCREF)
 787
 788 =item XML charref mode (I<CHECK> = Encode::FB_XMLCREF)
 789
 790 =back
 791
 792 For encodings that are implemented by the C<Encode::XS> module, C<CHECK> C<==>
 793 C<Encode::FB_PERLQQ> puts C<encode> and C<decode> into C<perlqq> fallback mode.
 794
 795 When you decode, C<\xI<HH>> is inserted for a malformed character, where
 796 I<HH> is the hex representation of the octet that could not be decoded to
 797 utf8.  When you encode, C<\x{I<HHHH>}> will be inserted, where I<HHHH> is
 798 the Unicode code point (in any number of hex digits) of the character that
 799 cannot be found in the character repertoire of the encoding.
 800
 801 The HTML/XML character reference modes are about the same. In place of
 802 C<\x{I<HHHH>}>, HTML uses C<&#I<NNN>;> where I<NNN> is a decimal number, and
 803 XML uses C<&#xI<HHHH>;> where I<HHHH> is the hexadecimal number.
 804
 805 In C<Encode> 2.10 or later, C<LEAVE_SRC> is also implied.
 806
 807 =head3 The bitmask
 808
 809 These modes are all actually set via a bitmask.  Here is how the C<FB_I<XXX>>
 810 constants are laid out.  You can import the C<FB_I<XXX>> constants via
 811 C<use Encode qw(:fallbacks)>, and you can import the generic bitmask
 812 constants via C<use Encode qw(:fallback_all)>.
 813
 814                      FB_DEFAULT FB_CROAK FB_QUIET FB_WARN  FB_PERLQQ
 815  DIE_ON_ERR    0x0001             X
 816  WARN_ON_ERR   0x0002                               X
 817  RETURN_ON_ERR 0x0004                      X        X
 818  LEAVE_SRC     0x0008                                        X
 819  PERLQQ        0x0100                                        X
 820  HTMLCREF      0x0200
 821  XMLCREF       0x0400
 822
 823 =head3 LEAVE_SRC
 824
 825   Encode::LEAVE_SRC
 826
 827 If the C<Encode::LEAVE_SRC> bit is I<not> set but I<CHECK> is set, then the
 828 source string to encode() or decode() will be overwritten in place.
 829 If you're not interested in this, then bitwise-OR it with the bitmask.
 830
 831 =head2 coderef for CHECK
 832
 833 As of C<Encode> 2.12, C<CHECK> can also be a code reference which takes the
 834 ordinal value of the unmapped character as an argument and returns
 835 octets that represent the fallback character.  For instance:
 836
 837   $ascii = encode("ascii", $utf8, sub{ sprintf "<U+%04X>", shift });
 838
 839 Acts like C<FB_PERLQQ> but U+I<XXXX> is used instead of C<\x{I<XXXX>}>.
 840
 841 Even the fallback for C<decode> must return octets, which are
 842 then decoded with the character encoding that C<decode> accepts. So for
 843 example if you wish to decode octets as UTF-8, and use ISO-8859-15 as
 844 a fallback for bytes that are not valid UTF-8, you could write
 845
 846     $str = decode 'UTF-8', $octets, sub {
 847         my $tmp = chr shift;
 848         from_to $tmp, 'ISO-8859-15', 'UTF-8';
 849         return $tmp;
 850     };
 851
 852 =head1 Defining Encodings
 853
 854 To define a new encoding, use:
 855
 856     use Encode qw(define_encoding);
 857     define_encoding($object, CANONICAL_NAME [, alias...]);
 858
 859 I<CANONICAL_NAME> will be associated with I<$object>.  The object
 860 should provide the interface described in L<Encode::Encoding>.
 861 If more than two arguments are provided, additional
 862 arguments are considered aliases for I<$object>.
 863
 864 See L<Encode::Encoding> for details.
 865
 866 =head1 The UTF8 flag
 867
 868 Before the introduction of Unicode support in Perl, The C<eq> operator
 869 just compared the strings represented by two scalars. Beginning with
 870 Perl 5.8, C<eq> compares two strings with simultaneous consideration of
 871 I<the UTF8 flag>. To explain why we made it so, I quote from page 402 of
 872 I<Programming Perl, 3rd ed.>
 873
 874 =over 2
 875
 876 =item Goal #1:
 877
 878 Old byte-oriented programs should not spontaneously break on the old
 879 byte-oriented data they used to work on.
 880
 881 =item Goal #2:
 882
 883 Old byte-oriented programs should magically start working on the new
 884 character-oriented data when appropriate.
 885
 886 =item Goal #3:
 887
 888 Programs should run just as fast in the new character-oriented mode
 889 as in the old byte-oriented mode.
 890
 891 =item Goal #4:
 892
 893 Perl should remain one language, rather than forking into a
 894 byte-oriented Perl and a character-oriented Perl.
 895
 896 =back
 897
 898 When I<Programming Perl, 3rd ed.> was written, not even Perl 5.6.0 had been
 899 born yet, many features documented in the book remained unimplemented for a
 900 long time.  Perl 5.8 corrected much of this, and the introduction of the
 901 UTF8 flag is one of them.  You can think of there being two fundamentally
 902 different kinds of strings and string-operations in Perl: one a
 903 byte-oriented mode  for when the internal UTF8 flag is off, and the other a
 904 character-oriented mode for when the internal UTF8 flag is on.
 905
 906 Here is how C<Encode> handles the UTF8 flag.
 907
 908 =over 2
 909
 910 =item *
 911
 912 When you I<encode>, the resulting UTF8 flag is always B<off>.
 913
 914 =item *
 915
 916 When you I<decode>, the resulting UTF8 flag is B<on>--I<unless> you can
 917 unambiguously represent data.  Here is what we mean by "unambiguously".
 918 After C<$utf8 = decode("foo", $octet)>,
 919
 920   When $octet is...   The UTF8 flag in $utf8 is
 921   ---------------------------------------------
 922   In ASCII only (or EBCDIC only)            OFF
 923   In ISO-8859-1                              ON
 924   In any other Encoding                      ON
 925   ---------------------------------------------
 926
 927 As you see, there is one exception: in ASCII.  That way you can assume
 928 Goal #1.  And with C<Encode>, Goal #2 is assumed but you still have to be
 929 careful in the cases mentioned in the B<CAVEAT> paragraphs above.
 930
 931 This UTF8 flag is not visible in Perl scripts, exactly for the same reason
 932 you cannot (or rather, you I<don't have to>) see whether a scalar contains
 933 a string, an integer, or a floating-point number.   But you can still peek
 934 and poke these if you will.  See the next section.
 935
 936 =back
 937
 938 =head2 Messing with Perl's Internals
 939
 940 The following API uses parts of Perl's internals in the current
 941 implementation.  As such, they are efficient but may change in a future
 942 release.
 943
 944 =head3 is_utf8
 945
 946   is_utf8(STRING [, CHECK])
 947
 948 [INTERNAL] Tests whether the UTF8 flag is turned on in the I<STRING>.
 949 If I<CHECK> is true, also checks whether I<STRING> contains well-formed
 950 UTF-8.  Returns true if successful, false otherwise.
 951
 952 As of Perl 5.8.1, L<utf8> also has the C<utf8::is_utf8> function.
 953
 954 =head3 _utf8_on
 955
 956   _utf8_on(STRING)
 957
 958 [INTERNAL] Turns the I<STRING>'s internal UTF8 flag B<on>.  The I<STRING>
 959 is I<not> checked for containing only well-formed UTF-8.  Do not use this
 960 unless you I<know with absolute certainty> that the STRING holds only
 961 well-formed UTF-8.  Returns the previous state of the UTF8 flag (so please
 962 don't treat the return value as indicating success or failure), or C<undef>
 963 if I<STRING> is not a string.
 964
 965 B<NOTE>: For security reasons, this function does not work on tainted values.
 966
 967 =head3 _utf8_off
 968
 969   _utf8_off(STRING)
 970
 971 [INTERNAL] Turns the I<STRING>'s internal UTF8 flag B<off>.  Do not use
 972 frivolously.  Returns the previous state of the UTF8 flag, or C<undef> if
 973 I<STRING> is not a string.  Do not treat the return value as indicative of
 974 success or failure, because that isn't what it means: it is only the
 975 previous setting.
 976
 977 B<NOTE>: For security reasons, this function does not work on tainted values.
 978
 979 =head1 UTF-8 vs. utf8 vs. UTF8
 980
 981   ....We now view strings not as sequences of bytes, but as sequences
 982   of numbers in the range 0 .. 2**32-1 (or in the case of 64-bit
 983   computers, 0 .. 2**64-1) -- Programming Perl, 3rd ed.
 984
 985 That has historically been Perl's notion of UTF-8, as that is how UTF-8 was
 986 first conceived by Ken Thompson when he invented it. However, thanks to
 987 later revisions to the applicable standards, official UTF-8 is now rather
 988 stricter than that. For example, its range is much narrower (0 .. 0x10_FFFF
 989 to cover only 21 bits instead of 32 or 64 bits) and some sequences
 990 are not allowed, like those used in surrogate pairs, the 31 non-character
 991 code points 0xFDD0 .. 0xFDEF, the last two code points in I<any> plane
 992 (0xI<XX>_FFFE and 0xI<XX>_FFFF), all non-shortest encodings, etc.
 993
 994 The former default in which Perl would always use a loose interpretation of
 995 UTF-8 has now been overruled:
 996
 997   From: Larry Wall <larry@wall.org>
 998   Date: December 04, 2004 11:51:58 JST
 999   To: perl-unicode@perl.org
1000   Subject: Re: Make Encode.pm support the real UTF-8
1001   Message-Id: <20041204025158.GA28754@wall.org>
1002
1003   On Fri, Dec 03, 2004 at 10:12:12PM +0000, Tim Bunce wrote:
1004   : I've no problem with 'utf8' being perl's unrestricted uft8 encoding,
1005   : but "UTF-8" is the name of the standard and should give the
1006   : corresponding behaviour.
1007
1008   For what it's worth, that's how I've always kept them straight in my
1009   head.
1010
1011   Also for what it's worth, Perl 6 will mostly default to strict but
1012   make it easy to switch back to lax.
1013
1014   Larry
1015
1016 Got that?  As of Perl 5.8.7, B<"UTF-8"> means UTF-8 in its current
1017 sense, which is conservative and strict and security-conscious, whereas
1018 B<"utf8"> means UTF-8 in its former sense, which was liberal and loose and
1019 lax.  C<Encode> version 2.10 or later thus groks this subtle but critically
1020 important distinction between C<"UTF-8"> and C<"utf8">.
1021
1022   encode("utf8",  "\x{FFFF_FFFF}", 1); # okay
1023   encode("UTF-8", "\x{FFFF_FFFF}", 1); # croaks
1024
1025 In the C<Encode> module, C<"UTF-8"> is actually a canonical name for
1026 C<"utf-8-strict">.  That hyphen between the C<"UTF"> and the C<"8"> is
1027 critical; without it, C<Encode> goes "liberal" and (perhaps overly-)permissive:
1028
1029   find_encoding("UTF-8")->name # is 'utf-8-strict'
1030   find_encoding("utf-8")->name # ditto. names are case insensitive
1031   find_encoding("utf_8")->name # ditto. "_" are treated as "-"
1032   find_encoding("UTF8")->name  # is 'utf8'.
1033
1034 Perl's internal UTF8 flag is called "UTF8", without a hyphen. It indicates
1035 whether a string is internally encoded as "utf8", also without a hyphen.
1036
1037 =head1 SEE ALSO
1038
1039 L<Encode::Encoding>,
1040 L<Encode::Supported>,
1041 L<Encode::PerlIO>,
1042 L<encoding>,
1043 L<perlebcdic>,
1044 L<perlfunc/open>,
1045 L<perlunicode>, L<perluniintro>, L<perlunifaq>, L<perlunitut>
1046 L<utf8>,
1047 the Perl Unicode Mailing List L<http://lists.perl.org/list/perl-unicode.html>
1048
1049 =head1 MAINTAINER
1050
1051 This project was originated by the late Nick Ing-Simmons and later
1052 maintained by Dan Kogai I<< <dankogai@cpan.org> >>.  See AUTHORS
1053 for a full list of people involved.  For any questions, send mail to
1054 I<< <perl-unicode@perl.org> >> so that we can all share.
1055
1056 While Dan Kogai retains the copyright as a maintainer, credit
1057 should go to all those involved.  See AUTHORS for a list of those
1058 who submitted code to the project.
1059
1060 =head1 COPYRIGHT
1061
1062 Copyright 2002-2014 Dan Kogai I<< <dankogai@cpan.org> >>.
1063
1064 This library is free software; you can redistribute it and/or modify
1065 it under the same terms as Perl itself.
1066
1067 =cut