regen/regcomp.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Regenerate (overwriting only if changed):
   4 #
   5 #    regnodes.h
   6 #
   7 # from information stored in
   8 #
   9 #    regcomp.sym
  10 #    regexp.h
  11 #
  12 # Accepts the standard regen_lib -q and -v args.
  13 #
  14 # This script is normally invoked from regen.pl.
  15
  16 BEGIN {
  17     # Get function prototypes
  18     require 'regen/regen_lib.pl';
  19 }
  20 use strict;
  21
  22 open DESC, 'regcomp.sym';
  23
  24 my $ind = 0;
  25 my (@name,@rest,@type,@code,@args,@flags,@longj);
  26 my ($desc,$lastregop);
  27 while (<DESC>) {
  28     s/#.*$//;
  29     next if /^\s*$/;
  30     chomp; # No \z in 5.004
  31     s/\s*$//;
  32     if (/^-+\s*$/) {
  33         $lastregop= $ind;
  34         next;
  35     }
  36     unless ($lastregop) {
  37         ($name[$ind], $desc, $rest[$ind]) = /^(\S+)\s+([^\t]+)\s*;\s*(.*)/;
  38         ($type[$ind], $code[$ind], $args[$ind], $flags[$ind], $longj[$ind])
  39           = split /[,\s]\s*/, $desc;
  40         ++$ind;
  41     } else {
  42         my ($type,@lists)=split /\s+/, $_;
  43         die "No list? $type" if !@lists;
  44         foreach my $list (@lists) {
  45             my ($names,$special)=split /:/, $list , 2;
  46             $special ||= "";
  47             foreach my $name (split /,/,$names) {
  48                 my $real= $name eq 'resume'
  49                         ? "resume_$type"
  50                         : "${type}_$name";
  51                 my @suffix;
  52                 if (!$special) {
  53                    @suffix=("");
  54                 } elsif ($special=~/\d/) {
  55                     @suffix=(1..$special);
  56                 } elsif ($special eq 'FAIL') {
  57                     @suffix=("","_fail");
  58                 } else {
  59                     die "unknown :type ':$special'";
  60                 }
  61                 foreach my $suffix (@suffix) {
  62                     $name[$ind]="$real$suffix";
  63                     $type[$ind]=$type;
  64                     $rest[$ind]="state for $type";
  65                     ++$ind;
  66                 }
  67             }
  68         }
  69
  70     }
  71 }
  72 # use fixed width to keep the diffs between regcomp.pl recompiles
  73 # as small as possible.
  74 my ($width,$rwidth,$twidth)=(22,12,9);
  75 $lastregop ||= $ind;
  76 my $tot = $ind;
  77 close DESC;
  78 die "Too many regexp/state opcodes! Maximum is 256, but there are $lastregop in file!"
  79     if $lastregop>256;
  80
  81 sub process_flags {
  82   my ($flag, $varname, $comment) = @_;
  83   $comment = '' unless defined $comment;
  84
  85   $ind = 0;
  86   my @selected;
  87   my $bitmap = '';
  88   do {
  89     my $set = $flags[$ind] && $flags[$ind] eq $flag ? 1 : 0;
  90     # Whilst I could do this with vec, I'd prefer to do longhand the arithmetic
  91     # ops in the C code.
  92     my $current = do {
  93       local $^W;
  94       ord do {
  95         substr $bitmap, ($ind >> 3);
  96       }
  97     };
  98     substr($bitmap, ($ind >> 3), 1) = chr($current | ($set << ($ind & 7)));
  99
 100     push @selected, $name[$ind] if $set;
 101   } while (++$ind < $lastregop);
 102   my $out_string = join ', ', @selected, 0;
 103   $out_string =~ s/(.{1,70},) /$1\n    /g;
 104
 105   my $out_mask = join ', ', map {sprintf "0x%02X", ord $_} split '', $bitmap;
 106
 107   return $comment . <<"EOP";
 108 #define REGNODE_\U$varname\E(node) (PL_${varname}_bitmask[(node) >> 3] & (1 << ((node) & 7)))
 109
 110 #ifndef DOINIT
 111 EXTCONST U8 PL_${varname}\[] __attribute__deprecated__;
 112 #else
 113 EXTCONST U8 PL_${varname}\[] __attribute__deprecated__ = {
 114     $out_string
 115 };
 116 #endif /* DOINIT */
 117
 118 #ifndef DOINIT
 119 EXTCONST U8 PL_${varname}_bitmask[];
 120 #else
 121 EXTCONST U8 PL_${varname}_bitmask[] = {
 122     $out_mask
 123 };
 124 #endif /* DOINIT */
 125 EOP
 126 }
 127
 128 my $out = safer_open('regnodes.h-new', 'regnodes.h');
 129
 130 print $out read_only_top(lang => 'C', by => 'regen/regcomp.pl',
 131                          from => 'regcomp.sym');
 132 printf $out <<EOP,
 133 /* Regops and State definitions */
 134
 135 #define %*s\t%d
 136 #define %*s\t%d
 137
 138 EOP
 139     -$width, REGNODE_MAX        => $lastregop - 1,
 140     -$width, REGMATCH_STATE_MAX => $tot - 1
 141 ;
 142
 143
 144 for ($ind=0; $ind < $lastregop ; ++$ind) {
 145   printf $out "#define\t%*s\t%d\t/* %#04x %s */\n",
 146     -$width, $name[$ind], $ind, $ind, $rest[$ind];
 147 }
 148 print $out "\t/* ------------ States ------------- */\n";
 149 for ( ; $ind < $tot ; $ind++) {
 150   printf $out "#define\t%*s\t(REGNODE_MAX + %d)\t/* %s */\n",
 151     -$width, $name[$ind], $ind - $lastregop + 1, $rest[$ind];
 152 }
 153
 154 print $out <<EOP;
 155
 156 /* PL_regkind[] What type of regop or state is this. */
 157
 158 #ifndef DOINIT
 159 EXTCONST U8 PL_regkind[];
 160 #else
 161 EXTCONST U8 PL_regkind[] = {
 162 EOP
 163
 164 $ind = 0;
 165 do {
 166   printf $out "\t%*s\t/* %*s */\n",
 167              -1-$twidth, "$type[$ind],", -$width, $name[$ind];
 168   print $out "\t/* ------------ States ------------- */\n"
 169     if $ind + 1 == $lastregop and $lastregop != $tot;
 170 } while (++$ind < $tot);
 171
 172 print $out <<EOP;
 173 };
 174 #endif
 175
 176 /* regarglen[] - How large is the argument part of the node (in regnodes) */
 177
 178 #ifdef REG_COMP_C
 179 static const U8 regarglen[] = {
 180 EOP
 181
 182 $ind = 0;
 183 do {
 184   my $size = 0;
 185   $size = "EXTRA_SIZE(struct regnode_$args[$ind])" if $args[$ind];
 186
 187   printf $out "\t%*s\t/* %*s */\n",
 188         -37, "$size,",-$rwidth,$name[$ind];
 189 } while (++$ind < $lastregop);
 190
 191 print $out <<EOP;
 192 };
 193
 194 /* reg_off_by_arg[] - Which argument holds the offset to the next node */
 195
 196 static const char reg_off_by_arg[] = {
 197 EOP
 198
 199 $ind = 0;
 200 do {
 201   my $size = $longj[$ind] || 0;
 202
 203   printf $out "\t%d,\t/* %*s */\n",
 204         $size, -$rwidth, $name[$ind]
 205 } while (++$ind < $lastregop);
 206
 207 print $out <<EOP;
 208 };
 209
 210 #endif /* REG_COMP_C */
 211
 212 /* reg_name[] - Opcode/state names in string form, for debugging */
 213
 214 #ifndef DOINIT
 215 EXTCONST char * PL_reg_name[];
 216 #else
 217 EXTCONST char * const PL_reg_name[] = {
 218 EOP
 219
 220 $ind = 0;
 221 my $ofs = 0;
 222 my $sym = "";
 223 do {
 224   my $size = $longj[$ind] || 0;
 225
 226   printf $out "\t%*s\t/* $sym%#04x */\n",
 227         -3-$width,qq("$name[$ind]",), $ind - $ofs;
 228   if ($ind + 1 == $lastregop and $lastregop != $tot) {
 229     print $out "\t/* ------------ States ------------- */\n";
 230     $ofs = $lastregop - 1;
 231     $sym = 'REGNODE_MAX +';
 232   }
 233
 234 } while (++$ind < $tot);
 235
 236 print $out <<EOP;
 237 };
 238 #endif /* DOINIT */
 239
 240 /* PL_reg_extflags_name[] - Opcode/state names in string form, for debugging */
 241
 242 #ifndef DOINIT
 243 EXTCONST char * PL_reg_extflags_name[];
 244 #else
 245 EXTCONST char * const PL_reg_extflags_name[] = {
 246 EOP
 247
 248 my %rxfv;
 249 my %definitions;    # Remember what the symbol definitions are
 250 my $val = 0;
 251 my %reverse;
 252 foreach my $file ("op_reg_common.h", "regexp.h") {
 253     open FH,"<$file" or die "Can't read $file: $!";
 254     while (<FH>) {
 255
 256         # optional leading '_'.  Return symbol in $1, and strip it from
 257         # rest of line
 258         if (s/ \#define \s+ ( _? RXf_ \w+ ) \s+ //xi) {
 259             chomp;
 260             my $define = $1;
 261             s: / \s* \* .*? \* \s* / : :x;    # Replace comments by a blank
 262
 263             # Replace any prior defined symbols by their values
 264             foreach my $key (keys %definitions) {
 265                 s/\b$key\b/$definitions{$key}/g;
 266             }
 267             my $newval = eval $_;   # Get numeric definition
 268
 269             $definitions{$define} = $newval;
 270
 271             next unless $_ =~ /<</; # Bit defines use left shift
 272             if($val & $newval) {
 273                 die sprintf "Both $define and $reverse{$newval} use %08X", $newval;
 274             }
 275             $val|=$newval;
 276             $rxfv{$define}= $newval;
 277             $reverse{$newval} = $define;
 278         }
 279     }
 280 }
 281 my %vrxf=reverse %rxfv;
 282 printf $out "\t/* Bits in extflags defined: %s */\n", unpack 'B*', pack 'N', $val;
 283 for (0..31) {
 284     my $power_of_2 = 2**$_;
 285     my $n=$vrxf{$power_of_2};
 286     if (! $n) {
 287
 288         # Here, there was no name that matched exactly the bit.  It could be
 289         # either that it is unused, or the name matches multiple bits.
 290         if (! ($val & $power_of_2)) {
 291             $n = "UNUSED_BIT_$_";
 292         }
 293         else {
 294
 295             # Here, must be because it matches multiple bits.  Look through
 296             # all possibilities until find one that matches this one.  Use
 297             # that name, and all the bits it matches
 298             foreach my $name (keys %rxfv) {
 299                 if ($rxfv{$name} & $power_of_2) {
 300                     $n = $name;
 301                     $power_of_2 = $rxfv{$name};
 302                     last;
 303                 }
 304             }
 305         }
 306     }
 307     $n=~s/^RXf_(PMf_)?//;
 308     printf $out qq(\t%-20s/* 0x%08x */\n),
 309         qq("$n",),$power_of_2;
 310 }
 311
 312 print $out <<EOP;
 313 };
 314 #endif /* DOINIT */
 315
 316 EOP
 317
 318 print $out process_flags('V', 'varies', <<'EOC');
 319 /* The following have no fixed length. U8 so we can do strchr() on it. */
 320 EOC
 321
 322 print $out process_flags('S', 'simple', <<'EOC');
 323
 324 /* The following always have a length of 1. U8 we can do strchr() on it. */
 325 /* (Note that length 1 means "one character" under UTF8, not "one octet".) */
 326 EOC
 327
 328 read_only_bottom_close_and_rename($out);