ext/re/re.pm

   1 package re;
   2
   3 # pragma for controlling the regexp engine
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION     = "0.26";
   8 our @ISA         = qw(Exporter);
   9 our @EXPORT_OK   = ('regmust',
  10                     qw(is_regexp regexp_pattern
  11                        regname regnames regnames_count));
  12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
  13
  14 my %bitmask = (
  15     taint   => 0x00100000, # HINT_RE_TAINT
  16     eval    => 0x00200000, # HINT_RE_EVAL
  17 );
  18
  19 my $flags_hint = 0x02000000; # HINT_RE_FLAGS
  20 my $PMMOD_SHIFT = 0;
  21 my %reflags = (
  22     m => 1 << ($PMMOD_SHIFT + 0),
  23     s => 1 << ($PMMOD_SHIFT + 1),
  24     i => 1 << ($PMMOD_SHIFT + 2),
  25     x => 1 << ($PMMOD_SHIFT + 3),
  26     p => 1 << ($PMMOD_SHIFT + 4),
  27 # special cases:
  28     d => 0,
  29     l => 1,
  30     u => 2,
  31     a => 3,
  32     aa => 4,
  33 );
  34
  35 sub setcolor {
  36  eval {                         # Ignore errors
  37   require Term::Cap;
  38
  39   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
  40   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
  41   my @props = split /,/, $props;
  42   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
  43
  44   $colors =~ s/\0//g;
  45   $ENV{PERL_RE_COLORS} = $colors;
  46  };
  47  if ($@) {
  48     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
  49  }
  50
  51 }
  52
  53 my %flags = (
  54     COMPILE         => 0x0000FF,
  55     PARSE           => 0x000001,
  56     OPTIMISE        => 0x000002,
  57     TRIEC           => 0x000004,
  58     DUMP            => 0x000008,
  59     FLAGS           => 0x000010,
  60
  61     EXECUTE         => 0x00FF00,
  62     INTUIT          => 0x000100,
  63     MATCH           => 0x000200,
  64     TRIEE           => 0x000400,
  65
  66     EXTRA           => 0xFF0000,
  67     TRIEM           => 0x010000,
  68     OFFSETS         => 0x020000,
  69     OFFSETSDBG      => 0x040000,
  70     STATE           => 0x080000,
  71     OPTIMISEM       => 0x100000,
  72     STACK           => 0x280000,
  73     BUFFERS         => 0x400000,
  74     GPOS            => 0x800000,
  75 );
  76 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
  77 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
  78 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
  79 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
  80 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
  81 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
  82
  83 if (defined &DynaLoader::boot_DynaLoader) {
  84     require XSLoader;
  85     XSLoader::load();
  86 }
  87 # else we're miniperl
  88 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
  89 # uses re 'taint'.
  90
  91 sub _load_unload {
  92     my ($on)= @_;
  93     if ($on) {
  94         # We call install() every time, as if we didn't, we wouldn't
  95         # "see" any changes to the color environment var since
  96         # the last time it was called.
  97
  98         # install() returns an integer, which if casted properly
  99         # in C resolves to a structure containing the regexp
 100         # hooks. Setting it to a random integer will guarantee
 101         # segfaults.
 102         $^H{regcomp} = install();
 103     } else {
 104         delete $^H{regcomp};
 105     }
 106 }
 107
 108 sub bits {
 109     my $on = shift;
 110     my $bits = 0;
 111    ARG:
 112     foreach my $idx (0..$#_){
 113         my $s=$_[$idx];
 114         if ($s eq 'Debug' or $s eq 'Debugcolor') {
 115             setcolor() if $s =~/color/i;
 116             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
 117             for my $idx ($idx+1..$#_) {
 118                 if ($flags{$_[$idx]}) {
 119                     if ($on) {
 120                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
 121                     } else {
 122                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
 123                     }
 124                 } else {
 125                     require Carp;
 126                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
 127                                join(", ",sort keys %flags ) );
 128                 }
 129             }
 130             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
 131             last;
 132         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
 133             setcolor() if $s =~/color/i;
 134             _load_unload($on);
 135             last;
 136         } elsif (exists $bitmask{$s}) {
 137             $bits |= $bitmask{$s};
 138         } elsif ($EXPORT_OK{$s}) {
 139             require Exporter;
 140             re->export_to_level(2, 're', $s);
 141         } elsif ($s =~ s/^\///) {
 142             my $reflags = $^H{reflags} || 0;
 143             my $seen_charset;
 144             while ($s =~ m/( . )/gx) {
 145                 local $_ = $1;
 146                 if (/[adul]/) {
 147                     # The 'a' may be repeated; hide this from the rest of the
 148                     # code by counting and getting rid of all of them, then
 149                     # changing to 'aa' if there is a repeat.
 150                     if ($_ eq 'a') {
 151                         my $sav_pos = pos $s;
 152                         my $a_count = $s =~ s/a//g;
 153                         pos $s = $sav_pos - 1;  # -1 because got rid of the 'a'
 154                         if ($a_count > 2) {
 155                             require Carp;
 156                             Carp::carp(
 157                             qq 'The "a" flag may only appear a maximum of twice'
 158                             );
 159                         }
 160                         elsif ($a_count == 2) {
 161                             $_ = 'aa';
 162                         }
 163                     }
 164                     if ($on) {
 165                         if ($seen_charset) {
 166                             require Carp;
 167                             if ($seen_charset ne $_) {
 168                                 Carp::carp(
 169                                 qq 'The "$seen_charset" and "$_" flags '
 170                                 .qq 'are exclusive'
 171                                 );
 172                             }
 173                             else {
 174                                 Carp::carp(
 175                                 qq 'The "$seen_charset" flag may not appear '
 176                                 .qq 'twice'
 177                                 );
 178                             }
 179                         }
 180                         $^H{reflags_charset} = $reflags{$_};
 181                         $seen_charset = $_;
 182                     }
 183                     else {
 184                         delete $^H{reflags_charset}
 185                          if  defined $^H{reflags_charset}
 186                           && $^H{reflags_charset} == $reflags{$_};
 187                     }
 188                 } elsif (exists $reflags{$_}) {
 189                     $on
 190                       ? $reflags |= $reflags{$_}
 191                       : ($reflags &= ~$reflags{$_});
 192                 } else {
 193                     require Carp;
 194                     Carp::carp(
 195                      qq'Unknown regular expression flag "$_"'
 196                     );
 197                     next ARG;
 198                 }
 199             }
 200             ($^H{reflags} = $reflags or defined $^H{reflags_charset})
 201              ? $^H |= $flags_hint
 202              : ($^H &= ~$flags_hint);
 203         } else {
 204             require Carp;
 205             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
 206                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
 207                        ")");
 208         }
 209     }
 210     $bits;
 211 }
 212
 213 sub import {
 214     shift;
 215     $^H |= bits(1, @_);
 216 }
 217
 218 sub unimport {
 219     shift;
 220     $^H &= ~ bits(0, @_);
 221 }
 222
 223 1;
 224
 225 __END__
 226
 227 =head1 NAME
 228
 229 re - Perl pragma to alter regular expression behaviour
 230
 231 =head1 SYNOPSIS
 232
 233     use re 'taint';
 234     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
 235
 236     $pat = '(?{ $foo = 1 })';
 237     use re 'eval';
 238     /foo${pat}bar/;                # won't fail (when not under -T
 239                                    # switch)
 240
 241     {
 242         no re 'taint';             # the default
 243         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
 244
 245         no re 'eval';              # the default
 246         /foo${pat}bar/;            # disallowed (with or without -T
 247                                    # switch)
 248     }
 249
 250     use re '/ix';
 251     "FOO" =~ / foo /; # /ix implied
 252     no re '/x';
 253     "FOO" =~ /foo/; # just /i implied
 254
 255     use re 'debug';                # output debugging info during
 256     /^(.*)$/s;                     # compile and run time
 257
 258
 259     use re 'debugcolor';           # same as 'debug', but with colored
 260                                    # output
 261     ...
 262
 263     use re qw(Debug All);          # Same as "use re 'debug'", but you
 264                                    # can use "Debug" with things other
 265                                    # than 'All'
 266     use re qw(Debug More);         # 'All' plus output more details
 267     no re qw(Debug ALL);           # Turn on (almost) all re debugging
 268                                    # in this scope
 269
 270     use re qw(is_regexp regexp_pattern); # import utility functions
 271     my ($pat,$mods)=regexp_pattern(qr/foo/i);
 272     if (is_regexp($obj)) {
 273         print "Got regexp: ",
 274             scalar regexp_pattern($obj); # just as perl would stringify
 275     }                                    # it but no hassle with blessed
 276                                          # re's.
 277
 278 (We use $^X in these examples because it's tainted by default.)
 279
 280 =head1 DESCRIPTION
 281
 282 =head2 'taint' mode
 283
 284 When C<use re 'taint'> is in effect, and a tainted string is the target
 285 of a regexp, the regexp memories (or values returned by the m// operator
 286 in list context) are tainted.  This feature is useful when regexp operations
 287 on tainted data aren't meant to extract safe substrings, but to perform
 288 other transformations.
 289
 290 =head2 'eval' mode
 291
 292 When C<use re 'eval'> is in effect, a regexp is allowed to contain
 293 C<(?{ ... })> zero-width assertions and C<(??{ ... })> postponed
 294 subexpressions that are derived from variable interpolation, rather than
 295 appearing literally within the regexp.  That is normally disallowed, since
 296 it is a
 297 potential security risk.  Note that this pragma is ignored when the regular
 298 expression is obtained from tainted data, i.e.  evaluation is always
 299 disallowed with tainted regular expressions.  See L<perlre/(?{ code })>
 300 and L<perlre/(??{ code })>.
 301
 302 For the purpose of this pragma, interpolation of precompiled regular
 303 expressions (i.e., the result of C<qr//>) is I<not> considered variable
 304 interpolation.  Thus:
 305
 306     /foo${pat}bar/
 307
 308 I<is> allowed if $pat is a precompiled regular expression, even
 309 if $pat contains C<(?{ ... })> assertions or C<(??{ ... })> subexpressions.
 310
 311 =head2 '/flags' mode
 312
 313 When C<use re '/flags'> is specified, the given flags are automatically
 314 added to every regular expression till the end of the lexical scope.
 315
 316 C<no re '/flags'> will turn off the effect of C<use re '/flags'> for the
 317 given flags.
 318
 319 For example, if you want all your regular expressions to have /msx on by
 320 default, simply put
 321
 322     use re '/msx';
 323
 324 at the top of your code.
 325
 326 The character set /adul flags cancel each other out. So, in this example,
 327
 328     use re "/u";
 329     "ss" =~ /\xdf/;
 330     use re "/d";
 331     "ss" =~ /\xdf/;
 332
 333 the second C<use re> does an implicit C<no re '/u'>.
 334
 335 Turning on one of the character set flags with C<use re> takes precedence over the
 336 C<locale> pragma and the 'unicode_strings' C<feature>, for regular
 337 expressions. Turning off one of these flags when it is active reverts to
 338 the behaviour specified by whatever other pragmata are in scope. For
 339 example:
 340
 341     use feature "unicode_strings";
 342     no re "/u"; # does nothing
 343     use re "/l";
 344     no re "/l"; # reverts to unicode_strings behaviour
 345
 346 =head2 'debug' mode
 347
 348 When C<use re 'debug'> is in effect, perl emits debugging messages when
 349 compiling and using regular expressions.  The output is the same as that
 350 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
 351 B<-Dr> switch. It may be quite voluminous depending on the complexity
 352 of the match.  Using C<debugcolor> instead of C<debug> enables a
 353 form of output that can be used to get a colorful display on terminals
 354 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
 355 comma-separated list of C<termcap> properties to use for highlighting
 356 strings on/off, pre-point part on/off.
 357 See L<perldebug/"Debugging Regular Expressions"> for additional info.
 358
 359 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 360 lexically scoped, as the other directives are.  However they have both
 361 compile-time and run-time effects.
 362
 363 See L<perlmodlib/Pragmatic Modules>.
 364
 365 =head2 'Debug' mode
 366
 367 Similarly C<use re 'Debug'> produces debugging output, the difference
 368 being that it allows the fine tuning of what debugging output will be
 369 emitted. Options are divided into three groups, those related to
 370 compilation, those related to execution and those related to special
 371 purposes. The options are as follows:
 372
 373 =over 4
 374
 375 =item Compile related options
 376
 377 =over 4
 378
 379 =item COMPILE
 380
 381 Turns on all compile related debug options.
 382
 383 =item PARSE
 384
 385 Turns on debug output related to the process of parsing the pattern.
 386
 387 =item OPTIMISE
 388
 389 Enables output related to the optimisation phase of compilation.
 390
 391 =item TRIEC
 392
 393 Detailed info about trie compilation.
 394
 395 =item DUMP
 396
 397 Dump the final program out after it is compiled and optimised.
 398
 399 =back
 400
 401 =item Execute related options
 402
 403 =over 4
 404
 405 =item EXECUTE
 406
 407 Turns on all execute related debug options.
 408
 409 =item MATCH
 410
 411 Turns on debugging of the main matching loop.
 412
 413 =item TRIEE
 414
 415 Extra debugging of how tries execute.
 416
 417 =item INTUIT
 418
 419 Enable debugging of start-point optimisations.
 420
 421 =back
 422
 423 =item Extra debugging options
 424
 425 =over 4
 426
 427 =item EXTRA
 428
 429 Turns on all "extra" debugging options.
 430
 431 =item BUFFERS
 432
 433 Enable debugging the capture group storage during match. Warning,
 434 this can potentially produce extremely large output.
 435
 436 =item TRIEM
 437
 438 Enable enhanced TRIE debugging. Enhances both TRIEE
 439 and TRIEC.
 440
 441 =item STATE
 442
 443 Enable debugging of states in the engine.
 444
 445 =item STACK
 446
 447 Enable debugging of the recursion stack in the engine. Enabling
 448 or disabling this option automatically does the same for debugging
 449 states as well. This output from this can be quite large.
 450
 451 =item OPTIMISEM
 452
 453 Enable enhanced optimisation debugging and start-point optimisations.
 454 Probably not useful except when debugging the regexp engine itself.
 455
 456 =item OFFSETS
 457
 458 Dump offset information. This can be used to see how regops correlate
 459 to the pattern. Output format is
 460
 461    NODENUM:POSITION[LENGTH]
 462
 463 Where 1 is the position of the first char in the string. Note that position
 464 can be 0, or larger than the actual length of the pattern, likewise length
 465 can be zero.
 466
 467 =item OFFSETSDBG
 468
 469 Enable debugging of offsets information. This emits copious
 470 amounts of trace information and doesn't mesh well with other
 471 debug options.
 472
 473 Almost definitely only useful to people hacking
 474 on the offsets part of the debug engine.
 475
 476 =back
 477
 478 =item Other useful flags
 479
 480 These are useful shortcuts to save on the typing.
 481
 482 =over 4
 483
 484 =item ALL
 485
 486 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS.
 487 (To get every single option without exception, use both ALL and EXTRA.)
 488
 489 =item All
 490
 491 Enable DUMP and all execute options. Equivalent to:
 492
 493   use re 'debug';
 494
 495 =item MORE
 496
 497 =item More
 498
 499 Enable the options enabled by "All", plus STATE, TRIEC, and TRIEM.
 500
 501 =back
 502
 503 =back
 504
 505 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 506 lexically scoped, as are the other directives.  However they have both
 507 compile-time and run-time effects.
 508
 509 =head2 Exportable Functions
 510
 511 As of perl 5.9.5 're' debug contains a number of utility functions that
 512 may be optionally exported into the caller's namespace. They are listed
 513 below.
 514
 515 =over 4
 516
 517 =item is_regexp($ref)
 518
 519 Returns true if the argument is a compiled regular expression as returned
 520 by C<qr//>, false if it is not.
 521
 522 This function will not be confused by overloading or blessing. In
 523 internals terms, this extracts the regexp pointer out of the
 524 PERL_MAGIC_qr structure so it cannot be fooled.
 525
 526 =item regexp_pattern($ref)
 527
 528 If the argument is a compiled regular expression as returned by C<qr//>,
 529 then this function returns the pattern.
 530
 531 In list context it returns a two element list, the first element
 532 containing the pattern and the second containing the modifiers used when
 533 the pattern was compiled.
 534
 535   my ($pat, $mods) = regexp_pattern($ref);
 536
 537 In scalar context it returns the same as perl would when stringifying a raw
 538 C<qr//> with the same pattern inside.  If the argument is not a compiled
 539 reference then this routine returns false but defined in scalar context,
 540 and the empty list in list context. Thus the following
 541
 542     if (regexp_pattern($ref) eq '(?^i:foo)')
 543
 544 will be warning free regardless of what $ref actually is.
 545
 546 Like C<is_regexp> this function will not be confused by overloading
 547 or blessing of the object.
 548
 549 =item regmust($ref)
 550
 551 If the argument is a compiled regular expression as returned by C<qr//>,
 552 then this function returns what the optimiser considers to be the longest
 553 anchored fixed string and longest floating fixed string in the pattern.
 554
 555 A I<fixed string> is defined as being a substring that must appear for the
 556 pattern to match. An I<anchored fixed string> is a fixed string that must
 557 appear at a particular offset from the beginning of the match. A I<floating
 558 fixed string> is defined as a fixed string that can appear at any point in
 559 a range of positions relative to the start of the match. For example,
 560
 561     my $qr = qr/here .* there/x;
 562     my ($anchored, $floating) = regmust($qr);
 563     print "anchored:'$anchored'\nfloating:'$floating'\n";
 564
 565 results in
 566
 567     anchored:'here'
 568     floating:'there'
 569
 570 Because the C<here> is before the C<.*> in the pattern, its position
 571 can be determined exactly. That's not true, however, for the C<there>;
 572 it could appear at any point after where the anchored string appeared.
 573 Perl uses both for its optimisations, preferring the longer, or, if they are
 574 equal, the floating.
 575
 576 B<NOTE:> This may not necessarily be the definitive longest anchored and
 577 floating string. This will be what the optimiser of the Perl that you
 578 are using thinks is the longest. If you believe that the result is wrong
 579 please report it via the L<perlbug> utility.
 580
 581 =item regname($name,$all)
 582
 583 Returns the contents of a named buffer of the last successful match. If
 584 $all is true, then returns an array ref containing one entry per buffer,
 585 otherwise returns the first defined buffer.
 586
 587 =item regnames($all)
 588
 589 Returns a list of all of the named buffers defined in the last successful
 590 match. If $all is true, then it returns all names defined, if not it returns
 591 only names which were involved in the match.
 592
 593 =item regnames_count()
 594
 595 Returns the number of distinct names defined in the pattern used
 596 for the last successful match.
 597
 598 B<Note:> this result is always the actual number of distinct
 599 named buffers defined, it may not actually match that which is
 600 returned by C<regnames()> and related routines when those routines
 601 have not been called with the $all parameter set.
 602
 603 =back
 604
 605 =head1 SEE ALSO
 606
 607 L<perlmodlib/Pragmatic Modules>.
 608
 609 =cut