utils/h2xs.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 my $origdir = cwd;
  17 chdir dirname($0);
  18 my $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 use warnings;
  39
  40 =head1 NAME
  41
  42 h2xs - convert .h C header files to Perl extensions
  43
  44 =head1 SYNOPSIS
  45
  46 B<h2xs> [B<OPTIONS> ...] [headerfile ... [extra_libraries]]
  47
  48 B<h2xs> B<-h>|B<-?>|B<--help>
  49
  50 =head1 DESCRIPTION
  51
  52 I<h2xs> builds a Perl extension from C header files.  The extension
  53 will include functions which can be used to retrieve the value of any
  54 #define statement which was in the C header files.
  55
  56 The I<module_name> will be used for the name of the extension.  If
  57 module_name is not supplied then the name of the first header file
  58 will be used, with the first character capitalized.
  59
  60 If the extension might need extra libraries, they should be included
  61 here.  The extension Makefile.PL will take care of checking whether
  62 the libraries actually exist and how they should be loaded.  The extra
  63 libraries should be specified in the form -lm -lposix, etc, just as on
  64 the cc command line.  By default, the Makefile.PL will search through
  65 the library path determined by Configure.  That path can be augmented
  66 by including arguments of the form B<-L/another/library/path> in the
  67 extra-libraries argument.
  68
  69 =head1 OPTIONS
  70
  71 =over 5
  72
  73 =item B<-A>, B<--omit-autoload>
  74
  75 Omit all autoload facilities.  This is the same as B<-c> but also
  76 removes the S<C<use AutoLoader>> statement from the .pm file.
  77
  78 =item B<-B>, B<--beta-version>
  79
  80 Use an alpha/beta style version number.  Causes version number to
  81 be "0.00_01" unless B<-v> is specified.
  82
  83 =item B<-C>, B<--omit-changes>
  84
  85 Omits creation of the F<Changes> file, and adds a HISTORY section to
  86 the POD template.
  87
  88 =item B<-F>, B<--cpp-flags>=I<addflags>
  89
  90 Additional flags to specify to C preprocessor when scanning header for
  91 function declarations.  Writes these options in the generated F<Makefile.PL>
  92 too.
  93
  94 =item B<-M>, B<--func-mask>=I<regular expression>
  95
  96 selects functions/macros to process.
  97
  98 =item B<-O>, B<--overwrite-ok>
  99
 100 Allows a pre-existing extension directory to be overwritten.
 101
 102 =item B<-P>, B<--omit-pod>
 103
 104 Omit the autogenerated stub POD section.
 105
 106 =item B<-X>, B<--omit-XS>
 107
 108 Omit the XS portion.  Used to generate templates for a module which is not
 109 XS-based.  C<-c> and C<-f> are implicitly enabled.
 110
 111 =item B<-a>, B<--gen-accessors>
 112
 113 Generate an accessor method for each element of structs and unions. The
 114 generated methods are named after the element name; will return the current
 115 value of the element if called without additional arguments; and will set
 116 the element to the supplied value (and return the new value) if called with
 117 an additional argument. Embedded structures and unions are returned as a
 118 pointer rather than the complete structure, to facilitate chained calls.
 119
 120 These methods all apply to the Ptr type for the structure; additionally
 121 two methods are constructed for the structure type itself, C<_to_ptr>
 122 which returns a Ptr type pointing to the same structure, and a C<new>
 123 method to construct and return a new structure, initialised to zeroes.
 124
 125 =item B<-b>, B<--compat-version>=I<version>
 126
 127 Generates a .pm file which is backwards compatible with the specified
 128 perl version.
 129
 130 For versions < 5.6.0, the changes are.
 131     - no use of 'our' (uses 'use vars' instead)
 132     - no 'use warnings'
 133
 134 Specifying a compatibility version higher than the version of perl you
 135 are using to run h2xs will have no effect.  If unspecified h2xs will default
 136 to compatibility with the version of perl you are using to run h2xs.
 137
 138 =item B<-c>, B<--omit-constant>
 139
 140 Omit C<constant()> from the .xs file and corresponding specialised
 141 C<AUTOLOAD> from the .pm file.
 142
 143 =item B<-d>, B<--debugging>
 144
 145 Turn on debugging messages.
 146
 147 =item B<-e>, B<--omit-enums>=[I<regular expression>]
 148
 149 If I<regular expression> is not given, skip all constants that are defined in
 150 a C enumeration. Otherwise skip only those constants that are defined in an
 151 enum whose name matches I<regular expression>.
 152
 153 Since I<regular expression> is optional, make sure that this switch is followed
 154 by at least one other switch if you omit I<regular expression> and have some
 155 pending arguments such as header-file names. This is ok:
 156
 157     h2xs -e -n Module::Foo foo.h
 158
 159 This is not ok:
 160
 161     h2xs -n Module::Foo -e foo.h
 162
 163 In the latter, foo.h is taken as I<regular expression>.
 164
 165 =item B<-f>, B<--force>
 166
 167 Allows an extension to be created for a header even if that header is
 168 not found in standard include directories.
 169
 170 =item B<-g>, B<--global>
 171
 172 Include code for safely storing static data in the .xs file.
 173 Extensions that do no make use of static data can ignore this option.
 174
 175 =item B<-h>, B<-?>, B<--help>
 176
 177 Print the usage, help and version for this h2xs and exit.
 178
 179 =item B<-k>, B<--omit-const-func>
 180
 181 For function arguments declared as C<const>, omit the const attribute in the
 182 generated XS code.
 183
 184 =item B<-m>, B<--gen-tied-var>
 185
 186 B<Experimental>: for each variable declared in the header file(s), declare
 187 a perl variable of the same name magically tied to the C variable.
 188
 189 =item B<-n>, B<--name>=I<module_name>
 190
 191 Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
 192
 193 =item B<-o>, B<--opaque-re>=I<regular expression>
 194
 195 Use "opaque" data type for the C types matched by the regular
 196 expression, even if these types are C<typedef>-equivalent to types
 197 from typemaps.  Should not be used without B<-x>.
 198
 199 This may be useful since, say, types which are C<typedef>-equivalent
 200 to integers may represent OS-related handles, and one may want to work
 201 with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
 202 Use C<-o .> if you want to handle all the C<typedef>ed types as opaque
 203 types.
 204
 205 The type-to-match is whitewashed (except for commas, which have no
 206 whitespace before them, and multiple C<*> which have no whitespace
 207 between them).
 208
 209 =item B<-p>, B<--remove-prefix>=I<prefix>
 210
 211 Specify a prefix which should be removed from the Perl function names,
 212 e.g., S<-p sec_rgy_> This sets up the XS B<PREFIX> keyword and removes
 213 the prefix from functions that are autoloaded via the C<constant()>
 214 mechanism.
 215
 216 =item B<-s>, B<--const-subs>=I<sub1,sub2>
 217
 218 Create a perl subroutine for the specified macros rather than autoload
 219 with the constant() subroutine.  These macros are assumed to have a
 220 return type of B<char *>, e.g.,
 221 S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
 222
 223 =item B<-t>, B<--default-type>=I<type>
 224
 225 Specify the internal type that the constant() mechanism uses for macros.
 226 The default is IV (signed integer).  Currently all macros found during the
 227 header scanning process will be assumed to have this type.  Future versions
 228 of C<h2xs> may gain the ability to make educated guesses.
 229
 230 =item B<--use-new-tests>
 231
 232 When B<--compat-version> (B<-b>) is present the generated tests will use
 233 C<Test::More> rather than C<Test> which is the default for versions before
 234 5.7.2 .   C<Test::More> will be added to PREREQ_PM in the generated
 235 C<Makefile.PL>.
 236
 237 =item B<--use-old-tests>
 238
 239 Will force the generation of test code that uses the older C<Test> module.
 240
 241 =item B<--skip-exporter>
 242
 243 Do not use C<Exporter> and/or export any symbol.
 244
 245 =item B<--skip-ppport>
 246
 247 Do not use C<Devel::PPPort>: no portability to older version.
 248
 249 =item B<--skip-autoloader>
 250
 251 Do not use the module C<AutoLoader>; but keep the constant() function
 252 and C<sub AUTOLOAD> for constants.
 253
 254 =item B<--skip-strict>
 255
 256 Do not use the pragma C<strict>.
 257
 258 =item B<--skip-warnings>
 259
 260 Do not use the pragma C<warnings>.
 261
 262 =item B<-v>, B<--version>=I<version>
 263
 264 Specify a version number for this extension.  This version number is added
 265 to the templates.  The default is 0.01, or 0.00_01 if C<-B> is specified.
 266 The version specified should be numeric.
 267
 268 =item B<-x>, B<--autogen-xsubs>
 269
 270 Automatically generate XSUBs basing on function declarations in the
 271 header file.  The package C<C::Scan> should be installed. If this
 272 option is specified, the name of the header file may look like
 273 C<NAME1,NAME2>. In this case NAME1 is used instead of the specified
 274 string, but XSUBs are emitted only for the declarations included from
 275 file NAME2.
 276
 277 Note that some types of arguments/return-values for functions may
 278 result in XSUB-declarations/typemap-entries which need
 279 hand-editing. Such may be objects which cannot be converted from/to a
 280 pointer (like C<long long>), pointers to functions, or arrays.  See
 281 also the section on L<LIMITATIONS of B<-x>>.
 282
 283 =back
 284
 285 =head1 EXAMPLES
 286
 287
 288     # Default behavior, extension is Rusers
 289     h2xs rpcsvc/rusers
 290
 291     # Same, but extension is RUSERS
 292     h2xs -n RUSERS rpcsvc/rusers
 293
 294     # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
 295     h2xs rpcsvc::rusers
 296
 297     # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
 298     h2xs -n ONC::RPC rpcsvc/rusers
 299
 300     # Without constant() or AUTOLOAD
 301     h2xs -c rpcsvc/rusers
 302
 303     # Creates templates for an extension named RPC
 304     h2xs -cfn RPC
 305
 306     # Extension is ONC::RPC.
 307     h2xs -cfn ONC::RPC
 308
 309     # Extension is Lib::Foo which works at least with Perl5.005_03.
 310     # Constants are created for all #defines and enums h2xs can find
 311     # in foo.h.
 312     h2xs -b 5.5.3 -n Lib::Foo foo.h
 313
 314     # Extension is Lib::Foo which works at least with Perl5.005_03.
 315     # Constants are created for all #defines but only for enums
 316     # whose names do not start with 'bar_'.
 317     h2xs -b 5.5.3 -e '^bar_' -n Lib::Foo foo.h
 318
 319     # Makefile.PL will look for library -lrpc in
 320     # additional directory /opt/net/lib
 321     h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
 322
 323     # Extension is DCE::rgynbase
 324     # prefix "sec_rgy_" is dropped from perl function names
 325     h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
 326
 327     # Extension is DCE::rgynbase
 328     # prefix "sec_rgy_" is dropped from perl function names
 329     # subroutines are created for sec_rgy_wildcard_name and
 330     # sec_rgy_wildcard_sid
 331     h2xs -n DCE::rgynbase -p sec_rgy_ \
 332     -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
 333
 334     # Make XS without defines in perl.h, but with function declarations
 335     # visible from perl.h. Name of the extension is perl1.
 336     # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
 337     # Extra backslashes below because the string is passed to shell.
 338     # Note that a directory with perl header files would
 339     #  be added automatically to include path.
 340     h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
 341
 342     # Same with function declaration in proto.h as visible from perl.h.
 343     h2xs -xAn perl2 perl.h,proto.h
 344
 345     # Same but select only functions which match /^av_/
 346     h2xs -M '^av_' -xAn perl2 perl.h,proto.h
 347
 348     # Same but treat SV* etc as "opaque" types
 349     h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
 350
 351 =head2 Extension based on F<.h> and F<.c> files
 352
 353 Suppose that you have some C files implementing some functionality,
 354 and the corresponding header files.  How to create an extension which
 355 makes this functionality accessable in Perl?  The example below
 356 assumes that the header files are F<interface_simple.h> and
 357 I<interface_hairy.h>, and you want the perl module be named as
 358 C<Ext::Ension>.  If you need some preprocessor directives and/or
 359 linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
 360 in L<"OPTIONS">.
 361
 362 =over
 363
 364 =item Find the directory name
 365
 366 Start with a dummy run of h2xs:
 367
 368   h2xs -Afn Ext::Ension
 369
 370 The only purpose of this step is to create the needed directories, and
 371 let you know the names of these directories.  From the output you can
 372 see that the directory for the extension is F<Ext/Ension>.
 373
 374 =item Copy C files
 375
 376 Copy your header files and C files to this directory F<Ext/Ension>.
 377
 378 =item Create the extension
 379
 380 Run h2xs, overwriting older autogenerated files:
 381
 382   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
 383
 384 h2xs looks for header files I<after> changing to the extension
 385 directory, so it will find your header files OK.
 386
 387 =item Archive and test
 388
 389 As usual, run
 390
 391   cd Ext/Ension
 392   perl Makefile.PL
 393   make dist
 394   make
 395   make test
 396
 397 =item Hints
 398
 399 It is important to do C<make dist> as early as possible.  This way you
 400 can easily merge(1) your changes to autogenerated files if you decide
 401 to edit your C<.h> files and rerun h2xs.
 402
 403 Do not forget to edit the documentation in the generated F<.pm> file.
 404
 405 Consider the autogenerated files as skeletons only, you may invent
 406 better interfaces than what h2xs could guess.
 407
 408 Consider this section as a guideline only, some other options of h2xs
 409 may better suit your needs.
 410
 411 =back
 412
 413 =head1 ENVIRONMENT
 414
 415 No environment variables are used.
 416
 417 =head1 AUTHOR
 418
 419 Larry Wall and others
 420
 421 =head1 SEE ALSO
 422
 423 L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
 424
 425 =head1 DIAGNOSTICS
 426
 427 The usual warnings if it cannot read or write the files involved.
 428
 429 =head1 LIMITATIONS of B<-x>
 430
 431 F<h2xs> would not distinguish whether an argument to a C function
 432 which is of the form, say, C<int *>, is an input, output, or
 433 input/output parameter.  In particular, argument declarations of the
 434 form
 435
 436     int
 437     foo(n)
 438         int *n
 439
 440 should be better rewritten as
 441
 442     int
 443     foo(n)
 444         int &n
 445
 446 if C<n> is an input parameter.
 447
 448 Additionally, F<h2xs> has no facilities to intuit that a function
 449
 450    int
 451    foo(addr,l)
 452         char *addr
 453         int   l
 454
 455 takes a pair of address and length of data at this address, so it is better
 456 to rewrite this function as
 457
 458     int
 459     foo(sv)
 460             SV *addr
 461         PREINIT:
 462             STRLEN len;
 463             char *s;
 464         CODE:
 465             s = SvPV(sv,len);
 466             RETVAL = foo(s, len);
 467         OUTPUT:
 468             RETVAL
 469
 470 or alternately
 471
 472     static int
 473     my_foo(SV *sv)
 474     {
 475         STRLEN len;
 476         char *s = SvPV(sv,len);
 477
 478         return foo(s, len);
 479     }
 480
 481     MODULE = foo        PACKAGE = foo   PREFIX = my_
 482
 483     int
 484     foo(sv)
 485         SV *sv
 486
 487 See L<perlxs> and L<perlxstut> for additional details.
 488
 489 =cut
 490
 491 # ' # Grr
 492 use strict;
 493
 494
 495 my( $H2XS_VERSION ) = ' $Revision: 1.23 $ ' =~ /\$Revision:\s+([^\s]+)/;
 496 my $TEMPLATE_VERSION = '0.01';
 497 my @ARGS = @ARGV;
 498 my $compat_version = $];
 499
 500 use Getopt::Long;
 501 use Config;
 502 use Text::Wrap;
 503 $Text::Wrap::huge = 'overflow';
 504 $Text::Wrap::columns = 80;
 505 use ExtUtils::Constant qw (WriteConstants WriteMakefileSnippet autoload);
 506 use File::Compare;
 507 use File::Path;
 508
 509 sub usage {
 510     warn "@_\n" if @_;
 511     die <<EOFUSAGE;
 512 h2xs [OPTIONS ... ] [headerfile [extra_libraries]]
 513 version: $H2XS_VERSION
 514 OPTIONS:
 515     -A, --omit-autoload   Omit all autoloading facilities (implies -c).
 516     -B, --beta-version    Use beta \$VERSION of 0.00_01 (ignored if -v).
 517     -C, --omit-changes    Omit creating the Changes file, add HISTORY heading
 518                           to stub POD.
 519     -F, --cpp-flags       Additional flags for C preprocessor/compile.
 520     -M, --func-mask       Mask to select C functions/macros
 521                           (default is select all).
 522     -O, --overwrite-ok    Allow overwriting of a pre-existing extension directory.
 523     -P, --omit-pod        Omit the stub POD section.
 524     -X, --omit-XS         Omit the XS portion (implies both -c and -f).
 525     -a, --gen-accessors   Generate get/set accessors for struct and union members                           (used with -x).
 526     -b, --compat-version  Specify a perl version to be backwards compatibile with
 527     -c, --omit-constant   Omit the constant() function and specialised AUTOLOAD
 528                           from the XS file.
 529     -d, --debugging       Turn on debugging messages.
 530     -e, --omit-enums      Omit constants from enums in the constant() function.
 531                           If a pattern is given, only the matching enums are
 532                           ignored.
 533     -f, --force           Force creation of the extension even if the C header
 534                           does not exist.
 535     -g, --global          Include code for safely storing static data in the .xs file.
 536     -h, -?, --help        Display this help message
 537     -k, --omit-const-func Omit 'const' attribute on function arguments
 538                           (used with -x).
 539     -m, --gen-tied-var    Generate tied variables for access to declared
 540                           variables.
 541     -n, --name            Specify a name to use for the extension (recommended).
 542     -o, --opaque-re       Regular expression for \"opaque\" types.
 543     -p, --remove-prefix   Specify a prefix which should be removed from the
 544                           Perl function names.
 545     -s, --const-subs      Create subroutines for specified macros.
 546     -t, --default-type    Default type for autoloaded constants (default is IV)
 547         --use-new-tests   Use Test::More in backward compatible modules
 548         --use-old-tests   Use the module Test rather than Test::More
 549         --skip-exporter   Do not export symbols
 550         --skip-ppport     Do not use portability layer
 551         --skip-autoloader Do not use the module C<AutoLoader>
 552         --skip-strict     Do not use the pragma C<strict>
 553         --skip-warnings   Do not use the pragma C<warnings>
 554     -v, --version         Specify a version number for this extension.
 555     -x, --autogen-xsubs   Autogenerate XSUBs using C::Scan.
 556
 557 extra_libraries
 558          are any libraries that might be needed for loading the
 559          extension, e.g. -lm would try to link in the math library.
 560 EOFUSAGE
 561 }
 562
 563 my ($opt_A,
 564     $opt_B,
 565     $opt_C,
 566     $opt_F,
 567     $opt_M,
 568     $opt_O,
 569     $opt_P,
 570     $opt_X,
 571     $opt_a,
 572     $opt_c,
 573     $opt_d,
 574     $opt_e,
 575     $opt_f,
 576     $opt_g,
 577     $opt_h,
 578     $opt_k,
 579     $opt_m,
 580     $opt_n,
 581     $opt_o,
 582     $opt_p,
 583     $opt_s,
 584     $opt_v,
 585     $opt_x,
 586     $opt_b,
 587     $opt_t,
 588     $new_test,
 589     $old_test,
 590     $skip_exporter,
 591     $skip_ppport,
 592     $skip_autoloader,
 593     $skip_strict,
 594     $skip_warnings,
 595    );
 596
 597 Getopt::Long::Configure('bundling');
 598 Getopt::Long::Configure('pass_through');
 599
 600 my %options = (
 601                 'omit-autoload|A'    => \$opt_A,
 602                 'beta-version|B'     => \$opt_B,
 603                 'omit-changes|C'     => \$opt_C,
 604                 'cpp-flags|F=s'      => \$opt_F,
 605                 'func-mask|M=s'      => \$opt_M,
 606                 'overwrite_ok|O'     => \$opt_O,
 607                 'omit-pod|P'         => \$opt_P,
 608                 'omit-XS|X'          => \$opt_X,
 609                 'gen-accessors|a'    => \$opt_a,
 610                 'compat-version|b=s' => \$opt_b,
 611                 'omit-constant|c'    => \$opt_c,
 612                 'debugging|d'        => \$opt_d,
 613                 'omit-enums|e:s'     => \$opt_e,
 614                 'force|f'            => \$opt_f,
 615                 'global|g'           => \$opt_g,
 616                 'help|h|?'           => \$opt_h,
 617                 'omit-const-func|k'  => \$opt_k,
 618                 'gen-tied-var|m'     => \$opt_m,
 619                 'name|n=s'           => \$opt_n,
 620                 'opaque-re|o=s'      => \$opt_o,
 621                 'remove-prefix|p=s'  => \$opt_p,
 622                 'const-subs|s=s'     => \$opt_s,
 623                 'default-type|t=s'   => \$opt_t,
 624                 'version|v=s'        => \$opt_v,
 625                 'autogen-xsubs|x'    => \$opt_x,
 626                 'use-new-tests'      => \$new_test,
 627                 'use-old-tests'      => \$old_test,
 628                 'skip-exporter'      => \$skip_exporter,
 629                 'skip-ppport'        => \$skip_ppport,
 630                 'skip-autoloader'    => \$skip_autoloader,
 631                 'skip-warnings'      => \$skip_warnings,
 632                 'skip-strict'        => \$skip_strict,
 633               );
 634
 635 GetOptions(%options) || usage;
 636
 637 usage if $opt_h;
 638
 639 if( $opt_b ){
 640     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
 641     $opt_b =~ /^\d+\.\d+\.\d+/ ||
 642     usage "You must provide the backwards compatibility version in X.Y.Z form. "
 643           .  "(i.e. 5.5.0)\n";
 644     my ($maj,$min,$sub) = split(/\./,$opt_b,3);
 645     if ($maj < 5 || ($maj == 5 && $min < 6)) {
 646         $compat_version =
 647             $sub ? sprintf("%d.%03d%02d",$maj,$min,$sub) :
 648                    sprintf("%d.%03d",    $maj,$min);
 649     } else {
 650         $compat_version =
 651             $sub ? sprintf("%d.%03d%03d",$maj,$min,$sub) :
 652                    sprintf("%d.%03d",    $maj,$min);
 653     }
 654 } else {
 655     my ($maj,$min,$sub) = $compat_version =~ /(\d+)\.(\d\d\d)(\d*)/;
 656     $sub ||= 0;
 657     warn sprintf <<'EOF', $maj,$min,$sub;
 658 Defaulting to backwards compatibility with perl %d.%d.%d
 659 If you intend this module to be compatible with earlier perl versions, please
 660 specify a minimum perl version with the -b option.
 661
 662 EOF
 663 }
 664
 665 if( $opt_B ){
 666     $TEMPLATE_VERSION = '0.00_01';
 667 }
 668
 669 if( $opt_v ){
 670         $TEMPLATE_VERSION = $opt_v;
 671
 672     # check if it is numeric
 673     my $temp_version = $TEMPLATE_VERSION;
 674     my $beta_version = $temp_version =~ s/(\d)_(\d\d)/$1$2/;
 675     my $notnum;
 676     {
 677         local $SIG{__WARN__} = sub { $notnum = 1 };
 678         use warnings 'numeric';
 679         $temp_version = 0+$temp_version;
 680     }
 681
 682     if ($notnum) {
 683         my $module = $opt_n || 'Your::Module';
 684         warn <<"EOF";
 685 You have specified a non-numeric version.  Unless you supply an
 686 appropriate VERSION class method, users may not be able to specify a
 687 minimum required version with C<use $module versionnum>.
 688
 689 EOF
 690     }
 691     else {
 692         $opt_B = $beta_version;
 693     }
 694 }
 695
 696 # -A implies -c.
 697 $skip_autoloader = $opt_c = 1 if $opt_A;
 698
 699 # -X implies -c and -f
 700 $opt_c = $opt_f = 1 if $opt_X;
 701
 702 $opt_t ||= 'IV';
 703
 704 my %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
 705
 706 my $extralibs = '';
 707
 708 my @path_h;
 709
 710 while (my $arg = shift) {
 711     if ($arg =~ /^-l/i) {
 712         $extralibs .= "$arg ";
 713         next;
 714     }
 715     last if $extralibs;
 716     push(@path_h, $arg);
 717 }
 718
 719 usage "Must supply header file or module name\n"
 720         unless (@path_h or $opt_n);
 721
 722 my $fmask;
 723 my $tmask;
 724
 725 $fmask = qr{$opt_M} if defined $opt_M;
 726 $tmask = qr{$opt_o} if defined $opt_o;
 727 my $tmask_all = $tmask && $opt_o eq '.';
 728
 729 if ($opt_x) {
 730   eval {require C::Scan; 1}
 731     or die <<EOD;
 732 C::Scan required if you use -x option.
 733 To install C::Scan, execute
 734    perl -MCPAN -e "install C::Scan"
 735 EOD
 736   unless ($tmask_all) {
 737     $C::Scan::VERSION >= 0.70
 738       or die <<EOD;
 739 C::Scan v. 0.70 or later required unless you use -o . option.
 740 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 741 To install C::Scan, execute
 742    perl -MCPAN -e "install C::Scan"
 743 EOD
 744   }
 745   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
 746     die <<EOD;
 747 C::Scan v. 0.73 or later required to use -m or -a options.
 748 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 749 To install C::Scan, execute
 750    perl -MCPAN -e "install C::Scan"
 751 EOD
 752   }
 753 }
 754 elsif ($opt_o or $opt_F) {
 755   warn <<EOD if $opt_o;
 756 Option -o does not make sense without -x.
 757 EOD
 758   warn <<EOD if $opt_F and $opt_X ;
 759 Option -F does not make sense with -X.
 760 EOD
 761 }
 762
 763 my @path_h_ini = @path_h;
 764 my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
 765
 766 my $module = $opt_n;
 767
 768 if( @path_h ){
 769     use File::Spec;
 770     my @paths;
 771     my $pre_sub_tri_graphs = 1;
 772     if ($^O eq 'VMS') {  # Consider overrides of default location
 773       # XXXX This is not equivalent to what the older version did:
 774       #         it was looking at $hadsys header-file per header-file...
 775       my($hadsys) = grep s!^sys/!!i , @path_h;
 776       @paths = qw( Sys$Library VAXC$Include );
 777       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
 778       push @paths, qw( DECC$Library_Include DECC$System_Include );
 779     }
 780     else {
 781       @paths = (File::Spec->curdir(), $Config{usrinc},
 782                 (split ' ', $Config{locincpth}), '/usr/include');
 783     }
 784     foreach my $path_h (@path_h) {
 785         $name ||= $path_h;
 786     $module ||= do {
 787       $name =~ s/\.h$//;
 788       if ( $name !~ /::/ ) {
 789         $name =~ s#^.*/##;
 790         $name = "\u$name";
 791       }
 792       $name;
 793     };
 794
 795     if( $path_h =~ s#::#/#g && $opt_n ){
 796         warn "Nesting of headerfile ignored with -n\n";
 797     }
 798     $path_h .= ".h" unless $path_h =~ /\.h$/;
 799     my $fullpath = $path_h;
 800     $path_h =~ s/,.*$// if $opt_x;
 801     $fullpath{$path_h} = $fullpath;
 802
 803     # Minor trickery: we can't chdir() before we processed the headers
 804     # (so know the name of the extension), but the header may be in the
 805     # extension directory...
 806     my $tmp_path_h = $path_h;
 807     my $rel_path_h = $path_h;
 808     my @dirs = @paths;
 809     if (not -f $path_h) {
 810       my $found;
 811       for my $dir (@paths) {
 812         $found++, last
 813           if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
 814       }
 815       if ($found) {
 816         $rel_path_h = $path_h;
 817         $fullpath{$path_h} = $fullpath;
 818       } else {
 819         (my $epath = $module) =~ s,::,/,g;
 820         $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
 821         $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
 822         $path_h = $tmp_path_h;  # Used during -x
 823         push @dirs, $epath;
 824       }
 825     }
 826
 827     if (!$opt_c) {
 828       die "Can't find $tmp_path_h in @dirs\n"
 829         if ( ! $opt_f && ! -f "$rel_path_h" );
 830       # Scan the header file (we should deal with nested header files)
 831       # Record the names of simple #define constants into const_names
 832             # Function prototypes are processed below.
 833       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
 834     defines:
 835       while (<CH>) {
 836         if ($pre_sub_tri_graphs) {
 837             # Preprocess all tri-graphs
 838             # including things stuck in quoted string constants.
 839             s/\?\?=/#/g;                         # | ??=|  #|
 840             s/\?\?\!/|/g;                        # | ??!|  ||
 841             s/\?\?'/^/g;                         # | ??'|  ^|
 842             s/\?\?\(/[/g;                        # | ??(|  [|
 843             s/\?\?\)/]/g;                        # | ??)|  ]|
 844             s/\?\?\-/~/g;                        # | ??-|  ~|
 845             s/\?\?\//\\/g;                       # | ??/|  \|
 846             s/\?\?</{/g;                         # | ??<|  {|
 847             s/\?\?>/}/g;                         # | ??>|  }|
 848         }
 849         if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^"\s])(.*)/) {
 850             my $def = $1;
 851             my $rest = $2;
 852             $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
 853             $rest =~ s/^\s+//;
 854             $rest =~ s/\s+$//;
 855             # Cannot do: (-1) and ((LHANDLE)3) are OK:
 856             #print("Skip non-wordy $def => $rest\n"),
 857             #  next defines if $rest =~ /[^\w\$]/;
 858             if ($rest =~ /"/) {
 859               print("Skip stringy $def => $rest\n") if $opt_d;
 860               next defines;
 861             }
 862             print "Matched $_ ($def)\n" if $opt_d;
 863             $seen_define{$def} = $rest;
 864             $_ = $def;
 865             next if /^_.*_h_*$/i; # special case, but for what?
 866             if (defined $opt_p) {
 867               if (!/^$opt_p(\d)/) {
 868                 ++$prefix{$_} if s/^$opt_p//;
 869               }
 870               else {
 871                 warn "can't remove $opt_p prefix from '$_'!\n";
 872               }
 873             }
 874             $prefixless{$def} = $_;
 875             if (!$fmask or /$fmask/) {
 876                 print "... Passes mask of -M.\n" if $opt_d and $fmask;
 877                 $const_names{$_}++;
 878             }
 879           }
 880       }
 881       if (defined $opt_e and !$opt_e) {
 882         close(CH);
 883       }
 884       else {
 885         # Work from miniperl too - on "normal" systems
 886         my $SEEK_SET = eval 'use Fcntl qw/SEEK_SET/; SEEK_SET' or 0;
 887         seek CH, 0, $SEEK_SET;
 888         my $src = do { local $/; <CH> };
 889         close CH;
 890         no warnings 'uninitialized';
 891
 892         # Remove C and C++ comments
 893         $src =~ s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#$2#gs;
 894
 895         while ($src =~ /(\benum\s*([\w_]*)\s*\{\s([\s\w=,]+)\})/gsc) {
 896             my ($enum_name, $enum_body) =
 897                 $1 =~ /enum\s*([\w_]*)\s*\{\s([\s\w=,]+)\}/gs;
 898             # skip enums matching $opt_e
 899             next if $opt_e && $enum_name =~ /$opt_e/;
 900             my $val = 0;
 901             for my $item (split /,/, $enum_body) {
 902                 my ($key, $declared_val) = $item =~ /(\w*)\s*=\s*(.*)/;
 903                 $val = length($declared_val) ? $declared_val : 1 + $val;
 904                 $seen_define{$key} = $declared_val;
 905                 $const_names{$key}++;
 906             }
 907         } # while (...)
 908       } # if (!defined $opt_e or $opt_e)
 909     }
 910     }
 911 }
 912
 913 # Save current directory so that C::Scan can use it
 914 my $cwd = File::Spec->rel2abs( File::Spec->curdir );
 915
 916 # As Ilya suggested, use a name that contains - and then it can't clash with
 917 # the names of any packages. A directory 'fallback' will clash with any
 918 # new pragmata down the fallback:: tree, but that seems unlikely.
 919 my $constscfname = 'const-c.inc';
 920 my $constsxsfname = 'const-xs.inc';
 921 my $fallbackdirname = 'fallback';
 922
 923 my $ext = chdir 'ext' ? 'ext/' : '';
 924
 925 my @modparts  = split(/::/,$module);
 926 my $modpname  = join('-', @modparts);
 927 my $modfname  = pop @modparts;
 928 my $modpmdir  = join '/', 'lib', @modparts;
 929 my $modpmname = join '/', $modpmdir, $modfname.'.pm';
 930
 931 if ($opt_O) {
 932         warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
 933 }
 934 else {
 935         die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
 936 }
 937 -d "$modpname"   || mkpath([$modpname], 0, 0775);
 938 chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
 939
 940 my %types_seen;
 941 my %std_types;
 942 my $fdecls = [];
 943 my $fdecls_parsed = [];
 944 my $typedef_rex;
 945 my %typedefs_pre;
 946 my %known_fnames;
 947 my %structs;
 948
 949 my @fnames;
 950 my @fnames_no_prefix;
 951 my %vdecl_hash;
 952 my @vdecls;
 953
 954 if( ! $opt_X ){  # use XS, unless it was disabled
 955   unless ($skip_ppport) {
 956     require Devel::PPPort;
 957     warn "Writing $ext$modpname/ppport.h\n";
 958     Devel::PPPort::WriteFile('ppport.h')
 959         || die "Can't create $ext$modpname/ppport.h: $!\n";
 960   }
 961   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
 962   if ($opt_x) {
 963     warn "Scanning typemaps...\n";
 964     get_typemap();
 965     my @td;
 966     my @good_td;
 967     my $addflags = $opt_F || '';
 968
 969     foreach my $filename (@path_h) {
 970       my $c;
 971       my $filter;
 972
 973       if ($fullpath{$filename} =~ /,/) {
 974         $filename = $`;
 975         $filter = $';
 976       }
 977       warn "Scanning $filename for functions...\n";
 978       my @styles = $Config{gccversion} ? qw(C++ C9X GNU) : qw(C++ C9X);
 979       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
 980         'add_cppflags' => $addflags, 'c_styles' => \@styles;
 981       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE", $cwd]);
 982
 983       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
 984       push(@$fdecls, @{$c->get('fdecls')});
 985
 986       push @td, @{$c->get('typedefs_maybe')};
 987       if ($opt_a) {
 988         my $structs = $c->get('typedef_structs');
 989         @structs{keys %$structs} = values %$structs;
 990       }
 991
 992       if ($opt_m) {
 993         %vdecl_hash = %{ $c->get('vdecl_hash') };
 994         @vdecls = sort keys %vdecl_hash;
 995         for (local $_ = 0; $_ < @vdecls; ++$_) {
 996           my $var = $vdecls[$_];
 997           my($type, $post) = @{ $vdecl_hash{$var} };
 998           if (defined $post) {
 999             warn "Can't handle variable '$type $var $post', skipping.\n";
1000             splice @vdecls, $_, 1;
1001             redo;
1002           }
1003           $type = normalize_type($type);
1004           $vdecl_hash{$var} = $type;
1005         }
1006       }
1007
1008       unless ($tmask_all) {
1009         warn "Scanning $filename for typedefs...\n";
1010         my $td = $c->get('typedef_hash');
1011         # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
1012         my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
1013         push @good_td, @f_good_td;
1014         @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
1015       }
1016     }
1017     { local $" = '|';
1018       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
1019     }
1020     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
1021     if ($fmask) {
1022       my @good;
1023       for my $i (0..$#$fdecls_parsed) {
1024         next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
1025         push @good, $i;
1026         print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
1027           if $opt_d;
1028       }
1029       $fdecls = [@$fdecls[@good]];
1030       $fdecls_parsed = [@$fdecls_parsed[@good]];
1031     }
1032     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
1033     # Sort declarations:
1034     {
1035       my %h = map( ($_->[1], $_), @$fdecls_parsed);
1036       $fdecls_parsed = [ @h{@fnames} ];
1037     }
1038     @fnames_no_prefix = @fnames;
1039     @fnames_no_prefix
1040       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix
1041          if defined $opt_p;
1042     # Remove macros which expand to typedefs
1043     print "Typedefs are @td.\n" if $opt_d;
1044     my %td = map {($_, $_)} @td;
1045     # Add some other possible but meaningless values for macros
1046     for my $k (qw(char double float int long short unsigned signed void)) {
1047       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
1048     }
1049     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
1050     my $n = 0;
1051     my %bad_macs;
1052     while (keys %td > $n) {
1053       $n = keys %td;
1054       my ($k, $v);
1055       while (($k, $v) = each %seen_define) {
1056         # print("found '$k'=>'$v'\n"),
1057         $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
1058       }
1059     }
1060     # Now %bad_macs contains names of bad macros
1061     for my $k (keys %bad_macs) {
1062       delete $const_names{$prefixless{$k}};
1063       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
1064     }
1065   }
1066 }
1067 my @const_names = sort keys %const_names;
1068
1069 -d $modpmdir || mkpath([$modpmdir], 0, 0775);
1070 open(PM, ">$modpmname") || die "Can't create $ext$modpname/$modpmname: $!\n";
1071
1072 $" = "\n\t";
1073 warn "Writing $ext$modpname/$modpmname\n";
1074
1075 print PM <<"END";
1076 package $module;
1077
1078 use $compat_version;
1079 END
1080
1081 print PM <<"END" unless $skip_strict;
1082 use strict;
1083 END
1084
1085 print PM "use warnings;\n" unless $skip_warnings or $compat_version < 5.006;
1086
1087 unless( $opt_X || $opt_c || $opt_A ){
1088         # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
1089         # will want Carp.
1090         print PM <<'END';
1091 use Carp;
1092 END
1093 }
1094
1095 print PM <<'END' unless $skip_exporter;
1096
1097 require Exporter;
1098 END
1099
1100 my $use_Dyna = (not $opt_X and $compat_version < 5.006);
1101 print PM <<"END" if $use_Dyna;  # use DynaLoader, unless XS was disabled
1102 require DynaLoader;
1103 END
1104
1105
1106 # Are we using AutoLoader or not?
1107 unless ($skip_autoloader) { # no autoloader whatsoever.
1108         unless ($opt_c) { # we're doing the AUTOLOAD
1109                 print PM "use AutoLoader;\n";
1110         }
1111         else {
1112                 print PM "use AutoLoader qw(AUTOLOAD);\n"
1113         }
1114 }
1115
1116 if ( $compat_version < 5.006 ) {
1117     my $vars = '$VERSION @ISA';
1118     $vars .= ' @EXPORT @EXPORT_OK %EXPORT_TAGS' unless $skip_exporter;
1119     $vars .= ' $AUTOLOAD' unless $opt_X || $opt_c || $opt_A;
1120     $vars .= ' $XS_VERSION' if $opt_B && !$opt_X;
1121     print PM "use vars qw($vars);";
1122 }
1123
1124 # Determine @ISA.
1125 my @modISA;
1126 push @modISA, 'Exporter'        unless $skip_exporter;
1127 push @modISA, 'DynaLoader'      if $use_Dyna;  # no XS
1128 my $myISA = "our \@ISA = qw(@modISA);";
1129 $myISA =~ s/^our // if $compat_version < 5.006;
1130
1131 print PM "\n$myISA\n\n";
1132
1133 my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
1134
1135 my $tmp='';
1136 $tmp .= <<"END" unless $skip_exporter;
1137 # Items to export into callers namespace by default. Note: do not export
1138 # names by default without a very good reason. Use EXPORT_OK instead.
1139 # Do not simply export all your public functions/methods/constants.
1140
1141 # This allows declaration       use $module ':all';
1142 # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
1143 # will save memory.
1144 our %EXPORT_TAGS = ( 'all' => [ qw(
1145         @exported_names
1146 ) ] );
1147
1148 our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
1149
1150 our \@EXPORT = qw(
1151         @const_names
1152 );
1153
1154 END
1155
1156 $tmp .= "our \$VERSION = '$TEMPLATE_VERSION';\n";
1157 if ($opt_B) {
1158     $tmp .= "our \$XS_VERSION = \$VERSION;\n" unless $opt_X;
1159     $tmp .= "\$VERSION = eval \$VERSION;  # see L<perlmodstyle>\n";
1160 }
1161 $tmp .= "\n";
1162
1163 $tmp =~ s/^our //mg if $compat_version < 5.006;
1164 print PM $tmp;
1165
1166 if (@vdecls) {
1167     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
1168 }
1169
1170
1171 print PM autoload ($module, $compat_version) unless $opt_c or $opt_X;
1172
1173 if( ! $opt_X ){ # print bootstrap, unless XS is disabled
1174   if ($use_Dyna) {
1175         $tmp = <<"END";
1176 bootstrap $module \$VERSION;
1177 END
1178   } else {
1179         $tmp = <<"END";
1180 require XSLoader;
1181 XSLoader::load('$module', \$VERSION);
1182 END
1183   }
1184   $tmp =~ s:\$VERSION:\$XS_VERSION:g if $opt_B;
1185   print PM $tmp;
1186 }
1187
1188 # tying the variables can happen only after bootstrap
1189 if (@vdecls) {
1190     printf PM <<END;
1191 {
1192 @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
1193 }
1194
1195 END
1196 }
1197
1198 my $after;
1199 if( $opt_P ){ # if POD is disabled
1200         $after = '__END__';
1201 }
1202 else {
1203         $after = '=cut';
1204 }
1205
1206 print PM <<"END";
1207
1208 # Preloaded methods go here.
1209 END
1210
1211 print PM <<"END" unless $opt_A;
1212
1213 # Autoload methods go after $after, and are processed by the autosplit program.
1214 END
1215
1216 print PM <<"END";
1217
1218 1;
1219 __END__
1220 END
1221
1222 my ($email,$author,$licence);
1223
1224 eval {
1225        my $username;
1226        ($username,$author) = (getpwuid($>))[0,6];
1227        if (defined $username && defined $author) {
1228            $author =~ s/,.*$//; # in case of sub fields
1229            my $domain = $Config{'mydomain'};
1230            $domain =~ s/^\.//;
1231            $email = "$username\@$domain";
1232        }
1233      };
1234
1235 $author ||= "A. U. Thor";
1236 $email  ||= 'a.u.thor@a.galaxy.far.far.away';
1237
1238 $licence = sprintf << "DEFAULT", $^V;
1239 Copyright (C) ${\(1900 + (localtime) [5])} by $author
1240
1241 This library is free software; you can redistribute it and/or modify
1242 it under the same terms as Perl itself, either Perl version %vd or,
1243 at your option, any later version of Perl 5 you may have available.
1244 DEFAULT
1245
1246 my $revhist = '';
1247 $revhist = <<EOT if $opt_C;
1248 #
1249 #=head1 HISTORY
1250 #
1251 #=over 8
1252 #
1253 #=item $TEMPLATE_VERSION
1254 #
1255 #Original version; created by h2xs $H2XS_VERSION with options
1256 #
1257 #  @ARGS
1258 #
1259 #=back
1260 #
1261 EOT
1262
1263 my $exp_doc = $skip_exporter ? '' : <<EOD;
1264 #
1265 #=head2 EXPORT
1266 #
1267 #None by default.
1268 #
1269 EOD
1270
1271 if (@const_names and not $opt_P) {
1272   $exp_doc .= <<EOD unless $skip_exporter;
1273 #=head2 Exportable constants
1274 #
1275 #  @{[join "\n  ", @const_names]}
1276 #
1277 EOD
1278 }
1279
1280 if (defined $fdecls and @$fdecls and not $opt_P) {
1281   $exp_doc .= <<EOD unless $skip_exporter;
1282 #=head2 Exportable functions
1283 #
1284 EOD
1285
1286 #  $exp_doc .= <<EOD if $opt_p;
1287 #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
1288 #
1289 #EOD
1290   $exp_doc .= <<EOD unless $skip_exporter;
1291 #  @{[join "\n  ", @known_fnames{@fnames}]}
1292 #
1293 EOD
1294 }
1295
1296 my $meth_doc = '';
1297
1298 if ($opt_x && $opt_a) {
1299   my($name, $struct);
1300   $meth_doc .= accessor_docs($name, $struct)
1301     while ($name, $struct) = each %structs;
1302 }
1303
1304 # Prefix the default licence with hash symbols.
1305 # Is this just cargo cult - it seems that the first thing that happens to this
1306 # block is that all the hashes are then s///g out.
1307 my $licence_hash = $licence;
1308 $licence_hash =~ s/^/#/gm;
1309
1310 my $pod = <<"END" unless $opt_P;
1311 ## Below is stub documentation for your module. You'd better edit it!
1312 #
1313 #=head1 NAME
1314 #
1315 #$module - Perl extension for blah blah blah
1316 #
1317 #=head1 SYNOPSIS
1318 #
1319 #  use $module;
1320 #  blah blah blah
1321 #
1322 #=head1 DESCRIPTION
1323 #
1324 #Stub documentation for $module, created by h2xs. It looks like the
1325 #author of the extension was negligent enough to leave the stub
1326 #unedited.
1327 #
1328 #Blah blah blah.
1329 $exp_doc$meth_doc$revhist
1330 #
1331 #=head1 SEE ALSO
1332 #
1333 #Mention other useful documentation such as the documentation of
1334 #related modules or operating system documentation (such as man pages
1335 #in UNIX), or any relevant external documentation such as RFCs or
1336 #standards.
1337 #
1338 #If you have a mailing list set up for your module, mention it here.
1339 #
1340 #If you have a web site set up for your module, mention it here.
1341 #
1342 #=head1 AUTHOR
1343 #
1344 #$author, E<lt>${email}E<gt>
1345 #
1346 #=head1 COPYRIGHT AND LICENSE
1347 #
1348 $licence_hash
1349 #
1350 #=cut
1351 END
1352
1353 $pod =~ s/^\#//gm unless $opt_P;
1354 print PM $pod unless $opt_P;
1355
1356 close PM;
1357
1358
1359 if( ! $opt_X ){ # print XS, unless it is disabled
1360 warn "Writing $ext$modpname/$modfname.xs\n";
1361
1362 print XS <<"END";
1363 #include "EXTERN.h"
1364 #include "perl.h"
1365 #include "XSUB.h"
1366
1367 END
1368
1369 print XS <<"END" unless $skip_ppport;
1370 #include "ppport.h"
1371
1372 END
1373
1374 if( @path_h ){
1375     foreach my $path_h (@path_h_ini) {
1376         my($h) = $path_h;
1377         $h =~ s#^/usr/include/##;
1378         if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
1379         print XS qq{#include <$h>\n};
1380     }
1381     print XS "\n";
1382 }
1383
1384 print XS <<"END" if $opt_g;
1385
1386 /* Global Data */
1387
1388 #define MY_CXT_KEY "${module}::_guts" XS_VERSION
1389
1390 typedef struct {
1391     /* Put Global Data in here */
1392     int dummy;          /* you can access this elsewhere as MY_CXT.dummy */
1393 } my_cxt_t;
1394
1395 START_MY_CXT
1396
1397 END
1398
1399 my %pointer_typedefs;
1400 my %struct_typedefs;
1401
1402 sub td_is_pointer {
1403   my $type = shift;
1404   my $out = $pointer_typedefs{$type};
1405   return $out if defined $out;
1406   my $otype = $type;
1407   $out = ($type =~ /\*$/);
1408   # This converts only the guys which do not have trailing part in the typedef
1409   if (not $out
1410       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1411     $type = normalize_type($type);
1412     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
1413       if $opt_d;
1414     $out = td_is_pointer($type);
1415   }
1416   return ($pointer_typedefs{$otype} = $out);
1417 }
1418
1419 sub td_is_struct {
1420   my $type = shift;
1421   my $out = $struct_typedefs{$type};
1422   return $out if defined $out;
1423   my $otype = $type;
1424   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
1425   # This converts only the guys which do not have trailing part in the typedef
1426   if (not $out
1427       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1428     $type = normalize_type($type);
1429     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
1430       if $opt_d;
1431     $out = td_is_struct($type);
1432   }
1433   return ($struct_typedefs{$otype} = $out);
1434 }
1435
1436 print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
1437
1438 if( ! $opt_c ) {
1439   # We write the "sample" files used when this module is built by perl without
1440   # ExtUtils::Constant.
1441   # h2xs will later check that these are the same as those generated by the
1442   # code embedded into Makefile.PL
1443   unless (-d $fallbackdirname) {
1444     mkdir "$fallbackdirname" or die "Cannot mkdir $fallbackdirname: $!\n";
1445   }
1446   warn "Writing $ext$modpname/$fallbackdirname/$constscfname\n";
1447   warn "Writing $ext$modpname/$fallbackdirname/$constsxsfname\n";
1448   my $cfallback = File::Spec->catfile($fallbackdirname, $constscfname);
1449   my $xsfallback = File::Spec->catfile($fallbackdirname, $constsxsfname);
1450   WriteConstants ( C_FILE =>       $cfallback,
1451                    XS_FILE =>      $xsfallback,
1452                    DEFAULT_TYPE => $opt_t,
1453                    NAME =>         $module,
1454                    NAMES =>        \@const_names,
1455                  );
1456   print XS "#include \"$constscfname\"\n";
1457 }
1458
1459
1460 my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
1461
1462 # Now switch from C to XS by issuing the first MODULE declaration:
1463 print XS <<"END";
1464
1465 MODULE = $module                PACKAGE = $module               $prefix
1466
1467 END
1468
1469 # If a constant() function was #included then output a corresponding
1470 # XS declaration:
1471 print XS "INCLUDE: $constsxsfname\n" unless $opt_c;
1472
1473 print XS <<"END" if $opt_g;
1474
1475 BOOT:
1476 {
1477     MY_CXT_INIT;
1478     /* If any of the fields in the my_cxt_t struct need
1479        to be initialised, do it here.
1480      */
1481 }
1482
1483 END
1484
1485 foreach (sort keys %const_xsub) {
1486     print XS <<"END";
1487 char *
1488 $_()
1489
1490     CODE:
1491 #ifdef $_
1492         RETVAL = $_;
1493 #else
1494         croak("Your vendor has not defined the $module macro $_");
1495 #endif
1496
1497     OUTPUT:
1498         RETVAL
1499
1500 END
1501 }
1502
1503 my %seen_decl;
1504 my %typemap;
1505
1506 sub print_decl {
1507   my $fh = shift;
1508   my $decl = shift;
1509   my ($type, $name, $args) = @$decl;
1510   return if $seen_decl{$name}++; # Need to do the same for docs as well?
1511
1512   my @argnames = map {$_->[1]} @$args;
1513   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
1514   if ($opt_k) {
1515     s/^\s*const\b\s*// for @argtypes;
1516   }
1517   my @argarrays = map { $_->[4] || '' } @$args;
1518   my $numargs = @$args;
1519   if ($numargs and $argtypes[-1] eq '...') {
1520     $numargs--;
1521     $argnames[-1] = '...';
1522   }
1523   local $" = ', ';
1524   $type = normalize_type($type, 1);
1525
1526   print $fh <<"EOP";
1527
1528 $type
1529 $name(@argnames)
1530 EOP
1531
1532   for my $arg (0 .. $numargs - 1) {
1533     print $fh <<"EOP";
1534         $argtypes[$arg] $argnames[$arg]$argarrays[$arg]
1535 EOP
1536   }
1537 }
1538
1539 sub print_tievar_subs {
1540   my($fh, $name, $type) = @_;
1541   print $fh <<END;
1542 I32
1543 _get_$name(IV index, SV *sv) {
1544     dSP;
1545     PUSHMARK(SP);
1546     XPUSHs(sv);
1547     PUTBACK;
1548     (void)call_pv("$module\::_get_$name", G_DISCARD);
1549     return (I32)0;
1550 }
1551
1552 I32
1553 _set_$name(IV index, SV *sv) {
1554     dSP;
1555     PUSHMARK(SP);
1556     XPUSHs(sv);
1557     PUTBACK;
1558     (void)call_pv("$module\::_set_$name", G_DISCARD);
1559     return (I32)0;
1560 }
1561
1562 END
1563 }
1564
1565 sub print_tievar_xsubs {
1566   my($fh, $name, $type) = @_;
1567   print $fh <<END;
1568 void
1569 _tievar_$name(sv)
1570         SV* sv
1571     PREINIT:
1572         struct ufuncs uf;
1573     CODE:
1574         uf.uf_val = &_get_$name;
1575         uf.uf_set = &_set_$name;
1576         uf.uf_index = (IV)&_get_$name;
1577         sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
1578
1579 void
1580 _get_$name(THIS)
1581         $type THIS = NO_INIT
1582     CODE:
1583         THIS = $name;
1584     OUTPUT:
1585         SETMAGIC: DISABLE
1586         THIS
1587
1588 void
1589 _set_$name(THIS)
1590         $type THIS
1591     CODE:
1592         $name = THIS;
1593
1594 END
1595 }
1596
1597 sub print_accessors {
1598   my($fh, $name, $struct) = @_;
1599   return unless defined $struct && $name !~ /\s|_ANON/;
1600   $name = normalize_type($name);
1601   my $ptrname = normalize_type("$name *");
1602   print $fh <<"EOF";
1603
1604 MODULE = $module                PACKAGE = ${name}               $prefix
1605
1606 $name *
1607 _to_ptr(THIS)
1608         $name THIS = NO_INIT
1609     PROTOTYPE: \$
1610     CODE:
1611         if (sv_derived_from(ST(0), "$name")) {
1612             STRLEN len;
1613             char *s = SvPV((SV*)SvRV(ST(0)), len);
1614             if (len != sizeof(THIS))
1615                 croak("Size \%d of packed data != expected \%d",
1616                         len, sizeof(THIS));
1617             RETVAL = ($name *)s;
1618         }
1619         else
1620             croak("THIS is not of type $name");
1621     OUTPUT:
1622         RETVAL
1623
1624 $name
1625 new(CLASS)
1626         char *CLASS = NO_INIT
1627     PROTOTYPE: \$
1628     CODE:
1629         Zero((void*)&RETVAL, sizeof(RETVAL), char);
1630     OUTPUT:
1631         RETVAL
1632
1633 MODULE = $module                PACKAGE = ${name}Ptr            $prefix
1634
1635 EOF
1636   my @items = @$struct;
1637   while (@items) {
1638     my $item = shift @items;
1639     if ($item->[0] =~ /_ANON/) {
1640       if (defined $item->[2]) {
1641         push @items, map [
1642           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1643         ], @{ $structs{$item->[0]} };
1644       } else {
1645         push @items, @{ $structs{$item->[0]} };
1646       }
1647     } else {
1648       my $type = normalize_type($item->[0]);
1649       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
1650       print $fh <<"EOF";
1651 $ttype
1652 $item->[2](THIS, __value = NO_INIT)
1653         $ptrname THIS
1654         $type __value
1655     PROTOTYPE: \$;\$
1656     CODE:
1657         if (items > 1)
1658             THIS->$item->[-1] = __value;
1659         RETVAL = @{[
1660             $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
1661         ]};
1662     OUTPUT:
1663         RETVAL
1664
1665 EOF
1666     }
1667   }
1668 }
1669
1670 sub accessor_docs {
1671   my($name, $struct) = @_;
1672   return unless defined $struct && $name !~ /\s|_ANON/;
1673   $name = normalize_type($name);
1674   my $ptrname = $name . 'Ptr';
1675   my @items = @$struct;
1676   my @list;
1677   while (@items) {
1678     my $item = shift @items;
1679     if ($item->[0] =~ /_ANON/) {
1680       if (defined $item->[2]) {
1681         push @items, map [
1682           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1683         ], @{ $structs{$item->[0]} };
1684       } else {
1685         push @items, @{ $structs{$item->[0]} };
1686       }
1687     } else {
1688       push @list, $item->[2];
1689     }
1690   }
1691   my $methods = (join '(...)>, C<', @list) . '(...)';
1692
1693   my $pod = <<"EOF";
1694 #
1695 #=head2 Object and class methods for C<$name>/C<$ptrname>
1696 #
1697 #The principal Perl representation of a C object of type C<$name> is an
1698 #object of class C<$ptrname> which is a reference to an integer
1699 #representation of a C pointer.  To create such an object, one may use
1700 #a combination
1701 #
1702 #  my \$buffer = $name->new();
1703 #  my \$obj = \$buffer->_to_ptr();
1704 #
1705 #This exersizes the following two methods, and an additional class
1706 #C<$name>, the internal representation of which is a reference to a
1707 #packed string with the C structure.  Keep in mind that \$buffer should
1708 #better survive longer than \$obj.
1709 #
1710 #=over
1711 #
1712 #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
1713 #
1714 #Converts an object of type C<$name> to an object of type C<$ptrname>.
1715 #
1716 #=item C<$name-E<gt>new()>
1717 #
1718 #Creates an empty object of type C<$name>.  The corresponding packed
1719 #string is zeroed out.
1720 #
1721 #=item C<$methods>
1722 #
1723 #return the current value of the corresponding element if called
1724 #without additional arguments.  Set the element to the supplied value
1725 #(and return the new value) if called with an additional argument.
1726 #
1727 #Applicable to objects of type C<$ptrname>.
1728 #
1729 #=back
1730 #
1731 EOF
1732   $pod =~ s/^\#//gm;
1733   return $pod;
1734 }
1735
1736 # Should be called before any actual call to normalize_type().
1737 sub get_typemap {
1738   # We do not want to read ./typemap by obvios reasons.
1739   my @tm =  qw(../../../typemap ../../typemap ../typemap);
1740   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
1741   unshift @tm, $stdtypemap;
1742   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
1743
1744   # Start with useful default values
1745   $typemap{float} = 'T_NV';
1746
1747   foreach my $typemap (@tm) {
1748     next unless -e $typemap ;
1749     # skip directories, binary files etc.
1750     warn " Scanning $typemap\n";
1751     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
1752       unless -T $typemap ;
1753     open(TYPEMAP, $typemap)
1754       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
1755     my $mode = 'Typemap';
1756     while (<TYPEMAP>) {
1757       next if /^\s*\#/;
1758       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
1759       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
1760       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
1761       elsif ($mode eq 'Typemap') {
1762         next if /^\s*($|\#)/ ;
1763         my ($type, $image);
1764         if ( ($type, $image) =
1765              /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
1766              # This may reference undefined functions:
1767              and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
1768           $typemap{normalize_type($type)} = $image;
1769         }
1770       }
1771     }
1772     close(TYPEMAP) or die "Cannot close $typemap: $!";
1773   }
1774   %std_types = %types_seen;
1775   %types_seen = ();
1776 }
1777
1778
1779 sub normalize_type {            # Second arg: do not strip const's before \*
1780   my $type = shift;
1781   my $do_keep_deep_const = shift;
1782   # If $do_keep_deep_const this is heuristical only
1783   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
1784   my $ignore_mods
1785     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
1786   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
1787     $type =~ s/$ignore_mods//go;
1788   }
1789   else {
1790     $type =~ s/$ignore_mods//go;
1791   }
1792   $type =~ s/([^\s\w])/ $1 /g;
1793   $type =~ s/\s+$//;
1794   $type =~ s/^\s+//;
1795   $type =~ s/\s+/ /g;
1796   $type =~ s/\* (?=\*)/*/g;
1797   $type =~ s/\. \. \./.../g;
1798   $type =~ s/ ,/,/g;
1799   $types_seen{$type}++
1800     unless $type eq '...' or $type eq 'void' or $std_types{$type};
1801   $type;
1802 }
1803
1804 my $need_opaque;
1805
1806 sub assign_typemap_entry {
1807   my $type = shift;
1808   my $otype = $type;
1809   my $entry;
1810   if ($tmask and $type =~ /$tmask/) {
1811     print "Type $type matches -o mask\n" if $opt_d;
1812     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1813   }
1814   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1815     $type = normalize_type $type;
1816     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
1817     $entry = assign_typemap_entry($type);
1818   }
1819   # XXX good do better if our UV happens to be long long
1820   return "T_NV" if $type =~ /^(unsigned\s+)?long\s+(long|double)\z/;
1821   $entry ||= $typemap{$otype}
1822     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1823   $typemap{$otype} = $entry;
1824   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
1825   return $entry;
1826 }
1827
1828 for (@vdecls) {
1829   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
1830 }
1831
1832 if ($opt_x) {
1833   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
1834   if ($opt_a) {
1835     while (my($name, $struct) = each %structs) {
1836       print_accessors(\*XS, $name, $struct);
1837     }
1838   }
1839 }
1840
1841 close XS;
1842
1843 if (%types_seen) {
1844   my $type;
1845   warn "Writing $ext$modpname/typemap\n";
1846   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
1847
1848   for $type (sort keys %types_seen) {
1849     my $entry = assign_typemap_entry $type;
1850     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
1851   }
1852
1853   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
1854 #############################################################################
1855 INPUT
1856 T_OPAQUE_STRUCT
1857         if (sv_derived_from($arg, \"${ntype}\")) {
1858             STRLEN len;
1859             char  *s = SvPV((SV*)SvRV($arg), len);
1860
1861             if (len != sizeof($var))
1862                 croak(\"Size %d of packed data != expected %d\",
1863                         len, sizeof($var));
1864             $var = *($type *)s;
1865         }
1866         else
1867             croak(\"$var is not of type ${ntype}\")
1868 #############################################################################
1869 OUTPUT
1870 T_OPAQUE_STRUCT
1871         sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
1872 EOP
1873
1874   close TM or die "Cannot close typemap file for write: $!";
1875 }
1876
1877 } # if( ! $opt_X )
1878
1879 warn "Writing $ext$modpname/Makefile.PL\n";
1880 open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
1881
1882 my $prereq_pm;
1883
1884 if ( $compat_version < 5.00702 and $new_test )
1885 {
1886   $prereq_pm = q%'Test::More'  =>  0%;
1887 }
1888 else
1889 {
1890   $prereq_pm = '';
1891 }
1892
1893 print PL <<"END";
1894 use $compat_version;
1895 use ExtUtils::MakeMaker;
1896 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
1897 # the contents of the Makefile that is written.
1898 WriteMakefile(
1899     NAME              => '$module',
1900     VERSION_FROM      => '$modpmname', # finds \$VERSION
1901     PREREQ_PM         => {$prereq_pm}, # e.g., Module::Name => 1.1
1902     (\$] >= 5.005 ?     ## Add these new keywords supported since 5.005
1903       (ABSTRACT_FROM  => '$modpmname', # retrieve abstract from module
1904        AUTHOR         => '$author <$email>') : ()),
1905 END
1906 if (!$opt_X) { # print C stuff, unless XS is disabled
1907   $opt_F = '' unless defined $opt_F;
1908   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
1909   my $Ihelp = ($I ? '-I. ' : '');
1910   my $Icomment = ($I ? '' : <<EOC);
1911         # Insert -I. if you add *.h files later:
1912 EOC
1913
1914   print PL <<END;
1915     LIBS              => ['$extralibs'], # e.g., '-lm'
1916     DEFINE            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
1917 $Icomment    INC               => '$I', # e.g., '${Ihelp}-I/usr/include/other'
1918 END
1919
1920   my $C = grep {$_ ne "$modfname.c"}
1921     (glob '*.c'), (glob '*.cc'), (glob '*.C');
1922   my $Cpre = ($C ? '' : '# ');
1923   my $Ccomment = ($C ? '' : <<EOC);
1924         # Un-comment this if you add C files to link with later:
1925 EOC
1926
1927   print PL <<END;
1928 $Ccomment    ${Cpre}OBJECT            => '\$(O_FILES)', # link all the C files too
1929 END
1930 } # ' # Grr
1931 print PL ");\n";
1932 if (!$opt_c) {
1933   my $generate_code =
1934     WriteMakefileSnippet ( C_FILE =>       $constscfname,
1935                            XS_FILE =>      $constsxsfname,
1936                            DEFAULT_TYPE => $opt_t,
1937                            NAME =>         $module,
1938                            NAMES =>        \@const_names,
1939                  );
1940   print PL <<"END";
1941 if  (eval {require ExtUtils::Constant; 1}) {
1942   # If you edit these definitions to change the constants used by this module,
1943   # you will need to use the generated $constscfname and $constsxsfname
1944   # files to replace their "fallback" counterparts before distributing your
1945   # changes.
1946 $generate_code
1947 }
1948 else {
1949   use File::Copy;
1950   use File::Spec;
1951   foreach my \$file ('$constscfname', '$constsxsfname') {
1952     my \$fallback = File::Spec->catfile('$fallbackdirname', \$file);
1953     copy (\$fallback, \$file) or die "Can't copy \$fallback to \$file: \$!";
1954   }
1955 }
1956 END
1957
1958   eval $generate_code;
1959   if ($@) {
1960     warn <<"EOM";
1961 Attempting to test constant code in $ext$modpname/Makefile.PL:
1962 $generate_code
1963 __END__
1964 gave unexpected error $@
1965 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1966 using the perlbug script.
1967 EOM
1968   } else {
1969     my $fail;
1970
1971     foreach my $file ($constscfname, $constsxsfname) {
1972       my $fallback = File::Spec->catfile($fallbackdirname, $file);
1973       if (compare($file, $fallback)) {
1974         warn << "EOM";
1975 Files "$ext$modpname/$fallbackdirname/$file" and "$ext$modpname/$file" differ.
1976 EOM
1977         $fail++;
1978       }
1979     }
1980     if ($fail) {
1981       warn fill ('','', <<"EOM") . "\n";
1982 It appears that the code in $ext$modpname/Makefile.PL does not autogenerate
1983 the files $ext$modpname/$constscfname and $ext$modpname/$constsxsfname
1984 correctly.
1985
1986 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1987 using the perlbug script.
1988 EOM
1989     } else {
1990       unlink $constscfname, $constsxsfname;
1991     }
1992   }
1993 }
1994 close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
1995
1996 # Create a simple README since this is a CPAN requirement
1997 # and it doesnt hurt to have one
1998 warn "Writing $ext$modpname/README\n";
1999 open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
2000 my $thisyear = (gmtime)[5] + 1900;
2001 my $rmhead = "$modpname version $TEMPLATE_VERSION";
2002 my $rmheadeq = "=" x length($rmhead);
2003
2004 my $rm_prereq;
2005
2006 if ( $compat_version < 5.00702 and $new_test )
2007 {
2008    $rm_prereq = 'Test::More';
2009 }
2010 else
2011 {
2012    $rm_prereq = 'blah blah blah';
2013 }
2014
2015 print RM <<_RMEND_;
2016 $rmhead
2017 $rmheadeq
2018
2019 The README is used to introduce the module and provide instructions on
2020 how to install the module, any machine dependencies it may have (for
2021 example C compilers and installed libraries) and any other information
2022 that should be provided before the module is installed.
2023
2024 A README file is required for CPAN modules since CPAN extracts the
2025 README file from a module distribution so that people browsing the
2026 archive can use it get an idea of the modules uses. It is usually a
2027 good idea to provide version information here so that people can
2028 decide whether fixes for the module are worth downloading.
2029
2030 INSTALLATION
2031
2032 To install this module type the following:
2033
2034    perl Makefile.PL
2035    make
2036    make test
2037    make install
2038
2039 DEPENDENCIES
2040
2041 This module requires these other modules and libraries:
2042
2043   $rm_prereq
2044
2045 COPYRIGHT AND LICENCE
2046
2047 Put the correct copyright and licence information here.
2048
2049 $licence
2050
2051 _RMEND_
2052 close(RM) || die "Can't close $ext$modpname/README: $!\n";
2053
2054 my $testdir  = "t";
2055 my $testfile = "$testdir/$modpname.t";
2056 unless (-d "$testdir") {
2057   mkdir "$testdir" or die "Cannot mkdir $testdir: $!\n";
2058 }
2059 warn "Writing $ext$modpname/$testfile\n";
2060 my $tests = @const_names ? 2 : 1;
2061
2062 open EX, ">$testfile" or die "Can't create $ext$modpname/$testfile: $!\n";
2063
2064 print EX <<_END_;
2065 # Before `make install' is performed this script should be runnable with
2066 # `make test'. After `make install' it should work as `perl $modpname.t'
2067
2068 #########################
2069
2070 # change 'tests => $tests' to 'tests => last_test_to_print';
2071
2072 _END_
2073
2074 my $test_mod = 'Test::More';
2075
2076 if ( $old_test or ($compat_version < 5.007 and not $new_test ))
2077 {
2078   my $test_mod = 'Test';
2079
2080   print EX <<_END_;
2081 use Test;
2082 BEGIN { plan tests => $tests };
2083 use $module;
2084 ok(1); # If we made it this far, we're ok.
2085
2086 _END_
2087
2088    if (@const_names) {
2089      my $const_names = join " ", @const_names;
2090      print EX <<'_END_';
2091
2092 my $fail;
2093 foreach my $constname (qw(
2094 _END_
2095
2096      print EX wrap ("\t", "\t", $const_names);
2097      print EX (")) {\n");
2098
2099      print EX <<_END_;
2100   next if (eval "my \\\$a = \$constname; 1");
2101   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2102     print "# pass: \$\@";
2103   } else {
2104     print "# fail: \$\@";
2105     \$fail = 1;
2106   }
2107 }
2108 if (\$fail) {
2109   print "not ok 2\\n";
2110 } else {
2111   print "ok 2\\n";
2112 }
2113
2114 _END_
2115   }
2116 }
2117 else
2118 {
2119   print EX <<_END_;
2120 use Test::More tests => $tests;
2121 BEGIN { use_ok('$module') };
2122
2123 _END_
2124
2125    if (@const_names) {
2126      my $const_names = join " ", @const_names;
2127      print EX <<'_END_';
2128
2129 my $fail = 0;
2130 foreach my $constname (qw(
2131 _END_
2132
2133      print EX wrap ("\t", "\t", $const_names);
2134      print EX (")) {\n");
2135
2136      print EX <<_END_;
2137   next if (eval "my \\\$a = \$constname; 1");
2138   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2139     print "# pass: \$\@";
2140   } else {
2141     print "# fail: \$\@";
2142     \$fail = 1;
2143   }
2144
2145 }
2146
2147 ok( \$fail == 0 , 'Constants' );
2148 _END_
2149   }
2150 }
2151
2152 print EX <<_END_;
2153 #########################
2154
2155 # Insert your test code below, the $test_mod module is use()ed here so read
2156 # its man page ( perldoc $test_mod ) for help writing this test script.
2157
2158 _END_
2159
2160 close(EX) || die "Can't close $ext$modpname/$testfile: $!\n";
2161
2162 unless ($opt_C) {
2163   warn "Writing $ext$modpname/Changes\n";
2164   $" = ' ';
2165   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
2166   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
2167   print EX <<EOP;
2168 Revision history for Perl extension $module.
2169
2170 $TEMPLATE_VERSION  @{[scalar localtime]}
2171 \t- original version; created by h2xs $H2XS_VERSION with options
2172 \t\t@ARGS
2173
2174 EOP
2175   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
2176 }
2177
2178 warn "Writing $ext$modpname/MANIFEST\n";
2179 open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
2180 my @files = grep { -f } (<*>, <t/*>, <$fallbackdirname/*>, <$modpmdir/*>);
2181 if (!@files) {
2182   eval {opendir(D,'.');};
2183   unless ($@) { @files = readdir(D); closedir(D); }
2184 }
2185 if (!@files) { @files = map {chomp && $_} `ls`; }
2186 if ($^O eq 'VMS') {
2187   foreach (@files) {
2188     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
2189     s%\.$%%;
2190     # Fix up for case-sensitive file systems
2191     s/$modfname/$modfname/i && next;
2192     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
2193     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
2194   }
2195 }
2196 print MANI join("\n",@files), "\n";
2197 close MANI;
2198 !NO!SUBS!
2199
2200 close OUT or die "Can't close $file: $!";
2201 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
2202 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
2203 chdir $origdir;