lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 use Cwd ();
 516
 517 my $_initial_cwd;
 518
 519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 520
 521 BEGIN {
 522     require feature;
 523     $^V =~ /^v(\d+\.\d+)/;
 524     feature->import(":$1");
 525     $_initial_cwd = Cwd::getcwd();
 526 }
 527
 528 # Debugger for Perl 5.00x; perl5db.pl patch level:
 529 use vars qw($VERSION $header);
 530
 531 # bump to X.XX in blead, only use X.XX_XX in maint
 532 $VERSION = '1.51';
 533
 534 $header = "perl5db.pl version $VERSION";
 535
 536 =head1 DEBUGGER ROUTINES
 537
 538 =head2 C<DB::eval()>
 539
 540 This function replaces straight C<eval()> inside the debugger; it simplifies
 541 the process of evaluating code in the user's context.
 542
 543 The code to be evaluated is passed via the package global variable
 544 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 545
 546 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 547 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 548 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 549 user's current package, grabbed when C<DB::DB> got control.  This causes the
 550 proper context to be used when the eval is actually done.  Afterward, we
 551 restore C<$trace>, C<$single>, and C<$^D>.
 552
 553 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 554 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 555 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 556 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 557 considered sane by the debugger. If there was an C<eval()> error, we print
 558 it on the debugger's output. If C<$onetimedump> is defined, we call
 559 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 560 'methods'. Setting it to something else causes the debugger to do the eval
 561 but not print the result - handy if you want to do something else with it
 562 (the "watch expressions" code does this to get the value of the watch
 563 expression but not show it unless it matters).
 564
 565 In any case, we then return the list of output from C<eval> to the caller,
 566 and unwinding restores the former version of C<$@> in C<@saved> as well
 567 (the localization of C<$saved[0]> goes away at the end of this scope).
 568
 569 =head3 Parameters and variables influencing execution of DB::eval()
 570
 571 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 572 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 573 The variables listed below influence C<DB::eval()>'s execution directly.
 574
 575 =over 4
 576
 577 =item C<$evalarg> - the thing to actually be eval'ed
 578
 579 =item C<$trace> - Current state of execution tracing
 580
 581 =item C<$single> - Current state of single-stepping
 582
 583 =item C<$onetimeDump> - what is to be displayed after the evaluation
 584
 585 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 586
 587 =back
 588
 589 The following variables are altered by C<DB::eval()> during its execution. They
 590 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 591
 592 =over 4
 593
 594 =item C<@res> - used to capture output from actual C<eval>.
 595
 596 =item C<$otrace> - saved value of C<$trace>.
 597
 598 =item C<$osingle> - saved value of C<$single>.
 599
 600 =item C<$od> - saved value of C<$^D>.
 601
 602 =item C<$saved[0]> - saved value of C<$@>.
 603
 604 =item $\ - for output of C<$@> if there is an evaluation error.
 605
 606 =back
 607
 608 =head3 The problem of lexicals
 609
 610 The context of C<DB::eval()> presents us with some problems. Obviously,
 611 we want to be 'sandboxed' away from the debugger's internals when we do
 612 the eval, but we need some way to control how punctuation variables and
 613 debugger globals are used.
 614
 615 We can't use local, because the code inside C<DB::eval> can see localized
 616 variables; and we can't use C<my> either for the same reason. The code
 617 in this routine compromises and uses C<my>.
 618
 619 After this routine is over, we don't have user code executing in the debugger's
 620 context, so we can use C<my> freely.
 621
 622 =cut
 623
 624 ############################################## Begin lexical danger zone
 625
 626 # 'my' variables used here could leak into (that is, be visible in)
 627 # the context that the code being evaluated is executing in. This means that
 628 # the code could modify the debugger's variables.
 629 #
 630 # Fiddling with the debugger's context could be Bad. We insulate things as
 631 # much as we can.
 632
 633 use vars qw(
 634     @args
 635     %break_on_load
 636     $CommandSet
 637     $CreateTTY
 638     $DBGR
 639     @dbline
 640     $dbline
 641     %dbline
 642     $dieLevel
 643     $filename
 644     $histfile
 645     $histsize
 646     $IN
 647     $inhibit_exit
 648     @ini_INC
 649     $ini_warn
 650     $maxtrace
 651     $od
 652     @options
 653     $osingle
 654     $otrace
 655     $pager
 656     $post
 657     %postponed
 658     $prc
 659     $pre
 660     $pretype
 661     $psh
 662     @RememberOnROptions
 663     $remoteport
 664     @res
 665     $rl
 666     @saved
 667     $signalLevel
 668     $sub
 669     $term
 670     $usercontext
 671     $warnLevel
 672 );
 673
 674 our (
 675     @cmdfhs,
 676     $evalarg,
 677     $frame,
 678     $hist,
 679     $ImmediateStop,
 680     $line,
 681     $onetimeDump,
 682     $onetimedumpDepth,
 683     %option,
 684     $OUT,
 685     $packname,
 686     $signal,
 687     $single,
 688     $start,
 689     %sub,
 690     $subname,
 691     $trace,
 692     $window,
 693 );
 694
 695 # Used to save @ARGV and extract any debugger-related flags.
 696 use vars qw(@ARGS);
 697
 698 # Used to prevent multiple entries to diesignal()
 699 # (if for instance diesignal() itself dies)
 700 use vars qw($panic);
 701
 702 # Used to prevent the debugger from running nonstop
 703 # after a restart
 704 our ($second_time);
 705
 706 sub _calc_usercontext {
 707     my ($package) = @_;
 708
 709     # Cancel strict completely for the evaluated code, so the code
 710     # the user evaluates won't be affected by it. (Shlomi Fish)
 711     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 712     . "package $package;";    # this won't let them modify, alas
 713 }
 714
 715 sub eval {
 716
 717     # 'my' would make it visible from user code
 718     #    but so does local! --tchrist
 719     # Remember: this localizes @DB::res, not @main::res.
 720     local @res;
 721     {
 722
 723         # Try to keep the user code from messing  with us. Save these so that
 724         # even if the eval'ed code changes them, we can put them back again.
 725         # Needed because the user could refer directly to the debugger's
 726         # package globals (and any 'my' variables in this containing scope)
 727         # inside the eval(), and we want to try to stay safe.
 728         local $otrace  = $trace;
 729         local $osingle = $single;
 730         local $od      = $^D;
 731
 732         # Untaint the incoming eval() argument.
 733         { ($evalarg) = $evalarg =~ /(.*)/s; }
 734
 735         # $usercontext built in DB::DB near the comment
 736         # "set up the context for DB::eval ..."
 737         # Evaluate and save any results.
 738         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 739
 740         # Restore those old values.
 741         $trace  = $otrace;
 742         $single = $osingle;
 743         $^D     = $od;
 744     }
 745
 746     # Save the current value of $@, and preserve it in the debugger's copy
 747     # of the saved precious globals.
 748     my $at = $@;
 749
 750     # Since we're only saving $@, we only have to localize the array element
 751     # that it will be stored in.
 752     local $saved[0];    # Preserve the old value of $@
 753     eval { &DB::save };
 754
 755     # Now see whether we need to report an error back to the user.
 756     if ($at) {
 757         local $\ = '';
 758         print $OUT $at;
 759     }
 760
 761     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 762     # are package globals.
 763     elsif ($onetimeDump) {
 764         if ( $onetimeDump eq 'dump' ) {
 765             local $option{dumpDepth} = $onetimedumpDepth
 766               if defined $onetimedumpDepth;
 767             dumpit( $OUT, \@res );
 768         }
 769         elsif ( $onetimeDump eq 'methods' ) {
 770             methods( $res[0] );
 771         }
 772     } ## end elsif ($onetimeDump)
 773     @res;
 774 } ## end sub eval
 775
 776 ############################################## End lexical danger zone
 777
 778 # After this point it is safe to introduce lexicals.
 779 # The code being debugged will be executing in its own context, and
 780 # can't see the inside of the debugger.
 781 #
 782 # However, one should not overdo it: leave as much control from outside as
 783 # possible. If you make something a lexical, it's not going to be addressable
 784 # from outside the debugger even if you know its name.
 785
 786 # This file is automatically included if you do perl -d.
 787 # It's probably not useful to include this yourself.
 788 #
 789 # Before venturing further into these twisty passages, it is
 790 # wise to read the perldebguts man page or risk the ire of dragons.
 791 #
 792 # (It should be noted that perldebguts will tell you a lot about
 793 # the underlying mechanics of how the debugger interfaces into the
 794 # Perl interpreter, but not a lot about the debugger itself. The new
 795 # comments in this code try to address this problem.)
 796
 797 # Note that no subroutine call is possible until &DB::sub is defined
 798 # (for subroutines defined outside of the package DB). In fact the same is
 799 # true if $deep is not defined.
 800
 801 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 802
 803 # modified Perl debugger, to be run from Emacs in perldb-mode
 804 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 805 # Johan Vromans -- upgrade to 4.0 pl 10
 806 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 807 ########################################################################
 808
 809 =head1 DEBUGGER INITIALIZATION
 810
 811 The debugger starts up in phases.
 812
 813 =head2 BASIC SETUP
 814
 815 First, it initializes the environment it wants to run in: turning off
 816 warnings during its own compilation, defining variables which it will need
 817 to avoid warnings later, setting itself up to not exit when the program
 818 terminates, and defaulting to printing return values for the C<r> command.
 819
 820 =cut
 821
 822 # Needed for the statement after exec():
 823 #
 824 # This BEGIN block is simply used to switch off warnings during debugger
 825 # compilation. Probably it would be better practice to fix the warnings,
 826 # but this is how it's done at the moment.
 827
 828 BEGIN {
 829     $ini_warn = $^W;
 830     $^W       = 0;
 831 }    # Switch compilation warnings off until another BEGIN.
 832
 833 local ($^W) = 0;    # Switch run-time warnings off during init.
 834
 835 =head2 THREADS SUPPORT
 836
 837 If we are running under a threaded Perl, we require threads and threads::shared
 838 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 839 threaded debugger control.  C<-dt> can also be used to set this.
 840
 841 Each new thread will be announced and the debugger prompt will always inform
 842 you of each new thread created.  It will also indicate the thread id in which
 843 we are currently running within the prompt like this:
 844
 845     [tid] DB<$i>
 846
 847 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 848 command prompt.  The prompt will show: C<[0]> when running under threads, but
 849 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 850
 851 While running under threads, when you set or delete a breakpoint (etc.), this
 852 will apply to all threads, not just the currently running one.  When you are
 853 in a currently executing thread, you will stay there until it completes.  With
 854 the current implementation it is not currently possible to hop from one thread
 855 to another.
 856
 857 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 858
 859 Note that threading support was built into the debugger as of Perl version
 860 C<5.8.6> and debugger version C<1.2.8>.
 861
 862 =cut
 863
 864 BEGIN {
 865     # ensure we can share our non-threaded variables or no-op
 866     if ($ENV{PERL5DB_THREADED}) {
 867         require threads;
 868         require threads::shared;
 869         import threads::shared qw(share);
 870         $DBGR;
 871         share(\$DBGR);
 872         lock($DBGR);
 873         print "Threads support enabled\n";
 874     } else {
 875         *lock = sub(*) {};
 876         *share = sub(\[$@%]) {};
 877     }
 878 }
 879
 880 # These variables control the execution of 'dumpvar.pl'.
 881 {
 882     package dumpvar;
 883     use vars qw(
 884     $hashDepth
 885     $arrayDepth
 886     $dumpDBFiles
 887     $dumpPackages
 888     $quoteHighBit
 889     $printUndef
 890     $globPrint
 891     $usageOnly
 892     );
 893 }
 894
 895 # used to control die() reporting in diesignal()
 896 {
 897     package Carp;
 898     use vars qw($CarpLevel);
 899 }
 900
 901 # without threads, $filename is not defined until DB::DB is called
 902 share($main::{'_<'.$filename}) if defined $filename;
 903
 904 # Command-line + PERLLIB:
 905 # Save the contents of @INC before they are modified elsewhere.
 906 @ini_INC = @INC;
 907
 908 # This was an attempt to clear out the previous values of various
 909 # trapped errors. Apparently it didn't help. XXX More info needed!
 910 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 911
 912 # We set these variables to safe values. We don't want to blindly turn
 913 # off warnings, because other packages may still want them.
 914 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 915                                    # (local $^W cannot help - other packages!).
 916
 917 # Default to not exiting when program finishes; print the return
 918 # value when the 'r' command is used to return from a subroutine.
 919 $inhibit_exit = $option{PrintRet} = 1;
 920
 921 use vars qw($trace_to_depth);
 922
 923 # Default to 1E9 so it won't be limited to a certain recursion depth.
 924 $trace_to_depth = 1E9;
 925
 926 =head1 OPTION PROCESSING
 927
 928 The debugger's options are actually spread out over the debugger itself and
 929 C<dumpvar.pl>; some of these are variables to be set, while others are
 930 subs to be called with a value. To try to make this a little easier to
 931 manage, the debugger uses a few data structures to define what options
 932 are legal and how they are to be processed.
 933
 934 First, the C<@options> array defines the I<names> of all the options that
 935 are to be accepted.
 936
 937 =cut
 938
 939 @options = qw(
 940   CommandSet   HistFile      HistSize
 941   hashDepth    arrayDepth    dumpDepth
 942   DumpDBFiles  DumpPackages  DumpReused
 943   compactDump  veryCompact   quote
 944   HighBit      undefPrint    globPrint
 945   PrintRet     UsageOnly     frame
 946   AutoTrace    TTY           noTTY
 947   ReadLine     NonStop       LineInfo
 948   maxTraceLen  recallCommand ShellBang
 949   pager        tkRunning     ornaments
 950   signalLevel  warnLevel     dieLevel
 951   inhibit_exit ImmediateStop bareStringify
 952   CreateTTY    RemotePort    windowSize
 953   DollarCaretP
 954 );
 955
 956 @RememberOnROptions = qw(DollarCaretP);
 957
 958 =pod
 959
 960 Second, C<optionVars> lists the variables that each option uses to save its
 961 state.
 962
 963 =cut
 964
 965 use vars qw(%optionVars);
 966
 967 %optionVars = (
 968     hashDepth     => \$dumpvar::hashDepth,
 969     arrayDepth    => \$dumpvar::arrayDepth,
 970     CommandSet    => \$CommandSet,
 971     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 972     DumpPackages  => \$dumpvar::dumpPackages,
 973     DumpReused    => \$dumpvar::dumpReused,
 974     HighBit       => \$dumpvar::quoteHighBit,
 975     undefPrint    => \$dumpvar::printUndef,
 976     globPrint     => \$dumpvar::globPrint,
 977     UsageOnly     => \$dumpvar::usageOnly,
 978     CreateTTY     => \$CreateTTY,
 979     bareStringify => \$dumpvar::bareStringify,
 980     frame         => \$frame,
 981     AutoTrace     => \$trace,
 982     inhibit_exit  => \$inhibit_exit,
 983     maxTraceLen   => \$maxtrace,
 984     ImmediateStop => \$ImmediateStop,
 985     RemotePort    => \$remoteport,
 986     windowSize    => \$window,
 987     HistFile      => \$histfile,
 988     HistSize      => \$histsize,
 989 );
 990
 991 =pod
 992
 993 Third, C<%optionAction> defines the subroutine to be called to process each
 994 option.
 995
 996 =cut
 997
 998 use vars qw(%optionAction);
 999
