ext/Encode/Makefile.PL

   1 use ExtUtils::MakeMaker;
   2
   3 my %tables = (iso8859 => ['ascii.ucm', 'cp1250.ucm', 'koi8-r.ucm' ],
   4               EBCDIC  => ['cp1047.ucm','cp37.ucm','posix-bc.ucm'],
   5               Symbols => ['symbol.ucm','dingbats.ucm'],
   6              );
   7
   8 opendir(ENC,'Encode');
   9 while (defined(my $file = readdir(ENC)))
  10  {
  11   if ($file =~ /iso8859.*\.ucm/)
  12    {
  13     push(@{$tables{iso8859}},$file);
  14    }
  15  }
  16 closedir(ENC);
  17
  18
  19 WriteMakefile(
  20         NAME            => "Encode",
  21         VERSION_FROM    => 'Encode.pm',
  22         OBJECT          => '$(O_FILES)',
  23         'dist'          => {
  24                              COMPRESS   => 'gzip -9f',
  25                              SUFFIX     => 'gz',
  26                              DIST_DEFAULT => 'all tardist',
  27                            },
  28         MAN3PODS        => {},
  29 );
  30
  31 package MY;
  32
  33
  34 sub post_initialize
  35 {
  36  my ($self) = @_;
  37  my %o;
  38  # Find existing O_FILES
  39  foreach my $f (@{$self->{'O_FILES'}})
  40   {
  41    $o{$f} = 1;
  42   }
  43  my $x = $self->{'OBJ_EXT'};
  44  # Add the table O_FILES
  45  foreach my $e (keys %tables)
  46   {
  47    $o{$e.$x} = 1;
  48   }
  49  # Reset the variable
  50  $self->{'O_FILES'} = [sort keys %o];
  51  my @files;
  52  foreach my $table (keys %tables)
  53   {
  54    foreach my $ext (qw($(OBJ_EXT) .c .h .def .fnm))
  55     {
  56      push (@files,$table.$ext);
  57     }
  58   }
  59  $self->{'clean'}{'FILES'} .= join(' ',@files);
  60  return '';
  61 }
  62
  63 sub postamble
  64 {
  65  my $self = shift;
  66  my $dir  = $self->catdir($self->curdir,'Encode');
  67  my $str  = "# Encode\$(OBJ_EXT) depends on .h and .def files not .c files - but all written by compile\n";
  68  $str  .= 'Encode$(OBJ_EXT) :';
  69  foreach my $table (keys %tables)
  70   {
  71    $str .= " $table.c";
  72   }
  73  $str .= "\n\n";
  74  foreach my $table (keys %tables)
  75   {
  76    my $numlines = 1;
  77    my $lengthsofar = length($str);
  78    my $continuator = '';
  79    $str .= "$table.c : compile Makefile.PL";
  80    foreach my $file (@{$tables{$table}})
  81     {
  82      $str .= $continuator.' '.$self->catfile($dir,$file);
  83      if ( length($str)-$lengthsofar > 128*$numlines )
  84       {
  85        $continuator .= " \\\n\t";
  86        $numlines++;
  87       } else {
  88        $continuator = '';
  89       }
  90     }
  91    $str .= "\n\t\$(PERL) compile -o \$\@ -f $table.fnm\n\n";
  92    open (FILELIST, ">$table.fnm")
  93        || die "Could not open $table.fnm: $!";
  94    foreach my $file (@{$tables{$table}})
  95     {
  96      print FILELIST $self->catfile($dir,$file) . "\n";
  97     }
  98    close(FILELIST);
  99   }
 100  return $str;
 101 }