lib/Cwd.pm

   1 package Cwd;
   2 use 5.006;
   3
   4 =head1 NAME
   5
   6 Cwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     my $dir = getcwd;
  12
  13     use Cwd 'abs_path';
  14     my $abs_path = abs_path($file);
  15
  16 =head1 DESCRIPTION
  17
  18 This module provides functions for determining the pathname of the
  19 current working directory.  It is recommended that getcwd (or another
  20 *cwd() function) be used in I<all> code to ensure portability.
  21
  22 By default, it exports the functions cwd(), getcwd(), fastcwd(), and
  23 fastgetcwd() into the caller's namespace.
  24
  25
  26 =head2 getcwd and friends
  27
  28 Each of these functions are called without arguments and return the
  29 absolute path of the current working directory.
  30
  31 =over 4
  32
  33 =item getcwd
  34
  35     my $cwd = getcwd();
  36
  37 Returns the current working directory.
  38
  39 Re-implements the getcwd(3) (or getwd(3)) functions in Perl.
  40
  41 Taint-safe.
  42
  43 =item cwd
  44
  45     my $cwd = cwd();
  46
  47 The cwd() is the most natural form for the current architecture. For
  48 most systems it is identical to `pwd` (but without the trailing line
  49 terminator).
  50
  51 Unfortunately, cwd() is B<not> taint-safe.
  52
  53 =item fastcwd
  54
  55     my $cwd = fastcwd();
  56
  57 A more dangerous version of getcwd(), but potentially faster.
  58
  59 It might conceivably chdir() you out of a directory that it can't
  60 chdir() you back into.  If fastcwd encounters a problem it will return
  61 undef but will probably leave you in a different directory.  For a
  62 measure of extra security, if everything appears to have worked, the
  63 fastcwd() function will check that it leaves you in the same directory
  64 that it started in. If it has changed it will C<die> with the message
  65 "Unstable directory path, current directory changed
  66 unexpectedly". That should never happen.
  67
  68 =item fastgetcwd
  69
  70   my $cwd = fastgetcwd();
  71
  72 The fastgetcwd() function is provided as a synonym for cwd().
  73
  74 =back
  75
  76
  77 =head2 abs_path and friends
  78
  79 These functions are exported only on request.  They each take a single
  80 argument and return the absolute pathname for it.
  81
  82 =over 4
  83
  84 =item abs_path
  85
  86   my $abs_path = abs_path($file);
  87
  88 Uses the same algorithm as getcwd().  Symbolic links and relative-path
  89 components ("." and "..") are resolved to return the canonical
  90 pathname, just like realpath(3).
  91
  92 Taint-safe.
  93
  94 =item realpath
  95
  96   my $abs_path = realpath($file);
  97
  98 A synonym for abs_path().
  99
 100 Taint-safe.
 101
 102 =item fast_abs_path
 103
 104   my $abs_path = fast_abs_path($file);
 105
 106 A more dangerous, but potentially faster version of abs_path.
 107
 108 B<Not> taint-safe.
 109
 110 =back
 111
 112 =head2 $ENV{PWD}
 113
 114 If you ask to override your chdir() built-in function,
 115
 116   use Cwd qw(chdir);
 117
 118 then your PWD environment variable will be kept up to date.  Note that
 119 it will only be kept up to date if all packages which use chdir import
 120 it from Cwd.
 121
 122
 123 =head1 NOTES
 124
 125 =over 4
 126
 127 =item *
 128
 129 Since the path seperators are different on some operating systems ('/'
 130 on Unix, ':' on MacPerl, etc...) we recommend you use the File::Spec
 131 modules wherever portability is a concern.
 132
 133 =item *
 134
 135 Actually, on Mac OS, the C<getcwd()>, C<fastgetcwd()> and C<fastcwd()>
 136 functions  are all aliases for the C<cwd()> function, which, on Mac OS,
 137 calls `pwd`. Likewise, the C<abs_path()> function is an alias for
 138 C<fast_abs_path()>.
 139
 140 =back
 141
 142 =head1 SEE ALSO
 143
 144 L<File::chdir>
 145
 146 =cut
 147
 148 use strict;
 149
 150 use Carp;
 151
 152 our $VERSION = '2.06';
 153
 154 use base qw/ Exporter /;
 155 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
 156 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
 157
 158 # sys_cwd may keep the builtin command
 159
 160 # All the functionality of this module may provided by builtins,
 161 # there is no sense to process the rest of the file.
 162 # The best choice may be to have this in BEGIN, but how to return from BEGIN?
 163
 164 if ($^O eq 'os2' && defined &sys_cwd && defined &sys_abspath) {
 165     local $^W = 0;
 166     *cwd                = \&sys_cwd;
 167     *getcwd             = \&cwd;
 168     *fastgetcwd         = \&cwd;
 169     *fastcwd            = \&cwd;
 170     *abs_path           = \&sys_abspath;
 171     *fast_abs_path      = \&abs_path;
 172     *realpath           = \&abs_path;
 173     *fast_realpath      = \&abs_path;
 174     return 1;
 175 }
 176
 177 eval {
 178     require XSLoader;
 179     undef *Cwd::fastcwd; # avoid redefinition warning
 180     XSLoader::load('Cwd');
 181 };
 182
 183
 184 # Find the pwd command in the expected locations.  We assume these
 185 # are safe.  This prevents _backtick_pwd() consulting $ENV{PATH}
 186 # so everything works under taint mode.
 187 my $pwd_cmd;
 188 foreach my $try (qw(/bin/pwd /usr/bin/pwd)) {
 189     if( -x $try ) {
 190         $pwd_cmd = $try;
 191         last;
 192     }
 193 }
 194 $pwd_cmd ||= 'pwd';
 195
 196 # The 'natural and safe form' for UNIX (pwd may be setuid root)
 197 sub _backtick_pwd {
 198     local @ENV{qw(PATH IFS CDPATH ENV BASH_ENV)};
 199     my $cwd = `$pwd_cmd`;
 200     # Belt-and-suspenders in case someone said "undef $/".
 201     local $/ = "\n";
 202     # `pwd` may fail e.g. if the disk is full
 203     chomp($cwd) if defined $cwd;
 204     $cwd;
 205 }
 206
 207 # Since some ports may predefine cwd internally (e.g., NT)
 208 # we take care not to override an existing definition for cwd().
 209
 210 unless(defined &cwd) {
 211     # The pwd command is not available in some chroot(2)'ed environments
 212     if( $^O eq 'MacOS' || (defined $ENV{PATH} &&
 213                            grep { -x "$_/pwd" } split(':', $ENV{PATH})) )
 214     {
 215         *cwd = \&_backtick_pwd;
 216     }
 217     else {
 218         *cwd = \&getcwd;
 219     }
 220 }
 221
 222 # set a reasonable (and very safe) default for fastgetcwd, in case it
 223 # isn't redefined later (20001212 rspier)
 224 *fastgetcwd = \&cwd;
 225
 226 # By Brandon S. Allbery
 227 #
 228 # Usage: $cwd = getcwd();
 229
 230 sub getcwd
 231 {
 232     abs_path('.');
 233 }
 234
 235
 236 # By John Bazik
 237 #
 238 # Usage: $cwd = &fastcwd;
 239 #
 240 # This is a faster version of getcwd.  It's also more dangerous because
 241 # you might chdir out of a directory that you can't chdir back into.
 242
 243 sub fastcwd {
 244     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 245     my(@path, $path);
 246     local(*DIR);
 247
 248     my($orig_cdev, $orig_cino) = stat('.');
 249     ($cdev, $cino) = ($orig_cdev, $orig_cino);
 250     for (;;) {
 251         my $direntry;
 252         ($odev, $oino) = ($cdev, $cino);
 253         CORE::chdir('..') || return undef;
 254         ($cdev, $cino) = stat('.');
 255         last if $odev == $cdev && $oino == $cino;
 256         opendir(DIR, '.') || return undef;
 257         for (;;) {
 258             $direntry = readdir(DIR);
 259             last unless defined $direntry;
 260             next if $direntry eq '.';
 261             next if $direntry eq '..';
 262
 263             ($tdev, $tino) = lstat($direntry);
 264             last unless $tdev != $odev || $tino != $oino;
 265         }
 266         closedir(DIR);
 267         return undef unless defined $direntry; # should never happen
 268         unshift(@path, $direntry);
 269     }
 270     $path = '/' . join('/', @path);
 271     if ($^O eq 'apollo') { $path = "/".$path; }
 272     # At this point $path may be tainted (if tainting) and chdir would fail.
 273     # To be more useful we untaint it then check that we landed where we started.
 274     $path = $1 if $path =~ /^(.*)\z/s;  # untaint
 275     CORE::chdir($path) || return undef;
 276     ($cdev, $cino) = stat('.');
 277     die "Unstable directory path, current directory changed unexpectedly"
 278         if $cdev != $orig_cdev || $cino != $orig_cino;
 279     $path;
 280 }
 281
 282
 283 # Keeps track of current working directory in PWD environment var
 284 # Usage:
 285 #       use Cwd 'chdir';
 286 #       chdir $newdir;
 287
 288 my $chdir_init = 0;
 289
 290 sub chdir_init {
 291     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
 292         my($dd,$di) = stat('.');
 293         my($pd,$pi) = stat($ENV{'PWD'});
 294         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 295             $ENV{'PWD'} = cwd();
 296         }
 297     }
 298     else {
 299         my $wd = cwd();
 300         $wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
 301         $ENV{'PWD'} = $wd;
 302     }
 303     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 304     if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 305         my($pd,$pi) = stat($2);
 306         my($dd,$di) = stat($1);
 307         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 308             $ENV{'PWD'}="$2$3";
 309         }
 310     }
 311     $chdir_init = 1;
 312 }
 313
 314 sub chdir {
 315     my $newdir = @_ ? shift : '';       # allow for no arg (chdir to HOME dir)
 316     $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
 317     chdir_init() unless $chdir_init;
 318     my $newpwd;
 319     if ($^O eq 'MSWin32') {
 320         # get the full path name *before* the chdir()
 321         $newpwd = Win32::GetFullPathName($newdir);
 322     }
 323
 324     return 0 unless CORE::chdir $newdir;
 325
 326     if ($^O eq 'VMS') {
 327         return $ENV{'PWD'} = $ENV{'DEFAULT'}
 328     }
 329     elsif ($^O eq 'MacOS') {
 330         return $ENV{'PWD'} = cwd();
 331     }
 332     elsif ($^O eq 'MSWin32') {
 333         $ENV{'PWD'} = $newpwd;
 334         return 1;
 335     }
 336
 337     if ($newdir =~ m#^/#s) {
 338         $ENV{'PWD'} = $newdir;
 339     } else {
 340         my @curdir = split(m#/#,$ENV{'PWD'});
 341         @curdir = ('') unless @curdir;
 342         my $component;
 343         foreach $component (split(m#/#, $newdir)) {
 344             next if $component eq '.';
 345             pop(@curdir),next if $component eq '..';
 346             push(@curdir,$component);
 347         }
 348         $ENV{'PWD'} = join('/',@curdir) || '/';
 349     }
 350     1;
 351 }
 352
 353
 354 # In case the XS version doesn't load.
 355 *abs_path = \&_perl_abs_path unless defined &abs_path;
 356 sub _perl_abs_path
 357 {
 358     my $start = @_ ? shift : '.';
 359     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
 360
 361     unless (@cst = stat( $start ))
 362     {
 363         carp "stat($start): $!";
 364         return '';
 365     }
 366     $cwd = '';
 367     $dotdots = $start;
 368     do
 369     {
 370         $dotdots .= '/..';
 371         @pst = @cst;
 372         unless (opendir(PARENT, $dotdots))
 373         {
 374             carp "opendir($dotdots): $!";
 375             return '';
 376         }
 377         unless (@cst = stat($dotdots))
 378         {
 379             carp "stat($dotdots): $!";
 380             closedir(PARENT);
 381             return '';
 382         }
 383         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 384         {
 385             $dir = undef;
 386         }
 387         else
 388         {
 389             do
 390             {
 391                 unless (defined ($dir = readdir(PARENT)))
 392                 {
 393                     carp "readdir($dotdots): $!";
 394                     closedir(PARENT);
 395                     return '';
 396                 }
 397                 $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
 398             }
 399             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 400                    $tst[1] != $pst[1]);
 401         }
 402         $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
 403         closedir(PARENT);
 404     } while (defined $dir);
 405     chop($cwd) unless $cwd eq '/'; # drop the trailing /
 406     $cwd;
 407 }
 408
 409
 410 # added function alias for those of us more
 411 # used to the libc function.  --tchrist 27-Jan-00
 412 *realpath = \&abs_path;
 413
 414 sub fast_abs_path {
 415     my $cwd = getcwd();
 416     require File::Spec;
 417     my $path = @_ ? shift : File::Spec->curdir;
 418     CORE::chdir($path) || croak "Cannot chdir to $path: $!";
 419     my $realpath = getcwd();
 420     -d $cwd && CORE::chdir($cwd) ||
 421         croak "Cannot chdir back to $cwd: $!";
 422     $realpath;
 423 }
 424
 425 # added function alias to follow principle of least surprise
 426 # based on previous aliasing.  --tchrist 27-Jan-00
 427 *fast_realpath = \&fast_abs_path;
 428
 429
 430 # --- PORTING SECTION ---
 431
 432 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 433 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 434 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 435 #   in the process logical name table as the default device and directory
 436 #   seen by Perl. This may not be the same as the default device
 437 #   and directory seen by DCL after Perl exits, since the effects
 438 #   the CRTL chdir() function persist only until Perl exits.
 439
 440 sub _vms_cwd {
 441     return $ENV{'DEFAULT'};
 442 }
 443
 444 sub _vms_abs_path {
 445     return $ENV{'DEFAULT'} unless @_;
 446     my $path = VMS::Filespec::pathify($_[0]);
 447     croak("Invalid path name $_[0]") unless defined $path;
 448     return VMS::Filespec::rmsexpand($path);
 449 }
 450
 451 sub _os2_cwd {
 452     $ENV{'PWD'} = `cmd /c cd`;
 453     chop $ENV{'PWD'};
 454     $ENV{'PWD'} =~ s:\\:/:g ;
 455     return $ENV{'PWD'};
 456 }
 457
 458 sub _win32_cwd {
 459     $ENV{'PWD'} = Win32::GetCwd();
 460     $ENV{'PWD'} =~ s:\\:/:g ;
 461     return $ENV{'PWD'};
 462 }
 463
 464 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 465                             defined &Win32::GetCwd);
 466
 467 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 468
 469 sub _dos_cwd {
 470     if (!defined &Dos::GetCwd) {
 471         $ENV{'PWD'} = `command /c cd`;
 472         chop $ENV{'PWD'};
 473         $ENV{'PWD'} =~ s:\\:/:g ;
 474     } else {
 475         $ENV{'PWD'} = Dos::GetCwd();
 476     }
 477     return $ENV{'PWD'};
 478 }
 479
 480 sub _qnx_cwd {
 481         local $ENV{PATH} = '';
 482         local $ENV{CDPATH} = '';
 483         local $ENV{ENV} = '';
 484     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 485     chop $ENV{'PWD'};
 486     return $ENV{'PWD'};
 487 }
 488
 489 sub _qnx_abs_path {
 490         local $ENV{PATH} = '';
 491         local $ENV{CDPATH} = '';
 492         local $ENV{ENV} = '';
 493     my $path = @_ ? shift : '.';
 494     my $realpath=`/usr/bin/fullpath -t $path`;
 495     chop $realpath;
 496     return $realpath;
 497 }
 498
 499 sub _epoc_cwd {
 500     $ENV{'PWD'} = EPOC::getcwd();
 501     return $ENV{'PWD'};
 502 }
 503
 504 {
 505     no warnings;        # assignments trigger 'subroutine redefined' warning
 506
 507     if ($^O eq 'VMS') {
 508         *cwd            = \&_vms_cwd;
 509         *getcwd         = \&_vms_cwd;
 510         *fastcwd        = \&_vms_cwd;
 511         *fastgetcwd     = \&_vms_cwd;
 512         *abs_path       = \&_vms_abs_path;
 513         *fast_abs_path  = \&_vms_abs_path;
 514     }
 515     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 516         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 517         *cwd            = \&_NT_cwd;
 518         *getcwd         = \&_NT_cwd;
 519         *fastcwd        = \&_NT_cwd;
 520         *fastgetcwd     = \&_NT_cwd;
 521         *abs_path       = \&fast_abs_path;
 522         *realpath   = \&fast_abs_path;
 523     }
 524     elsif ($^O eq 'os2') {
 525         # sys_cwd may keep the builtin command
 526         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 527         *getcwd         = \&cwd;
 528         *fastgetcwd     = \&cwd;
 529         *fastcwd        = \&cwd;
 530         *abs_path       = \&fast_abs_path;
 531     }
 532     elsif ($^O eq 'dos') {
 533         *cwd            = \&_dos_cwd;
 534         *getcwd         = \&_dos_cwd;
 535         *fastgetcwd     = \&_dos_cwd;
 536         *fastcwd        = \&_dos_cwd;
 537         *abs_path       = \&fast_abs_path;
 538     }
 539     elsif ($^O =~ m/^(?:qnx|nto)$/ ) {
 540         *cwd            = \&_qnx_cwd;
 541         *getcwd         = \&_qnx_cwd;
 542         *fastgetcwd     = \&_qnx_cwd;
 543         *fastcwd        = \&_qnx_cwd;
 544         *abs_path       = \&_qnx_abs_path;
 545         *fast_abs_path  = \&_qnx_abs_path;
 546     }
 547     elsif ($^O eq 'cygwin') {
 548         *getcwd = \&cwd;
 549         *fastgetcwd     = \&cwd;
 550         *fastcwd        = \&cwd;
 551         *abs_path       = \&fast_abs_path;
 552     }
 553     elsif ($^O eq 'epoc') {
 554         *cwd            = \&_epoc_cwd;
 555         *getcwd         = \&_epoc_cwd;
 556         *fastgetcwd     = \&_epoc_cwd;
 557         *fastcwd        = \&_epoc_cwd;
 558         *abs_path       = \&fast_abs_path;
 559     }
 560     elsif ($^O eq 'MacOS') {
 561         *getcwd     = \&cwd;
 562         *fastgetcwd = \&cwd;
 563         *fastcwd    = \&cwd;
 564         *abs_path   = \&fast_abs_path;
 565     }
 566 }
 567
 568
 569 1;