lib/AutoLoader.pm

   1 package AutoLoader;
   2
   3 # use vars qw(@EXPORT @EXPORT_OK $VERSION);
   4
   5 my $is_dosish;
   6 my $is_vms;
   7
   8 BEGIN {
   9     require Exporter;
  10     @EXPORT = @EXPORT = ();
  11     @EXPORT_OK = @EXPORT_OK = qw(AUTOLOAD);
  12     $is_dosish = $^O eq 'dos' || $^O eq 'os2' || $^O eq 'MSWin32';
  13     $is_vms = $^O eq 'VMS';
  14     $VERSION = $VERSION = '5.57';
  15 }
  16
  17 AUTOLOAD {
  18     my $sub = $AUTOLOAD;
  19     my $filename;
  20     # Braces used to preserve $1 et al.
  21     {
  22         # Try to find the autoloaded file from the package-qualified
  23         # name of the sub. e.g., if the sub needed is
  24         # Getopt::Long::GetOptions(), then $INC{Getopt/Long.pm} is
  25         # something like '/usr/lib/perl5/Getopt/Long.pm', and the
  26         # autoload file is '/usr/lib/perl5/auto/Getopt/Long/GetOptions.al'.
  27         #
  28         # However, if @INC is a relative path, this might not work.  If,
  29         # for example, @INC = ('lib'), then $INC{Getopt/Long.pm} is
  30         # 'lib/Getopt/Long.pm', and we want to require
  31         # 'auto/Getopt/Long/GetOptions.al' (without the leading 'lib').
  32         # In this case, we simple prepend the 'auto/' and let the
  33         # C<require> take care of the searching for us.
  34
  35         my ($pkg,$func) = ($sub =~ /(.*)::([^:]+)$/);
  36         $pkg =~ s#::#/#g;
  37         if (defined($filename = $INC{"$pkg.pm"})) {
  38             $filename =~ s#^(.*)$pkg\.pm$#$1auto/$pkg/$func.al#;
  39
  40             # if the file exists, then make sure that it is a
  41             # a fully anchored path (i.e either '/usr/lib/auto/foo/bar.al',
  42             # or './lib/auto/foo/bar.al'.  This avoids C<require> searching
  43             # (and failing) to find the 'lib/auto/foo/bar.al' because it
  44             # looked for 'lib/lib/auto/foo/bar.al', given @INC = ('lib').
  45
  46             if (-r $filename) {
  47                 unless ($filename =~ m|^/|) {
  48                     if ($is_dosish) {
  49                         unless ($filename =~ m{^([a-z]:)?[\\/]}i) {
  50                              $filename = "./$filename";
  51                         }
  52                     }
  53                     elsif ($is_vms) {
  54                         # XXX todo by VMSmiths
  55                         $filename = "./$filename";
  56                     }
  57                     else {
  58                         $filename = "./$filename";
  59                     }
  60                 }
  61             }
  62             else {
  63                 $filename = undef;
  64             }
  65         }
  66         unless (defined $filename) {
  67             # let C<require> do the searching
  68             $filename = "auto/$sub.al";
  69             $filename =~ s#::#/#g;
  70         }
  71     }
  72     my $save = $@;
  73     eval { local $SIG{__DIE__}; require $filename };
  74     if ($@) {
  75         if (substr($sub,-9) eq '::DESTROY') {
  76             *$sub = sub {};
  77         } else {
  78             # The load might just have failed because the filename was too
  79             # long for some old SVR3 systems which treat long names as errors.
  80             # If we can succesfully truncate a long name then it's worth a go.
  81             # There is a slight risk that we could pick up the wrong file here
  82             # but autosplit should have warned about that when splitting.
  83             if ($filename =~ s/(\w{12,})\.al$/substr($1,0,11).".al"/e){
  84                 eval { local $SIG{__DIE__}; require $filename };
  85             }
  86             if ($@){
  87                 $@ =~ s/ at .*\n//;
  88                 my $error = $@;
  89                 require Carp;
  90                 Carp::croak($error);
  91             }
  92         }
  93     }
  94     $@ = $save;
  95     goto &$sub;
  96 }
  97
  98 sub import {
  99     my $pkg = shift;
 100     my $callpkg = caller;
 101
 102     #
 103     # Export symbols, but not by accident of inheritance.
 104     #
 105
 106     if ($pkg eq 'AutoLoader') {
 107       local $Exporter::ExportLevel = 1;
 108       Exporter::import $pkg, @_;
 109     }
 110
 111     #
 112     # Try to find the autosplit index file.  Eg., if the call package
 113     # is POSIX, then $INC{POSIX.pm} is something like
 114     # '/usr/local/lib/perl5/POSIX.pm', and the autosplit index file is in
 115     # '/usr/local/lib/perl5/auto/POSIX/autosplit.ix', so we require that.
 116     #
 117     # However, if @INC is a relative path, this might not work.  If,
 118     # for example, @INC = ('lib'), then
 119     # $INC{POSIX.pm} is 'lib/POSIX.pm', and we want to require
 120     # 'auto/POSIX/autosplit.ix' (without the leading 'lib').
 121     #
 122
 123     (my $calldir = $callpkg) =~ s#::#/#g;
 124     my $path = $INC{$calldir . '.pm'};
 125     if (defined($path)) {
 126         # Try absolute path name.
 127         $path =~ s#^(.*)$calldir\.pm$#$1auto/$calldir/autosplit.ix#;
 128         eval { require $path; };
 129         # If that failed, try relative path with normal @INC searching.
 130         if ($@) {
 131             $path ="auto/$calldir/autosplit.ix";
 132             eval { require $path; };
 133         }
 134         if ($@) {
 135             my $error = $@;
 136             require Carp;
 137             Carp::carp($error);
 138         }
 139     }
 140 }
 141
 142 1;
 143
 144 __END__
 145
 146 =head1 NAME
 147
 148 AutoLoader - load subroutines only on demand
 149
 150 =head1 SYNOPSIS
 151
 152     package Foo;
 153     use AutoLoader 'AUTOLOAD';   # import the default AUTOLOAD subroutine
 154
 155     package Bar;
 156     use AutoLoader;              # don't import AUTOLOAD, define our own
 157     sub AUTOLOAD {
 158         ...
 159         $AutoLoader::AUTOLOAD = "...";
 160         goto &AutoLoader::AUTOLOAD;
 161     }
 162
 163 =head1 DESCRIPTION
 164
 165 The B<AutoLoader> module works with the B<AutoSplit> module and the
 166 C<__END__> token to defer the loading of some subroutines until they are
 167 used rather than loading them all at once.
 168
 169 To use B<AutoLoader>, the author of a module has to place the
 170 definitions of subroutines to be autoloaded after an C<__END__> token.
 171 (See L<perldata>.)  The B<AutoSplit> module can then be run manually to
 172 extract the definitions into individual files F<auto/funcname.al>.
 173
 174 B<AutoLoader> implements an AUTOLOAD subroutine.  When an undefined
 175 subroutine in is called in a client module of B<AutoLoader>,
 176 B<AutoLoader>'s AUTOLOAD subroutine attempts to locate the subroutine in a
 177 file with a name related to the location of the file from which the
 178 client module was read.  As an example, if F<POSIX.pm> is located in
 179 F</usr/local/lib/perl5/POSIX.pm>, B<AutoLoader> will look for perl
 180 subroutines B<POSIX> in F</usr/local/lib/perl5/auto/POSIX/*.al>, where
 181 the C<.al> file has the same name as the subroutine, sans package.  If
 182 such a file exists, AUTOLOAD will read and evaluate it,
 183 thus (presumably) defining the needed subroutine.  AUTOLOAD will then
 184 C<goto> the newly defined subroutine.
 185
 186 Once this process completes for a given function, it is defined, so
 187 future calls to the subroutine will bypass the AUTOLOAD mechanism.
 188
 189 =head2 Subroutine Stubs
 190
 191 In order for object method lookup and/or prototype checking to operate
 192 correctly even when methods have not yet been defined it is necessary to
 193 "forward declare" each subroutine (as in C<sub NAME;>).  See
 194 L<perlsub/"SYNOPSIS">.  Such forward declaration creates "subroutine
 195 stubs", which are place holders with no code.
 196
 197 The AutoSplit and B<AutoLoader> modules automate the creation of forward
 198 declarations.  The AutoSplit module creates an 'index' file containing
 199 forward declarations of all the AutoSplit subroutines.  When the
 200 AutoLoader module is 'use'd it loads these declarations into its callers
 201 package.
 202
 203 Because of this mechanism it is important that B<AutoLoader> is always
 204 C<use>d and not C<require>d.
 205
 206 =head2 Using B<AutoLoader>'s AUTOLOAD Subroutine
 207
 208 In order to use B<AutoLoader>'s AUTOLOAD subroutine you I<must>
 209 explicitly import it:
 210
 211     use AutoLoader 'AUTOLOAD';
 212
 213 =head2 Overriding B<AutoLoader>'s AUTOLOAD Subroutine
 214
 215 Some modules, mainly extensions, provide their own AUTOLOAD subroutines.
 216 They typically need to check for some special cases (such as constants)
 217 and then fallback to B<AutoLoader>'s AUTOLOAD for the rest.
 218
 219 Such modules should I<not> import B<AutoLoader>'s AUTOLOAD subroutine.
 220 Instead, they should define their own AUTOLOAD subroutines along these
 221 lines:
 222
 223     use AutoLoader;
 224     use Carp;
 225
 226     sub AUTOLOAD {
 227         my $sub = $AUTOLOAD;
 228         (my $constname = $sub) =~ s/.*:://;
 229         my $val = constant($constname, @_ ? $_[0] : 0);
 230         if ($! != 0) {
 231             if ($! =~ /Invalid/ || $!{EINVAL}) {
 232                 $AutoLoader::AUTOLOAD = $sub;
 233                 goto &AutoLoader::AUTOLOAD;
 234             }
 235             else {
 236                 croak "Your vendor has not defined constant $constname";
 237             }
 238         }
 239         *$sub = sub { $val }; # same as: eval "sub $sub { $val }";
 240         goto &$sub;
 241     }
 242
 243 If any module's own AUTOLOAD subroutine has no need to fallback to the
 244 AutoLoader's AUTOLOAD subroutine (because it doesn't have any AutoSplit
 245 subroutines), then that module should not use B<AutoLoader> at all.
 246
 247 =head2 Package Lexicals
 248
 249 Package lexicals declared with C<my> in the main block of a package
 250 using B<AutoLoader> will not be visible to auto-loaded subroutines, due to
 251 the fact that the given scope ends at the C<__END__> marker.  A module
 252 using such variables as package globals will not work properly under the
 253 B<AutoLoader>.
 254
 255 The C<vars> pragma (see L<perlmod/"vars">) may be used in such
 256 situations as an alternative to explicitly qualifying all globals with
 257 the package namespace.  Variables pre-declared with this pragma will be
 258 visible to any autoloaded routines (but will not be invisible outside
 259 the package, unfortunately).
 260
 261 =head2 B<AutoLoader> vs. B<SelfLoader>
 262
 263 The B<AutoLoader> is similar in purpose to B<SelfLoader>: both delay the
 264 loading of subroutines.
 265
 266 B<SelfLoader> uses the C<__DATA__> marker rather than C<__END__>.
 267 While this avoids the use of a hierarchy of disk files and the
 268 associated open/close for each routine loaded, B<SelfLoader> suffers a
 269 startup speed disadvantage in the one-time parsing of the lines after
 270 C<__DATA__>, after which routines are cached.  B<SelfLoader> can also
 271 handle multiple packages in a file.
 272
 273 B<AutoLoader> only reads code as it is requested, and in many cases
 274 should be faster, but requires a mechanism like B<AutoSplit> be used to
 275 create the individual files.  L<ExtUtils::MakeMaker> will invoke
 276 B<AutoSplit> automatically if B<AutoLoader> is used in a module source
 277 file.
 278
 279 =head1 CAVEATS
 280
 281 AutoLoaders prior to Perl 5.002 had a slightly different interface.  Any
 282 old modules which use B<AutoLoader> should be changed to the new calling
 283 style.  Typically this just means changing a require to a use, adding
 284 the explicit C<'AUTOLOAD'> import if needed, and removing B<AutoLoader>
 285 from C<@ISA>.
 286
 287 On systems with restrictions on file name length, the file corresponding
 288 to a subroutine may have a shorter name that the routine itself.  This
 289 can lead to conflicting file names.  The I<AutoSplit> package warns of
 290 these potential conflicts when used to split a module.
 291
 292 AutoLoader may fail to find the autosplit files (or even find the wrong
 293 ones) in cases where C<@INC> contains relative paths, B<and> the program
 294 does C<chdir>.
 295
 296 =head1 SEE ALSO
 297
 298 L<SelfLoader> - an autoloader that doesn't use external files.
 299
 300 =cut