lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline> via glob
 177 assignment) contains the text from C<$filename>, with each element
 178 corresponding to a single line of C<$filename>.
 179
 180 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 181 assignment) contains breakpoints and actions.  The keys are line numbers;
 182 you can set individual values, but not the whole hash. The Perl interpreter
 183 uses this hash to determine where breakpoints have been set. Any true value is
 184 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 185 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 186
 187 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 188 This is also the case for evaluated strings that contain subroutines, or
 189 which are currently being executed.  The $filename for C<eval>ed strings looks
 190 like C<(eval 34)> or C<(re_eval 19)>.
 191
 192 =head1 DEBUGGER STARTUP
 193
 194 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 195 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 196 of options. In addition, this file may define a subroutine C<&afterinit>
 197 that will be executed (in the debugger's context) after the debugger has
 198 initialized itself.
 199
 200 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 201 contents as the argument of a C<o> command in the debugger.
 202
 203 =head2 STARTUP-ONLY OPTIONS
 204
 205 The following options can only be specified at startup.
 206 To set them in your rcfile, add a call to
 207 C<&parse_options("optionName=new_value")>.
 208
 209 =over 4
 210
 211 =item * TTY
 212
 213 the TTY to use for debugging i/o.
 214
 215 =item * noTTY
 216
 217 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 218 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 219 Term::Rendezvous.  Current variant is to have the name of TTY in this
 220 file.
 221
 222 =item * ReadLine
 223
 224 if false, a dummy ReadLine is used, so you can debug
 225 ReadLine applications.
 226
 227 =item * NonStop
 228
 229 if true, no i/o is performed until interrupt.
 230
 231 =item * LineInfo
 232
 233 file or pipe to print line number info to.  If it is a
 234 pipe, a short "emacs like" message is used.
 235
 236 =item * RemotePort
 237
 238 host:port to connect to on remote host for remote debugging.
 239
 240 =item * HistFile
 241
 242 file to store session history to. There is no default and so no
 243 history file is written unless this variable is explicitly set.
 244
 245 =item * HistSize
 246
 247 number of commands to store to the file specified in C<HistFile>.
 248 Default is 100.
 249
 250 =back
 251
 252 =head3 SAMPLE RCFILE
 253
 254  &parse_options("NonStop=1 LineInfo=db.out");
 255   sub afterinit { $trace = 1; }
 256
 257 The script will run without human intervention, putting trace
 258 information into C<db.out>.  (If you interrupt it, you had better
 259 reset C<LineInfo> to something I<interactive>!)
 260
 261 =head1 INTERNALS DESCRIPTION
 262
 263 =head2 DEBUGGER INTERFACE VARIABLES
 264
 265 Perl supplies the values for C<%sub>.  It effectively inserts
 266 a C<&DB::DB();> in front of each place that can have a
 267 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 268 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 269 {require 'perl5db.pl'}> before the first line.
 270
 271 After each C<require>d file is compiled, but before it is executed, a
 272 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 273 is the expanded name of the C<require>d file (as found via C<%INC>).
 274
 275 =head3 IMPORTANT INTERNAL VARIABLES
 276
 277 =head4 C<$CreateTTY>
 278
 279 Used to control when the debugger will attempt to acquire another TTY to be
 280 used for input.
 281
 282 =over
 283
 284 =item * 1 -  on C<fork()>
 285
 286 =item * 2 - debugger is started inside debugger
 287
 288 =item * 4 -  on startup
 289
 290 =back
 291
 292 =head4 C<$doret>
 293
 294 The value -2 indicates that no return value should be printed.
 295 Any other positive value causes C<DB::sub> to print return values.
 296
 297 =head4 C<$evalarg>
 298
 299 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 300 contents of C<@_> when C<DB::eval> is called.
 301
 302 =head4 C<$frame>
 303
 304 Determines what messages (if any) will get printed when a subroutine (or eval)
 305 is entered or exited.
 306
 307 =over 4
 308
 309 =item * 0 -  No enter/exit messages
 310
 311 =item * 1 - Print I<entering> messages on subroutine entry
 312
 313 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 314
 315 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 316
 317 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 318
 319 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 320
 321 =back
 322
 323 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 324 The debugger internally juggles the value of C<$frame> during execution to
 325 protect external modules that the debugger uses from getting traced.
 326
 327 =head4 C<$level>
 328
 329 Tracks current debugger nesting level. Used to figure out how many
 330 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 331 outputs a prompt. Also used to help determine if the program has finished
 332 during command parsing.
 333
 334 =head4 C<$onetimeDump>
 335
 336 Controls what (if anything) C<DB::eval()> will print after evaluating an
 337 expression.
 338
 339 =over 4
 340
 341 =item * C<undef> - don't print anything
 342
 343 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 344
 345 =item * C<methods> - print the methods callable on the first item returned
 346
 347 =back
 348
 349 =head4 C<$onetimeDumpDepth>
 350
 351 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 352 dumping a structure. Numeric. If C<undef>, print all levels.
 353
 354 =head4 C<$signal>
 355
 356 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 357 which is called before every statement, checks this and puts the user into
 358 command mode if it finds C<$signal> set to a true value.
 359
 360 =head4 C<$single>
 361
 362 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 363 each subroutine; popped again at the end of each subroutine.
 364
 365 =over 4
 366
 367 =item * 0 - run continuously.
 368
 369 =item * 1 - single-step, go into subs. The C<s> command.
 370
 371 =item * 2 - single-step, don't go into subs. The C<n> command.
 372
 373 =item * 4 - print current sub depth (turned on to force this when C<too much
 374 recursion> occurs.
 375
 376 =back
 377
 378 =head4 C<$trace>
 379
 380 Controls the output of trace information.
 381
 382 =over 4
 383
 384 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 385
 386 =item * 2 - watch expressions are active
 387
 388 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 389
 390 =back
 391
 392 =head4 C<$slave_editor>
 393
 394 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 395
 396 =head4 C<@cmdfhs>
 397
 398 Stack of filehandles that C<DB::readline()> will read commands from.
 399 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 400
 401 =head4 C<@dbline>
 402
 403 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 404 supplied by the Perl interpreter to the debugger. Contains the source.
 405
 406 =head4 C<@old_watch>
 407
 408 Previous values of watch expressions. First set when the expression is
 409 entered; reset whenever the watch expression changes.
 410
 411 =head4 C<@saved>
 412
 413 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 414 so that the debugger can substitute safe values while it's running, and
 415 restore them when it returns control.
 416
 417 =head4 C<@stack>
 418
 419 Saves the current value of C<$single> on entry to a subroutine.
 420 Manipulated by the C<c> command to turn off tracing in all subs above the
 421 current one.
 422
 423 =head4 C<@to_watch>
 424
 425 The 'watch' expressions: to be evaluated before each line is executed.
 426
 427 =head4 C<@typeahead>
 428
 429 The typeahead buffer, used by C<DB::readline>.
 430
 431 =head4 C<%alias>
 432
 433 Command aliases. Stored as character strings to be substituted for a command
 434 entered.
 435
 436 =head4 C<%break_on_load>
 437
 438 Keys are file names, values are 1 (break when this file is loaded) or undef
 439 (don't break when it is loaded).
 440
 441 =head4 C<%dbline>
 442
 443 Keys are line numbers, values are C<condition\0action>. If used in numeric
 444 context, values are 0 if not breakable, 1 if breakable, no matter what is
 445 in the actual hash entry.
 446
 447 =head4 C<%had_breakpoints>
 448
 449 Keys are file names; values are bitfields:
 450
 451 =over 4
 452
 453 =item * 1 - file has a breakpoint in it.
 454
 455 =item * 2 - file has an action in it.
 456
 457 =back
 458
 459 A zero or undefined value means this file has neither.
 460
 461 =head4 C<%option>
 462
 463 Stores the debugger options. These are character string values.
 464
 465 =head4 C<%postponed>
 466
 467 Saves breakpoints for code that hasn't been compiled yet.
 468 Keys are subroutine names, values are:
 469
 470 =over 4
 471
 472 =item * C<compile> - break when this sub is compiled
 473
 474 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 475
 476 =back
 477
 478 =head4 C<%postponed_file>
 479
 480 This hash keeps track of breakpoints that need to be set for files that have
 481 not yet been compiled. Keys are filenames; values are references to hashes.
 482 Each of these hashes is keyed by line number, and its values are breakpoint
 483 definitions (C<condition\0action>).
 484
 485 =head1 DEBUGGER INITIALIZATION
 486
 487 The debugger's initialization actually jumps all over the place inside this
 488 package. This is because there are several BEGIN blocks (which of course
 489 execute immediately) spread through the code. Why is that?
 490
 491 The debugger needs to be able to change some things and set some things up
 492 before the debugger code is compiled; most notably, the C<$deep> variable that
 493 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 494 debugger has to turn off warnings while the debugger code is compiled, but then
 495 restore them to their original setting before the program being debugged begins
 496 executing.
 497
 498 The first C<BEGIN> block simply turns off warnings by saving the current
 499 setting of C<$^W> and then setting it to zero. The second one initializes
 500 the debugger variables that are needed before the debugger begins executing.
 501 The third one puts C<$^X> back to its former value.
 502
 503 We'll detail the second C<BEGIN> block later; just remember that if you need
 504 to initialize something before the debugger starts really executing, that's
 505 where it has to go.
 506
 507 =cut
 508
 509 package DB;
 510
 511 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 512
 513 # Debugger for Perl 5.00x; perl5db.pl patch level:
 514 $VERSION = 1.32;
 515
 516 $header = "perl5db.pl version $VERSION";
 517
 518 =head1 DEBUGGER ROUTINES
 519
 520 =head2 C<DB::eval()>
 521
 522 This function replaces straight C<eval()> inside the debugger; it simplifies
 523 the process of evaluating code in the user's context.
 524
 525 The code to be evaluated is passed via the package global variable
 526 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 527
 528 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 529 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 530 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 531 user's current package, grabbed when C<DB::DB> got control.  This causes the
 532 proper context to be used when the eval is actually done.  Afterward, we
 533 restore C<$trace>, C<$single>, and C<$^D>.
 534
 535 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 536 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 537 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 538 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 539 considered sane by the debugger. If there was an C<eval()> error, we print
 540 it on the debugger's output. If C<$onetimedump> is defined, we call
 541 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 542 'methods'. Setting it to something else causes the debugger to do the eval
 543 but not print the result - handy if you want to do something else with it
 544 (the "watch expressions" code does this to get the value of the watch
 545 expression but not show it unless it matters).
 546
 547 In any case, we then return the list of output from C<eval> to the caller,
 548 and unwinding restores the former version of C<$@> in C<@saved> as well
 549 (the localization of C<$saved[0]> goes away at the end of this scope).
 550
 551 =head3 Parameters and variables influencing execution of DB::eval()
 552
 553 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 554 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 555 The variables listed below influence C<DB::eval()>'s execution directly.
 556
 557 =over 4
 558
 559 =item C<$evalarg> - the thing to actually be eval'ed
 560
 561 =item C<$trace> - Current state of execution tracing
 562
 563 =item C<$single> - Current state of single-stepping
 564
 565 =item C<$onetimeDump> - what is to be displayed after the evaluation
 566
 567 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 568
 569 =back
 570
 571 The following variables are altered by C<DB::eval()> during its execution. They
 572 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 573
 574 =over 4
 575
 576 =item C<@res> - used to capture output from actual C<eval>.
 577
 578 =item C<$otrace> - saved value of C<$trace>.
 579
 580 =item C<$osingle> - saved value of C<$single>.
 581
 582 =item C<$od> - saved value of C<$^D>.
 583
 584 =item C<$saved[0]> - saved value of C<$@>.
 585
 586 =item $\ - for output of C<$@> if there is an evaluation error.
 587
 588 =back
 589
 590 =head3 The problem of lexicals
 591
 592 The context of C<DB::eval()> presents us with some problems. Obviously,
 593 we want to be 'sandboxed' away from the debugger's internals when we do
 594 the eval, but we need some way to control how punctuation variables and
 595 debugger globals are used.
 596
 597 We can't use local, because the code inside C<DB::eval> can see localized
 598 variables; and we can't use C<my> either for the same reason. The code
 599 in this routine compromises and uses C<my>.
 600
 601 After this routine is over, we don't have user code executing in the debugger's
 602 context, so we can use C<my> freely.
 603
 604 =cut
 605
 606 ############################################## Begin lexical danger zone
 607
 608 # 'my' variables used here could leak into (that is, be visible in)
 609 # the context that the code being evaluated is executing in. This means that
 610 # the code could modify the debugger's variables.
 611 #
 612 # Fiddling with the debugger's context could be Bad. We insulate things as
 613 # much as we can.
 614
 615 sub eval {
 616
 617     # 'my' would make it visible from user code
 618     #    but so does local! --tchrist
 619     # Remember: this localizes @DB::res, not @main::res.
 620     local @res;
 621     {
 622
 623         # Try to keep the user code from messing  with us. Save these so that
 624         # even if the eval'ed code changes them, we can put them back again.
 625         # Needed because the user could refer directly to the debugger's
 626         # package globals (and any 'my' variables in this containing scope)
 627         # inside the eval(), and we want to try to stay safe.
 628         local $otrace  = $trace;
 629         local $osingle = $single;
 630         local $od      = $^D;
 631
 632         # Untaint the incoming eval() argument.
 633         { ($evalarg) = $evalarg =~ /(.*)/s; }
 634
 635         # $usercontext built in DB::DB near the comment
 636         # "set up the context for DB::eval ..."
 637         # Evaluate and save any results.
 638         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 639
 640         # Restore those old values.
 641         $trace  = $otrace;
 642         $single = $osingle;
 643         $^D     = $od;
 644     }
 645
 646     # Save the current value of $@, and preserve it in the debugger's copy
 647     # of the saved precious globals.
 648     my $at = $@;
 649
 650     # Since we're only saving $@, we only have to localize the array element
 651     # that it will be stored in.
 652     local $saved[0];    # Preserve the old value of $@
 653     eval { &DB::save };
 654
 655     # Now see whether we need to report an error back to the user.
 656     if ($at) {
 657         local $\ = '';
 658         print $OUT $at;
 659     }
 660
 661     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 662     # are package globals.
 663     elsif ($onetimeDump) {
 664         if ( $onetimeDump eq 'dump' ) {
 665             local $option{dumpDepth} = $onetimedumpDepth
 666               if defined $onetimedumpDepth;
 667             dumpit( $OUT, \@res );
 668         }
 669         elsif ( $onetimeDump eq 'methods' ) {
 670             methods( $res[0] );
 671         }
 672     } ## end elsif ($onetimeDump)
 673     @res;
 674 } ## end sub eval
 675
 676 ############################################## End lexical danger zone
 677
 678 # After this point it is safe to introduce lexicals.
 679 # The code being debugged will be executing in its own context, and
 680 # can't see the inside of the debugger.
 681 #
 682 # However, one should not overdo it: leave as much control from outside as
 683 # possible. If you make something a lexical, it's not going to be addressable
 684 # from outside the debugger even if you know its name.
 685
 686 # This file is automatically included if you do perl -d.
 687 # It's probably not useful to include this yourself.
 688 #
 689 # Before venturing further into these twisty passages, it is
 690 # wise to read the perldebguts man page or risk the ire of dragons.
 691 #
 692 # (It should be noted that perldebguts will tell you a lot about
 693 # the underlying mechanics of how the debugger interfaces into the
 694 # Perl interpreter, but not a lot about the debugger itself. The new
 695 # comments in this code try to address this problem.)
 696
 697 # Note that no subroutine call is possible until &DB::sub is defined
 698 # (for subroutines defined outside of the package DB). In fact the same is
 699 # true if $deep is not defined.
 700
 701 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 702
 703 # modified Perl debugger, to be run from Emacs in perldb-mode
 704 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 705 # Johan Vromans -- upgrade to 4.0 pl 10
 706 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 707
 708 # (We have made efforts to  clarify the comments in the change log
 709 # in other places; some of them may seem somewhat obscure as they
 710 # were originally written, and explaining them away from the code
 711 # in question seems conterproductive.. -JM)
 712
 713 ########################################################################
 714 # Changes: 0.94
 715 #   + A lot of things changed after 0.94. First of all, core now informs
 716 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 717 #     BEGIN and END. Handy with `O f=2'.
 718 #   + This can make debugger a little bit too verbose, please be patient
 719 #     and report your problems promptly.
 720 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 721 #   + Note that if DESTROY returns a reference to the object (or object),
 722 #     the deletion of data may be postponed until the next function call,
 723 #     due to the need to examine the return value.
 724 #
 725 # Changes: 0.95
 726 #   + `v' command shows versions.
 727 #
 728 # Changes: 0.96
 729 #   + `v' command shows version of readline.
 730 #     primitive completion works (dynamic variables, subs for `b' and `l',
 731 #     options). Can `p %var'
 732 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
 733 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 734 #   + `c sub' documented.
 735 #   + At last enough magic combined to stop after the end of debuggee.
 736 #   + !! should work now (thanks to Emacs bracket matching an extra
 737 #     `]' in a regexp is caught).
 738 #   + `L', `D' and `A' span files now (as documented).
 739 #   + Breakpoints in `require'd code are possible (used in `R').
 740 #   +  Some additional words on internal work of debugger.
 741 #   + `b load filename' implemented.
 742 #   + `b postpone subr' implemented.
 743 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
 744 #   + When restarting debugger breakpoints/actions persist.
 745 #   + Buglet: When restarting debugger only one breakpoint/action per
 746 #             autoloaded function persists.
 747 #
 748 # Changes: 0.97: NonStop will not stop in at_exit().
 749 #   + Option AutoTrace implemented.
 750 #   + Trace printed differently if frames are printed too.
 751 #   + new `inhibitExit' option.
 752 #   + printing of a very long statement interruptible.
 753 # Changes: 0.98: New command `m' for printing possible methods
 754 #   + 'l -' is a synonym for `-'.
 755 #   + Cosmetic bugs in printing stack trace.
 756 #   +  `frame' & 8 to print "expanded args" in stack trace.
 757 #   + Can list/break in imported subs.
 758 #   + new `maxTraceLen' option.
 759 #   + frame & 4 and frame & 8 granted.
 760 #   + new command `m'
 761 #   + nonstoppable lines do not have `:' near the line number.
 762 #   + `b compile subname' implemented.
 763 #   + Will not use $` any more.
 764 #   + `-' behaves sane now.
 765 # Changes: 0.99: Completion for `f', `m'.
 766 #   +  `m' will remove duplicate names instead of duplicate functions.
 767 #   + `b load' strips trailing whitespace.
 768 #     completion ignores leading `|'; takes into account current package
 769 #     when completing a subroutine name (same for `l').
 770 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 771 #   BUG FIXES:
 772 #   + Added bare minimal security checks on perldb rc files, plus
 773 #     comments on what else is needed.
 774 #   + Fixed the ornaments that made "|h" completely unusable.
 775 #     They are not used in print_help if they will hurt.  Strip pod
 776 #     if we're paging to less.
 777 #   + Fixed mis-formatting of help messages caused by ornaments
 778 #     to restore Larry's original formatting.
 779 #   + Fixed many other formatting errors.  The code is still suboptimal,
 780 #     and needs a lot of work at restructuring.  It's also misindented
 781 #     in many places.
 782 #   + Fixed bug where trying to look at an option like your pager
 783 #     shows "1".
 784 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 785 #     lose.  You should consider shell escapes not using their shell,
 786 #     or else not caring about detailed status.  This should really be
 787 #     unified into one place, too.
 788 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 789 #     tricking Perl into thinking you weren't calling a debugger command!
 790 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 791 #     suggests a leading semicolon or any other irrelevant non-whitespace
 792 #     to indicate literal Perl code.)
 793 #   + Fixed bugs that ate warnings due to wrong selected handle.
 794 #   + Fixed a precedence bug on signal stuff.
 795 #   + Fixed some unseemly wording.
 796 #   + Fixed bug in help command trying to call perl method code.
 797 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 798 #   ENHANCEMENTS:
 799 #   + Added some comments.  This code is still nasty spaghetti.
 800 #   + Added message if you clear your pre/post command stacks which was
 801 #     very easy to do if you just typed a bare >, <, or {.  (A command
 802 #     without an argument should *never* be a destructive action; this
 803 #     API is fundamentally screwed up; likewise option setting, which
 804 #     is equally buggered.)
 805 #   + Added command stack dump on argument of "?" for >, <, or {.
 806 #   + Added a semi-built-in doc viewer command that calls man with the
 807 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 808 #     or else perldoc on obstreperous platforms.
 809 #   + Added to and rearranged the help information.
 810 #   + Detected apparent misuse of { ... } to declare a block; this used
 811 #     to work but now is a command, and mysteriously gave no complaint.
 812 #
 813 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 814 #   BUG FIX:
 815 #   + This patch to perl5db.pl cleans up formatting issues on the help
 816 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 817 #     issues, plus converted the printed text to use all spaces, since
 818 #     tabs don't seem to help much here.
 819 #
 820 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 821 #   Minor bugs corrected;
 822 #   + Support for auto-creation of new TTY window on startup, either
 823 #     unconditionally, or if started as a kid of another debugger session;
 824 #   + New `O'ption CreateTTY
 825 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 826 #                         1: on fork()
 827 #                         2: debugger is started inside debugger
 828 #                         4: on startup
 829 #   + Code to auto-create a new TTY window on OS/2 (currently one
 830 #     extra window per session - need named pipes to have more...);
 831 #   + Simplified interface for custom createTTY functions (with a backward
 832 #     compatibility hack); now returns the TTY name to use; return of ''
 833 #     means that the function reset the I/O handles itself;
 834 #   + Better message on the semantic of custom createTTY function;
 835 #   + Convert the existing code to create a TTY into a custom createTTY
 836 #     function;
 837 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 838 #   + Switch line-tracing output too to the created TTY window;
 839 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
 840 #   + High-level debugger API cmd_*():
 841 #      cmd_b_load($filenamepart)            # b load filenamepart
 842 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 843 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 844 #      cmd_stop()                           # Control-C
 845 #      cmd_d($lineno)                       # d lineno (B)
 846 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 847 #      the error message to the debugging output.
 848 #   + Low-level debugger API
 849 #      break_on_load($filename)             # b load filename
 850 #      @files = report_break_on_load()      # List files with load-breakpoints
 851 #      breakable_line_in_filename($name, $from [, $to])
 852 #                                           # First breakable line in the
 853 #                                           # range $from .. $to.  $to defaults
 854 #                                           # to $from, and may be less than
 855 #                                           # $to
 856 #      breakable_line($from [, $to])        # Same for the current file
 857 #      break_on_filename_line($name, $lineno [, $cond])
 858 #                                           # Set breakpoint,$cond defaults to
 859 #                                           # 1
 860 #      break_on_filename_line_range($name, $from, $to [, $cond])
 861 #                                           # As above, on the first
 862 #                                           # breakable line in range
 863 #      break_on_line($lineno [, $cond])     # As above, in the current file
 864 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 865 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 866 #                                           # The range of lines of the text
 867 #      The low-level API returns TRUE on success, and die()s on failure.
 868 #
 869 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 870 #   BUG FIXES:
 871 #   + Fixed warnings generated by "perl -dWe 42"
 872 #   + Corrected spelling errors
 873 #   + Squeezed Help (h) output into 80 columns
 874 #
 875 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 876 #   + Made "x @INC" work like it used to
 877 #
 878 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 879 #   + Fixed warnings generated by "O" (Show debugger options)
 880 #   + Fixed warnings generated by "p 42" (Print expression)
 881 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 882 #   + Added windowSize option
 883 # Changes: 1.14: Oct  9, 2001 multiple
 884 #   + Clean up after itself on VMS (Charles Lane in 12385)
 885 #   + Adding "@ file" syntax (Peter Scott in 12014)
 886 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 887 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 888 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 889 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 890 #   + Updated 1.14 change log
 891 #   + Added *dbline explainatory comments
 892 #   + Mentioning perldebguts man page
 893 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 894 #   + $onetimeDump improvements
 895 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 896 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 897 #   rationalised the following commands and added cmd_wrapper() to
 898 #   enable switching between old and frighteningly consistent new
 899 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 900 #     a(add),       A(del)            # action expr   (added del by line)
 901 #   + b(add),       B(del)            # break  [line] (was b,D)
 902 #   + w(add),       W(del)            # watch  expr   (was W,W)
 903 #                                     # added del by expr
 904 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 905 #   + m(methods),   M(modules)        # ...           (was m,v)
 906 #   + o(option)                       # lc            (was O)
 907 #   + v(view code), V(view Variables) # ...           (was w,V)
 908 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 909 #   + fixed missing cmd_O bug
 910 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 911 #   + Added missing local()s -- DB::DB is called recursively.
 912 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 913 #   + pre'n'post commands no longer trashed with no args
 914 #   + watch val joined out of eval()
 915 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 916 #   + Added comments and reformatted source. No bug fixes/enhancements.
 917 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 918 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 919 #   + Flush stdout/stderr before the debugger prompt is printed.
 920 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 921 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 922 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 923 #   + Added command to save all debugger commands for sourcing later.
 924 #   + Added command to display parent inheritance tree of given class.
 925 #   + Fixed minor newline in history bug.
 926 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 927 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 928 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 929 #   + unfork the 5.8.x and 5.9.x debuggers.
 930 #   + whitespace and assertions call cleanup across versions
 931 #   + H * deletes (resets) history
 932 #   + i now handles Class + blessed objects
 933 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 934 #   + updated pod page references - clunky.
 935 #   + removed windowid restriction for forking into an xterm.
 936 #   + more whitespace again.
 937 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 938 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 939 #   + Added threads support (inc. e and E commands)
 940 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 941 #   + Added macosx_get_fork_TTY support
 942 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
 943 #   + Added HistFile, HistSize
 944 # Changes: 1.31
 945 #   + Remove support for assertions and -A
 946 #   + stop NEXT::AUTOLOAD from emitting warnings under the debugger. RT #25053
 947 #   + "update for Mac OS X 10.5" [finding the tty device]
 948 #   + "What I needed to get the forked debugger to work" [on VMS]
 949 #   + [perl #57016] debugger: o warn=0 die=0 ignored
 950 #   + Note, but don't use, PERLDBf_SAVESRC
 951 #   + Fix #7013: lvalue subs not working inside debugger
 952 ########################################################################
 953
 954 =head1 DEBUGGER INITIALIZATION
 955
 956 The debugger starts up in phases.
 957
 958 =head2 BASIC SETUP
 959
 960 First, it initializes the environment it wants to run in: turning off
 961 warnings during its own compilation, defining variables which it will need
 962 to avoid warnings later, setting itself up to not exit when the program
 963 terminates, and defaulting to printing return values for the C<r> command.
 964
 965 =cut
 966
 967 # Needed for the statement after exec():
 968 #
 969 # This BEGIN block is simply used to switch off warnings during debugger
 970 # compiliation. Probably it would be better practice to fix the warnings,
 971 # but this is how it's done at the moment.
 972
 973 BEGIN {
 974     $ini_warn = $^W;
 975     $^W       = 0;
 976 }    # Switch compilation warnings off until another BEGIN.
 977
 978 local ($^W) = 0;    # Switch run-time warnings off during init.
 979
 980 =head2 THREADS SUPPORT
 981
 982 If we are running under a threaded Perl, we require threads and threads::shared
 983 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 984 threaded debugger control.  C<-dt> can also be used to set this.
 985
 986 Each new thread will be announced and the debugger prompt will always inform
 987 you of each new thread created.  It will also indicate the thread id in which
 988 we are currently running within the prompt like this:
 989
 990         [tid] DB<$i>
 991
 992 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 993 command prompt.  The prompt will show: C<[0]> when running under threads, but
 994 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 995
 996 While running under threads, when you set or delete a breakpoint (etc.), this
 997 will apply to all threads, not just the currently running one.  When you are
 998 in a currently executing thread, you will stay there until it completes.  With
 999 the current implementation it is not currently possible to hop from one thread
1000 to another.
1001
1002 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1003
1004 Note that threading support was built into the debugger as of Perl version
1005 C<5.8.6> and debugger version C<1.2.8>.
1006
1007 =cut
1008
1009 BEGIN {
1010   # ensure we can share our non-threaded variables or no-op
1011   if ($ENV{PERL5DB_THREADED}) {
1012         require threads;
1013         require threads::shared;
1014         import threads::shared qw(share);
1015         $DBGR;
1016         share(\$DBGR);
1017         lock($DBGR);
1018         print "Threads support enabled\n";
1019   } else {
1020         *lock  = sub(*) {};
1021         *share = sub(*) {};
1022   }
1023 }
1024
1025 # This would probably be better done with "use vars", but that wasn't around
1026 # when this code was originally written. (Neither was "use strict".) And on
1027 # the principle of not fiddling with something that was working, this was
1028 # left alone.
1029 warn(               # Do not ;-)
1030     # These variables control the execution of 'dumpvar.pl'.
1031     $dumpvar::hashDepth,
1032     $dumpvar::arrayDepth,
1033     $dumpvar::dumpDBFiles,
1034     $dumpvar::dumpPackages,
1035     $dumpvar::quoteHighBit,
1036     $dumpvar::printUndef,
1037     $dumpvar::globPrint,
1038     $dumpvar::usageOnly,
1039
1040     # used to save @ARGV and extract any debugger-related flags.
1041     @ARGS,
1042
1043     # used to control die() reporting in diesignal()
1044     $Carp::CarpLevel,
1045
1046     # used to prevent multiple entries to diesignal()
1047     # (if for instance diesignal() itself dies)
1048     $panic,
1049
1050     # used to prevent the debugger from running nonstop
1051     # after a restart
1052     $second_time,
1053   )
1054   if 0;
1055
1056 foreach my $k (keys (%INC)) {
1057         &share(\$main::{'_<'.$filename});
1058 };
1059
1060 # Command-line + PERLLIB:
1061 # Save the contents of @INC before they are modified elsewhere.
1062 @ini_INC = @INC;
1063
1064 # This was an attempt to clear out the previous values of various
1065 # trapped errors. Apparently it didn't help. XXX More info needed!
1066 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1067
1068 # We set these variables to safe values. We don't want to blindly turn
1069 # off warnings, because other packages may still want them.
1070 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1071                                    # (local $^W cannot help - other packages!).
1072
1073 # Default to not exiting when program finishes; print the return
1074 # value when the 'r' command is used to return from a subroutine.
1075 $inhibit_exit = $option{PrintRet} = 1;
1076
1077 =head1 OPTION PROCESSING
1078
1079 The debugger's options are actually spread out over the debugger itself and
1080 C<dumpvar.pl>; some of these are variables to be set, while others are
1081 subs to be called with a value. To try to make this a little easier to
1082 manage, the debugger uses a few data structures to define what options
1083 are legal and how they are to be processed.
1084
1085 First, the C<@options> array defines the I<names> of all the options that
1086 are to be accepted.
1087
1088 =cut
1089
1090 @options = qw(
1091   CommandSet   HistFile      HistSize
1092   hashDepth    arrayDepth    dumpDepth
1093   DumpDBFiles  DumpPackages  DumpReused
1094   compactDump  veryCompact   quote
1095   HighBit      undefPrint    globPrint
1096   PrintRet     UsageOnly     frame
1097   AutoTrace    TTY           noTTY
1098   ReadLine     NonStop       LineInfo
1099   maxTraceLen  recallCommand ShellBang
1100   pager        tkRunning     ornaments
1101   signalLevel  warnLevel     dieLevel
1102   inhibit_exit ImmediateStop bareStringify
1103   CreateTTY    RemotePort    windowSize
1104   DollarCaretP
1105 );
1106
1107 @RememberOnROptions = qw(DollarCaretP);
1108
1109 =pod
1110
1111 Second, C<optionVars> lists the variables that each option uses to save its
1112 state.
1113
1114 =cut
1115
1116 %optionVars = (
1117     hashDepth     => \$dumpvar::hashDepth,
1118     arrayDepth    => \$dumpvar::arrayDepth,
1119     CommandSet    => \$CommandSet,
1120     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1121     DumpPackages  => \$dumpvar::dumpPackages,
1122     DumpReused    => \$dumpvar::dumpReused,
1123     HighBit       => \$dumpvar::quoteHighBit,
1124     undefPrint    => \$dumpvar::printUndef,
1125     globPrint     => \$dumpvar::globPrint,
1126     UsageOnly     => \$dumpvar::usageOnly,
1127     CreateTTY     => \$CreateTTY,
1128     bareStringify => \$dumpvar::bareStringify,
1129     frame         => \$frame,
1130     AutoTrace     => \$trace,
1131     inhibit_exit  => \$inhibit_exit,
1132     maxTraceLen   => \$maxtrace,
1133     ImmediateStop => \$ImmediateStop,
1134     RemotePort    => \$remoteport,
1135     windowSize    => \$window,
1136     HistFile      => \$histfile,
1137     HistSize      => \$histsize,
1138 );
1139
1140 =pod
1141
1142 Third, C<%optionAction> defines the subroutine to be called to process each
1143 option.
1144
1145 =cut
1146
1147 %optionAction = (
1148     compactDump   => \&dumpvar::compactDump,
1149     veryCompact   => \&dumpvar::veryCompact,
1150     quote         => \&dumpvar::quote,
1151     TTY           => \&TTY,
1152     noTTY         => \&noTTY,
1153     ReadLine      => \&ReadLine,
1154     NonStop       => \&NonStop,
1155     LineInfo      => \&LineInfo,
1156     recallCommand => \&recallCommand,
1157     ShellBang     => \&shellBang,
1158     pager         => \&pager,
1159     signalLevel   => \&signalLevel,
1160     warnLevel     => \&warnLevel,
1161     dieLevel      => \&dieLevel,
1162     tkRunning     => \&tkRunning,
1163     ornaments     => \&ornaments,
1164     RemotePort    => \&RemotePort,
1165     DollarCaretP  => \&DollarCaretP,
1166 );
1167
1168 =pod
1169
1170 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1171 option is used.
1172
1173 =cut
1174
1175 # Note that this list is not complete: several options not listed here
1176 # actually require that dumpvar.pl be loaded for them to work, but are
1177 # not in the table. A subsequent patch will correct this problem; for
1178 # the moment, we're just recommenting, and we are NOT going to change
1179 # function.
1180 %optionRequire = (
1181     compactDump => 'dumpvar.pl',
1182     veryCompact => 'dumpvar.pl',
1183     quote       => 'dumpvar.pl',
1184 );
1185
1186 =pod
1187
1188 There are a number of initialization-related variables which can be set
1189 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1190 variable. These are:
1191
1192 =over 4
1193
1194 =item C<$rl> - readline control XXX needs more explanation
1195
1196 =item C<$warnLevel> - whether or not debugger takes over warning handling
1197
1198 =item C<$dieLevel> - whether or not debugger takes over die handling
1199
1200 =item C<$signalLevel> - whether or not debugger takes over signal handling
1201
1202 =item C<$pre> - preprompt actions (array reference)
1203
1204 =item C<$post> - postprompt actions (array reference)
1205
1206 =item C<$pretype>
1207
1208 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1209
1210 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1211
1212 =back
1213
1214 =cut
1215
1216 # These guys may be defined in $ENV{PERL5DB} :
1217 $rl          = 1     unless defined $rl;
1218 $warnLevel   = 1     unless defined $warnLevel;
1219 $dieLevel    = 1     unless defined $dieLevel;
1220 $signalLevel = 1     unless defined $signalLevel;
1221 $pre         = []    unless defined $pre;
1222 $post        = []    unless defined $post;
1223 $pretype     = []    unless defined $pretype;
1224 $CreateTTY   = 3     unless defined $CreateTTY;
1225 $CommandSet  = '580' unless defined $CommandSet;
1226
1227 share($rl);
1228 share($warnLevel);
1229 share($dieLevel);
1230 share($signalLevel);
1231 share($pre);
1232 share($post);
1233 share($pretype);
1234 share($rl);
1235 share($CreateTTY);
1236 share($CommandSet);
1237
1238 =pod
1239
1240 The default C<die>, C<warn>, and C<signal> handlers are set up.
1241
1242 =cut
1243
1244 warnLevel($warnLevel);
1245 dieLevel($dieLevel);
1246 signalLevel($signalLevel);
1247
1248 =pod
1249
1250 The pager to be used is needed next. We try to get it from the
1251 environment first.  If it's not defined there, we try to find it in
1252 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1253 then call the C<pager()> function to save the pager name.
1254
1255 =cut
1256
1257 # This routine makes sure $pager is set up so that '|' can use it.
1258 pager(
1259
1260     # If PAGER is defined in the environment, use it.
1261     defined $ENV{PAGER}
1262     ? $ENV{PAGER}
1263
1264       # If not, see if Config.pm defines it.
1265     : eval { require Config }
1266       && defined $Config::Config{pager}
1267     ? $Config::Config{pager}
1268
1269       # If not, fall back to 'more'.
1270     : 'more'
1271   )
1272   unless defined $pager;
1273
1274 =pod
1275
1276 We set up the command to be used to access the man pages, the command
1277 recall character (C<!> unless otherwise defined) and the shell escape
1278 character (C<!> unless otherwise defined). Yes, these do conflict, and
1279 neither works in the debugger at the moment.
1280
1281 =cut
1282
1283 setman();
1284
1285 # Set up defaults for command recall and shell escape (note:
1286 # these currently don't work in linemode debugging).
1287 &recallCommand("!") unless defined $prc;
1288 &shellBang("!")     unless defined $psh;
1289
1290 =pod
1291
1292 We then set up the gigantic string containing the debugger help.
1293 We also set the limit on the number of arguments we'll display during a
1294 trace.
1295
1296 =cut
1297
1298 sethelp();
1299
1300 # If we didn't get a default for the length of eval/stack trace args,
1301 # set it here.
1302 $maxtrace = 400 unless defined $maxtrace;
1303
1304 =head2 SETTING UP THE DEBUGGER GREETING
1305
1306 The debugger I<greeting> helps to inform the user how many debuggers are
1307 running, and whether the current debugger is the primary or a child.
1308
1309 If we are the primary, we just hang onto our pid so we'll have it when
1310 or if we start a child debugger. If we are a child, we'll set things up
1311 so we'll have a unique greeting and so the parent will give us our own
1312 TTY later.
1313
1314 We save the current contents of the C<PERLDB_PIDS> environment variable
1315 because we mess around with it. We'll also need to hang onto it because
1316 we'll need it if we restart.
1317
1318 Child debuggers make a label out of the current PID structure recorded in
1319 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1320 yet so the parent will give them one later via C<resetterm()>.
1321
1322 =cut
1323
1324 # Save the current contents of the environment; we're about to
1325 # much with it. We'll need this if we have to restart.
1326 $ini_pids = $ENV{PERLDB_PIDS};
1327
1328 if ( defined $ENV{PERLDB_PIDS} ) {
1329
1330     # We're a child. Make us a label out of the current PID structure
1331     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1332     # a term yet so the parent will give us one later via resetterm().
1333
1334     my $env_pids = $ENV{PERLDB_PIDS};
1335     $pids = "[$env_pids]";
1336
1337     # Unless we are on OpenVMS, all programs under the DCL shell run under
1338     # the same PID.
1339
1340     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1341         $term_pid         = $$;
1342     }
1343     else {
1344         $ENV{PERLDB_PIDS} .= "->$$";
1345         $term_pid = -1;
1346     }
1347
1348 } ## end if (defined $ENV{PERLDB_PIDS...
1349 else {
1350
1351     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1352     # child debugger, and mark us as the parent, so we'll know to set up
1353     # more TTY's is we have to.
1354     $ENV{PERLDB_PIDS} = "$$";
1355     $pids             = "[pid=$$]";
1356     $term_pid         = $$;
1357 }
1358
1359 $pidprompt = '';
1360
1361 # Sets up $emacs as a synonym for $slave_editor.
1362 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1363
1364 =head2 READING THE RC FILE
1365
1366 The debugger will read a file of initialization options if supplied. If
1367 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1368
1369 =cut
1370
1371 # As noted, this test really doesn't check accurately that the debugger
1372 # is running at a terminal or not.
1373
1374 my $dev_tty = '/dev/tty';
1375    $dev_tty = 'TT:' if ($^O eq 'VMS');
1376 if ( -e $dev_tty ) {                      # this is the wrong metric!
1377     $rcfile = ".perldb";
1378 }
1379 else {
1380     $rcfile = "perldb.ini";
1381 }
1382
1383 =pod
1384
1385 The debugger does a safety test of the file to be read. It must be owned
1386 either by the current user or root, and must only be writable by the owner.
1387
1388 =cut
1389
1390 # This wraps a safety test around "do" to read and evaluate the init file.
1391 #
1392 # This isn't really safe, because there's a race
1393 # between checking and opening.  The solution is to
1394 # open and fstat the handle, but then you have to read and
1395 # eval the contents.  But then the silly thing gets
1396 # your lexical scope, which is unfortunate at best.
1397 sub safe_do {
1398     my $file = shift;
1399
1400     # Just exactly what part of the word "CORE::" don't you understand?
1401     local $SIG{__WARN__};
1402     local $SIG{__DIE__};
1403
1404     unless ( is_safe_file($file) ) {
1405         CORE::warn <<EO_GRIPE;
1406 perldb: Must not source insecure rcfile $file.
1407         You or the superuser must be the owner, and it must not
1408         be writable by anyone but its owner.
1409 EO_GRIPE
1410         return;
1411     } ## end unless (is_safe_file($file...
1412
1413     do $file;
1414     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1415 } ## end sub safe_do
1416
1417 # This is the safety test itself.
1418 #
1419 # Verifies that owner is either real user or superuser and that no
1420 # one but owner may write to it.  This function is of limited use
1421 # when called on a path instead of upon a handle, because there are
1422 # no guarantees that filename (by dirent) whose file (by ino) is
1423 # eventually accessed is the same as the one tested.
1424 # Assumes that the file's existence is not in doubt.
1425 sub is_safe_file {
1426     my $path = shift;
1427     stat($path) || return;    # mysteriously vaporized
1428     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1429
1430     return 0 if $uid != 0 && $uid != $<;
1431     return 0 if $mode & 022;
1432     return 1;
1433 } ## end sub is_safe_file
1434
1435 # If the rcfile (whichever one we decided was the right one to read)
1436 # exists, we safely do it.
1437 if ( -f $rcfile ) {
1438     safe_do("./$rcfile");
1439 }
1440
1441 # If there isn't one here, try the user's home directory.
1442 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1443     safe_do("$ENV{HOME}/$rcfile");
1444 }
1445
1446 # Else try the login directory.
1447 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1448     safe_do("$ENV{LOGDIR}/$rcfile");
1449 }
1450
1451 # If the PERLDB_OPTS variable has options in it, parse those out next.
1452 if ( defined $ENV{PERLDB_OPTS} ) {
1453     parse_options( $ENV{PERLDB_OPTS} );
1454 }
1455
1456 =pod
1457
1458 The last thing we do during initialization is determine which subroutine is
1459 to be used to obtain a new terminal when a new debugger is started. Right now,
1460 the debugger only handles X Windows, OS/2, and Mac OS X (darwin).
1461
1462 =cut
1463
1464 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1465 # Works if you're running an xterm or xterm-like window, or you're on
1466 # OS/2, or on Mac OS X. This may need some expansion.
1467
1468 if (not defined &get_fork_TTY)       # only if no routine exists
1469 {
1470     if (defined $ENV{TERM}                       # If we know what kind
1471                                                  # of terminal this is,
1472         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1473         and defined $ENV{DISPLAY}                # and what display it's on,
1474       )
1475     {
1476         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1477     }
1478     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1479         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1480     }
1481     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1482             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1483             and $ENV{TERM_PROGRAM}
1484                 eq 'Apple_Terminal'              # Terminal.app
1485             )
1486     {
1487         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1488     }
1489 } ## end if (not defined &get_fork_TTY...
1490
1491 # untaint $^O, which may have been tainted by the last statement.
1492 # see bug [perl #24674]
1493 $^O =~ m/^(.*)\z/;
1494 $^O = $1;
1495
1496 # Here begin the unreadable code.  It needs fixing.
1497
1498 =head2 RESTART PROCESSING
1499
1500 This section handles the restart command. When the C<R> command is invoked, it
1501 tries to capture all of the state it can into environment variables, and
1502 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1503 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1504 the R command stuffed into the environment variables.
1505
1506   PERLDB_RESTART   - flag only, contains no restart data itself.
1507   PERLDB_HIST      - command history, if it's available
1508   PERLDB_ON_LOAD   - breakpoints set by the rc file
1509   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1510   PERLDB_VISITED   - files that had breakpoints
1511   PERLDB_FILE_...  - breakpoints for a file
1512   PERLDB_OPT       - active options
1513   PERLDB_INC       - the original @INC
1514   PERLDB_PRETYPE   - preprompt debugger actions
1515   PERLDB_PRE       - preprompt Perl code
1516   PERLDB_POST      - post-prompt Perl code
1517   PERLDB_TYPEAHEAD - typeahead captured by readline()
1518
1519 We chug through all these variables and plug the values saved in them
1520 back into the appropriate spots in the debugger.
1521
1522 =cut
1523
1524 if ( exists $ENV{PERLDB_RESTART} ) {
1525
1526     # We're restarting, so we don't need the flag that says to restart anymore.
1527     delete $ENV{PERLDB_RESTART};
1528
1529     # $restart = 1;
1530     @hist          = get_list('PERLDB_HIST');
1531     %break_on_load = get_list("PERLDB_ON_LOAD");
1532     %postponed     = get_list("PERLDB_POSTPONE");
1533
1534         share(@hist);
1535         share(@truehist);
1536         share(%break_on_load);
1537         share(%postponed);
1538
1539     # restore breakpoints/actions
1540     my @had_breakpoints = get_list("PERLDB_VISITED");
1541     for ( 0 .. $#had_breakpoints ) {
1542         my %pf = get_list("PERLDB_FILE_$_");
1543         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1544     }
1545
1546     # restore options
1547     my %opt = get_list("PERLDB_OPT");
1548     my ( $opt, $val );
1549     while ( ( $opt, $val ) = each %opt ) {
1550         $val =~ s/[\\\']/\\$1/g;
1551         parse_options("$opt'$val'");
1552     }
1553
1554     # restore original @INC
1555     @INC     = get_list("PERLDB_INC");
1556     @ini_INC = @INC;
1557
1558     # return pre/postprompt actions and typeahead buffer
1559     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1560     $pre       = [ get_list("PERLDB_PRE") ];
1561     $post      = [ get_list("PERLDB_POST") ];
1562     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1563 } ## end if (exists $ENV{PERLDB_RESTART...
1564
1565 =head2 SETTING UP THE TERMINAL
1566
1567 Now, we'll decide how the debugger is going to interact with the user.
1568 If there's no TTY, we set the debugger to run non-stop; there's not going
1569 to be anyone there to enter commands.
1570
1571 =cut
1572
1573 if ($notty) {
1574     $runnonstop = 1;
1575         share($runnonstop);
1576 }
1577
1578 =pod
1579
1580 If there is a TTY, we have to determine who it belongs to before we can
1581 proceed. If this is a slave editor or graphical debugger (denoted by
1582 the first command-line switch being '-emacs'), we shift this off and
1583 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1584
1585 =cut
1586
1587 else {
1588
1589     # Is Perl being run from a slave editor or graphical debugger?
1590     # If so, don't use readline, and set $slave_editor = 1.
1591     $slave_editor =
1592       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1593     $rl = 0, shift(@main::ARGV) if $slave_editor;
1594
1595     #require Term::ReadLine;
1596
1597 =pod
1598
1599 We then determine what the console should be on various systems:
1600
1601 =over 4
1602
1603 =item * Cygwin - We use C<stdin> instead of a separate device.
1604
1605 =cut
1606
1607     if ( $^O eq 'cygwin' ) {
1608
1609         # /dev/tty is binary. use stdin for textmode
1610         undef $console;
1611     }
1612
1613 =item * Unix - use C</dev/tty>.
1614
1615 =cut
1616
1617     elsif ( -e "/dev/tty" ) {
1618         $console = "/dev/tty";
1619     }
1620
1621 =item * Windows or MSDOS - use C<con>.
1622
1623 =cut
1624
1625     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1626         $console = "con";
1627     }
1628
1629 =item * MacOS - use C<Dev:Console:Perl Debug> if this is the MPW version; C<Dev:
1630 Console> if not.
1631
1632 Note that Mac OS X returns C<darwin>, not C<MacOS>. Also note that the debugger doesn't do anything special for C<darwin>. Maybe it should.
1633
1634 =cut
1635
1636     elsif ( $^O eq 'MacOS' ) {
1637         if ( $MacPerl::Version !~ /MPW/ ) {
1638             $console =
1639               "Dev:Console:Perl Debug";    # Separate window for application
1640         }
1641         else {
1642             $console = "Dev:Console";
1643         }
1644     } ## end elsif ($^O eq 'MacOS')
1645
1646 =item * VMS - use C<sys$command>.
1647
1648 =cut
1649
1650     else {
1651
1652         # everything else is ...
1653         $console = "sys\$command";
1654     }
1655
1656 =pod
1657
1658 =back
1659
1660 Several other systems don't use a specific console. We C<undef $console>
1661 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1662 with a slave editor, Epoc).
1663
1664 =cut
1665
1666     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1667
1668         # /dev/tty is binary. use stdin for textmode
1669         $console = undef;
1670     }
1671
1672     if ( $^O eq 'NetWare' ) {
1673
1674         # /dev/tty is binary. use stdin for textmode
1675         $console = undef;
1676     }
1677
1678     # In OS/2, we need to use STDIN to get textmode too, even though
1679     # it pretty much looks like Unix otherwise.
1680     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1681     {    # In OS/2
1682         $console = undef;
1683     }
1684
1685     # EPOC also falls into the 'got to use STDIN' camp.
1686     if ( $^O eq 'epoc' ) {
1687         $console = undef;
1688     }
1689
1690 =pod
1691
1692 If there is a TTY hanging around from a parent, we use that as the console.
1693
1694 =cut
1695
1696     $console = $tty if defined $tty;
1697
1698 =head2 SOCKET HANDLING
1699
1700 The debugger is capable of opening a socket and carrying out a debugging
1701 session over the socket.
1702
1703 If C<RemotePort> was defined in the options, the debugger assumes that it
1704 should try to start a debugging session on that port. It builds the socket
1705 and then tries to connect the input and output filehandles to it.
1706
1707 =cut
1708
1709     # Handle socket stuff.
1710
1711     if ( defined $remoteport ) {
1712
1713         # If RemotePort was defined in the options, connect input and output
1714         # to the socket.
1715         require IO::Socket;
1716         $OUT = new IO::Socket::INET(
1717             Timeout  => '10',
1718             PeerAddr => $remoteport,
1719             Proto    => 'tcp',
1720         );
1721         if ( !$OUT ) { die "Unable to connect to remote host: $remoteport\n"; }
1722         $IN = $OUT;
1723     } ## end if (defined $remoteport)
1724
1725 =pod
1726
1727 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1728 this is probably a situation where multiple debuggers are running (for example,
1729 a backticked command that starts up another debugger). We create a new IN and
1730 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1731 and if we can.
1732
1733 =cut
1734
1735     # Non-socket.
1736     else {
1737
1738         # Two debuggers running (probably a system or a backtick that invokes
1739         # the debugger itself under the running one). create a new IN and OUT
1740         # filehandle, and do the necessary mojo to create a new tty if we
1741         # know how, and we can.
1742         create_IN_OUT(4) if $CreateTTY & 4;
1743         if ($console) {
1744
1745             # If we have a console, check to see if there are separate ins and
1746             # outs to open. (They are assumed identical if not.)
1747
1748             my ( $i, $o ) = split /,/, $console;
1749             $o = $i unless defined $o;
1750
1751             # read/write on in, or just read, or read on STDIN.
1752             open( IN,      "+<$i" )
1753               || open( IN, "<$i" )
1754               || open( IN, "<&STDIN" );
1755
1756             # read/write/create/clobber out, or write/create/clobber out,
1757             # or merge with STDERR, or merge with STDOUT.
1758                  open( OUT, "+>$o" )
1759               || open( OUT, ">$o" )
1760               || open( OUT, ">&STDERR" )
1761               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1762
1763         } ## end if ($console)
1764         elsif ( not defined $console ) {
1765
1766             # No console. Open STDIN.
1767             open( IN, "<&STDIN" );
1768
1769             # merge with STDERR, or with STDOUT.
1770             open( OUT,      ">&STDERR" )
1771               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1772             $console = 'STDIN/OUT';
1773         } ## end elsif (not defined $console)
1774
1775         # Keep copies of the filehandles so that when the pager runs, it
1776         # can close standard input without clobbering ours.
1777         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1778     } ## end elsif (from if(defined $remoteport))
1779
1780     # Unbuffer DB::OUT. We need to see responses right away.
1781     my $previous = select($OUT);
1782     $| = 1;                                  # for DB::OUT
1783     select($previous);
1784
1785     # Line info goes to debugger output unless pointed elsewhere.
1786     # Pointing elsewhere makes it possible for slave editors to
1787     # keep track of file and position. We have both a filehandle
1788     # and a I/O description to keep track of.
1789     $LINEINFO = $OUT     unless defined $LINEINFO;
1790     $lineinfo = $console unless defined $lineinfo;
1791         # share($LINEINFO); # <- unable to share globs
1792         share($lineinfo);   #
1793
1794 =pod
1795
1796 To finish initialization, we show the debugger greeting,
1797 and then call the C<afterinit()> subroutine if there is one.
1798
1799 =cut
1800
1801     # Show the debugger greeting.
1802     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1803     unless ($runnonstop) {
1804         local $\ = '';
1805         local $, = '';
1806         if ( $term_pid eq '-1' ) {
1807             print $OUT "\nDaughter DB session started...\n";
1808         }
1809         else {
1810             print $OUT "\nLoading DB routines from $header\n";
1811             print $OUT (
1812                 "Editor support ",
1813                 $slave_editor ? "enabled" : "available", ".\n"
1814             );
1815             print $OUT
1816 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1817         } ## end else [ if ($term_pid eq '-1')
1818     } ## end unless ($runnonstop)
1819 } ## end else [ if ($notty)
1820
1821 # XXX This looks like a bug to me.
1822 # Why copy to @ARGS and then futz with @args?
1823 @ARGS = @ARGV;
1824 for (@args) {
1825     # Make sure backslashes before single quotes are stripped out, and
1826     # keep args unless they are numeric (XXX why?)
1827     # s/\'/\\\'/g;                      # removed while not justified understandably
1828     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1829 }
1830
1831 # If there was an afterinit() sub defined, call it. It will get
1832 # executed in our scope, so it can fiddle with debugger globals.
1833 if ( defined &afterinit ) {    # May be defined in $rcfile
1834     &afterinit();
1835 }
1836
1837 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1838 $I_m_init = 1;
1839
1840 ############################################################ Subroutines
1841
1842 =head1 SUBROUTINES
1843
1844 =head2 DB
1845
1846 This gigantic subroutine is the heart of the debugger. Called before every
1847 statement, its job is to determine if a breakpoint has been reached, and
1848 stop if so; read commands from the user, parse them, and execute
1849 them, and hen send execution off to the next statement.
1850
1851 Note that the order in which the commands are processed is very important;
1852 some commands earlier in the loop will actually alter the C<$cmd> variable
1853 to create other commands to be executed later. This is all highly I<optimized>
1854 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1855 see what's happening in any given command.
1856
1857 =cut
1858
1859 sub DB {
1860
1861     # lock the debugger and get the thread id for the prompt
1862         lock($DBGR);
1863         my $tid;
1864         if ($ENV{PERL5DB_THREADED}) {
1865                 $tid = eval { "[".threads->tid."]" };
1866         }
1867
1868     # Check for whether we should be running continuously or not.
1869     # _After_ the perl program is compiled, $single is set to 1:
1870     if ( $single and not $second_time++ ) {
1871
1872         # Options say run non-stop. Run until we get an interrupt.
1873         if ($runnonstop) {    # Disable until signal
1874                 # If there's any call stack in place, turn off single
1875                 # stepping into subs throughout the stack.
1876             for ( $i = 0 ; $i <= $stack_depth ; ) {
1877                 $stack[ $i++ ] &= ~1;
1878             }
1879
1880             # And we are now no longer in single-step mode.
1881             $single = 0;
1882
1883             # If we simply returned at this point, we wouldn't get
1884             # the trace info. Fall on through.
1885             # return;
1886         } ## end if ($runnonstop)
1887
1888         elsif ($ImmediateStop) {
1889
1890             # We are supposed to stop here; XXX probably a break.
1891             $ImmediateStop = 0;    # We've processed it; turn it off
1892             $signal        = 1;    # Simulate an interrupt to force
1893                                    # us into the command loop
1894         }
1895     } ## end if ($single and not $second_time...
1896
1897     # If we're in single-step mode, or an interrupt (real or fake)
1898     # has occurred, turn off non-stop mode.
1899     $runnonstop = 0 if $single or $signal;
1900
1901     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1902     # The code being debugged may have altered them.
1903     &save;
1904
1905     # Since DB::DB gets called after every line, we can use caller() to
1906     # figure out where we last were executing. Sneaky, eh? This works because
1907     # caller is returning all the extra information when called from the
1908     # debugger.
1909     local ( $package, $filename, $line ) = caller;
1910     local $filename_ini = $filename;
1911
1912     # set up the context for DB::eval, so it can properly execute
1913     # code on behalf of the user. We add the package in so that the
1914     # code is eval'ed in the proper package (not in the debugger!).
1915     local $usercontext =
1916       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1917
1918     # Create an alias to the active file magical array to simplify
1919     # the code here.
1920     local (*dbline) = $main::{ '_<' . $filename };
1921
1922     # we need to check for pseudofiles on Mac OS (these are files
1923     # not attached to a filename, but instead stored in Dev:Pseudo)
1924     if ( $^O eq 'MacOS' && $#dbline < 0 ) {
1925         $filename_ini = $filename = 'Dev:Pseudo';
1926         *dbline = $main::{ '_<' . $filename };
1927     }
1928
1929     # Last line in the program.
1930     local $max = $#dbline;
1931
1932     # if we have something here, see if we should break.
1933     if ( $dbline{$line}
1934         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1935     {
1936
1937         # Stop if the stop criterion says to just stop.
1938         if ( $stop eq '1' ) {
1939             $signal |= 1;
1940         }
1941
1942         # It's a conditional stop; eval it in the user's context and
1943         # see if we should stop. If so, remove the one-time sigil.
1944         elsif ($stop) {
1945             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1946             &eval;
1947             $dbline{$line} =~ s/;9($|\0)/$1/;
1948         }
1949     } ## end if ($dbline{$line} && ...
1950
1951     # Preserve the current stop-or-not, and see if any of the W
1952     # (watch expressions) has changed.
1953     my $was_signal = $signal;
1954
1955     # If we have any watch expressions ...
1956     if ( $trace & 2 ) {
1957         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1958             $evalarg = $to_watch[$n];
1959             local $onetimeDump;    # Tell DB::eval() to not output results
1960
1961             # Fix context DB::eval() wants to return an array, but
1962             # we need a scalar here.
1963             my ($val) = join( "', '", &eval );
1964             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1965
1966             # Did it change?
1967             if ( $val ne $old_watch[$n] ) {
1968
1969                 # Yep! Show the difference, and fake an interrupt.
1970                 $signal = 1;
1971                 print $OUT <<EOP;
1972 Watchpoint $n:\t$to_watch[$n] changed:
1973     old value:\t$old_watch[$n]
1974     new value:\t$val
1975 EOP
1976                 $old_watch[$n] = $val;
1977             } ## end if ($val ne $old_watch...
1978         } ## end for (my $n = 0 ; $n <= ...
1979     } ## end if ($trace & 2)
1980
1981 =head2 C<watchfunction()>
1982
1983 C<watchfunction()> is a function that can be defined by the user; it is a
1984 function which will be run on each entry to C<DB::DB>; it gets the
1985 current package, filename, and line as its parameters.
1986
1987 The watchfunction can do anything it likes; it is executing in the
1988 debugger's context, so it has access to all of the debugger's internal
1989 data structures and functions.
1990
1991 C<watchfunction()> can control the debugger's actions. Any of the following
1992 will cause the debugger to return control to the user's program after
1993 C<watchfunction()> executes:
1994
1995 =over 4
1996
1997 =item *
1998
1999 Returning a false value from the C<watchfunction()> itself.
2000
2001 =item *
2002
2003 Altering C<$single> to a false value.
2004
2005 =item *
2006
2007 Altering C<$signal> to a false value.
2008
2009 =item *
2010
2011 Turning off the C<4> bit in C<$trace> (this also disables the
2012 check for C<watchfunction()>. This can be done with
2013
2014     $trace &= ~4;
2015
2016 =back
2017
2018 =cut
2019
2020     # If there's a user-defined DB::watchfunction, call it with the
2021     # current package, filename, and line. The function executes in
2022     # the DB:: package.
2023     if ( $trace & 4 ) {    # User-installed watch
2024         return
2025           if watchfunction( $package, $filename, $line )
2026           and not $single
2027           and not $was_signal
2028           and not( $trace & ~4 );
2029     } ## end if ($trace & 4)
2030
2031     # Pick up any alteration to $signal in the watchfunction, and
2032     # turn off the signal now.
2033     $was_signal = $signal;
2034     $signal     = 0;
2035
2036 =head2 GETTING READY TO EXECUTE COMMANDS
2037
2038 The debugger decides to take control if single-step mode is on, the
2039 C<t> command was entered, or the user generated a signal. If the program
2040 has fallen off the end, we set things up so that entering further commands
2041 won't cause trouble, and we say that the program is over.
2042
2043 =cut
2044
2045     # Check to see if we should grab control ($single true,
2046     # trace set appropriately, or we got a signal).
2047     if ( $single || ( $trace & 1 ) || $was_signal ) {
2048
2049         # Yes, grab control.
2050         if ($slave_editor) {
2051
2052             # Tell the editor to update its position.
2053             $position = "\032\032$filename:$line:0\n";
2054             print_lineinfo($position);
2055         }
2056
2057 =pod
2058
2059 Special check: if we're in package C<DB::fake>, we've gone through the
2060 C<END> block at least once. We set up everything so that we can continue
2061 to enter commands and have a valid context to be in.
2062
2063 =cut
2064
2065         elsif ( $package eq 'DB::fake' ) {
2066
2067             # Fallen off the end already.
2068             $term || &setterm;
2069             print_help(<<EOP);
2070 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2071   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2072   B<h q>, B<h R> or B<h o> to get additional info.
2073 EOP
2074
2075             # Set the DB::eval context appropriately.
2076             $package     = 'main';
2077             $usercontext =
2078                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2079               . "package $package;";    # this won't let them modify, alas
2080         } ## end elsif ($package eq 'DB::fake')
2081
2082 =pod
2083
2084 If the program hasn't finished executing, we scan forward to the
2085 next executable line, print that out, build the prompt from the file and line
2086 number information, and print that.
2087
2088 =cut
2089
2090         else {
2091
2092             # Still somewhere in the midst of execution. Set up the
2093             #  debugger prompt.
2094             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2095                                  # Perl 5 ones (sorry, we don't print Klingon
2096                                  #module names)
2097
2098             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2099             $prefix .= "$sub($filename:";
2100             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2101
2102             # Break up the prompt if it's really long.
2103             if ( length($prefix) > 30 ) {
2104                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2105                 $prefix   = "";
2106                 $infix    = ":\t";
2107             }
2108             else {
2109                 $infix    = "):\t";
2110                 $position = "$prefix$line$infix$dbline[$line]$after";
2111             }
2112
2113             # Print current line info, indenting if necessary.
2114             if ($frame) {
2115                 print_lineinfo( ' ' x $stack_depth,
2116                     "$line:\t$dbline[$line]$after" );
2117             }
2118             else {
2119                 print_lineinfo($position);
2120             }
2121
2122             # Scan forward, stopping at either the end or the next
2123             # unbreakable line.
2124             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2125             {    #{ vi
2126
2127                 # Drop out on null statements, block closers, and comments.
2128                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2129
2130                 # Drop out if the user interrupted us.
2131                 last if $signal;
2132
2133                 # Append a newline if the line doesn't have one. Can happen
2134                 # in eval'ed text, for instance.
2135                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2136
2137                 # Next executable line.
2138                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2139                 $position .= $incr_pos;
2140                 if ($frame) {
2141
2142                     # Print it indented if tracing is on.
2143                     print_lineinfo( ' ' x $stack_depth,
2144                         "$i:\t$dbline[$i]$after" );
2145                 }
2146                 else {
2147                     print_lineinfo($incr_pos);
2148                 }
2149             } ## end for ($i = $line + 1 ; $i...
2150         } ## end else [ if ($slave_editor)
2151     } ## end if ($single || ($trace...
2152
2153 =pod
2154
2155 If there's an action to be executed for the line we stopped at, execute it.
2156 If there are any preprompt actions, execute those as well.
2157
2158 =cut
2159
2160     # If there's an action, do it now.
2161     $evalarg = $action, &eval if $action;
2162
2163     # Are we nested another level (e.g., did we evaluate a function
2164     # that had a breakpoint in it at the debugger prompt)?
2165     if ( $single || $was_signal ) {
2166
2167         # Yes, go down a level.
2168         local $level = $level + 1;
2169
2170         # Do any pre-prompt actions.
2171         foreach $evalarg (@$pre) {
2172             &eval;
2173         }
2174
2175         # Complain about too much recursion if we passed the limit.
2176         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2177           if $single & 4;
2178
2179         # The line we're currently on. Set $incr to -1 to stay here
2180         # until we get a command that tells us to advance.
2181         $start = $line;
2182         $incr  = -1;      # for backward motion.
2183
2184         # Tack preprompt debugger actions ahead of any actual input.
2185         @typeahead = ( @$pretype, @typeahead );
2186
2187 =head2 WHERE ARE WE?
2188
2189 XXX Relocate this section?
2190
2191 The debugger normally shows the line corresponding to the current line of
2192 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2193 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2194
2195 C<$incr> controls by how many lines the I<current> line should move forward
2196 after a command is executed. If set to -1, this indicates that the I<current>
2197 line shouldn't change.
2198
2199 C<$start> is the I<current> line. It is used for things like knowing where to
2200 move forwards or backwards from when doing an C<L> or C<-> command.
2201
2202 C<$max> tells the debugger where the last line of the current file is. It's
2203 used to terminate loops most often.
2204
2205 =head2 THE COMMAND LOOP
2206
2207 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2208 in two parts:
2209
2210 =over 4
2211
2212 =item *
2213
2214 The outer part of the loop, starting at the C<CMD> label. This loop
2215 reads a command and then executes it.
2216
2217 =item *
2218
2219 The inner part of the loop, starting at the C<PIPE> label. This part
2220 is wholly contained inside the C<CMD> block and only executes a command.
2221 Used to handle commands running inside a pager.
2222
2223 =back
2224
2225 So why have two labels to restart the loop? Because sometimes, it's easier to
2226 have a command I<generate> another command and then re-execute the loop to do
2227 the new command. This is faster, but perhaps a bit more convoluted.
2228
2229 =cut
2230
2231         # The big command dispatch loop. It keeps running until the
2232         # user yields up control again.
2233         #
2234         # If we have a terminal for input, and we get something back
2235         # from readline(), keep on processing.
2236       CMD:
2237         while (
2238
2239             # We have a terminal, or can get one ...
2240             ( $term || &setterm ),
2241
2242             # ... and it belogs to this PID or we get one for this PID ...
2243             ( $term_pid == $$ or resetterm(1) ),
2244
2245             # ... and we got a line of command input ...
2246             defined(
2247                 $cmd = &readline(
2248                         "$pidprompt $tid DB"
2249                       . ( '<' x $level )
2250                       . ( $#hist + 1 )
2251                       . ( '>' x $level ) . " "
2252                 )
2253             )
2254           )
2255         {
2256
2257                         share($cmd);
2258             # ... try to execute the input as debugger commands.
2259
2260             # Don't stop running.
2261             $single = 0;
2262
2263             # No signal is active.
2264             $signal = 0;
2265
2266             # Handle continued commands (ending with \):
2267             $cmd =~ s/\\$/\n/ && do {
2268                 $cmd .= &readline("  cont: ");
2269                 redo CMD;
2270             };
2271
2272 =head4 The null command
2273
2274 A newline entered by itself means I<re-execute the last command>. We grab the
2275 command out of C<$laststep> (where it was recorded previously), and copy it
2276 back into C<$cmd> to be executed below. If there wasn't any previous command,
2277 we'll do nothing below (no command will match). If there was, we also save it
2278 in the command history and fall through to allow the command parsing to pick
2279 it up.
2280
2281 =cut
2282
2283             # Empty input means repeat the last command.
2284             $cmd =~ /^$/ && ( $cmd = $laststep );
2285             chomp($cmd);    # get rid of the annoying extra newline
2286             push( @hist, $cmd ) if length($cmd) > 1;
2287             push( @truehist, $cmd );
2288                         share(@hist);
2289                         share(@truehist);
2290
2291             # This is a restart point for commands that didn't arrive
2292             # via direct user input. It allows us to 'redo PIPE' to
2293             # re-execute command processing without reading a new command.
2294           PIPE: {
2295                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2296                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2297                 ($i) = split( /\s+/, $cmd );
2298
2299 =head3 COMMAND ALIASES
2300
2301 The debugger can create aliases for commands (these are stored in the
2302 C<%alias> hash). Before a command is executed, the command loop looks it up
2303 in the alias hash and substitutes the contents of the alias for the command,
2304 completely replacing it.
2305
2306 =cut
2307
2308                 # See if there's an alias for the command, and set it up if so.
2309                 if ( $alias{$i} ) {
2310
2311                     # Squelch signal handling; we want to keep control here
2312                     # if something goes loco during the alias eval.
2313                     local $SIG{__DIE__};
2314                     local $SIG{__WARN__};
2315
2316                     # This is a command, so we eval it in the DEBUGGER's
2317                     # scope! Otherwise, we can't see the special debugger
2318                     # variables, or get to the debugger's subs. (Well, we
2319                     # _could_, but why make it even more complicated?)
2320                     eval "\$cmd =~ $alias{$i}";
2321                     if ($@) {
2322                         local $\ = '';
2323                         print $OUT "Couldn't evaluate `$i' alias: $@";
2324                         next CMD;
2325                     }
2326                 } ## end if ($alias{$i})
2327
2328 =head3 MAIN-LINE COMMANDS
2329
2330 All of these commands work up to and after the program being debugged has
2331 terminated.
2332
2333 =head4 C<q> - quit
2334
2335 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2336 try to execute further, cleaning any restart-related stuff out of the
2337 environment, and executing with the last value of C<$?>.
2338
2339 =cut
2340
2341                 $cmd =~ /^q$/ && do {
2342                     $fall_off_end = 1;
2343                     clean_ENV();
2344                     exit $?;
2345                 };
2346
2347 =head4 C<t> - trace
2348
2349 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2350
2351 =cut
2352
2353                 $cmd =~ /^t$/ && do {
2354                     $trace ^= 1;
2355                     local $\ = '';
2356                     print $OUT "Trace = "
2357                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2358                     next CMD;
2359                 };
2360
2361 =head4 C<S> - list subroutines matching/not matching a pattern
2362
2363 Walks through C<%sub>, checking to see whether or not to print the name.
2364
2365 =cut
2366
2367                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2368
2369                     $Srev     = defined $2;     # Reverse scan?
2370                     $Spatt    = $3;             # The pattern (if any) to use.
2371                     $Snocheck = !defined $1;    # No args - print all subs.
2372
2373                     # Need to make these sane here.
2374                     local $\ = '';
2375                     local $, = '';
2376
2377                     # Search through the debugger's magical hash of subs.
2378                     # If $nocheck is true, just print the sub name.
2379                     # Otherwise, check it against the pattern. We then use
2380                     # the XOR trick to reverse the condition as required.
2381                     foreach $subname ( sort( keys %sub ) ) {
2382                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2383                             print $OUT $subname, "\n";
2384                         }
2385                     }
2386                     next CMD;
2387                 };
2388
2389 =head4 C<X> - list variables in current package
2390
2391 Since the C<V> command actually processes this, just change this to the
2392 appropriate C<V> command and fall through.
2393
2394 =cut
2395
2396                 $cmd =~ s/^X\b/V $package/;
2397
2398 =head4 C<V> - list variables
2399
2400 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2401
2402 =cut
2403
2404                 # Bare V commands get the currently-being-debugged package
2405                 # added.
2406                 $cmd =~ /^V$/ && do {
2407                     $cmd = "V $package";
2408                 };
2409
2410                 # V - show variables in package.
2411                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2412
2413                     # Save the currently selected filehandle and
2414                     # force output to debugger's filehandle (dumpvar
2415                     # just does "print" for output).
2416                     local ($savout) = select($OUT);
2417
2418                     # Grab package name and variables to dump.
2419                     $packname = $1;
2420                     @vars     = split( ' ', $2 );
2421
2422                     # If main::dumpvar isn't here, get it.
2423                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2424                     if ( defined &main::dumpvar ) {
2425
2426                         # We got it. Turn off subroutine entry/exit messages
2427                         # for the moment, along with return values.
2428                         local $frame = 0;
2429                         local $doret = -2;
2430
2431                         # must detect sigpipe failures  - not catching
2432                         # then will cause the debugger to die.
2433                         eval {
2434                             &main::dumpvar(
2435                                 $packname,
2436                                 defined $option{dumpDepth}
2437                                 ? $option{dumpDepth}
2438                                 : -1,    # assume -1 unless specified
2439                                 @vars
2440                             );
2441                         };
2442
2443                         # The die doesn't need to include the $@, because
2444                         # it will automatically get propagated for us.
2445                         if ($@) {
2446                             die unless $@ =~ /dumpvar print failed/;
2447                         }
2448                     } ## end if (defined &main::dumpvar)
2449                     else {
2450
2451                         # Couldn't load dumpvar.
2452                         print $OUT "dumpvar.pl not available.\n";
2453                     }
2454
2455                     # Restore the output filehandle, and go round again.
2456                     select($savout);
2457                     next CMD;
2458                 };
2459
2460 =head4 C<x> - evaluate and print an expression
2461
2462 Hands the expression off to C<DB::eval>, setting it up to print the value
2463 via C<dumpvar.pl> instead of just printing it directly.
2464
2465 =cut
2466
2467                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2468                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2469
2470                     # handle special  "x 3 blah" syntax XXX propagate
2471                     # doc back to special variables.
2472                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2473                         $onetimedumpDepth = $1;
2474                     }
2475                 };
2476
2477 =head4 C<m> - print methods
2478
2479 Just uses C<DB::methods> to determine what methods are available.
2480
2481 =cut
2482
2483                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2484                     methods($1);
2485                     next CMD;
2486                 };
2487
2488                 # m expr - set up DB::eval to do the work
2489                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2490                     $onetimeDump = 'methods';   #  method output gets used there
2491                 };
2492
2493 =head4 C<f> - switch files
2494
2495 =cut
2496
2497                 $cmd =~ /^f\b\s*(.*)/ && do {
2498                     $file = $1;
2499                     $file =~ s/\s+$//;
2500
2501                     # help for no arguments (old-style was return from sub).
2502                     if ( !$file ) {
2503                         print $OUT
2504                           "The old f command is now the r command.\n";    # hint
2505                         print $OUT "The new f command switches filenames.\n";
2506                         next CMD;
2507                     } ## end if (!$file)
2508
2509                     # if not in magic file list, try a close match.
2510                     if ( !defined $main::{ '_<' . $file } ) {
2511                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2512                             {
2513                                 $try = substr( $try, 2 );
2514                                 print $OUT "Choosing $try matching `$file':\n";
2515                                 $file = $try;
2516                             }
2517                         } ## end if (($try) = grep(m#^_<.*$file#...
2518                     } ## end if (!defined $main::{ ...
2519
2520                     # If not successfully switched now, we failed.
2521                     if ( !defined $main::{ '_<' . $file } ) {
2522                         print $OUT "No file matching `$file' is loaded.\n";
2523                         next CMD;
2524                     }
2525
2526                     # We switched, so switch the debugger internals around.
2527                     elsif ( $file ne $filename ) {
2528                         *dbline   = $main::{ '_<' . $file };
2529                         $max      = $#dbline;
2530                         $filename = $file;
2531                         $start    = 1;
2532                         $cmd      = "l";
2533                     } ## end elsif ($file ne $filename)
2534
2535                     # We didn't switch; say we didn't.
2536                     else {
2537                         print $OUT "Already in $file.\n";
2538                         next CMD;
2539                     }
2540                 };
2541
2542 =head4 C<.> - return to last-executed line.
2543
2544 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2545 and then we look up the line in the magical C<%dbline> hash.
2546
2547 =cut
2548
2549                 # . command.
2550                 $cmd =~ /^\.$/ && do {
2551                     $incr = -1;    # stay at current line
2552
2553                     # Reset everything to the old location.
2554                     $start    = $line;
2555                     $filename = $filename_ini;
2556                     *dbline   = $main::{ '_<' . $filename };
2557                     $max      = $#dbline;
2558
2559                     # Now where are we?
2560                     print_lineinfo($position);
2561                     next CMD;
2562                 };
2563
2564 =head4 C<-> - back one window
2565
2566 We change C<$start> to be one window back; if we go back past the first line,
2567 we set it to be the first line. We ser C<$incr> to put us back at the
2568 currently-executing line, and then put a C<l $start +> (list one window from
2569 C<$start>) in C<$cmd> to be executed later.
2570
2571 =cut
2572
2573                 # - - back a window.
2574                 $cmd =~ /^-$/ && do {
2575
2576                     # back up by a window; go to 1 if back too far.
2577                     $start -= $incr + $window + 1;
2578                     $start = 1 if $start <= 0;
2579                     $incr  = $window - 1;
2580
2581                     # Generate and execute a "l +" command (handled below).
2582                     $cmd = 'l ' . ($start) . '+';
2583                 };
2584
2585 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2586
2587 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2588 problems, most notably that the default case of several commands destroying
2589 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2590 retain the old commands for those who were used to using them or who preferred
2591 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2592 deal with them instead of processing them in-line.
2593
2594 =cut
2595
2596                 # All of these commands were remapped in perl 5.8.0;
2597                 # we send them off to the secondary dispatcher (see below).
2598                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2599                     &cmd_wrapper( $1, $2, $line );
2600                     next CMD;
2601                 };
2602
2603 =head4 C<y> - List lexicals in higher scope
2604
2605 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2606 above the current one and then displays then using C<dumpvar.pl>.
2607
2608 =cut
2609
2610                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2611
2612                     # See if we've got the necessary support.
2613                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2614                       or &warn(
2615                         $@ =~ /locate/
2616                         ? "PadWalker module not found - please install\n"
2617                         : $@
2618                       )
2619                       and next CMD;
2620
2621                     # Load up dumpvar if we don't have it. If we can, that is.
2622                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2623                     defined &main::dumpvar
2624                       or print $OUT "dumpvar.pl not available.\n"
2625                       and next CMD;
2626
2627                     # Got all the modules we need. Find them and print them.
2628                     my @vars = split( ' ', $2 || '' );
2629
2630                     # Find the pad.
2631                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2632
2633                     # Oops. Can't find it.
2634                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2635
2636                     # Show the desired vars with dumplex().
2637                     my $savout = select($OUT);
2638
2639                     # Have dumplex dump the lexicals.
2640                     dumpvar::dumplex( $_, $h->{$_},
2641                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2642                         @vars )
2643                       for sort keys %$h;
2644                     select($savout);
2645                     next CMD;
2646                 };
2647
2648 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2649
2650 All of the commands below this point don't work after the program being
2651 debugged has ended. All of them check to see if the program has ended; this
2652 allows the commands to be relocated without worrying about a 'line of
2653 demarcation' above which commands can be entered anytime, and below which
2654 they can't.
2655
2656 =head4 C<n> - single step, but don't trace down into subs
2657
2658 Done by setting C<$single> to 2, which forces subs to execute straight through
2659 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2660 so a null command knows what to re-execute.
2661
2662 =cut
2663
2664                 # n - next
2665                 $cmd =~ /^n$/ && do {
2666                     end_report(), next CMD if $finished and $level <= 1;
2667
2668                     # Single step, but don't enter subs.
2669                     $single = 2;
2670
2671                     # Save for empty command (repeat last).
2672                     $laststep = $cmd;
2673                     last CMD;
2674                 };
2675
2676 =head4 C<s> - single-step, entering subs
2677
2678 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2679 subs. Also saves C<s> as C<$lastcmd>.
2680
2681 =cut
2682
2683                 # s - single step.
2684                 $cmd =~ /^s$/ && do {
2685
2686                     # Get out and restart the command loop if program
2687                     # has finished.
2688                     end_report(), next CMD if $finished and $level <= 1;
2689
2690                     # Single step should enter subs.
2691                     $single = 1;
2692
2693                     # Save for empty command (repeat last).
2694                     $laststep = $cmd;
2695                     last CMD;
2696                 };
2697
2698 =head4 C<c> - run continuously, setting an optional breakpoint
2699
2700 Most of the code for this command is taken up with locating the optional
2701 breakpoint, which is either a subroutine name or a line number. We set
2702 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2703 in this and all call levels above this one.
2704
2705 =cut
2706
2707                 # c - start continuous execution.
2708                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2709
2710                     # Hey, show's over. The debugged program finished
2711                     # executing already.
2712                     end_report(), next CMD if $finished and $level <= 1;
2713
2714                     # Capture the place to put a one-time break.
2715                     $subname = $i = $1;
2716
2717                     #  Probably not needed, since we finish an interactive
2718                     #  sub-session anyway...
2719                     # local $filename = $filename;
2720                     # local *dbline = *dbline; # XXX Would this work?!
2721                     #
2722                     # The above question wonders if localizing the alias
2723                     # to the magic array works or not. Since it's commented
2724                     # out, we'll just leave that to speculation for now.
2725
2726                     # If the "subname" isn't all digits, we'll assume it
2727                     # is a subroutine name, and try to find it.
2728                     if ( $subname =~ /\D/ ) {    # subroutine name
2729                             # Qualify it to the current package unless it's
2730                             # already qualified.
2731                         $subname = $package . "::" . $subname
2732                           unless $subname =~ /::/;
2733
2734                         # find_sub will return "file:line_number" corresponding
2735                         # to where the subroutine is defined; we call find_sub,
2736                         # break up the return value, and assign it in one
2737                         # operation.
2738                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2739
2740                         # Force the line number to be numeric.
2741                         $i += 0;
2742
2743                         # If we got a line number, we found the sub.
2744                         if ($i) {
2745
2746                             # Switch all the debugger's internals around so
2747                             # we're actually working with that file.
2748                             $filename = $file;
2749                             *dbline   = $main::{ '_<' . $filename };
2750
2751                             # Mark that there's a breakpoint in this file.
2752                             $had_breakpoints{$filename} |= 1;
2753
2754                             # Scan forward to the first executable line
2755                             # after the 'sub whatever' line.
2756                             $max = $#dbline;
2757                             ++$i while $dbline[$i] == 0 && $i < $max;
2758                         } ## end if ($i)
2759
2760                         # We didn't find a sub by that name.
2761                         else {
2762                             print $OUT "Subroutine $subname not found.\n";
2763                             next CMD;
2764                         }
2765                     } ## end if ($subname =~ /\D/)
2766
2767                     # At this point, either the subname was all digits (an
2768                     # absolute line-break request) or we've scanned through
2769                     # the code following the definition of the sub, looking
2770                     # for an executable, which we may or may not have found.
2771                     #
2772                     # If $i (which we set $subname from) is non-zero, we
2773                     # got a request to break at some line somewhere. On
2774                     # one hand, if there wasn't any real subroutine name
2775                     # involved, this will be a request to break in the current
2776                     # file at the specified line, so we have to check to make
2777                     # sure that the line specified really is breakable.
2778                     #
2779                     # On the other hand, if there was a subname supplied, the
2780                     # preceding block has moved us to the proper file and
2781                     # location within that file, and then scanned forward
2782                     # looking for the next executable line. We have to make
2783                     # sure that one was found.
2784                     #
2785                     # On the gripping hand, we can't do anything unless the
2786                     # current value of $i points to a valid breakable line.
2787                     # Check that.
2788                     if ($i) {
2789
2790                         # Breakable?
2791                         if ( $dbline[$i] == 0 ) {
2792                             print $OUT "Line $i not breakable.\n";
2793                             next CMD;
2794                         }
2795
2796                         # Yes. Set up the one-time-break sigil.
2797                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2798                     } ## end if ($i)
2799
2800                     # Turn off stack tracing from here up.
2801                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2802                         $stack[ $i++ ] &= ~1;
2803                     }
2804                     last CMD;
2805                 };
2806
2807 =head4 C<r> - return from a subroutine
2808
2809 For C<r> to work properly, the debugger has to stop execution again
2810 immediately after the return is executed. This is done by forcing
2811 single-stepping to be on in the call level above the current one. If
2812 we are printing return values when a C<r> is executed, set C<$doret>
2813 appropriately, and force us out of the command loop.
2814
2815 =cut
2816
2817                 # r - return from the current subroutine.
2818                 $cmd =~ /^r$/ && do {
2819
2820                     # Can't do anythign if the program's over.
2821                     end_report(), next CMD if $finished and $level <= 1;
2822
2823                     # Turn on stack trace.
2824                     $stack[$stack_depth] |= 1;
2825
2826                     # Print return value unless the stack is empty.
2827                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2828                     last CMD;
2829                 };
2830
2831 =head4 C<T> - stack trace
2832
2833 Just calls C<DB::print_trace>.
2834
2835 =cut
2836
2837                 $cmd =~ /^T$/ && do {
2838                     print_trace( $OUT, 1 );    # skip DB
2839                     next CMD;
2840                 };
2841
2842 =head4 C<w> - List window around current line.
2843
2844 Just calls C<DB::cmd_w>.
2845
2846 =cut
2847
2848                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2849
2850 =head4 C<W> - watch-expression processing.
2851
2852 Just calls C<DB::cmd_W>.
2853
2854 =cut
2855
2856                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2857
2858 =head4 C</> - search forward for a string in the source
2859
2860 We take the argument and treat it as a pattern. If it turns out to be a
2861 bad one, we return the error we got from trying to C<eval> it and exit.
2862 If not, we create some code to do the search and C<eval> it so it can't
2863 mess us up.
2864
2865 =cut
2866
2867                 $cmd =~ /^\/(.*)$/ && do {
2868
2869                     # The pattern as a string.
2870                     $inpat = $1;
2871
2872                     # Remove the final slash.
2873                     $inpat =~ s:([^\\])/$:$1:;
2874
2875                     # If the pattern isn't null ...
2876                     if ( $inpat ne "" ) {
2877
2878                         # Turn of warn and die procesing for a bit.
2879                         local $SIG{__DIE__};
2880                         local $SIG{__WARN__};
2881
2882                         # Create the pattern.
2883                         eval '$inpat =~ m' . "\a$inpat\a";
2884                         if ( $@ ne "" ) {
2885
2886                             # Oops. Bad pattern. No biscuit.
2887                             # Print the eval error and go back for more
2888                             # commands.
2889                             print $OUT "$@";
2890                             next CMD;
2891                         }
2892                         $pat = $inpat;
2893                     } ## end if ($inpat ne "")
2894
2895                     # Set up to stop on wrap-around.
2896                     $end = $start;
2897
2898                     # Don't move off the current line.
2899                     $incr = -1;
2900
2901                     # Done in eval so nothing breaks if the pattern
2902                     # does something weird.
2903                     eval '
2904                         for (;;) {
2905                             # Move ahead one line.
2906                             ++$start;
2907
2908                             # Wrap if we pass the last line.
2909                             $start = 1 if ($start > $max);
2910
2911                             # Stop if we have gotten back to this line again,
2912                             last if ($start == $end);
2913
2914                             # A hit! (Note, though, that we are doing
2915                             # case-insensitive matching. Maybe a qr//
2916                             # expression would be better, so the user could
2917                             # do case-sensitive matching if desired.
2918                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2919                                 if ($slave_editor) {
2920                                     # Handle proper escaping in the slave.
2921                                     print $OUT "\032\032$filename:$start:0\n";
2922                                 }
2923                                 else {
2924                                     # Just print the line normally.
2925                                     print $OUT "$start:\t",$dbline[$start],"\n";
2926                                 }
2927                                 # And quit since we found something.
2928                                 last;
2929                             }
2930                          } ';
2931
2932                     # If we wrapped, there never was a match.
2933                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2934                     next CMD;
2935                 };
2936
2937 =head4 C<?> - search backward for a string in the source
2938
2939 Same as for C</>, except the loop runs backwards.
2940
2941 =cut
2942
2943                 # ? - backward pattern search.
2944                 $cmd =~ /^\?(.*)$/ && do {
2945
2946                     # Get the pattern, remove trailing question mark.
2947                     $inpat = $1;
2948                     $inpat =~ s:([^\\])\?$:$1:;
2949
2950                     # If we've got one ...
2951                     if ( $inpat ne "" ) {
2952
2953                         # Turn off die & warn handlers.
2954                         local $SIG{__DIE__};
2955                         local $SIG{__WARN__};
2956                         eval '$inpat =~ m' . "\a$inpat\a";
2957
2958                         if ( $@ ne "" ) {
2959
2960                             # Ouch. Not good. Print the error.
2961                             print $OUT $@;
2962                             next CMD;
2963                         }
2964                         $pat = $inpat;
2965                     } ## end if ($inpat ne "")
2966
2967                     # Where we are now is where to stop after wraparound.
2968                     $end = $start;
2969
2970                     # Don't move away from this line.
2971                     $incr = -1;
2972
2973                     # Search inside the eval to prevent pattern badness
2974                     # from killing us.
2975                     eval '
2976                         for (;;) {
2977                             # Back up a line.
2978                             --$start;
2979
2980                             # Wrap if we pass the first line.
2981
2982                             $start = $max if ($start <= 0);
2983
2984                             # Quit if we get back where we started,
2985                             last if ($start == $end);
2986
2987                             # Match?
2988                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2989                                 if ($slave_editor) {
2990                                     # Yep, follow slave editor requirements.
2991                                     print $OUT "\032\032$filename:$start:0\n";
2992                                 }
2993                                 else {
2994                                     # Yep, just print normally.
2995                                     print $OUT "$start:\t",$dbline[$start],"\n";
2996                                 }
2997
2998                                 # Found, so done.
2999                                 last;
3000                             }
3001                         } ';
3002
3003                     # Say we failed if the loop never found anything,
3004                     print $OUT "?$pat?: not found\n" if ( $start == $end );
3005                     next CMD;
3006                 };
3007
3008 =head4 C<$rc> - Recall command
3009
3010 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3011 that the terminal supports history). It find the the command required, puts it
3012 into C<$cmd>, and redoes the loop to execute it.
3013
3014 =cut
3015
3016                 # $rc - recall command.
3017                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3018
3019                     # No arguments, take one thing off history.
3020                     pop(@hist) if length($cmd) > 1;
3021
3022                     # Relative (- found)?
3023                     #  Y - index back from most recent (by 1 if bare minus)
3024                     #  N - go to that particular command slot or the last
3025                     #      thing if nothing following.
3026                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3027
3028                     # Pick out the command desired.
3029                     $cmd = $hist[$i];
3030
3031                     # Print the command to be executed and restart the loop
3032                     # with that command in the buffer.
3033                     print $OUT $cmd, "\n";
3034                     redo CMD;
3035                 };
3036
3037 =head4 C<$sh$sh> - C<system()> command
3038
3039 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3040 C<STDOUT> from getting messed up.
3041
3042 =cut
3043
3044                 # $sh$sh - run a shell command (if it's all ASCII).
3045                 # Can't run shell commands with Unicode in the debugger, hmm.
3046                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3047
3048                     # System it.
3049                     &system($1);
3050                     next CMD;
3051                 };
3052
3053 =head4 C<$rc I<pattern> $rc> - Search command history
3054
3055 Another command to manipulate C<@hist>: this one searches it with a pattern.
3056 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3057
3058 =cut
3059
3060                 # $rc pattern $rc - find a command in the history.
3061                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3062
3063                     # Create the pattern to use.
3064                     $pat = "^$1";
3065
3066                     # Toss off last entry if length is >1 (and it always is).
3067                     pop(@hist) if length($cmd) > 1;
3068
3069                     # Look backward through the history.
3070                     for ( $i = $#hist ; $i ; --$i ) {
3071
3072                         # Stop if we find it.
3073                         last if $hist[$i] =~ /$pat/;
3074                     }
3075
3076                     if ( !$i ) {
3077
3078                         # Never found it.
3079                         print $OUT "No such command!\n\n";
3080                         next CMD;
3081                     }
3082
3083                     # Found it. Put it in the buffer, print it, and process it.
3084                     $cmd = $hist[$i];
3085                     print $OUT $cmd, "\n";
3086                     redo CMD;
3087                 };
3088
3089 =head4 C<$sh> - Invoke a shell
3090
3091 Uses C<DB::system> to invoke a shell.
3092
3093 =cut
3094
3095                 # $sh - start a shell.
3096                 $cmd =~ /^$sh$/ && do {
3097
3098                     # Run the user's shell. If none defined, run Bourne.
3099                     # We resume execution when the shell terminates.
3100                     &system( $ENV{SHELL} || "/bin/sh" );
3101                     next CMD;
3102                 };
3103
3104 =head4 C<$sh I<command>> - Force execution of a command in a shell
3105
3106 Like the above, but the command is passed to the shell. Again, we use
3107 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3108
3109 =cut
3110
3111                 # $sh command - start a shell and run a command in it.
3112                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3113
3114                     # XXX: using csh or tcsh destroys sigint retvals!
3115                     #&system($1);  # use this instead
3116
3117                     # use the user's shell, or Bourne if none defined.
3118                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3119                     next CMD;
3120                 };
3121
3122 =head4 C<H> - display commands in history
3123
3124 Prints the contents of C<@hist> (if any).
3125
3126 =cut
3127
3128                 $cmd =~ /^H\b\s*\*/ && do {
3129                     @hist = @truehist = ();
3130                     print $OUT "History cleansed\n";
3131                     next CMD;
3132                 };
3133
3134                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3135
3136                     # Anything other than negative numbers is ignored by
3137                     # the (incorrect) pattern, so this test does nothing.
3138                     $end = $2 ? ( $#hist - $2 ) : 0;
3139
3140                     # Set to the minimum if less than zero.
3141                     $hist = 0 if $hist < 0;
3142
3143                     # Start at the end of the array.
3144                     # Stay in while we're still above the ending value.
3145                     # Tick back by one each time around the loop.
3146                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3147
3148                         # Print the command  unless it has no arguments.
3149                         print $OUT "$i: ", $hist[$i], "\n"
3150                           unless $hist[$i] =~ /^.?$/;
3151                     }
3152                     next CMD;
3153                 };
3154
3155 =head4 C<man, doc, perldoc> - look up documentation
3156
3157 Just calls C<runman()> to print the appropriate document.
3158
3159 =cut
3160
3161                 # man, perldoc, doc - show manual pages.
3162                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3163                     runman($1);
3164                     next CMD;
3165                 };
3166
3167 =head4 C<p> - print
3168
3169 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3170 the bottom of the loop.
3171
3172 =cut
3173
3174                 # p - print (no args): print $_.
3175                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3176
3177                 # p - print the given expression.
3178                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3179
3180 =head4 C<=> - define command alias
3181
3182 Manipulates C<%alias> to add or list command aliases.
3183
3184 =cut
3185
3186                 # = - set up a command alias.
3187                 $cmd =~ s/^=\s*// && do {
3188                     my @keys;
3189                     if ( length $cmd == 0 ) {
3190
3191                         # No args, get current aliases.
3192                         @keys = sort keys %alias;
3193                     }
3194                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3195
3196                         # Creating a new alias. $k is alias name, $v is
3197                         # alias value.
3198
3199                         # can't use $_ or kill //g state
3200                         for my $x ( $k, $v ) {
3201
3202                             # Escape "alarm" characters.
3203                             $x =~ s/\a/\\a/g;
3204                         }
3205
3206                         # Substitute key for value, using alarm chars
3207                         # as separators (which is why we escaped them in
3208                         # the command).
3209                         $alias{$k} = "s\a$k\a$v\a";
3210
3211                         # Turn off standard warn and die behavior.
3212                         local $SIG{__DIE__};
3213                         local $SIG{__WARN__};
3214
3215                         # Is it valid Perl?
3216                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3217
3218                             # Nope. Bad alias. Say so and get out.
3219                             print $OUT "Can't alias $k to $v: $@\n";
3220                             delete $alias{$k};
3221                             next CMD;
3222                         }
3223
3224                         # We'll only list the new one.
3225                         @keys = ($k);
3226                     } ## end elsif (my ($k, $v) = ($cmd...
3227
3228                     # The argument is the alias to list.
3229                     else {
3230                         @keys = ($cmd);
3231                     }
3232
3233                     # List aliases.
3234                     for my $k (@keys) {
3235
3236                         # Messy metaquoting: Trim the substiution code off.
3237                         # We use control-G as the delimiter because it's not
3238                         # likely to appear in the alias.
3239                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3240
3241                             # Print the alias.
3242                             print $OUT "$k\t= $1\n";
3243                         }
3244                         elsif ( defined $alias{$k} ) {
3245
3246                             # Couldn't trim it off; just print the alias code.
3247                             print $OUT "$k\t$alias{$k}\n";
3248                         }
3249                         else {
3250
3251                             # No such, dude.
3252                             print "No alias for $k\n";
3253                         }
3254                     } ## end for my $k (@keys)
3255                     next CMD;
3256                 };
3257
3258 =head4 C<source> - read commands from a file.
3259
3260 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3261 pick it up.
3262
3263 =cut
3264
3265                 # source - read commands from a file (or pipe!) and execute.
3266                 $cmd =~ /^source\s+(.*\S)/ && do {
3267                     if ( open my $fh, $1 ) {
3268
3269                         # Opened OK; stick it in the list of file handles.
3270                         push @cmdfhs, $fh;
3271                     }
3272                     else {
3273
3274                         # Couldn't open it.
3275                         &warn("Can't execute `$1': $!\n");
3276                     }
3277                     next CMD;
3278                 };
3279
3280 =head4 C<save> - send current history to a file
3281
3282 Takes the complete history, (not the shrunken version you see with C<H>),
3283 and saves it to the given filename, so it can be replayed using C<source>.
3284
3285 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3286
3287 =cut
3288
3289                 # save source - write commands to a file for later use
3290                 $cmd =~ /^save\s*(.*)$/ && do {
3291                     my $file = $1 || '.perl5dbrc';    # default?
3292                     if ( open my $fh, "> $file" ) {
3293
3294                        # chomp to remove extraneous newlines from source'd files
3295                         chomp( my @truelist =
3296                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3297                               @truehist );
3298                         print $fh join( "\n", @truelist );
3299                         print "commands saved in $file\n";
3300                     }
3301                     else {
3302                         &warn("Can't save debugger commands in '$1': $!\n");
3303                     }
3304                     next CMD;
3305                 };
3306
3307 =head4 C<R> - restart
3308
3309 Restart the debugger session.
3310
3311 =head4 C<rerun> - rerun the current session
3312
3313 Return to any given position in the B<true>-history list
3314
3315 =cut
3316
3317                 # R - restart execution.
3318                 # rerun - controlled restart execution.
3319                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3320                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3321
3322                     # Close all non-system fds for a clean restart.  A more
3323                     # correct method would be to close all fds that were not
3324                     # open when the process started, but this seems to be
3325                     # hard.  See "debugger 'R'estart and open database
3326                     # connections" on p5p.
3327
3328                     my $max_fd = 1024; # default if POSIX can't be loaded
3329                     if (eval { require POSIX }) {
3330                         $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX());
3331                     }
3332
3333                     if (defined $max_fd) {
3334                         foreach ($^F+1 .. $max_fd-1) {
3335                             next unless open FD_TO_CLOSE, "<&=$_";
3336                             close(FD_TO_CLOSE);
3337                         }
3338                     }
3339
3340                     # And run Perl again.  We use exec() to keep the
3341                     # PID stable (and that way $ini_pids is still valid).
3342                     exec(@args) || print $OUT "exec failed: $!\n";
3343
3344                     last CMD;
3345                 };
3346
3347 =head4 C<|, ||> - pipe output through the pager.
3348
3349 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3350 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3351 pipe to the pager (restoring the output filehandles if this fails). If this
3352 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3353 set C<$signal>, sending us back into the debugger.
3354
3355 We then trim off the pipe symbols and C<redo> the command loop at the
3356 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3357 reading another.
3358
3359 =cut
3360
3361                 # || - run command in the pager, with output to DB::OUT.
3362                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3363                     if ( $pager =~ /^\|/ ) {
3364
3365                         # Default pager is into a pipe. Redirect I/O.
3366                         open( SAVEOUT, ">&STDOUT" )
3367                           || &warn("Can't save STDOUT");
3368                         open( STDOUT, ">&OUT" )
3369                           || &warn("Can't redirect STDOUT");
3370                     } ## end if ($pager =~ /^\|/)
3371                     else {
3372
3373                         # Not into a pipe. STDOUT is safe.
3374                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3375                     }
3376
3377                     # Fix up environment to record we have less if so.
3378                     fix_less();
3379
3380                     unless ( $piped = open( OUT, $pager ) ) {
3381
3382                         # Couldn't open pipe to pager.
3383                         &warn("Can't pipe output to `$pager'");
3384                         if ( $pager =~ /^\|/ ) {
3385
3386                             # Redirect I/O back again.
3387                             open( OUT, ">&STDOUT" )    # XXX: lost message
3388                               || &warn("Can't restore DB::OUT");
3389                             open( STDOUT, ">&SAVEOUT" )
3390                               || &warn("Can't restore STDOUT");
3391                             close(SAVEOUT);
3392                         } ## end if ($pager =~ /^\|/)
3393                         else {
3394
3395                             # Redirect I/O. STDOUT already safe.
3396                             open( OUT, ">&STDOUT" )    # XXX: lost message
3397                               || &warn("Can't restore DB::OUT");
3398                         }
3399                         next CMD;
3400                     } ## end unless ($piped = open(OUT,...
3401
3402                     # Set up broken-pipe handler if necessary.
3403                     $SIG{PIPE} = \&DB::catch
3404                       if $pager =~ /^\|/
3405                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3406
3407                     # Save current filehandle, unbuffer out, and put it back.
3408                     $selected = select(OUT);
3409                     $|        = 1;
3410
3411                     # Don't put it back if pager was a pipe.
3412                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3413
3414                     # Trim off the pipe symbols and run the command now.
3415                     $cmd =~ s/^\|+\s*//;
3416                     redo PIPE;
3417                 };
3418
3419 =head3 END OF COMMAND PARSING
3420
3421 Anything left in C<$cmd> at this point is a Perl expression that we want to
3422 evaluate. We'll always evaluate in the user's context, and fully qualify
3423 any variables we might want to address in the C<DB> package.
3424
3425 =cut
3426
3427                 # t - turn trace on.
3428                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3429
3430                 # s - single-step. Remember the last command was 's'.
3431                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3432
3433                 # n - single-step, but not into subs. Remember last command
3434                 # was 'n'.
3435                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3436
3437             }    # PIPE:
3438
3439             # Make sure the flag that says "the debugger's running" is
3440             # still on, to make sure we get control again.
3441             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3442
3443             # Run *our* eval that executes in the caller's context.
3444             &eval;
3445
3446             # Turn off the one-time-dump stuff now.
3447             if ($onetimeDump) {
3448                 $onetimeDump      = undef;
3449                 $onetimedumpDepth = undef;
3450             }
3451             elsif ( $term_pid == $$ ) {
3452                 eval {          # May run under miniperl, when not available...
3453                     STDOUT->flush();
3454                     STDERR->flush();
3455                 };
3456
3457                 # XXX If this is the master pid, print a newline.
3458                 print $OUT "\n";
3459             }
3460         } ## end while (($term || &setterm...
3461
3462 =head3 POST-COMMAND PROCESSING
3463
3464 After each command, we check to see if the command output was piped anywhere.
3465 If so, we go through the necessary code to unhook the pipe and go back to
3466 our standard filehandles for input and output.
3467
3468 =cut
3469
3470         continue {    # CMD:
3471
3472             # At the end of every command:
3473             if ($piped) {
3474
3475                 # Unhook the pipe mechanism now.
3476                 if ( $pager =~ /^\|/ ) {
3477
3478                     # No error from the child.
3479                     $? = 0;
3480
3481                     # we cannot warn here: the handle is missing --tchrist
3482                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3483
3484                     # most of the $? crud was coping with broken cshisms
3485                     # $? is explicitly set to 0, so this never runs.
3486                     if ($?) {
3487                         print SAVEOUT "Pager `$pager' failed: ";
3488                         if ( $? == -1 ) {
3489                             print SAVEOUT "shell returned -1\n";
3490                         }
3491                         elsif ( $? >> 8 ) {
3492                             print SAVEOUT ( $? & 127 )
3493                               ? " (SIG#" . ( $? & 127 ) . ")"
3494                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3495                         }
3496                         else {
3497                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3498                         }
3499                     } ## end if ($?)
3500
3501                     # Reopen filehandle for our output (if we can) and
3502                     # restore STDOUT (if we can).
3503                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3504                     open( STDOUT, ">&SAVEOUT" )
3505                       || &warn("Can't restore STDOUT");
3506
3507                     # Turn off pipe exception handler if necessary.
3508                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3509
3510                     # Will stop ignoring SIGPIPE if done like nohup(1)
3511                     # does SIGINT but Perl doesn't give us a choice.
3512                 } ## end if ($pager =~ /^\|/)
3513                 else {
3514
3515                     # Non-piped "pager". Just restore STDOUT.
3516                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3517                 }
3518
3519                 # Close filehandle pager was using, restore the normal one
3520                 # if necessary,
3521                 close(SAVEOUT);
3522                 select($selected), $selected = "" unless $selected eq "";
3523
3524                 # No pipes now.
3525                 $piped = "";
3526             } ## end if ($piped)
3527         }    # CMD:
3528
3529 =head3 COMMAND LOOP TERMINATION
3530
3531 When commands have finished executing, we come here. If the user closed the
3532 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3533 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3534 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3535 The interpreter will then execute the next line and then return control to us
3536 again.
3537
3538 =cut
3539
3540         # No more commands? Quit.
3541         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3542
3543         # Evaluate post-prompt commands.
3544         foreach $evalarg (@$post) {
3545             &eval;
3546         }
3547     }    # if ($single || $signal)
3548
3549     # Put the user's globals back where you found them.
3550     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3551     ();
3552 } ## end sub DB
3553
3554 # The following code may be executed now:
3555 # BEGIN {warn 4}
3556
3557 =head2 sub
3558
3559 C<sub> is called whenever a subroutine call happens in the program being
3560 debugged. The variable C<$DB::sub> contains the name of the subroutine
3561 being called.
3562
3563 The core function of this subroutine is to actually call the sub in the proper
3564 context, capturing its output. This of course causes C<DB::DB> to get called
3565 again, repeating until the subroutine ends and returns control to C<DB::sub>
3566 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3567 return value, and returns its captured copy of the return value as its own
3568 return value. The value then feeds back into the program being debugged as if
3569 C<DB::sub> hadn't been there at all.
3570
3571 C<sub> does all the work of printing the subroutine entry and exit messages
3572 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3573 and also prints the return value if needed (for the C<r> command and if
3574 the 16 bit is set in C<$frame>).
3575
3576 It also tracks the subroutine call depth by saving the current setting of
3577 C<$single> in the C<@stack> package global; if this exceeds the value in
3578 C<$deep>, C<sub> automatically turns on printing of the current depth by
3579 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3580 of stop/don't stop on entry to subs set as it currently is set.
3581
3582 =head3 C<caller()> support
3583
3584 If C<caller()> is called from the package C<DB>, it provides some
3585 additional data, in the following order:
3586
3587 =over 4
3588
3589 =item * C<$package>
3590
3591 The package name the sub was in
3592
3593 =item * C<$filename>
3594
3595 The filename it was defined in
3596
3597 =item * C<$line>
3598
3599 The line number it was defined on
3600
3601 =item * C<$subroutine>
3602
3603 The subroutine name; C<(eval)> if an C<eval>().
3604
3605 =item * C<$hasargs>
3606
3607 1 if it has arguments, 0 if not
3608
3609 =item * C<$wantarray>
3610
3611 1 if array context, 0 if scalar context
3612
3613 =item * C<$evaltext>
3614
3615 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3616
3617 =item * C<$is_require>
3618
3619 frame was created by a C<use> or C<require> statement
3620
3621 =item * C<$hints>
3622
3623 pragma information; subject to change between versions
3624
3625 =item * C<$bitmask>
3626
3627 pragma information; subject to change between versions
3628
3629 =item * C<@DB::args>
3630
3631 arguments with which the subroutine was invoked
3632
3633 =back
3634
3635 =cut
3636
3637 sub sub {
3638
3639         # lock ourselves under threads
3640         lock($DBGR);
3641
3642     # Whether or not the autoloader was running, a scalar to put the
3643     # sub's return value in (if needed), and an array to put the sub's
3644     # return value in (if needed).
3645     my ( $al, $ret, @ret ) = "";
3646         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3647                 print "creating new thread\n";
3648         }
3649
3650     # If the last ten characters are '::AUTOLOAD', note we've traced
3651     # into AUTOLOAD for $sub.
3652     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3653         $al = " for $$sub" if defined $$sub;
3654     }
3655
3656     # We stack the stack pointer and then increment it to protect us
3657     # from a situation that might unwind a whole bunch of call frames
3658     # at once. Localizing the stack pointer means that it will automatically
3659     # unwind the same amount when multiple stack frames are unwound.
3660     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3661
3662     # Expand @stack.
3663     $#stack = $stack_depth;
3664
3665     # Save current single-step setting.
3666     $stack[-1] = $single;
3667
3668     # Turn off all flags except single-stepping.
3669     $single &= 1;
3670
3671     # If we've gotten really deeply recursed, turn on the flag that will
3672     # make us stop with the 'deep recursion' message.
3673     $single |= 4 if $stack_depth == $deep;
3674
3675     # If frame messages are on ...
3676     (
3677         $frame & 4    # Extended frame entry message
3678         ? (
3679             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3680
3681             # Why -1? But it works! :-(
3682             # Because print_trace will call add 1 to it and then call
3683             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3684             # in dump_trace.
3685             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3686           )
3687         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3688
3689           # standard frame entry message
3690       )
3691       if $frame;
3692
3693     # Determine the sub's return type,and capture approppriately.
3694     if (wantarray) {
3695
3696         # Called in array context. call sub and capture output.
3697         # DB::DB will recursively get control again if appropriate; we'll come
3698         # back here when the sub is finished.
3699         @ret = &$sub;
3700
3701         # Pop the single-step value back off the stack.
3702         $single |= $stack[ $stack_depth-- ];
3703
3704         # Check for exit trace messages...
3705         (
3706             $frame & 4    # Extended exit message
3707             ? (
3708                 print_lineinfo( ' ' x $stack_depth, "out " ),
3709                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3710               )
3711             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3712
3713               # Standard exit message
3714           )
3715           if $frame & 2;
3716
3717         # Print the return info if we need to.
3718         if ( $doret eq $stack_depth or $frame & 16 ) {
3719
3720             # Turn off output record separator.
3721             local $\ = '';
3722             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3723
3724             # Indent if we're printing because of $frame tracing.
3725             print $fh ' ' x $stack_depth if $frame & 16;
3726
3727             # Print the return value.
3728             print $fh "list context return from $sub:\n";
3729             dumpit( $fh, \@ret );
3730
3731             # And don't print it again.
3732             $doret = -2;
3733         } ## end if ($doret eq $stack_depth...
3734             # And we have to return the return value now.
3735         @ret;
3736     } ## end if (wantarray)
3737
3738     # Scalar context.
3739     else {
3740         if ( defined wantarray ) {
3741
3742             # Save the value if it's wanted at all.
3743             $ret = &$sub;
3744         }
3745         else {
3746
3747             # Void return, explicitly.
3748             &$sub;
3749             undef $ret;
3750         }
3751
3752         # Pop the single-step value off the stack.
3753         $single |= $stack[ $stack_depth-- ];
3754
3755         # If we're doing exit messages...
3756         (
3757             $frame & 4    # Extended messsages
3758             ? (
3759                 print_lineinfo( ' ' x $stack_depth, "out " ),
3760                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3761               )
3762             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3763
3764               # Standard messages
3765           )
3766           if $frame & 2;
3767
3768         # If we are supposed to show the return value... same as before.
3769         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3770             local $\ = '';
3771             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3772             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3773             print $fh (
3774                 defined wantarray
3775                 ? "scalar context return from $sub: "
3776                 : "void context return from $sub\n"
3777             );
3778             dumpit( $fh, $ret ) if defined wantarray;
3779             $doret = -2;
3780         } ## end if ($doret eq $stack_depth...
3781
3782         # Return the appropriate scalar value.
3783         $ret;
3784     } ## end else [ if (wantarray)
3785 } ## end sub sub
3786
3787 sub lsub : lvalue {
3788
3789         # lock ourselves under threads
3790         lock($DBGR);
3791
3792     # Whether or not the autoloader was running, a scalar to put the
3793     # sub's return value in (if needed), and an array to put the sub's
3794     # return value in (if needed).
3795     my ( $al, $ret, @ret ) = "";
3796         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3797                 print "creating new thread\n";
3798         }
3799
3800     # If the last ten characters are C'::AUTOLOAD', note we've traced
3801     # into AUTOLOAD for $sub.
3802     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3803         $al = " for $$sub";
3804     }
3805
3806     # We stack the stack pointer and then increment it to protect us
3807     # from a situation that might unwind a whole bunch of call frames
3808     # at once. Localizing the stack pointer means that it will automatically
3809     # unwind the same amount when multiple stack frames are unwound.
3810     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3811
3812     # Expand @stack.
3813     $#stack = $stack_depth;
3814
3815     # Save current single-step setting.
3816     $stack[-1] = $single;
3817
3818     # Turn off all flags except single-stepping.
3819     $single &= 1;
3820
3821     # If we've gotten really deeply recursed, turn on the flag that will
3822     # make us stop with the 'deep recursion' message.
3823     $single |= 4 if $stack_depth == $deep;
3824
3825     # If frame messages are on ...
3826     (
3827         $frame & 4    # Extended frame entry message
3828         ? (
3829             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3830
3831             # Why -1? But it works! :-(
3832             # Because print_trace will call add 1 to it and then call
3833             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3834             # in dump_trace.
3835             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3836           )
3837         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3838
3839           # standard frame entry message
3840       )
3841       if $frame;
3842
3843     # Pop the single-step value back off the stack.
3844     $single |= $stack[ $stack_depth-- ];
3845
3846     # call the original lvalue sub.
3847     &$sub;
3848 }
3849
3850 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3851
3852 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3853 Most of the changes were to systematize the command structure and to eliminate
3854 commands that threw away user input without checking.
3855
3856 The following sections describe the code added to make it easy to support
3857 multiple command sets with conflicting command names. This section is a start
3858 at unifying all command processing to make it simpler to develop commands.
3859
3860 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3861 number, and C<$dbline> (the current line) as arguments.
3862
3863 Support functions in this section which have multiple modes of failure C<die>
3864 on error; the rest simply return a false value.
3865
3866 The user-interface functions (all of the C<cmd_*> functions) just output
3867 error messages.
3868
3869 =head2 C<%set>
3870
3871 The C<%set> hash defines the mapping from command letter to subroutine
3872 name suffix.
3873
3874 C<%set> is a two-level hash, indexed by set name and then by command name.
3875 Note that trying to set the CommandSet to C<foobar> simply results in the
3876 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3877
3878 =cut
3879
3880 ### The API section
3881
3882 my %set = (    #
3883     'pre580' => {
3884         'a' => 'pre580_a',
3885         'A' => 'pre580_null',
3886         'b' => 'pre580_b',
3887         'B' => 'pre580_null',
3888         'd' => 'pre580_null',
3889         'D' => 'pre580_D',
3890         'h' => 'pre580_h',
3891         'M' => 'pre580_null',
3892         'O' => 'o',
3893         'o' => 'pre580_null',
3894         'v' => 'M',
3895         'w' => 'v',
3896         'W' => 'pre580_W',
3897     },
3898     'pre590' => {
3899         '<'  => 'pre590_prepost',
3900         '<<' => 'pre590_prepost',
3901         '>'  => 'pre590_prepost',
3902         '>>' => 'pre590_prepost',
3903         '{'  => 'pre590_prepost',
3904         '{{' => 'pre590_prepost',
3905     },
3906 );
3907
3908 =head2 C<cmd_wrapper()> (API)
3909
3910 C<cmd_wrapper()> allows the debugger to switch command sets
3911 depending on the value of the C<CommandSet> option.
3912
3913 It tries to look up the command in the C<%set> package-level I<lexical>
3914 (which means external entities can't fiddle with it) and create the name of
3915 the sub to call based on the value found in the hash (if it's there). I<All>
3916 of the commands to be handled in a set have to be added to C<%set>; if they
3917 aren't found, the 5.8.0 equivalent is called (if there is one).
3918
3919 This code uses symbolic references.
3920
3921 =cut
3922
3923 sub cmd_wrapper {
3924     my $cmd      = shift;
3925     my $line     = shift;
3926     my $dblineno = shift;
3927
3928     # Assemble the command subroutine's name by looking up the
3929     # command set and command name in %set. If we can't find it,
3930     # default to the older version of the command.
3931     my $call = 'cmd_'
3932       . ( $set{$CommandSet}{$cmd}
3933           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3934
3935     # Call the command subroutine, call it by name.
3936     return &$call( $cmd, $line, $dblineno );
3937 } ## end sub cmd_wrapper
3938
3939 =head3 C<cmd_a> (command)
3940
3941 The C<a> command handles pre-execution actions. These are associated with a
3942 particular line, so they're stored in C<%dbline>. We default to the current
3943 line if none is specified.
3944
3945 =cut
3946
3947 sub cmd_a {
3948     my $cmd    = shift;
3949     my $line   = shift || '';    # [.|line] expr
3950     my $dbline = shift;
3951
3952     # If it's dot (here), or not all digits,  use the current line.
3953     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3954
3955     # Should be a line number followed by an expression.
3956     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3957         my ( $lineno, $expr ) = ( $1, $2 );
3958
3959         # If we have an expression ...
3960         if ( length $expr ) {
3961
3962             # ... but the line isn't breakable, complain.
3963             if ( $dbline[$lineno] == 0 ) {
3964                 print $OUT
3965                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3966             }
3967             else {
3968
3969                 # It's executable. Record that the line has an action.
3970                 $had_breakpoints{$filename} |= 2;
3971
3972                 # Remove any action, temp breakpoint, etc.
3973                 $dbline{$lineno} =~ s/\0[^\0]*//;
3974
3975                 # Add the action to the line.
3976                 $dbline{$lineno} .= "\0" . action($expr);
3977             }
3978         } ## end if (length $expr)
3979     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3980     else {
3981
3982         # Syntax wrong.
3983         print $OUT
3984           "Adding an action requires an optional lineno and an expression\n"
3985           ;    # hint
3986     }
3987 } ## end sub cmd_a
3988
3989 =head3 C<cmd_A> (command)
3990
3991 Delete actions. Similar to above, except the delete code is in a separate
3992 subroutine, C<delete_action>.
3993
3994 =cut
3995
3996 sub cmd_A {
3997     my $cmd    = shift;
3998     my $line   = shift || '';
3999     my $dbline = shift;
4000
4001     # Dot is this line.
4002     $line =~ s/^\./$dbline/;
4003
4004     # Call delete_action with a null param to delete them all.
4005     # The '1' forces the eval to be true. It'll be false only
4006     # if delete_action blows up for some reason, in which case
4007     # we print $@ and get out.
4008     if ( $line eq '*' ) {
4009         eval { &delete_action(); 1 } or print $OUT $@ and return;
4010     }
4011
4012     # There's a real line  number. Pass it to delete_action.
4013     # Error trapping is as above.
4014     elsif ( $line =~ /^(\S.*)/ ) {
4015         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4016     }
4017
4018     # Swing and a miss. Bad syntax.
4019     else {
4020         print $OUT
4021           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4022     }
4023 } ## end sub cmd_A
4024
4025 =head3 C<delete_action> (API)
4026
4027 C<delete_action> accepts either a line number or C<undef>. If a line number
4028 is specified, we check for the line being executable (if it's not, it
4029 couldn't have had an  action). If it is, we just take the action off (this
4030 will get any kind of an action, including breakpoints).
4031
4032 =cut
4033
4034 sub delete_action {
4035     my $i = shift;
4036     if ( defined($i) ) {
4037
4038         # Can there be one?
4039         die "Line $i has no action .\n" if $dbline[$i] == 0;
4040
4041         # Nuke whatever's there.
4042         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4043         delete $dbline{$i} if $dbline{$i} eq '';
4044     }
4045     else {
4046         print $OUT "Deleting all actions...\n";
4047         for my $file ( keys %had_breakpoints ) {
4048             local *dbline = $main::{ '_<' . $file };
4049             my $max = $#dbline;
4050             my $was;
4051             for ( $i = 1 ; $i <= $max ; $i++ ) {
4052                 if ( defined $dbline{$i} ) {
4053                     $dbline{$i} =~ s/\0[^\0]*//;
4054                     delete $dbline{$i} if $dbline{$i} eq '';
4055                 }
4056                 unless ( $had_breakpoints{$file} &= ~2 ) {
4057                     delete $had_breakpoints{$file};
4058                 }
4059             } ## end for ($i = 1 ; $i <= $max...
4060         } ## end for my $file (keys %had_breakpoints)
4061     } ## end else [ if (defined($i))
4062 } ## end sub delete_action
4063
4064 =head3 C<cmd_b> (command)
4065
4066 Set breakpoints. Since breakpoints can be set in so many places, in so many
4067 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4068 we try to parse the command type, and then shuttle it off to an appropriate
4069 subroutine to actually do the work of setting the breakpoint in the right
4070 place.
4071
4072 =cut
4073
4074 sub cmd_b {
4075     my $cmd    = shift;
4076     my $line   = shift;    # [.|line] [cond]
4077     my $dbline = shift;
4078
4079     # Make . the current line number if it's there..
4080     $line =~ s/^\./$dbline/;
4081
4082     # No line number, no condition. Simple break on current line.
4083     if ( $line =~ /^\s*$/ ) {
4084         &cmd_b_line( $dbline, 1 );
4085     }
4086
4087     # Break on load for a file.
4088     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4089         my $file = $1;
4090         $file =~ s/\s+$//;
4091         &cmd_b_load($file);
4092     }
4093
4094     # b compile|postpone <some sub> [<condition>]
4095     # The interpreter actually traps this one for us; we just put the
4096     # necessary condition in the %postponed hash.
4097     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4098
4099         # Capture the condition if there is one. Make it true if none.
4100         my $cond = length $3 ? $3 : '1';
4101
4102         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4103         # if it was 'compile'.
4104         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4105
4106         # De-Perl4-ify the name - ' separators to ::.
4107         $subname =~ s/\'/::/g;
4108
4109         # Qualify it into the current package unless it's already qualified.
4110         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4111
4112         # Add main if it starts with ::.
4113         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4114
4115         # Save the break type for this sub.
4116         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4117     } ## end elsif ($line =~ ...
4118
4119     # b <sub name> [<condition>]
4120     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4121
4122         #
4123         $subname = $1;
4124         $cond = length $2 ? $2 : '1';
4125         &cmd_b_sub( $subname, $cond );
4126     }
4127
4128     # b <line> [<condition>].
4129     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4130
4131         # Capture the line. If none, it's the current line.
4132         $line = $1 || $dbline;
4133
4134         # If there's no condition, make it '1'.
4135         $cond = length $2 ? $2 : '1';
4136
4137         # Break on line.
4138         &cmd_b_line( $line, $cond );
4139     }
4140
4141     # Line didn't make sense.
4142     else {
4143         print "confused by line($line)?\n";
4144     }
4145 } ## end sub cmd_b
4146
4147 =head3 C<break_on_load> (API)
4148
4149 We want to break when this file is loaded. Mark this file in the
4150 C<%break_on_load> hash, and note that it has a breakpoint in
4151 C<%had_breakpoints>.
4152
4153 =cut
4154
4155 sub break_on_load {
4156     my $file = shift;
4157     $break_on_load{$file} = 1;
4158     $had_breakpoints{$file} |= 1;
4159 }
4160
4161 =head3 C<report_break_on_load> (API)
4162
4163 Gives us an array of filenames that are set to break on load. Note that
4164 only files with break-on-load are in here, so simply showing the keys
4165 suffices.
4166
4167 =cut
4168
4169 sub report_break_on_load {
4170     sort keys %break_on_load;
4171 }
4172
4173 =head3 C<cmd_b_load> (command)
4174
4175 We take the file passed in and try to find it in C<%INC> (which maps modules
4176 to files they came from). We mark those files for break-on-load via
4177 C<break_on_load> and then report that it was done.
4178
4179 =cut
4180
4181 sub cmd_b_load {
4182     my $file = shift;
4183     my @files;
4184
4185     # This is a block because that way we can use a redo inside it
4186     # even without there being any looping structure at all outside it.
4187     {
4188
4189         # Save short name and full path if found.
4190         push @files, $file;
4191         push @files, $::INC{$file} if $::INC{$file};
4192
4193         # Tack on .pm and do it again unless there was a '.' in the name
4194         # already.
4195         $file .= '.pm', redo unless $file =~ /\./;
4196     }
4197
4198     # Do the real work here.
4199     break_on_load($_) for @files;
4200
4201     # All the files that have break-on-load breakpoints.
4202     @files = report_break_on_load;
4203
4204     # Normalize for the purposes of our printing this.
4205     local $\ = '';
4206     local $" = ' ';
4207     print $OUT "Will stop on load of `@files'.\n";
4208 } ## end sub cmd_b_load
4209
4210 =head3 C<$filename_error> (API package global)
4211
4212 Several of the functions we need to implement in the API need to work both
4213 on the current file and on other files. We don't want to duplicate code, so
4214 C<$filename_error> is used to contain the name of the file that's being
4215 worked on (if it's not the current one).
4216
4217 We can now build functions in pairs: the basic function works on the current
4218 file, and uses C<$filename_error> as part of its error message. Since this is
4219 initialized to C<"">, no filename will appear when we are working on the
4220 current file.
4221
4222 The second function is a wrapper which does the following:
4223
4224 =over 4
4225
4226 =item *
4227
4228 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4229
4230 =item *
4231
4232 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4233
4234 =item *
4235
4236 Calls the first function.
4237
4238 The first function works on the I<current> file (i.e., the one we changed to),
4239 and prints C<$filename_error> in the error message (the name of the other file)
4240 if it needs to. When the functions return, C<*dbline> is restored to point
4241 to the actual current file (the one we're executing in) and
4242 C<$filename_error> is restored to C<"">. This restores everything to
4243 the way it was before the second function was called at all.
4244
4245 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4246 details.
4247
4248 =back
4249
4250 =cut
4251
4252 $filename_error = '';
4253
4254 =head3 breakable_line(from, to) (API)
4255
4256 The subroutine decides whether or not a line in the current file is breakable.
4257 It walks through C<@dbline> within the range of lines specified, looking for
4258 the first line that is breakable.
4259
4260 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4261 first line I<after> C<$to> that's breakable, if there is one.
4262
4263 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4264 first line I<before> C<$to> that's breakable, if there is one.
4265
4266 =cut
4267
4268 sub breakable_line {
4269
4270     my ( $from, $to ) = @_;
4271
4272     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4273     my $i = $from;
4274
4275     # If there are at least 2 arguments, we're trying to search a range.
4276     if ( @_ >= 2 ) {
4277
4278         # $delta is positive for a forward search, negative for a backward one.
4279         my $delta = $from < $to ? +1 : -1;
4280
4281         # Keep us from running off the ends of the file.
4282         my $limit = $delta > 0 ? $#dbline : 1;
4283
4284         # Clever test. If you're a mathematician, it's obvious why this
4285         # test works. If not:
4286         # If $delta is positive (going forward), $limit will be $#dbline.
4287         #    If $to is less than $limit, ($limit - $to) will be positive, times
4288         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4289         #    as the stopping point.
4290         #
4291         #    If $to is greater than $limit, ($limit - $to) is negative,
4292         #    times $delta of 1 (positive), so the result is < 0 and we should
4293         #    use $limit ($#dbline) as the stopping point.
4294         #
4295         # If $delta is negative (going backward), $limit will be 1.
4296         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4297         #    (negative) so the result is > 0, and we use $to as the stopping
4298         #    point.
4299         #
4300         #    If $to is less than zero, ($limit - $to) will be positive,
4301         #    times $delta of -1 (negative), so the result is not > 0, and
4302         #    we use $limit (1) as the stopping point.
4303         #
4304         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4305         #    (negative), still giving zero; the result is not > 0, and
4306         #    we use $limit (1) as the stopping point.
4307         #
4308         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4309         #    (negative), giving a positive (>0) value, so we'll set $limit to
4310         #    $to.
4311
4312         $limit = $to if ( $limit - $to ) * $delta > 0;
4313
4314         # The real search loop.
4315         # $i starts at $from (the point we want to start searching from).
4316         # We move through @dbline in the appropriate direction (determined
4317         # by $delta: either -1 (back) or +1 (ahead).
4318         # We stay in as long as we haven't hit an executable line
4319         # ($dbline[$i] == 0 means not executable) and we haven't reached
4320         # the limit yet (test similar to the above).
4321         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4322
4323     } ## end if (@_ >= 2)
4324
4325     # If $i points to a line that is executable, return that.
4326     return $i unless $dbline[$i] == 0;
4327
4328     # Format the message and print it: no breakable lines in range.
4329     my ( $pl, $upto ) = ( '', '' );
4330     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4331
4332     # If there's a filename in filename_error, we'll see it.
4333     # If not, not.
4334     die "Line$pl $from$upto$filename_error not breakable\n";
4335 } ## end sub breakable_line
4336
4337 =head3 breakable_line_in_filename(file, from, to) (API)
4338
4339 Like C<breakable_line>, but look in another file.
4340
4341 =cut
4342
4343 sub breakable_line_in_filename {
4344
4345     # Capture the file name.
4346     my ($f) = shift;
4347
4348     # Swap the magic line array over there temporarily.
4349     local *dbline = $main::{ '_<' . $f };
4350
4351     # If there's an error, it's in this other file.
4352     local $filename_error = " of `$f'";
4353
4354     # Find the breakable line.
4355     breakable_line(@_);
4356
4357     # *dbline and $filename_error get restored when this block ends.
4358
4359 } ## end sub breakable_line_in_filename
4360
4361 =head3 break_on_line(lineno, [condition]) (API)
4362
4363 Adds a breakpoint with the specified condition (or 1 if no condition was
4364 specified) to the specified line. Dies if it can't.
4365
4366 =cut
4367
4368 sub break_on_line {
4369     my ( $i, $cond ) = @_;
4370
4371     # Always true if no condition supplied.
4372     $cond = 1 unless @_ >= 2;
4373
4374     my $inii  = $i;
4375     my $after = '';
4376     my $pl    = '';
4377
4378     # Woops, not a breakable line. $filename_error allows us to say
4379     # if it was in a different file.
4380     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4381
4382     # Mark this file as having breakpoints in it.
4383     $had_breakpoints{$filename} |= 1;
4384
4385     # If there is an action or condition here already ...
4386     if ( $dbline{$i} ) {
4387
4388         # ... swap this condition for the existing one.
4389         $dbline{$i} =~ s/^[^\0]*/$cond/;
4390     }
4391     else {
4392
4393         # Nothing here - just add the condition.
4394         $dbline{$i} = $cond;
4395     }
4396 } ## end sub break_on_line
4397
4398 =head3 cmd_b_line(line, [condition]) (command)
4399
4400 Wrapper for C<break_on_line>. Prints the failure message if it
4401 doesn't work.
4402
4403 =cut
4404
4405 sub cmd_b_line {
4406     eval { break_on_line(@_); 1 } or do {
4407         local $\ = '';
4408         print $OUT $@ and return;
4409     };
4410 } ## end sub cmd_b_line
4411
4412 =head3 break_on_filename_line(file, line, [condition]) (API)
4413
4414 Switches to the file specified and then calls C<break_on_line> to set
4415 the breakpoint.
4416
4417 =cut
4418
4419 sub break_on_filename_line {
4420     my ( $f, $i, $cond ) = @_;
4421
4422     # Always true if condition left off.
4423     $cond = 1 unless @_ >= 3;
4424
4425     # Switch the magical hash temporarily.
4426     local *dbline = $main::{ '_<' . $f };
4427
4428     # Localize the variables that break_on_line uses to make its message.
4429     local $filename_error = " of `$f'";
4430     local $filename       = $f;
4431
4432     # Add the breakpoint.
4433     break_on_line( $i, $cond );
4434 } ## end sub break_on_filename_line
4435
4436 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4437
4438 Switch to another file, search the range of lines specified for an
4439 executable one, and put a breakpoint on the first one you find.
4440
4441 =cut
4442
4443 sub break_on_filename_line_range {
4444     my ( $f, $from, $to, $cond ) = @_;
4445
4446     # Find a breakable line if there is one.
4447     my $i = breakable_line_in_filename( $f, $from, $to );
4448
4449     # Always true if missing.
4450     $cond = 1 unless @_ >= 3;
4451
4452     # Add the breakpoint.
4453     break_on_filename_line( $f, $i, $cond );
4454 } ## end sub break_on_filename_line_range
4455
4456 =head3 subroutine_filename_lines(subname, [condition]) (API)
4457
4458 Search for a subroutine within a given file. The condition is ignored.
4459 Uses C<find_sub> to locate the desired subroutine.
4460
4461 =cut
4462
4463 sub subroutine_filename_lines {
4464     my ( $subname, $cond ) = @_;
4465
4466     # Returned value from find_sub() is fullpathname:startline-endline.
4467     # The match creates the list (fullpathname, start, end). Falling off
4468     # the end of the subroutine returns this implicitly.
4469     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4470 } ## end sub subroutine_filename_lines
4471
4472 =head3 break_subroutine(subname) (API)
4473
4474 Places a break on the first line possible in the specified subroutine. Uses
4475 C<subroutine_filename_lines> to find the subroutine, and
4476 C<break_on_filename_line_range> to place the break.
4477
4478 =cut
4479
4480 sub break_subroutine {
4481     my $subname = shift;
4482
4483     # Get filename, start, and end.
4484     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4485       or die "Subroutine $subname not found.\n";
4486
4487     # Null condition changes to '1' (always true).
4488     $cond = 1 unless @_ >= 2;
4489
4490     # Put a break the first place possible in the range of lines
4491     # that make up this subroutine.
4492     break_on_filename_line_range( $file, $s, $e, @_ );
4493 } ## end sub break_subroutine
4494
4495 =head3 cmd_b_sub(subname, [condition]) (command)
4496
4497 We take the incoming subroutine name and fully-qualify it as best we can.
4498
4499 =over 4
4500
4501 =item 1. If it's already fully-qualified, leave it alone.
4502
4503 =item 2. Try putting it in the current package.
4504
4505 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4506
4507 =item 4. If it starts with '::', put it in 'main::'.
4508
4509 =back
4510
4511 After all this cleanup, we call C<break_subroutine> to try to set the
4512 breakpoint.
4513
4514 =cut
4515
4516 sub cmd_b_sub {
4517     my ( $subname, $cond ) = @_;
4518
4519     # Add always-true condition if we have none.
4520     $cond = 1 unless @_ >= 2;
4521
4522     # If the subname isn't a code reference, qualify it so that
4523     # break_subroutine() will work right.
4524     unless ( ref $subname eq 'CODE' ) {
4525
4526         # Not Perl4.
4527         $subname =~ s/\'/::/g;
4528         my $s = $subname;
4529
4530         # Put it in this package unless it's already qualified.
4531         $subname = "${'package'}::" . $subname
4532           unless $subname =~ /::/;
4533
4534         # Requalify it into CORE::GLOBAL if qualifying it into this
4535         # package resulted in its not being defined, but only do so
4536         # if it really is in CORE::GLOBAL.
4537         $subname = "CORE::GLOBAL::$s"
4538           if not defined &$subname
4539           and $s !~ /::/
4540           and defined &{"CORE::GLOBAL::$s"};
4541
4542         # Put it in package 'main' if it has a leading ::.
4543         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4544
4545     } ## end unless (ref $subname eq 'CODE')
4546
4547     # Try to set the breakpoint.
4548     eval { break_subroutine( $subname, $cond ); 1 } or do {
4549         local $\ = '';
4550         print $OUT $@ and return;
4551       }
4552 } ## end sub cmd_b_sub
4553
4554 =head3 C<cmd_B> - delete breakpoint(s) (command)
4555
4556 The command mostly parses the command line and tries to turn the argument
4557 into a line spec. If it can't, it uses the current line. It then calls
4558 C<delete_breakpoint> to actually do the work.
4559
4560 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4561 thereby deleting all the breakpoints.
4562
4563 =cut
4564
4565 sub cmd_B {
4566     my $cmd = shift;
4567
4568     # No line spec? Use dbline.
4569     # If there is one, use it if it's non-zero, or wipe it out if it is.
4570     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4571     my $dbline = shift;
4572
4573     # If the line was dot, make the line the current one.
4574     $line =~ s/^\./$dbline/;
4575
4576     # If it's * we're deleting all the breakpoints.
4577     if ( $line eq '*' ) {
4578         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4579     }
4580
4581     # If there is a line spec, delete the breakpoint on that line.
4582     elsif ( $line =~ /^(\S.*)/ ) {
4583         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4584             local $\ = '';
4585             print $OUT $@ and return;
4586         };
4587     } ## end elsif ($line =~ /^(\S.*)/)
4588
4589     # No line spec.
4590     else {
4591         print $OUT
4592           "Deleting a breakpoint requires a line number, or '*' for all\n"
4593           ;    # hint
4594     }
4595 } ## end sub cmd_B
4596
4597 =head3 delete_breakpoint([line]) (API)
4598
4599 This actually does the work of deleting either a single breakpoint, or all
4600 of them.
4601
4602 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4603 just drop out with a message saying so. If it is, we remove the condition
4604 part of the 'condition\0action' that says there's a breakpoint here. If,
4605 after we've done that, there's nothing left, we delete the corresponding
4606 line in C<%dbline> to signal that no action needs to be taken for this line.
4607
4608 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4609 which lists all currently-loaded files which have breakpoints. We then look
4610 at each line in each of these files, temporarily switching the C<%dbline>
4611 and C<@dbline> structures to point to the files in question, and do what
4612 we did in the single line case: delete the condition in C<@dbline>, and
4613 delete the key in C<%dbline> if nothing's left.
4614
4615 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4616 C<%break_on_load>, because these structures contain breakpoints for files
4617 and code that haven't been loaded yet. We can just kill these off because there
4618 are no magical debugger structures associated with them.
4619
4620 =cut
4621
4622 sub delete_breakpoint {
4623     my $i = shift;
4624
4625     # If we got a line, delete just that one.
4626     if ( defined($i) ) {
4627
4628         # Woops. This line wasn't breakable at all.
4629         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4630
4631         # Kill the condition, but leave any action.
4632         $dbline{$i} =~ s/^[^\0]*//;
4633
4634         # Remove the entry entirely if there's no action left.
4635         delete $dbline{$i} if $dbline{$i} eq '';
4636     }
4637
4638     # No line; delete them all.
4639     else {
4640         print $OUT "Deleting all breakpoints...\n";
4641
4642         # %had_breakpoints lists every file that had at least one
4643         # breakpoint in it.
4644         for my $file ( keys %had_breakpoints ) {
4645
4646             # Switch to the desired file temporarily.
4647             local *dbline = $main::{ '_<' . $file };
4648
4649             my $max = $#dbline;
4650             my $was;
4651
4652             # For all lines in this file ...
4653             for ( $i = 1 ; $i <= $max ; $i++ ) {
4654
4655                 # If there's a breakpoint or action on this line ...
4656                 if ( defined $dbline{$i} ) {
4657
4658                     # ... remove the breakpoint.
4659                     $dbline{$i} =~ s/^[^\0]+//;
4660                     if ( $dbline{$i} =~ s/^\0?$// ) {
4661
4662                         # Remove the entry altogether if no action is there.
4663                         delete $dbline{$i};
4664                     }
4665                 } ## end if (defined $dbline{$i...
4666             } ## end for ($i = 1 ; $i <= $max...
4667
4668             # If, after we turn off the "there were breakpoints in this file"
4669             # bit, the entry in %had_breakpoints for this file is zero,
4670             # we should remove this file from the hash.
4671             if ( not $had_breakpoints{$file} &= ~1 ) {
4672                 delete $had_breakpoints{$file};
4673             }
4674         } ## end for my $file (keys %had_breakpoints)
4675
4676         # Kill off all the other breakpoints that are waiting for files that
4677         # haven't been loaded yet.
4678         undef %postponed;
4679         undef %postponed_file;
4680         undef %break_on_load;
4681     } ## end else [ if (defined($i))
4682 } ## end sub delete_breakpoint
4683
4684 =head3 cmd_stop (command)
4685
4686 This is meant to be part of the new command API, but it isn't called or used
4687 anywhere else in the debugger. XXX It is probably meant for use in development
4688 of new commands.
4689
4690 =cut
4691
4692 sub cmd_stop {    # As on ^C, but not signal-safy.
4693     $signal = 1;
4694 }
4695
4696 =head3 C<cmd_e> - threads
4697
4698 Display the current thread id:
4699
4700         e
4701
4702 This could be how (when implemented) to send commands to this thread id (e cmd)
4703 or that thread id (e tid cmd).
4704
4705 =cut
4706
4707 sub cmd_e {
4708     my $cmd  = shift;
4709     my $line = shift;
4710         unless (exists($INC{'threads.pm'})) {
4711                 print "threads not loaded($ENV{PERL5DB_THREADED})
4712                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4713         } else {
4714                 my $tid = threads->tid;
4715                 print "thread id: $tid\n";
4716         }
4717 } ## end sub cmd_e
4718
4719 =head3 C<cmd_E> - list of thread ids
4720
4721 Display the list of available thread ids:
4722
4723         E
4724
4725 This could be used (when implemented) to send commands to all threads (E cmd).
4726
4727 =cut
4728
4729 sub cmd_E {
4730     my $cmd  = shift;
4731     my $line = shift;
4732         unless (exists($INC{'threads.pm'})) {
4733                 print "threads not loaded($ENV{PERL5DB_THREADED})
4734                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4735         } else {
4736                 my $tid = threads->tid;
4737                 print "thread ids: ".join(', ',
4738                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4739                 )."\n";
4740         }
4741 } ## end sub cmd_E
4742
4743 =head3 C<cmd_h> - help command (command)
4744
4745 Does the work of either
4746
4747 =over 4
4748
4749 =item *
4750
4751 Showing all the debugger help
4752
4753 =item *
4754
4755 Showing help for a specific command
4756
4757 =back
4758
4759 =cut
4760
4761 sub cmd_h {
4762     my $cmd = shift;
4763
4764     # If we have no operand, assume null.
4765     my $line = shift || '';
4766
4767     # 'h h'. Print the long-format help.
4768     if ( $line =~ /^h\s*/ ) {
4769         print_help($help);
4770     }
4771
4772     # 'h <something>'. Search for the command and print only its help.
4773     elsif ( $line =~ /^(\S.*)$/ ) {
4774
4775         # support long commands; otherwise bogus errors
4776         # happen when you ask for h on <CR> for example
4777         my $asked = $1;    # the command requested
4778                            # (for proper error message)
4779
4780         my $qasked = quotemeta($asked);    # for searching; we don't
4781                                            # want to use it as a pattern.
4782                                            # XXX: finds CR but not <CR>
4783
4784         # Search the help string for the command.
4785         if (
4786             $help =~ /^                    # Start of a line
4787                       <?                   # Optional '<'
4788                       (?:[IB]<)            # Optional markup
4789                       $qasked              # The requested command
4790                      /mx
4791           )
4792         {
4793
4794             # It's there; pull it out and print it.
4795             while (
4796                 $help =~ /^
4797                               (<?            # Optional '<'
4798                                  (?:[IB]<)   # Optional markup
4799                                  $qasked     # The command
4800                                  ([\s\S]*?)  # Description line(s)
4801                               \n)            # End of last description line
4802                               (?!\s)         # Next line not starting with
4803                                              # whitespace
4804                              /mgx
4805               )
4806             {
4807                 print_help($1);
4808             }
4809         }
4810
4811         # Not found; not a debugger command.
4812         else {
4813             print_help("B<$asked> is not a debugger command.\n");
4814         }
4815     } ## end elsif ($line =~ /^(\S.*)$/)
4816
4817     # 'h' - print the summary help.
4818     else {
4819         print_help($summary);
4820     }
4821 } ## end sub cmd_h
4822
4823 =head3 C<cmd_i> - inheritance display
4824
4825 Display the (nested) parentage of the module or object given.
4826
4827 =cut
4828
4829 sub cmd_i {
4830     my $cmd  = shift;
4831     my $line = shift;
4832     eval { require Class::ISA };
4833     if ($@) {
4834         &warn( $@ =~ /locate/
4835             ? "Class::ISA module not found - please install\n"
4836             : $@ );
4837     }
4838     else {
4839       ISA:
4840         foreach my $isa ( split( /\s+/, $line ) ) {
4841             $evalarg = $isa;
4842             ($isa) = &eval;
4843             no strict 'refs';
4844             print join(
4845                 ', ',
4846                 map {    # snaffled unceremoniously from Class::ISA
4847                     "$_"
4848                       . (
4849                         defined( ${"$_\::VERSION"} )
4850                         ? ' ' . ${"$_\::VERSION"}
4851                         : undef )
4852                   } Class::ISA::self_and_super_path(ref($isa) || $isa)
4853             );
4854             print "\n";
4855         }
4856     }
4857 } ## end sub cmd_i
4858
4859 =head3 C<cmd_l> - list lines (command)
4860
4861 Most of the command is taken up with transforming all the different line
4862 specification syntaxes into 'start-stop'. After that is done, the command
4863 runs a loop over C<@dbline> for the specified range of lines. It handles
4864 the printing of each line and any markers (C<==E<gt>> for current line,
4865 C<b> for break on this line, C<a> for action on this line, C<:> for this
4866 line breakable).
4867
4868 We save the last line listed in the C<$start> global for further listing
4869 later.
4870
4871 =cut
4872
4873 sub cmd_l {
4874     my $current_line = $line;
4875     my $cmd  = shift;
4876     my $line = shift;
4877
4878     # If this is '-something', delete any spaces after the dash.
4879     $line =~ s/^-\s*$/-/;
4880
4881     # If the line is '$something', assume this is a scalar containing a
4882     # line number.
4883     if ( $line =~ /^(\$.*)/s ) {
4884
4885         # Set up for DB::eval() - evaluate in *user* context.
4886         $evalarg = $1;
4887         # $evalarg = $2;
4888         my ($s) = &eval;
4889
4890         # Ooops. Bad scalar.
4891         print( $OUT "Error: $@\n" ), next CMD if $@;
4892
4893         # Good scalar. If it's a reference, find what it points to.
4894         $s = CvGV_name($s);
4895         print( $OUT "Interpreted as: $1 $s\n" );
4896         $line = "$1 $s";
4897
4898         # Call self recursively to really do the command.
4899         &cmd_l( 'l', $s );
4900     } ## end if ($line =~ /^(\$.*)/s)
4901
4902     # l name. Try to find a sub by that name.
4903     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
4904         my $s = $subname = $1;
4905
4906         # De-Perl4.
4907         $subname =~ s/\'/::/;
4908
4909         # Put it in this package unless it starts with ::.
4910         $subname = $package . "::" . $subname unless $subname =~ /::/;
4911
4912         # Put it in CORE::GLOBAL if t doesn't start with :: and
4913         # it doesn't live in this package and it lives in CORE::GLOBAL.
4914         $subname = "CORE::GLOBAL::$s"
4915           if not defined &$subname
4916           and $s !~ /::/
4917           and defined &{"CORE::GLOBAL::$s"};
4918
4919         # Put leading '::' names into 'main::'.
4920         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4921
4922         # Get name:start-stop from find_sub, and break this up at
4923         # colons.
4924         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
4925
4926         # Pull off start-stop.
4927         $subrange = pop @pieces;
4928
4929         # If the name contained colons, the split broke it up.
4930         # Put it back together.
4931         $file = join( ':', @pieces );
4932
4933         # If we're not in that file, switch over to it.
4934         if ( $file ne $filename ) {
4935             print $OUT "Switching to file '$file'.\n"
4936               unless $slave_editor;
4937
4938             # Switch debugger's magic structures.
4939             *dbline   = $main::{ '_<' . $file };
4940             $max      = $#dbline;
4941             $filename = $file;
4942         } ## end if ($file ne $filename)
4943
4944         # Subrange is 'start-stop'. If this is less than a window full,
4945         # swap it to 'start+', which will list a window from the start point.
4946         if ($subrange) {
4947             if ( eval($subrange) < -$window ) {
4948                 $subrange =~ s/-.*/+/;
4949             }
4950
4951             # Call self recursively to list the range.
4952             $line = $subrange;
4953             &cmd_l( 'l', $subrange );
4954         } ## end if ($subrange)
4955
4956         # Couldn't find it.
4957         else {
4958             print $OUT "Subroutine $subname not found.\n";
4959         }
4960     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
4961
4962     # Bare 'l' command.
4963     elsif ( $line =~ /^\s*$/ ) {
4964
4965         # Compute new range to list.
4966         $incr = $window - 1;
4967         $line = $start . '-' . ( $start + $incr );
4968
4969         # Recurse to do it.
4970         &cmd_l( 'l', $line );
4971     }
4972
4973     # l [start]+number_of_lines
4974     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
4975
4976         # Don't reset start for 'l +nnn'.
4977         $start = $1 if $1;
4978
4979         # Increment for list. Use window size if not specified.
4980         # (Allows 'l +' to work.)
4981         $incr = $2;
4982         $incr = $window - 1 unless $incr;
4983
4984         # Create a line range we'll understand, and recurse to do it.
4985         $line = $start . '-' . ( $start + $incr );
4986         &cmd_l( 'l', $line );
4987     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
4988
4989     # l start-stop or l start,stop
4990     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
4991
4992         # Determine end point; use end of file if not specified.
4993         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
4994
4995         # Go on to the end, and then stop.
4996         $end = $max if $end > $max;
4997
4998         # Determine start line.
4999         $i    = $2;
5000         $i    = $line if $i eq '.';
5001         $i    = 1 if $i < 1;
5002         $incr = $end - $i;
5003
5004         # If we're running under a slave editor, force it to show the lines.
5005         if ($slave_editor) {
5006             print $OUT "\032\032$filename:$i:0\n";
5007             $i = $end;
5008         }
5009
5010         # We're doing it ourselves. We want to show the line and special
5011         # markers for:
5012         # - the current line in execution
5013         # - whether a line is breakable or not
5014         # - whether a line has a break or not
5015         # - whether a line has an action or not
5016         else {
5017             for ( ; $i <= $end ; $i++ ) {
5018
5019                 # Check for breakpoints and actions.
5020                 my ( $stop, $action );
5021                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5022                   if $dbline{$i};
5023
5024                 # ==> if this is the current line in execution,
5025                 # : if it's breakable.
5026                 $arrow =
5027                   ( $i == $current_line and $filename eq $filename_ini )
5028                   ? '==>'
5029                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5030
5031                 # Add break and action indicators.
5032                 $arrow .= 'b' if $stop;
5033                 $arrow .= 'a' if $action;
5034
5035                 # Print the line.
5036                 print $OUT "$i$arrow\t", $dbline[$i];
5037
5038                 # Move on to the next line. Drop out on an interrupt.
5039                 $i++, last if $signal;
5040             } ## end for (; $i <= $end ; $i++)
5041
5042             # Line the prompt up; print a newline if the last line listed
5043             # didn't have a newline.
5044             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5045         } ## end else [ if ($slave_editor)
5046
5047         # Save the point we last listed to in case another relative 'l'
5048         # command is desired. Don't let it run off the end.
5049         $start = $i;
5050         $start = $max if $start > $max;
5051     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5052 } ## end sub cmd_l
5053
5054 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5055
5056 To list breakpoints, the command has to look determine where all of them are
5057 first. It starts a C<%had_breakpoints>, which tells us what all files have
5058 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5059 magic source and breakpoint data structures) to the file, and then look
5060 through C<%dbline> for lines with breakpoints and/or actions, listing them
5061 out. We look through C<%postponed> not-yet-compiled subroutines that have
5062 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5063 that have breakpoints.
5064
5065 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5066
5067 =cut
5068
5069 sub cmd_L {
5070     my $cmd = shift;
5071
5072     # If no argument, list everything. Pre-5.8.0 version always lists
5073     # everything
5074     my $arg = shift || 'abw';
5075     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5076
5077     # See what is wanted.
5078     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5079     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5080     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5081
5082     # Breaks and actions are found together, so we look in the same place
5083     # for both.
5084     if ( $break_wanted or $action_wanted ) {
5085
5086         # Look in all the files with breakpoints...
5087         for my $file ( keys %had_breakpoints ) {
5088
5089             # Temporary switch to this file.
5090             local *dbline = $main::{ '_<' . $file };
5091
5092             # Set up to look through the whole file.
5093             my $max = $#dbline;
5094             my $was;    # Flag: did we print something
5095                         # in this file?
5096
5097             # For each line in the file ...
5098             for ( $i = 1 ; $i <= $max ; $i++ ) {
5099
5100                 # We've got something on this line.
5101                 if ( defined $dbline{$i} ) {
5102
5103                     # Print the header if we haven't.
5104                     print $OUT "$file:\n" unless $was++;
5105
5106                     # Print the line.
5107                     print $OUT " $i:\t", $dbline[$i];
5108
5109                     # Pull out the condition and the action.
5110                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5111
5112                     # Print the break if there is one and it's wanted.
5113                     print $OUT "   break if (", $stop, ")\n"
5114                       if $stop
5115                       and $break_wanted;
5116
5117                     # Print the action if there is one and it's wanted.
5118                     print $OUT "   action:  ", $action, "\n"
5119                       if $action
5120                       and $action_wanted;
5121
5122                     # Quit if the user hit interrupt.
5123                     last if $signal;
5124                 } ## end if (defined $dbline{$i...
5125             } ## end for ($i = 1 ; $i <= $max...
5126         } ## end for my $file (keys %had_breakpoints)
5127     } ## end if ($break_wanted or $action_wanted)
5128
5129     # Look for breaks in not-yet-compiled subs:
5130     if ( %postponed and $break_wanted ) {
5131         print $OUT "Postponed breakpoints in subroutines:\n";
5132         my $subname;
5133         for $subname ( keys %postponed ) {
5134             print $OUT " $subname\t$postponed{$subname}\n";
5135             last if $signal;
5136         }
5137     } ## end if (%postponed and $break_wanted)
5138
5139     # Find files that have not-yet-loaded breaks:
5140     my @have = map {    # Combined keys
5141         keys %{ $postponed_file{$_} }
5142     } keys %postponed_file;
5143
5144     # If there are any, list them.
5145     if ( @have and ( $break_wanted or $action_wanted ) ) {
5146         print $OUT "Postponed breakpoints in files:\n";
5147         my ( $file, $line );
5148
5149         for $file ( keys %postponed_file ) {
5150             my $db = $postponed_file{$file};
5151             print $OUT " $file:\n";
5152             for $line ( sort { $a <=> $b } keys %$db ) {
5153                 print $OUT "  $line:\n";
5154                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5155                 print $OUT "    break if (", $stop, ")\n"
5156                   if $stop
5157                   and $break_wanted;
5158                 print $OUT "    action:  ", $action, "\n"
5159                   if $action
5160                   and $action_wanted;
5161                 last if $signal;
5162             } ## end for $line (sort { $a <=>...
5163             last if $signal;
5164         } ## end for $file (keys %postponed_file)
5165     } ## end if (@have and ($break_wanted...
5166     if ( %break_on_load and $break_wanted ) {
5167         print $OUT "Breakpoints on load:\n";
5168         my $file;
5169         for $file ( keys %break_on_load ) {
5170             print $OUT " $file\n";
5171             last if $signal;
5172         }
5173     } ## end if (%break_on_load and...
5174     if ($watch_wanted) {
5175         if ( $trace & 2 ) {
5176             print $OUT "Watch-expressions:\n" if @to_watch;
5177             for my $expr (@to_watch) {
5178                 print $OUT " $expr\n";
5179                 last if $signal;
5180             }
5181         } ## end if ($trace & 2)
5182     } ## end if ($watch_wanted)
5183 } ## end sub cmd_L
5184
5185 =head3 C<cmd_M> - list modules (command)
5186
5187 Just call C<list_modules>.
5188
5189 =cut
5190
5191 sub cmd_M {
5192     &list_modules();
5193 }
5194
5195 =head3 C<cmd_o> - options (command)
5196
5197 If this is just C<o> by itself, we list the current settings via
5198 C<dump_option>. If there's a nonblank value following it, we pass that on to
5199 C<parse_options> for processing.
5200
5201 =cut
5202
5203 sub cmd_o {
5204     my $cmd = shift;
5205     my $opt = shift || '';    # opt[=val]
5206
5207     # Nonblank. Try to parse and process.
5208     if ( $opt =~ /^(\S.*)/ ) {
5209         &parse_options($1);
5210     }
5211
5212     # Blank. List the current option settings.
5213     else {
5214         for (@options) {
5215             &dump_option($_);
5216         }
5217     }
5218 } ## end sub cmd_o
5219
5220 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5221
5222 Advises the user that the O command has been renamed.
5223
5224 =cut
5225
5226 sub cmd_O {
5227     print $OUT "The old O command is now the o command.\n";             # hint
5228     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5229     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5230 }
5231
5232 =head3 C<cmd_v> - view window (command)
5233
5234 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5235 move back a few lines to list the selected line in context. Uses C<cmd_l>
5236 to do the actual listing after figuring out the range of line to request.
5237
5238 =cut
5239
5240 sub cmd_v {
5241     my $cmd  = shift;
5242     my $line = shift;
5243
5244     # Extract the line to list around. (Astute readers will have noted that
5245     # this pattern will match whether or not a numeric line is specified,
5246     # which means that we'll always enter this loop (though a non-numeric
5247     # argument results in no action at all)).
5248     if ( $line =~ /^(\d*)$/ ) {
5249
5250         # Total number of lines to list (a windowful).
5251         $incr = $window - 1;
5252
5253         # Set the start to the argument given (if there was one).
5254         $start = $1 if $1;
5255
5256         # Back up by the context amount.
5257         $start -= $preview;
5258
5259         # Put together a linespec that cmd_l will like.
5260         $line = $start . '-' . ( $start + $incr );
5261
5262         # List the lines.
5263         &cmd_l( 'l', $line );
5264     } ## end if ($line =~ /^(\d*)$/)
5265 } ## end sub cmd_v
5266
5267 =head3 C<cmd_w> - add a watch expression (command)
5268
5269 The 5.8 version of this command adds a watch expression if one is specified;
5270 it does nothing if entered with no operands.
5271
5272 We extract the expression, save it, evaluate it in the user's context, and
5273 save the value. We'll re-evaluate it each time the debugger passes a line,
5274 and will stop (see the code at the top of the command loop) if the value
5275 of any of the expressions changes.
5276
5277 =cut
5278
5279 sub cmd_w {
5280     my $cmd = shift;
5281
5282     # Null expression if no arguments.
5283     my $expr = shift || '';
5284
5285     # If expression is not null ...
5286     if ( $expr =~ /^(\S.*)/ ) {
5287
5288         # ... save it.
5289         push @to_watch, $expr;
5290
5291         # Parameterize DB::eval and call it to get the expression's value
5292         # in the user's context. This version can handle expressions which
5293         # return a list value.
5294         $evalarg = $expr;
5295         my ($val) = join( ' ', &eval );
5296         $val = ( defined $val ) ? "'$val'" : 'undef';
5297
5298         # Save the current value of the expression.
5299         push @old_watch, $val;
5300
5301         # We are now watching expressions.
5302         $trace |= 2;
5303     } ## end if ($expr =~ /^(\S.*)/)
5304
5305     # You have to give one to get one.
5306     else {
5307         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5308     }
5309 } ## end sub cmd_w
5310
5311 =head3 C<cmd_W> - delete watch expressions (command)
5312
5313 This command accepts either a watch expression to be removed from the list
5314 of watch expressions, or C<*> to delete them all.
5315
5316 If C<*> is specified, we simply empty the watch expression list and the
5317 watch expression value list. We also turn off the bit that says we've got
5318 watch expressions.
5319
5320 If an expression (or partial expression) is specified, we pattern-match
5321 through the expressions and remove the ones that match. We also discard
5322 the corresponding values. If no watch expressions are left, we turn off
5323 the I<watching expressions> bit.
5324
5325 =cut
5326
5327 sub cmd_W {
5328     my $cmd  = shift;
5329     my $expr = shift || '';
5330
5331     # Delete them all.
5332     if ( $expr eq '*' ) {
5333
5334         # Not watching now.
5335         $trace &= ~2;
5336
5337         print $OUT "Deleting all watch expressions ...\n";
5338
5339         # And all gone.
5340         @to_watch = @old_watch = ();
5341     }
5342
5343     # Delete one of them.
5344     elsif ( $expr =~ /^(\S.*)/ ) {
5345
5346         # Where we are in the list.
5347         my $i_cnt = 0;
5348
5349         # For each expression ...
5350         foreach (@to_watch) {
5351             my $val = $to_watch[$i_cnt];
5352
5353             # Does this one match the command argument?
5354             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5355                                       # Yes. Turn it off, and its value too.
5356                 splice( @to_watch,  $i_cnt, 1 );
5357                 splice( @old_watch, $i_cnt, 1 );
5358             }
5359             $i_cnt++;
5360         } ## end foreach (@to_watch)
5361
5362         # We don't bother to turn watching off because
5363         #  a) we don't want to stop calling watchfunction() it it exists
5364         #  b) foreach over a null list doesn't do anything anyway
5365
5366     } ## end elsif ($expr =~ /^(\S.*)/)
5367
5368     # No command arguments entered.
5369     else {
5370         print $OUT
5371           "Deleting a watch-expression requires an expression, or '*' for all\n"
5372           ;    # hint
5373     }
5374 } ## end sub cmd_W
5375
5376 ### END of the API section
5377
5378 =head1 SUPPORT ROUTINES
5379
5380 These are general support routines that are used in a number of places
5381 throughout the debugger.
5382
5383 =head2 save
5384
5385 save() saves the user's versions of globals that would mess us up in C<@saved>,
5386 and installs the versions we like better.
5387
5388 =cut
5389
5390 sub save {
5391
5392     # Save eval failure, command failure, extended OS error, output field
5393     # separator, input record separator, output record separator and
5394     # the warning setting.
5395     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5396
5397     $,  = "";      # output field separator is null string
5398     $/  = "\n";    # input record separator is newline
5399     $\  = "";      # output record separator is null string
5400     $^W = 0;       # warnings are off
5401 } ## end sub save
5402
5403 =head2 C<print_lineinfo> - show where we are now
5404
5405 print_lineinfo prints whatever it is that it is handed; it prints it to the
5406 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5407 us to feed line information to a slave editor without messing up the
5408 debugger output.
5409
5410 =cut
5411
5412 sub print_lineinfo {
5413
5414     # Make the terminal sensible if we're not the primary debugger.
5415     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5416     local $\ = '';
5417     local $, = '';
5418     print $LINEINFO @_;
5419 } ## end sub print_lineinfo
5420
5421 =head2 C<postponed_sub>
5422
5423 Handles setting postponed breakpoints in subroutines once they're compiled.
5424 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5425 range for the subroutine, then mark the file as having a breakpoint,
5426 temporarily switch the C<*dbline> glob over to the source file, and then
5427 search the given range of lines to find a breakable line. If we find one,
5428 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5429
5430 =cut
5431
5432 # The following takes its argument via $evalarg to preserve current @_
5433
5434 sub postponed_sub {
5435
5436     # Get the subroutine name.
5437     my $subname = shift;
5438
5439     # If this is a 'break +<n> if <condition>' ...
5440     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5441
5442         # If there's no offset, use '+0'.
5443         my $offset = $1 || 0;
5444
5445         # find_sub's value is 'fullpath-filename:start-stop'. It's
5446         # possible that the filename might have colons in it too.
5447         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5448         if ($i) {
5449
5450             # We got the start line. Add the offset '+<n>' from
5451             # $postponed{subname}.
5452             $i += $offset;
5453
5454             # Switch to the file this sub is in, temporarily.
5455             local *dbline = $main::{ '_<' . $file };
5456
5457             # No warnings, please.
5458             local $^W = 0;    # != 0 is magical below
5459
5460             # This file's got a breakpoint in it.
5461             $had_breakpoints{$file} |= 1;
5462
5463             # Last line in file.
5464             my $max = $#dbline;
5465
5466             # Search forward until we hit a breakable line or get to
5467             # the end of the file.
5468             ++$i until $dbline[$i] != 0 or $i >= $max;
5469
5470             # Copy the breakpoint in and delete it from %postponed.
5471             $dbline{$i} = delete $postponed{$subname};
5472         } ## end if ($i)
5473
5474         # find_sub didn't find the sub.
5475         else {
5476             local $\ = '';
5477             print $OUT "Subroutine $subname not found.\n";
5478         }
5479         return;
5480     } ## end if ($postponed{$subname...
5481     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5482
5483     #print $OUT "In postponed_sub for `$subname'.\n";
5484 } ## end sub postponed_sub
5485
5486 =head2 C<postponed>
5487
5488 Called after each required file is compiled, but before it is executed;
5489 also called if the name of a just-compiled subroutine is a key of
5490 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5491 etc.) into the just-compiled code.
5492
5493 If this is a C<require>'d file, the incoming parameter is the glob
5494 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5495
5496 If it's a subroutine, the incoming parameter is the subroutine name.
5497
5498 =cut
5499
5500 sub postponed {
5501
5502     # If there's a break, process it.
5503     if ($ImmediateStop) {
5504
5505         # Right, we've stopped. Turn it off.
5506         $ImmediateStop = 0;
5507
5508         # Enter the command loop when DB::DB gets called.
5509         $signal = 1;
5510     }
5511
5512     # If this is a subroutine, let postponed_sub() deal with it.
5513     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5514
5515     # Not a subroutine. Deal with the file.
5516     local *dbline = shift;
5517     my $filename = $dbline;
5518     $filename =~ s/^_<//;
5519     local $\ = '';
5520     $signal = 1, print $OUT "'$filename' loaded...\n"
5521       if $break_on_load{$filename};
5522     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5523
5524     # Do we have any breakpoints to put in this file?
5525     return unless $postponed_file{$filename};
5526
5527     # Yes. Mark this file as having breakpoints.
5528     $had_breakpoints{$filename} |= 1;
5529
5530     # "Cannot be done: unsufficient magic" - we can't just put the
5531     # breakpoints saved in %postponed_file into %dbline by assigning
5532     # the whole hash; we have to do it one item at a time for the
5533     # breakpoints to be set properly.
5534     #%dbline = %{$postponed_file{$filename}};
5535
5536     # Set the breakpoints, one at a time.
5537     my $key;
5538
5539     for $key ( keys %{ $postponed_file{$filename} } ) {
5540
5541         # Stash the saved breakpoint into the current file's magic line array.
5542         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5543     }
5544
5545     # This file's been compiled; discard the stored breakpoints.
5546     delete $postponed_file{$filename};
5547
5548 } ## end sub postponed
5549
5550 =head2 C<dumpit>
5551
5552 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5553
5554 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5555 a reference to a variable (the thing to be dumped) as its input.
5556
5557 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5558 the currently-selected filehandle, thank you very much). The current
5559 values of the package globals C<$single> and C<$trace> are backed up in
5560 lexicals, and they are turned off (this keeps the debugger from trying
5561 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5562 preserve its current value and it is set to zero to prevent entry/exit
5563 messages from printing, and C<$doret> is localized as well and set to -2 to
5564 prevent return values from being shown.
5565
5566 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5567 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5568 installed version in C<@INC>, yours will be used instead. Possible security
5569 problem?).
5570
5571 It then checks to see if the subroutine C<main::dumpValue> is now defined
5572 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5573 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5574 is called, and picks up the variable to be dumped from the parameter list.
5575
5576 It checks the package global C<%options> to see if there's a C<dumpDepth>
5577 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5578 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5579 structure: -1 means dump everything.
5580
5581 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5582 warning.
5583
5584 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5585 and we then return to the caller.
5586
5587 =cut
5588
5589 sub dumpit {
5590
5591     # Save the current output filehandle and switch to the one
5592     # passed in as the first parameter.
5593     local ($savout) = select(shift);
5594
5595     # Save current settings of $single and $trace, and then turn them off.
5596     my $osingle = $single;
5597     my $otrace  = $trace;
5598     $single = $trace = 0;
5599
5600     # XXX Okay, what do $frame and $doret do, again?
5601     local $frame = 0;
5602     local $doret = -2;
5603
5604     # Load dumpvar.pl unless we've already got the sub we need from it.
5605     unless ( defined &main::dumpValue ) {
5606         do 'dumpvar.pl' or die $@;
5607     }
5608
5609     # If the load succeeded (or we already had dumpvalue()), go ahead
5610     # and dump things.
5611     if ( defined &main::dumpValue ) {
5612         local $\ = '';
5613         local $, = '';
5614         local $" = ' ';
5615         my $v = shift;
5616         my $maxdepth = shift || $option{dumpDepth};
5617         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5618         &main::dumpValue( $v, $maxdepth );
5619     } ## end if (defined &main::dumpValue)
5620
5621     # Oops, couldn't load dumpvar.pl.
5622     else {
5623         local $\ = '';
5624         print $OUT "dumpvar.pl not available.\n";
5625     }
5626
5627     # Reset $single and $trace to their old values.
5628     $single = $osingle;
5629     $trace  = $otrace;
5630
5631     # Restore the old filehandle.
5632     select($savout);
5633 } ## end sub dumpit
5634
5635 =head2 C<print_trace>
5636
5637 C<print_trace>'s job is to print a stack trace. It does this via the
5638 C<dump_trace> routine, which actually does all the ferreting-out of the
5639 stack trace data. C<print_trace> takes care of formatting it nicely and
5640 printing it to the proper filehandle.
5641
5642 Parameters:
5643
5644 =over 4
5645
5646 =item *
5647
5648 The filehandle to print to.
5649
5650 =item *
5651
5652 How many frames to skip before starting trace.
5653
5654 =item *
5655
5656 How many frames to print.
5657
5658 =item *
5659
5660 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5661
5662 =back
5663
5664 The original comment below seems to be noting that the traceback may not be
5665 correct if this routine is called in a tied method.
5666
5667 =cut
5668
5669 # Tied method do not create a context, so may get wrong message:
5670
5671 sub print_trace {
5672     local $\ = '';
5673     my $fh = shift;
5674
5675     # If this is going to a slave editor, but we're not the primary
5676     # debugger, reset it first.
5677     resetterm(1)
5678       if $fh        eq $LINEINFO    # slave editor
5679       and $LINEINFO eq $OUT         # normal output
5680       and $term_pid != $$;          # not the primary
5681
5682     # Collect the actual trace information to be formatted.
5683     # This is an array of hashes of subroutine call info.
5684     my @sub = dump_trace( $_[0] + 1, $_[1] );
5685
5686     # Grab the "short report" flag from @_.
5687     my $short = $_[2];              # Print short report, next one for sub name
5688
5689     # Run through the traceback info, format it, and print it.
5690     my $s;
5691     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5692
5693         # Drop out if the user has lost interest and hit control-C.
5694         last if $signal;
5695
5696         # Set the separator so arrys print nice.
5697         local $" = ', ';
5698
5699         # Grab and stringify the arguments if they are there.
5700         my $args =
5701           defined $sub[$i]{args}
5702           ? "(@{ $sub[$i]{args} })"
5703           : '';
5704
5705         # Shorten them up if $maxtrace says they're too long.
5706         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5707           if length $args > $maxtrace;
5708
5709         # Get the file name.
5710         my $file = $sub[$i]{file};
5711
5712         # Put in a filename header if short is off.
5713         $file = $file eq '-e' ? $file : "file `$file'" unless $short;
5714
5715         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5716         $s = $sub[$i]{sub};
5717         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5718
5719         # Short report uses trimmed file and sub names.
5720         if ($short) {
5721             my $sub = @_ >= 4 ? $_[3] : $s;
5722             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5723         } ## end if ($short)
5724
5725         # Non-short report includes full names.
5726         else {
5727             print $fh "$sub[$i]{context} = $s$args"
5728               . " called from $file"
5729               . " line $sub[$i]{line}\n";
5730         }
5731     } ## end for ($i = 0 ; $i <= $#sub...
5732 } ## end sub print_trace
5733
5734 =head2 dump_trace(skip[,count])
5735
5736 Actually collect the traceback information available via C<caller()>. It does
5737 some filtering and cleanup of the data, but mostly it just collects it to
5738 make C<print_trace()>'s job easier.
5739
5740 C<skip> defines the number of stack frames to be skipped, working backwards
5741 from the most current. C<count> determines the total number of frames to
5742 be returned; all of them (well, the first 10^9) are returned if C<count>
5743 is omitted.
5744
5745 This routine returns a list of hashes, from most-recent to least-recent
5746 stack frame. Each has the following keys and values:
5747
5748 =over 4
5749
5750 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5751
5752 =item * C<sub> - subroutine name, or C<eval> information
5753
5754 =item * C<args> - undef, or a reference to an array of arguments
5755
5756 =item * C<file> - the file in which this item was defined (if any)
5757
5758 =item * C<line> - the line on which it was defined
5759
5760 =back
5761
5762 =cut
5763
5764 sub dump_trace {
5765
5766     # How many levels to skip.
5767     my $skip = shift;
5768
5769     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5770     # it's unlikely that we'll have more than a billion stack frames. If you
5771     # do, you've got an awfully big machine...)
5772     my $count = shift || 1e9;
5773
5774     # We increment skip because caller(1) is the first level *back* from
5775     # the current one.  Add $skip to the count of frames so we have a
5776     # simple stop criterion, counting from $skip to $count+$skip.
5777     $skip++;
5778     $count += $skip;
5779
5780     # These variables are used to capture output from caller();
5781     my ( $p, $file, $line, $sub, $h, $context );
5782
5783     my ( $e, $r, @a, @sub, $args );
5784
5785     # XXX Okay... why'd we do that?
5786     my $nothard = not $frame & 8;
5787     local $frame = 0;
5788
5789     # Do not want to trace this.
5790     my $otrace = $trace;
5791     $trace = 0;
5792
5793     # Start out at the skip count.
5794     # If we haven't reached the number of frames requested, and caller() is
5795     # still returning something, stay in the loop. (If we pass the requested
5796     # number of stack frames, or we run out - caller() returns nothing - we
5797     # quit.
5798     # Up the stack frame index to go back one more level each time.
5799     for (
5800         $i = $skip ;
5801         $i < $count
5802         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5803         $i++
5804       )
5805     {
5806
5807         # Go through the arguments and save them for later.
5808         @a = ();
5809         for $arg (@args) {
5810             my $type;
5811             if ( not defined $arg ) {    # undefined parameter
5812                 push @a, "undef";
5813             }
5814
5815             elsif ( $nothard and tied $arg ) {    # tied parameter
5816                 push @a, "tied";
5817             }
5818             elsif ( $nothard and $type = ref $arg ) {    # reference
5819                 push @a, "ref($type)";
5820             }
5821             else {                                       # can be stringified
5822                 local $_ =
5823                   "$arg";    # Safe to stringify now - should not call f().
5824
5825                 # Backslash any single-quotes or backslashes.
5826                 s/([\'\\])/\\$1/g;
5827
5828                 # Single-quote it unless it's a number or a colon-separated
5829                 # name.
5830                 s/(.*)/'$1'/s
5831                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5832
5833                 # Turn high-bit characters into meta-whatever.
5834                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5835
5836                 # Turn control characters into ^-whatever.
5837                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5838
5839                 push( @a, $_ );
5840             } ## end else [ if (not defined $arg)
5841         } ## end for $arg (@args)
5842
5843         # If context is true, this is array (@)context.
5844         # If context is false, this is scalar ($) context.
5845         # If neither, context isn't defined. (This is apparently a 'can't
5846         # happen' trap.)
5847         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5848
5849         # if the sub has args ($h true), make an anonymous array of the
5850         # dumped args.
5851         $args = $h ? [@a] : undef;
5852
5853         # remove trailing newline-whitespace-semicolon-end of line sequence
5854         # from the eval text, if any.
5855         $e =~ s/\n\s*\;\s*\Z// if $e;
5856
5857         # Escape backslashed single-quotes again if necessary.
5858         $e =~ s/([\\\'])/\\$1/g if $e;
5859
5860         # if the require flag is true, the eval text is from a require.
5861         if ($r) {
5862             $sub = "require '$e'";
5863         }
5864
5865         # if it's false, the eval text is really from an eval.
5866         elsif ( defined $r ) {
5867             $sub = "eval '$e'";
5868         }
5869
5870         # If the sub is '(eval)', this is a block eval, meaning we don't
5871         # know what the eval'ed text actually was.
5872         elsif ( $sub eq '(eval)' ) {
5873             $sub = "eval {...}";
5874         }
5875
5876         # Stick the collected information into @sub as an anonymous hash.
5877         push(
5878             @sub,
5879             {
5880                 context => $context,
5881                 sub     => $sub,
5882                 args    => $args,
5883                 file    => $file,
5884                 line    => $line
5885             }
5886         );
5887
5888         # Stop processing frames if the user hit control-C.
5889         last if $signal;
5890     } ## end for ($i = $skip ; $i < ...
5891
5892     # Restore the trace value again.
5893     $trace = $otrace;
5894     @sub;
5895 } ## end sub dump_trace
5896
5897 =head2 C<action()>
5898
5899 C<action()> takes input provided as the argument to an add-action command,
5900 either pre- or post-, and makes sure it's a complete command. It doesn't do
5901 any fancy parsing; it just keeps reading input until it gets a string
5902 without a trailing backslash.
5903
5904 =cut
5905
5906 sub action {
5907     my $action = shift;
5908
5909     while ( $action =~ s/\\$// ) {
5910
5911         # We have a backslash on the end. Read more.
5912         $action .= &gets;
5913     } ## end while ($action =~ s/\\$//)
5914
5915     # Return the assembled action.
5916     $action;
5917 } ## end sub action
5918
5919 =head2 unbalanced
5920
5921 This routine mostly just packages up a regular expression to be used
5922 to check that the thing it's being matched against has properly-matched
5923 curly braces.
5924
5925 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
5926 speeds things up by only creating the qr//'ed expression once; if it's
5927 already defined, we don't try to define it again. A speed hack.
5928
5929 =cut
5930
5931 sub unbalanced {
5932
5933     # I hate using globals!
5934     $balanced_brace_re ||= qr{
5935         ^ \{
5936              (?:
5937                  (?> [^{}] + )              # Non-parens without backtracking
5938                 |
5939                  (??{ $balanced_brace_re }) # Group with matching parens
5940               ) *
5941           \} $
5942    }x;
5943     return $_[0] !~ m/$balanced_brace_re/;
5944 } ## end sub unbalanced
5945
5946 =head2 C<gets()>
5947
5948 C<gets()> is a primitive (very primitive) routine to read continuations.
5949 It was devised for reading continuations for actions.
5950 it just reads more input with C<readline()> and returns it.
5951
5952 =cut
5953
5954 sub gets {
5955     &readline("cont: ");
5956 }
5957
5958 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
5959
5960 The C<system()> function assumes that it can just go ahead and use STDIN and
5961 STDOUT, but under the debugger, we want it to use the debugger's input and
5962 outout filehandles.
5963
5964 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
5965 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
5966 and then puts everything back again.
5967
5968 =cut
5969
5970 sub system {
5971
5972     # We save, change, then restore STDIN and STDOUT to avoid fork() since
5973     # some non-Unix systems can do system() but have problems with fork().
5974     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
5975     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
5976     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
5977     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
5978
5979     # XXX: using csh or tcsh destroys sigint retvals!
5980     system(@_);
5981     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
5982     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
5983     close(SAVEIN);
5984     close(SAVEOUT);
5985
5986     # most of the $? crud was coping with broken cshisms
5987     if ( $? >> 8 ) {
5988         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
5989     }
5990     elsif ($?) {
5991         &warn(
5992             "(Command died of SIG#",
5993             ( $? & 127 ),
5994             ( ( $? & 128 ) ? " -- core dumped" : "" ),
5995             ")", "\n"
5996         );
5997     } ## end elsif ($?)
5998
5999     return $?;
6000
6001 } ## end sub system
6002
6003 =head1 TTY MANAGEMENT
6004
6005 The subs here do some of the terminal management for multiple debuggers.
6006
6007 =head2 setterm
6008
6009 Top-level function called when we want to set up a new terminal for use
6010 by the debugger.
6011
6012 If the C<noTTY> debugger option was set, we'll either use the terminal
6013 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6014 to find one. If we're a forked debugger, we call C<resetterm> to try to
6015 get a whole new terminal if we can.
6016
6017 In either case, we set up the terminal next. If the C<ReadLine> option was
6018 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6019 the appropriate attributes. We then
6020
6021 =cut
6022
6023 sub setterm {
6024
6025     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6026     local $frame = 0;
6027     local $doret = -2;
6028     eval { require Term::ReadLine } or die $@;
6029
6030     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6031     if ($notty) {
6032         if ($tty) {
6033             my ( $i, $o ) = split $tty, /,/;
6034             $o = $i unless defined $o;
6035             open( IN,  "<$i" ) or die "Cannot open TTY `$i' for read: $!";
6036             open( OUT, ">$o" ) or die "Cannot open TTY `$o' for write: $!";
6037             $IN  = \*IN;
6038             $OUT = \*OUT;
6039             my $sel = select($OUT);
6040             $| = 1;
6041             select($sel);
6042         } ## end if ($tty)
6043
6044         # We don't have a TTY - try to find one via Term::Rendezvous.
6045         else {
6046             eval "require Term::Rendezvous;" or die;
6047
6048             # See if we have anything to pass to Term::Rendezvous.
6049             # Use $HOME/.perldbtty$$ if not.
6050             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6051
6052             # Rendezvous and get the filehandles.
6053             my $term_rv = new Term::Rendezvous $rv;
6054             $IN  = $term_rv->IN;
6055             $OUT = $term_rv->OUT;
6056         } ## end else [ if ($tty)
6057     } ## end if ($notty)
6058
6059     # We're a daughter debugger. Try to fork off another TTY.
6060     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6061         resetterm(2);
6062     }
6063
6064     # If we shouldn't use Term::ReadLine, don't.
6065     if ( !$rl ) {
6066         $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6067     }
6068
6069     # We're using Term::ReadLine. Get all the attributes for this terminal.
6070     else {
6071         $term = new Term::ReadLine 'perldb', $IN, $OUT;
6072
6073         $rl_attribs = $term->Attribs;
6074         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6075           if defined $rl_attribs->{basic_word_break_characters}
6076           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6077         $rl_attribs->{special_prefixes} = '$@&%';
6078         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6079         $rl_attribs->{completion_function} = \&db_complete;
6080     } ## end else [ if (!$rl)
6081
6082     # Set up the LINEINFO filehandle.
6083     $LINEINFO = $OUT     unless defined $LINEINFO;
6084     $lineinfo = $console unless defined $lineinfo;
6085
6086     $term->MinLine(2);
6087
6088     &load_hist();
6089
6090     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6091         $term->SetHistory(@hist);
6092     }
6093
6094     # XXX Ornaments are turned on unconditionally, which is not
6095     # always a good thing.
6096     ornaments($ornaments) if defined $ornaments;
6097     $term_pid = $$;
6098 } ## end sub setterm
6099
6100 sub load_hist {
6101     $histfile //= option_val("HistFile", undef);
6102     return unless defined $histfile;
6103     open my $fh, "<", $histfile or return;
6104     local $/ = "\n";
6105     @hist = ();
6106     while (<$fh>) {
6107         chomp;
6108         push @hist, $_;
6109     }
6110     close $fh;
6111 }
6112
6113 sub save_hist {
6114     return unless defined $histfile;
6115     eval { require File::Path } or return;
6116     eval { require File::Basename } or return;
6117     File::Path::mkpath(File::Basename::dirname($histfile));
6118     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6119     $histsize //= option_val("HistSize",100);
6120     my @copy = grep { $_ ne '?' } @hist;
6121     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6122     for ($start .. $#copy) {
6123         print $fh "$copy[$_]\n";
6124     }
6125     close $fh or die "Could not write '$histfile': $!";
6126 }
6127
6128 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6129
6130 When the process being debugged forks, or the process invokes a command
6131 via C<system()> which starts a new debugger, we need to be able to get a new
6132 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6133 fight over the terminal, and you can never quite be sure who's going to get the
6134 input you're typing.
6135
6136 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6137 is tasked with doing all the necessary operating system mojo to get a new
6138 TTY (and probably another window) and to direct the new debugger to read and
6139 write there.
6140
6141 The debugger provides C<get_fork_TTY> functions which work for X Windows,
6142 OS/2, and Mac OS X. Other systems are not supported. You are encouraged
6143 to write C<get_fork_TTY> functions which work for I<your> platform
6144 and contribute them.
6145
6146 =head3 C<xterm_get_fork_TTY>
6147
6148 This function provides the C<get_fork_TTY> function for X windows. If a
6149 program running under the debugger forks, a new <xterm> window is opened and
6150 the subsidiary debugger is directed there.
6151
6152 The C<open()> call is of particular note here. We have the new C<xterm>
6153 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6154 command (which prints the device name of the TTY we'll want to use for input
6155 and output to STDOUT, then C<sleep> for a very long time, routing this output
6156 to file number 3. This way we can simply read from the <XT> filehandle (which
6157 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6158
6159 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6160 properly set up.
6161
6162 =cut
6163
6164 sub xterm_get_fork_TTY {
6165     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6166     open XT,
6167 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6168  sleep 10000000' |];
6169
6170     # Get the output from 'tty' and clean it up a little.
6171     my $tty = <XT>;
6172     chomp $tty;
6173
6174     $pidprompt = '';    # Shown anyway in titlebar
6175
6176     # We need $term defined or we can not switch to the newly created xterm
6177     if ($tty ne '' && !defined $term) {
6178         eval { require Term::ReadLine } or die $@;
6179         if ( !$rl ) {
6180             $term = new Term::ReadLine::Stub 'perldb', $IN, $OUT;
6181         }
6182         else {
6183             $term = new Term::ReadLine 'perldb', $IN, $OUT;
6184         }
6185     }
6186     # There's our new TTY.
6187     return $tty;
6188 } ## end sub xterm_get_fork_TTY
6189
6190 =head3 C<os2_get_fork_TTY>
6191
6192 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6193
6194 =cut
6195
6196 # This example function resets $IN, $OUT itself
6197 my $c_pipe = 0;
6198 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6199     local $\  = '';
6200     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6201     my %opt = ( title => "Daughter Perl debugger $pids $name",
6202                 ($rl ? (read_by_key => 1) : ()) );
6203     require OS2::Process;
6204     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6205       or return;
6206     $pidprompt = '';    # Shown anyway in titlebar
6207     reset_IN_OUT($in, $out);
6208     $tty = '*reset*';
6209     return '';          # Indicate that reset_IN_OUT is called
6210 } ## end sub os2_get_fork_TTY
6211
6212 =head3 C<macosx_get_fork_TTY>
6213
6214 The Mac OS X version uses AppleScript to tell Terminal.app to create
6215 a new window.
6216
6217 =cut
6218
6219 # Notes about Terminal.app's AppleScript support,
6220 # (aka things that might break in future OS versions).
6221 #
6222 # The "do script" command doesn't return a reference to the new window
6223 # it creates, but since it appears frontmost and windows are enumerated
6224 # front to back, we can use "first window" === "window 1".
6225 #
6226 # Since "do script" is implemented by supplying the argument (plus a
6227 # return character) as terminal input, there's a potential race condition
6228 # where the debugger could beat the shell to reading the command.
6229 # To prevent this, we wait for the screen to clear before proceeding.
6230 #
6231 # 10.3 and 10.4:
6232 # There's no direct accessor for the tty device name, so we fiddle
6233 # with the window title options until it says what we want.
6234 #
6235 # 10.5:
6236 # There _is_ a direct accessor for the tty device name, _and_ there's
6237 # a new possible component of the window title (the name of the settings
6238 # set).  A separate version is needed.
6239
6240 my @script_versions=
6241
6242     ([237, <<'__LEOPARD__'],
6243 tell application "Terminal"
6244     do script "clear;exec sleep 100000"
6245     tell first tab of first window
6246         copy tty to thetty
6247         set custom title to "forked perl debugger"
6248         set title displays custom title to true
6249         repeat while (length of first paragraph of (get contents)) > 0
6250             delay 0.1
6251         end repeat
6252     end tell
6253 end tell
6254 thetty
6255 __LEOPARD__
6256
6257      [100, <<'__JAGUAR_TIGER__'],
6258 tell application "Terminal"
6259     do script "clear;exec sleep 100000"
6260     tell first window
6261         set title displays shell path to false
6262         set title displays window size to false
6263         set title displays file name to false
6264         set title displays device name to true
6265         set title displays custom title to true
6266         set custom title to ""
6267         copy "/dev/" & name to thetty
6268         set custom title to "forked perl debugger"
6269         repeat while (length of first paragraph of (get contents)) > 0
6270             delay 0.1
6271         end repeat
6272     end tell
6273 end tell
6274 thetty
6275 __JAGUAR_TIGER__
6276
6277 );
6278
6279 sub macosx_get_fork_TTY
6280 {
6281     my($version,$script,$pipe,$tty);
6282
6283     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6284     foreach my $entry (@script_versions) {
6285         if ($version>=$entry->[0]) {
6286             $script=$entry->[1];
6287             last;
6288         }
6289     }
6290     return unless defined($script);
6291     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6292     $tty=readline($pipe);
6293     close($pipe);
6294     return unless defined($tty) && $tty =~ m(^/dev/);
6295     chomp $tty;
6296     return $tty;
6297 }
6298
6299 =head2 C<create_IN_OUT($flags)>
6300
6301 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6302 try to diagnose why.
6303
6304 Flags are:
6305
6306 =over 4
6307
6308 =item * 1 - Don't know how to create a new TTY.
6309
6310 =item * 2 - Debugger has forked, but we can't get a new TTY.
6311
6312 =item * 4 - standard debugger startup is happening.
6313
6314 =back
6315
6316 =cut
6317
6318 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6319
6320     # If we know how to get a new TTY, do it! $in will have
6321     # the TTY name if get_fork_TTY works.
6322     my $in = &get_fork_TTY if defined &get_fork_TTY;
6323
6324     # It used to be that
6325     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6326
6327     if ( not defined $in ) {
6328         my $why = shift;
6329
6330         # We don't know how.
6331         print_help(<<EOP) if $why == 1;
6332 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6333 EOP
6334
6335         # Forked debugger.
6336         print_help(<<EOP) if $why == 2;
6337 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6338   This may be an asynchronous session, so the parent debugger may be active.
6339 EOP
6340
6341         # Note that both debuggers are fighting over the same input.
6342         print_help(<<EOP) if $why != 4;
6343   Since two debuggers fight for the same TTY, input is severely entangled.
6344
6345 EOP
6346         print_help(<<EOP);
6347   I know how to switch the output to a different window in xterms, OS/2
6348   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6349   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6350   B<DB::get_fork_TTY()> returning this.
6351
6352   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6353   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6354
6355 EOP
6356     } ## end if (not defined $in)
6357     elsif ( $in ne '' ) {
6358         TTY($in);
6359     }
6360     else {
6361         $console = '';    # Indicate no need to open-from-the-console
6362     }
6363     undef $fork_TTY;
6364 } ## end sub create_IN_OUT
6365
6366 =head2 C<resetterm>
6367
6368 Handles rejiggering the prompt when we've forked off a new debugger.
6369
6370 If the new debugger happened because of a C<system()> that invoked a
6371 program under the debugger, the arrow between the old pid and the new
6372 in the prompt has I<two> dashes instead of one.
6373
6374 We take the current list of pids and add this one to the end. If there
6375 isn't any list yet, we make one up out of the initial pid associated with
6376 the terminal and our new pid, sticking an arrow (either one-dashed or
6377 two dashed) in between them.
6378
6379 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6380 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6381 and try to do that.
6382
6383 =cut
6384
6385 sub resetterm {    # We forked, so we need a different TTY
6386
6387     # Needs to be passed to create_IN_OUT() as well.
6388     my $in = shift;
6389
6390     # resetterm(2): got in here because of a system() starting a debugger.
6391     # resetterm(1): just forked.
6392     my $systemed = $in > 1 ? '-' : '';
6393
6394     # If there's already a list of pids, add this to the end.
6395     if ($pids) {
6396         $pids =~ s/\]/$systemed->$$]/;
6397     }
6398
6399     # No pid list. Time to make one.
6400     else {
6401         $pids = "[$term_pid->$$]";
6402     }
6403
6404     # The prompt we're going to be using for this debugger.
6405     $pidprompt = $pids;
6406
6407     # We now 0wnz this terminal.
6408     $term_pid = $$;
6409
6410     # Just return if we're not supposed to try to create a new TTY.
6411     return unless $CreateTTY & $in;
6412
6413     # Try to create a new IN/OUT pair.
6414     create_IN_OUT($in);
6415 } ## end sub resetterm
6416
6417 =head2 C<readline>
6418
6419 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6420 the next line, print a message saying we got it, add it to the terminal
6421 history (if possible), and return it.
6422
6423 If there's nothing in the typeahead buffer, check the command filehandle stack.
6424 If there are any filehandles there, read from the last one, and return the line
6425 if we got one. If not, we pop the filehandle off and close it, and try the
6426 next one up the stack.
6427
6428 If we've emptied the filehandle stack, we check to see if we've got a socket
6429 open, and we read that and return it if we do. If we don't, we just call the
6430 core C<readline()> and return its value.
6431
6432 =cut
6433
6434 sub readline {
6435
6436     # Localize to prevent it from being smashed in the program being debugged.
6437     local $.;
6438
6439     # Pull a line out of the typeahead if there's stuff there.
6440     if (@typeahead) {
6441
6442         # How many lines left.
6443         my $left = @typeahead;
6444
6445         # Get the next line.
6446         my $got = shift @typeahead;
6447
6448         # Print a message saying we got input from the typeahead.
6449         local $\ = '';
6450         print $OUT "auto(-$left)", shift, $got, "\n";
6451
6452         # Add it to the terminal history (if possible).
6453         $term->AddHistory($got)
6454           if length($got) > 1
6455           and defined $term->Features->{addHistory};
6456         return $got;
6457     } ## end if (@typeahead)
6458
6459     # We really need to read some input. Turn off entry/exit trace and
6460     # return value printing.
6461     local $frame = 0;
6462     local $doret = -2;
6463
6464     # If there are stacked filehandles to read from ...
6465     while (@cmdfhs) {
6466
6467         # Read from the last one in the stack.
6468         my $line = CORE::readline( $cmdfhs[-1] );
6469
6470         # If we got a line ...
6471         defined $line
6472           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6473           : close pop @cmdfhs;                            # Pop and close
6474     } ## end while (@cmdfhs)
6475
6476     # Nothing on the filehandle stack. Socket?
6477     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6478
6479         # Send anyting we have to send.
6480         $OUT->write( join( '', @_ ) );
6481
6482         # Receive anything there is to receive.
6483         $stuff;
6484         my $stuff = '';
6485         my $buf;
6486         do {
6487             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6488                                             # XXX Don't know. You tell me.
6489         } while length $buf and ($stuff .= $buf) !~ /\n/;
6490
6491         # What we got.
6492         $stuff;
6493     } ## end if (ref $OUT and UNIVERSAL::isa...
6494
6495     # No socket. Just read from the terminal.
6496     else {
6497         $term->readline(@_);
6498     }
6499 } ## end sub readline
6500
6501 =head1 OPTIONS SUPPORT ROUTINES
6502
6503 These routines handle listing and setting option values.
6504
6505 =head2 C<dump_option> - list the current value of an option setting
6506
6507 This routine uses C<option_val> to look up the value for an option.
6508 It cleans up escaped single-quotes and then displays the option and
6509 its value.
6510
6511 =cut
6512
6513 sub dump_option {
6514     my ( $opt, $val ) = @_;
6515     $val = option_val( $opt, 'N/A' );
6516     $val =~ s/([\\\'])/\\$1/g;
6517     printf $OUT "%20s = '%s'\n", $opt, $val;
6518 } ## end sub dump_option
6519
6520 sub options2remember {
6521     foreach my $k (@RememberOnROptions) {
6522         $option{$k} = option_val( $k, 'N/A' );
6523     }
6524     return %option;
6525 }
6526
6527 =head2 C<option_val> - find the current value of an option
6528
6529 This can't just be a simple hash lookup because of the indirect way that
6530 the option values are stored. Some are retrieved by calling a subroutine,
6531 some are just variables.
6532
6533 You must supply a default value to be used in case the option isn't set.
6534
6535 =cut
6536
6537 sub option_val {
6538     my ( $opt, $default ) = @_;
6539     my $val;
6540
6541     # Does this option exist, and is it a variable?
6542     # If so, retrieve the value via the value in %optionVars.
6543     if (    defined $optionVars{$opt}
6544         and defined ${ $optionVars{$opt} } )
6545     {
6546         $val = ${ $optionVars{$opt} };
6547     }
6548
6549     # Does this option exist, and it's a subroutine?
6550     # If so, call the subroutine via the ref in %optionAction
6551     # and capture the value.
6552     elsif ( defined $optionAction{$opt}
6553         and defined &{ $optionAction{$opt} } )
6554     {
6555         $val = &{ $optionAction{$opt} }();
6556     }
6557
6558     # If there's an action or variable for the supplied option,
6559     # but no value was set, use the default.
6560     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6561         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6562     {
6563         $val = $default;
6564     }
6565
6566     # Otherwise, do the simple hash lookup.
6567     else {
6568         $val = $option{$opt};
6569     }
6570
6571     # If the value isn't defined, use the default.
6572     # Then return whatever the value is.
6573     $val = $default unless defined $val;
6574     $val;
6575 } ## end sub option_val
6576
6577 =head2 C<parse_options>
6578
6579 Handles the parsing and execution of option setting/displaying commands.
6580
6581 An option entered by itself is assumed to be I<set me to 1> (the default value)
6582 if the option is a boolean one. If not, the user is prompted to enter a valid
6583 value or to query the current value (via C<option? >).
6584
6585 If C<option=value> is entered, we try to extract a quoted string from the
6586 value (if it is quoted). If it's not, we just use the whole value as-is.
6587
6588 We load any modules required to service this option, and then we set it: if
6589 it just gets stuck in a variable, we do that; if there's a subroutine to
6590 handle setting the option, we call that.
6591
6592 Finally, if we're running in interactive mode, we display the effect of the
6593 user's command back to the terminal, skipping this if we're setting things
6594 during initialization.
6595
6596 =cut
6597
6598 sub parse_options {
6599     local ($_) = @_;
6600     local $\ = '';
6601
6602     # These options need a value. Don't allow them to be clobbered by accident.
6603     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6604       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6605       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6606     };
6607
6608     while (length) {
6609         my $val_defaulted;
6610
6611         # Clean off excess leading whitespace.
6612         s/^\s+// && next;
6613
6614         # Options are always all word characters, followed by a non-word
6615         # separator.
6616         s/^(\w+)(\W?)// or print( $OUT "Invalid option `$_'\n" ), last;
6617         my ( $opt, $sep ) = ( $1, $2 );
6618
6619         # Make sure that such an option exists.
6620         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6621           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6622
6623         print( $OUT "Unknown option `$opt'\n" ), next unless $matches;
6624         print( $OUT "Ambiguous option `$opt'\n" ), next if $matches > 1;
6625         my $val;
6626
6627         # '?' as separator means query, but must have whitespace after it.
6628         if ( "?" eq $sep ) {
6629             print( $OUT "Option query `$opt?' followed by non-space `$_'\n" ),
6630               last
6631               if /^\S/;
6632
6633             #&dump_option($opt);
6634         } ## end if ("?" eq $sep)
6635
6636         # Separator is whitespace (or just a carriage return).
6637         # They're going for a default, which we assume is 1.
6638         elsif ( $sep !~ /\S/ ) {
6639             $val_defaulted = 1;
6640             $val           = "1";   #  this is an evil default; make 'em set it!
6641         }
6642
6643         # Separator is =. Trying to set a value.
6644         elsif ( $sep eq "=" ) {
6645
6646             # If quoted, extract a quoted string.
6647             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6648                 my $quote = $1;
6649                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6650             }
6651
6652             # Not quoted. Use the whole thing. Warn about 'option='.
6653             else {
6654                 s/^(\S*)//;
6655                 $val = $1;
6656                 print OUT qq(Option better cleared using $opt=""\n)
6657                   unless length $val;
6658             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6659
6660         } ## end elsif ($sep eq "=")
6661
6662         # "Quoted" with [], <>, or {}.
6663         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6664             my ($end) =
6665               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6666             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6667               or print( $OUT "Unclosed option value `$opt$sep$_'\n" ), last;
6668             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6669         } ## end else [ if ("?" eq $sep)
6670
6671         # Exclude non-booleans from getting set to 1 by default.
6672         if ( $opt_needs_val{$option} && $val_defaulted ) {
6673             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6674             print $OUT
6675 "Option `$opt' is non-boolean.  Use `$cmd $option=VAL' to set, `$cmd $option?' to query\n";
6676             next;
6677         } ## end if ($opt_needs_val{$option...
6678
6679         # Save the option value.
6680         $option{$option} = $val if defined $val;
6681
6682         # Load any module that this option requires.
6683         eval qq{
6684                 local \$frame = 0;
6685                 local \$doret = -2;
6686                 require '$optionRequire{$option}';
6687                 1;
6688                } || die    # XXX: shouldn't happen
6689           if defined $optionRequire{$option}
6690           && defined $val;
6691
6692         # Set it.
6693         # Stick it in the proper variable if it goes in a variable.
6694         ${ $optionVars{$option} } = $val
6695           if defined $optionVars{$option}
6696           && defined $val;
6697
6698         # Call the appropriate sub if it gets set via sub.
6699         &{ $optionAction{$option} }($val)
6700           if defined $optionAction{$option}
6701           && defined &{ $optionAction{$option} }
6702           && defined $val;
6703
6704         # Not initialization - echo the value we set it to.
6705         dump_option($option) unless $OUT eq \*STDERR;
6706     } ## end while (length)
6707 } ## end sub parse_options
6708
6709 =head1 RESTART SUPPORT
6710
6711 These routines are used to store (and restore) lists of items in environment
6712 variables during a restart.
6713
6714 =head2 set_list
6715
6716 Set_list packages up items to be stored in a set of environment variables
6717 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6718 the values). Values outside the standard ASCII charset are stored by encoding
6719 then as hexadecimal values.
6720
6721 =cut
6722
6723 sub set_list {
6724     my ( $stem, @list ) = @_;
6725     my $val;
6726
6727     # VAR_n: how many we have. Scalar assignment gets the number of items.
6728     $ENV{"${stem}_n"} = @list;
6729
6730     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6731     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6732     for $i ( 0 .. $#list ) {
6733         $val = $list[$i];
6734         $val =~ s/\\/\\\\/g;
6735         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6736         $ENV{"${stem}_$i"} = $val;
6737     } ## end for $i (0 .. $#list)
6738 } ## end sub set_list
6739
6740 =head2 get_list
6741
6742 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6743 back, and then pull VAR_0, VAR_1. etc. back out.
6744
6745 =cut
6746
6747 sub get_list {
6748     my $stem = shift;
6749     my @list;
6750     my $n = delete $ENV{"${stem}_n"};
6751     my $val;
6752     for $i ( 0 .. $n - 1 ) {
6753         $val = delete $ENV{"${stem}_$i"};
6754         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6755         push @list, $val;
6756     }
6757     @list;
6758 } ## end sub get_list
6759
6760 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6761
6762 =head2 catch()
6763
6764 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6765 set an already-existing global scalar variable to a constant value. This
6766 avoids allocating any memory possibly in the middle of something that will
6767 get all confused if we do, particularly under I<unsafe signals>.
6768
6769 =cut
6770
6771 sub catch {
6772     $signal = 1;
6773     return;    # Put nothing on the stack - malloc/free land!
6774 }
6775
6776 =head2 C<warn()>
6777
6778 C<warn> emits a warning, by joining together its arguments and printing
6779 them, with couple of fillips.
6780
6781 If the composited message I<doesn't> end with a newline, we automatically
6782 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6783 to be set to the filehandle to be used to output warnings; it makes no
6784 assumptions about what filehandles are available.
6785
6786 =cut
6787
6788 sub warn {
6789     my ($msg) = join( "", @_ );
6790     $msg .= ": $!\n" unless $msg =~ /\n$/;
6791     local $\ = '';
6792     print $OUT $msg;
6793 } ## end sub warn
6794
6795 =head1 INITIALIZATION TTY SUPPORT
6796
6797 =head2 C<reset_IN_OUT>
6798
6799 This routine handles restoring the debugger's input and output filehandles
6800 after we've tried and failed to move them elsewhere.  In addition, it assigns
6801 the debugger's output filehandle to $LINEINFO if it was already open there.
6802
6803 =cut
6804
6805 sub reset_IN_OUT {
6806     my $switch_li = $LINEINFO eq $OUT;
6807
6808     # If there's a term and it's able to get a new tty, try to get one.
6809     if ( $term and $term->Features->{newTTY} ) {
6810         ( $IN, $OUT ) = ( shift, shift );
6811         $term->newTTY( $IN, $OUT );
6812     }
6813
6814     # This term can't get a new tty now. Better luck later.
6815     elsif ($term) {
6816         &warn("Too late to set IN/OUT filehandles, enabled on next `R'!\n");
6817     }
6818
6819     # Set the filehndles up as they were.
6820     else {
6821         ( $IN, $OUT ) = ( shift, shift );
6822     }
6823
6824     # Unbuffer the output filehandle.
6825     my $o = select $OUT;
6826     $| = 1;
6827     select $o;
6828
6829     # Point LINEINFO to the same output filehandle if it was there before.
6830     $LINEINFO = $OUT if $switch_li;
6831 } ## end sub reset_IN_OUT
6832
6833 =head1 OPTION SUPPORT ROUTINES
6834
6835 The following routines are used to process some of the more complicated
6836 debugger options.
6837
6838 =head2 C<TTY>
6839
6840 Sets the input and output filehandles to the specified files or pipes.
6841 If the terminal supports switching, we go ahead and do it. If not, and
6842 there's already a terminal in place, we save the information to take effect
6843 on restart.
6844
6845 If there's no terminal yet (for instance, during debugger initialization),
6846 we go ahead and set C<$console> and C<$tty> to the file indicated.
6847
6848 =cut
6849
6850 sub TTY {
6851
6852     if ( @_ and $term and $term->Features->{newTTY} ) {
6853
6854         # This terminal supports switching to a new TTY.
6855         # Can be a list of two files, or on string containing both names,
6856         # comma-separated.
6857         # XXX Should this perhaps be an assignment from @_?
6858         my ( $in, $out ) = shift;
6859         if ( $in =~ /,/ ) {
6860
6861             # Split list apart if supplied.
6862             ( $in, $out ) = split /,/, $in, 2;
6863         }
6864         else {
6865
6866             # Use the same file for both input and output.
6867             $out = $in;
6868         }
6869
6870         # Open file onto the debugger's filehandles, if you can.
6871         open IN,  $in     or die "cannot open `$in' for read: $!";
6872         open OUT, ">$out" or die "cannot open `$out' for write: $!";
6873
6874         # Swap to the new filehandles.
6875         reset_IN_OUT( \*IN, \*OUT );
6876
6877         # Save the setting for later.
6878         return $tty = $in;
6879     } ## end if (@_ and $term and $term...
6880
6881     # Terminal doesn't support new TTY, or doesn't support readline.
6882     # Can't do it now, try restarting.
6883     &warn("Too late to set TTY, enabled on next `R'!\n") if $term and @_;
6884
6885     # Useful if done through PERLDB_OPTS:
6886     $console = $tty = shift if @_;
6887
6888     # Return whatever the TTY is.
6889     $tty or $console;
6890 } ## end sub TTY
6891
6892 =head2 C<noTTY>
6893
6894 Sets the C<$notty> global, controlling whether or not the debugger tries to
6895 get a terminal to read from. If called after a terminal is already in place,
6896 we save the value to use it if we're restarted.
6897
6898 =cut
6899
6900 sub noTTY {
6901     if ($term) {
6902         &warn("Too late to set noTTY, enabled on next `R'!\n") if @_;
6903     }
6904     $notty = shift if @_;
6905     $notty;
6906 } ## end sub noTTY
6907
6908 =head2 C<ReadLine>
6909
6910 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
6911 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
6912 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
6913 the value in case a restart is done so we can change it then.
6914
6915 =cut
6916
6917 sub ReadLine {
6918     if ($term) {
6919         &warn("Too late to set ReadLine, enabled on next `R'!\n") if @_;
6920     }
6921     $rl = shift if @_;
6922     $rl;
6923 } ## end sub ReadLine
6924
6925 =head2 C<RemotePort>
6926
6927 Sets the port that the debugger will try to connect to when starting up.
6928 If the terminal's already been set up, we can't do it, but we remember the
6929 setting in case the user does a restart.
6930
6931 =cut
6932
6933 sub RemotePort {
6934     if ($term) {
6935         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
6936     }
6937     $remoteport = shift if @_;
6938     $remoteport;
6939 } ## end sub RemotePort
6940
6941 =head2 C<tkRunning>
6942
6943 Checks with the terminal to see if C<Tk> is running, and returns true or
6944 false. Returns false if the current terminal doesn't support C<readline>.
6945
6946 =cut
6947
6948 sub tkRunning {
6949     if ( ${ $term->Features }{tkRunning} ) {
6950         return $term->tkRunning(@_);
6951     }
6952     else {
6953         local $\ = '';
6954         print $OUT "tkRunning not supported by current ReadLine package.\n";
6955         0;
6956     }
6957 } ## end sub tkRunning
6958
6959 =head2 C<NonStop>
6960
6961 Sets nonstop mode. If a terminal's already been set up, it's too late; the
6962 debugger remembers the setting in case you restart, though.
6963
6964 =cut
6965
6966 sub NonStop {
6967     if ($term) {
6968         &warn("Too late to set up NonStop mode, enabled on next `R'!\n")
6969           if @_;
6970     }
6971     $runnonstop = shift if @_;
6972     $runnonstop;
6973 } ## end sub NonStop
6974
6975 sub DollarCaretP {
6976     if ($term) {
6977         &warn("Some flag changes could not take effect until next 'R'!\n")
6978           if @_;
6979     }
6980     $^P = parse_DollarCaretP_flags(shift) if @_;
6981     expand_DollarCaretP_flags($^P);
6982 }
6983
6984 =head2 C<pager>
6985
6986 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
6987 there already.
6988
6989 =cut
6990
6991 sub pager {
6992     if (@_) {
6993         $pager = shift;
6994         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
6995     }
6996     $pager;
6997 } ## end sub pager
6998
6999 =head2 C<shellBang>
7000
7001 Sets the shell escape command, and generates a printable copy to be used
7002 in the help.
7003
7004 =cut
7005
7006 sub shellBang {
7007
7008     # If we got an argument, meta-quote it, and add '\b' if it
7009     # ends in a word character.
7010     if (@_) {
7011         $sh = quotemeta shift;
7012         $sh .= "\\b" if $sh =~ /\w$/;
7013     }
7014
7015     # Generate the printable version for the help:
7016     $psh = $sh;    # copy it
7017     $psh =~ s/\\b$//;        # Take off trailing \b if any
7018     $psh =~ s/\\(.)/$1/g;    # De-escape
7019     $psh;                    # return the printable version
7020 } ## end sub shellBang
7021
7022 =head2 C<ornaments>
7023
7024 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7025 was passed as the argument. (This means you can't override the terminal's
7026 ornaments.)
7027
7028 =cut
7029
7030 sub ornaments {
7031     if ( defined $term ) {
7032
7033         # We don't want to show warning backtraces, but we do want die() ones.
7034         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7035
7036         # No ornaments if the terminal doesn't support them.
7037         return '' unless $term->Features->{ornaments};
7038         eval { $term->ornaments(@_) } || '';
7039     }
7040
7041     # Use what was passed in if we can't determine it ourselves.
7042     else {
7043         $ornaments = shift;
7044     }
7045 } ## end sub ornaments
7046
7047 =head2 C<recallCommand>
7048
7049 Sets the recall command, and builds a printable version which will appear in
7050 the help text.
7051
7052 =cut
7053
7054 sub recallCommand {
7055
7056     # If there is input, metaquote it. Add '\b' if it ends with a word
7057     # character.
7058     if (@_) {
7059         $rc = quotemeta shift;
7060         $rc .= "\\b" if $rc =~ /\w$/;
7061     }
7062
7063     # Build it into a printable version.
7064     $prc = $rc;    # Copy it
7065     $prc =~ s/\\b$//;        # Remove trailing \b
7066     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7067     $prc;                    # Return the printable version
7068 } ## end sub recallCommand
7069
7070 =head2 C<LineInfo> - where the line number information goes
7071
7072 Called with no arguments, returns the file or pipe that line info should go to.
7073
7074 Called with an argument (a file or a pipe), it opens that onto the
7075 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7076 file or pipe again to the caller.
7077
7078 =cut
7079
7080 sub LineInfo {
7081     return $lineinfo unless @_;
7082     $lineinfo = shift;
7083
7084     #  If this is a valid "thing to be opened for output", tack a
7085     # '>' onto the front.
7086     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7087
7088     # If this is a pipe, the stream points to a slave editor.
7089     $slave_editor = ( $stream =~ /^\|/ );
7090
7091     # Open it up and unbuffer it.
7092     open( LINEINFO, "$stream" ) || &warn("Cannot open `$stream' for write");
7093     $LINEINFO = \*LINEINFO;
7094     my $save = select($LINEINFO);
7095     $| = 1;
7096     select($save);
7097
7098     # Hand the file or pipe back again.
7099     $lineinfo;
7100 } ## end sub LineInfo
7101
7102 =head1 COMMAND SUPPORT ROUTINES
7103
7104 These subroutines provide functionality for various commands.
7105
7106 =head2 C<list_modules>
7107
7108 For the C<M> command: list modules loaded and their versions.
7109 Essentially just runs through the keys in %INC, picks each package's
7110 C<$VERSION> variable, gets the file name, and formats the information
7111 for output.
7112
7113 =cut
7114
7115 sub list_modules {    # versions
7116     my %version;
7117     my $file;
7118
7119     # keys are the "as-loaded" name, values are the fully-qualified path
7120     # to the file itself.
7121     for ( keys %INC ) {
7122         $file = $_;                                # get the module name
7123         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7124         s,/,::,g;                                  # change '/' to '::'
7125         s/^perl5db$/DB/;                           # Special case: debugger
7126                                                    # moves to package DB
7127         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7128
7129         # If the package has a $VERSION package global (as all good packages
7130         # should!) decode it and save as partial message.
7131         if ( defined ${ $_ . '::VERSION' } ) {
7132             $version{$file} = "${ $_ . '::VERSION' } from ";
7133         }
7134
7135         # Finish up the message with the file the package came from.
7136         $version{$file} .= $INC{$file};
7137     } ## end for (keys %INC)
7138
7139     # Hey, dumpit() formats a hash nicely, so why not use it?
7140     dumpit( $OUT, \%version );
7141 } ## end sub list_modules
7142
7143 =head2 C<sethelp()>
7144
7145 Sets up the monster string used to format and print the help.
7146
7147 =head3 HELP MESSAGE FORMAT
7148
7149 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7150 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7151 easy to parse and portable, but which still allows the help to be a little
7152 nicer than just plain text.
7153
7154 Essentially, you define the command name (usually marked up with C<< B<> >>
7155 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7156 newline. The descriptive text can also be marked up in the same way. If you
7157 need to continue the descriptive text to another line, start that line with
7158 just tabs and then enter the marked-up text.
7159
7160 If you are modifying the help text, I<be careful>. The help-string parser is
7161 not very sophisticated, and if you don't follow these rules it will mangle the
7162 help beyond hope until you fix the string.
7163
7164 =cut
7165
7166 sub sethelp {
7167
7168     # XXX: make sure there are tabs between the command and explanation,
7169     #      or print_help will screw up your formatting if you have
7170     #      eeevil ornaments enabled.  This is an insane mess.
7171
7172     $help = "
7173 Help is currently only available for the new 5.8 command set.
7174 No help is available for the old command set.
7175 We assume you know what you're doing if you switch to it.
7176
7177 B<T>        Stack trace.
7178 B<s> [I<expr>]    Single step [in I<expr>].
7179 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7180 <B<CR>>        Repeat last B<n> or B<s> command.
7181 B<r>        Return from current subroutine.
7182 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7183         at the specified position.
7184 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7185 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7186 B<l> I<line>        List single I<line>.
7187 B<l> I<subname>    List first window of lines from subroutine.
7188 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7189 B<l>        List next window of lines.
7190 B<->        List previous window of lines.
7191 B<v> [I<line>]    View window around I<line>.
7192 B<.>        Return to the executed line.
7193 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7194         I<filename> may be either the full name of the file, or a regular
7195         expression matching the full file name:
7196         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7197         Evals (with saved bodies) are considered to be filenames:
7198         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7199         (in the order of execution).
7200 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7201 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7202 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7203 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7204 B<t>        Toggle trace mode.
7205 B<t> I<expr>        Trace through execution of I<expr>.
7206 B<b>        Sets breakpoint on current line)
7207 B<b> [I<line>] [I<condition>]
7208         Set breakpoint; I<line> defaults to the current execution line;
7209         I<condition> breaks if it evaluates to true, defaults to '1'.
7210 B<b> I<subname> [I<condition>]
7211         Set breakpoint at first line of subroutine.
7212 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7213 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7214 B<b> B<postpone> I<subname> [I<condition>]
7215         Set breakpoint at first line of subroutine after
7216         it is compiled.
7217 B<b> B<compile> I<subname>
7218         Stop after the subroutine is compiled.
7219 B<B> [I<line>]    Delete the breakpoint for I<line>.
7220 B<B> I<*>             Delete all breakpoints.
7221 B<a> [I<line>] I<command>
7222         Set an action to be done before the I<line> is executed;
7223         I<line> defaults to the current execution line.
7224         Sequence is: check for breakpoint/watchpoint, print line
7225         if necessary, do action, prompt user if necessary,
7226         execute line.
7227 B<a>        Does nothing
7228 B<A> [I<line>]    Delete the action for I<line>.
7229 B<A> I<*>             Delete all actions.
7230 B<w> I<expr>        Add a global watch-expression.
7231 B<w>             Does nothing
7232 B<W> I<expr>        Delete a global watch-expression.
7233 B<W> I<*>             Delete all watch-expressions.
7234 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7235         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7236 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7237 B<x> I<expr>        Evals expression in list context, dumps the result.
7238 B<m> I<expr>        Evals expression in list context, prints methods callable
7239         on the first element of the result.
7240 B<m> I<class>        Prints methods callable via the given class.
7241 B<M>        Show versions of loaded modules.
7242 B<i> I<class>       Prints nested parents of given class.
7243 B<e>         Display current thread id.
7244 B<E>         Display all thread ids the current one will be identified: <n>.
7245 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7246
7247 B<<> ?            List Perl commands to run before each prompt.
7248 B<<> I<expr>        Define Perl command to run before each prompt.
7249 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7250 B<< *>                Delete the list of perl commands to run before each prompt.
7251 B<>> ?            List Perl commands to run after each prompt.
7252 B<>> I<expr>        Define Perl command to run after each prompt.
7253 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7254 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7255 B<{> I<db_command>    Define debugger command to run before each prompt.
7256 B<{> ?            List debugger commands to run before each prompt.
7257 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7258 B<{ *>             Delete the list of debugger commands to run before each prompt.
7259 B<$prc> I<number>    Redo a previous command (default previous command).
7260 B<$prc> I<-number>    Redo number'th-to-last command.
7261 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7262         See 'B<O> I<recallCommand>' too.
7263 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7264       . (
7265         $rc eq $sh
7266         ? ""
7267         : "
7268 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7269       ) . "
7270         See 'B<O> I<shellBang>' too.
7271 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7272 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7273 B<rerun>           Rerun session to current position.
7274 B<rerun> I<n>         Rerun session to numbered command.
7275 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7276 B<H> I<-number>    Display last number commands (default all).
7277 B<H> I<*>          Delete complete history.
7278 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7279 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7280 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7281 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7282 I<command>        Execute as a perl statement in current package.
7283 B<R>        Pure-man-restart of debugger, some of debugger state
7284         and command-line options may be lost.
7285         Currently the following settings are preserved:
7286         history, breakpoints and actions, debugger B<O>ptions
7287         and the following command-line options: I<-w>, I<-I>, I<-e>.
7288
7289 B<o> [I<opt>] ...    Set boolean option to true
7290 B<o> [I<opt>B<?>]    Query options
7291 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7292         Set options.  Use quotes if spaces in value.
7293     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7294     I<pager>            program for output of \"|cmd\";
7295     I<tkRunning>            run Tk while prompting (with ReadLine);
7296     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7297     I<inhibit_exit>        Allows stepping off the end of the script.
7298     I<ImmediateStop>        Debugger should stop as early as possible.
7299     I<RemotePort>            Remote hostname:port for remote debugging
7300   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7301     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7302     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7303     I<globPrint>             whether to print contents of globs;
7304     I<DumpDBFiles>         dump arrays holding debugged files;
7305     I<DumpPackages>         dump symbol tables of packages;
7306     I<DumpReused>             dump contents of \"reused\" addresses;
7307     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7308     I<bareStringify>         Do not print the overload-stringified value;
7309   Other options include:
7310     I<PrintRet>        affects printing of return value after B<r> command,
7311     I<frame>        affects printing messages on subroutine entry/exit.
7312     I<AutoTrace>    affects printing messages on possible breaking points.
7313     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7314     I<ornaments>     affects screen appearance of the command line.
7315     I<CreateTTY>     bits control attempts to create a new TTY on events:
7316             1: on fork()    2: debugger is started inside debugger
7317             4: on startup
7318     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7319     You can put additional initialization options I<TTY>, I<noTTY>,
7320     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7321     `B<R>' after you set them).
7322
7323 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7324 B<h>        Summary of debugger commands.
7325 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7326 B<h h>        Long help for debugger commands
7327 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7328         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7329         Set B<\$DB::doccmd> to change viewer.
7330
7331 Type `|h h' for a paged display if this was too hard to read.
7332
7333 ";    # Fix balance of vi % matching: }}}}
7334
7335     #  note: tabs in the following section are not-so-helpful
7336     $summary = <<"END_SUM";
7337 I<List/search source lines:>               I<Control script execution:>
7338   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7339   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7340   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7341   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7342   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7343   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7344 I<Debugger controls:>                        B<L>           List break/watch/actions
7345   B<o> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7346   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7347   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7348   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7349   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7350   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7351   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7352   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7353   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7354 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7355   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7356   B<p> I<expr>         Print expression (uses script's current package).
7357   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7358   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7359   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7360   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7361   B<e>     Display thread id     B<E> Display all thread ids.
7362 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7363 END_SUM
7364
7365     # ')}}; # Fix balance of vi % matching
7366
7367     # and this is really numb...
7368     $pre580_help = "
7369 B<T>        Stack trace.
7370 B<s> [I<expr>]    Single step [in I<expr>].
7371 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7372 B<CR>>        Repeat last B<n> or B<s> command.
7373 B<r>        Return from current subroutine.
7374 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7375         at the specified position.
7376 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7377 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7378 B<l> I<line>        List single I<line>.
7379 B<l> I<subname>    List first window of lines from subroutine.
7380 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7381 B<l>        List next window of lines.
7382 B<->        List previous window of lines.
7383 B<w> [I<line>]    List window around I<line>.
7384 B<.>        Return to the executed line.
7385 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7386         I<filename> may be either the full name of the file, or a regular
7387         expression matching the full file name:
7388         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7389         Evals (with saved bodies) are considered to be filenames:
7390         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7391         (in the order of execution).
7392 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7393 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7394 B<L>        List all breakpoints and actions.
7395 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7396 B<t>        Toggle trace mode.
7397 B<t> I<expr>        Trace through execution of I<expr>.
7398 B<b> [I<line>] [I<condition>]
7399         Set breakpoint; I<line> defaults to the current execution line;
7400         I<condition> breaks if it evaluates to true, defaults to '1'.
7401 B<b> I<subname> [I<condition>]
7402         Set breakpoint at first line of subroutine.
7403 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7404 B<b> B<load> I<filename> Set breakpoint on `require'ing the given file.
7405 B<b> B<postpone> I<subname> [I<condition>]
7406         Set breakpoint at first line of subroutine after
7407         it is compiled.
7408 B<b> B<compile> I<subname>
7409         Stop after the subroutine is compiled.
7410 B<d> [I<line>]    Delete the breakpoint for I<line>.
7411 B<D>        Delete all breakpoints.
7412 B<a> [I<line>] I<command>
7413         Set an action to be done before the I<line> is executed;
7414         I<line> defaults to the current execution line.
7415         Sequence is: check for breakpoint/watchpoint, print line
7416         if necessary, do action, prompt user if necessary,
7417         execute line.
7418 B<a> [I<line>]    Delete the action for I<line>.
7419 B<A>        Delete all actions.
7420 B<W> I<expr>        Add a global watch-expression.
7421 B<W>        Delete all watch-expressions.
7422 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7423         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7424 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7425 B<x> I<expr>        Evals expression in list context, dumps the result.
7426 B<m> I<expr>        Evals expression in list context, prints methods callable
7427         on the first element of the result.
7428 B<m> I<class>        Prints methods callable via the given class.
7429
7430 B<<> ?            List Perl commands to run before each prompt.
7431 B<<> I<expr>        Define Perl command to run before each prompt.
7432 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7433 B<>> ?            List Perl commands to run after each prompt.
7434 B<>> I<expr>        Define Perl command to run after each prompt.
7435 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7436 B<{> I<db_command>    Define debugger command to run before each prompt.
7437 B<{> ?            List debugger commands to run before each prompt.
7438 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7439 B<$prc> I<number>    Redo a previous command (default previous command).
7440 B<$prc> I<-number>    Redo number'th-to-last command.
7441 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7442         See 'B<O> I<recallCommand>' too.
7443 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7444       . (
7445         $rc eq $sh
7446         ? ""
7447         : "
7448 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7449       ) . "
7450         See 'B<O> I<shellBang>' too.
7451 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7452 B<H> I<-number>    Display last number commands (default all).
7453 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7454 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7455 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7456 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7457 I<command>        Execute as a perl statement in current package.
7458 B<v>        Show versions of loaded modules.
7459 B<R>        Pure-man-restart of debugger, some of debugger state
7460         and command-line options may be lost.
7461         Currently the following settings are preserved:
7462         history, breakpoints and actions, debugger B<O>ptions
7463         and the following command-line options: I<-w>, I<-I>, I<-e>.
7464
7465 B<O> [I<opt>] ...    Set boolean option to true
7466 B<O> [I<opt>B<?>]    Query options
7467 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7468         Set options.  Use quotes if spaces in value.
7469     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7470     I<pager>            program for output of \"|cmd\";
7471     I<tkRunning>            run Tk while prompting (with ReadLine);
7472     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7473     I<inhibit_exit>        Allows stepping off the end of the script.
7474     I<ImmediateStop>        Debugger should stop as early as possible.
7475     I<RemotePort>            Remote hostname:port for remote debugging
7476   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7477     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7478     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7479     I<globPrint>             whether to print contents of globs;
7480     I<DumpDBFiles>         dump arrays holding debugged files;
7481     I<DumpPackages>         dump symbol tables of packages;
7482     I<DumpReused>             dump contents of \"reused\" addresses;
7483     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7484     I<bareStringify>         Do not print the overload-stringified value;
7485   Other options include:
7486     I<PrintRet>        affects printing of return value after B<r> command,
7487     I<frame>        affects printing messages on subroutine entry/exit.
7488     I<AutoTrace>    affects printing messages on possible breaking points.
7489     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7490     I<ornaments>     affects screen appearance of the command line.
7491     I<CreateTTY>     bits control attempts to create a new TTY on events:
7492             1: on fork()    2: debugger is started inside debugger
7493             4: on startup
7494     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7495     You can put additional initialization options I<TTY>, I<noTTY>,
7496     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7497     `B<R>' after you set them).
7498
7499 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7500 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7501 B<h h>        Summary of debugger commands.
7502 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7503         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7504         Set B<\$DB::doccmd> to change viewer.
7505
7506 Type `|h' for a paged display if this was too hard to read.
7507
7508 ";    # Fix balance of vi % matching: }}}}
7509
7510     #  note: tabs in the following section are not-so-helpful
7511     $pre580_summary = <<"END_SUM";
7512 I<List/search source lines:>               I<Control script execution:>
7513   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7514   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7515   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7516   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7517   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7518   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7519 I<Debugger controls:>                        B<L>           List break/watch/actions
7520   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7521   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7522   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7523   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7524   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7525   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7526   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7527   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7528 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7529   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7530   B<p> I<expr>         Print expression (uses script's current package).
7531   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7532   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7533   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7534   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7535 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7536 END_SUM
7537
7538     # ')}}; # Fix balance of vi % matching
7539
7540 } ## end sub sethelp
7541
7542 =head2 C<print_help()>
7543
7544 Most of what C<print_help> does is just text formatting. It finds the
7545 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7546 terminal control characters to simulate them (courtesy of
7547 C<Term::ReadLine::TermCap>).
7548
7549 =cut
7550
7551 sub print_help {
7552     local $_ = shift;
7553
7554     # Restore proper alignment destroyed by eeevil I<> and B<>
7555     # ornaments: A pox on both their houses!
7556     #
7557     # A help command will have everything up to and including
7558     # the first tab sequence padded into a field 16 (or if indented 20)
7559     # wide.  If it's wider than that, an extra space will be added.
7560     s{
7561         ^                       # only matters at start of line
7562           ( \040{4} | \t )*     # some subcommands are indented
7563           ( < ?                 # so <CR> works
7564             [BI] < [^\t\n] + )  # find an eeevil ornament
7565           ( \t+ )               # original separation, discarded
7566           ( .* )                # this will now start (no earlier) than
7567                                 # column 16
7568     } {
7569         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7570         my $clean = $command;
7571         $clean =~ s/[BI]<([^>]*)>/$1/g;
7572
7573         # replace with this whole string:
7574         ($leadwhite ? " " x 4 : "")
7575       . $command
7576       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7577       . $text;
7578
7579     }mgex;
7580
7581     s{                          # handle bold ornaments
7582        B < ( [^>] + | > ) >
7583     } {
7584           $Term::ReadLine::TermCap::rl_term_set[2]
7585         . $1
7586         . $Term::ReadLine::TermCap::rl_term_set[3]
7587     }gex;
7588
7589     s{                         # handle italic ornaments
7590        I < ( [^>] + | > ) >
7591     } {
7592           $Term::ReadLine::TermCap::rl_term_set[0]
7593         . $1
7594         . $Term::ReadLine::TermCap::rl_term_set[1]
7595     }gex;
7596
7597     local $\ = '';
7598     print $OUT $_;
7599 } ## end sub print_help
7600
7601 =head2 C<fix_less>
7602
7603 This routine does a lot of gyrations to be sure that the pager is C<less>.
7604 It checks for C<less> masquerading as C<more> and records the result in
7605 C<$ENV{LESS}> so we don't have to go through doing the stats again.
7606
7607 =cut
7608
7609 sub fix_less {
7610
7611     # We already know if this is set.
7612     return if defined $ENV{LESS} && $ENV{LESS} =~ /r/;
7613
7614     # Pager is less for sure.
7615     my $is_less = $pager =~ /\bless\b/;
7616     if ( $pager =~ /\bmore\b/ ) {
7617
7618         # Nope, set to more. See what's out there.
7619         my @st_more = stat('/usr/bin/more');
7620         my @st_less = stat('/usr/bin/less');
7621
7622         # is it really less, pretending to be more?
7623              $is_less = @st_more
7624           && @st_less
7625           && $st_more[0] == $st_less[0]
7626           && $st_more[1] == $st_less[1];
7627     } ## end if ($pager =~ /\bmore\b/)
7628
7629     # changes environment!
7630     # 'r' added so we don't do (slow) stats again.
7631     $ENV{LESS} .= 'r' if $is_less;
7632 } ## end sub fix_less
7633
7634 =head1 DIE AND WARN MANAGEMENT
7635
7636 =head2 C<diesignal>
7637
7638 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7639 to debug a debugger problem.
7640
7641 It does its best to report the error that occurred, and then forces the
7642 program, debugger, and everything to die.
7643
7644 =cut
7645
7646 sub diesignal {
7647
7648     # No entry/exit messages.
7649     local $frame = 0;
7650
7651     # No return value prints.
7652     local $doret = -2;
7653
7654     # set the abort signal handling to the default (just terminate).
7655     $SIG{'ABRT'} = 'DEFAULT';
7656
7657     # If we enter the signal handler recursively, kill myself with an
7658     # abort signal (so we just terminate).
7659     kill 'ABRT', $$ if $panic++;
7660
7661     # If we can show detailed info, do so.
7662     if ( defined &Carp::longmess ) {
7663
7664         # Don't recursively enter the warn handler, since we're carping.
7665         local $SIG{__WARN__} = '';
7666
7667         # Skip two levels before reporting traceback: we're skipping
7668         # mydie and confess.
7669         local $Carp::CarpLevel = 2;    # mydie + confess
7670
7671         # Tell us all about it.
7672         &warn( Carp::longmess("Signal @_") );
7673     }
7674
7675     # No Carp. Tell us about the signal as best we can.
7676     else {
7677         local $\ = '';
7678         print $DB::OUT "Got signal @_\n";
7679     }
7680
7681     # Drop dead.
7682     kill 'ABRT', $$;
7683 } ## end sub diesignal
7684
7685 =head2 C<dbwarn>
7686
7687 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7688 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7689
7690 =cut
7691
7692 sub dbwarn {
7693
7694     # No entry/exit trace.
7695     local $frame = 0;
7696
7697     # No return value printing.
7698     local $doret = -2;
7699
7700     # Turn off warn and die handling to prevent recursive entries to this
7701     # routine.
7702     local $SIG{__WARN__} = '';
7703     local $SIG{__DIE__}  = '';
7704
7705     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7706     # done yet), we may not be able to do a require.
7707     eval { require Carp }
7708       if defined $^S;    # If error/warning during compilation,
7709                          # require may be broken.
7710
7711     # Use the core warn() unless Carp loaded OK.
7712     CORE::warn( @_,
7713         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7714       return
7715       unless defined &Carp::longmess;
7716
7717     # Save the current values of $single and $trace, and then turn them off.
7718     my ( $mysingle, $mytrace ) = ( $single, $trace );
7719     $single = 0;
7720     $trace  = 0;
7721
7722     # We can call Carp::longmess without its being "debugged" (which we
7723     # don't want - we just want to use it!). Capture this for later.
7724     my $mess = Carp::longmess(@_);
7725
7726     # Restore $single and $trace to their original values.
7727     ( $single, $trace ) = ( $mysingle, $mytrace );
7728
7729     # Use the debugger's own special way of printing warnings to print
7730     # the stack trace message.
7731     &warn($mess);
7732 } ## end sub dbwarn
7733
7734 =head2 C<dbdie>
7735
7736 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7737 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7738 single stepping and tracing during the call to C<Carp::longmess> to avoid
7739 debugging it - we just want to use it.
7740
7741 If C<dieLevel> is zero, we let the program being debugged handle the
7742 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7743 the debugger takes over all exception handling, printing a backtrace and
7744 displaying the exception via its C<dbwarn()> routine.
7745
7746 =cut
7747
7748 sub dbdie {
7749     local $frame         = 0;
7750     local $doret         = -2;
7751     local $SIG{__DIE__}  = '';
7752     local $SIG{__WARN__} = '';
7753     my $i      = 0;
7754     my $ineval = 0;
7755     my $sub;
7756     if ( $dieLevel > 2 ) {
7757         local $SIG{__WARN__} = \&dbwarn;
7758         &warn(@_);    # Yell no matter what
7759         return;
7760     }
7761     if ( $dieLevel < 2 ) {
7762         die @_ if $^S;    # in eval propagate
7763     }
7764
7765     # The code used to check $^S to see if compiliation of the current thing
7766     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7767     eval { require Carp };
7768
7769     die( @_,
7770         "\nCannot print stack trace, load with -MCarp option to see stack" )
7771       unless defined &Carp::longmess;
7772
7773     # We do not want to debug this chunk (automatic disabling works
7774     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7775     # get the stack trace from Carp::longmess (if possible), restore $signal
7776     # and $trace, and then die with the stack trace.
7777     my ( $mysingle, $mytrace ) = ( $single, $trace );
7778     $single = 0;
7779     $trace  = 0;
7780     my $mess = "@_";
7781     {
7782
7783         package Carp;    # Do not include us in the list
7784         eval { $mess = Carp::longmess(@_); };
7785     }
7786     ( $single, $trace ) = ( $mysingle, $mytrace );
7787     die $mess;
7788 } ## end sub dbdie
7789
7790 =head2 C<warnlevel()>
7791
7792 Set the C<$DB::warnLevel> variable that stores the value of the
7793 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7794 results in the debugger taking over all warning handlers. Setting
7795 C<warnLevel> to zero leaves any warning handlers set up by the program
7796 being debugged in place.
7797
7798 =cut
7799
7800 sub warnLevel {
7801     if (@_) {
7802         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7803         $warnLevel = shift;
7804         if ($warnLevel) {
7805             $SIG{__WARN__} = \&DB::dbwarn;
7806         }
7807         elsif ($prevwarn) {
7808             $SIG{__WARN__} = $prevwarn;
7809         } else {
7810             undef $SIG{__WARN__};
7811         }
7812     } ## end if (@_)
7813     $warnLevel;
7814 } ## end sub warnLevel
7815
7816 =head2 C<dielevel>
7817
7818 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7819 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7820 zero lets you use your own C<die()> handler.
7821
7822 =cut
7823
7824 sub dieLevel {
7825     local $\ = '';
7826     if (@_) {
7827         $prevdie = $SIG{__DIE__} unless $dieLevel;
7828         $dieLevel = shift;
7829         if ($dieLevel) {
7830
7831             # Always set it to dbdie() for non-zero values.
7832             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
7833
7834             # No longer exists, so don't try  to use it.
7835             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
7836
7837             # If we've finished initialization, mention that stack dumps
7838             # are enabled, If dieLevel is 1, we won't stack dump if we die
7839             # in an eval().
7840             print $OUT "Stack dump during die enabled",
7841               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
7842               if $I_m_init;
7843
7844             # XXX This is probably obsolete, given that diehard() is gone.
7845             print $OUT "Dump printed too.\n" if $dieLevel > 2;
7846         } ## end if ($dieLevel)
7847
7848         # Put the old one back if there was one.
7849         elsif ($prevdie) {
7850             $SIG{__DIE__} = $prevdie;
7851             print $OUT "Default die handler restored.\n";
7852         } else {
7853             undef $SIG{__DIE__};
7854             print $OUT "Die handler removed.\n";
7855         }
7856     } ## end if (@_)
7857     $dieLevel;
7858 } ## end sub dieLevel
7859
7860 =head2 C<signalLevel>
7861
7862 Number three in a series: set C<signalLevel> to zero to keep your own
7863 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
7864 takes over and handles them with C<DB::diesignal()>.
7865
7866 =cut
7867
7868 sub signalLevel {
7869     if (@_) {
7870         $prevsegv = $SIG{SEGV} unless $signalLevel;
7871         $prevbus  = $SIG{BUS}  unless $signalLevel;
7872         $signalLevel = shift;
7873         if ($signalLevel) {
7874             $SIG{SEGV} = \&DB::diesignal;
7875             $SIG{BUS}  = \&DB::diesignal;
7876         }
7877         else {
7878             $SIG{SEGV} = $prevsegv;
7879             $SIG{BUS}  = $prevbus;
7880         }
7881     } ## end if (@_)
7882     $signalLevel;
7883 } ## end sub signalLevel
7884
7885 =head1 SUBROUTINE DECODING SUPPORT
7886
7887 These subroutines are used during the C<x> and C<X> commands to try to
7888 produce as much information as possible about a code reference. They use
7889 L<Devel::Peek> to try to find the glob in which this code reference lives
7890 (if it does) - this allows us to actually code references which correspond
7891 to named subroutines (including those aliased via glob assignment).
7892
7893 =head2 C<CvGV_name()>
7894
7895 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
7896 via that routine. If this fails, return the reference again (when the
7897 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
7898
7899 =cut
7900
7901 sub CvGV_name {
7902     my $in   = shift;
7903     my $name = CvGV_name_or_bust($in);
7904     defined $name ? $name : $in;
7905 }
7906
7907 =head2 C<CvGV_name_or_bust> I<coderef>
7908
7909 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
7910 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
7911 find a glob for this ref.
7912
7913 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
7914
7915 =cut
7916
7917 sub CvGV_name_or_bust {
7918     my $in = shift;
7919     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
7920     return unless ref $in;
7921     $in = \&$in;            # Hard reference...
7922     eval { require Devel::Peek; 1 } or return;
7923     my $gv = Devel::Peek::CvGV($in) or return;
7924     *$gv{PACKAGE} . '::' . *$gv{NAME};
7925 } ## end sub CvGV_name_or_bust
7926
7927 =head2 C<find_sub>
7928
7929 A utility routine used in various places; finds the file where a subroutine
7930 was defined, and returns that filename and a line-number range.
7931
7932 Tries to use C<@sub> first; if it can't find it there, it tries building a
7933 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
7934 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
7935 this way, it brute-force searches C<%sub>, checking for identical references.
7936
7937 =cut
7938
7939 sub find_sub {
7940     my $subr = shift;
7941     $sub{$subr} or do {
7942         return unless defined &$subr;
7943         my $name = CvGV_name_or_bust($subr);
7944         my $data;
7945         $data = $sub{$name} if defined $name;
7946         return $data if defined $data;
7947
7948         # Old stupid way...
7949         $subr = \&$subr;    # Hard reference
7950         my $s;
7951         for ( keys %sub ) {
7952             $s = $_, last if $subr eq \&$_;
7953         }
7954         $sub{$s} if $s;
7955       } ## end do
7956 } ## end sub find_sub
7957
7958 =head2 C<methods>
7959
7960 A subroutine that uses the utility function C<methods_via> to find all the
7961 methods in the class corresponding to the current reference and in
7962 C<UNIVERSAL>.
7963
7964 =cut
7965
7966 sub methods {
7967
7968     # Figure out the class - either this is the class or it's a reference
7969     # to something blessed into that class.
7970     my $class = shift;
7971     $class = ref $class if ref $class;
7972
7973     local %seen;
7974
7975     # Show the methods that this class has.
7976     methods_via( $class, '', 1 );
7977
7978     # Show the methods that UNIVERSAL has.
7979     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
7980 } ## end sub methods
7981
7982 =head2 C<methods_via($class, $prefix, $crawl_upward)>
7983
7984 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
7985 all the parent class methods. C<$class> is the name of the next class to
7986 try; C<$prefix> is the message prefix, which gets built up as we go up the
7987 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
7988 higher in the C<@ISA> tree, 0 if we should stop.
7989
7990 =cut
7991
7992 sub methods_via {
7993
7994     # If we've processed this class already, just quit.
7995     my $class = shift;
7996     return if $seen{$class}++;
7997
7998     # This is a package that is contributing the methods we're about to print.
7999     my $prefix  = shift;
8000     my $prepend = $prefix ? "via $prefix: " : '';
8001     my @to_print;
8002
8003     # Extract from all the symbols in this class.
8004     while (my ($name, $glob) = each %{"${class}::"}) {
8005         # references directly in the symbol table are Proxy Constant
8006         # Subroutines, and are by their very nature defined
8007         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8008         # to a subroutine reference, which can be tested by defined.
8009         # $glob might also be the value -1  (from sub foo;)
8010         # or (say) '$$' (from sub foo ($$);)
8011         # \$glob will be SCALAR in both cases.
8012         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8013             && !$seen{$name}++) {
8014             push @to_print, "$prepend$name\n";
8015         }
8016     }
8017
8018     {
8019         local $\ = '';
8020         local $, = '';
8021         print $DB::OUT $_ foreach sort @to_print;
8022     }
8023
8024     # If the $crawl_upward argument is false, just quit here.
8025     return unless shift;
8026
8027     # $crawl_upward true: keep going up the tree.
8028     # Find all the classes this one is a subclass of.
8029     for $name ( @{"${class}::ISA"} ) {
8030
8031         # Set up the new prefix.
8032         $prepend = $prefix ? $prefix . " -> $name" : $name;
8033
8034         # Crawl up the tree and keep trying to crawl up.
8035         methods_via( $name, $prepend, 1 );
8036     }
8037 } ## end sub methods_via
8038
8039 =head2 C<setman> - figure out which command to use to show documentation
8040
8041 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8042
8043 =cut
8044
8045 sub setman {
8046     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|MacOS|NetWare)\z/s
8047       ? "man"         # O Happy Day!
8048       : "perldoc";    # Alas, poor unfortunates
8049 } ## end sub setman
8050
8051 =head2 C<runman> - run the appropriate command to show documentation
8052
8053 Accepts a man page name; runs the appropriate command to display it (set up
8054 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8055 program's STDIN and STDOUT.
8056
8057 =cut
8058
8059 sub runman {
8060     my $page = shift;
8061     unless ($page) {
8062         &system("$doccmd $doccmd");
8063         return;
8064     }
8065
8066     # this way user can override, like with $doccmd="man -Mwhatever"
8067     # or even just "man " to disable the path check.
8068     unless ( $doccmd eq 'man' ) {
8069         &system("$doccmd $page");
8070         return;
8071     }
8072
8073     $page = 'perl' if lc($page) eq 'help';
8074
8075     require Config;
8076     my $man1dir = $Config::Config{'man1dir'};
8077     my $man3dir = $Config::Config{'man3dir'};
8078     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8079     my $manpath = '';
8080     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8081     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8082     chop $manpath if $manpath;
8083
8084     # harmless if missing, I figure
8085     my $oldpath = $ENV{MANPATH};
8086     $ENV{MANPATH} = $manpath if $manpath;
8087     my $nopathopt = $^O =~ /dunno what goes here/;
8088     if (
8089         CORE::system(
8090             $doccmd,
8091
8092             # I just *know* there are men without -M
8093             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8094             split ' ', $page
8095         )
8096       )
8097     {
8098         unless ( $page =~ /^perl\w/ ) {
8099 # do it this way because its easier to slurp in to keep up to date - clunky though.
8100 my @pods = qw(
8101     5004delta
8102     5005delta
8103     561delta
8104     56delta
8105     570delta
8106     571delta
8107     572delta
8108     573delta
8109     58delta
8110     581delta
8111     582delta
8112     583delta
8113     584delta
8114     590delta
8115     591delta
8116     592delta
8117     aix
8118     amiga
8119     apio
8120     api
8121     apollo
8122     artistic
8123     beos
8124     book
8125     boot
8126     bot
8127     bs2000
8128     call
8129     ce
8130     cheat
8131     clib
8132     cn
8133     compile
8134     cygwin
8135     data
8136     dbmfilter
8137     debguts
8138     debtut
8139     debug
8140     delta
8141     dgux
8142     diag
8143     doc
8144     dos
8145     dsc
8146     ebcdic
8147     embed
8148     epoc
8149     faq1
8150     faq2
8151     faq3
8152     faq4
8153     faq5
8154     faq6
8155     faq7
8156     faq8
8157     faq9
8158     faq
8159     filter
8160     fork
8161     form
8162     freebsd
8163     func
8164     gpl
8165     guts
8166     hack
8167     hist
8168     hpux
8169     hurd
8170     intern
8171     intro
8172     iol
8173     ipc
8174     irix
8175     jp
8176     ko
8177     lexwarn
8178     locale
8179     lol
8180     machten
8181     macos
8182     macosx
8183     mint
8184     modinstall
8185     modlib
8186     mod
8187     modstyle
8188     mpeix
8189     netware
8190     newmod
8191     number
8192     obj
8193     opentut
8194     op
8195     os2
8196     os390
8197     os400
8198     othrtut
8199     packtut
8200     plan9
8201     pod
8202     podspec
8203     port
8204     qnx
8205     ref
8206     reftut
8207     re
8208     requick
8209     reref
8210     retut
8211     run
8212     sec
8213     solaris
8214     style
8215     sub
8216     syn
8217     thrtut
8218     tie
8219     toc
8220     todo
8221     tooc
8222     toot
8223     trap
8224     tru64
8225     tw
8226     unicode
8227     uniintro
8228     util
8229     uts
8230     var
8231     vmesa
8232     vms
8233     vos
8234     win32
8235     xs
8236     xstut
8237 );
8238             if (grep { $page eq $_ } @pods) {
8239                 $page =~ s/^/perl/;
8240                 CORE::system( $doccmd,
8241                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8242                     $page );
8243             } ## end if (grep { $page eq $_...
8244         } ## end unless ($page =~ /^perl\w/)
8245     } ## end if (CORE::system($doccmd...
8246     if ( defined $oldpath ) {
8247         $ENV{MANPATH} = $manpath;
8248     }
8249     else {
8250         delete $ENV{MANPATH};
8251     }
8252 } ## end sub runman
8253
8254 #use Carp;                          # This did break, left for debugging
8255
8256 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8257
8258 Because of the way the debugger interface to the Perl core is designed, any
8259 debugger package globals that C<DB::sub()> requires have to be defined before
8260 any subroutines can be called. These are defined in the second C<BEGIN> block.
8261
8262 This block sets things up so that (basically) the world is sane
8263 before the debugger starts executing. We set up various variables that the
8264 debugger has to have set up before the Perl core starts running:
8265
8266 =over 4
8267
8268 =item *
8269
8270 The debugger's own filehandles (copies of STD and STDOUT for now).
8271
8272 =item *
8273
8274 Characters for shell escapes, the recall command, and the history command.
8275
8276 =item *
8277
8278 The maximum recursion depth.
8279
8280 =item *
8281
8282 The size of a C<w> command's window.
8283
8284 =item *
8285
8286 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8287
8288 =item *
8289
8290 The fact that we're not in a sub at all right now.
8291
8292 =item *
8293
8294 The default SIGINT handler for the debugger.
8295
8296 =item *
8297
8298 The appropriate value of the flag in C<$^D> that says the debugger is running
8299
8300 =item *
8301
8302 The current debugger recursion level
8303
8304 =item *
8305
8306 The list of postponed items and the C<$single> stack (XXX define this)
8307
8308 =item *
8309
8310 That we want no return values and no subroutine entry/exit trace.
8311
8312 =back
8313
8314 =cut
8315
8316 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8317
8318 BEGIN {    # This does not compile, alas. (XXX eh?)
8319     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8320     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8321
8322     # Define characters used by command parsing.
8323     $sh       = '!';      # Shell escape (does not work)
8324     $rc       = ',';      # Recall command (does not work)
8325     @hist     = ('?');    # Show history (does not work)
8326     @truehist = ();       # Can be saved for replay (per session)
8327
8328     # This defines the point at which you get the 'deep recursion'
8329     # warning. It MUST be defined or the debugger will not load.
8330     $deep = 100;
8331
8332     # Number of lines around the current one that are shown in the
8333     # 'w' command.
8334     $window = 10;
8335
8336     # How much before-the-current-line context the 'v' command should
8337     # use in calculating the start of the window it will display.
8338     $preview = 3;
8339
8340     # We're not in any sub yet, but we need this to be a defined value.
8341     $sub = '';
8342
8343     # Set up the debugger's interrupt handler. It simply sets a flag
8344     # ($signal) that DB::DB() will check before each command is executed.
8345     $SIG{INT} = \&DB::catch;
8346
8347     # The following lines supposedly, if uncommented, allow the debugger to
8348     # debug itself. Perhaps we can try that someday.
8349     # This may be enabled to debug debugger:
8350     #$warnLevel = 1 unless defined $warnLevel;
8351     #$dieLevel = 1 unless defined $dieLevel;
8352     #$signalLevel = 1 unless defined $signalLevel;
8353
8354     # This is the flag that says "a debugger is running, please call
8355     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8356     # execute anything in the user's context, because we always want to
8357     # get control back.
8358     $db_stop = 0;          # Compiler warning ...
8359     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8360
8361     # This variable records how many levels we're nested in debugging. Used
8362     # Used in the debugger prompt, and in determining whether it's all over or
8363     # not.
8364     $level = 0;            # Level of recursive debugging
8365
8366     # "Triggers bug (?) in perl if we postpone this until runtime."
8367     # XXX No details on this yet, or whether we should fix the bug instead
8368     # of work around it. Stay tuned.
8369     @postponed = @stack = (0);
8370
8371     # Used to track the current stack depth using the auto-stacked-variable
8372     # trick.
8373     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8374
8375     # Don't print return values on exiting a subroutine.
8376     $doret = -2;
8377
8378     # No extry/exit tracing.
8379     $frame = 0;
8380
8381 } ## end BEGIN
8382
8383 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8384
8385 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8386
8387 =head2 db_complete
8388
8389 C<readline> support - adds command completion to basic C<readline>.
8390
8391 Returns a list of possible completions to C<readline> when invoked. C<readline>
8392 will print the longest common substring following the text already entered.
8393
8394 If there is only a single possible completion, C<readline> will use it in full.
8395
8396 This code uses C<map> and C<grep> heavily to create lists of possible
8397 completion. Think LISP in this section.
8398
8399 =cut
8400
8401 sub db_complete {
8402
8403     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8404     # $text is the text to be completed.
8405     # $line is the incoming line typed by the user.
8406     # $start is the start of the text to be completed in the incoming line.
8407     my ( $text, $line, $start ) = @_;
8408
8409     # Save the initial text.
8410     # The search pattern is current package, ::, extract the next qualifier
8411     # Prefix and pack are set to undef.
8412     my ( $itext, $search, $prefix, $pack ) =
8413       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8414
8415 =head3 C<b postpone|compile>
8416
8417 =over 4
8418
8419 =item *
8420
8421 Find all the subroutines that might match in this package
8422
8423 =item *
8424
8425 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8426
8427 =item *
8428
8429 Include all the rest of the subs that are known
8430
8431 =item *
8432
8433 C<grep> out the ones that match the text we have so far
8434
8435 =item *
8436
8437 Return this as the list of possible completions
8438
8439 =back
8440
8441 =cut
8442
8443     return sort grep /^\Q$text/, ( keys %sub ),
8444       qw(postpone load compile),    # subroutines
8445       ( map { /$search/ ? ($1) : () } keys %sub )
8446       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8447
8448 =head3 C<b load>
8449
8450 Get all the possible files from C<@INC> as it currently stands and
8451 select the ones that match the text so far.
8452
8453 =cut
8454
8455     return sort grep /^\Q$text/, values %INC    # files
8456       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8457
8458 =head3  C<V> (list variable) and C<m> (list modules)
8459
8460 There are two entry points for these commands:
8461
8462 =head4 Unqualified package names
8463
8464 Get the top-level packages and grab everything that matches the text
8465 so far. For each match, recursively complete the partial packages to
8466 get all possible matching packages. Return this sorted list.
8467
8468 =cut
8469
8470     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8471       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8472       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8473
8474 =head4 Qualified package names
8475
8476 Take a partially-qualified package and find all subpackages for it
8477 by getting all the subpackages for the package so far, matching all
8478 the subpackages against the text, and discarding all of them which
8479 start with 'main::'. Return this list.
8480
8481 =cut
8482
8483     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8484       grep !/^main::/, grep /^\Q$text/,
8485       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8486       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8487       and $text =~ /^(.*[^:])::?(\w*)$/
8488       and $prefix = $1;
8489
8490 =head3 C<f> - switch files
8491
8492 Here, we want to get a fully-qualified filename for the C<f> command.
8493 Possibilities are:
8494
8495 =over 4
8496
8497 =item 1. The original source file itself
8498
8499 =item 2. A file from C<@INC>
8500
8501 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8502
8503 =back
8504
8505 =cut
8506
8507     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8508            # We might possibly want to switch to an eval (which has a "filename"
8509            # like '(eval 9)'), so we may need to clean up the completion text
8510            # before proceeding.
8511         $prefix = length($1) - length($text);
8512         $text   = $1;
8513
8514 =pod
8515
8516 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8517 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8518 out of C<%main::>, add the initial source file, and extract the ones that
8519 match the completion text so far.
8520
8521 =cut
8522
8523         return sort
8524           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8525           $0;
8526     } ## end if ($line =~ /^\|*f\s+(.*)/)
8527
8528 =head3 Subroutine name completion
8529
8530 We look through all of the defined subs (the keys of C<%sub>) and
8531 return both all the possible matches to the subroutine name plus
8532 all the matches qualified to the current package.
8533
8534 =cut
8535
8536     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8537         $text = substr $text, 1;
8538         $prefix = "&";
8539         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8540           (
8541             map { /$search/ ? ($1) : () }
8542               keys %sub
8543           );
8544     } ## end if ((substr $text, 0, ...
8545
8546 =head3  Scalar, array, and hash completion: partially qualified package
8547
8548 Much like the above, except we have to do a little more cleanup:
8549
8550 =cut
8551
8552     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8553
8554 =pod
8555
8556 =over 4
8557
8558 =item *
8559
8560 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8561
8562 =cut
8563
8564         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8565
8566 =pod
8567
8568 =item *
8569
8570 Figure out the prefix vs. what needs completing.
8571
8572 =cut
8573
8574         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8575         $text   = $2;
8576
8577 =pod
8578
8579 =item *
8580
8581 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8582
8583 =cut
8584
8585         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8586           keys %$pack;
8587
8588 =pod
8589
8590 =item *
8591
8592 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8593
8594 =cut
8595
8596         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8597             return db_complete( $out[0], $line, $start );
8598         }
8599
8600         # Return the list of possibles.
8601         return sort @out;
8602
8603     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8604
8605 =pod
8606
8607 =back
8608
8609 =head3 Symbol completion: current package or package C<main>.
8610
8611 =cut
8612
8613     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8614
8615 =pod
8616
8617 =over 4
8618
8619 =item *
8620
8621 If it's C<main>, delete main to just get C<::> leading.
8622
8623 =cut
8624
8625         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8626
8627 =pod
8628
8629 =item *
8630
8631 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8632
8633 =cut
8634
8635         $prefix = substr $text, 0, 1;
8636         $text   = substr $text, 1;
8637
8638 =pod
8639
8640 =item *
8641
8642 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8643
8644 =cut
8645
8646         my @out = map "$prefix$_", grep /^\Q$text/,
8647           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8648           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8649
8650 =item *
8651
8652 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8653
8654 =back
8655
8656 =cut
8657
8658         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8659             return db_complete( $out[0], $line, $start );
8660         }
8661
8662         # Return the list of possibles.
8663         return sort @out;
8664     } ## end if ($text =~ /^[\$@%]/)
8665
8666 =head3 Options
8667
8668 We use C<option_val()> to look up the current value of the option. If there's
8669 only a single value, we complete the command in such a way that it is a
8670 complete command for setting the option in question. If there are multiple
8671 possible values, we generate a command consisting of the option plus a trailing
8672 question mark, which, if executed, will list the current value of the option.
8673
8674 =cut
8675
8676     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8677     {    # Options after space
8678            # We look for the text to be matched in the list of possible options,
8679            # and fetch the current value.
8680         my @out = grep /^\Q$text/, @options;
8681         my $val = option_val( $out[0], undef );
8682
8683         # Set up a 'query option's value' command.
8684         my $out = '? ';
8685         if ( not defined $val or $val =~ /[\n\r]/ ) {
8686
8687             # There's really nothing else we can do.
8688         }
8689
8690         # We have a value. Create a proper option-setting command.
8691         elsif ( $val =~ /\s/ ) {
8692
8693             # XXX This may be an extraneous variable.
8694             my $found;
8695
8696             # We'll want to quote the string (because of the embedded
8697             # whtespace), but we want to make sure we don't end up with
8698             # mismatched quote characters. We try several possibilities.
8699             foreach $l ( split //, qq/\"\'\#\|/ ) {
8700
8701                 # If we didn't find this quote character in the value,
8702                 # quote it using this quote character.
8703                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8704             }
8705         } ## end elsif ($val =~ /\s/)
8706
8707         # Don't need any quotes.
8708         else {
8709             $out = "=$val ";
8710         }
8711
8712         # If there were multiple possible values, return '? ', which
8713         # makes the command into a query command. If there was just one,
8714         # have readline append that.
8715         $rl_attribs->{completer_terminator_character} =
8716           ( @out == 1 ? $out : '? ' );
8717
8718         # Return list of possibilities.
8719         return sort @out;
8720     } ## end if ((substr $line, 0, ...
8721
8722 =head3 Filename completion
8723
8724 For entering filenames. We simply call C<readline>'s C<filename_list()>
8725 method with the completion text to get the possible completions.
8726
8727 =cut
8728
8729     return $term->filename_list($text);    # filenames
8730
8731 } ## end sub db_complete
8732
8733 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8734
8735 Functions that possibly ought to be somewhere else.
8736
8737 =head2 end_report
8738
8739 Say we're done.
8740
8741 =cut
8742
8743 sub end_report {
8744     local $\ = '';
8745     print $OUT "Use `q' to quit or `R' to restart.  `h q' for details.\n";
8746 }
8747
8748 =head2 clean_ENV
8749
8750 If we have $ini_pids, save it in the environment; else remove it from the
8751 environment. Used by the C<R> (restart) command.
8752
8753 =cut
8754
8755 sub clean_ENV {
8756     if ( defined($ini_pids) ) {
8757         $ENV{PERLDB_PIDS} = $ini_pids;
8758     }
8759     else {
8760         delete( $ENV{PERLDB_PIDS} );
8761     }
8762 } ## end sub clean_ENV
8763
8764 # PERLDBf_... flag names from perl.h
8765 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8766
8767 BEGIN {
8768     %DollarCaretP_flags = (
8769         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8770         PERLDBf_LINE      => 0x02,     # Keep line #
8771         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8772         PERLDBf_INTER     => 0x08,     # Preserve more data
8773         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8774         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8775         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8776         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8777         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8778         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8779         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8780         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8781     );
8782     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8783     # doesn't need to set it. It's provided for the benefit of profilers and
8784     # other code analysers.
8785
8786     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8787 }
8788
8789 sub parse_DollarCaretP_flags {
8790     my $flags = shift;
8791     $flags =~ s/^\s+//;
8792     $flags =~ s/\s+$//;
8793     my $acu = 0;
8794     foreach my $f ( split /\s*\|\s*/, $flags ) {
8795         my $value;
8796         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8797             $value = hex $1;
8798         }
8799         elsif ( $f =~ /^(\d+)$/ ) {
8800             $value = int $1;
8801         }
8802         elsif ( $f =~ /^DEFAULT$/i ) {
8803             $value = $DollarCaretP_flags{PERLDB_ALL};
8804         }
8805         else {
8806             $f =~ /^(?:PERLDBf_)?(.*)$/i;
8807             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
8808             unless ( defined $value ) {
8809                 print $OUT (
8810                     "Unrecognized \$^P flag '$f'!\n",
8811                     "Acceptable flags are: "
8812                       . join( ', ', sort keys %DollarCaretP_flags ),
8813                     ", and hexadecimal and decimal numbers.\n"
8814                 );
8815                 return undef;
8816             }
8817         }
8818         $acu |= $value;
8819     }
8820     $acu;
8821 }
8822
8823 sub expand_DollarCaretP_flags {
8824     my $DollarCaretP = shift;
8825     my @bits         = (
8826         map {
8827             my $n = ( 1 << $_ );
8828             ( $DollarCaretP & $n )
8829               ? ( $DollarCaretP_flags_r{$n}
8830                   || sprintf( '0x%x', $n ) )
8831               : ()
8832           } 0 .. 31
8833     );
8834     return @bits ? join( '|', @bits ) : 0;
8835 }
8836
8837 =over 4
8838
8839 =item rerun
8840
8841 Rerun the current session to:
8842
8843     rerun        current position
8844
8845     rerun 4      command number 4
8846
8847     rerun -4     current command minus 4 (go back 4 steps)
8848
8849 Whether this always makes sense, in the current context is unknowable, and is
8850 in part left as a useful exersize for the reader.  This sub returns the
8851 appropriate arguments to rerun the current session.
8852
8853 =cut
8854
8855 sub rerun {
8856     my $i = shift;
8857     my @args;
8858     pop(@truehist);                      # strim
8859     unless (defined $truehist[$i]) {
8860         print "Unable to return to non-existent command: $i\n";
8861     } else {
8862         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
8863         my @temp = @truehist;            # store
8864         push(@DB::typeahead, @truehist); # saved
8865         @truehist = @hist = ();          # flush
8866         @args = &restart();              # setup
8867         &get_list("PERLDB_HIST");        # clean
8868         &set_list("PERLDB_HIST", @temp); # reset
8869     }
8870     return @args;
8871 }
8872
8873 =item restart
8874
8875 Restarting the debugger is a complex operation that occurs in several phases.
8876 First, we try to reconstruct the command line that was used to invoke Perl
8877 and the debugger.
8878
8879 =cut
8880
8881 sub restart {
8882     # I may not be able to resurrect you, but here goes ...
8883     print $OUT
8884 "Warning: some settings and command-line options may be lost!\n";
8885     my ( @script, @flags, $cl );
8886
8887     # If warn was on before, turn it on again.
8888     push @flags, '-w' if $ini_warn;
8889
8890     # Rebuild the -I flags that were on the initial
8891     # command line.
8892     for (@ini_INC) {
8893         push @flags, '-I', $_;
8894     }
8895
8896     # Turn on taint if it was on before.
8897     push @flags, '-T' if ${^TAINT};
8898
8899     # Arrange for setting the old INC:
8900     # Save the current @init_INC in the environment.
8901     set_list( "PERLDB_INC", @ini_INC );
8902
8903     # If this was a perl one-liner, go to the "file"
8904     # corresponding to the one-liner read all the lines
8905     # out of it (except for the first one, which is going
8906     # to be added back on again when 'perl -d' runs: that's
8907     # the 'require perl5db.pl;' line), and add them back on
8908     # to the command line to be executed.
8909     if ( $0 eq '-e' ) {
8910         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
8911             chomp( $cl = ${'::_<-e'}[$_] );
8912             push @script, '-e', $cl;
8913         }
8914     } ## end if ($0 eq '-e')
8915
8916     # Otherwise we just reuse the original name we had
8917     # before.
8918     else {
8919         @script = $0;
8920     }
8921
8922 =pod
8923
8924 After the command line  has been reconstructed, the next step is to save
8925 the debugger's status in environment variables. The C<DB::set_list> routine
8926 is used to save aggregate variables (both hashes and arrays); scalars are
8927 just popped into environment variables directly.
8928
8929 =cut
8930
8931     # If the terminal supported history, grab it and
8932     # save that in the environment.
8933     set_list( "PERLDB_HIST",
8934           $term->Features->{getHistory}
8935         ? $term->GetHistory
8936         : @hist );
8937
8938     # Find all the files that were visited during this
8939     # session (i.e., the debugger had magic hashes
8940     # corresponding to them) and stick them in the environment.
8941     my @had_breakpoints = keys %had_breakpoints;
8942     set_list( "PERLDB_VISITED", @had_breakpoints );
8943
8944     # Save the debugger options we chose.
8945     set_list( "PERLDB_OPT", %option );
8946     # set_list( "PERLDB_OPT", options2remember() );
8947
8948     # Save the break-on-loads.
8949     set_list( "PERLDB_ON_LOAD", %break_on_load );
8950
8951 =pod
8952
8953 The most complex part of this is the saving of all of the breakpoints. They
8954 can live in an awful lot of places, and we have to go through all of them,
8955 find the breakpoints, and then save them in the appropriate environment
8956 variable via C<DB::set_list>.
8957
8958 =cut
8959
8960     # Go through all the breakpoints and make sure they're
8961     # still valid.
8962     my @hard;
8963     for ( 0 .. $#had_breakpoints ) {
8964
8965         # We were in this file.
8966         my $file = $had_breakpoints[$_];
8967
8968         # Grab that file's magic line hash.
8969         *dbline = $main::{ '_<' . $file };
8970
8971         # Skip out if it doesn't exist, or if the breakpoint
8972         # is in a postponed file (we'll do postponed ones
8973         # later).
8974         next unless %dbline or $postponed_file{$file};
8975
8976         # In an eval. This is a little harder, so we'll
8977         # do more processing on that below.
8978         ( push @hard, $file ), next
8979           if $file =~ /^\(\w*eval/;
8980
8981         # XXX I have no idea what this is doing. Yet.
8982         my @add;
8983         @add = %{ $postponed_file{$file} }
8984           if $postponed_file{$file};
8985
8986         # Save the list of all the breakpoints for this file.
8987         set_list( "PERLDB_FILE_$_", %dbline, @add );
8988     } ## end for (0 .. $#had_breakpoints)
8989
8990     # The breakpoint was inside an eval. This is a little
8991     # more difficult. XXX and I don't understand it.
8992     for (@hard) {
8993         # Get over to the eval in question.
8994         *dbline = $main::{ '_<' . $_ };
8995         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
8996         for $sub ( keys %sub ) {
8997             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
8998             $subs{$sub} = [ $1, $2 ];
8999         }
9000         unless (%subs) {
9001             print $OUT
9002               "No subroutines in $_, ignoring breakpoints.\n";
9003             next;
9004         }
9005       LINES: for $line ( keys %dbline ) {
9006
9007             # One breakpoint per sub only:
9008             my ( $offset, $sub, $found );
9009           SUBS: for $sub ( keys %subs ) {
9010                 if (
9011                     $subs{$sub}->[1] >=
9012                     $line    # Not after the subroutine
9013                     and (
9014                         not defined $offset    # Not caught
9015                         or $offset < 0
9016                     )
9017                   )
9018                 {                              # or badly caught
9019                     $found  = $sub;
9020                     $offset = $line - $subs{$sub}->[0];
9021                     $offset = "+$offset", last SUBS
9022                       if $offset >= 0;
9023                 } ## end if ($subs{$sub}->[1] >=...
9024             } ## end for $sub (keys %subs)
9025             if ( defined $offset ) {
9026                 $postponed{$found} =
9027                   "break $offset if $dbline{$line}";
9028             }
9029             else {
9030                 print $OUT
9031 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9032             }
9033         } ## end for $line (keys %dbline)
9034     } ## end for (@hard)
9035
9036     # Save the other things that don't need to be
9037     # processed.
9038     set_list( "PERLDB_POSTPONE",  %postponed );
9039     set_list( "PERLDB_PRETYPE",   @$pretype );
9040     set_list( "PERLDB_PRE",       @$pre );
9041     set_list( "PERLDB_POST",      @$post );
9042     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9043
9044     # We are oficially restarting.
9045     $ENV{PERLDB_RESTART} = 1;
9046
9047     # We are junking all child debuggers.
9048     delete $ENV{PERLDB_PIDS};    # Restore ini state
9049
9050     # Set this back to the initial pid.
9051     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9052
9053 =pod
9054
9055 After all the debugger status has been saved, we take the command we built up
9056 and then return it, so we can C<exec()> it. The debugger will spot the
9057 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9058 from the environment.
9059
9060 =cut
9061
9062     # And run Perl again. Add the "-d" flag, all the
9063     # flags we built up, the script (whether a one-liner
9064     # or a file), add on the -emacs flag for a slave editor,
9065     # and then the old arguments.
9066
9067     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9068
9069 };  # end restart
9070
9071 =back
9072
9073 =head1 END PROCESSING - THE C<END> BLOCK
9074
9075 Come here at the very end of processing. We want to go into a
9076 loop where we allow the user to enter commands and interact with the
9077 debugger, but we don't want anything else to execute.
9078
9079 First we set the C<$finished> variable, so that some commands that
9080 shouldn't be run after the end of program quit working.
9081
9082 We then figure out whether we're truly done (as in the user entered a C<q>
9083 command, or we finished execution while running nonstop). If we aren't,
9084 we set C<$single> to 1 (causing the debugger to get control again).
9085
9086 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9087 message and returns control to the debugger. Repeat.
9088
9089 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9090 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9091 break, run to completion.).
9092
9093 =cut
9094
9095 END {
9096     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9097     $fall_off_end = 1 unless $inhibit_exit;
9098
9099     # Do not stop in at_exit() and destructors on exit:
9100     if ($fall_off_end or $runnonstop) {
9101         &save_hist();
9102     } else {
9103         $DB::single = 1;
9104         DB::fake::at_exit();
9105     }
9106 } ## end END
9107
9108 =head1 PRE-5.8 COMMANDS
9109
9110 Some of the commands changed function quite a bit in the 5.8 command
9111 realignment, so much so that the old code had to be replaced completely.
9112 Because we wanted to retain the option of being able to go back to the
9113 former command set, we moved the old code off to this section.
9114
9115 There's an awful lot of duplicated code here. We've duplicated the
9116 comments to keep things clear.
9117
9118 =head2 Null command
9119
9120 Does nothing. Used to I<turn off> commands.
9121
9122 =cut
9123
9124 sub cmd_pre580_null {
9125
9126     # do nothing...
9127 }
9128
9129 =head2 Old C<a> command.
9130
9131 This version added actions if you supplied them, and deleted them
9132 if you didn't.
9133
9134 =cut
9135
9136 sub cmd_pre580_a {
9137     my $xcmd = shift;
9138     my $cmd  = shift;
9139
9140     # Argument supplied. Add the action.
9141     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9142
9143         # If the line isn't there, use the current line.
9144         $i = $1 || $line;
9145         $j = $2;
9146
9147         # If there is an action ...
9148         if ( length $j ) {
9149
9150             # ... but the line isn't breakable, skip it.
9151             if ( $dbline[$i] == 0 ) {
9152                 print $OUT "Line $i may not have an action.\n";
9153             }
9154             else {
9155
9156                 # ... and the line is breakable:
9157                 # Mark that there's an action in this file.
9158                 $had_breakpoints{$filename} |= 2;
9159
9160                 # Delete any current action.
9161                 $dbline{$i} =~ s/\0[^\0]*//;
9162
9163                 # Add the new action, continuing the line as needed.
9164                 $dbline{$i} .= "\0" . action($j);
9165             }
9166         } ## end if (length $j)
9167
9168         # No action supplied.
9169         else {
9170
9171             # Delete the action.
9172             $dbline{$i} =~ s/\0[^\0]*//;
9173
9174             # Mark as having no break or action if nothing's left.
9175             delete $dbline{$i} if $dbline{$i} eq '';
9176         }
9177     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9178 } ## end sub cmd_pre580_a
9179
9180 =head2 Old C<b> command
9181
9182 Add breakpoints.
9183
9184 =cut
9185
9186 sub cmd_pre580_b {
9187     my $xcmd   = shift;
9188     my $cmd    = shift;
9189     my $dbline = shift;
9190
9191     # Break on load.
9192     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9193         my $file = $1;
9194         $file =~ s/\s+$//;
9195         &cmd_b_load($file);
9196     }
9197
9198     # b compile|postpone <some sub> [<condition>]
9199     # The interpreter actually traps this one for us; we just put the
9200     # necessary condition in the %postponed hash.
9201     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9202
9203         # Capture the condition if there is one. Make it true if none.
9204         my $cond = length $3 ? $3 : '1';
9205
9206         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9207         # if it was 'compile'.
9208         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9209
9210         # De-Perl4-ify the name - ' separators to ::.
9211         $subname =~ s/\'/::/g;
9212
9213         # Qualify it into the current package unless it's already qualified.
9214         $subname = "${'package'}::" . $subname
9215           unless $subname =~ /::/;
9216
9217         # Add main if it starts with ::.
9218         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9219
9220         # Save the break type for this sub.
9221         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9222     } ## end elsif ($cmd =~ ...
9223
9224     # b <sub name> [<condition>]
9225     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9226         my $subname = $1;
9227         my $cond = length $2 ? $2 : '1';
9228         &cmd_b_sub( $subname, $cond );
9229     }
9230
9231     # b <line> [<condition>].
9232     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9233         my $i = $1 || $dbline;
9234         my $cond = length $2 ? $2 : '1';
9235         &cmd_b_line( $i, $cond );
9236     }
9237 } ## end sub cmd_pre580_b
9238
9239 =head2 Old C<D> command.
9240
9241 Delete all breakpoints unconditionally.
9242
9243 =cut
9244
9245 sub cmd_pre580_D {
9246     my $xcmd = shift;
9247     my $cmd  = shift;
9248     if ( $cmd =~ /^\s*$/ ) {
9249         print $OUT "Deleting all breakpoints...\n";
9250
9251         # %had_breakpoints lists every file that had at least one
9252         # breakpoint in it.
9253         my $file;
9254         for $file ( keys %had_breakpoints ) {
9255
9256             # Switch to the desired file temporarily.
9257             local *dbline = $main::{ '_<' . $file };
9258
9259             my $max = $#dbline;
9260             my $was;
9261
9262             # For all lines in this file ...
9263             for ( $i = 1 ; $i <= $max ; $i++ ) {
9264
9265                 # If there's a breakpoint or action on this line ...
9266                 if ( defined $dbline{$i} ) {
9267
9268                     # ... remove the breakpoint.
9269                     $dbline{$i} =~ s/^[^\0]+//;
9270                     if ( $dbline{$i} =~ s/^\0?$// ) {
9271
9272                         # Remove the entry altogether if no action is there.
9273                         delete $dbline{$i};
9274                     }
9275                 } ## end if (defined $dbline{$i...
9276             } ## end for ($i = 1 ; $i <= $max...
9277
9278             # If, after we turn off the "there were breakpoints in this file"
9279             # bit, the entry in %had_breakpoints for this file is zero,
9280             # we should remove this file from the hash.
9281             if ( not $had_breakpoints{$file} &= ~1 ) {
9282                 delete $had_breakpoints{$file};
9283             }
9284         } ## end for $file (keys %had_breakpoints)
9285
9286         # Kill off all the other breakpoints that are waiting for files that
9287         # haven't been loaded yet.
9288         undef %postponed;
9289         undef %postponed_file;
9290         undef %break_on_load;
9291     } ## end if ($cmd =~ /^\s*$/)
9292 } ## end sub cmd_pre580_D
9293
9294 =head2 Old C<h> command
9295
9296 Print help. Defaults to printing the long-form help; the 5.8 version
9297 prints the summary by default.
9298
9299 =cut
9300
9301 sub cmd_pre580_h {
9302     my $xcmd = shift;
9303     my $cmd  = shift;
9304
9305     # Print the *right* help, long format.
9306     if ( $cmd =~ /^\s*$/ ) {
9307         print_help($pre580_help);
9308     }
9309
9310     # 'h h' - explicitly-requested summary.
9311     elsif ( $cmd =~ /^h\s*/ ) {
9312         print_help($pre580_summary);
9313     }
9314
9315     # Find and print a command's help.
9316     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9317         my $asked  = $1;                   # for proper errmsg
9318         my $qasked = quotemeta($asked);    # for searching
9319                                            # XXX: finds CR but not <CR>
9320         if (
9321             $pre580_help =~ /^
9322                               <?           # Optional '<'
9323                               (?:[IB]<)    # Optional markup
9324                               $qasked      # The command name
9325                             /mx
9326           )
9327         {
9328
9329             while (
9330                 $pre580_help =~ /^
9331                                   (             # The command help:
9332                                    <?           # Optional '<'
9333                                    (?:[IB]<)    # Optional markup
9334                                    $qasked      # The command name
9335                                    ([\s\S]*?)   # Lines starting with tabs
9336                                    \n           # Final newline
9337                                   )
9338                                   (?!\s)/mgx
9339               )    # Line not starting with space
9340                    # (Next command's help)
9341             {
9342                 print_help($1);
9343             }
9344         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9345
9346         # Help not found.
9347         else {
9348             print_help("B<$asked> is not a debugger command.\n");
9349         }
9350     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9351 } ## end sub cmd_pre580_h
9352
9353 =head2 Old C<W> command
9354
9355 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9356
9357 =cut
9358
9359 sub cmd_pre580_W {
9360     my $xcmd = shift;
9361     my $cmd  = shift;
9362
9363     # Delete all watch expressions.
9364     if ( $cmd =~ /^$/ ) {
9365
9366         # No watching is going on.
9367         $trace &= ~2;
9368
9369         # Kill all the watch expressions and values.
9370         @to_watch = @old_watch = ();
9371     }
9372
9373     # Add a watch expression.
9374     elsif ( $cmd =~ /^(.*)/s ) {
9375
9376         # add it to the list to be watched.
9377         push @to_watch, $1;
9378
9379         # Get the current value of the expression.
9380         # Doesn't handle expressions returning list values!
9381         $evalarg = $1;
9382         my ($val) = &eval;
9383         $val = ( defined $val ) ? "'$val'" : 'undef';
9384
9385         # Save it.
9386         push @old_watch, $val;
9387
9388         # We're watching stuff.
9389         $trace |= 2;
9390
9391     } ## end elsif ($cmd =~ /^(.*)/s)
9392 } ## end sub cmd_pre580_W
9393
9394 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9395
9396 The debugger used to have a bunch of nearly-identical code to handle
9397 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9398 C<cmd_prepost> unify all this into one set of code to handle the
9399 appropriate actions.
9400
9401 =head2 C<cmd_pre590_prepost>
9402
9403 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9404 do something destructive. In pre 5.8 debuggers, the default action was to
9405 delete all the actions.
9406
9407 =cut
9408
9409 sub cmd_pre590_prepost {
9410     my $cmd    = shift;
9411     my $line   = shift || '*';
9412     my $dbline = shift;
9413
9414     return &cmd_prepost( $cmd, $line, $dbline );
9415 } ## end sub cmd_pre590_prepost
9416
9417 =head2 C<cmd_prepost>
9418
9419 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9420 Since the lists of actions are all held in arrays that are pointed to by
9421 references anyway, all we have to do is pick the right array reference and
9422 then use generic code to all, delete, or list actions.
9423
9424 =cut
9425
9426 sub cmd_prepost {
9427     my $cmd = shift;
9428
9429     # No action supplied defaults to 'list'.
9430     my $line = shift || '?';
9431
9432     # Figure out what to put in the prompt.
9433     my $which = '';
9434
9435     # Make sure we have some array or another to address later.
9436     # This means that if ssome reason the tests fail, we won't be
9437     # trying to stash actions or delete them from the wrong place.
9438     my $aref = [];
9439
9440     # < - Perl code to run before prompt.
9441     if ( $cmd =~ /^\</o ) {
9442         $which = 'pre-perl';
9443         $aref  = $pre;
9444     }
9445
9446     # > - Perl code to run after prompt.
9447     elsif ( $cmd =~ /^\>/o ) {
9448         $which = 'post-perl';
9449         $aref  = $post;
9450     }
9451
9452     # { - first check for properly-balanced braces.
9453     elsif ( $cmd =~ /^\{/o ) {
9454         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9455             print $OUT
9456 "$cmd is now a debugger command\nuse `;$cmd' if you mean Perl code\n";
9457         }
9458
9459         # Properly balanced. Pre-prompt debugger actions.
9460         else {
9461             $which = 'pre-debugger';
9462             $aref  = $pretype;
9463         }
9464     } ## end elsif ( $cmd =~ /^\{/o )
9465
9466     # Did we find something that makes sense?
9467     unless ($which) {
9468         print $OUT "Confused by command: $cmd\n";
9469     }
9470
9471     # Yes.
9472     else {
9473
9474         # List actions.
9475         if ( $line =~ /^\s*\?\s*$/o ) {
9476             unless (@$aref) {
9477
9478                 # Nothing there. Complain.
9479                 print $OUT "No $which actions.\n";
9480             }
9481             else {
9482
9483                 # List the actions in the selected list.
9484                 print $OUT "$which commands:\n";
9485                 foreach my $action (@$aref) {
9486                     print $OUT "\t$cmd -- $action\n";
9487                 }
9488             } ## end else
9489         } ## end if ( $line =~ /^\s*\?\s*$/o)
9490
9491         # Might be a delete.
9492         else {
9493             if ( length($cmd) == 1 ) {
9494                 if ( $line =~ /^\s*\*\s*$/o ) {
9495
9496                     # It's a delete. Get rid of the old actions in the
9497                     # selected list..
9498                     @$aref = ();
9499                     print $OUT "All $cmd actions cleared.\n";
9500                 }
9501                 else {
9502
9503                     # Replace all the actions. (This is a <, >, or {).
9504                     @$aref = action($line);
9505                 }
9506             } ## end if ( length($cmd) == 1)
9507             elsif ( length($cmd) == 2 ) {
9508
9509                 # Add the action to the line. (This is a <<, >>, or {{).
9510                 push @$aref, action($line);
9511             }
9512             else {
9513
9514                 # <<<, >>>>, {{{{{{ ... something not a command.
9515                 print $OUT
9516                   "Confused by strange length of $which command($cmd)...\n";
9517             }
9518         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9519     } ## end else
9520 } ## end sub cmd_prepost
9521
9522 =head1 C<DB::fake>
9523
9524 Contains the C<at_exit> routine that the debugger uses to issue the
9525 C<Debugged program terminated ...> message after the program completes. See
9526 the C<END> block documentation for more details.
9527
9528 =cut
9529
9530 package DB::fake;
9531
9532 sub at_exit {
9533     "Debugged program terminated.  Use `q' to quit or `R' to restart.";
9534 }
9535
9536 package DB;    # Do not trace this 1; below!
9537
9538 1;
9539
9540