1000 %optionAction = (
1001     compactDump   => \&dumpvar::compactDump,
1002     veryCompact   => \&dumpvar::veryCompact,
1003     quote         => \&dumpvar::quote,
1004     TTY           => \&TTY,
1005     noTTY         => \&noTTY,
1006     ReadLine      => \&ReadLine,
1007     NonStop       => \&NonStop,
1008     LineInfo      => \&LineInfo,
1009     recallCommand => \&recallCommand,
1010     ShellBang     => \&shellBang,
1011     pager         => \&pager,
1012     signalLevel   => \&signalLevel,
1013     warnLevel     => \&warnLevel,
1014     dieLevel      => \&dieLevel,
1015     tkRunning     => \&tkRunning,
1016     ornaments     => \&ornaments,
1017     RemotePort    => \&RemotePort,
1018     DollarCaretP  => \&DollarCaretP,
1019 );
1020
1021 =pod
1022
1023 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1024 option is used.
1025
1026 =cut
1027
1028 # Note that this list is not complete: several options not listed here
1029 # actually require that dumpvar.pl be loaded for them to work, but are
1030 # not in the table. A subsequent patch will correct this problem; for
1031 # the moment, we're just recommenting, and we are NOT going to change
1032 # function.
1033 use vars qw(%optionRequire);
1034
1035 %optionRequire = (
1036     compactDump => 'dumpvar.pl',
1037     veryCompact => 'dumpvar.pl',
1038     quote       => 'dumpvar.pl',
1039 );
1040
1041 =pod
1042
1043 There are a number of initialization-related variables which can be set
1044 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1045 variable. These are:
1046
1047 =over 4
1048
1049 =item C<$rl> - readline control XXX needs more explanation
1050
1051 =item C<$warnLevel> - whether or not debugger takes over warning handling
1052
1053 =item C<$dieLevel> - whether or not debugger takes over die handling
1054
1055 =item C<$signalLevel> - whether or not debugger takes over signal handling
1056
1057 =item C<$pre> - preprompt actions (array reference)
1058
1059 =item C<$post> - postprompt actions (array reference)
1060
1061 =item C<$pretype>
1062
1063 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1064
1065 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1066
1067 =back
1068
1069 =cut
1070
1071 # These guys may be defined in $ENV{PERL5DB} :
1072 $rl          = 1     unless defined $rl;
1073 $warnLevel   = 1     unless defined $warnLevel;
1074 $dieLevel    = 1     unless defined $dieLevel;
1075 $signalLevel = 1     unless defined $signalLevel;
1076 $pre         = []    unless defined $pre;
1077 $post        = []    unless defined $post;
1078 $pretype     = []    unless defined $pretype;
1079 $CreateTTY   = 3     unless defined $CreateTTY;
1080 $CommandSet  = '580' unless defined $CommandSet;
1081
1082 share($rl);
1083 share($warnLevel);
1084 share($dieLevel);
1085 share($signalLevel);
1086 share($pre);
1087 share($post);
1088 share($pretype);
1089 share($rl);
1090 share($CreateTTY);
1091 share($CommandSet);
1092
1093 =pod
1094
1095 The default C<die>, C<warn>, and C<signal> handlers are set up.
1096
1097 =cut
1098
1099 warnLevel($warnLevel);
1100 dieLevel($dieLevel);
1101 signalLevel($signalLevel);
1102
1103 =pod
1104
1105 The pager to be used is needed next. We try to get it from the
1106 environment first.  If it's not defined there, we try to find it in
1107 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1108 then call the C<pager()> function to save the pager name.
1109
1110 =cut
1111
1112 # This routine makes sure $pager is set up so that '|' can use it.
1113 pager(
1114
1115     # If PAGER is defined in the environment, use it.
1116     defined $ENV{PAGER}
1117     ? $ENV{PAGER}
1118
1119       # If not, see if Config.pm defines it.
1120     : eval { require Config }
1121       && defined $Config::Config{pager}
1122     ? $Config::Config{pager}
1123
1124       # If not, fall back to 'more'.
1125     : 'more'
1126   )
1127   unless defined $pager;
1128
1129 =pod
1130
1131 We set up the command to be used to access the man pages, the command
1132 recall character (C<!> unless otherwise defined) and the shell escape
1133 character (C<!> unless otherwise defined). Yes, these do conflict, and
1134 neither works in the debugger at the moment.
1135
1136 =cut
1137
1138 setman();
1139
1140 # Set up defaults for command recall and shell escape (note:
1141 # these currently don't work in linemode debugging).
1142 recallCommand("!") unless defined $prc;
1143 shellBang("!")     unless defined $psh;
1144
1145 =pod
1146
1147 We then set up the gigantic string containing the debugger help.
1148 We also set the limit on the number of arguments we'll display during a
1149 trace.
1150
1151 =cut
1152
1153 sethelp();
1154
1155 # If we didn't get a default for the length of eval/stack trace args,
1156 # set it here.
1157 $maxtrace = 400 unless defined $maxtrace;
1158
1159 =head2 SETTING UP THE DEBUGGER GREETING
1160
1161 The debugger I<greeting> helps to inform the user how many debuggers are
1162 running, and whether the current debugger is the primary or a child.
1163
1164 If we are the primary, we just hang onto our pid so we'll have it when
1165 or if we start a child debugger. If we are a child, we'll set things up
1166 so we'll have a unique greeting and so the parent will give us our own
1167 TTY later.
1168
1169 We save the current contents of the C<PERLDB_PIDS> environment variable
1170 because we mess around with it. We'll also need to hang onto it because
1171 we'll need it if we restart.
1172
1173 Child debuggers make a label out of the current PID structure recorded in
1174 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1175 yet so the parent will give them one later via C<resetterm()>.
1176
1177 =cut
1178
1179 # Save the current contents of the environment; we're about to
1180 # much with it. We'll need this if we have to restart.
1181 use vars qw($ini_pids);
1182 $ini_pids = $ENV{PERLDB_PIDS};
1183
1184 use vars qw ($pids $term_pid);
1185
1186 if ( defined $ENV{PERLDB_PIDS} ) {
1187
1188     # We're a child. Make us a label out of the current PID structure
1189     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1190     # a term yet so the parent will give us one later via resetterm().
1191
1192     my $env_pids = $ENV{PERLDB_PIDS};
1193     $pids = "[$env_pids]";
1194
1195     # Unless we are on OpenVMS, all programs under the DCL shell run under
1196     # the same PID.
1197
1198     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1199         $term_pid         = $$;
1200     }
1201     else {
1202         $ENV{PERLDB_PIDS} .= "->$$";
1203         $term_pid = -1;
1204     }
1205
1206 } ## end if (defined $ENV{PERLDB_PIDS...
1207 else {
1208
1209     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1210     # child debugger, and mark us as the parent, so we'll know to set up
1211     # more TTY's is we have to.
1212     $ENV{PERLDB_PIDS} = "$$";
1213     $pids             = "[pid=$$]";
1214     $term_pid         = $$;
1215 }
1216
1217 use vars qw($pidprompt);
1218 $pidprompt = '';
1219
1220 # Sets up $emacs as a synonym for $slave_editor.
1221 our ($slave_editor);
1222 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1223
1224 =head2 READING THE RC FILE
1225
1226 The debugger will read a file of initialization options if supplied. If
1227 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1228
1229 =cut
1230
1231 # As noted, this test really doesn't check accurately that the debugger
1232 # is running at a terminal or not.
1233
1234 use vars qw($rcfile);
1235 {
1236     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1237     # this is the wrong metric!
1238     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1239 }
1240
1241 =pod
1242
1243 The debugger does a safety test of the file to be read. It must be owned
1244 either by the current user or root, and must only be writable by the owner.
1245
1246 =cut
1247
1248 # This wraps a safety test around "do" to read and evaluate the init file.
1249 #
1250 # This isn't really safe, because there's a race
1251 # between checking and opening.  The solution is to
1252 # open and fstat the handle, but then you have to read and
1253 # eval the contents.  But then the silly thing gets
1254 # your lexical scope, which is unfortunate at best.
1255 sub safe_do {
1256     my $file = shift;
1257
1258     # Just exactly what part of the word "CORE::" don't you understand?
1259     local $SIG{__WARN__};
1260     local $SIG{__DIE__};
1261
1262     unless ( is_safe_file($file) ) {
1263         CORE::warn <<EO_GRIPE;
1264 perldb: Must not source insecure rcfile $file.
1265         You or the superuser must be the owner, and it must not
1266         be writable by anyone but its owner.
1267 EO_GRIPE
1268         return;
1269     } ## end unless (is_safe_file($file...
1270
1271     do $file;
1272     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1273 } ## end sub safe_do
1274
1275 # This is the safety test itself.
1276 #
1277 # Verifies that owner is either real user or superuser and that no
1278 # one but owner may write to it.  This function is of limited use
1279 # when called on a path instead of upon a handle, because there are
1280 # no guarantees that filename (by dirent) whose file (by ino) is
1281 # eventually accessed is the same as the one tested.
1282 # Assumes that the file's existence is not in doubt.
1283 sub is_safe_file {
1284     my $path = shift;
1285     stat($path) || return;    # mysteriously vaporized
1286     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1287
1288     return 0 if $uid != 0 && $uid != $<;
1289     return 0 if $mode & 022;
1290     return 1;
1291 } ## end sub is_safe_file
1292
1293 # If the rcfile (whichever one we decided was the right one to read)
1294 # exists, we safely do it.
1295 if ( -f $rcfile ) {
1296     safe_do("./$rcfile");
1297 }
1298
1299 # If there isn't one here, try the user's home directory.
1300 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1301     safe_do("$ENV{HOME}/$rcfile");
1302 }
1303
1304 # Else try the login directory.
1305 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1306     safe_do("$ENV{LOGDIR}/$rcfile");
1307 }
1308
1309 # If the PERLDB_OPTS variable has options in it, parse those out next.
1310 if ( defined $ENV{PERLDB_OPTS} ) {
1311     parse_options( $ENV{PERLDB_OPTS} );
1312 }
1313
1314 =pod
1315
1316 The last thing we do during initialization is determine which subroutine is
1317 to be used to obtain a new terminal when a new debugger is started. Right now,
1318 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1319 (darwin).
1320
1321 =cut
1322
1323 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1324 # Works if you're running an xterm or xterm-like window, or you're on
1325 # OS/2, or on Mac OS X. This may need some expansion.
1326
1327 if (not defined &get_fork_TTY)       # only if no routine exists
1328 {
1329     if ( defined $remoteport ) {
1330                                                  # Expect an inetd-like server
1331         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1332     }
1333     elsif (defined $ENV{TERM}                    # If we know what kind
1334                                                  # of terminal this is,
1335         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1336         and defined $ENV{DISPLAY}                # and what display it's on,
1337       )
1338     {
1339         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1340     }
1341     elsif ( $ENV{TMUX} ) {
1342         *get_fork_TTY = \&tmux_get_fork_TTY;
1343     }
1344     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1345         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1346     }
1347     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1348             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1349             and $ENV{TERM_PROGRAM}
1350                 eq 'Apple_Terminal'              # Terminal.app
1351             )
1352     {
1353         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1354     }
1355 } ## end if (not defined &get_fork_TTY...
1356
1357 # untaint $^O, which may have been tainted by the last statement.
1358 # see bug [perl #24674]
1359 $^O =~ m/^(.*)\z/;
1360 $^O = $1;
1361
1362 # Here begin the unreadable code.  It needs fixing.
1363
1364 =head2 RESTART PROCESSING
1365
1366 This section handles the restart command. When the C<R> command is invoked, it
1367 tries to capture all of the state it can into environment variables, and
1368 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1369 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1370 the R command stuffed into the environment variables.
1371
1372   PERLDB_RESTART   - flag only, contains no restart data itself.
1373   PERLDB_HIST      - command history, if it's available
1374   PERLDB_ON_LOAD   - breakpoints set by the rc file
1375   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1376                      and have actions
1377   PERLDB_VISITED   - files that had breakpoints
1378   PERLDB_FILE_...  - breakpoints for a file
1379   PERLDB_OPT       - active options
1380   PERLDB_INC       - the original @INC
1381   PERLDB_PRETYPE   - preprompt debugger actions
1382   PERLDB_PRE       - preprompt Perl code
1383   PERLDB_POST      - post-prompt Perl code
1384   PERLDB_TYPEAHEAD - typeahead captured by readline()
1385
1386 We chug through all these variables and plug the values saved in them
1387 back into the appropriate spots in the debugger.
1388
1389 =cut
1390
1391 use vars qw(%postponed_file @typeahead);
1392
1393 our (@hist, @truehist);
1394
1395 sub _restore_shared_globals_after_restart
1396 {
1397     @hist          = get_list('PERLDB_HIST');
1398     %break_on_load = get_list("PERLDB_ON_LOAD");
1399     %postponed     = get_list("PERLDB_POSTPONE");
1400
1401     share(@hist);
1402     share(@truehist);
1403     share(%break_on_load);
1404     share(%postponed);
1405 }
1406
1407 sub _restore_breakpoints_and_actions {
1408
1409     my @had_breakpoints = get_list("PERLDB_VISITED");
1410
1411     for my $file_idx ( 0 .. $#had_breakpoints ) {
1412         my $filename = $had_breakpoints[$file_idx];
1413         my %pf = get_list("PERLDB_FILE_$file_idx");
1414         $postponed_file{ $filename } = \%pf if %pf;
1415         my @lines = sort {$a <=> $b} keys(%pf);
1416         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1417         for my $line_idx (0 .. $#lines) {
1418             _set_breakpoint_enabled_status(
1419                 $filename,
1420                 $lines[$line_idx],
1421                 ($enabled_statuses[$line_idx] ? 1 : ''),
1422             );
1423         }
1424     }
1425
1426     return;
1427 }
1428
1429 sub _restore_options_after_restart
1430 {
1431     my %options_map = get_list("PERLDB_OPT");
1432
1433     while ( my ( $opt, $val ) = each %options_map ) {
1434         $val =~ s/[\\\']/\\$1/g;
1435         parse_options("$opt'$val'");
1436     }
1437
1438     return;
1439 }
1440
1441 sub _restore_globals_after_restart
1442 {
1443     # restore original @INC
1444     @INC     = get_list("PERLDB_INC");
1445     @ini_INC = @INC;
1446
1447     # return pre/postprompt actions and typeahead buffer
1448     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1449     $pre       = [ get_list("PERLDB_PRE") ];
1450     $post      = [ get_list("PERLDB_POST") ];
1451     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1452
1453     return;
1454 }
1455
1456
1457 if ( exists $ENV{PERLDB_RESTART} ) {
1458
1459     # We're restarting, so we don't need the flag that says to restart anymore.
1460     delete $ENV{PERLDB_RESTART};
1461
1462     # $restart = 1;
1463     _restore_shared_globals_after_restart();
1464
1465     _restore_breakpoints_and_actions();
1466
1467     # restore options
1468     _restore_options_after_restart();
1469
1470     _restore_globals_after_restart();
1471 } ## end if (exists $ENV{PERLDB_RESTART...
1472
1473 =head2 SETTING UP THE TERMINAL
1474
1475 Now, we'll decide how the debugger is going to interact with the user.
1476 If there's no TTY, we set the debugger to run non-stop; there's not going
1477 to be anyone there to enter commands.
1478
1479 =cut
1480
1481 use vars qw($notty $console $tty $LINEINFO);
1482 use vars qw($lineinfo $doccmd);
1483
1484 our ($runnonstop);
1485
1486 # Local autoflush to avoid rt#116769,
1487 # as calling IO::File methods causes an unresolvable loop
1488 # that results in debugger failure.
1489 sub _autoflush {
1490     my $o = select($_[0]);
1491     $|++;
1492     select($o);
1493 }
1494
1495 if ($notty) {
1496     $runnonstop = 1;
1497     share($runnonstop);
1498 }
1499
1500 =pod
1501
1502 If there is a TTY, we have to determine who it belongs to before we can
1503 proceed. If this is a slave editor or graphical debugger (denoted by
1504 the first command-line switch being '-emacs'), we shift this off and
1505 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1506
1507 =cut
1508
1509 else {
1510
1511     # Is Perl being run from a slave editor or graphical debugger?
1512     # If so, don't use readline, and set $slave_editor = 1.
1513     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1514         $rl = 0;
1515         shift(@main::ARGV);
1516     }
1517
1518     #require Term::ReadLine;
1519
1520 =pod
1521
1522 We then determine what the console should be on various systems:
1523
1524 =over 4
1525
1526 =item * Cygwin - We use C<stdin> instead of a separate device.
1527
1528 =cut
1529
1530     if ( $^O eq 'cygwin' ) {
1531
1532         # /dev/tty is binary. use stdin for textmode
1533         undef $console;
1534     }
1535
1536 =item * Windows or MSDOS - use C<con>.
1537
1538 =cut
1539
1540     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1541         $console = "con";
1542     }
1543
1544 =item * AmigaOS - use C<CONSOLE:>.
1545
1546 =cut
1547
1548     elsif ( $^O eq 'amigaos' ) {
1549         $console = "CONSOLE:";
1550     }
1551
1552 =item * VMS - use C<sys$command>.
1553
1554 =cut
1555
1556     elsif ($^O eq 'VMS') {
1557         $console = 'sys$command';
1558     }
1559
1560 # Keep this penultimate, on the grounds that it satisfies a wide variety of
1561 # Unix-like systems that would otherwise need to be identified individually.
1562
1563 =item * Unix - use F</dev/tty>.
1564
1565 =cut
1566
1567     elsif ( -e "/dev/tty" ) {
1568         $console = "/dev/tty";
1569     }
1570
1571 # Keep this last.
1572
1573     else {
1574         _db_warn("Can't figure out your console, using stdin");
1575         undef $console;
1576     }
1577
1578 =pod
1579
1580 =back
1581
1582 Several other systems don't use a specific console. We C<undef $console>
1583 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1584 with a slave editor).
1585
1586 =cut
1587
1588     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1589
1590         # /dev/tty is binary. use stdin for textmode
1591         $console = undef;
1592     }
1593
1594     if ( $^O eq 'NetWare' ) {
1595
1596         # /dev/tty is binary. use stdin for textmode
1597         $console = undef;
1598     }
1599
1600     # In OS/2, we need to use STDIN to get textmode too, even though
1601     # it pretty much looks like Unix otherwise.
1602     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1603     {    # In OS/2
1604         $console = undef;
1605     }
1606
1607 =pod
1608
1609 If there is a TTY hanging around from a parent, we use that as the console.
1610
1611 =cut
1612
1613     $console = $tty if defined $tty;
1614
1615 =head2 SOCKET HANDLING
1616
1617 The debugger is capable of opening a socket and carrying out a debugging
1618 session over the socket.
1619
1620 If C<RemotePort> was defined in the options, the debugger assumes that it
1621 should try to start a debugging session on that port. It builds the socket
1622 and then tries to connect the input and output filehandles to it.
1623
1624 =cut
1625
1626     # Handle socket stuff.
1627
1628     if ( defined $remoteport ) {
1629
1630         # If RemotePort was defined in the options, connect input and output
1631         # to the socket.
1632         $IN = $OUT = connect_remoteport();
1633     } ## end if (defined $remoteport)
1634
1635 =pod
1636
1637 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1638 this is probably a situation where multiple debuggers are running (for example,
1639 a backticked command that starts up another debugger). We create a new IN and
1640 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1641 and if we can.
1642
1643 =cut
1644
1645     # Non-socket.
1646     else {
1647
1648         # Two debuggers running (probably a system or a backtick that invokes
1649         # the debugger itself under the running one). create a new IN and OUT
1650         # filehandle, and do the necessary mojo to create a new tty if we
1651         # know how, and we can.
1652         create_IN_OUT(4) if $CreateTTY & 4;
1653         if ($console) {
1654
1655             # If we have a console, check to see if there are separate ins and
1656             # outs to open. (They are assumed identical if not.)
1657
1658             my ( $i, $o ) = split /,/, $console;
1659             $o = $i unless defined $o;
1660
1661             # read/write on in, or just read, or read on STDIN.
1662                  open( IN, '+<', $i )
1663               || open( IN, '<',  $i )
1664               || open( IN, "<&STDIN" );
1665
1666             # read/write/create/clobber out, or write/create/clobber out,
1667             # or merge with STDERR, or merge with STDOUT.
1668                  open( OUT, '+>', $o )
1669               || open( OUT, '>',  $o )
1670               || open( OUT, ">&STDERR" )
1671               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1672
1673         } ## end if ($console)
1674         elsif ( not defined $console ) {
1675
1676             # No console. Open STDIN.
1677             open( IN, "<&STDIN" );
1678
1679             # merge with STDERR, or with STDOUT.
1680             open( OUT,      ">&STDERR" )
1681               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1682             $console = 'STDIN/OUT';
1683         } ## end elsif (not defined $console)
1684
1685         # Keep copies of the filehandles so that when the pager runs, it
1686         # can close standard input without clobbering ours.
1687         if ($console or (not defined($console))) {
1688             $IN = \*IN;
1689             $OUT = \*OUT;
1690         }
1691     } ## end elsif (from if(defined $remoteport))
1692
1693     # Unbuffer DB::OUT. We need to see responses right away.
1694     _autoflush($OUT);
1695
1696     # Line info goes to debugger output unless pointed elsewhere.
1697     # Pointing elsewhere makes it possible for slave editors to
1698     # keep track of file and position. We have both a filehandle
1699     # and a I/O description to keep track of.
1700     $LINEINFO = $OUT     unless defined $LINEINFO;
1701     $lineinfo = $console unless defined $lineinfo;
1702     # share($LINEINFO); # <- unable to share globs
1703     share($lineinfo);   #
1704
1705 =pod
1706
1707 To finish initialization, we show the debugger greeting,
1708 and then call the C<afterinit()> subroutine if there is one.
1709
1710 =cut
1711
1712     # Show the debugger greeting.
1713     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1714     unless ($runnonstop) {
1715         local $\ = '';
1716         local $, = '';
1717         if ( $term_pid eq '-1' ) {
1718             print $OUT "\nDaughter DB session started...\n";
1719         }
1720         else {
1721             print $OUT "\nLoading DB routines from $header\n";
1722             print $OUT (
1723                 "Editor support ",
1724                 $slave_editor ? "enabled" : "available", ".\n"
1725             );
1726             print $OUT
1727 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1728         } ## end else [ if ($term_pid eq '-1')
1729     } ## end unless ($runnonstop)
1730 } ## end else [ if ($notty)
1731
1732 # XXX This looks like a bug to me.
1733 # Why copy to @ARGS and then futz with @args?
1734 @ARGS = @ARGV;
1735 # for (@args) {
1736     # Make sure backslashes before single quotes are stripped out, and
1737     # keep args unless they are numeric (XXX why?)
1738     # s/\'/\\\'/g;                      # removed while not justified understandably
1739     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1740 # }
1741
1742 # If there was an afterinit() sub defined, call it. It will get
1743 # executed in our scope, so it can fiddle with debugger globals.
1744 if ( defined &afterinit ) {    # May be defined in $rcfile
1745     afterinit();
1746 }
1747
1748 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1749 use vars qw($I_m_init);
1750
1751 $I_m_init = 1;
1752
1753 ############################################################ Subroutines
1754
1755 =head1 SUBROUTINES
1756
1757 =head2 DB
1758
1759 This gigantic subroutine is the heart of the debugger. Called before every
1760 statement, its job is to determine if a breakpoint has been reached, and
1761 stop if so; read commands from the user, parse them, and execute
1762 them, and then send execution off to the next statement.
1763
1764 Note that the order in which the commands are processed is very important;
1765 some commands earlier in the loop will actually alter the C<$cmd> variable
1766 to create other commands to be executed later. This is all highly I<optimized>
1767 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1768 see what's happening in any given command.
1769
1770 =cut
1771
1772 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1773
1774 use vars qw(
1775     $action
1776     $cmd
1777     $file
1778     $filename_ini
1779     $finished
1780     %had_breakpoints
1781     $level
1782     $max
1783     $package
1784     $try
1785 );
1786
1787 our (
1788     %alias,
1789     $doret,
1790     $end,
1791     $fall_off_end,
1792     $incr,
1793     $laststep,
1794     $rc,
1795     $sh,
1796     $stack_depth,
1797     @stack,
1798     @to_watch,
1799     @old_watch,
1800 );
1801
1802 sub _DB__determine_if_we_should_break
1803 {
1804     # if we have something here, see if we should break.
1805     # $stop is lexical and local to this block - $action on the other hand
1806     # is global.
1807     my $stop;
1808
1809     if ( $dbline{$line}
1810         && _is_breakpoint_enabled($filename, $line)
1811         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1812     {
1813
1814         # Stop if the stop criterion says to just stop.
1815         if ( $stop eq '1' ) {
1816             $signal |= 1;
1817         }
1818
1819         # It's a conditional stop; eval it in the user's context and
1820         # see if we should stop. If so, remove the one-time sigil.
1821         elsif ($stop) {
1822             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1823             # The &-call is here to ascertain the mutability of @_.
1824             &DB::eval;
1825             # If the breakpoint is temporary, then delete its enabled status.
1826             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1827                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1828             }
1829         }
1830     } ## end if ($dbline{$line} && ...
1831 }
1832
1833 sub _DB__is_finished {
1834     if ($finished and $level <= 1) {
1835         end_report();
1836         return 1;
1837     }
1838     else {
1839         return;
1840     }
1841 }
1842
1843 sub _DB__read_next_cmd
1844 {
1845     my ($tid) = @_;
1846
1847     # We have a terminal, or can get one ...
1848     if (!$term) {
1849         setterm();
1850     }
1851
1852     # ... and it belongs to this PID or we get one for this PID ...
1853     if ($term_pid != $$) {
1854         resetterm(1);
1855     }
1856
1857     # ... and we got a line of command input ...
1858     $cmd = DB::readline(
1859         "$pidprompt $tid DB"
1860         . ( '<' x $level )
1861         . ( $#hist + 1 )
1862         . ( '>' x $level ) . " "
1863     );
1864
1865     return defined($cmd);
1866 }
1867
1868 sub _DB__trim_command_and_return_first_component {
1869     my ($obj) = @_;
1870
1871     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1872     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1873
1874     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1875
1876     $obj->cmd_verb($verb);
1877     $obj->cmd_args($args);
1878
1879     return;
1880 }
1881
1882 sub _DB__handle_f_command {
1883     my ($obj) = @_;
1884
1885     if ($file = $obj->cmd_args) {
1886         # help for no arguments (old-style was return from sub).
1887         if ( !$file ) {
1888             print $OUT
1889             "The old f command is now the r command.\n";    # hint
1890             print $OUT "The new f command switches filenames.\n";
1891             next CMD;
1892         } ## end if (!$file)
1893
1894         # if not in magic file list, try a close match.
1895         if ( !defined $main::{ '_<' . $file } ) {
1896             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1897                 {
1898                     $try = substr( $try, 2 );
1899                     print $OUT "Choosing $try matching '$file':\n";
1900                     $file = $try;
1901                 }
1902             } ## end if (($try) = grep(m#^_<.*$file#...
1903         } ## end if (!defined $main::{ ...
1904
1905         # If not successfully switched now, we failed.
1906         if ( !defined $main::{ '_<' . $file } ) {
1907             print $OUT "No file matching '$file' is loaded.\n";
1908             next CMD;
1909         }
1910
1911         # We switched, so switch the debugger internals around.
1912         elsif ( $file ne $filename ) {
1913             *dbline   = $main::{ '_<' . $file };
1914             $max      = $#dbline;
1915             $filename = $file;
1916             $start    = 1;
1917             $cmd      = "l";
1918         } ## end elsif ($file ne $filename)
1919
1920         # We didn't switch; say we didn't.
1921         else {
1922             print $OUT "Already in $file.\n";
1923             next CMD;
1924         }
1925     }
1926
1927     return;
1928 }
1929
1930 sub _DB__handle_dot_command {
1931     my ($obj) = @_;
1932
1933     # . command.
1934     if ($obj->_is_full('.')) {
1935         $incr = -1;    # stay at current line
1936
1937         # Reset everything to the old location.
1938         $start    = $line;
1939         $filename = $filename_ini;
1940         *dbline   = $main::{ '_<' . $filename };
1941         $max      = $#dbline;
1942
1943         # Now where are we?
1944         print_lineinfo($obj->position());
1945         next CMD;
1946     }
1947
1948     return;
1949 }
1950
1951 sub _DB__handle_y_command {
1952     my ($obj) = @_;
1953
1954     if (my ($match_level, $match_vars)
1955         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1956
1957         # See if we've got the necessary support.
1958         if (!eval {
1959             local @INC = @INC;
1960             pop @INC if $INC[-1] eq '.';
1961             require PadWalker; PadWalker->VERSION(0.08) }) {
1962             my $Err = $@;
1963             _db_warn(
1964                 $Err =~ /locate/
1965                 ? "PadWalker module not found - please install\n"
1966                 : $Err
1967             );
1968             next CMD;
1969         }
1970
1971         # Load up dumpvar if we don't have it. If we can, that is.
1972         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1973         defined &main::dumpvar
1974             or print $OUT "dumpvar.pl not available.\n"
1975             and next CMD;
1976
1977         # Got all the modules we need. Find them and print them.
1978         my @vars = split( ' ', $match_vars || '' );
1979
1980         # Find the pad.
1981         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1982
1983         # Oops. Can't find it.
1984         if (my $Err = $@) {
1985             $Err =~ s/ at .*//;
1986             _db_warn($Err);
1987             next CMD;
1988         }
1989
1990         # Show the desired vars with dumplex().
1991         my $savout = select($OUT);
1992
1993         # Have dumplex dump the lexicals.
1994         foreach my $key (sort keys %$h) {
1995             dumpvar::dumplex( $key, $h->{$key},
1996                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1997                 @vars );
1998         }
1999         select($savout);
2000         next CMD;
2001     }
2002 }
2003
2004 sub _DB__handle_c_command {
2005     my ($obj) = @_;
2006
2007     my $i = $obj->cmd_args;
2008
2009     if ($i =~ m#\A[\w:]*\z#) {
2010
2011         # Hey, show's over. The debugged program finished
2012         # executing already.
2013         next CMD if _DB__is_finished();
2014
2015         # Capture the place to put a one-time break.
2016         $subname = $i;
2017
2018         #  Probably not needed, since we finish an interactive
2019         #  sub-session anyway...
2020         # local $filename = $filename;
2021         # local *dbline = *dbline; # XXX Would this work?!
2022         #
2023         # The above question wonders if localizing the alias
2024         # to the magic array works or not. Since it's commented
2025         # out, we'll just leave that to speculation for now.
2026
2027         # If the "subname" isn't all digits, we'll assume it
2028         # is a subroutine name, and try to find it.
2029         if ( $subname =~ /\D/ ) {    # subroutine name
2030             # Qualify it to the current package unless it's
2031             # already qualified.
2032             $subname = $package . "::" . $subname
2033             unless $subname =~ /::/;
2034
2035             # find_sub will return "file:line_number" corresponding
2036             # to where the subroutine is defined; we call find_sub,
2037             # break up the return value, and assign it in one
2038             # operation.
2039             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2040
2041             # Force the line number to be numeric.
2042             $i = $i + 0;
2043
2044             # If we got a line number, we found the sub.
2045             if ($i) {
2046
2047                 # Switch all the debugger's internals around so
2048                 # we're actually working with that file.
2049                 $filename = $file;
2050                 *dbline   = $main::{ '_<' . $filename };
2051
2052                 # Mark that there's a breakpoint in this file.
2053                 $had_breakpoints{$filename} |= 1;
2054
2055                 # Scan forward to the first executable line
2056                 # after the 'sub whatever' line.
2057                 $max = $#dbline;
2058                 my $_line_num = $i;
2059                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2060                 {
2061                     $_line_num++;
2062                 }
2063                 $i = $_line_num;
2064             } ## end if ($i)
2065
2066             # We didn't find a sub by that name.
2067             else {
2068                 print $OUT "Subroutine $subname not found.\n";
2069                 next CMD;
2070             }
2071         } ## end if ($subname =~ /\D/)
2072
2073         # At this point, either the subname was all digits (an
2074         # absolute line-break request) or we've scanned through
2075         # the code following the definition of the sub, looking
2076         # for an executable, which we may or may not have found.
2077         #
2078         # If $i (which we set $subname from) is non-zero, we
2079         # got a request to break at some line somewhere. On
2080         # one hand, if there wasn't any real subroutine name
2081         # involved, this will be a request to break in the current
2082         # file at the specified line, so we have to check to make
2083         # sure that the line specified really is breakable.
2084         #
2085         # On the other hand, if there was a subname supplied, the
2086         # preceding block has moved us to the proper file and
2087         # location within that file, and then scanned forward
2088         # looking for the next executable line. We have to make
2089         # sure that one was found.
2090         #
2091         # On the gripping hand, we can't do anything unless the
2092         # current value of $i points to a valid breakable line.
2093         # Check that.
2094         if ($i) {
2095
2096             # Breakable?
2097             if ( $dbline[$i] == 0 ) {
2098                 print $OUT "Line $i not breakable.\n";
2099                 next CMD;
2100             }
2101
2102             # Yes. Set up the one-time-break sigil.
2103             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2104             _enable_breakpoint_temp_enabled_status($filename, $i);
2105         } ## end if ($i)
2106
2107         # Turn off stack tracing from here up.
2108         for my $j (0 .. $stack_depth) {
2109             $stack[ $j ] &= ~1;
2110         }
2111         last CMD;
2112     }
2113
2114     return;
2115 }
2116
2117 sub _DB__handle_forward_slash_command {
2118     my ($obj) = @_;
2119
2120     # The pattern as a string.
2121     use vars qw($inpat);
2122
2123     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2124
2125         # Remove the final slash.
2126         $inpat =~ s:([^\\])/$:$1:;
2127
2128         # If the pattern isn't null ...
2129         if ( $inpat ne "" ) {
2130
2131             # Turn off warn and die processing for a bit.
2132             local $SIG{__DIE__};
2133             local $SIG{__WARN__};
2134
2135             # Create the pattern.
2136             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2137             if ( $@ ne "" ) {
2138
2139                 # Oops. Bad pattern. No biscuit.
2140                 # Print the eval error and go back for more
2141                 # commands.
2142                 print {$OUT} "$@";
2143                 next CMD;
2144             }
2145             $obj->pat($inpat);
2146         } ## end if ($inpat ne "")
2147
2148         # Set up to stop on wrap-around.
2149         $end = $start;
2150
2151         # Don't move off the current line.
2152         $incr = -1;
2153
2154         my $pat = $obj->pat;
2155
2156         # Done in eval so nothing breaks if the pattern
2157         # does something weird.
2158         eval
2159         {
2160             no strict q/vars/;
2161             for (;;) {
2162                 # Move ahead one line.
2163                 ++$start;
2164
2165                 # Wrap if we pass the last line.
2166                 if ($start > $max) {
2167                     $start = 1;
2168                 }
2169
2170                 # Stop if we have gotten back to this line again,
2171                 last if ($start == $end);
2172
2173                 # A hit! (Note, though, that we are doing
2174                 # case-insensitive matching. Maybe a qr//
2175                 # expression would be better, so the user could
2176                 # do case-sensitive matching if desired.
2177                 if ($dbline[$start] =~ m/$pat/i) {
2178                     if ($slave_editor) {
2179                         # Handle proper escaping in the slave.
2180                         print {$OUT} "\032\032$filename:$start:0\n";
2181                     }
2182                     else {
2183                         # Just print the line normally.
2184                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2185                     }
2186                     # And quit since we found something.
2187                     last;
2188                 }
2189             }
2190         };
2191
2192         if ($@) {
2193             warn $@;
2194         }
2195
2196         # If we wrapped, there never was a match.
2197         if ( $start == $end ) {
2198             print {$OUT} "/$pat/: not found\n";
2199         }
2200         next CMD;
2201     }
2202
2203     return;
2204 }
2205
2206 sub _DB__handle_question_mark_command {
2207     my ($obj) = @_;
2208
2209     # ? - backward pattern search.
2210     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2211
2212         # Get the pattern, remove trailing question mark.
2213         $inpat =~ s:([^\\])\?$:$1:;
2214
2215         # If we've got one ...
2216         if ( $inpat ne "" ) {
2217
2218             # Turn off die & warn handlers.
2219             local $SIG{__DIE__};
2220             local $SIG{__WARN__};
2221             eval '$inpat =~ m' . "\a$inpat\a";
2222
2223             if ( $@ ne "" ) {
2224
2225                 # Ouch. Not good. Print the error.
2226                 print $OUT $@;
2227                 next CMD;
2228             }
2229             $obj->pat($inpat);
2230         } ## end if ($inpat ne "")
2231
2232         # Where we are now is where to stop after wraparound.
2233         $end = $start;
2234
2235         # Don't move away from this line.
2236         $incr = -1;
2237
2238         my $pat = $obj->pat;
2239         # Search inside the eval to prevent pattern badness
2240         # from killing us.
2241         eval {
2242             no strict q/vars/;
2243             for (;;) {
2244                 # Back up a line.
2245                 --$start;
2246
2247                 # Wrap if we pass the first line.
2248
2249                 $start = $max if ($start <= 0);
2250
2251                 # Quit if we get back where we started,
2252                 last if ($start == $end);
2253
2254                 # Match?
2255                 if ($dbline[$start] =~ m/$pat/i) {
2256                     if ($slave_editor) {
2257                         # Yep, follow slave editor requirements.
2258                         print $OUT "\032\032$filename:$start:0\n";
2259                     }
2260                     else {
2261                         # Yep, just print normally.
2262                         print $OUT "$start:\t",$dbline[$start],"\n";
2263                     }
2264
2265                     # Found, so done.
2266                     last;
2267                 }
2268             }
2269         };
2270
2271         # Say we failed if the loop never found anything,
2272         if ( $start == $end ) {
2273             print {$OUT} "?$pat?: not found\n";
2274         }
2275         next CMD;
2276     }
2277
2278     return;
2279 }
2280
2281 sub _DB__handle_restart_and_rerun_commands {
2282     my ($obj) = @_;
2283
2284     my $cmd_cmd = $obj->cmd_verb;
2285     my $cmd_params = $obj->cmd_args;
2286     # R - restart execution.
2287     # rerun - controlled restart execution.
2288     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2289
2290         # Change directory to the initial current working directory on
2291         # the script startup, so if the debugged program changed the
2292         # directory, then we will still be able to find the path to the
2293         # the program. (perl 5 RT #121509 ).
2294         chdir ($_initial_cwd);
2295
2296         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2297
2298         # Close all non-system fds for a clean restart.  A more
2299         # correct method would be to close all fds that were not
2300         # open when the process started, but this seems to be
2301         # hard.  See "debugger 'R'estart and open database
2302         # connections" on p5p.
2303
2304         my $max_fd = 1024; # default if POSIX can't be loaded
2305         if (eval { require POSIX }) {
2306             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2307         }
2308
2309         if (defined $max_fd) {
2310             foreach ($^F+1 .. $max_fd-1) {
2311                 next unless open FD_TO_CLOSE, "<&=$_";
2312                 close(FD_TO_CLOSE);
2313             }
2314         }
2315
2316         # And run Perl again.  We use exec() to keep the
2317         # PID stable (and that way $ini_pids is still valid).
2318         exec(@args) or print {$OUT} "exec failed: $!\n";
2319
2320         last CMD;
2321     }
2322
2323     return;
2324 }
2325
2326 sub _DB__handle_run_command_in_pager_command {
2327     my ($obj) = @_;
2328
2329     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2330         if ( $pager =~ /^\|/ ) {
2331
2332             # Default pager is into a pipe. Redirect I/O.
2333             open( SAVEOUT, ">&STDOUT" )
2334             || _db_warn("Can't save STDOUT");
2335             open( STDOUT, ">&OUT" )
2336             || _db_warn("Can't redirect STDOUT");
2337         } ## end if ($pager =~ /^\|/)
2338         else {
2339
2340             # Not into a pipe. STDOUT is safe.
2341             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2342         }
2343
2344         # Fix up environment to record we have less if so.
2345         fix_less();
2346
2347         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2348
2349             # Couldn't open pipe to pager.
2350             _db_warn("Can't pipe output to '$pager'");
2351             if ( $pager =~ /^\|/ ) {
2352
2353                 # Redirect I/O back again.
2354                 open( OUT, ">&STDOUT" )    # XXX: lost message
2355                 || _db_warn("Can't restore DB::OUT");
2356                 open( STDOUT, ">&SAVEOUT" )
2357                 || _db_warn("Can't restore STDOUT");
2358                 close(SAVEOUT);
2359             } ## end if ($pager =~ /^\|/)
2360             else {
2361
2362                 # Redirect I/O. STDOUT already safe.
2363                 open( OUT, ">&STDOUT" )    # XXX: lost message
2364                 || _db_warn("Can't restore DB::OUT");
2365             }
2366             next CMD;
2367         } ## end unless ($piped = open(OUT,...
2368
2369         # Set up broken-pipe handler if necessary.
2370         $SIG{PIPE} = \&DB::catch
2371         if $pager =~ /^\|/
2372         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2373
2374         _autoflush(\*OUT);
2375         # Save current filehandle, and put it back.
2376         $obj->selected(scalar( select(OUT) ));
2377         # Don't put it back if pager was a pipe.
2378         if ($cmd !~ /\A\|\|/)
2379         {
2380             select($obj->selected());
2381             $obj->selected("");
2382         }
2383
2384         # Trim off the pipe symbols and run the command now.
2385         $cmd =~ s#\A\|+\s*##;
2386         redo PIPE;
2387     }
2388
2389     return;
2390 }
2391
2392 sub _DB__handle_m_command {
2393     my ($obj) = @_;
2394
2395     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2396         methods($1);
2397         next CMD;
2398     }
2399
2400     # m expr - set up DB::eval to do the work
2401     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2402         $onetimeDump = 'methods';   #  method output gets used there
2403     }
2404
2405     return;
2406 }
2407
2408 sub _DB__at_end_of_every_command {
2409     my ($obj) = @_;
2410
2411     # At the end of every command:
2412     if ($obj->piped) {
2413
2414         # Unhook the pipe mechanism now.
2415         if ( $pager =~ /^\|/ ) {
2416
2417             # No error from the child.
2418             $? = 0;
2419
2420             # we cannot warn here: the handle is missing --tchrist
2421             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2422
2423             # most of the $? crud was coping with broken cshisms
2424             # $? is explicitly set to 0, so this never runs.
2425             if ($?) {
2426                 print SAVEOUT "Pager '$pager' failed: ";
2427                 if ( $? == -1 ) {
2428                     print SAVEOUT "shell returned -1\n";
2429                 }
2430                 elsif ( $? >> 8 ) {
2431                     print SAVEOUT ( $? & 127 )
2432                     ? " (SIG#" . ( $? & 127 ) . ")"
2433                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2434                 }
2435                 else {
2436                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2437                 }
2438             } ## end if ($?)
2439
2440             # Reopen filehandle for our output (if we can) and
2441             # restore STDOUT (if we can).
2442             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2443             open( STDOUT, ">&SAVEOUT" )
2444             || _db_warn("Can't restore STDOUT");
2445
2446             # Turn off pipe exception handler if necessary.
2447             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2448
2449             # Will stop ignoring SIGPIPE if done like nohup(1)
2450             # does SIGINT but Perl doesn't give us a choice.
2451         } ## end if ($pager =~ /^\|/)
2452         else {
2453
2454             # Non-piped "pager". Just restore STDOUT.
2455             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2456         }
2457
2458         # Let Readline know about the new filehandles.
2459         reset_IN_OUT( \*IN, \*OUT );
2460
2461         # Close filehandle pager was using, restore the normal one
2462         # if necessary,
2463         close(SAVEOUT);
2464
2465         if ($obj->selected() ne "") {
2466             select($obj->selected);
2467             $obj->selected("");
2468         }
2469
2470         # No pipes now.
2471         $obj->piped("");
2472     } ## end if ($piped)
2473
2474     return;
2475 }
2476
2477 sub _DB__handle_watch_expressions
2478 {
2479     my $self = shift;
2480
2481     if ( $DB::trace & 2 ) {
2482         for my $n (0 .. $#DB::to_watch) {
2483             $DB::evalarg = $DB::to_watch[$n];
2484             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2485
2486             # Fix context DB::eval() wants to return an array, but
2487             # we need a scalar here.
2488             my ($val) = join( "', '", DB::eval(@_) );
2489             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2490
2491             # Did it change?
2492             if ( $val ne $DB::old_watch[$n] ) {
2493
2494                 # Yep! Show the difference, and fake an interrupt.
2495                 $DB::signal = 1;
2496                 print {$DB::OUT} <<EOP;
2497 Watchpoint $n:\t$DB::to_watch[$n] changed:
2498     old value:\t$DB::old_watch[$n]
2499     new value:\t$val
2500 EOP
2501                 $DB::old_watch[$n] = $val;
2502             } ## end if ($val ne $old_watch...
2503         } ## end for my $n (0 ..
2504     } ## end if ($trace & 2)
2505
2506     return;
2507 }
2508
2509 # 't' is type.
2510 # 'm' is method.
2511 # 'v' is the value (i.e: method name or subroutine ref).
2512 # 's' is subroutine.
2513 my %cmd_lookup;
2514
2515 BEGIN
2516 {
2517     %cmd_lookup =
2518 (
2519     '-' => { t => 'm', v => '_handle_dash_command', },
2520     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2521     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2522     'H' => { t => 'm', v => '_handle_H_command', },
2523     'S' => { t => 'm', v => '_handle_S_command', },
2524     'T' => { t => 'm', v => '_handle_T_command', },
2525     'W' => { t => 'm', v => '_handle_W_command', },
2526     'c' => { t => 's', v => \&_DB__handle_c_command, },
2527     'f' => { t => 's', v => \&_DB__handle_f_command, },
2528     'm' => { t => 's', v => \&_DB__handle_m_command, },
2529     'n' => { t => 'm', v => '_handle_n_command', },
2530     'p' => { t => 'm', v => '_handle_p_command', },
2531     'q' => { t => 'm', v => '_handle_q_command', },
2532     'r' => { t => 'm', v => '_handle_r_command', },
2533     's' => { t => 'm', v => '_handle_s_command', },
2534     'save' => { t => 'm', v => '_handle_save_command', },
2535     'source' => { t => 'm', v => '_handle_source_command', },
2536     't' => { t => 'm', v => '_handle_t_command', },
2537     'w' => { t => 'm', v => '_handle_w_command', },
2538     'x' => { t => 'm', v => '_handle_x_command', },
2539     'y' => { t => 's', v => \&_DB__handle_y_command, },
2540     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2541         ('X', 'V')),
2542     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2543         qw(enable disable)),
2544     (map { $_ =>
2545         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2546         } qw(R rerun)),
2547     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2548         qw(a A b B e E h i l L M o O v w W)),
2549 );
2550 };
2551
2552 sub DB {
2553
2554     # lock the debugger and get the thread id for the prompt
2555     lock($DBGR);
2556     my $tid;
2557     my $position;
2558     my ($prefix, $after, $infix);
2559     my $pat;
2560     my $explicit_stop;
2561     my $piped;
2562     my $selected;
2563
2564     if ($ENV{PERL5DB_THREADED}) {
2565         $tid = eval { "[".threads->tid."]" };
2566     }
2567
2568     my $cmd_verb;
2569     my $cmd_args;
2570
2571     my $obj = DB::Obj->new(
2572         {
2573             position => \$position,
2574             prefix => \$prefix,
2575             after => \$after,
2576             explicit_stop => \$explicit_stop,
2577             infix => \$infix,
2578             cmd_args => \$cmd_args,
2579             cmd_verb => \$cmd_verb,
2580             pat => \$pat,
2581             piped => \$piped,
2582             selected => \$selected,
2583         },
2584     );
2585
2586     $obj->_DB_on_init__initialize_globals(@_);
2587
2588     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2589     # The code being debugged may have altered them.
2590     DB::save();
2591
2592     # Since DB::DB gets called after every line, we can use caller() to
2593     # figure out where we last were executing. Sneaky, eh? This works because
2594     # caller is returning all the extra information when called from the
2595     # debugger.
2596     local ( $package, $filename, $line ) = caller;
2597     $filename_ini = $filename;
2598
2599     # set up the context for DB::eval, so it can properly execute
2600     # code on behalf of the user. We add the package in so that the
2601     # code is eval'ed in the proper package (not in the debugger!).
2602     local $usercontext = _calc_usercontext($package);
2603
2604     # Create an alias to the active file magical array to simplify
2605     # the code here.
2606     local (*dbline) = $main::{ '_<' . $filename };
2607
2608     # Last line in the program.
2609     $max = $#dbline;
2610
2611     # The &-call is here to ascertain the mutability of @_.
2612     &_DB__determine_if_we_should_break;
2613
2614     # Preserve the current stop-or-not, and see if any of the W
2615     # (watch expressions) has changed.
2616     my $was_signal = $signal;
2617
2618     # If we have any watch expressions ...
2619     _DB__handle_watch_expressions($obj);
2620
2621 =head2 C<watchfunction()>
2622
2623 C<watchfunction()> is a function that can be defined by the user; it is a
2624 function which will be run on each entry to C<DB::DB>; it gets the
2625 current package, filename, and line as its parameters.
2626
2627 The watchfunction can do anything it likes; it is executing in the
2628 debugger's context, so it has access to all of the debugger's internal
2629 data structures and functions.
2630
2631 C<watchfunction()> can control the debugger's actions. Any of the following
2632 will cause the debugger to return control to the user's program after
2633 C<watchfunction()> executes:
2634
2635 =over 4
2636
2637 =item *
2638
2639 Returning a false value from the C<watchfunction()> itself.
2640
2641 =item *
2642
2643 Altering C<$single> to a false value.
2644
2645 =item *
2646
2647 Altering C<$signal> to a false value.
2648
2649 =item *
2650
2651 Turning off the C<4> bit in C<$trace> (this also disables the
2652 check for C<watchfunction()>. This can be done with
2653
2654     $trace &= ~4;
2655
2656 =back
2657
2658 =cut
2659
2660     # If there's a user-defined DB::watchfunction, call it with the
2661     # current package, filename, and line. The function executes in
2662     # the DB:: package.
2663     if ( $trace & 4 ) {    # User-installed watch
2664         return
2665           if watchfunction( $package, $filename, $line )
2666           and not $single
2667           and not $was_signal
2668           and not( $trace & ~4 );
2669     } ## end if ($trace & 4)
2670
2671     # Pick up any alteration to $signal in the watchfunction, and
2672     # turn off the signal now.
2673     $was_signal = $signal;
2674     $signal     = 0;
2675
2676 =head2 GETTING READY TO EXECUTE COMMANDS
2677
2678 The debugger decides to take control if single-step mode is on, the
2679 C<t> command was entered, or the user generated a signal. If the program
2680 has fallen off the end, we set things up so that entering further commands
2681 won't cause trouble, and we say that the program is over.
2682
2683 =cut
2684
2685     # Make sure that we always print if asked for explicitly regardless
2686     # of $trace_to_depth .
2687     $explicit_stop = ($single || $was_signal);
2688
2689     # Check to see if we should grab control ($single true,
2690     # trace set appropriately, or we got a signal).
2691     if ( $explicit_stop || ( $trace & 1 ) ) {
2692         $obj->_DB__grab_control(@_);
2693     } ## end if ($single || ($trace...
2694
2695 =pod
2696
2697 If there's an action to be executed for the line we stopped at, execute it.
2698 If there are any preprompt actions, execute those as well.
2699
2700 =cut
2701
2702     # If there's an action, do it now.
2703     if ($action) {
2704         $evalarg = $action;
2705         # The &-call is here to ascertain the mutability of @_.
2706         &DB::eval;
2707     }
2708
2709     # Are we nested another level (e.g., did we evaluate a function
2710     # that had a breakpoint in it at the debugger prompt)?
2711     if ( $single || $was_signal ) {
2712
2713         # Yes, go down a level.
2714         local $level = $level + 1;
2715
2716         # Do any pre-prompt actions.
2717         foreach $evalarg (@$pre) {
2718             # The &-call is here to ascertain the mutability of @_.
2719             &DB::eval;
2720         }
2721
2722         # Complain about too much recursion if we passed the limit.
2723         if ($single & 4) {
2724             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2725         }
2726
2727         # The line we're currently on. Set $incr to -1 to stay here
2728         # until we get a command that tells us to advance.
2729         $start = $line;
2730         $incr  = -1;      # for backward motion.
2731
2732         # Tack preprompt debugger actions ahead of any actual input.
2733         @typeahead = ( @$pretype, @typeahead );
2734
2735 =head2 WHERE ARE WE?
2736
2737 XXX Relocate this section?
2738
2739 The debugger normally shows the line corresponding to the current line of
2740 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2741 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2742
2743 C<$incr> controls by how many lines the I<current> line should move forward
2744 after a command is executed. If set to -1, this indicates that the I<current>
2745 line shouldn't change.
2746
2747 C<$start> is the I<current> line. It is used for things like knowing where to
2748 move forwards or backwards from when doing an C<L> or C<-> command.
2749
2750 C<$max> tells the debugger where the last line of the current file is. It's
2751 used to terminate loops most often.
2752
2753 =head2 THE COMMAND LOOP
2754
2755 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2756 in two parts:
2757
2758 =over 4
2759
2760 =item *
2761
2762 The outer part of the loop, starting at the C<CMD> label. This loop
2763 reads a command and then executes it.
2764
2765 =item *
2766
2767 The inner part of the loop, starting at the C<PIPE> label. This part
2768 is wholly contained inside the C<CMD> block and only executes a command.
2769 Used to handle commands running inside a pager.
2770
2771 =back
2772
2773 So why have two labels to restart the loop? Because sometimes, it's easier to
2774 have a command I<generate> another command and then re-execute the loop to do
2775 the new command. This is faster, but perhaps a bit more convoluted.
2776
2777 =cut
2778
2779         # The big command dispatch loop. It keeps running until the
2780         # user yields up control again.
2781         #
2782         # If we have a terminal for input, and we get something back
2783         # from readline(), keep on processing.
2784
2785       CMD:
2786         while (_DB__read_next_cmd($tid))
2787         {
2788
2789             share($cmd);
2790             # ... try to execute the input as debugger commands.
2791
2792             # Don't stop running.
2793             $single = 0;
2794
2795             # No signal is active.
2796             $signal = 0;
2797
2798             # Handle continued commands (ending with \):
2799             if ($cmd =~ s/\\\z/\n/) {
2800                 $cmd .= DB::readline("  cont: ");
2801                 redo CMD;
2802             }
2803
2804 =head4 The null command
2805
2806 A newline entered by itself means I<re-execute the last command>. We grab the
2807 command out of C<$laststep> (where it was recorded previously), and copy it
2808 back into C<$cmd> to be executed below. If there wasn't any previous command,
2809 we'll do nothing below (no command will match). If there was, we also save it
2810 in the command history and fall through to allow the command parsing to pick
2811 it up.
2812
2813 =cut
2814
2815             # Empty input means repeat the last command.
2816             if ($cmd eq '') {
2817                 $cmd = $laststep;
2818             }
2819             chomp($cmd);    # get rid of the annoying extra newline
2820             if (length($cmd) >= 2) {
2821                 push( @hist, $cmd );
2822             }
2823             push( @truehist, $cmd );
2824             share(@hist);
2825             share(@truehist);
2826
2827             # This is a restart point for commands that didn't arrive
2828             # via direct user input. It allows us to 'redo PIPE' to
2829             # re-execute command processing without reading a new command.
2830           PIPE: {
2831                 _DB__trim_command_and_return_first_component($obj);
2832
2833 =head3 COMMAND ALIASES
2834
2835 The debugger can create aliases for commands (these are stored in the
2836 C<%alias> hash). Before a command is executed, the command loop looks it up
2837 in the alias hash and substitutes the contents of the alias for the command,
2838 completely replacing it.
2839
2840 =cut
2841
2842                 # See if there's an alias for the command, and set it up if so.
2843                 if ( $alias{$cmd_verb} ) {
2844
2845                     # Squelch signal handling; we want to keep control here
2846                     # if something goes loco during the alias eval.
2847                     local $SIG{__DIE__};
2848                     local $SIG{__WARN__};
2849
2850                     # This is a command, so we eval it in the DEBUGGER's
2851                     # scope! Otherwise, we can't see the special debugger
2852                     # variables, or get to the debugger's subs. (Well, we
2853                     # _could_, but why make it even more complicated?)
2854                     eval "\$cmd =~ $alias{$cmd_verb}";
2855                     if ($@) {
2856                         local $\ = '';
2857                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2858                         next CMD;
2859                     }
2860                     _DB__trim_command_and_return_first_component($obj);
2861                 } ## end if ($alias{$cmd_verb})
2862
2863 =head3 MAIN-LINE COMMANDS
2864
2865 All of these commands work up to and after the program being debugged has
2866 terminated.
2867
2868 =head4 C<q> - quit
2869
2870 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2871 try to execute further, cleaning any restart-related stuff out of the
2872 environment, and executing with the last value of C<$?>.
2873
2874 =cut
2875
2876                 # All of these commands were remapped in perl 5.8.0;
2877                 # we send them off to the secondary dispatcher (see below).
2878                 $obj->_handle_special_char_cmd_wrapper_commands;
2879                 _DB__trim_command_and_return_first_component($obj);
2880
2881                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2882                     my $type = $cmd_rec->{t};
2883                     my $val = $cmd_rec->{v};
2884                     if ($type eq 'm') {
2885                         $obj->$val();
2886                     }
2887                     elsif ($type eq 's') {
2888                         $val->($obj);
2889                     }
2890                 }
2891
2892 =head4 C<t> - trace [n]
2893
2894 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2895 If level is specified, set C<$trace_to_depth>.
2896
2897 =head4 C<S> - list subroutines matching/not matching a pattern
2898
2899 Walks through C<%sub>, checking to see whether or not to print the name.
2900
2901 =head4 C<X> - list variables in current package
2902
2903 Since the C<V> command actually processes this, just change this to the
2904 appropriate C<V> command and fall through.
2905
2906 =head4 C<V> - list variables
2907
2908 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2909
2910 =head4 C<x> - evaluate and print an expression
2911
2912 Hands the expression off to C<DB::eval>, setting it up to print the value
2913 via C<dumpvar.pl> instead of just printing it directly.
2914
2915 =head4 C<m> - print methods
2916
2917 Just uses C<DB::methods> to determine what methods are available.
2918
2919 =head4 C<f> - switch files
2920
2921 Switch to a different filename.
2922
2923 =head4 C<.> - return to last-executed line.
2924
2925 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2926 and then we look up the line in the magical C<%dbline> hash.
2927
2928 =head4 C<-> - back one window
2929
2930 We change C<$start> to be one window back; if we go back past the first line,
2931 we set it to be the first line. We ser C<$incr> to put us back at the
2932 currently-executing line, and then put a C<l $start +> (list one window from
2933 C<$start>) in C<$cmd> to be executed later.
2934
2935 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2936
2937 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2938 problems, most notably that the default case of several commands destroying
2939 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2940 retain the old commands for those who were used to using them or who preferred
2941 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2942 deal with them instead of processing them in-line.
2943
2944 =head4 C<y> - List lexicals in higher scope
2945
2946 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2947 above the current one and then displays then using C<dumpvar.pl>.
2948
2949 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2950
2951 All of the commands below this point don't work after the program being
2952 debugged has ended. All of them check to see if the program has ended; this
2953 allows the commands to be relocated without worrying about a 'line of
2954 demarcation' above which commands can be entered anytime, and below which
2955 they can't.
2956
2957 =head4 C<n> - single step, but don't trace down into subs
2958
2959 Done by setting C<$single> to 2, which forces subs to execute straight through
2960 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2961 so a null command knows what to re-execute.
2962
2963 =head4 C<s> - single-step, entering subs
2964
2965 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2966 subs. Also saves C<s> as C<$lastcmd>.
2967
2968 =head4 C<c> - run continuously, setting an optional breakpoint
2969
2970 Most of the code for this command is taken up with locating the optional
2971 breakpoint, which is either a subroutine name or a line number. We set
2972 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2973 in this and all call levels above this one.
2974
2975 =head4 C<r> - return from a subroutine
2976
2977 For C<r> to work properly, the debugger has to stop execution again
2978 immediately after the return is executed. This is done by forcing
2979 single-stepping to be on in the call level above the current one. If
2980 we are printing return values when a C<r> is executed, set C<$doret>
2981 appropriately, and force us out of the command loop.
2982
2983 =head4 C<T> - stack trace
2984
2985 Just calls C<DB::print_trace>.
2986
2987 =head4 C<w> - List window around current line.
2988
2989 Just calls C<DB::cmd_w>.
2990
2991 =head4 C<W> - watch-expression processing.
2992
2993 Just calls C<DB::cmd_W>.
2994
2995 =head4 C</> - search forward for a string in the source
2996
2997 We take the argument and treat it as a pattern. If it turns out to be a
2998 bad one, we return the error we got from trying to C<eval> it and exit.
2999 If not, we create some code to do the search and C<eval> it so it can't
3000 mess us up.
3001
3002 =cut
3003
3004                 _DB__handle_forward_slash_command($obj);
3005
3006 =head4 C<?> - search backward for a string in the source
3007
3008 Same as for C</>, except the loop runs backwards.
3009
3010 =cut
3011
3012                 _DB__handle_question_mark_command($obj);
3013
3014 =head4 C<$rc> - Recall command
3015
3016 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3017 that the terminal supports history). It finds the command required, puts it
3018 into C<$cmd>, and redoes the loop to execute it.
3019
3020 =cut
3021
3022                 # $rc - recall command.
3023                 $obj->_handle_rc_recall_command;
3024
3025 =head4 C<$sh$sh> - C<system()> command
3026
3027 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3028 C<STDOUT> from getting messed up.
3029
3030 =cut
3031
3032                 $obj->_handle_sh_command;
3033
3034 =head4 C<$rc I<pattern> $rc> - Search command history
3035
3036 Another command to manipulate C<@hist>: this one searches it with a pattern.
3037 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3038
3039 =cut
3040
3041                 $obj->_handle_rc_search_history_command;
3042
3043 =head4 C<$sh> - Invoke a shell
3044
3045 Uses C<_db_system()> to invoke a shell.
3046
3047 =cut
3048
3049 =head4 C<$sh I<command>> - Force execution of a command in a shell
3050
3051 Like the above, but the command is passed to the shell. Again, we use
3052 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3053
3054 =head4 C<H> - display commands in history
3055
3056 Prints the contents of C<@hist> (if any).
3057
3058 =head4 C<man, doc, perldoc> - look up documentation
3059
3060 Just calls C<runman()> to print the appropriate document.
3061
3062 =cut
3063
3064                 $obj->_handle_doc_command;
3065
3066 =head4 C<p> - print
3067
3068 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3069 the bottom of the loop.
3070
3071 =head4 C<=> - define command alias
3072
3073 Manipulates C<%alias> to add or list command aliases.
3074
3075 =head4 C<source> - read commands from a file.
3076
3077 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3078 pick it up.
3079
3080 =head4 C<enable> C<disable> - enable or disable breakpoints
3081
3082 This enables or disables breakpoints.
3083
3084 =head4 C<save> - send current history to a file
3085
3086 Takes the complete history, (not the shrunken version you see with C<H>),
3087 and saves it to the given filename, so it can be replayed using C<source>.
3088
3089 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3090
3091 =head4 C<R> - restart
3092
3093 Restart the debugger session.
3094
3095 =head4 C<rerun> - rerun the current session
3096
3097 Return to any given position in the B<true>-history list
3098
3099 =head4 C<|, ||> - pipe output through the pager.
3100
3101 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3102 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3103 pipe to the pager (restoring the output filehandles if this fails). If this
3104 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3105 set C<$signal>, sending us back into the debugger.
3106
3107 We then trim off the pipe symbols and C<redo> the command loop at the
3108 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3109 reading another.
3110
3111 =cut
3112
3113                 # || - run command in the pager, with output to DB::OUT.
3114                 _DB__handle_run_command_in_pager_command($obj);
3115
3116 =head3 END OF COMMAND PARSING
3117
3118 Anything left in C<$cmd> at this point is a Perl expression that we want to
3119 evaluate. We'll always evaluate in the user's context, and fully qualify
3120 any variables we might want to address in the C<DB> package.
3121
3122 =cut
3123
3124             }    # PIPE:
3125
3126             # trace an expression
3127             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3128
3129             # Make sure the flag that says "the debugger's running" is
3130             # still on, to make sure we get control again.
3131             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3132
3133             # Run *our* eval that executes in the caller's context.
3134             # The &-call is here to ascertain the mutability of @_.
3135             &DB::eval;
3136
3137             # Turn off the one-time-dump stuff now.
3138             if ($onetimeDump) {
3139                 $onetimeDump      = undef;
3140                 $onetimedumpDepth = undef;
3141             }
3142             elsif ( $term_pid == $$ ) {
3143                 eval { # May run under miniperl, when not available...
3144                     STDOUT->flush();
3145                     STDERR->flush();
3146                 };
3147
3148                 # XXX If this is the master pid, print a newline.
3149                 print {$OUT} "\n";
3150             }
3151         } ## end while (($term || &setterm...
3152
3153 =head3 POST-COMMAND PROCESSING
3154
3155 After each command, we check to see if the command output was piped anywhere.
3156 If so, we go through the necessary code to unhook the pipe and go back to
3157 our standard filehandles for input and output.
3158
3159 =cut
3160
3161         continue {    # CMD:
3162             _DB__at_end_of_every_command($obj);
3163         }    # CMD:
3164
3165 =head3 COMMAND LOOP TERMINATION
3166
3167 When commands have finished executing, we come here. If the user closed the
3168 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3169 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3170 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3171 The interpreter will then execute the next line and then return control to us
3172 again.
3173
3174 =cut
3175
3176         # No more commands? Quit.
3177         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3178
3179         # Evaluate post-prompt commands.
3180         foreach $evalarg (@$post) {
3181             # The &-call is here to ascertain the mutability of @_.
3182             &DB::eval;
3183         }
3184     }    # if ($single || $signal)
3185
3186     # Put the user's globals back where you found them.
3187     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3188     ();
3189 } ## end sub DB
3190
3191 # Because DB::Obj is used above,
3192 #
3193 #   my $obj = DB::Obj->new(
3194 #
3195 # The following package declaration must come before that,
3196 # or else runtime errors will occur with
3197 #
3198 #   PERLDB_OPTS="autotrace nonstop"
3199 #
3200 # ( rt#116771 )
3201 BEGIN {
3202
3203 package DB::Obj;
3204
3205 sub new {
3206     my $class = shift;
3207
3208     my $self = bless {}, $class;
3209
3210     $self->_init(@_);
3211
3212     return $self;
3213 }
3214
3215 sub _init {
3216     my ($self, $args) = @_;
3217
3218     %{$self} = (%$self, %$args);
3219
3220     return;
3221 }
3222
3223 {
3224     no strict 'refs';
3225     foreach my $slot_name (qw(
3226         after explicit_stop infix pat piped position prefix selected cmd_verb
3227         cmd_args
3228         )) {
3229         my $slot = $slot_name;
3230         *{$slot} = sub {
3231             my $self = shift;
3232
3233             if (@_) {
3234                 ${ $self->{$slot} } = shift;
3235             }
3236
3237             return ${ $self->{$slot} };
3238         };
3239
3240         *{"append_to_$slot"} = sub {
3241             my $self = shift;
3242             my $s = shift;
3243
3244             return $self->$slot($self->$slot . $s);
3245         };
3246     }
3247 }
3248
3249 sub _DB_on_init__initialize_globals
3250 {
3251     my $self = shift;
3252
3253     # Check for whether we should be running continuously or not.
3254     # _After_ the perl program is compiled, $single is set to 1:
3255     if ( $single and not $second_time++ ) {
3256
3257         # Options say run non-stop. Run until we get an interrupt.
3258         if ($runnonstop) {    # Disable until signal
3259                 # If there's any call stack in place, turn off single
3260                 # stepping into subs throughout the stack.
3261             for my $i (0 .. $stack_depth) {
3262                 $stack[ $i ] &= ~1;
3263             }
3264
3265             # And we are now no longer in single-step mode.
3266             $single = 0;
3267
3268             # If we simply returned at this point, we wouldn't get
3269             # the trace info. Fall on through.
3270             # return;
3271         } ## end if ($runnonstop)
3272
3273         elsif ($ImmediateStop) {
3274
3275             # We are supposed to stop here; XXX probably a break.
3276             $ImmediateStop = 0;    # We've processed it; turn it off
3277             $signal        = 1;    # Simulate an interrupt to force
3278                                    # us into the command loop
3279         }
3280     } ## end if ($single and not $second_time...
3281
3282     # If we're in single-step mode, or an interrupt (real or fake)
3283     # has occurred, turn off non-stop mode.
3284     $runnonstop = 0 if $single or $signal;
3285
3286     return;
3287 }
3288
3289 sub _my_print_lineinfo
3290 {
3291     my ($self, $i, $incr_pos) = @_;
3292
3293     if ($frame) {
3294         # Print it indented if tracing is on.
3295         DB::print_lineinfo( ' ' x $stack_depth,
3296             "$i:\t$DB::dbline[$i]" . $self->after );
3297     }
3298     else {
3299         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3300     }
3301 }
3302
3303 sub _curr_line {
3304     return $DB::dbline[$line];
3305 }
3306
3307 sub _is_full {
3308     my ($self, $letter) = @_;
3309
3310     return ($DB::cmd eq $letter);
3311 }
3312
3313 sub _DB__grab_control
3314 {
3315     my $self = shift;
3316
3317     # Yes, grab control.
3318     if ($slave_editor) {
3319
3320         # Tell the editor to update its position.
3321         $self->position("\032\032${DB::filename}:$line:0\n");
3322         DB::print_lineinfo($self->position());
3323     }
3324
3325 =pod
3326
3327 Special check: if we're in package C<DB::fake>, we've gone through the
3328 C<END> block at least once. We set up everything so that we can continue
3329 to enter commands and have a valid context to be in.
3330
3331 =cut
3332
3333     elsif ( $DB::package eq 'DB::fake' ) {
3334
3335         # Fallen off the end already.
3336         if (!$DB::term) {
3337             DB::setterm();
3338         }
3339
3340         DB::print_help(<<EOP);
3341 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3342 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3343 B<h q>, B<h R> or B<h o> to get additional info.
3344 EOP
3345
3346         # Set the DB::eval context appropriately.
3347         # At program termination disable any user actions.
3348         $DB::action = undef;
3349
3350         $DB::package     = 'main';
3351         $DB::usercontext = DB::_calc_usercontext($DB::package);
3352     } ## end elsif ($package eq 'DB::fake')
3353
3354 =pod
3355
3356 If the program hasn't finished executing, we scan forward to the
3357 next executable line, print that out, build the prompt from the file and line
3358 number information, and print that.
3359
3360 =cut
3361
3362     else {
3363
3364
3365         # Still somewhere in the midst of execution. Set up the
3366         #  debugger prompt.
3367         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3368                              # Perl 5 ones (sorry, we don't print Klingon
3369                              #module names)
3370
3371         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3372         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3373         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3374
3375         # Break up the prompt if it's really long.
3376         if ( length($self->prefix()) > 30 ) {
3377             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3378             $self->prefix("");
3379             $self->infix(":\t");
3380         }
3381         else {
3382             $self->infix("):\t");
3383             $self->position(
3384                 $self->prefix . $line. $self->infix
3385                 . $self->_curr_line . $self->after
3386             );
3387         }
3388
3389         # Print current line info, indenting if necessary.
3390         $self->_my_print_lineinfo($line, $self->position);
3391
3392         my $i;
3393         my $line_i = sub { return $DB::dbline[$i]; };
3394
3395         # Scan forward, stopping at either the end or the next
3396         # unbreakable line.
3397         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3398         {    #{ vi
3399
3400             # Drop out on null statements, block closers, and comments.
3401             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3402
3403             # Drop out if the user interrupted us.
3404             last if $signal;
3405
3406             # Append a newline if the line doesn't have one. Can happen
3407             # in eval'ed text, for instance.
3408             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3409
3410             # Next executable line.
3411             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3412                 . $self->after;
3413             $self->append_to_position($incr_pos);
3414             $self->_my_print_lineinfo($i, $incr_pos);
3415         } ## end for ($i = $line + 1 ; $i...
3416     } ## end else [ if ($slave_editor)
3417
3418     return;
3419 }
3420
3421 sub _handle_t_command {
3422     my $self = shift;
3423
3424     my $levels = $self->cmd_args();
3425
3426     if ((!length($levels)) or ($levels !~ /\D/)) {
3427         $trace ^= 1;
3428         local $\ = '';
3429         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3430         print {$OUT} "Trace = "
3431         . ( ( $trace & 1 )
3432             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3433             : "off" ) . "\n";
3434         next CMD;
3435     }
3436
3437     return;
3438 }
3439
3440
3441 sub _handle_S_command {
3442     my $self = shift;
3443
3444     if (my ($print_all_subs, $should_reverse, $Spatt)
3445         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3446         # $Spatt is the pattern (if any) to use.
3447         # Reverse scan?
3448         my $Srev     = defined $should_reverse;
3449         # No args - print all subs.
3450         my $Snocheck = !defined $print_all_subs;
3451
3452         # Need to make these sane here.
3453         local $\ = '';
3454         local $, = '';
3455
3456         # Search through the debugger's magical hash of subs.
3457         # If $nocheck is true, just print the sub name.
3458         # Otherwise, check it against the pattern. We then use
3459         # the XOR trick to reverse the condition as required.
3460         foreach $subname ( sort( keys %sub ) ) {
3461             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3462                 print $OUT $subname, "\n";
3463             }
3464         }
3465         next CMD;
3466     }
3467
3468     return;
3469 }
3470
3471 sub _handle_V_command_and_X_command {
3472     my $self = shift;
3473
3474     $DB::cmd =~ s/^X\b/V $DB::package/;
3475
3476     # Bare V commands get the currently-being-debugged package
3477     # added.
3478     if ($self->_is_full('V')) {
3479         $DB::cmd = "V $DB::package";
3480     }
3481
3482     # V - show variables in package.
3483     if (my ($new_packname, $new_vars_str) =
3484         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3485
3486         # Save the currently selected filehandle and
3487         # force output to debugger's filehandle (dumpvar
3488         # just does "print" for output).
3489         my $savout = select($OUT);
3490
3491         # Grab package name and variables to dump.
3492         $packname = $new_packname;
3493         my @vars     = split( ' ', $new_vars_str );
3494
3495         # If main::dumpvar isn't here, get it.
3496         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3497         if ( defined &main::dumpvar ) {
3498
3499             # We got it. Turn off subroutine entry/exit messages
3500             # for the moment, along with return values.
3501             local $frame = 0;
3502             local $doret = -2;
3503
3504             # must detect sigpipe failures  - not catching
3505             # then will cause the debugger to die.
3506             eval {
3507                 main::dumpvar(
3508                     $packname,
3509                     defined $option{dumpDepth}
3510                     ? $option{dumpDepth}
3511                     : -1,    # assume -1 unless specified
3512                     @vars
3513                 );
3514             };
3515
3516             # The die doesn't need to include the $@, because
3517             # it will automatically get propagated for us.
3518             if ($@) {
3519                 die unless $@ =~ /dumpvar print failed/;
3520             }
3521         } ## end if (defined &main::dumpvar)
3522         else {
3523
3524             # Couldn't load dumpvar.
3525             print $OUT "dumpvar.pl not available.\n";
3526         }
3527
3528         # Restore the output filehandle, and go round again.
3529         select($savout);
3530         next CMD;
3531     }
3532
3533     return;
3534 }
3535
3536 sub _handle_dash_command {
3537     my $self = shift;
3538
3539     if ($self->_is_full('-')) {
3540
3541         # back up by a window; go to 1 if back too far.
3542         $start -= $incr + $window + 1;
3543         $start = 1 if $start <= 0;
3544         $incr  = $window - 1;
3545
3546         # Generate and execute a "l +" command (handled below).
3547         $DB::cmd = 'l ' . ($start) . '+';
3548         redo CMD;
3549     }
3550     return;
3551 }
3552
3553 sub _n_or_s_commands_generic {
3554     my ($self, $new_val) = @_;
3555     # n - next
3556     next CMD if DB::_DB__is_finished();
3557
3558     # Single step, but don't enter subs.
3559     $single = $new_val;
3560
3561     # Save for empty command (repeat last).
3562     $laststep = $DB::cmd;
3563     last CMD;
3564 }
3565
3566 sub _n_or_s {
3567     my ($self, $letter, $new_val) = @_;
3568
3569     if ($self->_is_full($letter)) {
3570         $self->_n_or_s_commands_generic($new_val);
3571     }
3572     else {
3573         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3574     }
3575
3576     return;
3577 }
3578
3579 sub _handle_n_command {
3580     my $self = shift;
3581
3582     return $self->_n_or_s('n', 2);
3583 }
3584
3585 sub _handle_s_command {
3586     my $self = shift;
3587
3588     return $self->_n_or_s('s', 1);
3589 }
3590
3591 sub _handle_r_command {
3592     my $self = shift;
3593
3594     # r - return from the current subroutine.
3595     if ($self->_is_full('r')) {
3596
3597         # Can't do anything if the program's over.
3598         next CMD if DB::_DB__is_finished();
3599
3600         # Turn on stack trace.
3601         $stack[$stack_depth] |= 1;
3602
3603         # Print return value unless the stack is empty.
3604         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3605         last CMD;
3606     }
3607
3608     return;
3609 }
3610
3611 sub _handle_T_command {
3612     my $self = shift;
3613
3614     if ($self->_is_full('T')) {
3615         DB::print_trace( $OUT, 1 );    # skip DB
3616         next CMD;
3617     }
3618
3619     return;
3620 }
3621
3622 sub _handle_w_command {
3623     my $self = shift;
3624
3625     DB::cmd_w( 'w', $self->cmd_args() );
3626     next CMD;
3627
3628     return;
3629 }
3630
3631 sub _handle_W_command {
3632     my $self = shift;
3633
3634     if (my $arg = $self->cmd_args) {
3635         DB::cmd_W( 'W', $arg );
3636         next CMD;
3637     }
3638
3639     return;
3640 }
3641
3642 sub _handle_rc_recall_command {
3643     my $self = shift;
3644
3645     # $rc - recall command.
3646     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3647
3648         # No arguments, take one thing off history.
3649         pop(@hist) if length($DB::cmd) > 1;
3650
3651         # Relative (- found)?
3652         #  Y - index back from most recent (by 1 if bare minus)
3653         #  N - go to that particular command slot or the last
3654         #      thing if nothing following.
3655
3656         $self->cmd_verb(
3657             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3658         );
3659
3660         # Pick out the command desired.
3661         $DB::cmd = $hist[$self->cmd_verb];
3662
3663         # Print the command to be executed and restart the loop
3664         # with that command in the buffer.
3665         print {$OUT} $DB::cmd, "\n";
3666         redo CMD;
3667     }
3668
3669     return;
3670 }
3671
3672 sub _handle_rc_search_history_command {
3673     my $self = shift;
3674
3675     # $rc pattern $rc - find a command in the history.
3676     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3677
3678         # Create the pattern to use.
3679         my $pat = "^$arg";
3680         $self->pat($pat);
3681
3682         # Toss off last entry if length is >1 (and it always is).
3683         pop(@hist) if length($DB::cmd) > 1;
3684
3685         my $i;
3686
3687         # Look backward through the history.
3688         SEARCH_HIST:
3689         for ( $i = $#hist ; $i ; --$i ) {
3690             # Stop if we find it.
3691             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3692         }
3693
3694         if ( !$i ) {
3695
3696             # Never found it.
3697             print $OUT "No such command!\n\n";
3698             next CMD;
3699         }
3700
3701         # Found it. Put it in the buffer, print it, and process it.
3702         $DB::cmd = $hist[$i];
3703         print $OUT $DB::cmd, "\n";
3704         redo CMD;
3705     }
3706
3707     return;
3708 }
3709
3710 sub _handle_H_command {
3711     my $self = shift;
3712
3713     if ($self->cmd_args =~ m#\A\*#) {
3714         @hist = @truehist = ();
3715         print $OUT "History cleansed\n";
3716         next CMD;
3717     }
3718
3719     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3720
3721         # Anything other than negative numbers is ignored by
3722         # the (incorrect) pattern, so this test does nothing.
3723         $end = $num ? ( $#hist - $num ) : 0;
3724
3725         # Set to the minimum if less than zero.
3726         $hist = 0 if $hist < 0;
3727
3728         # Start at the end of the array.
3729         # Stay in while we're still above the ending value.
3730         # Tick back by one each time around the loop.
3731         my $i;
3732
3733         for ( $i = $#hist ; $i > $end ; $i-- ) {
3734
3735             # Print the command  unless it has no arguments.
3736             print $OUT "$i: ", $hist[$i], "\n"
3737             unless $hist[$i] =~ /^.?$/;
3738         }
3739
3740         next CMD;
3741     }
3742
3743     return;
3744 }
3745
3746 sub _handle_doc_command {
3747     my $self = shift;
3748
3749     # man, perldoc, doc - show manual pages.
3750     if (my ($man_page)
3751         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3752         DB::runman($man_page);
3753         next CMD;
3754     }
3755
3756     return;
3757 }
3758
3759 sub _handle_p_command {
3760     my $self = shift;
3761
3762     my $print_cmd = 'print {$DB::OUT} ';
3763     # p - print (no args): print $_.
3764     if ($self->_is_full('p')) {
3765         $DB::cmd = $print_cmd . '$_';
3766     }
3767     else {
3768         # p - print the given expression.
3769         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3770     }
3771
3772     return;
3773 }
3774
3775 sub _handle_equal_sign_command {
3776     my $self = shift;
3777
3778     if ($DB::cmd =~ s/\A=\s*//) {
3779         my @keys;
3780         if ( length $DB::cmd == 0 ) {
3781
3782             # No args, get current aliases.
3783             @keys = sort keys %alias;
3784         }
3785         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3786
3787             # Creating a new alias. $k is alias name, $v is
3788             # alias value.
3789
3790             # can't use $_ or kill //g state
3791             for my $x ( $k, $v ) {
3792
3793                 # Escape "alarm" characters.
3794                 $x =~ s/\a/\\a/g;
3795             }
3796
3797             # Substitute key for value, using alarm chars
3798             # as separators (which is why we escaped them in
3799             # the command).
3800             $alias{$k} = "s\a$k\a$v\a";
3801
3802             # Turn off standard warn and die behavior.
3803             local $SIG{__DIE__};
3804             local $SIG{__WARN__};
3805
3806             # Is it valid Perl?
3807             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3808
3809                 # Nope. Bad alias. Say so and get out.
3810                 print $OUT "Can't alias $k to $v: $@\n";
3811                 delete $alias{$k};
3812                 next CMD;
3813             }
3814
3815             # We'll only list the new one.
3816             @keys = ($k);
3817         } ## end elsif (my ($k, $v) = ($DB::cmd...
3818
3819         # The argument is the alias to list.
3820         else {
3821             @keys = ($DB::cmd);
3822         }
3823
3824         # List aliases.
3825         for my $k (@keys) {
3826
3827             # Messy metaquoting: Trim the substitution code off.
3828             # We use control-G as the delimiter because it's not
3829             # likely to appear in the alias.
3830             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3831
3832                 # Print the alias.
3833                 print $OUT "$k\t= $1\n";
3834             }
3835             elsif ( defined $alias{$k} ) {
3836
3837                 # Couldn't trim it off; just print the alias code.
3838                 print $OUT "$k\t$alias{$k}\n";
3839             }
3840             else {
3841
3842                 # No such, dude.
3843                 print "No alias for $k\n";
3844             }
3845         } ## end for my $k (@keys)
3846         next CMD;
3847     }
3848
3849     return;
3850 }
3851
3852 sub _handle_source_command {
3853     my $self = shift;
3854
3855     # source - read commands from a file (or pipe!) and execute.
3856     if (my $sourced_fn = $self->cmd_args) {
3857         if ( open my $fh, $sourced_fn ) {
3858
3859             # Opened OK; stick it in the list of file handles.
3860             push @cmdfhs, $fh;
3861         }
3862         else {
3863
3864             # Couldn't open it.
3865             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3866         }
3867         next CMD;
3868     }
3869
3870     return;
3871 }
3872
3873 sub _handle_enable_disable_commands {
3874     my $self = shift;
3875
3876     my $which_cmd = $self->cmd_verb;
3877     my $position = $self->cmd_args;
3878
3879     if ($position !~ /\s/) {
3880         my ($fn, $line_num);
3881         if ($position =~ m{\A\d+\z})
3882         {
3883             $fn = $DB::filename;
3884             $line_num = $position;
3885         }
3886         elsif (my ($new_fn, $new_line_num)
3887             = $position =~ m{\A(.*):(\d+)\z}) {
3888             ($fn, $line_num) = ($new_fn, $new_line_num);
3889         }
3890         else
3891         {
3892             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3893         }
3894
3895         if (defined($fn)) {
3896             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3897                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3898                     ($which_cmd eq 'enable' ? 1 : '')
3899                 );
3900             }
3901             else {
3902                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3903             }
3904         }
3905
3906         next CMD;
3907     }
3908
3909     return;
3910 }
3911
3912 sub _handle_save_command {
3913     my $self = shift;
3914
3915     if (my $new_fn = $self->cmd_args) {
3916         my $filename = $new_fn || '.perl5dbrc';    # default?
3917         if ( open my $fh, '>', $filename ) {
3918
3919             # chomp to remove extraneous newlines from source'd files
3920             chomp( my @truelist =
3921                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3922                 @truehist );
3923             print {$fh} join( "\n", @truelist );
3924             print "commands saved in $filename\n";
3925         }
3926         else {
3927             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3928         }
3929         next CMD;
3930     }
3931
3932     return;
3933 }
3934
3935 sub _n_or_s_and_arg_commands_generic {
3936     my ($self, $letter, $new_val) = @_;
3937
3938     # s - single-step. Remember the last command was 's'.
3939     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3940         $laststep = $letter;
3941     }
3942
3943     return;
3944 }
3945
3946 sub _handle_sh_command {
3947     my $self = shift;
3948
3949     # $sh$sh - run a shell command (if it's all ASCII).
3950     # Can't run shell commands with Unicode in the debugger, hmm.
3951     my $my_cmd = $DB::cmd;
3952     if ($my_cmd =~ m#\A$sh#gms) {
3953
3954         if ($my_cmd =~ m#\G\z#cgms) {
3955             # Run the user's shell. If none defined, run Bourne.
3956             # We resume execution when the shell terminates.
3957             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3958             next CMD;
3959         }
3960         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3961             # System it.
3962             DB::_db_system($1);
3963             next CMD;
3964         }
3965         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3966             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3967             next CMD;
3968         }
3969     }
3970 }
3971
3972 sub _handle_x_command {
3973     my $self = shift;
3974
3975     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3976         $onetimeDump = 'dump';    # main::dumpvar shows the output
3977
3978         # handle special  "x 3 blah" syntax XXX propagate
3979         # doc back to special variables.
3980         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3981             $onetimedumpDepth = $1;
3982         }
3983     }
3984
3985     return;
3986 }
3987
3988 sub _handle_q_command {
3989     my $self = shift;
3990
3991     if ($self->_is_full('q')) {
3992         $fall_off_end = 1;
3993         DB::clean_ENV();
3994         exit $?;
3995     }
3996
3997     return;
3998 }
3999
4000 sub _handle_cmd_wrapper_commands {
4001     my $self = shift;
4002
4003     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
4004     next CMD;
4005 }
4006
4007 sub _handle_special_char_cmd_wrapper_commands {
4008     my $self = shift;
4009
4010     # All of these commands were remapped in perl 5.8.0;
4011     # we send them off to the secondary dispatcher (see below).
4012     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4013         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4014         next CMD;
4015     }
4016
4017     return;
4018 }
4019
4020 } ## end DB::Obj
4021
4022 package DB;
4023
4024 # The following code may be executed now:
4025 # BEGIN {warn 4}
4026
4027 =head2 sub
4028
4029 C<sub> is called whenever a subroutine call happens in the program being
4030 debugged. The variable C<$DB::sub> contains the name of the subroutine
4031 being called.
4032
4033 The core function of this subroutine is to actually call the sub in the proper
4034 context, capturing its output. This of course causes C<DB::DB> to get called
4035 again, repeating until the subroutine ends and returns control to C<DB::sub>
4036 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4037 return value, and returns its captured copy of the return value as its own
4038 return value. The value then feeds back into the program being debugged as if
4039 C<DB::sub> hadn't been there at all.
4040
4041 C<sub> does all the work of printing the subroutine entry and exit messages
4042 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4043 and also prints the return value if needed (for the C<r> command and if
4044 the 16 bit is set in C<$frame>).
4045
4046 It also tracks the subroutine call depth by saving the current setting of
4047 C<$single> in the C<@stack> package global; if this exceeds the value in
4048 C<$deep>, C<sub> automatically turns on printing of the current depth by
4049 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4050 of stop/don't stop on entry to subs set as it currently is set.
4051
4052 =head3 C<caller()> support
4053
4054 If C<caller()> is called from the package C<DB>, it provides some
4055 additional data, in the following order:
4056
4057 =over 4
4058
4059 =item * C<$package>
4060
4061 The package name the sub was in
4062
4063 =item * C<$filename>
4064
4065 The filename it was defined in
4066
4067 =item * C<$line>
4068
4069 The line number it was defined on
4070
4071 =item * C<$subroutine>
4072
4073 The subroutine name; C<(eval)> if an C<eval>().
4074
4075 =item * C<$hasargs>
4076
4077 1 if it has arguments, 0 if not
4078
4079 =item * C<$wantarray>
4080
4081 1 if array context, 0 if scalar context
4082
4083 =item * C<$evaltext>
4084
4085 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4086
4087 =item * C<$is_require>
4088
4089 frame was created by a C<use> or C<require> statement
4090
4091 =item * C<$hints>
4092
4093 pragma information; subject to change between versions
4094
4095 =item * C<$bitmask>
4096
4097 pragma information; subject to change between versions
4098
4099 =item * C<@DB::args>
4100
4101 arguments with which the subroutine was invoked
4102
4103 =back
4104
4105 =cut
4106
4107 use vars qw($deep);
4108
4109 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4110 # happy. -- Shlomi Fish
4111
4112 sub _indent_print_line_info {
4113     my ($offset, $str) = @_;
4114
4115     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4116
4117     return;
4118 }
4119
4120 sub _print_frame_message {
4121     my ($al) = @_;
4122
4123     if ($frame) {
4124         if ($frame & 4) {   # Extended frame entry message
4125             _indent_print_line_info(-1, "in  ");
4126
4127             # Why -1? But it works! :-(
4128             # Because print_trace will call add 1 to it and then call
4129             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4130             # in dump_trace.
4131             #
4132             # Now it's 0 because we extracted a function.
4133             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4134         }
4135         else {
4136             _indent_print_line_info(-1, "entering $sub$al\n" );
4137         }
4138     }
4139
4140     return;
4141 }
4142
4143 sub DB::sub {
4144     # lock ourselves under threads
4145     lock($DBGR);
4146
4147     # Whether or not the autoloader was running, a scalar to put the
4148     # sub's return value in (if needed), and an array to put the sub's
4149     # return value in (if needed).
4150     my ( $al, $ret, @ret ) = "";
4151     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4152         print "creating new thread\n";
4153     }
4154
4155     # If the last ten characters are '::AUTOLOAD', note we've traced
4156     # into AUTOLOAD for $sub.
4157     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4158         no strict 'refs';
4159         $al = " for $$sub" if defined $$sub;
4160     }
4161
4162     # We stack the stack pointer and then increment it to protect us
4163     # from a situation that might unwind a whole bunch of call frames
4164     # at once. Localizing the stack pointer means that it will automatically
4165     # unwind the same amount when multiple stack frames are unwound.
4166     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4167
4168     # Expand @stack.
4169     $#stack = $stack_depth;
4170
4171     # Save current single-step setting.
4172     $stack[-1] = $single;
4173
4174     # Turn off all flags except single-stepping.
4175     $single &= 1;
4176
4177     # If we've gotten really deeply recursed, turn on the flag that will
4178     # make us stop with the 'deep recursion' message.
4179     $single |= 4 if $stack_depth == $deep;
4180
4181     # If frame messages are on ...
4182
4183     _print_frame_message($al);
4184     # standard frame entry message
4185
4186     my $print_exit_msg = sub {
4187         # Check for exit trace messages...
4188         if ($frame & 2)
4189         {
4190             if ($frame & 4)    # Extended exit message
4191             {
4192                 _indent_print_line_info(0, "out ");
4193                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4194             }
4195             else
4196             {
4197                 _indent_print_line_info(0, "exited $sub$al\n" );
4198             }
4199         }
4200         return;
4201     };
4202
4203     # Determine the sub's return type, and capture appropriately.
4204     if (wantarray) {
4205
4206         # Called in array context. call sub and capture output.
4207         # DB::DB will recursively get control again if appropriate; we'll come
4208         # back here when the sub is finished.
4209         {
4210             no strict 'refs';
4211             @ret = &$sub;
4212         }
4213
4214         # Pop the single-step value back off the stack.
4215         $single |= $stack[ $stack_depth-- ];
4216
4217         $print_exit_msg->();
4218
4219         # Print the return info if we need to.
4220         if ( $doret eq $stack_depth or $frame & 16 ) {
4221
4222             # Turn off output record separator.
4223             local $\ = '';
4224             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4225
4226             # Indent if we're printing because of $frame tracing.
4227             if ($frame & 16)
4228             {
4229                 print {$fh} ' ' x $stack_depth;
4230             }
4231
4232             # Print the return value.
4233             print {$fh} "list context return from $sub:\n";
4234             dumpit( $fh, \@ret );
4235
4236             # And don't print it again.
4237             $doret = -2;
4238         } ## end if ($doret eq $stack_depth...
4239             # And we have to return the return value now.
4240         @ret;
4241     } ## end if (wantarray)
4242
4243     # Scalar context.
4244     else {
4245         if ( defined wantarray ) {
4246             no strict 'refs';
4247             # Save the value if it's wanted at all.
4248             $ret = &$sub;
4249         }
4250         else {
4251             no strict 'refs';
4252             # Void return, explicitly.
4253             &$sub;
4254             undef $ret;
4255         }
4256
4257         # Pop the single-step value off the stack.
4258         $single |= $stack[ $stack_depth-- ];
4259
4260         # If we're doing exit messages...
4261         $print_exit_msg->();
4262
4263         # If we are supposed to show the return value... same as before.
4264         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4265             local $\ = '';
4266             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4267             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4268             print $fh (
4269                 defined wantarray
4270                 ? "scalar context return from $sub: "
4271                 : "void context return from $sub\n"
4272             );
4273             dumpit( $fh, $ret ) if defined wantarray;
4274             $doret = -2;
4275         } ## end if ($doret eq $stack_depth...
4276
4277         # Return the appropriate scalar value.
4278         $ret;
4279     } ## end else [ if (wantarray)
4280 } ## end sub _sub
4281
4282 sub lsub : lvalue {
4283
4284     no strict 'refs';
4285
4286     # lock ourselves under threads
4287     lock($DBGR);
4288
4289     # Whether or not the autoloader was running, a scalar to put the
4290     # sub's return value in (if needed), and an array to put the sub's
4291     # return value in (if needed).
4292     my ( $al, $ret, @ret ) = "";
4293     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4294         print "creating new thread\n";
4295     }
4296
4297     # If the last ten characters are C'::AUTOLOAD', note we've traced
4298     # into AUTOLOAD for $sub.
4299     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4300         $al = " for $$sub";
4301     }
4302
4303     # We stack the stack pointer and then increment it to protect us
4304     # from a situation that might unwind a whole bunch of call frames
4305     # at once. Localizing the stack pointer means that it will automatically
4306     # unwind the same amount when multiple stack frames are unwound.
4307     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4308
4309     # Expand @stack.
4310     $#stack = $stack_depth;
4311
4312     # Save current single-step setting.
4313     $stack[-1] = $single;
4314
4315     # Turn off all flags except single-stepping.
4316     # Use local so the single-step value is popped back off the
4317     # stack for us.
4318     local $single = $single & 1;
4319
4320     # If we've gotten really deeply recursed, turn on the flag that will
4321     # make us stop with the 'deep recursion' message.
4322     $single |= 4 if $stack_depth == $deep;
4323
4324     # If frame messages are on ...
4325     _print_frame_message($al);
4326
4327     # call the original lvalue sub.
4328     &$sub;
4329 }
4330
4331 # Abstracting common code from multiple places elsewhere:
4332 sub depth_print_lineinfo {
4333     my $always_print = shift;
4334
4335     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4336 }
4337
4338 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4339
4340 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4341 Most of the changes were to systematize the command structure and to eliminate
4342 commands that threw away user input without checking.
4343
4344 The following sections describe the code added to make it easy to support
4345 multiple command sets with conflicting command names. This section is a start
4346 at unifying all command processing to make it simpler to develop commands.
4347
4348 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4349 number, and C<$dbline> (the current line) as arguments.
4350
4351 Support functions in this section which have multiple modes of failure C<die>
4352 on error; the rest simply return a false value.
4353
4354 The user-interface functions (all of the C<cmd_*> functions) just output
4355 error messages.
4356
4357 =head2 C<%set>
4358
4359 The C<%set> hash defines the mapping from command letter to subroutine
4360 name suffix.
4361
4362 C<%set> is a two-level hash, indexed by set name and then by command name.
4363 Note that trying to set the CommandSet to C<foobar> simply results in the
4364 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4365
4366 =cut
4367
4368 ### The API section
4369
4370 my %set = (    #
4371     'pre580' => {
4372         'a' => 'pre580_a',
4373         'A' => 'pre580_null',
4374         'b' => 'pre580_b',
4375         'B' => 'pre580_null',
4376         'd' => 'pre580_null',
4377         'D' => 'pre580_D',
4378         'h' => 'pre580_h',
4379         'M' => 'pre580_null',
4380         'O' => 'o',
4381         'o' => 'pre580_null',
4382         'v' => 'M',
4383         'w' => 'v',
4384         'W' => 'pre580_W',
4385     },
4386     'pre590' => {
4387         '<'  => 'pre590_prepost',
4388         '<<' => 'pre590_prepost',
4389         '>'  => 'pre590_prepost',
4390         '>>' => 'pre590_prepost',
4391         '{'  => 'pre590_prepost',
4392         '{{' => 'pre590_prepost',
4393     },
4394 );
4395
4396 my %breakpoints_data;
4397
4398 sub _has_breakpoint_data_ref {
4399     my ($filename, $line) = @_;
4400
4401     return (
4402         exists( $breakpoints_data{$filename} )
4403             and
4404         exists( $breakpoints_data{$filename}{$line} )
4405     );
4406 }
4407
4408 sub _get_breakpoint_data_ref {
4409     my ($filename, $line) = @_;
4410
4411     return ($breakpoints_data{$filename}{$line} ||= +{});
4412 }
4413
4414 sub _delete_breakpoint_data_ref {
4415     my ($filename, $line) = @_;
4416
4417     delete($breakpoints_data{$filename}{$line});
4418     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4419         delete($breakpoints_data{$filename});
4420     }
4421
4422     return;
4423 }
4424
4425 sub _set_breakpoint_enabled_status {
4426     my ($filename, $line, $status) = @_;
4427
4428     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4429         ($status ? 1 : '')
4430         ;
4431
4432     return;
4433 }
4434
4435 sub _enable_breakpoint_temp_enabled_status {
4436     my ($filename, $line) = @_;
4437
4438     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4439
4440     return;
4441 }
4442
4443 sub _cancel_breakpoint_temp_enabled_status {
4444     my ($filename, $line) = @_;
4445
4446     my $ref = _get_breakpoint_data_ref($filename, $line);
4447
4448     delete ($ref->{'temp_enabled'});
4449
4450     if (! %$ref) {
4451         _delete_breakpoint_data_ref($filename, $line);
4452     }
4453
4454     return;
4455 }
4456
4457 sub _is_breakpoint_enabled {
4458     my ($filename, $line) = @_;
4459
4460     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4461     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4462 }
4463
4464 =head2 C<cmd_wrapper()> (API)
4465
4466 C<cmd_wrapper()> allows the debugger to switch command sets
4467 depending on the value of the C<CommandSet> option.
4468
4469 It tries to look up the command in the C<%set> package-level I<lexical>
4470 (which means external entities can't fiddle with it) and create the name of
4471 the sub to call based on the value found in the hash (if it's there). I<All>
4472 of the commands to be handled in a set have to be added to C<%set>; if they
4473 aren't found, the 5.8.0 equivalent is called (if there is one).
4474
4475 This code uses symbolic references.
4476
4477 =cut
4478
4479 sub cmd_wrapper {
4480     my $cmd      = shift;
4481     my $line     = shift;
4482     my $dblineno = shift;
4483
4484     # Assemble the command subroutine's name by looking up the
4485     # command set and command name in %set. If we can't find it,
4486     # default to the older version of the command.
4487     my $call = 'cmd_'
4488       . ( $set{$CommandSet}{$cmd}
4489           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4490
4491     # Call the command subroutine, call it by name.
4492     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4493 } ## end sub cmd_wrapper
4494
4495 =head3 C<cmd_a> (command)
4496
4497 The C<a> command handles pre-execution actions. These are associated with a
4498 particular line, so they're stored in C<%dbline>. We default to the current
4499 line if none is specified.
4500
4501 =cut
4502
4503 sub cmd_a {
4504     my $cmd    = shift;
4505     my $line   = shift || '';    # [.|line] expr
4506     my $dbline = shift;
4507
4508     # If it's dot (here), or not all digits,  use the current line.
4509     $line =~ s/\A\./$dbline/;
4510
4511     # Should be a line number followed by an expression.
4512     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4513
4514         if (! length($lineno)) {
4515             $lineno = $dbline;
4516         }
4517
4518         # If we have an expression ...
4519         if ( length $expr ) {
4520
4521             # ... but the line isn't breakable, complain.
4522             if ( $dbline[$lineno] == 0 ) {
4523                 print $OUT
4524                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4525             }
4526             else {
4527
4528                 # It's executable. Record that the line has an action.
4529                 $had_breakpoints{$filename} |= 2;
4530
4531                 # Remove any action, temp breakpoint, etc.
4532                 $dbline{$lineno} =~ s/\0[^\0]*//;
4533
4534                 # Add the action to the line.
4535                 $dbline{$lineno} .= "\0" . action($expr);
4536
4537                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4538             }
4539         } ## end if (length $expr)
4540     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4541     else {
4542
4543         # Syntax wrong.
4544         print $OUT
4545           "Adding an action requires an optional lineno and an expression\n"
4546           ;    # hint
4547     }
4548 } ## end sub cmd_a
4549
4550 =head3 C<cmd_A> (command)
4551
4552 Delete actions. Similar to above, except the delete code is in a separate
4553 subroutine, C<delete_action>.
4554
4555 =cut
4556
4557 sub cmd_A {
4558     my $cmd    = shift;
4559     my $line   = shift || '';
4560     my $dbline = shift;
4561
4562     # Dot is this line.
4563     $line =~ s/^\./$dbline/;
4564
4565     # Call delete_action with a null param to delete them all.
4566     # The '1' forces the eval to be true. It'll be false only
4567     # if delete_action blows up for some reason, in which case
4568     # we print $@ and get out.
4569     if ( $line eq '*' ) {
4570         if (! eval { _delete_all_actions(); 1 }) {
4571             print {$OUT} $@;
4572             return;
4573         }
4574     }
4575
4576     # There's a real line  number. Pass it to delete_action.
4577     # Error trapping is as above.
4578     elsif ( $line =~ /^(\S.*)/ ) {
4579         if (! eval { delete_action($1); 1 }) {
4580             print {$OUT} $@;
4581             return;
4582         }
4583     }
4584
4585     # Swing and a miss. Bad syntax.
4586     else {
4587         print $OUT
4588           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4589     }
4590 } ## end sub cmd_A
4591
4592 =head3 C<delete_action> (API)
4593
4594 C<delete_action> accepts either a line number or C<undef>. If a line number
4595 is specified, we check for the line being executable (if it's not, it
4596 couldn't have had an  action). If it is, we just take the action off (this
4597 will get any kind of an action, including breakpoints).
4598
4599 =cut
4600
4601 sub _remove_action_from_dbline {
4602     my $i = shift;
4603
4604     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4605     delete $dbline{$i} if $dbline{$i} eq '';
4606
4607     return;
4608 }
4609
4610 sub _delete_all_actions {
4611     print {$OUT} "Deleting all actions...\n";
4612
4613     for my $file ( keys %had_breakpoints ) {
4614         local *dbline = $main::{ '_<' . $file };
4615         $max = $#dbline;
4616         my $was;
4617         for my $i (1 .. $max) {
4618             if ( defined $dbline{$i} ) {
4619                 _remove_action_from_dbline($i);
4620             }
4621         }
4622
4623         unless ( $had_breakpoints{$file} &= ~2 ) {
4624             delete $had_breakpoints{$file};
4625         }
4626     }
4627
4628     return;
4629 }
4630
4631 sub delete_action {
4632     my $i = shift;
4633
4634     if ( defined($i) ) {
4635         # Can there be one?
4636         die "Line $i has no action .\n" if $dbline[$i] == 0;
4637
4638         # Nuke whatever's there.
4639         _remove_action_from_dbline($i);
4640     }
4641     else {
4642         _delete_all_actions();
4643     }
4644 }
4645
4646 =head3 C<cmd_b> (command)
4647
4648 Set breakpoints. Since breakpoints can be set in so many places, in so many
4649 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4650 we try to parse the command type, and then shuttle it off to an appropriate
4651 subroutine to actually do the work of setting the breakpoint in the right
4652 place.
4653
4654 =cut
4655
4656 sub cmd_b {
4657     my $cmd    = shift;
4658     my $line   = shift;    # [.|line] [cond]
4659     my $dbline = shift;
4660
4661     my $default_cond = sub {
4662         my $cond = shift;
4663         return length($cond) ? $cond : '1';
4664     };
4665
4666     # Make . the current line number if it's there..
4667     $line =~ s/^\.(\s|\z)/$dbline$1/;
4668
4669     # No line number, no condition. Simple break on current line.
4670     if ( $line =~ /^\s*$/ ) {
4671         cmd_b_line( $dbline, 1 );
4672     }
4673
4674     # Break on load for a file.
4675     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4676         $file =~ s/\s+\z//;
4677         cmd_b_load($file);
4678     }
4679
4680     # b compile|postpone <some sub> [<condition>]
4681     # The interpreter actually traps this one for us; we just put the
4682     # necessary condition in the %postponed hash.
4683     elsif ( my ($action, $subname, $cond)
4684         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4685
4686         # De-Perl4-ify the name - ' separators to ::.
4687         $subname =~ s/'/::/g;
4688
4689         # Qualify it into the current package unless it's already qualified.
4690         $subname = "${package}::" . $subname unless $subname =~ /::/;
4691
4692         # Add main if it starts with ::.
4693         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4694
4695         # Save the break type for this sub.
4696         $postponed{$subname} = (($action eq 'postpone')
4697             ? ( "break +0 if " . $default_cond->($cond) )
4698             : "compile");
4699     } ## end elsif ($line =~ ...
4700     # b <filename>:<line> [<condition>]
4701     elsif (my ($filename, $line_num, $cond)
4702         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4703         cmd_b_filename_line(
4704             $filename,
4705             $line_num,
4706             (length($cond) ? $cond : '1'),
4707         );
4708     }
4709     # b <sub name> [<condition>]
4710     elsif ( my ($new_subname, $new_cond) =
4711         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4712
4713         #
4714         $subname = $new_subname;
4715         cmd_b_sub( $subname, $default_cond->($new_cond) );
4716     }
4717
4718     # b <line> [<condition>].
4719     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4720
4721         # Capture the line. If none, it's the current line.
4722         $line = $line_n || $dbline;
4723
4724         # Break on line.
4725         cmd_b_line( $line, $default_cond->($cond) );
4726     }
4727
4728     # Line didn't make sense.
4729     else {
4730         print "confused by line($line)?\n";
4731     }
4732
4733     return;
4734 } ## end sub cmd_b
4735
4736 =head3 C<break_on_load> (API)
4737
4738 We want to break when this file is loaded. Mark this file in the
4739 C<%break_on_load> hash, and note that it has a breakpoint in
4740 C<%had_breakpoints>.
4741
4742 =cut
4743
4744 sub break_on_load {
4745     my $file = shift;
4746     $break_on_load{$file} = 1;
4747     $had_breakpoints{$file} |= 1;
4748 }
4749
4750 =head3 C<report_break_on_load> (API)
4751
4752 Gives us an array of filenames that are set to break on load. Note that
4753 only files with break-on-load are in here, so simply showing the keys
4754 suffices.
4755
4756 =cut
4757
4758 sub report_break_on_load {
4759     sort keys %break_on_load;
4760 }
4761
4762 =head3 C<cmd_b_load> (command)
4763
4764 We take the file passed in and try to find it in C<%INC> (which maps modules
4765 to files they came from). We mark those files for break-on-load via
4766 C<break_on_load> and then report that it was done.
4767
4768 =cut
4769
4770 sub cmd_b_load {
4771     my $file = shift;
4772     my @files;
4773
4774     # This is a block because that way we can use a redo inside it
4775     # even without there being any looping structure at all outside it.
4776     {
4777
4778         # Save short name and full path if found.
4779         push @files, $file;
4780         push @files, $::INC{$file} if $::INC{$file};
4781
4782         # Tack on .pm and do it again unless there was a '.' in the name
4783         # already.
4784         $file .= '.pm', redo unless $file =~ /\./;
4785     }
4786
4787     # Do the real work here.
4788     break_on_load($_) for @files;
4789
4790     # All the files that have break-on-load breakpoints.
4791     @files = report_break_on_load;
4792
4793     # Normalize for the purposes of our printing this.
4794     local $\ = '';
4795     local $" = ' ';
4796     print $OUT "Will stop on load of '@files'.\n";
4797 } ## end sub cmd_b_load
4798
4799 =head3 C<$filename_error> (API package global)
4800
4801 Several of the functions we need to implement in the API need to work both
4802 on the current file and on other files. We don't want to duplicate code, so
4803 C<$filename_error> is used to contain the name of the file that's being
4804 worked on (if it's not the current one).
4805
4806 We can now build functions in pairs: the basic function works on the current
4807 file, and uses C<$filename_error> as part of its error message. Since this is
4808 initialized to C<"">, no filename will appear when we are working on the
4809 current file.
4810
4811 The second function is a wrapper which does the following:
4812
4813 =over 4
4814
4815 =item *
4816
4817 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4818
4819 =item *
4820
4821 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4822
4823 =item *
4824
4825 Calls the first function.
4826
4827 The first function works on the I<current> file (i.e., the one we changed to),
4828 and prints C<$filename_error> in the error message (the name of the other file)
4829 if it needs to. When the functions return, C<*dbline> is restored to point
4830 to the actual current file (the one we're executing in) and
4831 C<$filename_error> is restored to C<"">. This restores everything to
4832 the way it was before the second function was called at all.
4833
4834 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4835 details.
4836
4837 =back
4838
4839 =cut
4840
4841 use vars qw($filename_error);
4842 $filename_error = '';
4843
4844 =head3 breakable_line(from, to) (API)
4845
4846 The subroutine decides whether or not a line in the current file is breakable.
4847 It walks through C<@dbline> within the range of lines specified, looking for
4848 the first line that is breakable.
4849
4850 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4851 first line I<after> C<$to> that's breakable, if there is one.
4852
4853 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4854 first line I<before> C<$to> that's breakable, if there is one.
4855
4856 =cut
4857
4858 sub breakable_line {
4859
4860     my ( $from, $to ) = @_;
4861
4862     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4863     my $i = $from;
4864
4865     # If there are at least 2 arguments, we're trying to search a range.
4866     if ( @_ >= 2 ) {
4867
4868         # $delta is positive for a forward search, negative for a backward one.
4869         my $delta = $from < $to ? +1 : -1;
4870
4871         # Keep us from running off the ends of the file.
4872         my $limit = $delta > 0 ? $#dbline : 1;
4873
4874         # Clever test. If you're a mathematician, it's obvious why this
4875         # test works. If not:
4876         # If $delta is positive (going forward), $limit will be $#dbline.
4877         #    If $to is less than $limit, ($limit - $to) will be positive, times
4878         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4879         #    as the stopping point.
4880         #
4881         #    If $to is greater than $limit, ($limit - $to) is negative,
4882         #    times $delta of 1 (positive), so the result is < 0 and we should
4883         #    use $limit ($#dbline) as the stopping point.
4884         #
4885         # If $delta is negative (going backward), $limit will be 1.
4886         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4887         #    (negative) so the result is > 0, and we use $to as the stopping
4888         #    point.
4889         #
4890         #    If $to is less than zero, ($limit - $to) will be positive,
4891         #    times $delta of -1 (negative), so the result is not > 0, and
4892         #    we use $limit (1) as the stopping point.
4893         #
4894         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4895         #    (negative), still giving zero; the result is not > 0, and
4896         #    we use $limit (1) as the stopping point.
4897         #
4898         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4899         #    (negative), giving a positive (>0) value, so we'll set $limit to
4900         #    $to.
4901
4902         $limit = $to if ( $limit - $to ) * $delta > 0;
4903
4904         # The real search loop.
4905         # $i starts at $from (the point we want to start searching from).
4906         # We move through @dbline in the appropriate direction (determined
4907         # by $delta: either -1 (back) or +1 (ahead).
4908         # We stay in as long as we haven't hit an executable line
4909         # ($dbline[$i] == 0 means not executable) and we haven't reached
4910         # the limit yet (test similar to the above).
4911         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4912
4913     } ## end if (@_ >= 2)
4914
4915     # If $i points to a line that is executable, return that.
4916     return $i unless $dbline[$i] == 0;
4917
4918     # Format the message and print it: no breakable lines in range.
4919     my ( $pl, $upto ) = ( '', '' );
4920     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4921
4922     # If there's a filename in filename_error, we'll see it.
4923     # If not, not.
4924     die "Line$pl $from$upto$filename_error not breakable\n";
4925 } ## end sub breakable_line
4926
4927 =head3 breakable_line_in_filename(file, from, to) (API)
4928
4929 Like C<breakable_line>, but look in another file.
4930
4931 =cut
4932
4933 sub breakable_line_in_filename {
4934
4935     # Capture the file name.
4936     my ($f) = shift;
4937
4938     # Swap the magic line array over there temporarily.
4939     local *dbline = $main::{ '_<' . $f };
4940
4941     # If there's an error, it's in this other file.
4942     local $filename_error = " of '$f'";
4943
4944     # Find the breakable line.
4945     breakable_line(@_);
4946
4947     # *dbline and $filename_error get restored when this block ends.
4948
4949 } ## end sub breakable_line_in_filename
4950
4951 =head3 break_on_line(lineno, [condition]) (API)
4952
4953 Adds a breakpoint with the specified condition (or 1 if no condition was
4954 specified) to the specified line. Dies if it can't.
4955
4956 =cut
4957
4958 sub break_on_line {
4959     my $i = shift;
4960     my $cond = @_ ? shift(@_) : 1;
4961
4962     my $inii  = $i;
4963     my $after = '';
4964     my $pl    = '';
4965
4966     # Woops, not a breakable line. $filename_error allows us to say
4967     # if it was in a different file.
4968     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4969
4970     # Mark this file as having breakpoints in it.
4971     $had_breakpoints{$filename} |= 1;
4972
4973     # If there is an action or condition here already ...
4974     if ( $dbline{$i} ) {
4975
4976         # ... swap this condition for the existing one.
4977         $dbline{$i} =~ s/^[^\0]*/$cond/;
4978     }
4979     else {
4980
4981         # Nothing here - just add the condition.
4982         $dbline{$i} = $cond;
4983
4984         _set_breakpoint_enabled_status($filename, $i, 1);
4985     }
4986
4987     return;
4988 } ## end sub break_on_line
4989
4990 =head3 cmd_b_line(line, [condition]) (command)
4991
4992 Wrapper for C<break_on_line>. Prints the failure message if it
4993 doesn't work.
4994
4995 =cut
4996
4997 sub cmd_b_line {
4998     if (not eval { break_on_line(@_); 1 }) {
4999         local $\ = '';
5000         print $OUT $@ and return;
5001     }
5002
5003     return;
5004 } ## end sub cmd_b_line
5005
5006 =head3 cmd_b_filename_line(line, [condition]) (command)
5007
5008 Wrapper for C<break_on_filename_line>. Prints the failure message if it
5009 doesn't work.
5010
5011 =cut
5012
5013 sub cmd_b_filename_line {
5014     if (not eval { break_on_filename_line(@_); 1 }) {
5015         local $\ = '';
5016         print $OUT $@ and return;
5017     }
5018
5019     return;
5020 }
5021
5022 =head3 break_on_filename_line(file, line, [condition]) (API)
5023
5024 Switches to the file specified and then calls C<break_on_line> to set
5025 the breakpoint.
5026
5027 =cut
5028
5029 sub break_on_filename_line {
5030     my $f = shift;
5031     my $i = shift;
5032     my $cond = @_ ? shift(@_) : 1;
5033
5034     # Switch the magical hash temporarily.
5035     local *dbline = $main::{ '_<' . $f };
5036
5037     # Localize the variables that break_on_line uses to make its message.
5038     local $filename_error = " of '$f'";
5039     local $filename       = $f;
5040
5041     # Add the breakpoint.
5042     break_on_line( $i, $cond );
5043
5044     return;
5045 } ## end sub break_on_filename_line
5046
5047 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
5048
5049 Switch to another file, search the range of lines specified for an
5050 executable one, and put a breakpoint on the first one you find.
5051
5052 =cut
5053
5054 sub break_on_filename_line_range {
5055     my $f = shift;
5056     my $from = shift;
5057     my $to = shift;
5058     my $cond = @_ ? shift(@_) : 1;
5059
5060     # Find a breakable line if there is one.
5061     my $i = breakable_line_in_filename( $f, $from, $to );
5062
5063     # Add the breakpoint.
5064     break_on_filename_line( $f, $i, $cond );
5065
5066     return;
5067 } ## end sub break_on_filename_line_range
5068
5069 =head3 subroutine_filename_lines(subname, [condition]) (API)
5070
5071 Search for a subroutine within a given file. The condition is ignored.
5072 Uses C<find_sub> to locate the desired subroutine.
5073
5074 =cut
5075
5076 sub subroutine_filename_lines {
5077     my ( $subname ) = @_;
5078
5079     # Returned value from find_sub() is fullpathname:startline-endline.
5080     # The match creates the list (fullpathname, start, end).
5081     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5082 } ## end sub subroutine_filename_lines
5083
5084 =head3 break_subroutine(subname) (API)
5085
5086 Places a break on the first line possible in the specified subroutine. Uses
5087 C<subroutine_filename_lines> to find the subroutine, and
5088 C<break_on_filename_line_range> to place the break.
5089
5090 =cut
5091
5092 sub break_subroutine {
5093     my $subname = shift;
5094
5095     # Get filename, start, and end.
5096     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5097       or die "Subroutine $subname not found.\n";
5098
5099
5100     # Null condition changes to '1' (always true).
5101     my $cond = @_ ? shift(@_) : 1;
5102
5103     # Put a break the first place possible in the range of lines
5104     # that make up this subroutine.
5105     break_on_filename_line_range( $file, $s, $e, $cond );
5106
5107     return;
5108 } ## end sub break_subroutine
5109
5110 =head3 cmd_b_sub(subname, [condition]) (command)
5111
5112 We take the incoming subroutine name and fully-qualify it as best we can.
5113
5114 =over 4
5115
5116 =item 1. If it's already fully-qualified, leave it alone.
5117
5118 =item 2. Try putting it in the current package.
5119
5120 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5121
5122 =item 4. If it starts with '::', put it in 'main::'.
5123
5124 =back
5125
5126 After all this cleanup, we call C<break_subroutine> to try to set the
5127 breakpoint.
5128
5129 =cut
5130
5131 sub cmd_b_sub {
5132     my $subname = shift;
5133     my $cond = @_ ? shift : 1;
5134
5135     # If the subname isn't a code reference, qualify it so that
5136     # break_subroutine() will work right.
5137     if ( ref($subname) ne 'CODE' ) {
5138
5139         # Not Perl 4.
5140         $subname =~ s/'/::/g;
5141         my $s = $subname;
5142
5143         # Put it in this package unless it's already qualified.
5144         if ($subname !~ /::/)
5145         {
5146             $subname = $package . '::' . $subname;
5147         };
5148
5149         # Requalify it into CORE::GLOBAL if qualifying it into this
5150         # package resulted in its not being defined, but only do so
5151         # if it really is in CORE::GLOBAL.
5152         my $core_name = "CORE::GLOBAL::$s";
5153         if ((!defined(&$subname))
5154                 and ($s !~ /::/)
5155                 and (defined &{$core_name}))
5156         {
5157             $subname = $core_name;
5158         }
5159
5160         # Put it in package 'main' if it has a leading ::.
5161         if ($subname =~ /\A::/)
5162         {
5163             $subname = "main" . $subname;
5164         }
5165     } ## end if ( ref($subname) ne 'CODE' ) {
5166
5167     # Try to set the breakpoint.
5168     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5169         local $\ = '';
5170         print {$OUT} $@;
5171         return;
5172     }
5173
5174     return;
5175 } ## end sub cmd_b_sub
5176
5177 =head3 C<cmd_B> - delete breakpoint(s) (command)
5178
5179 The command mostly parses the command line and tries to turn the argument
5180 into a line spec. If it can't, it uses the current line. It then calls
5181 C<delete_breakpoint> to actually do the work.
5182
5183 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5184 thereby deleting all the breakpoints.
5185
5186 =cut
5187
5188 sub cmd_B {
5189     my $cmd = shift;
5190
5191     # No line spec? Use dbline.
5192     # If there is one, use it if it's non-zero, or wipe it out if it is.
5193     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5194     my $dbline = shift;
5195
5196     # If the line was dot, make the line the current one.
5197     $line =~ s/^\./$dbline/;
5198
5199     # If it's * we're deleting all the breakpoints.
5200     if ( $line eq '*' ) {
5201         if (not eval { delete_breakpoint(); 1 }) {
5202             print {$OUT} $@;
5203         }
5204     }
5205
5206     # If there is a line spec, delete the breakpoint on that line.
5207     elsif ( $line =~ /\A(\S.*)/ ) {
5208         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5209             local $\ = '';
5210             print {$OUT} $@;
5211         }
5212     } ## end elsif ($line =~ /^(\S.*)/)
5213
5214     # No line spec.
5215     else {
5216         print {$OUT}
5217           "Deleting a breakpoint requires a line number, or '*' for all\n"
5218           ;    # hint
5219     }
5220
5221     return;
5222 } ## end sub cmd_B
5223
5224 =head3 delete_breakpoint([line]) (API)
5225
5226 This actually does the work of deleting either a single breakpoint, or all
5227 of them.
5228
5229 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5230 just drop out with a message saying so. If it is, we remove the condition
5231 part of the 'condition\0action' that says there's a breakpoint here. If,
5232 after we've done that, there's nothing left, we delete the corresponding
5233 line in C<%dbline> to signal that no action needs to be taken for this line.
5234
5235 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5236 which lists all currently-loaded files which have breakpoints. We then look
5237 at each line in each of these files, temporarily switching the C<%dbline>
5238 and C<@dbline> structures to point to the files in question, and do what
5239 we did in the single line case: delete the condition in C<@dbline>, and
5240 delete the key in C<%dbline> if nothing's left.
5241
5242 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5243 C<%break_on_load>, because these structures contain breakpoints for files
5244 and code that haven't been loaded yet. We can just kill these off because there
5245 are no magical debugger structures associated with them.
5246
5247 =cut
5248
5249 sub _remove_breakpoint_entry {
5250     my ($fn, $i) = @_;
5251
5252     delete $dbline{$i};
5253     _delete_breakpoint_data_ref($fn, $i);
5254
5255     return;
5256 }
5257
5258 sub _delete_all_breakpoints {
5259     print {$OUT} "Deleting all breakpoints...\n";
5260
5261     # %had_breakpoints lists every file that had at least one
5262     # breakpoint in it.
5263     for my $fn ( keys %had_breakpoints ) {
5264
5265         # Switch to the desired file temporarily.
5266         local *dbline = $main::{ '_<' . $fn };
5267
5268         $max = $#dbline;
5269
5270         # For all lines in this file ...
5271         for my $i (1 .. $max) {
5272
5273             # If there's a breakpoint or action on this line ...
5274             if ( defined $dbline{$i} ) {
5275
5276                 # ... remove the breakpoint.
5277                 $dbline{$i} =~ s/\A[^\0]+//;
5278                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5279                     # Remove the entry altogether if no action is there.
5280                     _remove_breakpoint_entry($fn, $i);
5281                 }
5282             } ## end if (defined $dbline{$i...
5283         } ## end for $i (1 .. $max)
5284
5285         # If, after we turn off the "there were breakpoints in this file"
5286         # bit, the entry in %had_breakpoints for this file is zero,
5287         # we should remove this file from the hash.
5288         if ( not $had_breakpoints{$fn} &= (~1) ) {
5289             delete $had_breakpoints{$fn};
5290         }
5291     } ## end for my $fn (keys %had_breakpoints)
5292
5293     # Kill off all the other breakpoints that are waiting for files that
5294     # haven't been loaded yet.
5295     undef %postponed;
5296     undef %postponed_file;
5297     undef %break_on_load;
5298
5299     return;
5300 }
5301
5302 sub _delete_breakpoint_from_line {
5303     my ($i) = @_;
5304
5305     # Woops. This line wasn't breakable at all.
5306     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5307
5308     # Kill the condition, but leave any action.
5309     $dbline{$i} =~ s/\A[^\0]*//;
5310
5311     # Remove the entry entirely if there's no action left.
5312     if ($dbline{$i} eq '') {
5313         _remove_breakpoint_entry($filename, $i);
5314     }
5315
5316     return;
5317 }
5318
5319 sub delete_breakpoint {
5320     my $i = shift;
5321
5322     # If we got a line, delete just that one.
5323     if ( defined($i) ) {
5324         _delete_breakpoint_from_line($i);
5325     }
5326     # No line; delete them all.
5327     else {
5328         _delete_all_breakpoints();
5329     }
5330
5331     return;
5332 }
5333
5334 =head3 cmd_stop (command)
5335
5336 This is meant to be part of the new command API, but it isn't called or used
5337 anywhere else in the debugger. XXX It is probably meant for use in development
5338 of new commands.
5339
5340 =cut
5341
5342 sub cmd_stop {    # As on ^C, but not signal-safy.
5343     $signal = 1;
5344 }
5345
5346 =head3 C<cmd_e> - threads
5347
5348 Display the current thread id:
5349
5350     e
5351
5352 This could be how (when implemented) to send commands to this thread id (e cmd)
5353 or that thread id (e tid cmd).
5354
5355 =cut
5356
5357 sub cmd_e {
5358     my $cmd  = shift;
5359     my $line = shift;
5360     unless (exists($INC{'threads.pm'})) {
5361         print "threads not loaded($ENV{PERL5DB_THREADED})
5362         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5363     } else {
5364         my $tid = threads->tid;
5365         print "thread id: $tid\n";
5366     }
5367 } ## end sub cmd_e
5368
5369 =head3 C<cmd_E> - list of thread ids
5370
5371 Display the list of available thread ids:
5372
5373     E
5374
5375 This could be used (when implemented) to send commands to all threads (E cmd).
5376
5377 =cut
5378
5379 sub cmd_E {
5380     my $cmd  = shift;
5381     my $line = shift;
5382     unless (exists($INC{'threads.pm'})) {
5383         print "threads not loaded($ENV{PERL5DB_THREADED})
5384         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5385     } else {
5386         my $tid = threads->tid;
5387         print "thread ids: ".join(', ',
5388             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5389         )."\n";
5390     }
5391 } ## end sub cmd_E
5392
5393 =head3 C<cmd_h> - help command (command)
5394
5395 Does the work of either
5396
5397 =over 4
5398
5399 =item *
5400
5401 Showing all the debugger help
5402
5403 =item *
5404
5405 Showing help for a specific command
5406
5407 =back
5408
5409 =cut
5410
5411 use vars qw($help);
5412 use vars qw($summary);
5413
5414 sub cmd_h {
5415     my $cmd = shift;
5416
5417     # If we have no operand, assume null.
5418     my $line = shift || '';
5419
5420     # 'h h'. Print the long-format help.
5421     if ( $line =~ /\Ah\s*\z/ ) {
5422         print_help($help);
5423     }
5424
5425     # 'h <something>'. Search for the command and print only its help.
5426     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5427
5428         # support long commands; otherwise bogus errors
5429         # happen when you ask for h on <CR> for example
5430         my $qasked = quotemeta($asked);    # for searching; we don't
5431                                            # want to use it as a pattern.
5432                                            # XXX: finds CR but not <CR>
5433
5434         # Search the help string for the command.
5435         if (
5436             $help =~ /^                    # Start of a line
5437                       <?                   # Optional '<'
5438                       (?:[IB]<)            # Optional markup
5439                       $qasked              # The requested command
5440                      /mx
5441           )
5442         {
5443
5444             # It's there; pull it out and print it.
5445             while (
5446                 $help =~ /^
5447                               (<?            # Optional '<'
5448                                  (?:[IB]<)   # Optional markup
5449                                  $qasked     # The command
5450                                  ([\s\S]*?)  # Description line(s)
5451                               \n)            # End of last description line
5452                               (?!\s)         # Next line not starting with
5453                                              # whitespace
5454                              /mgx
5455               )
5456             {
5457                 print_help($1);
5458             }
5459         }
5460
5461         # Not found; not a debugger command.
5462         else {
5463             print_help("B<$asked> is not a debugger command.\n");
5464         }
5465     } ## end elsif ($line =~ /^(\S.*)$/)
5466
5467     # 'h' - print the summary help.
5468     else {
5469         print_help($summary);
5470     }
5471 } ## end sub cmd_h
5472
5473 =head3 C<cmd_i> - inheritance display
5474
5475 Display the (nested) parentage of the module or object given.
5476
5477 =cut
5478
5479 sub cmd_i {
5480     my $cmd  = shift;
5481     my $line = shift;
5482     foreach my $isa ( split( /\s+/, $line ) ) {
5483         $evalarg = $isa;
5484         # The &-call is here to ascertain the mutability of @_.
5485         ($isa) = &DB::eval;
5486         no strict 'refs';
5487         print join(
5488             ', ',
5489             map {
5490                 "$_"
5491                   . (
5492                     defined( ${"$_\::VERSION"} )
5493                     ? ' ' . ${"$_\::VERSION"}
5494                     : undef )
5495               } @{mro::get_linear_isa(ref($isa) || $isa)}
5496         );
5497         print "\n";
5498     }
5499 } ## end sub cmd_i
5500
5501 =head3 C<cmd_l> - list lines (command)
5502
5503 Most of the command is taken up with transforming all the different line
5504 specification syntaxes into 'start-stop'. After that is done, the command
5505 runs a loop over C<@dbline> for the specified range of lines. It handles
5506 the printing of each line and any markers (C<==E<gt>> for current line,
5507 C<b> for break on this line, C<a> for action on this line, C<:> for this
5508 line breakable).
5509
5510 We save the last line listed in the C<$start> global for further listing
5511 later.
5512
5513 =cut
5514
5515 sub _min {
5516     my $min = shift;
5517     foreach my $v (@_) {
5518         if ($min > $v) {
5519             $min = $v;
5520         }
5521     }
5522     return $min;
5523 }
5524
5525 sub _max {
5526     my $max = shift;
5527     foreach my $v (@_) {
5528         if ($max < $v) {
5529             $max = $v;
5530         }
5531     }
5532     return $max;
5533 }
5534
5535 sub _minify_to_max {
5536     my $ref = shift;
5537
5538     $$ref = _min($$ref, $max);
5539
5540     return;
5541 }
5542
5543 sub _cmd_l_handle_var_name {
5544     my $var_name = shift;
5545
5546     $evalarg = $var_name;
5547
5548     my ($s) = DB::eval();
5549
5550     # Ooops. Bad scalar.
5551     if ($@) {
5552         print {$OUT} "Error: $@\n";
5553         next CMD;
5554     }
5555
5556     # Good scalar. If it's a reference, find what it points to.
5557     $s = CvGV_name($s);
5558     print {$OUT} "Interpreted as: $1 $s\n";
5559     $line = "$1 $s";
5560
5561     # Call self recursively to really do the command.
5562     return _cmd_l_main( $s );
5563 }
5564
5565 sub _cmd_l_handle_subname {
5566
5567     my $s = $subname;
5568
5569     # De-Perl4.
5570     $subname =~ s/\'/::/;
5571
5572     # Put it in this package unless it starts with ::.
5573     $subname = $package . "::" . $subname unless $subname =~ /::/;
5574
5575     # Put it in CORE::GLOBAL if t doesn't start with :: and
5576     # it doesn't live in this package and it lives in CORE::GLOBAL.
5577     $subname = "CORE::GLOBAL::$s"
5578     if not defined &$subname
5579         and $s !~ /::/
5580         and defined &{"CORE::GLOBAL::$s"};
5581
5582     # Put leading '::' names into 'main::'.
5583     $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5584
5585     # Get name:start-stop from find_sub, and break this up at
5586     # colons.
5587     my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5588
5589     # Pull off start-stop.
5590     my $subrange = pop @pieces;
5591
5592     # If the name contained colons, the split broke it up.
5593     # Put it back together.
5594     $file = join( ':', @pieces );
5595
5596     # If we're not in that file, switch over to it.
5597     if ( $file ne $filename ) {
5598         if (! $slave_editor) {
5599             print {$OUT} "Switching to file '$file'.\n";
5600         }
5601
5602         # Switch debugger's magic structures.
5603         *dbline   = $main::{ '_<' . $file };
5604         $max      = $#dbline;
5605         $filename = $file;
5606     } ## end if ($file ne $filename)
5607
5608     # Subrange is 'start-stop'. If this is less than a window full,
5609     # swap it to 'start+', which will list a window from the start point.
5610     if ($subrange) {
5611         if ( eval($subrange) < -$window ) {
5612             $subrange =~ s/-.*/+/;
5613         }
5614
5615         # Call self recursively to list the range.
5616         return _cmd_l_main( $subrange );
5617     } ## end if ($subrange)
5618
5619     # Couldn't find it.
5620     else {
5621         print {$OUT} "Subroutine $subname not found.\n";
5622         return;
5623     }
5624 }
5625
5626 sub _cmd_l_empty {
5627     # Compute new range to list.
5628     $incr = $window - 1;
5629
5630     # Recurse to do it.
5631     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5632 }
5633
5634 sub _cmd_l_plus {
5635     my ($new_start, $new_incr) = @_;
5636
5637     # Don't reset start for 'l +nnn'.
5638     $start = $new_start if $new_start;
5639
5640     # Increment for list. Use window size if not specified.
5641     # (Allows 'l +' to work.)
5642     $incr = $new_incr || ($window - 1);
5643
5644     # Create a line range we'll understand, and recurse to do it.
5645     return _cmd_l_main( $start . '-' . ( $start + $incr ) );
5646 }
5647
5648 sub _cmd_l_calc_initial_end_and_i {
5649     my ($spec, $start_match, $end_match) = @_;
5650
5651     # Determine end point; use end of file if not specified.
5652     my $end = ( !defined $start_match ) ? $max :
5653     ( $end_match ? $end_match : $start_match );
5654
5655     # Go on to the end, and then stop.
5656     _minify_to_max(\$end);
5657
5658     # Determine start line.
5659     my $i = $start_match;
5660
5661     if ($i eq '.') {
5662         $i = $spec;
5663     }
5664
5665     $i = _max($i, 1);
5666
5667     $incr = $end - $i;
5668
5669     return ($end, $i);
5670 }
5671
5672 sub _cmd_l_range {
5673     my ($spec, $current_line, $start_match, $end_match) = @_;
5674
5675     my ($end, $i) =
5676         _cmd_l_calc_initial_end_and_i($spec, $start_match, $end_match);
5677
5678     # If we're running under a slave editor, force it to show the lines.
5679     if ($slave_editor) {
5680         print {$OUT} "\032\032$filename:$i:0\n";
5681         $i = $end;
5682     }
5683     # We're doing it ourselves. We want to show the line and special
5684     # markers for:
5685     # - the current line in execution
5686     # - whether a line is breakable or not
5687     # - whether a line has a break or not
5688     # - whether a line has an action or not
5689     else {
5690         I_TO_END:
5691         for ( ; $i <= $end ; $i++ ) {
5692
5693             # Check for breakpoints and actions.
5694             my ( $stop, $action );
5695             if ($dbline{$i}) {
5696                 ( $stop, $action ) = split( /\0/, $dbline{$i} );
5697             }
5698
5699             # ==> if this is the current line in execution,
5700             # : if it's breakable.
5701             my $arrow =
5702             ( $i == $current_line and $filename eq $filename_ini )
5703             ? '==>'
5704             : ( $dbline[$i] + 0 ? ':' : ' ' );
5705
5706             # Add break and action indicators.
5707             $arrow .= 'b' if $stop;
5708             $arrow .= 'a' if $action;
5709
5710             # Print the line.
5711             print {$OUT} "$i$arrow\t", $dbline[$i];
5712
5713             # Move on to the next line. Drop out on an interrupt.
5714             if ($signal) {
5715                 $i++;
5716                 last I_TO_END;
5717             }
5718         } ## end for (; $i <= $end ; $i++)
5719
5720         # Line the prompt up; print a newline if the last line listed
5721         # didn't have a newline.
5722         if ($dbline[ $i - 1 ] !~ /\n\z/) {
5723             print {$OUT} "\n";
5724         }
5725     } ## end else [ if ($slave_editor)
5726
5727     # Save the point we last listed to in case another relative 'l'
5728     # command is desired. Don't let it run off the end.
5729     $start = $i;
5730     _minify_to_max(\$start);
5731
5732     return;
5733 }
5734
5735 sub _cmd_l_main {
5736     my $spec = shift;
5737
5738     # If this is '-something', delete any spaces after the dash.
5739     $spec =~ s/\A-\s*\z/-/;
5740
5741     # If the line is '$something', assume this is a scalar containing a
5742     # line number.
5743     # Set up for DB::eval() - evaluate in *user* context.
5744     if ( my ($var_name) = $spec =~ /\A(\$.*)/s ) {
5745         return _cmd_l_handle_var_name($var_name);
5746     }
5747     # l name. Try to find a sub by that name.
5748     elsif ( ($subname) = $spec =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5749         return _cmd_l_handle_subname();
5750     }
5751     # Bare 'l' command.
5752     elsif ( $spec !~ /\S/ ) {
5753         return _cmd_l_empty();
5754     }
5755     # l [start]+number_of_lines
5756     elsif ( my ($new_start, $new_incr) = $spec =~ /\A(\d*)\+(\d*)\z/ ) {
5757         return _cmd_l_plus($new_start, $new_incr);
5758     }
5759     # l start-stop or l start,stop
5760     elsif (my ($s, $e) = $spec =~ /^(?:(-?[\d\$\.]+)(?:[-,]([\d\$\.]+))?)?/ ) {
5761         return _cmd_l_range($spec, $line, $s, $e);
5762     }
5763
5764     return;
5765 } ## end sub cmd_l
5766
5767 sub cmd_l {
5768     my (undef, $line) = @_;
5769
5770     return _cmd_l_main($line);
5771 }
5772
5773 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5774
5775 To list breakpoints, the command has to look determine where all of them are
5776 first. It starts a C<%had_breakpoints>, which tells us what all files have
5777 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5778 magic source and breakpoint data structures) to the file, and then look
5779 through C<%dbline> for lines with breakpoints and/or actions, listing them
5780 out. We look through C<%postponed> not-yet-compiled subroutines that have
5781 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5782 that have breakpoints.
5783
5784 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5785
5786 =cut
5787
5788 sub _cmd_L_calc_arg {
5789     # If no argument, list everything. Pre-5.8.0 version always lists
5790     # everything
5791     my $arg = shift || 'abw';
5792     if ($CommandSet ne '580')
5793     {
5794         $arg = 'abw';
5795     }
5796
5797     return $arg;
5798 }
5799
5800 sub _cmd_L_calc_wanted_flags {
5801     my $arg = _cmd_L_calc_arg(shift);
5802
5803     return (map { index($arg, $_) >= 0 ? 1 : 0 } qw(a b w));
5804 }
5805
5806
5807 sub _cmd_L_handle_breakpoints {
5808     my ($handle_db_line) = @_;
5809
5810     BREAKPOINTS_SCAN:
5811     # Look in all the files with breakpoints...
5812     for my $file ( keys %had_breakpoints ) {
5813
5814         # Temporary switch to this file.
5815         local *dbline = $main::{ '_<' . $file };
5816
5817         # Set up to look through the whole file.
5818         $max = $#dbline;
5819         my $was;    # Flag: did we print something
5820         # in this file?
5821
5822         # For each line in the file ...
5823         for my $i (1 .. $max) {
5824
5825             # We've got something on this line.
5826             if ( defined $dbline{$i} ) {
5827
5828                 # Print the header if we haven't.
5829                 if (not $was++) {
5830                     print {$OUT} "$file:\n";
5831                 }
5832
5833                 # Print the line.
5834                 print {$OUT} " $i:\t", $dbline[$i];
5835
5836                 $handle_db_line->($dbline{$i});
5837
5838                 # Quit if the user hit interrupt.
5839                 if ($signal) {
5840                     last BREAKPOINTS_SCAN;
5841                 }
5842             } ## end if (defined $dbline{$i...
5843         } ## end for my $i (1 .. $max)
5844     } ## end for my $file (keys %had_breakpoints)
5845
5846     return;
5847 }
5848
5849 sub _cmd_L_handle_postponed_breakpoints {
5850     my ($handle_db_line) = @_;
5851
5852     print {$OUT} "Postponed breakpoints in files:\n";
5853
5854     POSTPONED_SCANS:
5855     for my $file ( keys %postponed_file ) {
5856         my $db = $postponed_file{$file};
5857         print {$OUT} " $file:\n";
5858         for my $line ( sort { $a <=> $b } keys %$db ) {
5859             print {$OUT} "  $line:\n";
5860
5861             $handle_db_line->($db->{$line});
5862
5863             if ($signal) {
5864                 last POSTPONED_SCANS;
5865             }
5866         }
5867         if ($signal) {
5868             last POSTPONED_SCANS;
5869         }
5870     }
5871
5872     return;
5873 }
5874
5875
5876 sub cmd_L {
5877     my $cmd = shift;
5878
5879     my ($action_wanted, $break_wanted, $watch_wanted) =
5880         _cmd_L_calc_wanted_flags(shift);
5881
5882     my $handle_db_line = sub {
5883         my ($l) = @_;
5884
5885         my ( $stop, $action ) = split( /\0/, $l );
5886
5887         if ($stop and $break_wanted) {
5888             print {$OUT} "    break if (", $stop, ")\n"
5889         }
5890
5891         if ($action && $action_wanted) {
5892             print {$OUT} "    action:  ", $action, "\n"
5893         }
5894
5895         return;
5896     };
5897
5898     # Breaks and actions are found together, so we look in the same place
5899     # for both.
5900     if ( $break_wanted or $action_wanted ) {
5901         _cmd_L_handle_breakpoints($handle_db_line);
5902     }
5903
5904     # Look for breaks in not-yet-compiled subs:
5905     if ( %postponed and $break_wanted ) {
5906         print {$OUT} "Postponed breakpoints in subroutines:\n";
5907         my $subname;
5908         SUBS_SCAN:
5909         for $subname ( keys %postponed ) {
5910             print {$OUT} " $subname\t$postponed{$subname}\n";
5911             if ($signal) {
5912                 last SUBS_SCAN;
5913             }
5914         }
5915     } ## end if (%postponed and $break_wanted)
5916
5917     # Find files that have not-yet-loaded breaks:
5918     my @have = map {    # Combined keys
5919         keys %{ $postponed_file{$_} }
5920     } keys %postponed_file;
5921
5922     # If there are any, list them.
5923     if ( @have and ( $break_wanted or $action_wanted ) ) {
5924         _cmd_L_handle_postponed_breakpoints($handle_db_line);
5925     } ## end if (@have and ($break_wanted...
5926
5927     if ( %break_on_load and $break_wanted ) {
5928         print {$OUT} "Breakpoints on load:\n";
5929         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5930             print {$OUT} " $filename\n";
5931             last BREAK_ON_LOAD if $signal;
5932         }
5933     } ## end if (%break_on_load and...
5934
5935     if ($watch_wanted and ( $trace & 2 )) {
5936         print {$OUT} "Watch-expressions:\n" if @to_watch;
5937         TO_WATCH: for my $expr (@to_watch) {
5938             print {$OUT} " $expr\n";
5939             last TO_WATCH if $signal;
5940         }
5941     }
5942
5943     return;
5944 } ## end sub cmd_L
5945
5946 =head3 C<cmd_M> - list modules (command)
5947
5948 Just call C<list_modules>.
5949
5950 =cut
5951
5952 sub cmd_M {
5953     list_modules();
5954
5955     return;
5956 }
5957
5958 =head3 C<cmd_o> - options (command)
5959
5960 If this is just C<o> by itself, we list the current settings via
5961 C<dump_option>. If there's a nonblank value following it, we pass that on to
5962 C<parse_options> for processing.
5963
5964 =cut
5965
5966 sub cmd_o {
5967     my $cmd = shift;
5968     my $opt = shift || '';    # opt[=val]
5969
5970     # Nonblank. Try to parse and process.
5971     if ( $opt =~ /^(\S.*)/ ) {
5972         parse_options($1);
5973     }
5974
5975     # Blank. List the current option settings.
5976     else {
5977         for (@options) {
5978             dump_option($_);
5979         }
5980     }
5981 } ## end sub cmd_o
5982
5983 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5984
5985 Advises the user that the O command has been renamed.
5986
5987 =cut
5988
5989 sub cmd_O {
5990     print $OUT "The old O command is now the o command.\n";             # hint
5991     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5992     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5993 }
5994
5995 =head3 C<cmd_v> - view window (command)
5996
5997 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5998 move back a few lines to list the selected line in context. Uses C<cmd_l>
5999 to do the actual listing after figuring out the range of line to request.
6000
6001 =cut
6002
6003 use vars qw($preview);
6004
6005 sub cmd_v {
6006     my $cmd  = shift;
6007     my $line = shift;
6008
6009     # Extract the line to list around. (Astute readers will have noted that
6010     # this pattern will match whether or not a numeric line is specified,
6011     # which means that we'll always enter this loop (though a non-numeric
6012     # argument results in no action at all)).
6013     if ( $line =~ /^(\d*)$/ ) {
6014
6015         # Total number of lines to list (a windowful).
6016         $incr = $window - 1;
6017
6018         # Set the start to the argument given (if there was one).
6019         $start = $1 if $1;
6020
6021         # Back up by the context amount.
6022         $start -= $preview;
6023
6024         # Put together a linespec that cmd_l will like.
6025         $line = $start . '-' . ( $start + $incr );
6026
6027         # List the lines.
6028         cmd_l( 'l', $line );
6029     } ## end if ($line =~ /^(\d*)$/)
6030 } ## end sub cmd_v
6031
6032 =head3 C<cmd_w> - add a watch expression (command)
6033
6034 The 5.8 version of this command adds a watch expression if one is specified;
6035 it does nothing if entered with no operands.
6036
6037 We extract the expression, save it, evaluate it in the user's context, and
6038 save the value. We'll re-evaluate it each time the debugger passes a line,
6039 and will stop (see the code at the top of the command loop) if the value
6040 of any of the expressions changes.
6041
6042 =cut
6043
6044 sub _add_watch_expr {
6045     my $expr = shift;
6046
6047     # ... save it.
6048     push @to_watch, $expr;
6049
6050     # Parameterize DB::eval and call it to get the expression's value
6051     # in the user's context. This version can handle expressions which
6052     # return a list value.
6053     $evalarg = $expr;
6054     # The &-call is here to ascertain the mutability of @_.
6055     my ($val) = join( ' ', &DB::eval);
6056     $val = ( defined $val ) ? "'$val'" : 'undef';
6057
6058     # Save the current value of the expression.
6059     push @old_watch, $val;
6060
6061     # We are now watching expressions.
6062     $trace |= 2;
6063
6064     return;
6065 }
6066
6067 sub cmd_w {
6068     my $cmd = shift;
6069
6070     # Null expression if no arguments.
6071     my $expr = shift || '';
6072
6073     # If expression is not null ...
6074     if ( $expr =~ /\A\S/ ) {
6075         _add_watch_expr($expr);
6076     } ## end if ($expr =~ /^(\S.*)/)
6077
6078     # You have to give one to get one.
6079     else {
6080         print $OUT "Adding a watch-expression requires an expression\n";  # hint
6081     }
6082
6083     return;
6084 }
6085
6086 =head3 C<cmd_W> - delete watch expressions (command)
6087
6088 This command accepts either a watch expression to be removed from the list
6089 of watch expressions, or C<*> to delete them all.
6090
6091 If C<*> is specified, we simply empty the watch expression list and the
6092 watch expression value list. We also turn off the bit that says we've got
6093 watch expressions.
6094
6095 If an expression (or partial expression) is specified, we pattern-match
6096 through the expressions and remove the ones that match. We also discard
6097 the corresponding values. If no watch expressions are left, we turn off
6098 the I<watching expressions> bit.
6099
6100 =cut
6101
6102 sub cmd_W {
6103     my $cmd  = shift;
6104     my $expr = shift || '';
6105
6106     # Delete them all.
6107     if ( $expr eq '*' ) {
6108
6109         # Not watching now.
6110         $trace &= ~2;
6111
6112         print $OUT "Deleting all watch expressions ...\n";
6113
6114         # And all gone.
6115         @to_watch = @old_watch = ();
6116     }
6117
6118     # Delete one of them.
6119     elsif ( $expr =~ /^(\S.*)/ ) {
6120
6121         # Where we are in the list.
6122         my $i_cnt = 0;
6123
6124         # For each expression ...
6125         foreach (@to_watch) {
6126             my $val = $to_watch[$i_cnt];
6127
6128             # Does this one match the command argument?
6129             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
6130                                       # Yes. Turn it off, and its value too.
6131                 splice( @to_watch,  $i_cnt, 1 );
6132                 splice( @old_watch, $i_cnt, 1 );
6133             }
6134             $i_cnt++;
6135         } ## end foreach (@to_watch)
6136
6137         # We don't bother to turn watching off because
6138         #  a) we don't want to stop calling watchfunction() if it exists
6139         #  b) foreach over a null list doesn't do anything anyway
6140
6141     } ## end elsif ($expr =~ /^(\S.*)/)
6142
6143     # No command arguments entered.
6144     else {
6145         print $OUT
6146           "Deleting a watch-expression requires an expression, or '*' for all\n"
6147           ;    # hint
6148     }
6149 } ## end sub cmd_W
6150
6151 ### END of the API section
6152
6153 =head1 SUPPORT ROUTINES
6154
6155 These are general support routines that are used in a number of places
6156 throughout the debugger.
6157
6158 =head2 save
6159
6160 save() saves the user's versions of globals that would mess us up in C<@saved>,
6161 and installs the versions we like better.
6162
6163 =cut
6164
6165 sub save {
6166
6167     # Save eval failure, command failure, extended OS error, output field
6168     # separator, input record separator, output record separator and
6169     # the warning setting.
6170     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
6171
6172     $,  = "";      # output field separator is null string
6173     $/  = "\n";    # input record separator is newline
6174     $\  = "";      # output record separator is null string
6175     $^W = 0;       # warnings are off
6176 } ## end sub save
6177
6178 =head2 C<print_lineinfo> - show where we are now
6179
6180 print_lineinfo prints whatever it is that it is handed; it prints it to the
6181 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
6182 us to feed line information to a slave editor without messing up the
6183 debugger output.
6184
6185 =cut
6186
6187 sub print_lineinfo {
6188
6189     # Make the terminal sensible if we're not the primary debugger.
6190     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
6191     local $\ = '';
6192     local $, = '';
6193     # $LINEINFO may be undef if $noTTY is set or some other issue.
6194     if ($LINEINFO)
6195     {
6196         print {$LINEINFO} @_;
6197     }
6198 } ## end sub print_lineinfo
6199
6200 =head2 C<postponed_sub>
6201
6202 Handles setting postponed breakpoints in subroutines once they're compiled.
6203 For breakpoints, we use C<DB::find_sub> to locate the source file and line
6204 range for the subroutine, then mark the file as having a breakpoint,
6205 temporarily switch the C<*dbline> glob over to the source file, and then
6206 search the given range of lines to find a breakable line. If we find one,
6207 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6208
6209 =cut
6210
6211 # The following takes its argument via $evalarg to preserve current @_
6212
6213 sub postponed_sub {
6214
6215     # Get the subroutine name.
6216     my $subname = shift;
6217
6218     # If this is a 'break +<n> if <condition>' ...
6219     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6220
6221         # If there's no offset, use '+0'.
6222         my $offset = $1 || 0;
6223
6224         # find_sub's value is 'fullpath-filename:start-stop'. It's
6225         # possible that the filename might have colons in it too.
6226         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6227         if ($i) {
6228
6229             # We got the start line. Add the offset '+<n>' from
6230             # $postponed{subname}.
6231             $i += $offset;
6232
6233             # Switch to the file this sub is in, temporarily.
6234             local *dbline = $main::{ '_<' . $file };
6235
6236             # No warnings, please.
6237             local $^W = 0;    # != 0 is magical below
6238
6239             # This file's got a breakpoint in it.
6240             $had_breakpoints{$file} |= 1;
6241
6242             # Last line in file.
6243             $max = $#dbline;
6244
6245             # Search forward until we hit a breakable line or get to
6246             # the end of the file.
6247             ++$i until $dbline[$i] != 0 or $i >= $max;
6248
6249             # Copy the breakpoint in and delete it from %postponed.
6250             $dbline{$i} = delete $postponed{$subname};
6251         } ## end if ($i)
6252
6253         # find_sub didn't find the sub.
6254         else {
6255             local $\ = '';
6256             print $OUT "Subroutine $subname not found.\n";
6257         }
6258         return;
6259     } ## end if ($postponed{$subname...
6260     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6261
6262     #print $OUT "In postponed_sub for '$subname'.\n";
6263 } ## end sub postponed_sub
6264
6265 =head2 C<postponed>
6266
6267 Called after each required file is compiled, but before it is executed;
6268 also called if the name of a just-compiled subroutine is a key of
6269 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6270 etc.) into the just-compiled code.
6271
6272 If this is a C<require>'d file, the incoming parameter is the glob
6273 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6274
6275 If it's a subroutine, the incoming parameter is the subroutine name.
6276
6277 =cut
6278
6279 sub postponed {
6280
6281     # If there's a break, process it.
6282     if ($ImmediateStop) {
6283
6284         # Right, we've stopped. Turn it off.
6285         $ImmediateStop = 0;
6286
6287         # Enter the command loop when DB::DB gets called.
6288         $signal = 1;
6289     }
6290
6291     # If this is a subroutine, let postponed_sub() deal with it.
6292     if (ref(\$_[0]) ne 'GLOB') {
6293         return postponed_sub(@_);
6294     }
6295
6296     # Not a subroutine. Deal with the file.
6297     local *dbline = shift;
6298     my $filename = $dbline;
6299     $filename =~ s/^_<//;
6300     local $\ = '';
6301     $signal = 1, print $OUT "'$filename' loaded...\n"
6302       if $break_on_load{$filename};
6303     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6304
6305     # Do we have any breakpoints to put in this file?
6306     return unless $postponed_file{$filename};
6307
6308     # Yes. Mark this file as having breakpoints.
6309     $had_breakpoints{$filename} |= 1;
6310
6311     # "Cannot be done: insufficient magic" - we can't just put the
6312     # breakpoints saved in %postponed_file into %dbline by assigning
6313     # the whole hash; we have to do it one item at a time for the
6314     # breakpoints to be set properly.
6315     #%dbline = %{$postponed_file{$filename}};
6316
6317     # Set the breakpoints, one at a time.
6318     my $key;
6319
6320     for $key ( keys %{ $postponed_file{$filename} } ) {
6321
6322         # Stash the saved breakpoint into the current file's magic line array.
6323         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6324     }
6325
6326     # This file's been compiled; discard the stored breakpoints.
6327     delete $postponed_file{$filename};
6328
6329 } ## end sub postponed
6330
6331 =head2 C<dumpit>
6332
6333 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6334
6335 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6336 a reference to a variable (the thing to be dumped) as its input.
6337
6338 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6339 the currently-selected filehandle, thank you very much). The current
6340 values of the package globals C<$single> and C<$trace> are backed up in
6341 lexicals, and they are turned off (this keeps the debugger from trying
6342 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6343 preserve its current value and it is set to zero to prevent entry/exit
6344 messages from printing, and C<$doret> is localized as well and set to -2 to
6345 prevent return values from being shown.
6346
6347 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6348 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6349 installed version in C<@INC>, yours will be used instead. Possible security
6350 problem?).
6351
6352 It then checks to see if the subroutine C<main::dumpValue> is now defined
6353 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6354 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6355 is called, and picks up the variable to be dumped from the parameter list.
6356
6357 It checks the package global C<%options> to see if there's a C<dumpDepth>
6358 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6359 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6360 structure: -1 means dump everything.
6361
6362 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6363 warning.
6364
6365 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6366 and we then return to the caller.
6367
6368 =cut
6369
6370 sub dumpit {
6371
6372     # Save the current output filehandle and switch to the one
6373     # passed in as the first parameter.
6374     my $savout = select(shift);
6375
6376     # Save current settings of $single and $trace, and then turn them off.
6377     my $osingle = $single;
6378     my $otrace  = $trace;
6379     $single = $trace = 0;
6380
6381     # XXX Okay, what do $frame and $doret do, again?
6382     local $frame = 0;
6383     local $doret = -2;
6384
6385     # Load dumpvar.pl unless we've already got the sub we need from it.
6386     unless ( defined &main::dumpValue ) {
6387         do 'dumpvar.pl' or die $@;
6388     }
6389
6390     # If the load succeeded (or we already had dumpvalue()), go ahead
6391     # and dump things.
6392     if ( defined &main::dumpValue ) {
6393         local $\ = '';
6394         local $, = '';
6395         local $" = ' ';
6396         my $v = shift;
6397         my $maxdepth = shift || $option{dumpDepth};
6398         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6399         main::dumpValue( $v, $maxdepth );
6400     } ## end if (defined &main::dumpValue)
6401
6402     # Oops, couldn't load dumpvar.pl.
6403     else {
6404         local $\ = '';
6405         print $OUT "dumpvar.pl not available.\n";
6406     }
6407
6408     # Reset $single and $trace to their old values.
6409     $single = $osingle;
6410     $trace  = $otrace;
6411
6412     # Restore the old filehandle.
6413     select($savout);
6414 } ## end sub dumpit
6415
6416 =head2 C<print_trace>
6417
6418 C<print_trace>'s job is to print a stack trace. It does this via the
6419 C<dump_trace> routine, which actually does all the ferreting-out of the
6420 stack trace data. C<print_trace> takes care of formatting it nicely and
6421 printing it to the proper filehandle.
6422
6423 Parameters:
6424
6425 =over 4
6426
6427 =item *
6428
6429 The filehandle to print to.
6430
6431 =item *
6432
6433 How many frames to skip before starting trace.
6434
6435 =item *
6436
6437 How many frames to print.
6438
6439 =item *
6440
6441 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6442
6443 =back
6444
6445 The original comment below seems to be noting that the traceback may not be
6446 correct if this routine is called in a tied method.
6447
6448 =cut
6449
6450 # Tied method do not create a context, so may get wrong message:
6451
6452 sub print_trace {
6453     local $\ = '';
6454     my $fh = shift;
6455
6456     # If this is going to a slave editor, but we're not the primary
6457     # debugger, reset it first.
6458     resetterm(1)
6459       if $fh        eq $LINEINFO    # slave editor
6460       and $LINEINFO eq $OUT         # normal output
6461       and $term_pid != $$;          # not the primary
6462
6463     # Collect the actual trace information to be formatted.
6464     # This is an array of hashes of subroutine call info.
6465     my @sub = dump_trace( $_[0] + 1, $_[1] );
6466
6467     # Grab the "short report" flag from @_.
6468     my $short = $_[2];              # Print short report, next one for sub name
6469
6470     # Run through the traceback info, format it, and print it.
6471     my $s;
6472     for my $i (0 .. $#sub) {
6473
6474         # Drop out if the user has lost interest and hit control-C.
6475         last if $signal;
6476
6477         # Set the separator so arrays print nice.
6478         local $" = ', ';
6479
6480         # Grab and stringify the arguments if they are there.
6481         my $args =
6482           defined $sub[$i]{args}
6483           ? "(@{ $sub[$i]{args} })"
6484           : '';
6485
6486         # Shorten them up if $maxtrace says they're too long.
6487         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6488           if length $args > $maxtrace;
6489
6490         # Get the file name.
6491         my $file = $sub[$i]{file};
6492
6493         # Put in a filename header if short is off.
6494         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6495
6496         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6497         $s = $sub[$i]{'sub'};
6498         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6499
6500         # Short report uses trimmed file and sub names.
6501         if ($short) {
6502             my $sub = @_ >= 4 ? $_[3] : $s;
6503             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6504         } ## end if ($short)
6505
6506         # Non-short report includes full names.
6507         else {
6508             print $fh "$sub[$i]{context} = $s$args"
6509               . " called from $file"
6510               . " line $sub[$i]{line}\n";
6511         }
6512     } ## end for my $i (0 .. $#sub)
6513 } ## end sub print_trace
6514
6515 =head2 dump_trace(skip[,count])
6516
6517 Actually collect the traceback information available via C<caller()>. It does
6518 some filtering and cleanup of the data, but mostly it just collects it to
6519 make C<print_trace()>'s job easier.
6520
6521 C<skip> defines the number of stack frames to be skipped, working backwards
6522 from the most current. C<count> determines the total number of frames to
6523 be returned; all of them (well, the first 10^9) are returned if C<count>
6524 is omitted.
6525
6526 This routine returns a list of hashes, from most-recent to least-recent
6527 stack frame. Each has the following keys and values:
6528
6529 =over 4
6530
6531 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6532
6533 =item * C<sub> - subroutine name, or C<eval> information
6534
6535 =item * C<args> - undef, or a reference to an array of arguments
6536
6537 =item * C<file> - the file in which this item was defined (if any)
6538
6539 =item * C<line> - the line on which it was defined
6540
6541 =back
6542
6543 =cut
6544
6545 sub _dump_trace_calc_saved_single_arg
6546 {
6547     my ($nothard, $arg) = @_;
6548
6549     my $type;
6550     if ( not defined $arg ) {    # undefined parameter
6551         return "undef";
6552     }
6553
6554     elsif ( $nothard and tied $arg ) {    # tied parameter
6555         return "tied";
6556     }
6557     elsif ( $nothard and $type = ref $arg ) {    # reference
6558         return "ref($type)";
6559     }
6560     else {                                       # can be stringified
6561         local $_ =
6562         "$arg";    # Safe to stringify now - should not call f().
6563
6564         # Backslash any single-quotes or backslashes.
6565         s/([\'\\])/\\$1/g;
6566
6567         # Single-quote it unless it's a number or a colon-separated
6568         # name.
6569         s/(.*)/'$1'/s
6570         unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6571
6572         # Turn high-bit characters into meta-whatever, and controls into like
6573         # '^D'.
6574         require 'meta_notation.pm';
6575         $_ = _meta_notation($_) if /[[:^print:]]/a;
6576
6577         return $_;
6578     }
6579 }
6580
6581 sub _dump_trace_calc_save_args {
6582     my ($nothard) = @_;
6583
6584     return [
6585         map { _dump_trace_calc_saved_single_arg($nothard, $_) } @args
6586     ];
6587 }
6588
6589 sub dump_trace {
6590
6591     # How many levels to skip.
6592     my $skip = shift;
6593
6594     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6595     # it's unlikely that we'll have more than a billion stack frames. If you
6596     # do, you've got an awfully big machine...)
6597     my $count = shift || 1e9;
6598
6599     # We increment skip because caller(1) is the first level *back* from
6600     # the current one.  Add $skip to the count of frames so we have a
6601     # simple stop criterion, counting from $skip to $count+$skip.
6602     $skip++;
6603     $count += $skip;
6604
6605     # These variables are used to capture output from caller();
6606     my ( $p, $file, $line, $sub, $h, $context );
6607
6608     my ( $e, $r, @sub, $args );
6609
6610     # XXX Okay... why'd we do that?
6611     my $nothard = not $frame & 8;
6612     local $frame = 0;
6613
6614     # Do not want to trace this.
6615     my $otrace = $trace;
6616     $trace = 0;
6617
6618     # Start out at the skip count.
6619     # If we haven't reached the number of frames requested, and caller() is
6620     # still returning something, stay in the loop. (If we pass the requested
6621     # number of stack frames, or we run out - caller() returns nothing - we
6622     # quit.
6623     # Up the stack frame index to go back one more level each time.
6624     for (
6625         my $i = $skip ;
6626         $i < $count
6627         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6628         $i++
6629     )
6630     {
6631
6632         # Go through the arguments and save them for later.
6633         my $save_args = _dump_trace_calc_save_args($nothard);
6634
6635         # If context is true, this is array (@)context.
6636         # If context is false, this is scalar ($) context.
6637         # If neither, context isn't defined. (This is apparently a 'can't
6638         # happen' trap.)
6639         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6640
6641         # if the sub has args ($h true), make an anonymous array of the
6642         # dumped args.
6643         $args = $h ? $save_args : undef;
6644
6645         # remove trailing newline-whitespace-semicolon-end of line sequence
6646         # from the eval text, if any.
6647         $e =~ s/\n\s*\;\s*\Z// if $e;
6648
6649         # Escape backslashed single-quotes again if necessary.
6650         $e =~ s/([\\\'])/\\$1/g if $e;
6651
6652         # if the require flag is true, the eval text is from a require.
6653         if ($r) {
6654             $sub = "require '$e'";
6655         }
6656
6657         # if it's false, the eval text is really from an eval.
6658         elsif ( defined $r ) {
6659             $sub = "eval '$e'";
6660         }
6661
6662         # If the sub is '(eval)', this is a block eval, meaning we don't
6663         # know what the eval'ed text actually was.
6664         elsif ( $sub eq '(eval)' ) {
6665             $sub = "eval {...}";
6666         }
6667
6668         # Stick the collected information into @sub as an anonymous hash.
6669         push(
6670             @sub,
6671             {
6672                 context => $context,
6673                 sub     => $sub,
6674                 args    => $args,
6675                 file    => $file,
6676                 line    => $line
6677             }
6678         );
6679
6680         # Stop processing frames if the user hit control-C.
6681         last if $signal;
6682     } ## end for ($i = $skip ; $i < ...
6683
6684     # Restore the trace value again.
6685     $trace = $otrace;
6686     @sub;
6687 } ## end sub dump_trace
6688
6689 =head2 C<action()>
6690
6691 C<action()> takes input provided as the argument to an add-action command,
6692 either pre- or post-, and makes sure it's a complete command. It doesn't do
6693 any fancy parsing; it just keeps reading input until it gets a string
6694 without a trailing backslash.
6695
6696 =cut
6697
6698 sub action {
6699     my $action = shift;
6700
6701     while ( $action =~ s/\\$// ) {
6702
6703         # We have a backslash on the end. Read more.
6704         $action .= gets();
6705     } ## end while ($action =~ s/\\$//)
6706
6707     # Return the assembled action.
6708     $action;
6709 } ## end sub action
6710
6711 =head2 unbalanced
6712
6713 This routine mostly just packages up a regular expression to be used
6714 to check that the thing it's being matched against has properly-matched
6715 curly braces.
6716
6717 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6718 speeds things up by only creating the qr//'ed expression once; if it's
6719 already defined, we don't try to define it again. A speed hack.
6720
6721 =cut
6722
6723 use vars qw($balanced_brace_re);
6724
6725 sub unbalanced {
6726
6727     # I hate using globals!
6728     $balanced_brace_re ||= qr{
6729         ^ \{
6730              (?:
6731                  (?> [^{}] + )              # Non-parens without backtracking
6732                 |
6733                  (??{ $balanced_brace_re }) # Group with matching parens
6734               ) *
6735           \} $
6736    }x;
6737     return $_[0] !~ m/$balanced_brace_re/;
6738 } ## end sub unbalanced
6739
6740 =head2 C<gets()>
6741
6742 C<gets()> is a primitive (very primitive) routine to read continuations.
6743 It was devised for reading continuations for actions.
6744 it just reads more input with C<readline()> and returns it.
6745
6746 =cut
6747
6748 sub gets {
6749     return DB::readline("cont: ");
6750 }
6751
6752 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6753
6754 The C<system()> function assumes that it can just go ahead and use STDIN and
6755 STDOUT, but under the debugger, we want it to use the debugger's input and
6756 outout filehandles.
6757
6758 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6759 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6760 and then puts everything back again.
6761
6762 =cut
6763
6764 sub _db_system {
6765
6766     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6767     # some non-Unix systems can do system() but have problems with fork().
6768     open( SAVEIN,  "<&STDIN" )  || _db_warn("Can't save STDIN");
6769     open( SAVEOUT, ">&STDOUT" ) || _db_warn("Can't save STDOUT");
6770     open( STDIN,   "<&IN" )     || _db_warn("Can't redirect STDIN");
6771     open( STDOUT,  ">&OUT" )    || _db_warn("Can't redirect STDOUT");
6772
6773     # XXX: using csh or tcsh destroys sigint retvals!
6774     system(@_);
6775     open( STDIN,  "<&SAVEIN" )  || _db_warn("Can't restore STDIN");
6776     open( STDOUT, ">&SAVEOUT" ) || _db_warn("Can't restore STDOUT");
6777     close(SAVEIN);
6778     close(SAVEOUT);
6779
6780     # most of the $? crud was coping with broken cshisms
6781     if ( $? >> 8 ) {
6782         _db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6783     }
6784     elsif ($?) {
6785         _db_warn(
6786             "(Command died of SIG#",
6787             ( $? & 127 ),
6788             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6789             ")", "\n"
6790         );
6791     } ## end elsif ($?)
6792
6793     return $?;
6794
6795 } ## end sub system
6796
6797 *system = \&_db_system;
6798
6799 =head1 TTY MANAGEMENT
6800
6801 The subs here do some of the terminal management for multiple debuggers.
6802
6803 =head2 setterm
6804
6805 Top-level function called when we want to set up a new terminal for use
6806 by the debugger.
6807
6808 If the C<noTTY> debugger option was set, we'll either use the terminal
6809 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6810 to find one. If we're a forked debugger, we call C<resetterm> to try to
6811 get a whole new terminal if we can.
6812
6813 In either case, we set up the terminal next. If the C<ReadLine> option was
6814 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6815 the appropriate attributes. We then
6816
6817 =cut
6818
6819 use vars qw($ornaments);
6820 use vars qw($rl_attribs);
6821
6822 sub setterm {
6823
6824     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6825     local $frame = 0;
6826     local $doret = -2;
6827     require Term::ReadLine;
6828
6829     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6830     if ($notty) {
6831         if ($tty) {
6832             my ( $i, $o ) = split $tty, /,/;
6833             $o = $i unless defined $o;
6834             open( IN,  '<', $i ) or die "Cannot open TTY '$i' for read: $!";
6835             open( OUT, '>', $o ) or die "Cannot open TTY '$o' for write: $!";
6836             $IN  = \*IN;
6837             $OUT = \*OUT;
6838             _autoflush($OUT);
6839         } ## end if ($tty)
6840
6841         # We don't have a TTY - try to find one via Term::Rendezvous.
6842         else {
6843             require Term::Rendezvous;
6844
6845             # See if we have anything to pass to Term::Rendezvous.
6846             # Use $HOME/.perldbtty$$ if not.
6847             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6848
6849             # Rendezvous and get the filehandles.
6850             my $term_rv = Term::Rendezvous->new( $rv );
6851             $IN  = $term_rv->IN;
6852             $OUT = $term_rv->OUT;
6853         } ## end else [ if ($tty)
6854     } ## end if ($notty)
6855
6856     # We're a daughter debugger. Try to fork off another TTY.
6857     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6858         resetterm(2);
6859     }
6860
6861     # If we shouldn't use Term::ReadLine, don't.
6862     if ( !$rl ) {
6863         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6864     }
6865
6866     # We're using Term::ReadLine. Get all the attributes for this terminal.
6867     else {
6868         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6869
6870         $rl_attribs = $term->Attribs;
6871         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6872           if defined $rl_attribs->{basic_word_break_characters}
6873           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6874         $rl_attribs->{special_prefixes} = '$@&%';
6875         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6876         $rl_attribs->{completion_function} = \&db_complete;
6877     } ## end else [ if (!$rl)
6878
6879     # Set up the LINEINFO filehandle.
6880     $LINEINFO = $OUT     unless defined $LINEINFO;
6881     $lineinfo = $console unless defined $lineinfo;
6882
6883     $term->MinLine(2);
6884
6885     load_hist();
6886
6887     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6888         $term->SetHistory(@hist);
6889     }
6890
6891     # XXX Ornaments are turned on unconditionally, which is not
6892     # always a good thing.
6893     ornaments($ornaments) if defined $ornaments;
6894     $term_pid = $$;
6895 } ## end sub setterm
6896
6897 sub load_hist {
6898     $histfile //= option_val("HistFile", undef);
6899     return unless defined $histfile;
6900     open my $fh, "<", $histfile or return;
6901     local $/ = "\n";
6902     @hist = ();
6903     while (<$fh>) {
6904         chomp;
6905         push @hist, $_;
6906     }
6907     close $fh;
6908 }
6909
6910 sub save_hist {
6911     return unless defined $histfile;
6912     eval { require File::Path } or return;
6913     eval { require File::Basename } or return;
6914     File::Path::mkpath(File::Basename::dirname($histfile));
6915     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6916     $histsize //= option_val("HistSize",100);
6917     my @copy = grep { $_ ne '?' } @hist;
6918     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6919     for ($start .. $#copy) {
6920         print $fh "$copy[$_]\n";
6921     }
6922     close $fh or die "Could not write '$histfile': $!";
6923 }
6924
6925 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6926
6927 When the process being debugged forks, or the process invokes a command
6928 via C<system()> which starts a new debugger, we need to be able to get a new
6929 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6930 fight over the terminal, and you can never quite be sure who's going to get the
6931 input you're typing.
6932
6933 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6934 is tasked with doing all the necessary operating system mojo to get a new
6935 TTY (and probably another window) and to direct the new debugger to read and
6936 write there.
6937
6938 The debugger provides C<get_fork_TTY> functions which work for TCP
6939 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6940 supported. You are encouraged to write C<get_fork_TTY> functions which
6941 work for I<your> platform and contribute them.
6942
6943 =head3 C<socket_get_fork_TTY>
6944
6945 =cut
6946
6947 sub connect_remoteport {
6948     require IO::Socket;
6949
6950     my $socket = IO::Socket::INET->new(
6951         Timeout  => '10',
6952         PeerAddr => $remoteport,
6953         Proto    => 'tcp',
6954     );
6955     if ( ! $socket ) {
6956         die "Unable to connect to remote host: $remoteport\n";
6957     }
6958     return $socket;
6959 }
6960
6961 sub socket_get_fork_TTY {
6962     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6963
6964     # Do I need to worry about setting $term?
6965
6966     reset_IN_OUT( $IN, $OUT );
6967     return '';
6968 }
6969
6970 =head3 C<xterm_get_fork_TTY>
6971
6972 This function provides the C<get_fork_TTY> function for X11. If a
6973 program running under the debugger forks, a new <xterm> window is opened and
6974 the subsidiary debugger is directed there.
6975
6976 The C<open()> call is of particular note here. We have the new C<xterm>
6977 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6978 command (which prints the device name of the TTY we'll want to use for input
6979 and output to STDOUT, then C<sleep> for a very long time, routing this output
6980 to file number 3. This way we can simply read from the <XT> filehandle (which
6981 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6982
6983 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6984 properly set up.
6985
6986 =cut
6987
6988 sub xterm_get_fork_TTY {
6989     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6990     open XT,
6991 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6992  sleep 10000000' |];
6993
6994     # Get the output from 'tty' and clean it up a little.
6995     my $tty = <XT>;
6996     chomp $tty;
6997
6998     $pidprompt = '';    # Shown anyway in titlebar
6999
7000     # We need $term defined or we can not switch to the newly created xterm
7001     if ($tty ne '' && !defined $term) {
7002         require Term::ReadLine;
7003         if ( !$rl ) {
7004             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7005         }
7006         else {
7007             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7008         }
7009     }
7010     # There's our new TTY.
7011     return $tty;
7012 } ## end sub xterm_get_fork_TTY
7013
7014 =head3 C<os2_get_fork_TTY>
7015
7016 XXX It behooves an OS/2 expert to write the necessary documentation for this!
7017
7018 =cut
7019
7020 # This example function resets $IN, $OUT itself
7021 my $c_pipe = 0;
7022 sub os2_get_fork_TTY { # A simplification of the following (and works without):
7023     local $\  = '';
7024     ( my $name = $0 ) =~ s,^.*[/\\],,s;
7025     my %opt = ( title => "Daughter Perl debugger $pids $name",
7026         ($rl ? (read_by_key => 1) : ()) );
7027     require OS2::Process;
7028     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
7029       or return;
7030     $pidprompt = '';    # Shown anyway in titlebar
7031     reset_IN_OUT($in, $out);
7032     $tty = '*reset*';
7033     return '';          # Indicate that reset_IN_OUT is called
7034 } ## end sub os2_get_fork_TTY
7035
7036 =head3 C<macosx_get_fork_TTY>
7037
7038 The Mac OS X version uses AppleScript to tell Terminal.app to create
7039 a new window.
7040
7041 =cut
7042
7043 # Notes about Terminal.app's AppleScript support,
7044 # (aka things that might break in future OS versions).
7045 #
7046 # The "do script" command doesn't return a reference to the new window
7047 # it creates, but since it appears frontmost and windows are enumerated
7048 # front to back, we can use "first window" === "window 1".
7049 #
7050 # Since "do script" is implemented by supplying the argument (plus a
7051 # return character) as terminal input, there's a potential race condition
7052 # where the debugger could beat the shell to reading the command.
7053 # To prevent this, we wait for the screen to clear before proceeding.
7054 #
7055 # 10.3 and 10.4:
7056 # There's no direct accessor for the tty device name, so we fiddle
7057 # with the window title options until it says what we want.
7058 #
7059 # 10.5:
7060 # There _is_ a direct accessor for the tty device name, _and_ there's
7061 # a new possible component of the window title (the name of the settings
7062 # set).  A separate version is needed.
7063
7064 my @script_versions=
7065
7066     ([237, <<'__LEOPARD__'],
7067 tell application "Terminal"
7068     do script "clear;exec sleep 100000"
7069     tell first tab of first window
7070         copy tty to thetty
7071         set custom title to "forked perl debugger"
7072         set title displays custom title to true
7073         repeat while (length of first paragraph of (get contents)) > 0
7074             delay 0.1
7075         end repeat
7076     end tell
7077 end tell
7078 thetty
7079 __LEOPARD__
7080
7081      [100, <<'__JAGUAR_TIGER__'],
7082 tell application "Terminal"
7083     do script "clear;exec sleep 100000"
7084     tell first window
7085         set title displays shell path to false
7086         set title displays window size to false
7087         set title displays file name to false
7088         set title displays device name to true
7089         set title displays custom title to true
7090         set custom title to ""
7091         copy "/dev/" & name to thetty
7092         set custom title to "forked perl debugger"
7093         repeat while (length of first paragraph of (get contents)) > 0
7094             delay 0.1
7095         end repeat
7096     end tell
7097 end tell
7098 thetty
7099 __JAGUAR_TIGER__
7100
7101 );
7102
7103 sub macosx_get_fork_TTY
7104 {
7105     my($version,$script,$pipe,$tty);
7106
7107     return unless $version=$ENV{TERM_PROGRAM_VERSION};
7108     foreach my $entry (@script_versions) {
7109         if ($version>=$entry->[0]) {
7110             $script=$entry->[1];
7111             last;
7112         }
7113     }
7114     return unless defined($script);
7115     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
7116     $tty=readline($pipe);
7117     close($pipe);
7118     return unless defined($tty) && $tty =~ m(^/dev/);
7119     chomp $tty;
7120     return $tty;
7121 }
7122
7123 =head3 C<tmux_get_fork_TTY>
7124
7125 Creates a split window for subprocesses when a process running under the
7126 perl debugger in Tmux forks.
7127
7128 =cut
7129
7130 sub tmux_get_fork_TTY {
7131     return unless $ENV{TMUX};
7132
7133     my $pipe;
7134
7135     my $status = open $pipe, '-|', 'tmux', 'split-window',
7136         '-P', '-F', '#{pane_tty}', 'sleep 100000';
7137
7138     if ( !$status ) {
7139         return;
7140     }
7141
7142     my $tty = <$pipe>;
7143     close $pipe;
7144
7145     if ( $tty ) {
7146         chomp $tty;
7147
7148         if ( !defined $term ) {
7149             require Term::ReadLine;
7150             if ( !$rl ) {
7151                 $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
7152             }
7153             else {
7154                 $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
7155             }
7156         }
7157     }
7158
7159     return $tty;
7160 }
7161
7162 =head2 C<create_IN_OUT($flags)>
7163
7164 Create a new pair of filehandles, pointing to a new TTY. If impossible,
7165 try to diagnose why.
7166
7167 Flags are:
7168
7169 =over 4
7170
7171 =item * 1 - Don't know how to create a new TTY.
7172
7173 =item * 2 - Debugger has forked, but we can't get a new TTY.
7174
7175 =item * 4 - standard debugger startup is happening.
7176
7177 =back
7178
7179 =cut
7180
7181 use vars qw($fork_TTY);
7182
7183 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
7184
7185     # If we know how to get a new TTY, do it! $in will have
7186     # the TTY name if get_fork_TTY works.
7187     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
7188
7189     # It used to be that
7190     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
7191
7192     if ( not defined $in ) {
7193         my $why = shift;
7194
7195         # We don't know how.
7196         print_help(<<EOP) if $why == 1;
7197 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
7198 EOP
7199
7200         # Forked debugger.
7201         print_help(<<EOP) if $why == 2;
7202 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
7203   This may be an asynchronous session, so the parent debugger may be active.
7204 EOP
7205
7206         # Note that both debuggers are fighting over the same input.
7207         print_help(<<EOP) if $why != 4;
7208   Since two debuggers fight for the same TTY, input is severely entangled.
7209
7210 EOP
7211         print_help(<<EOP);
7212   I know how to switch the output to a different window in xterms, OS/2
7213   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
7214   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
7215   B<DB::get_fork_TTY()> returning this.
7216
7217   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
7218   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
7219
7220 EOP
7221     } ## end if (not defined $in)
7222     elsif ( $in ne '' ) {
7223         TTY($in);
7224     }
7225     else {
7226         $console = '';    # Indicate no need to open-from-the-console
7227     }
7228     undef $fork_TTY;
7229 } ## end sub create_IN_OUT
7230
7231 =head2 C<resetterm>
7232
7233 Handles rejiggering the prompt when we've forked off a new debugger.
7234
7235 If the new debugger happened because of a C<system()> that invoked a
7236 program under the debugger, the arrow between the old pid and the new
7237 in the prompt has I<two> dashes instead of one.
7238
7239 We take the current list of pids and add this one to the end. If there
7240 isn't any list yet, we make one up out of the initial pid associated with
7241 the terminal and our new pid, sticking an arrow (either one-dashed or
7242 two dashed) in between them.
7243
7244 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
7245 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
7246 and try to do that.
7247
7248 =cut
7249
7250 sub resetterm {    # We forked, so we need a different TTY
7251
7252     # Needs to be passed to create_IN_OUT() as well.
7253     my $in = shift;
7254
7255     # resetterm(2): got in here because of a system() starting a debugger.
7256     # resetterm(1): just forked.
7257     my $systemed = $in > 1 ? '-' : '';
7258
7259     # If there's already a list of pids, add this to the end.
7260     if ($pids) {
7261         $pids =~ s/\]/$systemed->$$]/;
7262     }
7263
7264     # No pid list. Time to make one.
7265     else {
7266         $pids = "[$term_pid->$$]";
7267     }
7268
7269     # The prompt we're going to be using for this debugger.
7270     $pidprompt = $pids;
7271
7272     # We now 0wnz this terminal.
7273     $term_pid = $$;
7274
7275     # Just return if we're not supposed to try to create a new TTY.
7276     return unless $CreateTTY & $in;
7277
7278     # Try to create a new IN/OUT pair.
7279     create_IN_OUT($in);
7280 } ## end sub resetterm
7281
7282 =head2 C<readline>
7283
7284 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7285 the next line, print a message saying we got it, add it to the terminal
7286 history (if possible), and return it.
7287
7288 If there's nothing in the typeahead buffer, check the command filehandle stack.
7289 If there are any filehandles there, read from the last one, and return the line
7290 if we got one. If not, we pop the filehandle off and close it, and try the
7291 next one up the stack.
7292
7293 If we've emptied the filehandle stack, we check to see if we've got a socket
7294 open, and we read that and return it if we do. If we don't, we just call the
7295 core C<readline()> and return its value.
7296
7297 =cut
7298
7299 sub readline {
7300
7301     # Localize to prevent it from being smashed in the program being debugged.
7302     local $.;
7303
7304     # If there are stacked filehandles to read from ...
7305     # (Handle it before the typeahead, because we may call source/etc. from
7306     # the typeahead.)
7307     while (@cmdfhs) {
7308
7309         # Read from the last one in the stack.
7310         my $line = CORE::readline( $cmdfhs[-1] );
7311
7312         # If we got a line ...
7313         defined $line
7314           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7315           : close pop @cmdfhs;                            # Pop and close
7316     } ## end while (@cmdfhs)
7317
7318     # Pull a line out of the typeahead if there's stuff there.
7319     if (@typeahead) {
7320
7321         # How many lines left.
7322         my $left = @typeahead;
7323
7324         # Get the next line.
7325         my $got = shift @typeahead;
7326
7327         # Print a message saying we got input from the typeahead.
7328         local $\ = '';
7329         print $OUT "auto(-$left)", shift, $got, "\n";
7330
7331         # Add it to the terminal history (if possible).
7332         $term->AddHistory($got)
7333           if length($got) > 1
7334           and defined $term->Features->{addHistory};
7335         return $got;
7336     } ## end if (@typeahead)
7337
7338     # We really need to read some input. Turn off entry/exit trace and
7339     # return value printing.
7340     local $frame = 0;
7341     local $doret = -2;
7342
7343     # Nothing on the filehandle stack. Socket?
7344     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7345
7346         # Send anything we have to send.
7347         $OUT->write( join( '', @_ ) );
7348
7349         # Receive anything there is to receive.
7350         my $stuff = '';
7351         my $buf;
7352         my $first_time = 1;
7353
7354         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7355         {
7356             $first_time = 0;
7357             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7358                                             # XXX Don't know. You tell me.
7359         }
7360
7361         # What we got.
7362         return $stuff;
7363     } ## end if (ref $OUT and UNIVERSAL::isa...
7364
7365     # No socket. Just read from the terminal.
7366     else {
7367         return $term->readline(@_);
7368     }
7369 } ## end sub readline
7370
7371 =head1 OPTIONS SUPPORT ROUTINES
7372
7373 These routines handle listing and setting option values.
7374
7375 =head2 C<dump_option> - list the current value of an option setting
7376
7377 This routine uses C<option_val> to look up the value for an option.
7378 It cleans up escaped single-quotes and then displays the option and
7379 its value.
7380
7381 =cut
7382
7383 sub dump_option {
7384     my ( $opt, $val ) = @_;
7385     $val = option_val( $opt, 'N/A' );
7386     $val =~ s/([\\\'])/\\$1/g;
7387     printf $OUT "%20s = '%s'\n", $opt, $val;
7388 } ## end sub dump_option
7389
7390 sub options2remember {
7391     foreach my $k (@RememberOnROptions) {
7392         $option{$k} = option_val( $k, 'N/A' );
7393     }
7394     return %option;
7395 }
7396
7397 =head2 C<option_val> - find the current value of an option
7398
7399 This can't just be a simple hash lookup because of the indirect way that
7400 the option values are stored. Some are retrieved by calling a subroutine,
7401 some are just variables.
7402
7403 You must supply a default value to be used in case the option isn't set.
7404
7405 =cut
7406
7407 sub option_val {
7408     my ( $opt, $default ) = @_;
7409     my $val;
7410
7411     # Does this option exist, and is it a variable?
7412     # If so, retrieve the value via the value in %optionVars.
7413     if (    defined $optionVars{$opt}
7414         and defined ${ $optionVars{$opt} } )
7415     {
7416         $val = ${ $optionVars{$opt} };
7417     }
7418
7419     # Does this option exist, and it's a subroutine?
7420     # If so, call the subroutine via the ref in %optionAction
7421     # and capture the value.
7422     elsif ( defined $optionAction{$opt}
7423         and defined &{ $optionAction{$opt} } )
7424     {
7425         $val = &{ $optionAction{$opt} }();
7426     }
7427
7428     # If there's an action or variable for the supplied option,
7429     # but no value was set, use the default.
7430     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7431         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7432     {
7433         $val = $default;
7434     }
7435
7436     # Otherwise, do the simple hash lookup.
7437     else {
7438         $val = $option{$opt};
7439     }
7440
7441     # If the value isn't defined, use the default.
7442     # Then return whatever the value is.
7443     $val = $default unless defined $val;
7444     $val;
7445 } ## end sub option_val
7446
7447 =head2 C<parse_options>
7448
7449 Handles the parsing and execution of option setting/displaying commands.
7450
7451 An option entered by itself is assumed to be I<set me to 1> (the default value)
7452 if the option is a boolean one. If not, the user is prompted to enter a valid
7453 value or to query the current value (via C<option? >).
7454
7455 If C<option=value> is entered, we try to extract a quoted string from the
7456 value (if it is quoted). If it's not, we just use the whole value as-is.
7457
7458 We load any modules required to service this option, and then we set it: if
7459 it just gets stuck in a variable, we do that; if there's a subroutine to
7460 handle setting the option, we call that.
7461
7462 Finally, if we're running in interactive mode, we display the effect of the
7463 user's command back to the terminal, skipping this if we're setting things
7464 during initialization.
7465
7466 =cut
7467
7468 sub parse_options {
7469     my ($s) = @_;
7470     local $\ = '';
7471
7472     my $option;
7473
7474     # These options need a value. Don't allow them to be clobbered by accident.
7475     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7476       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7477       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7478     };
7479
7480     while (length($s)) {
7481         my $val_defaulted;
7482
7483         # Clean off excess leading whitespace.
7484         $s =~ s/^\s+// && next;
7485
7486         # Options are always all word characters, followed by a non-word
7487         # separator.
7488         if ($s !~ s/^(\w+)(\W?)//) {
7489             print {$OUT} "Invalid option '$s'\n";
7490             last;
7491         }
7492         my ( $opt, $sep ) = ( $1, $2 );
7493
7494         # Make sure that such an option exists.
7495         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7496           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7497
7498         unless ($matches) {
7499             print {$OUT} "Unknown option '$opt'\n";
7500             next;
7501         }
7502         if ($matches > 1) {
7503             print {$OUT} "Ambiguous option '$opt'\n";
7504             next;
7505         }
7506         my $val;
7507
7508         # '?' as separator means query, but must have whitespace after it.
7509         if ( "?" eq $sep ) {
7510             if ($s =~ /\A\S/) {
7511                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7512
7513                 last;
7514             }
7515
7516             #&dump_option($opt);
7517         } ## end if ("?" eq $sep)
7518
7519         # Separator is whitespace (or just a carriage return).
7520         # They're going for a default, which we assume is 1.
7521         elsif ( $sep !~ /\S/ ) {
7522             $val_defaulted = 1;
7523             $val           = "1";   #  this is an evil default; make 'em set it!
7524         }
7525
7526         # Separator is =. Trying to set a value.
7527         elsif ( $sep eq "=" ) {
7528
7529             # If quoted, extract a quoted string.
7530             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7531                 my $quote = $1;
7532                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7533             }
7534
7535             # Not quoted. Use the whole thing. Warn about 'option='.
7536             else {
7537                 $s =~ s/^(\S*)//;
7538                 $val = $1;
7539                 print OUT qq(Option better cleared using $opt=""\n)
7540                   unless length $val;
7541             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7542
7543         } ## end elsif ($sep eq "=")
7544
7545         # "Quoted" with [], <>, or {}.
7546         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7547             my ($end) =
7548               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7549             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7550               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7551             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7552         } ## end else [ if ("?" eq $sep)
7553
7554         # Exclude non-booleans from getting set to 1 by default.
7555         if ( $opt_needs_val{$option} && $val_defaulted ) {
7556             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7557             print {$OUT}
7558 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7559             next;
7560         } ## end if ($opt_needs_val{$option...
7561
7562         # Save the option value.
7563         $option{$option} = $val if defined $val;
7564
7565         # Load any module that this option requires.
7566         if ( defined($optionRequire{$option}) && defined($val) ) {
7567             eval qq{
7568             local \$frame = 0;
7569             local \$doret = -2;
7570             require '$optionRequire{$option}';
7571             1;
7572             } || die $@   # XXX: shouldn't happen
7573         }
7574
7575         # Set it.
7576         # Stick it in the proper variable if it goes in a variable.
7577         if (defined($optionVars{$option}) && defined($val)) {
7578             ${ $optionVars{$option} } = $val;
7579         }
7580
7581         # Call the appropriate sub if it gets set via sub.
7582         if (defined($optionAction{$option})
7583           && defined (&{ $optionAction{$option} })
7584           && defined ($val))
7585         {
7586           &{ $optionAction{$option} }($val);
7587         }
7588
7589         # Not initialization - echo the value we set it to.
7590         dump_option($option) if ($OUT ne \*STDERR);
7591     } ## end while (length)
7592 } ## end sub parse_options
7593
7594 =head1 RESTART SUPPORT
7595
7596 These routines are used to store (and restore) lists of items in environment
7597 variables during a restart.
7598
7599 =head2 set_list
7600
7601 Set_list packages up items to be stored in a set of environment variables
7602 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7603 the values). Values outside the standard ASCII charset are stored by encoding
7604 them as hexadecimal values.
7605
7606 =cut
7607
7608 sub set_list {
7609     my ( $stem, @list ) = @_;
7610     my $val;
7611
7612     # VAR_n: how many we have. Scalar assignment gets the number of items.
7613     $ENV{"${stem}_n"} = @list;
7614
7615     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7616     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7617     for my $i ( 0 .. $#list ) {
7618         $val = $list[$i];
7619         $val =~ s/\\/\\\\/g;
7620         no warnings 'experimental::regex_sets';
7621         $val =~ s/ ( (?[ [\000-\xFF] & [:^print:] ]) ) /
7622                                                 "\\0x" . unpack('H2',$1)/xaeg;
7623         $ENV{"${stem}_$i"} = $val;
7624     } ## end for $i (0 .. $#list)
7625 } ## end sub set_list
7626
7627 =head2 get_list
7628
7629 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7630 back, and then pull VAR_0, VAR_1. etc. back out.
7631
7632 =cut
7633
7634 sub get_list {
7635     my $stem = shift;
7636     my @list;
7637     my $n = delete $ENV{"${stem}_n"};
7638     my $val;
7639     for my $i ( 0 .. $n - 1 ) {
7640         $val = delete $ENV{"${stem}_$i"};
7641         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7642         push @list, $val;
7643     }
7644     @list;
7645 } ## end sub get_list
7646
7647 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7648
7649 =head2 catch()
7650
7651 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7652 set an already-existing global scalar variable to a constant value. This
7653 avoids allocating any memory possibly in the middle of something that will
7654 get all confused if we do, particularly under I<unsafe signals>.
7655
7656 =cut
7657
7658 sub catch {
7659     $signal = 1;
7660     return;    # Put nothing on the stack - malloc/free land!
7661 }
7662
7663 =head2 C<warn()>
7664
7665 C<warn> emits a warning, by joining together its arguments and printing
7666 them, with couple of fillips.
7667
7668 If the composited message I<doesn't> end with a newline, we automatically
7669 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7670 to be set to the filehandle to be used to output warnings; it makes no
7671 assumptions about what filehandles are available.
7672
7673 =cut
7674
7675 sub _db_warn {
7676     my ($msg) = join( "", @_ );
7677     $msg .= ": $!\n" unless $msg =~ /\n$/;
7678     local $\ = '';
7679     print $OUT $msg;
7680 } ## end sub warn
7681
7682 *warn = \&_db_warn;
7683
7684 =head1 INITIALIZATION TTY SUPPORT
7685
7686 =head2 C<reset_IN_OUT>
7687
7688 This routine handles restoring the debugger's input and output filehandles
7689 after we've tried and failed to move them elsewhere.  In addition, it assigns
7690 the debugger's output filehandle to $LINEINFO if it was already open there.
7691
7692 =cut
7693
7694 sub reset_IN_OUT {
7695     my $switch_li = $LINEINFO eq $OUT;
7696
7697     # If there's a term and it's able to get a new tty, try to get one.
7698     if ( $term and $term->Features->{newTTY} ) {
7699         ( $IN, $OUT ) = ( shift, shift );
7700         $term->newTTY( $IN, $OUT );
7701     }
7702
7703     # This term can't get a new tty now. Better luck later.
7704     elsif ($term) {
7705         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7706     }
7707
7708     # Set the filehndles up as they were.
7709     else {
7710         ( $IN, $OUT ) = ( shift, shift );
7711     }
7712
7713     # Unbuffer the output filehandle.
7714     _autoflush($OUT);
7715
7716     # Point LINEINFO to the same output filehandle if it was there before.
7717     $LINEINFO = $OUT if $switch_li;
7718 } ## end sub reset_IN_OUT
7719
7720 =head1 OPTION SUPPORT ROUTINES
7721
7722 The following routines are used to process some of the more complicated
7723 debugger options.
7724
7725 =head2 C<TTY>
7726
7727 Sets the input and output filehandles to the specified files or pipes.
7728 If the terminal supports switching, we go ahead and do it. If not, and
7729 there's already a terminal in place, we save the information to take effect
7730 on restart.
7731
7732 If there's no terminal yet (for instance, during debugger initialization),
7733 we go ahead and set C<$console> and C<$tty> to the file indicated.
7734
7735 =cut
7736
7737 sub TTY {
7738
7739     if ( @_ and $term and $term->Features->{newTTY} ) {
7740
7741         # This terminal supports switching to a new TTY.
7742         # Can be a list of two files, or on string containing both names,
7743         # comma-separated.
7744         # XXX Should this perhaps be an assignment from @_?
7745         my ( $in, $out ) = shift;
7746         if ( $in =~ /,/ ) {
7747
7748             # Split list apart if supplied.
7749             ( $in, $out ) = split /,/, $in, 2;
7750         }
7751         else {
7752
7753             # Use the same file for both input and output.
7754             $out = $in;
7755         }
7756
7757         # Open file onto the debugger's filehandles, if you can.
7758         open IN,  '<', $in or die "cannot open '$in' for read: $!";
7759         open OUT, '>', $out or die "cannot open '$out' for write: $!";
7760
7761         # Swap to the new filehandles.
7762         reset_IN_OUT( \*IN, \*OUT );
7763
7764         # Save the setting for later.
7765         return $tty = $in;
7766     } ## end if (@_ and $term and $term...
7767
7768     # Terminal doesn't support new TTY, or doesn't support readline.
7769     # Can't do it now, try restarting.
7770     if ($term and @_) {
7771         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7772     }
7773
7774     # Useful if done through PERLDB_OPTS:
7775     $console = $tty = shift if @_;
7776
7777     # Return whatever the TTY is.
7778     $tty or $console;
7779 } ## end sub TTY
7780
7781 =head2 C<noTTY>
7782
7783 Sets the C<$notty> global, controlling whether or not the debugger tries to
7784 get a terminal to read from. If called after a terminal is already in place,
7785 we save the value to use it if we're restarted.
7786
7787 =cut
7788
7789 sub noTTY {
7790     if ($term) {
7791         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7792     }
7793     $notty = shift if @_;
7794     $notty;
7795 } ## end sub noTTY
7796
7797 =head2 C<ReadLine>
7798
7799 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7800 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7801 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7802 the value in case a restart is done so we can change it then.
7803
7804 =cut
7805
7806 sub ReadLine {
7807     if ($term) {
7808         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7809     }
7810     $rl = shift if @_;
7811     $rl;
7812 } ## end sub ReadLine
7813
7814 =head2 C<RemotePort>
7815
7816 Sets the port that the debugger will try to connect to when starting up.
7817 If the terminal's already been set up, we can't do it, but we remember the
7818 setting in case the user does a restart.
7819
7820 =cut
7821
7822 sub RemotePort {
7823     if ($term) {
7824         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7825     }
7826     $remoteport = shift if @_;
7827     $remoteport;
7828 } ## end sub RemotePort
7829
7830 =head2 C<tkRunning>
7831
7832 Checks with the terminal to see if C<Tk> is running, and returns true or
7833 false. Returns false if the current terminal doesn't support C<readline>.
7834
7835 =cut
7836
7837 sub tkRunning {
7838     if ( ${ $term->Features }{tkRunning} ) {
7839         return $term->tkRunning(@_);
7840     }
7841     else {
7842         local $\ = '';
7843         print $OUT "tkRunning not supported by current ReadLine package.\n";
7844         0;
7845     }
7846 } ## end sub tkRunning
7847
7848 =head2 C<NonStop>
7849
7850 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7851 debugger remembers the setting in case you restart, though.
7852
7853 =cut
7854
7855 sub NonStop {
7856     if ($term) {
7857         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7858           if @_;
7859     }
7860     $runnonstop = shift if @_;
7861     $runnonstop;
7862 } ## end sub NonStop
7863
7864 sub DollarCaretP {
7865     if ($term) {
7866         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7867           if @_;
7868     }
7869     $^P = parse_DollarCaretP_flags(shift) if @_;
7870     expand_DollarCaretP_flags($^P);
7871 }
7872
7873 =head2 C<pager>
7874
7875 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7876 there already.
7877
7878 =cut
7879
7880 sub pager {
7881     if (@_) {
7882         $pager = shift;
7883         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7884     }
7885     $pager;
7886 } ## end sub pager
7887
7888 =head2 C<shellBang>
7889
7890 Sets the shell escape command, and generates a printable copy to be used
7891 in the help.
7892
7893 =cut
7894
7895 sub shellBang {
7896
7897     # If we got an argument, meta-quote it, and add '\b' if it
7898     # ends in a word character.
7899     if (@_) {
7900         $sh = quotemeta shift;
7901         $sh .= "\\b" if $sh =~ /\w$/;
7902     }
7903
7904     # Generate the printable version for the help:
7905     $psh = $sh;    # copy it
7906     $psh =~ s/\\b$//;        # Take off trailing \b if any
7907     $psh =~ s/\\(.)/$1/g;    # De-escape
7908     $psh;                    # return the printable version
7909 } ## end sub shellBang
7910
7911 =head2 C<ornaments>
7912
7913 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7914 was passed as the argument. (This means you can't override the terminal's
7915 ornaments.)
7916
7917 =cut
7918
7919 sub ornaments {
7920     if ( defined $term ) {
7921
7922         # We don't want to show warning backtraces, but we do want die() ones.
7923         local $warnLevel = 0;
7924         local $dieLevel = 1;
7925
7926         # No ornaments if the terminal doesn't support them.
7927         if (not $term->Features->{ornaments}) {
7928             return '';
7929         }
7930
7931         return (eval { $term->ornaments(@_) } || '');
7932     }
7933
7934     # Use what was passed in if we can't determine it ourselves.
7935     else {
7936         $ornaments = shift;
7937
7938         return $ornaments;
7939     }
7940
7941 } ## end sub ornaments
7942
7943 =head2 C<recallCommand>
7944
7945 Sets the recall command, and builds a printable version which will appear in
7946 the help text.
7947
7948 =cut
7949
7950 sub recallCommand {
7951
7952     # If there is input, metaquote it. Add '\b' if it ends with a word
7953     # character.
7954     if (@_) {
7955         $rc = quotemeta shift;
7956         $rc .= "\\b" if $rc =~ /\w$/;
7957     }
7958
7959     # Build it into a printable version.
7960     $prc = $rc;              # Copy it
7961     $prc =~ s/\\b$//;        # Remove trailing \b
7962     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7963     return $prc;             # Return the printable version
7964 } ## end sub recallCommand
7965
7966 =head2 C<LineInfo> - where the line number information goes
7967
7968 Called with no arguments, returns the file or pipe that line info should go to.
7969
7970 Called with an argument (a file or a pipe), it opens that onto the
7971 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7972 file or pipe again to the caller.
7973
7974 =cut
7975
7976 sub LineInfo {
7977     if (@_) {
7978         $lineinfo = shift;
7979
7980         #  If this is a valid "thing to be opened for output", tack a
7981         # '>' onto the front.
7982         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7983
7984         # If this is a pipe, the stream points to a slave editor.
7985         $slave_editor = ( $stream =~ /^\|/ );
7986
7987         my $new_lineinfo_fh;
7988         # Open it up and unbuffer it.
7989         open ($new_lineinfo_fh , $stream )
7990             or _db_warn("Cannot open '$stream' for write");
7991         $LINEINFO = $new_lineinfo_fh;
7992         _autoflush($LINEINFO);
7993     }
7994
7995     return $lineinfo;
7996 } ## end sub LineInfo
7997
7998 =head1 COMMAND SUPPORT ROUTINES
7999
8000 These subroutines provide functionality for various commands.
8001
8002 =head2 C<list_modules>
8003
8004 For the C<M> command: list modules loaded and their versions.
8005 Essentially just runs through the keys in %INC, picks each package's
8006 C<$VERSION> variable, gets the file name, and formats the information
8007 for output.
8008
8009 =cut
8010
8011 sub list_modules {    # versions
8012     my %version;
8013     my $file;
8014
8015     # keys are the "as-loaded" name, values are the fully-qualified path
8016     # to the file itself.
8017     for ( keys %INC ) {
8018         $file = $_;                                # get the module name
8019         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
8020         s,/,::,g;                                  # change '/' to '::'
8021         s/^perl5db$/DB/;                           # Special case: debugger
8022                                                    # moves to package DB
8023         s/^Term::ReadLine::readline$/readline/;    # simplify readline
8024
8025         # If the package has a $VERSION package global (as all good packages
8026         # should!) decode it and save as partial message.
8027         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
8028         if ( defined $pkg_version ) {
8029             $version{$file} = "$pkg_version from ";
8030         }
8031
8032         # Finish up the message with the file the package came from.
8033         $version{$file} .= $INC{$file};
8034     } ## end for (keys %INC)
8035
8036     # Hey, dumpit() formats a hash nicely, so why not use it?
8037     dumpit( $OUT, \%version );
8038 } ## end sub list_modules
8039
8040 =head2 C<sethelp()>
8041
8042 Sets up the monster string used to format and print the help.
8043
8044 =head3 HELP MESSAGE FORMAT
8045
8046 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
8047 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
8048 easy to parse and portable, but which still allows the help to be a little
8049 nicer than just plain text.
8050
8051 Essentially, you define the command name (usually marked up with C<< B<> >>
8052 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
8053 newline. The descriptive text can also be marked up in the same way. If you
8054 need to continue the descriptive text to another line, start that line with
8055 just tabs and then enter the marked-up text.
8056
8057 If you are modifying the help text, I<be careful>. The help-string parser is
8058 not very sophisticated, and if you don't follow these rules it will mangle the
8059 help beyond hope until you fix the string.
8060
8061 =cut
8062
8063 use vars qw($pre580_help);
8064 use vars qw($pre580_summary);
8065
8066 sub sethelp {
8067
8068     # XXX: make sure there are tabs between the command and explanation,
8069     #      or print_help will screw up your formatting if you have
8070     #      eeevil ornaments enabled.  This is an insane mess.
8071
8072     $help = "
8073 Help is currently only available for the new 5.8 command set.
8074 No help is available for the old command set.
8075 We assume you know what you're doing if you switch to it.
8076
8077 B<T>        Stack trace.
8078 B<s> [I<expr>]    Single step [in I<expr>].
8079 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8080 <B<CR>>        Repeat last B<n> or B<s> command.
8081 B<r>        Return from current subroutine.
8082 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8083         at the specified position.
8084 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8085 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8086 B<l> I<line>        List single I<line>.
8087 B<l> I<subname>    List first window of lines from subroutine.
8088 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8089 B<l>        List next window of lines.
8090 B<->        List previous window of lines.
8091 B<v> [I<line>]    View window around I<line>.
8092 B<.>        Return to the executed line.
8093 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8094         I<filename> may be either the full name of the file, or a regular
8095         expression matching the full file name:
8096         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8097         Evals (with saved bodies) are considered to be filenames:
8098         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8099         (in the order of execution).
8100 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8101 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8102 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
8103 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8104 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
8105 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8106 B<b>        Sets breakpoint on current line)
8107 B<b> [I<line>] [I<condition>]
8108         Set breakpoint; I<line> defaults to the current execution line;
8109         I<condition> breaks if it evaluates to true, defaults to '1'.
8110 B<b> I<subname> [I<condition>]
8111         Set breakpoint at first line of subroutine.
8112 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8113 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8114 B<b> B<postpone> I<subname> [I<condition>]
8115         Set breakpoint at first line of subroutine after
8116         it is compiled.
8117 B<b> B<compile> I<subname>
8118         Stop after the subroutine is compiled.
8119 B<B> [I<line>]    Delete the breakpoint for I<line>.
8120 B<B> I<*>             Delete all breakpoints.
8121 B<a> [I<line>] I<command>
8122         Set an action to be done before the I<line> is executed;
8123         I<line> defaults to the current execution line.
8124         Sequence is: check for breakpoint/watchpoint, print line
8125         if necessary, do action, prompt user if necessary,
8126         execute line.
8127 B<a>        Does nothing
8128 B<A> [I<line>]    Delete the action for I<line>.
8129 B<A> I<*>             Delete all actions.
8130 B<w> I<expr>        Add a global watch-expression.
8131 B<w>             Does nothing
8132 B<W> I<expr>        Delete a global watch-expression.
8133 B<W> I<*>             Delete all watch-expressions.
8134 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8135         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8136 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8137 B<x> I<expr>        Evals expression in list context, dumps the result.
8138 B<m> I<expr>        Evals expression in list context, prints methods callable
8139         on the first element of the result.
8140 B<m> I<class>        Prints methods callable via the given class.
8141 B<M>        Show versions of loaded modules.
8142 B<i> I<class>       Prints nested parents of given class.
8143 B<e>         Display current thread id.
8144 B<E>         Display all thread ids the current one will be identified: <n>.
8145 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8146
8147 B<<> ?            List Perl commands to run before each prompt.
8148 B<<> I<expr>        Define Perl command to run before each prompt.
8149 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8150 B<< *>                Delete the list of perl commands to run before each prompt.
8151 B<>> ?            List Perl commands to run after each prompt.
8152 B<>> I<expr>        Define Perl command to run after each prompt.
8153 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8154 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
8155 B<{> I<db_command>    Define debugger command to run before each prompt.
8156 B<{> ?            List debugger commands to run before each prompt.
8157 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8158 B<{ *>             Delete the list of debugger commands to run before each prompt.
8159 B<$prc> I<number>    Redo a previous command (default previous command).
8160 B<$prc> I<-number>    Redo number'th-to-last command.
8161 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8162         See 'B<O> I<recallCommand>' too.
8163 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8164       . (
8165         $rc eq $sh
8166         ? ""
8167         : "
8168 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8169       ) . "
8170         See 'B<O> I<shellBang>' too.
8171 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
8172 B<save> I<file>       Save current debugger session (actual history) to I<file>.
8173 B<rerun>           Rerun session to current position.
8174 B<rerun> I<n>         Rerun session to numbered command.
8175 B<rerun> I<-n>        Rerun session to number'th-to-last command.
8176 B<H> I<-number>    Display last number commands (default all).
8177 B<H> I<*>          Delete complete history.
8178 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8179 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8180 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
8181 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8182 I<command>        Execute as a perl statement in current package.
8183 B<R>        Pure-man-restart of debugger, some of debugger state
8184         and command-line options may be lost.
8185         Currently the following settings are preserved:
8186         history, breakpoints and actions, debugger B<O>ptions
8187         and the following command-line options: I<-w>, I<-I>, I<-e>.
8188
8189 B<o> [I<opt>] ...    Set boolean option to true
8190 B<o> [I<opt>B<?>]    Query options
8191 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8192         Set options.  Use quotes if spaces in value.
8193     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8194     I<pager>            program for output of \"|cmd\";
8195     I<tkRunning>            run Tk while prompting (with ReadLine);
8196     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8197     I<inhibit_exit>        Allows stepping off the end of the script.
8198     I<ImmediateStop>        Debugger should stop as early as possible.
8199     I<RemotePort>            Remote hostname:port for remote debugging
8200   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8201     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8202     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8203     I<globPrint>             whether to print contents of globs;
8204     I<DumpDBFiles>         dump arrays holding debugged files;
8205     I<DumpPackages>         dump symbol tables of packages;
8206     I<DumpReused>             dump contents of \"reused\" addresses;
8207     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8208     I<bareStringify>         Do not print the overload-stringified value;
8209   Other options include:
8210     I<PrintRet>        affects printing of return value after B<r> command,
8211     I<frame>        affects printing messages on subroutine entry/exit.
8212     I<AutoTrace>    affects printing messages on possible breaking points.
8213     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8214     I<ornaments>     affects screen appearance of the command line.
8215     I<CreateTTY>     bits control attempts to create a new TTY on events:
8216             1: on fork()    2: debugger is started inside debugger
8217             4: on startup
8218     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8219     You can put additional initialization options I<TTY>, I<noTTY>,
8220     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8221     B<R> after you set them).
8222
8223 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8224 B<h>        Summary of debugger commands.
8225 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8226 B<h h>        Long help for debugger commands
8227 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8228         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8229         Set B<\$DB::doccmd> to change viewer.
8230
8231 Type '|h h' for a paged display if this was too hard to read.
8232
8233 ";    # Fix balance of vi % matching: }}}}
8234
8235     #  note: tabs in the following section are not-so-helpful
8236     $summary = <<"END_SUM";
8237 I<List/search source lines:>               I<Control script execution:>
8238   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8239   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8240   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
8241   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8242   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8243   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
8244 I<Debugger controls:>                        B<L>           List break/watch/actions
8245   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
8246   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8247   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
8248   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8249   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
8250   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
8251   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
8252   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8253   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8254 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8255   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8256   B<p> I<expr>         Print expression (uses script's current package).
8257   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8258   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8259   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
8260   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8261   B<e>     Display thread id     B<E> Display all thread ids.
8262 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8263 END_SUM
8264
8265     # ')}}; # Fix balance of vi % matching
8266
8267     # and this is really numb...
8268     $pre580_help = "
8269 B<T>        Stack trace.
8270 B<s> [I<expr>]    Single step [in I<expr>].
8271 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8272 B<CR>>        Repeat last B<n> or B<s> command.
8273 B<r>        Return from current subroutine.
8274 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8275         at the specified position.
8276 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8277 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8278 B<l> I<line>        List single I<line>.
8279 B<l> I<subname>    List first window of lines from subroutine.
8280 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8281 B<l>        List next window of lines.
8282 B<->        List previous window of lines.
8283 B<w> [I<line>]    List window around I<line>.
8284 B<.>        Return to the executed line.
8285 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8286         I<filename> may be either the full name of the file, or a regular
8287         expression matching the full file name:
8288         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8289         Evals (with saved bodies) are considered to be filenames:
8290         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8291         (in the order of execution).
8292 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8293 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8294 B<L>        List all breakpoints and actions.
8295 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8296 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8297 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8298 B<b> [I<line>] [I<condition>]
8299         Set breakpoint; I<line> defaults to the current execution line;
8300         I<condition> breaks if it evaluates to true, defaults to '1'.
8301 B<b> I<subname> [I<condition>]
8302         Set breakpoint at first line of subroutine.
8303 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8304 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8305 B<b> B<postpone> I<subname> [I<condition>]
8306         Set breakpoint at first line of subroutine after
8307         it is compiled.
8308 B<b> B<compile> I<subname>
8309         Stop after the subroutine is compiled.
8310 B<d> [I<line>]    Delete the breakpoint for I<line>.
8311 B<D>        Delete all breakpoints.
8312 B<a> [I<line>] I<command>
8313         Set an action to be done before the I<line> is executed;
8314         I<line> defaults to the current execution line.
8315         Sequence is: check for breakpoint/watchpoint, print line
8316         if necessary, do action, prompt user if necessary,
8317         execute line.
8318 B<a> [I<line>]    Delete the action for I<line>.
8319 B<A>        Delete all actions.
8320 B<W> I<expr>        Add a global watch-expression.
8321 B<W>        Delete all watch-expressions.
8322 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8323         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8324 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8325 B<x> I<expr>        Evals expression in list context, dumps the result.
8326 B<m> I<expr>        Evals expression in list context, prints methods callable
8327         on the first element of the result.
8328 B<m> I<class>        Prints methods callable via the given class.
8329
8330 B<<> ?            List Perl commands to run before each prompt.
8331 B<<> I<expr>        Define Perl command to run before each prompt.
8332 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8333 B<>> ?            List Perl commands to run after each prompt.
8334 B<>> I<expr>        Define Perl command to run after each prompt.
8335 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8336 B<{> I<db_command>    Define debugger command to run before each prompt.
8337 B<{> ?            List debugger commands to run before each prompt.
8338 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8339 B<$prc> I<number>    Redo a previous command (default previous command).
8340 B<$prc> I<-number>    Redo number'th-to-last command.
8341 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8342         See 'B<O> I<recallCommand>' too.
8343 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8344       . (
8345         $rc eq $sh
8346         ? ""
8347         : "
8348 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8349       ) . "
8350         See 'B<O> I<shellBang>' too.
8351 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8352 B<H> I<-number>    Display last number commands (default all).
8353 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8354 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8355 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8356 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8357 I<command>        Execute as a perl statement in current package.
8358 B<v>        Show versions of loaded modules.
8359 B<R>        Pure-man-restart of debugger, some of debugger state
8360         and command-line options may be lost.
8361         Currently the following settings are preserved:
8362         history, breakpoints and actions, debugger B<O>ptions
8363         and the following command-line options: I<-w>, I<-I>, I<-e>.
8364
8365 B<O> [I<opt>] ...    Set boolean option to true
8366 B<O> [I<opt>B<?>]    Query options
8367 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8368         Set options.  Use quotes if spaces in value.
8369     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8370     I<pager>            program for output of \"|cmd\";
8371     I<tkRunning>            run Tk while prompting (with ReadLine);
8372     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8373     I<inhibit_exit>        Allows stepping off the end of the script.
8374     I<ImmediateStop>        Debugger should stop as early as possible.
8375     I<RemotePort>            Remote hostname:port for remote debugging
8376   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8377     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8378     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8379     I<globPrint>             whether to print contents of globs;
8380     I<DumpDBFiles>         dump arrays holding debugged files;
8381     I<DumpPackages>         dump symbol tables of packages;
8382     I<DumpReused>             dump contents of \"reused\" addresses;
8383     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8384     I<bareStringify>         Do not print the overload-stringified value;
8385   Other options include:
8386     I<PrintRet>        affects printing of return value after B<r> command,
8387     I<frame>        affects printing messages on subroutine entry/exit.
8388     I<AutoTrace>    affects printing messages on possible breaking points.
8389     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8390     I<ornaments>     affects screen appearance of the command line.
8391     I<CreateTTY>     bits control attempts to create a new TTY on events:
8392             1: on fork()    2: debugger is started inside debugger
8393             4: on startup
8394     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8395     You can put additional initialization options I<TTY>, I<noTTY>,
8396     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8397     B<R> after you set them).
8398
8399 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8400 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8401 B<h h>        Summary of debugger commands.
8402 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8403         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8404         Set B<\$DB::doccmd> to change viewer.
8405
8406 Type '|h' for a paged display if this was too hard to read.
8407
8408 ";    # Fix balance of vi % matching: }}}}
8409
8410     #  note: tabs in the following section are not-so-helpful
8411     $pre580_summary = <<"END_SUM";
8412 I<List/search source lines:>               I<Control script execution:>
8413   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8414   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8415   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8416   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8417   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8418   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8419 I<Debugger controls:>                        B<L>           List break/watch/actions
8420   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8421   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8422   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8423   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8424   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8425   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8426   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8427   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8428 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8429   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8430   B<p> I<expr>         Print expression (uses script's current package).
8431   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8432   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8433   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8434   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8435 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8436 END_SUM
8437
8438     # ')}}; # Fix balance of vi % matching
8439
8440 } ## end sub sethelp
8441
8442 =head2 C<print_help()>
8443
8444 Most of what C<print_help> does is just text formatting. It finds the
8445 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8446 terminal control characters to simulate them (courtesy of
8447 C<Term::ReadLine::TermCap>).
8448
8449 =cut
8450
8451 sub print_help {
8452     my $help_str = shift;
8453
8454     # Restore proper alignment destroyed by eeevil I<> and B<>
8455     # ornaments: A pox on both their houses!
8456     #
8457     # A help command will have everything up to and including
8458     # the first tab sequence padded into a field 16 (or if indented 20)
8459     # wide.  If it's wider than that, an extra space will be added.
8460     $help_str =~ s{
8461         ^                       # only matters at start of line
8462           ( \ {4} | \t )*       # some subcommands are indented
8463           ( < ?                 # so <CR> works
8464             [BI] < [^\t\n] + )  # find an eeevil ornament
8465           ( \t+ )               # original separation, discarded
8466           ( .* )                # this will now start (no earlier) than
8467                                 # column 16
8468     } {
8469         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8470         my $clean = $command;
8471         $clean =~ s/[BI]<([^>]*)>/$1/g;
8472
8473         # replace with this whole string:
8474         ($leadwhite ? " " x 4 : "")
8475       . $command
8476       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8477       . $text;
8478
8479     }mgex;
8480
8481     $help_str =~ s{                          # handle bold ornaments
8482        B < ( [^>] + | > ) >
8483     } {
8484           $Term::ReadLine::TermCap::rl_term_set[2]
8485         . $1
8486         . $Term::ReadLine::TermCap::rl_term_set[3]
8487     }gex;
8488
8489     $help_str =~ s{                         # handle italic ornaments
8490        I < ( [^>] + | > ) >
8491     } {
8492           $Term::ReadLine::TermCap::rl_term_set[0]
8493         . $1
8494         . $Term::ReadLine::TermCap::rl_term_set[1]
8495     }gex;
8496
8497     local $\ = '';
8498     print {$OUT} $help_str;
8499
8500     return;
8501 } ## end sub print_help
8502
8503 =head2 C<fix_less>
8504
8505 This routine does a lot of gyrations to be sure that the pager is C<less>.
8506 It checks for C<less> masquerading as C<more> and records the result in
8507 C<$fixed_less> so we don't have to go through doing the stats again.
8508
8509 =cut
8510
8511 use vars qw($fixed_less);
8512
8513 sub _calc_is_less {
8514     if ($pager =~ /\bless\b/)
8515     {
8516         return 1;
8517     }
8518     elsif ($pager =~ /\bmore\b/)
8519     {
8520         # Nope, set to more. See what's out there.
8521         my @st_more = stat('/usr/bin/more');
8522         my @st_less = stat('/usr/bin/less');
8523
8524         # is it really less, pretending to be more?
8525         return (
8526             @st_more
8527             && @st_less
8528             && $st_more[0] == $st_less[0]
8529             && $st_more[1] == $st_less[1]
8530         );
8531     }
8532     else {
8533         return;
8534     }
8535 }
8536
8537 sub fix_less {
8538
8539     # We already know if this is set.
8540     return if $fixed_less;
8541
8542     # changes environment!
8543     # 'r' added so we don't do (slow) stats again.
8544     $fixed_less = 1 if _calc_is_less();
8545
8546     return;
8547 } ## end sub fix_less
8548
8549 =head1 DIE AND WARN MANAGEMENT
8550
8551 =head2 C<diesignal>
8552
8553 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8554 to debug a debugger problem.
8555
8556 It does its best to report the error that occurred, and then forces the
8557 program, debugger, and everything to die.
8558
8559 =cut
8560
8561 sub diesignal {
8562
8563     # No entry/exit messages.
8564     local $frame = 0;
8565
8566     # No return value prints.
8567     local $doret = -2;
8568
8569     # set the abort signal handling to the default (just terminate).
8570     $SIG{'ABRT'} = 'DEFAULT';
8571
8572     # If we enter the signal handler recursively, kill myself with an
8573     # abort signal (so we just terminate).
8574     kill 'ABRT', $$ if $panic++;
8575
8576     # If we can show detailed info, do so.
8577     if ( defined &Carp::longmess ) {
8578
8579         # Don't recursively enter the warn handler, since we're carping.
8580         local $SIG{__WARN__} = '';
8581
8582         # Skip two levels before reporting traceback: we're skipping
8583         # mydie and confess.
8584         local $Carp::CarpLevel = 2;    # mydie + confess
8585
8586         # Tell us all about it.
8587         _db_warn( Carp::longmess("Signal @_") );
8588     }
8589
8590     # No Carp. Tell us about the signal as best we can.
8591     else {
8592         local $\ = '';
8593         print $DB::OUT "Got signal @_\n";
8594     }
8595
8596     # Drop dead.
8597     kill 'ABRT', $$;
8598 } ## end sub diesignal
8599
8600 =head2 C<dbwarn>
8601
8602 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8603 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8604
8605 =cut
8606
8607 sub dbwarn {
8608
8609     # No entry/exit trace.
8610     local $frame = 0;
8611
8612     # No return value printing.
8613     local $doret = -2;
8614
8615     # Turn off warn and die handling to prevent recursive entries to this
8616     # routine.
8617     local $SIG{__WARN__} = '';
8618     local $SIG{__DIE__}  = '';
8619
8620     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8621     # done yet), we may not be able to do a require.
8622     eval { require Carp }
8623       if defined $^S;    # If error/warning during compilation,
8624                          # require may be broken.
8625
8626     # Use the core warn() unless Carp loaded OK.
8627     CORE::warn( @_,
8628         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8629       return
8630       unless defined &Carp::longmess;
8631
8632     # Save the current values of $single and $trace, and then turn them off.
8633     my ( $mysingle, $mytrace ) = ( $single, $trace );
8634     $single = 0;
8635     $trace  = 0;
8636
8637     # We can call Carp::longmess without its being "debugged" (which we
8638     # don't want - we just want to use it!). Capture this for later.
8639     my $mess = Carp::longmess(@_);
8640
8641     # Restore $single and $trace to their original values.
8642     ( $single, $trace ) = ( $mysingle, $mytrace );
8643
8644     # Use the debugger's own special way of printing warnings to print
8645     # the stack trace message.
8646     _db_warn($mess);
8647 } ## end sub dbwarn
8648
8649 =head2 C<dbdie>
8650
8651 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8652 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8653 single stepping and tracing during the call to C<Carp::longmess> to avoid
8654 debugging it - we just want to use it.
8655
8656 If C<dieLevel> is zero, we let the program being debugged handle the
8657 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8658 the debugger takes over all exception handling, printing a backtrace and
8659 displaying the exception via its C<dbwarn()> routine.
8660
8661 =cut
8662
8663 sub dbdie {
8664     local $frame         = 0;
8665     local $doret         = -2;
8666     local $SIG{__DIE__}  = '';
8667     local $SIG{__WARN__} = '';
8668     if ( $dieLevel > 2 ) {
8669         local $SIG{__WARN__} = \&dbwarn;
8670         _db_warn(@_);    # Yell no matter what
8671         return;
8672     }
8673     if ( $dieLevel < 2 ) {
8674         die @_ if $^S;    # in eval propagate
8675     }
8676
8677     # The code used to check $^S to see if compilation of the current thing
8678     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8679     eval { require Carp };
8680
8681     die( @_,
8682         "\nCannot print stack trace, load with -MCarp option to see stack" )
8683       unless defined &Carp::longmess;
8684
8685     # We do not want to debug this chunk (automatic disabling works
8686     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8687     # get the stack trace from Carp::longmess (if possible), restore $signal
8688     # and $trace, and then die with the stack trace.
8689     my ( $mysingle, $mytrace ) = ( $single, $trace );
8690     $single = 0;
8691     $trace  = 0;
8692     my $mess = "@_";
8693     {
8694
8695         package Carp;    # Do not include us in the list
8696         eval { $mess = Carp::longmess(@_); };
8697     }
8698     ( $single, $trace ) = ( $mysingle, $mytrace );
8699     die $mess;
8700 } ## end sub dbdie
8701
8702 =head2 C<warnlevel()>
8703
8704 Set the C<$DB::warnLevel> variable that stores the value of the
8705 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8706 results in the debugger taking over all warning handlers. Setting
8707 C<warnLevel> to zero leaves any warning handlers set up by the program
8708 being debugged in place.
8709
8710 =cut
8711
8712 sub warnLevel {
8713     if (@_) {
8714         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8715         $warnLevel = shift;
8716         if ($warnLevel) {
8717             $SIG{__WARN__} = \&DB::dbwarn;
8718         }
8719         elsif ($prevwarn) {
8720             $SIG{__WARN__} = $prevwarn;
8721         } else {
8722             undef $SIG{__WARN__};
8723         }
8724     } ## end if (@_)
8725     $warnLevel;
8726 } ## end sub warnLevel
8727
8728 =head2 C<dielevel>
8729
8730 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8731 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8732 zero lets you use your own C<die()> handler.
8733
8734 =cut
8735
8736 sub dieLevel {
8737     local $\ = '';
8738     if (@_) {
8739         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8740         $dieLevel = shift;
8741         if ($dieLevel) {
8742
8743             # Always set it to dbdie() for non-zero values.
8744             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8745
8746             # No longer exists, so don't try  to use it.
8747             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8748
8749             # If we've finished initialization, mention that stack dumps
8750             # are enabled, If dieLevel is 1, we won't stack dump if we die
8751             # in an eval().
8752             print $OUT "Stack dump during die enabled",
8753               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8754               if $I_m_init;
8755
8756             # XXX This is probably obsolete, given that diehard() is gone.
8757             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8758         } ## end if ($dieLevel)
8759
8760         # Put the old one back if there was one.
8761         elsif ($prevdie) {
8762             $SIG{__DIE__} = $prevdie;
8763             print $OUT "Default die handler restored.\n";
8764         } else {
8765             undef $SIG{__DIE__};
8766             print $OUT "Die handler removed.\n";
8767         }
8768     } ## end if (@_)
8769     $dieLevel;
8770 } ## end sub dieLevel
8771
8772 =head2 C<signalLevel>
8773
8774 Number three in a series: set C<signalLevel> to zero to keep your own
8775 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8776 takes over and handles them with C<DB::diesignal()>.
8777
8778 =cut
8779
8780 sub signalLevel {
8781     if (@_) {
8782         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8783         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8784         $signalLevel = shift;
8785         if ($signalLevel) {
8786             $SIG{SEGV} = \&DB::diesignal;
8787             $SIG{BUS}  = \&DB::diesignal;
8788         }
8789         else {
8790             $SIG{SEGV} = $prevsegv;
8791             $SIG{BUS}  = $prevbus;
8792         }
8793     } ## end if (@_)
8794     $signalLevel;
8795 } ## end sub signalLevel
8796
8797 =head1 SUBROUTINE DECODING SUPPORT
8798
8799 These subroutines are used during the C<x> and C<X> commands to try to
8800 produce as much information as possible about a code reference. They use
8801 L<Devel::Peek> to try to find the glob in which this code reference lives
8802 (if it does) - this allows us to actually code references which correspond
8803 to named subroutines (including those aliased via glob assignment).
8804
8805 =head2 C<CvGV_name()>
8806
8807 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8808 via that routine. If this fails, return the reference again (when the
8809 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8810
8811 =cut
8812
8813 sub CvGV_name {
8814     my $in   = shift;
8815     my $name = CvGV_name_or_bust($in);
8816     defined $name ? $name : $in;
8817 }
8818
8819 =head2 C<CvGV_name_or_bust> I<coderef>
8820
8821 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8822 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8823 find a glob for this ref.
8824
8825 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8826
8827 =cut
8828
8829 use vars qw($skipCvGV);
8830
8831 sub CvGV_name_or_bust {
8832     my $in = shift;
8833     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8834     return unless ref $in;
8835     $in = \&$in;            # Hard reference...
8836     eval { require Devel::Peek; 1 } or return;
8837     my $gv = Devel::Peek::CvGV($in) or return;
8838     *$gv{PACKAGE} . '::' . *$gv{NAME};
8839 } ## end sub CvGV_name_or_bust
8840
8841 =head2 C<find_sub>
8842
8843 A utility routine used in various places; finds the file where a subroutine
8844 was defined, and returns that filename and a line-number range.
8845
8846 Tries to use C<@sub> first; if it can't find it there, it tries building a
8847 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8848 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8849 this way, it brute-force searches C<%sub>, checking for identical references.
8850
8851 =cut
8852
8853 sub _find_sub_helper {
8854     my $subr = shift;
8855
8856     return unless defined &$subr;
8857     my $name = CvGV_name_or_bust($subr);
8858     my $data;
8859     $data = $sub{$name} if defined $name;
8860     return $data if defined $data;
8861
8862     # Old stupid way...
8863     $subr = \&$subr;    # Hard reference
8864     my $s;
8865     for ( keys %sub ) {
8866         $s = $_, last if $subr eq \&$_;
8867     }
8868     if ($s)
8869     {
8870         return $sub{$s};
8871     }
8872     else
8873     {
8874         return;
8875     }
8876
8877 }
8878
8879 sub find_sub {
8880     my $subr = shift;
8881     return ( $sub{$subr} || _find_sub_helper($subr) );
8882 } ## end sub find_sub
8883
8884 =head2 C<methods>
8885
8886 A subroutine that uses the utility function C<methods_via> to find all the
8887 methods in the class corresponding to the current reference and in
8888 C<UNIVERSAL>.
8889
8890 =cut
8891
8892 use vars qw(%seen);
8893
8894 sub methods {
8895
8896     # Figure out the class - either this is the class or it's a reference
8897     # to something blessed into that class.
8898     my $class = shift;
8899     $class = ref $class if ref $class;
8900
8901     local %seen;
8902
8903     # Show the methods that this class has.
8904     methods_via( $class, '', 1 );
8905
8906     # Show the methods that UNIVERSAL has.
8907     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8908 } ## end sub methods
8909
8910 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8911
8912 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8913 all the parent class methods. C<$class> is the name of the next class to
8914 try; C<$prefix> is the message prefix, which gets built up as we go up the
8915 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8916 higher in the C<@ISA> tree, 0 if we should stop.
8917
8918 =cut
8919
8920 sub methods_via {
8921
8922     # If we've processed this class already, just quit.
8923     my $class = shift;
8924     return if $seen{$class}++;
8925
8926     # This is a package that is contributing the methods we're about to print.
8927     my $prefix  = shift;
8928     my $prepend = $prefix ? "via $prefix: " : '';
8929     my @to_print;
8930
8931     # Extract from all the symbols in this class.
8932     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8933     while (my ($name, $glob) = each %$class_ref) {
8934         # references directly in the symbol table are Proxy Constant
8935         # Subroutines, and are by their very nature defined
8936         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8937         # to a subroutine reference, which can be tested by defined.
8938         # $glob might also be the value -1  (from sub foo;)
8939         # or (say) '$$' (from sub foo ($$);)
8940         # \$glob will be SCALAR in both cases.
8941         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8942             && !$seen{$name}++) {
8943             push @to_print, "$prepend$name\n";
8944         }
8945     }
8946
8947     {
8948         local $\ = '';
8949         local $, = '';
8950         print $DB::OUT $_ foreach sort @to_print;
8951     }
8952
8953     # If the $crawl_upward argument is false, just quit here.
8954     return unless shift;
8955
8956     # $crawl_upward true: keep going up the tree.
8957     # Find all the classes this one is a subclass of.
8958     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8959     for my $name ( @$class_ISA_ref ) {
8960
8961         # Set up the new prefix.
8962         $prepend = $prefix ? $prefix . " -> $name" : $name;
8963
8964         # Crawl up the tree and keep trying to crawl up.
8965         methods_via( $name, $prepend, 1 );
8966     }
8967 } ## end sub methods_via
8968
8969 =head2 C<setman> - figure out which command to use to show documentation
8970
8971 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8972
8973 =cut
8974
8975 sub setman {
8976     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8977       ? "man"         # O Happy Day!
8978       : "perldoc";    # Alas, poor unfortunates
8979 } ## end sub setman
8980
8981 =head2 C<runman> - run the appropriate command to show documentation
8982
8983 Accepts a man page name; runs the appropriate command to display it (set up
8984 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8985 program's STDIN and STDOUT.
8986
8987 =cut
8988
8989 sub runman {
8990     my $page = shift;
8991     unless ($page) {
8992         _db_system("$doccmd $doccmd");
8993         return;
8994     }
8995
8996     # this way user can override, like with $doccmd="man -Mwhatever"
8997     # or even just "man " to disable the path check.
8998     if ( $doccmd ne 'man' ) {
8999         _db_system("$doccmd $page");
9000         return;
9001     }
9002
9003     $page = 'perl' if lc($page) eq 'help';
9004
9005     require Config;
9006     my $man1dir = $Config::Config{man1direxp};
9007     my $man3dir = $Config::Config{man3direxp};
9008     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
9009     my $manpath = '';
9010     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
9011     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
9012     chop $manpath if $manpath;
9013
9014     # harmless if missing, I figure
9015     local $ENV{MANPATH} = $manpath if $manpath;
9016     my $nopathopt = $^O =~ /dunno what goes here/;
9017     if (
9018         CORE::system(
9019             $doccmd,
9020
9021             # I just *know* there are men without -M
9022             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9023             split ' ', $page
9024         )
9025       )
9026     {
9027         unless ( $page =~ /^perl\w/ ) {
9028             # Previously the debugger contained a list which it slurped in,
9029             # listing the known "perl" manpages. However, it was out of date,
9030             # with errors both of omission and inclusion. This approach is
9031             # considerably less complex. The failure mode on a butchered
9032             # install is simply that the user has to run man or perldoc
9033             # "manually" with the full manpage name.
9034
9035             # There is a list of $^O values in installperl to determine whether
9036             # the directory is 'pods' or 'pod'. However, we can avoid tight
9037             # coupling to that by simply checking the "non-standard" 'pods'
9038             # first.
9039             my $pods = "$Config::Config{privlibexp}/pods";
9040             $pods = "$Config::Config{privlibexp}/pod"
9041                 unless -d $pods;
9042             if (-f "$pods/perl$page.pod") {
9043                 CORE::system( $doccmd,
9044                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
9045                     "perl$page" );
9046             }
9047         }
9048     } ## end if (CORE::system($doccmd...
9049 } ## end sub runman
9050
9051 #use Carp;                          # This did break, left for debugging
9052
9053 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
9054
9055 Because of the way the debugger interface to the Perl core is designed, any
9056 debugger package globals that C<DB::sub()> requires have to be defined before
9057 any subroutines can be called. These are defined in the second C<BEGIN> block.
9058
9059 This block sets things up so that (basically) the world is sane
9060 before the debugger starts executing. We set up various variables that the
9061 debugger has to have set up before the Perl core starts running:
9062
9063 =over 4
9064
9065 =item *
9066
9067 The debugger's own filehandles (copies of STD and STDOUT for now).
9068
9069 =item *
9070
9071 Characters for shell escapes, the recall command, and the history command.
9072
9073 =item *
9074
9075 The maximum recursion depth.
9076
9077 =item *
9078
9079 The size of a C<w> command's window.
9080
9081 =item *
9082
9083 The before-this-line context to be printed in a C<v> (view a window around this line) command.
9084
9085 =item *
9086
9087 The fact that we're not in a sub at all right now.
9088
9089 =item *
9090
9091 The default SIGINT handler for the debugger.
9092
9093 =item *
9094
9095 The appropriate value of the flag in C<$^D> that says the debugger is running
9096
9097 =item *
9098
9099 The current debugger recursion level
9100
9101 =item *
9102
9103 The list of postponed items and the C<$single> stack (XXX define this)
9104
9105 =item *
9106
9107 That we want no return values and no subroutine entry/exit trace.
9108
9109 =back
9110
9111 =cut
9112
9113 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
9114
9115 use vars qw($db_stop);
9116
9117 BEGIN {    # This does not compile, alas. (XXX eh?)
9118     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
9119     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
9120
9121     # Define characters used by command parsing.
9122     $sh       = '!';      # Shell escape (does not work)
9123     $rc       = ',';      # Recall command (does not work)
9124     @hist     = ('?');    # Show history (does not work)
9125     @truehist = ();       # Can be saved for replay (per session)
9126
9127     # This defines the point at which you get the 'deep recursion'
9128     # warning. It MUST be defined or the debugger will not load.
9129     $deep = 1000;
9130
9131     # Number of lines around the current one that are shown in the
9132     # 'w' command.
9133     $window = 10;
9134
9135     # How much before-the-current-line context the 'v' command should
9136     # use in calculating the start of the window it will display.
9137     $preview = 3;
9138
9139     # We're not in any sub yet, but we need this to be a defined value.
9140     $sub = '';
9141
9142     # Set up the debugger's interrupt handler. It simply sets a flag
9143     # ($signal) that DB::DB() will check before each command is executed.
9144     $SIG{INT} = \&DB::catch;
9145
9146     # The following lines supposedly, if uncommented, allow the debugger to
9147     # debug itself. Perhaps we can try that someday.
9148     # This may be enabled to debug debugger:
9149     #$warnLevel = 1 unless defined $warnLevel;
9150     #$dieLevel = 1 unless defined $dieLevel;
9151     #$signalLevel = 1 unless defined $signalLevel;
9152
9153     # This is the flag that says "a debugger is running, please call
9154     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9155     # execute anything in the user's context, because we always want to
9156     # get control back.
9157     $db_stop = 0;          # Compiler warning ...
9158     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9159
9160     # This variable records how many levels we're nested in debugging. Used
9161     # Used in the debugger prompt, and in determining whether it's all over or
9162     # not.
9163     $level = 0;            # Level of recursive debugging
9164
9165     # "Triggers bug (?) in perl if we postpone this until runtime."
9166     # XXX No details on this yet, or whether we should fix the bug instead
9167     # of work around it. Stay tuned.
9168     @stack = (0);
9169
9170     # Used to track the current stack depth using the auto-stacked-variable
9171     # trick.
9172     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9173
9174     # Don't print return values on exiting a subroutine.
9175     $doret = -2;
9176
9177     # No extry/exit tracing.
9178     $frame = 0;
9179
9180 } ## end BEGIN
9181
9182 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9183
9184 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9185
9186 =head2 db_complete
9187
9188 C<readline> support - adds command completion to basic C<readline>.
9189
9190 Returns a list of possible completions to C<readline> when invoked. C<readline>
9191 will print the longest common substring following the text already entered.
9192
9193 If there is only a single possible completion, C<readline> will use it in full.
9194
9195 This code uses C<map> and C<grep> heavily to create lists of possible
9196 completion. Think LISP in this section.
9197
9198 =cut
9199
9200 sub db_complete {
9201
9202     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9203     # $text is the text to be completed.
9204     # $line is the incoming line typed by the user.
9205     # $start is the start of the text to be completed in the incoming line.
9206     my ( $text, $line, $start ) = @_;
9207
9208     # Save the initial text.
9209     # The search pattern is current package, ::, extract the next qualifier
9210     # Prefix and pack are set to undef.
9211     my ( $itext, $search, $prefix, $pack ) =
9212       ( $text, "^\Q${package}::\E([^:]+)\$" );
9213
9214 =head3 C<b postpone|compile>
9215
9216 =over 4
9217
9218 =item *
9219
9220 Find all the subroutines that might match in this package
9221
9222 =item *
9223
9224 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9225
9226 =item *
9227
9228 Include all the rest of the subs that are known
9229
9230 =item *
9231
9232 C<grep> out the ones that match the text we have so far
9233
9234 =item *
9235
9236 Return this as the list of possible completions
9237
9238 =back
9239
9240 =cut
9241
9242     return sort grep /^\Q$text/, ( keys %sub ),
9243       qw(postpone load compile),    # subroutines
9244       ( map { /$search/ ? ($1) : () } keys %sub )
9245       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9246
9247 =head3 C<b load>
9248
9249 Get all the possible files from C<@INC> as it currently stands and
9250 select the ones that match the text so far.
9251
9252 =cut
9253
9254     return sort grep /^\Q$text/, values %INC    # files
9255       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9256
9257 =head3  C<V> (list variable) and C<m> (list modules)
9258
9259 There are two entry points for these commands:
9260
9261 =head4 Unqualified package names
9262
9263 Get the top-level packages and grab everything that matches the text
9264 so far. For each match, recursively complete the partial packages to
9265 get all possible matching packages. Return this sorted list.
9266
9267 =cut
9268
9269     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9270       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9271       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9272
9273 =head4 Qualified package names
9274
9275 Take a partially-qualified package and find all subpackages for it
9276 by getting all the subpackages for the package so far, matching all
9277 the subpackages against the text, and discarding all of them which
9278 start with 'main::'. Return this list.
9279
9280 =cut
9281
9282     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9283       grep !/^main::/, grep /^\Q$text/,
9284       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9285       do { no strict 'refs'; keys %{ $prefix . '::' } }
9286       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9287       and $text =~ /^(.*[^:])::?(\w*)$/
9288       and $prefix = $1;
9289
9290 =head3 C<f> - switch files
9291
9292 Here, we want to get a fully-qualified filename for the C<f> command.
9293 Possibilities are:
9294
9295 =over 4
9296
9297 =item 1. The original source file itself
9298
9299 =item 2. A file from C<@INC>
9300
9301 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9302
9303 =back
9304
9305 =cut
9306
9307     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9308            # We might possibly want to switch to an eval (which has a "filename"
9309            # like '(eval 9)'), so we may need to clean up the completion text
9310            # before proceeding.
9311         $prefix = length($1) - length($text);
9312         $text   = $1;
9313
9314 =pod
9315
9316 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9317 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9318 out of C<%main::>, add the initial source file, and extract the ones that
9319 match the completion text so far.
9320
9321 =cut
9322
9323         return sort
9324           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9325           $0;
9326     } ## end if ($line =~ /^\|*f\s+(.*)/)
9327
9328 =head3 Subroutine name completion
9329
9330 We look through all of the defined subs (the keys of C<%sub>) and
9331 return both all the possible matches to the subroutine name plus
9332 all the matches qualified to the current package.
9333
9334 =cut
9335
9336     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9337         $text = substr $text, 1;
9338         $prefix = "&";
9339         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9340           (
9341             map { /$search/ ? ($1) : () }
9342               keys %sub
9343           );
9344     } ## end if ((substr $text, 0, ...
9345
9346 =head3  Scalar, array, and hash completion: partially qualified package
9347
9348 Much like the above, except we have to do a little more cleanup:
9349
9350 =cut
9351
9352     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9353
9354 =pod
9355
9356 =over 4
9357
9358 =item *
9359
9360 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9361
9362 =cut
9363
9364         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9365
9366 =pod
9367
9368 =item *
9369
9370 Figure out the prefix vs. what needs completing.
9371
9372 =cut
9373
9374         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9375         $text   = $2;
9376
9377 =pod
9378
9379 =item *
9380
9381 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9382
9383 =cut
9384
9385         my @out = do {
9386             no strict 'refs';
9387             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9388             keys %$pack;
9389         };
9390
9391 =pod
9392
9393 =item *
9394
9395 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9396
9397 =cut
9398
9399         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9400             return db_complete( $out[0], $line, $start );
9401         }
9402
9403         # Return the list of possibles.
9404         return sort @out;
9405
9406     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9407
9408 =pod
9409
9410 =back
9411
9412 =head3 Symbol completion: current package or package C<main>.
9413
9414 =cut
9415
9416     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9417 =pod
9418
9419 =over 4
9420
9421 =item *
9422
9423 If it's C<main>, delete main to just get C<::> leading.
9424
9425 =cut
9426
9427         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9428
9429 =pod
9430
9431 =item *
9432
9433 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9434
9435 =cut
9436
9437         $prefix = substr $text, 0, 1;
9438         $text   = substr $text, 1;
9439
9440         my @out;
9441
9442 =pod
9443
9444 =item *
9445
9446 We look for the lexical scope above DB::DB and auto-complete lexical variables
9447 if PadWalker could be loaded.
9448
9449 =cut
9450
9451         if (not $text =~ /::/ and eval {
9452             local @INC = @INC;
9453             pop @INC if $INC[-1] eq '.';
9454             require PadWalker } ) {
9455             my $level = 1;
9456             while (1) {
9457                 my @info = caller($level);
9458                 $level++;
9459                 $level = -1, last
9460                   if not @info;
9461                 last if $info[3] eq 'DB::DB';
9462             }
9463             if ($level > 0) {
9464                 my $lexicals = PadWalker::peek_my($level);
9465                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9466             }
9467         }
9468
9469 =pod
9470
9471 =item *
9472
9473 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9474
9475 =cut
9476
9477         push @out, map "$prefix$_", grep /^\Q$text/,
9478           ( grep /^_?[a-zA-Z]/, do { no strict 'refs'; keys %$pack } ),
9479           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9480
9481 =item *
9482
9483 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9484
9485 =back
9486
9487 =cut
9488
9489         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9490             return db_complete( $out[0], $line, $start );
9491         }
9492
9493         # Return the list of possibles.
9494         return sort @out;
9495     } ## end if ($text =~ /^[\$@%]/)
9496
9497 =head3 Options
9498
9499 We use C<option_val()> to look up the current value of the option. If there's
9500 only a single value, we complete the command in such a way that it is a
9501 complete command for setting the option in question. If there are multiple
9502 possible values, we generate a command consisting of the option plus a trailing
9503 question mark, which, if executed, will list the current value of the option.
9504
9505 =cut
9506
9507     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9508     {    # Options after space
9509            # We look for the text to be matched in the list of possible options,
9510            # and fetch the current value.
9511         my @out = grep /^\Q$text/, @options;
9512         my $val = option_val( $out[0], undef );
9513
9514         # Set up a 'query option's value' command.
9515         my $out = '? ';
9516         if ( not defined $val or $val =~ /[\n\r]/ ) {
9517
9518             # There's really nothing else we can do.
9519         }
9520
9521         # We have a value. Create a proper option-setting command.
9522         elsif ( $val =~ /\s/ ) {
9523
9524             # XXX This may be an extraneous variable.
9525             my $found;
9526
9527             # We'll want to quote the string (because of the embedded
9528             # whtespace), but we want to make sure we don't end up with
9529             # mismatched quote characters. We try several possibilities.
9530             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9531
9532                 # If we didn't find this quote character in the value,
9533                 # quote it using this quote character.
9534                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9535             }
9536         } ## end elsif ($val =~ /\s/)
9537
9538         # Don't need any quotes.
9539         else {
9540             $out = "=$val ";
9541         }
9542
9543         # If there were multiple possible values, return '? ', which
9544         # makes the command into a query command. If there was just one,
9545         # have readline append that.
9546         $rl_attribs->{completer_terminator_character} =
9547           ( @out == 1 ? $out : '? ' );
9548
9549         # Return list of possibilities.
9550         return sort @out;
9551     } ## end if ((substr $line, 0, ...
9552
9553 =head3 Filename completion
9554
9555 For entering filenames. We simply call C<readline>'s C<filename_list()>
9556 method with the completion text to get the possible completions.
9557
9558 =cut
9559
9560     return $term->filename_list($text);    # filenames
9561
9562 } ## end sub db_complete
9563
9564 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9565
9566 Functions that possibly ought to be somewhere else.
9567
9568 =head2 end_report
9569
9570 Say we're done.
9571
9572 =cut
9573
9574 sub end_report {
9575     local $\ = '';
9576     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9577 }
9578
9579 =head2 clean_ENV
9580
9581 If we have $ini_pids, save it in the environment; else remove it from the
9582 environment. Used by the C<R> (restart) command.
9583
9584 =cut
9585
9586 sub clean_ENV {
9587     if ( defined($ini_pids) ) {
9588         $ENV{PERLDB_PIDS} = $ini_pids;
9589     }
9590     else {
9591         delete( $ENV{PERLDB_PIDS} );
9592     }
9593 } ## end sub clean_ENV
9594
9595 # PERLDBf_... flag names from perl.h
9596 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9597
9598 BEGIN {
9599     %DollarCaretP_flags = (
9600         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9601         PERLDBf_LINE      => 0x02,     # Keep line #
9602         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9603         PERLDBf_INTER     => 0x08,     # Preserve more data
9604         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9605         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9606         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9607         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9608         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9609         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9610         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9611         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9612     );
9613     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9614     # doesn't need to set it. It's provided for the benefit of profilers and
9615     # other code analysers.
9616
9617     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9618 }
9619
9620 sub parse_DollarCaretP_flags {
9621     my $flags = shift;
9622     $flags =~ s/^\s+//;
9623     $flags =~ s/\s+$//;
9624     my $acu = 0;
9625     foreach my $f ( split /\s*\|\s*/, $flags ) {
9626         my $value;
9627         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9628             $value = hex $1;
9629         }
9630         elsif ( $f =~ /^(\d+)$/ ) {
9631             $value = int $1;
9632         }
9633         elsif ( $f =~ /^DEFAULT$/i ) {
9634             $value = $DollarCaretP_flags{PERLDB_ALL};
9635         }
9636         else {
9637             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9638             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9639             unless ( defined $value ) {
9640                 print $OUT (
9641                     "Unrecognized \$^P flag '$f'!\n",
9642                     "Acceptable flags are: "
9643                       . join( ', ', sort keys %DollarCaretP_flags ),
9644                     ", and hexadecimal and decimal numbers.\n"
9645                 );
9646                 return undef;
9647             }
9648         }
9649         $acu |= $value;
9650     }
9651     $acu;
9652 }
9653
9654 sub expand_DollarCaretP_flags {
9655     my $DollarCaretP = shift;
9656     my @bits         = (
9657         map {
9658             my $n = ( 1 << $_ );
9659             ( $DollarCaretP & $n )
9660               ? ( $DollarCaretP_flags_r{$n}
9661                   || sprintf( '0x%x', $n ) )
9662               : ()
9663           } 0 .. 31
9664     );
9665     return @bits ? join( '|', @bits ) : 0;
9666 }
9667
9668 =over 4
9669
9670 =item rerun
9671
9672 Rerun the current session to:
9673
9674     rerun        current position
9675
9676     rerun 4      command number 4
9677
9678     rerun -4     current command minus 4 (go back 4 steps)
9679
9680 Whether this always makes sense, in the current context is unknowable, and is
9681 in part left as a useful exercise for the reader.  This sub returns the
9682 appropriate arguments to rerun the current session.
9683
9684 =cut
9685
9686 sub rerun {
9687     my $i = shift;
9688     my @args;
9689     pop(@truehist);                      # strim
9690     unless (defined $truehist[$i]) {
9691         print "Unable to return to non-existent command: $i\n";
9692     } else {
9693         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9694         my @temp = @truehist;            # store
9695         push(@DB::typeahead, @truehist); # saved
9696         @truehist = @hist = ();          # flush
9697         @args = restart();              # setup
9698         get_list("PERLDB_HIST");        # clean
9699         set_list("PERLDB_HIST", @temp); # reset
9700     }
9701     return @args;
9702 }
9703
9704 =item restart
9705
9706 Restarting the debugger is a complex operation that occurs in several phases.
9707 First, we try to reconstruct the command line that was used to invoke Perl
9708 and the debugger.
9709
9710 =cut
9711
9712 sub restart {
9713     # I may not be able to resurrect you, but here goes ...
9714     print $OUT
9715 "Warning: some settings and command-line options may be lost!\n";
9716     my ( @script, @flags, $cl );
9717
9718     # If warn was on before, turn it on again.
9719     push @flags, '-w' if $ini_warn;
9720
9721     # Rebuild the -I flags that were on the initial
9722     # command line.
9723     for (@ini_INC) {
9724         push @flags, '-I', $_;
9725     }
9726
9727     # Turn on taint if it was on before.
9728     push @flags, '-T' if ${^TAINT};
9729
9730     # Arrange for setting the old INC:
9731     # Save the current @init_INC in the environment.
9732     set_list( "PERLDB_INC", @ini_INC );
9733
9734     # If this was a perl one-liner, go to the "file"
9735     # corresponding to the one-liner read all the lines
9736     # out of it (except for the first one, which is going
9737     # to be added back on again when 'perl -d' runs: that's
9738     # the 'require perl5db.pl;' line), and add them back on
9739     # to the command line to be executed.
9740     if ( $0 eq '-e' ) {
9741         my $lines = *{$main::{'_<-e'}}{ARRAY};
9742         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9743             chomp( $cl = $lines->[$_] );
9744             push @script, '-e', $cl;
9745         }
9746     } ## end if ($0 eq '-e')
9747
9748     # Otherwise we just reuse the original name we had
9749     # before.
9750     else {
9751         @script = $0;
9752     }
9753
9754 =pod
9755
9756 After the command line  has been reconstructed, the next step is to save
9757 the debugger's status in environment variables. The C<DB::set_list> routine
9758 is used to save aggregate variables (both hashes and arrays); scalars are
9759 just popped into environment variables directly.
9760
9761 =cut
9762
9763     # If the terminal supported history, grab it and
9764     # save that in the environment.
9765     set_list( "PERLDB_HIST",
9766           $term->Features->{getHistory}
9767         ? $term->GetHistory
9768         : @hist );
9769
9770     # Find all the files that were visited during this
9771     # session (i.e., the debugger had magic hashes
9772     # corresponding to them) and stick them in the environment.
9773     my @had_breakpoints = keys %had_breakpoints;
9774     set_list( "PERLDB_VISITED", @had_breakpoints );
9775
9776     # Save the debugger options we chose.
9777     set_list( "PERLDB_OPT", %option );
9778     # set_list( "PERLDB_OPT", options2remember() );
9779
9780     # Save the break-on-loads.
9781     set_list( "PERLDB_ON_LOAD", %break_on_load );
9782
9783 =pod
9784
9785 The most complex part of this is the saving of all of the breakpoints. They
9786 can live in an awful lot of places, and we have to go through all of them,
9787 find the breakpoints, and then save them in the appropriate environment
9788 variable via C<DB::set_list>.
9789
9790 =cut
9791
9792     # Go through all the breakpoints and make sure they're
9793     # still valid.
9794     my @hard;
9795     for ( 0 .. $#had_breakpoints ) {
9796
9797         # We were in this file.
9798         my $file = $had_breakpoints[$_];
9799
9800         # Grab that file's magic line hash.
9801         *dbline = $main::{ '_<' . $file };
9802
9803         # Skip out if it doesn't exist, or if the breakpoint
9804         # is in a postponed file (we'll do postponed ones
9805         # later).
9806         next unless %dbline or $postponed_file{$file};
9807
9808         # In an eval. This is a little harder, so we'll
9809         # do more processing on that below.
9810         ( push @hard, $file ), next
9811           if $file =~ /^\(\w*eval/;
9812
9813         # XXX I have no idea what this is doing. Yet.
9814         my @add;
9815         @add = %{ $postponed_file{$file} }
9816           if $postponed_file{$file};
9817
9818         # Save the list of all the breakpoints for this file.
9819         set_list( "PERLDB_FILE_$_", %dbline, @add );
9820
9821         # Serialize the extra data %breakpoints_data hash.
9822         # That's a bug fix.
9823         set_list( "PERLDB_FILE_ENABLED_$_",
9824             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9825             sort { $a <=> $b } keys(%dbline)
9826         )
9827     } ## end for (0 .. $#had_breakpoints)
9828
9829     # The breakpoint was inside an eval. This is a little
9830     # more difficult. XXX and I don't understand it.
9831     foreach my $hard_file (@hard) {
9832         # Get over to the eval in question.
9833         *dbline = $main::{ '_<' . $hard_file };
9834         my $quoted = quotemeta $hard_file;
9835         my %subs;
9836         for my $sub ( keys %sub ) {
9837             if (my ($n1, $n2) = $sub{$sub} =~ /\A$quoted:(\d+)-(\d+)\z/) {
9838                 $subs{$sub} = [ $n1, $n2 ];
9839             }
9840         }
9841         unless (%subs) {
9842             print {$OUT}
9843             "No subroutines in $hard_file, ignoring breakpoints.\n";
9844             next;
9845         }
9846         LINES: foreach my $line ( keys %dbline ) {
9847
9848             # One breakpoint per sub only:
9849             my ( $offset, $found );
9850             SUBS: foreach my $sub ( keys %subs ) {
9851                 if (
9852                     $subs{$sub}->[1] >= $line    # Not after the subroutine
9853                     and (
9854                         not defined $offset    # Not caught
9855                             or $offset < 0
9856                     )
9857                 )
9858                 {                              # or badly caught
9859                     $found  = $sub;
9860                     $offset = $line - $subs{$sub}->[0];
9861                     if ($offset >= 0) {
9862                         $offset = "+$offset";
9863                         last SUBS;
9864                     }
9865                 } ## end if ($subs{$sub}->[1] >=...
9866             } ## end for $sub (keys %subs)
9867             if ( defined $offset ) {
9868                 $postponed{$found} =
9869                 "break $offset if $dbline{$line}";
9870             }
9871             else {
9872                 print {$OUT}
9873                 ("Breakpoint in ${hard_file}:$line ignored:"
9874                 . " after all the subroutines.\n");
9875             }
9876         } ## end for $line (keys %dbline)
9877     } ## end for (@hard)
9878
9879     # Save the other things that don't need to be
9880     # processed.
9881     set_list( "PERLDB_POSTPONE",  %postponed );
9882     set_list( "PERLDB_PRETYPE",   @$pretype );
9883     set_list( "PERLDB_PRE",       @$pre );
9884     set_list( "PERLDB_POST",      @$post );
9885     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9886
9887     # We are officially restarting.
9888     $ENV{PERLDB_RESTART} = 1;
9889
9890     # We are junking all child debuggers.
9891     delete $ENV{PERLDB_PIDS};    # Restore ini state
9892
9893     # Set this back to the initial pid.
9894     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9895
9896 =pod
9897
9898 After all the debugger status has been saved, we take the command we built up
9899 and then return it, so we can C<exec()> it. The debugger will spot the
9900 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9901 from the environment.
9902
9903 =cut
9904
9905     # And run Perl again. Add the "-d" flag, all the
9906     # flags we built up, the script (whether a one-liner
9907     # or a file), add on the -emacs flag for a slave editor,
9908     # and then the old arguments.
9909
9910     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9911
9912 };  # end restart
9913
9914 =back
9915
9916 =head1 END PROCESSING - THE C<END> BLOCK
9917
9918 Come here at the very end of processing. We want to go into a
9919 loop where we allow the user to enter commands and interact with the
9920 debugger, but we don't want anything else to execute.
9921
9922 First we set the C<$finished> variable, so that some commands that
9923 shouldn't be run after the end of program quit working.
9924
9925 We then figure out whether we're truly done (as in the user entered a C<q>
9926 command, or we finished execution while running nonstop). If we aren't,
9927 we set C<$single> to 1 (causing the debugger to get control again).
9928
9929 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9930 message and returns control to the debugger. Repeat.
9931
9932 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9933 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9934 break, run to completion.).
9935
9936 =cut
9937
9938 END {
9939     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9940     $fall_off_end = 1 unless $inhibit_exit;
9941
9942     # Do not stop in at_exit() and destructors on exit:
9943     if ($fall_off_end or $runnonstop) {
9944         save_hist();
9945     } else {
9946         $DB::single = 1;
9947         DB::fake::at_exit();
9948     }
9949 } ## end END
9950
9951 =head1 PRE-5.8 COMMANDS
9952
9953 Some of the commands changed function quite a bit in the 5.8 command
9954 realignment, so much so that the old code had to be replaced completely.
9955 Because we wanted to retain the option of being able to go back to the
9956 former command set, we moved the old code off to this section.
9957
9958 There's an awful lot of duplicated code here. We've duplicated the
9959 comments to keep things clear.
9960
9961 =head2 Null command
9962
9963 Does nothing. Used to I<turn off> commands.
9964
9965 =cut
9966
9967 sub cmd_pre580_null {
9968
9969     # do nothing...
9970 }
9971
9972 =head2 Old C<a> command.
9973
9974 This version added actions if you supplied them, and deleted them
9975 if you didn't.
9976
9977 =cut
9978
9979 sub cmd_pre580_a {
9980     my $xcmd = shift;
9981     my $cmd  = shift;
9982
9983     # Argument supplied. Add the action.
9984     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9985
9986         # If the line isn't there, use the current line.
9987         my $i = $1 || $line;
9988         my $j = $2;
9989
9990         # If there is an action ...
9991         if ( length $j ) {
9992
9993             # ... but the line isn't breakable, skip it.
9994             if ( $dbline[$i] == 0 ) {
9995                 print $OUT "Line $i may not have an action.\n";
9996             }
9997             else {
9998
9999                 # ... and the line is breakable:
10000                 # Mark that there's an action in this file.
10001                 $had_breakpoints{$filename} |= 2;
10002
10003                 # Delete any current action.
10004                 $dbline{$i} =~ s/\0[^\0]*//;
10005
10006                 # Add the new action, continuing the line as needed.
10007                 $dbline{$i} .= "\0" . action($j);
10008             }
10009         } ## end if (length $j)
10010
10011         # No action supplied.
10012         else {
10013
10014             # Delete the action.
10015             $dbline{$i} =~ s/\0[^\0]*//;
10016
10017             # Mark as having no break or action if nothing's left.
10018             delete $dbline{$i} if $dbline{$i} eq '';
10019         }
10020     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
10021 } ## end sub cmd_pre580_a
10022
10023 =head2 Old C<b> command
10024
10025 Add breakpoints.
10026
10027 =cut
10028
10029 sub cmd_pre580_b {
10030     my $xcmd   = shift;
10031     my $cmd    = shift;
10032     my $dbline = shift;
10033
10034     # Break on load.
10035     if ( $cmd =~ /^load\b\s*(.*)/ ) {
10036         my $file = $1;
10037         $file =~ s/\s+$//;
10038         cmd_b_load($file);
10039     }
10040
10041     # b compile|postpone <some sub> [<condition>]
10042     # The interpreter actually traps this one for us; we just put the
10043     # necessary condition in the %postponed hash.
10044     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
10045
10046         # Capture the condition if there is one. Make it true if none.
10047         my $cond = length $3 ? $3 : '1';
10048
10049         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
10050         # if it was 'compile'.
10051         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
10052
10053         # De-Perl4-ify the name - ' separators to ::.
10054         $subname =~ s/\'/::/g;
10055
10056         # Qualify it into the current package unless it's already qualified.
10057         $subname = "${package}::" . $subname
10058           unless $subname =~ /::/;
10059
10060         # Add main if it starts with ::.
10061         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
10062
10063         # Save the break type for this sub.
10064         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
10065     } ## end elsif ($cmd =~ ...
10066
10067     # b <sub name> [<condition>]
10068     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
10069         my $subname = $1;
10070         my $cond = length $2 ? $2 : '1';
10071         cmd_b_sub( $subname, $cond );
10072     }
10073     # b <line> [<condition>].
10074     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
10075         my $i = $1 || $dbline;
10076         my $cond = length $2 ? $2 : '1';
10077         cmd_b_line( $i, $cond );
10078     }
10079 } ## end sub cmd_pre580_b
10080
10081 =head2 Old C<D> command.
10082
10083 Delete all breakpoints unconditionally.
10084
10085 =cut
10086
10087 sub cmd_pre580_D {
10088     my $xcmd = shift;
10089     my $cmd  = shift;
10090     if ( $cmd =~ /^\s*$/ ) {
10091         print $OUT "Deleting all breakpoints...\n";
10092
10093         # %had_breakpoints lists every file that had at least one
10094         # breakpoint in it.
10095         my $file;
10096         for $file ( keys %had_breakpoints ) {
10097
10098             # Switch to the desired file temporarily.
10099             local *dbline = $main::{ '_<' . $file };
10100
10101             $max = $#dbline;
10102             my $was;
10103
10104             # For all lines in this file ...
10105             for my $i (1 .. $max) {
10106
10107                 # If there's a breakpoint or action on this line ...
10108                 if ( defined $dbline{$i} ) {
10109
10110                     # ... remove the breakpoint.
10111                     $dbline{$i} =~ s/^[^\0]+//;
10112                     if ( $dbline{$i} =~ s/^\0?$// ) {
10113
10114                         # Remove the entry altogether if no action is there.
10115                         delete $dbline{$i};
10116                     }
10117                 } ## end if (defined $dbline{$i...
10118             } ## end for my $i (1 .. $max)
10119
10120             # If, after we turn off the "there were breakpoints in this file"
10121             # bit, the entry in %had_breakpoints for this file is zero,
10122             # we should remove this file from the hash.
10123             if ( not $had_breakpoints{$file} &= ~1 ) {
10124                 delete $had_breakpoints{$file};
10125             }
10126         } ## end for $file (keys %had_breakpoints)
10127
10128         # Kill off all the other breakpoints that are waiting for files that
10129         # haven't been loaded yet.
10130         undef %postponed;
10131         undef %postponed_file;
10132         undef %break_on_load;
10133     } ## end if ($cmd =~ /^\s*$/)
10134 } ## end sub cmd_pre580_D
10135
10136 =head2 Old C<h> command
10137
10138 Print help. Defaults to printing the long-form help; the 5.8 version
10139 prints the summary by default.
10140
10141 =cut
10142
10143 sub cmd_pre580_h {
10144     my $xcmd = shift;
10145     my $cmd  = shift;
10146
10147     # Print the *right* help, long format.
10148     if ( $cmd =~ /^\s*$/ ) {
10149         print_help($pre580_help);
10150     }
10151
10152     # 'h h' - explicitly-requested summary.
10153     elsif ( $cmd =~ /^h\s*/ ) {
10154         print_help($pre580_summary);
10155     }
10156
10157     # Find and print a command's help.
10158     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10159         my $asked  = $1;                   # for proper errmsg
10160         my $qasked = quotemeta($asked);    # for searching
10161                                            # XXX: finds CR but not <CR>
10162         if (
10163             $pre580_help =~ /^
10164                               <?           # Optional '<'
10165                               (?:[IB]<)    # Optional markup
10166                               $qasked      # The command name
10167                             /mx
10168           )
10169         {
10170
10171             while (
10172                 $pre580_help =~ /^
10173                                   (             # The command help:
10174                                    <?           # Optional '<'
10175                                    (?:[IB]<)    # Optional markup
10176                                    $qasked      # The command name
10177                                    ([\s\S]*?)   # Lines starting with tabs
10178                                    \n           # Final newline
10179                                   )
10180                                   (?!\s)/mgx
10181               )    # Line not starting with space
10182                    # (Next command's help)
10183             {
10184                 print_help($1);
10185             }
10186         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10187
10188         # Help not found.
10189         else {
10190             print_help("B<$asked> is not a debugger command.\n");
10191         }
10192     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10193 } ## end sub cmd_pre580_h
10194
10195 =head2 Old C<W> command
10196
10197 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10198
10199 =cut
10200
10201 sub cmd_pre580_W {
10202     my $xcmd = shift;
10203     my $cmd  = shift;
10204
10205     # Delete all watch expressions.
10206     if ( $cmd =~ /^$/ ) {
10207
10208         # No watching is going on.
10209         $trace &= ~2;
10210
10211         # Kill all the watch expressions and values.
10212         @to_watch = @old_watch = ();
10213     }
10214
10215     # Add a watch expression.
10216     elsif ( $cmd =~ /^(.*)/s ) {
10217
10218         # add it to the list to be watched.
10219         push @to_watch, $1;
10220
10221         # Get the current value of the expression.
10222         # Doesn't handle expressions returning list values!
10223         $evalarg = $1;
10224         # The &-call is here to ascertain the mutability of @_.
10225         my ($val) = &DB::eval;
10226         $val = ( defined $val ) ? "'$val'" : 'undef';
10227
10228         # Save it.
10229         push @old_watch, $val;
10230
10231         # We're watching stuff.
10232         $trace |= 2;
10233
10234     } ## end elsif ($cmd =~ /^(.*)/s)
10235 } ## end sub cmd_pre580_W
10236
10237 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10238
10239 The debugger used to have a bunch of nearly-identical code to handle
10240 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10241 C<cmd_prepost> unify all this into one set of code to handle the
10242 appropriate actions.
10243
10244 =head2 C<cmd_pre590_prepost>
10245
10246 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10247 do something destructive. In pre 5.8 debuggers, the default action was to
10248 delete all the actions.
10249
10250 =cut
10251
10252 sub cmd_pre590_prepost {
10253     my $cmd    = shift;
10254     my $line   = shift || '*';
10255     my $dbline = shift;
10256
10257     return cmd_prepost( $cmd, $line, $dbline );
10258 } ## end sub cmd_pre590_prepost
10259
10260 =head2 C<cmd_prepost>
10261
10262 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10263 Since the lists of actions are all held in arrays that are pointed to by
10264 references anyway, all we have to do is pick the right array reference and
10265 then use generic code to all, delete, or list actions.
10266
10267 =cut
10268
10269 sub cmd_prepost {
10270     my $cmd = shift;
10271
10272     # No action supplied defaults to 'list'.
10273     my $line = shift || '?';
10274
10275     # Figure out what to put in the prompt.
10276     my $which = '';
10277
10278     # Make sure we have some array or another to address later.
10279     # This means that if for some reason the tests fail, we won't be
10280     # trying to stash actions or delete them from the wrong place.
10281     my $aref = [];
10282
10283     # < - Perl code to run before prompt.
10284     if ( $cmd =~ /^\</o ) {
10285         $which = 'pre-perl';
10286         $aref  = $pre;
10287     }
10288
10289     # > - Perl code to run after prompt.
10290     elsif ( $cmd =~ /^\>/o ) {
10291         $which = 'post-perl';
10292         $aref  = $post;
10293     }
10294
10295     # { - first check for properly-balanced braces.
10296     elsif ( $cmd =~ /^\{/o ) {
10297         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10298             print $OUT
10299 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10300         }
10301
10302         # Properly balanced. Pre-prompt debugger actions.
10303         else {
10304             $which = 'pre-debugger';
10305             $aref  = $pretype;
10306         }
10307     } ## end elsif ( $cmd =~ /^\{/o )
10308
10309     # Did we find something that makes sense?
10310     unless ($which) {
10311         print $OUT "Confused by command: $cmd\n";
10312     }
10313
10314     # Yes.
10315     else {
10316
10317         # List actions.
10318         if ( $line =~ /^\s*\?\s*$/o ) {
10319             unless (@$aref) {
10320
10321                 # Nothing there. Complain.
10322                 print $OUT "No $which actions.\n";
10323             }
10324             else {
10325
10326                 # List the actions in the selected list.
10327                 print $OUT "$which commands:\n";
10328                 foreach my $action (@$aref) {
10329                     print $OUT "\t$cmd -- $action\n";
10330                 }
10331             } ## end else
10332         } ## end if ( $line =~ /^\s*\?\s*$/o)
10333
10334         # Might be a delete.
10335         else {
10336             if ( length($cmd) == 1 ) {
10337                 if ( $line =~ /^\s*\*\s*$/o ) {
10338
10339                     # It's a delete. Get rid of the old actions in the
10340                     # selected list..
10341                     @$aref = ();
10342                     print $OUT "All $cmd actions cleared.\n";
10343                 }
10344                 else {
10345
10346                     # Replace all the actions. (This is a <, >, or {).
10347                     @$aref = action($line);
10348                 }
10349             } ## end if ( length($cmd) == 1)
10350             elsif ( length($cmd) == 2 ) {
10351
10352                 # Add the action to the line. (This is a <<, >>, or {{).
10353                 push @$aref, action($line);
10354             }
10355             else {
10356
10357                 # <<<, >>>>, {{{{{{ ... something not a command.
10358                 print $OUT
10359                   "Confused by strange length of $which command($cmd)...\n";
10360             }
10361         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10362     } ## end else
10363 } ## end sub cmd_prepost
10364
10365 =head1 C<DB::fake>
10366
10367 Contains the C<at_exit> routine that the debugger uses to issue the
10368 C<Debugged program terminated ...> message after the program completes. See
10369 the C<END> block documentation for more details.
10370
10371 =cut
10372
10373 package DB::fake;
10374
10375 sub at_exit {
10376     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10377 }
10378
10379 package DB;    # Do not trace this 1; below!
10380
10381 1;
10382
10383