utils/perlivp.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename;
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries:
  11 #  $startperl
  12 #  $perlpath
  13 #  $eunicefix
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 my $origdir = cwd;
  18 chdir dirname($0);
  19 my $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 # Create output file.
  23 open OUT,">$file" or die "Can't create $file: $!";
  24
  25 print "Extracting $file (with variable substitutions)\n";
  26
  27 # In this section, perl variables will be expanded during extraction.
  28 # You can use $Config{...} to use Configure variables.
  29
  30 print OUT <<"!GROK!THIS!";
  31 $Config{'startperl'}
  32     eval 'exec $Config{'perlpath'} -S \$0 \${1+"\$@"}'
  33         if \$running_under_some_shell;
  34 !GROK!THIS!
  35
  36 print OUT "\n# perlivp $^V\n";
  37
  38 # In the following, perl variables are not expanded during extraction.
  39
  40 print OUT <<'!NO!SUBS!';
  41
  42 sub usage {
  43     warn "@_\n" if @_;
  44     print << "    EOUSAGE";
  45 Usage:
  46
  47     $0 [-a] [-p] [-v] | [-h]
  48
  49     -a Run all tests (default is to skip .ph tests)
  50     -p Print a preface before each test telling what it will test.
  51     -v Verbose mode in which extra information about test results
  52        is printed.  Test failures always print out some extra information
  53        regardless of whether or not this switch is set.
  54     -h Prints this help message.
  55     EOUSAGE
  56     exit;
  57 }
  58
  59 use vars qw(%opt); # allow testing with older versions (do not use our)
  60
  61 @opt{ qw/? H h P p V v/ } = qw(0 0 0 0 0 0 0);
  62
  63 while ($ARGV[0] =~ /^-/) {
  64     $ARGV[0] =~ s/^-//;
  65     for my $flag (split(//,$ARGV[0])) {
  66         usage() if '?' =~ /\Q$flag/;
  67         usage() if 'h' =~ /\Q$flag/;
  68         usage() if 'H' =~ /\Q$flag/;
  69         usage("unknown flag: `$flag'") unless 'HhPpVva' =~ /\Q$flag/;
  70         warn "$0: `$flag' flag already set\n" if $opt{$flag}++;
  71     }
  72     shift;
  73 }
  74
  75 $opt{p}++ if $opt{P};
  76 $opt{v}++ if $opt{V};
  77
  78 my $pass__total = 0;
  79 my $error_total = 0;
  80 my $tests_total = 0;
  81
  82 !NO!SUBS!
  83
  84 # We cannot merely check the variable `$^X' in general since on many
  85 # Unixes it is the basename rather than the full path to the perl binary.
  86 my $perlpath = '';
  87 if (defined($Config{'perlpath'})) { $perlpath = $Config{'perlpath'}; }
  88
  89 # The useithreads Config variable plays a role in whether or not
  90 # threads and threads/shared work when C<use>d.  They apparently always
  91 # get installed on systems that can run Configure.
  92 my $useithreads = '';
  93 if (defined($Config{'useithreads'})) { $useithreads = $Config{'useithreads'}; }
  94
  95 print OUT <<"!GROK!THIS!";
  96 my \$perlpath = '$perlpath';
  97 my \$useithreads = '$useithreads';
  98 !GROK!THIS!
  99
 100 print OUT <<'!NO!SUBS!';
 101
 102 print "## Checking Perl binary via variable `\$perlpath' = $perlpath.\n" if $opt{'p'};
 103
 104 if (-x $perlpath) {
 105     print "## Perl binary `$perlpath' appears executable.\n" if $opt{'v'};
 106     print "ok 1\n";
 107     $pass__total++;
 108 }
 109 else {
 110     print "# Perl binary `$perlpath' does not appear executable.\n";
 111     print "not ok 1\n";
 112     $error_total++;
 113 }
 114 $tests_total++;
 115
 116
 117 print "## Checking Perl version via variable `\$]'.\n" if $opt{'p'};
 118
 119 !NO!SUBS!
 120
 121 print OUT <<"!GROK!THIS!";
 122 my \$ivp_VERSION = $];
 123
 124 !GROK!THIS!
 125 print OUT <<'!NO!SUBS!';
 126 if ($ivp_VERSION eq $]) {
 127     print "## Perl version `$]' appears installed as expected.\n" if $opt{'v'};
 128     print "ok 2\n";
 129     $pass__total++;
 130 }
 131 else {
 132     print "# Perl version `$]' installed, expected $ivp_VERSION.\n";
 133     print "not ok 2\n";
 134     $error_total++;
 135 }
 136 $tests_total++;
 137
 138
 139 print "## Checking roots of the Perl library directory tree via variable `\@INC'.\n" if $opt{'p'};
 140
 141 my $INC_total = 0;
 142 my $INC_there = 0;
 143 foreach (@INC) {
 144     next if $_ eq '.'; # skip -d test here
 145     if ($^O eq 'MacOS') {
 146         next if $_ eq ':'; # skip -d test here
 147         next if $_ eq 'Dev:Pseudo:'; # why is this in @INC?
 148     }
 149     if (-d $_) {
 150         print "## Perl \@INC directory `$_' exists.\n" if $opt{'v'};
 151         $INC_there++;
 152     }
 153     else {
 154         print "# Perl \@INC directory `$_' does not appear to exist.\n";
 155     }
 156     $INC_total++;
 157 }
 158 if ($INC_total == $INC_there) {
 159     print "ok 3\n";
 160     $pass__total++;
 161 }
 162 else {
 163     print "not ok 3\n";
 164     $error_total++;
 165 }
 166 $tests_total++;
 167
 168
 169 print "## Checking installations of modules necessary for ivp.\n" if $opt{'p'};
 170
 171 my $needed_total = 0;
 172 my $needed_there = 0;
 173 foreach (qw(Config.pm ExtUtils/Installed.pm)) {
 174     $@ = undef;
 175     $needed_total++;
 176     eval "require \"$_\";";
 177     if (!$@) {
 178         print "## Module `$_' appears to be installed.\n" if $opt{'v'};
 179         $needed_there++;
 180     }
 181     else {
 182         print "# Needed module `$_' does not appear to be properly installed.\n";
 183     }
 184     $@ = undef;
 185 }
 186 if ($needed_total == $needed_there) {
 187     print "ok 4\n";
 188     $pass__total++;
 189 }
 190 else {
 191     print "not ok 4\n";
 192     $error_total++;
 193 }
 194 $tests_total++;
 195
 196
 197 print "## Checking installations of extensions built with perl.\n" if $opt{'p'};
 198
 199 use Config;
 200
 201 my $extensions_total = 0;
 202 my $extensions_there = 0;
 203 if (defined($Config{'extensions'})) {
 204     my @extensions = split(/\s+/,$Config{'extensions'});
 205     foreach (@extensions) {
 206         next if ($_ eq '');
 207         if ( $useithreads !~ /define/i ) {
 208             next if ($_ eq 'threads');
 209             next if ($_ eq 'threads/shared');
 210         }
 211         # that's a distribution name, not a module name
 212         next if $_ eq 'IO/Compress/Zlib';
 213         next if $_ eq 'Devel/DProf';
 214         # test modules
 215         next if $_ eq 'XS/APItest';
 216         next if $_ eq 'XS/Typemap';
 217            # VMS$ perl  -e "eval ""require \""Devel/DProf.pm\"";"" print $@"
 218            # \NT> perl  -e "eval \"require 'Devel/DProf.pm'\"; print $@"
 219            # DProf: run perl with -d to use DProf.
 220            # Compilation failed in require at (eval 1) line 1.
 221         eval " require \"$_.pm\"; ";
 222         if (!$@) {
 223             print "## Module `$_' appears to be installed.\n" if $opt{'v'};
 224             $extensions_there++;
 225         }
 226         else {
 227             print "# Required module `$_' does not appear to be properly installed.\n";
 228             $@ = undef;
 229         }
 230         $extensions_total++;
 231     }
 232
 233     # A silly name for a module (that hopefully won't ever exist).
 234     # Note that this test serves more as a check of the validity of the
 235     # actuall required module tests above.
 236     my $unnecessary = 'bLuRfle';
 237
 238     if (!grep(/$unnecessary/, @extensions)) {
 239         $@ = undef;
 240         eval " require \"$unnecessary.pm\"; ";
 241         if ($@) {
 242             print "## Unnecessary module `$unnecessary' does not appear to be installed.\n" if $opt{'v'};
 243         }
 244         else {
 245             print "# Unnecessary module `$unnecessary' appears to be installed.\n";
 246             $extensions_there++;
 247         }
 248     }
 249     $@ = undef;
 250 }
 251 if ($extensions_total == $extensions_there) {
 252     print "ok 5\n";
 253     $pass__total++;
 254 }
 255 else {
 256     print "not ok 5\n";
 257     $error_total++;
 258 }
 259 $tests_total++;
 260
 261
 262 print "## Checking installations of later additional extensions.\n" if $opt{'p'};
 263
 264 use ExtUtils::Installed;
 265
 266 my $installed_total = 0;
 267 my $installed_there = 0;
 268 my $version_check = 0;
 269 my $installed = ExtUtils::Installed -> new();
 270 my @modules = $installed -> modules();
 271 my @missing = ();
 272 my $version = undef;
 273 for (@modules) {
 274     $installed_total++;
 275     # Consider it there if it contains one or more files,
 276     # and has zero missing files,
 277     # and has a defined version
 278     $version = undef;
 279     $version = $installed -> version($_);
 280     if ($version) {
 281         print "## $_; $version\n" if $opt{'v'};
 282         $version_check++;
 283     }
 284     else {
 285         print "# $_; NO VERSION\n" if $opt{'v'};
 286     }
 287     $version = undef;
 288     @missing = ();
 289     @missing = $installed -> validate($_);
 290     if ($#missing >= 0) {
 291         print "# file",+($#missing == 0) ? '' : 's'," missing from installation:\n";
 292         print '# ',join(' ',@missing),"\n";
 293     }
 294     elsif ($#missing == -1) {
 295         $installed_there++;
 296     }
 297     @missing = ();
 298 }
 299 if (($installed_total == $installed_there) &&
 300     ($installed_total == $version_check)) {
 301     print "ok 6\n";
 302     $pass__total++;
 303 }
 304 else {
 305     print "not ok 6\n";
 306     $error_total++;
 307 }
 308 $tests_total++;
 309
 310
 311 if ($opt{'a'}) {
 312 print "## Checking installations of *.h -> *.ph header files.\n" if $opt{'p'};
 313 my $ph_there = 0;
 314 my $var = undef;
 315 my $val = undef;
 316 my $h_file = undef;
 317 # Just about "any" C implementation ought to have a stdio.h (even if
 318 # Config.pm may not list a i_stdio var).
 319 my @ph_files = qw(stdio.ph);
 320 # Add the ones that we know that perl thinks are there:
 321 while (($var, $val) = each %Config) {
 322     if ($var =~ m/i_(.+)/ && $val eq 'define') {
 323         $h_file = $1;
 324         # Some header and symbol names don't match for hysterical raisins.
 325         $h_file = 'arpa/inet'    if $h_file eq 'arpainet';
 326         $h_file = 'netinet/in'   if $h_file eq 'niin';
 327         $h_file = 'netinet/tcp'  if $h_file eq 'netinettcp';
 328         $h_file = 'sys/resource' if $h_file eq 'sysresrc';
 329         $h_file = 'sys/select'   if $h_file eq 'sysselct';
 330         $h_file = 'sys/security' if $h_file eq 'syssecrt';
 331         $h_file = 'rpcsvc/dbm'   if $h_file eq 'rpcsvcdbm';
 332         # This ought to distinguish syslog from sys/syslog.
 333         # (NB syslog.ph is heavily used for the DBI pre-requisites).
 334         $h_file =~ s{^sys(\w.+)}{sys/$1} unless $h_file eq 'syslog';
 335         push(@ph_files, "$h_file.ph");
 336     }
 337 }
 338 #foreach (qw(stdio.ph syslog.ph)) {
 339 foreach (@ph_files) {
 340     $@ = undef;
 341     eval "require \"$_\";";
 342     if (!$@) {
 343         print "## Perl header `$_' appears to be installed.\n" if $opt{'v'};
 344         $ph_there++;
 345     }
 346     else {
 347         print "# Perl header `$_' does not appear to be properly installed.\n";
 348     }
 349     $@ = undef;
 350 }
 351
 352 if (scalar(@ph_files) == $ph_there) {
 353     print "ok 7\n";
 354     $pass__total++;
 355 }
 356 else {
 357     print "not ok 7\n";
 358     $error_total++;
 359 }
 360 $tests_total++;
 361 }
 362 else {
 363     print "##  Skip checking of *.ph header files.\n" if $opt{'p'};
 364 }
 365
 366 # Final report (rather than feed ousrselves to Test::Harness::runtests()
 367 # we simply format some output on our own to keep things simple and
 368 # easier to "fix" - at least for now.
 369
 370 if ($error_total == 0 && $tests_total) {
 371     print "All tests successful.\n";
 372 } elsif ($tests_total==0){
 373         die "FAILED--no tests were run for some reason.\n";
 374 } else {
 375     my $rate = 0.0;
 376     if ($tests_total > 0) { $rate = sprintf "%.2f", 100.0 * ($pass__total / $tests_total); }
 377     printf " %d/%d subtests failed, %.2f%% okay.\n",
 378                               $error_total, $tests_total, $rate;
 379 }
 380
 381 =head1 NAME
 382
 383 perlivp - Perl Installation Verification Procedure
 384
 385 =head1 SYNOPSIS
 386
 387 B<perlivp> [B<-a>] [B<-p>] [B<-v>] [B<-h>]
 388
 389 =head1 DESCRIPTION
 390
 391 The B<perlivp> program is set up at Perl source code build time to test the
 392 Perl version it was built under.  It can be used after running:
 393
 394     make install
 395
 396 (or your platform's equivalent procedure) to verify that B<perl> and its
 397 libraries have been installed correctly.  A correct installation is verified
 398 by output that looks like:
 399
 400     ok 1
 401     ok 2
 402
 403 etc.
 404
 405 =head1 OPTIONS
 406
 407 =over 5
 408
 409 =item B<-h> help
 410
 411 Prints out a brief help message.
 412
 413 =item B<-a> run all tests
 414
 415 Normally tests for optional features are skipped.  With -a all tests
 416 are executed.
 417
 418 =item B<-p> print preface
 419
 420 Gives a description of each test prior to performing it.
 421
 422 =item B<-v> verbose
 423
 424 Gives more detailed information about each test, after it has been performed.
 425 Note that any failed tests ought to print out some extra information whether
 426 or not -v is thrown.
 427
 428 =back
 429
 430 =head1 DIAGNOSTICS
 431
 432 =over 4
 433
 434 =item * print "# Perl binary `$perlpath' does not appear executable.\n";
 435
 436 Likely to occur for a perl binary that was not properly installed.
 437 Correct by conducting a proper installation.
 438
 439 =item * print "# Perl version `$]' installed, expected $ivp_VERSION.\n";
 440
 441 Likely to occur for a perl that was not properly installed.
 442 Correct by conducting a proper installation.
 443
 444 =item * print "# Perl \@INC directory `$_' does not appear to exist.\n";
 445
 446 Likely to occur for a perl library tree that was not properly installed.
 447 Correct by conducting a proper installation.
 448
 449 =item * print "# Needed module `$_' does not appear to be properly installed.\n";
 450
 451 One of the two modules that is used by perlivp was not present in the
 452 installation.  This is a serious error since it adversely affects perlivp's
 453 ability to function.  You may be able to correct this by performing a
 454 proper perl installation.
 455
 456 =item * print "# Required module `$_' does not appear to be properly installed.\n";
 457
 458 An attempt to C<eval "require $module"> failed, even though the list of
 459 extensions indicated that it should succeed.  Correct by conducting a proper
 460 installation.
 461
 462 =item * print "# Unnecessary module `bLuRfle' appears to be installed.\n";
 463
 464 This test not coming out ok could indicate that you have in fact installed
 465 a bLuRfle.pm module or that the C<eval " require \"$module_name.pm\"; ">
 466 test may give misleading results with your installation of perl.  If yours
 467 is the latter case then please let the author know.
 468
 469 =item * print "# file",+($#missing == 0) ? '' : 's'," missing from installation:\n";
 470
 471 One or more files turned up missing according to a run of
 472 C<ExtUtils::Installed -E<gt> validate()> over your installation.
 473 Correct by conducting a proper installation.
 474
 475 =item * print "# Perl header `$_' does not appear to be properly installed.\n";
 476
 477 Correct by running B<h2ph> over your system's C header files.  If necessary,
 478 edit the resulting *.ph files to eliminate perl syntax errors.
 479
 480 =back
 481
 482 For further information on how to conduct a proper installation consult the
 483 INSTALL file that comes with the perl source and the README file for your
 484 platform.
 485
 486 =head1 AUTHOR
 487
 488 Peter Prymmer
 489
 490 =cut
 491
 492 !NO!SUBS!
 493
 494 close OUT or die "Can't close $file: $!";
 495 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 496 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 497 chdir $origdir;
 498