pod/perlvar.pod

   1 =head1 NAME
   2
   3 perlvar - Perl predefined variables
   4
   5 =head1 DESCRIPTION
   6
   7 =head2 The Syntax of Variable Names
   8
   9 Variable names in Perl can have several formats.  Usually, they
  10 must begin with a letter or underscore, in which case they can be
  11 arbitrarily long (up to an internal limit of 251 characters) and
  12 may contain letters, digits, underscores, or the special sequence
  13 C<::> or C<'>.  In this case, the part before the last C<::> or
  14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
  15 A Unicode letter that is not ASCII is not considered to be a letter
  16 unless S<C<"use utf8">> is in effect, and somewhat more complicated
  17 rules apply; see L<perldata/Identifier parsing> for details.
  18
  19 Perl variable names may also be a sequence of digits, a single
  20 punctuation character, or the two-character sequence: C<^> (caret or
  21 CIRCUMFLEX ACCENT) followed by any one of the characters C<[][A-Z^_?\]>.
  22 These names are all reserved for
  23 special uses by Perl; for example, the all-digits names are used
  24 to hold data captured by backreferences after a regular expression
  25 match.
  26
  27 Since Perl v5.6.0, Perl variable names may also be alphanumeric strings
  28 preceded by a caret.  These must all be written in the form C<${^Foo}>;
  29 the braces are not optional.  C<${^Foo}> denotes the scalar variable
  30 whose name is considered to be a control-C<F> followed by two C<o>'s.
  31 These variables are
  32 reserved for future special uses by Perl, except for the ones that
  33 begin with C<^_> (caret-underscore).  No
  34 name that begins with C<^_> will acquire a special
  35 meaning in any future version of Perl; such names may therefore be
  36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
  37
  38 Perl identifiers that begin with digits or
  39 punctuation characters are exempt from the effects of the C<package>
  40 declaration and are always forced to be in package C<main>; they are
  41 also exempt from C<strict 'vars'> errors.  A few other names are also
  42 exempt in these ways:
  43
  44     ENV      STDIN
  45     INC      STDOUT
  46     ARGV     STDERR
  47     ARGVOUT
  48     SIG
  49
  50 In particular, the special C<${^_XYZ}> variables are always taken
  51 to be in package C<main>, regardless of any C<package> declarations
  52 presently in scope.
  53
  54 =head1 SPECIAL VARIABLES
  55
  56 The following names have special meaning to Perl.  Most punctuation
  57 names have reasonable mnemonics, or analogs in the shells.
  58 Nevertheless, if you wish to use long variable names, you need only say:
  59
  60     use English;
  61
  62 at the top of your program.  This aliases all the short names to the long
  63 names in the current package.  Some even have medium names, generally
  64 borrowed from B<awk>.  For more info, please see L<English>.
  65
  66 Before you continue, note the sort order for variables.  In general, we
  67 first list the variables in case-insensitive, almost-lexigraphical
  68 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
  69 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
  70 For variables with the same identifier, we list it in order of scalar,
  71 array, hash, and bareword.
  72
  73 =head2 General Variables
  74
  75 =over 8
  76
  77 =item $ARG
  78
  79 =item $_
  80 X<$_> X<$ARG>
  81
  82 The default input and pattern-searching space.  The following pairs are
  83 equivalent:
  84
  85     while (<>) {...}    # equivalent only in while!
  86     while (defined($_ = <>)) {...}
  87
  88     /^Subject:/
  89     $_ =~ /^Subject:/
  90
  91     tr/a-z/A-Z/
  92     $_ =~ tr/a-z/A-Z/
  93
  94     chomp
  95     chomp($_)
  96
  97 Here are the places where Perl will assume C<$_> even if you don't use it:
  98
  99 =over 3
 100
 101 =item *
 102
 103 The following functions use C<$_> as a default argument:
 104
 105 abs, alarm, chomp, chop, chr, chroot,
 106 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
 107 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
 108 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
 109 rmdir, say, sin, split (for its second
 110 argument), sqrt, stat, study, uc, ucfirst,
 111 unlink, unpack.
 112
 113 =item *
 114
 115 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
 116 See L<perlfunc/-X>
 117
 118 =item *
 119
 120 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
 121 when used without an C<=~> operator.
 122
 123 =item *
 124
 125 The default iterator variable in a C<foreach> loop if no other
 126 variable is supplied.
 127
 128 =item *
 129
 130 The implicit iterator variable in the C<grep()> and C<map()> functions.
 131
 132 =item *
 133
 134 The implicit variable of C<given()>.
 135
 136 =item *
 137
 138 The default place to put the next value or input record
 139 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
 140 operation's result is tested by itself as the sole criterion of a C<while>
 141 test.  Outside a C<while> test, this will not happen.
 142
 143 =back
 144
 145 C<$_> is a global variable.
 146
 147 However, between perl v5.10.0 and v5.24.0, it could be used lexically by
 148 writing C<my $_>.  Making C<$_> refer to the global C<$_> in the same scope
 149 was then possible with C<our $_>.  This experimental feature was removed and is
 150 now a fatal error, but you may encounter it in older code.
 151
 152 Mnemonic: underline is understood in certain operations.
 153
 154 =item @ARG
 155
 156 =item @_
 157 X<@_> X<@ARG>
 158
 159 Within a subroutine the array C<@_> contains the parameters passed to
 160 that subroutine.  Inside a subroutine, C<@_> is the default array for
 161 the array operators C<pop> and C<shift>.
 162
 163 See L<perlsub>.
 164
 165 =item $LIST_SEPARATOR
 166
 167 =item $"
 168 X<$"> X<$LIST_SEPARATOR>
 169
 170 When an array or an array slice is interpolated into a double-quoted
 171 string or a similar context such as C</.../>, its elements are
 172 separated by this value.  Default is a space.  For example, this:
 173
 174     print "The array is: @array\n";
 175
 176 is equivalent to this:
 177
 178     print "The array is: " . join($", @array) . "\n";
 179
 180 Mnemonic: works in double-quoted context.
 181
 182 =item $PROCESS_ID
 183
 184 =item $PID
 185
 186 =item $$
 187 X<$$> X<$PID> X<$PROCESS_ID>
 188
 189 The process number of the Perl running this script.  Though you I<can> set
 190 this variable, doing so is generally discouraged, although it can be
 191 invaluable for some testing purposes.  It will be reset automatically
 192 across C<fork()> calls.
 193
 194 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
 195 would emulate POSIX semantics on Linux systems using LinuxThreads, a
 196 partial implementation of POSIX Threads that has since been superseded
 197 by the Native POSIX Thread Library (NPTL).
 198
 199 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
 200 like this made embedding perl unnecessarily complex (since you'd have
 201 to manually update the value of $$), so now C<$$> and C<getppid()>
 202 will always return the same values as the underlying C library.
 203
 204 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
 205 including the 6.0 release, but after that moved to FreeBSD thread
 206 semantics, which are POSIX-like.
 207
 208 To see if your system is affected by this discrepancy check if
 209 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
 210 value.  NTPL threads preserve the POSIX semantics.
 211
 212 Mnemonic: same as shells.
 213
 214 =item $PROGRAM_NAME
 215
 216 =item $0
 217 X<$0> X<$PROGRAM_NAME>
 218
 219 Contains the name of the program being executed.
 220
 221 On some (but not all) operating systems assigning to C<$0> modifies
 222 the argument area that the C<ps> program sees.  On some platforms you
 223 may have to use special C<ps> options or a different C<ps> to see the
 224 changes.  Modifying the C<$0> is more useful as a way of indicating the
 225 current program state than it is for hiding the program you're
 226 running.
 227
 228 Note that there are platform-specific limitations on the maximum
 229 length of C<$0>.  In the most extreme case it may be limited to the
 230 space occupied by the original C<$0>.
 231
 232 In some platforms there may be arbitrary amount of padding, for
 233 example space characters, after the modified name as shown by C<ps>.
 234 In some platforms this padding may extend all the way to the original
 235 length of the argument area, no matter what you do (this is the case
 236 for example with Linux 2.2).
 237
 238 Note for BSD users: setting C<$0> does not completely remove "perl"
 239 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
 240 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
 241 and the " (perl)" suffix are shown depends on your exact BSD variant
 242 and version).  This is an operating system feature, Perl cannot help it.
 243
 244 In multithreaded scripts Perl coordinates the threads so that any
 245 thread may modify its copy of the C<$0> and the change becomes visible
 246 to ps(1) (assuming the operating system plays along).  Note that
 247 the view of C<$0> the other threads have will not change since they
 248 have their own copies of it.
 249
 250 If the program has been given to perl via the switches C<-e> or C<-E>,
 251 C<$0> will contain the string C<"-e">.
 252
 253 On Linux as of perl v5.14.0 the legacy process name will be set with
 254 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
 255 perl has done since version 4.000.  Now system utilities that read the
 256 legacy process name such as ps, top and killall will recognize the
 257 name you set when assigning to C<$0>.  The string you supply will be
 258 cut off at 16 bytes, this is a limitation imposed by Linux.
 259
 260 Mnemonic: same as B<sh> and B<ksh>.
 261
 262 =item $REAL_GROUP_ID
 263
 264 =item $GID
 265
 266 =item $(
 267 X<$(> X<$GID> X<$REAL_GROUP_ID>
 268
 269 The real gid of this process.  If you are on a machine that supports
 270 membership in multiple groups simultaneously, gives a space separated
 271 list of groups you are in.  The first number is the one returned by
 272 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
 273 the same as the first number.
 274
 275 However, a value assigned to C<$(> must be a single number used to
 276 set the real gid.  So the value given by C<$(> should I<not> be assigned
 277 back to C<$(> without being forced numeric, such as by adding zero.  Note
 278 that this is different to the effective gid (C<$)>) which does take a
 279 list.
 280
 281 You can change both the real gid and the effective gid at the same
 282 time by using C<POSIX::setgid()>.  Changes
 283 to C<$(> require a check to C<$!>
 284 to detect any possible errors after an attempted change.
 285
 286 Mnemonic: parentheses are used to I<group> things.  The real gid is the
 287 group you I<left>, if you're running setgid.
 288
 289 =item $EFFECTIVE_GROUP_ID
 290
 291 =item $EGID
 292
 293 =item $)
 294 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
 295
 296 The effective gid of this process.  If you are on a machine that
 297 supports membership in multiple groups simultaneously, gives a space
 298 separated list of groups you are in.  The first number is the one
 299 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
 300 one of which may be the same as the first number.
 301
 302 Similarly, a value assigned to C<$)> must also be a space-separated
 303 list of numbers.  The first number sets the effective gid, and
 304 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
 305 empty list for C<setgroups()>, just repeat the new effective gid; that is,
 306 to force an effective gid of 5 and an effectively empty C<setgroups()>
 307 list, say C< $) = "5 5" >.
 308
 309 You can change both the effective gid and the real gid at the same
 310 time by using C<POSIX::setgid()> (use only a single numeric argument).
 311 Changes to C<$)> require a check to C<$!> to detect any possible errors
 312 after an attempted change.
 313
 314 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
 315 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
 316 and C<$)> can be swapped only on machines supporting C<setregid()>.
 317
 318 Mnemonic: parentheses are used to I<group> things.  The effective gid
 319 is the group that's I<right> for you, if you're running setgid.
 320
 321 =item $REAL_USER_ID
 322
 323 =item $UID
 324
 325 =item $<
 326 X<< $< >> X<$UID> X<$REAL_USER_ID>
 327
 328 The real uid of this process.  You can change both the real uid and the
 329 effective uid at the same time by using C<POSIX::setuid()>.  Since
 330 changes to C<< $< >> require a system call, check C<$!> after a change
 331 attempt to detect any possible errors.
 332
 333 Mnemonic: it's the uid you came I<from>, if you're running setuid.
 334
 335 =item $EFFECTIVE_USER_ID
 336
 337 =item $EUID
 338
 339 =item $>
 340 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
 341
 342 The effective uid of this process.  For example:
 343
 344     $< = $>;            # set real to effective uid
 345     ($<,$>) = ($>,$<);  # swap real and effective uids
 346
 347 You can change both the effective uid and the real uid at the same
 348 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
 349 to C<$!> to detect any possible errors after an attempted change.
 350
 351 C<< $< >> and C<< $> >> can be swapped only on machines
 352 supporting C<setreuid()>.
 353
 354 Mnemonic: it's the uid you went I<to>, if you're running setuid.
 355
 356 =item $SUBSCRIPT_SEPARATOR
 357
 358 =item $SUBSEP
 359
 360 =item $;
 361 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
 362
 363 The subscript separator for multidimensional array emulation.  If you
 364 refer to a hash element as
 365
 366     $foo{$x,$y,$z}
 367
 368 it really means
 369
 370     $foo{join($;, $x, $y, $z)}
 371
 372 But don't put
 373
 374     @foo{$x,$y,$z}      # a slice--note the @
 375
 376 which means
 377
 378     ($foo{$x},$foo{$y},$foo{$z})
 379
 380 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
 381 binary data there might not be any safe value for C<$;>.
 382
 383 Consider using "real" multidimensional arrays as described
 384 in L<perllol>.
 385
 386 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
 387
 388 =item $a
 389
 390 =item $b
 391 X<$a> X<$b>
 392
 393 Special package variables when using C<sort()>, see L<perlfunc/sort>.
 394 Because of this specialness C<$a> and C<$b> don't need to be declared
 395 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
 396 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
 397 be able to use them in the C<sort()> comparison block or function.
 398
 399 =item %ENV
 400 X<%ENV>
 401
 402 The hash C<%ENV> contains your current environment.  Setting a
 403 value in C<ENV> changes the environment for any child processes
 404 you subsequently C<fork()> off.
 405
 406 As of v5.18.0, both keys and values stored in C<%ENV> are stringified.
 407
 408     my $foo = 1;
 409     $ENV{'bar'} = \$foo;
 410     if( ref $ENV{'bar'} ) {
 411         say "Pre 5.18.0 Behaviour";
 412     } else {
 413         say "Post 5.18.0 Behaviour";
 414     }
 415
 416 Previously, only child processes received stringified values:
 417
 418     my $foo = 1;
 419     $ENV{'bar'} = \$foo;
 420
 421     # Always printed 'non ref'
 422     system($^X, '-e',
 423            q/print ( ref $ENV{'bar'}  ? 'ref' : 'non ref' ) /);
 424
 425 This happens because you can't really share arbitrary data structures with
 426 foreign processes.
 427
 428 =item $OLD_PERL_VERSION
 429
 430 =item $]
 431 X<$]> X<$OLD_PERL_VERSION>
 432
 433 The revision, version, and subversion of the Perl interpreter, represented
 434 as a decimal of the form 5.XXXYYY, where XXX is the version / 1e3 and YYY
 435 is the subversion / 1e6.  For example, Perl v5.10.1 would be "5.010001".
 436
 437 This variable can be used to determine whether the Perl interpreter
 438 executing a script is in the right range of versions:
 439
 440     warn "No PerlIO!\n" if $] lt '5.008';
 441
 442 When comparing C<$]>, string comparison operators are B<highly
 443 recommended>.  The inherent limitations of binary floating point
 444 representation can sometimes lead to incorrect comparisons for some
 445 numbers on some architectures.
 446
 447 See also the documentation of C<use VERSION> and C<require VERSION>
 448 for a convenient way to fail if the running Perl interpreter is too old.
 449
 450 See L</$^V> for a representation of the Perl version as a L<version>
 451 object, which allows more flexible string comparisons.
 452
 453 The main advantage of C<$]> over C<$^V> is that it works the same on any
 454 version of Perl.  The disadvantages are that it can't easily be compared
 455 to versions in other formats (e.g. literal v-strings, "v1.2.3" or
 456 version objects) and numeric comparisons can occasionally fail; it's good
 457 for string literal version checks and bad for comparing to a variable
 458 that hasn't been sanity-checked.
 459
 460 The C<$OLD_PERL_VERSION> form was added in Perl v5.20.0 for historical
 461 reasons but its use is discouraged. (If your reason to use C<$]> is to
 462 run code on old perls then referring to it as C<$OLD_PERL_VERSION> would
 463 be self-defeating.)
 464
 465 Mnemonic: Is this version of perl in the right bracket?
 466
 467 =item $SYSTEM_FD_MAX
 468
 469 =item $^F
 470 X<$^F> X<$SYSTEM_FD_MAX>
 471
 472 The maximum system file descriptor, ordinarily 2.  System file
 473 descriptors are passed to C<exec()>ed processes, while higher file
 474 descriptors are not.  Also, during an
 475 C<open()>, system file descriptors are
 476 preserved even if the C<open()> fails (ordinary file descriptors are
 477 closed before the C<open()> is attempted).  The close-on-exec
 478 status of a file descriptor will be decided according to the value of
 479 C<$^F> when the corresponding file, pipe, or socket was opened, not the
 480 time of the C<exec()>.
 481
 482 =item @F
 483 X<@F>
 484
 485 The array C<@F> contains the fields of each line read in when autosplit
 486 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
 487 is package-specific, and must be declared or given a full package name
 488 if not in package main when running under C<strict 'vars'>.
 489
 490 =item @INC
 491 X<@INC>
 492
 493 The array C<@INC> contains the list of places that the C<do EXPR>,
 494 C<require>, or C<use> constructs look for their library files.  It
 495 initially consists of the arguments to any B<-I> command-line
 496 switches, followed by the default Perl library, probably
 497 F</usr/local/lib/perl>, followed by ".", to represent the current
 498 directory.  ("." will not be appended if taint checks are enabled,
 499 either by C<-T> or by C<-t>, or if configured not to do so by the
 500 C<-Ddefault_inc_excludes_dot> compile time option.)  If you need to
 501 modify this at runtime, you should use the C<use lib> pragma to get
 502 the machine-dependent library properly loaded also:
 503
 504     use lib '/mypath/libdir/';
 505     use SomeMod;
 506
 507 You can also insert hooks into the file inclusion system by putting Perl
 508 code directly into C<@INC>.  Those hooks may be subroutine references,
 509 array references or blessed objects.  See L<perlfunc/require> for details.
 510
 511 =item %INC
 512 X<%INC>
 513
 514 The hash C<%INC> contains entries for each filename included via the
 515 C<do>, C<require>, or C<use> operators.  The key is the filename
 516 you specified (with module names converted to pathnames), and the
 517 value is the location of the file found.  The C<require>
 518 operator uses this hash to determine whether a particular file has
 519 already been included.
 520
 521 If the file was loaded via a hook (e.g. a subroutine reference, see
 522 L<perlfunc/require> for a description of these hooks), this hook is
 523 by default inserted into C<%INC> in place of a filename.  Note, however,
 524 that the hook may have set the C<%INC> entry by itself to provide some more
 525 specific info.
 526
 527 =item $INPLACE_EDIT
 528
 529 =item $^I
 530 X<$^I> X<$INPLACE_EDIT>
 531
 532 The current value of the inplace-edit extension.  Use C<undef> to disable
 533 inplace editing.
 534
 535 Mnemonic: value of B<-i> switch.
 536
 537 =item @ISA
 538 X<@ISA>
 539
 540 Each package contains a special array called C<@ISA> which contains a list
 541 of that class's parent classes, if any. This array is simply a list of
 542 scalars, each of which is a string that corresponds to a package name. The
 543 array is examined when Perl does method resolution, which is covered in
 544 L<perlobj>.
 545
 546 To load packages while adding them to C<@ISA>, see the L<parent> pragma. The
 547 discouraged L<base> pragma does this as well, but should not be used except
 548 when compatibility with the discouraged L<fields> pragma is required.
 549
 550 =item $^M
 551 X<$^M>
 552
 553 By default, running out of memory is an untrappable, fatal error.
 554 However, if suitably built, Perl can use the contents of C<$^M>
 555 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
 556 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
 557 Then
 558
 559     $^M = 'a' x (1 << 16);
 560
 561 would allocate a 64K buffer for use in an emergency.  See the
 562 F<INSTALL> file in the Perl distribution for information on how to
 563 add custom C compilation flags when compiling perl.  To discourage casual
 564 use of this advanced feature, there is no L<English|English> long name for
 565 this variable.
 566
 567 This variable was added in Perl 5.004.
 568
 569 =item $OSNAME
 570
 571 =item $^O
 572 X<$^O> X<$OSNAME>
 573
 574 The name of the operating system under which this copy of Perl was
 575 built, as determined during the configuration process.  For examples
 576 see L<perlport/PLATFORMS>.
 577
 578 The value is identical to C<$Config{'osname'}>.  See also L<Config>
 579 and the B<-V> command-line switch documented in L<perlrun>.
 580
 581 In Windows platforms, C<$^O> is not very helpful: since it is always
 582 C<MSWin32>, it doesn't tell the difference between
 583 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
 584 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
 585 between the variants.
 586
 587 This variable was added in Perl 5.003.
 588
 589 =item %SIG
 590 X<%SIG>
 591
 592 The hash C<%SIG> contains signal handlers for signals.  For example:
 593
 594     sub handler {   # 1st argument is signal name
 595         my($sig) = @_;
 596         print "Caught a SIG$sig--shutting down\n";
 597         close(LOG);
 598         exit(0);
 599         }
 600
 601     $SIG{'INT'}  = \&handler;
 602     $SIG{'QUIT'} = \&handler;
 603     ...
 604     $SIG{'INT'}  = 'DEFAULT';   # restore default action
 605     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
 606
 607 Using a value of C<'IGNORE'> usually has the effect of ignoring the
 608 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
 609 this special case.
 610
 611 Here are some other examples:
 612
 613     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
 614                                 # recommended)
 615     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
 616                                 # Plumber
 617     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
 618     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
 619                                 # return??
 620
 621 Be sure not to use a bareword as the name of a signal handler,
 622 lest you inadvertently call it.
 623
 624 If your system has the C<sigaction()> function then signal handlers
 625 are installed using it.  This means you get reliable signal handling.
 626
 627 The default delivery policy of signals changed in Perl v5.8.0 from
 628 immediate (also known as "unsafe") to deferred, also known as "safe
 629 signals".  See L<perlipc> for more information.
 630
 631 Certain internal hooks can be also set using the C<%SIG> hash.  The
 632 routine indicated by C<$SIG{__WARN__}> is called when a warning
 633 message is about to be printed.  The warning message is passed as the
 634 first argument.  The presence of a C<__WARN__> hook causes the
 635 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
 636 use this to save warnings in a variable, or turn warnings into fatal
 637 errors, like this:
 638
 639     local $SIG{__WARN__} = sub { die $_[0] };
 640     eval $proggie;
 641
 642 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
 643 disable warnings using the empty subroutine:
 644
 645     local $SIG{__WARN__} = sub {};
 646
 647 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
 648 exception is about to be thrown.  The error message is passed as the
 649 first argument.  When a C<__DIE__> hook routine returns, the exception
 650 processing continues as it would have in the absence of the hook,
 651 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
 652 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
 653 the call, so that you can die from a C<__DIE__> handler.  Similarly
 654 for C<__WARN__>.
 655
 656 The C<$SIG{__DIE__}> hook is called even inside an C<eval()>. It was
 657 never intended to happen this way, but an implementation glitch made
 658 this possible. This used to be deprecated, as it allowed strange action
 659 at a distance like rewriting a pending exception in C<$@>. Plans to
 660 rectify this have been scrapped, as users found that rewriting a
 661 pending exception is actually a useful feature, and not a bug.
 662
 663 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
 664 may be called to report (probable) errors found by the parser.  In such
 665 a case the parser may be in inconsistent state, so any attempt to
 666 evaluate Perl code from such a handler will probably result in a
 667 segfault.  This means that warnings or errors that result from parsing
 668 Perl should be used with extreme caution, like this:
 669
 670     require Carp if defined $^S;
 671     Carp::confess("Something wrong") if defined &Carp::confess;
 672     die "Something wrong, but could not load Carp to give "
 673       . "backtrace...\n\t"
 674       . "To see backtrace try starting Perl with -MCarp switch";
 675
 676 Here the first line will load C<Carp> I<unless> it is the parser who
 677 called the handler.  The second line will print backtrace and die if
 678 C<Carp> was available.  The third line will be executed only if C<Carp> was
 679 not available.
 680
 681 Having to even think about the C<$^S> variable in your exception
 682 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
 683 invites grievous and difficult to track down errors.  Avoid it
 684 and use an C<END{}> or CORE::GLOBAL::die override instead.
 685
 686 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
 687 L<warnings> for additional information.
 688
 689 =item $BASETIME
 690
 691 =item $^T
 692 X<$^T> X<$BASETIME>
 693
 694 The time at which the program began running, in seconds since the
 695 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
 696 and B<-C> filetests are based on this value.
 697
 698 =item $PERL_VERSION
 699
 700 =item $^V
 701 X<$^V> X<$PERL_VERSION>
 702
 703 The revision, version, and subversion of the Perl interpreter,
 704 represented as a L<version> object.
 705
 706 This variable first appeared in perl v5.6.0; earlier versions of perl
 707 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
 708 as a v-string rather than a L<version> object.
 709
 710 C<$^V> can be used to determine whether the Perl interpreter executing
 711 a script is in the right range of versions.  For example:
 712
 713     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
 714
 715 While version objects overload stringification, to portably convert
 716 C<$^V> into its string representation, use C<sprintf()>'s C<"%vd">
 717 conversion, which works for both v-strings or version objects:
 718
 719     printf "version is v%vd\n", $^V;  # Perl's version
 720
 721 See the documentation of C<use VERSION> and C<require VERSION>
 722 for a convenient way to fail if the running Perl interpreter is too old.
 723
 724 See also C<L</$]>> for a decimal representation of the Perl version.
 725
 726 The main advantage of C<$^V> over C<$]> is that, for Perl v5.10.0 or
 727 later, it overloads operators, allowing easy comparison against other
 728 version representations (e.g. decimal, literal v-string, "v1.2.3", or
 729 objects).  The disadvantage is that prior to v5.10.0, it was only a
 730 literal v-string, which can't be easily printed or compared, whereas
 731 the behavior of C<$]> is unchanged on all versions of Perl.
 732
 733 Mnemonic: use ^V for a version object.
 734
 735 =item ${^WIN32_SLOPPY_STAT}
 736 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
 737
 738 If this variable is set to a true value, then C<stat()> on Windows will
 739 not try to open the file.  This means that the link count cannot be
 740 determined and file attributes may be out of date if additional
 741 hardlinks to the file exist.  On the other hand, not opening the file
 742 is considerably faster, especially for files on network drives.
 743
 744 This variable could be set in the F<sitecustomize.pl> file to
 745 configure the local Perl installation to use "sloppy" C<stat()> by
 746 default.  See the documentation for B<-f> in
 747 L<perlrun|perlrun/"Command Switches"> for more information about site
 748 customization.
 749
 750 This variable was added in Perl v5.10.0.
 751
 752 =item $EXECUTABLE_NAME
 753
 754 =item $^X
 755 X<$^X> X<$EXECUTABLE_NAME>
 756
 757 The name used to execute the current copy of Perl, from C's
 758 C<argv[0]> or (where supported) F</proc/self/exe>.
 759
 760 Depending on the host operating system, the value of C<$^X> may be
 761 a relative or absolute pathname of the perl program file, or may
 762 be the string used to invoke perl but not the pathname of the
 763 perl program file.  Also, most operating systems permit invoking
 764 programs that are not in the PATH environment variable, so there
 765 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
 766 value may or may not include a version number.
 767
 768 You usually can use the value of C<$^X> to re-invoke an independent
 769 copy of the same perl that is currently running, e.g.,
 770
 771     @first_run = `$^X -le "print int rand 100 for 1..100"`;
 772
 773 But recall that not all operating systems support forking or
 774 capturing of the output of commands, so this complex statement
 775 may not be portable.
 776
 777 It is not safe to use the value of C<$^X> as a path name of a file,
 778 as some operating systems that have a mandatory suffix on
 779 executable files do not require use of the suffix when invoking
 780 a command.  To convert the value of C<$^X> to a path name, use the
 781 following statements:
 782
 783     # Build up a set of file names (not command names).
 784     use Config;
 785     my $this_perl = $^X;
 786     if ($^O ne 'VMS') {
 787         $this_perl .= $Config{_exe}
 788           unless $this_perl =~ m/$Config{_exe}$/i;
 789         }
 790
 791 Because many operating systems permit anyone with read access to
 792 the Perl program file to make a copy of it, patch the copy, and
 793 then execute the copy, the security-conscious Perl programmer
 794 should take care to invoke the installed copy of perl, not the
 795 copy referenced by C<$^X>.  The following statements accomplish
 796 this goal, and produce a pathname that can be invoked as a
 797 command or referenced as a file.
 798
 799     use Config;
 800     my $secure_perl_path = $Config{perlpath};
 801     if ($^O ne 'VMS') {
 802         $secure_perl_path .= $Config{_exe}
 803             unless $secure_perl_path =~ m/$Config{_exe}$/i;
 804         }
 805
 806 =back
 807
 808 =head2 Variables related to regular expressions
 809
 810 Most of the special variables related to regular expressions are side
 811 effects.  Perl sets these variables when it has a successful match, so
 812 you should check the match result before using them.  For instance:
 813
 814     if( /P(A)TT(ER)N/ ) {
 815         print "I found $1 and $2\n";
 816         }
 817
 818 These variables are read-only and dynamically-scoped, unless we note
 819 otherwise.
 820
 821 The dynamic nature of the regular expression variables means that
 822 their value is limited to the block that they are in, as demonstrated
 823 by this bit of code:
 824
 825     my $outer = 'Wallace and Grommit';
 826     my $inner = 'Mutt and Jeff';
 827
 828     my $pattern = qr/(\S+) and (\S+)/;
 829
 830     sub show_n { print "\$1 is $1; \$2 is $2\n" }
 831
 832     {
 833     OUTER:
 834         show_n() if $outer =~ m/$pattern/;
 835
 836         INNER: {
 837             show_n() if $inner =~ m/$pattern/;
 838             }
 839
 840         show_n();
 841     }
 842
 843 The output shows that while in the C<OUTER> block, the values of C<$1>
 844 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
 845 block, the values of C<$1> and C<$2> are from the match against
 846 C<$inner>, but only until the end of the block (i.e. the dynamic
 847 scope).  After the C<INNER> block completes, the values of C<$1> and
 848 C<$2> return to the values for the match against C<$outer> even though
 849 we have not made another match:
 850
 851     $1 is Wallace; $2 is Grommit
 852     $1 is Mutt; $2 is Jeff
 853     $1 is Wallace; $2 is Grommit
 854
 855 =head3 Performance issues
 856
 857 Traditionally in Perl, any use of any of the three variables  C<$`>, C<$&>
 858 or C<$'> (or their C<use English> equivalents) anywhere in the code, caused
 859 all subsequent successful pattern matches to make a copy of the matched
 860 string, in case the code might subsequently access one of those variables.
 861 This imposed a considerable performance penalty across the whole program,
 862 so generally the use of these variables has been discouraged.
 863
 864 In Perl 5.6.0 the C<@-> and C<@+> dynamic arrays were introduced that
 865 supply the indices of successful matches. So you could for example do
 866 this:
 867
 868     $str =~ /pattern/;
 869
 870     print $`, $&, $'; # bad: performance hit
 871
 872     print             # good: no performance hit
 873         substr($str, 0,     $-[0]),
 874         substr($str, $-[0], $+[0]-$-[0]),
 875         substr($str, $+[0]);
 876
 877 In Perl 5.10.0 the C</p> match operator flag and the C<${^PREMATCH}>,
 878 C<${^MATCH}>, and C<${^POSTMATCH}> variables were introduced, that allowed
 879 you to suffer the penalties only on patterns marked with C</p>.
 880
 881 In Perl 5.18.0 onwards, perl started noting the presence of each of the
 882 three variables separately, and only copied that part of the string
 883 required; so in
 884
 885     $`; $&; "abcdefgh" =~ /d/
 886
 887 perl would only copy the "abcd" part of the string. That could make a big
 888 difference in something like
 889
 890     $str = 'x' x 1_000_000;
 891     $&; # whoops
 892     $str =~ /x/g # one char copied a million times, not a million chars
 893
 894 In Perl 5.20.0 a new copy-on-write system was enabled by default, which
 895 finally fixes all performance issues with these three variables, and makes
 896 them safe to use anywhere.
 897
 898 The C<Devel::NYTProf> and C<Devel::FindAmpersand> modules can help you
 899 find uses of these problematic match variables in your code.
 900
 901 =over 8
 902
 903 =item $<I<digits>> ($1, $2, ...)
 904 X<$1> X<$2> X<$3> X<$I<digits>>
 905
 906 Contains the subpattern from the corresponding set of capturing
 907 parentheses from the last successful pattern match, not counting patterns
 908 matched in nested blocks that have been exited already.
 909
 910 Note there is a distinction between a capture buffer which matches
 911 the empty string a capture buffer which is optional. Eg, C<(x?)> and
 912 C<(x)?> The latter may be undef, the former not.
 913
 914 These variables are read-only and dynamically-scoped.
 915
 916 Mnemonic: like \digits.
 917
 918 =item @{^CAPTURE}
 919 X<@{^CAPTURE}> X<@^CAPTURE>
 920
 921 An array which exposes the contents of the capture buffers, if any, of
 922 the last successful pattern match, not counting patterns matched
 923 in nested blocks that have been exited already.
 924
 925 Note that the 0 index of @{^CAPTURE} is equivalent to $1, the 1 index
 926 is equivalent to $2, etc.
 927
 928     if ("foal"=~/(.)(.)(.)(.)/) {
 929         print join "-", @{^CAPTURE};
 930     }
 931
 932 should output "f-o-a-l".
 933
 934 See also L</$I<digits>>, L</%{^CAPTURE}> and L</%{^CAPTURE_ALL}>.
 935
 936 Note that unlike most other regex magic variables there is no single
 937 letter equivalent to C<@{^CAPTURE}>.
 938
 939 This variable was added in 5.25.7
 940
 941 =item $MATCH
 942
 943 =item $&
 944 X<$&> X<$MATCH>
 945
 946 The string matched by the last successful pattern match (not counting
 947 any matches hidden within a BLOCK or C<eval()> enclosed by the current
 948 BLOCK).
 949
 950 See L</Performance issues> above for the serious performance implications
 951 of using this variable (even once) in your code.
 952
 953 This variable is read-only and dynamically-scoped.
 954
 955 Mnemonic: like C<&> in some editors.
 956
 957 =item ${^MATCH}
 958 X<${^MATCH}>
 959
 960 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
 961 performance penalty associated with that variable.
 962
 963 See L</Performance issues> above.
 964
 965 In Perl v5.18 and earlier, it is only guaranteed
 966 to return a defined value when the pattern was compiled or executed with
 967 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
 968 C<${^MATCH}> does the same thing as C<$MATCH>.
 969
 970 This variable was added in Perl v5.10.0.
 971
 972 This variable is read-only and dynamically-scoped.
 973
 974 =item $PREMATCH
 975
 976 =item $`
 977 X<$`> X<$PREMATCH> X<${^PREMATCH}>
 978
 979 The string preceding whatever was matched by the last successful
 980 pattern match, not counting any matches hidden within a BLOCK or C<eval>
 981 enclosed by the current BLOCK.
 982
 983 See L</Performance issues> above for the serious performance implications
 984 of using this variable (even once) in your code.
 985
 986 This variable is read-only and dynamically-scoped.
 987
 988 Mnemonic: C<`> often precedes a quoted string.
 989
 990 =item ${^PREMATCH}
 991 X<$`> X<${^PREMATCH}>
 992
 993 This is similar to C<$`> ($PREMATCH) except that it does not incur the
 994 performance penalty associated with that variable.
 995
 996 See L</Performance issues> above.
 997
 998 In Perl v5.18 and earlier, it is only guaranteed
 999 to return a defined value when the pattern was compiled or executed with
