lib/utf8.pm

   1 package utf8;
   2
   3 $utf8::hint_bits = 0x00800000;
   4
   5 our $VERSION = '1.17';
   6
   7 sub import {
   8     $^H |= $utf8::hint_bits;
   9 }
  10
  11 sub unimport {
  12     $^H &= ~$utf8::hint_bits;
  13 }
  14
  15 sub AUTOLOAD {
  16     require "utf8_heavy.pl";
  17     goto &$AUTOLOAD if defined &$AUTOLOAD;
  18     require Carp;
  19     Carp::croak("Undefined subroutine $AUTOLOAD called");
  20 }
  21
  22 1;
  23 __END__
  24
  25 =head1 NAME
  26
  27 utf8 - Perl pragma to enable/disable UTF-8 (or UTF-EBCDIC) in source code
  28
  29 =head1 SYNOPSIS
  30
  31  use utf8;
  32  no utf8;
  33
  34  # Convert the internal representation of a Perl scalar to/from UTF-8.
  35
  36  $num_octets = utf8::upgrade($string);
  37  $success    = utf8::downgrade($string[, $fail_ok]);
  38
  39  # Change each character of a Perl scalar to/from a series of
  40  # characters that represent the UTF-8 bytes of each original character.
  41
  42  utf8::encode($string);  # "\x{100}"  becomes "\xc4\x80"
  43  utf8::decode($string);  # "\xc4\x80" becomes "\x{100}"
  44
  45  # Convert a code point from the platform native character set to
  46  # Unicode, and vice-versa.
  47  $unicode = utf8::native_to_unicode(ord('A')); # returns 65 on both
  48                                                # ASCII and EBCDIC
  49                                                # platforms
  50  $native = utf8::unicode_to_native(65);       # returns 65 on ASCII
  51                                               # platforms; 193 on EBCDIC
  52
  53  $flag = utf8::is_utf8($string); # since Perl 5.8.1
  54  $flag = utf8::valid($string);
  55
  56 =head1 DESCRIPTION
  57
  58 The C<use utf8> pragma tells the Perl parser to allow UTF-8 in the
  59 program text in the current lexical scope (allow UTF-EBCDIC on EBCDIC based
  60 platforms).  The C<no utf8> pragma tells Perl to switch back to treating
  61 the source text as literal bytes in the current lexical scope.
  62
  63 B<Do not use this pragma for anything else than telling Perl that your
  64 script is written in UTF-8.> The utility functions described below are
  65 directly usable without C<use utf8;>.
  66
  67 Because it is not possible to reliably tell UTF-8 from native 8 bit
  68 encodings, you need either a Byte Order Mark at the beginning of your
  69 source code, or C<use utf8;>, to instruct perl.
  70
  71 When UTF-8 becomes the standard source format, this pragma will
  72 effectively become a no-op.  For convenience in what follows the term
  73 I<UTF-X> is used to refer to UTF-8 on ASCII and ISO Latin based
  74 platforms and UTF-EBCDIC on EBCDIC based platforms.
  75
  76 See also the effects of the C<-C> switch and its cousin, the
  77 C<PERL_UNICODE> environment variable, in L<perlrun>.
  78
  79 Enabling the C<utf8> pragma has the following effect:
  80
  81 =over 4
  82
  83 =item *
  84
  85 Bytes in the source text that have their high-bit set will be treated
  86 as being part of a literal UTF-X sequence.  This includes most
  87 literals such as identifier names, string constants, and constant
  88 regular expression patterns.
  89
  90 On EBCDIC platforms characters in the Latin 1 character set are
  91 treated as being part of a literal UTF-EBCDIC character.
  92
  93 =back
  94
  95 Note that if you have bytes with the eighth bit on in your script
  96 (for example embedded Latin-1 in your string literals), C<use utf8>
  97 will be unhappy since the bytes are most probably not well-formed
  98 UTF-X.  If you want to have such bytes under C<use utf8>, you can disable
  99 this pragma until the end the block (or file, if at top level) by
 100 C<no utf8;>.
 101
 102 =head2 Utility functions
 103
 104 The following functions are defined in the C<utf8::> package by the
 105 Perl core.  You do not need to say C<use utf8> to use these and in fact
 106 you should not say that unless you really want to have UTF-8 source code.
 107
 108 =over 4
 109
 110 =item * C<$num_octets = utf8::upgrade($string)>
 111
 112 Converts in-place the internal representation of the string from an octet
 113 sequence in the native encoding (Latin-1 or EBCDIC) to I<UTF-X>. The
 114 logical character sequence itself is unchanged.  If I<$string> is already
 115 stored as I<UTF-X>, then this is a no-op. Returns the
 116 number of octets necessary to represent the string as I<UTF-X>.  Can be
 117 used to make sure that the UTF-8 flag is on, so that C<\w> or C<lc()>
 118 work as Unicode on strings containing characters in the range 0x80-0xFF
 119 (on ASCII and derivatives).
 120
 121 B<Note that this function does not handle arbitrary encodings.>
 122 Therefore Encode is recommended for the general purposes; see also
 123 L<Encode>.
 124
 125 =item * C<$success = utf8::downgrade($string[, $fail_ok])>
 126
 127 Converts in-place the internal representation of the string from
 128 I<UTF-X> to the equivalent octet sequence in the native encoding (Latin-1
 129 or EBCDIC). The logical character sequence itself is unchanged. If
 130 I<$string> is already stored as native 8 bit, then this is a no-op.  Can
 131 be used to
 132 make sure that the UTF-8 flag is off, e.g. when you want to make sure
 133 that the substr() or length() function works with the usually faster
 134 byte algorithm.
 135
 136 Fails if the original I<UTF-X> sequence cannot be represented in the
 137 native 8 bit encoding. On failure dies or, if the value of I<$fail_ok> is
 138 true, returns false.
 139
 140 Returns true on success.
 141
 142 B<Note that this function does not handle arbitrary encodings.>
 143 Therefore Encode is recommended for the general purposes; see also
 144 L<Encode>.
 145
 146 =item * C<utf8::encode($string)>
 147
 148 Converts in-place the character sequence to the corresponding octet
 149 sequence in I<UTF-X>. That is, every (possibly wide) character gets
 150 replaced with a sequence of one or more characters that represent the
 151 individual I<UTF-X> bytes of the character.  The UTF8 flag is turned off.
 152 Returns nothing.
 153
 154  my $a = "\x{100}"; # $a contains one character, with ord 0x100
 155  utf8::encode($a);  # $a contains two characters, with ords (on
 156                     # ASCII platforms) 0xc4 and 0x80
 157
 158 B<Note that this function does not handle arbitrary encodings.>
 159 Therefore Encode is recommended for the general purposes; see also
 160 L<Encode>.
 161
 162 =item * C<$success = utf8::decode($string)>
 163
 164 Attempts to convert in-place the octet sequence encoded as I<UTF-X> to the
 165 corresponding character sequence. That is, it replaces each sequence of
 166 characters in the string whose ords represent a valid UTF-X byte
 167 sequence, with the corresponding single character.  The UTF-8 flag is
 168 turned on only if the source string contains multiple-byte I<UTF-X>
 169 characters.  If I<$string> is invalid as I<UTF-X>, returns false;
 170 otherwise returns true.
 171
 172  my $a = "\xc4\x80"; # $a contains two characters, with ords
 173                      # 0xc4 and 0x80
 174  utf8::decode($a);   # On ASCII platforms, $a contains one char,
 175                      # with ord 0x100.   On EBCDIC platforms, $a
 176                      # is unchanged and the function returns FALSE.
 177
 178 (C<"\xc4\x80"> is not a valid sequence of bytes in any UTF-8-encoded
 179 character(s) in the EBCDIC code pages that Perl supports, which is why the
 180 above example returns failure on them.  What does decode into C<\x{100}>
 181 depends on the platform.  It is C<"\x8C\x41"> in IBM-1047.)
 182
 183 B<Note that this function does not handle arbitrary encodings.>
 184 Therefore Encode is recommended for the general purposes; see also
 185 L<Encode>.
 186
 187 =item * C<$unicode = utf8::native_to_unicode($code_point)>
 188
 189 (Since Perl v5.8.0)
 190 This takes an unsigned integer (which represents the ordinal number of a
 191 character (or a code point) on the platform the program is being run on) and
 192 returns its Unicode equivalent value.  Since ASCII platforms natively use the
 193 Unicode code points, this function returns its input on them.  On EBCDIC
 194 platforms it converts from EBCDIC to Unicode.
 195
 196 A meaningless value will currently be returned if the input is not an unsigned
 197 integer.
 198
 199 Since Perl v5.22.0, calls to this function are optimized out on ASCII
 200 platforms, so there is no performance hit in using it there.
 201
 202 =item * C<$native = utf8::unicode_to_native($code_point)>
 203
 204 (Since Perl v5.8.0)
 205 This is the inverse of C<utf8::native_to_unicode()>, converting the other
 206 direction.  Again, on ASCII platforms, this returns its input, but on EBCDIC
 207 platforms it will find the native platform code point, given any Unicode one.
 208
 209 A meaningless value will currently be returned if the input is not an unsigned
 210 integer.
 211
 212 Since Perl v5.22.0, calls to this function are optimized out on ASCII
 213 platforms, so there is no performance hit in using it there.
 214
 215 =item * C<$flag = utf8::is_utf8($string)>
 216
 217 (Since Perl 5.8.1)  Test whether I<$string> is marked internally as encoded in
 218 UTF-8.  Functionally the same as Encode::is_utf8().
 219
 220 =item * C<$flag = utf8::valid($string)>
 221
 222 [INTERNAL] Test whether I<$string> is in a consistent state regarding
 223 UTF-8.  Will return true if it is well-formed UTF-8 and has the UTF-8 flag
 224 on B<or> if I<$string> is held as bytes (both these states are 'consistent').
 225 Main reason for this routine is to allow Perl's test suite to check
 226 that operations have left strings in a consistent state.  You most
 227 probably want to use utf8::is_utf8() instead.
 228
 229 =back
 230
 231 C<utf8::encode> is like C<utf8::upgrade>, but the UTF8 flag is
 232 cleared.  See L<perlunicode> for more on the UTF8 flag and the C API
 233 functions C<sv_utf8_upgrade>, C<sv_utf8_downgrade>, C<sv_utf8_encode>,
 234 and C<sv_utf8_decode>, which are wrapped by the Perl functions
 235 C<utf8::upgrade>, C<utf8::downgrade>, C<utf8::encode> and
 236 C<utf8::decode>.  Also, the functions utf8::is_utf8, utf8::valid,
 237 utf8::encode, utf8::decode, utf8::upgrade, and utf8::downgrade are
 238 actually internal, and thus always available, without a C<require utf8>
 239 statement.
 240
 241 =head1 BUGS
 242
 243 One can have Unicode in identifier names, but not in package/class or
 244 subroutine names.  While some limited functionality towards this does
 245 exist as of Perl 5.8.0, that is more accidental than designed; use of
 246 Unicode for the said purposes is unsupported.
 247
 248 One reason of this unfinishedness is its (currently) inherent
 249 unportability: since both package names and subroutine names may need
 250 to be mapped to file and directory names, the Unicode capability of
 251 the filesystem becomes important-- and there unfortunately aren't
 252 portable answers.
 253
 254 =head1 SEE ALSO
 255
 256 L<perlunitut>, L<perluniintro>, L<perlrun>, L<bytes>, L<perlunicode>
 257
 258 =cut