t/porting/exec-bit.t

   1 #!/perl -w
   2 use 5.010;
   3 use strict;
   4
   5 # This test checks that anything with an executable bit is
   6 # identified in Porting/exec-bit.txt to makerel will set
   7 # the exe bit in the release tarball
   8
   9 require './test.pl';
  10 if ( $^O eq "MSWin32" ) {
  11   skip_all( "-x on MSWin32 only indicates file has executable suffix. Try Cygwin?" );
  12 }
  13
  14 if ( $^O eq "VMS" ) {
  15   skip_all( "Filename case may not be preserved and other porting issues." );
  16 }
  17
  18 plan('no_plan');
  19
  20 use ExtUtils::Manifest qw(maniread);
  21 use File::Basename;
  22 use File::Find;
  23 use File::Spec::Functions;
  24
  25 # Copied from Porting/makerel - these will get +x in the tarball
  26 # XXX refactor? -- dagolden, 2010-07-23
  27 my %exe_list =
  28   map   { $_ => 1 }
  29   map   { my ($f) = split; glob("../$f") }
  30   grep  { $_ !~ /\A#/ && $_ !~ /\A\s*\z/ }
  31   map   { split "\n" }
  32   do    { local (@ARGV, $/) = '../Porting/exec-bit.txt'; <> };
  33
  34 # Get MANIFEST
  35 $ExtUtils::Manifest::Quiet = 1;
  36 my @manifest = sort keys %{ maniread("../MANIFEST") };
  37
  38 # Check that +x files in repo get +x from makerel
  39 for my $f ( map { "../$_" } @manifest ) {
  40   next unless -x $f;
  41
  42   ok( $exe_list{$f}, "tarball will chmod +x $f" )
  43     or diag( "Remove the exec bit or add '$f' to Porting/exec-bit.txt" );
  44
  45   delete $exe_list{$f}; # seen it
  46 }
  47
  48 ok( ! %exe_list, "Everything in Porting/exec-bit.txt has +x in repo" )
  49   or diag( "Files missing exec bit:\n  " . join("\n  ", sort keys %exe_list) . "\n");
  50