lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 use Cwd ();
 516
 517 my $_initial_cwd;
 518
 519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 520
 521 BEGIN {
 522     require feature;
 523     $^V =~ /^v(\d+\.\d+)/;
 524     feature->import(":$1");
 525     $_initial_cwd = Cwd::getcwd();
 526 }
 527
 528 # Debugger for Perl 5.00x; perl5db.pl patch level:
 529 use vars qw($VERSION $header);
 530
 531 # bump to X.XX in blead, only use X.XX_XX in maint
 532 $VERSION = '1.50';
 533
 534 $header = "perl5db.pl version $VERSION";
 535
 536 =head1 DEBUGGER ROUTINES
 537
 538 =head2 C<DB::eval()>
 539
 540 This function replaces straight C<eval()> inside the debugger; it simplifies
 541 the process of evaluating code in the user's context.
 542
 543 The code to be evaluated is passed via the package global variable
 544 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 545
 546 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 547 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 548 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 549 user's current package, grabbed when C<DB::DB> got control.  This causes the
 550 proper context to be used when the eval is actually done.  Afterward, we
 551 restore C<$trace>, C<$single>, and C<$^D>.
 552
 553 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 554 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 555 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 556 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 557 considered sane by the debugger. If there was an C<eval()> error, we print
 558 it on the debugger's output. If C<$onetimedump> is defined, we call
 559 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 560 'methods'. Setting it to something else causes the debugger to do the eval
 561 but not print the result - handy if you want to do something else with it
 562 (the "watch expressions" code does this to get the value of the watch
 563 expression but not show it unless it matters).
 564
 565 In any case, we then return the list of output from C<eval> to the caller,
 566 and unwinding restores the former version of C<$@> in C<@saved> as well
 567 (the localization of C<$saved[0]> goes away at the end of this scope).
 568
 569 =head3 Parameters and variables influencing execution of DB::eval()
 570
 571 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 572 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 573 The variables listed below influence C<DB::eval()>'s execution directly.
 574
 575 =over 4
 576
 577 =item C<$evalarg> - the thing to actually be eval'ed
 578
 579 =item C<$trace> - Current state of execution tracing
 580
 581 =item C<$single> - Current state of single-stepping
 582
 583 =item C<$onetimeDump> - what is to be displayed after the evaluation
 584
 585 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 586
 587 =back
 588
 589 The following variables are altered by C<DB::eval()> during its execution. They
 590 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 591
 592 =over 4
 593
 594 =item C<@res> - used to capture output from actual C<eval>.
 595
 596 =item C<$otrace> - saved value of C<$trace>.
 597
 598 =item C<$osingle> - saved value of C<$single>.
 599
 600 =item C<$od> - saved value of C<$^D>.
 601
 602 =item C<$saved[0]> - saved value of C<$@>.
 603
 604 =item $\ - for output of C<$@> if there is an evaluation error.
 605
 606 =back
 607
 608 =head3 The problem of lexicals
 609
 610 The context of C<DB::eval()> presents us with some problems. Obviously,
 611 we want to be 'sandboxed' away from the debugger's internals when we do
 612 the eval, but we need some way to control how punctuation variables and
 613 debugger globals are used.
 614
 615 We can't use local, because the code inside C<DB::eval> can see localized
 616 variables; and we can't use C<my> either for the same reason. The code
 617 in this routine compromises and uses C<my>.
 618
 619 After this routine is over, we don't have user code executing in the debugger's
 620 context, so we can use C<my> freely.
 621
 622 =cut
 623
 624 ############################################## Begin lexical danger zone
 625
 626 # 'my' variables used here could leak into (that is, be visible in)
 627 # the context that the code being evaluated is executing in. This means that
 628 # the code could modify the debugger's variables.
 629 #
 630 # Fiddling with the debugger's context could be Bad. We insulate things as
 631 # much as we can.
 632
 633 use vars qw(
 634     @args
 635     %break_on_load
 636     $CommandSet
 637     $CreateTTY
 638     $DBGR
 639     @dbline
 640     $dbline
 641     %dbline
 642     $dieLevel
 643     $filename
 644     $histfile
 645     $histsize
 646     $IN
 647     $inhibit_exit
 648     @ini_INC
 649     $ini_warn
 650     $maxtrace
 651     $od
 652     @options
 653     $osingle
 654     $otrace
 655     $pager
 656     $post
 657     %postponed
 658     $prc
 659     $pre
 660     $pretype
 661     $psh
 662     @RememberOnROptions
 663     $remoteport
 664     @res
 665     $rl
 666     @saved
 667     $signalLevel
 668     $sub
 669     $term
 670     $usercontext
 671     $warnLevel
 672 );
 673
 674 our (
 675     @cmdfhs,
 676     $evalarg,
 677     $frame,
 678     $hist,
 679     $ImmediateStop,
 680     $line,
 681     $onetimeDump,
 682     $onetimedumpDepth,
 683     %option,
 684     $OUT,
 685     $packname,
 686     $signal,
 687     $single,
 688     $start,
 689     %sub,
 690     $subname,
 691     $trace,
 692     $window,
 693 );
 694
 695 # Used to save @ARGV and extract any debugger-related flags.
 696 use vars qw(@ARGS);
 697
 698 # Used to prevent multiple entries to diesignal()
 699 # (if for instance diesignal() itself dies)
 700 use vars qw($panic);
 701
 702 # Used to prevent the debugger from running nonstop
 703 # after a restart
 704 our ($second_time);
 705
 706 sub _calc_usercontext {
 707     my ($package) = @_;
 708
 709     # Cancel strict completely for the evaluated code, so the code
 710     # the user evaluates won't be affected by it. (Shlomi Fish)
 711     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 712     . "package $package;";    # this won't let them modify, alas
 713 }
 714
 715 sub eval {
 716
 717     # 'my' would make it visible from user code
 718     #    but so does local! --tchrist
 719     # Remember: this localizes @DB::res, not @main::res.
 720     local @res;
 721     {
 722
 723         # Try to keep the user code from messing  with us. Save these so that
 724         # even if the eval'ed code changes them, we can put them back again.
 725         # Needed because the user could refer directly to the debugger's
 726         # package globals (and any 'my' variables in this containing scope)
 727         # inside the eval(), and we want to try to stay safe.
 728         local $otrace  = $trace;
 729         local $osingle = $single;
 730         local $od      = $^D;
 731
 732         # Untaint the incoming eval() argument.
 733         { ($evalarg) = $evalarg =~ /(.*)/s; }
 734
 735         # $usercontext built in DB::DB near the comment
 736         # "set up the context for DB::eval ..."
 737         # Evaluate and save any results.
 738         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 739
 740         # Restore those old values.
 741         $trace  = $otrace;
 742         $single = $osingle;
 743         $^D     = $od;
 744     }
 745
 746     # Save the current value of $@, and preserve it in the debugger's copy
 747     # of the saved precious globals.
 748     my $at = $@;
 749
 750     # Since we're only saving $@, we only have to localize the array element
 751     # that it will be stored in.
 752     local $saved[0];    # Preserve the old value of $@
 753     eval { &DB::save };
 754
 755     # Now see whether we need to report an error back to the user.
 756     if ($at) {
 757         local $\ = '';
 758         print $OUT $at;
 759     }
 760
 761     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 762     # are package globals.
 763     elsif ($onetimeDump) {
 764         if ( $onetimeDump eq 'dump' ) {
 765             local $option{dumpDepth} = $onetimedumpDepth
 766               if defined $onetimedumpDepth;
 767             dumpit( $OUT, \@res );
 768         }
 769         elsif ( $onetimeDump eq 'methods' ) {
 770             methods( $res[0] );
 771         }
 772     } ## end elsif ($onetimeDump)
 773     @res;
 774 } ## end sub eval
 775
 776 ############################################## End lexical danger zone
 777
 778 # After this point it is safe to introduce lexicals.
 779 # The code being debugged will be executing in its own context, and
 780 # can't see the inside of the debugger.
 781 #
 782 # However, one should not overdo it: leave as much control from outside as
 783 # possible. If you make something a lexical, it's not going to be addressable
 784 # from outside the debugger even if you know its name.
 785
 786 # This file is automatically included if you do perl -d.
 787 # It's probably not useful to include this yourself.
 788 #
 789 # Before venturing further into these twisty passages, it is
 790 # wise to read the perldebguts man page or risk the ire of dragons.
 791 #
 792 # (It should be noted that perldebguts will tell you a lot about
 793 # the underlying mechanics of how the debugger interfaces into the
 794 # Perl interpreter, but not a lot about the debugger itself. The new
 795 # comments in this code try to address this problem.)
 796
 797 # Note that no subroutine call is possible until &DB::sub is defined
 798 # (for subroutines defined outside of the package DB). In fact the same is
 799 # true if $deep is not defined.
 800
 801 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 802
 803 # modified Perl debugger, to be run from Emacs in perldb-mode
 804 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 805 # Johan Vromans -- upgrade to 4.0 pl 10
 806 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 807 ########################################################################
 808
 809 =head1 DEBUGGER INITIALIZATION
 810
 811 The debugger starts up in phases.
 812
 813 =head2 BASIC SETUP
 814
 815 First, it initializes the environment it wants to run in: turning off
 816 warnings during its own compilation, defining variables which it will need
 817 to avoid warnings later, setting itself up to not exit when the program
 818 terminates, and defaulting to printing return values for the C<r> command.
 819
 820 =cut
 821
 822 # Needed for the statement after exec():
 823 #
 824 # This BEGIN block is simply used to switch off warnings during debugger
 825 # compilation. Probably it would be better practice to fix the warnings,
 826 # but this is how it's done at the moment.
 827
 828 BEGIN {
 829     $ini_warn = $^W;
 830     $^W       = 0;
 831 }    # Switch compilation warnings off until another BEGIN.
 832
 833 local ($^W) = 0;    # Switch run-time warnings off during init.
 834
 835 =head2 THREADS SUPPORT
 836
 837 If we are running under a threaded Perl, we require threads and threads::shared
 838 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 839 threaded debugger control.  C<-dt> can also be used to set this.
 840
 841 Each new thread will be announced and the debugger prompt will always inform
 842 you of each new thread created.  It will also indicate the thread id in which
 843 we are currently running within the prompt like this:
 844
 845     [tid] DB<$i>
 846
 847 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 848 command prompt.  The prompt will show: C<[0]> when running under threads, but
 849 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 850
 851 While running under threads, when you set or delete a breakpoint (etc.), this
 852 will apply to all threads, not just the currently running one.  When you are
 853 in a currently executing thread, you will stay there until it completes.  With
 854 the current implementation it is not currently possible to hop from one thread
 855 to another.
 856
 857 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 858
 859 Note that threading support was built into the debugger as of Perl version
 860 C<5.8.6> and debugger version C<1.2.8>.
 861
 862 =cut
 863
 864 BEGIN {
 865     # ensure we can share our non-threaded variables or no-op
 866     if ($ENV{PERL5DB_THREADED}) {
 867         require threads;
 868         require threads::shared;
 869         import threads::shared qw(share);
 870         $DBGR;
 871         share(\$DBGR);
 872         lock($DBGR);
 873         print "Threads support enabled\n";
 874     } else {
 875         *lock = sub(*) {};
 876         *share = sub(\[$@%]) {};
 877     }
 878 }
 879
 880 # These variables control the execution of 'dumpvar.pl'.
 881 {
 882     package dumpvar;
 883     use vars qw(
 884     $hashDepth
 885     $arrayDepth
 886     $dumpDBFiles
 887     $dumpPackages
 888     $quoteHighBit
 889     $printUndef
 890     $globPrint
 891     $usageOnly
 892     );
 893 }
 894
 895 # used to control die() reporting in diesignal()
 896 {
 897     package Carp;
 898     use vars qw($CarpLevel);
 899 }
 900
 901 # without threads, $filename is not defined until DB::DB is called
 902 share($main::{'_<'.$filename}) if defined $filename;
 903
 904 # Command-line + PERLLIB:
 905 # Save the contents of @INC before they are modified elsewhere.
 906 @ini_INC = @INC;
 907
 908 # This was an attempt to clear out the previous values of various
 909 # trapped errors. Apparently it didn't help. XXX More info needed!
 910 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 911
 912 # We set these variables to safe values. We don't want to blindly turn
 913 # off warnings, because other packages may still want them.
 914 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 915                                    # (local $^W cannot help - other packages!).
 916
 917 # Default to not exiting when program finishes; print the return
 918 # value when the 'r' command is used to return from a subroutine.
 919 $inhibit_exit = $option{PrintRet} = 1;
 920
 921 use vars qw($trace_to_depth);
 922
 923 # Default to 1E9 so it won't be limited to a certain recursion depth.
 924 $trace_to_depth = 1E9;
 925
 926 =head1 OPTION PROCESSING
 927
 928 The debugger's options are actually spread out over the debugger itself and
 929 C<dumpvar.pl>; some of these are variables to be set, while others are
 930 subs to be called with a value. To try to make this a little easier to
 931 manage, the debugger uses a few data structures to define what options
 932 are legal and how they are to be processed.
 933
 934 First, the C<@options> array defines the I<names> of all the options that
 935 are to be accepted.
 936
 937 =cut
 938
 939 @options = qw(
 940   CommandSet   HistFile      HistSize
 941   hashDepth    arrayDepth    dumpDepth
 942   DumpDBFiles  DumpPackages  DumpReused
 943   compactDump  veryCompact   quote
 944   HighBit      undefPrint    globPrint
 945   PrintRet     UsageOnly     frame
 946   AutoTrace    TTY           noTTY
 947   ReadLine     NonStop       LineInfo
 948   maxTraceLen  recallCommand ShellBang
 949   pager        tkRunning     ornaments
 950   signalLevel  warnLevel     dieLevel
 951   inhibit_exit ImmediateStop bareStringify
 952   CreateTTY    RemotePort    windowSize
 953   DollarCaretP
 954 );
 955
 956 @RememberOnROptions = qw(DollarCaretP);
 957
 958 =pod
 959
 960 Second, C<optionVars> lists the variables that each option uses to save its
 961 state.
 962
 963 =cut
 964
 965 use vars qw(%optionVars);
 966
 967 %optionVars = (
 968     hashDepth     => \$dumpvar::hashDepth,
 969     arrayDepth    => \$dumpvar::arrayDepth,
 970     CommandSet    => \$CommandSet,
 971     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 972     DumpPackages  => \$dumpvar::dumpPackages,
 973     DumpReused    => \$dumpvar::dumpReused,
 974     HighBit       => \$dumpvar::quoteHighBit,
 975     undefPrint    => \$dumpvar::printUndef,
 976     globPrint     => \$dumpvar::globPrint,
 977     UsageOnly     => \$dumpvar::usageOnly,
 978     CreateTTY     => \$CreateTTY,
 979     bareStringify => \$dumpvar::bareStringify,
 980     frame         => \$frame,
 981     AutoTrace     => \$trace,
 982     inhibit_exit  => \$inhibit_exit,
 983     maxTraceLen   => \$maxtrace,
 984     ImmediateStop => \$ImmediateStop,
 985     RemotePort    => \$remoteport,
 986     windowSize    => \$window,
 987     HistFile      => \$histfile,
 988     HistSize      => \$histsize,
 989 );
 990
 991 =pod
 992
 993 Third, C<%optionAction> defines the subroutine to be called to process each
 994 option.
 995
 996 =cut
 997
 998 use vars qw(%optionAction);
 999