1000 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1001 C<${^PREMATCH}> does the same thing as C<$PREMATCH>.
1002
1003 This variable was added in Perl v5.10.0.
1004
1005 This variable is read-only and dynamically-scoped.
1006
1007 =item $POSTMATCH
1008
1009 =item $'
1010 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
1011
1012 The string following whatever was matched by the last successful
1013 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
1014 enclosed by the current BLOCK).  Example:
1015
1016     local $_ = 'abcdefghi';
1017     /def/;
1018     print "$`:$&:$'\n";         # prints abc:def:ghi
1019
1020 See L</Performance issues> above for the serious performance implications
1021 of using this variable (even once) in your code.
1022
1023 This variable is read-only and dynamically-scoped.
1024
1025 Mnemonic: C<'> often follows a quoted string.
1026
1027 =item ${^POSTMATCH}
1028 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
1029
1030 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
1031 performance penalty associated with that variable.
1032
1033 See L</Performance issues> above.
1034
1035 In Perl v5.18 and earlier, it is only guaranteed
1036 to return a defined value when the pattern was compiled or executed with
1037 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1038 C<${^POSTMATCH}> does the same thing as C<$POSTMATCH>.
1039
1040 This variable was added in Perl v5.10.0.
1041
1042 This variable is read-only and dynamically-scoped.
1043
1044 =item $LAST_PAREN_MATCH
1045
1046 =item $+
1047 X<$+> X<$LAST_PAREN_MATCH>
1048
1049 The text matched by the highest used capture group of the last
1050 successful search pattern.  It is logically equivalent to the highest
1051 numbered capture variable (C<$1>, C<$2>, ...) which has a defined value.
1052
1053 This is useful if you don't know which one of a set of alternative patterns
1054 matched.  For example:
1055
1056     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1057
1058 This variable is read-only and dynamically-scoped.
1059
1060 Mnemonic: be positive and forward looking.
1061
1062 =item $LAST_SUBMATCH_RESULT
1063
1064 =item $^N
1065 X<$^N> X<$LAST_SUBMATCH_RESULT>
1066
1067 The text matched by the used group most-recently closed (i.e. the group
1068 with the rightmost closing parenthesis) of the last successful search
1069 pattern. This is subtly different from C<$+>. For example in
1070
1071     "ab" =~ /^((.)(.))$/
1072
1073 we have
1074
1075     $1,$^N   have the value "ab"
1076     $2       has  the value "a"
1077     $3,$+    have the value "b"
1078
1079 This is primarily used inside C<(?{...})> blocks for examining text
1080 recently matched.  For example, to effectively capture text to a variable
1081 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1082
1083     (?:(...)(?{ $var = $^N }))
1084
1085 By setting and then using C<$var> in this way relieves you from having to
1086 worry about exactly which numbered set of parentheses they are.
1087
1088 This variable was added in Perl v5.8.0.
1089
1090 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1091
1092 =item @LAST_MATCH_END
1093
1094 =item @+
1095 X<@+> X<@LAST_MATCH_END>
1096
1097 This array holds the offsets of the ends of the last successful
1098 submatches in the currently active dynamic scope.  C<$+[0]> is
1099 the offset into the string of the end of the entire match.  This
1100 is the same value as what the C<pos> function returns when called
1101 on the variable that was matched against.  The I<n>th element
1102 of this array holds the offset of the I<n>th submatch, so
1103 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1104 past where C<$2> ends, and so on.  You can use C<$#+> to determine
1105 how many subgroups were in the last successful match.  See the
1106 examples given for the C<@-> variable.
1107
1108 This variable was added in Perl v5.6.0.
1109
1110 =item %{^CAPTURE}
1111
1112 =item %LAST_PAREN_MATCH
1113
1114 =item %+
1115 X<%+> X<%LAST_PAREN_MATCH> X<%{^CAPTURE}>
1116
1117 Similar to C<@+>, the C<%+> hash allows access to the named capture
1118 buffers, should they exist, in the last successful match in the
1119 currently active dynamic scope.
1120
1121 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1122
1123     'foo' =~ /(?<foo>foo)/;
1124
1125 The keys of the C<%+> hash list only the names of buffers that have
1126 captured (and that are thus associated to defined values).
1127
1128 If multiple distinct capture groups have the same name, then
1129 C<$+{NAME}> will refer to the leftmost defined group in the match.
1130
1131 The underlying behaviour of C<%+> is provided by the
1132 L<Tie::Hash::NamedCapture> module.
1133
1134 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1135 associated with the last successful regular expression.  Therefore mixing
1136 iterative access to them via C<each> may have unpredictable results.
1137 Likewise, if the last successful match changes, then the results may be
1138 surprising.
1139
1140 This variable was added in Perl v5.10.0. The C<%{^CAPTURE}> alias was
1141 added in 5.25.7.
1142
1143 This variable is read-only and dynamically-scoped.
1144
1145 =item @LAST_MATCH_START
1146
1147 =item @-
1148 X<@-> X<@LAST_MATCH_START>
1149
1150 C<$-[0]> is the offset of the start of the last successful match.
1151 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1152 I<n>-th subpattern, or undef if the subpattern did not match.
1153
1154 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1155 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1156 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1157 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1158 last matched subgroup in the last successful match.  Contrast with
1159 C<$#+>, the number of subgroups in the regular expression.  Compare
1160 with C<@+>.
1161
1162 This array holds the offsets of the beginnings of the last
1163 successful submatches in the currently active dynamic scope.
1164 C<$-[0]> is the offset into the string of the beginning of the
1165 entire match.  The I<n>th element of this array holds the offset
1166 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1167 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1168
1169 After a match against some variable C<$var>:
1170
1171 =over 5
1172
1173 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1174
1175 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1176
1177 =item C<$'> is the same as C<substr($var, $+[0])>
1178
1179 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1180
1181 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1182
1183 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1184
1185 =back
1186
1187 This variable was added in Perl v5.6.0.
1188
1189 =item %{^CAPTURE_ALL}
1190 X<%{^CAPTURE_ALL}>
1191
1192 =item %-
1193 X<%->
1194
1195 Similar to C<%+>, this variable allows access to the named capture groups
1196 in the last successful match in the currently active dynamic scope.  To
1197 each capture group name found in the regular expression, it associates a
1198 reference to an array containing the list of values captured by all
1199 buffers with that name (should there be several of them), in the order
1200 where they appear.
1201
1202 Here's an example:
1203
1204     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1205         foreach my $bufname (sort keys %-) {
1206             my $ary = $-{$bufname};
1207             foreach my $idx (0..$#$ary) {
1208                 print "\$-{$bufname}[$idx] : ",
1209                       (defined($ary->[$idx])
1210                           ? "'$ary->[$idx]'"
1211                           : "undef"),
1212                       "\n";
1213             }
1214         }
1215     }
1216
1217 would print out:
1218
1219     $-{A}[0] : '1'
1220     $-{A}[1] : '3'
1221     $-{B}[0] : '2'
1222     $-{B}[1] : '4'
1223
1224 The keys of the C<%-> hash correspond to all buffer names found in
1225 the regular expression.
1226
1227 The behaviour of C<%-> is implemented via the
1228 L<Tie::Hash::NamedCapture> module.
1229
1230 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1231 associated with the last successful regular expression.  Therefore mixing
1232 iterative access to them via C<each> may have unpredictable results.
1233 Likewise, if the last successful match changes, then the results may be
1234 surprising.
1235
1236 This variable was added in Perl v5.10.0. The C<%{^CAPTURE_ALL}> alias was
1237 added in 5.25.7.
1238
1239 This variable is read-only and dynamically-scoped.
1240
1241 =item $LAST_REGEXP_CODE_RESULT
1242
1243 =item $^R
1244 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1245
1246 The result of evaluation of the last successful C<(?{ code })>
1247 regular expression assertion (see L<perlre>).  May be written to.
1248
1249 This variable was added in Perl 5.005.
1250
1251 =item ${^RE_DEBUG_FLAGS}
1252 X<${^RE_DEBUG_FLAGS}>
1253
1254 The current value of the regex debugging flags.  Set to 0 for no debug output
1255 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1256
1257 This variable was added in Perl v5.10.0.
1258
1259 =item ${^RE_TRIE_MAXBUF}
1260 X<${^RE_TRIE_MAXBUF}>
1261
1262 Controls how certain regex optimisations are applied and how much memory they
1263 utilize.  This value by default is 65536 which corresponds to a 512kB
1264 temporary cache.  Set this to a higher value to trade
1265 memory for speed when matching large alternations.  Set
1266 it to a lower value if you want the optimisations to
1267 be as conservative of memory as possible but still occur, and set it to a
1268 negative value to prevent the optimisation and conserve the most memory.
1269 Under normal situations this variable should be of no interest to you.
1270
1271 This variable was added in Perl v5.10.0.
1272
1273 =back
1274
1275 =head2 Variables related to filehandles
1276
1277 Variables that depend on the currently selected filehandle may be set
1278 by calling an appropriate object method on the C<IO::Handle> object,
1279 although this is less efficient than using the regular built-in
1280 variables.  (Summary lines below for this contain the word HANDLE.)
1281 First you must say
1282
1283     use IO::Handle;
1284
1285 after which you may use either
1286
1287     method HANDLE EXPR
1288
1289 or more safely,
1290
1291     HANDLE->method(EXPR)
1292
1293 Each method returns the old value of the C<IO::Handle> attribute.  The
1294 methods each take an optional EXPR, which, if supplied, specifies the
1295 new value for the C<IO::Handle> attribute in question.  If not
1296 supplied, most methods do nothing to the current value--except for
1297 C<autoflush()>, which will assume a 1 for you, just to be different.
1298
1299 Because loading in the C<IO::Handle> class is an expensive operation,
1300 you should learn how to use the regular built-in variables.
1301
1302 A few of these variables are considered "read-only".  This means that
1303 if you try to assign to this variable, either directly or indirectly
1304 through a reference, you'll raise a run-time exception.
1305
1306 You should be very careful when modifying the default values of most
1307 special variables described in this document.  In most cases you want
1308 to localize these variables before changing them, since if you don't,
1309 the change may affect other modules which rely on the default values
1310 of the special variables that you have changed.  This is one of the
1311 correct ways to read the whole file at once:
1312
1313     open my $fh, "<", "foo" or die $!;
1314     local $/; # enable localized slurp mode
1315     my $content = <$fh>;
1316     close $fh;
1317
1318 But the following code is quite bad:
1319
1320     open my $fh, "<", "foo" or die $!;
1321     undef $/; # enable slurp mode
1322     my $content = <$fh>;
1323     close $fh;
1324
1325 since some other module, may want to read data from some file in the
1326 default "line mode", so if the code we have just presented has been
1327 executed, the global value of C<$/> is now changed for any other code
1328 running inside the same Perl interpreter.
1329
1330 Usually when a variable is localized you want to make sure that this
1331 change affects the shortest scope possible.  So unless you are already
1332 inside some short C<{}> block, you should create one yourself.  For
1333 example:
1334
1335     my $content = '';
1336     open my $fh, "<", "foo" or die $!;
1337     {
1338         local $/;
1339         $content = <$fh>;
1340     }
1341     close $fh;
1342
1343 Here is an example of how your own code can go broken:
1344
1345     for ( 1..3 ){
1346         $\ = "\r\n";
1347         nasty_break();
1348         print "$_";
1349     }
1350
1351     sub nasty_break {
1352         $\ = "\f";
1353         # do something with $_
1354     }
1355
1356 You probably expect this code to print the equivalent of
1357
1358     "1\r\n2\r\n3\r\n"
1359
1360 but instead you get:
1361
1362     "1\f2\f3\f"
1363
1364 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1365 first.  The value you set in  C<nasty_break()> is still there when you
1366 return.  The fix is to add C<local()> so the value doesn't leak out of
1367 C<nasty_break()>:
1368
1369     local $\ = "\f";
1370
1371 It's easy to notice the problem in such a short example, but in more
1372 complicated code you are looking for trouble if you don't localize
1373 changes to the special variables.
1374
1375 =over 8
1376
1377 =item $ARGV
1378 X<$ARGV>
1379
1380 Contains the name of the current file when reading from C<< <> >>.
1381
1382 =item @ARGV
1383 X<@ARGV>
1384
1385 The array C<@ARGV> contains the command-line arguments intended for
1386 the script.  C<$#ARGV> is generally the number of arguments minus
1387 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1388 command name itself.  See L</$0> for the command name.
1389
1390 =item ARGV
1391 X<ARGV>
1392
1393 The special filehandle that iterates over command-line filenames in
1394 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1395 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1396 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1397 corresponding to the last file opened by C<< <> >>.  In particular,
1398 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1399 may not cause your function to automatically read the contents of all the
1400 files in C<@ARGV>.
1401
1402 =item ARGVOUT
1403 X<ARGVOUT>
1404
1405 The special filehandle that points to the currently open output file
1406 when doing edit-in-place processing with B<-i>.  Useful when you have
1407 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1408 L<perlrun> for the B<-i> switch.
1409
1410 =item IO::Handle->output_field_separator( EXPR )
1411
1412 =item $OUTPUT_FIELD_SEPARATOR
1413
1414 =item $OFS
1415
1416 =item $,
1417 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1418
1419 The output field separator for the print operator.  If defined, this
1420 value is printed between each of print's arguments.  Default is C<undef>.
1421
1422 You cannot call C<output_field_separator()> on a handle, only as a
1423 static method.  See L<IO::Handle|IO::Handle>.
1424
1425 Mnemonic: what is printed when there is a "," in your print statement.
1426
1427 =item HANDLE->input_line_number( EXPR )
1428
1429 =item $INPUT_LINE_NUMBER
1430
1431 =item $NR
1432
1433 =item $.
1434 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1435
1436 Current line number for the last filehandle accessed.
1437
1438 Each filehandle in Perl counts the number of lines that have been read
1439 from it.  (Depending on the value of C<$/>, Perl's idea of what
1440 constitutes a line may not match yours.)  When a line is read from a
1441 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1442 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1443 for that filehandle.
1444
1445 You can adjust the counter by assigning to C<$.>, but this will not
1446 actually move the seek pointer.  I<Localizing C<$.> will not localize
1447 the filehandle's line count>.  Instead, it will localize perl's notion
1448 of which filehandle C<$.> is currently aliased to.
1449
1450 C<$.> is reset when the filehandle is closed, but B<not> when an open
1451 filehandle is reopened without an intervening C<close()>.  For more
1452 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1453 an explicit close, line numbers increase across C<ARGV> files (but see
1454 examples in L<perlfunc/eof>).
1455
1456 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1457 line counter for a given filehandle without having to worry about
1458 which handle you last accessed.
1459
1460 Mnemonic: many programs use "." to mean the current line number.
1461
1462 =item IO::Handle->input_record_separator( EXPR )
1463
1464 =item $INPUT_RECORD_SEPARATOR
1465
1466 =item $RS
1467
1468 =item $/
1469 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1470
1471 The input record separator, newline by default.  This influences Perl's
1472 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1473 treating empty lines as a terminator if set to the null string (an
1474 empty line cannot contain any spaces or tabs).  You may set it to a
1475 multi-character string to match a multi-character terminator, or to
1476 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1477 means something slightly different than setting to C<"">, if the file
1478 contains consecutive empty lines.  Setting to C<""> will treat two or
1479 more consecutive empty lines as a single empty line.  Setting to
1480 C<"\n\n"> will blindly assume that the next input character belongs to
1481 the next paragraph, even if it's a newline.
1482
1483     local $/;           # enable "slurp" mode
1484     local $_ = <FH>;    # whole file now here
1485     s/\n[ \t]+/ /g;
1486
1487 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1488 be better for something. :-)
1489
1490 Setting C<$/> to a reference to an integer, scalar containing an
1491 integer, or scalar that's convertible to an integer will attempt to
1492 read records instead of lines, with the maximum record size being the
1493 referenced integer number of characters.  So this:
1494
1495     local $/ = \32768; # or \"32768", or \$var_containing_32768
1496     open my $fh, "<", $myfile or die $!;
1497     local $_ = <$fh>;
1498
1499 will read a record of no more than 32768 characters from $fh.  If you're
1500 not reading from a record-oriented file (or your OS doesn't have
1501 record-oriented files), then you'll likely get a full chunk of data
1502 with every read.  If a record is larger than the record size you've
1503 set, you'll get the record back in pieces.  Trying to set the record
1504 size to zero or less is deprecated and will cause $/ to have the value
1505 of "undef", which will cause reading in the (rest of the) whole file.
1506
1507 As of 5.19.9 setting C<$/> to any other form of reference will throw a
1508 fatal exception. This is in preparation for supporting new ways to set
1509 C<$/> in the future.
1510
1511 On VMS only, record reads bypass PerlIO layers and any associated
1512 buffering, so you must not mix record and non-record reads on the
1513 same filehandle.  Record mode mixes with line mode only when the
1514 same buffering layer is in use for both modes.
1515
1516 You cannot call C<input_record_separator()> on a handle, only as a
1517 static method.  See L<IO::Handle|IO::Handle>.
1518
1519 See also L<perlport/"Newlines">.  Also see L</$.>.
1520
1521 Mnemonic: / delimits line boundaries when quoting poetry.
1522
1523 =item IO::Handle->output_record_separator( EXPR )
1524
1525 =item $OUTPUT_RECORD_SEPARATOR
1526
1527 =item $ORS
1528
1529 =item $\
1530 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1531
1532 The output record separator for the print operator.  If defined, this
1533 value is printed after the last of print's arguments.  Default is C<undef>.
1534
1535 You cannot call C<output_record_separator()> on a handle, only as a
1536 static method.  See L<IO::Handle|IO::Handle>.
1537
1538 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1539 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1540
1541 =item HANDLE->autoflush( EXPR )
1542
1543 =item $OUTPUT_AUTOFLUSH
1544
1545 =item $|
1546 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1547
1548 If set to nonzero, forces a flush right away and after every write or
1549 print on the currently selected output channel.  Default is 0
1550 (regardless of whether the channel is really buffered by the system or
1551 not; C<$|> tells you only whether you've asked Perl explicitly to
1552 flush after each write).  STDOUT will typically be line buffered if
1553 output is to the terminal and block buffered otherwise.  Setting this
1554 variable is useful primarily when you are outputting to a pipe or
1555 socket, such as when you are running a Perl program under B<rsh> and
1556 want to see the output as it's happening.  This has no effect on input
1557 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1558 how to select the output channel.  See also L<IO::Handle>.
1559
1560 Mnemonic: when you want your pipes to be piping hot.
1561
1562 =item ${^LAST_FH}
1563 X<${^LAST_FH}>
1564
1565 This read-only variable contains a reference to the last-read filehandle.
1566 This is set by C<< <HANDLE> >>, C<readline>, C<tell>, C<eof> and C<seek>.
1567 This is the same handle that C<$.> and C<tell> and C<eof> without arguments
1568 use.  It is also the handle used when Perl appends ", <STDIN> line 1" to
1569 an error or warning message.
1570
1571 This variable was added in Perl v5.18.0.
1572
1573 =back
1574
1575 =head3 Variables related to formats
1576
1577 The special variables for formats are a subset of those for
1578 filehandles.  See L<perlform> for more information about Perl's
1579 formats.
1580
1581 =over 8
1582
1583 =item $ACCUMULATOR
1584
1585 =item $^A
1586 X<$^A> X<$ACCUMULATOR>
1587
1588 The current value of the C<write()> accumulator for C<format()> lines.
1589 A format contains C<formline()> calls that put their result into
1590 C<$^A>.  After calling its format, C<write()> prints out the contents
1591 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1592 unless you call C<formline()> yourself and then look at it.  See
1593 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1594
1595 =item IO::Handle->format_formfeed(EXPR)
1596
1597 =item $FORMAT_FORMFEED
1598
1599 =item $^L
1600 X<$^L> X<$FORMAT_FORMFEED>
1601
1602 What formats output as a form feed.  The default is C<\f>.
1603
1604 You cannot call C<format_formfeed()> on a handle, only as a static
1605 method.  See L<IO::Handle|IO::Handle>.
1606
1607 =item HANDLE->format_page_number(EXPR)
1608
1609 =item $FORMAT_PAGE_NUMBER
1610
1611 =item $%
1612 X<$%> X<$FORMAT_PAGE_NUMBER>
1613
1614 The current page number of the currently selected output channel.
1615
1616 Mnemonic: C<%> is page number in B<nroff>.
1617
1618 =item HANDLE->format_lines_left(EXPR)
1619
1620 =item $FORMAT_LINES_LEFT
1621
1622 =item $-
1623 X<$-> X<$FORMAT_LINES_LEFT>
1624
1625 The number of lines left on the page of the currently selected output
1626 channel.
1627
1628 Mnemonic: lines_on_page - lines_printed.
1629
1630 =item IO::Handle->format_line_break_characters EXPR
1631
1632 =item $FORMAT_LINE_BREAK_CHARACTERS
1633
1634 =item $:
1635 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1636
1637 The current set of characters after which a string may be broken to
1638 fill continuation fields (starting with C<^>) in a format.  The default is
1639 S<" \n-">, to break on a space, newline, or a hyphen.
1640
1641 You cannot call C<format_line_break_characters()> on a handle, only as
1642 a static method.  See L<IO::Handle|IO::Handle>.
1643
1644 Mnemonic: a "colon" in poetry is a part of a line.
1645
1646 =item HANDLE->format_lines_per_page(EXPR)
1647
1648 =item $FORMAT_LINES_PER_PAGE
1649
1650 =item $=
1651 X<$=> X<$FORMAT_LINES_PER_PAGE>
1652
1653 The current page length (printable lines) of the currently selected
1654 output channel.  The default is 60.
1655
1656 Mnemonic: = has horizontal lines.
1657
1658 =item HANDLE->format_top_name(EXPR)
1659
1660 =item $FORMAT_TOP_NAME
1661
1662 =item $^
1663 X<$^> X<$FORMAT_TOP_NAME>
1664
1665 The name of the current top-of-page format for the currently selected
1666 output channel.  The default is the name of the filehandle with C<_TOP>
1667 appended.  For example, the default format top name for the C<STDOUT>
1668 filehandle is C<STDOUT_TOP>.
1669
1670 Mnemonic: points to top of page.
1671
1672 =item HANDLE->format_name(EXPR)
1673
1674 =item $FORMAT_NAME
1675
1676 =item $~
1677 X<$~> X<$FORMAT_NAME>
1678
1679 The name of the current report format for the currently selected
1680 output channel.  The default format name is the same as the filehandle
1681 name.  For example, the default format name for the C<STDOUT>
1682 filehandle is just C<STDOUT>.
1683
1684 Mnemonic: brother to C<$^>.
1685
1686 =back
1687
1688 =head2 Error Variables
1689 X<error> X<exception>
1690
1691 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1692 about different types of error conditions that may appear during
1693 execution of a Perl program.  The variables are shown ordered by
1694 the "distance" between the subsystem which reported the error and
1695 the Perl process.  They correspond to errors detected by the Perl
1696 interpreter, C library, operating system, or an external program,
1697 respectively.
1698
1699 To illustrate the differences between these variables, consider the
1700 following Perl expression, which uses a single-quoted string.  After
1701 execution of this statement, perl may have set all four special error
1702 variables:
1703
1704     eval q{
1705         open my $pipe, "/cdrom/install |" or die $!;
1706         my @res = <$pipe>;
1707         close $pipe or die "bad pipe: $?, $!";
1708     };
1709
1710 When perl executes the C<eval()> expression, it translates the
1711 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1712 and thence to the operating system kernel.  perl sets C<$!> to
1713 the C library's C<errno> if one of these calls fails.
1714
1715 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1716 happen if C<open> or C<close> were imported with bad prototypes), or
1717 if Perl code executed during evaluation C<die()>d.  In these cases the
1718 value of C<$@> is the compile error, or the argument to C<die> (which
1719 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1720
1721 Under a few operating systems, C<$^E> may contain a more verbose error
1722 indicator, such as in this case, "CDROM tray not closed."  Systems that
1723 do not support extended error messages leave C<$^E> the same as C<$!>.
1724
1725 Finally, C<$?> may be set to a non-0 value if the external program
1726 F</cdrom/install> fails.  The upper eight bits reflect specific error
1727 conditions encountered by the program (the program's C<exit()> value).
1728 The lower eight bits reflect mode of failure, like signal death and
1729 core dump information.  See L<wait(2)> for details.  In contrast to
1730 C<$!> and C<$^E>, which are set only if an error condition is detected,
1731 the variable C<$?> is set on each C<wait> or pipe C<close>,
1732 overwriting the old value.  This is more like C<$@>, which on every
1733 C<eval()> is always set on failure and cleared on success.
1734
1735 For more details, see the individual descriptions at C<$@>, C<$!>,
1736 C<$^E>, and C<$?>.
1737
1738 =over 8
1739
1740 =item ${^CHILD_ERROR_NATIVE}
1741 X<$^CHILD_ERROR_NATIVE>
1742
1743 The native status returned by the last pipe close, backtick (C<``>)
1744 command, successful call to C<wait()> or C<waitpid()>, or from the
1745 C<system()> operator.  On POSIX-like systems this value can be decoded
1746 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1747 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1748
1749 Under VMS this reflects the actual VMS exit status; i.e. it is the
1750 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1751
1752 This variable was added in Perl v5.10.0.
1753
1754 =item $EXTENDED_OS_ERROR
1755
1756 =item $^E
1757 X<$^E> X<$EXTENDED_OS_ERROR>
1758
1759 Error information specific to the current operating system.  At the
1760 moment, this differs from C<L</$!>> under only VMS, OS/2, and Win32 (and
1761 for MacPerl).  On all other platforms, C<$^E> is always just the same
1762 as C<$!>.
1763
1764 Under VMS, C<$^E> provides the VMS status value from the last system
1765 error.  This is more specific information about the last system error
1766 than that provided by C<$!>.  This is particularly important when C<$!>
1767 is set to B<EVMSERR>.
1768
1769 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1770 API either via CRT, or directly from perl.
1771
1772 Under Win32, C<$^E> always returns the last error information reported
1773 by the Win32 call C<GetLastError()> which describes the last error
1774 from within the Win32 API.  Most Win32-specific code will report errors
1775 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1776 portable Perl code will report errors via C<$!>.
1777
1778 Caveats mentioned in the description of C<L</$!>> generally apply to
1779 C<$^E>, also.
1780
1781 This variable was added in Perl 5.003.
1782
1783 Mnemonic: Extra error explanation.
1784
1785 =item $EXCEPTIONS_BEING_CAUGHT
1786
1787 =item $^S
1788 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1789
1790 Current state of the interpreter.
1791
1792         $^S         State
1793         ---------   -------------------------------------
1794         undef       Parsing module, eval, or main program
1795         true (1)    Executing an eval
1796         false (0)   Otherwise
1797
1798 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1799 handlers.
1800
1801 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1802 the C<undef> value does not indicate whether exceptions are being caught,
1803 since compilation of the main program does not catch exceptions.
1804
1805 This variable was added in Perl 5.004.
1806
1807 =item $WARNING
1808
1809 =item $^W
1810 X<$^W> X<$WARNING>
1811
1812 The current value of the warning switch, initially true if B<-w> was
1813 used, false otherwise, but directly modifiable.
1814
1815 See also L<warnings>.
1816
1817 Mnemonic: related to the B<-w> switch.
1818
1819 =item ${^WARNING_BITS}
1820 X<${^WARNING_BITS}>
1821
1822 The current set of warning checks enabled by the C<use warnings> pragma.
1823 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1824 values are considered internal to the L<warnings> pragma and may change
1825 between versions of Perl.
1826
1827 This variable was added in Perl v5.6.0.
1828
1829 =item $OS_ERROR
1830
1831 =item $ERRNO
1832
1833 =item $!
1834 X<$!> X<$ERRNO> X<$OS_ERROR>
1835
1836 When referenced, C<$!> retrieves the current value
1837 of the C C<errno> integer variable.
1838 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1839 When referenced as a string, C<$!> yields the system error string
1840 corresponding to C<errno>.
1841
1842 Many system or library calls set C<errno> if they fail,
1843 to indicate the cause of failure.  They usually do B<not>
1844 set C<errno> to zero if they succeed.  This means C<errno>,
1845 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1846
1847     if (open my $fh, "<", $filename) {
1848                 # Here $! is meaningless.
1849                 ...
1850     }
1851     else {
1852                 # ONLY here is $! meaningful.
1853                 ...
1854                 # Already here $! might be meaningless.
1855     }
1856     # Since here we might have either success or failure,
1857     # $! is meaningless.
1858
1859 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1860 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1861 It can be used immediately before invoking the C<die()> operator,
1862 to set the exit value, or to inspect the system error string
1863 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1864
1865 Mnemonic: What just went bang?
1866
1867 =item %OS_ERROR
1868
1869 =item %ERRNO
1870
1871 =item %!
1872 X<%!> X<%OS_ERROR> X<%ERRNO>
1873
1874 Each element of C<%!> has a true value only if C<$!> is set to that
1875 value.  For example, C<$!{ENOENT}> is true if and only if the current
1876 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1877 such file or directory" (or its moral equivalent: not all operating
1878 systems give that exact error, and certainly not all languages).  The
1879 specific true value is not guaranteed, but in the past has generally
1880 been the numeric value of C<$!>.  To check if a particular key is
1881 meaningful on your system, use C<exists $!{the_key}>; for a list of legal
1882 keys, use C<keys %!>.  See L<Errno> for more information, and also see
1883 L</$!>.
1884
1885 This variable was added in Perl 5.005.
1886
1887 =item $CHILD_ERROR
1888
1889 =item $?
1890 X<$?> X<$CHILD_ERROR>
1891
1892 The status returned by the last pipe close, backtick (C<``>) command,
1893 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1894 operator.  This is just the 16-bit status word returned by the
1895 traditional Unix C<wait()> system call (or else is made up to look
1896 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1897 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1898 from, and C<$? & 128> reports whether there was a core dump.
1899
1900 Additionally, if the C<h_errno> variable is supported in C, its value
1901 is returned via C<$?> if any C<gethost*()> function fails.
1902
1903 If you have installed a signal handler for C<SIGCHLD>, the
1904 value of C<$?> will usually be wrong outside that handler.
1905
1906 Inside an C<END> subroutine C<$?> contains the value that is going to be
1907 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1908 change the exit status of your program.  For example:
1909
1910     END {
1911         $? = 1 if $? == 255;  # die would make it 255
1912     }
1913
1914 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1915 actual VMS exit status, instead of the default emulation of POSIX
1916 status; see L<perlvms/$?> for details.
1917
1918 Mnemonic: similar to B<sh> and B<ksh>.
1919
1920 =item $EVAL_ERROR
1921
1922 =item $@
1923 X<$@> X<$EVAL_ERROR>
1924
1925 The Perl error from the last C<eval> operator, i.e. the last exception that
1926 was caught.  For C<eval BLOCK>, this is either a runtime error message or the
1927 string or reference C<die> was called with.  The C<eval STRING> form also
1928 catches syntax errors and other compile time exceptions.
1929
1930 If no error occurs, C<eval> sets C<$@> to the empty string.
1931
1932 Warning messages are not collected in this variable.  You can, however,
1933 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1934 described in L</%SIG>.
1935
1936 Mnemonic: Where was the error "at"?
1937
1938 =back
1939
1940 =head2 Variables related to the interpreter state
1941
1942 These variables provide information about the current interpreter state.
1943
1944 =over 8
1945
1946 =item $COMPILING
1947
1948 =item $^C
1949 X<$^C> X<$COMPILING>
1950
1951 The current value of the flag associated with the B<-c> switch.
1952 Mainly of use with B<-MO=...> to allow code to alter its behavior
1953 when being compiled, such as for example to C<AUTOLOAD> at compile
1954 time rather than normal, deferred loading.  Setting
1955 C<$^C = 1> is similar to calling C<B::minus_c>.
1956
1957 This variable was added in Perl v5.6.0.
1958
1959 =item $DEBUGGING
1960
1961 =item $^D
1962 X<$^D> X<$DEBUGGING>
1963
1964 The current value of the debugging flags.  May be read or set.  Like its
1965 L<command-line equivalent|perlrun/B<-D>I<letters>>, you can use numeric
1966 or symbolic values, e.g. C<$^D = 10> or C<$^D = "st">.  See
1967 L<perlrun/B<-D>I<number>>.  The contents of this variable also affects the
1968 debugger operation.  See L<perldebguts/Debugger Internals>.
1969
1970 Mnemonic: value of B<-D> switch.
1971
1972 =item ${^ENCODING}
1973 X<${^ENCODING}>
1974
1975 This variable is no longer supported.
1976
1977 It used to hold the I<object reference> to the C<Encode> object that was
1978 used to convert the source code to Unicode.
1979
1980 Its purpose was to allow your non-ASCII Perl
1981 scripts not to have to be written in UTF-8; this was
1982 useful before editors that worked on UTF-8 encoded text were common, but
1983 that was long ago.  It caused problems, such as affecting the operation
1984 of other modules that weren't expecting it, causing general mayhem.
1985
1986 If you need something like this functionality, it is recommended that use
1987 you a simple source filter, such as L<Filter::Encoding>.
1988
1989 If you are coming here because code of yours is being adversely affected
1990 by someone's use of this variable, you can usually work around it by
1991 doing this:
1992
1993  local ${^ENCODING};
1994
1995 near the beginning of the functions that are getting broken.  This
1996 undefines the variable during the scope of execution of the including
1997 function.
1998
1999 This variable was added in Perl 5.8.2 and removed in 5.26.0.
2000 Setting it to anything other than C<undef> was made fatal in Perl 5.28.0.
2001
2002 =item ${^GLOBAL_PHASE}
2003 X<${^GLOBAL_PHASE}>
2004
2005 The current phase of the perl interpreter.
2006
2007 Possible values are:
2008
2009 =over 8
2010
2011 =item CONSTRUCT
2012
2013 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
2014 value is mostly there for completeness and for use via the
2015 underlying C variable C<PL_phase>.  It's not really possible for Perl
2016 code to be executed unless construction of the interpreter is
2017 finished.
2018
2019 =item START
2020
2021 This is the global compile-time.  That includes, basically, every
2022 C<BEGIN> block executed directly or indirectly from during the
2023 compile-time of the top-level program.
2024
2025 This phase is not called "BEGIN" to avoid confusion with
2026 C<BEGIN>-blocks, as those are executed during compile-time of any
2027 compilation unit, not just the top-level program.  A new, localised
2028 compile-time entered at run-time, for example by constructs as
2029 C<eval "use SomeModule"> are not global interpreter phases, and
2030 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
2031
2032 =item CHECK
2033
2034 Execution of any C<CHECK> blocks.
2035
2036 =item INIT
2037
2038 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
2039
2040 =item RUN
2041
2042 The main run-time, i.e. the execution of C<PL_main_root>.
2043
2044 =item END
2045
2046 Execution of any C<END> blocks.
2047
2048 =item DESTRUCT
2049
2050 Global destruction.
2051
2052 =back
2053
2054 Also note that there's no value for UNITCHECK-blocks.  That's because
2055 those are run for each compilation unit individually, and therefore is
2056 not a global interpreter phase.
2057
2058 Not every program has to go through each of the possible phases, but
2059 transition from one phase to another can only happen in the order
2060 described in the above list.
2061
2062 An example of all of the phases Perl code can see:
2063
2064     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
2065
2066     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
2067
2068     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
2069
2070     {
2071         package Print::Phase;
2072
2073         sub new {
2074             my ($class, $time) = @_;
2075             return bless \$time, $class;
2076         }
2077
2078         sub DESTROY {
2079             my $self = shift;
2080             print "$$self: ${^GLOBAL_PHASE}\n";
2081         }
2082     }
2083
2084     print "run-time: ${^GLOBAL_PHASE}\n";
2085
2086     my $runtime = Print::Phase->new(
2087         "lexical variables are garbage collected before END"
2088     );
2089
2090     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
2091
2092     our $destruct = Print::Phase->new(
2093         "package variables are garbage collected after END"
2094     );
2095
2096 This will print out
2097
2098     compile-time: START
2099     check-time: CHECK
2100     init-time: INIT
2101     run-time: RUN
2102     lexical variables are garbage collected before END: RUN
2103     end-time: END
2104     package variables are garbage collected after END: DESTRUCT
2105
2106 This variable was added in Perl 5.14.0.
2107
2108 =item $^H
2109 X<$^H>
2110
2111 WARNING: This variable is strictly for
2112 internal use only.  Its availability,
2113 behavior, and contents are subject to change without notice.
2114
2115 This variable contains compile-time hints for the Perl interpreter.  At the
2116 end of compilation of a BLOCK the value of this variable is restored to the
2117 value when the interpreter started to compile the BLOCK.
2118
2119 When perl begins to parse any block construct that provides a lexical scope
2120 (e.g., eval body, required file, subroutine body, loop body, or conditional
2121 block), the existing value of C<$^H> is saved, but its value is left unchanged.
2122 When the compilation of the block is completed, it regains the saved value.
2123 Between the points where its value is saved and restored, code that
2124 executes within BEGIN blocks is free to change the value of C<$^H>.
2125
2126 This behavior provides the semantic of lexical scoping, and is used in,
2127 for instance, the C<use strict> pragma.
2128
2129 The contents should be an integer; different bits of it are used for
2130 different pragmatic flags.  Here's an example:
2131
2132     sub add_100 { $^H |= 0x100 }
2133
2134     sub foo {
2135         BEGIN { add_100() }
2136         bar->baz($boon);
2137     }
2138
2139 Consider what happens during execution of the BEGIN block.  At this point
2140 the BEGIN block has already been compiled, but the body of C<foo()> is still
2141 being compiled.  The new value of C<$^H>
2142 will therefore be visible only while
2143 the body of C<foo()> is being compiled.
2144
2145 Substitution of C<BEGIN { add_100() }> block with:
2146
2147     BEGIN { require strict; strict->import('vars') }
2148
2149 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
2150 version of the same lexical pragma:
2151
2152     BEGIN {
2153         require strict; strict->import('vars') if $condition
2154     }
2155
2156 This variable was added in Perl 5.003.
2157
2158 =item %^H
2159 X<%^H>
2160
2161 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
2162 it useful for implementation of lexically scoped pragmas.  See
2163 L<perlpragma>.   All the entries are stringified when accessed at
2164 runtime, so only simple values can be accommodated.  This means no
2165 pointers to objects, for example.
2166
2167 When putting items into C<%^H>, in order to avoid conflicting with other
2168 users of the hash there is a convention regarding which keys to use.
2169 A module should use only keys that begin with the module's name (the
2170 name of its main package) and a "/" character.  For example, a module
2171 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
2172
2173 This variable was added in Perl v5.6.0.
2174
2175 =item ${^OPEN}
2176 X<${^OPEN}>
2177
2178 An internal variable used by PerlIO.  A string in two parts, separated
2179 by a C<\0> byte, the first part describes the input layers, the second
2180 part describes the output layers.
2181
2182 This variable was added in Perl v5.8.0.
2183
2184 =item $PERLDB
2185
2186 =item $^P
2187 X<$^P> X<$PERLDB>
2188
2189 The internal variable for debugging support.  The meanings of the
2190 various bits are subject to change, but currently indicate:
2191
2192 =over 6
2193
2194 =item 0x01
2195
2196 Debug subroutine enter/exit.
2197
2198 =item 0x02
2199
2200 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
2201 each statement executed.  Also causes saving source code lines (like
2202 0x400).
2203
2204 =item 0x04
2205
2206 Switch off optimizations.
2207
2208 =item 0x08
2209
2210 Preserve more data for future interactive inspections.
2211
2212 =item 0x10
2213
2214 Keep info about source lines on which a subroutine is defined.
2215
2216 =item 0x20
2217
2218 Start with single-step on.
2219
2220 =item 0x40
2221
2222 Use subroutine address instead of name when reporting.
2223
2224 =item 0x80
2225
2226 Report C<goto &subroutine> as well.
2227
2228 =item 0x100
2229
2230 Provide informative "file" names for evals based on the place they were compiled.
2231
2232 =item 0x200
2233
2234 Provide informative names to anonymous subroutines based on the place they
2235 were compiled.
2236
2237 =item 0x400
2238
2239 Save source code lines into C<@{"_<$filename"}>.
2240
2241 =item 0x800
2242
2243 When saving source, include evals that generate no subroutines.
2244
2245 =item 0x1000
2246
2247 When saving source, include source that did not compile.
2248
2249 =back
2250
2251 Some bits may be relevant at compile-time only, some at
2252 run-time only.  This is a new mechanism and the details may change.
2253 See also L<perldebguts>.
2254
2255 =item ${^TAINT}
2256 X<${^TAINT}>
2257
2258 Reflects if taint mode is on or off.  1 for on (the program was run with
2259 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2260 B<-t> or B<-TU>).
2261
2262 This variable is read-only.
2263
2264 This variable was added in Perl v5.8.0.
2265
2266 =item ${^SAFE_LOCALES}
2267 X<${^SAFE_LOCALES}>
2268
2269 Reflects if safe locale operations are available to this perl (when the
2270 value is 1) or not (the value is 0).  This variable is always 1 if the
2271 perl has been compiled without threads.  It is also 1 if this perl is
2272 using thread-safe locale operations.  Note that an individual thread may
2273 choose to use the global locale (generally unsafe) by calling
2274 L<perlapi/switch_to_global_locale>.  This variable currently is still
2275 set to 1 in such threads.
2276
2277 This variable is read-only.
2278
2279 This variable was added in Perl v5.28.0.
2280
2281 =item ${^UNICODE}
2282 X<${^UNICODE}>
2283
2284 Reflects certain Unicode settings of Perl.  See L<perlrun>
2285 documentation for the C<-C> switch for more information about
2286 the possible values.
2287
2288 This variable is set during Perl startup and is thereafter read-only.
2289
2290 This variable was added in Perl v5.8.2.
2291
2292 =item ${^UTF8CACHE}
2293 X<${^UTF8CACHE}>
2294
2295 This variable controls the state of the internal UTF-8 offset caching code.
2296 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2297 all its results against linear scans, and panicking on any discrepancy.
2298
2299 This variable was added in Perl v5.8.9.  It is subject to change or
2300 removal without notice, but is currently used to avoid recalculating the
2301 boundaries of multi-byte UTF-8-encoded characters.
2302
2303 =item ${^UTF8LOCALE}
2304 X<${^UTF8LOCALE}>
2305
2306 This variable indicates whether a UTF-8 locale was detected by perl at
2307 startup.  This information is used by perl when it's in
2308 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2309 switch); see L<perlrun> for more info on this.
2310
2311 This variable was added in Perl v5.8.8.
2312
2313 =back
2314
2315 =head2 Deprecated and removed variables
2316
2317 Deprecating a variable announces the intent of the perl maintainers to
2318 eventually remove the variable from the language.  It may still be
2319 available despite its status.  Using a deprecated variable triggers
2320 a warning.
2321
2322 Once a variable is removed, its use triggers an error telling you
2323 the variable is unsupported.
2324
2325 See L<perldiag> for details about error messages.
2326
2327 =over 8
2328
2329 =item $#
2330 X<$#>
2331
2332 C<$#> was a variable that could be used to format printed numbers.
2333 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2334 using it now triggers a warning: C<$# is no longer supported>.
2335
2336 This is not the sigil you use in front of an array name to get the
2337 last index, like C<$#array>.  That's still how you get the last index
2338 of an array in Perl.  The two have nothing to do with each other.
2339
2340 Deprecated in Perl 5.
2341
2342 Removed in Perl v5.10.0.
2343
2344 =item $*
2345 X<$*>
2346
2347 C<$*> was a variable that you could use to enable multiline matching.
2348 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2349 Using it now triggers a warning: C<$* is no longer supported>.
2350 You should use the C</s> and C</m> regexp modifiers instead.
2351
2352 Deprecated in Perl 5.
2353
2354 Removed in Perl v5.10.0.
2355
2356 =item $[
2357 X<$[>
2358
2359 This variable stores the index of the first element in an array, and
2360 of the first character in a substring.  The default is 0, but you could
2361 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2362 when subscripting and when evaluating the index() and substr() functions.
2363
2364 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2365 directive, and cannot influence the behavior of any other file.
2366 (That's why you can only assign compile-time constants to it.)
2367 Its use is highly discouraged.
2368
2369 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2370 scopes in the same file, unlike other compile-time directives (such as
2371 L<strict>).  Using local() on it would bind its value strictly to a lexical
2372 block.  Now it is always lexically scoped.
2373
2374 As of Perl v5.16.0, it is implemented by the L<arybase> module.
2375
2376 As of Perl v5.30.0, or under C<use v5.16>, or C<no feature "array_base">,
2377 C<$[> no longer has any effect, and always contains 0.
2378 Assigning 0 to it is permitted, but any other value will produce an error.
2379
2380 Mnemonic: [ begins subscripts.
2381
2382 Deprecated in Perl v5.12.0.
2383
2384 =back
2385
2386 =cut