lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 use Cwd ();
 516
 517 my $_initial_cwd;
 518
 519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 520
 521 BEGIN {
 522     require feature;
 523     $^V =~ /^v(\d+\.\d+)/;
 524     feature->import(":$1");
 525     $_initial_cwd = Cwd::getcwd();
 526 }
 527
 528 # Debugger for Perl 5.00x; perl5db.pl patch level:
 529 use vars qw($VERSION $header);
 530
 531 $VERSION = '1.49_01';
 532
 533 $header = "perl5db.pl version $VERSION";
 534
 535 =head1 DEBUGGER ROUTINES
 536
 537 =head2 C<DB::eval()>
 538
 539 This function replaces straight C<eval()> inside the debugger; it simplifies
 540 the process of evaluating code in the user's context.
 541
 542 The code to be evaluated is passed via the package global variable
 543 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 544
 545 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 546 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 547 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 548 user's current package, grabbed when C<DB::DB> got control.  This causes the
 549 proper context to be used when the eval is actually done.  Afterward, we
 550 restore C<$trace>, C<$single>, and C<$^D>.
 551
 552 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 553 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 554 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 555 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 556 considered sane by the debugger. If there was an C<eval()> error, we print
 557 it on the debugger's output. If C<$onetimedump> is defined, we call
 558 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 559 'methods'. Setting it to something else causes the debugger to do the eval
 560 but not print the result - handy if you want to do something else with it
 561 (the "watch expressions" code does this to get the value of the watch
 562 expression but not show it unless it matters).
 563
 564 In any case, we then return the list of output from C<eval> to the caller,
 565 and unwinding restores the former version of C<$@> in C<@saved> as well
 566 (the localization of C<$saved[0]> goes away at the end of this scope).
 567
 568 =head3 Parameters and variables influencing execution of DB::eval()
 569
 570 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 571 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 572 The variables listed below influence C<DB::eval()>'s execution directly.
 573
 574 =over 4
 575
 576 =item C<$evalarg> - the thing to actually be eval'ed
 577
 578 =item C<$trace> - Current state of execution tracing
 579
 580 =item C<$single> - Current state of single-stepping
 581
 582 =item C<$onetimeDump> - what is to be displayed after the evaluation
 583
 584 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 585
 586 =back
 587
 588 The following variables are altered by C<DB::eval()> during its execution. They
 589 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 590
 591 =over 4
 592
 593 =item C<@res> - used to capture output from actual C<eval>.
 594
 595 =item C<$otrace> - saved value of C<$trace>.
 596
 597 =item C<$osingle> - saved value of C<$single>.
 598
 599 =item C<$od> - saved value of C<$^D>.
 600
 601 =item C<$saved[0]> - saved value of C<$@>.
 602
 603 =item $\ - for output of C<$@> if there is an evaluation error.
 604
 605 =back
 606
 607 =head3 The problem of lexicals
 608
 609 The context of C<DB::eval()> presents us with some problems. Obviously,
 610 we want to be 'sandboxed' away from the debugger's internals when we do
 611 the eval, but we need some way to control how punctuation variables and
 612 debugger globals are used.
 613
 614 We can't use local, because the code inside C<DB::eval> can see localized
 615 variables; and we can't use C<my> either for the same reason. The code
 616 in this routine compromises and uses C<my>.
 617
 618 After this routine is over, we don't have user code executing in the debugger's
 619 context, so we can use C<my> freely.
 620
 621 =cut
 622
 623 ############################################## Begin lexical danger zone
 624
 625 # 'my' variables used here could leak into (that is, be visible in)
 626 # the context that the code being evaluated is executing in. This means that
 627 # the code could modify the debugger's variables.
 628 #
 629 # Fiddling with the debugger's context could be Bad. We insulate things as
 630 # much as we can.
 631
 632 use vars qw(
 633     @args
 634     %break_on_load
 635     $CommandSet
 636     $CreateTTY
 637     $DBGR
 638     @dbline
 639     $dbline
 640     %dbline
 641     $dieLevel
 642     $filename
 643     $histfile
 644     $histsize
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $maxtrace
 650     $od
 651     @options
 652     $osingle
 653     $otrace
 654     $pager
 655     $post
 656     %postponed
 657     $prc
 658     $pre
 659     $pretype
 660     $psh
 661     @RememberOnROptions
 662     $remoteport
 663     @res
 664     $rl
 665     @saved
 666     $signalLevel
 667     $sub
 668     $term
 669     $usercontext
 670     $warnLevel
 671 );
 672
 673 our (
 674     @cmdfhs,
 675     $evalarg,
 676     $frame,
 677     $hist,
 678     $ImmediateStop,
 679     $line,
 680     $onetimeDump,
 681     $onetimedumpDepth,
 682     %option,
 683     $OUT,
 684     $packname,
 685     $signal,
 686     $single,
 687     $start,
 688     %sub,
 689     $subname,
 690     $trace,
 691     $window,
 692 );
 693
 694 # Used to save @ARGV and extract any debugger-related flags.
 695 use vars qw(@ARGS);
 696
 697 # Used to prevent multiple entries to diesignal()
 698 # (if for instance diesignal() itself dies)
 699 use vars qw($panic);
 700
 701 # Used to prevent the debugger from running nonstop
 702 # after a restart
 703 our ($second_time);
 704
 705 sub _calc_usercontext {
 706     my ($package) = @_;
 707
 708     # Cancel strict completely for the evaluated code, so the code
 709     # the user evaluates won't be affected by it. (Shlomi Fish)
 710     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 711     . "package $package;";    # this won't let them modify, alas
 712 }
 713
 714 sub eval {
 715
 716     # 'my' would make it visible from user code
 717     #    but so does local! --tchrist
 718     # Remember: this localizes @DB::res, not @main::res.
 719     local @res;
 720     {
 721
 722         # Try to keep the user code from messing  with us. Save these so that
 723         # even if the eval'ed code changes them, we can put them back again.
 724         # Needed because the user could refer directly to the debugger's
 725         # package globals (and any 'my' variables in this containing scope)
 726         # inside the eval(), and we want to try to stay safe.
 727         local $otrace  = $trace;
 728         local $osingle = $single;
 729         local $od      = $^D;
 730
 731         # Untaint the incoming eval() argument.
 732         { ($evalarg) = $evalarg =~ /(.*)/s; }
 733
 734         # $usercontext built in DB::DB near the comment
 735         # "set up the context for DB::eval ..."
 736         # Evaluate and save any results.
 737         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 738
 739         # Restore those old values.
 740         $trace  = $otrace;
 741         $single = $osingle;
 742         $^D     = $od;
 743     }
 744
 745     # Save the current value of $@, and preserve it in the debugger's copy
 746     # of the saved precious globals.
 747     my $at = $@;
 748
 749     # Since we're only saving $@, we only have to localize the array element
 750     # that it will be stored in.
 751     local $saved[0];    # Preserve the old value of $@
 752     eval { &DB::save };
 753
 754     # Now see whether we need to report an error back to the user.
 755     if ($at) {
 756         local $\ = '';
 757         print $OUT $at;
 758     }
 759
 760     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 761     # are package globals.
 762     elsif ($onetimeDump) {
 763         if ( $onetimeDump eq 'dump' ) {
 764             local $option{dumpDepth} = $onetimedumpDepth
 765               if defined $onetimedumpDepth;
 766             dumpit( $OUT, \@res );
 767         }
 768         elsif ( $onetimeDump eq 'methods' ) {
 769             methods( $res[0] );
 770         }
 771     } ## end elsif ($onetimeDump)
 772     @res;
 773 } ## end sub eval
 774
 775 ############################################## End lexical danger zone
 776
 777 # After this point it is safe to introduce lexicals.
 778 # The code being debugged will be executing in its own context, and
 779 # can't see the inside of the debugger.
 780 #
 781 # However, one should not overdo it: leave as much control from outside as
 782 # possible. If you make something a lexical, it's not going to be addressable
 783 # from outside the debugger even if you know its name.
 784
 785 # This file is automatically included if you do perl -d.
 786 # It's probably not useful to include this yourself.
 787 #
 788 # Before venturing further into these twisty passages, it is
 789 # wise to read the perldebguts man page or risk the ire of dragons.
 790 #
 791 # (It should be noted that perldebguts will tell you a lot about
 792 # the underlying mechanics of how the debugger interfaces into the
 793 # Perl interpreter, but not a lot about the debugger itself. The new
 794 # comments in this code try to address this problem.)
 795
 796 # Note that no subroutine call is possible until &DB::sub is defined
 797 # (for subroutines defined outside of the package DB). In fact the same is
 798 # true if $deep is not defined.
 799
 800 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 801
 802 # modified Perl debugger, to be run from Emacs in perldb-mode
 803 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 804 # Johan Vromans -- upgrade to 4.0 pl 10
 805 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 806 ########################################################################
 807
 808 =head1 DEBUGGER INITIALIZATION
 809
 810 The debugger starts up in phases.
 811
 812 =head2 BASIC SETUP
 813
 814 First, it initializes the environment it wants to run in: turning off
 815 warnings during its own compilation, defining variables which it will need
 816 to avoid warnings later, setting itself up to not exit when the program
 817 terminates, and defaulting to printing return values for the C<r> command.
 818
 819 =cut
 820
 821 # Needed for the statement after exec():
 822 #
 823 # This BEGIN block is simply used to switch off warnings during debugger
 824 # compilation. Probably it would be better practice to fix the warnings,
 825 # but this is how it's done at the moment.
 826
 827 BEGIN {
 828     $ini_warn = $^W;
 829     $^W       = 0;
 830 }    # Switch compilation warnings off until another BEGIN.
 831
 832 local ($^W) = 0;    # Switch run-time warnings off during init.
 833
 834 =head2 THREADS SUPPORT
 835
 836 If we are running under a threaded Perl, we require threads and threads::shared
 837 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 838 threaded debugger control.  C<-dt> can also be used to set this.
 839
 840 Each new thread will be announced and the debugger prompt will always inform
 841 you of each new thread created.  It will also indicate the thread id in which
 842 we are currently running within the prompt like this:
 843
 844     [tid] DB<$i>
 845
 846 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 847 command prompt.  The prompt will show: C<[0]> when running under threads, but
 848 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 849
 850 While running under threads, when you set or delete a breakpoint (etc.), this
 851 will apply to all threads, not just the currently running one.  When you are
 852 in a currently executing thread, you will stay there until it completes.  With
 853 the current implementation it is not currently possible to hop from one thread
 854 to another.
 855
 856 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 857
 858 Note that threading support was built into the debugger as of Perl version
 859 C<5.8.6> and debugger version C<1.2.8>.
 860
 861 =cut
 862
 863 BEGIN {
 864     # ensure we can share our non-threaded variables or no-op
 865     if ($ENV{PERL5DB_THREADED}) {
 866         require threads;
 867         require threads::shared;
 868         import threads::shared qw(share);
 869         $DBGR;
 870         share(\$DBGR);
 871         lock($DBGR);
 872         print "Threads support enabled\n";
 873     } else {
 874         *lock = sub(*) {};
 875         *share = sub(\[$@%]) {};
 876     }
 877 }
 878
 879 # These variables control the execution of 'dumpvar.pl'.
 880 {
 881     package dumpvar;
 882     use vars qw(
 883     $hashDepth
 884     $arrayDepth
 885     $dumpDBFiles
 886     $dumpPackages
 887     $quoteHighBit
 888     $printUndef
 889     $globPrint
 890     $usageOnly
 891     );
 892 }
 893
 894 # used to control die() reporting in diesignal()
 895 {
 896     package Carp;
 897     use vars qw($CarpLevel);
 898 }
 899
 900 # without threads, $filename is not defined until DB::DB is called
 901 share($main::{'_<'.$filename}) if defined $filename;
 902
 903 # Command-line + PERLLIB:
 904 # Save the contents of @INC before they are modified elsewhere.
 905 @ini_INC = @INC;
 906
 907 # This was an attempt to clear out the previous values of various
 908 # trapped errors. Apparently it didn't help. XXX More info needed!
 909 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 910
 911 # We set these variables to safe values. We don't want to blindly turn
 912 # off warnings, because other packages may still want them.
 913 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 914                                    # (local $^W cannot help - other packages!).
 915
 916 # Default to not exiting when program finishes; print the return
 917 # value when the 'r' command is used to return from a subroutine.
 918 $inhibit_exit = $option{PrintRet} = 1;
 919
 920 use vars qw($trace_to_depth);
 921
 922 # Default to 1E9 so it won't be limited to a certain recursion depth.
 923 $trace_to_depth = 1E9;
 924
 925 =head1 OPTION PROCESSING
 926
 927 The debugger's options are actually spread out over the debugger itself and
 928 C<dumpvar.pl>; some of these are variables to be set, while others are
 929 subs to be called with a value. To try to make this a little easier to
 930 manage, the debugger uses a few data structures to define what options
 931 are legal and how they are to be processed.
 932
 933 First, the C<@options> array defines the I<names> of all the options that
 934 are to be accepted.
 935
 936 =cut
 937
 938 @options = qw(
 939   CommandSet   HistFile      HistSize
 940   hashDepth    arrayDepth    dumpDepth
 941   DumpDBFiles  DumpPackages  DumpReused
 942   compactDump  veryCompact   quote
 943   HighBit      undefPrint    globPrint
 944   PrintRet     UsageOnly     frame
 945   AutoTrace    TTY           noTTY
 946   ReadLine     NonStop       LineInfo
 947   maxTraceLen  recallCommand ShellBang
 948   pager        tkRunning     ornaments
 949   signalLevel  warnLevel     dieLevel
 950   inhibit_exit ImmediateStop bareStringify
 951   CreateTTY    RemotePort    windowSize
 952   DollarCaretP
 953 );
 954
 955 @RememberOnROptions = qw(DollarCaretP);
 956
 957 =pod
 958
 959 Second, C<optionVars> lists the variables that each option uses to save its
 960 state.
 961
 962 =cut
 963
 964 use vars qw(%optionVars);
 965
 966 %optionVars = (
 967     hashDepth     => \$dumpvar::hashDepth,
 968     arrayDepth    => \$dumpvar::arrayDepth,
 969     CommandSet    => \$CommandSet,
 970     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 971     DumpPackages  => \$dumpvar::dumpPackages,
 972     DumpReused    => \$dumpvar::dumpReused,
 973     HighBit       => \$dumpvar::quoteHighBit,
 974     undefPrint    => \$dumpvar::printUndef,
 975     globPrint     => \$dumpvar::globPrint,
 976     UsageOnly     => \$dumpvar::usageOnly,
 977     CreateTTY     => \$CreateTTY,
 978     bareStringify => \$dumpvar::bareStringify,
 979     frame         => \$frame,
 980     AutoTrace     => \$trace,
 981     inhibit_exit  => \$inhibit_exit,
 982     maxTraceLen   => \$maxtrace,
 983     ImmediateStop => \$ImmediateStop,
 984     RemotePort    => \$remoteport,
 985     windowSize    => \$window,
 986     HistFile      => \$histfile,
 987     HistSize      => \$histsize,
 988 );
 989
 990 =pod
 991
 992 Third, C<%optionAction> defines the subroutine to be called to process each
 993 option.
 994
 995 =cut
 996
 997 use vars qw(%optionAction);
 998
 999 %optionAction = (
1000     compactDump   => \&dumpvar::compactDump,
1001     veryCompact   => \&dumpvar::veryCompact,
1002     quote         => \&dumpvar::quote,
1003     TTY           => \&TTY,
1004     noTTY         => \&noTTY,
1005     ReadLine      => \&ReadLine,
1006     NonStop       => \&NonStop,
1007     LineInfo      => \&LineInfo,
1008     recallCommand => \&recallCommand,
1009     ShellBang     => \&shellBang,
1010     pager         => \&pager,
1011     signalLevel   => \&signalLevel,
1012     warnLevel     => \&warnLevel,
1013     dieLevel      => \&dieLevel,
1014     tkRunning     => \&tkRunning,
1015     ornaments     => \&ornaments,
1016     RemotePort    => \&RemotePort,
1017     DollarCaretP  => \&DollarCaretP,
1018 );
1019
1020 =pod
1021
1022 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1023 option is used.
1024
1025 =cut
1026
1027 # Note that this list is not complete: several options not listed here
1028 # actually require that dumpvar.pl be loaded for them to work, but are
1029 # not in the table. A subsequent patch will correct this problem; for
1030 # the moment, we're just recommenting, and we are NOT going to change
1031 # function.
1032 use vars qw(%optionRequire);
1033
1034 %optionRequire = (
1035     compactDump => 'dumpvar.pl',
1036     veryCompact => 'dumpvar.pl',
1037     quote       => 'dumpvar.pl',
1038 );
1039
1040 =pod
1041
1042 There are a number of initialization-related variables which can be set
1043 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1044 variable. These are:
1045
1046 =over 4
1047
1048 =item C<$rl> - readline control XXX needs more explanation
1049
1050 =item C<$warnLevel> - whether or not debugger takes over warning handling
1051
1052 =item C<$dieLevel> - whether or not debugger takes over die handling
1053
1054 =item C<$signalLevel> - whether or not debugger takes over signal handling
1055
1056 =item C<$pre> - preprompt actions (array reference)
1057
1058 =item C<$post> - postprompt actions (array reference)
1059
1060 =item C<$pretype>
1061
1062 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1063
1064 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1065
1066 =back
1067
1068 =cut
1069
1070 # These guys may be defined in $ENV{PERL5DB} :
1071 $rl          = 1     unless defined $rl;
1072 $warnLevel   = 1     unless defined $warnLevel;
1073 $dieLevel    = 1     unless defined $dieLevel;
1074 $signalLevel = 1     unless defined $signalLevel;
1075 $pre         = []    unless defined $pre;
1076 $post        = []    unless defined $post;
1077 $pretype     = []    unless defined $pretype;
1078 $CreateTTY   = 3     unless defined $CreateTTY;
1079 $CommandSet  = '580' unless defined $CommandSet;
1080
1081 share($rl);
1082 share($warnLevel);
1083 share($dieLevel);
1084 share($signalLevel);
1085 share($pre);
1086 share($post);
1087 share($pretype);
1088 share($rl);
1089 share($CreateTTY);
1090 share($CommandSet);
1091
1092 =pod
1093
1094 The default C<die>, C<warn>, and C<signal> handlers are set up.
1095
1096 =cut
1097
1098 warnLevel($warnLevel);
1099 dieLevel($dieLevel);
1100 signalLevel($signalLevel);
1101
1102 =pod
1103
1104 The pager to be used is needed next. We try to get it from the
1105 environment first.  If it's not defined there, we try to find it in
1106 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1107 then call the C<pager()> function to save the pager name.
1108
1109 =cut
1110
1111 # This routine makes sure $pager is set up so that '|' can use it.
1112 pager(
1113
1114     # If PAGER is defined in the environment, use it.
1115     defined $ENV{PAGER}
1116     ? $ENV{PAGER}
1117
1118       # If not, see if Config.pm defines it.
1119     : eval { require Config }
1120       && defined $Config::Config{pager}
1121     ? $Config::Config{pager}
1122
1123       # If not, fall back to 'more'.
1124     : 'more'
1125   )
1126   unless defined $pager;
1127
1128 =pod
1129
1130 We set up the command to be used to access the man pages, the command
1131 recall character (C<!> unless otherwise defined) and the shell escape
1132 character (C<!> unless otherwise defined). Yes, these do conflict, and
1133 neither works in the debugger at the moment.
1134
1135 =cut
1136
1137 setman();
1138
1139 # Set up defaults for command recall and shell escape (note:
1140 # these currently don't work in linemode debugging).
1141 recallCommand("!") unless defined $prc;
1142 shellBang("!")     unless defined $psh;
1143
1144 =pod
1145
1146 We then set up the gigantic string containing the debugger help.
1147 We also set the limit on the number of arguments we'll display during a
1148 trace.
1149
1150 =cut
1151
1152 sethelp();
1153
1154 # If we didn't get a default for the length of eval/stack trace args,
1155 # set it here.
1156 $maxtrace = 400 unless defined $maxtrace;
1157
1158 =head2 SETTING UP THE DEBUGGER GREETING
1159
1160 The debugger I<greeting> helps to inform the user how many debuggers are
1161 running, and whether the current debugger is the primary or a child.
1162
1163 If we are the primary, we just hang onto our pid so we'll have it when
1164 or if we start a child debugger. If we are a child, we'll set things up
1165 so we'll have a unique greeting and so the parent will give us our own
1166 TTY later.
1167
1168 We save the current contents of the C<PERLDB_PIDS> environment variable
1169 because we mess around with it. We'll also need to hang onto it because
1170 we'll need it if we restart.
1171
1172 Child debuggers make a label out of the current PID structure recorded in
1173 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1174 yet so the parent will give them one later via C<resetterm()>.
1175
1176 =cut
1177
1178 # Save the current contents of the environment; we're about to
1179 # much with it. We'll need this if we have to restart.
1180 use vars qw($ini_pids);
1181 $ini_pids = $ENV{PERLDB_PIDS};
1182
1183 use vars qw ($pids $term_pid);
1184
1185 if ( defined $ENV{PERLDB_PIDS} ) {
1186
1187     # We're a child. Make us a label out of the current PID structure
1188     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1189     # a term yet so the parent will give us one later via resetterm().
1190
1191     my $env_pids = $ENV{PERLDB_PIDS};
1192     $pids = "[$env_pids]";
1193
1194     # Unless we are on OpenVMS, all programs under the DCL shell run under
1195     # the same PID.
1196
1197     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1198         $term_pid         = $$;
1199     }
1200     else {
1201         $ENV{PERLDB_PIDS} .= "->$$";
1202         $term_pid = -1;
1203     }
1204
1205 } ## end if (defined $ENV{PERLDB_PIDS...
1206 else {
1207
1208     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1209     # child debugger, and mark us as the parent, so we'll know to set up
1210     # more TTY's is we have to.
1211     $ENV{PERLDB_PIDS} = "$$";
1212     $pids             = "[pid=$$]";
1213     $term_pid         = $$;
1214 }
1215
1216 use vars qw($pidprompt);
1217 $pidprompt = '';
1218
1219 # Sets up $emacs as a synonym for $slave_editor.
1220 our ($slave_editor);
1221 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1222
1223 =head2 READING THE RC FILE
1224
1225 The debugger will read a file of initialization options if supplied. If
1226 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1227
1228 =cut
1229
1230 # As noted, this test really doesn't check accurately that the debugger
1231 # is running at a terminal or not.
1232
1233 use vars qw($rcfile);
1234 {
1235     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1236     # this is the wrong metric!
1237     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1238 }
1239
1240 =pod
1241
1242 The debugger does a safety test of the file to be read. It must be owned
1243 either by the current user or root, and must only be writable by the owner.
1244
1245 =cut
1246
1247 # This wraps a safety test around "do" to read and evaluate the init file.
1248 #
1249 # This isn't really safe, because there's a race
1250 # between checking and opening.  The solution is to
1251 # open and fstat the handle, but then you have to read and
1252 # eval the contents.  But then the silly thing gets
1253 # your lexical scope, which is unfortunate at best.
1254 sub safe_do {
1255     my $file = shift;
1256
1257     # Just exactly what part of the word "CORE::" don't you understand?
1258     local $SIG{__WARN__};
1259     local $SIG{__DIE__};
1260
1261     unless ( is_safe_file($file) ) {
1262         CORE::warn <<EO_GRIPE;
1263 perldb: Must not source insecure rcfile $file.
1264         You or the superuser must be the owner, and it must not
1265         be writable by anyone but its owner.
1266 EO_GRIPE
1267         return;
1268     } ## end unless (is_safe_file($file...
1269
1270     do $file;
1271     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1272 } ## end sub safe_do
1273
1274 # This is the safety test itself.
1275 #
1276 # Verifies that owner is either real user or superuser and that no
1277 # one but owner may write to it.  This function is of limited use
1278 # when called on a path instead of upon a handle, because there are
1279 # no guarantees that filename (by dirent) whose file (by ino) is
1280 # eventually accessed is the same as the one tested.
1281 # Assumes that the file's existence is not in doubt.
1282 sub is_safe_file {
1283     my $path = shift;
1284     stat($path) || return;    # mysteriously vaporized
1285     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1286
1287     return 0 if $uid != 0 && $uid != $<;
1288     return 0 if $mode & 022;
1289     return 1;
1290 } ## end sub is_safe_file
1291
1292 # If the rcfile (whichever one we decided was the right one to read)
1293 # exists, we safely do it.
1294 if ( -f $rcfile ) {
1295     safe_do("./$rcfile");
1296 }
1297
1298 # If there isn't one here, try the user's home directory.
1299 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1300     safe_do("$ENV{HOME}/$rcfile");
1301 }
1302
1303 # Else try the login directory.
1304 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1305     safe_do("$ENV{LOGDIR}/$rcfile");
1306 }
1307
1308 # If the PERLDB_OPTS variable has options in it, parse those out next.
1309 if ( defined $ENV{PERLDB_OPTS} ) {
1310     parse_options( $ENV{PERLDB_OPTS} );
1311 }
1312
1313 =pod
1314
1315 The last thing we do during initialization is determine which subroutine is
1316 to be used to obtain a new terminal when a new debugger is started. Right now,
1317 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1318 (darwin).
1319
1320 =cut
1321
1322 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1323 # Works if you're running an xterm or xterm-like window, or you're on
1324 # OS/2, or on Mac OS X. This may need some expansion.
1325
1326 if (not defined &get_fork_TTY)       # only if no routine exists
1327 {
1328     if ( defined $remoteport ) {
1329                                                  # Expect an inetd-like server
1330         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1331     }
1332     elsif (defined $ENV{TERM}                    # If we know what kind
1333                                                  # of terminal this is,
1334         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1335         and defined $ENV{DISPLAY}                # and what display it's on,
1336       )
1337     {
1338         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1339     }
1340     elsif ( $ENV{TMUX} ) {
1341         *get_fork_TTY = \&tmux_get_fork_TTY;
1342     }
1343     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1344         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1345     }
1346     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1347             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1348             and $ENV{TERM_PROGRAM}
1349                 eq 'Apple_Terminal'              # Terminal.app
1350             )
1351     {
1352         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1353     }
1354 } ## end if (not defined &get_fork_TTY...
1355
1356 # untaint $^O, which may have been tainted by the last statement.
1357 # see bug [perl #24674]
1358 $^O =~ m/^(.*)\z/;
1359 $^O = $1;
1360
1361 # Here begin the unreadable code.  It needs fixing.
1362
1363 =head2 RESTART PROCESSING
1364
1365 This section handles the restart command. When the C<R> command is invoked, it
1366 tries to capture all of the state it can into environment variables, and
1367 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1368 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1369 the R command stuffed into the environment variables.
1370
1371   PERLDB_RESTART   - flag only, contains no restart data itself.
1372   PERLDB_HIST      - command history, if it's available
1373   PERLDB_ON_LOAD   - breakpoints set by the rc file
1374   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1375                      and have actions
1376   PERLDB_VISITED   - files that had breakpoints
1377   PERLDB_FILE_...  - breakpoints for a file
1378   PERLDB_OPT       - active options
1379   PERLDB_INC       - the original @INC
1380   PERLDB_PRETYPE   - preprompt debugger actions
1381   PERLDB_PRE       - preprompt Perl code
1382   PERLDB_POST      - post-prompt Perl code
1383   PERLDB_TYPEAHEAD - typeahead captured by readline()
1384
1385 We chug through all these variables and plug the values saved in them
1386 back into the appropriate spots in the debugger.
1387
1388 =cut
1389
1390 use vars qw(%postponed_file @typeahead);
1391
1392 our (@hist, @truehist);
1393
1394 sub _restore_shared_globals_after_restart
1395 {
1396     @hist          = get_list('PERLDB_HIST');
1397     %break_on_load = get_list("PERLDB_ON_LOAD");
1398     %postponed     = get_list("PERLDB_POSTPONE");
1399
1400     share(@hist);
1401     share(@truehist);
1402     share(%break_on_load);
1403     share(%postponed);
1404 }
1405
1406 sub _restore_breakpoints_and_actions {
1407
1408     my @had_breakpoints = get_list("PERLDB_VISITED");
1409
1410     for my $file_idx ( 0 .. $#had_breakpoints ) {
1411         my $filename = $had_breakpoints[$file_idx];
1412         my %pf = get_list("PERLDB_FILE_$file_idx");
1413         $postponed_file{ $filename } = \%pf if %pf;
1414         my @lines = sort {$a <=> $b} keys(%pf);
1415         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1416         for my $line_idx (0 .. $#lines) {
1417             _set_breakpoint_enabled_status(
1418                 $filename,
1419                 $lines[$line_idx],
1420                 ($enabled_statuses[$line_idx] ? 1 : ''),
1421             );
1422         }
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_options_after_restart
1429 {
1430     my %options_map = get_list("PERLDB_OPT");
1431
1432     while ( my ( $opt, $val ) = each %options_map ) {
1433         $val =~ s/[\\\']/\\$1/g;
1434         parse_options("$opt'$val'");
1435     }
1436
1437     return;
1438 }
1439
1440 sub _restore_globals_after_restart
1441 {
1442     # restore original @INC
1443     @INC     = get_list("PERLDB_INC");
1444     @ini_INC = @INC;
1445
1446     # return pre/postprompt actions and typeahead buffer
1447     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1448     $pre       = [ get_list("PERLDB_PRE") ];
1449     $post      = [ get_list("PERLDB_POST") ];
1450     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1451
1452     return;
1453 }
1454
1455
1456 if ( exists $ENV{PERLDB_RESTART} ) {
1457
1458     # We're restarting, so we don't need the flag that says to restart anymore.
1459     delete $ENV{PERLDB_RESTART};
1460
1461     # $restart = 1;
1462     _restore_shared_globals_after_restart();
1463
1464     _restore_breakpoints_and_actions();
1465
1466     # restore options
1467     _restore_options_after_restart();
1468
1469     _restore_globals_after_restart();
1470 } ## end if (exists $ENV{PERLDB_RESTART...
1471
1472 =head2 SETTING UP THE TERMINAL
1473
1474 Now, we'll decide how the debugger is going to interact with the user.
1475 If there's no TTY, we set the debugger to run non-stop; there's not going
1476 to be anyone there to enter commands.
1477
1478 =cut
1479
1480 use vars qw($notty $console $tty $LINEINFO);
1481 use vars qw($lineinfo $doccmd);
1482
1483 our ($runnonstop);
1484
1485 # Local autoflush to avoid rt#116769,
1486 # as calling IO::File methods causes an unresolvable loop
1487 # that results in debugger failure.
1488 sub _autoflush {
1489     my $o = select($_[0]);
1490     $|++;
1491     select($o);
1492 }
1493
1494 if ($notty) {
1495     $runnonstop = 1;
1496     share($runnonstop);
1497 }
1498
1499 =pod
1500
1501 If there is a TTY, we have to determine who it belongs to before we can
1502 proceed. If this is a slave editor or graphical debugger (denoted by
1503 the first command-line switch being '-emacs'), we shift this off and
1504 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1505
1506 =cut
1507
1508 else {
1509
1510     # Is Perl being run from a slave editor or graphical debugger?
1511     # If so, don't use readline, and set $slave_editor = 1.
1512     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1513         $rl = 0;
1514         shift(@main::ARGV);
1515     }
1516
1517     #require Term::ReadLine;
1518
1519 =pod
1520
1521 We then determine what the console should be on various systems:
1522
1523 =over 4
1524
1525 =item * Cygwin - We use C<stdin> instead of a separate device.
1526
1527 =cut
1528
1529     if ( $^O eq 'cygwin' ) {
1530
1531         # /dev/tty is binary. use stdin for textmode
1532         undef $console;
1533     }
1534
1535 =item * Unix - use F</dev/tty>.
1536
1537 =cut
1538
1539     elsif ( -e "/dev/tty" ) {
1540         $console = "/dev/tty";
1541     }
1542
1543 =item * Windows or MSDOS - use C<con>.
1544
1545 =cut
1546
1547     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1548         $console = "con";
1549     }
1550
1551 =item * VMS - use C<sys$command>.
1552
1553 =cut
1554
1555     else {
1556
1557         # everything else is ...
1558         $console = "sys\$command";
1559     }
1560
1561 =pod
1562
1563 =back
1564
1565 Several other systems don't use a specific console. We C<undef $console>
1566 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1567 with a slave editor).
1568
1569 =cut
1570
1571     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1572
1573         # /dev/tty is binary. use stdin for textmode
1574         $console = undef;
1575     }
1576
1577     if ( $^O eq 'NetWare' ) {
1578
1579         # /dev/tty is binary. use stdin for textmode
1580         $console = undef;
1581     }
1582
1583     # In OS/2, we need to use STDIN to get textmode too, even though
1584     # it pretty much looks like Unix otherwise.
1585     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1586     {    # In OS/2
1587         $console = undef;
1588     }
1589
1590 =pod
1591
1592 If there is a TTY hanging around from a parent, we use that as the console.
1593
1594 =cut
1595
1596     $console = $tty if defined $tty;
1597
1598 =head2 SOCKET HANDLING
1599
1600 The debugger is capable of opening a socket and carrying out a debugging
1601 session over the socket.
1602
1603 If C<RemotePort> was defined in the options, the debugger assumes that it
1604 should try to start a debugging session on that port. It builds the socket
1605 and then tries to connect the input and output filehandles to it.
1606
1607 =cut
1608
1609     # Handle socket stuff.
1610
1611     if ( defined $remoteport ) {
1612
1613         # If RemotePort was defined in the options, connect input and output
1614         # to the socket.
1615         $IN = $OUT = connect_remoteport();
1616     } ## end if (defined $remoteport)
1617
1618 =pod
1619
1620 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1621 this is probably a situation where multiple debuggers are running (for example,
1622 a backticked command that starts up another debugger). We create a new IN and
1623 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1624 and if we can.
1625
1626 =cut
1627
1628     # Non-socket.
1629     else {
1630
1631         # Two debuggers running (probably a system or a backtick that invokes
1632         # the debugger itself under the running one). create a new IN and OUT
1633         # filehandle, and do the necessary mojo to create a new tty if we
1634         # know how, and we can.
1635         create_IN_OUT(4) if $CreateTTY & 4;
1636         if ($console) {
1637
1638             # If we have a console, check to see if there are separate ins and
1639             # outs to open. (They are assumed identical if not.)
1640
1641             my ( $i, $o ) = split /,/, $console;
1642             $o = $i unless defined $o;
1643
1644             # read/write on in, or just read, or read on STDIN.
1645             open( IN,      "+<$i" )
1646               || open( IN, "<$i" )
1647               || open( IN, "<&STDIN" );
1648
1649             # read/write/create/clobber out, or write/create/clobber out,
1650             # or merge with STDERR, or merge with STDOUT.
1651                  open( OUT, "+>$o" )
1652               || open( OUT, ">$o" )
1653               || open( OUT, ">&STDERR" )
1654               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1655
1656         } ## end if ($console)
1657         elsif ( not defined $console ) {
1658
1659             # No console. Open STDIN.
1660             open( IN, "<&STDIN" );
1661
1662             # merge with STDERR, or with STDOUT.
1663             open( OUT,      ">&STDERR" )
1664               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1665             $console = 'STDIN/OUT';
1666         } ## end elsif (not defined $console)
1667
1668         # Keep copies of the filehandles so that when the pager runs, it
1669         # can close standard input without clobbering ours.
1670         if ($console or (not defined($console))) {
1671             $IN = \*IN;
1672             $OUT = \*OUT;
1673         }
1674     } ## end elsif (from if(defined $remoteport))
1675
1676     # Unbuffer DB::OUT. We need to see responses right away.
1677     _autoflush($OUT);
1678
1679     # Line info goes to debugger output unless pointed elsewhere.
1680     # Pointing elsewhere makes it possible for slave editors to
1681     # keep track of file and position. We have both a filehandle
1682     # and a I/O description to keep track of.
1683     $LINEINFO = $OUT     unless defined $LINEINFO;
1684     $lineinfo = $console unless defined $lineinfo;
1685     # share($LINEINFO); # <- unable to share globs
1686     share($lineinfo);   #
1687
1688 =pod
1689
1690 To finish initialization, we show the debugger greeting,
1691 and then call the C<afterinit()> subroutine if there is one.
1692
1693 =cut
1694
1695     # Show the debugger greeting.
1696     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1697     unless ($runnonstop) {
1698         local $\ = '';
1699         local $, = '';
1700         if ( $term_pid eq '-1' ) {
1701             print $OUT "\nDaughter DB session started...\n";
1702         }
1703         else {
1704             print $OUT "\nLoading DB routines from $header\n";
1705             print $OUT (
1706                 "Editor support ",
1707                 $slave_editor ? "enabled" : "available", ".\n"
1708             );
1709             print $OUT
1710 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1711         } ## end else [ if ($term_pid eq '-1')
1712     } ## end unless ($runnonstop)
1713 } ## end else [ if ($notty)
1714
1715 # XXX This looks like a bug to me.
1716 # Why copy to @ARGS and then futz with @args?
1717 @ARGS = @ARGV;
1718 # for (@args) {
1719     # Make sure backslashes before single quotes are stripped out, and
1720     # keep args unless they are numeric (XXX why?)
1721     # s/\'/\\\'/g;                      # removed while not justified understandably
1722     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1723 # }
1724
1725 # If there was an afterinit() sub defined, call it. It will get
1726 # executed in our scope, so it can fiddle with debugger globals.
1727 if ( defined &afterinit ) {    # May be defined in $rcfile
1728     afterinit();
1729 }
1730
1731 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1732 use vars qw($I_m_init);
1733
1734 $I_m_init = 1;
1735
1736 ############################################################ Subroutines
1737
1738 =head1 SUBROUTINES
1739
1740 =head2 DB
1741
1742 This gigantic subroutine is the heart of the debugger. Called before every
1743 statement, its job is to determine if a breakpoint has been reached, and
1744 stop if so; read commands from the user, parse them, and execute
1745 them, and then send execution off to the next statement.
1746
1747 Note that the order in which the commands are processed is very important;
1748 some commands earlier in the loop will actually alter the C<$cmd> variable
1749 to create other commands to be executed later. This is all highly I<optimized>
1750 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1751 see what's happening in any given command.
1752
1753 =cut
1754
1755 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1756
1757 use vars qw(
1758     $action
1759     $cmd
1760     $file
1761     $filename_ini
1762     $finished
1763     %had_breakpoints
1764     $level
1765     $max
1766     $package
1767     $try
1768 );
1769
1770 our (
1771     %alias,
1772     $doret,
1773     $end,
1774     $fall_off_end,
1775     $incr,
1776     $laststep,
1777     $rc,
1778     $sh,
1779     $stack_depth,
1780     @stack,
1781     @to_watch,
1782     @old_watch,
1783 );
1784
1785 sub _DB__determine_if_we_should_break
1786 {
1787     # if we have something here, see if we should break.
1788     # $stop is lexical and local to this block - $action on the other hand
1789     # is global.
1790     my $stop;
1791
1792     if ( $dbline{$line}
1793         && _is_breakpoint_enabled($filename, $line)
1794         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1795     {
1796
1797         # Stop if the stop criterion says to just stop.
1798         if ( $stop eq '1' ) {
1799             $signal |= 1;
1800         }
1801
1802         # It's a conditional stop; eval it in the user's context and
1803         # see if we should stop. If so, remove the one-time sigil.
1804         elsif ($stop) {
1805             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1806             # The &-call is here to ascertain the mutability of @_.
1807             &DB::eval;
1808             # If the breakpoint is temporary, then delete its enabled status.
1809             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1810                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1811             }
1812         }
1813     } ## end if ($dbline{$line} && ...
1814 }
1815
1816 sub _DB__is_finished {
1817     if ($finished and $level <= 1) {
1818         end_report();
1819         return 1;
1820     }
1821     else {
1822         return;
1823     }
1824 }
1825
1826 sub _DB__read_next_cmd
1827 {
1828     my ($tid) = @_;
1829
1830     # We have a terminal, or can get one ...
1831     if (!$term) {
1832         setterm();
1833     }
1834
1835     # ... and it belongs to this PID or we get one for this PID ...
1836     if ($term_pid != $$) {
1837         resetterm(1);
1838     }
1839
1840     # ... and we got a line of command input ...
1841     $cmd = DB::readline(
1842         "$pidprompt $tid DB"
1843         . ( '<' x $level )
1844         . ( $#hist + 1 )
1845         . ( '>' x $level ) . " "
1846     );
1847
1848     return defined($cmd);
1849 }
1850
1851 sub _DB__trim_command_and_return_first_component {
1852     my ($obj) = @_;
1853
1854     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1855     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1856
1857     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1858
1859     $obj->cmd_verb($verb);
1860     $obj->cmd_args($args);
1861
1862     return;
1863 }
1864
1865 sub _DB__handle_f_command {
1866     my ($obj) = @_;
1867
1868     if ($file = $obj->cmd_args) {
1869         # help for no arguments (old-style was return from sub).
1870         if ( !$file ) {
1871             print $OUT
1872             "The old f command is now the r command.\n";    # hint
1873             print $OUT "The new f command switches filenames.\n";
1874             next CMD;
1875         } ## end if (!$file)
1876
1877         # if not in magic file list, try a close match.
1878         if ( !defined $main::{ '_<' . $file } ) {
1879             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1880                 {
1881                     $try = substr( $try, 2 );
1882                     print $OUT "Choosing $try matching '$file':\n";
1883                     $file = $try;
1884                 }
1885             } ## end if (($try) = grep(m#^_<.*$file#...
1886         } ## end if (!defined $main::{ ...
1887
1888         # If not successfully switched now, we failed.
1889         if ( !defined $main::{ '_<' . $file } ) {
1890             print $OUT "No file matching '$file' is loaded.\n";
1891             next CMD;
1892         }
1893
1894         # We switched, so switch the debugger internals around.
1895         elsif ( $file ne $filename ) {
1896             *dbline   = $main::{ '_<' . $file };
1897             $max      = $#dbline;
1898             $filename = $file;
1899             $start    = 1;
1900             $cmd      = "l";
1901         } ## end elsif ($file ne $filename)
1902
1903         # We didn't switch; say we didn't.
1904         else {
1905             print $OUT "Already in $file.\n";
1906             next CMD;
1907         }
1908     }
1909
1910     return;
1911 }
1912
1913 sub _DB__handle_dot_command {
1914     my ($obj) = @_;
1915
1916     # . command.
1917     if ($obj->_is_full('.')) {
1918         $incr = -1;    # stay at current line
1919
1920         # Reset everything to the old location.
1921         $start    = $line;
1922         $filename = $filename_ini;
1923         *dbline   = $main::{ '_<' . $filename };
1924         $max      = $#dbline;
1925
1926         # Now where are we?
1927         print_lineinfo($obj->position());
1928         next CMD;
1929     }
1930
1931     return;
1932 }
1933
1934 sub _DB__handle_y_command {
1935     my ($obj) = @_;
1936
1937     if (my ($match_level, $match_vars)
1938         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1939
1940         # See if we've got the necessary support.
1941         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1942             my $Err = $@;
1943             _db_warn(
1944                 $Err =~ /locate/
1945                 ? "PadWalker module not found - please install\n"
1946                 : $Err
1947             );
1948             next CMD;
1949         }
1950
1951         # Load up dumpvar if we don't have it. If we can, that is.
1952         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1953         defined &main::dumpvar
1954             or print $OUT "dumpvar.pl not available.\n"
1955             and next CMD;
1956
1957         # Got all the modules we need. Find them and print them.
1958         my @vars = split( ' ', $match_vars || '' );
1959
1960         # Find the pad.
1961         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1962
1963         # Oops. Can't find it.
1964         if (my $Err = $@) {
1965             $Err =~ s/ at .*//;
1966             _db_warn($Err);
1967             next CMD;
1968         }
1969
1970         # Show the desired vars with dumplex().
1971         my $savout = select($OUT);
1972
1973         # Have dumplex dump the lexicals.
1974         foreach my $key (sort keys %$h) {
1975             dumpvar::dumplex( $key, $h->{$key},
1976                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1977                 @vars );
1978         }
1979         select($savout);
1980         next CMD;
1981     }
1982 }
1983
1984 sub _DB__handle_c_command {
1985     my ($obj) = @_;
1986
1987     my $i = $obj->cmd_args;
1988
1989     if ($i =~ m#\A[\w:]*\z#) {
1990
1991         # Hey, show's over. The debugged program finished
1992         # executing already.
1993         next CMD if _DB__is_finished();
1994
1995         # Capture the place to put a one-time break.
1996         $subname = $i;
1997
1998         #  Probably not needed, since we finish an interactive
1999         #  sub-session anyway...
2000         # local $filename = $filename;
2001         # local *dbline = *dbline; # XXX Would this work?!
2002         #
2003         # The above question wonders if localizing the alias
2004         # to the magic array works or not. Since it's commented
2005         # out, we'll just leave that to speculation for now.
2006
2007         # If the "subname" isn't all digits, we'll assume it
2008         # is a subroutine name, and try to find it.
2009         if ( $subname =~ /\D/ ) {    # subroutine name
2010             # Qualify it to the current package unless it's
2011             # already qualified.
2012             $subname = $package . "::" . $subname
2013             unless $subname =~ /::/;
2014
2015             # find_sub will return "file:line_number" corresponding
2016             # to where the subroutine is defined; we call find_sub,
2017             # break up the return value, and assign it in one
2018             # operation.
2019             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2020
2021             # Force the line number to be numeric.
2022             $i = $i + 0;
2023
2024             # If we got a line number, we found the sub.
2025             if ($i) {
2026
2027                 # Switch all the debugger's internals around so
2028                 # we're actually working with that file.
2029                 $filename = $file;
2030                 *dbline   = $main::{ '_<' . $filename };
2031
2032                 # Mark that there's a breakpoint in this file.
2033                 $had_breakpoints{$filename} |= 1;
2034
2035                 # Scan forward to the first executable line
2036                 # after the 'sub whatever' line.
2037                 $max = $#dbline;
2038                 my $_line_num = $i;
2039                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2040                 {
2041                     $_line_num++;
2042                 }
2043                 $i = $_line_num;
2044             } ## end if ($i)
2045
2046             # We didn't find a sub by that name.
2047             else {
2048                 print $OUT "Subroutine $subname not found.\n";
2049                 next CMD;
2050             }
2051         } ## end if ($subname =~ /\D/)
2052
2053         # At this point, either the subname was all digits (an
2054         # absolute line-break request) or we've scanned through
2055         # the code following the definition of the sub, looking
2056         # for an executable, which we may or may not have found.
2057         #
2058         # If $i (which we set $subname from) is non-zero, we
2059         # got a request to break at some line somewhere. On
2060         # one hand, if there wasn't any real subroutine name
2061         # involved, this will be a request to break in the current
2062         # file at the specified line, so we have to check to make
2063         # sure that the line specified really is breakable.
2064         #
2065         # On the other hand, if there was a subname supplied, the
2066         # preceding block has moved us to the proper file and
2067         # location within that file, and then scanned forward
2068         # looking for the next executable line. We have to make
2069         # sure that one was found.
2070         #
2071         # On the gripping hand, we can't do anything unless the
2072         # current value of $i points to a valid breakable line.
2073         # Check that.
2074         if ($i) {
2075
2076             # Breakable?
2077             if ( $dbline[$i] == 0 ) {
2078                 print $OUT "Line $i not breakable.\n";
2079                 next CMD;
2080             }
2081
2082             # Yes. Set up the one-time-break sigil.
2083             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2084             _enable_breakpoint_temp_enabled_status($filename, $i);
2085         } ## end if ($i)
2086
2087         # Turn off stack tracing from here up.
2088         for my $j (0 .. $stack_depth) {
2089             $stack[ $j ] &= ~1;
2090         }
2091         last CMD;
2092     }
2093
2094     return;
2095 }
2096
2097 sub _DB__handle_forward_slash_command {
2098     my ($obj) = @_;
2099
2100     # The pattern as a string.
2101     use vars qw($inpat);
2102
2103     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2104
2105         # Remove the final slash.
2106         $inpat =~ s:([^\\])/$:$1:;
2107
2108         # If the pattern isn't null ...
2109         if ( $inpat ne "" ) {
2110
2111             # Turn off warn and die processing for a bit.
2112             local $SIG{__DIE__};
2113             local $SIG{__WARN__};
2114
2115             # Create the pattern.
2116             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2117             if ( $@ ne "" ) {
2118
2119                 # Oops. Bad pattern. No biscuit.
2120                 # Print the eval error and go back for more
2121                 # commands.
2122                 print {$OUT} "$@";
2123                 next CMD;
2124             }
2125             $obj->pat($inpat);
2126         } ## end if ($inpat ne "")
2127
2128         # Set up to stop on wrap-around.
2129         $end = $start;
2130
2131         # Don't move off the current line.
2132         $incr = -1;
2133
2134         my $pat = $obj->pat;
2135
2136         # Done in eval so nothing breaks if the pattern
2137         # does something weird.
2138         eval
2139         {
2140             no strict q/vars/;
2141             for (;;) {
2142                 # Move ahead one line.
2143                 ++$start;
2144
2145                 # Wrap if we pass the last line.
2146                 if ($start > $max) {
2147                     $start = 1;
2148                 }
2149
2150                 # Stop if we have gotten back to this line again,
2151                 last if ($start == $end);
2152
2153                 # A hit! (Note, though, that we are doing
2154                 # case-insensitive matching. Maybe a qr//
2155                 # expression would be better, so the user could
2156                 # do case-sensitive matching if desired.
2157                 if ($dbline[$start] =~ m/$pat/i) {
2158                     if ($slave_editor) {
2159                         # Handle proper escaping in the slave.
2160                         print {$OUT} "\032\032$filename:$start:0\n";
2161                     }
2162                     else {
2163                         # Just print the line normally.
2164                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2165                     }
2166                     # And quit since we found something.
2167                     last;
2168                 }
2169             }
2170         };
2171
2172         if ($@) {
2173             warn $@;
2174         }
2175
2176         # If we wrapped, there never was a match.
2177         if ( $start == $end ) {
2178             print {$OUT} "/$pat/: not found\n";
2179         }
2180         next CMD;
2181     }
2182
2183     return;
2184 }
2185
2186 sub _DB__handle_question_mark_command {
2187     my ($obj) = @_;
2188
2189     # ? - backward pattern search.
2190     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2191
2192         # Get the pattern, remove trailing question mark.
2193         $inpat =~ s:([^\\])\?$:$1:;
2194
2195         # If we've got one ...
2196         if ( $inpat ne "" ) {
2197
2198             # Turn off die & warn handlers.
2199             local $SIG{__DIE__};
2200             local $SIG{__WARN__};
2201             eval '$inpat =~ m' . "\a$inpat\a";
2202
2203             if ( $@ ne "" ) {
2204
2205                 # Ouch. Not good. Print the error.
2206                 print $OUT $@;
2207                 next CMD;
2208             }
2209             $obj->pat($inpat);
2210         } ## end if ($inpat ne "")
2211
2212         # Where we are now is where to stop after wraparound.
2213         $end = $start;
2214
2215         # Don't move away from this line.
2216         $incr = -1;
2217
2218         my $pat = $obj->pat;
2219         # Search inside the eval to prevent pattern badness
2220         # from killing us.
2221         eval {
2222             no strict q/vars/;
2223             for (;;) {
2224                 # Back up a line.
2225                 --$start;
2226
2227                 # Wrap if we pass the first line.
2228
2229                 $start = $max if ($start <= 0);
2230
2231                 # Quit if we get back where we started,
2232                 last if ($start == $end);
2233
2234                 # Match?
2235                 if ($dbline[$start] =~ m/$pat/i) {
2236                     if ($slave_editor) {
2237                         # Yep, follow slave editor requirements.
2238                         print $OUT "\032\032$filename:$start:0\n";
2239                     }
2240                     else {
2241                         # Yep, just print normally.
2242                         print $OUT "$start:\t",$dbline[$start],"\n";
2243                     }
2244
2245                     # Found, so done.
2246                     last;
2247                 }
2248             }
2249         };
2250
2251         # Say we failed if the loop never found anything,
2252         if ( $start == $end ) {
2253             print {$OUT} "?$pat?: not found\n";
2254         }
2255         next CMD;
2256     }
2257
2258     return;
2259 }
2260
2261 sub _DB__handle_restart_and_rerun_commands {
2262     my ($obj) = @_;
2263
2264     my $cmd_cmd = $obj->cmd_verb;
2265     my $cmd_params = $obj->cmd_args;
2266     # R - restart execution.
2267     # rerun - controlled restart execution.
2268     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2269
2270         # Change directory to the initial current working directory on
2271         # the script startup, so if the debugged program changed the
2272         # directory, then we will still be able to find the path to the
2273         # the program. (perl 5 RT #121509 ).
2274         chdir ($_initial_cwd);
2275
2276         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2277
2278         # Close all non-system fds for a clean restart.  A more
2279         # correct method would be to close all fds that were not
2280         # open when the process started, but this seems to be
2281         # hard.  See "debugger 'R'estart and open database
2282         # connections" on p5p.
2283
2284         my $max_fd = 1024; # default if POSIX can't be loaded
2285         if (eval { require POSIX }) {
2286             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2287         }
2288
2289         if (defined $max_fd) {
2290             foreach ($^F+1 .. $max_fd-1) {
2291                 next unless open FD_TO_CLOSE, "<&=$_";
2292                 close(FD_TO_CLOSE);
2293             }
2294         }
2295
2296         # And run Perl again.  We use exec() to keep the
2297         # PID stable (and that way $ini_pids is still valid).
2298         exec(@args) or print {$OUT} "exec failed: $!\n";
2299
2300         last CMD;
2301     }
2302
2303     return;
2304 }
2305
2306 sub _DB__handle_run_command_in_pager_command {
2307     my ($obj) = @_;
2308
2309     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2310         if ( $pager =~ /^\|/ ) {
2311
2312             # Default pager is into a pipe. Redirect I/O.
2313             open( SAVEOUT, ">&STDOUT" )
2314             || _db_warn("Can't save STDOUT");
2315             open( STDOUT, ">&OUT" )
2316             || _db_warn("Can't redirect STDOUT");
2317         } ## end if ($pager =~ /^\|/)
2318         else {
2319
2320             # Not into a pipe. STDOUT is safe.
2321             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2322         }
2323
2324         # Fix up environment to record we have less if so.
2325         fix_less();
2326
2327         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2328
2329             # Couldn't open pipe to pager.
2330             _db_warn("Can't pipe output to '$pager'");
2331             if ( $pager =~ /^\|/ ) {
2332
2333                 # Redirect I/O back again.
2334                 open( OUT, ">&STDOUT" )    # XXX: lost message
2335                 || _db_warn("Can't restore DB::OUT");
2336                 open( STDOUT, ">&SAVEOUT" )
2337                 || _db_warn("Can't restore STDOUT");
2338                 close(SAVEOUT);
2339             } ## end if ($pager =~ /^\|/)
2340             else {
2341
2342                 # Redirect I/O. STDOUT already safe.
2343                 open( OUT, ">&STDOUT" )    # XXX: lost message
2344                 || _db_warn("Can't restore DB::OUT");
2345             }
2346             next CMD;
2347         } ## end unless ($piped = open(OUT,...
2348
2349         # Set up broken-pipe handler if necessary.
2350         $SIG{PIPE} = \&DB::catch
2351         if $pager =~ /^\|/
2352         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2353
2354         _autoflush(\*OUT);
2355         # Save current filehandle, and put it back.
2356         $obj->selected(scalar( select(OUT) ));
2357         # Don't put it back if pager was a pipe.
2358         if ($cmd !~ /\A\|\|/)
2359         {
2360             select($obj->selected());
2361             $obj->selected("");
2362         }
2363
2364         # Trim off the pipe symbols and run the command now.
2365         $cmd =~ s#\A\|+\s*##;
2366         redo PIPE;
2367     }
2368
2369     return;
2370 }
2371
2372 sub _DB__handle_m_command {
2373     my ($obj) = @_;
2374
2375     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2376         methods($1);
2377         next CMD;
2378     }
2379
2380     # m expr - set up DB::eval to do the work
2381     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2382         $onetimeDump = 'methods';   #  method output gets used there
2383     }
2384
2385     return;
2386 }
2387
2388 sub _DB__at_end_of_every_command {
2389     my ($obj) = @_;
2390
2391     # At the end of every command:
2392     if ($obj->piped) {
2393
2394         # Unhook the pipe mechanism now.
2395         if ( $pager =~ /^\|/ ) {
2396
2397             # No error from the child.
2398             $? = 0;
2399
2400             # we cannot warn here: the handle is missing --tchrist
2401             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2402
2403             # most of the $? crud was coping with broken cshisms
2404             # $? is explicitly set to 0, so this never runs.
2405             if ($?) {
2406                 print SAVEOUT "Pager '$pager' failed: ";
2407                 if ( $? == -1 ) {
2408                     print SAVEOUT "shell returned -1\n";
2409                 }
2410                 elsif ( $? >> 8 ) {
2411                     print SAVEOUT ( $? & 127 )
2412                     ? " (SIG#" . ( $? & 127 ) . ")"
2413                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2414                 }
2415                 else {
2416                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2417                 }
2418             } ## end if ($?)
2419
2420             # Reopen filehandle for our output (if we can) and
2421             # restore STDOUT (if we can).
2422             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2423             open( STDOUT, ">&SAVEOUT" )
2424             || _db_warn("Can't restore STDOUT");
2425
2426             # Turn off pipe exception handler if necessary.
2427             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2428
2429             # Will stop ignoring SIGPIPE if done like nohup(1)
2430             # does SIGINT but Perl doesn't give us a choice.
2431         } ## end if ($pager =~ /^\|/)
2432         else {
2433
2434             # Non-piped "pager". Just restore STDOUT.
2435             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2436         }
2437
2438         # Let Readline know about the new filehandles.
2439         reset_IN_OUT( \*IN, \*OUT );
2440
2441         # Close filehandle pager was using, restore the normal one
2442         # if necessary,
2443         close(SAVEOUT);
2444
2445         if ($obj->selected() ne "") {
2446             select($obj->selected);
2447             $obj->selected("");
2448         }
2449
2450         # No pipes now.
2451         $obj->piped("");
2452     } ## end if ($piped)
2453
2454     return;
2455 }
2456
2457 sub _DB__handle_watch_expressions
2458 {
2459     my $self = shift;
2460
2461     if ( $DB::trace & 2 ) {
2462         for my $n (0 .. $#DB::to_watch) {
2463             $DB::evalarg = $DB::to_watch[$n];
2464             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2465
2466             # Fix context DB::eval() wants to return an array, but
2467             # we need a scalar here.
2468             my ($val) = join( "', '", DB::eval(@_) );
2469             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2470
2471             # Did it change?
2472             if ( $val ne $DB::old_watch[$n] ) {
2473
2474                 # Yep! Show the difference, and fake an interrupt.
2475                 $DB::signal = 1;
2476                 print {$DB::OUT} <<EOP;
2477 Watchpoint $n:\t$DB::to_watch[$n] changed:
2478     old value:\t$DB::old_watch[$n]
2479     new value:\t$val
2480 EOP
2481                 $DB::old_watch[$n] = $val;
2482             } ## end if ($val ne $old_watch...
2483         } ## end for my $n (0 ..
2484     } ## end if ($trace & 2)
2485
2486     return;
2487 }
2488
2489 # 't' is type.
2490 # 'm' is method.
2491 # 'v' is the value (i.e: method name or subroutine ref).
2492 # 's' is subroutine.
2493 my %cmd_lookup =
2494 (
2495     '-' => { t => 'm', v => '_handle_dash_command', },
2496     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2497     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2498     'H' => { t => 'm', v => '_handle_H_command', },
2499     'S' => { t => 'm', v => '_handle_S_command', },
2500     'T' => { t => 'm', v => '_handle_T_command', },
2501     'W' => { t => 'm', v => '_handle_W_command', },
2502     'c' => { t => 's', v => \&_DB__handle_c_command, },
2503     'f' => { t => 's', v => \&_DB__handle_f_command, },
2504     'm' => { t => 's', v => \&_DB__handle_m_command, },
2505     'n' => { t => 'm', v => '_handle_n_command', },
2506     'p' => { t => 'm', v => '_handle_p_command', },
2507     'q' => { t => 'm', v => '_handle_q_command', },
2508     'r' => { t => 'm', v => '_handle_r_command', },
2509     's' => { t => 'm', v => '_handle_s_command', },
2510     'save' => { t => 'm', v => '_handle_save_command', },
2511     'source' => { t => 'm', v => '_handle_source_command', },
2512     't' => { t => 'm', v => '_handle_t_command', },
2513     'w' => { t => 'm', v => '_handle_w_command', },
2514     'x' => { t => 'm', v => '_handle_x_command', },
2515     'y' => { t => 's', v => \&_DB__handle_y_command, },
2516     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2517         ('X', 'V')),
2518     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2519         qw(enable disable)),
2520     (map { $_ =>
2521         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2522         } qw(R rerun)),
2523     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2524         qw(a A b B e E h i l L M o O v w W)),
2525 );
2526
2527 sub DB {
2528
2529     # lock the debugger and get the thread id for the prompt
2530     lock($DBGR);
2531     my $tid;
2532     my $position;
2533     my ($prefix, $after, $infix);
2534     my $pat;
2535     my $explicit_stop;
2536     my $piped;
2537     my $selected;
2538
2539     if ($ENV{PERL5DB_THREADED}) {
2540         $tid = eval { "[".threads->tid."]" };
2541     }
2542
2543     my $cmd_verb;
2544     my $cmd_args;
2545
2546     my $obj = DB::Obj->new(
2547         {
2548             position => \$position,
2549             prefix => \$prefix,
2550             after => \$after,
2551             explicit_stop => \$explicit_stop,
2552             infix => \$infix,
2553             cmd_args => \$cmd_args,
2554             cmd_verb => \$cmd_verb,
2555             pat => \$pat,
2556             piped => \$piped,
2557             selected => \$selected,
2558         },
2559     );
2560
2561     $obj->_DB_on_init__initialize_globals(@_);
2562
2563     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2564     # The code being debugged may have altered them.
2565     DB::save();
2566
2567     # Since DB::DB gets called after every line, we can use caller() to
2568     # figure out where we last were executing. Sneaky, eh? This works because
2569     # caller is returning all the extra information when called from the
2570     # debugger.
2571     local ( $package, $filename, $line ) = caller;
2572     $filename_ini = $filename;
2573
2574     # set up the context for DB::eval, so it can properly execute
2575     # code on behalf of the user. We add the package in so that the
2576     # code is eval'ed in the proper package (not in the debugger!).
2577     local $usercontext = _calc_usercontext($package);
2578
2579     # Create an alias to the active file magical array to simplify
2580     # the code here.
2581     local (*dbline) = $main::{ '_<' . $filename };
2582
2583     # Last line in the program.
2584     $max = $#dbline;
2585
2586     # The &-call is here to ascertain the mutability of @_.
2587     &_DB__determine_if_we_should_break;
2588
2589     # Preserve the current stop-or-not, and see if any of the W
2590     # (watch expressions) has changed.
2591     my $was_signal = $signal;
2592
2593     # If we have any watch expressions ...
2594     _DB__handle_watch_expressions($obj);
2595
2596 =head2 C<watchfunction()>
2597
2598 C<watchfunction()> is a function that can be defined by the user; it is a
2599 function which will be run on each entry to C<DB::DB>; it gets the
2600 current package, filename, and line as its parameters.
2601
2602 The watchfunction can do anything it likes; it is executing in the
2603 debugger's context, so it has access to all of the debugger's internal
2604 data structures and functions.
2605
2606 C<watchfunction()> can control the debugger's actions. Any of the following
2607 will cause the debugger to return control to the user's program after
2608 C<watchfunction()> executes:
2609
2610 =over 4
2611
2612 =item *
2613
2614 Returning a false value from the C<watchfunction()> itself.
2615
2616 =item *
2617
2618 Altering C<$single> to a false value.
2619
2620 =item *
2621
2622 Altering C<$signal> to a false value.
2623
2624 =item *
2625
2626 Turning off the C<4> bit in C<$trace> (this also disables the
2627 check for C<watchfunction()>. This can be done with
2628
2629     $trace &= ~4;
2630
2631 =back
2632
2633 =cut
2634
2635     # If there's a user-defined DB::watchfunction, call it with the
2636     # current package, filename, and line. The function executes in
2637     # the DB:: package.
2638     if ( $trace & 4 ) {    # User-installed watch
2639         return
2640           if watchfunction( $package, $filename, $line )
2641           and not $single
2642           and not $was_signal
2643           and not( $trace & ~4 );
2644     } ## end if ($trace & 4)
2645
2646     # Pick up any alteration to $signal in the watchfunction, and
2647     # turn off the signal now.
2648     $was_signal = $signal;
2649     $signal     = 0;
2650
2651 =head2 GETTING READY TO EXECUTE COMMANDS
2652
2653 The debugger decides to take control if single-step mode is on, the
2654 C<t> command was entered, or the user generated a signal. If the program
2655 has fallen off the end, we set things up so that entering further commands
2656 won't cause trouble, and we say that the program is over.
2657
2658 =cut
2659
2660     # Make sure that we always print if asked for explicitly regardless
2661     # of $trace_to_depth .
2662     $explicit_stop = ($single || $was_signal);
2663
2664     # Check to see if we should grab control ($single true,
2665     # trace set appropriately, or we got a signal).
2666     if ( $explicit_stop || ( $trace & 1 ) ) {
2667         $obj->_DB__grab_control(@_);
2668     } ## end if ($single || ($trace...
2669
2670 =pod
2671
2672 If there's an action to be executed for the line we stopped at, execute it.
2673 If there are any preprompt actions, execute those as well.
2674
2675 =cut
2676
2677     # If there's an action, do it now.
2678     if ($action) {
2679         $evalarg = $action;
2680         # The &-call is here to ascertain the mutability of @_.
2681         &DB::eval;
2682     }
2683
2684     # Are we nested another level (e.g., did we evaluate a function
2685     # that had a breakpoint in it at the debugger prompt)?
2686     if ( $single || $was_signal ) {
2687
2688         # Yes, go down a level.
2689         local $level = $level + 1;
2690
2691         # Do any pre-prompt actions.
2692         foreach $evalarg (@$pre) {
2693             # The &-call is here to ascertain the mutability of @_.
2694             &DB::eval;
2695         }
2696
2697         # Complain about too much recursion if we passed the limit.
2698         if ($single & 4) {
2699             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2700         }
2701
2702         # The line we're currently on. Set $incr to -1 to stay here
2703         # until we get a command that tells us to advance.
2704         $start = $line;
2705         $incr  = -1;      # for backward motion.
2706
2707         # Tack preprompt debugger actions ahead of any actual input.
2708         @typeahead = ( @$pretype, @typeahead );
2709
2710 =head2 WHERE ARE WE?
2711
2712 XXX Relocate this section?
2713
2714 The debugger normally shows the line corresponding to the current line of
2715 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2716 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2717
2718 C<$incr> controls by how many lines the I<current> line should move forward
2719 after a command is executed. If set to -1, this indicates that the I<current>
2720 line shouldn't change.
2721
2722 C<$start> is the I<current> line. It is used for things like knowing where to
2723 move forwards or backwards from when doing an C<L> or C<-> command.
2724
2725 C<$max> tells the debugger where the last line of the current file is. It's
2726 used to terminate loops most often.
2727
2728 =head2 THE COMMAND LOOP
2729
2730 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2731 in two parts:
2732
2733 =over 4
2734
2735 =item *
2736
2737 The outer part of the loop, starting at the C<CMD> label. This loop
2738 reads a command and then executes it.
2739
2740 =item *
2741
2742 The inner part of the loop, starting at the C<PIPE> label. This part
2743 is wholly contained inside the C<CMD> block and only executes a command.
2744 Used to handle commands running inside a pager.
2745
2746 =back
2747
2748 So why have two labels to restart the loop? Because sometimes, it's easier to
2749 have a command I<generate> another command and then re-execute the loop to do
2750 the new command. This is faster, but perhaps a bit more convoluted.
2751
2752 =cut
2753
2754         # The big command dispatch loop. It keeps running until the
2755         # user yields up control again.
2756         #
2757         # If we have a terminal for input, and we get something back
2758         # from readline(), keep on processing.
2759
2760       CMD:
2761         while (_DB__read_next_cmd($tid))
2762         {
2763
2764             share($cmd);
2765             # ... try to execute the input as debugger commands.
2766
2767             # Don't stop running.
2768             $single = 0;
2769
2770             # No signal is active.
2771             $signal = 0;
2772
2773             # Handle continued commands (ending with \):
2774             if ($cmd =~ s/\\\z/\n/) {
2775                 $cmd .= DB::readline("  cont: ");
2776                 redo CMD;
2777             }
2778
2779 =head4 The null command
2780
2781 A newline entered by itself means I<re-execute the last command>. We grab the
2782 command out of C<$laststep> (where it was recorded previously), and copy it
2783 back into C<$cmd> to be executed below. If there wasn't any previous command,
2784 we'll do nothing below (no command will match). If there was, we also save it
2785 in the command history and fall through to allow the command parsing to pick
2786 it up.
2787
2788 =cut
2789
2790             # Empty input means repeat the last command.
2791             if ($cmd eq '') {
2792                 $cmd = $laststep;
2793             }
2794             chomp($cmd);    # get rid of the annoying extra newline
2795             if (length($cmd) >= 2) {
2796                 push( @hist, $cmd );
2797             }
2798             push( @truehist, $cmd );
2799             share(@hist);
2800             share(@truehist);
2801
2802             # This is a restart point for commands that didn't arrive
2803             # via direct user input. It allows us to 'redo PIPE' to
2804             # re-execute command processing without reading a new command.
2805           PIPE: {
2806                 _DB__trim_command_and_return_first_component($obj);
2807
2808 =head3 COMMAND ALIASES
2809
2810 The debugger can create aliases for commands (these are stored in the
2811 C<%alias> hash). Before a command is executed, the command loop looks it up
2812 in the alias hash and substitutes the contents of the alias for the command,
2813 completely replacing it.
2814
2815 =cut
2816
2817                 # See if there's an alias for the command, and set it up if so.
2818                 if ( $alias{$cmd_verb} ) {
2819
2820                     # Squelch signal handling; we want to keep control here
2821                     # if something goes loco during the alias eval.
2822                     local $SIG{__DIE__};
2823                     local $SIG{__WARN__};
2824
2825                     # This is a command, so we eval it in the DEBUGGER's
2826                     # scope! Otherwise, we can't see the special debugger
2827                     # variables, or get to the debugger's subs. (Well, we
2828                     # _could_, but why make it even more complicated?)
2829                     eval "\$cmd =~ $alias{$cmd_verb}";
2830                     if ($@) {
2831                         local $\ = '';
2832                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2833                         next CMD;
2834                     }
2835                     _DB__trim_command_and_return_first_component($obj);
2836                 } ## end if ($alias{$cmd_verb})
2837
2838 =head3 MAIN-LINE COMMANDS
2839
2840 All of these commands work up to and after the program being debugged has
2841 terminated.
2842
2843 =head4 C<q> - quit
2844
2845 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2846 try to execute further, cleaning any restart-related stuff out of the
2847 environment, and executing with the last value of C<$?>.
2848
2849 =cut
2850
2851                 # All of these commands were remapped in perl 5.8.0;
2852                 # we send them off to the secondary dispatcher (see below).
2853                 $obj->_handle_special_char_cmd_wrapper_commands;
2854                 _DB__trim_command_and_return_first_component($obj);
2855
2856                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2857                     my $type = $cmd_rec->{t};
2858                     my $val = $cmd_rec->{v};
2859                     if ($type eq 'm') {
2860                         $obj->$val();
2861                     }
2862                     elsif ($type eq 's') {
2863                         $val->($obj);
2864                     }
2865                 }
2866
2867 =head4 C<t> - trace [n]
2868
2869 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2870 If level is specified, set C<$trace_to_depth>.
2871
2872 =head4 C<S> - list subroutines matching/not matching a pattern
2873
2874 Walks through C<%sub>, checking to see whether or not to print the name.
2875
2876 =head4 C<X> - list variables in current package
2877
2878 Since the C<V> command actually processes this, just change this to the
2879 appropriate C<V> command and fall through.
2880
2881 =head4 C<V> - list variables
2882
2883 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2884
2885 =head4 C<x> - evaluate and print an expression
2886
2887 Hands the expression off to C<DB::eval>, setting it up to print the value
2888 via C<dumpvar.pl> instead of just printing it directly.
2889
2890 =head4 C<m> - print methods
2891
2892 Just uses C<DB::methods> to determine what methods are available.
2893
2894 =head4 C<f> - switch files
2895
2896 Switch to a different filename.
2897
2898 =head4 C<.> - return to last-executed line.
2899
2900 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2901 and then we look up the line in the magical C<%dbline> hash.
2902
2903 =head4 C<-> - back one window
2904
2905 We change C<$start> to be one window back; if we go back past the first line,
2906 we set it to be the first line. We ser C<$incr> to put us back at the
2907 currently-executing line, and then put a C<l $start +> (list one window from
2908 C<$start>) in C<$cmd> to be executed later.
2909
2910 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2911
2912 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2913 problems, most notably that the default case of several commands destroying
2914 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2915 retain the old commands for those who were used to using them or who preferred
2916 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2917 deal with them instead of processing them in-line.
2918
2919 =head4 C<y> - List lexicals in higher scope
2920
2921 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2922 above the current one and then displays then using C<dumpvar.pl>.
2923
2924 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2925
2926 All of the commands below this point don't work after the program being
2927 debugged has ended. All of them check to see if the program has ended; this
2928 allows the commands to be relocated without worrying about a 'line of
2929 demarcation' above which commands can be entered anytime, and below which
2930 they can't.
2931
2932 =head4 C<n> - single step, but don't trace down into subs
2933
2934 Done by setting C<$single> to 2, which forces subs to execute straight through
2935 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2936 so a null command knows what to re-execute.
2937
2938 =head4 C<s> - single-step, entering subs
2939
2940 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2941 subs. Also saves C<s> as C<$lastcmd>.
2942
2943 =head4 C<c> - run continuously, setting an optional breakpoint
2944
2945 Most of the code for this command is taken up with locating the optional
2946 breakpoint, which is either a subroutine name or a line number. We set
2947 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2948 in this and all call levels above this one.
2949
2950 =head4 C<r> - return from a subroutine
2951
2952 For C<r> to work properly, the debugger has to stop execution again
2953 immediately after the return is executed. This is done by forcing
2954 single-stepping to be on in the call level above the current one. If
2955 we are printing return values when a C<r> is executed, set C<$doret>
2956 appropriately, and force us out of the command loop.
2957
2958 =head4 C<T> - stack trace
2959
2960 Just calls C<DB::print_trace>.
2961
2962 =head4 C<w> - List window around current line.
2963
2964 Just calls C<DB::cmd_w>.
2965
2966 =head4 C<W> - watch-expression processing.
2967
2968 Just calls C<DB::cmd_W>.
2969
2970 =head4 C</> - search forward for a string in the source
2971
2972 We take the argument and treat it as a pattern. If it turns out to be a
2973 bad one, we return the error we got from trying to C<eval> it and exit.
2974 If not, we create some code to do the search and C<eval> it so it can't
2975 mess us up.
2976
2977 =cut
2978
2979                 _DB__handle_forward_slash_command($obj);
2980
2981 =head4 C<?> - search backward for a string in the source
2982
2983 Same as for C</>, except the loop runs backwards.
2984
2985 =cut
2986
2987                 _DB__handle_question_mark_command($obj);
2988
2989 =head4 C<$rc> - Recall command
2990
2991 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2992 that the terminal supports history). It finds the command required, puts it
2993 into C<$cmd>, and redoes the loop to execute it.
2994
2995 =cut
2996
2997                 # $rc - recall command.
2998                 $obj->_handle_rc_recall_command;
2999
3000 =head4 C<$sh$sh> - C<system()> command
3001
3002 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3003 C<STDOUT> from getting messed up.
3004
3005 =cut
3006
3007                 $obj->_handle_sh_command;
3008
3009 =head4 C<$rc I<pattern> $rc> - Search command history
3010
3011 Another command to manipulate C<@hist>: this one searches it with a pattern.
3012 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3013
3014 =cut
3015
3016                 $obj->_handle_rc_search_history_command;
3017
3018 =head4 C<$sh> - Invoke a shell
3019
3020 Uses C<_db_system()> to invoke a shell.
3021
3022 =cut
3023
3024 =head4 C<$sh I<command>> - Force execution of a command in a shell
3025
3026 Like the above, but the command is passed to the shell. Again, we use
3027 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3028
3029 =head4 C<H> - display commands in history
3030
3031 Prints the contents of C<@hist> (if any).
3032
3033 =head4 C<man, doc, perldoc> - look up documentation
3034
3035 Just calls C<runman()> to print the appropriate document.
3036
3037 =cut
3038
3039                 $obj->_handle_doc_command;
3040
3041 =head4 C<p> - print
3042
3043 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3044 the bottom of the loop.
3045
3046 =head4 C<=> - define command alias
3047
3048 Manipulates C<%alias> to add or list command aliases.
3049
3050 =head4 C<source> - read commands from a file.
3051
3052 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3053 pick it up.
3054
3055 =head4 C<enable> C<disable> - enable or disable breakpoints
3056
3057 This enables or disables breakpoints.
3058
3059 =head4 C<save> - send current history to a file
3060
3061 Takes the complete history, (not the shrunken version you see with C<H>),
3062 and saves it to the given filename, so it can be replayed using C<source>.
3063
3064 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3065
3066 =head4 C<R> - restart
3067
3068 Restart the debugger session.
3069
3070 =head4 C<rerun> - rerun the current session
3071
3072 Return to any given position in the B<true>-history list
3073
3074 =head4 C<|, ||> - pipe output through the pager.
3075
3076 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3077 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3078 pipe to the pager (restoring the output filehandles if this fails). If this
3079 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3080 set C<$signal>, sending us back into the debugger.
3081
3082 We then trim off the pipe symbols and C<redo> the command loop at the
3083 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3084 reading another.
3085
3086 =cut
3087
3088                 # || - run command in the pager, with output to DB::OUT.
3089                 _DB__handle_run_command_in_pager_command($obj);
3090
3091 =head3 END OF COMMAND PARSING
3092
3093 Anything left in C<$cmd> at this point is a Perl expression that we want to
3094 evaluate. We'll always evaluate in the user's context, and fully qualify
3095 any variables we might want to address in the C<DB> package.
3096
3097 =cut
3098
3099             }    # PIPE:
3100
3101             # trace an expression
3102             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3103
3104             # Make sure the flag that says "the debugger's running" is
3105             # still on, to make sure we get control again.
3106             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3107
3108             # Run *our* eval that executes in the caller's context.
3109             # The &-call is here to ascertain the mutability of @_.
3110             &DB::eval;
3111
3112             # Turn off the one-time-dump stuff now.
3113             if ($onetimeDump) {
3114                 $onetimeDump      = undef;
3115                 $onetimedumpDepth = undef;
3116             }
3117             elsif ( $term_pid == $$ ) {
3118                 eval { # May run under miniperl, when not available...
3119                     STDOUT->flush();
3120                     STDERR->flush();
3121                 };
3122
3123                 # XXX If this is the master pid, print a newline.
3124                 print {$OUT} "\n";
3125             }
3126         } ## end while (($term || &setterm...
3127
3128 =head3 POST-COMMAND PROCESSING
3129
3130 After each command, we check to see if the command output was piped anywhere.
3131 If so, we go through the necessary code to unhook the pipe and go back to
3132 our standard filehandles for input and output.
3133
3134 =cut
3135
3136         continue {    # CMD:
3137             _DB__at_end_of_every_command($obj);
3138         }    # CMD:
3139
3140 =head3 COMMAND LOOP TERMINATION
3141
3142 When commands have finished executing, we come here. If the user closed the
3143 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3144 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3145 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3146 The interpreter will then execute the next line and then return control to us
3147 again.
3148
3149 =cut
3150
3151         # No more commands? Quit.
3152         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3153
3154         # Evaluate post-prompt commands.
3155         foreach $evalarg (@$post) {
3156             # The &-call is here to ascertain the mutability of @_.
3157             &DB::eval;
3158         }
3159     }    # if ($single || $signal)
3160
3161     # Put the user's globals back where you found them.
3162     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3163     ();
3164 } ## end sub DB
3165
3166 # Because DB::Obj is used above,
3167 #
3168 #   my $obj = DB::Obj->new(
3169 #
3170 # The following package declaration must come before that,
3171 # or else runtime errors will occur with
3172 #
3173 #   PERLDB_OPTS="autotrace nonstop"
3174 #
3175 # ( rt#116771 )
3176 BEGIN {
3177
3178 package DB::Obj;
3179
3180 sub new {
3181     my $class = shift;
3182
3183     my $self = bless {}, $class;
3184
3185     $self->_init(@_);
3186
3187     return $self;
3188 }
3189
3190 sub _init {
3191     my ($self, $args) = @_;
3192
3193     %{$self} = (%$self, %$args);
3194
3195     return;
3196 }
3197
3198 {
3199     no strict 'refs';
3200     foreach my $slot_name (qw(
3201         after explicit_stop infix pat piped position prefix selected cmd_verb
3202         cmd_args
3203         )) {
3204         my $slot = $slot_name;
3205         *{$slot} = sub {
3206             my $self = shift;
3207
3208             if (@_) {
3209                 ${ $self->{$slot} } = shift;
3210             }
3211
3212             return ${ $self->{$slot} };
3213         };
3214
3215         *{"append_to_$slot"} = sub {
3216             my $self = shift;
3217             my $s = shift;
3218
3219             return $self->$slot($self->$slot . $s);
3220         };
3221     }
3222 }
3223
3224 sub _DB_on_init__initialize_globals
3225 {
3226     my $self = shift;
3227
3228     # Check for whether we should be running continuously or not.
3229     # _After_ the perl program is compiled, $single is set to 1:
3230     if ( $single and not $second_time++ ) {
3231
3232         # Options say run non-stop. Run until we get an interrupt.
3233         if ($runnonstop) {    # Disable until signal
3234                 # If there's any call stack in place, turn off single
3235                 # stepping into subs throughout the stack.
3236             for my $i (0 .. $stack_depth) {
3237                 $stack[ $i ] &= ~1;
3238             }
3239
3240             # And we are now no longer in single-step mode.
3241             $single = 0;
3242
3243             # If we simply returned at this point, we wouldn't get
3244             # the trace info. Fall on through.
3245             # return;
3246         } ## end if ($runnonstop)
3247
3248         elsif ($ImmediateStop) {
3249
3250             # We are supposed to stop here; XXX probably a break.
3251             $ImmediateStop = 0;    # We've processed it; turn it off
3252             $signal        = 1;    # Simulate an interrupt to force
3253                                    # us into the command loop
3254         }
3255     } ## end if ($single and not $second_time...
3256
3257     # If we're in single-step mode, or an interrupt (real or fake)
3258     # has occurred, turn off non-stop mode.
3259     $runnonstop = 0 if $single or $signal;
3260
3261     return;
3262 }
3263
3264 sub _my_print_lineinfo
3265 {
3266     my ($self, $i, $incr_pos) = @_;
3267
3268     if ($frame) {
3269         # Print it indented if tracing is on.
3270         DB::print_lineinfo( ' ' x $stack_depth,
3271             "$i:\t$DB::dbline[$i]" . $self->after );
3272     }
3273     else {
3274         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3275     }
3276 }
3277
3278 sub _curr_line {
3279     return $DB::dbline[$line];
3280 }
3281
3282 sub _is_full {
3283     my ($self, $letter) = @_;
3284
3285     return ($DB::cmd eq $letter);
3286 }
3287
3288 sub _DB__grab_control
3289 {
3290     my $self = shift;
3291
3292     # Yes, grab control.
3293     if ($slave_editor) {
3294
3295         # Tell the editor to update its position.
3296         $self->position("\032\032${DB::filename}:$line:0\n");
3297         DB::print_lineinfo($self->position());
3298     }
3299
3300 =pod
3301
3302 Special check: if we're in package C<DB::fake>, we've gone through the
3303 C<END> block at least once. We set up everything so that we can continue
3304 to enter commands and have a valid context to be in.
3305
3306 =cut
3307
3308     elsif ( $DB::package eq 'DB::fake' ) {
3309
3310         # Fallen off the end already.
3311         if (!$DB::term) {
3312             DB::setterm();
3313         }
3314
3315         DB::print_help(<<EOP);
3316 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3317 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3318 B<h q>, B<h R> or B<h o> to get additional info.
3319 EOP
3320
3321         # Set the DB::eval context appropriately.
3322         # At program termination disable any user actions.
3323         $DB::action = undef;
3324
3325         $DB::package     = 'main';
3326         $DB::usercontext = DB::_calc_usercontext($DB::package);
3327     } ## end elsif ($package eq 'DB::fake')
3328
3329 =pod
3330
3331 If the program hasn't finished executing, we scan forward to the
3332 next executable line, print that out, build the prompt from the file and line
3333 number information, and print that.
3334
3335 =cut
3336
3337     else {
3338
3339
3340         # Still somewhere in the midst of execution. Set up the
3341         #  debugger prompt.
3342         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3343                              # Perl 5 ones (sorry, we don't print Klingon
3344                              #module names)
3345
3346         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3347         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3348         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3349
3350         # Break up the prompt if it's really long.
3351         if ( length($self->prefix()) > 30 ) {
3352             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3353             $self->prefix("");
3354             $self->infix(":\t");
3355         }
3356         else {
3357             $self->infix("):\t");
3358             $self->position(
3359                 $self->prefix . $line. $self->infix
3360                 . $self->_curr_line . $self->after
3361             );
3362         }
3363
3364         # Print current line info, indenting if necessary.
3365         $self->_my_print_lineinfo($line, $self->position);
3366
3367         my $i;
3368         my $line_i = sub { return $DB::dbline[$i]; };
3369
3370         # Scan forward, stopping at either the end or the next
3371         # unbreakable line.
3372         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3373         {    #{ vi
3374
3375             # Drop out on null statements, block closers, and comments.
3376             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3377
3378             # Drop out if the user interrupted us.
3379             last if $signal;
3380
3381             # Append a newline if the line doesn't have one. Can happen
3382             # in eval'ed text, for instance.
3383             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3384
3385             # Next executable line.
3386             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3387                 . $self->after;
3388             $self->append_to_position($incr_pos);
3389             $self->_my_print_lineinfo($i, $incr_pos);
3390         } ## end for ($i = $line + 1 ; $i...
3391     } ## end else [ if ($slave_editor)
3392
3393     return;
3394 }
3395
3396 sub _handle_t_command {
3397     my $self = shift;
3398
3399     my $levels = $self->cmd_args();
3400
3401     if ((!length($levels)) or ($levels !~ /\D/)) {
3402         $trace ^= 1;
3403         local $\ = '';
3404         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3405         print {$OUT} "Trace = "
3406         . ( ( $trace & 1 )
3407             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3408             : "off" ) . "\n";
3409         next CMD;
3410     }
3411
3412     return;
3413 }
3414
3415
3416 sub _handle_S_command {
3417     my $self = shift;
3418
3419     if (my ($print_all_subs, $should_reverse, $Spatt)
3420         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3421         # $Spatt is the pattern (if any) to use.
3422         # Reverse scan?
3423         my $Srev     = defined $should_reverse;
3424         # No args - print all subs.
3425         my $Snocheck = !defined $print_all_subs;
3426
3427         # Need to make these sane here.
3428         local $\ = '';
3429         local $, = '';
3430
3431         # Search through the debugger's magical hash of subs.
3432         # If $nocheck is true, just print the sub name.
3433         # Otherwise, check it against the pattern. We then use
3434         # the XOR trick to reverse the condition as required.
3435         foreach $subname ( sort( keys %sub ) ) {
3436             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3437                 print $OUT $subname, "\n";
3438             }
3439         }
3440         next CMD;
3441     }
3442
3443     return;
3444 }
3445
3446 sub _handle_V_command_and_X_command {
3447     my $self = shift;
3448
3449     $DB::cmd =~ s/^X\b/V $DB::package/;
3450
3451     # Bare V commands get the currently-being-debugged package
3452     # added.
3453     if ($self->_is_full('V')) {
3454         $DB::cmd = "V $DB::package";
3455     }
3456
3457     # V - show variables in package.
3458     if (my ($new_packname, $new_vars_str) =
3459         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3460
3461         # Save the currently selected filehandle and
3462         # force output to debugger's filehandle (dumpvar
3463         # just does "print" for output).
3464         my $savout = select($OUT);
3465
3466         # Grab package name and variables to dump.
3467         $packname = $new_packname;
3468         my @vars     = split( ' ', $new_vars_str );
3469
3470         # If main::dumpvar isn't here, get it.
3471         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3472         if ( defined &main::dumpvar ) {
3473
3474             # We got it. Turn off subroutine entry/exit messages
3475             # for the moment, along with return values.
3476             local $frame = 0;
3477             local $doret = -2;
3478
3479             # must detect sigpipe failures  - not catching
3480             # then will cause the debugger to die.
3481             eval {
3482                 main::dumpvar(
3483                     $packname,
3484                     defined $option{dumpDepth}
3485                     ? $option{dumpDepth}
3486                     : -1,    # assume -1 unless specified
3487                     @vars
3488                 );
3489             };
3490
3491             # The die doesn't need to include the $@, because
3492             # it will automatically get propagated for us.
3493             if ($@) {
3494                 die unless $@ =~ /dumpvar print failed/;
3495             }
3496         } ## end if (defined &main::dumpvar)
3497         else {
3498
3499             # Couldn't load dumpvar.
3500             print $OUT "dumpvar.pl not available.\n";
3501         }
3502
3503         # Restore the output filehandle, and go round again.
3504         select($savout);
3505         next CMD;
3506     }
3507
3508     return;
3509 }
3510
3511 sub _handle_dash_command {
3512     my $self = shift;
3513
3514     if ($self->_is_full('-')) {
3515
3516         # back up by a window; go to 1 if back too far.
3517         $start -= $incr + $window + 1;
3518         $start = 1 if $start <= 0;
3519         $incr  = $window - 1;
3520
3521         # Generate and execute a "l +" command (handled below).
3522         $DB::cmd = 'l ' . ($start) . '+';
3523         redo CMD;
3524     }
3525     return;
3526 }
3527
3528 sub _n_or_s_commands_generic {
3529     my ($self, $new_val) = @_;
3530     # n - next
3531     next CMD if DB::_DB__is_finished();
3532
3533     # Single step, but don't enter subs.
3534     $single = $new_val;
3535
3536     # Save for empty command (repeat last).
3537     $laststep = $DB::cmd;
3538     last CMD;
3539 }
3540
3541 sub _n_or_s {
3542     my ($self, $letter, $new_val) = @_;
3543
3544     if ($self->_is_full($letter)) {
3545         $self->_n_or_s_commands_generic($new_val);
3546     }
3547     else {
3548         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3549     }
3550
3551     return;
3552 }
3553
3554 sub _handle_n_command {
3555     my $self = shift;
3556
3557     return $self->_n_or_s('n', 2);
3558 }
3559
3560 sub _handle_s_command {
3561     my $self = shift;
3562
3563     return $self->_n_or_s('s', 1);
3564 }
3565
3566 sub _handle_r_command {
3567     my $self = shift;
3568
3569     # r - return from the current subroutine.
3570     if ($self->_is_full('r')) {
3571
3572         # Can't do anything if the program's over.
3573         next CMD if DB::_DB__is_finished();
3574
3575         # Turn on stack trace.
3576         $stack[$stack_depth] |= 1;
3577
3578         # Print return value unless the stack is empty.
3579         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3580         last CMD;
3581     }
3582
3583     return;
3584 }
3585
3586 sub _handle_T_command {
3587     my $self = shift;
3588
3589     if ($self->_is_full('T')) {
3590         DB::print_trace( $OUT, 1 );    # skip DB
3591         next CMD;
3592     }
3593
3594     return;
3595 }
3596
3597 sub _handle_w_command {
3598     my $self = shift;
3599
3600     DB::cmd_w( 'w', $self->cmd_args() );
3601     next CMD;
3602
3603     return;
3604 }
3605
3606 sub _handle_W_command {
3607     my $self = shift;
3608
3609     if (my $arg = $self->cmd_args) {
3610         DB::cmd_W( 'W', $arg );
3611         next CMD;
3612     }
3613
3614     return;
3615 }
3616
3617 sub _handle_rc_recall_command {
3618     my $self = shift;
3619
3620     # $rc - recall command.
3621     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3622
3623         # No arguments, take one thing off history.
3624         pop(@hist) if length($DB::cmd) > 1;
3625
3626         # Relative (- found)?
3627         #  Y - index back from most recent (by 1 if bare minus)
3628         #  N - go to that particular command slot or the last
3629         #      thing if nothing following.
3630
3631         $self->cmd_verb(
3632             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3633         );
3634
3635         # Pick out the command desired.
3636         $DB::cmd = $hist[$self->cmd_verb];
3637
3638         # Print the command to be executed and restart the loop
3639         # with that command in the buffer.
3640         print {$OUT} $DB::cmd, "\n";
3641         redo CMD;
3642     }
3643
3644     return;
3645 }
3646
3647 sub _handle_rc_search_history_command {
3648     my $self = shift;
3649
3650     # $rc pattern $rc - find a command in the history.
3651     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3652
3653         # Create the pattern to use.
3654         my $pat = "^$arg";
3655         $self->pat($pat);
3656
3657         # Toss off last entry if length is >1 (and it always is).
3658         pop(@hist) if length($DB::cmd) > 1;
3659
3660         my $i;
3661
3662         # Look backward through the history.
3663         SEARCH_HIST:
3664         for ( $i = $#hist ; $i ; --$i ) {
3665             # Stop if we find it.
3666             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3667         }
3668
3669         if ( !$i ) {
3670
3671             # Never found it.
3672             print $OUT "No such command!\n\n";
3673             next CMD;
3674         }
3675
3676         # Found it. Put it in the buffer, print it, and process it.
3677         $DB::cmd = $hist[$i];
3678         print $OUT $DB::cmd, "\n";
3679         redo CMD;
3680     }
3681
3682     return;
3683 }
3684
3685 sub _handle_H_command {
3686     my $self = shift;
3687
3688     if ($self->cmd_args =~ m#\A\*#) {
3689         @hist = @truehist = ();
3690         print $OUT "History cleansed\n";
3691         next CMD;
3692     }
3693
3694     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3695
3696         # Anything other than negative numbers is ignored by
3697         # the (incorrect) pattern, so this test does nothing.
3698         $end = $num ? ( $#hist - $num ) : 0;
3699
3700         # Set to the minimum if less than zero.
3701         $hist = 0 if $hist < 0;
3702
3703         # Start at the end of the array.
3704         # Stay in while we're still above the ending value.
3705         # Tick back by one each time around the loop.
3706         my $i;
3707
3708         for ( $i = $#hist ; $i > $end ; $i-- ) {
3709
3710             # Print the command  unless it has no arguments.
3711             print $OUT "$i: ", $hist[$i], "\n"
3712             unless $hist[$i] =~ /^.?$/;
3713         }
3714
3715         next CMD;
3716     }
3717
3718     return;
3719 }
3720
3721 sub _handle_doc_command {
3722     my $self = shift;
3723
3724     # man, perldoc, doc - show manual pages.
3725     if (my ($man_page)
3726         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3727         DB::runman($man_page);
3728         next CMD;
3729     }
3730
3731     return;
3732 }
3733
3734 sub _handle_p_command {
3735     my $self = shift;
3736
3737     my $print_cmd = 'print {$DB::OUT} ';
3738     # p - print (no args): print $_.
3739     if ($self->_is_full('p')) {
3740         $DB::cmd = $print_cmd . '$_';
3741     }
3742     else {
3743         # p - print the given expression.
3744         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3745     }
3746
3747     return;
3748 }
3749
3750 sub _handle_equal_sign_command {
3751     my $self = shift;
3752
3753     if ($DB::cmd =~ s/\A=\s*//) {
3754         my @keys;
3755         if ( length $DB::cmd == 0 ) {
3756
3757             # No args, get current aliases.
3758             @keys = sort keys %alias;
3759         }
3760         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3761
3762             # Creating a new alias. $k is alias name, $v is
3763             # alias value.
3764
3765             # can't use $_ or kill //g state
3766             for my $x ( $k, $v ) {
3767
3768                 # Escape "alarm" characters.
3769                 $x =~ s/\a/\\a/g;
3770             }
3771
3772             # Substitute key for value, using alarm chars
3773             # as separators (which is why we escaped them in
3774             # the command).
3775             $alias{$k} = "s\a$k\a$v\a";
3776
3777             # Turn off standard warn and die behavior.
3778             local $SIG{__DIE__};
3779             local $SIG{__WARN__};
3780
3781             # Is it valid Perl?
3782             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3783
3784                 # Nope. Bad alias. Say so and get out.
3785                 print $OUT "Can't alias $k to $v: $@\n";
3786                 delete $alias{$k};
3787                 next CMD;
3788             }
3789
3790             # We'll only list the new one.
3791             @keys = ($k);
3792         } ## end elsif (my ($k, $v) = ($DB::cmd...
3793
3794         # The argument is the alias to list.
3795         else {
3796             @keys = ($DB::cmd);
3797         }
3798
3799         # List aliases.
3800         for my $k (@keys) {
3801
3802             # Messy metaquoting: Trim the substitution code off.
3803             # We use control-G as the delimiter because it's not
3804             # likely to appear in the alias.
3805             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3806
3807                 # Print the alias.
3808                 print $OUT "$k\t= $1\n";
3809             }
3810             elsif ( defined $alias{$k} ) {
3811
3812                 # Couldn't trim it off; just print the alias code.
3813                 print $OUT "$k\t$alias{$k}\n";
3814             }
3815             else {
3816
3817                 # No such, dude.
3818                 print "No alias for $k\n";
3819             }
3820         } ## end for my $k (@keys)
3821         next CMD;
3822     }
3823
3824     return;
3825 }
3826
3827 sub _handle_source_command {
3828     my $self = shift;
3829
3830     # source - read commands from a file (or pipe!) and execute.
3831     if (my $sourced_fn = $self->cmd_args) {
3832         if ( open my $fh, $sourced_fn ) {
3833
3834             # Opened OK; stick it in the list of file handles.
3835             push @cmdfhs, $fh;
3836         }
3837         else {
3838
3839             # Couldn't open it.
3840             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3841         }
3842         next CMD;
3843     }
3844
3845     return;
3846 }
3847
3848 sub _handle_enable_disable_commands {
3849     my $self = shift;
3850
3851     my $which_cmd = $self->cmd_verb;
3852     my $position = $self->cmd_args;
3853
3854     if ($position !~ /\s/) {
3855         my ($fn, $line_num);
3856         if ($position =~ m{\A\d+\z})
3857         {
3858             $fn = $DB::filename;
3859             $line_num = $position;
3860         }
3861         elsif (my ($new_fn, $new_line_num)
3862             = $position =~ m{\A(.*):(\d+)\z}) {
3863             ($fn, $line_num) = ($new_fn, $new_line_num);
3864         }
3865         else
3866         {
3867             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3868         }
3869
3870         if (defined($fn)) {
3871             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3872                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3873                     ($which_cmd eq 'enable' ? 1 : '')
3874                 );
3875             }
3876             else {
3877                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3878             }
3879         }
3880
3881         next CMD;
3882     }
3883
3884     return;
3885 }
3886
3887 sub _handle_save_command {
3888     my $self = shift;
3889
3890     if (my $new_fn = $self->cmd_args) {
3891         my $filename = $new_fn || '.perl5dbrc';    # default?
3892         if ( open my $fh, '>', $filename ) {
3893
3894             # chomp to remove extraneous newlines from source'd files
3895             chomp( my @truelist =
3896                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3897                 @truehist );
3898             print {$fh} join( "\n", @truelist );
3899             print "commands saved in $filename\n";
3900         }
3901         else {
3902             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3903         }
3904         next CMD;
3905     }
3906
3907     return;
3908 }
3909
3910 sub _n_or_s_and_arg_commands_generic {
3911     my ($self, $letter, $new_val) = @_;
3912
3913     # s - single-step. Remember the last command was 's'.
3914     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3915         $laststep = $letter;
3916     }
3917
3918     return;
3919 }
3920
3921 sub _handle_sh_command {
3922     my $self = shift;
3923
3924     # $sh$sh - run a shell command (if it's all ASCII).
3925     # Can't run shell commands with Unicode in the debugger, hmm.
3926     my $my_cmd = $DB::cmd;
3927     if ($my_cmd =~ m#\A$sh#gms) {
3928
3929         if ($my_cmd =~ m#\G\z#cgms) {
3930             # Run the user's shell. If none defined, run Bourne.
3931             # We resume execution when the shell terminates.
3932             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3933             next CMD;
3934         }
3935         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3936             # System it.
3937             DB::_db_system($1);
3938             next CMD;
3939         }
3940         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3941             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3942             next CMD;
3943         }
3944     }
3945 }
3946
3947 sub _handle_x_command {
3948     my $self = shift;
3949
3950     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3951         $onetimeDump = 'dump';    # main::dumpvar shows the output
3952
3953         # handle special  "x 3 blah" syntax XXX propagate
3954         # doc back to special variables.
3955         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3956             $onetimedumpDepth = $1;
3957         }
3958     }
3959
3960     return;
3961 }
3962
3963 sub _handle_q_command {
3964     my $self = shift;
3965
3966     if ($self->_is_full('q')) {
3967         $fall_off_end = 1;
3968         DB::clean_ENV();
3969         exit $?;
3970     }
3971
3972     return;
3973 }
3974
3975 sub _handle_cmd_wrapper_commands {
3976     my $self = shift;
3977
3978     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3979     next CMD;
3980 }
3981
3982 sub _handle_special_char_cmd_wrapper_commands {
3983     my $self = shift;
3984
3985     # All of these commands were remapped in perl 5.8.0;
3986     # we send them off to the secondary dispatcher (see below).
3987     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
3988         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
3989         next CMD;
3990     }
3991
3992     return;
3993 }
3994
3995 } ## end DB::Obj
3996
3997 package DB;
3998
3999 # The following code may be executed now:
4000 # BEGIN {warn 4}
4001
4002 =head2 sub
4003
4004 C<sub> is called whenever a subroutine call happens in the program being
4005 debugged. The variable C<$DB::sub> contains the name of the subroutine
4006 being called.
4007
4008 The core function of this subroutine is to actually call the sub in the proper
4009 context, capturing its output. This of course causes C<DB::DB> to get called
4010 again, repeating until the subroutine ends and returns control to C<DB::sub>
4011 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4012 return value, and returns its captured copy of the return value as its own
4013 return value. The value then feeds back into the program being debugged as if
4014 C<DB::sub> hadn't been there at all.
4015
4016 C<sub> does all the work of printing the subroutine entry and exit messages
4017 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4018 and also prints the return value if needed (for the C<r> command and if
4019 the 16 bit is set in C<$frame>).
4020
4021 It also tracks the subroutine call depth by saving the current setting of
4022 C<$single> in the C<@stack> package global; if this exceeds the value in
4023 C<$deep>, C<sub> automatically turns on printing of the current depth by
4024 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4025 of stop/don't stop on entry to subs set as it currently is set.
4026
4027 =head3 C<caller()> support
4028
4029 If C<caller()> is called from the package C<DB>, it provides some
4030 additional data, in the following order:
4031
4032 =over 4
4033
4034 =item * C<$package>
4035
4036 The package name the sub was in
4037
4038 =item * C<$filename>
4039
4040 The filename it was defined in
4041
4042 =item * C<$line>
4043
4044 The line number it was defined on
4045
4046 =item * C<$subroutine>
4047
4048 The subroutine name; C<(eval)> if an C<eval>().
4049
4050 =item * C<$hasargs>
4051
4052 1 if it has arguments, 0 if not
4053
4054 =item * C<$wantarray>
4055
4056 1 if array context, 0 if scalar context
4057
4058 =item * C<$evaltext>
4059
4060 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4061
4062 =item * C<$is_require>
4063
4064 frame was created by a C<use> or C<require> statement
4065
4066 =item * C<$hints>
4067
4068 pragma information; subject to change between versions
4069
4070 =item * C<$bitmask>
4071
4072 pragma information; subject to change between versions
4073
4074 =item * C<@DB::args>
4075
4076 arguments with which the subroutine was invoked
4077
4078 =back
4079
4080 =cut
4081
4082 use vars qw($deep);
4083
4084 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4085 # happy. -- Shlomi Fish
4086
4087 sub _indent_print_line_info {
4088     my ($offset, $str) = @_;
4089
4090     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4091
4092     return;
4093 }
4094
4095 sub _print_frame_message {
4096     my ($al) = @_;
4097
4098     if ($frame) {
4099         if ($frame & 4) {   # Extended frame entry message
4100             _indent_print_line_info(-1, "in  ");
4101
4102             # Why -1? But it works! :-(
4103             # Because print_trace will call add 1 to it and then call
4104             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4105             # in dump_trace.
4106             #
4107             # Now it's 0 because we extracted a function.
4108             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4109         }
4110         else {
4111             _indent_print_line_info(-1, "entering $sub$al\n" );
4112         }
4113     }
4114
4115     return;
4116 }
4117
4118 sub DB::sub {
4119     # lock ourselves under threads
4120     lock($DBGR);
4121
4122     # Whether or not the autoloader was running, a scalar to put the
4123     # sub's return value in (if needed), and an array to put the sub's
4124     # return value in (if needed).
4125     my ( $al, $ret, @ret ) = "";
4126     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4127         print "creating new thread\n";
4128     }
4129
4130     # If the last ten characters are '::AUTOLOAD', note we've traced
4131     # into AUTOLOAD for $sub.
4132     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4133         no strict 'refs';
4134         $al = " for $$sub" if defined $$sub;
4135     }
4136
4137     # We stack the stack pointer and then increment it to protect us
4138     # from a situation that might unwind a whole bunch of call frames
4139     # at once. Localizing the stack pointer means that it will automatically
4140     # unwind the same amount when multiple stack frames are unwound.
4141     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4142
4143     # Expand @stack.
4144     $#stack = $stack_depth;
4145
4146     # Save current single-step setting.
4147     $stack[-1] = $single;
4148
4149     # Turn off all flags except single-stepping.
4150     $single &= 1;
4151
4152     # If we've gotten really deeply recursed, turn on the flag that will
4153     # make us stop with the 'deep recursion' message.
4154     $single |= 4 if $stack_depth == $deep;
4155
4156     # If frame messages are on ...
4157
4158     _print_frame_message($al);
4159     # standard frame entry message
4160
4161     my $print_exit_msg = sub {
4162         # Check for exit trace messages...
4163         if ($frame & 2)
4164         {
4165             if ($frame & 4)    # Extended exit message
4166             {
4167                 _indent_print_line_info(0, "out ");
4168                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4169             }
4170             else
4171             {
4172                 _indent_print_line_info(0, "exited $sub$al\n" );
4173             }
4174         }
4175         return;
4176     };
4177
4178     # Determine the sub's return type, and capture appropriately.
4179     if (wantarray) {
4180
4181         # Called in array context. call sub and capture output.
4182         # DB::DB will recursively get control again if appropriate; we'll come
4183         # back here when the sub is finished.
4184         {
4185             no strict 'refs';
4186             @ret = &$sub;
4187         }
4188
4189         # Pop the single-step value back off the stack.
4190         $single |= $stack[ $stack_depth-- ];
4191
4192         $print_exit_msg->();
4193
4194         # Print the return info if we need to.
4195         if ( $doret eq $stack_depth or $frame & 16 ) {
4196
4197             # Turn off output record separator.
4198             local $\ = '';
4199             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4200
4201             # Indent if we're printing because of $frame tracing.
4202             if ($frame & 16)
4203             {
4204                 print {$fh} ' ' x $stack_depth;
4205             }
4206
4207             # Print the return value.
4208             print {$fh} "list context return from $sub:\n";
4209             dumpit( $fh, \@ret );
4210
4211             # And don't print it again.
4212             $doret = -2;
4213         } ## end if ($doret eq $stack_depth...
4214             # And we have to return the return value now.
4215         @ret;
4216     } ## end if (wantarray)
4217
4218     # Scalar context.
4219     else {
4220         if ( defined wantarray ) {
4221             no strict 'refs';
4222             # Save the value if it's wanted at all.
4223             $ret = &$sub;
4224         }
4225         else {
4226             no strict 'refs';
4227             # Void return, explicitly.
4228             &$sub;
4229             undef $ret;
4230         }
4231
4232         # Pop the single-step value off the stack.
4233         $single |= $stack[ $stack_depth-- ];
4234
4235         # If we're doing exit messages...
4236         $print_exit_msg->();
4237
4238         # If we are supposed to show the return value... same as before.
4239         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4240             local $\ = '';
4241             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4242             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4243             print $fh (
4244                 defined wantarray
4245                 ? "scalar context return from $sub: "
4246                 : "void context return from $sub\n"
4247             );
4248             dumpit( $fh, $ret ) if defined wantarray;
4249             $doret = -2;
4250         } ## end if ($doret eq $stack_depth...
4251
4252         # Return the appropriate scalar value.
4253         $ret;
4254     } ## end else [ if (wantarray)
4255 } ## end sub _sub
4256
4257 sub lsub : lvalue {
4258
4259     no strict 'refs';
4260
4261     # lock ourselves under threads
4262     lock($DBGR);
4263
4264     # Whether or not the autoloader was running, a scalar to put the
4265     # sub's return value in (if needed), and an array to put the sub's
4266     # return value in (if needed).
4267     my ( $al, $ret, @ret ) = "";
4268     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4269         print "creating new thread\n";
4270     }
4271
4272     # If the last ten characters are C'::AUTOLOAD', note we've traced
4273     # into AUTOLOAD for $sub.
4274     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4275         $al = " for $$sub";
4276     }
4277
4278     # We stack the stack pointer and then increment it to protect us
4279     # from a situation that might unwind a whole bunch of call frames
4280     # at once. Localizing the stack pointer means that it will automatically
4281     # unwind the same amount when multiple stack frames are unwound.
4282     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4283
4284     # Expand @stack.
4285     $#stack = $stack_depth;
4286
4287     # Save current single-step setting.
4288     $stack[-1] = $single;
4289
4290     # Turn off all flags except single-stepping.
4291     # Use local so the single-step value is popped back off the
4292     # stack for us.
4293     local $single = $single & 1;
4294
4295     # If we've gotten really deeply recursed, turn on the flag that will
4296     # make us stop with the 'deep recursion' message.
4297     $single |= 4 if $stack_depth == $deep;
4298
4299     # If frame messages are on ...
4300     _print_frame_message($al);
4301
4302     # call the original lvalue sub.
4303     &$sub;
4304 }
4305
4306 # Abstracting common code from multiple places elsewhere:
4307 sub depth_print_lineinfo {
4308     my $always_print = shift;
4309
4310     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4311 }
4312
4313 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4314
4315 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4316 Most of the changes were to systematize the command structure and to eliminate
4317 commands that threw away user input without checking.
4318
4319 The following sections describe the code added to make it easy to support
4320 multiple command sets with conflicting command names. This section is a start
4321 at unifying all command processing to make it simpler to develop commands.
4322
4323 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4324 number, and C<$dbline> (the current line) as arguments.
4325
4326 Support functions in this section which have multiple modes of failure C<die>
4327 on error; the rest simply return a false value.
4328
4329 The user-interface functions (all of the C<cmd_*> functions) just output
4330 error messages.
4331
4332 =head2 C<%set>
4333
4334 The C<%set> hash defines the mapping from command letter to subroutine
4335 name suffix.
4336
4337 C<%set> is a two-level hash, indexed by set name and then by command name.
4338 Note that trying to set the CommandSet to C<foobar> simply results in the
4339 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4340
4341 =cut
4342
4343 ### The API section
4344
4345 my %set = (    #
4346     'pre580' => {
4347         'a' => 'pre580_a',
4348         'A' => 'pre580_null',
4349         'b' => 'pre580_b',
4350         'B' => 'pre580_null',
4351         'd' => 'pre580_null',
4352         'D' => 'pre580_D',
4353         'h' => 'pre580_h',
4354         'M' => 'pre580_null',
4355         'O' => 'o',
4356         'o' => 'pre580_null',
4357         'v' => 'M',
4358         'w' => 'v',
4359         'W' => 'pre580_W',
4360     },
4361     'pre590' => {
4362         '<'  => 'pre590_prepost',
4363         '<<' => 'pre590_prepost',
4364         '>'  => 'pre590_prepost',
4365         '>>' => 'pre590_prepost',
4366         '{'  => 'pre590_prepost',
4367         '{{' => 'pre590_prepost',
4368     },
4369 );
4370
4371 my %breakpoints_data;
4372
4373 sub _has_breakpoint_data_ref {
4374     my ($filename, $line) = @_;
4375
4376     return (
4377         exists( $breakpoints_data{$filename} )
4378             and
4379         exists( $breakpoints_data{$filename}{$line} )
4380     );
4381 }
4382
4383 sub _get_breakpoint_data_ref {
4384     my ($filename, $line) = @_;
4385
4386     return ($breakpoints_data{$filename}{$line} ||= +{});
4387 }
4388
4389 sub _delete_breakpoint_data_ref {
4390     my ($filename, $line) = @_;
4391
4392     delete($breakpoints_data{$filename}{$line});
4393     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4394         delete($breakpoints_data{$filename});
4395     }
4396
4397     return;
4398 }
4399
4400 sub _set_breakpoint_enabled_status {
4401     my ($filename, $line, $status) = @_;
4402
4403     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4404         ($status ? 1 : '')
4405         ;
4406
4407     return;
4408 }
4409
4410 sub _enable_breakpoint_temp_enabled_status {
4411     my ($filename, $line) = @_;
4412
4413     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4414
4415     return;
4416 }
4417
4418 sub _cancel_breakpoint_temp_enabled_status {
4419     my ($filename, $line) = @_;
4420
4421     my $ref = _get_breakpoint_data_ref($filename, $line);
4422
4423     delete ($ref->{'temp_enabled'});
4424
4425     if (! %$ref) {
4426         _delete_breakpoint_data_ref($filename, $line);
4427     }
4428
4429     return;
4430 }
4431
4432 sub _is_breakpoint_enabled {
4433     my ($filename, $line) = @_;
4434
4435     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4436     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4437 }
4438
4439 =head2 C<cmd_wrapper()> (API)
4440
4441 C<cmd_wrapper()> allows the debugger to switch command sets
4442 depending on the value of the C<CommandSet> option.
4443
4444 It tries to look up the command in the C<%set> package-level I<lexical>
4445 (which means external entities can't fiddle with it) and create the name of
4446 the sub to call based on the value found in the hash (if it's there). I<All>
4447 of the commands to be handled in a set have to be added to C<%set>; if they
4448 aren't found, the 5.8.0 equivalent is called (if there is one).
4449
4450 This code uses symbolic references.
4451
4452 =cut
4453
4454 sub cmd_wrapper {
4455     my $cmd      = shift;
4456     my $line     = shift;
4457     my $dblineno = shift;
4458
4459     # Assemble the command subroutine's name by looking up the
4460     # command set and command name in %set. If we can't find it,
4461     # default to the older version of the command.
4462     my $call = 'cmd_'
4463       . ( $set{$CommandSet}{$cmd}
4464           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4465
4466     # Call the command subroutine, call it by name.
4467     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4468 } ## end sub cmd_wrapper
4469
4470 =head3 C<cmd_a> (command)
4471
4472 The C<a> command handles pre-execution actions. These are associated with a
4473 particular line, so they're stored in C<%dbline>. We default to the current
4474 line if none is specified.
4475
4476 =cut
4477
4478 sub cmd_a {
4479     my $cmd    = shift;
4480     my $line   = shift || '';    # [.|line] expr
4481     my $dbline = shift;
4482
4483     # If it's dot (here), or not all digits,  use the current line.
4484     $line =~ s/\A\./$dbline/;
4485
4486     # Should be a line number followed by an expression.
4487     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4488
4489         if (! length($lineno)) {
4490             $lineno = $dbline;
4491         }
4492
4493         # If we have an expression ...
4494         if ( length $expr ) {
4495
4496             # ... but the line isn't breakable, complain.
4497             if ( $dbline[$lineno] == 0 ) {
4498                 print $OUT
4499                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4500             }
4501             else {
4502
4503                 # It's executable. Record that the line has an action.
4504                 $had_breakpoints{$filename} |= 2;
4505
4506                 # Remove any action, temp breakpoint, etc.
4507                 $dbline{$lineno} =~ s/\0[^\0]*//;
4508
4509                 # Add the action to the line.
4510                 $dbline{$lineno} .= "\0" . action($expr);
4511
4512                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4513             }
4514         } ## end if (length $expr)
4515     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4516     else {
4517
4518         # Syntax wrong.
4519         print $OUT
4520           "Adding an action requires an optional lineno and an expression\n"
4521           ;    # hint
4522     }
4523 } ## end sub cmd_a
4524
4525 =head3 C<cmd_A> (command)
4526
4527 Delete actions. Similar to above, except the delete code is in a separate
4528 subroutine, C<delete_action>.
4529
4530 =cut
4531
4532 sub cmd_A {
4533     my $cmd    = shift;
4534     my $line   = shift || '';
4535     my $dbline = shift;
4536
4537     # Dot is this line.
4538     $line =~ s/^\./$dbline/;
4539
4540     # Call delete_action with a null param to delete them all.
4541     # The '1' forces the eval to be true. It'll be false only
4542     # if delete_action blows up for some reason, in which case
4543     # we print $@ and get out.
4544     if ( $line eq '*' ) {
4545         if (! eval { _delete_all_actions(); 1 }) {
4546             print {$OUT} $@;
4547             return;
4548         }
4549     }
4550
4551     # There's a real line  number. Pass it to delete_action.
4552     # Error trapping is as above.
4553     elsif ( $line =~ /^(\S.*)/ ) {
4554         if (! eval { delete_action($1); 1 }) {
4555             print {$OUT} $@;
4556             return;
4557         }
4558     }
4559
4560     # Swing and a miss. Bad syntax.
4561     else {
4562         print $OUT
4563           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4564     }
4565 } ## end sub cmd_A
4566
4567 =head3 C<delete_action> (API)
4568
4569 C<delete_action> accepts either a line number or C<undef>. If a line number
4570 is specified, we check for the line being executable (if it's not, it
4571 couldn't have had an  action). If it is, we just take the action off (this
4572 will get any kind of an action, including breakpoints).
4573
4574 =cut
4575
4576 sub _remove_action_from_dbline {
4577     my $i = shift;
4578
4579     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4580     delete $dbline{$i} if $dbline{$i} eq '';
4581
4582     return;
4583 }
4584
4585 sub _delete_all_actions {
4586     print {$OUT} "Deleting all actions...\n";
4587
4588     for my $file ( keys %had_breakpoints ) {
4589         local *dbline = $main::{ '_<' . $file };
4590         $max = $#dbline;
4591         my $was;
4592         for my $i (1 .. $max) {
4593             if ( defined $dbline{$i} ) {
4594                 _remove_action_from_dbline($i);
4595             }
4596         }
4597
4598         unless ( $had_breakpoints{$file} &= ~2 ) {
4599             delete $had_breakpoints{$file};
4600         }
4601     }
4602
4603     return;
4604 }
4605
4606 sub delete_action {
4607     my $i = shift;
4608
4609     if ( defined($i) ) {
4610         # Can there be one?
4611         die "Line $i has no action .\n" if $dbline[$i] == 0;
4612
4613         # Nuke whatever's there.
4614         _remove_action_from_dbline($i);
4615     }
4616     else {
4617         _delete_all_actions();
4618     }
4619 }
4620
4621 =head3 C<cmd_b> (command)
4622
4623 Set breakpoints. Since breakpoints can be set in so many places, in so many
4624 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4625 we try to parse the command type, and then shuttle it off to an appropriate
4626 subroutine to actually do the work of setting the breakpoint in the right
4627 place.
4628
4629 =cut
4630
4631 sub cmd_b {
4632     my $cmd    = shift;
4633     my $line   = shift;    # [.|line] [cond]
4634     my $dbline = shift;
4635
4636     my $default_cond = sub {
4637         my $cond = shift;
4638         return length($cond) ? $cond : '1';
4639     };
4640
4641     # Make . the current line number if it's there..
4642     $line =~ s/^\.(\s|\z)/$dbline$1/;
4643
4644     # No line number, no condition. Simple break on current line.
4645     if ( $line =~ /^\s*$/ ) {
4646         cmd_b_line( $dbline, 1 );
4647     }
4648
4649     # Break on load for a file.
4650     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4651         $file =~ s/\s+\z//;
4652         cmd_b_load($file);
4653     }
4654
4655     # b compile|postpone <some sub> [<condition>]
4656     # The interpreter actually traps this one for us; we just put the
4657     # necessary condition in the %postponed hash.
4658     elsif ( my ($action, $subname, $cond)
4659         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4660
4661         # De-Perl4-ify the name - ' separators to ::.
4662         $subname =~ s/'/::/g;
4663
4664         # Qualify it into the current package unless it's already qualified.
4665         $subname = "${package}::" . $subname unless $subname =~ /::/;
4666
4667         # Add main if it starts with ::.
4668         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4669
4670         # Save the break type for this sub.
4671         $postponed{$subname} = (($action eq 'postpone')
4672             ? ( "break +0 if " . $default_cond->($cond) )
4673             : "compile");
4674     } ## end elsif ($line =~ ...
4675     # b <filename>:<line> [<condition>]
4676     elsif (my ($filename, $line_num, $cond)
4677         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4678         cmd_b_filename_line(
4679             $filename,
4680             $line_num,
4681             (length($cond) ? $cond : '1'),
4682         );
4683     }
4684     # b <sub name> [<condition>]
4685     elsif ( my ($new_subname, $new_cond) =
4686         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4687
4688         #
4689         $subname = $new_subname;
4690         cmd_b_sub( $subname, $default_cond->($new_cond) );
4691     }
4692
4693     # b <line> [<condition>].
4694     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4695
4696         # Capture the line. If none, it's the current line.
4697         $line = $line_n || $dbline;
4698
4699         # Break on line.
4700         cmd_b_line( $line, $default_cond->($cond) );
4701     }
4702
4703     # Line didn't make sense.
4704     else {
4705         print "confused by line($line)?\n";
4706     }
4707
4708     return;
4709 } ## end sub cmd_b
4710
4711 =head3 C<break_on_load> (API)
4712
4713 We want to break when this file is loaded. Mark this file in the
4714 C<%break_on_load> hash, and note that it has a breakpoint in
4715 C<%had_breakpoints>.
4716
4717 =cut
4718
4719 sub break_on_load {
4720     my $file = shift;
4721     $break_on_load{$file} = 1;
4722     $had_breakpoints{$file} |= 1;
4723 }
4724
4725 =head3 C<report_break_on_load> (API)
4726
4727 Gives us an array of filenames that are set to break on load. Note that
4728 only files with break-on-load are in here, so simply showing the keys
4729 suffices.
4730
4731 =cut
4732
4733 sub report_break_on_load {
4734     sort keys %break_on_load;
4735 }
4736
4737 =head3 C<cmd_b_load> (command)
4738
4739 We take the file passed in and try to find it in C<%INC> (which maps modules
4740 to files they came from). We mark those files for break-on-load via
4741 C<break_on_load> and then report that it was done.
4742
4743 =cut
4744
4745 sub cmd_b_load {
4746     my $file = shift;
4747     my @files;
4748
4749     # This is a block because that way we can use a redo inside it
4750     # even without there being any looping structure at all outside it.
4751     {
4752
4753         # Save short name and full path if found.
4754         push @files, $file;
4755         push @files, $::INC{$file} if $::INC{$file};
4756
4757         # Tack on .pm and do it again unless there was a '.' in the name
4758         # already.
4759         $file .= '.pm', redo unless $file =~ /\./;
4760     }
4761
4762     # Do the real work here.
4763     break_on_load($_) for @files;
4764
4765     # All the files that have break-on-load breakpoints.
4766     @files = report_break_on_load;
4767
4768     # Normalize for the purposes of our printing this.
4769     local $\ = '';
4770     local $" = ' ';
4771     print $OUT "Will stop on load of '@files'.\n";
4772 } ## end sub cmd_b_load
4773
4774 =head3 C<$filename_error> (API package global)
4775
4776 Several of the functions we need to implement in the API need to work both
4777 on the current file and on other files. We don't want to duplicate code, so
4778 C<$filename_error> is used to contain the name of the file that's being
4779 worked on (if it's not the current one).
4780
4781 We can now build functions in pairs: the basic function works on the current
4782 file, and uses C<$filename_error> as part of its error message. Since this is
4783 initialized to C<"">, no filename will appear when we are working on the
4784 current file.
4785
4786 The second function is a wrapper which does the following:
4787
4788 =over 4
4789
4790 =item *
4791
4792 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4793
4794 =item *
4795
4796 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4797
4798 =item *
4799
4800 Calls the first function.
4801
4802 The first function works on the I<current> file (i.e., the one we changed to),
4803 and prints C<$filename_error> in the error message (the name of the other file)
4804 if it needs to. When the functions return, C<*dbline> is restored to point
4805 to the actual current file (the one we're executing in) and
4806 C<$filename_error> is restored to C<"">. This restores everything to
4807 the way it was before the second function was called at all.
4808
4809 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4810 details.
4811
4812 =back
4813
4814 =cut
4815
4816 use vars qw($filename_error);
4817 $filename_error = '';
4818
4819 =head3 breakable_line(from, to) (API)
4820
4821 The subroutine decides whether or not a line in the current file is breakable.
4822 It walks through C<@dbline> within the range of lines specified, looking for
4823 the first line that is breakable.
4824
4825 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4826 first line I<after> C<$to> that's breakable, if there is one.
4827
4828 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4829 first line I<before> C<$to> that's breakable, if there is one.
4830
4831 =cut
4832
4833 sub breakable_line {
4834
4835     my ( $from, $to ) = @_;
4836
4837     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4838     my $i = $from;
4839
4840     # If there are at least 2 arguments, we're trying to search a range.
4841     if ( @_ >= 2 ) {
4842
4843         # $delta is positive for a forward search, negative for a backward one.
4844         my $delta = $from < $to ? +1 : -1;
4845
4846         # Keep us from running off the ends of the file.
4847         my $limit = $delta > 0 ? $#dbline : 1;
4848
4849         # Clever test. If you're a mathematician, it's obvious why this
4850         # test works. If not:
4851         # If $delta is positive (going forward), $limit will be $#dbline.
4852         #    If $to is less than $limit, ($limit - $to) will be positive, times
4853         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4854         #    as the stopping point.
4855         #
4856         #    If $to is greater than $limit, ($limit - $to) is negative,
4857         #    times $delta of 1 (positive), so the result is < 0 and we should
4858         #    use $limit ($#dbline) as the stopping point.
4859         #
4860         # If $delta is negative (going backward), $limit will be 1.
4861         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4862         #    (negative) so the result is > 0, and we use $to as the stopping
4863         #    point.
4864         #
4865         #    If $to is less than zero, ($limit - $to) will be positive,
4866         #    times $delta of -1 (negative), so the result is not > 0, and
4867         #    we use $limit (1) as the stopping point.
4868         #
4869         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4870         #    (negative), still giving zero; the result is not > 0, and
4871         #    we use $limit (1) as the stopping point.
4872         #
4873         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4874         #    (negative), giving a positive (>0) value, so we'll set $limit to
4875         #    $to.
4876
4877         $limit = $to if ( $limit - $to ) * $delta > 0;
4878
4879         # The real search loop.
4880         # $i starts at $from (the point we want to start searching from).
4881         # We move through @dbline in the appropriate direction (determined
4882         # by $delta: either -1 (back) or +1 (ahead).
4883         # We stay in as long as we haven't hit an executable line
4884         # ($dbline[$i] == 0 means not executable) and we haven't reached
4885         # the limit yet (test similar to the above).
4886         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4887
4888     } ## end if (@_ >= 2)
4889
4890     # If $i points to a line that is executable, return that.
4891     return $i unless $dbline[$i] == 0;
4892
4893     # Format the message and print it: no breakable lines in range.
4894     my ( $pl, $upto ) = ( '', '' );
4895     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4896
4897     # If there's a filename in filename_error, we'll see it.
4898     # If not, not.
4899     die "Line$pl $from$upto$filename_error not breakable\n";
4900 } ## end sub breakable_line
4901
4902 =head3 breakable_line_in_filename(file, from, to) (API)
4903
4904 Like C<breakable_line>, but look in another file.
4905
4906 =cut
4907
4908 sub breakable_line_in_filename {
4909
4910     # Capture the file name.
4911     my ($f) = shift;
4912
4913     # Swap the magic line array over there temporarily.
4914     local *dbline = $main::{ '_<' . $f };
4915
4916     # If there's an error, it's in this other file.
4917     local $filename_error = " of '$f'";
4918
4919     # Find the breakable line.
4920     breakable_line(@_);
4921
4922     # *dbline and $filename_error get restored when this block ends.
4923
4924 } ## end sub breakable_line_in_filename
4925
4926 =head3 break_on_line(lineno, [condition]) (API)
4927
4928 Adds a breakpoint with the specified condition (or 1 if no condition was
4929 specified) to the specified line. Dies if it can't.
4930
4931 =cut
4932
4933 sub break_on_line {
4934     my $i = shift;
4935     my $cond = @_ ? shift(@_) : 1;
4936
4937     my $inii  = $i;
4938     my $after = '';
4939     my $pl    = '';
4940
4941     # Woops, not a breakable line. $filename_error allows us to say
4942     # if it was in a different file.
4943     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4944
4945     # Mark this file as having breakpoints in it.
4946     $had_breakpoints{$filename} |= 1;
4947
4948     # If there is an action or condition here already ...
4949     if ( $dbline{$i} ) {
4950
4951         # ... swap this condition for the existing one.
4952         $dbline{$i} =~ s/^[^\0]*/$cond/;
4953     }
4954     else {
4955
4956         # Nothing here - just add the condition.
4957         $dbline{$i} = $cond;
4958
4959         _set_breakpoint_enabled_status($filename, $i, 1);
4960     }
4961
4962     return;
4963 } ## end sub break_on_line
4964
4965 =head3 cmd_b_line(line, [condition]) (command)
4966
4967 Wrapper for C<break_on_line>. Prints the failure message if it
4968 doesn't work.
4969
4970 =cut
4971
4972 sub cmd_b_line {
4973     if (not eval { break_on_line(@_); 1 }) {
4974         local $\ = '';
4975         print $OUT $@ and return;
4976     }
4977
4978     return;
4979 } ## end sub cmd_b_line
4980
4981 =head3 cmd_b_filename_line(line, [condition]) (command)
4982
4983 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4984 doesn't work.
4985
4986 =cut
4987
4988 sub cmd_b_filename_line {
4989     if (not eval { break_on_filename_line(@_); 1 }) {
4990         local $\ = '';
4991         print $OUT $@ and return;
4992     }
4993
4994     return;
4995 }
4996
4997 =head3 break_on_filename_line(file, line, [condition]) (API)
4998
4999 Switches to the file specified and then calls C<break_on_line> to set
5000 the breakpoint.
5001
5002 =cut
5003
5004 sub break_on_filename_line {
5005     my $f = shift;
5006     my $i = shift;
5007     my $cond = @_ ? shift(@_) : 1;
5008
5009     # Switch the magical hash temporarily.
5010     local *dbline = $main::{ '_<' . $f };
5011
5012     # Localize the variables that break_on_line uses to make its message.
5013     local $filename_error = " of '$f'";
5014     local $filename       = $f;
5015
5016     # Add the breakpoint.
5017     break_on_line( $i, $cond );
5018
5019     return;
5020 } ## end sub break_on_filename_line
5021
5022 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
5023
5024 Switch to another file, search the range of lines specified for an
5025 executable one, and put a breakpoint on the first one you find.
5026
5027 =cut
5028
5029 sub break_on_filename_line_range {
5030     my $f = shift;
5031     my $from = shift;
5032     my $to = shift;
5033     my $cond = @_ ? shift(@_) : 1;
5034
5035     # Find a breakable line if there is one.
5036     my $i = breakable_line_in_filename( $f, $from, $to );
5037
5038     # Add the breakpoint.
5039     break_on_filename_line( $f, $i, $cond );
5040
5041     return;
5042 } ## end sub break_on_filename_line_range
5043
5044 =head3 subroutine_filename_lines(subname, [condition]) (API)
5045
5046 Search for a subroutine within a given file. The condition is ignored.
5047 Uses C<find_sub> to locate the desired subroutine.
5048
5049 =cut
5050
5051 sub subroutine_filename_lines {
5052     my ( $subname ) = @_;
5053
5054     # Returned value from find_sub() is fullpathname:startline-endline.
5055     # The match creates the list (fullpathname, start, end).
5056     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5057 } ## end sub subroutine_filename_lines
5058
5059 =head3 break_subroutine(subname) (API)
5060
5061 Places a break on the first line possible in the specified subroutine. Uses
5062 C<subroutine_filename_lines> to find the subroutine, and
5063 C<break_on_filename_line_range> to place the break.
5064
5065 =cut
5066
5067 sub break_subroutine {
5068     my $subname = shift;
5069
5070     # Get filename, start, and end.
5071     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5072       or die "Subroutine $subname not found.\n";
5073
5074
5075     # Null condition changes to '1' (always true).
5076     my $cond = @_ ? shift(@_) : 1;
5077
5078     # Put a break the first place possible in the range of lines
5079     # that make up this subroutine.
5080     break_on_filename_line_range( $file, $s, $e, $cond );
5081
5082     return;
5083 } ## end sub break_subroutine
5084
5085 =head3 cmd_b_sub(subname, [condition]) (command)
5086
5087 We take the incoming subroutine name and fully-qualify it as best we can.
5088
5089 =over 4
5090
5091 =item 1. If it's already fully-qualified, leave it alone.
5092
5093 =item 2. Try putting it in the current package.
5094
5095 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5096
5097 =item 4. If it starts with '::', put it in 'main::'.
5098
5099 =back
5100
5101 After all this cleanup, we call C<break_subroutine> to try to set the
5102 breakpoint.
5103
5104 =cut
5105
5106 sub cmd_b_sub {
5107     my $subname = shift;
5108     my $cond = @_ ? shift : 1;
5109
5110     # If the subname isn't a code reference, qualify it so that
5111     # break_subroutine() will work right.
5112     if ( ref($subname) ne 'CODE' ) {
5113
5114         # Not Perl 4.
5115         $subname =~ s/'/::/g;
5116         my $s = $subname;
5117
5118         # Put it in this package unless it's already qualified.
5119         if ($subname !~ /::/)
5120         {
5121             $subname = $package . '::' . $subname;
5122         };
5123
5124         # Requalify it into CORE::GLOBAL if qualifying it into this
5125         # package resulted in its not being defined, but only do so
5126         # if it really is in CORE::GLOBAL.
5127         my $core_name = "CORE::GLOBAL::$s";
5128         if ((!defined(&$subname))
5129                 and ($s !~ /::/)
5130                 and (defined &{$core_name}))
5131         {
5132             $subname = $core_name;
5133         }
5134
5135         # Put it in package 'main' if it has a leading ::.
5136         if ($subname =~ /\A::/)
5137         {
5138             $subname = "main" . $subname;
5139         }
5140     } ## end if ( ref($subname) ne 'CODE' ) {
5141
5142     # Try to set the breakpoint.
5143     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5144         local $\ = '';
5145         print {$OUT} $@;
5146         return;
5147     }
5148
5149     return;
5150 } ## end sub cmd_b_sub
5151
5152 =head3 C<cmd_B> - delete breakpoint(s) (command)
5153
5154 The command mostly parses the command line and tries to turn the argument
5155 into a line spec. If it can't, it uses the current line. It then calls
5156 C<delete_breakpoint> to actually do the work.
5157
5158 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5159 thereby deleting all the breakpoints.
5160
5161 =cut
5162
5163 sub cmd_B {
5164     my $cmd = shift;
5165
5166     # No line spec? Use dbline.
5167     # If there is one, use it if it's non-zero, or wipe it out if it is.
5168     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5169     my $dbline = shift;
5170
5171     # If the line was dot, make the line the current one.
5172     $line =~ s/^\./$dbline/;
5173
5174     # If it's * we're deleting all the breakpoints.
5175     if ( $line eq '*' ) {
5176         if (not eval { delete_breakpoint(); 1 }) {
5177             print {$OUT} $@;
5178         }
5179     }
5180
5181     # If there is a line spec, delete the breakpoint on that line.
5182     elsif ( $line =~ /\A(\S.*)/ ) {
5183         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5184             local $\ = '';
5185             print {$OUT} $@;
5186         }
5187     } ## end elsif ($line =~ /^(\S.*)/)
5188
5189     # No line spec.
5190     else {
5191         print {$OUT}
5192           "Deleting a breakpoint requires a line number, or '*' for all\n"
5193           ;    # hint
5194     }
5195
5196     return;
5197 } ## end sub cmd_B
5198
5199 =head3 delete_breakpoint([line]) (API)
5200
5201 This actually does the work of deleting either a single breakpoint, or all
5202 of them.
5203
5204 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5205 just drop out with a message saying so. If it is, we remove the condition
5206 part of the 'condition\0action' that says there's a breakpoint here. If,
5207 after we've done that, there's nothing left, we delete the corresponding
5208 line in C<%dbline> to signal that no action needs to be taken for this line.
5209
5210 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5211 which lists all currently-loaded files which have breakpoints. We then look
5212 at each line in each of these files, temporarily switching the C<%dbline>
5213 and C<@dbline> structures to point to the files in question, and do what
5214 we did in the single line case: delete the condition in C<@dbline>, and
5215 delete the key in C<%dbline> if nothing's left.
5216
5217 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5218 C<%break_on_load>, because these structures contain breakpoints for files
5219 and code that haven't been loaded yet. We can just kill these off because there
5220 are no magical debugger structures associated with them.
5221
5222 =cut
5223
5224 sub _remove_breakpoint_entry {
5225     my ($fn, $i) = @_;
5226
5227     delete $dbline{$i};
5228     _delete_breakpoint_data_ref($fn, $i);
5229
5230     return;
5231 }
5232
5233 sub _delete_all_breakpoints {
5234     print {$OUT} "Deleting all breakpoints...\n";
5235
5236     # %had_breakpoints lists every file that had at least one
5237     # breakpoint in it.
5238     for my $fn ( keys %had_breakpoints ) {
5239
5240         # Switch to the desired file temporarily.
5241         local *dbline = $main::{ '_<' . $fn };
5242
5243         $max = $#dbline;
5244
5245         # For all lines in this file ...
5246         for my $i (1 .. $max) {
5247
5248             # If there's a breakpoint or action on this line ...
5249             if ( defined $dbline{$i} ) {
5250
5251                 # ... remove the breakpoint.
5252                 $dbline{$i} =~ s/\A[^\0]+//;
5253                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5254                     # Remove the entry altogether if no action is there.
5255                     _remove_breakpoint_entry($fn, $i);
5256                 }
5257             } ## end if (defined $dbline{$i...
5258         } ## end for $i (1 .. $max)
5259
5260         # If, after we turn off the "there were breakpoints in this file"
5261         # bit, the entry in %had_breakpoints for this file is zero,
5262         # we should remove this file from the hash.
5263         if ( not $had_breakpoints{$fn} &= (~1) ) {
5264             delete $had_breakpoints{$fn};
5265         }
5266     } ## end for my $fn (keys %had_breakpoints)
5267
5268     # Kill off all the other breakpoints that are waiting for files that
5269     # haven't been loaded yet.
5270     undef %postponed;
5271     undef %postponed_file;
5272     undef %break_on_load;
5273
5274     return;
5275 }
5276
5277 sub _delete_breakpoint_from_line {
5278     my ($i) = @_;
5279
5280     # Woops. This line wasn't breakable at all.
5281     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5282
5283     # Kill the condition, but leave any action.
5284     $dbline{$i} =~ s/\A[^\0]*//;
5285
5286     # Remove the entry entirely if there's no action left.
5287     if ($dbline{$i} eq '') {
5288         _remove_breakpoint_entry($filename, $i);
5289     }
5290
5291     return;
5292 }
5293
5294 sub delete_breakpoint {
5295     my $i = shift;
5296
5297     # If we got a line, delete just that one.
5298     if ( defined($i) ) {
5299         _delete_breakpoint_from_line($i);
5300     }
5301     # No line; delete them all.
5302     else {
5303         _delete_all_breakpoints();
5304     }
5305
5306     return;
5307 }
5308
5309 =head3 cmd_stop (command)
5310
5311 This is meant to be part of the new command API, but it isn't called or used
5312 anywhere else in the debugger. XXX It is probably meant for use in development
5313 of new commands.
5314
5315 =cut
5316
5317 sub cmd_stop {    # As on ^C, but not signal-safy.
5318     $signal = 1;
5319 }
5320
5321 =head3 C<cmd_e> - threads
5322
5323 Display the current thread id:
5324
5325     e
5326
5327 This could be how (when implemented) to send commands to this thread id (e cmd)
5328 or that thread id (e tid cmd).
5329
5330 =cut
5331
5332 sub cmd_e {
5333     my $cmd  = shift;
5334     my $line = shift;
5335     unless (exists($INC{'threads.pm'})) {
5336         print "threads not loaded($ENV{PERL5DB_THREADED})
5337         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5338     } else {
5339         my $tid = threads->tid;
5340         print "thread id: $tid\n";
5341     }
5342 } ## end sub cmd_e
5343
5344 =head3 C<cmd_E> - list of thread ids
5345
5346 Display the list of available thread ids:
5347
5348     E
5349
5350 This could be used (when implemented) to send commands to all threads (E cmd).
5351
5352 =cut
5353
5354 sub cmd_E {
5355     my $cmd  = shift;
5356     my $line = shift;
5357     unless (exists($INC{'threads.pm'})) {
5358         print "threads not loaded($ENV{PERL5DB_THREADED})
5359         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5360     } else {
5361         my $tid = threads->tid;
5362         print "thread ids: ".join(', ',
5363             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5364         )."\n";
5365     }
5366 } ## end sub cmd_E
5367
5368 =head3 C<cmd_h> - help command (command)
5369
5370 Does the work of either
5371
5372 =over 4
5373
5374 =item *
5375
5376 Showing all the debugger help
5377
5378 =item *
5379
5380 Showing help for a specific command
5381
5382 =back
5383
5384 =cut
5385
5386 use vars qw($help);
5387 use vars qw($summary);
5388
5389 sub cmd_h {
5390     my $cmd = shift;
5391
5392     # If we have no operand, assume null.
5393     my $line = shift || '';
5394
5395     # 'h h'. Print the long-format help.
5396     if ( $line =~ /\Ah\s*\z/ ) {
5397         print_help($help);
5398     }
5399
5400     # 'h <something>'. Search for the command and print only its help.
5401     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5402
5403         # support long commands; otherwise bogus errors
5404         # happen when you ask for h on <CR> for example
5405         my $qasked = quotemeta($asked);    # for searching; we don't
5406                                            # want to use it as a pattern.
5407                                            # XXX: finds CR but not <CR>
5408
5409         # Search the help string for the command.
5410         if (
5411             $help =~ /^                    # Start of a line
5412                       <?                   # Optional '<'
5413                       (?:[IB]<)            # Optional markup
5414                       $qasked              # The requested command
5415                      /mx
5416           )
5417         {
5418
5419             # It's there; pull it out and print it.
5420             while (
5421                 $help =~ /^
5422                               (<?            # Optional '<'
5423                                  (?:[IB]<)   # Optional markup
5424                                  $qasked     # The command
5425                                  ([\s\S]*?)  # Description line(s)
5426                               \n)            # End of last description line
5427                               (?!\s)         # Next line not starting with
5428                                              # whitespace
5429                              /mgx
5430               )
5431             {
5432                 print_help($1);
5433             }
5434         }
5435
5436         # Not found; not a debugger command.
5437         else {
5438             print_help("B<$asked> is not a debugger command.\n");
5439         }
5440     } ## end elsif ($line =~ /^(\S.*)$/)
5441
5442     # 'h' - print the summary help.
5443     else {
5444         print_help($summary);
5445     }
5446 } ## end sub cmd_h
5447
5448 =head3 C<cmd_i> - inheritance display
5449
5450 Display the (nested) parentage of the module or object given.
5451
5452 =cut
5453
5454 sub cmd_i {
5455     my $cmd  = shift;
5456     my $line = shift;
5457     foreach my $isa ( split( /\s+/, $line ) ) {
5458         $evalarg = $isa;
5459         # The &-call is here to ascertain the mutability of @_.
5460         ($isa) = &DB::eval;
5461         no strict 'refs';
5462         print join(
5463             ', ',
5464             map {
5465                 "$_"
5466                   . (
5467                     defined( ${"$_\::VERSION"} )
5468                     ? ' ' . ${"$_\::VERSION"}
5469                     : undef )
5470               } @{mro::get_linear_isa(ref($isa) || $isa)}
5471         );
5472         print "\n";
5473     }
5474 } ## end sub cmd_i
5475
5476 =head3 C<cmd_l> - list lines (command)
5477
5478 Most of the command is taken up with transforming all the different line
5479 specification syntaxes into 'start-stop'. After that is done, the command
5480 runs a loop over C<@dbline> for the specified range of lines. It handles
5481 the printing of each line and any markers (C<==E<gt>> for current line,
5482 C<b> for break on this line, C<a> for action on this line, C<:> for this
5483 line breakable).
5484
5485 We save the last line listed in the C<$start> global for further listing
5486 later.
5487
5488 =cut
5489
5490 sub _min {
5491     my $min = shift;
5492     foreach my $v (@_) {
5493         if ($min > $v) {
5494             $min = $v;
5495         }
5496     }
5497     return $min;
5498 }
5499
5500 sub _max {
5501     my $max = shift;
5502     foreach my $v (@_) {
5503         if ($max < $v) {
5504             $max = $v;
5505         }
5506     }
5507     return $max;
5508 }
5509
5510 sub _minify_to_max {
5511     my $ref = shift;
5512
5513     $$ref = _min($$ref, $max);
5514
5515     return;
5516 }
5517
5518 sub _cmd_l_handle_var_name {
5519     my $var_name = shift;
5520
5521     $evalarg = $var_name;
5522
5523     my ($s) = DB::eval();
5524
5525     # Ooops. Bad scalar.
5526     if ($@) {
5527         print {$OUT} "Error: $@\n";
5528         next CMD;
5529     }
5530
5531     # Good scalar. If it's a reference, find what it points to.
5532     $s = CvGV_name($s);
5533     print {$OUT} "Interpreted as: $1 $s\n";
5534     $line = "$1 $s";
5535
5536     # Call self recursively to really do the command.
5537     return _cmd_l_main( $s );
5538 }
5539
5540 sub _cmd_l_handle_subname {
5541
5542     my $s = $subname;
5543
5544     # De-Perl4.
5545     $subname =~ s/\'/::/;
5546
5547     # Put it in this package unless it starts with ::.
5548     $subname = $package . "::" . $subname unless $subname =~ /::/;
5549
5550     # Put it in CORE::GLOBAL if t doesn't start with :: and
5551     # it doesn't live in this package and it lives in CORE::GLOBAL.
5552     $subname = "CORE::GLOBAL::$s"
5553     if not defined &$subname
5554         and $s !~ /::/
5555         and defined &{"CORE::GLOBAL::$s"};
5556
5557     # Put leading '::' names into 'main::'.
5558     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5559
5560     # Get name:start-stop from find_sub, and break this up at
5561     # colons.
5562     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5563
5564     # Pull off start-stop.
5565     my $subrange = pop @pieces;
5566
5567     # If the name contained colons, the split broke it up.
5568     # Put it back together.
5569     $file = join( ':', @pieces );
5570
5571     # If we're not in that file, switch over to it.
5572     if ( $file ne $filename ) {
5573         if (! $slave_editor) {
5574             print {$OUT} "Switching to file '$file'.\n";
5575         }
5576
5577         # Switch debugger's magic structures.
5578         *dbline   = $main::{ '_<' . $file };
5579         $max      = $#dbline;
5580         $filename = $file;
5581     } ## end if ($file ne $filename)
5582
5583     # Subrange is 'start-stop'. If this is less than a window full,
5584     # swap it to 'start+', which will list a window from the start point.
5585     if ($subrange) {
5586         if ( eval($subrange) < -$window ) {
5587             $subrange =~ s/-.*/+/;
5588         }
5589
5590         # Call self recursively to list the range.
5591         return _cmd_l_main( $subrange );
5592     } ## end if ($subrange)
5593
5594     # Couldn't find it.
5595     else {
5596         print {$OUT} "Subroutine $subname not found.\n";
5597         return;
5598     }
5599 }
5600
5601 sub _cmd_l_empty {
5602     # Compute new range to list.
5603     $incr = $window - 1;
5604
5605     # Recurse to do it.
5606     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5607 }
5608
5609 sub _cmd_l_plus {
5610     my ($new_start, $new_incr) = @_;
5611
5612     # Don't reset start for 'l +nnn'.
5613     $start = $new_start if $new_start;
5614
5615     # Increment for list. Use window size if not specified.
5616     # (Allows 'l +' to work.)
5617     $incr = $new_incr || ($window - 1);
5618
5619     # Create a line range we'll understand, and recurse to do it.
5620     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5621 }
5622
5623 sub _cmd_l_calc_initial_end_and_i {
5624     my ($spec, $start_match, $end_match) = @_;
5625
5626     # Determine end point; use end of file if not specified.
5627     my $end = ( !defined $start_match ) ? $max :
5628     ( $end_match ? $end_match : $start_match );
5629
5630     # Go on to the end, and then stop.
5631     _minify_to_max(\$end);
5632
5633     # Determine start line.
5634     my $i = $start_match;
5635
5636     if ($i eq '.') {
5637         $i = $spec;
5638     }
5639
5640     $i = _max($i, 1);
5641
5642     $incr = $end - $i;
5643
5644     return ($end, $i);
5645 }
5646
5647 sub _cmd_l_range {
5648     my ($spec, $current_line, $start_match, $end_match) = @_;
5649
5650     my ($end, $i) =
5651         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5652
5653     # If we're running under a slave editor, force it to show the lines.
5654     if ($slave_editor) {
5655         print {$OUT} "\032\032$filename:$i:0\n";
5656         $i = $end;
5657     }
5658     # We're doing it ourselves. We want to show the line and special
5659     # markers for:
5660     # - the current line in execution
5661     # - whether a line is breakable or not
5662     # - whether a line has a break or not
5663     # - whether a line has an action or not
5664     else {
5665         I_TO_END:
5666         for ( ; $i <= $end ; $i++ ) {
5667
5668             # Check for breakpoints and actions.
5669             my ( $stop, $action );
5670             if ($dbline{$i}) {
5671                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5672             }
5673
5674             # ==> if this is the current line in execution,
5675             # : if it's breakable.
5676             my $arrow =
5677             ( $i == $current_line and $filename eq $filename_ini )
5678             ? '==>'
5679             : ( $dbline[$i] + 0 ? ':' : ' ' );
5680
5681             # Add break and action indicators.
5682             $arrow .= 'b' if $stop;
5683             $arrow .= 'a' if $action;
5684
5685             # Print the line.
5686             print {$OUT} "$i$arrow\t", $dbline[$i];
5687
5688             # Move on to the next line. Drop out on an interrupt.
5689             if ($signal) {
5690                 $i++;
5691                 last I_TO_END;
5692             }
5693         } ## end for (; $i <= $end ; $i++)
5694
5695         # Line the prompt up; print a newline if the last line listed
5696         # didn't have a newline.
5697         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5698             print {$OUT} "\n";
5699         }
5700     } ## end else [ if ($slave_editor)
5701
5702     # Save the point we last listed to in case another relative 'l'
5703     # command is desired. Don't let it run off the end.
5704     $start = $i;
5705     _minify_to_max(\$start);
5706
5707     return;
5708 }
5709
5710 sub _cmd_l_main {
5711     my $spec = shift;
5712
5713     # If this is '-something', delete any spaces after the dash.
5714     $spec =~ s/\A-\s*\z/-/;
5715
5716     # If the line is '$something', assume this is a scalar containing a
5717     # line number.
5718     # Set up for DB::eval() - evaluate in *user* context.
5719     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5720         return _cmd_l_handle_var_name($var_name);
5721     }
5722     # l name. Try to find a sub by that name.
5723     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5724         return _cmd_l_handle_subname();
5725     }
5726     # Bare 'l' command.
5727     elsif ( $spec !~ /\S/ ) {
5728         return _cmd_l_empty();
5729     }
5730     # l [start]+number_of_lines
5731     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5732         return _cmd_l_plus($new_start, $new_incr);
5733     }
5734     # l start-stop or l start,stop
5735     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5736         return _cmd_l_range($spec, $line, $s, $e);
5737     }
5738
5739     return;
5740 } ## end sub cmd_l
5741
5742 sub cmd_l {
5743     my (undef, $line) = @_;
5744
5745     return _cmd_l_main($line);
5746 }
5747
5748 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5749
5750 To list breakpoints, the command has to look determine where all of them are
5751 first. It starts a C<%had_breakpoints>, which tells us what all files have
5752 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5753 magic source and breakpoint data structures) to the file, and then look
5754 through C<%dbline> for lines with breakpoints and/or actions, listing them
5755 out. We look through C<%postponed> not-yet-compiled subroutines that have
5756 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5757 that have breakpoints.
5758
5759 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5760
5761 =cut
5762
5763 sub _cmd_L_calc_arg {
5764     # If no argument, list everything. Pre-5.8.0 version always lists
5765     # everything
5766     my $arg = shift || 'abw';
5767     if ($CommandSet ne '580')
5768     {
5769         $arg = 'abw';
5770     }
5771
5772     return $arg;
5773 }
5774
5775 sub _cmd_L_calc_wanted_flags {
5776     my $arg = _cmd_L_calc_arg(shift);
5777
5778     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5779 }
5780
5781
5782 sub _cmd_L_handle_breakpoints {
5783     my ($handle_db_line) = @_;
5784
5785     BREAKPOINTS_SCAN:
5786     # Look in all the files with breakpoints...
5787     for my $file ( keys %had_breakpoints ) {
5788
5789         # Temporary switch to this file.
5790         local *dbline = $main::{ '_<' . $file };
5791
5792         # Set up to look through the whole file.
5793         $max = $#dbline;
5794         my $was;    # Flag: did we print something
5795         # in this file?
5796
5797         # For each line in the file ...
5798         for my $i (1 .. $max) {
5799
5800             # We've got something on this line.
5801             if ( defined $dbline{$i} ) {
5802
5803                 # Print the header if we haven't.
5804                 if (not $was++) {
5805                     print {$OUT} "$file:\n";
5806                 }
5807
5808                 # Print the line.
5809                 print {$OUT} " $i:\t", $dbline[$i];
5810
5811                 $handle_db_line->($dbline{$i});
5812
5813                 # Quit if the user hit interrupt.
5814                 if ($signal) {
5815                     last BREAKPOINTS_SCAN;
5816                 }
5817             } ## end if (defined $dbline{$i...
5818         } ## end for my $i (1 .. $max)
5819     } ## end for my $file (keys %had_breakpoints)
5820
5821     return;
5822 }
5823
5824 sub _cmd_L_handle_postponed_breakpoints {
5825     my ($handle_db_line) = @_;
5826
5827     print {$OUT} "Postponed breakpoints in files:\n";
5828
5829     POSTPONED_SCANS:
5830     for my $file ( keys %postponed_file ) {
5831         my $db = $postponed_file{$file};
5832         print {$OUT} " $file:\n";
5833         for my $line ( sort { $a <=> $b } keys %$db ) {
5834             print {$OUT} "  $line:\n";
5835
5836             $handle_db_line->($db->{$line});
5837
5838             if ($signal) {
5839                 last POSTPONED_SCANS;
5840             }
5841         }
5842         if ($signal) {
5843             last POSTPONED_SCANS;
5844         }
5845     }
5846
5847     return;
5848 }
5849
5850
5851 sub cmd_L {
5852     my $cmd = shift;
5853
5854     my ($action_wanted, $break_wanted, $watch_wanted) =
5855         _cmd_L_calc_wanted_flags(shift);
5856
5857     my $handle_db_line = sub {
5858         my ($l) = @_;
5859
5860         my ( $stop, $action ) = split( /\0/, $l );
5861
5862         if ($stop and $break_wanted) {
5863             print {$OUT} "    break if (", $stop, ")\n"
5864         }
5865
5866         if ($action && $action_wanted) {
5867             print {$OUT} "    action:  ", $action, "\n"
5868         }
5869
5870         return;
5871     };
5872
5873     # Breaks and actions are found together, so we look in the same place
5874     # for both.
5875     if ( $break_wanted or $action_wanted ) {
5876         _cmd_L_handle_breakpoints($handle_db_line);
5877     }
5878
5879     # Look for breaks in not-yet-compiled subs:
5880     if ( %postponed and $break_wanted ) {
5881         print {$OUT} "Postponed breakpoints in subroutines:\n";
5882         my $subname;
5883         SUBS_SCAN:
5884         for $subname ( keys %postponed ) {
5885             print {$OUT} " $subname\t$postponed{$subname}\n";
5886             if ($signal) {
5887                 last SUBS_SCAN;
5888             }
5889         }
5890     } ## end if (%postponed and $break_wanted)
5891
5892     # Find files that have not-yet-loaded breaks:
5893     my @have = map {    # Combined keys
5894         keys %{ $postponed_file{$_} }
5895     } keys %postponed_file;
5896
5897     # If there are any, list them.
5898     if ( @have and ( $break_wanted or $action_wanted ) ) {
5899         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5900     } ## end if (@have and ($break_wanted...
5901
5902     if ( %break_on_load and $break_wanted ) {
5903         print {$OUT} "Breakpoints on load:\n";
5904         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5905             print {$OUT} " $filename\n";
5906             last BREAK_ON_LOAD if $signal;
5907         }
5908     } ## end if (%break_on_load and...
5909
5910     if ($watch_wanted and ( $trace & 2 )) {
5911         print {$OUT} "Watch-expressions:\n" if @to_watch;
5912         TO_WATCH: for my $expr (@to_watch) {
5913             print {$OUT} " $expr\n";
5914             last TO_WATCH if $signal;
5915         }
5916     }
5917
5918     return;
5919 } ## end sub cmd_L
5920
5921 =head3 C<cmd_M> - list modules (command)
5922
5923 Just call C<list_modules>.
5924
5925 =cut
5926
5927 sub cmd_M {
5928     list_modules();
5929
5930     return;
5931 }
5932
5933 =head3 C<cmd_o> - options (command)
5934
5935 If this is just C<o> by itself, we list the current settings via
5936 C<dump_option>. If there's a nonblank value following it, we pass that on to
5937 C<parse_options> for processing.
5938
5939 =cut
5940
5941 sub cmd_o {
5942     my $cmd = shift;
5943     my $opt = shift || '';    # opt[=val]
5944
5945     # Nonblank. Try to parse and process.
5946     if ( $opt =~ /^(\S.*)/ ) {
5947         parse_options($1);
5948     }
5949
5950     # Blank. List the current option settings.
5951     else {
5952         for (@options) {
5953             dump_option($_);
5954         }
5955     }
5956 } ## end sub cmd_o
5957
5958 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5959
5960 Advises the user that the O command has been renamed.
5961
5962 =cut
5963
5964 sub cmd_O {
5965     print $OUT "The old O command is now the o command.\n";             # hint
5966     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5967     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5968 }
5969
5970 =head3 C<cmd_v> - view window (command)
5971
5972 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5973 move back a few lines to list the selected line in context. Uses C<cmd_l>
5974 to do the actual listing after figuring out the range of line to request.
5975
5976 =cut
5977
5978 use vars qw($preview);
5979
5980 sub cmd_v {
5981     my $cmd  = shift;
5982     my $line = shift;
5983
5984     # Extract the line to list around. (Astute readers will have noted that
5985     # this pattern will match whether or not a numeric line is specified,
5986     # which means that we'll always enter this loop (though a non-numeric
5987     # argument results in no action at all)).
5988     if ( $line =~ /^(\d*)$/ ) {
5989
5990         # Total number of lines to list (a windowful).
5991         $incr = $window - 1;
5992
5993         # Set the start to the argument given (if there was one).
5994         $start = $1 if $1;
5995
5996         # Back up by the context amount.
5997         $start -= $preview;
5998
5999         # Put together a linespec that cmd_l will like.
6000         $line = $start . '-' . ( $start + $incr );
6001
6002         # List the lines.
6003         cmd_l( 'l', $line );
6004     } ## end if ($line =~ /^(\d*)$/)
6005 } ## end sub cmd_v
6006
6007 =head3 C<cmd_w> - add a watch expression (command)
6008
6009 The 5.8 version of this command adds a watch expression if one is specified;
6010 it does nothing if entered with no operands.
6011
6012 We extract the expression, save it, evaluate it in the user's context, and
6013 save the value. We'll re-evaluate it each time the debugger passes a line,
6014 and will stop (see the code at the top of the command loop) if the value
6015 of any of the expressions changes.
6016
6017 =cut
6018
6019 sub _add_watch_expr {
6020     my $expr = shift;
6021
6022     # ... save it.
6023     push @to_watch, $expr;
6024
6025     # Parameterize DB::eval and call it to get the expression's value
6026     # in the user's context. This version can handle expressions which
6027     # return a list value.
6028     $evalarg = $expr;
6029     # The &-call is here to ascertain the mutability of @_.
6030     my ($val) = join( ' ', &DB::eval);
6031     $val = ( defined $val ) ? "'$val'" : 'undef';
6032
6033     # Save the current value of the expression.
6034     push @old_watch, $val;
6035
6036     # We are now watching expressions.
6037     $trace |= 2;
6038
6039     return;
6040 }
6041
6042 sub cmd_w {
6043     my $cmd = shift;
6044
6045     # Null expression if no arguments.
6046     my $expr = shift || '';
6047
6048     # If expression is not null ...
6049     if ( $expr =~ /\A\S/ ) {
6050         _add_watch_expr($expr);
6051     } ## end if ($expr =~ /^(\S.*)/)
6052
6053     # You have to give one to get one.
6054     else {
6055         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6056     }
6057
6058     return;
6059 }
6060
6061 =head3 C<cmd_W> - delete watch expressions (command)
6062
6063 This command accepts either a watch expression to be removed from the list
6064 of watch expressions, or C<*> to delete them all.
6065
6066 If C<*> is specified, we simply empty the watch expression list and the
6067 watch expression value list. We also turn off the bit that says we've got
6068 watch expressions.
6069
6070 If an expression (or partial expression) is specified, we pattern-match
6071 through the expressions and remove the ones that match. We also discard
6072 the corresponding values. If no watch expressions are left, we turn off
6073 the I<watching expressions> bit.
6074
6075 =cut
6076
6077 sub cmd_W {
6078     my $cmd  = shift;
6079     my $expr = shift || '';
6080
6081     # Delete them all.
6082     if ( $expr eq '*' ) {
6083
6084         # Not watching now.
6085         $trace &= ~2;
6086
6087         print $OUT "Deleting all watch expressions ...\n";
6088
6089         # And all gone.
6090         @to_watch = @old_watch = ();
6091     }
6092
6093     # Delete one of them.
6094     elsif ( $expr =~ /^(\S.*)/ ) {
6095
6096         # Where we are in the list.
6097         my $i_cnt = 0;
6098
6099         # For each expression ...
6100         foreach (@to_watch) {
6101             my $val = $to_watch[$i_cnt];
6102
6103             # Does this one match the command argument?
6104             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6105                                       # Yes. Turn it off, and its value too.
6106                 splice( @to_watch,  $i_cnt, 1 );
6107                 splice( @old_watch, $i_cnt, 1 );
6108             }
6109             $i_cnt++;
6110         } ## end foreach (@to_watch)
6111
6112         # We don't bother to turn watching off because
6113         #  a) we don't want to stop calling watchfunction() if it exists
6114         #  b) foreach over a null list doesn't do anything anyway
6115
6116     } ## end elsif ($expr =~ /^(\S.*)/)
6117
6118     # No command arguments entered.
6119     else {
6120         print $OUT
6121           "Deleting a watch-expression requires an expression, or '*' for all\n"
6122           ;    # hint
6123     }
6124 } ## end sub cmd_W
6125
6126 ### END of the API section
6127
6128 =head1 SUPPORT ROUTINES
6129
6130 These are general support routines that are used in a number of places
6131 throughout the debugger.
6132
6133 =head2 save
6134
6135 save() saves the user's versions of globals that would mess us up in C<@saved>,
6136 and installs the versions we like better.
6137
6138 =cut
6139
6140 sub save {
6141
6142     # Save eval failure, command failure, extended OS error, output field
6143     # separator, input record separator, output record separator and
6144     # the warning setting.
6145     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6146
6147     $,  = "";      # output field separator is null string
6148     $/  = "\n";    # input record separator is newline
6149     $\  = "";      # output record separator is null string
6150     $^W = 0;       # warnings are off
6151 } ## end sub save
6152
6153 =head2 C<print_lineinfo> - show where we are now
6154
6155 print_lineinfo prints whatever it is that it is handed; it prints it to the
6156 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6157 us to feed line information to a slave editor without messing up the
6158 debugger output.
6159
6160 =cut
6161
6162 sub print_lineinfo {
6163
6164     # Make the terminal sensible if we're not the primary debugger.
6165     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6166     local $\ = '';
6167     local $, = '';
6168     # $LINEINFO may be undef if $noTTY is set or some other issue.
6169     if ($LINEINFO)
6170     {
6171         print {$LINEINFO} @_;
6172     }
6173 } ## end sub print_lineinfo
6174
6175 =head2 C<postponed_sub>
6176
6177 Handles setting postponed breakpoints in subroutines once they're compiled.
6178 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6179 range for the subroutine, then mark the file as having a breakpoint,
6180 temporarily switch the C<*dbline> glob over to the source file, and then
6181 search the given range of lines to find a breakable line. If we find one,
6182 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6183
6184 =cut
6185
6186 # The following takes its argument via $evalarg to preserve current @_
6187
6188 sub postponed_sub {
6189
6190     # Get the subroutine name.
6191     my $subname = shift;
6192
6193     # If this is a 'break +<n> if <condition>' ...
6194     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6195
6196         # If there's no offset, use '+0'.
6197         my $offset = $1 || 0;
6198
6199         # find_sub's value is 'fullpath-filename:start-stop'. It's
6200         # possible that the filename might have colons in it too.
6201         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6202         if ($i) {
6203
6204             # We got the start line. Add the offset '+<n>' from
6205             # $postponed{subname}.
6206             $i += $offset;
6207
6208             # Switch to the file this sub is in, temporarily.
6209             local *dbline = $main::{ '_<' . $file };
6210
6211             # No warnings, please.
6212             local $^W = 0;    # != 0 is magical below
6213
6214             # This file's got a breakpoint in it.
6215             $had_breakpoints{$file} |= 1;
6216
6217             # Last line in file.
6218             $max = $#dbline;
6219
6220             # Search forward until we hit a breakable line or get to
6221             # the end of the file.
6222             ++$i until $dbline[$i] != 0 or $i >= $max;
6223
6224             # Copy the breakpoint in and delete it from %postponed.
6225             $dbline{$i} = delete $postponed{$subname};
6226         } ## end if ($i)
6227
6228         # find_sub didn't find the sub.
6229         else {
6230             local $\ = '';
6231             print $OUT "Subroutine $subname not found.\n";
6232         }
6233         return;
6234     } ## end if ($postponed{$subname...
6235     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6236
6237     #print $OUT "In postponed_sub for '$subname'.\n";
6238 } ## end sub postponed_sub
6239
6240 =head2 C<postponed>
6241
6242 Called after each required file is compiled, but before it is executed;
6243 also called if the name of a just-compiled subroutine is a key of
6244 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6245 etc.) into the just-compiled code.
6246
6247 If this is a C<require>'d file, the incoming parameter is the glob
6248 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6249
6250 If it's a subroutine, the incoming parameter is the subroutine name.
6251
6252 =cut
6253
6254 sub postponed {
6255
6256     # If there's a break, process it.
6257     if ($ImmediateStop) {
6258
6259         # Right, we've stopped. Turn it off.
6260         $ImmediateStop = 0;
6261
6262         # Enter the command loop when DB::DB gets called.
6263         $signal = 1;
6264     }
6265
6266     # If this is a subroutine, let postponed_sub() deal with it.
6267     if (ref(\$_[0]) ne 'GLOB') {
6268         return postponed_sub(@_);
6269     }
6270
6271     # Not a subroutine. Deal with the file.
6272     local *dbline = shift;
6273     my $filename = $dbline;
6274     $filename =~ s/^_<//;
6275     local $\ = '';
6276     $signal = 1, print $OUT "'$filename' loaded...\n"
6277       if $break_on_load{$filename};
6278     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6279
6280     # Do we have any breakpoints to put in this file?
6281     return unless $postponed_file{$filename};
6282
6283     # Yes. Mark this file as having breakpoints.
6284     $had_breakpoints{$filename} |= 1;
6285
6286     # "Cannot be done: insufficient magic" - we can't just put the
6287     # breakpoints saved in %postponed_file into %dbline by assigning
6288     # the whole hash; we have to do it one item at a time for the
6289     # breakpoints to be set properly.
6290     #%dbline = %{$postponed_file{$filename}};
6291
6292     # Set the breakpoints, one at a time.
6293     my $key;
6294
6295     for $key ( keys %{ $postponed_file{$filename} } ) {
6296
6297         # Stash the saved breakpoint into the current file's magic line array.
6298         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6299     }
6300
6301     # This file's been compiled; discard the stored breakpoints.
6302     delete $postponed_file{$filename};
6303
6304 } ## end sub postponed
6305
6306 =head2 C<dumpit>
6307
6308 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6309
6310 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6311 a reference to a variable (the thing to be dumped) as its input.
6312
6313 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6314 the currently-selected filehandle, thank you very much). The current
6315 values of the package globals C<$single> and C<$trace> are backed up in
6316 lexicals, and they are turned off (this keeps the debugger from trying
6317 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6318 preserve its current value and it is set to zero to prevent entry/exit
6319 messages from printing, and C<$doret> is localized as well and set to -2 to
6320 prevent return values from being shown.
6321
6322 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6323 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6324 installed version in C<@INC>, yours will be used instead. Possible security
6325 problem?).
6326
6327 It then checks to see if the subroutine C<main::dumpValue> is now defined
6328 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6329 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6330 is called, and picks up the variable to be dumped from the parameter list.
6331
6332 It checks the package global C<%options> to see if there's a C<dumpDepth>
6333 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6334 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6335 structure: -1 means dump everything.
6336
6337 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6338 warning.
6339
6340 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6341 and we then return to the caller.
6342
6343 =cut
6344
6345 sub dumpit {
6346
6347     # Save the current output filehandle and switch to the one
6348     # passed in as the first parameter.
6349     my $savout = select(shift);
6350
6351     # Save current settings of $single and $trace, and then turn them off.
6352     my $osingle = $single;
6353     my $otrace  = $trace;
6354     $single = $trace = 0;
6355
6356     # XXX Okay, what do $frame and $doret do, again?
6357     local $frame = 0;
6358     local $doret = -2;
6359
6360     # Load dumpvar.pl unless we've already got the sub we need from it.
6361     unless ( defined &main::dumpValue ) {
6362         do 'dumpvar.pl' or die $@;
6363     }
6364
6365     # If the load succeeded (or we already had dumpvalue()), go ahead
6366     # and dump things.
6367     if ( defined &main::dumpValue ) {
6368         local $\ = '';
6369         local $, = '';
6370         local $" = ' ';
6371         my $v = shift;
6372         my $maxdepth = shift || $option{dumpDepth};
6373         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6374         main::dumpValue( $v, $maxdepth );
6375     } ## end if (defined &main::dumpValue)
6376
6377     # Oops, couldn't load dumpvar.pl.
6378     else {
6379         local $\ = '';
6380         print $OUT "dumpvar.pl not available.\n";
6381     }
6382
6383     # Reset $single and $trace to their old values.
6384     $single = $osingle;
6385     $trace  = $otrace;
6386
6387     # Restore the old filehandle.
6388     select($savout);
6389 } ## end sub dumpit
6390
6391 =head2 C<print_trace>
6392
6393 C<print_trace>'s job is to print a stack trace. It does this via the
6394 C<dump_trace> routine, which actually does all the ferreting-out of the
6395 stack trace data. C<print_trace> takes care of formatting it nicely and
6396 printing it to the proper filehandle.
6397
6398 Parameters:
6399
6400 =over 4
6401
6402 =item *
6403
6404 The filehandle to print to.
6405
6406 =item *
6407
6408 How many frames to skip before starting trace.
6409
6410 =item *
6411
6412 How many frames to print.
6413
6414 =item *
6415
6416 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6417
6418 =back
6419
6420 The original comment below seems to be noting that the traceback may not be
6421 correct if this routine is called in a tied method.
6422
6423 =cut
6424
6425 # Tied method do not create a context, so may get wrong message:
6426
6427 sub print_trace {
6428     local $\ = '';
6429     my $fh = shift;
6430
6431     # If this is going to a slave editor, but we're not the primary
6432     # debugger, reset it first.
6433     resetterm(1)
6434       if $fh        eq $LINEINFO    # slave editor
6435       and $LINEINFO eq $OUT         # normal output
6436       and $term_pid != $$;          # not the primary
6437
6438     # Collect the actual trace information to be formatted.
6439     # This is an array of hashes of subroutine call info.
6440     my @sub = dump_trace( $_[0] + 1, $_[1] );
6441
6442     # Grab the "short report" flag from @_.
6443     my $short = $_[2];              # Print short report, next one for sub name
6444
6445     # Run through the traceback info, format it, and print it.
6446     my $s;
6447     for my $i (0 .. $#sub) {
6448
6449         # Drop out if the user has lost interest and hit control-C.
6450         last if $signal;
6451
6452         # Set the separator so arrays print nice.
6453         local $" = ', ';
6454
6455         # Grab and stringify the arguments if they are there.
6456         my $args =
6457           defined $sub[$i]{args}
6458           ? "(@{ $sub[$i]{args} })"
6459           : '';
6460
6461         # Shorten them up if $maxtrace says they're too long.
6462         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6463           if length $args > $maxtrace;
6464
6465         # Get the file name.
6466         my $file = $sub[$i]{file};
6467
6468         # Put in a filename header if short is off.
6469         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6470
6471         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6472         $s = $sub[$i]{'sub'};
6473         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6474
6475         # Short report uses trimmed file and sub names.
6476         if ($short) {
6477             my $sub = @_ >= 4 ? $_[3] : $s;
6478             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6479         } ## end if ($short)
6480
6481         # Non-short report includes full names.
6482         else {
6483             print $fh "$sub[$i]{context} = $s$args"
6484               . " called from $file"
6485               . " line $sub[$i]{line}\n";
6486         }
6487     } ## end for my $i (0 .. $#sub)
6488 } ## end sub print_trace
6489
6490 =head2 dump_trace(skip[,count])
6491
6492 Actually collect the traceback information available via C<caller()>. It does
6493 some filtering and cleanup of the data, but mostly it just collects it to
6494 make C<print_trace()>'s job easier.
6495
6496 C<skip> defines the number of stack frames to be skipped, working backwards
6497 from the most current. C<count> determines the total number of frames to
6498 be returned; all of them (well, the first 10^9) are returned if C<count>
6499 is omitted.
6500
6501 This routine returns a list of hashes, from most-recent to least-recent
6502 stack frame. Each has the following keys and values:
6503
6504 =over 4
6505
6506 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6507
6508 =item * C<sub> - subroutine name, or C<eval> information
6509
6510 =item * C<args> - undef, or a reference to an array of arguments
6511
6512 =item * C<file> - the file in which this item was defined (if any)
6513
6514 =item * C<line> - the line on which it was defined
6515
6516 =back
6517
6518 =cut
6519
6520 sub _dump_trace_calc_saved_single_arg
6521 {
6522     my ($nothard, $arg) = @_;
6523
6524     my $type;
6525     if ( not defined $arg ) {    # undefined parameter
6526         return "undef";
6527     }
6528
6529     elsif ( $nothard and tied $arg ) {    # tied parameter
6530         return "tied";
6531     }
6532     elsif ( $nothard and $type = ref $arg ) {    # reference
6533         return "ref($type)";
6534     }
6535     else {                                       # can be stringified
6536         local $_ =
6537         "$arg";    # Safe to stringify now - should not call f().
6538
6539         # Backslash any single-quotes or backslashes.
6540         s/([\'\\])/\\$1/g;
6541
6542         # Single-quote it unless it's a number or a colon-separated
6543         # name.
6544         s/(.*)/'$1'/s
6545         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6546
6547         # Turn high-bit characters into meta-whatever, and controls into like
6548         # '^D'.
6549         require 'meta_notation.pm';
6550         $_ = _meta_notation($_) if /[[:^print:]]/a;
6551
6552         return $_;
6553     }
6554 }
6555
6556 sub _dump_trace_calc_save_args {
6557     my ($nothard) = @_;
6558
6559     return [
6560         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6561     ];
6562 }
6563
6564 sub dump_trace {
6565
6566     # How many levels to skip.
6567     my $skip = shift;
6568
6569     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6570     # it's unlikely that we'll have more than a billion stack frames. If you
6571     # do, you've got an awfully big machine...)
6572     my $count = shift || 1e9;
6573
6574     # We increment skip because caller(1) is the first level *back* from
6575     # the current one.  Add $skip to the count of frames so we have a
6576     # simple stop criterion, counting from $skip to $count+$skip.
6577     $skip++;
6578     $count += $skip;
6579
6580     # These variables are used to capture output from caller();
6581     my ( $p, $file, $line, $sub, $h, $context );
6582
6583     my ( $e, $r, @sub, $args );
6584
6585     # XXX Okay... why'd we do that?
6586     my $nothard = not $frame & 8;
6587     local $frame = 0;
6588
6589     # Do not want to trace this.
6590     my $otrace = $trace;
6591     $trace = 0;
6592
6593     # Start out at the skip count.
6594     # If we haven't reached the number of frames requested, and caller() is
6595     # still returning something, stay in the loop. (If we pass the requested
6596     # number of stack frames, or we run out - caller() returns nothing - we
6597     # quit.
6598     # Up the stack frame index to go back one more level each time.
6599     for (
6600         my $i = $skip ;
6601         $i < $count
6602         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6603         $i++
6604     )
6605     {
6606
6607         # Go through the arguments and save them for later.
6608         my $save_args = _dump_trace_calc_save_args($nothard);
6609
6610         # If context is true, this is array (@)context.
6611         # If context is false, this is scalar ($) context.
6612         # If neither, context isn't defined. (This is apparently a 'can't
6613         # happen' trap.)
6614         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6615
6616         # if the sub has args ($h true), make an anonymous array of the
6617         # dumped args.
6618         $args = $h ? $save_args : undef;
6619
6620         # remove trailing newline-whitespace-semicolon-end of line sequence
6621         # from the eval text, if any.
6622         $e =~ s/\n\s*\;\s*\Z// if $e;
6623
6624         # Escape backslashed single-quotes again if necessary.
6625         $e =~ s/([\\\'])/\\$1/g if $e;
6626
6627         # if the require flag is true, the eval text is from a require.
6628         if ($r) {
6629             $sub = "require '$e'";
6630         }
6631
6632         # if it's false, the eval text is really from an eval.
6633         elsif ( defined $r ) {
6634             $sub = "eval '$e'";
6635         }
6636
6637         # If the sub is '(eval)', this is a block eval, meaning we don't
6638         # know what the eval'ed text actually was.
6639         elsif ( $sub eq '(eval)' ) {
6640             $sub = "eval {...}";
6641         }
6642
6643         # Stick the collected information into @sub as an anonymous hash.
6644         push(
6645             @sub,
6646             {
6647                 context => $context,
6648                 sub     => $sub,
6649                 args    => $args,
6650                 file    => $file,
6651                 line    => $line
6652             }
6653         );
6654
6655         # Stop processing frames if the user hit control-C.
6656         last if $signal;
6657     } ## end for ($i = $skip ; $i < ...
6658
6659     # Restore the trace value again.
6660     $trace = $otrace;
6661     @sub;
6662 } ## end sub dump_trace
6663
6664 =head2 C<action()>
6665
6666 C<action()> takes input provided as the argument to an add-action command,
6667 either pre- or post-, and makes sure it's a complete command. It doesn't do
6668 any fancy parsing; it just keeps reading input until it gets a string
6669 without a trailing backslash.
6670
6671 =cut
6672
6673 sub action {
6674     my $action = shift;
6675
6676     while ( $action =~ s/\\$// ) {
6677
6678         # We have a backslash on the end. Read more.
6679         $action .= gets();
6680     } ## end while ($action =~ s/\\$//)
6681
6682     # Return the assembled action.
6683     $action;
6684 } ## end sub action
6685
6686 =head2 unbalanced
6687
6688 This routine mostly just packages up a regular expression to be used
6689 to check that the thing it's being matched against has properly-matched
6690 curly braces.
6691
6692 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6693 speeds things up by only creating the qr//'ed expression once; if it's
6694 already defined, we don't try to define it again. A speed hack.
6695
6696 =cut
6697
6698 use vars qw($balanced_brace_re);
6699
6700 sub unbalanced {
6701
6702     # I hate using globals!
6703     $balanced_brace_re ||= qr{
6704         ^ \{
6705              (?:
6706                  (?> [^{}] + )              # Non-parens without backtracking
6707                 |
6708                  (??{ $balanced_brace_re }) # Group with matching parens
6709               ) *
6710           \} $
6711    }x;
6712     return $_[0] !~ m/$balanced_brace_re/;
6713 } ## end sub unbalanced
6714
6715 =head2 C<gets()>
6716
6717 C<gets()> is a primitive (very primitive) routine to read continuations.
6718 It was devised for reading continuations for actions.
6719 it just reads more input with C<readline()> and returns it.
6720
6721 =cut
6722
6723 sub gets {
6724     return DB::readline("cont: ");
6725 }
6726
6727 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6728
6729 The C<system()> function assumes that it can just go ahead and use STDIN and
6730 STDOUT, but under the debugger, we want it to use the debugger's input and
6731 outout filehandles.
6732
6733 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6734 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6735 and then puts everything back again.
6736
6737 =cut
6738
6739 sub _db_system {
6740
6741     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6742     # some non-Unix systems can do system() but have problems with fork().
6743     open( SAVEIN,  "<&STDIN" )  || _db_warn("Can't save STDIN");
6744     open( SAVEOUT, ">&STDOUT" ) || _db_warn("Can't save STDOUT");
6745     open( STDIN,   "<&IN" )     || _db_warn("Can't redirect STDIN");
6746     open( STDOUT,  ">&OUT" )    || _db_warn("Can't redirect STDOUT");
6747
6748     # XXX: using csh or tcsh destroys sigint retvals!
6749     system(@_);
6750     open( STDIN,  "<&SAVEIN" )  || _db_warn("Can't restore STDIN");
6751     open( STDOUT, ">&SAVEOUT" ) || _db_warn("Can't restore STDOUT");
6752     close(SAVEIN);
6753     close(SAVEOUT);
6754
6755     # most of the $? crud was coping with broken cshisms
6756     if ( $? >> 8 ) {
6757         _db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6758     }
6759     elsif ($?) {
6760         _db_warn(
6761             "(Command died of SIG#",
6762             ( $? & 127 ),
6763             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6764             ")", "\n"
6765         );
6766     } ## end elsif ($?)
6767
6768     return $?;
6769
6770 } ## end sub system
6771
6772 *system = \&_db_system;
6773
6774 =head1 TTY MANAGEMENT
6775
6776 The subs here do some of the terminal management for multiple debuggers.
6777
6778 =head2 setterm
6779
6780 Top-level function called when we want to set up a new terminal for use
6781 by the debugger.
6782
6783 If the C<noTTY> debugger option was set, we'll either use the terminal
6784 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6785 to find one. If we're a forked debugger, we call C<resetterm> to try to
6786 get a whole new terminal if we can.
6787
6788 In either case, we set up the terminal next. If the C<ReadLine> option was
6789 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6790 the appropriate attributes. We then
6791
6792 =cut
6793
6794 use vars qw($ornaments);
6795 use vars qw($rl_attribs);
6796
6797 sub setterm {
6798
6799     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6800     local $frame = 0;
6801     local $doret = -2;
6802     require Term::ReadLine;
6803
6804     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6805     if ($notty) {
6806         if ($tty) {
6807             my ( $i, $o ) = split $tty, /,/;
6808             $o = $i unless defined $o;
6809             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6810             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6811             $IN  = \*IN;
6812             $OUT = \*OUT;
6813             _autoflush($OUT);
6814         } ## end if ($tty)
6815
6816         # We don't have a TTY - try to find one via Term::Rendezvous.
6817         else {
6818             require Term::Rendezvous;
6819
6820             # See if we have anything to pass to Term::Rendezvous.
6821             # Use $HOME/.perldbtty$$ if not.
6822             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6823
6824             # Rendezvous and get the filehandles.
6825             my $term_rv = Term::Rendezvous->new( $rv );
6826             $IN  = $term_rv->IN;
6827             $OUT = $term_rv->OUT;
6828         } ## end else [ if ($tty)
6829     } ## end if ($notty)
6830
6831     # We're a daughter debugger. Try to fork off another TTY.
6832     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6833         resetterm(2);
6834     }
6835
6836     # If we shouldn't use Term::ReadLine, don't.
6837     if ( !$rl ) {
6838         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6839     }
6840
6841     # We're using Term::ReadLine. Get all the attributes for this terminal.
6842     else {
6843         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6844
6845         $rl_attribs = $term->Attribs;
6846         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6847           if defined $rl_attribs->{basic_word_break_characters}
6848           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6849         $rl_attribs->{special_prefixes} = '$@&%';
6850         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6851         $rl_attribs->{completion_function} = \&db_complete;
6852     } ## end else [ if (!$rl)
6853
6854     # Set up the LINEINFO filehandle.
6855     $LINEINFO = $OUT     unless defined $LINEINFO;
6856     $lineinfo = $console unless defined $lineinfo;
6857
6858     $term->MinLine(2);
6859
6860     load_hist();
6861
6862     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6863         $term->SetHistory(@hist);
6864     }
6865
6866     # XXX Ornaments are turned on unconditionally, which is not
6867     # always a good thing.
6868     ornaments($ornaments) if defined $ornaments;
6869     $term_pid = $$;
6870 } ## end sub setterm
6871
6872 sub load_hist {
6873     $histfile //= option_val("HistFile", undef);
6874     return unless defined $histfile;
6875     open my $fh, "<", $histfile or return;
6876     local $/ = "\n";
6877     @hist = ();
6878     while (<$fh>) {
6879         chomp;
6880         push @hist, $_;
6881     }
6882     close $fh;
6883 }
6884
6885 sub save_hist {
6886     return unless defined $histfile;
6887     eval { require File::Path } or return;
6888     eval { require File::Basename } or return;
6889     File::Path::mkpath(File::Basename::dirname($histfile));
6890     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6891     $histsize //= option_val("HistSize",100);
6892     my @copy = grep { $_ ne '?' } @hist;
6893     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6894     for ($start .. $#copy) {
6895         print $fh "$copy[$_]\n";
6896     }
6897     close $fh or die "Could not write '$histfile': $!";
6898 }
6899
6900 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6901
6902 When the process being debugged forks, or the process invokes a command
6903 via C<system()> which starts a new debugger, we need to be able to get a new
6904 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6905 fight over the terminal, and you can never quite be sure who's going to get the
6906 input you're typing.
6907
6908 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6909 is tasked with doing all the necessary operating system mojo to get a new
6910 TTY (and probably another window) and to direct the new debugger to read and
6911 write there.
6912
6913 The debugger provides C<get_fork_TTY> functions which work for TCP
6914 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6915 supported. You are encouraged to write C<get_fork_TTY> functions which
6916 work for I<your> platform and contribute them.
6917
6918 =head3 C<socket_get_fork_TTY>
6919
6920 =cut
6921
6922 sub connect_remoteport {
6923     require IO::Socket;
6924
6925     my $socket = IO::Socket::INET->new(
6926         Timeout  => '10',
6927         PeerAddr => $remoteport,
6928         Proto    => 'tcp',
6929     );
6930     if ( ! $socket ) {
6931         die "Unable to connect to remote host: $remoteport\n";
6932     }
6933     return $socket;
6934 }
6935
6936 sub socket_get_fork_TTY {
6937     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6938
6939     # Do I need to worry about setting $term?
6940
6941     reset_IN_OUT( $IN, $OUT );
6942     return '';
6943 }
6944
6945 =head3 C<xterm_get_fork_TTY>
6946
6947 This function provides the C<get_fork_TTY> function for X11. If a
6948 program running under the debugger forks, a new <xterm> window is opened and
6949 the subsidiary debugger is directed there.
6950
6951 The C<open()> call is of particular note here. We have the new C<xterm>
6952 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6953 command (which prints the device name of the TTY we'll want to use for input
6954 and output to STDOUT, then C<sleep> for a very long time, routing this output
6955 to file number 3. This way we can simply read from the <XT> filehandle (which
6956 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6957
6958 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6959 properly set up.
6960
6961 =cut
6962
6963 sub xterm_get_fork_TTY {
6964     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6965     open XT,
6966 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6967  sleep 10000000' |];
6968
6969     # Get the output from 'tty' and clean it up a little.
6970     my $tty = <XT>;
6971     chomp $tty;
6972
6973     $pidprompt = '';    # Shown anyway in titlebar
6974
6975     # We need $term defined or we can not switch to the newly created xterm
6976     if ($tty ne '' && !defined $term) {
6977         require Term::ReadLine;
6978         if ( !$rl ) {
6979             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6980         }
6981         else {
6982             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6983         }
6984     }
6985     # There's our new TTY.
6986     return $tty;
6987 } ## end sub xterm_get_fork_TTY
6988
6989 =head3 C<os2_get_fork_TTY>
6990
6991 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6992
6993 =cut
6994
6995 # This example function resets $IN, $OUT itself
6996 my $c_pipe = 0;
6997 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6998     local $\  = '';
6999     ( my $name = $0 ) =~ s,^.*[/\\],,s;
7000     my %opt = ( title => "Daughter Perl debugger $pids $name",
7001         ($rl ? (read_by_key => 1) : ()) );
7002     require OS2::Process;
7003     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
7004       or return;
7005     $pidprompt = '';    # Shown anyway in titlebar
7006     reset_IN_OUT($in, $out);
7007     $tty = '*reset*';
7008     return '';          # Indicate that reset_IN_OUT is called
7009 } ## end sub os2_get_fork_TTY
7010
7011 =head3 C<macosx_get_fork_TTY>
7012
7013 The Mac OS X version uses AppleScript to tell Terminal.app to create
7014 a new window.
7015
7016 =cut
7017
7018 # Notes about Terminal.app's AppleScript support,
7019 # (aka things that might break in future OS versions).
7020 #
7021 # The "do script" command doesn't return a reference to the new window
7022 # it creates, but since it appears frontmost and windows are enumerated
7023 # front to back, we can use "first window" === "window 1".
7024 #
7025 # Since "do script" is implemented by supplying the argument (plus a
7026 # return character) as terminal input, there's a potential race condition
7027 # where the debugger could beat the shell to reading the command.
7028 # To prevent this, we wait for the screen to clear before proceeding.
7029 #
7030 # 10.3 and 10.4:
7031 # There's no direct accessor for the tty device name, so we fiddle
7032 # with the window title options until it says what we want.
7033 #
7034 # 10.5:
7035 # There _is_ a direct accessor for the tty device name, _and_ there's
7036 # a new possible component of the window title (the name of the settings
7037 # set).  A separate version is needed.
7038
7039 my @script_versions=
7040
7041     ([237, <<'__LEOPARD__'],
7042 tell application "Terminal"
7043     do script "clear;exec sleep 100000"
7044     tell first tab of first window
7045         copy tty to thetty
7046         set custom title to "forked perl debugger"
7047         set title displays custom title to true
7048         repeat while (length of first paragraph of (get contents)) > 0
7049             delay 0.1
7050         end repeat
7051     end tell
7052 end tell
7053 thetty
7054 __LEOPARD__
7055
7056      [100, <<'__JAGUAR_TIGER__'],
7057 tell application "Terminal"
7058     do script "clear;exec sleep 100000"
7059     tell first window
7060         set title displays shell path to false
7061         set title displays window size to false
7062         set title displays file name to false
7063         set title displays device name to true
7064         set title displays custom title to true
7065         set custom title to ""
7066         copy "/dev/" & name to thetty
7067         set custom title to "forked perl debugger"
7068         repeat while (length of first paragraph of (get contents)) > 0
7069             delay 0.1
7070         end repeat
7071     end tell
7072 end tell
7073 thetty
7074 __JAGUAR_TIGER__
7075
7076 );
7077
7078 sub macosx_get_fork_TTY
7079 {
7080     my($version,$script,$pipe,$tty);
7081
7082     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7083     foreach my $entry (@script_versions) {
7084         if ($version>=$entry->[0]) {
7085             $script=$entry->[1];
7086             last;
7087         }
7088     }
7089     return unless defined($script);
7090     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7091     $tty=readline($pipe);
7092     close($pipe);
7093     return unless defined($tty) && $tty =~ m(^/dev/);
7094     chomp $tty;
7095     return $tty;
7096 }
7097
7098 =head3 C<tmux_get_fork_TTY>
7099
7100 Creates a split window for subprocesses when a process running under the
7101 perl debugger in Tmux forks.
7102
7103 =cut
7104
7105 sub tmux_get_fork_TTY {
7106     return unless $ENV{TMUX};
7107
7108     my $pipe;
7109
7110     my $status = open $pipe, '-|', 'tmux', 'split-window',
7111         '-P', '-F', '#{pane_tty}', 'sleep 100000';
7112
7113     if ( !$status ) {
7114         return;
7115     }
7116
7117     my $tty = <$pipe>;
7118     close $pipe;
7119
7120     if ( $tty ) {
7121         chomp $tty;
7122
7123         if ( !defined $term ) {
7124             require Term::ReadLine;
7125             if ( !$rl ) {
7126                 $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7127             }
7128             else {
7129                 $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7130             }
7131         }
7132     }
7133
7134     return $tty;
7135 }
7136
7137 =head2 C<create_IN_OUT($flags)>
7138
7139 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7140 try to diagnose why.
7141
7142 Flags are:
7143
7144 =over 4
7145
7146 =item * 1 - Don't know how to create a new TTY.
7147
7148 =item * 2 - Debugger has forked, but we can't get a new TTY.
7149
7150 =item * 4 - standard debugger startup is happening.
7151
7152 =back
7153
7154 =cut
7155
7156 use vars qw($fork_TTY);
7157
7158 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7159
7160     # If we know how to get a new TTY, do it! $in will have
7161     # the TTY name if get_fork_TTY works.
7162     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7163
7164     # It used to be that
7165     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7166
7167     if ( not defined $in ) {
7168         my $why = shift;
7169
7170         # We don't know how.
7171         print_help(<<EOP) if $why == 1;
7172 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7173 EOP
7174
7175         # Forked debugger.
7176         print_help(<<EOP) if $why == 2;
7177 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7178   This may be an asynchronous session, so the parent debugger may be active.
7179 EOP
7180
7181         # Note that both debuggers are fighting over the same input.
7182         print_help(<<EOP) if $why != 4;
7183   Since two debuggers fight for the same TTY, input is severely entangled.
7184
7185 EOP
7186         print_help(<<EOP);
7187   I know how to switch the output to a different window in xterms, OS/2
7188   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7189   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7190   B<DB::get_fork_TTY()> returning this.
7191
7192   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7193   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7194
7195 EOP
7196     } ## end if (not defined $in)
7197     elsif ( $in ne '' ) {
7198         TTY($in);
7199     }
7200     else {
7201         $console = '';    # Indicate no need to open-from-the-console
7202     }
7203     undef $fork_TTY;
7204 } ## end sub create_IN_OUT
7205
7206 =head2 C<resetterm>
7207
7208 Handles rejiggering the prompt when we've forked off a new debugger.
7209
7210 If the new debugger happened because of a C<system()> that invoked a
7211 program under the debugger, the arrow between the old pid and the new
7212 in the prompt has I<two> dashes instead of one.
7213
7214 We take the current list of pids and add this one to the end. If there
7215 isn't any list yet, we make one up out of the initial pid associated with
7216 the terminal and our new pid, sticking an arrow (either one-dashed or
7217 two dashed) in between them.
7218
7219 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7220 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7221 and try to do that.
7222
7223 =cut
7224
7225 sub resetterm {    # We forked, so we need a different TTY
7226
7227     # Needs to be passed to create_IN_OUT() as well.
7228     my $in = shift;
7229
7230     # resetterm(2): got in here because of a system() starting a debugger.
7231     # resetterm(1): just forked.
7232     my $systemed = $in > 1 ? '-' : '';
7233
7234     # If there's already a list of pids, add this to the end.
7235     if ($pids) {
7236         $pids =~ s/\]/$systemed->$$]/;
7237     }
7238
7239     # No pid list. Time to make one.
7240     else {
7241         $pids = "[$term_pid->$$]";
7242     }
7243
7244     # The prompt we're going to be using for this debugger.
7245     $pidprompt = $pids;
7246
7247     # We now 0wnz this terminal.
7248     $term_pid = $$;
7249
7250     # Just return if we're not supposed to try to create a new TTY.
7251     return unless $CreateTTY & $in;
7252
7253     # Try to create a new IN/OUT pair.
7254     create_IN_OUT($in);
7255 } ## end sub resetterm
7256
7257 =head2 C<readline>
7258
7259 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7260 the next line, print a message saying we got it, add it to the terminal
7261 history (if possible), and return it.
7262
7263 If there's nothing in the typeahead buffer, check the command filehandle stack.
7264 If there are any filehandles there, read from the last one, and return the line
7265 if we got one. If not, we pop the filehandle off and close it, and try the
7266 next one up the stack.
7267
7268 If we've emptied the filehandle stack, we check to see if we've got a socket
7269 open, and we read that and return it if we do. If we don't, we just call the
7270 core C<readline()> and return its value.
7271
7272 =cut
7273
7274 sub readline {
7275
7276     # Localize to prevent it from being smashed in the program being debugged.
7277     local $.;
7278
7279     # If there are stacked filehandles to read from ...
7280     # (Handle it before the typeahead, because we may call source/etc. from
7281     # the typeahead.)
7282     while (@cmdfhs) {
7283
7284         # Read from the last one in the stack.
7285         my $line = CORE::readline( $cmdfhs[-1] );
7286
7287         # If we got a line ...
7288         defined $line
7289           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7290           : close pop @cmdfhs;                            # Pop and close
7291     } ## end while (@cmdfhs)
7292
7293     # Pull a line out of the typeahead if there's stuff there.
7294     if (@typeahead) {
7295
7296         # How many lines left.
7297         my $left = @typeahead;
7298
7299         # Get the next line.
7300         my $got = shift @typeahead;
7301
7302         # Print a message saying we got input from the typeahead.
7303         local $\ = '';
7304         print $OUT "auto(-$left)", shift, $got, "\n";
7305
7306         # Add it to the terminal history (if possible).
7307         $term->AddHistory($got)
7308           if length($got) > 1
7309           and defined $term->Features->{addHistory};
7310         return $got;
7311     } ## end if (@typeahead)
7312
7313     # We really need to read some input. Turn off entry/exit trace and
7314     # return value printing.
7315     local $frame = 0;
7316     local $doret = -2;
7317
7318     # Nothing on the filehandle stack. Socket?
7319     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7320
7321         # Send anything we have to send.
7322         $OUT->write( join( '', @_ ) );
7323
7324         # Receive anything there is to receive.
7325         my $stuff = '';
7326         my $buf;
7327         my $first_time = 1;
7328
7329         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7330         {
7331             $first_time = 0;
7332             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7333                                             # XXX Don't know. You tell me.
7334         }
7335
7336         # What we got.
7337         return $stuff;
7338     } ## end if (ref $OUT and UNIVERSAL::isa...
7339
7340     # No socket. Just read from the terminal.
7341     else {
7342         return $term->readline(@_);
7343     }
7344 } ## end sub readline
7345
7346 =head1 OPTIONS SUPPORT ROUTINES
7347
7348 These routines handle listing and setting option values.
7349
7350 =head2 C<dump_option> - list the current value of an option setting
7351
7352 This routine uses C<option_val> to look up the value for an option.
7353 It cleans up escaped single-quotes and then displays the option and
7354 its value.
7355
7356 =cut
7357
7358 sub dump_option {
7359     my ( $opt, $val ) = @_;
7360     $val = option_val( $opt, 'N/A' );
7361     $val =~ s/([\\\'])/\\$1/g;
7362     printf $OUT "%20s = '%s'\n", $opt, $val;
7363 } ## end sub dump_option
7364
7365 sub options2remember {
7366     foreach my $k (@RememberOnROptions) {
7367         $option{$k} = option_val( $k, 'N/A' );
7368     }
7369     return %option;
7370 }
7371
7372 =head2 C<option_val> - find the current value of an option
7373
7374 This can't just be a simple hash lookup because of the indirect way that
7375 the option values are stored. Some are retrieved by calling a subroutine,
7376 some are just variables.
7377
7378 You must supply a default value to be used in case the option isn't set.
7379
7380 =cut
7381
7382 sub option_val {
7383     my ( $opt, $default ) = @_;
7384     my $val;
7385
7386     # Does this option exist, and is it a variable?
7387     # If so, retrieve the value via the value in %optionVars.
7388     if (    defined $optionVars{$opt}
7389         and defined ${ $optionVars{$opt} } )
7390     {
7391         $val = ${ $optionVars{$opt} };
7392     }
7393
7394     # Does this option exist, and it's a subroutine?
7395     # If so, call the subroutine via the ref in %optionAction
7396     # and capture the value.
7397     elsif ( defined $optionAction{$opt}
7398         and defined &{ $optionAction{$opt} } )
7399     {
7400         $val = &{ $optionAction{$opt} }();
7401     }
7402
7403     # If there's an action or variable for the supplied option,
7404     # but no value was set, use the default.
7405     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7406         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7407     {
7408         $val = $default;
7409     }
7410
7411     # Otherwise, do the simple hash lookup.
7412     else {
7413         $val = $option{$opt};
7414     }
7415
7416     # If the value isn't defined, use the default.
7417     # Then return whatever the value is.
7418     $val = $default unless defined $val;
7419     $val;
7420 } ## end sub option_val
7421
7422 =head2 C<parse_options>
7423
7424 Handles the parsing and execution of option setting/displaying commands.
7425
7426 An option entered by itself is assumed to be I<set me to 1> (the default value)
7427 if the option is a boolean one. If not, the user is prompted to enter a valid
7428 value or to query the current value (via C<option? >).
7429
7430 If C<option=value> is entered, we try to extract a quoted string from the
7431 value (if it is quoted). If it's not, we just use the whole value as-is.
7432
7433 We load any modules required to service this option, and then we set it: if
7434 it just gets stuck in a variable, we do that; if there's a subroutine to
7435 handle setting the option, we call that.
7436
7437 Finally, if we're running in interactive mode, we display the effect of the
7438 user's command back to the terminal, skipping this if we're setting things
7439 during initialization.
7440
7441 =cut
7442
7443 sub parse_options {
7444     my ($s) = @_;
7445     local $\ = '';
7446
7447     my $option;
7448
7449     # These options need a value. Don't allow them to be clobbered by accident.
7450     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7451       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7452       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7453     };
7454
7455     while (length($s)) {
7456         my $val_defaulted;
7457
7458         # Clean off excess leading whitespace.
7459         $s =~ s/^\s+// && next;
7460
7461         # Options are always all word characters, followed by a non-word
7462         # separator.
7463         if ($s !~ s/^(\w+)(\W?)//) {
7464             print {$OUT} "Invalid option '$s'\n";
7465             last;
7466         }
7467         my ( $opt, $sep ) = ( $1, $2 );
7468
7469         # Make sure that such an option exists.
7470         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7471           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7472
7473         unless ($matches) {
7474             print {$OUT} "Unknown option '$opt'\n";
7475             next;
7476         }
7477         if ($matches > 1) {
7478             print {$OUT} "Ambiguous option '$opt'\n";
7479             next;
7480         }
7481         my $val;
7482
7483         # '?' as separator means query, but must have whitespace after it.
7484         if ( "?" eq $sep ) {
7485             if ($s =~ /\A\S/) {
7486                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7487
7488                 last;
7489             }
7490
7491             #&dump_option($opt);
7492         } ## end if ("?" eq $sep)
7493
7494         # Separator is whitespace (or just a carriage return).
7495         # They're going for a default, which we assume is 1.
7496         elsif ( $sep !~ /\S/ ) {
7497             $val_defaulted = 1;
7498             $val           = "1";   #  this is an evil default; make 'em set it!
7499         }
7500
7501         # Separator is =. Trying to set a value.
7502         elsif ( $sep eq "=" ) {
7503
7504             # If quoted, extract a quoted string.
7505             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7506                 my $quote = $1;
7507                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7508             }
7509
7510             # Not quoted. Use the whole thing. Warn about 'option='.
7511             else {
7512                 $s =~ s/^(\S*)//;
7513                 $val = $1;
7514                 print OUT qq(Option better cleared using $opt=""\n)
7515                   unless length $val;
7516             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7517
7518         } ## end elsif ($sep eq "=")
7519
7520         # "Quoted" with [], <>, or {}.
7521         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7522             my ($end) =
7523               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7524             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7525               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7526             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7527         } ## end else [ if ("?" eq $sep)
7528
7529         # Exclude non-booleans from getting set to 1 by default.
7530         if ( $opt_needs_val{$option} && $val_defaulted ) {
7531             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7532             print {$OUT}
7533 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7534             next;
7535         } ## end if ($opt_needs_val{$option...
7536
7537         # Save the option value.
7538         $option{$option} = $val if defined $val;
7539
7540         # Load any module that this option requires.
7541         if ( defined($optionRequire{$option}) && defined($val) ) {
7542             eval qq{
7543             local \$frame = 0;
7544             local \$doret = -2;
7545             require '$optionRequire{$option}';
7546             1;
7547             } || die $@   # XXX: shouldn't happen
7548         }
7549
7550         # Set it.
7551         # Stick it in the proper variable if it goes in a variable.
7552         if (defined($optionVars{$option}) && defined($val)) {
7553             ${ $optionVars{$option} } = $val;
7554         }
7555
7556         # Call the appropriate sub if it gets set via sub.
7557         if (defined($optionAction{$option})
7558           && defined (&{ $optionAction{$option} })
7559           && defined ($val))
7560         {
7561           &{ $optionAction{$option} }($val);
7562         }
7563
7564         # Not initialization - echo the value we set it to.
7565         dump_option($option) if ($OUT ne \*STDERR);
7566     } ## end while (length)
7567 } ## end sub parse_options
7568
7569 =head1 RESTART SUPPORT
7570
7571 These routines are used to store (and restore) lists of items in environment
7572 variables during a restart.
7573
7574 =head2 set_list
7575
7576 Set_list packages up items to be stored in a set of environment variables
7577 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7578 the values). Values outside the standard ASCII charset are stored by encoding
7579 them as hexadecimal values.
7580
7581 =cut
7582
7583 sub set_list {
7584     my ( $stem, @list ) = @_;
7585     my $val;
7586
7587     # VAR_n: how many we have. Scalar assignment gets the number of items.
7588     $ENV{"${stem}_n"} = @list;
7589
7590     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7591     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7592     for my $i ( 0 .. $#list ) {
7593         $val = $list[$i];
7594         $val =~ s/\\/\\\\/g;
7595         no warnings 'experimental::regex_sets';
7596         $val =~ s/ ( (?[ [\000-\xFF] & [:^print:] ]) ) /
7597                                                 "\\0x" . unpack('H2',$1)/xaeg;
7598         $ENV{"${stem}_$i"} = $val;
7599     } ## end for $i (0 .. $#list)
7600 } ## end sub set_list
7601
7602 =head2 get_list
7603
7604 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7605 back, and then pull VAR_0, VAR_1. etc. back out.
7606
7607 =cut
7608
7609 sub get_list {
7610     my $stem = shift;
7611     my @list;
7612     my $n = delete $ENV{"${stem}_n"};
7613     my $val;
7614     for my $i ( 0 .. $n - 1 ) {
7615         $val = delete $ENV{"${stem}_$i"};
7616         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7617         push @list, $val;
7618     }
7619     @list;
7620 } ## end sub get_list
7621
7622 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7623
7624 =head2 catch()
7625
7626 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7627 set an already-existing global scalar variable to a constant value. This
7628 avoids allocating any memory possibly in the middle of something that will
7629 get all confused if we do, particularly under I<unsafe signals>.
7630
7631 =cut
7632
7633 sub catch {
7634     $signal = 1;
7635     return;    # Put nothing on the stack - malloc/free land!
7636 }
7637
7638 =head2 C<warn()>
7639
7640 C<warn> emits a warning, by joining together its arguments and printing
7641 them, with couple of fillips.
7642
7643 If the composited message I<doesn't> end with a newline, we automatically
7644 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7645 to be set to the filehandle to be used to output warnings; it makes no
7646 assumptions about what filehandles are available.
7647
7648 =cut
7649
7650 sub _db_warn {
7651     my ($msg) = join( "", @_ );
7652     $msg .= ": $!\n" unless $msg =~ /\n$/;
7653     local $\ = '';
7654     print $OUT $msg;
7655 } ## end sub warn
7656
7657 *warn = \&_db_warn;
7658
7659 =head1 INITIALIZATION TTY SUPPORT
7660
7661 =head2 C<reset_IN_OUT>
7662
7663 This routine handles restoring the debugger's input and output filehandles
7664 after we've tried and failed to move them elsewhere.  In addition, it assigns
7665 the debugger's output filehandle to $LINEINFO if it was already open there.
7666
7667 =cut
7668
7669 sub reset_IN_OUT {
7670     my $switch_li = $LINEINFO eq $OUT;
7671
7672     # If there's a term and it's able to get a new tty, try to get one.
7673     if ( $term and $term->Features->{newTTY} ) {
7674         ( $IN, $OUT ) = ( shift, shift );
7675         $term->newTTY( $IN, $OUT );
7676     }
7677
7678     # This term can't get a new tty now. Better luck later.
7679     elsif ($term) {
7680         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7681     }
7682
7683     # Set the filehndles up as they were.
7684     else {
7685         ( $IN, $OUT ) = ( shift, shift );
7686     }
7687
7688     # Unbuffer the output filehandle.
7689     _autoflush($OUT);
7690
7691     # Point LINEINFO to the same output filehandle if it was there before.
7692     $LINEINFO = $OUT if $switch_li;
7693 } ## end sub reset_IN_OUT
7694
7695 =head1 OPTION SUPPORT ROUTINES
7696
7697 The following routines are used to process some of the more complicated
7698 debugger options.
7699
7700 =head2 C<TTY>
7701
7702 Sets the input and output filehandles to the specified files or pipes.
7703 If the terminal supports switching, we go ahead and do it. If not, and
7704 there's already a terminal in place, we save the information to take effect
7705 on restart.
7706
7707 If there's no terminal yet (for instance, during debugger initialization),
7708 we go ahead and set C<$console> and C<$tty> to the file indicated.
7709
7710 =cut
7711
7712 sub TTY {
7713
7714     if ( @_ and $term and $term->Features->{newTTY} ) {
7715
7716         # This terminal supports switching to a new TTY.
7717         # Can be a list of two files, or on string containing both names,
7718         # comma-separated.
7719         # XXX Should this perhaps be an assignment from @_?
7720         my ( $in, $out ) = shift;
7721         if ( $in =~ /,/ ) {
7722
7723             # Split list apart if supplied.
7724             ( $in, $out ) = split /,/, $in, 2;
7725         }
7726         else {
7727
7728             # Use the same file for both input and output.
7729             $out = $in;
7730         }
7731
7732         # Open file onto the debugger's filehandles, if you can.
7733         open IN,  $in     or die "cannot open '$in' for read: $!";
7734         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7735
7736         # Swap to the new filehandles.
7737         reset_IN_OUT( \*IN, \*OUT );
7738
7739         # Save the setting for later.
7740         return $tty = $in;
7741     } ## end if (@_ and $term and $term...
7742
7743     # Terminal doesn't support new TTY, or doesn't support readline.
7744     # Can't do it now, try restarting.
7745     if ($term and @_) {
7746         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7747     }
7748
7749     # Useful if done through PERLDB_OPTS:
7750     $console = $tty = shift if @_;
7751
7752     # Return whatever the TTY is.
7753     $tty or $console;
7754 } ## end sub TTY
7755
7756 =head2 C<noTTY>
7757
7758 Sets the C<$notty> global, controlling whether or not the debugger tries to
7759 get a terminal to read from. If called after a terminal is already in place,
7760 we save the value to use it if we're restarted.
7761
7762 =cut
7763
7764 sub noTTY {
7765     if ($term) {
7766         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7767     }
7768     $notty = shift if @_;
7769     $notty;
7770 } ## end sub noTTY
7771
7772 =head2 C<ReadLine>
7773
7774 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7775 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7776 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7777 the value in case a restart is done so we can change it then.
7778
7779 =cut
7780
7781 sub ReadLine {
7782     if ($term) {
7783         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7784     }
7785     $rl = shift if @_;
7786     $rl;
7787 } ## end sub ReadLine
7788
7789 =head2 C<RemotePort>
7790
7791 Sets the port that the debugger will try to connect to when starting up.
7792 If the terminal's already been set up, we can't do it, but we remember the
7793 setting in case the user does a restart.
7794
7795 =cut
7796
7797 sub RemotePort {
7798     if ($term) {
7799         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7800     }
7801     $remoteport = shift if @_;
7802     $remoteport;
7803 } ## end sub RemotePort
7804
7805 =head2 C<tkRunning>
7806
7807 Checks with the terminal to see if C<Tk> is running, and returns true or
7808 false. Returns false if the current terminal doesn't support C<readline>.
7809
7810 =cut
7811
7812 sub tkRunning {
7813     if ( ${ $term->Features }{tkRunning} ) {
7814         return $term->tkRunning(@_);
7815     }
7816     else {
7817         local $\ = '';
7818         print $OUT "tkRunning not supported by current ReadLine package.\n";
7819         0;
7820     }
7821 } ## end sub tkRunning
7822
7823 =head2 C<NonStop>
7824
7825 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7826 debugger remembers the setting in case you restart, though.
7827
7828 =cut
7829
7830 sub NonStop {
7831     if ($term) {
7832         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7833           if @_;
7834     }
7835     $runnonstop = shift if @_;
7836     $runnonstop;
7837 } ## end sub NonStop
7838
7839 sub DollarCaretP {
7840     if ($term) {
7841         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7842           if @_;
7843     }
7844     $^P = parse_DollarCaretP_flags(shift) if @_;
7845     expand_DollarCaretP_flags($^P);
7846 }
7847
7848 =head2 C<pager>
7849
7850 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7851 there already.
7852
7853 =cut
7854
7855 sub pager {
7856     if (@_) {
7857         $pager = shift;
7858         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7859     }
7860     $pager;
7861 } ## end sub pager
7862
7863 =head2 C<shellBang>
7864
7865 Sets the shell escape command, and generates a printable copy to be used
7866 in the help.
7867
7868 =cut
7869
7870 sub shellBang {
7871
7872     # If we got an argument, meta-quote it, and add '\b' if it
7873     # ends in a word character.
7874     if (@_) {
7875         $sh = quotemeta shift;
7876         $sh .= "\\b" if $sh =~ /\w$/;
7877     }
7878
7879     # Generate the printable version for the help:
7880     $psh = $sh;    # copy it
7881     $psh =~ s/\\b$//;        # Take off trailing \b if any
7882     $psh =~ s/\\(.)/$1/g;    # De-escape
7883     $psh;                    # return the printable version
7884 } ## end sub shellBang
7885
7886 =head2 C<ornaments>
7887
7888 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7889 was passed as the argument. (This means you can't override the terminal's
7890 ornaments.)
7891
7892 =cut
7893
7894 sub ornaments {
7895     if ( defined $term ) {
7896
7897         # We don't want to show warning backtraces, but we do want die() ones.
7898         local $warnLevel = 0;
7899         local $dieLevel = 1;
7900
7901         # No ornaments if the terminal doesn't support them.
7902         if (not $term->Features->{ornaments}) {
7903             return '';
7904         }
7905
7906         return (eval { $term->ornaments(@_) } || '');
7907     }
7908
7909     # Use what was passed in if we can't determine it ourselves.
7910     else {
7911         $ornaments = shift;
7912
7913         return $ornaments;
7914     }
7915
7916 } ## end sub ornaments
7917
7918 =head2 C<recallCommand>
7919
7920 Sets the recall command, and builds a printable version which will appear in
7921 the help text.
7922
7923 =cut
7924
7925 sub recallCommand {
7926
7927     # If there is input, metaquote it. Add '\b' if it ends with a word
7928     # character.
7929     if (@_) {
7930         $rc = quotemeta shift;
7931         $rc .= "\\b" if $rc =~ /\w$/;
7932     }
7933
7934     # Build it into a printable version.
7935     $prc = $rc;              # Copy it
7936     $prc =~ s/\\b$//;        # Remove trailing \b
7937     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7938     return $prc;             # Return the printable version
7939 } ## end sub recallCommand
7940
7941 =head2 C<LineInfo> - where the line number information goes
7942
7943 Called with no arguments, returns the file or pipe that line info should go to.
7944
7945 Called with an argument (a file or a pipe), it opens that onto the
7946 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7947 file or pipe again to the caller.
7948
7949 =cut
7950
7951 sub LineInfo {
7952     if (@_) {
7953         $lineinfo = shift;
7954
7955         #  If this is a valid "thing to be opened for output", tack a
7956         # '>' onto the front.
7957         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7958
7959         # If this is a pipe, the stream points to a slave editor.
7960         $slave_editor = ( $stream =~ /^\|/ );
7961
7962         my $new_lineinfo_fh;
7963         # Open it up and unbuffer it.
7964         open ($new_lineinfo_fh , $stream )
7965             or _db_warn("Cannot open '$stream' for write");
7966         $LINEINFO = $new_lineinfo_fh;
7967         _autoflush($LINEINFO);
7968     }
7969
7970     return $lineinfo;
7971 } ## end sub LineInfo
7972
7973 =head1 COMMAND SUPPORT ROUTINES
7974
7975 These subroutines provide functionality for various commands.
7976
7977 =head2 C<list_modules>
7978
7979 For the C<M> command: list modules loaded and their versions.
7980 Essentially just runs through the keys in %INC, picks each package's
7981 C<$VERSION> variable, gets the file name, and formats the information
7982 for output.
7983
7984 =cut
7985
7986 sub list_modules {    # versions
7987     my %version;
7988     my $file;
7989
7990     # keys are the "as-loaded" name, values are the fully-qualified path
7991     # to the file itself.
7992     for ( keys %INC ) {
7993         $file = $_;                                # get the module name
7994         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7995         s,/,::,g;                                  # change '/' to '::'
7996         s/^perl5db$/DB/;                           # Special case: debugger
7997                                                    # moves to package DB
7998         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7999
8000         # If the package has a $VERSION package global (as all good packages
8001         # should!) decode it and save as partial message.
8002         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
8003         if ( defined $pkg_version ) {
8004             $version{$file} = "$pkg_version from ";
8005         }
8006
8007         # Finish up the message with the file the package came from.
8008         $version{$file} .= $INC{$file};
8009     } ## end for (keys %INC)
8010
8011     # Hey, dumpit() formats a hash nicely, so why not use it?
8012     dumpit( $OUT, \%version );
8013 } ## end sub list_modules
8014
8015 =head2 C<sethelp()>
8016
8017 Sets up the monster string used to format and print the help.
8018
8019 =head3 HELP MESSAGE FORMAT
8020
8021 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
8022 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
8023 easy to parse and portable, but which still allows the help to be a little
8024 nicer than just plain text.
8025
8026 Essentially, you define the command name (usually marked up with C<< B<> >>
8027 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
8028 newline. The descriptive text can also be marked up in the same way. If you
8029 need to continue the descriptive text to another line, start that line with
8030 just tabs and then enter the marked-up text.
8031
8032 If you are modifying the help text, I<be careful>. The help-string parser is
8033 not very sophisticated, and if you don't follow these rules it will mangle the
8034 help beyond hope until you fix the string.
8035
8036 =cut
8037
8038 use vars qw($pre580_help);
8039 use vars qw($pre580_summary);
8040
8041 sub sethelp {
8042
8043     # XXX: make sure there are tabs between the command and explanation,
8044     #      or print_help will screw up your formatting if you have
8045     #      eeevil ornaments enabled.  This is an insane mess.
8046
8047     $help = "
8048 Help is currently only available for the new 5.8 command set.
8049 No help is available for the old command set.
8050 We assume you know what you're doing if you switch to it.
8051
8052 B<T>        Stack trace.
8053 B<s> [I<expr>]    Single step [in I<expr>].
8054 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8055 <B<CR>>        Repeat last B<n> or B<s> command.
8056 B<r>        Return from current subroutine.
8057 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8058         at the specified position.
8059 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8060 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8061 B<l> I<line>        List single I<line>.
8062 B<l> I<subname>    List first window of lines from subroutine.
8063 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8064 B<l>        List next window of lines.
8065 B<->        List previous window of lines.
8066 B<v> [I<line>]    View window around I<line>.
8067 B<.>        Return to the executed line.
8068 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8069         I<filename> may be either the full name of the file, or a regular
8070         expression matching the full file name:
8071         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8072         Evals (with saved bodies) are considered to be filenames:
8073         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8074         (in the order of execution).
8075 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8076 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8077 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8078 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8079 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8080 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8081 B<b>        Sets breakpoint on current line)
8082 B<b> [I<line>] [I<condition>]
8083         Set breakpoint; I<line> defaults to the current execution line;
8084         I<condition> breaks if it evaluates to true, defaults to '1'.
8085 B<b> I<subname> [I<condition>]
8086         Set breakpoint at first line of subroutine.
8087 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8088 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8089 B<b> B<postpone> I<subname> [I<condition>]
8090         Set breakpoint at first line of subroutine after
8091         it is compiled.
8092 B<b> B<compile> I<subname>
8093         Stop after the subroutine is compiled.
8094 B<B> [I<line>]    Delete the breakpoint for I<line>.
8095 B<B> I<*>             Delete all breakpoints.
8096 B<a> [I<line>] I<command>
8097         Set an action to be done before the I<line> is executed;
8098         I<line> defaults to the current execution line.
8099         Sequence is: check for breakpoint/watchpoint, print line
8100         if necessary, do action, prompt user if necessary,
8101         execute line.
8102 B<a>        Does nothing
8103 B<A> [I<line>]    Delete the action for I<line>.
8104 B<A> I<*>             Delete all actions.
8105 B<w> I<expr>        Add a global watch-expression.
8106 B<w>             Does nothing
8107 B<W> I<expr>        Delete a global watch-expression.
8108 B<W> I<*>             Delete all watch-expressions.
8109 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8110         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8111 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8112 B<x> I<expr>        Evals expression in list context, dumps the result.
8113 B<m> I<expr>        Evals expression in list context, prints methods callable
8114         on the first element of the result.
8115 B<m> I<class>        Prints methods callable via the given class.
8116 B<M>        Show versions of loaded modules.
8117 B<i> I<class>       Prints nested parents of given class.
8118 B<e>         Display current thread id.
8119 B<E>         Display all thread ids the current one will be identified: <n>.
8120 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8121
8122 B<<> ?            List Perl commands to run before each prompt.
8123 B<<> I<expr>        Define Perl command to run before each prompt.
8124 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8125 B<< *>                Delete the list of perl commands to run before each prompt.
8126 B<>> ?            List Perl commands to run after each prompt.
8127 B<>> I<expr>        Define Perl command to run after each prompt.
8128 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8129 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8130 B<{> I<db_command>    Define debugger command to run before each prompt.
8131 B<{> ?            List debugger commands to run before each prompt.
8132 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8133 B<{ *>             Delete the list of debugger commands to run before each prompt.
8134 B<$prc> I<number>    Redo a previous command (default previous command).
8135 B<$prc> I<-number>    Redo number'th-to-last command.
8136 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8137         See 'B<O> I<recallCommand>' too.
8138 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8139       . (
8140         $rc eq $sh
8141         ? ""
8142         : "
8143 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8144       ) . "
8145         See 'B<O> I<shellBang>' too.
8146 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8147 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8148 B<rerun>           Rerun session to current position.
8149 B<rerun> I<n>         Rerun session to numbered command.
8150 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8151 B<H> I<-number>    Display last number commands (default all).
8152 B<H> I<*>          Delete complete history.
8153 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8154 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8155 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8156 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8157 I<command>        Execute as a perl statement in current package.
8158 B<R>        Pure-man-restart of debugger, some of debugger state
8159         and command-line options may be lost.
8160         Currently the following settings are preserved:
8161         history, breakpoints and actions, debugger B<O>ptions
8162         and the following command-line options: I<-w>, I<-I>, I<-e>.
8163
8164 B<o> [I<opt>] ...    Set boolean option to true
8165 B<o> [I<opt>B<?>]    Query options
8166 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8167         Set options.  Use quotes if spaces in value.
8168     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8169     I<pager>            program for output of \"|cmd\";
8170     I<tkRunning>            run Tk while prompting (with ReadLine);
8171     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8172     I<inhibit_exit>        Allows stepping off the end of the script.
8173     I<ImmediateStop>        Debugger should stop as early as possible.
8174     I<RemotePort>            Remote hostname:port for remote debugging
8175   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8176     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8177     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8178     I<globPrint>             whether to print contents of globs;
8179     I<DumpDBFiles>         dump arrays holding debugged files;
8180     I<DumpPackages>         dump symbol tables of packages;
8181     I<DumpReused>             dump contents of \"reused\" addresses;
8182     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8183     I<bareStringify>         Do not print the overload-stringified value;
8184   Other options include:
8185     I<PrintRet>        affects printing of return value after B<r> command,
8186     I<frame>        affects printing messages on subroutine entry/exit.
8187     I<AutoTrace>    affects printing messages on possible breaking points.
8188     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8189     I<ornaments>     affects screen appearance of the command line.
8190     I<CreateTTY>     bits control attempts to create a new TTY on events:
8191             1: on fork()    2: debugger is started inside debugger
8192             4: on startup
8193     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8194     You can put additional initialization options I<TTY>, I<noTTY>,
8195     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8196     B<R> after you set them).
8197
8198 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8199 B<h>        Summary of debugger commands.
8200 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8201 B<h h>        Long help for debugger commands
8202 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8203         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8204         Set B<\$DB::doccmd> to change viewer.
8205
8206 Type '|h h' for a paged display if this was too hard to read.
8207
8208 ";    # Fix balance of vi % matching: }}}}
8209
8210     #  note: tabs in the following section are not-so-helpful
8211     $summary = <<"END_SUM";
8212 I<List/search source lines:>               I<Control script execution:>
8213   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8214   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8215   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8216   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8217   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8218   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8219 I<Debugger controls:>                        B<L>           List break/watch/actions
8220   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8221   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8222   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8223   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8224   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8225   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8226   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8227   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8228   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8229 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8230   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8231   B<p> I<expr>         Print expression (uses script's current package).
8232   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8233   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8234   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8235   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8236   B<e>     Display thread id     B<E> Display all thread ids.
8237 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8238 END_SUM
8239
8240     # ')}}; # Fix balance of vi % matching
8241
8242     # and this is really numb...
8243     $pre580_help = "
8244 B<T>        Stack trace.
8245 B<s> [I<expr>]    Single step [in I<expr>].
8246 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8247 B<CR>>        Repeat last B<n> or B<s> command.
8248 B<r>        Return from current subroutine.
8249 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8250         at the specified position.
8251 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8252 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8253 B<l> I<line>        List single I<line>.
8254 B<l> I<subname>    List first window of lines from subroutine.
8255 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8256 B<l>        List next window of lines.
8257 B<->        List previous window of lines.
8258 B<w> [I<line>]    List window around I<line>.
8259 B<.>        Return to the executed line.
8260 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8261         I<filename> may be either the full name of the file, or a regular
8262         expression matching the full file name:
8263         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8264         Evals (with saved bodies) are considered to be filenames:
8265         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8266         (in the order of execution).
8267 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8268 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8269 B<L>        List all breakpoints and actions.
8270 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8271 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8272 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8273 B<b> [I<line>] [I<condition>]
8274         Set breakpoint; I<line> defaults to the current execution line;
8275         I<condition> breaks if it evaluates to true, defaults to '1'.
8276 B<b> I<subname> [I<condition>]
8277         Set breakpoint at first line of subroutine.
8278 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8279 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8280 B<b> B<postpone> I<subname> [I<condition>]
8281         Set breakpoint at first line of subroutine after
8282         it is compiled.
8283 B<b> B<compile> I<subname>
8284         Stop after the subroutine is compiled.
8285 B<d> [I<line>]    Delete the breakpoint for I<line>.
8286 B<D>        Delete all breakpoints.
8287 B<a> [I<line>] I<command>
8288         Set an action to be done before the I<line> is executed;
8289         I<line> defaults to the current execution line.
8290         Sequence is: check for breakpoint/watchpoint, print line
8291         if necessary, do action, prompt user if necessary,
8292         execute line.
8293 B<a> [I<line>]    Delete the action for I<line>.
8294 B<A>        Delete all actions.
8295 B<W> I<expr>        Add a global watch-expression.
8296 B<W>        Delete all watch-expressions.
8297 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8298         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8299 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8300 B<x> I<expr>        Evals expression in list context, dumps the result.
8301 B<m> I<expr>        Evals expression in list context, prints methods callable
8302         on the first element of the result.
8303 B<m> I<class>        Prints methods callable via the given class.
8304
8305 B<<> ?            List Perl commands to run before each prompt.
8306 B<<> I<expr>        Define Perl command to run before each prompt.
8307 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8308 B<>> ?            List Perl commands to run after each prompt.
8309 B<>> I<expr>        Define Perl command to run after each prompt.
8310 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8311 B<{> I<db_command>    Define debugger command to run before each prompt.
8312 B<{> ?            List debugger commands to run before each prompt.
8313 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8314 B<$prc> I<number>    Redo a previous command (default previous command).
8315 B<$prc> I<-number>    Redo number'th-to-last command.
8316 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8317         See 'B<O> I<recallCommand>' too.
8318 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8319       . (
8320         $rc eq $sh
8321         ? ""
8322         : "
8323 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8324       ) . "
8325         See 'B<O> I<shellBang>' too.
8326 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8327 B<H> I<-number>    Display last number commands (default all).
8328 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8329 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8330 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8331 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8332 I<command>        Execute as a perl statement in current package.
8333 B<v>        Show versions of loaded modules.
8334 B<R>        Pure-man-restart of debugger, some of debugger state
8335         and command-line options may be lost.
8336         Currently the following settings are preserved:
8337         history, breakpoints and actions, debugger B<O>ptions
8338         and the following command-line options: I<-w>, I<-I>, I<-e>.
8339
8340 B<O> [I<opt>] ...    Set boolean option to true
8341 B<O> [I<opt>B<?>]    Query options
8342 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8343         Set options.  Use quotes if spaces in value.
8344     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8345     I<pager>            program for output of \"|cmd\";
8346     I<tkRunning>            run Tk while prompting (with ReadLine);
8347     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8348     I<inhibit_exit>        Allows stepping off the end of the script.
8349     I<ImmediateStop>        Debugger should stop as early as possible.
8350     I<RemotePort>            Remote hostname:port for remote debugging
8351   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8352     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8353     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8354     I<globPrint>             whether to print contents of globs;
8355     I<DumpDBFiles>         dump arrays holding debugged files;
8356     I<DumpPackages>         dump symbol tables of packages;
8357     I<DumpReused>             dump contents of \"reused\" addresses;
8358     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8359     I<bareStringify>         Do not print the overload-stringified value;
8360   Other options include:
8361     I<PrintRet>        affects printing of return value after B<r> command,
8362     I<frame>        affects printing messages on subroutine entry/exit.
8363     I<AutoTrace>    affects printing messages on possible breaking points.
8364     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8365     I<ornaments>     affects screen appearance of the command line.
8366     I<CreateTTY>     bits control attempts to create a new TTY on events:
8367             1: on fork()    2: debugger is started inside debugger
8368             4: on startup
8369     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8370     You can put additional initialization options I<TTY>, I<noTTY>,
8371     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8372     B<R> after you set them).
8373
8374 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8375 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8376 B<h h>        Summary of debugger commands.
8377 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8378         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8379         Set B<\$DB::doccmd> to change viewer.
8380
8381 Type '|h' for a paged display if this was too hard to read.
8382
8383 ";    # Fix balance of vi % matching: }}}}
8384
8385     #  note: tabs in the following section are not-so-helpful
8386     $pre580_summary = <<"END_SUM";
8387 I<List/search source lines:>               I<Control script execution:>
8388   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8389   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8390   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8391   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8392   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8393   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8394 I<Debugger controls:>                        B<L>           List break/watch/actions
8395   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8396   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8397   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8398   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8399   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8400   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8401   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8402   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8403 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8404   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8405   B<p> I<expr>         Print expression (uses script's current package).
8406   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8407   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8408   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8409   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8410 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8411 END_SUM
8412
8413     # ')}}; # Fix balance of vi % matching
8414
8415 } ## end sub sethelp
8416
8417 =head2 C<print_help()>
8418
8419 Most of what C<print_help> does is just text formatting. It finds the
8420 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8421 terminal control characters to simulate them (courtesy of
8422 C<Term::ReadLine::TermCap>).
8423
8424 =cut
8425
8426 sub print_help {
8427     my $help_str = shift;
8428
8429     # Restore proper alignment destroyed by eeevil I<> and B<>
8430     # ornaments: A pox on both their houses!
8431     #
8432     # A help command will have everything up to and including
8433     # the first tab sequence padded into a field 16 (or if indented 20)
8434     # wide.  If it's wider than that, an extra space will be added.
8435     $help_str =~ s{
8436         ^                       # only matters at start of line
8437           ( \ {4} | \t )*       # some subcommands are indented
8438           ( < ?                 # so <CR> works
8439             [BI] < [^\t\n] + )  # find an eeevil ornament
8440           ( \t+ )               # original separation, discarded
8441           ( .* )                # this will now start (no earlier) than
8442                                 # column 16
8443     } {
8444         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8445         my $clean = $command;
8446         $clean =~ s/[BI]<([^>]*)>/$1/g;
8447
8448         # replace with this whole string:
8449         ($leadwhite ? " " x 4 : "")
8450       . $command
8451       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8452       . $text;
8453
8454     }mgex;
8455
8456     $help_str =~ s{                          # handle bold ornaments
8457        B < ( [^>] + | > ) >
8458     } {
8459           $Term::ReadLine::TermCap::rl_term_set[2]
8460         . $1
8461         . $Term::ReadLine::TermCap::rl_term_set[3]
8462     }gex;
8463
8464     $help_str =~ s{                         # handle italic ornaments
8465        I < ( [^>] + | > ) >
8466     } {
8467           $Term::ReadLine::TermCap::rl_term_set[0]
8468         . $1
8469         . $Term::ReadLine::TermCap::rl_term_set[1]
8470     }gex;
8471
8472     local $\ = '';
8473     print {$OUT} $help_str;
8474
8475     return;
8476 } ## end sub print_help
8477
8478 =head2 C<fix_less>
8479
8480 This routine does a lot of gyrations to be sure that the pager is C<less>.
8481 It checks for C<less> masquerading as C<more> and records the result in
8482 C<$fixed_less> so we don't have to go through doing the stats again.
8483
8484 =cut
8485
8486 use vars qw($fixed_less);
8487
8488 sub _calc_is_less {
8489     if ($pager =~ /\bless\b/)
8490     {
8491         return 1;
8492     }
8493     elsif ($pager =~ /\bmore\b/)
8494     {
8495         # Nope, set to more. See what's out there.
8496         my @st_more = stat('/usr/bin/more');
8497         my @st_less = stat('/usr/bin/less');
8498
8499         # is it really less, pretending to be more?
8500         return (
8501             @st_more
8502             && @st_less
8503             && $st_more[0] == $st_less[0]
8504             && $st_more[1] == $st_less[1]
8505         );
8506     }
8507     else {
8508         return;
8509     }
8510 }
8511
8512 sub fix_less {
8513
8514     # We already know if this is set.
8515     return if $fixed_less;
8516
8517     # changes environment!
8518     # 'r' added so we don't do (slow) stats again.
8519     $fixed_less = 1 if _calc_is_less();
8520
8521     return;
8522 } ## end sub fix_less
8523
8524 =head1 DIE AND WARN MANAGEMENT
8525
8526 =head2 C<diesignal>
8527
8528 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8529 to debug a debugger problem.
8530
8531 It does its best to report the error that occurred, and then forces the
8532 program, debugger, and everything to die.
8533
8534 =cut
8535
8536 sub diesignal {
8537
8538     # No entry/exit messages.
8539     local $frame = 0;
8540
8541     # No return value prints.
8542     local $doret = -2;
8543
8544     # set the abort signal handling to the default (just terminate).
8545     $SIG{'ABRT'} = 'DEFAULT';
8546
8547     # If we enter the signal handler recursively, kill myself with an
8548     # abort signal (so we just terminate).
8549     kill 'ABRT', $$ if $panic++;
8550
8551     # If we can show detailed info, do so.
8552     if ( defined &Carp::longmess ) {
8553
8554         # Don't recursively enter the warn handler, since we're carping.
8555         local $SIG{__WARN__} = '';
8556
8557         # Skip two levels before reporting traceback: we're skipping
8558         # mydie and confess.
8559         local $Carp::CarpLevel = 2;    # mydie + confess
8560
8561         # Tell us all about it.
8562         _db_warn( Carp::longmess("Signal @_") );
8563     }
8564
8565     # No Carp. Tell us about the signal as best we can.
8566     else {
8567         local $\ = '';
8568         print $DB::OUT "Got signal @_\n";
8569     }
8570
8571     # Drop dead.
8572     kill 'ABRT', $$;
8573 } ## end sub diesignal
8574
8575 =head2 C<dbwarn>
8576
8577 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8578 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8579
8580 =cut
8581
8582 sub dbwarn {
8583
8584     # No entry/exit trace.
8585     local $frame = 0;
8586
8587     # No return value printing.
8588     local $doret = -2;
8589
8590     # Turn off warn and die handling to prevent recursive entries to this
8591     # routine.
8592     local $SIG{__WARN__} = '';
8593     local $SIG{__DIE__}  = '';
8594
8595     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8596     # done yet), we may not be able to do a require.
8597     eval { require Carp }
8598       if defined $^S;    # If error/warning during compilation,
8599                          # require may be broken.
8600
8601     # Use the core warn() unless Carp loaded OK.
8602     CORE::warn( @_,
8603         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8604       return
8605       unless defined &Carp::longmess;
8606
8607     # Save the current values of $single and $trace, and then turn them off.
8608     my ( $mysingle, $mytrace ) = ( $single, $trace );
8609     $single = 0;
8610     $trace  = 0;
8611
8612     # We can call Carp::longmess without its being "debugged" (which we
8613     # don't want - we just want to use it!). Capture this for later.
8614     my $mess = Carp::longmess(@_);
8615
8616     # Restore $single and $trace to their original values.
8617     ( $single, $trace ) = ( $mysingle, $mytrace );
8618
8619     # Use the debugger's own special way of printing warnings to print
8620     # the stack trace message.
8621     _db_warn($mess);
8622 } ## end sub dbwarn
8623
8624 =head2 C<dbdie>
8625
8626 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8627 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8628 single stepping and tracing during the call to C<Carp::longmess> to avoid
8629 debugging it - we just want to use it.
8630
8631 If C<dieLevel> is zero, we let the program being debugged handle the
8632 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8633 the debugger takes over all exception handling, printing a backtrace and
8634 displaying the exception via its C<dbwarn()> routine.
8635
8636 =cut
8637
8638 sub dbdie {
8639     local $frame         = 0;
8640     local $doret         = -2;
8641     local $SIG{__DIE__}  = '';
8642     local $SIG{__WARN__} = '';
8643     if ( $dieLevel > 2 ) {
8644         local $SIG{__WARN__} = \&dbwarn;
8645         _db_warn(@_);    # Yell no matter what
8646         return;
8647     }
8648     if ( $dieLevel < 2 ) {
8649         die @_ if $^S;    # in eval propagate
8650     }
8651
8652     # The code used to check $^S to see if compilation of the current thing
8653     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8654     eval { require Carp };
8655
8656     die( @_,
8657         "\nCannot print stack trace, load with -MCarp option to see stack" )
8658       unless defined &Carp::longmess;
8659
8660     # We do not want to debug this chunk (automatic disabling works
8661     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8662     # get the stack trace from Carp::longmess (if possible), restore $signal
8663     # and $trace, and then die with the stack trace.
8664     my ( $mysingle, $mytrace ) = ( $single, $trace );
8665     $single = 0;
8666     $trace  = 0;
8667     my $mess = "@_";
8668     {
8669
8670         package Carp;    # Do not include us in the list
8671         eval { $mess = Carp::longmess(@_); };
8672     }
8673     ( $single, $trace ) = ( $mysingle, $mytrace );
8674     die $mess;
8675 } ## end sub dbdie
8676
8677 =head2 C<warnlevel()>
8678
8679 Set the C<$DB::warnLevel> variable that stores the value of the
8680 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8681 results in the debugger taking over all warning handlers. Setting
8682 C<warnLevel> to zero leaves any warning handlers set up by the program
8683 being debugged in place.
8684
8685 =cut
8686
8687 sub warnLevel {
8688     if (@_) {
8689         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8690         $warnLevel = shift;
8691         if ($warnLevel) {
8692             $SIG{__WARN__} = \&DB::dbwarn;
8693         }
8694         elsif ($prevwarn) {
8695             $SIG{__WARN__} = $prevwarn;
8696         } else {
8697             undef $SIG{__WARN__};
8698         }
8699     } ## end if (@_)
8700     $warnLevel;
8701 } ## end sub warnLevel
8702
8703 =head2 C<dielevel>
8704
8705 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8706 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8707 zero lets you use your own C<die()> handler.
8708
8709 =cut
8710
8711 sub dieLevel {
8712     local $\ = '';
8713     if (@_) {
8714         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8715         $dieLevel = shift;
8716         if ($dieLevel) {
8717
8718             # Always set it to dbdie() for non-zero values.
8719             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8720
8721             # No longer exists, so don't try  to use it.
8722             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8723
8724             # If we've finished initialization, mention that stack dumps
8725             # are enabled, If dieLevel is 1, we won't stack dump if we die
8726             # in an eval().
8727             print $OUT "Stack dump during die enabled",
8728               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8729               if $I_m_init;
8730
8731             # XXX This is probably obsolete, given that diehard() is gone.
8732             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8733         } ## end if ($dieLevel)
8734
8735         # Put the old one back if there was one.
8736         elsif ($prevdie) {
8737             $SIG{__DIE__} = $prevdie;
8738             print $OUT "Default die handler restored.\n";
8739         } else {
8740             undef $SIG{__DIE__};
8741             print $OUT "Die handler removed.\n";
8742         }
8743     } ## end if (@_)
8744     $dieLevel;
8745 } ## end sub dieLevel
8746
8747 =head2 C<signalLevel>
8748
8749 Number three in a series: set C<signalLevel> to zero to keep your own
8750 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8751 takes over and handles them with C<DB::diesignal()>.
8752
8753 =cut
8754
8755 sub signalLevel {
8756     if (@_) {
8757         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8758         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8759         $signalLevel = shift;
8760         if ($signalLevel) {
8761             $SIG{SEGV} = \&DB::diesignal;
8762             $SIG{BUS}  = \&DB::diesignal;
8763         }
8764         else {
8765             $SIG{SEGV} = $prevsegv;
8766             $SIG{BUS}  = $prevbus;
8767         }
8768     } ## end if (@_)
8769     $signalLevel;
8770 } ## end sub signalLevel
8771
8772 =head1 SUBROUTINE DECODING SUPPORT
8773
8774 These subroutines are used during the C<x> and C<X> commands to try to
8775 produce as much information as possible about a code reference. They use
8776 L<Devel::Peek> to try to find the glob in which this code reference lives
8777 (if it does) - this allows us to actually code references which correspond
8778 to named subroutines (including those aliased via glob assignment).
8779
8780 =head2 C<CvGV_name()>
8781
8782 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8783 via that routine. If this fails, return the reference again (when the
8784 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8785
8786 =cut
8787
8788 sub CvGV_name {
8789     my $in   = shift;
8790     my $name = CvGV_name_or_bust($in);
8791     defined $name ? $name : $in;
8792 }
8793
8794 =head2 C<CvGV_name_or_bust> I<coderef>
8795
8796 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8797 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8798 find a glob for this ref.
8799
8800 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8801
8802 =cut
8803
8804 use vars qw($skipCvGV);
8805
8806 sub CvGV_name_or_bust {
8807     my $in = shift;
8808     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8809     return unless ref $in;
8810     $in = \&$in;            # Hard reference...
8811     eval { require Devel::Peek; 1 } or return;
8812     my $gv = Devel::Peek::CvGV($in) or return;
8813     *$gv{PACKAGE} . '::' . *$gv{NAME};
8814 } ## end sub CvGV_name_or_bust
8815
8816 =head2 C<find_sub>
8817
8818 A utility routine used in various places; finds the file where a subroutine
8819 was defined, and returns that filename and a line-number range.
8820
8821 Tries to use C<@sub> first; if it can't find it there, it tries building a
8822 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8823 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8824 this way, it brute-force searches C<%sub>, checking for identical references.
8825
8826 =cut
8827
8828 sub _find_sub_helper {
8829     my $subr = shift;
8830
8831     return unless defined &$subr;
8832     my $name = CvGV_name_or_bust($subr);
8833     my $data;
8834     $data = $sub{$name} if defined $name;
8835     return $data if defined $data;
8836
8837     # Old stupid way...
8838     $subr = \&$subr;    # Hard reference
8839     my $s;
8840     for ( keys %sub ) {
8841         $s = $_, last if $subr eq \&$_;
8842     }
8843     if ($s)
8844     {
8845         return $sub{$s};
8846     }
8847     else
8848     {
8849         return;
8850     }
8851
8852 }
8853
8854 sub find_sub {
8855     my $subr = shift;
8856     return ( $sub{$subr} || _find_sub_helper($subr) );
8857 } ## end sub find_sub
8858
8859 =head2 C<methods>
8860
8861 A subroutine that uses the utility function C<methods_via> to find all the
8862 methods in the class corresponding to the current reference and in
8863 C<UNIVERSAL>.
8864
8865 =cut
8866
8867 use vars qw(%seen);
8868
8869 sub methods {
8870
8871     # Figure out the class - either this is the class or it's a reference
8872     # to something blessed into that class.
8873     my $class = shift;
8874     $class = ref $class if ref $class;
8875
8876     local %seen;
8877
8878     # Show the methods that this class has.
8879     methods_via( $class, '', 1 );
8880
8881     # Show the methods that UNIVERSAL has.
8882     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8883 } ## end sub methods
8884
8885 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8886
8887 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8888 all the parent class methods. C<$class> is the name of the next class to
8889 try; C<$prefix> is the message prefix, which gets built up as we go up the
8890 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8891 higher in the C<@ISA> tree, 0 if we should stop.
8892
8893 =cut
8894
8895 sub methods_via {
8896
8897     # If we've processed this class already, just quit.
8898     my $class = shift;
8899     return if $seen{$class}++;
8900
8901     # This is a package that is contributing the methods we're about to print.
8902     my $prefix  = shift;
8903     my $prepend = $prefix ? "via $prefix: " : '';
8904     my @to_print;
8905
8906     # Extract from all the symbols in this class.
8907     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8908     while (my ($name, $glob) = each %$class_ref) {
8909         # references directly in the symbol table are Proxy Constant
8910         # Subroutines, and are by their very nature defined
8911         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8912         # to a subroutine reference, which can be tested by defined.
8913         # $glob might also be the value -1  (from sub foo;)
8914         # or (say) '$$' (from sub foo ($$);)
8915         # \$glob will be SCALAR in both cases.
8916         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8917             && !$seen{$name}++) {
8918             push @to_print, "$prepend$name\n";
8919         }
8920     }
8921
8922     {
8923         local $\ = '';
8924         local $, = '';
8925         print $DB::OUT $_ foreach sort @to_print;
8926     }
8927
8928     # If the $crawl_upward argument is false, just quit here.
8929     return unless shift;
8930
8931     # $crawl_upward true: keep going up the tree.
8932     # Find all the classes this one is a subclass of.
8933     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8934     for my $name ( @$class_ISA_ref ) {
8935
8936         # Set up the new prefix.
8937         $prepend = $prefix ? $prefix . " -> $name" : $name;
8938
8939         # Crawl up the tree and keep trying to crawl up.
8940         methods_via( $name, $prepend, 1 );
8941     }
8942 } ## end sub methods_via
8943
8944 =head2 C<setman> - figure out which command to use to show documentation
8945
8946 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8947
8948 =cut
8949
8950 sub setman {
8951     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8952       ? "man"         # O Happy Day!
8953       : "perldoc";    # Alas, poor unfortunates
8954 } ## end sub setman
8955
8956 =head2 C<runman> - run the appropriate command to show documentation
8957
8958 Accepts a man page name; runs the appropriate command to display it (set up
8959 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8960 program's STDIN and STDOUT.
8961
8962 =cut
8963
8964 sub runman {
8965     my $page = shift;
8966     unless ($page) {
8967         _db_system("$doccmd $doccmd");
8968         return;
8969     }
8970
8971     # this way user can override, like with $doccmd="man -Mwhatever"
8972     # or even just "man " to disable the path check.
8973     if ( $doccmd ne 'man' ) {
8974         _db_system("$doccmd $page");
8975         return;
8976     }
8977
8978     $page = 'perl' if lc($page) eq 'help';
8979
8980     require Config;
8981     my $man1dir = $Config::Config{man1direxp};
8982     my $man3dir = $Config::Config{man3direxp};
8983     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8984     my $manpath = '';
8985     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8986     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8987     chop $manpath if $manpath;
8988
8989     # harmless if missing, I figure
8990     local $ENV{MANPATH} = $manpath if $manpath;
8991     my $nopathopt = $^O =~ /dunno what goes here/;
8992     if (
8993         CORE::system(
8994             $doccmd,
8995
8996             # I just *know* there are men without -M
8997             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8998             split ' ', $page
8999         )
9000       )
9001     {
9002         unless ( $page =~ /^perl\w/ ) {
9003             # Previously the debugger contained a list which it slurped in,
9004             # listing the known "perl" manpages. However, it was out of date,
9005             # with errors both of omission and inclusion. This approach is
9006             # considerably less complex. The failure mode on a butchered
9007             # install is simply that the user has to run man or perldoc
9008             # "manually" with the full manpage name.
9009
9010             # There is a list of $^O values in installperl to determine whether
9011             # the directory is 'pods' or 'pod'. However, we can avoid tight
9012             # coupling to that by simply checking the "non-standard" 'pods'
9013             # first.
9014             my $pods = "$Config::Config{privlibexp}/pods";
9015             $pods = "$Config::Config{privlibexp}/pod"
9016                 unless -d $pods;
9017             if (-f "$pods/perl$page.pod") {
9018                 CORE::system( $doccmd,
9019                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9020                     "perl$page" );
9021             }
9022         }
9023     } ## end if (CORE::system($doccmd...
9024 } ## end sub runman
9025
9026 #use Carp;                          # This did break, left for debugging
9027
9028 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
9029
9030 Because of the way the debugger interface to the Perl core is designed, any
9031 debugger package globals that C<DB::sub()> requires have to be defined before
9032 any subroutines can be called. These are defined in the second C<BEGIN> block.
9033
9034 This block sets things up so that (basically) the world is sane
9035 before the debugger starts executing. We set up various variables that the
9036 debugger has to have set up before the Perl core starts running:
9037
9038 =over 4
9039
9040 =item *
9041
9042 The debugger's own filehandles (copies of STD and STDOUT for now).
9043
9044 =item *
9045
9046 Characters for shell escapes, the recall command, and the history command.
9047
9048 =item *
9049
9050 The maximum recursion depth.
9051
9052 =item *
9053
9054 The size of a C<w> command's window.
9055
9056 =item *
9057
9058 The before-this-line context to be printed in a C<v> (view a window around this line) command.
9059
9060 =item *
9061
9062 The fact that we're not in a sub at all right now.
9063
9064 =item *
9065
9066 The default SIGINT handler for the debugger.
9067
9068 =item *
9069
9070 The appropriate value of the flag in C<$^D> that says the debugger is running
9071
9072 =item *
9073
9074 The current debugger recursion level
9075
9076 =item *
9077
9078 The list of postponed items and the C<$single> stack (XXX define this)
9079
9080 =item *
9081
9082 That we want no return values and no subroutine entry/exit trace.
9083
9084 =back
9085
9086 =cut
9087
9088 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9089
9090 use vars qw($db_stop);
9091
9092 BEGIN {    # This does not compile, alas. (XXX eh?)
9093     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9094     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9095
9096     # Define characters used by command parsing.
9097     $sh       = '!';      # Shell escape (does not work)
9098     $rc       = ',';      # Recall command (does not work)
9099     @hist     = ('?');    # Show history (does not work)
9100     @truehist = ();       # Can be saved for replay (per session)
9101
9102     # This defines the point at which you get the 'deep recursion'
9103     # warning. It MUST be defined or the debugger will not load.
9104     $deep = 1000;
9105
9106     # Number of lines around the current one that are shown in the
9107     # 'w' command.
9108     $window = 10;
9109
9110     # How much before-the-current-line context the 'v' command should
9111     # use in calculating the start of the window it will display.
9112     $preview = 3;
9113
9114     # We're not in any sub yet, but we need this to be a defined value.
9115     $sub = '';
9116
9117     # Set up the debugger's interrupt handler. It simply sets a flag
9118     # ($signal) that DB::DB() will check before each command is executed.
9119     $SIG{INT} = \&DB::catch;
9120
9121     # The following lines supposedly, if uncommented, allow the debugger to
9122     # debug itself. Perhaps we can try that someday.
9123     # This may be enabled to debug debugger:
9124     #$warnLevel = 1 unless defined $warnLevel;
9125     #$dieLevel = 1 unless defined $dieLevel;
9126     #$signalLevel = 1 unless defined $signalLevel;
9127
9128     # This is the flag that says "a debugger is running, please call
9129     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9130     # execute anything in the user's context, because we always want to
9131     # get control back.
9132     $db_stop = 0;          # Compiler warning ...
9133     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9134
9135     # This variable records how many levels we're nested in debugging. Used
9136     # Used in the debugger prompt, and in determining whether it's all over or
9137     # not.
9138     $level = 0;            # Level of recursive debugging
9139
9140     # "Triggers bug (?) in perl if we postpone this until runtime."
9141     # XXX No details on this yet, or whether we should fix the bug instead
9142     # of work around it. Stay tuned.
9143     @stack = (0);
9144
9145     # Used to track the current stack depth using the auto-stacked-variable
9146     # trick.
9147     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9148
9149     # Don't print return values on exiting a subroutine.
9150     $doret = -2;
9151
9152     # No extry/exit tracing.
9153     $frame = 0;
9154
9155 } ## end BEGIN
9156
9157 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9158
9159 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9160
9161 =head2 db_complete
9162
9163 C<readline> support - adds command completion to basic C<readline>.
9164
9165 Returns a list of possible completions to C<readline> when invoked. C<readline>
9166 will print the longest common substring following the text already entered.
9167
9168 If there is only a single possible completion, C<readline> will use it in full.
9169
9170 This code uses C<map> and C<grep> heavily to create lists of possible
9171 completion. Think LISP in this section.
9172
9173 =cut
9174
9175 sub db_complete {
9176
9177     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9178     # $text is the text to be completed.
9179     # $line is the incoming line typed by the user.
9180     # $start is the start of the text to be completed in the incoming line.
9181     my ( $text, $line, $start ) = @_;
9182
9183     # Save the initial text.
9184     # The search pattern is current package, ::, extract the next qualifier
9185     # Prefix and pack are set to undef.
9186     my ( $itext, $search, $prefix, $pack ) =
9187       ( $text, "^\Q${package}::\E([^:]+)\$" );
9188
9189 =head3 C<b postpone|compile>
9190
9191 =over 4
9192
9193 =item *
9194
9195 Find all the subroutines that might match in this package
9196
9197 =item *
9198
9199 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9200
9201 =item *
9202
9203 Include all the rest of the subs that are known
9204
9205 =item *
9206
9207 C<grep> out the ones that match the text we have so far
9208
9209 =item *
9210
9211 Return this as the list of possible completions
9212
9213 =back
9214
9215 =cut
9216
9217     return sort grep /^\Q$text/, ( keys %sub ),
9218       qw(postpone load compile),    # subroutines
9219       ( map { /$search/ ? ($1) : () } keys %sub )
9220       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9221
9222 =head3 C<b load>
9223
9224 Get all the possible files from C<@INC> as it currently stands and
9225 select the ones that match the text so far.
9226
9227 =cut
9228
9229     return sort grep /^\Q$text/, values %INC    # files
9230       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9231
9232 =head3  C<V> (list variable) and C<m> (list modules)
9233
9234 There are two entry points for these commands:
9235
9236 =head4 Unqualified package names
9237
9238 Get the top-level packages and grab everything that matches the text
9239 so far. For each match, recursively complete the partial packages to
9240 get all possible matching packages. Return this sorted list.
9241
9242 =cut
9243
9244     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9245       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9246       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9247
9248 =head4 Qualified package names
9249
9250 Take a partially-qualified package and find all subpackages for it
9251 by getting all the subpackages for the package so far, matching all
9252 the subpackages against the text, and discarding all of them which
9253 start with 'main::'. Return this list.
9254
9255 =cut
9256
9257     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9258       grep !/^main::/, grep /^\Q$text/,
9259       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9260       do { no strict 'refs'; keys %{ $prefix . '::' } }
9261       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9262       and $text =~ /^(.*[^:])::?(\w*)$/
9263       and $prefix = $1;
9264
9265 =head3 C<f> - switch files
9266
9267 Here, we want to get a fully-qualified filename for the C<f> command.
9268 Possibilities are:
9269
9270 =over 4
9271
9272 =item 1. The original source file itself
9273
9274 =item 2. A file from C<@INC>
9275
9276 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9277
9278 =back
9279
9280 =cut
9281
9282     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9283            # We might possibly want to switch to an eval (which has a "filename"
9284            # like '(eval 9)'), so we may need to clean up the completion text
9285            # before proceeding.
9286         $prefix = length($1) - length($text);
9287         $text   = $1;
9288
9289 =pod
9290
9291 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9292 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9293 out of C<%main::>, add the initial source file, and extract the ones that
9294 match the completion text so far.
9295
9296 =cut
9297
9298         return sort
9299           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9300           $0;
9301     } ## end if ($line =~ /^\|*f\s+(.*)/)
9302
9303 =head3 Subroutine name completion
9304
9305 We look through all of the defined subs (the keys of C<%sub>) and
9306 return both all the possible matches to the subroutine name plus
9307 all the matches qualified to the current package.
9308
9309 =cut
9310
9311     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9312         $text = substr $text, 1;
9313         $prefix = "&";
9314         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9315           (
9316             map { /$search/ ? ($1) : () }
9317               keys %sub
9318           );
9319     } ## end if ((substr $text, 0, ...
9320
9321 =head3  Scalar, array, and hash completion: partially qualified package
9322
9323 Much like the above, except we have to do a little more cleanup:
9324
9325 =cut
9326
9327     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9328
9329 =pod
9330
9331 =over 4
9332
9333 =item *
9334
9335 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9336
9337 =cut
9338
9339         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9340
9341 =pod
9342
9343 =item *
9344
9345 Figure out the prefix vs. what needs completing.
9346
9347 =cut
9348
9349         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9350         $text   = $2;
9351
9352 =pod
9353
9354 =item *
9355
9356 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9357
9358 =cut
9359
9360         my @out = do {
9361             no strict 'refs';
9362             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9363             keys %$pack;
9364         };
9365
9366 =pod
9367
9368 =item *
9369
9370 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9371
9372 =cut
9373
9374         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9375             return db_complete( $out[0], $line, $start );
9376         }
9377
9378         # Return the list of possibles.
9379         return sort @out;
9380
9381     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9382
9383 =pod
9384
9385 =back
9386
9387 =head3 Symbol completion: current package or package C<main>.
9388
9389 =cut
9390
9391     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9392 =pod
9393
9394 =over 4
9395
9396 =item *
9397
9398 If it's C<main>, delete main to just get C<::> leading.
9399
9400 =cut
9401
9402         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9403
9404 =pod
9405
9406 =item *
9407
9408 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9409
9410 =cut
9411
9412         $prefix = substr $text, 0, 1;
9413         $text   = substr $text, 1;
9414
9415         my @out;
9416
9417 =pod
9418
9419 =item *
9420
9421 We look for the lexical scope above DB::DB and auto-complete lexical variables
9422 if PadWalker could be loaded.
9423
9424 =cut
9425
9426         if (not $text =~ /::/ and eval { require PadWalker } ) {
9427             my $level = 1;
9428             while (1) {
9429                 my @info = caller($level);
9430                 $level++;
9431                 $level = -1, last
9432                   if not @info;
9433                 last if $info[3] eq 'DB::DB';
9434             }
9435             if ($level > 0) {
9436                 my $lexicals = PadWalker::peek_my($level);
9437                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9438             }
9439         }
9440
9441 =pod
9442
9443 =item *
9444
9445 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9446
9447 =cut
9448
9449         push @out, map "$prefix$_", grep /^\Q$text/,
9450           ( grep /^_?[a-zA-Z]/, do { no strict 'refs'; keys %$pack } ),
9451           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9452
9453 =item *
9454
9455 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9456
9457 =back
9458
9459 =cut
9460
9461         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9462             return db_complete( $out[0], $line, $start );
9463         }
9464
9465         # Return the list of possibles.
9466         return sort @out;
9467     } ## end if ($text =~ /^[\$@%]/)
9468
9469 =head3 Options
9470
9471 We use C<option_val()> to look up the current value of the option. If there's
9472 only a single value, we complete the command in such a way that it is a
9473 complete command for setting the option in question. If there are multiple
9474 possible values, we generate a command consisting of the option plus a trailing
9475 question mark, which, if executed, will list the current value of the option.
9476
9477 =cut
9478
9479     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9480     {    # Options after space
9481            # We look for the text to be matched in the list of possible options,
9482            # and fetch the current value.
9483         my @out = grep /^\Q$text/, @options;
9484         my $val = option_val( $out[0], undef );
9485
9486         # Set up a 'query option's value' command.
9487         my $out = '? ';
9488         if ( not defined $val or $val =~ /[\n\r]/ ) {
9489
9490             # There's really nothing else we can do.
9491         }
9492
9493         # We have a value. Create a proper option-setting command.
9494         elsif ( $val =~ /\s/ ) {
9495
9496             # XXX This may be an extraneous variable.
9497             my $found;
9498
9499             # We'll want to quote the string (because of the embedded
9500             # whtespace), but we want to make sure we don't end up with
9501             # mismatched quote characters. We try several possibilities.
9502             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9503
9504                 # If we didn't find this quote character in the value,
9505                 # quote it using this quote character.
9506                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9507             }
9508         } ## end elsif ($val =~ /\s/)
9509
9510         # Don't need any quotes.
9511         else {
9512             $out = "=$val ";
9513         }
9514
9515         # If there were multiple possible values, return '? ', which
9516         # makes the command into a query command. If there was just one,
9517         # have readline append that.
9518         $rl_attribs->{completer_terminator_character} =
9519           ( @out == 1 ? $out : '? ' );
9520
9521         # Return list of possibilities.
9522         return sort @out;
9523     } ## end if ((substr $line, 0, ...
9524
9525 =head3 Filename completion
9526
9527 For entering filenames. We simply call C<readline>'s C<filename_list()>
9528 method with the completion text to get the possible completions.
9529
9530 =cut
9531
9532     return $term->filename_list($text);    # filenames
9533
9534 } ## end sub db_complete
9535
9536 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9537
9538 Functions that possibly ought to be somewhere else.
9539
9540 =head2 end_report
9541
9542 Say we're done.
9543
9544 =cut
9545
9546 sub end_report {
9547     local $\ = '';
9548     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9549 }
9550
9551 =head2 clean_ENV
9552
9553 If we have $ini_pids, save it in the environment; else remove it from the
9554 environment. Used by the C<R> (restart) command.
9555
9556 =cut
9557
9558 sub clean_ENV {
9559     if ( defined($ini_pids) ) {
9560         $ENV{PERLDB_PIDS} = $ini_pids;
9561     }
9562     else {
9563         delete( $ENV{PERLDB_PIDS} );
9564     }
9565 } ## end sub clean_ENV
9566
9567 # PERLDBf_... flag names from perl.h
9568 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9569
9570 BEGIN {
9571     %DollarCaretP_flags = (
9572         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9573         PERLDBf_LINE      => 0x02,     # Keep line #
9574         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9575         PERLDBf_INTER     => 0x08,     # Preserve more data
9576         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9577         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9578         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9579         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9580         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9581         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9582         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9583         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9584     );
9585     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9586     # doesn't need to set it. It's provided for the benefit of profilers and
9587     # other code analysers.
9588
9589     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9590 }
9591
9592 sub parse_DollarCaretP_flags {
9593     my $flags = shift;
9594     $flags =~ s/^\s+//;
9595     $flags =~ s/\s+$//;
9596     my $acu = 0;
9597     foreach my $f ( split /\s*\|\s*/, $flags ) {
9598         my $value;
9599         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9600             $value = hex $1;
9601         }
9602         elsif ( $f =~ /^(\d+)$/ ) {
9603             $value = int $1;
9604         }
9605         elsif ( $f =~ /^DEFAULT$/i ) {
9606             $value = $DollarCaretP_flags{PERLDB_ALL};
9607         }
9608         else {
9609             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9610             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9611             unless ( defined $value ) {
9612                 print $OUT (
9613                     "Unrecognized \$^P flag '$f'!\n",
9614                     "Acceptable flags are: "
9615                       . join( ', ', sort keys %DollarCaretP_flags ),
9616                     ", and hexadecimal and decimal numbers.\n"
9617                 );
9618                 return undef;
9619             }
9620         }
9621         $acu |= $value;
9622     }
9623     $acu;
9624 }
9625
9626 sub expand_DollarCaretP_flags {
9627     my $DollarCaretP = shift;
9628     my @bits         = (
9629         map {
9630             my $n = ( 1 << $_ );
9631             ( $DollarCaretP & $n )
9632               ? ( $DollarCaretP_flags_r{$n}
9633                   || sprintf( '0x%x', $n ) )
9634               : ()
9635           } 0 .. 31
9636     );
9637     return @bits ? join( '|', @bits ) : 0;
9638 }
9639
9640 =over 4
9641
9642 =item rerun
9643
9644 Rerun the current session to:
9645
9646     rerun        current position
9647
9648     rerun 4      command number 4
9649
9650     rerun -4     current command minus 4 (go back 4 steps)
9651
9652 Whether this always makes sense, in the current context is unknowable, and is
9653 in part left as a useful exercise for the reader.  This sub returns the
9654 appropriate arguments to rerun the current session.
9655
9656 =cut
9657
9658 sub rerun {
9659     my $i = shift;
9660     my @args;
9661     pop(@truehist);                      # strim
9662     unless (defined $truehist[$i]) {
9663         print "Unable to return to non-existent command: $i\n";
9664     } else {
9665         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9666         my @temp = @truehist;            # store
9667         push(@DB::typeahead, @truehist); # saved
9668         @truehist = @hist = ();          # flush
9669         @args = restart();              # setup
9670         get_list("PERLDB_HIST");        # clean
9671         set_list("PERLDB_HIST", @temp); # reset
9672     }
9673     return @args;
9674 }
9675
9676 =item restart
9677
9678 Restarting the debugger is a complex operation that occurs in several phases.
9679 First, we try to reconstruct the command line that was used to invoke Perl
9680 and the debugger.
9681
9682 =cut
9683
9684 sub restart {
9685     # I may not be able to resurrect you, but here goes ...
9686     print $OUT
9687 "Warning: some settings and command-line options may be lost!\n";
9688     my ( @script, @flags, $cl );
9689
9690     # If warn was on before, turn it on again.
9691     push @flags, '-w' if $ini_warn;
9692
9693     # Rebuild the -I flags that were on the initial
9694     # command line.
9695     for (@ini_INC) {
9696         push @flags, '-I', $_;
9697     }
9698
9699     # Turn on taint if it was on before.
9700     push @flags, '-T' if ${^TAINT};
9701
9702     # Arrange for setting the old INC:
9703     # Save the current @init_INC in the environment.
9704     set_list( "PERLDB_INC", @ini_INC );
9705
9706     # If this was a perl one-liner, go to the "file"
9707     # corresponding to the one-liner read all the lines
9708     # out of it (except for the first one, which is going
9709     # to be added back on again when 'perl -d' runs: that's
9710     # the 'require perl5db.pl;' line), and add them back on
9711     # to the command line to be executed.
9712     if ( $0 eq '-e' ) {
9713         my $lines = *{$main::{'_<-e'}}{ARRAY};
9714         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9715             chomp( $cl = $lines->[$_] );
9716             push @script, '-e', $cl;
9717         }
9718     } ## end if ($0 eq '-e')
9719
9720     # Otherwise we just reuse the original name we had
9721     # before.
9722     else {
9723         @script = $0;
9724     }
9725
9726 =pod
9727
9728 After the command line  has been reconstructed, the next step is to save
9729 the debugger's status in environment variables. The C<DB::set_list> routine
9730 is used to save aggregate variables (both hashes and arrays); scalars are
9731 just popped into environment variables directly.
9732
9733 =cut
9734
9735     # If the terminal supported history, grab it and
9736     # save that in the environment.
9737     set_list( "PERLDB_HIST",
9738           $term->Features->{getHistory}
9739         ? $term->GetHistory
9740         : @hist );
9741
9742     # Find all the files that were visited during this
9743     # session (i.e., the debugger had magic hashes
9744     # corresponding to them) and stick them in the environment.
9745     my @had_breakpoints = keys %had_breakpoints;
9746     set_list( "PERLDB_VISITED", @had_breakpoints );
9747
9748     # Save the debugger options we chose.
9749     set_list( "PERLDB_OPT", %option );
9750     # set_list( "PERLDB_OPT", options2remember() );
9751
9752     # Save the break-on-loads.
9753     set_list( "PERLDB_ON_LOAD", %break_on_load );
9754
9755 =pod
9756
9757 The most complex part of this is the saving of all of the breakpoints. They
9758 can live in an awful lot of places, and we have to go through all of them,
9759 find the breakpoints, and then save them in the appropriate environment
9760 variable via C<DB::set_list>.
9761
9762 =cut
9763
9764     # Go through all the breakpoints and make sure they're
9765     # still valid.
9766     my @hard;
9767     for ( 0 .. $#had_breakpoints ) {
9768
9769         # We were in this file.
9770         my $file = $had_breakpoints[$_];
9771
9772         # Grab that file's magic line hash.
9773         *dbline = $main::{ '_<' . $file };
9774
9775         # Skip out if it doesn't exist, or if the breakpoint
9776         # is in a postponed file (we'll do postponed ones
9777         # later).
9778         next unless %dbline or $postponed_file{$file};
9779
9780         # In an eval. This is a little harder, so we'll
9781         # do more processing on that below.
9782         ( push @hard, $file ), next
9783           if $file =~ /^\(\w*eval/;
9784
9785         # XXX I have no idea what this is doing. Yet.
9786         my @add;
9787         @add = %{ $postponed_file{$file} }
9788           if $postponed_file{$file};
9789
9790         # Save the list of all the breakpoints for this file.
9791         set_list( "PERLDB_FILE_$_", %dbline, @add );
9792
9793         # Serialize the extra data %breakpoints_data hash.
9794         # That's a bug fix.
9795         set_list( "PERLDB_FILE_ENABLED_$_",
9796             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9797             sort { $a <=> $b } keys(%dbline)
9798         )
9799     } ## end for (0 .. $#had_breakpoints)
9800
9801     # The breakpoint was inside an eval. This is a little
9802     # more difficult. XXX and I don't understand it.
9803     foreach my $hard_file (@hard) {
9804         # Get over to the eval in question.
9805         *dbline = $main::{ '_<' . $hard_file };
9806         my $quoted = quotemeta $hard_file;
9807         my %subs;
9808         for my $sub ( keys %sub ) {
9809             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9810                 $subs{$sub} = [ $n1, $n2 ];
9811             }
9812         }
9813         unless (%subs) {
9814             print {$OUT}
9815             "No subroutines in $hard_file, ignoring breakpoints.\n";
9816             next;
9817         }
9818         LINES: foreach my $line ( keys %dbline ) {
9819
9820             # One breakpoint per sub only:
9821             my ( $offset, $found );
9822             SUBS: foreach my $sub ( keys %subs ) {
9823                 if (
9824                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9825                     and (
9826                         not defined $offset    # Not caught
9827                             or $offset < 0
9828                     )
9829                 )
9830                 {                              # or badly caught
9831                     $found  = $sub;
9832                     $offset = $line - $subs{$sub}->[0];
9833                     if ($offset >= 0) {
9834                         $offset = "+$offset";
9835                         last SUBS;
9836                     }
9837                 } ## end if ($subs{$sub}->[1] >=...
9838             } ## end for $sub (keys %subs)
9839             if ( defined $offset ) {
9840                 $postponed{$found} =
9841                 "break $offset if $dbline{$line}";
9842             }
9843             else {
9844                 print {$OUT}
9845                 ("Breakpoint in ${hard_file}:$line ignored:"
9846                 . " after all the subroutines.\n");
9847             }
9848         } ## end for $line (keys %dbline)
9849     } ## end for (@hard)
9850
9851     # Save the other things that don't need to be
9852     # processed.
9853     set_list( "PERLDB_POSTPONE",  %postponed );
9854     set_list( "PERLDB_PRETYPE",   @$pretype );
9855     set_list( "PERLDB_PRE",       @$pre );
9856     set_list( "PERLDB_POST",      @$post );
9857     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9858
9859     # We are officially restarting.
9860     $ENV{PERLDB_RESTART} = 1;
9861
9862     # We are junking all child debuggers.
9863     delete $ENV{PERLDB_PIDS};    # Restore ini state
9864
9865     # Set this back to the initial pid.
9866     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9867
9868 =pod
9869
9870 After all the debugger status has been saved, we take the command we built up
9871 and then return it, so we can C<exec()> it. The debugger will spot the
9872 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9873 from the environment.
9874
9875 =cut
9876
9877     # And run Perl again. Add the "-d" flag, all the
9878     # flags we built up, the script (whether a one-liner
9879     # or a file), add on the -emacs flag for a slave editor,
9880     # and then the old arguments.
9881
9882     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9883
9884 };  # end restart
9885
9886 =back
9887
9888 =head1 END PROCESSING - THE C<END> BLOCK
9889
9890 Come here at the very end of processing. We want to go into a
9891 loop where we allow the user to enter commands and interact with the
9892 debugger, but we don't want anything else to execute.
9893
9894 First we set the C<$finished> variable, so that some commands that
9895 shouldn't be run after the end of program quit working.
9896
9897 We then figure out whether we're truly done (as in the user entered a C<q>
9898 command, or we finished execution while running nonstop). If we aren't,
9899 we set C<$single> to 1 (causing the debugger to get control again).
9900
9901 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9902 message and returns control to the debugger. Repeat.
9903
9904 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9905 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9906 break, run to completion.).
9907
9908 =cut
9909
9910 END {
9911     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9912     $fall_off_end = 1 unless $inhibit_exit;
9913
9914     # Do not stop in at_exit() and destructors on exit:
9915     if ($fall_off_end or $runnonstop) {
9916         save_hist();
9917     } else {
9918         $DB::single = 1;
9919         DB::fake::at_exit();
9920     }
9921 } ## end END
9922
9923 =head1 PRE-5.8 COMMANDS
9924
9925 Some of the commands changed function quite a bit in the 5.8 command
9926 realignment, so much so that the old code had to be replaced completely.
9927 Because we wanted to retain the option of being able to go back to the
9928 former command set, we moved the old code off to this section.
9929
9930 There's an awful lot of duplicated code here. We've duplicated the
9931 comments to keep things clear.
9932
9933 =head2 Null command
9934
9935 Does nothing. Used to I<turn off> commands.
9936
9937 =cut
9938
9939 sub cmd_pre580_null {
9940
9941     # do nothing...
9942 }
9943
9944 =head2 Old C<a> command.
9945
9946 This version added actions if you supplied them, and deleted them
9947 if you didn't.
9948
9949 =cut
9950
9951 sub cmd_pre580_a {
9952     my $xcmd = shift;
9953     my $cmd  = shift;
9954
9955     # Argument supplied. Add the action.
9956     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9957
9958         # If the line isn't there, use the current line.
9959         my $i = $1 || $line;
9960         my $j = $2;
9961
9962         # If there is an action ...
9963         if ( length $j ) {
9964
9965             # ... but the line isn't breakable, skip it.
9966             if ( $dbline[$i] == 0 ) {
9967                 print $OUT "Line $i may not have an action.\n";
9968             }
9969             else {
9970
9971                 # ... and the line is breakable:
9972                 # Mark that there's an action in this file.
9973                 $had_breakpoints{$filename} |= 2;
9974
9975                 # Delete any current action.
9976                 $dbline{$i} =~ s/\0[^\0]*//;
9977
9978                 # Add the new action, continuing the line as needed.
9979                 $dbline{$i} .= "\0" . action($j);
9980             }
9981         } ## end if (length $j)
9982
9983         # No action supplied.
9984         else {
9985
9986             # Delete the action.
9987             $dbline{$i} =~ s/\0[^\0]*//;
9988
9989             # Mark as having no break or action if nothing's left.
9990             delete $dbline{$i} if $dbline{$i} eq '';
9991         }
9992     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9993 } ## end sub cmd_pre580_a
9994
9995 =head2 Old C<b> command
9996
9997 Add breakpoints.
9998
9999 =cut
10000
10001 sub cmd_pre580_b {
10002     my $xcmd   = shift;
10003     my $cmd    = shift;
10004     my $dbline = shift;
10005
10006     # Break on load.
10007     if ( $cmd =~ /^load\b\s*(.*)/ ) {
10008         my $file = $1;
10009         $file =~ s/\s+$//;
10010         cmd_b_load($file);
10011     }
10012
10013     # b compile|postpone <some sub> [<condition>]
10014     # The interpreter actually traps this one for us; we just put the
10015     # necessary condition in the %postponed hash.
10016     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
10017
10018         # Capture the condition if there is one. Make it true if none.
10019         my $cond = length $3 ? $3 : '1';
10020
10021         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
10022         # if it was 'compile'.
10023         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
10024
10025         # De-Perl4-ify the name - ' separators to ::.
10026         $subname =~ s/\'/::/g;
10027
10028         # Qualify it into the current package unless it's already qualified.
10029         $subname = "${package}::" . $subname
10030           unless $subname =~ /::/;
10031
10032         # Add main if it starts with ::.
10033         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
10034
10035         # Save the break type for this sub.
10036         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
10037     } ## end elsif ($cmd =~ ...
10038
10039     # b <sub name> [<condition>]
10040     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
10041         my $subname = $1;
10042         my $cond = length $2 ? $2 : '1';
10043         cmd_b_sub( $subname, $cond );
10044     }
10045     # b <line> [<condition>].
10046     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
10047         my $i = $1 || $dbline;
10048         my $cond = length $2 ? $2 : '1';
10049         cmd_b_line( $i, $cond );
10050     }
10051 } ## end sub cmd_pre580_b
10052
10053 =head2 Old C<D> command.
10054
10055 Delete all breakpoints unconditionally.
10056
10057 =cut
10058
10059 sub cmd_pre580_D {
10060     my $xcmd = shift;
10061     my $cmd  = shift;
10062     if ( $cmd =~ /^\s*$/ ) {
10063         print $OUT "Deleting all breakpoints...\n";
10064
10065         # %had_breakpoints lists every file that had at least one
10066         # breakpoint in it.
10067         my $file;
10068         for $file ( keys %had_breakpoints ) {
10069
10070             # Switch to the desired file temporarily.
10071             local *dbline = $main::{ '_<' . $file };
10072
10073             $max = $#dbline;
10074             my $was;
10075
10076             # For all lines in this file ...
10077             for my $i (1 .. $max) {
10078
10079                 # If there's a breakpoint or action on this line ...
10080                 if ( defined $dbline{$i} ) {
10081
10082                     # ... remove the breakpoint.
10083                     $dbline{$i} =~ s/^[^\0]+//;
10084                     if ( $dbline{$i} =~ s/^\0?$// ) {
10085
10086                         # Remove the entry altogether if no action is there.
10087                         delete $dbline{$i};
10088                     }
10089                 } ## end if (defined $dbline{$i...
10090             } ## end for my $i (1 .. $max)
10091
10092             # If, after we turn off the "there were breakpoints in this file"
10093             # bit, the entry in %had_breakpoints for this file is zero,
10094             # we should remove this file from the hash.
10095             if ( not $had_breakpoints{$file} &= ~1 ) {
10096                 delete $had_breakpoints{$file};
10097             }
10098         } ## end for $file (keys %had_breakpoints)
10099
10100         # Kill off all the other breakpoints that are waiting for files that
10101         # haven't been loaded yet.
10102         undef %postponed;
10103         undef %postponed_file;
10104         undef %break_on_load;
10105     } ## end if ($cmd =~ /^\s*$/)
10106 } ## end sub cmd_pre580_D
10107
10108 =head2 Old C<h> command
10109
10110 Print help. Defaults to printing the long-form help; the 5.8 version
10111 prints the summary by default.
10112
10113 =cut
10114
10115 sub cmd_pre580_h {
10116     my $xcmd = shift;
10117     my $cmd  = shift;
10118
10119     # Print the *right* help, long format.
10120     if ( $cmd =~ /^\s*$/ ) {
10121         print_help($pre580_help);
10122     }
10123
10124     # 'h h' - explicitly-requested summary.
10125     elsif ( $cmd =~ /^h\s*/ ) {
10126         print_help($pre580_summary);
10127     }
10128
10129     # Find and print a command's help.
10130     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10131         my $asked  = $1;                   # for proper errmsg
10132         my $qasked = quotemeta($asked);    # for searching
10133                                            # XXX: finds CR but not <CR>
10134         if (
10135             $pre580_help =~ /^
10136                               <?           # Optional '<'
10137                               (?:[IB]<)    # Optional markup
10138                               $qasked      # The command name
10139                             /mx
10140           )
10141         {
10142
10143             while (
10144                 $pre580_help =~ /^
10145                                   (             # The command help:
10146                                    <?           # Optional '<'
10147                                    (?:[IB]<)    # Optional markup
10148                                    $qasked      # The command name
10149                                    ([\s\S]*?)   # Lines starting with tabs
10150                                    \n           # Final newline
10151                                   )
10152                                   (?!\s)/mgx
10153               )    # Line not starting with space
10154                    # (Next command's help)
10155             {
10156                 print_help($1);
10157             }
10158         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10159
10160         # Help not found.
10161         else {
10162             print_help("B<$asked> is not a debugger command.\n");
10163         }
10164     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10165 } ## end sub cmd_pre580_h
10166
10167 =head2 Old C<W> command
10168
10169 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10170
10171 =cut
10172
10173 sub cmd_pre580_W {
10174     my $xcmd = shift;
10175     my $cmd  = shift;
10176
10177     # Delete all watch expressions.
10178     if ( $cmd =~ /^$/ ) {
10179
10180         # No watching is going on.
10181         $trace &= ~2;
10182
10183         # Kill all the watch expressions and values.
10184         @to_watch = @old_watch = ();
10185     }
10186
10187     # Add a watch expression.
10188     elsif ( $cmd =~ /^(.*)/s ) {
10189
10190         # add it to the list to be watched.
10191         push @to_watch, $1;
10192
10193         # Get the current value of the expression.
10194         # Doesn't handle expressions returning list values!
10195         $evalarg = $1;
10196         # The &-call is here to ascertain the mutability of @_.
10197         my ($val) = &DB::eval;
10198         $val = ( defined $val ) ? "'$val'" : 'undef';
10199
10200         # Save it.
10201         push @old_watch, $val;
10202
10203         # We're watching stuff.
10204         $trace |= 2;
10205
10206     } ## end elsif ($cmd =~ /^(.*)/s)
10207 } ## end sub cmd_pre580_W
10208
10209 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10210
10211 The debugger used to have a bunch of nearly-identical code to handle
10212 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10213 C<cmd_prepost> unify all this into one set of code to handle the
10214 appropriate actions.
10215
10216 =head2 C<cmd_pre590_prepost>
10217
10218 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10219 do something destructive. In pre 5.8 debuggers, the default action was to
10220 delete all the actions.
10221
10222 =cut
10223
10224 sub cmd_pre590_prepost {
10225     my $cmd    = shift;
10226     my $line   = shift || '*';
10227     my $dbline = shift;
10228
10229     return cmd_prepost( $cmd, $line, $dbline );
10230 } ## end sub cmd_pre590_prepost
10231
10232 =head2 C<cmd_prepost>
10233
10234 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10235 Since the lists of actions are all held in arrays that are pointed to by
10236 references anyway, all we have to do is pick the right array reference and
10237 then use generic code to all, delete, or list actions.
10238
10239 =cut
10240
10241 sub cmd_prepost {
10242     my $cmd = shift;
10243
10244     # No action supplied defaults to 'list'.
10245     my $line = shift || '?';
10246
10247     # Figure out what to put in the prompt.
10248     my $which = '';
10249
10250     # Make sure we have some array or another to address later.
10251     # This means that if for some reason the tests fail, we won't be
10252     # trying to stash actions or delete them from the wrong place.
10253     my $aref = [];
10254
10255     # < - Perl code to run before prompt.
10256     if ( $cmd =~ /^\</o ) {
10257         $which = 'pre-perl';
10258         $aref  = $pre;
10259     }
10260
10261     # > - Perl code to run after prompt.
10262     elsif ( $cmd =~ /^\>/o ) {
10263         $which = 'post-perl';
10264         $aref  = $post;
10265     }
10266
10267     # { - first check for properly-balanced braces.
10268     elsif ( $cmd =~ /^\{/o ) {
10269         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10270             print $OUT
10271 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10272         }
10273
10274         # Properly balanced. Pre-prompt debugger actions.
10275         else {
10276             $which = 'pre-debugger';
10277             $aref  = $pretype;
10278         }
10279     } ## end elsif ( $cmd =~ /^\{/o )
10280
10281     # Did we find something that makes sense?
10282     unless ($which) {
10283         print $OUT "Confused by command: $cmd\n";
10284     }
10285
10286     # Yes.
10287     else {
10288
10289         # List actions.
10290         if ( $line =~ /^\s*\?\s*$/o ) {
10291             unless (@$aref) {
10292
10293                 # Nothing there. Complain.
10294                 print $OUT "No $which actions.\n";
10295             }
10296             else {
10297
10298                 # List the actions in the selected list.
10299                 print $OUT "$which commands:\n";
10300                 foreach my $action (@$aref) {
10301                     print $OUT "\t$cmd -- $action\n";
10302                 }
10303             } ## end else
10304         } ## end if ( $line =~ /^\s*\?\s*$/o)
10305
10306         # Might be a delete.
10307         else {
10308             if ( length($cmd) == 1 ) {
10309                 if ( $line =~ /^\s*\*\s*$/o ) {
10310
10311                     # It's a delete. Get rid of the old actions in the
10312                     # selected list..
10313                     @$aref = ();
10314                     print $OUT "All $cmd actions cleared.\n";
10315                 }
10316                 else {
10317
10318                     # Replace all the actions. (This is a <, >, or {).
10319                     @$aref = action($line);
10320                 }
10321             } ## end if ( length($cmd) == 1)
10322             elsif ( length($cmd) == 2 ) {
10323
10324                 # Add the action to the line. (This is a <<, >>, or {{).
10325                 push @$aref, action($line);
10326             }
10327             else {
10328
10329                 # <<<, >>>>, {{{{{{ ... something not a command.
10330                 print $OUT
10331                   "Confused by strange length of $which command($cmd)...\n";
10332             }
10333         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10334     } ## end else
10335 } ## end sub cmd_prepost
10336
10337 =head1 C<DB::fake>
10338
10339 Contains the C<at_exit> routine that the debugger uses to issue the
10340 C<Debugged program terminated ...> message after the program completes. See
10341 the C<END> block documentation for more details.
10342
10343 =cut
10344
10345 package DB::fake;
10346
10347 sub at_exit {
10348     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10349 }
10350
10351 package DB;    # Do not trace this 1; below!
10352
10353 1;
10354
10355