t/io/eintr.t

   1 #!./perl
   2
   3 # If a read or write is interrupted by a signal, Perl will call the
   4 # signal handler and then attempt to restart the call. If the handler does
   5 # something nasty like close the handle or pop layers, make sure that the
   6 # read/write handles this gracefully (for some definition of 'graceful':
   7 # principally, don't segfault).
   8
   9 BEGIN {
  10     chdir 't' if -d 't';
  11     @INC = '../lib';
  12 }
  13
  14 use warnings;
  15 use strict;
  16 use Config;
  17
  18 require './test.pl';
  19
  20 my $piped;
  21 eval {
  22         pipe my $in, my $out;
  23         $piped = 1;
  24 };
  25 if (!$piped) {
  26         skip_all('pipe not implemented');
  27         exit 0;
  28 }
  29 unless (exists  $Config{'d_alarm'}) {
  30         skip_all('alarm not implemented');
  31         exit 0;
  32 }
  33
  34 # XXX for some reason the stdio layer doesn't seem to interrupt
  35 # write system call when the alarm triggers.  This makes the tests
  36 # hang.
  37
  38 if (exists $ENV{PERLIO} && $ENV{PERLIO} =~ /stdio/  ) {
  39         skip_all('stdio not supported for this script');
  40         exit 0;
  41 }
  42
  43 # on Win32, alarm() won't interrupt the read/write call.
  44 # Similar issues with VMS.
  45 # On FreeBSD, writes to pipes of 8192 bytes or more use a mechanism
  46 # that is not interruptible (see perl #85842 and #84688).
  47 # "close during print" also hangs on Solaris 8 (but not 10 or 11).
  48 #
  49 # Also skip on release builds, to avoid other possibly problematic
  50 # platforms
  51
  52 my ($osmajmin) = $Config{osvers} =~ /^(\d+\.\d+)/;
  53 if ($^O eq 'VMS' || $^O eq 'MSWin32' || $^O eq 'cygwin' || $^O =~ /freebsd/ || $^O eq 'midnightbsd' ||
  54      ($^O eq 'solaris' && $Config{osvers} eq '2.8') || $^O eq 'nto' ||
  55      ($^O eq 'darwin' && $osmajmin < 9) ||
  56     ((int($]*1000) & 1) == 0)
  57 ) {
  58         skip_all('various portability issues');
  59         exit 0;
  60 }
  61
  62 my ($in, $out, $st, $sigst, $buf);
  63
  64 plan(tests => 10);
  65
  66
  67 # make two handles that will always block
  68
  69 sub fresh_io {
  70         undef $in; undef $out; # use fresh handles each time
  71         pipe $in, $out;
  72         $sigst = "";
  73 }
  74
  75 $SIG{PIPE} = 'IGNORE';
  76
  77 # close during read
  78
  79 fresh_io;
  80 $SIG{ALRM} = sub { $sigst = close($in) ? "ok" : "nok" };
  81 alarm(1);
  82 $st = read($in, $buf, 1);
  83 alarm(0);
  84 is($sigst, 'ok', 'read/close: sig handler close status');
  85 ok(!$st, 'read/close: read status');
  86 ok(!close($in), 'read/close: close status');
  87
  88 # die during read
  89
  90 fresh_io;
  91 $SIG{ALRM} = sub { die };
  92 alarm(1);
  93 $st = eval { read($in, $buf, 1) };
  94 alarm(0);
  95 ok(!$st, 'read/die: read status');
  96 ok(close($in), 'read/die: close status');
  97
  98 # close during print
  99
 100 fresh_io;
 101 $SIG{ALRM} = sub { $sigst = close($out) ? "ok" : "nok" };
 102 $buf = "a" x 1_000_000 . "\n"; # bigger than any pipe buffer hopefully
 103 select $out; $| = 1; select STDOUT;
 104 alarm(1);
 105 $st = print $out $buf;
 106 alarm(0);
 107 is($sigst, 'nok', 'print/close: sig handler close status');
 108 ok(!$st, 'print/close: print status');
 109 ok(!close($out), 'print/close: close status');
 110
 111 # die during print
 112
 113 fresh_io;
 114 $SIG{ALRM} = sub { die };
 115 $buf = "a" x 1_000_000 . "\n"; # bigger than any pipe buffer hopefully
 116 select $out; $| = 1; select STDOUT;
 117 alarm(1);
 118 $st = eval { print $out $buf };
 119 alarm(0);
 120 ok(!$st, 'print/die: print status');
 121 # the close will hang since there's data to flush, so use alarm
 122 alarm(1);
 123 ok(!eval {close($out)}, 'print/die: close status');
 124 alarm(0);
 125
 126 # close during close
 127
 128 # Apparently there's nothing in standard Linux that can cause an
 129 # EINTR in close(2); but run the code below just in case it does on some
 130 # platform, just to see if it segfaults.
 131 fresh_io;
 132 $SIG{ALRM} = sub { $sigst = close($in) ? "ok" : "nok" };
 133 alarm(1);
 134 close $in;
 135 alarm(0);
 136
 137 # die during close
 138
 139 fresh_io;
 140 $SIG{ALRM} = sub { die };
 141 alarm(1);
 142 eval { close $in };
 143 alarm(0);
 144
 145 # vim: ts=4 sts=4 sw=4: