t/op/stat.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';        # for which_perl() etc
   7 }
   8
   9 use Config;
  10
  11 my ($Null, $Curdir);
  12 if(eval {require File::Spec; 1}) {
  13     $Null = File::Spec->devnull;
  14     $Curdir = File::Spec->curdir;
  15 } else {
  16     die $@ unless is_miniperl();
  17     $Curdir = '.';
  18     diag("miniperl failed to load File::Spec, error is:\n$@");
  19     diag("\ncontinuing, assuming '.' for current directory. Some tests will be skipped.");
  20 }
  21
  22
  23 plan tests => 107;
  24
  25 my $Perl = which_perl();
  26
  27 $Is_Amiga   = $^O eq 'amigaos';
  28 $Is_Cygwin  = $^O eq 'cygwin';
  29 $Is_Darwin  = $^O eq 'darwin';
  30 $Is_Dos     = $^O eq 'dos';
  31 $Is_MPE     = $^O eq 'mpeix';
  32 $Is_MSWin32 = $^O eq 'MSWin32';
  33 $Is_NetWare = $^O eq 'NetWare';
  34 $Is_OS2     = $^O eq 'os2';
  35 $Is_Solaris = $^O eq 'solaris';
  36 $Is_VMS     = $^O eq 'VMS';
  37 $Is_DGUX    = $^O eq 'dgux';
  38 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
  39 $Is_Rhapsody= $^O eq 'rhapsody';
  40
  41 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare;
  42
  43 $Is_UFS     = $Is_Darwin && (() = `df -t ufs . 2>/dev/null`) == 2;
  44
  45 if ($Is_Cygwin) {
  46   require Win32;
  47   Win32->import;
  48 }
  49
  50 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
  51    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
  52
  53 my $tmpfile = tempfile();
  54 my $tmpfile_link = tempfile();
  55
  56 chmod 0666, $tmpfile;
  57 unlink_all $tmpfile;
  58 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  59 close FOO;
  60
  61 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
  62
  63 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
  64
  65 # The clock on a network filesystem might be different from the
  66 # system clock.
  67 my $Filesystem_Time_Offset = abs($mtime - time);
  68
  69 #nlink should if link support configured in Perl.
  70 SKIP: {
  71     skip "No link count - Hard link support not built in.", 1
  72         unless $Config{d_link};
  73
  74     is($nlink, 1, 'nlink on regular file');
  75 }
  76
  77 SKIP: {
  78   skip "mtime and ctime not reliable", 2
  79     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_Darwin;
  80
  81   ok( $mtime,           'mtime' );
  82   is( $mtime, $ctime,   'mtime == ctime' );
  83 }
  84
  85
  86 # Cygwin seems to have a 3 second granularity on its timestamps.
  87 my $funky_FAT_timestamps = $Is_Cygwin;
  88 sleep 3 if $funky_FAT_timestamps;
  89
  90 print FOO "Now is the time for all good men to come to.\n";
  91 close(FOO);
  92
  93 sleep 2;
  94
  95
  96 SKIP: {
  97     unlink $tmpfile_link;
  98     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
  99     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
 100
 101     is( $@, '',         'link() implemented' );
 102     ok( $lnk_result,    'linked tmp testfile' );
 103     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
 104
 105     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
 106
 107     SKIP: {
 108         skip "No link count", 1 if $Config{dont_use_nlink};
 109         skip "Cygwin9X fakes hard links by copying", 1
 110           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
 111
 112         is($nlink, 2,     'Link count on hard linked file' );
 113     }
 114
 115     SKIP: {
 116         skip_if_miniperl("File::Spec not built for minitest", 2);
 117         my $cwd = File::Spec->rel2abs($Curdir);
 118         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
 119                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
 120                                         $mtime && $mtime == $ctime;
 121         skip "AFS has different mtime/ctime link semantics", 2
 122                                      if $cwd =~ m#$Config{'afsroot'}/#;
 123         skip "AmigaOS has different mtime/ctime link semantics", 2
 124                                      if $Is_Amiga;
 125         # Win32 could pass $mtime test but as FAT and NTFS have
 126         # no ctime concept $ctime is ALWAYS == $mtime
 127         # expect netware to be the same ...
 128         skip "No ctime concept on this OS", 2
 129                                      if $Is_MSWin32 ||
 130                                         ($Is_Darwin && $Is_UFS);
 131
 132         if( !ok($mtime, 'hard link mtime') ||
 133             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
 134             print STDERR <<DIAG;
 135 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
 136 # has this problem.  Building on the ClearCase VOBS filesystem may also
 137 # cause this failure.
 138 #
 139 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
 140 # this test.
 141 DIAG
 142         }
 143     }
 144
 145 }
 146
 147 # truncate and touch $tmpfile.
 148 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 149 ok(-z \*F,     '-z on empty filehandle');
 150 ok(! -s \*F,   '   and -s');
 151 close F;
 152
 153 ok(-z $tmpfile,     '-z on empty file');
 154 ok(! -s $tmpfile,   '   and -s');
 155
 156 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
 157 print F "hi\n";
 158 close F;
 159
 160 open(F, "<$tmpfile") || DIE("Can't open temp test file: $!");
 161 ok(!-z *F,     '-z on empty filehandle');
 162 ok( -s *F,   '   and -s');
 163 close F;
 164
 165 ok(! -z $tmpfile,   '-z on non-empty file');
 166 ok(-s $tmpfile,     '   and -s');
 167
 168
 169 # Strip all access rights from the file.
 170 ok( chmod(0000, $tmpfile),     'chmod 0000' );
 171
 172 SKIP: {
 173     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
 174
 175     SKIP: {
 176         # Going to try to switch away from root.  Might not work.
 177         my $olduid = $>;
 178         eval { $> = 1; };
 179         skip "Can't test -r or -w meaningfully if you're superuser", 2
 180           if ($Is_Cygwin ? Win32::IsAdminUser : $> == 0);
 181
 182         SKIP: {
 183             skip "Can't test -r meaningfully?", 1 if $Is_Dos;
 184             ok(!-r $tmpfile,    "   -r");
 185         }
 186
 187         ok(!-w $tmpfile,    "   -w");
 188
 189         # switch uid back (may not be implemented)
 190         eval { $> = $olduid; };
 191     }
 192
 193     ok(! -x $tmpfile,   '   -x');
 194 }
 195
 196
 197
 198 ok(chmod(0700,$tmpfile),    'chmod 0700');
 199 ok(-r $tmpfile,     '   -r');
 200 ok(-w $tmpfile,     '   -w');
 201
 202 SKIP: {
 203     skip "-x simply determines if a file ends in an executable suffix", 1
 204       if $Is_Dosish;
 205
 206     ok(-x $tmpfile,     '   -x');
 207 }
 208
 209 ok(  -f $tmpfile,   '   -f');
 210 ok(! -d $tmpfile,   '   !-d');
 211
 212 # Is this portable?
 213 ok(  -d '.',          '-d cwd' );
 214 ok(! -f '.',          '!-f cwd' );
 215
 216
 217 SKIP: {
 218     unlink($tmpfile_link);
 219     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
 220     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
 221
 222     is( $@, '',     'symlink() implemented' );
 223     ok( $symlink_rslt,      'symlink() ok' );
 224     ok(-l $tmpfile_link,    '-l');
 225 }
 226
 227 ok(-o $tmpfile,     '-o');
 228
 229 ok(-e $tmpfile,     '-e');
 230
 231 unlink($tmpfile_link);
 232 ok(! -e $tmpfile_link,  '   -e on unlinked file');
 233
 234 SKIP: {
 235     skip "No character, socket or block special files", 6
 236       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
 237     skip "/dev isn't available to test against", 6
 238       unless -d '/dev' && -r '/dev' && -x '/dev';
 239     skip "Skipping: unexpected ls output in MP-RAS", 6
 240       if $Is_MPRAS;
 241
 242     # VMS problem:  If GNV or other UNIX like tool is installed, then
 243     # sometimes Perl will find /bin/ls, and will try to run it.
 244     # But since Perl on VMS does not know to run it under Bash, it will
 245     # try to run the DCL verb LS.  And if the VMS product Language
 246     # Sensitive Editor is installed, or some other LS verb, that will
 247     # be run instead.  So do not do this until we can teach Perl
 248     # when to use BASH on VMS.
 249     skip "ls command not available to Perl in OpenVMS right now.", 6
 250       if $Is_VMS;
 251
 252     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
 253     my $CMD = "$LS /dev 2>/dev/null";
 254     my $DEV = qx($CMD);
 255
 256     skip "$CMD failed", 6 if $DEV eq '';
 257
 258     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
 259
 260     skip "opendir failed: $!", 6 if @DEV == 0;
 261
 262     # /dev/stdout might be either character special or a named pipe,
 263     # or a symlink, or a socket, depending on which OS and how are
 264     # you running the test, so let's censor that one away.
 265     # Similar remarks hold for stderr.
 266     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
 267     @DEV =  grep { $_ ne 'stdout' } @DEV;
 268     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
 269     @DEV =  grep { $_ ne 'stderr' } @DEV;
 270
 271     # /dev/printer is also naughty: in IRIX it shows up as
 272     # Srwx-----, not srwx------.
 273     $DEV =~ s{^.+?\sprinter$}{}m;
 274     @DEV =  grep { $_ ne 'printer' } @DEV;
 275
 276     # If running as root, we will see .files in the ls result,
 277     # and readdir() will see them always.  Potential for conflict,
 278     # so let's weed them out.
 279     $DEV =~ s{^.+?\s\..+?$}{}m;
 280     @DEV =  grep { ! m{^\..+$} } @DEV;
 281
 282     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
 283     if ($^O eq 'irix') {
 284         $DEV =~ s{^S(.+?)}{s$1}mg;
 285     }
 286
 287     my $try = sub {
 288         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
 289         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
 290         my $c1 = scalar @c1;
 291         my $c2 = scalar @c2;
 292         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
 293     };
 294
 295 SKIP: {
 296     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
 297
 298     $try->('b', '-b');
 299     $try->('c', '-c');
 300     $try->('s', '-S');
 301
 302 }
 303
 304 ok(! -b $Curdir,    '!-b cwd');
 305 ok(! -c $Curdir,    '!-c cwd');
 306 ok(! -S $Curdir,    '!-S cwd');
 307
 308 }
 309
 310 SKIP: {
 311     my($cnt, $uid);
 312     $cnt = $uid = 0;
 313
 314     # Find a set of directories that's very likely to have setuid files
 315     # but not likely to be *all* setuid files.
 316     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
 317     skip "Can't find a setuid file to test with", 3 unless @bin;
 318
 319     for my $bin (@bin) {
 320         opendir BIN, $bin or die "Can't opendir $bin: $!";
 321         while (defined($_ = readdir BIN)) {
 322             $_ = "$bin/$_";
 323             $cnt++;
 324             $uid++ if -u;
 325             last if $uid && $uid < $cnt;
 326         }
 327     }
 328     closedir BIN;
 329
 330     skip "No setuid programs", 3 if $uid == 0;
 331
 332     isnt($cnt, 0,    'found some programs');
 333     isnt($uid, 0,    '  found some setuid programs');
 334     ok($uid < $cnt,  "    they're not all setuid");
 335 }
 336
 337
 338 # To assist in automated testing when a controlling terminal (/dev/tty)
 339 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
 340 # can be set to skip the tests that need a tty.
 341 SKIP: {
 342     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
 343
 344     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
 345
 346     SKIP: {
 347         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
 348         skip "No TTY to test -t with", 2 unless -e $TTY;
 349
 350         open(TTY, $TTY) ||
 351           warn "Can't open $TTY--run t/TEST outside of make.\n";
 352         ok(-t TTY,  '-t');
 353         ok(-c TTY,  'tty is -c');
 354         close(TTY);
 355     }
 356     ok(! -t TTY,    '!-t on closed TTY filehandle');
 357
 358     {
 359         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
 360         ok(-t,          '-t on STDIN');
 361     }
 362 }
 363
 364 SKIP: {
 365     skip "No null device to test with", 1 unless -e $Null;
 366     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
 367
 368     open(NULL, $Null) or DIE("Can't open $Null: $!");
 369     ok(! -t NULL,   'null device is not a TTY');
 370     close(NULL);
 371 }
 372
 373
 374 # These aren't strictly "stat" calls, but so what?
 375 my $statfile = './op/stat.t';
 376 ok(  -T $statfile,    '-T');
 377 ok(! -B $statfile,    '!-B');
 378
 379 SKIP: {
 380      skip("DG/UX", 1) if $Is_DGUX;
 381 ok(-B $Perl,      '-B');
 382 }
 383
 384 ok(! -T $Perl,    '!-T');
 385
 386 open(FOO,$statfile);
 387 SKIP: {
 388     eval { -T FOO; };
 389     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
 390
 391     is( $@, '',     '-T on filehandle causes no errors' );
 392
 393     ok(-T FOO,      '   -T');
 394     ok(! -B FOO,    '   !-B');
 395
 396     $_ = <FOO>;
 397     like($_, qr/perl/, 'after readline');
 398     ok(-T FOO,      '   still -T');
 399     ok(! -B FOO,    '   still -B');
 400     close(FOO);
 401
 402     open(FOO,$statfile);
 403     $_ = <FOO>;
 404     like($_, qr/perl/,      'reopened and after readline');
 405     ok(-T FOO,      '   still -T');
 406     ok(! -B FOO,    '   still !-B');
 407
 408     ok(seek(FOO,0,0),   'after seek');
 409     ok(-T FOO,          '   still -T');
 410     ok(! -B FOO,        '   still !-B');
 411
 412     # It's documented this way in perlfunc *shrug*
 413     () = <FOO>;
 414     ok(eof FOO,         'at EOF');
 415     ok(-T FOO,          '   still -T');
 416     ok(-B FOO,          '   now -B');
 417 }
 418 close(FOO);
 419
 420
 421 SKIP: {
 422     skip "No null device to test with", 2 unless -e $Null;
 423
 424     ok(-T $Null,  'null device is -T');
 425     ok(-B $Null,  '    and -B');
 426 }
 427
 428
 429 # and now, a few parsing tests:
 430 $_ = $tmpfile;
 431 ok(-f,      'bare -f   uses $_');
 432 ok(-f(),    '     -f() "');
 433
 434 unlink $tmpfile or print "# unlink failed: $!\n";
 435
 436 # bug id 20011101.069
 437 my @r = \stat($Curdir);
 438 is(scalar @r, 13,   'stat returns full 13 elements');
 439
 440 stat $0;
 441 eval { lstat _ };
 442 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 443     'lstat _ croaks after stat' );
 444 eval { -l _ };
 445 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 446     '-l _ croaks after stat' );
 447
 448 lstat $0;
 449 eval { lstat _ };
 450 is( "$@", "", "lstat _ ok after lstat" );
 451 eval { -l _ };
 452 is( "$@", "", "-l _ ok after lstat" );
 453
 454 SKIP: {
 455     skip "No lstat", 2 unless $Config{d_lstat};
 456
 457     # bug id 20020124.004
 458     # If we have d_lstat, we should have symlink()
 459     my $linkname = 'dolzero';
 460     symlink $0, $linkname or die "# Can't symlink $0: $!";
 461     lstat $linkname;
 462     -T _;
 463     eval { lstat _ };
 464     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
 465         'lstat croaks after -T _' );
 466     eval { -l _ };
 467     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
 468         '-l _ croaks after -T _' );
 469     unlink $linkname or print "# unlink $linkname failed: $!\n";
 470 }
 471
 472 SKIP: {
 473     skip "Too much clock skew between system and filesystem", 5
 474         if ($Filesystem_Time_Offset > 5);
 475     print "# Zzz...\n";
 476     sleep($Filesystem_Time_Offset+1);
 477     my $f = 'tstamp.tmp';
 478     unlink $f;
 479     ok (open(S, "> $f"), 'can create tmp file');
 480     close S or die;
 481     my @a = stat $f;
 482     print "# time=$^T, stat=(@a)\n";
 483     my @b = (-M _, -A _, -C _);
 484     print "# -MAC=(@b)\n";
 485     ok( (-M _) < 0, 'negative -M works');
 486     ok( (-A _) < 0, 'negative -A works');
 487     ok( (-C _) < 0, 'negative -C works');
 488     ok(unlink($f), 'unlink tmp file');
 489 }
 490
 491 {
 492     ok(open(F, ">", $tmpfile), 'can create temp file');
 493     close F;
 494     chmod 0077, $tmpfile;
 495     my @a = stat($tmpfile);
 496     my $s1 = -s _;
 497     -T _;
 498     my $s2 = -s _;
 499     is($s1, $s2, q(-T _ doesn't break the statbuffer));
 500     unlink $tmpfile;
 501 }
 502
 503 SKIP: {
 504     skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 505     ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 506     ok(stat(DIR), "stat() on dirhandle works");
 507     ok(-d -r _ , "chained -x's on dirhandle");
 508     ok(-d DIR, "-d on a dirhandle works");
 509
 510     # And now for the ambiguous bareword case
 511     {
 512         no warnings 'deprecated';
 513         ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 514             || diag "Can't open 'TEST':  $!";
 515     }
 516     my $size = (stat(DIR))[7];
 517     ok(defined $size, "stat() on bareword works");
 518     is($size, -s "TEST", "size returned by stat of bareword is for the file");
 519     ok(-f _, "ambiguous bareword uses file handle, not dir handle");
 520     ok(-f DIR);
 521     closedir DIR or die $!;
 522     close DIR or die $!;
 523 }
 524
 525 {
 526     # RT #8244: *FILE{IO} does not behave like *FILE for stat() and -X() operators
 527     ok(open(F, ">", $tmpfile), 'can create temp file');
 528     my @thwap = stat *F{IO};
 529     ok(@thwap, "stat(*F{IO}) works");
 530     ok( -f *F{IO} , "single file tests work with *F{IO}");
 531     close F;
 532     unlink $tmpfile;
 533
 534     #PVIO's hold dirhandle information, so let's test them too.
 535
 536     SKIP: {
 537         skip "No dirfd()", 9 unless $Config{d_dirfd} || $Config{d_dir_dd_fd};
 538         ok(opendir(DIR, "."), 'Can open "." dir') || diag "Can't open '.':  $!";
 539         ok(stat(*DIR{IO}), "stat() on *DIR{IO} works");
 540         ok(-d _ , "The special file handle _ is set correctly");
 541         ok(-d -r *DIR{IO} , "chained -x's on *DIR{IO}");
 542
 543         # And now for the ambiguous bareword case
 544         {
 545             no warnings 'deprecated';
 546             ok(open(DIR, "TEST"), 'Can open "TEST" dir')
 547                 || diag "Can't open 'TEST':  $!";
 548         }
 549         my $size = (stat(*DIR{IO}))[7];
 550         ok(defined $size, "stat() on *THINGY{IO} works");
 551         is($size, -s "TEST",
 552            "size returned by stat of *THINGY{IO} is for the file");
 553         ok(-f _, "ambiguous *THINGY{IO} uses file handle, not dir handle");
 554         ok(-f *DIR{IO});
 555         closedir DIR or die $!;
 556         close DIR or die $!;
 557     }
 558 }
 559
 560 END {
 561     chmod 0666, $tmpfile;
 562     unlink_all $tmpfile;
 563 }