utils/h2ph.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(basename dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13 # Wanted:  $archlibexp
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 $origdir = cwd;
  18 chdir dirname($0);
  19 $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 open OUT,">$file" or die "Can't create $file: $!";
  23
  24 print "Extracting $file (with variable substitutions)\n";
  25
  26 # In this section, perl variables will be expanded during extraction.
  27 # You can use $Config{...} to use Configure variables.
  28
  29 print OUT <<"!GROK!THIS!";
  30 $Config{startperl}
  31     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  32         if \$running_under_some_shell;
  33 !GROK!THIS!
  34
  35 # In the following, perl variables are not expanded during extraction.
  36
  37 print OUT <<'!NO!SUBS!';
  38
  39 use strict;
  40
  41 use Config;
  42 use File::Path qw(mkpath);
  43 use Getopt::Std;
  44
  45 # Make sure read permissions for all are set:
  46 if (defined umask && (umask() & 0444)) {
  47     umask (umask() & ~0444);
  48 }
  49
  50 getopts('Dd:rlhaQe');
  51 use vars qw($opt_D $opt_d $opt_r $opt_l $opt_h $opt_a $opt_Q $opt_e);
  52 die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  53 my @inc_dirs = inc_dirs() if $opt_a;
  54
  55 my $Exit = 0;
  56
  57 my $Dest_dir = $opt_d || $Config{installsitearch};
  58 die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  59     unless -d $Dest_dir;
  60
  61 my @isatype = qw(
  62         char    uchar   u_char
  63         short   ushort  u_short
  64         int     uint    u_int
  65         long    ulong   u_long
  66         FILE    key_t   caddr_t
  67         float   double  size_t
  68 );
  69
  70 my %isatype;
  71 @isatype{@isatype} = (1) x @isatype;
  72 my $inif = 0;
  73 my %Is_converted;
  74 my %bad_file = ();
  75
  76 @ARGV = ('-') unless @ARGV;
  77
  78 build_preamble_if_necessary();
  79
  80 sub reindent($) {
  81     my($text) = shift;
  82     $text =~ s/\n/\n    /g;
  83     $text =~ s/        /\t/g;
  84     $text;
  85 }
  86
  87 my ($t, $tab, %curargs, $new, $eval_index, $dir, $name, $args, $outfile);
  88 my ($incl, $incl_type, $next);
  89 while (defined (my $file = next_file())) {
  90     if (-l $file and -d $file) {
  91         link_if_possible($file) if ($opt_l);
  92         next;
  93     }
  94
  95     # Recover from header files with unbalanced cpp directives
  96     $t = '';
  97     $tab = 0;
  98
  99     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
 100     $eval_index = 1;
 101
 102     if ($file eq '-') {
 103         open(IN, "-");
 104         open(OUT, ">-");
 105     } else {
 106         ($outfile = $file) =~ s/\.h$/.ph/ || next;
 107         print "$file -> $outfile\n" unless $opt_Q;
 108         if ($file =~ m|^(.*)/|) {
 109             $dir = $1;
 110             mkpath "$Dest_dir/$dir";
 111         }
 112
 113         if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
 114             foreach (@inc_dirs) {
 115                 chdir $_;
 116                 last if -f $file;
 117             }
 118         }
 119
 120         open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
 121         open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
 122     }
 123
 124     print OUT
 125         "require '_h2ph_pre.ph';\n\n",
 126         "no warnings 'redefine';\n\n";
 127
 128     while (defined (local $_ = next_line($file))) {
 129         if (s/^\s*\#\s*//) {
 130             if (s/^define\s+(\w+)//) {
 131                 $name = $1;
 132                 $new = '';
 133                 s/\s+$//;
 134                 s/\(\w+\s*\(\*\)\s*\(\w*\)\)\s*(-?\d+)/$1/; # (int (*)(foo_t))0
 135                 if (s/^\(([\w,\s]*)\)//) {
 136                     $args = $1;
 137                     my $proto = '() ';
 138                     if ($args ne '') {
 139                         $proto = '';
 140                         foreach my $arg (split(/,\s*/,$args)) {
 141                             $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
 142                             $curargs{$arg} = 1;
 143                         }
 144                         $args =~ s/\b(\w)/\$$1/g;
 145                         $args = "my($args) = \@_;\n$t    ";
 146                     }
 147                     s/^\s+//;
 148                     expr();
 149                     $new =~ s/(["\\])/\\$1/g;       #"]);
 150                   EMIT:
 151                     $new = reindent($new);
 152                     $args = reindent($args);
 153                     if ($t ne '') {
 154                         $new =~ s/(['\\])/\\$1/g;   #']);
 155                         if ($opt_h) {
 156                             print OUT $t,
 157                             "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 158                             $eval_index++;
 159                         } else {
 160                             print OUT $t,
 161                             "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 162                         }
 163                     } else {
 164                       print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 165                     }
 166                     %curargs = ();
 167                 } else {
 168                     s/^\s+//;
 169                     expr();
 170                     $new = 1 if $new eq '';
 171                     $new = reindent($new);
 172                     $args = reindent($args);
 173                     if ($t ne '') {
 174                         $new =~ s/(['\\])/\\$1/g;        #']);
 175
 176                         if ($opt_h) {
 177                             print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 178                             $eval_index++;
 179                         } else {
 180                             print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 181                         }
 182                     } else {
 183                         # Shunt around such directives as `#define FOO FOO':
 184                         next if " \&$name" eq $new;
 185
 186                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
 187                     }
 188                 }
 189             } elsif (/^(include|import|include_next)\s*[<\"](.*)[>\"]/) {
 190                 $incl_type = $1;
 191                 $incl = $2;
 192                 if (($incl_type eq 'include_next') ||
 193                     ($opt_e && exists($bad_file{$incl}))) {
 194                     $incl =~ s/\.h$/.ph/;
 195                 print OUT ($t,
 196                            "eval {\n");
 197                 $tab += 4;
 198                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 199                     print OUT ($t, "my(\@REM);\n");
 200                     if ($incl_type eq 'include_next') {
 201                 print OUT ($t,
 202                            "my(\%INCD) = map { \$INC{\$_} => 1 } ",
 203                                    "(grep { \$_ eq \"$incl\" } ",
 204                                    "keys(\%INC));\n");
 205                 print OUT ($t,
 206                                    "\@REM = map { \"\$_/$incl\" } ",
 207                            "(grep { not exists(\$INCD{\"\$_/$incl\"})",
 208                                    " and -f \"\$_/$incl\" } \@INC);\n");
 209                     } else {
 210                         print OUT ($t,
 211                                    "\@REM = map { \"\$_/$incl\" } ",
 212                                    "(grep {-r \"\$_/$incl\" } \@INC);\n");
 213                     }
 214                 print OUT ($t,
 215                            "require \"\$REM[0]\" if \@REM;\n");
 216                 $tab -= 4;
 217                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 218                 print OUT ($t,
 219                            "};\n");
 220                 print OUT ($t,
 221                            "warn(\$\@) if \$\@;\n");
 222                 } else {
 223                     $incl =~ s/\.h$/.ph/;
 224                     print OUT $t,"require '$incl';\n";
 225                 }
 226             } elsif (/^ifdef\s+(\w+)/) {
 227                 print OUT $t,"if(defined(&$1)) {\n";
 228                 $tab += 4;
 229                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 230             } elsif (/^ifndef\s+(\w+)/) {
 231                 print OUT $t,"unless(defined(&$1)) {\n";
 232                 $tab += 4;
 233                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 234             } elsif (s/^if\s+//) {
 235                 $new = '';
 236                 $inif = 1;
 237                 expr();
 238                 $inif = 0;
 239                 print OUT $t,"if($new) {\n";
 240                 $tab += 4;
 241                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 242             } elsif (s/^elif\s+//) {
 243                 $new = '';
 244                 $inif = 1;
 245                 expr();
 246                 $inif = 0;
 247                 $tab -= 4;
 248                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 249                 print OUT $t,"}\n elsif($new) {\n";
 250                 $tab += 4;
 251                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 252             } elsif (/^else/) {
 253                 $tab -= 4;
 254                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 255                 print OUT $t,"} else {\n";
 256                 $tab += 4;
 257                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 258             } elsif (/^endif/) {
 259                 $tab -= 4;
 260                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 261                 print OUT $t,"}\n";
 262             } elsif(/^undef\s+(\w+)/) {
 263                 print OUT $t, "undef(&$1) if defined(&$1);\n";
 264             } elsif(/^error\s+(".*")/) {
 265                 print OUT $t, "die($1);\n";
 266             } elsif(/^error\s+(.*)/) {
 267                 print OUT $t, "die(\"", quotemeta($1), "\");\n";
 268             } elsif(/^warning\s+(.*)/) {
 269                 print OUT $t, "warn(\"", quotemeta($1), "\");\n";
 270             } elsif(/^ident\s+(.*)/) {
 271                 print OUT $t, "# $1\n";
 272             }
 273         } elsif (/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?/) { # { for vi
 274             until(/\{[^}]*\}.*;/ || /;/) {
 275                 last unless defined ($next = next_line($file));
 276                 chomp $next;
 277                 # drop "#define FOO FOO" in enums
 278                 $next =~ s/^\s*#\s*define\s+(\w+)\s+\1\s*$//;
 279                 # #defines in enums (aliases)
 280                 $next =~ s/^\s*#\s*define\s+(\w+)\s+(\w+)\s*$/$1 = $2,/;
 281                 $_ .= $next;
 282                 print OUT "# $next\n" if $opt_D;
 283             }
 284             s/#\s*if.*?#\s*endif//g; # drop #ifdefs
 285             s@/\*.*?\*/@@g;
 286             s/\s+/ /g;
 287             next unless /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
 288             (my $enum_subs = $3) =~ s/\s//g;
 289             my @enum_subs = split(/,/, $enum_subs);
 290             my $enum_val = -1;
 291             foreach my $enum (@enum_subs) {
 292                 my ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
 293                 $enum_name or next;
 294                 $enum_value =~ s/^=//;
 295                 $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
 296                 if ($opt_h) {
 297                     print OUT ($t,
 298                                "eval(\"\\n#line $eval_index $outfile\\n",
 299                                "sub $enum_name () \{ $enum_val; \}\") ",
 300                                "unless defined(\&$enum_name);\n");
 301                     ++ $eval_index;
 302                 } else {
 303                     print OUT ($t,
 304                                "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
 305                                "unless defined(\&$enum_name);\n");
 306                 }
 307             }
 308         } elsif (/^(?:__extension__\s+)?(?:extern|static)\s+(?:__)?inline(?:__)?\s+/
 309             and !/;\s*$/ and !/{\s*}\s*$/)
 310         { # { for vi
 311             # This is a hack to parse the inline functions in the glibc headers.
 312             # Warning: massive kludge ahead. We suppose inline functions
 313             # are mainly constructed like macros.
 314             while (1) {
 315                 last unless defined ($next = next_line($file));
 316                 chomp $next;
 317                 undef $_, last if $next =~ /__THROW\s*;/
 318                                or $next =~ /^(__extension__|extern|static)\b/;
 319                 $_ .= " $next";
 320                 print OUT "# $next\n" if $opt_D;
 321                 last if $next =~ /^}|^{.*}\s*$/;
 322             }
 323             next if not defined; # because it's only a prototype
 324             s/\b(__extension__|extern|static|(?:__)?inline(?:__)?)\b//g;
 325             # violently drop #ifdefs
 326             s/#\s*if.*?#\s*endif//g
 327                 and print OUT "# some #ifdef were dropped here -- fill in the blanks\n";
 328             if (s/^(?:\w|\s|\*)*\s(\w+)\s*//) {
 329                 $name = $1;
 330             } else {
 331                 warn "name not found"; next; # shouldn't occur...
 332             }
 333             my @args;
 334             if (s/^\(([^()]*)\)\s*(\w+\s*)*//) {
 335                 for my $arg (split /,/, $1) {
 336                     if ($arg =~ /(\w+)\s*$/) {
 337                         $curargs{$1} = 1;
 338                         push @args, $1;
 339                     }
 340                 }
 341             }
 342             $args = (
 343                 @args
 344                 ? "my(" . (join ',', map "\$$_", @args) . ") = \@_;\n$t    "
 345                 : ""
 346             );
 347             my $proto = @args ? '' : '() ';
 348             $new = '';
 349             s/\breturn\b//g; # "return" doesn't occur in macros usually...
 350             expr();
 351             # try to find and perlify local C variables
 352             our @local_variables = (); # needs to be a our(): (?{...}) bug workaround
 353             {
 354                 use re "eval";
 355                 my $typelist = join '|', keys %isatype;
 356                 $new =~ s['
 357                   (?:(?:un)?signed\s+)?
 358                   (?:long\s+)?
 359                   (?:$typelist)\s+
 360                   (\w+)
 361                   (?{ push @local_variables, $1 })
 362                   ']
 363                  [my \$$1]gx;
 364                 $new =~ s['
 365                   (?:(?:un)?signed\s+)?
 366                   (?:long\s+)?
 367                   (?:$typelist)\s+
 368                   ' \s+ &(\w+) \s* ;
 369                   (?{ push @local_variables, $1 })
 370                   ]
 371                  [my \$$1;]gx;
 372              }
 373             $new =~ s/&$_\b/\$$_/g for @local_variables;
 374             $new =~ s/(["\\])/\\$1/g;       #"]);
 375             # now that's almost like a macro (we hope)
 376             goto EMIT;
 377         }
 378     }
 379     $Is_converted{$file} = 1;
 380     if ($opt_e && exists($bad_file{$file})) {
 381         unlink($Dest_dir . '/' . $outfile);
 382         $next = '';
 383     } else {
 384         print OUT "1;\n";
 385         queue_includes_from($file) if $opt_a;
 386     }
 387 }
 388
 389 if ($opt_e && (scalar(keys %bad_file) > 0)) {
 390     warn "Was unable to convert the following files:\n";
 391     warn "\t" . join("\n\t",sort(keys %bad_file)) . "\n";
 392 }
 393
 394 exit $Exit;
 395
 396 sub expr {
 397     $new = '"(assembly code)"' and return if /\b__asm__\b/; # freak out.
 398     my $joined_args;
 399     if(keys(%curargs)) {
 400         $joined_args = join('|', keys(%curargs));
 401     }
 402     while ($_ ne '') {
 403         s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
 404         s/^\&([\(a-z\)]+)/$1/i; # hack for things that take the address of
 405         s/^(\s+)//              && do {$new .= ' '; next;};
 406         s/^0X([0-9A-F]+)[UL]*//i
 407             && do {my $hex = $1;
 408                    $hex =~ s/^0+//;
 409                    if (length $hex > 8 && !$Config{use64bitint}) {
 410                        # Croak if nv_preserves_uv_bits < 64 ?
 411                        $new .=         hex(substr($hex, -8)) +
 412                                2**32 * hex(substr($hex,  0, -8));
 413                        # The above will produce "errorneus" code
 414                        # if the hex constant was e.g. inside UINT64_C
 415                        # macro, but then again, h2ph is an approximation.
 416                    } else {
 417                        $new .= lc("0x$hex");
 418                    }
 419                    next;};
 420         s/^(-?\d+\.\d+E[-+]?\d+)[FL]?//i        && do {$new .= $1; next;};
 421         s/^(\d+)\s*[LU]*//i     && do {$new .= $1; next;};
 422         s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
 423         s/^'((\\"|[^"])*)'//    && do {
 424             if ($curargs{$1}) {
 425                 $new .= "ord('\$$1')";
 426             } else {
 427                 $new .= "ord('$1')";
 428             }
 429             next;
 430         };
 431         # replace "sizeof(foo)" with "{foo}"
 432         # also, remove * (C dereference operator) to avoid perl syntax
 433         # problems.  Where the %sizeof array comes from is anyone's
 434         # guess (c2ph?), but this at least avoids fatal syntax errors.
 435         # Behavior is undefined if sizeof() delimiters are unbalanced.
 436         # This code was modified to able to handle constructs like this:
 437         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
 438         s/^sizeof\s*\(// && do {
 439             $new .= '$sizeof';
 440             my $lvl = 1;  # already saw one open paren
 441             # tack { on the front, and skip it in the loop
 442             $_ = "{" . "$_";
 443             my $index = 1;
 444             # find balanced closing paren
 445             while ($index <= length($_) && $lvl > 0) {
 446                 $lvl++ if substr($_, $index, 1) eq "(";
 447                 $lvl-- if substr($_, $index, 1) eq ")";
 448                 $index++;
 449             }
 450             # tack } on the end, replacing )
 451             substr($_, $index - 1, 1) = "}";
 452             # remove pesky * operators within the sizeof argument
 453             substr($_, 0, $index - 1) =~ s/\*//g;
 454             next;
 455         };
 456         # Eliminate typedefs
 457         /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
 458             my $doit = 1;
 459             foreach (split /\s+/, $1) {  # Make sure all the words are types,
 460                 unless($isatype{$_} or $_ eq 'struct' or $_ eq 'union'){
 461                     $doit = 0;
 462                     last;
 463                 }
 464             }
 465             if( $doit ){
 466                 s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
 467             }
 468         };
 469         # struct/union member, including arrays:
 470         s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
 471             my $id = $1;
 472             $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
 473             $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
 474             while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
 475                 my($index) = $1;
 476                 $index =~ s/\s//g;
 477                 if(exists($curargs{$index})) {
 478                     $index = "\$$index";
 479                 } else {
 480                     $index = "&$index";
 481                 }
 482                 $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
 483             }
 484             $new .= " (\$$id)";
 485         };
 486         s/^([_a-zA-Z]\w*)//     && do {
 487             my $id = $1;
 488             if ($id eq 'struct' || $id eq 'union') {
 489                 s/^\s+(\w+)//;
 490                 $id .= ' ' . $1;
 491                 $isatype{$id} = 1;
 492             } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
 493                 while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
 494                 $isatype{$id} = 1;
 495             }
 496             if ($curargs{$id}) {
 497                 $new .= "\$$id";
 498                 $new .= '->' if /^[\[\{]/;
 499             } elsif ($id eq 'defined') {
 500                 $new .= 'defined';
 501             } elsif (/^\s*\(/) {
 502                 s/^\s*\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;  # cheat
 503                 $new .= " &$id";
 504             } elsif ($isatype{$id}) {
 505                 if ($new =~ /{\s*$/) {
 506                     $new .= "'$id'";
 507                 } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
 508                     $new =~ s/\(\s*$//;
 509                     s/^[\s*]*\)//;
 510                 } else {
 511                     $new .= q(').$id.q(');
 512                 }
 513             } else {
 514                 if ($inif && $new !~ /defined\s*\($/) {
 515                     $new .= '(defined(&' . $id . ') ? &' . $id . ' : 0)';
 516                 } elsif (/^\[/) {
 517                     $new .= " \$$id";
 518                 } else {
 519                     $new .= ' &' . $id;
 520                 }
 521             }
 522             next;
 523         };
 524         s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
 525     }
 526 }
 527
 528
 529 sub next_line
 530 {
 531     my $file = shift;
 532     my ($in, $out);
 533     my $pre_sub_tri_graphs = 1;
 534
 535     READ: while (not eof IN) {
 536         $in  .= <IN>;
 537         chomp $in;
 538         next unless length $in;
 539
 540         while (length $in) {
 541             if ($pre_sub_tri_graphs) {
 542                 # Preprocess all tri-graphs
 543                 # including things stuck in quoted string constants.
 544                 $in =~ s/\?\?=/#/g;                         # | ??=|  #|
 545                 $in =~ s/\?\?\!/|/g;                        # | ??!|  ||
 546                 $in =~ s/\?\?'/^/g;                         # | ??'|  ^|
 547                 $in =~ s/\?\?\(/[/g;                        # | ??(|  [|
 548                 $in =~ s/\?\?\)/]/g;                        # | ??)|  ]|
 549                 $in =~ s/\?\?\-/~/g;                        # | ??-|  ~|
 550                 $in =~ s/\?\?\//\\/g;                       # | ??/|  \|
 551                 $in =~ s/\?\?</{/g;                         # | ??<|  {|
 552                 $in =~ s/\?\?>/}/g;                         # | ??>|  }|
 553             }
 554             if ($in =~ /^\#ifdef __LANGUAGE_PASCAL__/) {
 555                 # Tru64 disassembler.h evilness: mixed C and Pascal.
 556                 while (<IN>) {
 557                     last if /^\#endif/;
 558                 }
 559                 next READ;
 560             }
 561             if ($in =~ /^extern inline / && # Inlined assembler.
 562                 $^O eq 'linux' && $file =~ m!(?:^|/)asm/[^/]+\.h$!) {
 563                 while (<IN>) {
 564                     last if /^}/;
 565                 }
 566                 next READ;
 567             }
 568             if ($in =~ s/\\$//) {                           # \-newline
 569                 $out    .= ' ';
 570                 next READ;
 571             } elsif ($in =~ s/^([^"'\\\/]+)//) {            # Passthrough
 572                 $out    .= $1;
 573             } elsif ($in =~ s/^(\\.)//) {                   # \...
 574                 $out    .= $1;
 575             } elsif ($in =~ /^'/) {                         # '...
 576                 if ($in =~ s/^('(\\.|[^'\\])*')//) {
 577                     $out    .= $1;
 578                 } else {
 579                     next READ;
 580                 }
 581             } elsif ($in =~ /^"/) {                         # "...
 582                 if ($in =~ s/^("(\\.|[^"\\])*")//) {
 583                     $out    .= $1;
 584                 } else {
 585                     next READ;
 586                 }
 587             } elsif ($in =~ s/^\/\/.*//) {                  # //...
 588                 # fall through
 589             } elsif ($in =~ m/^\/\*/) {                     # /*...
 590                 # C comment removal adapted from perlfaq6:
 591                 if ($in =~ s/^\/\*[^*]*\*+([^\/*][^*]*\*+)*\///) {
 592                     $out    .= ' ';
 593                 } else {                                    # Incomplete /* */
 594                     next READ;
 595                 }
 596             } elsif ($in =~ s/^(\/)//) {                    # /...
 597                 $out    .= $1;
 598             } elsif ($in =~ s/^([^\'\"\\\/]+)//) {
 599                 $out    .= $1;
 600             } elsif ($^O eq 'linux' &&
 601                      $file =~ m!(?:^|/)linux/byteorder/pdp_endian\.h$! &&
 602                      $in   =~ s!\'T KNOW!!) {
 603                 $out    =~ s!I DON$!I_DO_NOT_KNOW!;
 604             } else {
 605                 if ($opt_e) {
 606                     warn "Cannot parse $file:\n$in\n";
 607                     $bad_file{$file} = 1;
 608                     $in = '';
 609                     $out = undef;
 610                     last READ;
 611                 } else {
 612                 die "Cannot parse:\n$in\n";
 613                 }
 614             }
 615         }
 616
 617         last READ if $out =~ /\S/;
 618     }
 619
 620     return $out;
 621 }
 622
 623
 624 # Handle recursive subdirectories without getting a grotesquely big stack.
 625 # Could this be implemented using File::Find?
 626 sub next_file
 627 {
 628     my $file;
 629
 630     while (@ARGV) {
 631         $file = shift @ARGV;
 632
 633         if ($file eq '-' or -f $file or -l $file) {
 634             return $file;
 635         } elsif (-d $file) {
 636             if ($opt_r) {
 637                 expand_glob($file);
 638             } else {
 639                 print STDERR "Skipping directory `$file'\n";
 640             }
 641         } elsif ($opt_a) {
 642             return $file;
 643         } else {
 644             print STDERR "Skipping `$file':  not a file or directory\n";
 645         }
 646     }
 647
 648     return undef;
 649 }
 650
 651
 652 # Put all the files in $directory into @ARGV for processing.
 653 sub expand_glob
 654 {
 655     my ($directory)  = @_;
 656
 657     $directory =~ s:/$::;
 658
 659     opendir DIR, $directory;
 660         foreach (readdir DIR) {
 661             next if ($_ eq '.' or $_ eq '..');
 662
 663             # expand_glob() is going to be called until $ARGV[0] isn't a
 664             # directory; so push directories, and unshift everything else.
 665             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
 666             else                    { unshift @ARGV, "$directory/$_" }
 667         }
 668     closedir DIR;
 669 }
 670
 671
 672 # Given $file, a symbolic link to a directory in the C include directory,
 673 # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
 674 # Otherwise, just duplicate the file or directory.
 675 sub link_if_possible
 676 {
 677     my ($dirlink)  = @_;
 678     my $target  = eval 'readlink($dirlink)';
 679
 680     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
 681         # The target of a parent or absolute link could leave the $Dest_dir
 682         # hierarchy, so let's put all of the contents of $dirlink (actually,
 683         # the contents of $target) into @ARGV; as a side effect down the
 684         # line, $dirlink will get created as an _actual_ directory.
 685         expand_glob($dirlink);
 686     } else {
 687         if (-l "$Dest_dir/$dirlink") {
 688             unlink "$Dest_dir/$dirlink" or
 689                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
 690         }
 691
 692         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
 693             print "Linking $target -> $Dest_dir/$dirlink\n";
 694
 695             # Make sure that the link _links_ to something:
 696             if (! -e "$Dest_dir/$target") {
 697                 mkpath("$Dest_dir/$target", 0755) or
 698                     print STDERR "Could not create $Dest_dir/$target/\n";
 699             }
 700         } else {
 701             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
 702         }
 703     }
 704 }
 705
 706
 707 # Push all #included files in $file onto our stack, except for STDIN
 708 # and files we've already processed.
 709 sub queue_includes_from
 710 {
 711     my ($file)    = @_;
 712     my $line;
 713
 714     return if ($file eq "-");
 715
 716     open HEADER, $file or return;
 717         while (defined($line = <HEADER>)) {
 718             while (/\\$/) { # Handle continuation lines
 719                 chop $line;
 720                 $line .= <HEADER>;
 721             }
 722
 723             if ($line =~ /^#\s*include\s+<(.*?)>/) {
 724                 push(@ARGV, $1) unless $Is_converted{$1};
 725             }
 726         }
 727     close HEADER;
 728 }
 729
 730
 731 # Determine include directories; $Config{usrinc} should be enough for (all
 732 # non-GCC?) C compilers, but gcc uses an additional include directory.
 733 sub inc_dirs
 734 {
 735     my $from_gcc    = `$Config{cc} -v 2>&1`;
 736     $from_gcc       =~ s:^Reading specs from (.*?)/specs\b.*:$1/include:s;
 737
 738     length($from_gcc) ? ($from_gcc, $Config{usrinc}) : ($Config{usrinc});
 739 }
 740
 741
 742 # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
 743 # version of h2ph.
 744 sub build_preamble_if_necessary
 745 {
 746     # Increment $VERSION every time this function is modified:
 747     my $VERSION     = 2;
 748     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
 749
 750     # Can we skip building the preamble file?
 751     if (-r $preamble) {
 752         # Extract version number from first line of preamble:
 753         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
 754             my $line = <PREAMBLE>;
 755             $line =~ /(\b\d+\b)/;
 756         close PREAMBLE            or die "Cannot close $preamble:  $!";
 757
 758         # Don't build preamble if a compatible preamble exists:
 759         return if $1 == $VERSION;
 760     }
 761
 762     my (%define) = _extract_cc_defines();
 763
 764     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
 765         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
 766
 767         foreach (sort keys %define) {
 768             if ($opt_D) {
 769                 print PREAMBLE "# $_=$define{$_}\n";
 770             }
 771
 772             if ($define{$_} =~ /^(\d+)U?L{0,2}$/i) {
 773                 print PREAMBLE
 774                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
 775             } elsif ($define{$_} =~ /^\w+$/) {
 776                 print PREAMBLE
 777                     "unless (defined &$_) { sub $_() { &$define{$_} } }\n\n";
 778             } else {
 779                 print PREAMBLE
 780                     "unless (defined &$_) { sub $_() { \"",
 781                     quotemeta($define{$_}), "\" } }\n\n";
 782             }
 783         }
 784     close PREAMBLE               or die "Cannot close $preamble:  $!";
 785 }
 786
 787
 788 # %Config contains information on macros that are pre-defined by the
 789 # system's compiler.  We need this information to make the .ph files
 790 # function with perl as the .h files do with cc.
 791 sub _extract_cc_defines
 792 {
 793     my %define;
 794     my $allsymbols  = join " ",
 795         @Config{'ccsymbols', 'cppsymbols', 'cppccsymbols'};
 796
 797     # Split compiler pre-definitions into `key=value' pairs:
 798     foreach (split /\s+/, $allsymbols) {
 799         /(.+?)=(.+)/ and $define{$1} = $2;
 800
 801         if ($opt_D) {
 802             print STDERR "$_:  $1 -> $2\n";
 803         }
 804     }
 805
 806     return %define;
 807 }
 808
 809
 810 1;
 811
 812 ##############################################################################
 813 __END__
 814
 815 =head1 NAME
 816
 817 h2ph - convert .h C header files to .ph Perl header files
 818
 819 =head1 SYNOPSIS
 820
 821 B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
 822
 823 =head1 DESCRIPTION
 824
 825 I<h2ph>
 826 converts any C header files specified to the corresponding Perl header file
 827 format.
 828 It is most easily run while in /usr/include:
 829
 830         cd /usr/include; h2ph * sys/*
 831
 832 or
 833
 834         cd /usr/include; h2ph * sys/* arpa/* netinet/*
 835
 836 or
 837
 838         cd /usr/include; h2ph -r -l .
 839
 840 The output files are placed in the hierarchy rooted at Perl's
 841 architecture dependent library directory.  You can specify a different
 842 hierarchy with a B<-d> switch.
 843
 844 If run with no arguments, filters standard input to standard output.
 845
 846 =head1 OPTIONS
 847
 848 =over 4
 849
 850 =item -d destination_dir
 851
 852 Put the resulting B<.ph> files beneath B<destination_dir>, instead of
 853 beneath the default Perl library location (C<$Config{'installsitsearch'}>).
 854
 855 =item -r
 856
 857 Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
 858 on all files in those directories (and their subdirectories, etc.).  B<-r>
 859 and B<-a> are mutually exclusive.
 860
 861 =item -a
 862
 863 Run automagically; convert B<headerfiles>, as well as any B<.h> files
 864 which they include.  This option will search for B<.h> files in all
 865 directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
 866 mutually exclusive.
 867
 868 =item -l
 869
 870 Symbolic links will be replicated in the destination directory.  If B<-l>
 871 is not specified, then links are skipped over.
 872
 873 =item -h
 874
 875 Put ``hints'' in the .ph files which will help in locating problems with
 876 I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
 877 errors, instead of the cryptic
 878
 879         [ some error condition ] at (eval mmm) line nnn
 880
 881 you will see the slightly more helpful
 882
 883         [ some error condition ] at filename.ph line nnn
 884
 885 However, the B<.ph> files almost double in size when built using B<-h>.
 886
 887 =item -D
 888
 889 Include the code from the B<.h> file as a comment in the B<.ph> file.
 890 This is primarily used for debugging I<h2ph>.
 891
 892 =item -Q
 893
 894 ``Quiet'' mode; don't print out the names of the files being converted.
 895
 896 =back
 897
 898 =head1 ENVIRONMENT
 899
 900 No environment variables are used.
 901
 902 =head1 FILES
 903
 904  /usr/include/*.h
 905  /usr/include/sys/*.h
 906
 907 etc.
 908
 909 =head1 AUTHOR
 910
 911 Larry Wall
 912
 913 =head1 SEE ALSO
 914
 915 perl(1)
 916
 917 =head1 DIAGNOSTICS
 918
 919 The usual warnings if it can't read or write the files involved.
 920
 921 =head1 BUGS
 922
 923 Doesn't construct the %sizeof array for you.
 924
 925 It doesn't handle all C constructs, but it does attempt to isolate
 926 definitions inside evals so that you can get at the definitions
 927 that it can translate.
 928
 929 It's only intended as a rough tool.
 930 You may need to dicker with the files produced.
 931
 932 You have to run this program by hand; it's not run as part of the Perl
 933 installation.
 934
 935 Doesn't handle complicated expressions built piecemeal, a la:
 936
 937     enum {
 938         FIRST_VALUE,
 939         SECOND_VALUE,
 940     #ifdef ABC
 941         THIRD_VALUE
 942     #endif
 943     };
 944
 945 Doesn't necessarily locate all of your C compiler's internally-defined
 946 symbols.
 947
 948 =cut
 949
 950 !NO!SUBS!
 951
 952 close OUT or die "Can't close $file: $!";
 953 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 954 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 955 chdir $origdir;