1000 %optionAction = (
1001     compactDump   => \&dumpvar::compactDump,
1002     veryCompact   => \&dumpvar::veryCompact,
1003     quote         => \&dumpvar::quote,
1004     TTY           => \&TTY,
1005     noTTY         => \&noTTY,
1006     ReadLine      => \&ReadLine,
1007     NonStop       => \&NonStop,
1008     LineInfo      => \&LineInfo,
1009     recallCommand => \&recallCommand,
1010     ShellBang     => \&shellBang,
1011     pager         => \&pager,
1012     signalLevel   => \&signalLevel,
1013     warnLevel     => \&warnLevel,
1014     dieLevel      => \&dieLevel,
1015     tkRunning     => \&tkRunning,
1016     ornaments     => \&ornaments,
1017     RemotePort    => \&RemotePort,
1018     DollarCaretP  => \&DollarCaretP,
1019 );
1020
1021 =pod
1022
1023 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1024 option is used.
1025
1026 =cut
1027
1028 # Note that this list is not complete: several options not listed here
1029 # actually require that dumpvar.pl be loaded for them to work, but are
1030 # not in the table. A subsequent patch will correct this problem; for
1031 # the moment, we're just recommenting, and we are NOT going to change
1032 # function.
1033 use vars qw(%optionRequire);
1034
1035 %optionRequire = (
1036     compactDump => 'dumpvar.pl',
1037     veryCompact => 'dumpvar.pl',
1038     quote       => 'dumpvar.pl',
1039 );
1040
1041 =pod
1042
1043 There are a number of initialization-related variables which can be set
1044 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1045 variable. These are:
1046
1047 =over 4
1048
1049 =item C<$rl> - readline control XXX needs more explanation
1050
1051 =item C<$warnLevel> - whether or not debugger takes over warning handling
1052
1053 =item C<$dieLevel> - whether or not debugger takes over die handling
1054
1055 =item C<$signalLevel> - whether or not debugger takes over signal handling
1056
1057 =item C<$pre> - preprompt actions (array reference)
1058
1059 =item C<$post> - postprompt actions (array reference)
1060
1061 =item C<$pretype>
1062
1063 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1064
1065 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1066
1067 =back
1068
1069 =cut
1070
1071 # These guys may be defined in $ENV{PERL5DB} :
1072 $rl          = 1     unless defined $rl;
1073 $warnLevel   = 1     unless defined $warnLevel;
1074 $dieLevel    = 1     unless defined $dieLevel;
1075 $signalLevel = 1     unless defined $signalLevel;
1076 $pre         = []    unless defined $pre;
1077 $post        = []    unless defined $post;
1078 $pretype     = []    unless defined $pretype;
1079 $CreateTTY   = 3     unless defined $CreateTTY;
1080 $CommandSet  = '580' unless defined $CommandSet;
1081
1082 share($rl);
1083 share($warnLevel);
1084 share($dieLevel);
1085 share($signalLevel);
1086 share($pre);
1087 share($post);
1088 share($pretype);
1089 share($rl);
1090 share($CreateTTY);
1091 share($CommandSet);
1092
1093 =pod
1094
1095 The default C<die>, C<warn>, and C<signal> handlers are set up.
1096
1097 =cut
1098
1099 warnLevel($warnLevel);
1100 dieLevel($dieLevel);
1101 signalLevel($signalLevel);
1102
1103 =pod
1104
1105 The pager to be used is needed next. We try to get it from the
1106 environment first.  If it's not defined there, we try to find it in
1107 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1108 then call the C<pager()> function to save the pager name.
1109
1110 =cut
1111
1112 # This routine makes sure $pager is set up so that '|' can use it.
1113 pager(
1114
1115     # If PAGER is defined in the environment, use it.
1116     defined $ENV{PAGER}
1117     ? $ENV{PAGER}
1118
1119       # If not, see if Config.pm defines it.
1120     : eval { require Config }
1121       && defined $Config::Config{pager}
1122     ? $Config::Config{pager}
1123
1124       # If not, fall back to 'more'.
1125     : 'more'
1126   )
1127   unless defined $pager;
1128
1129 =pod
1130
1131 We set up the command to be used to access the man pages, the command
1132 recall character (C<!> unless otherwise defined) and the shell escape
1133 character (C<!> unless otherwise defined). Yes, these do conflict, and
1134 neither works in the debugger at the moment.
1135
1136 =cut
1137
1138 setman();
1139
1140 # Set up defaults for command recall and shell escape (note:
1141 # these currently don't work in linemode debugging).
1142 recallCommand("!") unless defined $prc;
1143 shellBang("!")     unless defined $psh;
1144
1145 =pod
1146
1147 We then set up the gigantic string containing the debugger help.
1148 We also set the limit on the number of arguments we'll display during a
1149 trace.
1150
1151 =cut
1152
1153 sethelp();
1154
1155 # If we didn't get a default for the length of eval/stack trace args,
1156 # set it here.
1157 $maxtrace = 400 unless defined $maxtrace;
1158
1159 =head2 SETTING UP THE DEBUGGER GREETING
1160
1161 The debugger I<greeting> helps to inform the user how many debuggers are
1162 running, and whether the current debugger is the primary or a child.
1163
1164 If we are the primary, we just hang onto our pid so we'll have it when
1165 or if we start a child debugger. If we are a child, we'll set things up
1166 so we'll have a unique greeting and so the parent will give us our own
1167 TTY later.
1168
1169 We save the current contents of the C<PERLDB_PIDS> environment variable
1170 because we mess around with it. We'll also need to hang onto it because
1171 we'll need it if we restart.
1172
1173 Child debuggers make a label out of the current PID structure recorded in
1174 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1175 yet so the parent will give them one later via C<resetterm()>.
1176
1177 =cut
1178
1179 # Save the current contents of the environment; we're about to
1180 # much with it. We'll need this if we have to restart.
1181 use vars qw($ini_pids);
1182 $ini_pids = $ENV{PERLDB_PIDS};
1183
1184 use vars qw ($pids $term_pid);
1185
1186 if ( defined $ENV{PERLDB_PIDS} ) {
1187
1188     # We're a child. Make us a label out of the current PID structure
1189     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1190     # a term yet so the parent will give us one later via resetterm().
1191
1192     my $env_pids = $ENV{PERLDB_PIDS};
1193     $pids = "[$env_pids]";
1194
1195     # Unless we are on OpenVMS, all programs under the DCL shell run under
1196     # the same PID.
1197
1198     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1199         $term_pid         = $$;
1200     }
1201     else {
1202         $ENV{PERLDB_PIDS} .= "->$$";
1203         $term_pid = -1;
1204     }
1205
1206 } ## end if (defined $ENV{PERLDB_PIDS...
1207 else {
1208
1209     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1210     # child debugger, and mark us as the parent, so we'll know to set up
1211     # more TTY's is we have to.
1212     $ENV{PERLDB_PIDS} = "$$";
1213     $pids             = "[pid=$$]";
1214     $term_pid         = $$;
1215 }
1216
1217 use vars qw($pidprompt);
1218 $pidprompt = '';
1219
1220 # Sets up $emacs as a synonym for $slave_editor.
1221 our ($slave_editor);
1222 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1223
1224 =head2 READING THE RC FILE
1225
1226 The debugger will read a file of initialization options if supplied. If
1227 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1228
1229 =cut
1230
1231 # As noted, this test really doesn't check accurately that the debugger
1232 # is running at a terminal or not.
1233
1234 use vars qw($rcfile);
1235 {
1236     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1237     # this is the wrong metric!
1238     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1239 }
1240
1241 =pod
1242
1243 The debugger does a safety test of the file to be read. It must be owned
1244 either by the current user or root, and must only be writable by the owner.
1245
1246 =cut
1247
1248 # This wraps a safety test around "do" to read and evaluate the init file.
1249 #
1250 # This isn't really safe, because there's a race
1251 # between checking and opening.  The solution is to
1252 # open and fstat the handle, but then you have to read and
1253 # eval the contents.  But then the silly thing gets
1254 # your lexical scope, which is unfortunate at best.
1255 sub safe_do {
1256     my $file = shift;
1257
1258     # Just exactly what part of the word "CORE::" don't you understand?
1259     local $SIG{__WARN__};
1260     local $SIG{__DIE__};
1261
1262     unless ( is_safe_file($file) ) {
1263         CORE::warn <<EO_GRIPE;
1264 perldb: Must not source insecure rcfile $file.
1265         You or the superuser must be the owner, and it must not
1266         be writable by anyone but its owner.
1267 EO_GRIPE
1268         return;
1269     } ## end unless (is_safe_file($file...
1270
1271     do $file;
1272     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1273 } ## end sub safe_do
1274
1275 # This is the safety test itself.
1276 #
1277 # Verifies that owner is either real user or superuser and that no
1278 # one but owner may write to it.  This function is of limited use
1279 # when called on a path instead of upon a handle, because there are
1280 # no guarantees that filename (by dirent) whose file (by ino) is
1281 # eventually accessed is the same as the one tested.
1282 # Assumes that the file's existence is not in doubt.
1283 sub is_safe_file {
1284     my $path = shift;
1285     stat($path) || return;    # mysteriously vaporized
1286     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1287
1288     return 0 if $uid != 0 && $uid != $<;
1289     return 0 if $mode & 022;
1290     return 1;
1291 } ## end sub is_safe_file
1292
1293 # If the rcfile (whichever one we decided was the right one to read)
1294 # exists, we safely do it.
1295 if ( -f $rcfile ) {
1296     safe_do("./$rcfile");
1297 }
1298
1299 # If there isn't one here, try the user's home directory.
1300 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1301     safe_do("$ENV{HOME}/$rcfile");
1302 }
1303
1304 # Else try the login directory.
1305 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1306     safe_do("$ENV{LOGDIR}/$rcfile");
1307 }
1308
1309 # If the PERLDB_OPTS variable has options in it, parse those out next.
1310 if ( defined $ENV{PERLDB_OPTS} ) {
1311     parse_options( $ENV{PERLDB_OPTS} );
1312 }
1313
1314 =pod
1315
1316 The last thing we do during initialization is determine which subroutine is
1317 to be used to obtain a new terminal when a new debugger is started. Right now,
1318 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1319 (darwin).
1320
1321 =cut
1322
1323 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1324 # Works if you're running an xterm or xterm-like window, or you're on
1325 # OS/2, or on Mac OS X. This may need some expansion.
1326
1327 if (not defined &get_fork_TTY)       # only if no routine exists
1328 {
1329     if ( defined $remoteport ) {
1330                                                  # Expect an inetd-like server
1331         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1332     }
1333     elsif (defined $ENV{TERM}                    # If we know what kind
1334                                                  # of terminal this is,
1335         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1336         and defined $ENV{DISPLAY}                # and what display it's on,
1337       )
1338     {
1339         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1340     }
1341     elsif ( $ENV{TMUX} ) {
1342         *get_fork_TTY = \&tmux_get_fork_TTY;
1343     }
1344     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1345         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1346     }
1347     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1348             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1349             and $ENV{TERM_PROGRAM}
1350                 eq 'Apple_Terminal'              # Terminal.app
1351             )
1352     {
1353         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1354     }
1355 } ## end if (not defined &get_fork_TTY...
1356
1357 # untaint $^O, which may have been tainted by the last statement.
1358 # see bug [perl #24674]
1359 $^O =~ m/^(.*)\z/;
1360 $^O = $1;
1361
1362 # Here begin the unreadable code.  It needs fixing.
1363
1364 =head2 RESTART PROCESSING
1365
1366 This section handles the restart command. When the C<R> command is invoked, it
1367 tries to capture all of the state it can into environment variables, and
1368 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1369 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1370 the R command stuffed into the environment variables.
1371
1372   PERLDB_RESTART   - flag only, contains no restart data itself.
1373   PERLDB_HIST      - command history, if it's available
1374   PERLDB_ON_LOAD   - breakpoints set by the rc file
1375   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1376                      and have actions
1377   PERLDB_VISITED   - files that had breakpoints
1378   PERLDB_FILE_...  - breakpoints for a file
1379   PERLDB_OPT       - active options
1380   PERLDB_INC       - the original @INC
1381   PERLDB_PRETYPE   - preprompt debugger actions
1382   PERLDB_PRE       - preprompt Perl code
1383   PERLDB_POST      - post-prompt Perl code
1384   PERLDB_TYPEAHEAD - typeahead captured by readline()
1385
1386 We chug through all these variables and plug the values saved in them
1387 back into the appropriate spots in the debugger.
1388
1389 =cut
1390
1391 use vars qw(%postponed_file @typeahead);
1392
1393 our (@hist, @truehist);
1394
1395 sub _restore_shared_globals_after_restart
1396 {
1397     @hist          = get_list('PERLDB_HIST');
1398     %break_on_load = get_list("PERLDB_ON_LOAD");
1399     %postponed     = get_list("PERLDB_POSTPONE");
1400
1401     share(@hist);
1402     share(@truehist);
1403     share(%break_on_load);
1404     share(%postponed);
1405 }
1406
1407 sub _restore_breakpoints_and_actions {
1408
1409     my @had_breakpoints = get_list("PERLDB_VISITED");
1410
1411     for my $file_idx ( 0 .. $#had_breakpoints ) {
1412         my $filename = $had_breakpoints[$file_idx];
1413         my %pf = get_list("PERLDB_FILE_$file_idx");
1414         $postponed_file{ $filename } = \%pf if %pf;
1415         my @lines = sort {$a <=> $b} keys(%pf);
1416         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1417         for my $line_idx (0 .. $#lines) {
1418             _set_breakpoint_enabled_status(
1419                 $filename,
1420                 $lines[$line_idx],
1421                 ($enabled_statuses[$line_idx] ? 1 : ''),
1422             );
1423         }
1424     }
1425
1426     return;
1427 }
1428
1429 sub _restore_options_after_restart
1430 {
1431     my %options_map = get_list("PERLDB_OPT");
1432
1433     while ( my ( $opt, $val ) = each %options_map ) {
1434         $val =~ s/[\\\']/\\$1/g;
1435         parse_options("$opt'$val'");
1436     }
1437
1438     return;
1439 }
1440
1441 sub _restore_globals_after_restart
1442 {
1443     # restore original @INC
1444     @INC     = get_list("PERLDB_INC");
1445     @ini_INC = @INC;
1446
1447     # return pre/postprompt actions and typeahead buffer
1448     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1449     $pre       = [ get_list("PERLDB_PRE") ];
1450     $post      = [ get_list("PERLDB_POST") ];
1451     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1452
1453     return;
1454 }
1455
1456
1457 if ( exists $ENV{PERLDB_RESTART} ) {
1458
1459     # We're restarting, so we don't need the flag that says to restart anymore.
1460     delete $ENV{PERLDB_RESTART};
1461
1462     # $restart = 1;
1463     _restore_shared_globals_after_restart();
1464
1465     _restore_breakpoints_and_actions();
1466
1467     # restore options
1468     _restore_options_after_restart();
1469
1470     _restore_globals_after_restart();
1471 } ## end if (exists $ENV{PERLDB_RESTART...
1472
1473 =head2 SETTING UP THE TERMINAL
1474
1475 Now, we'll decide how the debugger is going to interact with the user.
1476 If there's no TTY, we set the debugger to run non-stop; there's not going
1477 to be anyone there to enter commands.
1478
1479 =cut
1480
1481 use vars qw($notty $console $tty $LINEINFO);
1482 use vars qw($lineinfo $doccmd);
1483
1484 our ($runnonstop);
1485
1486 # Local autoflush to avoid rt#116769,
1487 # as calling IO::File methods causes an unresolvable loop
1488 # that results in debugger failure.
1489 sub _autoflush {
1490     my $o = select($_[0]);
1491     $|++;
1492     select($o);
1493 }
1494
1495 if ($notty) {
1496     $runnonstop = 1;
1497     share($runnonstop);
1498 }
1499
1500 =pod
1501
1502 If there is a TTY, we have to determine who it belongs to before we can
1503 proceed. If this is a slave editor or graphical debugger (denoted by
1504 the first command-line switch being '-emacs'), we shift this off and
1505 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1506
1507 =cut
1508
1509 else {
1510
1511     # Is Perl being run from a slave editor or graphical debugger?
1512     # If so, don't use readline, and set $slave_editor = 1.
1513     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1514         $rl = 0;
1515         shift(@main::ARGV);
1516     }
1517
1518     #require Term::ReadLine;
1519
1520 =pod
1521
1522 We then determine what the console should be on various systems:
1523
1524 =over 4
1525
1526 =item * Cygwin - We use C<stdin> instead of a separate device.
1527
1528 =cut
1529
1530     if ( $^O eq 'cygwin' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         undef $console;
1534     }
1535
1536 =item * Unix - use F</dev/tty>.
1537
1538 =cut
1539
1540     elsif ( -e "/dev/tty" ) {
1541         $console = "/dev/tty";
1542     }
1543
1544 =item * Windows or MSDOS - use C<con>.
1545
1546 =cut
1547
1548     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1549         $console = "con";
1550     }
1551
1552 =item * AmigaOS - use C<CONSOLE:>.
1553
1554 =cut
1555
1556     elsif ( $^O eq 'amigaos' ) {
1557         $console = "CONSOLE:";
1558     }
1559
1560 =item * VMS - use C<sys$command>.
1561
1562 =cut
1563
1564     elsif ($^O eq 'VMS') {
1565         $console = 'sys$command';
1566     }
1567
1568 # Keep this last.
1569
1570     else {
1571         _db_warn("Can't figure out your console, using stdin");
1572         undef $console;
1573     }
1574
1575 =pod
1576
1577 =back
1578
1579 Several other systems don't use a specific console. We C<undef $console>
1580 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1581 with a slave editor).
1582
1583 =cut
1584
1585     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1586
1587         # /dev/tty is binary. use stdin for textmode
1588         $console = undef;
1589     }
1590
1591     if ( $^O eq 'NetWare' ) {
1592
1593         # /dev/tty is binary. use stdin for textmode
1594         $console = undef;
1595     }
1596
1597     # In OS/2, we need to use STDIN to get textmode too, even though
1598     # it pretty much looks like Unix otherwise.
1599     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1600     {    # In OS/2
1601         $console = undef;
1602     }
1603
1604 =pod
1605
1606 If there is a TTY hanging around from a parent, we use that as the console.
1607
1608 =cut
1609
1610     $console = $tty if defined $tty;
1611
1612 =head2 SOCKET HANDLING
1613
1614 The debugger is capable of opening a socket and carrying out a debugging
1615 session over the socket.
1616
1617 If C<RemotePort> was defined in the options, the debugger assumes that it
1618 should try to start a debugging session on that port. It builds the socket
1619 and then tries to connect the input and output filehandles to it.
1620
1621 =cut
1622
1623     # Handle socket stuff.
1624
1625     if ( defined $remoteport ) {
1626
1627         # If RemotePort was defined in the options, connect input and output
1628         # to the socket.
1629         $IN = $OUT = connect_remoteport();
1630     } ## end if (defined $remoteport)
1631
1632 =pod
1633
1634 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1635 this is probably a situation where multiple debuggers are running (for example,
1636 a backticked command that starts up another debugger). We create a new IN and
1637 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1638 and if we can.
1639
1640 =cut
1641
1642     # Non-socket.
1643     else {
1644
1645         # Two debuggers running (probably a system or a backtick that invokes
1646         # the debugger itself under the running one). create a new IN and OUT
1647         # filehandle, and do the necessary mojo to create a new tty if we
1648         # know how, and we can.
1649         create_IN_OUT(4) if $CreateTTY & 4;
1650         if ($console) {
1651
1652             # If we have a console, check to see if there are separate ins and
1653             # outs to open. (They are assumed identical if not.)
1654
1655             my ( $i, $o ) = split /,/, $console;
1656             $o = $i unless defined $o;
1657
1658             # read/write on in, or just read, or read on STDIN.
1659             open( IN,      "+<$i" )
1660               || open( IN, "<$i" )
1661               || open( IN, "<&STDIN" );
1662
1663             # read/write/create/clobber out, or write/create/clobber out,
1664             # or merge with STDERR, or merge with STDOUT.
1665                  open( OUT, "+>$o" )
1666               || open( OUT, ">$o" )
1667               || open( OUT, ">&STDERR" )
1668               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1669
1670         } ## end if ($console)
1671         elsif ( not defined $console ) {
1672
1673             # No console. Open STDIN.
1674             open( IN, "<&STDIN" );
1675
1676             # merge with STDERR, or with STDOUT.
1677             open( OUT,      ">&STDERR" )
1678               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1679             $console = 'STDIN/OUT';
1680         } ## end elsif (not defined $console)
1681
1682         # Keep copies of the filehandles so that when the pager runs, it
1683         # can close standard input without clobbering ours.
1684         if ($console or (not defined($console))) {
1685             $IN = \*IN;
1686             $OUT = \*OUT;
1687         }
1688     } ## end elsif (from if(defined $remoteport))
1689
1690     # Unbuffer DB::OUT. We need to see responses right away.
1691     _autoflush($OUT);
1692
1693     # Line info goes to debugger output unless pointed elsewhere.
1694     # Pointing elsewhere makes it possible for slave editors to
1695     # keep track of file and position. We have both a filehandle
1696     # and a I/O description to keep track of.
1697     $LINEINFO = $OUT     unless defined $LINEINFO;
1698     $lineinfo = $console unless defined $lineinfo;
1699     # share($LINEINFO); # <- unable to share globs
1700     share($lineinfo);   #
1701
1702 =pod
1703
1704 To finish initialization, we show the debugger greeting,
1705 and then call the C<afterinit()> subroutine if there is one.
1706
1707 =cut
1708
1709     # Show the debugger greeting.
1710     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1711     unless ($runnonstop) {
1712         local $\ = '';
1713         local $, = '';
1714         if ( $term_pid eq '-1' ) {
1715             print $OUT "\nDaughter DB session started...\n";
1716         }
1717         else {
1718             print $OUT "\nLoading DB routines from $header\n";
1719             print $OUT (
1720                 "Editor support ",
1721                 $slave_editor ? "enabled" : "available", ".\n"
1722             );
1723             print $OUT
1724 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1725         } ## end else [ if ($term_pid eq '-1')
1726     } ## end unless ($runnonstop)
1727 } ## end else [ if ($notty)
1728
1729 # XXX This looks like a bug to me.
1730 # Why copy to @ARGS and then futz with @args?
1731 @ARGS = @ARGV;
1732 # for (@args) {
1733     # Make sure backslashes before single quotes are stripped out, and
1734     # keep args unless they are numeric (XXX why?)
1735     # s/\'/\\\'/g;                      # removed while not justified understandably
1736     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1737 # }
1738
1739 # If there was an afterinit() sub defined, call it. It will get
1740 # executed in our scope, so it can fiddle with debugger globals.
1741 if ( defined &afterinit ) {    # May be defined in $rcfile
1742     afterinit();
1743 }
1744
1745 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1746 use vars qw($I_m_init);
1747
1748 $I_m_init = 1;
1749
1750 ############################################################ Subroutines
1751
1752 =head1 SUBROUTINES
1753
1754 =head2 DB
1755
1756 This gigantic subroutine is the heart of the debugger. Called before every
1757 statement, its job is to determine if a breakpoint has been reached, and
1758 stop if so; read commands from the user, parse them, and execute
1759 them, and then send execution off to the next statement.
1760
1761 Note that the order in which the commands are processed is very important;
1762 some commands earlier in the loop will actually alter the C<$cmd> variable
1763 to create other commands to be executed later. This is all highly I<optimized>
1764 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1765 see what's happening in any given command.
1766
1767 =cut
1768
1769 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1770
1771 use vars qw(
1772     $action
1773     $cmd
1774     $file
1775     $filename_ini
1776     $finished
1777     %had_breakpoints
1778     $level
1779     $max
1780     $package
1781     $try
1782 );
1783
1784 our (
1785     %alias,
1786     $doret,
1787     $end,
1788     $fall_off_end,
1789     $incr,
1790     $laststep,
1791     $rc,
1792     $sh,
1793     $stack_depth,
1794     @stack,
1795     @to_watch,
1796     @old_watch,
1797 );
1798
1799 sub _DB__determine_if_we_should_break
1800 {
1801     # if we have something here, see if we should break.
1802     # $stop is lexical and local to this block - $action on the other hand
1803     # is global.
1804     my $stop;
1805
1806     if ( $dbline{$line}
1807         && _is_breakpoint_enabled($filename, $line)
1808         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1809     {
1810
1811         # Stop if the stop criterion says to just stop.
1812         if ( $stop eq '1' ) {
1813             $signal |= 1;
1814         }
1815
1816         # It's a conditional stop; eval it in the user's context and
1817         # see if we should stop. If so, remove the one-time sigil.
1818         elsif ($stop) {
1819             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1820             # The &-call is here to ascertain the mutability of @_.
1821             &DB::eval;
1822             # If the breakpoint is temporary, then delete its enabled status.
1823             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1824                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1825             }
1826         }
1827     } ## end if ($dbline{$line} && ...
1828 }
1829
1830 sub _DB__is_finished {
1831     if ($finished and $level <= 1) {
1832         end_report();
1833         return 1;
1834     }
1835     else {
1836         return;
1837     }
1838 }
1839
1840 sub _DB__read_next_cmd
1841 {
1842     my ($tid) = @_;
1843
1844     # We have a terminal, or can get one ...
1845     if (!$term) {
1846         setterm();
1847     }
1848
1849     # ... and it belongs to this PID or we get one for this PID ...
1850     if ($term_pid != $$) {
1851         resetterm(1);
1852     }
1853
1854     # ... and we got a line of command input ...
1855     $cmd = DB::readline(
1856         "$pidprompt $tid DB"
1857         . ( '<' x $level )
1858         . ( $#hist + 1 )
1859         . ( '>' x $level ) . " "
1860     );
1861
1862     return defined($cmd);
1863 }
1864
1865 sub _DB__trim_command_and_return_first_component {
1866     my ($obj) = @_;
1867
1868     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1869     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1870
1871     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1872
1873     $obj->cmd_verb($verb);
1874     $obj->cmd_args($args);
1875
1876     return;
1877 }
1878
1879 sub _DB__handle_f_command {
1880     my ($obj) = @_;
1881
1882     if ($file = $obj->cmd_args) {
1883         # help for no arguments (old-style was return from sub).
1884         if ( !$file ) {
1885             print $OUT
1886             "The old f command is now the r command.\n";    # hint
1887             print $OUT "The new f command switches filenames.\n";
1888             next CMD;
1889         } ## end if (!$file)
1890
1891         # if not in magic file list, try a close match.
1892         if ( !defined $main::{ '_<' . $file } ) {
1893             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1894                 {
1895                     $try = substr( $try, 2 );
1896                     print $OUT "Choosing $try matching '$file':\n";
1897                     $file = $try;
1898                 }
1899             } ## end if (($try) = grep(m#^_<.*$file#...
1900         } ## end if (!defined $main::{ ...
1901
1902         # If not successfully switched now, we failed.
1903         if ( !defined $main::{ '_<' . $file } ) {
1904             print $OUT "No file matching '$file' is loaded.\n";
1905             next CMD;
1906         }
1907
1908         # We switched, so switch the debugger internals around.
1909         elsif ( $file ne $filename ) {
1910             *dbline   = $main::{ '_<' . $file };
1911             $max      = $#dbline;
1912             $filename = $file;
1913             $start    = 1;
1914             $cmd      = "l";
1915         } ## end elsif ($file ne $filename)
1916
1917         # We didn't switch; say we didn't.
1918         else {
1919             print $OUT "Already in $file.\n";
1920             next CMD;
1921         }
1922     }
1923
1924     return;
1925 }
1926
1927 sub _DB__handle_dot_command {
1928     my ($obj) = @_;
1929
1930     # . command.
1931     if ($obj->_is_full('.')) {
1932         $incr = -1;    # stay at current line
1933
1934         # Reset everything to the old location.
1935         $start    = $line;
1936         $filename = $filename_ini;
1937         *dbline   = $main::{ '_<' . $filename };
1938         $max      = $#dbline;
1939
1940         # Now where are we?
1941         print_lineinfo($obj->position());
1942         next CMD;
1943     }
1944
1945     return;
1946 }
1947
1948 sub _DB__handle_y_command {
1949     my ($obj) = @_;
1950
1951     if (my ($match_level, $match_vars)
1952         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1953
1954         # See if we've got the necessary support.
1955         if (!eval {
1956             local @INC = @INC;
1957             pop @INC if $INC[-1] eq '.';
1958             require PadWalker; PadWalker->VERSION(0.08) }) {
1959             my $Err = $@;
1960             _db_warn(
1961                 $Err =~ /locate/
1962                 ? "PadWalker module not found - please install\n"
1963                 : $Err
1964             );
1965             next CMD;
1966         }
1967
1968         # Load up dumpvar if we don't have it. If we can, that is.
1969         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1970         defined &main::dumpvar
1971             or print $OUT "dumpvar.pl not available.\n"
1972             and next CMD;
1973
1974         # Got all the modules we need. Find them and print them.
1975         my @vars = split( ' ', $match_vars || '' );
1976
1977         # Find the pad.
1978         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1979
1980         # Oops. Can't find it.
1981         if (my $Err = $@) {
1982             $Err =~ s/ at .*//;
1983             _db_warn($Err);
1984             next CMD;
1985         }
1986
1987         # Show the desired vars with dumplex().
1988         my $savout = select($OUT);
1989
1990         # Have dumplex dump the lexicals.
1991         foreach my $key (sort keys %$h) {
1992             dumpvar::dumplex( $key, $h->{$key},
1993                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1994                 @vars );
1995         }
1996         select($savout);
1997         next CMD;
1998     }
1999 }
2000
2001 sub _DB__handle_c_command {
2002     my ($obj) = @_;
2003
2004     my $i = $obj->cmd_args;
2005
2006     if ($i =~ m#\A[\w:]*\z#) {
2007
2008         # Hey, show's over. The debugged program finished
2009         # executing already.
2010         next CMD if _DB__is_finished();
2011
2012         # Capture the place to put a one-time break.
2013         $subname = $i;
2014
2015         #  Probably not needed, since we finish an interactive
2016         #  sub-session anyway...
2017         # local $filename = $filename;
2018         # local *dbline = *dbline; # XXX Would this work?!
2019         #
2020         # The above question wonders if localizing the alias
2021         # to the magic array works or not. Since it's commented
2022         # out, we'll just leave that to speculation for now.
2023
2024         # If the "subname" isn't all digits, we'll assume it
2025         # is a subroutine name, and try to find it.
2026         if ( $subname =~ /\D/ ) {    # subroutine name
2027             # Qualify it to the current package unless it's
2028             # already qualified.
2029             $subname = $package . "::" . $subname
2030             unless $subname =~ /::/;
2031
2032             # find_sub will return "file:line_number" corresponding
2033             # to where the subroutine is defined; we call find_sub,
2034             # break up the return value, and assign it in one
2035             # operation.
2036             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2037
2038             # Force the line number to be numeric.
2039             $i = $i + 0;
2040
2041             # If we got a line number, we found the sub.
2042             if ($i) {
2043
2044                 # Switch all the debugger's internals around so
2045                 # we're actually working with that file.
2046                 $filename = $file;
2047                 *dbline   = $main::{ '_<' . $filename };
2048
2049                 # Mark that there's a breakpoint in this file.
2050                 $had_breakpoints{$filename} |= 1;
2051
2052                 # Scan forward to the first executable line
2053                 # after the 'sub whatever' line.
2054                 $max = $#dbline;
2055                 my $_line_num = $i;
2056                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2057                 {
2058                     $_line_num++;
2059                 }
2060                 $i = $_line_num;
2061             } ## end if ($i)
2062
2063             # We didn't find a sub by that name.
2064             else {
2065                 print $OUT "Subroutine $subname not found.\n";
2066                 next CMD;
2067             }
2068         } ## end if ($subname =~ /\D/)
2069
2070         # At this point, either the subname was all digits (an
2071         # absolute line-break request) or we've scanned through
2072         # the code following the definition of the sub, looking
2073         # for an executable, which we may or may not have found.
2074         #
2075         # If $i (which we set $subname from) is non-zero, we
2076         # got a request to break at some line somewhere. On
2077         # one hand, if there wasn't any real subroutine name
2078         # involved, this will be a request to break in the current
2079         # file at the specified line, so we have to check to make
2080         # sure that the line specified really is breakable.
2081         #
2082         # On the other hand, if there was a subname supplied, the
2083         # preceding block has moved us to the proper file and
2084         # location within that file, and then scanned forward
2085         # looking for the next executable line. We have to make
2086         # sure that one was found.
2087         #
2088         # On the gripping hand, we can't do anything unless the
2089         # current value of $i points to a valid breakable line.
2090         # Check that.
2091         if ($i) {
2092
2093             # Breakable?
2094             if ( $dbline[$i] == 0 ) {
2095                 print $OUT "Line $i not breakable.\n";
2096                 next CMD;
2097             }
2098
2099             # Yes. Set up the one-time-break sigil.
2100             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2101             _enable_breakpoint_temp_enabled_status($filename, $i);
2102         } ## end if ($i)
2103
2104         # Turn off stack tracing from here up.
2105         for my $j (0 .. $stack_depth) {
2106             $stack[ $j ] &= ~1;
2107         }
2108         last CMD;
2109     }
2110
2111     return;
2112 }
2113
2114 sub _DB__handle_forward_slash_command {
2115     my ($obj) = @_;
2116
2117     # The pattern as a string.
2118     use vars qw($inpat);
2119
2120     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2121
2122         # Remove the final slash.
2123         $inpat =~ s:([^\\])/$:$1:;
2124
2125         # If the pattern isn't null ...
2126         if ( $inpat ne "" ) {
2127
2128             # Turn off warn and die processing for a bit.
2129             local $SIG{__DIE__};
2130             local $SIG{__WARN__};
2131
2132             # Create the pattern.
2133             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2134             if ( $@ ne "" ) {
2135
2136                 # Oops. Bad pattern. No biscuit.
2137                 # Print the eval error and go back for more
2138                 # commands.
2139                 print {$OUT} "$@";
2140                 next CMD;
2141             }
2142             $obj->pat($inpat);
2143         } ## end if ($inpat ne "")
2144
2145         # Set up to stop on wrap-around.
2146         $end = $start;
2147
2148         # Don't move off the current line.
2149         $incr = -1;
2150
2151         my $pat = $obj->pat;
2152
2153         # Done in eval so nothing breaks if the pattern
2154         # does something weird.
2155         eval
2156         {
2157             no strict q/vars/;
2158             for (;;) {
2159                 # Move ahead one line.
2160                 ++$start;
2161
2162                 # Wrap if we pass the last line.
2163                 if ($start > $max) {
2164                     $start = 1;
2165                 }
2166
2167                 # Stop if we have gotten back to this line again,
2168                 last if ($start == $end);
2169
2170                 # A hit! (Note, though, that we are doing
2171                 # case-insensitive matching. Maybe a qr//
2172                 # expression would be better, so the user could
2173                 # do case-sensitive matching if desired.
2174                 if ($dbline[$start] =~ m/$pat/i) {
2175                     if ($slave_editor) {
2176                         # Handle proper escaping in the slave.
2177                         print {$OUT} "\032\032$filename:$start:0\n";
2178                     }
2179                     else {
2180                         # Just print the line normally.
2181                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2182                     }
2183                     # And quit since we found something.
2184                     last;
2185                 }
2186             }
2187         };
2188
2189         if ($@) {
2190             warn $@;
2191         }
2192
2193         # If we wrapped, there never was a match.
2194         if ( $start == $end ) {
2195             print {$OUT} "/$pat/: not found\n";
2196         }
2197         next CMD;
2198     }
2199
2200     return;
2201 }
2202
2203 sub _DB__handle_question_mark_command {
2204     my ($obj) = @_;
2205
2206     # ? - backward pattern search.
2207     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2208
2209         # Get the pattern, remove trailing question mark.
2210         $inpat =~ s:([^\\])\?$:$1:;
2211
2212         # If we've got one ...
2213         if ( $inpat ne "" ) {
2214
2215             # Turn off die & warn handlers.
2216             local $SIG{__DIE__};
2217             local $SIG{__WARN__};
2218             eval '$inpat =~ m' . "\a$inpat\a";
2219
2220             if ( $@ ne "" ) {
2221
2222                 # Ouch. Not good. Print the error.
2223                 print $OUT $@;
2224                 next CMD;
2225             }
2226             $obj->pat($inpat);
2227         } ## end if ($inpat ne "")
2228
2229         # Where we are now is where to stop after wraparound.
2230         $end = $start;
2231
2232         # Don't move away from this line.
2233         $incr = -1;
2234
2235         my $pat = $obj->pat;
2236         # Search inside the eval to prevent pattern badness
2237         # from killing us.
2238         eval {
2239             no strict q/vars/;
2240             for (;;) {
2241                 # Back up a line.
2242                 --$start;
2243
2244                 # Wrap if we pass the first line.
2245
2246                 $start = $max if ($start <= 0);
2247
2248                 # Quit if we get back where we started,
2249                 last if ($start == $end);
2250
2251                 # Match?
2252                 if ($dbline[$start] =~ m/$pat/i) {
2253                     if ($slave_editor) {
2254                         # Yep, follow slave editor requirements.
2255                         print $OUT "\032\032$filename:$start:0\n";
2256                     }
2257                     else {
2258                         # Yep, just print normally.
2259                         print $OUT "$start:\t",$dbline[$start],"\n";
2260                     }
2261
2262                     # Found, so done.
2263                     last;
2264                 }
2265             }
2266         };
2267
2268         # Say we failed if the loop never found anything,
2269         if ( $start == $end ) {
2270             print {$OUT} "?$pat?: not found\n";
2271         }
2272         next CMD;
2273     }
2274
2275     return;
2276 }
2277
2278 sub _DB__handle_restart_and_rerun_commands {
2279     my ($obj) = @_;
2280
2281     my $cmd_cmd = $obj->cmd_verb;
2282     my $cmd_params = $obj->cmd_args;
2283     # R - restart execution.
2284     # rerun - controlled restart execution.
2285     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2286
2287         # Change directory to the initial current working directory on
2288         # the script startup, so if the debugged program changed the
2289         # directory, then we will still be able to find the path to the
2290         # the program. (perl 5 RT #121509 ).
2291         chdir ($_initial_cwd);
2292
2293         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2294
2295         # Close all non-system fds for a clean restart.  A more
2296         # correct method would be to close all fds that were not
2297         # open when the process started, but this seems to be
2298         # hard.  See "debugger 'R'estart and open database
2299         # connections" on p5p.
2300
2301         my $max_fd = 1024; # default if POSIX can't be loaded
2302         if (eval { require POSIX }) {
2303             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2304         }
2305
2306         if (defined $max_fd) {
2307             foreach ($^F+1 .. $max_fd-1) {
2308                 next unless open FD_TO_CLOSE, "<&=$_";
2309                 close(FD_TO_CLOSE);
2310             }
2311         }
2312
2313         # And run Perl again.  We use exec() to keep the
2314         # PID stable (and that way $ini_pids is still valid).
2315         exec(@args) or print {$OUT} "exec failed: $!\n";
2316
2317         last CMD;
2318     }
2319
2320     return;
2321 }
2322
2323 sub _DB__handle_run_command_in_pager_command {
2324     my ($obj) = @_;
2325
2326     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2327         if ( $pager =~ /^\|/ ) {
2328
2329             # Default pager is into a pipe. Redirect I/O.
2330             open( SAVEOUT, ">&STDOUT" )
2331             || _db_warn("Can't save STDOUT");
2332             open( STDOUT, ">&OUT" )
2333             || _db_warn("Can't redirect STDOUT");
2334         } ## end if ($pager =~ /^\|/)
2335         else {
2336
2337             # Not into a pipe. STDOUT is safe.
2338             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2339         }
2340
2341         # Fix up environment to record we have less if so.
2342         fix_less();
2343
2344         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2345
2346             # Couldn't open pipe to pager.
2347             _db_warn("Can't pipe output to '$pager'");
2348             if ( $pager =~ /^\|/ ) {
2349
2350                 # Redirect I/O back again.
2351                 open( OUT, ">&STDOUT" )    # XXX: lost message
2352                 || _db_warn("Can't restore DB::OUT");
2353                 open( STDOUT, ">&SAVEOUT" )
2354                 || _db_warn("Can't restore STDOUT");
2355                 close(SAVEOUT);
2356             } ## end if ($pager =~ /^\|/)
2357             else {
2358
2359                 # Redirect I/O. STDOUT already safe.
2360                 open( OUT, ">&STDOUT" )    # XXX: lost message
2361                 || _db_warn("Can't restore DB::OUT");
2362             }
2363             next CMD;
2364         } ## end unless ($piped = open(OUT,...
2365
2366         # Set up broken-pipe handler if necessary.
2367         $SIG{PIPE} = \&DB::catch
2368         if $pager =~ /^\|/
2369         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2370
2371         _autoflush(\*OUT);
2372         # Save current filehandle, and put it back.
2373         $obj->selected(scalar( select(OUT) ));
2374         # Don't put it back if pager was a pipe.
2375         if ($cmd !~ /\A\|\|/)
2376         {
2377             select($obj->selected());
2378             $obj->selected("");
2379         }
2380
2381         # Trim off the pipe symbols and run the command now.
2382         $cmd =~ s#\A\|+\s*##;
2383         redo PIPE;
2384     }
2385
2386     return;
2387 }
2388
2389 sub _DB__handle_m_command {
2390     my ($obj) = @_;
2391
2392     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2393         methods($1);
2394         next CMD;
2395     }
2396
2397     # m expr - set up DB::eval to do the work
2398     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2399         $onetimeDump = 'methods';   #  method output gets used there
2400     }
2401
2402     return;
2403 }
2404
2405 sub _DB__at_end_of_every_command {
2406     my ($obj) = @_;
2407
2408     # At the end of every command:
2409     if ($obj->piped) {
2410
2411         # Unhook the pipe mechanism now.
2412         if ( $pager =~ /^\|/ ) {
2413
2414             # No error from the child.
2415             $? = 0;
2416
2417             # we cannot warn here: the handle is missing --tchrist
2418             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2419
2420             # most of the $? crud was coping with broken cshisms
2421             # $? is explicitly set to 0, so this never runs.
2422             if ($?) {
2423                 print SAVEOUT "Pager '$pager' failed: ";
2424                 if ( $? == -1 ) {
2425                     print SAVEOUT "shell returned -1\n";
2426                 }
2427                 elsif ( $? >> 8 ) {
2428                     print SAVEOUT ( $? & 127 )
2429                     ? " (SIG#" . ( $? & 127 ) . ")"
2430                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2431                 }
2432                 else {
2433                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2434                 }
2435             } ## end if ($?)
2436
2437             # Reopen filehandle for our output (if we can) and
2438             # restore STDOUT (if we can).
2439             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2440             open( STDOUT, ">&SAVEOUT" )
2441             || _db_warn("Can't restore STDOUT");
2442
2443             # Turn off pipe exception handler if necessary.
2444             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2445
2446             # Will stop ignoring SIGPIPE if done like nohup(1)
2447             # does SIGINT but Perl doesn't give us a choice.
2448         } ## end if ($pager =~ /^\|/)
2449         else {
2450
2451             # Non-piped "pager". Just restore STDOUT.
2452             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2453         }
2454
2455         # Let Readline know about the new filehandles.
2456         reset_IN_OUT( \*IN, \*OUT );
2457
2458         # Close filehandle pager was using, restore the normal one
2459         # if necessary,
2460         close(SAVEOUT);
2461
2462         if ($obj->selected() ne "") {
2463             select($obj->selected);
2464             $obj->selected("");
2465         }
2466
2467         # No pipes now.
2468         $obj->piped("");
2469     } ## end if ($piped)
2470
2471     return;
2472 }
2473
2474 sub _DB__handle_watch_expressions
2475 {
2476     my $self = shift;
2477
2478     if ( $DB::trace & 2 ) {
2479         for my $n (0 .. $#DB::to_watch) {
2480             $DB::evalarg = $DB::to_watch[$n];
2481             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2482
2483             # Fix context DB::eval() wants to return an array, but
2484             # we need a scalar here.
2485             my ($val) = join( "', '", DB::eval(@_) );
2486             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2487
2488             # Did it change?
2489             if ( $val ne $DB::old_watch[$n] ) {
2490
2491                 # Yep! Show the difference, and fake an interrupt.
2492                 $DB::signal = 1;
2493                 print {$DB::OUT} <<EOP;
2494 Watchpoint $n:\t$DB::to_watch[$n] changed:
2495     old value:\t$DB::old_watch[$n]
2496     new value:\t$val
2497 EOP
2498                 $DB::old_watch[$n] = $val;
2499             } ## end if ($val ne $old_watch...
2500         } ## end for my $n (0 ..
2501     } ## end if ($trace & 2)
2502
2503     return;
2504 }
2505
2506 # 't' is type.
2507 # 'm' is method.
2508 # 'v' is the value (i.e: method name or subroutine ref).
2509 # 's' is subroutine.
2510 my %cmd_lookup;
2511
2512 BEGIN
2513 {
2514     %cmd_lookup =
2515 (
2516     '-' => { t => 'm', v => '_handle_dash_command', },
2517     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2518     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2519     'H' => { t => 'm', v => '_handle_H_command', },
2520     'S' => { t => 'm', v => '_handle_S_command', },
2521     'T' => { t => 'm', v => '_handle_T_command', },
2522     'W' => { t => 'm', v => '_handle_W_command', },
2523     'c' => { t => 's', v => \&_DB__handle_c_command, },
2524     'f' => { t => 's', v => \&_DB__handle_f_command, },
2525     'm' => { t => 's', v => \&_DB__handle_m_command, },
2526     'n' => { t => 'm', v => '_handle_n_command', },
2527     'p' => { t => 'm', v => '_handle_p_command', },
2528     'q' => { t => 'm', v => '_handle_q_command', },
2529     'r' => { t => 'm', v => '_handle_r_command', },
2530     's' => { t => 'm', v => '_handle_s_command', },
2531     'save' => { t => 'm', v => '_handle_save_command', },
2532     'source' => { t => 'm', v => '_handle_source_command', },
2533     't' => { t => 'm', v => '_handle_t_command', },
2534     'w' => { t => 'm', v => '_handle_w_command', },
2535     'x' => { t => 'm', v => '_handle_x_command', },
2536     'y' => { t => 's', v => \&_DB__handle_y_command, },
2537     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2538         ('X', 'V')),
2539     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2540         qw(enable disable)),
2541     (map { $_ =>
2542         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2543         } qw(R rerun)),
2544     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2545         qw(a A b B e E h i l L M o O v w W)),
2546 );
2547 };
2548
2549 sub DB {
2550
2551     # lock the debugger and get the thread id for the prompt
2552     lock($DBGR);
2553     my $tid;
2554     my $position;
2555     my ($prefix, $after, $infix);
2556     my $pat;
2557     my $explicit_stop;
2558     my $piped;
2559     my $selected;
2560
2561     if ($ENV{PERL5DB_THREADED}) {
2562         $tid = eval { "[".threads->tid."]" };
2563     }
2564
2565     my $cmd_verb;
2566     my $cmd_args;
2567
2568     my $obj = DB::Obj->new(
2569         {
2570             position => \$position,
2571             prefix => \$prefix,
2572             after => \$after,
2573             explicit_stop => \$explicit_stop,
2574             infix => \$infix,
2575             cmd_args => \$cmd_args,
2576             cmd_verb => \$cmd_verb,
2577             pat => \$pat,
2578             piped => \$piped,
2579             selected => \$selected,
2580         },
2581     );
2582
2583     $obj->_DB_on_init__initialize_globals(@_);
2584
2585     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2586     # The code being debugged may have altered them.
2587     DB::save();
2588
2589     # Since DB::DB gets called after every line, we can use caller() to
2590     # figure out where we last were executing. Sneaky, eh? This works because
2591     # caller is returning all the extra information when called from the
2592     # debugger.
2593     local ( $package, $filename, $line ) = caller;
2594     $filename_ini = $filename;
2595
2596     # set up the context for DB::eval, so it can properly execute
2597     # code on behalf of the user. We add the package in so that the
2598     # code is eval'ed in the proper package (not in the debugger!).
2599     local $usercontext = _calc_usercontext($package);
2600
2601     # Create an alias to the active file magical array to simplify
2602     # the code here.
2603     local (*dbline) = $main::{ '_<' . $filename };
2604
2605     # Last line in the program.
2606     $max = $#dbline;
2607
2608     # The &-call is here to ascertain the mutability of @_.
2609     &_DB__determine_if_we_should_break;
2610
2611     # Preserve the current stop-or-not, and see if any of the W
2612     # (watch expressions) has changed.
2613     my $was_signal = $signal;
2614
2615     # If we have any watch expressions ...
2616     _DB__handle_watch_expressions($obj);
2617
2618 =head2 C<watchfunction()>
2619
2620 C<watchfunction()> is a function that can be defined by the user; it is a
2621 function which will be run on each entry to C<DB::DB>; it gets the
2622 current package, filename, and line as its parameters.
2623
2624 The watchfunction can do anything it likes; it is executing in the
2625 debugger's context, so it has access to all of the debugger's internal
2626 data structures and functions.
2627
2628 C<watchfunction()> can control the debugger's actions. Any of the following
2629 will cause the debugger to return control to the user's program after
2630 C<watchfunction()> executes:
2631
2632 =over 4
2633
2634 =item *
2635
2636 Returning a false value from the C<watchfunction()> itself.
2637
2638 =item *
2639
2640 Altering C<$single> to a false value.
2641
2642 =item *
2643
2644 Altering C<$signal> to a false value.
2645
2646 =item *
2647
2648 Turning off the C<4> bit in C<$trace> (this also disables the
2649 check for C<watchfunction()>. This can be done with
2650
2651     $trace &= ~4;
2652
2653 =back
2654
2655 =cut
2656
2657     # If there's a user-defined DB::watchfunction, call it with the
2658     # current package, filename, and line. The function executes in
2659     # the DB:: package.
2660     if ( $trace & 4 ) {    # User-installed watch
2661         return
2662           if watchfunction( $package, $filename, $line )
2663           and not $single
2664           and not $was_signal
2665           and not( $trace & ~4 );
2666     } ## end if ($trace & 4)
2667
2668     # Pick up any alteration to $signal in the watchfunction, and
2669     # turn off the signal now.
2670     $was_signal = $signal;
2671     $signal     = 0;
2672
2673 =head2 GETTING READY TO EXECUTE COMMANDS
2674
2675 The debugger decides to take control if single-step mode is on, the
2676 C<t> command was entered, or the user generated a signal. If the program
2677 has fallen off the end, we set things up so that entering further commands
2678 won't cause trouble, and we say that the program is over.
2679
2680 =cut
2681
2682     # Make sure that we always print if asked for explicitly regardless
2683     # of $trace_to_depth .
2684     $explicit_stop = ($single || $was_signal);
2685
2686     # Check to see if we should grab control ($single true,
2687     # trace set appropriately, or we got a signal).
2688     if ( $explicit_stop || ( $trace & 1 ) ) {
2689         $obj->_DB__grab_control(@_);
2690     } ## end if ($single || ($trace...
2691
2692 =pod
2693
2694 If there's an action to be executed for the line we stopped at, execute it.
2695 If there are any preprompt actions, execute those as well.
2696
2697 =cut
2698
2699     # If there's an action, do it now.
2700     if ($action) {
2701         $evalarg = $action;
2702         # The &-call is here to ascertain the mutability of @_.
2703         &DB::eval;
2704     }
2705
2706     # Are we nested another level (e.g., did we evaluate a function
2707     # that had a breakpoint in it at the debugger prompt)?
2708     if ( $single || $was_signal ) {
2709
2710         # Yes, go down a level.
2711         local $level = $level + 1;
2712
2713         # Do any pre-prompt actions.
2714         foreach $evalarg (@$pre) {
2715             # The &-call is here to ascertain the mutability of @_.
2716             &DB::eval;
2717         }
2718
2719         # Complain about too much recursion if we passed the limit.
2720         if ($single & 4) {
2721             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2722         }
2723
2724         # The line we're currently on. Set $incr to -1 to stay here
2725         # until we get a command that tells us to advance.
2726         $start = $line;
2727         $incr  = -1;      # for backward motion.
2728
2729         # Tack preprompt debugger actions ahead of any actual input.
2730         @typeahead = ( @$pretype, @typeahead );
2731
2732 =head2 WHERE ARE WE?
2733
2734 XXX Relocate this section?
2735
2736 The debugger normally shows the line corresponding to the current line of
2737 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2738 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2739
2740 C<$incr> controls by how many lines the I<current> line should move forward
2741 after a command is executed. If set to -1, this indicates that the I<current>
2742 line shouldn't change.
2743
2744 C<$start> is the I<current> line. It is used for things like knowing where to
2745 move forwards or backwards from when doing an C<L> or C<-> command.
2746
2747 C<$max> tells the debugger where the last line of the current file is. It's
2748 used to terminate loops most often.
2749
2750 =head2 THE COMMAND LOOP
2751
2752 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2753 in two parts:
2754
2755 =over 4
2756
2757 =item *
2758
2759 The outer part of the loop, starting at the C<CMD> label. This loop
2760 reads a command and then executes it.
2761
2762 =item *
2763
2764 The inner part of the loop, starting at the C<PIPE> label. This part
2765 is wholly contained inside the C<CMD> block and only executes a command.
2766 Used to handle commands running inside a pager.
2767
2768 =back
2769
2770 So why have two labels to restart the loop? Because sometimes, it's easier to
2771 have a command I<generate> another command and then re-execute the loop to do
2772 the new command. This is faster, but perhaps a bit more convoluted.
2773
2774 =cut
2775
2776         # The big command dispatch loop. It keeps running until the
2777         # user yields up control again.
2778         #
2779         # If we have a terminal for input, and we get something back
2780         # from readline(), keep on processing.
2781
2782       CMD:
2783         while (_DB__read_next_cmd($tid))
2784         {
2785
2786             share($cmd);
2787             # ... try to execute the input as debugger commands.
2788
2789             # Don't stop running.
2790             $single = 0;
2791
2792             # No signal is active.
2793             $signal = 0;
2794
2795             # Handle continued commands (ending with \):
2796             if ($cmd =~ s/\\\z/\n/) {
2797                 $cmd .= DB::readline("  cont: ");
2798                 redo CMD;
2799             }
2800
2801 =head4 The null command
2802
2803 A newline entered by itself means I<re-execute the last command>. We grab the
2804 command out of C<$laststep> (where it was recorded previously), and copy it
2805 back into C<$cmd> to be executed below. If there wasn't any previous command,
2806 we'll do nothing below (no command will match). If there was, we also save it
2807 in the command history and fall through to allow the command parsing to pick
2808 it up.
2809
2810 =cut
2811
2812             # Empty input means repeat the last command.
2813             if ($cmd eq '') {
2814                 $cmd = $laststep;
2815             }
2816             chomp($cmd);    # get rid of the annoying extra newline
2817             if (length($cmd) >= 2) {
2818                 push( @hist, $cmd );
2819             }
2820             push( @truehist, $cmd );
2821             share(@hist);
2822             share(@truehist);
2823
2824             # This is a restart point for commands that didn't arrive
2825             # via direct user input. It allows us to 'redo PIPE' to
2826             # re-execute command processing without reading a new command.
2827           PIPE: {
2828                 _DB__trim_command_and_return_first_component($obj);
2829
2830 =head3 COMMAND ALIASES
2831
2832 The debugger can create aliases for commands (these are stored in the
2833 C<%alias> hash). Before a command is executed, the command loop looks it up
2834 in the alias hash and substitutes the contents of the alias for the command,
2835 completely replacing it.
2836
2837 =cut
2838
2839                 # See if there's an alias for the command, and set it up if so.
2840                 if ( $alias{$cmd_verb} ) {
2841
2842                     # Squelch signal handling; we want to keep control here
2843                     # if something goes loco during the alias eval.
2844                     local $SIG{__DIE__};
2845                     local $SIG{__WARN__};
2846
2847                     # This is a command, so we eval it in the DEBUGGER's
2848                     # scope! Otherwise, we can't see the special debugger
2849                     # variables, or get to the debugger's subs. (Well, we
2850                     # _could_, but why make it even more complicated?)
2851                     eval "\$cmd =~ $alias{$cmd_verb}";
2852                     if ($@) {
2853                         local $\ = '';
2854                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2855                         next CMD;
2856                     }
2857                     _DB__trim_command_and_return_first_component($obj);
2858                 } ## end if ($alias{$cmd_verb})
2859
2860 =head3 MAIN-LINE COMMANDS
2861
2862 All of these commands work up to and after the program being debugged has
2863 terminated.
2864
2865 =head4 C<q> - quit
2866
2867 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2868 try to execute further, cleaning any restart-related stuff out of the
2869 environment, and executing with the last value of C<$?>.
2870
2871 =cut
2872
2873                 # All of these commands were remapped in perl 5.8.0;
2874                 # we send them off to the secondary dispatcher (see below).
2875                 $obj->_handle_special_char_cmd_wrapper_commands;
2876                 _DB__trim_command_and_return_first_component($obj);
2877
2878                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2879                     my $type = $cmd_rec->{t};
2880                     my $val = $cmd_rec->{v};
2881                     if ($type eq 'm') {
2882                         $obj->$val();
2883                     }
2884                     elsif ($type eq 's') {
2885                         $val->($obj);
2886                     }
2887                 }
2888
2889 =head4 C<t> - trace [n]
2890
2891 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2892 If level is specified, set C<$trace_to_depth>.
2893
2894 =head4 C<S> - list subroutines matching/not matching a pattern
2895
2896 Walks through C<%sub>, checking to see whether or not to print the name.
2897
2898 =head4 C<X> - list variables in current package
2899
2900 Since the C<V> command actually processes this, just change this to the
2901 appropriate C<V> command and fall through.
2902
2903 =head4 C<V> - list variables
2904
2905 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2906
2907 =head4 C<x> - evaluate and print an expression
2908
2909 Hands the expression off to C<DB::eval>, setting it up to print the value
2910 via C<dumpvar.pl> instead of just printing it directly.
2911
2912 =head4 C<m> - print methods
2913
2914 Just uses C<DB::methods> to determine what methods are available.
2915
2916 =head4 C<f> - switch files
2917
2918 Switch to a different filename.
2919
2920 =head4 C<.> - return to last-executed line.
2921
2922 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2923 and then we look up the line in the magical C<%dbline> hash.
2924
2925 =head4 C<-> - back one window
2926
2927 We change C<$start> to be one window back; if we go back past the first line,
2928 we set it to be the first line. We ser C<$incr> to put us back at the
2929 currently-executing line, and then put a C<l $start +> (list one window from
2930 C<$start>) in C<$cmd> to be executed later.
2931
2932 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2933
2934 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2935 problems, most notably that the default case of several commands destroying
2936 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2937 retain the old commands for those who were used to using them or who preferred
2938 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2939 deal with them instead of processing them in-line.
2940
2941 =head4 C<y> - List lexicals in higher scope
2942
2943 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2944 above the current one and then displays then using C<dumpvar.pl>.
2945
2946 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2947
2948 All of the commands below this point don't work after the program being
2949 debugged has ended. All of them check to see if the program has ended; this
2950 allows the commands to be relocated without worrying about a 'line of
2951 demarcation' above which commands can be entered anytime, and below which
2952 they can't.
2953
2954 =head4 C<n> - single step, but don't trace down into subs
2955
2956 Done by setting C<$single> to 2, which forces subs to execute straight through
2957 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2958 so a null command knows what to re-execute.
2959
2960 =head4 C<s> - single-step, entering subs
2961
2962 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2963 subs. Also saves C<s> as C<$lastcmd>.
2964
2965 =head4 C<c> - run continuously, setting an optional breakpoint
2966
2967 Most of the code for this command is taken up with locating the optional
2968 breakpoint, which is either a subroutine name or a line number. We set
2969 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2970 in this and all call levels above this one.
2971
2972 =head4 C<r> - return from a subroutine
2973
2974 For C<r> to work properly, the debugger has to stop execution again
2975 immediately after the return is executed. This is done by forcing
2976 single-stepping to be on in the call level above the current one. If
2977 we are printing return values when a C<r> is executed, set C<$doret>
2978 appropriately, and force us out of the command loop.
2979
2980 =head4 C<T> - stack trace
2981
2982 Just calls C<DB::print_trace>.
2983
2984 =head4 C<w> - List window around current line.
2985
2986 Just calls C<DB::cmd_w>.
2987
2988 =head4 C<W> - watch-expression processing.
2989
2990 Just calls C<DB::cmd_W>.
2991
2992 =head4 C</> - search forward for a string in the source
2993
2994 We take the argument and treat it as a pattern. If it turns out to be a
2995 bad one, we return the error we got from trying to C<eval> it and exit.
2996 If not, we create some code to do the search and C<eval> it so it can't
2997 mess us up.
2998
2999 =cut
3000
3001                 _DB__handle_forward_slash_command($obj);
3002
3003 =head4 C<?> - search backward for a string in the source
3004
3005 Same as for C</>, except the loop runs backwards.
3006
3007 =cut
3008
3009                 _DB__handle_question_mark_command($obj);
3010
3011 =head4 C<$rc> - Recall command
3012
3013 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3014 that the terminal supports history). It finds the command required, puts it
3015 into C<$cmd>, and redoes the loop to execute it.
3016
3017 =cut
3018
3019                 # $rc - recall command.
3020                 $obj->_handle_rc_recall_command;
3021
3022 =head4 C<$sh$sh> - C<system()> command
3023
3024 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3025 C<STDOUT> from getting messed up.
3026
3027 =cut
3028
3029                 $obj->_handle_sh_command;
3030
3031 =head4 C<$rc I<pattern> $rc> - Search command history
3032
3033 Another command to manipulate C<@hist>: this one searches it with a pattern.
3034 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3035
3036 =cut
3037
3038                 $obj->_handle_rc_search_history_command;
3039
3040 =head4 C<$sh> - Invoke a shell
3041
3042 Uses C<_db_system()> to invoke a shell.
3043
3044 =cut
3045
3046 =head4 C<$sh I<command>> - Force execution of a command in a shell
3047
3048 Like the above, but the command is passed to the shell. Again, we use
3049 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3050
3051 =head4 C<H> - display commands in history
3052
3053 Prints the contents of C<@hist> (if any).
3054
3055 =head4 C<man, doc, perldoc> - look up documentation
3056
3057 Just calls C<runman()> to print the appropriate document.
3058
3059 =cut
3060
3061                 $obj->_handle_doc_command;
3062
3063 =head4 C<p> - print
3064
3065 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3066 the bottom of the loop.
3067
3068 =head4 C<=> - define command alias
3069
3070 Manipulates C<%alias> to add or list command aliases.
3071
3072 =head4 C<source> - read commands from a file.
3073
3074 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3075 pick it up.
3076
3077 =head4 C<enable> C<disable> - enable or disable breakpoints
3078
3079 This enables or disables breakpoints.
3080
3081 =head4 C<save> - send current history to a file
3082
3083 Takes the complete history, (not the shrunken version you see with C<H>),
3084 and saves it to the given filename, so it can be replayed using C<source>.
3085
3086 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3087
3088 =head4 C<R> - restart
3089
3090 Restart the debugger session.
3091
3092 =head4 C<rerun> - rerun the current session
3093
3094 Return to any given position in the B<true>-history list
3095
3096 =head4 C<|, ||> - pipe output through the pager.
3097
3098 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3099 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3100 pipe to the pager (restoring the output filehandles if this fails). If this
3101 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3102 set C<$signal>, sending us back into the debugger.
3103
3104 We then trim off the pipe symbols and C<redo> the command loop at the
3105 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3106 reading another.
3107
3108 =cut
3109
3110                 # || - run command in the pager, with output to DB::OUT.
3111                 _DB__handle_run_command_in_pager_command($obj);
3112
3113 =head3 END OF COMMAND PARSING
3114
3115 Anything left in C<$cmd> at this point is a Perl expression that we want to
3116 evaluate. We'll always evaluate in the user's context, and fully qualify
3117 any variables we might want to address in the C<DB> package.
3118
3119 =cut
3120
3121             }    # PIPE:
3122
3123             # trace an expression
3124             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3125
3126             # Make sure the flag that says "the debugger's running" is
3127             # still on, to make sure we get control again.
3128             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3129
3130             # Run *our* eval that executes in the caller's context.
3131             # The &-call is here to ascertain the mutability of @_.
3132             &DB::eval;
3133
3134             # Turn off the one-time-dump stuff now.
3135             if ($onetimeDump) {
3136                 $onetimeDump      = undef;
3137                 $onetimedumpDepth = undef;
3138             }
3139             elsif ( $term_pid == $$ ) {
3140                 eval { # May run under miniperl, when not available...
3141                     STDOUT->flush();
3142                     STDERR->flush();
3143                 };
3144
3145                 # XXX If this is the master pid, print a newline.
3146                 print {$OUT} "\n";
3147             }
3148         } ## end while (($term || &setterm...
3149
3150 =head3 POST-COMMAND PROCESSING
3151
3152 After each command, we check to see if the command output was piped anywhere.
3153 If so, we go through the necessary code to unhook the pipe and go back to
3154 our standard filehandles for input and output.
3155
3156 =cut
3157
3158         continue {    # CMD:
3159             _DB__at_end_of_every_command($obj);
3160         }    # CMD:
3161
3162 =head3 COMMAND LOOP TERMINATION
3163
3164 When commands have finished executing, we come here. If the user closed the
3165 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3166 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3167 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3168 The interpreter will then execute the next line and then return control to us
3169 again.
3170
3171 =cut
3172
3173         # No more commands? Quit.
3174         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3175
3176         # Evaluate post-prompt commands.
3177         foreach $evalarg (@$post) {
3178             # The &-call is here to ascertain the mutability of @_.
3179             &DB::eval;
3180         }
3181     }    # if ($single || $signal)
3182
3183     # Put the user's globals back where you found them.
3184     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3185     ();
3186 } ## end sub DB
3187
3188 # Because DB::Obj is used above,
3189 #
3190 #   my $obj = DB::Obj->new(
3191 #
3192 # The following package declaration must come before that,
3193 # or else runtime errors will occur with
3194 #
3195 #   PERLDB_OPTS="autotrace nonstop"
3196 #
3197 # ( rt#116771 )
3198 BEGIN {
3199
3200 package DB::Obj;
3201
3202 sub new {
3203     my $class = shift;
3204
3205     my $self = bless {}, $class;
3206
3207     $self->_init(@_);
3208
3209     return $self;
3210 }
3211
3212 sub _init {
3213     my ($self, $args) = @_;
3214
3215     %{$self} = (%$self, %$args);
3216
3217     return;
3218 }
3219
3220 {
3221     no strict 'refs';
3222     foreach my $slot_name (qw(
3223         after explicit_stop infix pat piped position prefix selected cmd_verb
3224         cmd_args
3225         )) {
3226         my $slot = $slot_name;
3227         *{$slot} = sub {
3228             my $self = shift;
3229
3230             if (@_) {
3231                 ${ $self->{$slot} } = shift;
3232             }
3233
3234             return ${ $self->{$slot} };
3235         };
3236
3237         *{"append_to_$slot"} = sub {
3238             my $self = shift;
3239             my $s = shift;
3240
3241             return $self->$slot($self->$slot . $s);
3242         };
3243     }
3244 }
3245
3246 sub _DB_on_init__initialize_globals
3247 {
3248     my $self = shift;
3249
3250     # Check for whether we should be running continuously or not.
3251     # _After_ the perl program is compiled, $single is set to 1:
3252     if ( $single and not $second_time++ ) {
3253
3254         # Options say run non-stop. Run until we get an interrupt.
3255         if ($runnonstop) {    # Disable until signal
3256                 # If there's any call stack in place, turn off single
3257                 # stepping into subs throughout the stack.
3258             for my $i (0 .. $stack_depth) {
3259                 $stack[ $i ] &= ~1;
3260             }
3261
3262             # And we are now no longer in single-step mode.
3263             $single = 0;
3264
3265             # If we simply returned at this point, we wouldn't get
3266             # the trace info. Fall on through.
3267             # return;
3268         } ## end if ($runnonstop)
3269
3270         elsif ($ImmediateStop) {
3271
3272             # We are supposed to stop here; XXX probably a break.
3273             $ImmediateStop = 0;    # We've processed it; turn it off
3274             $signal        = 1;    # Simulate an interrupt to force
3275                                    # us into the command loop
3276         }
3277     } ## end if ($single and not $second_time...
3278
3279     # If we're in single-step mode, or an interrupt (real or fake)
3280     # has occurred, turn off non-stop mode.
3281     $runnonstop = 0 if $single or $signal;
3282
3283     return;
3284 }
3285
3286 sub _my_print_lineinfo
3287 {
3288     my ($self, $i, $incr_pos) = @_;
3289
3290     if ($frame) {
3291         # Print it indented if tracing is on.
3292         DB::print_lineinfo( ' ' x $stack_depth,
3293             "$i:\t$DB::dbline[$i]" . $self->after );
3294     }
3295     else {
3296         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3297     }
3298 }
3299
3300 sub _curr_line {
3301     return $DB::dbline[$line];
3302 }
3303
3304 sub _is_full {
3305     my ($self, $letter) = @_;
3306
3307     return ($DB::cmd eq $letter);
3308 }
3309
3310 sub _DB__grab_control
3311 {
3312     my $self = shift;
3313
3314     # Yes, grab control.
3315     if ($slave_editor) {
3316
3317         # Tell the editor to update its position.
3318         $self->position("\032\032${DB::filename}:$line:0\n");
3319         DB::print_lineinfo($self->position());
3320     }
3321
3322 =pod
3323
3324 Special check: if we're in package C<DB::fake>, we've gone through the
3325 C<END> block at least once. We set up everything so that we can continue
3326 to enter commands and have a valid context to be in.
3327
3328 =cut
3329
3330     elsif ( $DB::package eq 'DB::fake' ) {
3331
3332         # Fallen off the end already.
3333         if (!$DB::term) {
3334             DB::setterm();
3335         }
3336
3337         DB::print_help(<<EOP);
3338 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3339 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3340 B<h q>, B<h R> or B<h o> to get additional info.
3341 EOP
3342
3343         # Set the DB::eval context appropriately.
3344         # At program termination disable any user actions.
3345         $DB::action = undef;
3346
3347         $DB::package     = 'main';
3348         $DB::usercontext = DB::_calc_usercontext($DB::package);
3349     } ## end elsif ($package eq 'DB::fake')
3350
3351 =pod
3352
3353 If the program hasn't finished executing, we scan forward to the
3354 next executable line, print that out, build the prompt from the file and line
3355 number information, and print that.
3356
3357 =cut
3358
3359     else {
3360
3361
3362         # Still somewhere in the midst of execution. Set up the
3363         #  debugger prompt.
3364         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3365                              # Perl 5 ones (sorry, we don't print Klingon
3366                              #module names)
3367
3368         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3369         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3370         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3371
3372         # Break up the prompt if it's really long.
3373         if ( length($self->prefix()) > 30 ) {
3374             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3375             $self->prefix("");
3376             $self->infix(":\t");
3377         }
3378         else {
3379             $self->infix("):\t");
3380             $self->position(
3381                 $self->prefix . $line. $self->infix
3382                 . $self->_curr_line . $self->after
3383             );
3384         }
3385
3386         # Print current line info, indenting if necessary.
3387         $self->_my_print_lineinfo($line, $self->position);
3388
3389         my $i;
3390         my $line_i = sub { return $DB::dbline[$i]; };
3391
3392         # Scan forward, stopping at either the end or the next
3393         # unbreakable line.
3394         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3395         {    #{ vi
3396
3397             # Drop out on null statements, block closers, and comments.
3398             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3399
3400             # Drop out if the user interrupted us.
3401             last if $signal;
3402
3403             # Append a newline if the line doesn't have one. Can happen
3404             # in eval'ed text, for instance.
3405             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3406
3407             # Next executable line.
3408             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3409                 . $self->after;
3410             $self->append_to_position($incr_pos);
3411             $self->_my_print_lineinfo($i, $incr_pos);
3412         } ## end for ($i = $line + 1 ; $i...
3413     } ## end else [ if ($slave_editor)
3414
3415     return;
3416 }
3417
3418 sub _handle_t_command {
3419     my $self = shift;
3420
3421     my $levels = $self->cmd_args();
3422
3423     if ((!length($levels)) or ($levels !~ /\D/)) {
3424         $trace ^= 1;
3425         local $\ = '';
3426         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3427         print {$OUT} "Trace = "
3428         . ( ( $trace & 1 )
3429             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3430             : "off" ) . "\n";
3431         next CMD;
3432     }
3433
3434     return;
3435 }
3436
3437
3438 sub _handle_S_command {
3439     my $self = shift;
3440
3441     if (my ($print_all_subs, $should_reverse, $Spatt)
3442         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3443         # $Spatt is the pattern (if any) to use.
3444         # Reverse scan?
3445         my $Srev     = defined $should_reverse;
3446         # No args - print all subs.
3447         my $Snocheck = !defined $print_all_subs;
3448
3449         # Need to make these sane here.
3450         local $\ = '';
3451         local $, = '';
3452
3453         # Search through the debugger's magical hash of subs.
3454         # If $nocheck is true, just print the sub name.
3455         # Otherwise, check it against the pattern. We then use
3456         # the XOR trick to reverse the condition as required.
3457         foreach $subname ( sort( keys %sub ) ) {
3458             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3459                 print $OUT $subname, "\n";
3460             }
3461         }
3462         next CMD;
3463     }
3464
3465     return;
3466 }
3467
3468 sub _handle_V_command_and_X_command {
3469     my $self = shift;
3470
3471     $DB::cmd =~ s/^X\b/V $DB::package/;
3472
3473     # Bare V commands get the currently-being-debugged package
3474     # added.
3475     if ($self->_is_full('V')) {
3476         $DB::cmd = "V $DB::package";
3477     }
3478
3479     # V - show variables in package.
3480     if (my ($new_packname, $new_vars_str) =
3481         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3482
3483         # Save the currently selected filehandle and
3484         # force output to debugger's filehandle (dumpvar
3485         # just does "print" for output).
3486         my $savout = select($OUT);
3487
3488         # Grab package name and variables to dump.
3489         $packname = $new_packname;
3490         my @vars     = split( ' ', $new_vars_str );
3491
3492         # If main::dumpvar isn't here, get it.
3493         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3494         if ( defined &main::dumpvar ) {
3495
3496             # We got it. Turn off subroutine entry/exit messages
3497             # for the moment, along with return values.
3498             local $frame = 0;
3499             local $doret = -2;
3500
3501             # must detect sigpipe failures  - not catching
3502             # then will cause the debugger to die.
3503             eval {
3504                 main::dumpvar(
3505                     $packname,
3506                     defined $option{dumpDepth}
3507                     ? $option{dumpDepth}
3508                     : -1,    # assume -1 unless specified
3509                     @vars
3510                 );
3511             };
3512
3513             # The die doesn't need to include the $@, because
3514             # it will automatically get propagated for us.
3515             if ($@) {
3516                 die unless $@ =~ /dumpvar print failed/;
3517             }
3518         } ## end if (defined &main::dumpvar)
3519         else {
3520
3521             # Couldn't load dumpvar.
3522             print $OUT "dumpvar.pl not available.\n";
3523         }
3524
3525         # Restore the output filehandle, and go round again.
3526         select($savout);
3527         next CMD;
3528     }
3529
3530     return;
3531 }
3532
3533 sub _handle_dash_command {
3534     my $self = shift;
3535
3536     if ($self->_is_full('-')) {
3537
3538         # back up by a window; go to 1 if back too far.
3539         $start -= $incr + $window + 1;
3540         $start = 1 if $start <= 0;
3541         $incr  = $window - 1;
3542
3543         # Generate and execute a "l +" command (handled below).
3544         $DB::cmd = 'l ' . ($start) . '+';
3545         redo CMD;
3546     }
3547     return;
3548 }
3549
3550 sub _n_or_s_commands_generic {
3551     my ($self, $new_val) = @_;
3552     # n - next
3553     next CMD if DB::_DB__is_finished();
3554
3555     # Single step, but don't enter subs.
3556     $single = $new_val;
3557
3558     # Save for empty command (repeat last).
3559     $laststep = $DB::cmd;
3560     last CMD;
3561 }
3562
3563 sub _n_or_s {
3564     my ($self, $letter, $new_val) = @_;
3565
3566     if ($self->_is_full($letter)) {
3567         $self->_n_or_s_commands_generic($new_val);
3568     }
3569     else {
3570         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3571     }
3572
3573     return;
3574 }
3575
3576 sub _handle_n_command {
3577     my $self = shift;
3578
3579     return $self->_n_or_s('n', 2);
3580 }
3581
3582 sub _handle_s_command {
3583     my $self = shift;
3584
3585     return $self->_n_or_s('s', 1);
3586 }
3587
3588 sub _handle_r_command {
3589     my $self = shift;
3590
3591     # r - return from the current subroutine.
3592     if ($self->_is_full('r')) {
3593
3594         # Can't do anything if the program's over.
3595         next CMD if DB::_DB__is_finished();
3596
3597         # Turn on stack trace.
3598         $stack[$stack_depth] |= 1;
3599
3600         # Print return value unless the stack is empty.
3601         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3602         last CMD;
3603     }
3604
3605     return;
3606 }
3607
3608 sub _handle_T_command {
3609     my $self = shift;
3610
3611     if ($self->_is_full('T')) {
3612         DB::print_trace( $OUT, 1 );    # skip DB
3613         next CMD;
3614     }
3615
3616     return;
3617 }
3618
3619 sub _handle_w_command {
3620     my $self = shift;
3621
3622     DB::cmd_w( 'w', $self->cmd_args() );
3623     next CMD;
3624
3625     return;
3626 }
3627
3628 sub _handle_W_command {
3629     my $self = shift;
3630
3631     if (my $arg = $self->cmd_args) {
3632         DB::cmd_W( 'W', $arg );
3633         next CMD;
3634     }
3635
3636     return;
3637 }
3638
3639 sub _handle_rc_recall_command {
3640     my $self = shift;
3641
3642     # $rc - recall command.
3643     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3644
3645         # No arguments, take one thing off history.
3646         pop(@hist) if length($DB::cmd) > 1;
3647
3648         # Relative (- found)?
3649         #  Y - index back from most recent (by 1 if bare minus)
3650         #  N - go to that particular command slot or the last
3651         #      thing if nothing following.
3652
3653         $self->cmd_verb(
3654             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3655         );
3656
3657         # Pick out the command desired.
3658         $DB::cmd = $hist[$self->cmd_verb];
3659
3660         # Print the command to be executed and restart the loop
3661         # with that command in the buffer.
3662         print {$OUT} $DB::cmd, "\n";
3663         redo CMD;
3664     }
3665
3666     return;
3667 }
3668
3669 sub _handle_rc_search_history_command {
3670     my $self = shift;
3671
3672     # $rc pattern $rc - find a command in the history.
3673     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3674
3675         # Create the pattern to use.
3676         my $pat = "^$arg";
3677         $self->pat($pat);
3678
3679         # Toss off last entry if length is >1 (and it always is).
3680         pop(@hist) if length($DB::cmd) > 1;
3681
3682         my $i;
3683
3684         # Look backward through the history.
3685         SEARCH_HIST:
3686         for ( $i = $#hist ; $i ; --$i ) {
3687             # Stop if we find it.
3688             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3689         }
3690
3691         if ( !$i ) {
3692
3693             # Never found it.
3694             print $OUT "No such command!\n\n";
3695             next CMD;
3696         }
3697
3698         # Found it. Put it in the buffer, print it, and process it.
3699         $DB::cmd = $hist[$i];
3700         print $OUT $DB::cmd, "\n";
3701         redo CMD;
3702     }
3703
3704     return;
3705 }
3706
3707 sub _handle_H_command {
3708     my $self = shift;
3709
3710     if ($self->cmd_args =~ m#\A\*#) {
3711         @hist = @truehist = ();
3712         print $OUT "History cleansed\n";
3713         next CMD;
3714     }
3715
3716     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3717
3718         # Anything other than negative numbers is ignored by
3719         # the (incorrect) pattern, so this test does nothing.
3720         $end = $num ? ( $#hist - $num ) : 0;
3721
3722         # Set to the minimum if less than zero.
3723         $hist = 0 if $hist < 0;
3724
3725         # Start at the end of the array.
3726         # Stay in while we're still above the ending value.
3727         # Tick back by one each time around the loop.
3728         my $i;
3729
3730         for ( $i = $#hist ; $i > $end ; $i-- ) {
3731
3732             # Print the command  unless it has no arguments.
3733             print $OUT "$i: ", $hist[$i], "\n"
3734             unless $hist[$i] =~ /^.?$/;
3735         }
3736
3737         next CMD;
3738     }
3739
3740     return;
3741 }
3742
3743 sub _handle_doc_command {
3744     my $self = shift;
3745
3746     # man, perldoc, doc - show manual pages.
3747     if (my ($man_page)
3748         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3749         DB::runman($man_page);
3750         next CMD;
3751     }
3752
3753     return;
3754 }
3755
3756 sub _handle_p_command {
3757     my $self = shift;
3758
3759     my $print_cmd = 'print {$DB::OUT} ';
3760     # p - print (no args): print $_.
3761     if ($self->_is_full('p')) {
3762         $DB::cmd = $print_cmd . '$_';
3763     }
3764     else {
3765         # p - print the given expression.
3766         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3767     }
3768
3769     return;
3770 }
3771
3772 sub _handle_equal_sign_command {
3773     my $self = shift;
3774
3775     if ($DB::cmd =~ s/\A=\s*//) {
3776         my @keys;
3777         if ( length $DB::cmd == 0 ) {
3778
3779             # No args, get current aliases.
3780             @keys = sort keys %alias;
3781         }
3782         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3783
3784             # Creating a new alias. $k is alias name, $v is
3785             # alias value.
3786
3787             # can't use $_ or kill //g state
3788             for my $x ( $k, $v ) {
3789
3790                 # Escape "alarm" characters.
3791                 $x =~ s/\a/\\a/g;
3792             }
3793
3794             # Substitute key for value, using alarm chars
3795             # as separators (which is why we escaped them in
3796             # the command).
3797             $alias{$k} = "s\a$k\a$v\a";
3798
3799             # Turn off standard warn and die behavior.
3800             local $SIG{__DIE__};
3801             local $SIG{__WARN__};
3802
3803             # Is it valid Perl?
3804             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3805
3806                 # Nope. Bad alias. Say so and get out.
3807                 print $OUT "Can't alias $k to $v: $@\n";
3808                 delete $alias{$k};
3809                 next CMD;
3810             }
3811
3812             # We'll only list the new one.
3813             @keys = ($k);
3814         } ## end elsif (my ($k, $v) = ($DB::cmd...
3815
3816         # The argument is the alias to list.
3817         else {
3818             @keys = ($DB::cmd);
3819         }
3820
3821         # List aliases.
3822         for my $k (@keys) {
3823
3824             # Messy metaquoting: Trim the substitution code off.
3825             # We use control-G as the delimiter because it's not
3826             # likely to appear in the alias.
3827             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3828
3829                 # Print the alias.
3830                 print $OUT "$k\t= $1\n";
3831             }
3832             elsif ( defined $alias{$k} ) {
3833
3834                 # Couldn't trim it off; just print the alias code.
3835                 print $OUT "$k\t$alias{$k}\n";
3836             }
3837             else {
3838
3839                 # No such, dude.
3840                 print "No alias for $k\n";
3841             }
3842         } ## end for my $k (@keys)
3843         next CMD;
3844     }
3845
3846     return;
3847 }
3848
3849 sub _handle_source_command {
3850     my $self = shift;
3851
3852     # source - read commands from a file (or pipe!) and execute.
3853     if (my $sourced_fn = $self->cmd_args) {
3854         if ( open my $fh, $sourced_fn ) {
3855
3856             # Opened OK; stick it in the list of file handles.
3857             push @cmdfhs, $fh;
3858         }
3859         else {
3860
3861             # Couldn't open it.
3862             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3863         }
3864         next CMD;
3865     }
3866
3867     return;
3868 }
3869
3870 sub _handle_enable_disable_commands {
3871     my $self = shift;
3872
3873     my $which_cmd = $self->cmd_verb;
3874     my $position = $self->cmd_args;
3875
3876     if ($position !~ /\s/) {
3877         my ($fn, $line_num);
3878         if ($position =~ m{\A\d+\z})
3879         {
3880             $fn = $DB::filename;
3881             $line_num = $position;
3882         }
3883         elsif (my ($new_fn, $new_line_num)
3884             = $position =~ m{\A(.*):(\d+)\z}) {
3885             ($fn, $line_num) = ($new_fn, $new_line_num);
3886         }
3887         else
3888         {
3889             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3890         }
3891
3892         if (defined($fn)) {
3893             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3894                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3895                     ($which_cmd eq 'enable' ? 1 : '')
3896                 );
3897             }
3898             else {
3899                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3900             }
3901         }
3902
3903         next CMD;
3904     }
3905
3906     return;
3907 }
3908
3909 sub _handle_save_command {
3910     my $self = shift;
3911
3912     if (my $new_fn = $self->cmd_args) {
3913         my $filename = $new_fn || '.perl5dbrc';    # default?
3914         if ( open my $fh, '>', $filename ) {
3915
3916             # chomp to remove extraneous newlines from source'd files
3917             chomp( my @truelist =
3918                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3919                 @truehist );
3920             print {$fh} join( "\n", @truelist );
3921             print "commands saved in $filename\n";
3922         }
3923         else {
3924             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3925         }
3926         next CMD;
3927     }
3928
3929     return;
3930 }
3931
3932 sub _n_or_s_and_arg_commands_generic {
3933     my ($self, $letter, $new_val) = @_;
3934
3935     # s - single-step. Remember the last command was 's'.
3936     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3937         $laststep = $letter;
3938     }
3939
3940     return;
3941 }
3942
3943 sub _handle_sh_command {
3944     my $self = shift;
3945
3946     # $sh$sh - run a shell command (if it's all ASCII).
3947     # Can't run shell commands with Unicode in the debugger, hmm.
3948     my $my_cmd = $DB::cmd;
3949     if ($my_cmd =~ m#\A$sh#gms) {
3950
3951         if ($my_cmd =~ m#\G\z#cgms) {
3952             # Run the user's shell. If none defined, run Bourne.
3953             # We resume execution when the shell terminates.
3954             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3955             next CMD;
3956         }
3957         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3958             # System it.
3959             DB::_db_system($1);
3960             next CMD;
3961         }
3962         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3963             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3964             next CMD;
3965         }
3966     }
3967 }
3968
3969 sub _handle_x_command {
3970     my $self = shift;
3971
3972     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3973         $onetimeDump = 'dump';    # main::dumpvar shows the output
3974
3975         # handle special  "x 3 blah" syntax XXX propagate
3976         # doc back to special variables.
3977         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3978             $onetimedumpDepth = $1;
3979         }
3980     }
3981
3982     return;
3983 }
3984
3985 sub _handle_q_command {
3986     my $self = shift;
3987
3988     if ($self->_is_full('q')) {
3989         $fall_off_end = 1;
3990         DB::clean_ENV();
3991         exit $?;
3992     }
3993
3994     return;
3995 }
3996
3997 sub _handle_cmd_wrapper_commands {
3998     my $self = shift;
3999
4000     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
4001     next CMD;
4002 }
4003
4004 sub _handle_special_char_cmd_wrapper_commands {
4005     my $self = shift;
4006
4007     # All of these commands were remapped in perl 5.8.0;
4008     # we send them off to the secondary dispatcher (see below).
4009     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4010         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4011         next CMD;
4012     }
4013
4014     return;
4015 }
4016
4017 } ## end DB::Obj
4018
4019 package DB;
4020
4021 # The following code may be executed now:
4022 # BEGIN {warn 4}
4023
4024 =head2 sub
4025
4026 C<sub> is called whenever a subroutine call happens in the program being
4027 debugged. The variable C<$DB::sub> contains the name of the subroutine
4028 being called.
4029
4030 The core function of this subroutine is to actually call the sub in the proper
4031 context, capturing its output. This of course causes C<DB::DB> to get called
4032 again, repeating until the subroutine ends and returns control to C<DB::sub>
4033 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4034 return value, and returns its captured copy of the return value as its own
4035 return value. The value then feeds back into the program being debugged as if
4036 C<DB::sub> hadn't been there at all.
4037
4038 C<sub> does all the work of printing the subroutine entry and exit messages
4039 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4040 and also prints the return value if needed (for the C<r> command and if
4041 the 16 bit is set in C<$frame>).
4042
4043 It also tracks the subroutine call depth by saving the current setting of
4044 C<$single> in the C<@stack> package global; if this exceeds the value in
4045 C<$deep>, C<sub> automatically turns on printing of the current depth by
4046 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4047 of stop/don't stop on entry to subs set as it currently is set.
4048
4049 =head3 C<caller()> support
4050
4051 If C<caller()> is called from the package C<DB>, it provides some
4052 additional data, in the following order:
4053
4054 =over 4
4055
4056 =item * C<$package>
4057
4058 The package name the sub was in
4059
4060 =item * C<$filename>
4061
4062 The filename it was defined in
4063
4064 =item * C<$line>
4065
4066 The line number it was defined on
4067
4068 =item * C<$subroutine>
4069
4070 The subroutine name; C<(eval)> if an C<eval>().
4071
4072 =item * C<$hasargs>
4073
4074 1 if it has arguments, 0 if not
4075
4076 =item * C<$wantarray>
4077
4078 1 if array context, 0 if scalar context
4079
4080 =item * C<$evaltext>
4081
4082 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4083
4084 =item * C<$is_require>
4085
4086 frame was created by a C<use> or C<require> statement
4087
4088 =item * C<$hints>
4089
4090 pragma information; subject to change between versions
4091
4092 =item * C<$bitmask>
4093
4094 pragma information; subject to change between versions
4095
4096 =item * C<@DB::args>
4097
4098 arguments with which the subroutine was invoked
4099
4100 =back
4101
4102 =cut
4103
4104 use vars qw($deep);
4105
4106 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4107 # happy. -- Shlomi Fish
4108
4109 sub _indent_print_line_info {
4110     my ($offset, $str) = @_;
4111
4112     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4113
4114     return;
4115 }
4116
4117 sub _print_frame_message {
4118     my ($al) = @_;
4119
4120     if ($frame) {
4121         if ($frame & 4) {   # Extended frame entry message
4122             _indent_print_line_info(-1, "in  ");
4123
4124             # Why -1? But it works! :-(
4125             # Because print_trace will call add 1 to it and then call
4126             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4127             # in dump_trace.
4128             #
4129             # Now it's 0 because we extracted a function.
4130             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4131         }
4132         else {
4133             _indent_print_line_info(-1, "entering $sub$al\n" );
4134         }
4135     }
4136
4137     return;
4138 }
4139
4140 sub DB::sub {
4141     # lock ourselves under threads
4142     lock($DBGR);
4143
4144     # Whether or not the autoloader was running, a scalar to put the
4145     # sub's return value in (if needed), and an array to put the sub's
4146     # return value in (if needed).
4147     my ( $al, $ret, @ret ) = "";
4148     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4149         print "creating new thread\n";
4150     }
4151
4152     # If the last ten characters are '::AUTOLOAD', note we've traced
4153     # into AUTOLOAD for $sub.
4154     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4155         no strict 'refs';
4156         $al = " for $$sub" if defined $$sub;
4157     }
4158
4159     # We stack the stack pointer and then increment it to protect us
4160     # from a situation that might unwind a whole bunch of call frames
4161     # at once. Localizing the stack pointer means that it will automatically
4162     # unwind the same amount when multiple stack frames are unwound.
4163     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4164
4165     # Expand @stack.
4166     $#stack = $stack_depth;
4167
4168     # Save current single-step setting.
4169     $stack[-1] = $single;
4170
4171     # Turn off all flags except single-stepping.
4172     $single &= 1;
4173
4174     # If we've gotten really deeply recursed, turn on the flag that will
4175     # make us stop with the 'deep recursion' message.
4176     $single |= 4 if $stack_depth == $deep;
4177
4178     # If frame messages are on ...
4179
4180     _print_frame_message($al);
4181     # standard frame entry message
4182
4183     my $print_exit_msg = sub {
4184         # Check for exit trace messages...
4185         if ($frame & 2)
4186         {
4187             if ($frame & 4)    # Extended exit message
4188             {
4189                 _indent_print_line_info(0, "out ");
4190                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4191             }
4192             else
4193             {
4194                 _indent_print_line_info(0, "exited $sub$al\n" );
4195             }
4196         }
4197         return;
4198     };
4199
4200     # Determine the sub's return type, and capture appropriately.
4201     if (wantarray) {
4202
4203         # Called in array context. call sub and capture output.
4204         # DB::DB will recursively get control again if appropriate; we'll come
4205         # back here when the sub is finished.
4206         {
4207             no strict 'refs';
4208             @ret = &$sub;
4209         }
4210
4211         # Pop the single-step value back off the stack.
4212         $single |= $stack[ $stack_depth-- ];
4213
4214         $print_exit_msg->();
4215
4216         # Print the return info if we need to.
4217         if ( $doret eq $stack_depth or $frame & 16 ) {
4218
4219             # Turn off output record separator.
4220             local $\ = '';
4221             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4222
4223             # Indent if we're printing because of $frame tracing.
4224             if ($frame & 16)
4225             {
4226                 print {$fh} ' ' x $stack_depth;
4227             }
4228
4229             # Print the return value.
4230             print {$fh} "list context return from $sub:\n";
4231             dumpit( $fh, \@ret );
4232
4233             # And don't print it again.
4234             $doret = -2;
4235         } ## end if ($doret eq $stack_depth...
4236             # And we have to return the return value now.
4237         @ret;
4238     } ## end if (wantarray)
4239
4240     # Scalar context.
4241     else {
4242         if ( defined wantarray ) {
4243             no strict 'refs';
4244             # Save the value if it's wanted at all.
4245             $ret = &$sub;
4246         }
4247         else {
4248             no strict 'refs';
4249             # Void return, explicitly.
4250             &$sub;
4251             undef $ret;
4252         }
4253
4254         # Pop the single-step value off the stack.
4255         $single |= $stack[ $stack_depth-- ];
4256
4257         # If we're doing exit messages...
4258         $print_exit_msg->();
4259
4260         # If we are supposed to show the return value... same as before.
4261         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4262             local $\ = '';
4263             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4264             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4265             print $fh (
4266                 defined wantarray
4267                 ? "scalar context return from $sub: "
4268                 : "void context return from $sub\n"
4269             );
4270             dumpit( $fh, $ret ) if defined wantarray;
4271             $doret = -2;
4272         } ## end if ($doret eq $stack_depth...
4273
4274         # Return the appropriate scalar value.
4275         $ret;
4276     } ## end else [ if (wantarray)
4277 } ## end sub _sub
4278
4279 sub lsub : lvalue {
4280
4281     no strict 'refs';
4282
4283     # lock ourselves under threads
4284     lock($DBGR);
4285
4286     # Whether or not the autoloader was running, a scalar to put the
4287     # sub's return value in (if needed), and an array to put the sub's
4288     # return value in (if needed).
4289     my ( $al, $ret, @ret ) = "";
4290     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4291         print "creating new thread\n";
4292     }
4293
4294     # If the last ten characters are C'::AUTOLOAD', note we've traced
4295     # into AUTOLOAD for $sub.
4296     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4297         $al = " for $$sub";
4298     }
4299
4300     # We stack the stack pointer and then increment it to protect us
4301     # from a situation that might unwind a whole bunch of call frames
4302     # at once. Localizing the stack pointer means that it will automatically
4303     # unwind the same amount when multiple stack frames are unwound.
4304     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4305
4306     # Expand @stack.
4307     $#stack = $stack_depth;
4308
4309     # Save current single-step setting.
4310     $stack[-1] = $single;
4311
4312     # Turn off all flags except single-stepping.
4313     # Use local so the single-step value is popped back off the
4314     # stack for us.
4315     local $single = $single & 1;
4316
4317     # If we've gotten really deeply recursed, turn on the flag that will
4318     # make us stop with the 'deep recursion' message.
4319     $single |= 4 if $stack_depth == $deep;
4320
4321     # If frame messages are on ...
4322     _print_frame_message($al);
4323
4324     # call the original lvalue sub.
4325     &$sub;
4326 }
4327
4328 # Abstracting common code from multiple places elsewhere:
4329 sub depth_print_lineinfo {
4330     my $always_print = shift;
4331
4332     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4333 }
4334
4335 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4336
4337 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4338 Most of the changes were to systematize the command structure and to eliminate
4339 commands that threw away user input without checking.
4340
4341 The following sections describe the code added to make it easy to support
4342 multiple command sets with conflicting command names. This section is a start
4343 at unifying all command processing to make it simpler to develop commands.
4344
4345 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4346 number, and C<$dbline> (the current line) as arguments.
4347
4348 Support functions in this section which have multiple modes of failure C<die>
4349 on error; the rest simply return a false value.
4350
4351 The user-interface functions (all of the C<cmd_*> functions) just output
4352 error messages.
4353
4354 =head2 C<%set>
4355
4356 The C<%set> hash defines the mapping from command letter to subroutine
4357 name suffix.
4358
4359 C<%set> is a two-level hash, indexed by set name and then by command name.
4360 Note that trying to set the CommandSet to C<foobar> simply results in the
4361 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4362
4363 =cut
4364
4365 ### The API section
4366
4367 my %set = (    #
4368     'pre580' => {
4369         'a' => 'pre580_a',
4370         'A' => 'pre580_null',
4371         'b' => 'pre580_b',
4372         'B' => 'pre580_null',
4373         'd' => 'pre580_null',
4374         'D' => 'pre580_D',
4375         'h' => 'pre580_h',
4376         'M' => 'pre580_null',
4377         'O' => 'o',
4378         'o' => 'pre580_null',
4379         'v' => 'M',
4380         'w' => 'v',
4381         'W' => 'pre580_W',
4382     },
4383     'pre590' => {
4384         '<'  => 'pre590_prepost',
4385         '<<' => 'pre590_prepost',
4386         '>'  => 'pre590_prepost',
4387         '>>' => 'pre590_prepost',
4388         '{'  => 'pre590_prepost',
4389         '{{' => 'pre590_prepost',
4390     },
4391 );
4392
4393 my %breakpoints_data;
4394
4395 sub _has_breakpoint_data_ref {
4396     my ($filename, $line) = @_;
4397
4398     return (
4399         exists( $breakpoints_data{$filename} )
4400             and
4401         exists( $breakpoints_data{$filename}{$line} )
4402     );
4403 }
4404
4405 sub _get_breakpoint_data_ref {
4406     my ($filename, $line) = @_;
4407
4408     return ($breakpoints_data{$filename}{$line} ||= +{});
4409 }
4410
4411 sub _delete_breakpoint_data_ref {
4412     my ($filename, $line) = @_;
4413
4414     delete($breakpoints_data{$filename}{$line});
4415     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4416         delete($breakpoints_data{$filename});
4417     }
4418
4419     return;
4420 }
4421
4422 sub _set_breakpoint_enabled_status {
4423     my ($filename, $line, $status) = @_;
4424
4425     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4426         ($status ? 1 : '')
4427         ;
4428
4429     return;
4430 }
4431
4432 sub _enable_breakpoint_temp_enabled_status {
4433     my ($filename, $line) = @_;
4434
4435     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4436
4437     return;
4438 }
4439
4440 sub _cancel_breakpoint_temp_enabled_status {
4441     my ($filename, $line) = @_;
4442
4443     my $ref = _get_breakpoint_data_ref($filename, $line);
4444
4445     delete ($ref->{'temp_enabled'});
4446
4447     if (! %$ref) {
4448         _delete_breakpoint_data_ref($filename, $line);
4449     }
4450
4451     return;
4452 }
4453
4454 sub _is_breakpoint_enabled {
4455     my ($filename, $line) = @_;
4456
4457     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4458     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4459 }
4460
4461 =head2 C<cmd_wrapper()> (API)
4462
4463 C<cmd_wrapper()> allows the debugger to switch command sets
4464 depending on the value of the C<CommandSet> option.
4465
4466 It tries to look up the command in the C<%set> package-level I<lexical>
4467 (which means external entities can't fiddle with it) and create the name of
4468 the sub to call based on the value found in the hash (if it's there). I<All>
4469 of the commands to be handled in a set have to be added to C<%set>; if they
4470 aren't found, the 5.8.0 equivalent is called (if there is one).
4471
4472 This code uses symbolic references.
4473
4474 =cut
4475
4476 sub cmd_wrapper {
4477     my $cmd      = shift;
4478     my $line     = shift;
4479     my $dblineno = shift;
4480
4481     # Assemble the command subroutine's name by looking up the
4482     # command set and command name in %set. If we can't find it,
4483     # default to the older version of the command.
4484     my $call = 'cmd_'
4485       . ( $set{$CommandSet}{$cmd}
4486           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4487
4488     # Call the command subroutine, call it by name.
4489     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4490 } ## end sub cmd_wrapper
4491
4492 =head3 C<cmd_a> (command)
4493
4494 The C<a> command handles pre-execution actions. These are associated with a
4495 particular line, so they're stored in C<%dbline>. We default to the current
4496 line if none is specified.
4497
4498 =cut
4499
4500 sub cmd_a {
4501     my $cmd    = shift;
4502     my $line   = shift || '';    # [.|line] expr
4503     my $dbline = shift;
4504
4505     # If it's dot (here), or not all digits,  use the current line.
4506     $line =~ s/\A\./$dbline/;
4507
4508     # Should be a line number followed by an expression.
4509     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4510
4511         if (! length($lineno)) {
4512             $lineno = $dbline;
4513         }
4514
4515         # If we have an expression ...
4516         if ( length $expr ) {
4517
4518             # ... but the line isn't breakable, complain.
4519             if ( $dbline[$lineno] == 0 ) {
4520                 print $OUT
4521                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4522             }
4523             else {
4524
4525                 # It's executable. Record that the line has an action.
4526                 $had_breakpoints{$filename} |= 2;
4527
4528                 # Remove any action, temp breakpoint, etc.
4529                 $dbline{$lineno} =~ s/\0[^\0]*//;
4530
4531                 # Add the action to the line.
4532                 $dbline{$lineno} .= "\0" . action($expr);
4533
4534                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4535             }
4536         } ## end if (length $expr)
4537     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4538     else {
4539
4540         # Syntax wrong.
4541         print $OUT
4542           "Adding an action requires an optional lineno and an expression\n"
4543           ;    # hint
4544     }
4545 } ## end sub cmd_a
4546
4547 =head3 C<cmd_A> (command)
4548
4549 Delete actions. Similar to above, except the delete code is in a separate
4550 subroutine, C<delete_action>.
4551
4552 =cut
4553
4554 sub cmd_A {
4555     my $cmd    = shift;
4556     my $line   = shift || '';
4557     my $dbline = shift;
4558
4559     # Dot is this line.
4560     $line =~ s/^\./$dbline/;
4561
4562     # Call delete_action with a null param to delete them all.
4563     # The '1' forces the eval to be true. It'll be false only
4564     # if delete_action blows up for some reason, in which case
4565     # we print $@ and get out.
4566     if ( $line eq '*' ) {
4567         if (! eval { _delete_all_actions(); 1 }) {
4568             print {$OUT} $@;
4569             return;
4570         }
4571     }
4572
4573     # There's a real line  number. Pass it to delete_action.
4574     # Error trapping is as above.
4575     elsif ( $line =~ /^(\S.*)/ ) {
4576         if (! eval { delete_action($1); 1 }) {
4577             print {$OUT} $@;
4578             return;
4579         }
4580     }
4581
4582     # Swing and a miss. Bad syntax.
4583     else {
4584         print $OUT
4585           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4586     }
4587 } ## end sub cmd_A
4588
4589 =head3 C<delete_action> (API)
4590
4591 C<delete_action> accepts either a line number or C<undef>. If a line number
4592 is specified, we check for the line being executable (if it's not, it
4593 couldn't have had an  action). If it is, we just take the action off (this
4594 will get any kind of an action, including breakpoints).
4595
4596 =cut
4597
4598 sub _remove_action_from_dbline {
4599     my $i = shift;
4600
4601     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4602     delete $dbline{$i} if $dbline{$i} eq '';
4603
4604     return;
4605 }
4606
4607 sub _delete_all_actions {
4608     print {$OUT} "Deleting all actions...\n";
4609
4610     for my $file ( keys %had_breakpoints ) {
4611         local *dbline = $main::{ '_<' . $file };
4612         $max = $#dbline;
4613         my $was;
4614         for my $i (1 .. $max) {
4615             if ( defined $dbline{$i} ) {
4616                 _remove_action_from_dbline($i);
4617             }
4618         }
4619
4620         unless ( $had_breakpoints{$file} &= ~2 ) {
4621             delete $had_breakpoints{$file};
4622         }
4623     }
4624
4625     return;
4626 }
4627
4628 sub delete_action {
4629     my $i = shift;
4630
4631     if ( defined($i) ) {
4632         # Can there be one?
4633         die "Line $i has no action .\n" if $dbline[$i] == 0;
4634
4635         # Nuke whatever's there.
4636         _remove_action_from_dbline($i);
4637     }
4638     else {
4639         _delete_all_actions();
4640     }
4641 }
4642
4643 =head3 C<cmd_b> (command)
4644
4645 Set breakpoints. Since breakpoints can be set in so many places, in so many
4646 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4647 we try to parse the command type, and then shuttle it off to an appropriate
4648 subroutine to actually do the work of setting the breakpoint in the right
4649 place.
4650
4651 =cut
4652
4653 sub cmd_b {
4654     my $cmd    = shift;
4655     my $line   = shift;    # [.|line] [cond]
4656     my $dbline = shift;
4657
4658     my $default_cond = sub {
4659         my $cond = shift;
4660         return length($cond) ? $cond : '1';
4661     };
4662
4663     # Make . the current line number if it's there..
4664     $line =~ s/^\.(\s|\z)/$dbline$1/;
4665
4666     # No line number, no condition. Simple break on current line.
4667     if ( $line =~ /^\s*$/ ) {
4668         cmd_b_line( $dbline, 1 );
4669     }
4670
4671     # Break on load for a file.
4672     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4673         $file =~ s/\s+\z//;
4674         cmd_b_load($file);
4675     }
4676
4677     # b compile|postpone <some sub> [<condition>]
4678     # The interpreter actually traps this one for us; we just put the
4679     # necessary condition in the %postponed hash.
4680     elsif ( my ($action, $subname, $cond)
4681         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4682
4683         # De-Perl4-ify the name - ' separators to ::.
4684         $subname =~ s/'/::/g;
4685
4686         # Qualify it into the current package unless it's already qualified.
4687         $subname = "${package}::" . $subname unless $subname =~ /::/;
4688
4689         # Add main if it starts with ::.
4690         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4691
4692         # Save the break type for this sub.
4693         $postponed{$subname} = (($action eq 'postpone')
4694             ? ( "break +0 if " . $default_cond->($cond) )
4695             : "compile");
4696     } ## end elsif ($line =~ ...
4697     # b <filename>:<line> [<condition>]
4698     elsif (my ($filename, $line_num, $cond)
4699         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4700         cmd_b_filename_line(
4701             $filename,
4702             $line_num,
4703             (length($cond) ? $cond : '1'),
4704         );
4705     }
4706     # b <sub name> [<condition>]
4707     elsif ( my ($new_subname, $new_cond) =
4708         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4709
4710         #
4711         $subname = $new_subname;
4712         cmd_b_sub( $subname, $default_cond->($new_cond) );
4713     }
4714
4715     # b <line> [<condition>].
4716     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4717
4718         # Capture the line. If none, it's the current line.
4719         $line = $line_n || $dbline;
4720
4721         # Break on line.
4722         cmd_b_line( $line, $default_cond->($cond) );
4723     }
4724
4725     # Line didn't make sense.
4726     else {
4727         print "confused by line($line)?\n";
4728     }
4729
4730     return;
4731 } ## end sub cmd_b
4732
4733 =head3 C<break_on_load> (API)
4734
4735 We want to break when this file is loaded. Mark this file in the
4736 C<%break_on_load> hash, and note that it has a breakpoint in
4737 C<%had_breakpoints>.
4738
4739 =cut
4740
4741 sub break_on_load {
4742     my $file = shift;
4743     $break_on_load{$file} = 1;
4744     $had_breakpoints{$file} |= 1;
4745 }
4746
4747 =head3 C<report_break_on_load> (API)
4748
4749 Gives us an array of filenames that are set to break on load. Note that
4750 only files with break-on-load are in here, so simply showing the keys
4751 suffices.
4752
4753 =cut
4754
4755 sub report_break_on_load {
4756     sort keys %break_on_load;
4757 }
4758
4759 =head3 C<cmd_b_load> (command)
4760
4761 We take the file passed in and try to find it in C<%INC> (which maps modules
4762 to files they came from). We mark those files for break-on-load via
4763 C<break_on_load> and then report that it was done.
4764
4765 =cut
4766
4767 sub cmd_b_load {
4768     my $file = shift;
4769     my @files;
4770
4771     # This is a block because that way we can use a redo inside it
4772     # even without there being any looping structure at all outside it.
4773     {
4774
4775         # Save short name and full path if found.
4776         push @files, $file;
4777         push @files, $::INC{$file} if $::INC{$file};
4778
4779         # Tack on .pm and do it again unless there was a '.' in the name
4780         # already.
4781         $file .= '.pm', redo unless $file =~ /\./;
4782     }
4783
4784     # Do the real work here.
4785     break_on_load($_) for @files;
4786
4787     # All the files that have break-on-load breakpoints.
4788     @files = report_break_on_load;
4789
4790     # Normalize for the purposes of our printing this.
4791     local $\ = '';
4792     local $" = ' ';
4793     print $OUT "Will stop on load of '@files'.\n";
4794 } ## end sub cmd_b_load
4795
4796 =head3 C<$filename_error> (API package global)
4797
4798 Several of the functions we need to implement in the API need to work both
4799 on the current file and on other files. We don't want to duplicate code, so
4800 C<$filename_error> is used to contain the name of the file that's being
4801 worked on (if it's not the current one).
4802
4803 We can now build functions in pairs: the basic function works on the current
4804 file, and uses C<$filename_error> as part of its error message. Since this is
4805 initialized to C<"">, no filename will appear when we are working on the
4806 current file.
4807
4808 The second function is a wrapper which does the following:
4809
4810 =over 4
4811
4812 =item *
4813
4814 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4815
4816 =item *
4817
4818 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4819
4820 =item *
4821
4822 Calls the first function.
4823
4824 The first function works on the I<current> file (i.e., the one we changed to),
4825 and prints C<$filename_error> in the error message (the name of the other file)
4826 if it needs to. When the functions return, C<*dbline> is restored to point
4827 to the actual current file (the one we're executing in) and
4828 C<$filename_error> is restored to C<"">. This restores everything to
4829 the way it was before the second function was called at all.
4830
4831 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4832 details.
4833
4834 =back
4835
4836 =cut
4837
4838 use vars qw($filename_error);
4839 $filename_error = '';
4840
4841 =head3 breakable_line(from, to) (API)
4842
4843 The subroutine decides whether or not a line in the current file is breakable.
4844 It walks through C<@dbline> within the range of lines specified, looking for
4845 the first line that is breakable.
4846
4847 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4848 first line I<after> C<$to> that's breakable, if there is one.
4849
4850 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4851 first line I<before> C<$to> that's breakable, if there is one.
4852
4853 =cut
4854
4855 sub breakable_line {
4856
4857     my ( $from, $to ) = @_;
4858
4859     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4860     my $i = $from;
4861
4862     # If there are at least 2 arguments, we're trying to search a range.
4863     if ( @_ >= 2 ) {
4864
4865         # $delta is positive for a forward search, negative for a backward one.
4866         my $delta = $from < $to ? +1 : -1;
4867
4868         # Keep us from running off the ends of the file.
4869         my $limit = $delta > 0 ? $#dbline : 1;
4870
4871         # Clever test. If you're a mathematician, it's obvious why this
4872         # test works. If not:
4873         # If $delta is positive (going forward), $limit will be $#dbline.
4874         #    If $to is less than $limit, ($limit - $to) will be positive, times
4875         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4876         #    as the stopping point.
4877         #
4878         #    If $to is greater than $limit, ($limit - $to) is negative,
4879         #    times $delta of 1 (positive), so the result is < 0 and we should
4880         #    use $limit ($#dbline) as the stopping point.
4881         #
4882         # If $delta is negative (going backward), $limit will be 1.
4883         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4884         #    (negative) so the result is > 0, and we use $to as the stopping
4885         #    point.
4886         #
4887         #    If $to is less than zero, ($limit - $to) will be positive,
4888         #    times $delta of -1 (negative), so the result is not > 0, and
4889         #    we use $limit (1) as the stopping point.
4890         #
4891         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4892         #    (negative), still giving zero; the result is not > 0, and
4893         #    we use $limit (1) as the stopping point.
4894         #
4895         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4896         #    (negative), giving a positive (>0) value, so we'll set $limit to
4897         #    $to.
4898
4899         $limit = $to if ( $limit - $to ) * $delta > 0;
4900
4901         # The real search loop.
4902         # $i starts at $from (the point we want to start searching from).
4903         # We move through @dbline in the appropriate direction (determined
4904         # by $delta: either -1 (back) or +1 (ahead).
4905         # We stay in as long as we haven't hit an executable line
4906         # ($dbline[$i] == 0 means not executable) and we haven't reached
4907         # the limit yet (test similar to the above).
4908         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4909
4910     } ## end if (@_ >= 2)
4911
4912     # If $i points to a line that is executable, return that.
4913     return $i unless $dbline[$i] == 0;
4914
4915     # Format the message and print it: no breakable lines in range.
4916     my ( $pl, $upto ) = ( '', '' );
4917     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4918
4919     # If there's a filename in filename_error, we'll see it.
4920     # If not, not.
4921     die "Line$pl $from$upto$filename_error not breakable\n";
4922 } ## end sub breakable_line
4923
4924 =head3 breakable_line_in_filename(file, from, to) (API)
4925
4926 Like C<breakable_line>, but look in another file.
4927
4928 =cut
4929
4930 sub breakable_line_in_filename {
4931
4932     # Capture the file name.
4933     my ($f) = shift;
4934
4935     # Swap the magic line array over there temporarily.
4936     local *dbline = $main::{ '_<' . $f };
4937
4938     # If there's an error, it's in this other file.
4939     local $filename_error = " of '$f'";
4940
4941     # Find the breakable line.
4942     breakable_line(@_);
4943
4944     # *dbline and $filename_error get restored when this block ends.
4945
4946 } ## end sub breakable_line_in_filename
4947
4948 =head3 break_on_line(lineno, [condition]) (API)
4949
4950 Adds a breakpoint with the specified condition (or 1 if no condition was
4951 specified) to the specified line. Dies if it can't.
4952
4953 =cut
4954
4955 sub break_on_line {
4956     my $i = shift;
4957     my $cond = @_ ? shift(@_) : 1;
4958
4959     my $inii  = $i;
4960     my $after = '';
4961     my $pl    = '';
4962
4963     # Woops, not a breakable line. $filename_error allows us to say
4964     # if it was in a different file.
4965     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4966
4967     # Mark this file as having breakpoints in it.
4968     $had_breakpoints{$filename} |= 1;
4969
4970     # If there is an action or condition here already ...
4971     if ( $dbline{$i} ) {
4972
4973         # ... swap this condition for the existing one.
4974         $dbline{$i} =~ s/^[^\0]*/$cond/;
4975     }
4976     else {
4977
4978         # Nothing here - just add the condition.
4979         $dbline{$i} = $cond;
4980
4981         _set_breakpoint_enabled_status($filename, $i, 1);
4982     }
4983
4984     return;
4985 } ## end sub break_on_line
4986
4987 =head3 cmd_b_line(line, [condition]) (command)
4988
4989 Wrapper for C<break_on_line>. Prints the failure message if it
4990 doesn't work.
4991
4992 =cut
4993
4994 sub cmd_b_line {
4995     if (not eval { break_on_line(@_); 1 }) {
4996         local $\ = '';
4997         print $OUT $@ and return;
4998     }
4999
5000     return;
5001 } ## end sub cmd_b_line
5002
5003 =head3 cmd_b_filename_line(line, [condition]) (command)
5004
5005 Wrapper for C<break_on_filename_line>. Prints the failure message if it
5006 doesn't work.
5007
5008 =cut
5009
5010 sub cmd_b_filename_line {
5011     if (not eval { break_on_filename_line(@_); 1 }) {
5012         local $\ = '';
5013         print $OUT $@ and return;
5014     }
5015
5016     return;
5017 }
5018
5019 =head3 break_on_filename_line(file, line, [condition]) (API)
5020
5021 Switches to the file specified and then calls C<break_on_line> to set
5022 the breakpoint.
5023
5024 =cut
5025
5026 sub break_on_filename_line {
5027     my $f = shift;
5028     my $i = shift;
5029     my $cond = @_ ? shift(@_) : 1;
5030
5031     # Switch the magical hash temporarily.
5032     local *dbline = $main::{ '_<' . $f };
5033
5034     # Localize the variables that break_on_line uses to make its message.
5035     local $filename_error = " of '$f'";
5036     local $filename       = $f;
5037
5038     # Add the breakpoint.
5039     break_on_line( $i, $cond );
5040
5041     return;
5042 } ## end sub break_on_filename_line
5043
5044 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
5045
5046 Switch to another file, search the range of lines specified for an
5047 executable one, and put a breakpoint on the first one you find.
5048
5049 =cut
5050
5051 sub break_on_filename_line_range {
5052     my $f = shift;
5053     my $from = shift;
5054     my $to = shift;
5055     my $cond = @_ ? shift(@_) : 1;
5056
5057     # Find a breakable line if there is one.
5058     my $i = breakable_line_in_filename( $f, $from, $to );
5059
5060     # Add the breakpoint.
5061     break_on_filename_line( $f, $i, $cond );
5062
5063     return;
5064 } ## end sub break_on_filename_line_range
5065
5066 =head3 subroutine_filename_lines(subname, [condition]) (API)
5067
5068 Search for a subroutine within a given file. The condition is ignored.
5069 Uses C<find_sub> to locate the desired subroutine.
5070
5071 =cut
5072
5073 sub subroutine_filename_lines {
5074     my ( $subname ) = @_;
5075
5076     # Returned value from find_sub() is fullpathname:startline-endline.
5077     # The match creates the list (fullpathname, start, end).
5078     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5079 } ## end sub subroutine_filename_lines
5080
5081 =head3 break_subroutine(subname) (API)
5082
5083 Places a break on the first line possible in the specified subroutine. Uses
5084 C<subroutine_filename_lines> to find the subroutine, and
5085 C<break_on_filename_line_range> to place the break.
5086
5087 =cut
5088
5089 sub break_subroutine {
5090     my $subname = shift;
5091
5092     # Get filename, start, and end.
5093     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5094       or die "Subroutine $subname not found.\n";
5095
5096
5097     # Null condition changes to '1' (always true).
5098     my $cond = @_ ? shift(@_) : 1;
5099
5100     # Put a break the first place possible in the range of lines
5101     # that make up this subroutine.
5102     break_on_filename_line_range( $file, $s, $e, $cond );
5103
5104     return;
5105 } ## end sub break_subroutine
5106
5107 =head3 cmd_b_sub(subname, [condition]) (command)
5108
5109 We take the incoming subroutine name and fully-qualify it as best we can.
5110
5111 =over 4
5112
5113 =item 1. If it's already fully-qualified, leave it alone.
5114
5115 =item 2. Try putting it in the current package.
5116
5117 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5118
5119 =item 4. If it starts with '::', put it in 'main::'.
5120
5121 =back
5122
5123 After all this cleanup, we call C<break_subroutine> to try to set the
5124 breakpoint.
5125
5126 =cut
5127
5128 sub cmd_b_sub {
5129     my $subname = shift;
5130     my $cond = @_ ? shift : 1;
5131
5132     # If the subname isn't a code reference, qualify it so that
5133     # break_subroutine() will work right.
5134     if ( ref($subname) ne 'CODE' ) {
5135
5136         # Not Perl 4.
5137         $subname =~ s/'/::/g;
5138         my $s = $subname;
5139
5140         # Put it in this package unless it's already qualified.
5141         if ($subname !~ /::/)
5142         {
5143             $subname = $package . '::' . $subname;
5144         };
5145
5146         # Requalify it into CORE::GLOBAL if qualifying it into this
5147         # package resulted in its not being defined, but only do so
5148         # if it really is in CORE::GLOBAL.
5149         my $core_name = "CORE::GLOBAL::$s";
5150         if ((!defined(&$subname))
5151                 and ($s !~ /::/)
5152                 and (defined &{$core_name}))
5153         {
5154             $subname = $core_name;
5155         }
5156
5157         # Put it in package 'main' if it has a leading ::.
5158         if ($subname =~ /\A::/)
5159         {
5160             $subname = "main" . $subname;
5161         }
5162     } ## end if ( ref($subname) ne 'CODE' ) {
5163
5164     # Try to set the breakpoint.
5165     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5166         local $\ = '';
5167         print {$OUT} $@;
5168         return;
5169     }
5170
5171     return;
5172 } ## end sub cmd_b_sub
5173
5174 =head3 C<cmd_B> - delete breakpoint(s) (command)
5175
5176 The command mostly parses the command line and tries to turn the argument
5177 into a line spec. If it can't, it uses the current line. It then calls
5178 C<delete_breakpoint> to actually do the work.
5179
5180 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5181 thereby deleting all the breakpoints.
5182
5183 =cut
5184
5185 sub cmd_B {
5186     my $cmd = shift;
5187
5188     # No line spec? Use dbline.
5189     # If there is one, use it if it's non-zero, or wipe it out if it is.
5190     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5191     my $dbline = shift;
5192
5193     # If the line was dot, make the line the current one.
5194     $line =~ s/^\./$dbline/;
5195
5196     # If it's * we're deleting all the breakpoints.
5197     if ( $line eq '*' ) {
5198         if (not eval { delete_breakpoint(); 1 }) {
5199             print {$OUT} $@;
5200         }
5201     }
5202
5203     # If there is a line spec, delete the breakpoint on that line.
5204     elsif ( $line =~ /\A(\S.*)/ ) {
5205         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5206             local $\ = '';
5207             print {$OUT} $@;
5208         }
5209     } ## end elsif ($line =~ /^(\S.*)/)
5210
5211     # No line spec.
5212     else {
5213         print {$OUT}
5214           "Deleting a breakpoint requires a line number, or '*' for all\n"
5215           ;    # hint
5216     }
5217
5218     return;
5219 } ## end sub cmd_B
5220
5221 =head3 delete_breakpoint([line]) (API)
5222
5223 This actually does the work of deleting either a single breakpoint, or all
5224 of them.
5225
5226 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5227 just drop out with a message saying so. If it is, we remove the condition
5228 part of the 'condition\0action' that says there's a breakpoint here. If,
5229 after we've done that, there's nothing left, we delete the corresponding
5230 line in C<%dbline> to signal that no action needs to be taken for this line.
5231
5232 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5233 which lists all currently-loaded files which have breakpoints. We then look
5234 at each line in each of these files, temporarily switching the C<%dbline>
5235 and C<@dbline> structures to point to the files in question, and do what
5236 we did in the single line case: delete the condition in C<@dbline>, and
5237 delete the key in C<%dbline> if nothing's left.
5238
5239 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5240 C<%break_on_load>, because these structures contain breakpoints for files
5241 and code that haven't been loaded yet. We can just kill these off because there
5242 are no magical debugger structures associated with them.
5243
5244 =cut
5245
5246 sub _remove_breakpoint_entry {
5247     my ($fn, $i) = @_;
5248
5249     delete $dbline{$i};
5250     _delete_breakpoint_data_ref($fn, $i);
5251
5252     return;
5253 }
5254
5255 sub _delete_all_breakpoints {
5256     print {$OUT} "Deleting all breakpoints...\n";
5257
5258     # %had_breakpoints lists every file that had at least one
5259     # breakpoint in it.
5260     for my $fn ( keys %had_breakpoints ) {
5261
5262         # Switch to the desired file temporarily.
5263         local *dbline = $main::{ '_<' . $fn };
5264
5265         $max = $#dbline;
5266
5267         # For all lines in this file ...
5268         for my $i (1 .. $max) {
5269
5270             # If there's a breakpoint or action on this line ...
5271             if ( defined $dbline{$i} ) {
5272
5273                 # ... remove the breakpoint.
5274                 $dbline{$i} =~ s/\A[^\0]+//;
5275                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5276                     # Remove the entry altogether if no action is there.
5277                     _remove_breakpoint_entry($fn, $i);
5278                 }
5279             } ## end if (defined $dbline{$i...
5280         } ## end for $i (1 .. $max)
5281
5282         # If, after we turn off the "there were breakpoints in this file"
5283         # bit, the entry in %had_breakpoints for this file is zero,
5284         # we should remove this file from the hash.
5285         if ( not $had_breakpoints{$fn} &= (~1) ) {
5286             delete $had_breakpoints{$fn};
5287         }
5288     } ## end for my $fn (keys %had_breakpoints)
5289
5290     # Kill off all the other breakpoints that are waiting for files that
5291     # haven't been loaded yet.
5292     undef %postponed;
5293     undef %postponed_file;
5294     undef %break_on_load;
5295
5296     return;
5297 }
5298
5299 sub _delete_breakpoint_from_line {
5300     my ($i) = @_;
5301
5302     # Woops. This line wasn't breakable at all.
5303     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5304
5305     # Kill the condition, but leave any action.
5306     $dbline{$i} =~ s/\A[^\0]*//;
5307
5308     # Remove the entry entirely if there's no action left.
5309     if ($dbline{$i} eq '') {
5310         _remove_breakpoint_entry($filename, $i);
5311     }
5312
5313     return;
5314 }
5315
5316 sub delete_breakpoint {
5317     my $i = shift;
5318
5319     # If we got a line, delete just that one.
5320     if ( defined($i) ) {
5321         _delete_breakpoint_from_line($i);
5322     }
5323     # No line; delete them all.
5324     else {
5325         _delete_all_breakpoints();
5326     }
5327
5328     return;
5329 }
5330
5331 =head3 cmd_stop (command)
5332
5333 This is meant to be part of the new command API, but it isn't called or used
5334 anywhere else in the debugger. XXX It is probably meant for use in development
5335 of new commands.
5336
5337 =cut
5338
5339 sub cmd_stop {    # As on ^C, but not signal-safy.
5340     $signal = 1;
5341 }
5342
5343 =head3 C<cmd_e> - threads
5344
5345 Display the current thread id:
5346
5347     e
5348
5349 This could be how (when implemented) to send commands to this thread id (e cmd)
5350 or that thread id (e tid cmd).
5351
5352 =cut
5353
5354 sub cmd_e {
5355     my $cmd  = shift;
5356     my $line = shift;
5357     unless (exists($INC{'threads.pm'})) {
5358         print "threads not loaded($ENV{PERL5DB_THREADED})
5359         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5360     } else {
5361         my $tid = threads->tid;
5362         print "thread id: $tid\n";
5363     }
5364 } ## end sub cmd_e
5365
5366 =head3 C<cmd_E> - list of thread ids
5367
5368 Display the list of available thread ids:
5369
5370     E
5371
5372 This could be used (when implemented) to send commands to all threads (E cmd).
5373
5374 =cut
5375
5376 sub cmd_E {
5377     my $cmd  = shift;
5378     my $line = shift;
5379     unless (exists($INC{'threads.pm'})) {
5380         print "threads not loaded($ENV{PERL5DB_THREADED})
5381         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5382     } else {
5383         my $tid = threads->tid;
5384         print "thread ids: ".join(', ',
5385             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5386         )."\n";
5387     }
5388 } ## end sub cmd_E
5389
5390 =head3 C<cmd_h> - help command (command)
5391
5392 Does the work of either
5393
5394 =over 4
5395
5396 =item *
5397
5398 Showing all the debugger help
5399
5400 =item *
5401
5402 Showing help for a specific command
5403
5404 =back
5405
5406 =cut
5407
5408 use vars qw($help);
5409 use vars qw($summary);
5410
5411 sub cmd_h {
5412     my $cmd = shift;
5413
5414     # If we have no operand, assume null.
5415     my $line = shift || '';
5416
5417     # 'h h'. Print the long-format help.
5418     if ( $line =~ /\Ah\s*\z/ ) {
5419         print_help($help);
5420     }
5421
5422     # 'h <something>'. Search for the command and print only its help.
5423     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5424
5425         # support long commands; otherwise bogus errors
5426         # happen when you ask for h on <CR> for example
5427         my $qasked = quotemeta($asked);    # for searching; we don't
5428                                            # want to use it as a pattern.
5429                                            # XXX: finds CR but not <CR>
5430
5431         # Search the help string for the command.
5432         if (
5433             $help =~ /^                    # Start of a line
5434                       <?                   # Optional '<'
5435                       (?:[IB]<)            # Optional markup
5436                       $qasked              # The requested command
5437                      /mx
5438           )
5439         {
5440
5441             # It's there; pull it out and print it.
5442             while (
5443                 $help =~ /^
5444                               (<?            # Optional '<'
5445                                  (?:[IB]<)   # Optional markup
5446                                  $qasked     # The command
5447                                  ([\s\S]*?)  # Description line(s)
5448                               \n)            # End of last description line
5449                               (?!\s)         # Next line not starting with
5450                                              # whitespace
5451                              /mgx
5452               )
5453             {
5454                 print_help($1);
5455             }
5456         }
5457
5458         # Not found; not a debugger command.
5459         else {
5460             print_help("B<$asked> is not a debugger command.\n");
5461         }
5462     } ## end elsif ($line =~ /^(\S.*)$/)
5463
5464     # 'h' - print the summary help.
5465     else {
5466         print_help($summary);
5467     }
5468 } ## end sub cmd_h
5469
5470 =head3 C<cmd_i> - inheritance display
5471
5472 Display the (nested) parentage of the module or object given.
5473
5474 =cut
5475
5476 sub cmd_i {
5477     my $cmd  = shift;
5478     my $line = shift;
5479     foreach my $isa ( split( /\s+/, $line ) ) {
5480         $evalarg = $isa;
5481         # The &-call is here to ascertain the mutability of @_.
5482         ($isa) = &DB::eval;
5483         no strict 'refs';
5484         print join(
5485             ', ',
5486             map {
5487                 "$_"
5488                   . (
5489                     defined( ${"$_\::VERSION"} )
5490                     ? ' ' . ${"$_\::VERSION"}
5491                     : undef )
5492               } @{mro::get_linear_isa(ref($isa) || $isa)}
5493         );
5494         print "\n";
5495     }
5496 } ## end sub cmd_i
5497
5498 =head3 C<cmd_l> - list lines (command)
5499
5500 Most of the command is taken up with transforming all the different line
5501 specification syntaxes into 'start-stop'. After that is done, the command
5502 runs a loop over C<@dbline> for the specified range of lines. It handles
5503 the printing of each line and any markers (C<==E<gt>> for current line,
5504 C<b> for break on this line, C<a> for action on this line, C<:> for this
5505 line breakable).
5506
5507 We save the last line listed in the C<$start> global for further listing
5508 later.
5509
5510 =cut
5511
5512 sub _min {
5513     my $min = shift;
5514     foreach my $v (@_) {
5515         if ($min > $v) {
5516             $min = $v;
5517         }
5518     }
5519     return $min;
5520 }
5521
5522 sub _max {
5523     my $max = shift;
5524     foreach my $v (@_) {
5525         if ($max < $v) {
5526             $max = $v;
5527         }
5528     }
5529     return $max;
5530 }
5531
5532 sub _minify_to_max {
5533     my $ref = shift;
5534
5535     $$ref = _min($$ref, $max);
5536
5537     return;
5538 }
5539
5540 sub _cmd_l_handle_var_name {
5541     my $var_name = shift;
5542
5543     $evalarg = $var_name;
5544
5545     my ($s) = DB::eval();
5546
5547     # Ooops. Bad scalar.
5548     if ($@) {
5549         print {$OUT} "Error: $@\n";
5550         next CMD;
5551     }
5552
5553     # Good scalar. If it's a reference, find what it points to.
5554     $s = CvGV_name($s);
5555     print {$OUT} "Interpreted as: $1 $s\n";
5556     $line = "$1 $s";
5557
5558     # Call self recursively to really do the command.
5559     return _cmd_l_main( $s );
5560 }
5561
5562 sub _cmd_l_handle_subname {
5563
5564     my $s = $subname;
5565
5566     # De-Perl4.
5567     $subname =~ s/\'/::/;
5568
5569     # Put it in this package unless it starts with ::.
5570     $subname = $package . "::" . $subname unless $subname =~ /::/;
5571
5572     # Put it in CORE::GLOBAL if t doesn't start with :: and
5573     # it doesn't live in this package and it lives in CORE::GLOBAL.
5574     $subname = "CORE::GLOBAL::$s"
5575     if not defined &$subname
5576         and $s !~ /::/
5577         and defined &{"CORE::GLOBAL::$s"};
5578
5579     # Put leading '::' names into 'main::'.
5580     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5581
5582     # Get name:start-stop from find_sub, and break this up at
5583     # colons.
5584     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5585
5586     # Pull off start-stop.
5587     my $subrange = pop @pieces;
5588
5589     # If the name contained colons, the split broke it up.
5590     # Put it back together.
5591     $file = join( ':', @pieces );
5592
5593     # If we're not in that file, switch over to it.
5594     if ( $file ne $filename ) {
5595         if (! $slave_editor) {
5596             print {$OUT} "Switching to file '$file'.\n";
5597         }
5598
5599         # Switch debugger's magic structures.
5600         *dbline   = $main::{ '_<' . $file };
5601         $max      = $#dbline;
5602         $filename = $file;
5603     } ## end if ($file ne $filename)
5604
5605     # Subrange is 'start-stop'. If this is less than a window full,
5606     # swap it to 'start+', which will list a window from the start point.
5607     if ($subrange) {
5608         if ( eval($subrange) < -$window ) {
5609             $subrange =~ s/-.*/+/;
5610         }
5611
5612         # Call self recursively to list the range.
5613         return _cmd_l_main( $subrange );
5614     } ## end if ($subrange)
5615
5616     # Couldn't find it.
5617     else {
5618         print {$OUT} "Subroutine $subname not found.\n";
5619         return;
5620     }
5621 }
5622
5623 sub _cmd_l_empty {
5624     # Compute new range to list.
5625     $incr = $window - 1;
5626
5627     # Recurse to do it.
5628     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5629 }
5630
5631 sub _cmd_l_plus {
5632     my ($new_start, $new_incr) = @_;
5633
5634     # Don't reset start for 'l +nnn'.
5635     $start = $new_start if $new_start;
5636
5637     # Increment for list. Use window size if not specified.
5638     # (Allows 'l +' to work.)
5639     $incr = $new_incr || ($window - 1);
5640
5641     # Create a line range we'll understand, and recurse to do it.
5642     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5643 }
5644
5645 sub _cmd_l_calc_initial_end_and_i {
5646     my ($spec, $start_match, $end_match) = @_;
5647
5648     # Determine end point; use end of file if not specified.
5649     my $end = ( !defined $start_match ) ? $max :
5650     ( $end_match ? $end_match : $start_match );
5651
5652     # Go on to the end, and then stop.
5653     _minify_to_max(\$end);
5654
5655     # Determine start line.
5656     my $i = $start_match;
5657
5658     if ($i eq '.') {
5659         $i = $spec;
5660     }
5661
5662     $i = _max($i, 1);
5663
5664     $incr = $end - $i;
5665
5666     return ($end, $i);
5667 }
5668
5669 sub _cmd_l_range {
5670     my ($spec, $current_line, $start_match, $end_match) = @_;
5671
5672     my ($end, $i) =
5673         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5674
5675     # If we're running under a slave editor, force it to show the lines.
5676     if ($slave_editor) {
5677         print {$OUT} "\032\032$filename:$i:0\n";
5678         $i = $end;
5679     }
5680     # We're doing it ourselves. We want to show the line and special
5681     # markers for:
5682     # - the current line in execution
5683     # - whether a line is breakable or not
5684     # - whether a line has a break or not
5685     # - whether a line has an action or not
5686     else {
5687         I_TO_END:
5688         for ( ; $i <= $end ; $i++ ) {
5689
5690             # Check for breakpoints and actions.
5691             my ( $stop, $action );
5692             if ($dbline{$i}) {
5693                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5694             }
5695
5696             # ==> if this is the current line in execution,
5697             # : if it's breakable.
5698             my $arrow =
5699             ( $i == $current_line and $filename eq $filename_ini )
5700             ? '==>'
5701             : ( $dbline[$i] + 0 ? ':' : ' ' );
5702
5703             # Add break and action indicators.
5704             $arrow .= 'b' if $stop;
5705             $arrow .= 'a' if $action;
5706
5707             # Print the line.
5708             print {$OUT} "$i$arrow\t", $dbline[$i];
5709
5710             # Move on to the next line. Drop out on an interrupt.
5711             if ($signal) {
5712                 $i++;
5713                 last I_TO_END;
5714             }
5715         } ## end for (; $i <= $end ; $i++)
5716
5717         # Line the prompt up; print a newline if the last line listed
5718         # didn't have a newline.
5719         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5720             print {$OUT} "\n";
5721         }
5722     } ## end else [ if ($slave_editor)
5723
5724     # Save the point we last listed to in case another relative 'l'
5725     # command is desired. Don't let it run off the end.
5726     $start = $i;
5727     _minify_to_max(\$start);
5728
5729     return;
5730 }
5731
5732 sub _cmd_l_main {
5733     my $spec = shift;
5734
5735     # If this is '-something', delete any spaces after the dash.
5736     $spec =~ s/\A-\s*\z/-/;
5737
5738     # If the line is '$something', assume this is a scalar containing a
5739     # line number.
5740     # Set up for DB::eval() - evaluate in *user* context.
5741     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5742         return _cmd_l_handle_var_name($var_name);
5743     }
5744     # l name. Try to find a sub by that name.
5745     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5746         return _cmd_l_handle_subname();
5747     }
5748     # Bare 'l' command.
5749     elsif ( $spec !~ /\S/ ) {
5750         return _cmd_l_empty();
5751     }
5752     # l [start]+number_of_lines
5753     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5754         return _cmd_l_plus($new_start, $new_incr);
5755     }
5756     # l start-stop or l start,stop
5757     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5758         return _cmd_l_range($spec, $line, $s, $e);
5759     }
5760
5761     return;
5762 } ## end sub cmd_l
5763
5764 sub cmd_l {
5765     my (undef, $line) = @_;
5766
5767     return _cmd_l_main($line);
5768 }
5769
5770 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5771
5772 To list breakpoints, the command has to look determine where all of them are
5773 first. It starts a C<%had_breakpoints>, which tells us what all files have
5774 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5775 magic source and breakpoint data structures) to the file, and then look
5776 through C<%dbline> for lines with breakpoints and/or actions, listing them
5777 out. We look through C<%postponed> not-yet-compiled subroutines that have
5778 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5779 that have breakpoints.
5780
5781 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5782
5783 =cut
5784
5785 sub _cmd_L_calc_arg {
5786     # If no argument, list everything. Pre-5.8.0 version always lists
5787     # everything
5788     my $arg = shift || 'abw';
5789     if ($CommandSet ne '580')
5790     {
5791         $arg = 'abw';
5792     }
5793
5794     return $arg;
5795 }
5796
5797 sub _cmd_L_calc_wanted_flags {
5798     my $arg = _cmd_L_calc_arg(shift);
5799
5800     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5801 }
5802
5803
5804 sub _cmd_L_handle_breakpoints {
5805     my ($handle_db_line) = @_;
5806
5807     BREAKPOINTS_SCAN:
5808     # Look in all the files with breakpoints...
5809     for my $file ( keys %had_breakpoints ) {
5810
5811         # Temporary switch to this file.
5812         local *dbline = $main::{ '_<' . $file };
5813
5814         # Set up to look through the whole file.
5815         $max = $#dbline;
5816         my $was;    # Flag: did we print something
5817         # in this file?
5818
5819         # For each line in the file ...
5820         for my $i (1 .. $max) {
5821
5822             # We've got something on this line.
5823             if ( defined $dbline{$i} ) {
5824
5825                 # Print the header if we haven't.
5826                 if (not $was++) {
5827                     print {$OUT} "$file:\n";
5828                 }
5829
5830                 # Print the line.
5831                 print {$OUT} " $i:\t", $dbline[$i];
5832
5833                 $handle_db_line->($dbline{$i});
5834
5835                 # Quit if the user hit interrupt.
5836                 if ($signal) {
5837                     last BREAKPOINTS_SCAN;
5838                 }
5839             } ## end if (defined $dbline{$i...
5840         } ## end for my $i (1 .. $max)
5841     } ## end for my $file (keys %had_breakpoints)
5842
5843     return;
5844 }
5845
5846 sub _cmd_L_handle_postponed_breakpoints {
5847     my ($handle_db_line) = @_;
5848
5849     print {$OUT} "Postponed breakpoints in files:\n";
5850
5851     POSTPONED_SCANS:
5852     for my $file ( keys %postponed_file ) {
5853         my $db = $postponed_file{$file};
5854         print {$OUT} " $file:\n";
5855         for my $line ( sort { $a <=> $b } keys %$db ) {
5856             print {$OUT} "  $line:\n";
5857
5858             $handle_db_line->($db->{$line});
5859
5860             if ($signal) {
5861                 last POSTPONED_SCANS;
5862             }
5863         }
5864         if ($signal) {
5865             last POSTPONED_SCANS;
5866         }
5867     }
5868
5869     return;
5870 }
5871
5872
5873 sub cmd_L {
5874     my $cmd = shift;
5875
5876     my ($action_wanted, $break_wanted, $watch_wanted) =
5877         _cmd_L_calc_wanted_flags(shift);
5878
5879     my $handle_db_line = sub {
5880         my ($l) = @_;
5881
5882         my ( $stop, $action ) = split( /\0/, $l );
5883
5884         if ($stop and $break_wanted) {
5885             print {$OUT} "    break if (", $stop, ")\n"
5886         }
5887
5888         if ($action && $action_wanted) {
5889             print {$OUT} "    action:  ", $action, "\n"
5890         }
5891
5892         return;
5893     };
5894
5895     # Breaks and actions are found together, so we look in the same place
5896     # for both.
5897     if ( $break_wanted or $action_wanted ) {
5898         _cmd_L_handle_breakpoints($handle_db_line);
5899     }
5900
5901     # Look for breaks in not-yet-compiled subs:
5902     if ( %postponed and $break_wanted ) {
5903         print {$OUT} "Postponed breakpoints in subroutines:\n";
5904         my $subname;
5905         SUBS_SCAN:
5906         for $subname ( keys %postponed ) {
5907             print {$OUT} " $subname\t$postponed{$subname}\n";
5908             if ($signal) {
5909                 last SUBS_SCAN;
5910             }
5911         }
5912     } ## end if (%postponed and $break_wanted)
5913
5914     # Find files that have not-yet-loaded breaks:
5915     my @have = map {    # Combined keys
5916         keys %{ $postponed_file{$_} }
5917     } keys %postponed_file;
5918
5919     # If there are any, list them.
5920     if ( @have and ( $break_wanted or $action_wanted ) ) {
5921         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5922     } ## end if (@have and ($break_wanted...
5923
5924     if ( %break_on_load and $break_wanted ) {
5925         print {$OUT} "Breakpoints on load:\n";
5926         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5927             print {$OUT} " $filename\n";
5928             last BREAK_ON_LOAD if $signal;
5929         }
5930     } ## end if (%break_on_load and...
5931
5932     if ($watch_wanted and ( $trace & 2 )) {
5933         print {$OUT} "Watch-expressions:\n" if @to_watch;
5934         TO_WATCH: for my $expr (@to_watch) {
5935             print {$OUT} " $expr\n";
5936             last TO_WATCH if $signal;
5937         }
5938     }
5939
5940     return;
5941 } ## end sub cmd_L
5942
5943 =head3 C<cmd_M> - list modules (command)
5944
5945 Just call C<list_modules>.
5946
5947 =cut
5948
5949 sub cmd_M {
5950     list_modules();
5951
5952     return;
5953 }
5954
5955 =head3 C<cmd_o> - options (command)
5956
5957 If this is just C<o> by itself, we list the current settings via
5958 C<dump_option>. If there's a nonblank value following it, we pass that on to
5959 C<parse_options> for processing.
5960
5961 =cut
5962
5963 sub cmd_o {
5964     my $cmd = shift;
5965     my $opt = shift || '';    # opt[=val]
5966
5967     # Nonblank. Try to parse and process.
5968     if ( $opt =~ /^(\S.*)/ ) {
5969         parse_options($1);
5970     }
5971
5972     # Blank. List the current option settings.
5973     else {
5974         for (@options) {
5975             dump_option($_);
5976         }
5977     }
5978 } ## end sub cmd_o
5979
5980 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5981
5982 Advises the user that the O command has been renamed.
5983
5984 =cut
5985
5986 sub cmd_O {
5987     print $OUT "The old O command is now the o command.\n";             # hint
5988     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5989     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5990 }
5991
5992 =head3 C<cmd_v> - view window (command)
5993
5994 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5995 move back a few lines to list the selected line in context. Uses C<cmd_l>
5996 to do the actual listing after figuring out the range of line to request.
5997
5998 =cut
5999
6000 use vars qw($preview);
6001
6002 sub cmd_v {
6003     my $cmd  = shift;
6004     my $line = shift;
6005
6006     # Extract the line to list around. (Astute readers will have noted that
6007     # this pattern will match whether or not a numeric line is specified,
6008     # which means that we'll always enter this loop (though a non-numeric
6009     # argument results in no action at all)).
6010     if ( $line =~ /^(\d*)$/ ) {
6011
6012         # Total number of lines to list (a windowful).
6013         $incr = $window - 1;
6014
6015         # Set the start to the argument given (if there was one).
6016         $start = $1 if $1;
6017
6018         # Back up by the context amount.
6019         $start -= $preview;
6020
6021         # Put together a linespec that cmd_l will like.
6022         $line = $start . '-' . ( $start + $incr );
6023
6024         # List the lines.
6025         cmd_l( 'l', $line );
6026     } ## end if ($line =~ /^(\d*)$/)
6027 } ## end sub cmd_v
6028
6029 =head3 C<cmd_w> - add a watch expression (command)
6030
6031 The 5.8 version of this command adds a watch expression if one is specified;
6032 it does nothing if entered with no operands.
6033
6034 We extract the expression, save it, evaluate it in the user's context, and
6035 save the value. We'll re-evaluate it each time the debugger passes a line,
6036 and will stop (see the code at the top of the command loop) if the value
6037 of any of the expressions changes.
6038
6039 =cut
6040
6041 sub _add_watch_expr {
6042     my $expr = shift;
6043
6044     # ... save it.
6045     push @to_watch, $expr;
6046
6047     # Parameterize DB::eval and call it to get the expression's value
6048     # in the user's context. This version can handle expressions which
6049     # return a list value.
6050     $evalarg = $expr;
6051     # The &-call is here to ascertain the mutability of @_.
6052     my ($val) = join( ' ', &DB::eval);
6053     $val = ( defined $val ) ? "'$val'" : 'undef';
6054
6055     # Save the current value of the expression.
6056     push @old_watch, $val;
6057
6058     # We are now watching expressions.
6059     $trace |= 2;
6060
6061     return;
6062 }
6063
6064 sub cmd_w {
6065     my $cmd = shift;
6066
6067     # Null expression if no arguments.
6068     my $expr = shift || '';
6069
6070     # If expression is not null ...
6071     if ( $expr =~ /\A\S/ ) {
6072         _add_watch_expr($expr);
6073     } ## end if ($expr =~ /^(\S.*)/)
6074
6075     # You have to give one to get one.
6076     else {
6077         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6078     }
6079
6080     return;
6081 }
6082
6083 =head3 C<cmd_W> - delete watch expressions (command)
6084
6085 This command accepts either a watch expression to be removed from the list
6086 of watch expressions, or C<*> to delete them all.
6087
6088 If C<*> is specified, we simply empty the watch expression list and the
6089 watch expression value list. We also turn off the bit that says we've got
6090 watch expressions.
6091
6092 If an expression (or partial expression) is specified, we pattern-match
6093 through the expressions and remove the ones that match. We also discard
6094 the corresponding values. If no watch expressions are left, we turn off
6095 the I<watching expressions> bit.
6096
6097 =cut
6098
6099 sub cmd_W {
6100     my $cmd  = shift;
6101     my $expr = shift || '';
6102
6103     # Delete them all.
6104     if ( $expr eq '*' ) {
6105
6106         # Not watching now.
6107         $trace &= ~2;
6108
6109         print $OUT "Deleting all watch expressions ...\n";
6110
6111         # And all gone.
6112         @to_watch = @old_watch = ();
6113     }
6114
6115     # Delete one of them.
6116     elsif ( $expr =~ /^(\S.*)/ ) {
6117
6118         # Where we are in the list.
6119         my $i_cnt = 0;
6120
6121         # For each expression ...
6122         foreach (@to_watch) {
6123             my $val = $to_watch[$i_cnt];
6124
6125             # Does this one match the command argument?
6126             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6127                                       # Yes. Turn it off, and its value too.
6128                 splice( @to_watch,  $i_cnt, 1 );
6129                 splice( @old_watch, $i_cnt, 1 );
6130             }
6131             $i_cnt++;
6132         } ## end foreach (@to_watch)
6133
6134         # We don't bother to turn watching off because
6135         #  a) we don't want to stop calling watchfunction() if it exists
6136         #  b) foreach over a null list doesn't do anything anyway
6137
6138     } ## end elsif ($expr =~ /^(\S.*)/)
6139
6140     # No command arguments entered.
6141     else {
6142         print $OUT
6143           "Deleting a watch-expression requires an expression, or '*' for all\n"
6144           ;    # hint
6145     }
6146 } ## end sub cmd_W
6147
6148 ### END of the API section
6149
6150 =head1 SUPPORT ROUTINES
6151
6152 These are general support routines that are used in a number of places
6153 throughout the debugger.
6154
6155 =head2 save
6156
6157 save() saves the user's versions of globals that would mess us up in C<@saved>,
6158 and installs the versions we like better.
6159
6160 =cut
6161
6162 sub save {
6163
6164     # Save eval failure, command failure, extended OS error, output field
6165     # separator, input record separator, output record separator and
6166     # the warning setting.
6167     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6168
6169     $,  = "";      # output field separator is null string
6170     $/  = "\n";    # input record separator is newline
6171     $\  = "";      # output record separator is null string
6172     $^W = 0;       # warnings are off
6173 } ## end sub save
6174
6175 =head2 C<print_lineinfo> - show where we are now
6176
6177 print_lineinfo prints whatever it is that it is handed; it prints it to the
6178 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6179 us to feed line information to a slave editor without messing up the
6180 debugger output.
6181
6182 =cut
6183
6184 sub print_lineinfo {
6185
6186     # Make the terminal sensible if we're not the primary debugger.
6187     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6188     local $\ = '';
6189     local $, = '';
6190     # $LINEINFO may be undef if $noTTY is set or some other issue.
6191     if ($LINEINFO)
6192     {
6193         print {$LINEINFO} @_;
6194     }
6195 } ## end sub print_lineinfo
6196
6197 =head2 C<postponed_sub>
6198
6199 Handles setting postponed breakpoints in subroutines once they're compiled.
6200 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6201 range for the subroutine, then mark the file as having a breakpoint,
6202 temporarily switch the C<*dbline> glob over to the source file, and then
6203 search the given range of lines to find a breakable line. If we find one,
6204 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6205
6206 =cut
6207
6208 # The following takes its argument via $evalarg to preserve current @_
6209
6210 sub postponed_sub {
6211
6212     # Get the subroutine name.
6213     my $subname = shift;
6214
6215     # If this is a 'break +<n> if <condition>' ...
6216     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6217
6218         # If there's no offset, use '+0'.
6219         my $offset = $1 || 0;
6220
6221         # find_sub's value is 'fullpath-filename:start-stop'. It's
6222         # possible that the filename might have colons in it too.
6223         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6224         if ($i) {
6225
6226             # We got the start line. Add the offset '+<n>' from
6227             # $postponed{subname}.
6228             $i += $offset;
6229
6230             # Switch to the file this sub is in, temporarily.
6231             local *dbline = $main::{ '_<' . $file };
6232
6233             # No warnings, please.
6234             local $^W = 0;    # != 0 is magical below
6235
6236             # This file's got a breakpoint in it.
6237             $had_breakpoints{$file} |= 1;
6238
6239             # Last line in file.
6240             $max = $#dbline;
6241
6242             # Search forward until we hit a breakable line or get to
6243             # the end of the file.
6244             ++$i until $dbline[$i] != 0 or $i >= $max;
6245
6246             # Copy the breakpoint in and delete it from %postponed.
6247             $dbline{$i} = delete $postponed{$subname};
6248         } ## end if ($i)
6249
6250         # find_sub didn't find the sub.
6251         else {
6252             local $\ = '';
6253             print $OUT "Subroutine $subname not found.\n";
6254         }
6255         return;
6256     } ## end if ($postponed{$subname...
6257     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6258
6259     #print $OUT "In postponed_sub for '$subname'.\n";
6260 } ## end sub postponed_sub
6261
6262 =head2 C<postponed>
6263
6264 Called after each required file is compiled, but before it is executed;
6265 also called if the name of a just-compiled subroutine is a key of
6266 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6267 etc.) into the just-compiled code.
6268
6269 If this is a C<require>'d file, the incoming parameter is the glob
6270 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6271
6272 If it's a subroutine, the incoming parameter is the subroutine name.
6273
6274 =cut
6275
6276 sub postponed {
6277
6278     # If there's a break, process it.
6279     if ($ImmediateStop) {
6280
6281         # Right, we've stopped. Turn it off.
6282         $ImmediateStop = 0;
6283
6284         # Enter the command loop when DB::DB gets called.
6285         $signal = 1;
6286     }
6287
6288     # If this is a subroutine, let postponed_sub() deal with it.
6289     if (ref(\$_[0]) ne 'GLOB') {
6290         return postponed_sub(@_);
6291     }
6292
6293     # Not a subroutine. Deal with the file.
6294     local *dbline = shift;
6295     my $filename = $dbline;
6296     $filename =~ s/^_<//;
6297     local $\ = '';
6298     $signal = 1, print $OUT "'$filename' loaded...\n"
6299       if $break_on_load{$filename};
6300     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6301
6302     # Do we have any breakpoints to put in this file?
6303     return unless $postponed_file{$filename};
6304
6305     # Yes. Mark this file as having breakpoints.
6306     $had_breakpoints{$filename} |= 1;
6307
6308     # "Cannot be done: insufficient magic" - we can't just put the
6309     # breakpoints saved in %postponed_file into %dbline by assigning
6310     # the whole hash; we have to do it one item at a time for the
6311     # breakpoints to be set properly.
6312     #%dbline = %{$postponed_file{$filename}};
6313
6314     # Set the breakpoints, one at a time.
6315     my $key;
6316
6317     for $key ( keys %{ $postponed_file{$filename} } ) {
6318
6319         # Stash the saved breakpoint into the current file's magic line array.
6320         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6321     }
6322
6323     # This file's been compiled; discard the stored breakpoints.
6324     delete $postponed_file{$filename};
6325
6326 } ## end sub postponed
6327
6328 =head2 C<dumpit>
6329
6330 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6331
6332 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6333 a reference to a variable (the thing to be dumped) as its input.
6334
6335 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6336 the currently-selected filehandle, thank you very much). The current
6337 values of the package globals C<$single> and C<$trace> are backed up in
6338 lexicals, and they are turned off (this keeps the debugger from trying
6339 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6340 preserve its current value and it is set to zero to prevent entry/exit
6341 messages from printing, and C<$doret> is localized as well and set to -2 to
6342 prevent return values from being shown.
6343
6344 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6345 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6346 installed version in C<@INC>, yours will be used instead. Possible security
6347 problem?).
6348
6349 It then checks to see if the subroutine C<main::dumpValue> is now defined
6350 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6351 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6352 is called, and picks up the variable to be dumped from the parameter list.
6353
6354 It checks the package global C<%options> to see if there's a C<dumpDepth>
6355 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6356 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6357 structure: -1 means dump everything.
6358
6359 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6360 warning.
6361
6362 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6363 and we then return to the caller.
6364
6365 =cut
6366
6367 sub dumpit {
6368
6369     # Save the current output filehandle and switch to the one
6370     # passed in as the first parameter.
6371     my $savout = select(shift);
6372
6373     # Save current settings of $single and $trace, and then turn them off.
6374     my $osingle = $single;
6375     my $otrace  = $trace;
6376     $single = $trace = 0;
6377
6378     # XXX Okay, what do $frame and $doret do, again?
6379     local $frame = 0;
6380     local $doret = -2;
6381
6382     # Load dumpvar.pl unless we've already got the sub we need from it.
6383     unless ( defined &main::dumpValue ) {
6384         do 'dumpvar.pl' or die $@;
6385     }
6386
6387     # If the load succeeded (or we already had dumpvalue()), go ahead
6388     # and dump things.
6389     if ( defined &main::dumpValue ) {
6390         local $\ = '';
6391         local $, = '';
6392         local $" = ' ';
6393         my $v = shift;
6394         my $maxdepth = shift || $option{dumpDepth};
6395         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6396         main::dumpValue( $v, $maxdepth );
6397     } ## end if (defined &main::dumpValue)
6398
6399     # Oops, couldn't load dumpvar.pl.
6400     else {
6401         local $\ = '';
6402         print $OUT "dumpvar.pl not available.\n";
6403     }
6404
6405     # Reset $single and $trace to their old values.
6406     $single = $osingle;
6407     $trace  = $otrace;
6408
6409     # Restore the old filehandle.
6410     select($savout);
6411 } ## end sub dumpit
6412
6413 =head2 C<print_trace>
6414
6415 C<print_trace>'s job is to print a stack trace. It does this via the
6416 C<dump_trace> routine, which actually does all the ferreting-out of the
6417 stack trace data. C<print_trace> takes care of formatting it nicely and
6418 printing it to the proper filehandle.
6419
6420 Parameters:
6421
6422 =over 4
6423
6424 =item *
6425
6426 The filehandle to print to.
6427
6428 =item *
6429
6430 How many frames to skip before starting trace.
6431
6432 =item *
6433
6434 How many frames to print.
6435
6436 =item *
6437
6438 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6439
6440 =back
6441
6442 The original comment below seems to be noting that the traceback may not be
6443 correct if this routine is called in a tied method.
6444
6445 =cut
6446
6447 # Tied method do not create a context, so may get wrong message:
6448
6449 sub print_trace {
6450     local $\ = '';
6451     my $fh = shift;
6452
6453     # If this is going to a slave editor, but we're not the primary
6454     # debugger, reset it first.
6455     resetterm(1)
6456       if $fh        eq $LINEINFO    # slave editor
6457       and $LINEINFO eq $OUT         # normal output
6458       and $term_pid != $$;          # not the primary
6459
6460     # Collect the actual trace information to be formatted.
6461     # This is an array of hashes of subroutine call info.
6462     my @sub = dump_trace( $_[0] + 1, $_[1] );
6463
6464     # Grab the "short report" flag from @_.
6465     my $short = $_[2];              # Print short report, next one for sub name
6466
6467     # Run through the traceback info, format it, and print it.
6468     my $s;
6469     for my $i (0 .. $#sub) {
6470
6471         # Drop out if the user has lost interest and hit control-C.
6472         last if $signal;
6473
6474         # Set the separator so arrays print nice.
6475         local $" = ', ';
6476
6477         # Grab and stringify the arguments if they are there.
6478         my $args =
6479           defined $sub[$i]{args}
6480           ? "(@{ $sub[$i]{args} })"
6481           : '';
6482
6483         # Shorten them up if $maxtrace says they're too long.
6484         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6485           if length $args > $maxtrace;
6486
6487         # Get the file name.
6488         my $file = $sub[$i]{file};
6489
6490         # Put in a filename header if short is off.
6491         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6492
6493         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6494         $s = $sub[$i]{'sub'};
6495         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6496
6497         # Short report uses trimmed file and sub names.
6498         if ($short) {
6499             my $sub = @_ >= 4 ? $_[3] : $s;
6500             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6501         } ## end if ($short)
6502
6503         # Non-short report includes full names.
6504         else {
6505             print $fh "$sub[$i]{context} = $s$args"
6506               . " called from $file"
6507               . " line $sub[$i]{line}\n";
6508         }
6509     } ## end for my $i (0 .. $#sub)
6510 } ## end sub print_trace
6511
6512 =head2 dump_trace(skip[,count])
6513
6514 Actually collect the traceback information available via C<caller()>. It does
6515 some filtering and cleanup of the data, but mostly it just collects it to
6516 make C<print_trace()>'s job easier.
6517
6518 C<skip> defines the number of stack frames to be skipped, working backwards
6519 from the most current. C<count> determines the total number of frames to
6520 be returned; all of them (well, the first 10^9) are returned if C<count>
6521 is omitted.
6522
6523 This routine returns a list of hashes, from most-recent to least-recent
6524 stack frame. Each has the following keys and values:
6525
6526 =over 4
6527
6528 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6529
6530 =item * C<sub> - subroutine name, or C<eval> information
6531
6532 =item * C<args> - undef, or a reference to an array of arguments
6533
6534 =item * C<file> - the file in which this item was defined (if any)
6535
6536 =item * C<line> - the line on which it was defined
6537
6538 =back
6539
6540 =cut
6541
6542 sub _dump_trace_calc_saved_single_arg
6543 {
6544     my ($nothard, $arg) = @_;
6545
6546     my $type;
6547     if ( not defined $arg ) {    # undefined parameter
6548         return "undef";
6549     }
6550
6551     elsif ( $nothard and tied $arg ) {    # tied parameter
6552         return "tied";
6553     }
6554     elsif ( $nothard and $type = ref $arg ) {    # reference
6555         return "ref($type)";
6556     }
6557     else {                                       # can be stringified
6558         local $_ =
6559         "$arg";    # Safe to stringify now - should not call f().
6560
6561         # Backslash any single-quotes or backslashes.
6562         s/([\'\\])/\\$1/g;
6563
6564         # Single-quote it unless it's a number or a colon-separated
6565         # name.
6566         s/(.*)/'$1'/s
6567         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6568
6569         # Turn high-bit characters into meta-whatever, and controls into like
6570         # '^D'.
6571         require 'meta_notation.pm';
6572         $_ = _meta_notation($_) if /[[:^print:]]/a;
6573
6574         return $_;
6575     }
6576 }
6577
6578 sub _dump_trace_calc_save_args {
6579     my ($nothard) = @_;
6580
6581     return [
6582         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6583     ];
6584 }
6585
6586 sub dump_trace {
6587
6588     # How many levels to skip.
6589     my $skip = shift;
6590
6591     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6592     # it's unlikely that we'll have more than a billion stack frames. If you
6593     # do, you've got an awfully big machine...)
6594     my $count = shift || 1e9;
6595
6596     # We increment skip because caller(1) is the first level *back* from
6597     # the current one.  Add $skip to the count of frames so we have a
6598     # simple stop criterion, counting from $skip to $count+$skip.
6599     $skip++;
6600     $count += $skip;
6601
6602     # These variables are used to capture output from caller();
6603     my ( $p, $file, $line, $sub, $h, $context );
6604
6605     my ( $e, $r, @sub, $args );
6606
6607     # XXX Okay... why'd we do that?
6608     my $nothard = not $frame & 8;
6609     local $frame = 0;
6610
6611     # Do not want to trace this.
6612     my $otrace = $trace;
6613     $trace = 0;
6614
6615     # Start out at the skip count.
6616     # If we haven't reached the number of frames requested, and caller() is
6617     # still returning something, stay in the loop. (If we pass the requested
6618     # number of stack frames, or we run out - caller() returns nothing - we
6619     # quit.
6620     # Up the stack frame index to go back one more level each time.
6621     for (
6622         my $i = $skip ;
6623         $i < $count
6624         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6625         $i++
6626     )
6627     {
6628
6629         # Go through the arguments and save them for later.
6630         my $save_args = _dump_trace_calc_save_args($nothard);
6631
6632         # If context is true, this is array (@)context.
6633         # If context is false, this is scalar ($) context.
6634         # If neither, context isn't defined. (This is apparently a 'can't
6635         # happen' trap.)
6636         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6637
6638         # if the sub has args ($h true), make an anonymous array of the
6639         # dumped args.
6640         $args = $h ? $save_args : undef;
6641
6642         # remove trailing newline-whitespace-semicolon-end of line sequence
6643         # from the eval text, if any.
6644         $e =~ s/\n\s*\;\s*\Z// if $e;
6645
6646         # Escape backslashed single-quotes again if necessary.
6647         $e =~ s/([\\\'])/\\$1/g if $e;
6648
6649         # if the require flag is true, the eval text is from a require.
6650         if ($r) {
6651             $sub = "require '$e'";
6652         }
6653
6654         # if it's false, the eval text is really from an eval.
6655         elsif ( defined $r ) {
6656             $sub = "eval '$e'";
6657         }
6658
6659         # If the sub is '(eval)', this is a block eval, meaning we don't
6660         # know what the eval'ed text actually was.
6661         elsif ( $sub eq '(eval)' ) {
6662             $sub = "eval {...}";
6663         }
6664
6665         # Stick the collected information into @sub as an anonymous hash.
6666         push(
6667             @sub,
6668             {
6669                 context => $context,
6670                 sub     => $sub,
6671                 args    => $args,
6672                 file    => $file,
6673                 line    => $line
6674             }
6675         );
6676
6677         # Stop processing frames if the user hit control-C.
6678         last if $signal;
6679     } ## end for ($i = $skip ; $i < ...
6680
6681     # Restore the trace value again.
6682     $trace = $otrace;
6683     @sub;
6684 } ## end sub dump_trace
6685
6686 =head2 C<action()>
6687
6688 C<action()> takes input provided as the argument to an add-action command,
6689 either pre- or post-, and makes sure it's a complete command. It doesn't do
6690 any fancy parsing; it just keeps reading input until it gets a string
6691 without a trailing backslash.
6692
6693 =cut
6694
6695 sub action {
6696     my $action = shift;
6697
6698     while ( $action =~ s/\\$// ) {
6699
6700         # We have a backslash on the end. Read more.
6701         $action .= gets();
6702     } ## end while ($action =~ s/\\$//)
6703
6704     # Return the assembled action.
6705     $action;
6706 } ## end sub action
6707
6708 =head2 unbalanced
6709
6710 This routine mostly just packages up a regular expression to be used
6711 to check that the thing it's being matched against has properly-matched
6712 curly braces.
6713
6714 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6715 speeds things up by only creating the qr//'ed expression once; if it's
6716 already defined, we don't try to define it again. A speed hack.
6717
6718 =cut
6719
6720 use vars qw($balanced_brace_re);
6721
6722 sub unbalanced {
6723
6724     # I hate using globals!
6725     $balanced_brace_re ||= qr{
6726         ^ \{
6727              (?:
6728                  (?> [^{}] + )              # Non-parens without backtracking
6729                 |
6730                  (??{ $balanced_brace_re }) # Group with matching parens
6731               ) *
6732           \} $
6733    }x;
6734     return $_[0] !~ m/$balanced_brace_re/;
6735 } ## end sub unbalanced
6736
6737 =head2 C<gets()>
6738
6739 C<gets()> is a primitive (very primitive) routine to read continuations.
6740 It was devised for reading continuations for actions.
6741 it just reads more input with C<readline()> and returns it.
6742
6743 =cut
6744
6745 sub gets {
6746     return DB::readline("cont: ");
6747 }
6748
6749 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6750
6751 The C<system()> function assumes that it can just go ahead and use STDIN and
6752 STDOUT, but under the debugger, we want it to use the debugger's input and
6753 outout filehandles.
6754
6755 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6756 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6757 and then puts everything back again.
6758
6759 =cut
6760
6761 sub _db_system {
6762
6763     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6764     # some non-Unix systems can do system() but have problems with fork().
6765     open( SAVEIN,  "<&STDIN" )  || _db_warn("Can't save STDIN");
6766     open( SAVEOUT, ">&STDOUT" ) || _db_warn("Can't save STDOUT");
6767     open( STDIN,   "<&IN" )     || _db_warn("Can't redirect STDIN");
6768     open( STDOUT,  ">&OUT" )    || _db_warn("Can't redirect STDOUT");
6769
6770     # XXX: using csh or tcsh destroys sigint retvals!
6771     system(@_);
6772     open( STDIN,  "<&SAVEIN" )  || _db_warn("Can't restore STDIN");
6773     open( STDOUT, ">&SAVEOUT" ) || _db_warn("Can't restore STDOUT");
6774     close(SAVEIN);
6775     close(SAVEOUT);
6776
6777     # most of the $? crud was coping with broken cshisms
6778     if ( $? >> 8 ) {
6779         _db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6780     }
6781     elsif ($?) {
6782         _db_warn(
6783             "(Command died of SIG#",
6784             ( $? & 127 ),
6785             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6786             ")", "\n"
6787         );
6788     } ## end elsif ($?)
6789
6790     return $?;
6791
6792 } ## end sub system
6793
6794 *system = \&_db_system;
6795
6796 =head1 TTY MANAGEMENT
6797
6798 The subs here do some of the terminal management for multiple debuggers.
6799
6800 =head2 setterm
6801
6802 Top-level function called when we want to set up a new terminal for use
6803 by the debugger.
6804
6805 If the C<noTTY> debugger option was set, we'll either use the terminal
6806 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6807 to find one. If we're a forked debugger, we call C<resetterm> to try to
6808 get a whole new terminal if we can.
6809
6810 In either case, we set up the terminal next. If the C<ReadLine> option was
6811 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6812 the appropriate attributes. We then
6813
6814 =cut
6815
6816 use vars qw($ornaments);
6817 use vars qw($rl_attribs);
6818
6819 sub setterm {
6820
6821     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6822     local $frame = 0;
6823     local $doret = -2;
6824     require Term::ReadLine;
6825
6826     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6827     if ($notty) {
6828         if ($tty) {
6829             my ( $i, $o ) = split $tty, /,/;
6830             $o = $i unless defined $o;
6831             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6832             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6833             $IN  = \*IN;
6834             $OUT = \*OUT;
6835             _autoflush($OUT);
6836         } ## end if ($tty)
6837
6838         # We don't have a TTY - try to find one via Term::Rendezvous.
6839         else {
6840             require Term::Rendezvous;
6841
6842             # See if we have anything to pass to Term::Rendezvous.
6843             # Use $HOME/.perldbtty$$ if not.
6844             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6845
6846             # Rendezvous and get the filehandles.
6847             my $term_rv = Term::Rendezvous->new( $rv );
6848             $IN  = $term_rv->IN;
6849             $OUT = $term_rv->OUT;
6850         } ## end else [ if ($tty)
6851     } ## end if ($notty)
6852
6853     # We're a daughter debugger. Try to fork off another TTY.
6854     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6855         resetterm(2);
6856     }
6857
6858     # If we shouldn't use Term::ReadLine, don't.
6859     if ( !$rl ) {
6860         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6861     }
6862
6863     # We're using Term::ReadLine. Get all the attributes for this terminal.
6864     else {
6865         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6866
6867         $rl_attribs = $term->Attribs;
6868         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6869           if defined $rl_attribs->{basic_word_break_characters}
6870           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6871         $rl_attribs->{special_prefixes} = '$@&%';
6872         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6873         $rl_attribs->{completion_function} = \&db_complete;
6874     } ## end else [ if (!$rl)
6875
6876     # Set up the LINEINFO filehandle.
6877     $LINEINFO = $OUT     unless defined $LINEINFO;
6878     $lineinfo = $console unless defined $lineinfo;
6879
6880     $term->MinLine(2);
6881
6882     load_hist();
6883
6884     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6885         $term->SetHistory(@hist);
6886     }
6887
6888     # XXX Ornaments are turned on unconditionally, which is not
6889     # always a good thing.
6890     ornaments($ornaments) if defined $ornaments;
6891     $term_pid = $$;
6892 } ## end sub setterm
6893
6894 sub load_hist {
6895     $histfile //= option_val("HistFile", undef);
6896     return unless defined $histfile;
6897     open my $fh, "<", $histfile or return;
6898     local $/ = "\n";
6899     @hist = ();
6900     while (<$fh>) {
6901         chomp;
6902         push @hist, $_;
6903     }
6904     close $fh;
6905 }
6906
6907 sub save_hist {
6908     return unless defined $histfile;
6909     eval { require File::Path } or return;
6910     eval { require File::Basename } or return;
6911     File::Path::mkpath(File::Basename::dirname($histfile));
6912     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6913     $histsize //= option_val("HistSize",100);
6914     my @copy = grep { $_ ne '?' } @hist;
6915     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6916     for ($start .. $#copy) {
6917         print $fh "$copy[$_]\n";
6918     }
6919     close $fh or die "Could not write '$histfile': $!";
6920 }
6921
6922 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6923
6924 When the process being debugged forks, or the process invokes a command
6925 via C<system()> which starts a new debugger, we need to be able to get a new
6926 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6927 fight over the terminal, and you can never quite be sure who's going to get the
6928 input you're typing.
6929
6930 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6931 is tasked with doing all the necessary operating system mojo to get a new
6932 TTY (and probably another window) and to direct the new debugger to read and
6933 write there.
6934
6935 The debugger provides C<get_fork_TTY> functions which work for TCP
6936 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6937 supported. You are encouraged to write C<get_fork_TTY> functions which
6938 work for I<your> platform and contribute them.
6939
6940 =head3 C<socket_get_fork_TTY>
6941
6942 =cut
6943
6944 sub connect_remoteport {
6945     require IO::Socket;
6946
6947     my $socket = IO::Socket::INET->new(
6948         Timeout  => '10',
6949         PeerAddr => $remoteport,
6950         Proto    => 'tcp',
6951     );
6952     if ( ! $socket ) {
6953         die "Unable to connect to remote host: $remoteport\n";
6954     }
6955     return $socket;
6956 }
6957
6958 sub socket_get_fork_TTY {
6959     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6960
6961     # Do I need to worry about setting $term?
6962
6963     reset_IN_OUT( $IN, $OUT );
6964     return '';
6965 }
6966
6967 =head3 C<xterm_get_fork_TTY>
6968
6969 This function provides the C<get_fork_TTY> function for X11. If a
6970 program running under the debugger forks, a new <xterm> window is opened and
6971 the subsidiary debugger is directed there.
6972
6973 The C<open()> call is of particular note here. We have the new C<xterm>
6974 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6975 command (which prints the device name of the TTY we'll want to use for input
6976 and output to STDOUT, then C<sleep> for a very long time, routing this output
6977 to file number 3. This way we can simply read from the <XT> filehandle (which
6978 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6979
6980 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6981 properly set up.
6982
6983 =cut
6984
6985 sub xterm_get_fork_TTY {
6986     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6987     open XT,
6988 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6989  sleep 10000000' |];
6990
6991     # Get the output from 'tty' and clean it up a little.
6992     my $tty = <XT>;
6993     chomp $tty;
6994
6995     $pidprompt = '';    # Shown anyway in titlebar
6996
6997     # We need $term defined or we can not switch to the newly created xterm
6998     if ($tty ne '' && !defined $term) {
6999         require Term::ReadLine;
7000         if ( !$rl ) {
7001             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7002         }
7003         else {
7004             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7005         }
7006     }
7007     # There's our new TTY.
7008     return $tty;
7009 } ## end sub xterm_get_fork_TTY
7010
7011 =head3 C<os2_get_fork_TTY>
7012
7013 XXX It behooves an OS/2 expert to write the necessary documentation for this!
7014
7015 =cut
7016
7017 # This example function resets $IN, $OUT itself
7018 my $c_pipe = 0;
7019 sub os2_get_fork_TTY { # A simplification of the following (and works without):
7020     local $\  = '';
7021     ( my $name = $0 ) =~ s,^.*[/\\],,s;
7022     my %opt = ( title => "Daughter Perl debugger $pids $name",
7023         ($rl ? (read_by_key => 1) : ()) );
7024     require OS2::Process;
7025     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
7026       or return;
7027     $pidprompt = '';    # Shown anyway in titlebar
7028     reset_IN_OUT($in, $out);
7029     $tty = '*reset*';
7030     return '';          # Indicate that reset_IN_OUT is called
7031 } ## end sub os2_get_fork_TTY
7032
7033 =head3 C<macosx_get_fork_TTY>
7034
7035 The Mac OS X version uses AppleScript to tell Terminal.app to create
7036 a new window.
7037
7038 =cut
7039
7040 # Notes about Terminal.app's AppleScript support,
7041 # (aka things that might break in future OS versions).
7042 #
7043 # The "do script" command doesn't return a reference to the new window
7044 # it creates, but since it appears frontmost and windows are enumerated
7045 # front to back, we can use "first window" === "window 1".
7046 #
7047 # Since "do script" is implemented by supplying the argument (plus a
7048 # return character) as terminal input, there's a potential race condition
7049 # where the debugger could beat the shell to reading the command.
7050 # To prevent this, we wait for the screen to clear before proceeding.
7051 #
7052 # 10.3 and 10.4:
7053 # There's no direct accessor for the tty device name, so we fiddle
7054 # with the window title options until it says what we want.
7055 #
7056 # 10.5:
7057 # There _is_ a direct accessor for the tty device name, _and_ there's
7058 # a new possible component of the window title (the name of the settings
7059 # set).  A separate version is needed.
7060
7061 my @script_versions=
7062
7063     ([237, <<'__LEOPARD__'],
7064 tell application "Terminal"
7065     do script "clear;exec sleep 100000"
7066     tell first tab of first window
7067         copy tty to thetty
7068         set custom title to "forked perl debugger"
7069         set title displays custom title to true
7070         repeat while (length of first paragraph of (get contents)) > 0
7071             delay 0.1
7072         end repeat
7073     end tell
7074 end tell
7075 thetty
7076 __LEOPARD__
7077
7078      [100, <<'__JAGUAR_TIGER__'],
7079 tell application "Terminal"
7080     do script "clear;exec sleep 100000"
7081     tell first window
7082         set title displays shell path to false
7083         set title displays window size to false
7084         set title displays file name to false
7085         set title displays device name to true
7086         set title displays custom title to true
7087         set custom title to ""
7088         copy "/dev/" & name to thetty
7089         set custom title to "forked perl debugger"
7090         repeat while (length of first paragraph of (get contents)) > 0
7091             delay 0.1
7092         end repeat
7093     end tell
7094 end tell
7095 thetty
7096 __JAGUAR_TIGER__
7097
7098 );
7099
7100 sub macosx_get_fork_TTY
7101 {
7102     my($version,$script,$pipe,$tty);
7103
7104     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7105     foreach my $entry (@script_versions) {
7106         if ($version>=$entry->[0]) {
7107             $script=$entry->[1];
7108             last;
7109         }
7110     }
7111     return unless defined($script);
7112     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7113     $tty=readline($pipe);
7114     close($pipe);
7115     return unless defined($tty) && $tty =~ m(^/dev/);
7116     chomp $tty;
7117     return $tty;
7118 }
7119
7120 =head3 C<tmux_get_fork_TTY>
7121
7122 Creates a split window for subprocesses when a process running under the
7123 perl debugger in Tmux forks.
7124
7125 =cut
7126
7127 sub tmux_get_fork_TTY {
7128     return unless $ENV{TMUX};
7129
7130     my $pipe;
7131
7132     my $status = open $pipe, '-|', 'tmux', 'split-window',
7133         '-P', '-F', '#{pane_tty}', 'sleep 100000';
7134
7135     if ( !$status ) {
7136         return;
7137     }
7138
7139     my $tty = <$pipe>;
7140     close $pipe;
7141
7142     if ( $tty ) {
7143         chomp $tty;
7144
7145         if ( !defined $term ) {
7146             require Term::ReadLine;
7147             if ( !$rl ) {
7148                 $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7149             }
7150             else {
7151                 $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7152             }
7153         }
7154     }
7155
7156     return $tty;
7157 }
7158
7159 =head2 C<create_IN_OUT($flags)>
7160
7161 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7162 try to diagnose why.
7163
7164 Flags are:
7165
7166 =over 4
7167
7168 =item * 1 - Don't know how to create a new TTY.
7169
7170 =item * 2 - Debugger has forked, but we can't get a new TTY.
7171
7172 =item * 4 - standard debugger startup is happening.
7173
7174 =back
7175
7176 =cut
7177
7178 use vars qw($fork_TTY);
7179
7180 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7181
7182     # If we know how to get a new TTY, do it! $in will have
7183     # the TTY name if get_fork_TTY works.
7184     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7185
7186     # It used to be that
7187     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7188
7189     if ( not defined $in ) {
7190         my $why = shift;
7191
7192         # We don't know how.
7193         print_help(<<EOP) if $why == 1;
7194 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7195 EOP
7196
7197         # Forked debugger.
7198         print_help(<<EOP) if $why == 2;
7199 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7200   This may be an asynchronous session, so the parent debugger may be active.
7201 EOP
7202
7203         # Note that both debuggers are fighting over the same input.
7204         print_help(<<EOP) if $why != 4;
7205   Since two debuggers fight for the same TTY, input is severely entangled.
7206
7207 EOP
7208         print_help(<<EOP);
7209   I know how to switch the output to a different window in xterms, OS/2
7210   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7211   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7212   B<DB::get_fork_TTY()> returning this.
7213
7214   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7215   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7216
7217 EOP
7218     } ## end if (not defined $in)
7219     elsif ( $in ne '' ) {
7220         TTY($in);
7221     }
7222     else {
7223         $console = '';    # Indicate no need to open-from-the-console
7224     }
7225     undef $fork_TTY;
7226 } ## end sub create_IN_OUT
7227
7228 =head2 C<resetterm>
7229
7230 Handles rejiggering the prompt when we've forked off a new debugger.
7231
7232 If the new debugger happened because of a C<system()> that invoked a
7233 program under the debugger, the arrow between the old pid and the new
7234 in the prompt has I<two> dashes instead of one.
7235
7236 We take the current list of pids and add this one to the end. If there
7237 isn't any list yet, we make one up out of the initial pid associated with
7238 the terminal and our new pid, sticking an arrow (either one-dashed or
7239 two dashed) in between them.
7240
7241 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7242 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7243 and try to do that.
7244
7245 =cut
7246
7247 sub resetterm {    # We forked, so we need a different TTY
7248
7249     # Needs to be passed to create_IN_OUT() as well.
7250     my $in = shift;
7251
7252     # resetterm(2): got in here because of a system() starting a debugger.
7253     # resetterm(1): just forked.
7254     my $systemed = $in > 1 ? '-' : '';
7255
7256     # If there's already a list of pids, add this to the end.
7257     if ($pids) {
7258         $pids =~ s/\]/$systemed->$$]/;
7259     }
7260
7261     # No pid list. Time to make one.
7262     else {
7263         $pids = "[$term_pid->$$]";
7264     }
7265
7266     # The prompt we're going to be using for this debugger.
7267     $pidprompt = $pids;
7268
7269     # We now 0wnz this terminal.
7270     $term_pid = $$;
7271
7272     # Just return if we're not supposed to try to create a new TTY.
7273     return unless $CreateTTY & $in;
7274
7275     # Try to create a new IN/OUT pair.
7276     create_IN_OUT($in);
7277 } ## end sub resetterm
7278
7279 =head2 C<readline>
7280
7281 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7282 the next line, print a message saying we got it, add it to the terminal
7283 history (if possible), and return it.
7284
7285 If there's nothing in the typeahead buffer, check the command filehandle stack.
7286 If there are any filehandles there, read from the last one, and return the line
7287 if we got one. If not, we pop the filehandle off and close it, and try the
7288 next one up the stack.
7289
7290 If we've emptied the filehandle stack, we check to see if we've got a socket
7291 open, and we read that and return it if we do. If we don't, we just call the
7292 core C<readline()> and return its value.
7293
7294 =cut
7295
7296 sub readline {
7297
7298     # Localize to prevent it from being smashed in the program being debugged.
7299     local $.;
7300
7301     # If there are stacked filehandles to read from ...
7302     # (Handle it before the typeahead, because we may call source/etc. from
7303     # the typeahead.)
7304     while (@cmdfhs) {
7305
7306         # Read from the last one in the stack.
7307         my $line = CORE::readline( $cmdfhs[-1] );
7308
7309         # If we got a line ...
7310         defined $line
7311           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7312           : close pop @cmdfhs;                            # Pop and close
7313     } ## end while (@cmdfhs)
7314
7315     # Pull a line out of the typeahead if there's stuff there.
7316     if (@typeahead) {
7317
7318         # How many lines left.
7319         my $left = @typeahead;
7320
7321         # Get the next line.
7322         my $got = shift @typeahead;
7323
7324         # Print a message saying we got input from the typeahead.
7325         local $\ = '';
7326         print $OUT "auto(-$left)", shift, $got, "\n";
7327
7328         # Add it to the terminal history (if possible).
7329         $term->AddHistory($got)
7330           if length($got) > 1
7331           and defined $term->Features->{addHistory};
7332         return $got;
7333     } ## end if (@typeahead)
7334
7335     # We really need to read some input. Turn off entry/exit trace and
7336     # return value printing.
7337     local $frame = 0;
7338     local $doret = -2;
7339
7340     # Nothing on the filehandle stack. Socket?
7341     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7342
7343         # Send anything we have to send.
7344         $OUT->write( join( '', @_ ) );
7345
7346         # Receive anything there is to receive.
7347         my $stuff = '';
7348         my $buf;
7349         my $first_time = 1;
7350
7351         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7352         {
7353             $first_time = 0;
7354             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7355                                             # XXX Don't know. You tell me.
7356         }
7357
7358         # What we got.
7359         return $stuff;
7360     } ## end if (ref $OUT and UNIVERSAL::isa...
7361
7362     # No socket. Just read from the terminal.
7363     else {
7364         return $term->readline(@_);
7365     }
7366 } ## end sub readline
7367
7368 =head1 OPTIONS SUPPORT ROUTINES
7369
7370 These routines handle listing and setting option values.
7371
7372 =head2 C<dump_option> - list the current value of an option setting
7373
7374 This routine uses C<option_val> to look up the value for an option.
7375 It cleans up escaped single-quotes and then displays the option and
7376 its value.
7377
7378 =cut
7379
7380 sub dump_option {
7381     my ( $opt, $val ) = @_;
7382     $val = option_val( $opt, 'N/A' );
7383     $val =~ s/([\\\'])/\\$1/g;
7384     printf $OUT "%20s = '%s'\n", $opt, $val;
7385 } ## end sub dump_option
7386
7387 sub options2remember {
7388     foreach my $k (@RememberOnROptions) {
7389         $option{$k} = option_val( $k, 'N/A' );
7390     }
7391     return %option;
7392 }
7393
7394 =head2 C<option_val> - find the current value of an option
7395
7396 This can't just be a simple hash lookup because of the indirect way that
7397 the option values are stored. Some are retrieved by calling a subroutine,
7398 some are just variables.
7399
7400 You must supply a default value to be used in case the option isn't set.
7401
7402 =cut
7403
7404 sub option_val {
7405     my ( $opt, $default ) = @_;
7406     my $val;
7407
7408     # Does this option exist, and is it a variable?
7409     # If so, retrieve the value via the value in %optionVars.
7410     if (    defined $optionVars{$opt}
7411         and defined ${ $optionVars{$opt} } )
7412     {
7413         $val = ${ $optionVars{$opt} };
7414     }
7415
7416     # Does this option exist, and it's a subroutine?
7417     # If so, call the subroutine via the ref in %optionAction
7418     # and capture the value.
7419     elsif ( defined $optionAction{$opt}
7420         and defined &{ $optionAction{$opt} } )
7421     {
7422         $val = &{ $optionAction{$opt} }();
7423     }
7424
7425     # If there's an action or variable for the supplied option,
7426     # but no value was set, use the default.
7427     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7428         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7429     {
7430         $val = $default;
7431     }
7432
7433     # Otherwise, do the simple hash lookup.
7434     else {
7435         $val = $option{$opt};
7436     }
7437
7438     # If the value isn't defined, use the default.
7439     # Then return whatever the value is.
7440     $val = $default unless defined $val;
7441     $val;
7442 } ## end sub option_val
7443
7444 =head2 C<parse_options>
7445
7446 Handles the parsing and execution of option setting/displaying commands.
7447
7448 An option entered by itself is assumed to be I<set me to 1> (the default value)
7449 if the option is a boolean one. If not, the user is prompted to enter a valid
7450 value or to query the current value (via C<option? >).
7451
7452 If C<option=value> is entered, we try to extract a quoted string from the
7453 value (if it is quoted). If it's not, we just use the whole value as-is.
7454
7455 We load any modules required to service this option, and then we set it: if
7456 it just gets stuck in a variable, we do that; if there's a subroutine to
7457 handle setting the option, we call that.
7458
7459 Finally, if we're running in interactive mode, we display the effect of the
7460 user's command back to the terminal, skipping this if we're setting things
7461 during initialization.
7462
7463 =cut
7464
7465 sub parse_options {
7466     my ($s) = @_;
7467     local $\ = '';
7468
7469     my $option;
7470
7471     # These options need a value. Don't allow them to be clobbered by accident.
7472     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7473       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7474       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7475     };
7476
7477     while (length($s)) {
7478         my $val_defaulted;
7479
7480         # Clean off excess leading whitespace.
7481         $s =~ s/^\s+// && next;
7482
7483         # Options are always all word characters, followed by a non-word
7484         # separator.
7485         if ($s !~ s/^(\w+)(\W?)//) {
7486             print {$OUT} "Invalid option '$s'\n";
7487             last;
7488         }
7489         my ( $opt, $sep ) = ( $1, $2 );
7490
7491         # Make sure that such an option exists.
7492         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7493           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7494
7495         unless ($matches) {
7496             print {$OUT} "Unknown option '$opt'\n";
7497             next;
7498         }
7499         if ($matches > 1) {
7500             print {$OUT} "Ambiguous option '$opt'\n";
7501             next;
7502         }
7503         my $val;
7504
7505         # '?' as separator means query, but must have whitespace after it.
7506         if ( "?" eq $sep ) {
7507             if ($s =~ /\A\S/) {
7508                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7509
7510                 last;
7511             }
7512
7513             #&dump_option($opt);
7514         } ## end if ("?" eq $sep)
7515
7516         # Separator is whitespace (or just a carriage return).
7517         # They're going for a default, which we assume is 1.
7518         elsif ( $sep !~ /\S/ ) {
7519             $val_defaulted = 1;
7520             $val           = "1";   #  this is an evil default; make 'em set it!
7521         }
7522
7523         # Separator is =. Trying to set a value.
7524         elsif ( $sep eq "=" ) {
7525
7526             # If quoted, extract a quoted string.
7527             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7528                 my $quote = $1;
7529                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7530             }
7531
7532             # Not quoted. Use the whole thing. Warn about 'option='.
7533             else {
7534                 $s =~ s/^(\S*)//;
7535                 $val = $1;
7536                 print OUT qq(Option better cleared using $opt=""\n)
7537                   unless length $val;
7538             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7539
7540         } ## end elsif ($sep eq "=")
7541
7542         # "Quoted" with [], <>, or {}.
7543         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7544             my ($end) =
7545               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7546             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7547               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7548             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7549         } ## end else [ if ("?" eq $sep)
7550
7551         # Exclude non-booleans from getting set to 1 by default.
7552         if ( $opt_needs_val{$option} && $val_defaulted ) {
7553             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7554             print {$OUT}
7555 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7556             next;
7557         } ## end if ($opt_needs_val{$option...
7558
7559         # Save the option value.
7560         $option{$option} = $val if defined $val;
7561
7562         # Load any module that this option requires.
7563         if ( defined($optionRequire{$option}) && defined($val) ) {
7564             eval qq{
7565             local \$frame = 0;
7566             local \$doret = -2;
7567             require '$optionRequire{$option}';
7568             1;
7569             } || die $@   # XXX: shouldn't happen
7570         }
7571
7572         # Set it.
7573         # Stick it in the proper variable if it goes in a variable.
7574         if (defined($optionVars{$option}) && defined($val)) {
7575             ${ $optionVars{$option} } = $val;
7576         }
7577
7578         # Call the appropriate sub if it gets set via sub.
7579         if (defined($optionAction{$option})
7580           && defined (&{ $optionAction{$option} })
7581           && defined ($val))
7582         {
7583           &{ $optionAction{$option} }($val);
7584         }
7585
7586         # Not initialization - echo the value we set it to.
7587         dump_option($option) if ($OUT ne \*STDERR);
7588     } ## end while (length)
7589 } ## end sub parse_options
7590
7591 =head1 RESTART SUPPORT
7592
7593 These routines are used to store (and restore) lists of items in environment
7594 variables during a restart.
7595
7596 =head2 set_list
7597
7598 Set_list packages up items to be stored in a set of environment variables
7599 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7600 the values). Values outside the standard ASCII charset are stored by encoding
7601 them as hexadecimal values.
7602
7603 =cut
7604
7605 sub set_list {
7606     my ( $stem, @list ) = @_;
7607     my $val;
7608
7609     # VAR_n: how many we have. Scalar assignment gets the number of items.
7610     $ENV{"${stem}_n"} = @list;
7611
7612     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7613     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7614     for my $i ( 0 .. $#list ) {
7615         $val = $list[$i];
7616         $val =~ s/\\/\\\\/g;
7617         no warnings 'experimental::regex_sets';
7618         $val =~ s/ ( (?[ [\000-\xFF] & [:^print:] ]) ) /
7619                                                 "\\0x" . unpack('H2',$1)/xaeg;
7620         $ENV{"${stem}_$i"} = $val;
7621     } ## end for $i (0 .. $#list)
7622 } ## end sub set_list
7623
7624 =head2 get_list
7625
7626 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7627 back, and then pull VAR_0, VAR_1. etc. back out.
7628
7629 =cut
7630
7631 sub get_list {
7632     my $stem = shift;
7633     my @list;
7634     my $n = delete $ENV{"${stem}_n"};
7635     my $val;
7636     for my $i ( 0 .. $n - 1 ) {
7637         $val = delete $ENV{"${stem}_$i"};
7638         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7639         push @list, $val;
7640     }
7641     @list;
7642 } ## end sub get_list
7643
7644 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7645
7646 =head2 catch()
7647
7648 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7649 set an already-existing global scalar variable to a constant value. This
7650 avoids allocating any memory possibly in the middle of something that will
7651 get all confused if we do, particularly under I<unsafe signals>.
7652
7653 =cut
7654
7655 sub catch {
7656     $signal = 1;
7657     return;    # Put nothing on the stack - malloc/free land!
7658 }
7659
7660 =head2 C<warn()>
7661
7662 C<warn> emits a warning, by joining together its arguments and printing
7663 them, with couple of fillips.
7664
7665 If the composited message I<doesn't> end with a newline, we automatically
7666 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7667 to be set to the filehandle to be used to output warnings; it makes no
7668 assumptions about what filehandles are available.
7669
7670 =cut
7671
7672 sub _db_warn {
7673     my ($msg) = join( "", @_ );
7674     $msg .= ": $!\n" unless $msg =~ /\n$/;
7675     local $\ = '';
7676     print $OUT $msg;
7677 } ## end sub warn
7678
7679 *warn = \&_db_warn;
7680
7681 =head1 INITIALIZATION TTY SUPPORT
7682
7683 =head2 C<reset_IN_OUT>
7684
7685 This routine handles restoring the debugger's input and output filehandles
7686 after we've tried and failed to move them elsewhere.  In addition, it assigns
7687 the debugger's output filehandle to $LINEINFO if it was already open there.
7688
7689 =cut
7690
7691 sub reset_IN_OUT {
7692     my $switch_li = $LINEINFO eq $OUT;
7693
7694     # If there's a term and it's able to get a new tty, try to get one.
7695     if ( $term and $term->Features->{newTTY} ) {
7696         ( $IN, $OUT ) = ( shift, shift );
7697         $term->newTTY( $IN, $OUT );
7698     }
7699
7700     # This term can't get a new tty now. Better luck later.
7701     elsif ($term) {
7702         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7703     }
7704
7705     # Set the filehndles up as they were.
7706     else {
7707         ( $IN, $OUT ) = ( shift, shift );
7708     }
7709
7710     # Unbuffer the output filehandle.
7711     _autoflush($OUT);
7712
7713     # Point LINEINFO to the same output filehandle if it was there before.
7714     $LINEINFO = $OUT if $switch_li;
7715 } ## end sub reset_IN_OUT
7716
7717 =head1 OPTION SUPPORT ROUTINES
7718
7719 The following routines are used to process some of the more complicated
7720 debugger options.
7721
7722 =head2 C<TTY>
7723
7724 Sets the input and output filehandles to the specified files or pipes.
7725 If the terminal supports switching, we go ahead and do it. If not, and
7726 there's already a terminal in place, we save the information to take effect
7727 on restart.
7728
7729 If there's no terminal yet (for instance, during debugger initialization),
7730 we go ahead and set C<$console> and C<$tty> to the file indicated.
7731
7732 =cut
7733
7734 sub TTY {
7735
7736     if ( @_ and $term and $term->Features->{newTTY} ) {
7737
7738         # This terminal supports switching to a new TTY.
7739         # Can be a list of two files, or on string containing both names,
7740         # comma-separated.
7741         # XXX Should this perhaps be an assignment from @_?
7742         my ( $in, $out ) = shift;
7743         if ( $in =~ /,/ ) {
7744
7745             # Split list apart if supplied.
7746             ( $in, $out ) = split /,/, $in, 2;
7747         }
7748         else {
7749
7750             # Use the same file for both input and output.
7751             $out = $in;
7752         }
7753
7754         # Open file onto the debugger's filehandles, if you can.
7755         open IN,  $in     or die "cannot open '$in' for read: $!";
7756         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7757
7758         # Swap to the new filehandles.
7759         reset_IN_OUT( \*IN, \*OUT );
7760
7761         # Save the setting for later.
7762         return $tty = $in;
7763     } ## end if (@_ and $term and $term...
7764
7765     # Terminal doesn't support new TTY, or doesn't support readline.
7766     # Can't do it now, try restarting.
7767     if ($term and @_) {
7768         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7769     }
7770
7771     # Useful if done through PERLDB_OPTS:
7772     $console = $tty = shift if @_;
7773
7774     # Return whatever the TTY is.
7775     $tty or $console;
7776 } ## end sub TTY
7777
7778 =head2 C<noTTY>
7779
7780 Sets the C<$notty> global, controlling whether or not the debugger tries to
7781 get a terminal to read from. If called after a terminal is already in place,
7782 we save the value to use it if we're restarted.
7783
7784 =cut
7785
7786 sub noTTY {
7787     if ($term) {
7788         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7789     }
7790     $notty = shift if @_;
7791     $notty;
7792 } ## end sub noTTY
7793
7794 =head2 C<ReadLine>
7795
7796 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7797 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7798 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7799 the value in case a restart is done so we can change it then.
7800
7801 =cut
7802
7803 sub ReadLine {
7804     if ($term) {
7805         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7806     }
7807     $rl = shift if @_;
7808     $rl;
7809 } ## end sub ReadLine
7810
7811 =head2 C<RemotePort>
7812
7813 Sets the port that the debugger will try to connect to when starting up.
7814 If the terminal's already been set up, we can't do it, but we remember the
7815 setting in case the user does a restart.
7816
7817 =cut
7818
7819 sub RemotePort {
7820     if ($term) {
7821         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7822     }
7823     $remoteport = shift if @_;
7824     $remoteport;
7825 } ## end sub RemotePort
7826
7827 =head2 C<tkRunning>
7828
7829 Checks with the terminal to see if C<Tk> is running, and returns true or
7830 false. Returns false if the current terminal doesn't support C<readline>.
7831
7832 =cut
7833
7834 sub tkRunning {
7835     if ( ${ $term->Features }{tkRunning} ) {
7836         return $term->tkRunning(@_);
7837     }
7838     else {
7839         local $\ = '';
7840         print $OUT "tkRunning not supported by current ReadLine package.\n";
7841         0;
7842     }
7843 } ## end sub tkRunning
7844
7845 =head2 C<NonStop>
7846
7847 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7848 debugger remembers the setting in case you restart, though.
7849
7850 =cut
7851
7852 sub NonStop {
7853     if ($term) {
7854         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7855           if @_;
7856     }
7857     $runnonstop = shift if @_;
7858     $runnonstop;
7859 } ## end sub NonStop
7860
7861 sub DollarCaretP {
7862     if ($term) {
7863         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7864           if @_;
7865     }
7866     $^P = parse_DollarCaretP_flags(shift) if @_;
7867     expand_DollarCaretP_flags($^P);
7868 }
7869
7870 =head2 C<pager>
7871
7872 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7873 there already.
7874
7875 =cut
7876
7877 sub pager {
7878     if (@_) {
7879         $pager = shift;
7880         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7881     }
7882     $pager;
7883 } ## end sub pager
7884
7885 =head2 C<shellBang>
7886
7887 Sets the shell escape command, and generates a printable copy to be used
7888 in the help.
7889
7890 =cut
7891
7892 sub shellBang {
7893
7894     # If we got an argument, meta-quote it, and add '\b' if it
7895     # ends in a word character.
7896     if (@_) {
7897         $sh = quotemeta shift;
7898         $sh .= "\\b" if $sh =~ /\w$/;
7899     }
7900
7901     # Generate the printable version for the help:
7902     $psh = $sh;    # copy it
7903     $psh =~ s/\\b$//;        # Take off trailing \b if any
7904     $psh =~ s/\\(.)/$1/g;    # De-escape
7905     $psh;                    # return the printable version
7906 } ## end sub shellBang
7907
7908 =head2 C<ornaments>
7909
7910 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7911 was passed as the argument. (This means you can't override the terminal's
7912 ornaments.)
7913
7914 =cut
7915
7916 sub ornaments {
7917     if ( defined $term ) {
7918
7919         # We don't want to show warning backtraces, but we do want die() ones.
7920         local $warnLevel = 0;
7921         local $dieLevel = 1;
7922
7923         # No ornaments if the terminal doesn't support them.
7924         if (not $term->Features->{ornaments}) {
7925             return '';
7926         }
7927
7928         return (eval { $term->ornaments(@_) } || '');
7929     }
7930
7931     # Use what was passed in if we can't determine it ourselves.
7932     else {
7933         $ornaments = shift;
7934
7935         return $ornaments;
7936     }
7937
7938 } ## end sub ornaments
7939
7940 =head2 C<recallCommand>
7941
7942 Sets the recall command, and builds a printable version which will appear in
7943 the help text.
7944
7945 =cut
7946
7947 sub recallCommand {
7948
7949     # If there is input, metaquote it. Add '\b' if it ends with a word
7950     # character.
7951     if (@_) {
7952         $rc = quotemeta shift;
7953         $rc .= "\\b" if $rc =~ /\w$/;
7954     }
7955
7956     # Build it into a printable version.
7957     $prc = $rc;              # Copy it
7958     $prc =~ s/\\b$//;        # Remove trailing \b
7959     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7960     return $prc;             # Return the printable version
7961 } ## end sub recallCommand
7962
7963 =head2 C<LineInfo> - where the line number information goes
7964
7965 Called with no arguments, returns the file or pipe that line info should go to.
7966
7967 Called with an argument (a file or a pipe), it opens that onto the
7968 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7969 file or pipe again to the caller.
7970
7971 =cut
7972
7973 sub LineInfo {
7974     if (@_) {
7975         $lineinfo = shift;
7976
7977         #  If this is a valid "thing to be opened for output", tack a
7978         # '>' onto the front.
7979         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7980
7981         # If this is a pipe, the stream points to a slave editor.
7982         $slave_editor = ( $stream =~ /^\|/ );
7983
7984         my $new_lineinfo_fh;
7985         # Open it up and unbuffer it.
7986         open ($new_lineinfo_fh , $stream )
7987             or _db_warn("Cannot open '$stream' for write");
7988         $LINEINFO = $new_lineinfo_fh;
7989         _autoflush($LINEINFO);
7990     }
7991
7992     return $lineinfo;
7993 } ## end sub LineInfo
7994
7995 =head1 COMMAND SUPPORT ROUTINES
7996
7997 These subroutines provide functionality for various commands.
7998
7999 =head2 C<list_modules>
8000
8001 For the C<M> command: list modules loaded and their versions.
8002 Essentially just runs through the keys in %INC, picks each package's
8003 C<$VERSION> variable, gets the file name, and formats the information
8004 for output.
8005
8006 =cut
8007
8008 sub list_modules {    # versions
8009     my %version;
8010     my $file;
8011
8012     # keys are the "as-loaded" name, values are the fully-qualified path
8013     # to the file itself.
8014     for ( keys %INC ) {
8015         $file = $_;                                # get the module name
8016         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
8017         s,/,::,g;                                  # change '/' to '::'
8018         s/^perl5db$/DB/;                           # Special case: debugger
8019                                                    # moves to package DB
8020         s/^Term::ReadLine::readline$/readline/;    # simplify readline
8021
8022         # If the package has a $VERSION package global (as all good packages
8023         # should!) decode it and save as partial message.
8024         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
8025         if ( defined $pkg_version ) {
8026             $version{$file} = "$pkg_version from ";
8027         }
8028
8029         # Finish up the message with the file the package came from.
8030         $version{$file} .= $INC{$file};
8031     } ## end for (keys %INC)
8032
8033     # Hey, dumpit() formats a hash nicely, so why not use it?
8034     dumpit( $OUT, \%version );
8035 } ## end sub list_modules
8036
8037 =head2 C<sethelp()>
8038
8039 Sets up the monster string used to format and print the help.
8040
8041 =head3 HELP MESSAGE FORMAT
8042
8043 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
8044 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
8045 easy to parse and portable, but which still allows the help to be a little
8046 nicer than just plain text.
8047
8048 Essentially, you define the command name (usually marked up with C<< B<> >>
8049 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
8050 newline. The descriptive text can also be marked up in the same way. If you
8051 need to continue the descriptive text to another line, start that line with
8052 just tabs and then enter the marked-up text.
8053
8054 If you are modifying the help text, I<be careful>. The help-string parser is
8055 not very sophisticated, and if you don't follow these rules it will mangle the
8056 help beyond hope until you fix the string.
8057
8058 =cut
8059
8060 use vars qw($pre580_help);
8061 use vars qw($pre580_summary);
8062
8063 sub sethelp {
8064
8065     # XXX: make sure there are tabs between the command and explanation,
8066     #      or print_help will screw up your formatting if you have
8067     #      eeevil ornaments enabled.  This is an insane mess.
8068
8069     $help = "
8070 Help is currently only available for the new 5.8 command set.
8071 No help is available for the old command set.
8072 We assume you know what you're doing if you switch to it.
8073
8074 B<T>        Stack trace.
8075 B<s> [I<expr>]    Single step [in I<expr>].
8076 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8077 <B<CR>>        Repeat last B<n> or B<s> command.
8078 B<r>        Return from current subroutine.
8079 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8080         at the specified position.
8081 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8082 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8083 B<l> I<line>        List single I<line>.
8084 B<l> I<subname>    List first window of lines from subroutine.
8085 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8086 B<l>        List next window of lines.
8087 B<->        List previous window of lines.
8088 B<v> [I<line>]    View window around I<line>.
8089 B<.>        Return to the executed line.
8090 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8091         I<filename> may be either the full name of the file, or a regular
8092         expression matching the full file name:
8093         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8094         Evals (with saved bodies) are considered to be filenames:
8095         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8096         (in the order of execution).
8097 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8098 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8099 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8100 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8101 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8102 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8103 B<b>        Sets breakpoint on current line)
8104 B<b> [I<line>] [I<condition>]
8105         Set breakpoint; I<line> defaults to the current execution line;
8106         I<condition> breaks if it evaluates to true, defaults to '1'.
8107 B<b> I<subname> [I<condition>]
8108         Set breakpoint at first line of subroutine.
8109 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8110 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8111 B<b> B<postpone> I<subname> [I<condition>]
8112         Set breakpoint at first line of subroutine after
8113         it is compiled.
8114 B<b> B<compile> I<subname>
8115         Stop after the subroutine is compiled.
8116 B<B> [I<line>]    Delete the breakpoint for I<line>.
8117 B<B> I<*>             Delete all breakpoints.
8118 B<a> [I<line>] I<command>
8119         Set an action to be done before the I<line> is executed;
8120         I<line> defaults to the current execution line.
8121         Sequence is: check for breakpoint/watchpoint, print line
8122         if necessary, do action, prompt user if necessary,
8123         execute line.
8124 B<a>        Does nothing
8125 B<A> [I<line>]    Delete the action for I<line>.
8126 B<A> I<*>             Delete all actions.
8127 B<w> I<expr>        Add a global watch-expression.
8128 B<w>             Does nothing
8129 B<W> I<expr>        Delete a global watch-expression.
8130 B<W> I<*>             Delete all watch-expressions.
8131 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8132         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8133 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8134 B<x> I<expr>        Evals expression in list context, dumps the result.
8135 B<m> I<expr>        Evals expression in list context, prints methods callable
8136         on the first element of the result.
8137 B<m> I<class>        Prints methods callable via the given class.
8138 B<M>        Show versions of loaded modules.
8139 B<i> I<class>       Prints nested parents of given class.
8140 B<e>         Display current thread id.
8141 B<E>         Display all thread ids the current one will be identified: <n>.
8142 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8143
8144 B<<> ?            List Perl commands to run before each prompt.
8145 B<<> I<expr>        Define Perl command to run before each prompt.
8146 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8147 B<< *>                Delete the list of perl commands to run before each prompt.
8148 B<>> ?            List Perl commands to run after each prompt.
8149 B<>> I<expr>        Define Perl command to run after each prompt.
8150 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8151 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8152 B<{> I<db_command>    Define debugger command to run before each prompt.
8153 B<{> ?            List debugger commands to run before each prompt.
8154 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8155 B<{ *>             Delete the list of debugger commands to run before each prompt.
8156 B<$prc> I<number>    Redo a previous command (default previous command).
8157 B<$prc> I<-number>    Redo number'th-to-last command.
8158 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8159         See 'B<O> I<recallCommand>' too.
8160 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8161       . (
8162         $rc eq $sh
8163         ? ""
8164         : "
8165 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8166       ) . "
8167         See 'B<O> I<shellBang>' too.
8168 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8169 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8170 B<rerun>           Rerun session to current position.
8171 B<rerun> I<n>         Rerun session to numbered command.
8172 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8173 B<H> I<-number>    Display last number commands (default all).
8174 B<H> I<*>          Delete complete history.
8175 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8176 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8177 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8178 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8179 I<command>        Execute as a perl statement in current package.
8180 B<R>        Pure-man-restart of debugger, some of debugger state
8181         and command-line options may be lost.
8182         Currently the following settings are preserved:
8183         history, breakpoints and actions, debugger B<O>ptions
8184         and the following command-line options: I<-w>, I<-I>, I<-e>.
8185
8186 B<o> [I<opt>] ...    Set boolean option to true
8187 B<o> [I<opt>B<?>]    Query options
8188 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8189         Set options.  Use quotes if spaces in value.
8190     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8191     I<pager>            program for output of \"|cmd\";
8192     I<tkRunning>            run Tk while prompting (with ReadLine);
8193     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8194     I<inhibit_exit>        Allows stepping off the end of the script.
8195     I<ImmediateStop>        Debugger should stop as early as possible.
8196     I<RemotePort>            Remote hostname:port for remote debugging
8197   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8198     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8199     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8200     I<globPrint>             whether to print contents of globs;
8201     I<DumpDBFiles>         dump arrays holding debugged files;
8202     I<DumpPackages>         dump symbol tables of packages;
8203     I<DumpReused>             dump contents of \"reused\" addresses;
8204     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8205     I<bareStringify>         Do not print the overload-stringified value;
8206   Other options include:
8207     I<PrintRet>        affects printing of return value after B<r> command,
8208     I<frame>        affects printing messages on subroutine entry/exit.
8209     I<AutoTrace>    affects printing messages on possible breaking points.
8210     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8211     I<ornaments>     affects screen appearance of the command line.
8212     I<CreateTTY>     bits control attempts to create a new TTY on events:
8213             1: on fork()    2: debugger is started inside debugger
8214             4: on startup
8215     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8216     You can put additional initialization options I<TTY>, I<noTTY>,
8217     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8218     B<R> after you set them).
8219
8220 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8221 B<h>        Summary of debugger commands.
8222 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8223 B<h h>        Long help for debugger commands
8224 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8225         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8226         Set B<\$DB::doccmd> to change viewer.
8227
8228 Type '|h h' for a paged display if this was too hard to read.
8229
8230 ";    # Fix balance of vi % matching: }}}}
8231
8232     #  note: tabs in the following section are not-so-helpful
8233     $summary = <<"END_SUM";
8234 I<List/search source lines:>               I<Control script execution:>
8235   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8236   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8237   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8238   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8239   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8240   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8241 I<Debugger controls:>                        B<L>           List break/watch/actions
8242   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8243   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8244   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8245   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8246   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8247   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8248   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8249   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8250   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8251 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8252   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8253   B<p> I<expr>         Print expression (uses script's current package).
8254   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8255   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8256   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8257   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8258   B<e>     Display thread id     B<E> Display all thread ids.
8259 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8260 END_SUM
8261
8262     # ')}}; # Fix balance of vi % matching
8263
8264     # and this is really numb...
8265     $pre580_help = "
8266 B<T>        Stack trace.
8267 B<s> [I<expr>]    Single step [in I<expr>].
8268 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8269 B<CR>>        Repeat last B<n> or B<s> command.
8270 B<r>        Return from current subroutine.
8271 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8272         at the specified position.
8273 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8274 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8275 B<l> I<line>        List single I<line>.
8276 B<l> I<subname>    List first window of lines from subroutine.
8277 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8278 B<l>        List next window of lines.
8279 B<->        List previous window of lines.
8280 B<w> [I<line>]    List window around I<line>.
8281 B<.>        Return to the executed line.
8282 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8283         I<filename> may be either the full name of the file, or a regular
8284         expression matching the full file name:
8285         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8286         Evals (with saved bodies) are considered to be filenames:
8287         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8288         (in the order of execution).
8289 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8290 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8291 B<L>        List all breakpoints and actions.
8292 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8293 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8294 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8295 B<b> [I<line>] [I<condition>]
8296         Set breakpoint; I<line> defaults to the current execution line;
8297         I<condition> breaks if it evaluates to true, defaults to '1'.
8298 B<b> I<subname> [I<condition>]
8299         Set breakpoint at first line of subroutine.
8300 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8301 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8302 B<b> B<postpone> I<subname> [I<condition>]
8303         Set breakpoint at first line of subroutine after
8304         it is compiled.
8305 B<b> B<compile> I<subname>
8306         Stop after the subroutine is compiled.
8307 B<d> [I<line>]    Delete the breakpoint for I<line>.
8308 B<D>        Delete all breakpoints.
8309 B<a> [I<line>] I<command>
8310         Set an action to be done before the I<line> is executed;
8311         I<line> defaults to the current execution line.
8312         Sequence is: check for breakpoint/watchpoint, print line
8313         if necessary, do action, prompt user if necessary,
8314         execute line.
8315 B<a> [I<line>]    Delete the action for I<line>.
8316 B<A>        Delete all actions.
8317 B<W> I<expr>        Add a global watch-expression.
8318 B<W>        Delete all watch-expressions.
8319 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8320         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8321 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8322 B<x> I<expr>        Evals expression in list context, dumps the result.
8323 B<m> I<expr>        Evals expression in list context, prints methods callable
8324         on the first element of the result.
8325 B<m> I<class>        Prints methods callable via the given class.
8326
8327 B<<> ?            List Perl commands to run before each prompt.
8328 B<<> I<expr>        Define Perl command to run before each prompt.
8329 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8330 B<>> ?            List Perl commands to run after each prompt.
8331 B<>> I<expr>        Define Perl command to run after each prompt.
8332 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8333 B<{> I<db_command>    Define debugger command to run before each prompt.
8334 B<{> ?            List debugger commands to run before each prompt.
8335 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8336 B<$prc> I<number>    Redo a previous command (default previous command).
8337 B<$prc> I<-number>    Redo number'th-to-last command.
8338 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8339         See 'B<O> I<recallCommand>' too.
8340 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8341       . (
8342         $rc eq $sh
8343         ? ""
8344         : "
8345 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8346       ) . "
8347         See 'B<O> I<shellBang>' too.
8348 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8349 B<H> I<-number>    Display last number commands (default all).
8350 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8351 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8352 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8353 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8354 I<command>        Execute as a perl statement in current package.
8355 B<v>        Show versions of loaded modules.
8356 B<R>        Pure-man-restart of debugger, some of debugger state
8357         and command-line options may be lost.
8358         Currently the following settings are preserved:
8359         history, breakpoints and actions, debugger B<O>ptions
8360         and the following command-line options: I<-w>, I<-I>, I<-e>.
8361
8362 B<O> [I<opt>] ...    Set boolean option to true
8363 B<O> [I<opt>B<?>]    Query options
8364 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8365         Set options.  Use quotes if spaces in value.
8366     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8367     I<pager>            program for output of \"|cmd\";
8368     I<tkRunning>            run Tk while prompting (with ReadLine);
8369     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8370     I<inhibit_exit>        Allows stepping off the end of the script.
8371     I<ImmediateStop>        Debugger should stop as early as possible.
8372     I<RemotePort>            Remote hostname:port for remote debugging
8373   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8374     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8375     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8376     I<globPrint>             whether to print contents of globs;
8377     I<DumpDBFiles>         dump arrays holding debugged files;
8378     I<DumpPackages>         dump symbol tables of packages;
8379     I<DumpReused>             dump contents of \"reused\" addresses;
8380     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8381     I<bareStringify>         Do not print the overload-stringified value;
8382   Other options include:
8383     I<PrintRet>        affects printing of return value after B<r> command,
8384     I<frame>        affects printing messages on subroutine entry/exit.
8385     I<AutoTrace>    affects printing messages on possible breaking points.
8386     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8387     I<ornaments>     affects screen appearance of the command line.
8388     I<CreateTTY>     bits control attempts to create a new TTY on events:
8389             1: on fork()    2: debugger is started inside debugger
8390             4: on startup
8391     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8392     You can put additional initialization options I<TTY>, I<noTTY>,
8393     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8394     B<R> after you set them).
8395
8396 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8397 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8398 B<h h>        Summary of debugger commands.
8399 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8400         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8401         Set B<\$DB::doccmd> to change viewer.
8402
8403 Type '|h' for a paged display if this was too hard to read.
8404
8405 ";    # Fix balance of vi % matching: }}}}
8406
8407     #  note: tabs in the following section are not-so-helpful
8408     $pre580_summary = <<"END_SUM";
8409 I<List/search source lines:>               I<Control script execution:>
8410   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8411   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8412   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8413   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8414   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8415   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8416 I<Debugger controls:>                        B<L>           List break/watch/actions
8417   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8418   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8419   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8420   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8421   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8422   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8423   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8424   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8425 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8426   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8427   B<p> I<expr>         Print expression (uses script's current package).
8428   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8429   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8430   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8431   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8432 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8433 END_SUM
8434
8435     # ')}}; # Fix balance of vi % matching
8436
8437 } ## end sub sethelp
8438
8439 =head2 C<print_help()>
8440
8441 Most of what C<print_help> does is just text formatting. It finds the
8442 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8443 terminal control characters to simulate them (courtesy of
8444 C<Term::ReadLine::TermCap>).
8445
8446 =cut
8447
8448 sub print_help {
8449     my $help_str = shift;
8450
8451     # Restore proper alignment destroyed by eeevil I<> and B<>
8452     # ornaments: A pox on both their houses!
8453     #
8454     # A help command will have everything up to and including
8455     # the first tab sequence padded into a field 16 (or if indented 20)
8456     # wide.  If it's wider than that, an extra space will be added.
8457     $help_str =~ s{
8458         ^                       # only matters at start of line
8459           ( \ {4} | \t )*       # some subcommands are indented
8460           ( < ?                 # so <CR> works
8461             [BI] < [^\t\n] + )  # find an eeevil ornament
8462           ( \t+ )               # original separation, discarded
8463           ( .* )                # this will now start (no earlier) than
8464                                 # column 16
8465     } {
8466         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8467         my $clean = $command;
8468         $clean =~ s/[BI]<([^>]*)>/$1/g;
8469
8470         # replace with this whole string:
8471         ($leadwhite ? " " x 4 : "")
8472       . $command
8473       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8474       . $text;
8475
8476     }mgex;
8477
8478     $help_str =~ s{                          # handle bold ornaments
8479        B < ( [^>] + | > ) >
8480     } {
8481           $Term::ReadLine::TermCap::rl_term_set[2]
8482         . $1
8483         . $Term::ReadLine::TermCap::rl_term_set[3]
8484     }gex;
8485
8486     $help_str =~ s{                         # handle italic ornaments
8487        I < ( [^>] + | > ) >
8488     } {
8489           $Term::ReadLine::TermCap::rl_term_set[0]
8490         . $1
8491         . $Term::ReadLine::TermCap::rl_term_set[1]
8492     }gex;
8493
8494     local $\ = '';
8495     print {$OUT} $help_str;
8496
8497     return;
8498 } ## end sub print_help
8499
8500 =head2 C<fix_less>
8501
8502 This routine does a lot of gyrations to be sure that the pager is C<less>.
8503 It checks for C<less> masquerading as C<more> and records the result in
8504 C<$fixed_less> so we don't have to go through doing the stats again.
8505
8506 =cut
8507
8508 use vars qw($fixed_less);
8509
8510 sub _calc_is_less {
8511     if ($pager =~ /\bless\b/)
8512     {
8513         return 1;
8514     }
8515     elsif ($pager =~ /\bmore\b/)
8516     {
8517         # Nope, set to more. See what's out there.
8518         my @st_more = stat('/usr/bin/more');
8519         my @st_less = stat('/usr/bin/less');
8520
8521         # is it really less, pretending to be more?
8522         return (
8523             @st_more
8524             && @st_less
8525             && $st_more[0] == $st_less[0]
8526             && $st_more[1] == $st_less[1]
8527         );
8528     }
8529     else {
8530         return;
8531     }
8532 }
8533
8534 sub fix_less {
8535
8536     # We already know if this is set.
8537     return if $fixed_less;
8538
8539     # changes environment!
8540     # 'r' added so we don't do (slow) stats again.
8541     $fixed_less = 1 if _calc_is_less();
8542
8543     return;
8544 } ## end sub fix_less
8545
8546 =head1 DIE AND WARN MANAGEMENT
8547
8548 =head2 C<diesignal>
8549
8550 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8551 to debug a debugger problem.
8552
8553 It does its best to report the error that occurred, and then forces the
8554 program, debugger, and everything to die.
8555
8556 =cut
8557
8558 sub diesignal {
8559
8560     # No entry/exit messages.
8561     local $frame = 0;
8562
8563     # No return value prints.
8564     local $doret = -2;
8565
8566     # set the abort signal handling to the default (just terminate).
8567     $SIG{'ABRT'} = 'DEFAULT';
8568
8569     # If we enter the signal handler recursively, kill myself with an
8570     # abort signal (so we just terminate).
8571     kill 'ABRT', $$ if $panic++;
8572
8573     # If we can show detailed info, do so.
8574     if ( defined &Carp::longmess ) {
8575
8576         # Don't recursively enter the warn handler, since we're carping.
8577         local $SIG{__WARN__} = '';
8578
8579         # Skip two levels before reporting traceback: we're skipping
8580         # mydie and confess.
8581         local $Carp::CarpLevel = 2;    # mydie + confess
8582
8583         # Tell us all about it.
8584         _db_warn( Carp::longmess("Signal @_") );
8585     }
8586
8587     # No Carp. Tell us about the signal as best we can.
8588     else {
8589         local $\ = '';
8590         print $DB::OUT "Got signal @_\n";
8591     }
8592
8593     # Drop dead.
8594     kill 'ABRT', $$;
8595 } ## end sub diesignal
8596
8597 =head2 C<dbwarn>
8598
8599 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8600 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8601
8602 =cut
8603
8604 sub dbwarn {
8605
8606     # No entry/exit trace.
8607     local $frame = 0;
8608
8609     # No return value printing.
8610     local $doret = -2;
8611
8612     # Turn off warn and die handling to prevent recursive entries to this
8613     # routine.
8614     local $SIG{__WARN__} = '';
8615     local $SIG{__DIE__}  = '';
8616
8617     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8618     # done yet), we may not be able to do a require.
8619     eval { require Carp }
8620       if defined $^S;    # If error/warning during compilation,
8621                          # require may be broken.
8622
8623     # Use the core warn() unless Carp loaded OK.
8624     CORE::warn( @_,
8625         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8626       return
8627       unless defined &Carp::longmess;
8628
8629     # Save the current values of $single and $trace, and then turn them off.
8630     my ( $mysingle, $mytrace ) = ( $single, $trace );
8631     $single = 0;
8632     $trace  = 0;
8633
8634     # We can call Carp::longmess without its being "debugged" (which we
8635     # don't want - we just want to use it!). Capture this for later.
8636     my $mess = Carp::longmess(@_);
8637
8638     # Restore $single and $trace to their original values.
8639     ( $single, $trace ) = ( $mysingle, $mytrace );
8640
8641     # Use the debugger's own special way of printing warnings to print
8642     # the stack trace message.
8643     _db_warn($mess);
8644 } ## end sub dbwarn
8645
8646 =head2 C<dbdie>
8647
8648 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8649 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8650 single stepping and tracing during the call to C<Carp::longmess> to avoid
8651 debugging it - we just want to use it.
8652
8653 If C<dieLevel> is zero, we let the program being debugged handle the
8654 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8655 the debugger takes over all exception handling, printing a backtrace and
8656 displaying the exception via its C<dbwarn()> routine.
8657
8658 =cut
8659
8660 sub dbdie {
8661     local $frame         = 0;
8662     local $doret         = -2;
8663     local $SIG{__DIE__}  = '';
8664     local $SIG{__WARN__} = '';
8665     if ( $dieLevel > 2 ) {
8666         local $SIG{__WARN__} = \&dbwarn;
8667         _db_warn(@_);    # Yell no matter what
8668         return;
8669     }
8670     if ( $dieLevel < 2 ) {
8671         die @_ if $^S;    # in eval propagate
8672     }
8673
8674     # The code used to check $^S to see if compilation of the current thing
8675     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8676     eval { require Carp };
8677
8678     die( @_,
8679         "\nCannot print stack trace, load with -MCarp option to see stack" )
8680       unless defined &Carp::longmess;
8681
8682     # We do not want to debug this chunk (automatic disabling works
8683     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8684     # get the stack trace from Carp::longmess (if possible), restore $signal
8685     # and $trace, and then die with the stack trace.
8686     my ( $mysingle, $mytrace ) = ( $single, $trace );
8687     $single = 0;
8688     $trace  = 0;
8689     my $mess = "@_";
8690     {
8691
8692         package Carp;    # Do not include us in the list
8693         eval { $mess = Carp::longmess(@_); };
8694     }
8695     ( $single, $trace ) = ( $mysingle, $mytrace );
8696     die $mess;
8697 } ## end sub dbdie
8698
8699 =head2 C<warnlevel()>
8700
8701 Set the C<$DB::warnLevel> variable that stores the value of the
8702 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8703 results in the debugger taking over all warning handlers. Setting
8704 C<warnLevel> to zero leaves any warning handlers set up by the program
8705 being debugged in place.
8706
8707 =cut
8708
8709 sub warnLevel {
8710     if (@_) {
8711         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8712         $warnLevel = shift;
8713         if ($warnLevel) {
8714             $SIG{__WARN__} = \&DB::dbwarn;
8715         }
8716         elsif ($prevwarn) {
8717             $SIG{__WARN__} = $prevwarn;
8718         } else {
8719             undef $SIG{__WARN__};
8720         }
8721     } ## end if (@_)
8722     $warnLevel;
8723 } ## end sub warnLevel
8724
8725 =head2 C<dielevel>
8726
8727 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8728 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8729 zero lets you use your own C<die()> handler.
8730
8731 =cut
8732
8733 sub dieLevel {
8734     local $\ = '';
8735     if (@_) {
8736         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8737         $dieLevel = shift;
8738         if ($dieLevel) {
8739
8740             # Always set it to dbdie() for non-zero values.
8741             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8742
8743             # No longer exists, so don't try  to use it.
8744             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8745
8746             # If we've finished initialization, mention that stack dumps
8747             # are enabled, If dieLevel is 1, we won't stack dump if we die
8748             # in an eval().
8749             print $OUT "Stack dump during die enabled",
8750               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8751               if $I_m_init;
8752
8753             # XXX This is probably obsolete, given that diehard() is gone.
8754             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8755         } ## end if ($dieLevel)
8756
8757         # Put the old one back if there was one.
8758         elsif ($prevdie) {
8759             $SIG{__DIE__} = $prevdie;
8760             print $OUT "Default die handler restored.\n";
8761         } else {
8762             undef $SIG{__DIE__};
8763             print $OUT "Die handler removed.\n";
8764         }
8765     } ## end if (@_)
8766     $dieLevel;
8767 } ## end sub dieLevel
8768
8769 =head2 C<signalLevel>
8770
8771 Number three in a series: set C<signalLevel> to zero to keep your own
8772 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8773 takes over and handles them with C<DB::diesignal()>.
8774
8775 =cut
8776
8777 sub signalLevel {
8778     if (@_) {
8779         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8780         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8781         $signalLevel = shift;
8782         if ($signalLevel) {
8783             $SIG{SEGV} = \&DB::diesignal;
8784             $SIG{BUS}  = \&DB::diesignal;
8785         }
8786         else {
8787             $SIG{SEGV} = $prevsegv;
8788             $SIG{BUS}  = $prevbus;
8789         }
8790     } ## end if (@_)
8791     $signalLevel;
8792 } ## end sub signalLevel
8793
8794 =head1 SUBROUTINE DECODING SUPPORT
8795
8796 These subroutines are used during the C<x> and C<X> commands to try to
8797 produce as much information as possible about a code reference. They use
8798 L<Devel::Peek> to try to find the glob in which this code reference lives
8799 (if it does) - this allows us to actually code references which correspond
8800 to named subroutines (including those aliased via glob assignment).
8801
8802 =head2 C<CvGV_name()>
8803
8804 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8805 via that routine. If this fails, return the reference again (when the
8806 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8807
8808 =cut
8809
8810 sub CvGV_name {
8811     my $in   = shift;
8812     my $name = CvGV_name_or_bust($in);
8813     defined $name ? $name : $in;
8814 }
8815
8816 =head2 C<CvGV_name_or_bust> I<coderef>
8817
8818 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8819 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8820 find a glob for this ref.
8821
8822 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8823
8824 =cut
8825
8826 use vars qw($skipCvGV);
8827
8828 sub CvGV_name_or_bust {
8829     my $in = shift;
8830     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8831     return unless ref $in;
8832     $in = \&$in;            # Hard reference...
8833     eval { require Devel::Peek; 1 } or return;
8834     my $gv = Devel::Peek::CvGV($in) or return;
8835     *$gv{PACKAGE} . '::' . *$gv{NAME};
8836 } ## end sub CvGV_name_or_bust
8837
8838 =head2 C<find_sub>
8839
8840 A utility routine used in various places; finds the file where a subroutine
8841 was defined, and returns that filename and a line-number range.
8842
8843 Tries to use C<@sub> first; if it can't find it there, it tries building a
8844 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8845 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8846 this way, it brute-force searches C<%sub>, checking for identical references.
8847
8848 =cut
8849
8850 sub _find_sub_helper {
8851     my $subr = shift;
8852
8853     return unless defined &$subr;
8854     my $name = CvGV_name_or_bust($subr);
8855     my $data;
8856     $data = $sub{$name} if defined $name;
8857     return $data if defined $data;
8858
8859     # Old stupid way...
8860     $subr = \&$subr;    # Hard reference
8861     my $s;
8862     for ( keys %sub ) {
8863         $s = $_, last if $subr eq \&$_;
8864     }
8865     if ($s)
8866     {
8867         return $sub{$s};
8868     }
8869     else
8870     {
8871         return;
8872     }
8873
8874 }
8875
8876 sub find_sub {
8877     my $subr = shift;
8878     return ( $sub{$subr} || _find_sub_helper($subr) );
8879 } ## end sub find_sub
8880
8881 =head2 C<methods>
8882
8883 A subroutine that uses the utility function C<methods_via> to find all the
8884 methods in the class corresponding to the current reference and in
8885 C<UNIVERSAL>.
8886
8887 =cut
8888
8889 use vars qw(%seen);
8890
8891 sub methods {
8892
8893     # Figure out the class - either this is the class or it's a reference
8894     # to something blessed into that class.
8895     my $class = shift;
8896     $class = ref $class if ref $class;
8897
8898     local %seen;
8899
8900     # Show the methods that this class has.
8901     methods_via( $class, '', 1 );
8902
8903     # Show the methods that UNIVERSAL has.
8904     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8905 } ## end sub methods
8906
8907 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8908
8909 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8910 all the parent class methods. C<$class> is the name of the next class to
8911 try; C<$prefix> is the message prefix, which gets built up as we go up the
8912 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8913 higher in the C<@ISA> tree, 0 if we should stop.
8914
8915 =cut
8916
8917 sub methods_via {
8918
8919     # If we've processed this class already, just quit.
8920     my $class = shift;
8921     return if $seen{$class}++;
8922
8923     # This is a package that is contributing the methods we're about to print.
8924     my $prefix  = shift;
8925     my $prepend = $prefix ? "via $prefix: " : '';
8926     my @to_print;
8927
8928     # Extract from all the symbols in this class.
8929     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8930     while (my ($name, $glob) = each %$class_ref) {
8931         # references directly in the symbol table are Proxy Constant
8932         # Subroutines, and are by their very nature defined
8933         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8934         # to a subroutine reference, which can be tested by defined.
8935         # $glob might also be the value -1  (from sub foo;)
8936         # or (say) '$$' (from sub foo ($$);)
8937         # \$glob will be SCALAR in both cases.
8938         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8939             && !$seen{$name}++) {
8940             push @to_print, "$prepend$name\n";
8941         }
8942     }
8943
8944     {
8945         local $\ = '';
8946         local $, = '';
8947         print $DB::OUT $_ foreach sort @to_print;
8948     }
8949
8950     # If the $crawl_upward argument is false, just quit here.
8951     return unless shift;
8952
8953     # $crawl_upward true: keep going up the tree.
8954     # Find all the classes this one is a subclass of.
8955     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8956     for my $name ( @$class_ISA_ref ) {
8957
8958         # Set up the new prefix.
8959         $prepend = $prefix ? $prefix . " -> $name" : $name;
8960
8961         # Crawl up the tree and keep trying to crawl up.
8962         methods_via( $name, $prepend, 1 );
8963     }
8964 } ## end sub methods_via
8965
8966 =head2 C<setman> - figure out which command to use to show documentation
8967
8968 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8969
8970 =cut
8971
8972 sub setman {
8973     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8974       ? "man"         # O Happy Day!
8975       : "perldoc";    # Alas, poor unfortunates
8976 } ## end sub setman
8977
8978 =head2 C<runman> - run the appropriate command to show documentation
8979
8980 Accepts a man page name; runs the appropriate command to display it (set up
8981 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8982 program's STDIN and STDOUT.
8983
8984 =cut
8985
8986 sub runman {
8987     my $page = shift;
8988     unless ($page) {
8989         _db_system("$doccmd $doccmd");
8990         return;
8991     }
8992
8993     # this way user can override, like with $doccmd="man -Mwhatever"
8994     # or even just "man " to disable the path check.
8995     if ( $doccmd ne 'man' ) {
8996         _db_system("$doccmd $page");
8997         return;
8998     }
8999
9000     $page = 'perl' if lc($page) eq 'help';
9001
9002     require Config;
9003     my $man1dir = $Config::Config{man1direxp};
9004     my $man3dir = $Config::Config{man3direxp};
9005     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
9006     my $manpath = '';
9007     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
9008     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
9009     chop $manpath if $manpath;
9010
9011     # harmless if missing, I figure
9012     local $ENV{MANPATH} = $manpath if $manpath;
9013     my $nopathopt = $^O =~ /dunno what goes here/;
9014     if (
9015         CORE::system(
9016             $doccmd,
9017
9018             # I just *know* there are men without -M
9019             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9020             split ' ', $page
9021         )
9022       )
9023     {
9024         unless ( $page =~ /^perl\w/ ) {
9025             # Previously the debugger contained a list which it slurped in,
9026             # listing the known "perl" manpages. However, it was out of date,
9027             # with errors both of omission and inclusion. This approach is
9028             # considerably less complex. The failure mode on a butchered
9029             # install is simply that the user has to run man or perldoc
9030             # "manually" with the full manpage name.
9031
9032             # There is a list of $^O values in installperl to determine whether
9033             # the directory is 'pods' or 'pod'. However, we can avoid tight
9034             # coupling to that by simply checking the "non-standard" 'pods'
9035             # first.
9036             my $pods = "$Config::Config{privlibexp}/pods";
9037             $pods = "$Config::Config{privlibexp}/pod"
9038                 unless -d $pods;
9039             if (-f "$pods/perl$page.pod") {
9040                 CORE::system( $doccmd,
9041                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9042                     "perl$page" );
9043             }
9044         }
9045     } ## end if (CORE::system($doccmd...
9046 } ## end sub runman
9047
9048 #use Carp;                          # This did break, left for debugging
9049
9050 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
9051
9052 Because of the way the debugger interface to the Perl core is designed, any
9053 debugger package globals that C<DB::sub()> requires have to be defined before
9054 any subroutines can be called. These are defined in the second C<BEGIN> block.
9055
9056 This block sets things up so that (basically) the world is sane
9057 before the debugger starts executing. We set up various variables that the
9058 debugger has to have set up before the Perl core starts running:
9059
9060 =over 4
9061
9062 =item *
9063
9064 The debugger's own filehandles (copies of STD and STDOUT for now).
9065
9066 =item *
9067
9068 Characters for shell escapes, the recall command, and the history command.
9069
9070 =item *
9071
9072 The maximum recursion depth.
9073
9074 =item *
9075
9076 The size of a C<w> command's window.
9077
9078 =item *
9079
9080 The before-this-line context to be printed in a C<v> (view a window around this line) command.
9081
9082 =item *
9083
9084 The fact that we're not in a sub at all right now.
9085
9086 =item *
9087
9088 The default SIGINT handler for the debugger.
9089
9090 =item *
9091
9092 The appropriate value of the flag in C<$^D> that says the debugger is running
9093
9094 =item *
9095
9096 The current debugger recursion level
9097
9098 =item *
9099
9100 The list of postponed items and the C<$single> stack (XXX define this)
9101
9102 =item *
9103
9104 That we want no return values and no subroutine entry/exit trace.
9105
9106 =back
9107
9108 =cut
9109
9110 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9111
9112 use vars qw($db_stop);
9113
9114 BEGIN {    # This does not compile, alas. (XXX eh?)
9115     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9116     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9117
9118     # Define characters used by command parsing.
9119     $sh       = '!';      # Shell escape (does not work)
9120     $rc       = ',';      # Recall command (does not work)
9121     @hist     = ('?');    # Show history (does not work)
9122     @truehist = ();       # Can be saved for replay (per session)
9123
9124     # This defines the point at which you get the 'deep recursion'
9125     # warning. It MUST be defined or the debugger will not load.
9126     $deep = 1000;
9127
9128     # Number of lines around the current one that are shown in the
9129     # 'w' command.
9130     $window = 10;
9131
9132     # How much before-the-current-line context the 'v' command should
9133     # use in calculating the start of the window it will display.
9134     $preview = 3;
9135
9136     # We're not in any sub yet, but we need this to be a defined value.
9137     $sub = '';
9138
9139     # Set up the debugger's interrupt handler. It simply sets a flag
9140     # ($signal) that DB::DB() will check before each command is executed.
9141     $SIG{INT} = \&DB::catch;
9142
9143     # The following lines supposedly, if uncommented, allow the debugger to
9144     # debug itself. Perhaps we can try that someday.
9145     # This may be enabled to debug debugger:
9146     #$warnLevel = 1 unless defined $warnLevel;
9147     #$dieLevel = 1 unless defined $dieLevel;
9148     #$signalLevel = 1 unless defined $signalLevel;
9149
9150     # This is the flag that says "a debugger is running, please call
9151     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9152     # execute anything in the user's context, because we always want to
9153     # get control back.
9154     $db_stop = 0;          # Compiler warning ...
9155     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9156
9157     # This variable records how many levels we're nested in debugging. Used
9158     # Used in the debugger prompt, and in determining whether it's all over or
9159     # not.
9160     $level = 0;            # Level of recursive debugging
9161
9162     # "Triggers bug (?) in perl if we postpone this until runtime."
9163     # XXX No details on this yet, or whether we should fix the bug instead
9164     # of work around it. Stay tuned.
9165     @stack = (0);
9166
9167     # Used to track the current stack depth using the auto-stacked-variable
9168     # trick.
9169     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9170
9171     # Don't print return values on exiting a subroutine.
9172     $doret = -2;
9173
9174     # No extry/exit tracing.
9175     $frame = 0;
9176
9177 } ## end BEGIN
9178
9179 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9180
9181 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9182
9183 =head2 db_complete
9184
9185 C<readline> support - adds command completion to basic C<readline>.
9186
9187 Returns a list of possible completions to C<readline> when invoked. C<readline>
9188 will print the longest common substring following the text already entered.
9189
9190 If there is only a single possible completion, C<readline> will use it in full.
9191
9192 This code uses C<map> and C<grep> heavily to create lists of possible
9193 completion. Think LISP in this section.
9194
9195 =cut
9196
9197 sub db_complete {
9198
9199     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9200     # $text is the text to be completed.
9201     # $line is the incoming line typed by the user.
9202     # $start is the start of the text to be completed in the incoming line.
9203     my ( $text, $line, $start ) = @_;
9204
9205     # Save the initial text.
9206     # The search pattern is current package, ::, extract the next qualifier
9207     # Prefix and pack are set to undef.
9208     my ( $itext, $search, $prefix, $pack ) =
9209       ( $text, "^\Q${package}::\E([^:]+)\$" );
9210
9211 =head3 C<b postpone|compile>
9212
9213 =over 4
9214
9215 =item *
9216
9217 Find all the subroutines that might match in this package
9218
9219 =item *
9220
9221 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9222
9223 =item *
9224
9225 Include all the rest of the subs that are known
9226
9227 =item *
9228
9229 C<grep> out the ones that match the text we have so far
9230
9231 =item *
9232
9233 Return this as the list of possible completions
9234
9235 =back
9236
9237 =cut
9238
9239     return sort grep /^\Q$text/, ( keys %sub ),
9240       qw(postpone load compile),    # subroutines
9241       ( map { /$search/ ? ($1) : () } keys %sub )
9242       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9243
9244 =head3 C<b load>
9245
9246 Get all the possible files from C<@INC> as it currently stands and
9247 select the ones that match the text so far.
9248
9249 =cut
9250
9251     return sort grep /^\Q$text/, values %INC    # files
9252       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9253
9254 =head3  C<V> (list variable) and C<m> (list modules)
9255
9256 There are two entry points for these commands:
9257
9258 =head4 Unqualified package names
9259
9260 Get the top-level packages and grab everything that matches the text
9261 so far. For each match, recursively complete the partial packages to
9262 get all possible matching packages. Return this sorted list.
9263
9264 =cut
9265
9266     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9267       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9268       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9269
9270 =head4 Qualified package names
9271
9272 Take a partially-qualified package and find all subpackages for it
9273 by getting all the subpackages for the package so far, matching all
9274 the subpackages against the text, and discarding all of them which
9275 start with 'main::'. Return this list.
9276
9277 =cut
9278
9279     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9280       grep !/^main::/, grep /^\Q$text/,
9281       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9282       do { no strict 'refs'; keys %{ $prefix . '::' } }
9283       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9284       and $text =~ /^(.*[^:])::?(\w*)$/
9285       and $prefix = $1;
9286
9287 =head3 C<f> - switch files
9288
9289 Here, we want to get a fully-qualified filename for the C<f> command.
9290 Possibilities are:
9291
9292 =over 4
9293
9294 =item 1. The original source file itself
9295
9296 =item 2. A file from C<@INC>
9297
9298 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9299
9300 =back
9301
9302 =cut
9303
9304     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9305            # We might possibly want to switch to an eval (which has a "filename"
9306            # like '(eval 9)'), so we may need to clean up the completion text
9307            # before proceeding.
9308         $prefix = length($1) - length($text);
9309         $text   = $1;
9310
9311 =pod
9312
9313 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9314 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9315 out of C<%main::>, add the initial source file, and extract the ones that
9316 match the completion text so far.
9317
9318 =cut
9319
9320         return sort
9321           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9322           $0;
9323     } ## end if ($line =~ /^\|*f\s+(.*)/)
9324
9325 =head3 Subroutine name completion
9326
9327 We look through all of the defined subs (the keys of C<%sub>) and
9328 return both all the possible matches to the subroutine name plus
9329 all the matches qualified to the current package.
9330
9331 =cut
9332
9333     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9334         $text = substr $text, 1;
9335         $prefix = "&";
9336         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9337           (
9338             map { /$search/ ? ($1) : () }
9339               keys %sub
9340           );
9341     } ## end if ((substr $text, 0, ...
9342
9343 =head3  Scalar, array, and hash completion: partially qualified package
9344
9345 Much like the above, except we have to do a little more cleanup:
9346
9347 =cut
9348
9349     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9350
9351 =pod
9352
9353 =over 4
9354
9355 =item *
9356
9357 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9358
9359 =cut
9360
9361         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9362
9363 =pod
9364
9365 =item *
9366
9367 Figure out the prefix vs. what needs completing.
9368
9369 =cut
9370
9371         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9372         $text   = $2;
9373
9374 =pod
9375
9376 =item *
9377
9378 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9379
9380 =cut
9381
9382         my @out = do {
9383             no strict 'refs';
9384             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9385             keys %$pack;
9386         };
9387
9388 =pod
9389
9390 =item *
9391
9392 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9393
9394 =cut
9395
9396         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9397             return db_complete( $out[0], $line, $start );
9398         }
9399
9400         # Return the list of possibles.
9401         return sort @out;
9402
9403     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9404
9405 =pod
9406
9407 =back
9408
9409 =head3 Symbol completion: current package or package C<main>.
9410
9411 =cut
9412
9413     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9414 =pod
9415
9416 =over 4
9417
9418 =item *
9419
9420 If it's C<main>, delete main to just get C<::> leading.
9421
9422 =cut
9423
9424         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9425
9426 =pod
9427
9428 =item *
9429
9430 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9431
9432 =cut
9433
9434         $prefix = substr $text, 0, 1;
9435         $text   = substr $text, 1;
9436
9437         my @out;
9438
9439 =pod
9440
9441 =item *
9442
9443 We look for the lexical scope above DB::DB and auto-complete lexical variables
9444 if PadWalker could be loaded.
9445
9446 =cut
9447
9448         if (not $text =~ /::/ and eval {
9449             local @INC = @INC;
9450             pop @INC if $INC[-1] eq '.';
9451             require PadWalker } ) {
9452             my $level = 1;
9453             while (1) {
9454                 my @info = caller($level);
9455                 $level++;
9456                 $level = -1, last
9457                   if not @info;
9458                 last if $info[3] eq 'DB::DB';
9459             }
9460             if ($level > 0) {
9461                 my $lexicals = PadWalker::peek_my($level);
9462                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9463             }
9464         }
9465
9466 =pod
9467
9468 =item *
9469
9470 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9471
9472 =cut
9473
9474         push @out, map "$prefix$_", grep /^\Q$text/,
9475           ( grep /^_?[a-zA-Z]/, do { no strict 'refs'; keys %$pack } ),
9476           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9477
9478 =item *
9479
9480 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9481
9482 =back
9483
9484 =cut
9485
9486         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9487             return db_complete( $out[0], $line, $start );
9488         }
9489
9490         # Return the list of possibles.
9491         return sort @out;
9492     } ## end if ($text =~ /^[\$@%]/)
9493
9494 =head3 Options
9495
9496 We use C<option_val()> to look up the current value of the option. If there's
9497 only a single value, we complete the command in such a way that it is a
9498 complete command for setting the option in question. If there are multiple
9499 possible values, we generate a command consisting of the option plus a trailing
9500 question mark, which, if executed, will list the current value of the option.
9501
9502 =cut
9503
9504     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9505     {    # Options after space
9506            # We look for the text to be matched in the list of possible options,
9507            # and fetch the current value.
9508         my @out = grep /^\Q$text/, @options;
9509         my $val = option_val( $out[0], undef );
9510
9511         # Set up a 'query option's value' command.
9512         my $out = '? ';
9513         if ( not defined $val or $val =~ /[\n\r]/ ) {
9514
9515             # There's really nothing else we can do.
9516         }
9517
9518         # We have a value. Create a proper option-setting command.
9519         elsif ( $val =~ /\s/ ) {
9520
9521             # XXX This may be an extraneous variable.
9522             my $found;
9523
9524             # We'll want to quote the string (because of the embedded
9525             # whtespace), but we want to make sure we don't end up with
9526             # mismatched quote characters. We try several possibilities.
9527             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9528
9529                 # If we didn't find this quote character in the value,
9530                 # quote it using this quote character.
9531                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9532             }
9533         } ## end elsif ($val =~ /\s/)
9534
9535         # Don't need any quotes.
9536         else {
9537             $out = "=$val ";
9538         }
9539
9540         # If there were multiple possible values, return '? ', which
9541         # makes the command into a query command. If there was just one,
9542         # have readline append that.
9543         $rl_attribs->{completer_terminator_character} =
9544           ( @out == 1 ? $out : '? ' );
9545
9546         # Return list of possibilities.
9547         return sort @out;
9548     } ## end if ((substr $line, 0, ...
9549
9550 =head3 Filename completion
9551
9552 For entering filenames. We simply call C<readline>'s C<filename_list()>
9553 method with the completion text to get the possible completions.
9554
9555 =cut
9556
9557     return $term->filename_list($text);    # filenames
9558
9559 } ## end sub db_complete
9560
9561 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9562
9563 Functions that possibly ought to be somewhere else.
9564
9565 =head2 end_report
9566
9567 Say we're done.
9568
9569 =cut
9570
9571 sub end_report {
9572     local $\ = '';
9573     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9574 }
9575
9576 =head2 clean_ENV
9577
9578 If we have $ini_pids, save it in the environment; else remove it from the
9579 environment. Used by the C<R> (restart) command.
9580
9581 =cut
9582
9583 sub clean_ENV {
9584     if ( defined($ini_pids) ) {
9585         $ENV{PERLDB_PIDS} = $ini_pids;
9586     }
9587     else {
9588         delete( $ENV{PERLDB_PIDS} );
9589     }
9590 } ## end sub clean_ENV
9591
9592 # PERLDBf_... flag names from perl.h
9593 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9594
9595 BEGIN {
9596     %DollarCaretP_flags = (
9597         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9598         PERLDBf_LINE      => 0x02,     # Keep line #
9599         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9600         PERLDBf_INTER     => 0x08,     # Preserve more data
9601         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9602         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9603         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9604         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9605         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9606         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9607         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9608         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9609     );
9610     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9611     # doesn't need to set it. It's provided for the benefit of profilers and
9612     # other code analysers.
9613
9614     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9615 }
9616
9617 sub parse_DollarCaretP_flags {
9618     my $flags = shift;
9619     $flags =~ s/^\s+//;
9620     $flags =~ s/\s+$//;
9621     my $acu = 0;
9622     foreach my $f ( split /\s*\|\s*/, $flags ) {
9623         my $value;
9624         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9625             $value = hex $1;
9626         }
9627         elsif ( $f =~ /^(\d+)$/ ) {
9628             $value = int $1;
9629         }
9630         elsif ( $f =~ /^DEFAULT$/i ) {
9631             $value = $DollarCaretP_flags{PERLDB_ALL};
9632         }
9633         else {
9634             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9635             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9636             unless ( defined $value ) {
9637                 print $OUT (
9638                     "Unrecognized \$^P flag '$f'!\n",
9639                     "Acceptable flags are: "
9640                       . join( ', ', sort keys %DollarCaretP_flags ),
9641                     ", and hexadecimal and decimal numbers.\n"
9642                 );
9643                 return undef;
9644             }
9645         }
9646         $acu |= $value;
9647     }
9648     $acu;
9649 }
9650
9651 sub expand_DollarCaretP_flags {
9652     my $DollarCaretP = shift;
9653     my @bits         = (
9654         map {
9655             my $n = ( 1 << $_ );
9656             ( $DollarCaretP & $n )
9657               ? ( $DollarCaretP_flags_r{$n}
9658                   || sprintf( '0x%x', $n ) )
9659               : ()
9660           } 0 .. 31
9661     );
9662     return @bits ? join( '|', @bits ) : 0;
9663 }
9664
9665 =over 4
9666
9667 =item rerun
9668
9669 Rerun the current session to:
9670
9671     rerun        current position
9672
9673     rerun 4      command number 4
9674
9675     rerun -4     current command minus 4 (go back 4 steps)
9676
9677 Whether this always makes sense, in the current context is unknowable, and is
9678 in part left as a useful exercise for the reader.  This sub returns the
9679 appropriate arguments to rerun the current session.
9680
9681 =cut
9682
9683 sub rerun {
9684     my $i = shift;
9685     my @args;
9686     pop(@truehist);                      # strim
9687     unless (defined $truehist[$i]) {
9688         print "Unable to return to non-existent command: $i\n";
9689     } else {
9690         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9691         my @temp = @truehist;            # store
9692         push(@DB::typeahead, @truehist); # saved
9693         @truehist = @hist = ();          # flush
9694         @args = restart();              # setup
9695         get_list("PERLDB_HIST");        # clean
9696         set_list("PERLDB_HIST", @temp); # reset
9697     }
9698     return @args;
9699 }
9700
9701 =item restart
9702
9703 Restarting the debugger is a complex operation that occurs in several phases.
9704 First, we try to reconstruct the command line that was used to invoke Perl
9705 and the debugger.
9706
9707 =cut
9708
9709 sub restart {
9710     # I may not be able to resurrect you, but here goes ...
9711     print $OUT
9712 "Warning: some settings and command-line options may be lost!\n";
9713     my ( @script, @flags, $cl );
9714
9715     # If warn was on before, turn it on again.
9716     push @flags, '-w' if $ini_warn;
9717
9718     # Rebuild the -I flags that were on the initial
9719     # command line.
9720     for (@ini_INC) {
9721         push @flags, '-I', $_;
9722     }
9723
9724     # Turn on taint if it was on before.
9725     push @flags, '-T' if ${^TAINT};
9726
9727     # Arrange for setting the old INC:
9728     # Save the current @init_INC in the environment.
9729     set_list( "PERLDB_INC", @ini_INC );
9730
9731     # If this was a perl one-liner, go to the "file"
9732     # corresponding to the one-liner read all the lines
9733     # out of it (except for the first one, which is going
9734     # to be added back on again when 'perl -d' runs: that's
9735     # the 'require perl5db.pl;' line), and add them back on
9736     # to the command line to be executed.
9737     if ( $0 eq '-e' ) {
9738         my $lines = *{$main::{'_<-e'}}{ARRAY};
9739         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9740             chomp( $cl = $lines->[$_] );
9741             push @script, '-e', $cl;
9742         }
9743     } ## end if ($0 eq '-e')
9744
9745     # Otherwise we just reuse the original name we had
9746     # before.
9747     else {
9748         @script = $0;
9749     }
9750
9751 =pod
9752
9753 After the command line  has been reconstructed, the next step is to save
9754 the debugger's status in environment variables. The C<DB::set_list> routine
9755 is used to save aggregate variables (both hashes and arrays); scalars are
9756 just popped into environment variables directly.
9757
9758 =cut
9759
9760     # If the terminal supported history, grab it and
9761     # save that in the environment.
9762     set_list( "PERLDB_HIST",
9763           $term->Features->{getHistory}
9764         ? $term->GetHistory
9765         : @hist );
9766
9767     # Find all the files that were visited during this
9768     # session (i.e., the debugger had magic hashes
9769     # corresponding to them) and stick them in the environment.
9770     my @had_breakpoints = keys %had_breakpoints;
9771     set_list( "PERLDB_VISITED", @had_breakpoints );
9772
9773     # Save the debugger options we chose.
9774     set_list( "PERLDB_OPT", %option );
9775     # set_list( "PERLDB_OPT", options2remember() );
9776
9777     # Save the break-on-loads.
9778     set_list( "PERLDB_ON_LOAD", %break_on_load );
9779
9780 =pod
9781
9782 The most complex part of this is the saving of all of the breakpoints. They
9783 can live in an awful lot of places, and we have to go through all of them,
9784 find the breakpoints, and then save them in the appropriate environment
9785 variable via C<DB::set_list>.
9786
9787 =cut
9788
9789     # Go through all the breakpoints and make sure they're
9790     # still valid.
9791     my @hard;
9792     for ( 0 .. $#had_breakpoints ) {
9793
9794         # We were in this file.
9795         my $file = $had_breakpoints[$_];
9796
9797         # Grab that file's magic line hash.
9798         *dbline = $main::{ '_<' . $file };
9799
9800         # Skip out if it doesn't exist, or if the breakpoint
9801         # is in a postponed file (we'll do postponed ones
9802         # later).
9803         next unless %dbline or $postponed_file{$file};
9804
9805         # In an eval. This is a little harder, so we'll
9806         # do more processing on that below.
9807         ( push @hard, $file ), next
9808           if $file =~ /^\(\w*eval/;
9809
9810         # XXX I have no idea what this is doing. Yet.
9811         my @add;
9812         @add = %{ $postponed_file{$file} }
9813           if $postponed_file{$file};
9814
9815         # Save the list of all the breakpoints for this file.
9816         set_list( "PERLDB_FILE_$_", %dbline, @add );
9817
9818         # Serialize the extra data %breakpoints_data hash.
9819         # That's a bug fix.
9820         set_list( "PERLDB_FILE_ENABLED_$_",
9821             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9822             sort { $a <=> $b } keys(%dbline)
9823         )
9824     } ## end for (0 .. $#had_breakpoints)
9825
9826     # The breakpoint was inside an eval. This is a little
9827     # more difficult. XXX and I don't understand it.
9828     foreach my $hard_file (@hard) {
9829         # Get over to the eval in question.
9830         *dbline = $main::{ '_<' . $hard_file };
9831         my $quoted = quotemeta $hard_file;
9832         my %subs;
9833         for my $sub ( keys %sub ) {
9834             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9835                 $subs{$sub} = [ $n1, $n2 ];
9836             }
9837         }
9838         unless (%subs) {
9839             print {$OUT}
9840             "No subroutines in $hard_file, ignoring breakpoints.\n";
9841             next;
9842         }
9843         LINES: foreach my $line ( keys %dbline ) {
9844
9845             # One breakpoint per sub only:
9846             my ( $offset, $found );
9847             SUBS: foreach my $sub ( keys %subs ) {
9848                 if (
9849                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9850                     and (
9851                         not defined $offset    # Not caught
9852                             or $offset < 0
9853                     )
9854                 )
9855                 {                              # or badly caught
9856                     $found  = $sub;
9857                     $offset = $line - $subs{$sub}->[0];
9858                     if ($offset >= 0) {
9859                         $offset = "+$offset";
9860                         last SUBS;
9861                     }
9862                 } ## end if ($subs{$sub}->[1] >=...
9863             } ## end for $sub (keys %subs)
9864             if ( defined $offset ) {
9865                 $postponed{$found} =
9866                 "break $offset if $dbline{$line}";
9867             }
9868             else {
9869                 print {$OUT}
9870                 ("Breakpoint in ${hard_file}:$line ignored:"
9871                 . " after all the subroutines.\n");
9872             }
9873         } ## end for $line (keys %dbline)
9874     } ## end for (@hard)
9875
9876     # Save the other things that don't need to be
9877     # processed.
9878     set_list( "PERLDB_POSTPONE",  %postponed );
9879     set_list( "PERLDB_PRETYPE",   @$pretype );
9880     set_list( "PERLDB_PRE",       @$pre );
9881     set_list( "PERLDB_POST",      @$post );
9882     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9883
9884     # We are officially restarting.
9885     $ENV{PERLDB_RESTART} = 1;
9886
9887     # We are junking all child debuggers.
9888     delete $ENV{PERLDB_PIDS};    # Restore ini state
9889
9890     # Set this back to the initial pid.
9891     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9892
9893 =pod
9894
9895 After all the debugger status has been saved, we take the command we built up
9896 and then return it, so we can C<exec()> it. The debugger will spot the
9897 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9898 from the environment.
9899
9900 =cut
9901
9902     # And run Perl again. Add the "-d" flag, all the
9903     # flags we built up, the script (whether a one-liner
9904     # or a file), add on the -emacs flag for a slave editor,
9905     # and then the old arguments.
9906
9907     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9908
9909 };  # end restart
9910
9911 =back
9912
9913 =head1 END PROCESSING - THE C<END> BLOCK
9914
9915 Come here at the very end of processing. We want to go into a
9916 loop where we allow the user to enter commands and interact with the
9917 debugger, but we don't want anything else to execute.
9918
9919 First we set the C<$finished> variable, so that some commands that
9920 shouldn't be run after the end of program quit working.
9921
9922 We then figure out whether we're truly done (as in the user entered a C<q>
9923 command, or we finished execution while running nonstop). If we aren't,
9924 we set C<$single> to 1 (causing the debugger to get control again).
9925
9926 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9927 message and returns control to the debugger. Repeat.
9928
9929 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9930 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9931 break, run to completion.).
9932
9933 =cut
9934
9935 END {
9936     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9937     $fall_off_end = 1 unless $inhibit_exit;
9938
9939     # Do not stop in at_exit() and destructors on exit:
9940     if ($fall_off_end or $runnonstop) {
9941         save_hist();
9942     } else {
9943         $DB::single = 1;
9944         DB::fake::at_exit();
9945     }
9946 } ## end END
9947
9948 =head1 PRE-5.8 COMMANDS
9949
9950 Some of the commands changed function quite a bit in the 5.8 command
9951 realignment, so much so that the old code had to be replaced completely.
9952 Because we wanted to retain the option of being able to go back to the
9953 former command set, we moved the old code off to this section.
9954
9955 There's an awful lot of duplicated code here. We've duplicated the
9956 comments to keep things clear.
9957
9958 =head2 Null command
9959
9960 Does nothing. Used to I<turn off> commands.
9961
9962 =cut
9963
9964 sub cmd_pre580_null {
9965
9966     # do nothing...
9967 }
9968
9969 =head2 Old C<a> command.
9970
9971 This version added actions if you supplied them, and deleted them
9972 if you didn't.
9973
9974 =cut
9975
9976 sub cmd_pre580_a {
9977     my $xcmd = shift;
9978     my $cmd  = shift;
9979
9980     # Argument supplied. Add the action.
9981     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9982
9983         # If the line isn't there, use the current line.
9984         my $i = $1 || $line;
9985         my $j = $2;
9986
9987         # If there is an action ...
9988         if ( length $j ) {
9989
9990             # ... but the line isn't breakable, skip it.
9991             if ( $dbline[$i] == 0 ) {
9992                 print $OUT "Line $i may not have an action.\n";
9993             }
9994             else {
9995
9996                 # ... and the line is breakable:
9997                 # Mark that there's an action in this file.
9998                 $had_breakpoints{$filename} |= 2;
9999
10000                 # Delete any current action.
10001                 $dbline{$i} =~ s/\0[^\0]*//;
10002
10003                 # Add the new action, continuing the line as needed.
10004                 $dbline{$i} .= "\0" . action($j);
10005             }
10006         } ## end if (length $j)
10007
10008         # No action supplied.
10009         else {
10010
10011             # Delete the action.
10012             $dbline{$i} =~ s/\0[^\0]*//;
10013
10014             # Mark as having no break or action if nothing's left.
10015             delete $dbline{$i} if $dbline{$i} eq '';
10016         }
10017     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
10018 } ## end sub cmd_pre580_a
10019
10020 =head2 Old C<b> command
10021
10022 Add breakpoints.
10023
10024 =cut
10025
10026 sub cmd_pre580_b {
10027     my $xcmd   = shift;
10028     my $cmd    = shift;
10029     my $dbline = shift;
10030
10031     # Break on load.
10032     if ( $cmd =~ /^load\b\s*(.*)/ ) {
10033         my $file = $1;
10034         $file =~ s/\s+$//;
10035         cmd_b_load($file);
10036     }
10037
10038     # b compile|postpone <some sub> [<condition>]
10039     # The interpreter actually traps this one for us; we just put the
10040     # necessary condition in the %postponed hash.
10041     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
10042
10043         # Capture the condition if there is one. Make it true if none.
10044         my $cond = length $3 ? $3 : '1';
10045
10046         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
10047         # if it was 'compile'.
10048         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
10049
10050         # De-Perl4-ify the name - ' separators to ::.
10051         $subname =~ s/\'/::/g;
10052
10053         # Qualify it into the current package unless it's already qualified.
10054         $subname = "${package}::" . $subname
10055           unless $subname =~ /::/;
10056
10057         # Add main if it starts with ::.
10058         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
10059
10060         # Save the break type for this sub.
10061         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
10062     } ## end elsif ($cmd =~ ...
10063
10064     # b <sub name> [<condition>]
10065     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
10066         my $subname = $1;
10067         my $cond = length $2 ? $2 : '1';
10068         cmd_b_sub( $subname, $cond );
10069     }
10070     # b <line> [<condition>].
10071     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
10072         my $i = $1 || $dbline;
10073         my $cond = length $2 ? $2 : '1';
10074         cmd_b_line( $i, $cond );
10075     }
10076 } ## end sub cmd_pre580_b
10077
10078 =head2 Old C<D> command.
10079
10080 Delete all breakpoints unconditionally.
10081
10082 =cut
10083
10084 sub cmd_pre580_D {
10085     my $xcmd = shift;
10086     my $cmd  = shift;
10087     if ( $cmd =~ /^\s*$/ ) {
10088         print $OUT "Deleting all breakpoints...\n";
10089
10090         # %had_breakpoints lists every file that had at least one
10091         # breakpoint in it.
10092         my $file;
10093         for $file ( keys %had_breakpoints ) {
10094
10095             # Switch to the desired file temporarily.
10096             local *dbline = $main::{ '_<' . $file };
10097
10098             $max = $#dbline;
10099             my $was;
10100
10101             # For all lines in this file ...
10102             for my $i (1 .. $max) {
10103
10104                 # If there's a breakpoint or action on this line ...
10105                 if ( defined $dbline{$i} ) {
10106
10107                     # ... remove the breakpoint.
10108                     $dbline{$i} =~ s/^[^\0]+//;
10109                     if ( $dbline{$i} =~ s/^\0?$// ) {
10110
10111                         # Remove the entry altogether if no action is there.
10112                         delete $dbline{$i};
10113                     }
10114                 } ## end if (defined $dbline{$i...
10115             } ## end for my $i (1 .. $max)
10116
10117             # If, after we turn off the "there were breakpoints in this file"
10118             # bit, the entry in %had_breakpoints for this file is zero,
10119             # we should remove this file from the hash.
10120             if ( not $had_breakpoints{$file} &= ~1 ) {
10121                 delete $had_breakpoints{$file};
10122             }
10123         } ## end for $file (keys %had_breakpoints)
10124
10125         # Kill off all the other breakpoints that are waiting for files that
10126         # haven't been loaded yet.
10127         undef %postponed;
10128         undef %postponed_file;
10129         undef %break_on_load;
10130     } ## end if ($cmd =~ /^\s*$/)
10131 } ## end sub cmd_pre580_D
10132
10133 =head2 Old C<h> command
10134
10135 Print help. Defaults to printing the long-form help; the 5.8 version
10136 prints the summary by default.
10137
10138 =cut
10139
10140 sub cmd_pre580_h {
10141     my $xcmd = shift;
10142     my $cmd  = shift;
10143
10144     # Print the *right* help, long format.
10145     if ( $cmd =~ /^\s*$/ ) {
10146         print_help($pre580_help);
10147     }
10148
10149     # 'h h' - explicitly-requested summary.
10150     elsif ( $cmd =~ /^h\s*/ ) {
10151         print_help($pre580_summary);
10152     }
10153
10154     # Find and print a command's help.
10155     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10156         my $asked  = $1;                   # for proper errmsg
10157         my $qasked = quotemeta($asked);    # for searching
10158                                            # XXX: finds CR but not <CR>
10159         if (
10160             $pre580_help =~ /^
10161                               <?           # Optional '<'
10162                               (?:[IB]<)    # Optional markup
10163                               $qasked      # The command name
10164                             /mx
10165           )
10166         {
10167
10168             while (
10169                 $pre580_help =~ /^
10170                                   (             # The command help:
10171                                    <?           # Optional '<'
10172                                    (?:[IB]<)    # Optional markup
10173                                    $qasked      # The command name
10174                                    ([\s\S]*?)   # Lines starting with tabs
10175                                    \n           # Final newline
10176                                   )
10177                                   (?!\s)/mgx
10178               )    # Line not starting with space
10179                    # (Next command's help)
10180             {
10181                 print_help($1);
10182             }
10183         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10184
10185         # Help not found.
10186         else {
10187             print_help("B<$asked> is not a debugger command.\n");
10188         }
10189     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10190 } ## end sub cmd_pre580_h
10191
10192 =head2 Old C<W> command
10193
10194 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10195
10196 =cut
10197
10198 sub cmd_pre580_W {
10199     my $xcmd = shift;
10200     my $cmd  = shift;
10201
10202     # Delete all watch expressions.
10203     if ( $cmd =~ /^$/ ) {
10204
10205         # No watching is going on.
10206         $trace &= ~2;
10207
10208         # Kill all the watch expressions and values.
10209         @to_watch = @old_watch = ();
10210     }
10211
10212     # Add a watch expression.
10213     elsif ( $cmd =~ /^(.*)/s ) {
10214
10215         # add it to the list to be watched.
10216         push @to_watch, $1;
10217
10218         # Get the current value of the expression.
10219         # Doesn't handle expressions returning list values!
10220         $evalarg = $1;
10221         # The &-call is here to ascertain the mutability of @_.
10222         my ($val) = &DB::eval;
10223         $val = ( defined $val ) ? "'$val'" : 'undef';
10224
10225         # Save it.
10226         push @old_watch, $val;
10227
10228         # We're watching stuff.
10229         $trace |= 2;
10230
10231     } ## end elsif ($cmd =~ /^(.*)/s)
10232 } ## end sub cmd_pre580_W
10233
10234 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10235
10236 The debugger used to have a bunch of nearly-identical code to handle
10237 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10238 C<cmd_prepost> unify all this into one set of code to handle the
10239 appropriate actions.
10240
10241 =head2 C<cmd_pre590_prepost>
10242
10243 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10244 do something destructive. In pre 5.8 debuggers, the default action was to
10245 delete all the actions.
10246
10247 =cut
10248
10249 sub cmd_pre590_prepost {
10250     my $cmd    = shift;
10251     my $line   = shift || '*';
10252     my $dbline = shift;
10253
10254     return cmd_prepost( $cmd, $line, $dbline );
10255 } ## end sub cmd_pre590_prepost
10256
10257 =head2 C<cmd_prepost>
10258
10259 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10260 Since the lists of actions are all held in arrays that are pointed to by
10261 references anyway, all we have to do is pick the right array reference and
10262 then use generic code to all, delete, or list actions.
10263
10264 =cut
10265
10266 sub cmd_prepost {
10267     my $cmd = shift;
10268
10269     # No action supplied defaults to 'list'.
10270     my $line = shift || '?';
10271
10272     # Figure out what to put in the prompt.
10273     my $which = '';
10274
10275     # Make sure we have some array or another to address later.
10276     # This means that if for some reason the tests fail, we won't be
10277     # trying to stash actions or delete them from the wrong place.
10278     my $aref = [];
10279
10280     # < - Perl code to run before prompt.
10281     if ( $cmd =~ /^\</o ) {
10282         $which = 'pre-perl';
10283         $aref  = $pre;
10284     }
10285
10286     # > - Perl code to run after prompt.
10287     elsif ( $cmd =~ /^\>/o ) {
10288         $which = 'post-perl';
10289         $aref  = $post;
10290     }
10291
10292     # { - first check for properly-balanced braces.
10293     elsif ( $cmd =~ /^\{/o ) {
10294         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10295             print $OUT
10296 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10297         }
10298
10299         # Properly balanced. Pre-prompt debugger actions.
10300         else {
10301             $which = 'pre-debugger';
10302             $aref  = $pretype;
10303         }
10304     } ## end elsif ( $cmd =~ /^\{/o )
10305
10306     # Did we find something that makes sense?
10307     unless ($which) {
10308         print $OUT "Confused by command: $cmd\n";
10309     }
10310
10311     # Yes.
10312     else {
10313
10314         # List actions.
10315         if ( $line =~ /^\s*\?\s*$/o ) {
10316             unless (@$aref) {
10317
10318                 # Nothing there. Complain.
10319                 print $OUT "No $which actions.\n";
10320             }
10321             else {
10322
10323                 # List the actions in the selected list.
10324                 print $OUT "$which commands:\n";
10325                 foreach my $action (@$aref) {
10326                     print $OUT "\t$cmd -- $action\n";
10327                 }
10328             } ## end else
10329         } ## end if ( $line =~ /^\s*\?\s*$/o)
10330
10331         # Might be a delete.
10332         else {
10333             if ( length($cmd) == 1 ) {
10334                 if ( $line =~ /^\s*\*\s*$/o ) {
10335
10336                     # It's a delete. Get rid of the old actions in the
10337                     # selected list..
10338                     @$aref = ();
10339                     print $OUT "All $cmd actions cleared.\n";
10340                 }
10341                 else {
10342
10343                     # Replace all the actions. (This is a <, >, or {).
10344                     @$aref = action($line);
10345                 }
10346             } ## end if ( length($cmd) == 1)
10347             elsif ( length($cmd) == 2 ) {
10348
10349                 # Add the action to the line. (This is a <<, >>, or {{).
10350                 push @$aref, action($line);
10351             }
10352             else {
10353
10354                 # <<<, >>>>, {{{{{{ ... something not a command.
10355                 print $OUT
10356                   "Confused by strange length of $which command($cmd)...\n";
10357             }
10358         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10359     } ## end else
10360 } ## end sub cmd_prepost
10361
10362 =head1 C<DB::fake>
10363
10364 Contains the C<at_exit> routine that the debugger uses to issue the
10365 C<Debugged program terminated ...> message after the program completes. See
10366 the C<END> block documentation for more details.
10367
10368 =cut
10369
10370 package DB::fake;
10371
10372 sub at_exit {
10373     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10374 }
10375
10376 package DB;    # Do not trace this 1; below!
10377
10378 1;
10379
10380