utils/h2xs.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 my $origdir = cwd;
  17 chdir dirname($0);
  18 my $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 use warnings;
  39
  40 =head1 NAME
  41
  42 h2xs - convert .h C header files to Perl extensions
  43
  44 =head1 SYNOPSIS
  45
  46 B<h2xs> [B<OPTIONS> ...] [headerfile ... [extra_libraries]]
  47
  48 B<h2xs> B<-h>|B<-?>|B<--help>
  49
  50 =head1 DESCRIPTION
  51
  52 I<h2xs> builds a Perl extension from C header files.  The extension
  53 will include functions which can be used to retrieve the value of any
  54 #define statement which was in the C header files.
  55
  56 The I<module_name> will be used for the name of the extension.  If
  57 module_name is not supplied then the name of the first header file
  58 will be used, with the first character capitalized.
  59
  60 If the extension might need extra libraries, they should be included
  61 here.  The extension Makefile.PL will take care of checking whether
  62 the libraries actually exist and how they should be loaded.  The extra
  63 libraries should be specified in the form -lm -lposix, etc, just as on
  64 the cc command line.  By default, the Makefile.PL will search through
  65 the library path determined by Configure.  That path can be augmented
  66 by including arguments of the form B<-L/another/library/path> in the
  67 extra-libraries argument.
  68
  69 =head1 OPTIONS
  70
  71 =over 5
  72
  73 =item B<-A>, B<--omit-autoload>
  74
  75 Omit all autoload facilities.  This is the same as B<-c> but also
  76 removes the S<C<use AutoLoader>> statement from the .pm file.
  77
  78 =item B<-B>, B<--beta-version>
  79
  80 Use an alpha/beta style version number.  Causes version number to
  81 be "0.00_01" unless B<-v> is specified.
  82
  83 =item B<-C>, B<--omit-changes>
  84
  85 Omits creation of the F<Changes> file, and adds a HISTORY section to
  86 the POD template.
  87
  88 =item B<-F>, B<--cpp-flags>=I<addflags>
  89
  90 Additional flags to specify to C preprocessor when scanning header for
  91 function declarations.  Writes these options in the generated F<Makefile.PL>
  92 too.
  93
  94 =item B<-M>, B<--func-mask>=I<regular expression>
  95
  96 selects functions/macros to process.
  97
  98 =item B<-O>, B<--overwrite-ok>
  99
 100 Allows a pre-existing extension directory to be overwritten.
 101
 102 =item B<-P>, B<--omit-pod>
 103
 104 Omit the autogenerated stub POD section.
 105
 106 =item B<-X>, B<--omit-XS>
 107
 108 Omit the XS portion.  Used to generate templates for a module which is not
 109 XS-based.  C<-c> and C<-f> are implicitly enabled.
 110
 111 =item B<-a>, B<--gen-accessors>
 112
 113 Generate an accessor method for each element of structs and unions. The
 114 generated methods are named after the element name; will return the current
 115 value of the element if called without additional arguments; and will set
 116 the element to the supplied value (and return the new value) if called with
 117 an additional argument. Embedded structures and unions are returned as a
 118 pointer rather than the complete structure, to facilitate chained calls.
 119
 120 These methods all apply to the Ptr type for the structure; additionally
 121 two methods are constructed for the structure type itself, C<_to_ptr>
 122 which returns a Ptr type pointing to the same structure, and a C<new>
 123 method to construct and return a new structure, initialised to zeroes.
 124
 125 =item B<-b>, B<--compat-version>=I<version>
 126
 127 Generates a .pm file which is backwards compatible with the specified
 128 perl version.
 129
 130 For versions < 5.6.0, the changes are.
 131     - no use of 'our' (uses 'use vars' instead)
 132     - no 'use warnings'
 133
 134 Specifying a compatibility version higher than the version of perl you
 135 are using to run h2xs will have no effect.  If unspecified h2xs will default
 136 to compatibility with the version of perl you are using to run h2xs.
 137
 138 =item B<-c>, B<--omit-constant>
 139
 140 Omit C<constant()> from the .xs file and corresponding specialised
 141 C<AUTOLOAD> from the .pm file.
 142
 143 =item B<-d>, B<--debugging>
 144
 145 Turn on debugging messages.
 146
 147 =item B<-f>, B<--force>
 148
 149 Allows an extension to be created for a header even if that header is
 150 not found in standard include directories.
 151
 152 =item B<-g>, B<--global>
 153
 154 Include code for safely storing static data in the .xs file.
 155 Extensions that do no make use of static data can ignore this option.
 156
 157 =item B<-h>, B<-?>, B<--help>
 158
 159 Print the usage, help and version for this h2xs and exit.
 160
 161 =item B<-k>, B<--omit-const-func>
 162
 163 For function arguments declared as C<const>, omit the const attribute in the
 164 generated XS code.
 165
 166 =item B<-m>, B<--gen-tied-var>
 167
 168 B<Experimental>: for each variable declared in the header file(s), declare
 169 a perl variable of the same name magically tied to the C variable.
 170
 171 =item B<-n>, B<--name>=I<module_name>
 172
 173 Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
 174
 175 =item B<-o>, B<--opaque-re>=I<regular expression>
 176
 177 Use "opaque" data type for the C types matched by the regular
 178 expression, even if these types are C<typedef>-equivalent to types
 179 from typemaps.  Should not be used without B<-x>.
 180
 181 This may be useful since, say, types which are C<typedef>-equivalent
 182 to integers may represent OS-related handles, and one may want to work
 183 with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
 184 Use C<-o .> if you want to handle all the C<typedef>ed types as opaque
 185 types.
 186
 187 The type-to-match is whitewashed (except for commas, which have no
 188 whitespace before them, and multiple C<*> which have no whitespace
 189 between them).
 190
 191 =item B<-p>, B<--remove-prefix>=I<prefix>
 192
 193 Specify a prefix which should be removed from the Perl function names,
 194 e.g., S<-p sec_rgy_> This sets up the XS B<PREFIX> keyword and removes
 195 the prefix from functions that are autoloaded via the C<constant()>
 196 mechanism.
 197
 198 =item B<-s>, B<--const-subs>=I<sub1,sub2>
 199
 200 Create a perl subroutine for the specified macros rather than autoload
 201 with the constant() subroutine.  These macros are assumed to have a
 202 return type of B<char *>, e.g.,
 203 S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
 204
 205 =item B<-t>, B<--default-type>=I<type>
 206
 207 Specify the internal type that the constant() mechanism uses for macros.
 208 The default is IV (signed integer).  Currently all macros found during the
 209 header scanning process will be assumed to have this type.  Future versions
 210 of C<h2xs> may gain the ability to make educated guesses.
 211
 212 =item B<--use-new-tests>
 213
 214 When B<--compat-version> (B<-b>) is present the generated tests will use
 215 C<Test::More> rather than C<Test> which is the default for versions before
 216 5.7.2 .   C<Test::More> will be added to PREREQ_PM in the generated
 217 C<Makefile.PL>.
 218
 219 =item B<--use-old-tests>
 220
 221 Will force the generation of test code that uses the older C<Test> module.
 222
 223 =item B<--skip-exporter>
 224
 225 Do not use C<Exporter> and/or export any symbol.
 226
 227 =item B<--skip-ppport>
 228
 229 Do not use C<Devel::PPPort>: no portability to older version.
 230
 231 =item B<--skip-autoloader>
 232
 233 Do not use the module C<AutoLoader>; but keep the constant() function
 234 and C<sub AUTOLOAD> for constants.
 235
 236 =item B<--skip-strict>
 237
 238 Do not use the pragma C<strict>.
 239
 240 =item B<--skip-warnings>
 241
 242 Do not use the pragma C<warnings>.
 243
 244 =item B<-v>, B<--version>=I<version>
 245
 246 Specify a version number for this extension.  This version number is added
 247 to the templates.  The default is 0.01, or 0.00_01 if C<-B> is specified.
 248 The version specified should be numeric.
 249
 250 =item B<-x>, B<--autogen-xsubs>
 251
 252 Automatically generate XSUBs basing on function declarations in the
 253 header file.  The package C<C::Scan> should be installed. If this
 254 option is specified, the name of the header file may look like
 255 C<NAME1,NAME2>. In this case NAME1 is used instead of the specified
 256 string, but XSUBs are emitted only for the declarations included from
 257 file NAME2.
 258
 259 Note that some types of arguments/return-values for functions may
 260 result in XSUB-declarations/typemap-entries which need
 261 hand-editing. Such may be objects which cannot be converted from/to a
 262 pointer (like C<long long>), pointers to functions, or arrays.  See
 263 also the section on L<LIMITATIONS of B<-x>>.
 264
 265 =back
 266
 267 =head1 EXAMPLES
 268
 269
 270         # Default behavior, extension is Rusers
 271         h2xs rpcsvc/rusers
 272
 273         # Same, but extension is RUSERS
 274         h2xs -n RUSERS rpcsvc/rusers
 275
 276         # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
 277         h2xs rpcsvc::rusers
 278
 279         # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
 280         h2xs -n ONC::RPC rpcsvc/rusers
 281
 282         # Without constant() or AUTOLOAD
 283         h2xs -c rpcsvc/rusers
 284
 285         # Creates templates for an extension named RPC
 286         h2xs -cfn RPC
 287
 288         # Extension is ONC::RPC.
 289         h2xs -cfn ONC::RPC
 290
 291         # Makefile.PL will look for library -lrpc in
 292         # additional directory /opt/net/lib
 293         h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
 294
 295         # Extension is DCE::rgynbase
 296         # prefix "sec_rgy_" is dropped from perl function names
 297         h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
 298
 299         # Extension is DCE::rgynbase
 300         # prefix "sec_rgy_" is dropped from perl function names
 301         # subroutines are created for sec_rgy_wildcard_name and sec_rgy_wildcard_sid
 302         h2xs -n DCE::rgynbase -p sec_rgy_ \
 303         -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
 304
 305         # Make XS without defines in perl.h, but with function declarations
 306         # visible from perl.h. Name of the extension is perl1.
 307         # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
 308         # Extra backslashes below because the string is passed to shell.
 309         # Note that a directory with perl header files would
 310         #  be added automatically to include path.
 311         h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
 312
 313         # Same with function declaration in proto.h as visible from perl.h.
 314         h2xs -xAn perl2 perl.h,proto.h
 315
 316         # Same but select only functions which match /^av_/
 317         h2xs -M '^av_' -xAn perl2 perl.h,proto.h
 318
 319         # Same but treat SV* etc as "opaque" types
 320         h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
 321
 322 =head2 Extension based on F<.h> and F<.c> files
 323
 324 Suppose that you have some C files implementing some functionality,
 325 and the corresponding header files.  How to create an extension which
 326 makes this functionality accessable in Perl?  The example below
 327 assumes that the header files are F<interface_simple.h> and
 328 I<interface_hairy.h>, and you want the perl module be named as
 329 C<Ext::Ension>.  If you need some preprocessor directives and/or
 330 linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
 331 in L<"OPTIONS">.
 332
 333 =over
 334
 335 =item Find the directory name
 336
 337 Start with a dummy run of h2xs:
 338
 339   h2xs -Afn Ext::Ension
 340
 341 The only purpose of this step is to create the needed directories, and
 342 let you know the names of these directories.  From the output you can
 343 see that the directory for the extension is F<Ext/Ension>.
 344
 345 =item Copy C files
 346
 347 Copy your header files and C files to this directory F<Ext/Ension>.
 348
 349 =item Create the extension
 350
 351 Run h2xs, overwriting older autogenerated files:
 352
 353   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
 354
 355 h2xs looks for header files I<after> changing to the extension
 356 directory, so it will find your header files OK.
 357
 358 =item Archive and test
 359
 360 As usual, run
 361
 362   cd Ext/Ension
 363   perl Makefile.PL
 364   make dist
 365   make
 366   make test
 367
 368 =item Hints
 369
 370 It is important to do C<make dist> as early as possible.  This way you
 371 can easily merge(1) your changes to autogenerated files if you decide
 372 to edit your C<.h> files and rerun h2xs.
 373
 374 Do not forget to edit the documentation in the generated F<.pm> file.
 375
 376 Consider the autogenerated files as skeletons only, you may invent
 377 better interfaces than what h2xs could guess.
 378
 379 Consider this section as a guideline only, some other options of h2xs
 380 may better suit your needs.
 381
 382 =back
 383
 384 =head1 ENVIRONMENT
 385
 386 No environment variables are used.
 387
 388 =head1 AUTHOR
 389
 390 Larry Wall and others
 391
 392 =head1 SEE ALSO
 393
 394 L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
 395
 396 =head1 DIAGNOSTICS
 397
 398 The usual warnings if it cannot read or write the files involved.
 399
 400 =head1 LIMITATIONS of B<-x>
 401
 402 F<h2xs> would not distinguish whether an argument to a C function
 403 which is of the form, say, C<int *>, is an input, output, or
 404 input/output parameter.  In particular, argument declarations of the
 405 form
 406
 407     int
 408     foo(n)
 409         int *n
 410
 411 should be better rewritten as
 412
 413     int
 414     foo(n)
 415         int &n
 416
 417 if C<n> is an input parameter.
 418
 419 Additionally, F<h2xs> has no facilities to intuit that a function
 420
 421    int
 422    foo(addr,l)
 423         char *addr
 424         int   l
 425
 426 takes a pair of address and length of data at this address, so it is better
 427 to rewrite this function as
 428
 429     int
 430     foo(sv)
 431             SV *addr
 432         PREINIT:
 433             STRLEN len;
 434             char *s;
 435         CODE:
 436             s = SvPV(sv,len);
 437             RETVAL = foo(s, len);
 438         OUTPUT:
 439             RETVAL
 440
 441 or alternately
 442
 443     static int
 444     my_foo(SV *sv)
 445     {
 446         STRLEN len;
 447         char *s = SvPV(sv,len);
 448
 449         return foo(s, len);
 450     }
 451
 452     MODULE = foo        PACKAGE = foo   PREFIX = my_
 453
 454     int
 455     foo(sv)
 456         SV *sv
 457
 458 See L<perlxs> and L<perlxstut> for additional details.
 459
 460 =cut
 461
 462 # ' # Grr
 463 use strict;
 464
 465
 466 my( $H2XS_VERSION ) = ' $Revision: 1.22 $ ' =~ /\$Revision:\s+([^\s]+)/;
 467 my $TEMPLATE_VERSION = '0.01';
 468 my @ARGS = @ARGV;
 469 my $compat_version = $];
 470
 471 use Getopt::Long;
 472 use Config;
 473 use Text::Wrap;
 474 $Text::Wrap::huge = 'overflow';
 475 $Text::Wrap::columns = 80;
 476 use ExtUtils::Constant qw (WriteConstants WriteMakefileSnippet autoload);
 477 use File::Compare;
 478
 479 sub usage {
 480     warn "@_\n" if @_;
 481     die <<EOFUSAGE;
 482 h2xs [OPTIONS ... ] [headerfile [extra_libraries]]
 483 version: $H2XS_VERSION
 484 OPTIONS:
 485     -A, --omit-autoload   Omit all autoloading facilities (implies -c).
 486     -B, --beta-version    Use beta \$VERSION of 0.00_01 (ignored if -v).
 487     -C, --omit-changes    Omit creating the Changes file, add HISTORY heading
 488                           to stub POD.
 489     -F, --cpp-flags       Additional flags for C preprocessor/compile.
 490     -M, --func-mask       Mask to select C functions/macros
 491                           (default is select all).
 492     -O, --overwrite-ok    Allow overwriting of a pre-existing extension directory.
 493     -P, --omit-pod        Omit the stub POD section.
 494     -X, --omit-XS         Omit the XS portion (implies both -c and -f).
 495     -a, --gen-accessors   Generate get/set accessors for struct and union members                           (used with -x).
 496     -b, --compat-version  Specify a perl version to be backwards compatibile with
 497     -c, --omit-constant   Omit the constant() function and specialised AUTOLOAD
 498                           from the XS file.
 499     -d, --debugging       Turn on debugging messages.
 500     -f, --force           Force creation of the extension even if the C header
 501                           does not exist.
 502     -g, --global          Include code for safely storing static data in the .xs file.
 503     -h, -?, --help        Display this help message
 504     -k, --omit-const-func Omit 'const' attribute on function arguments
 505                           (used with -x).
 506     -m, --gen-tied-var    Generate tied variables for access to declared
 507                           variables.
 508     -n, --name            Specify a name to use for the extension (recommended).
 509     -o, --opaque-re       Regular expression for \"opaque\" types.
 510     -p, --remove-prefix   Specify a prefix which should be removed from the
 511                           Perl function names.
 512     -s, --const-subs      Create subroutines for specified macros.
 513     -t, --default-type    Default type for autoloaded constants (default is IV)
 514         --use-new-tests   Use Test::More in backward compatible modules
 515         --use-old-tests   Use the module Test rather than Test::More
 516         --skip-exporter   Do not export symbols
 517         --skip-ppport     Do not use portability layer
 518         --skip-autoloader Do not use the module C<AutoLoader>
 519         --skip-strict     Do not use the pragma C<strict>
 520         --skip-warnings   Do not use the pragma C<warnings>
 521     -v, --version         Specify a version number for this extension.
 522     -x, --autogen-xsubs   Autogenerate XSUBs using C::Scan.
 523
 524 extra_libraries
 525          are any libraries that might be needed for loading the
 526          extension, e.g. -lm would try to link in the math library.
 527 EOFUSAGE
 528 }
 529
 530 my ($opt_A,
 531     $opt_B,
 532     $opt_C,
 533     $opt_F,
 534     $opt_M,
 535     $opt_O,
 536     $opt_P,
 537     $opt_X,
 538     $opt_a,
 539     $opt_c,
 540     $opt_d,
 541     $opt_f,
 542     $opt_g,
 543     $opt_h,
 544     $opt_k,
 545     $opt_m,
 546     $opt_n,
 547     $opt_o,
 548     $opt_p,
 549     $opt_s,
 550     $opt_v,
 551     $opt_x,
 552     $opt_b,
 553     $opt_t,
 554     $new_test,
 555     $old_test,
 556     $skip_exporter,
 557     $skip_ppport,
 558     $skip_autoloader,
 559     $skip_strict,
 560     $skip_warnings,
 561    );
 562
 563 Getopt::Long::Configure('bundling');
 564
 565 my %options = (
 566                 'omit-autoload|A'    => \$opt_A,
 567                 'beta-version|B'     => \$opt_B,
 568                 'omit-changes|C'     => \$opt_C,
 569                 'cpp-flags|F=s'      => \$opt_F,
 570                 'func-mask|M=s'      => \$opt_M,
 571                 'overwrite_ok|O'     => \$opt_O,
 572                 'omit-pod|P'         => \$opt_P,
 573                 'omit-XS|X'          => \$opt_X,
 574                 'gen-accessors|a'    => \$opt_a,
 575                 'compat-version|b=s' => \$opt_b,
 576                 'omit-constant|c'    => \$opt_c,
 577                 'debugging|d'        => \$opt_d,
 578                 'force|f'            => \$opt_f,
 579                 'global|g'           => \$opt_g,
 580                 'help|h|?'           => \$opt_h,
 581                 'omit-const-func|k'  => \$opt_k,
 582                 'gen-tied-var|m'     => \$opt_m,
 583                 'name|n=s'           => \$opt_n,
 584                 'opaque-re|o=s'      => \$opt_o,
 585                 'remove-prefix|p=s'  => \$opt_p,
 586                 'const-subs|s=s'     => \$opt_s,
 587                 'default-type|t=s'   => \$opt_t,
 588                 'version|v=s'        => \$opt_v,
 589                 'autogen-xsubs|x'    => \$opt_x,
 590                 'use-new-tests'      => \$new_test,
 591                 'use-old-tests'      => \$old_test,
 592                 'skip-exporter'      => \$skip_exporter,
 593                 'skip-ppport'        => \$skip_ppport,
 594                 'skip-autoloader'    => \$skip_autoloader,
 595                 'skip-warnings'      => \$skip_warnings,
 596                 'skip-strict'        => \$skip_strict,
 597               );
 598
 599 GetOptions(%options) || usage;
 600
 601 usage if $opt_h;
 602
 603 if( $opt_b ){
 604     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
 605     $opt_b =~ /^\d+\.\d+\.\d+/ ||
 606     usage "You must provide the backwards compatibility version in X.Y.Z form. "
 607           .  "(i.e. 5.5.0)\n";
 608     my ($maj,$min,$sub) = split(/\./,$opt_b,3);
 609     if ($maj < 5 || ($maj == 5 && $min < 6)) {
 610         $compat_version =
 611             $sub ? sprintf("%d.%03d%02d",$maj,$min,$sub) :
 612                    sprintf("%d.%03d",    $maj,$min);
 613     } else {
 614         $compat_version =
 615             $sub ? sprintf("%d.%03d%03d",$maj,$min,$sub) :
 616                    sprintf("%d.%03d",    $maj,$min);
 617     }
 618 } else {
 619     my ($maj,$min,$sub) = $compat_version =~ /(\d+)\.(\d\d\d)(\d*)/;
 620     $sub ||= 0;
 621     warn sprintf <<'EOF', $maj,$min,$sub;
 622 Defaulting to backwards compatibility with perl %d.%d.%d
 623 If you intend this module to be compatible with earlier perl versions, please
 624 specify a minimum perl version with the -b option.
 625
 626 EOF
 627 }
 628
 629 if( $opt_B ){
 630     $TEMPLATE_VERSION = '0.00_01';
 631 }
 632
 633 if( $opt_v ){
 634         $TEMPLATE_VERSION = $opt_v;
 635
 636     # check if it is numeric
 637     my $temp_version = $TEMPLATE_VERSION;
 638     my $beta_version = $temp_version =~ s/(\d)_(\d\d)/$1$2/;
 639     my $notnum;
 640     {
 641         local $SIG{__WARN__} = sub { $notnum = 1 };
 642         use warnings 'numeric';
 643         $temp_version = 0+$temp_version;
 644     }
 645
 646     if ($notnum) {
 647         my $module = $opt_n || 'Your::Module';
 648         warn <<"EOF";
 649 You have specified a non-numeric version.  Unless you supply an
 650 appropriate VERSION class method, users may not be able to specify a
 651 minimum required version with C<use $module versionnum>.
 652
 653 EOF
 654     }
 655     else {
 656         $opt_B = $beta_version;
 657     }
 658 }
 659
 660 # -A implies -c.
 661 $skip_autoloader = $opt_c = 1 if $opt_A;
 662
 663 # -X implies -c and -f
 664 $opt_c = $opt_f = 1 if $opt_X;
 665
 666 $opt_t ||= 'IV';
 667
 668 my %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
 669
 670 my $extralibs = '';
 671
 672 my @path_h;
 673
 674 while (my $arg = shift) {
 675     if ($arg =~ /^-l/i) {
 676         $extralibs = "$arg @ARGV";
 677         last;
 678     }
 679     push(@path_h, $arg);
 680 }
 681
 682 usage "Must supply header file or module name\n"
 683         unless (@path_h or $opt_n);
 684
 685 my $fmask;
 686 my $tmask;
 687
 688 $fmask = qr{$opt_M} if defined $opt_M;
 689 $tmask = qr{$opt_o} if defined $opt_o;
 690 my $tmask_all = $tmask && $opt_o eq '.';
 691
 692 if ($opt_x) {
 693   eval {require C::Scan; 1}
 694     or die <<EOD;
 695 C::Scan required if you use -x option.
 696 To install C::Scan, execute
 697    perl -MCPAN -e "install C::Scan"
 698 EOD
 699   unless ($tmask_all) {
 700     $C::Scan::VERSION >= 0.70
 701       or die <<EOD;
 702 C::Scan v. 0.70 or later required unless you use -o . option.
 703 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 704 To install C::Scan, execute
 705    perl -MCPAN -e "install C::Scan"
 706 EOD
 707   }
 708   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
 709     die <<EOD;
 710 C::Scan v. 0.73 or later required to use -m or -a options.
 711 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 712 To install C::Scan, execute
 713    perl -MCPAN -e "install C::Scan"
 714 EOD
 715   }
 716 }
 717 elsif ($opt_o or $opt_F) {
 718   warn <<EOD if $opt_o;
 719 Option -o does not make sense without -x.
 720 EOD
 721   warn <<EOD if $opt_F and $opt_X ;
 722 Option -F does not make sense with -X.
 723 EOD
 724 }
 725
 726 my @path_h_ini = @path_h;
 727 my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
 728
 729 my $module = $opt_n;
 730
 731 if( @path_h ){
 732     use File::Spec;
 733     my @paths;
 734     my $pre_sub_tri_graphs = 1;
 735     if ($^O eq 'VMS') {  # Consider overrides of default location
 736       # XXXX This is not equivalent to what the older version did:
 737       #         it was looking at $hadsys header-file per header-file...
 738       my($hadsys) = grep s!^sys/!!i , @path_h;
 739       @paths = qw( Sys$Library VAXC$Include );
 740       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
 741       push @paths, qw( DECC$Library_Include DECC$System_Include );
 742     }
 743     else {
 744       @paths = (File::Spec->curdir(), $Config{usrinc},
 745                 (split ' ', $Config{locincpth}), '/usr/include');
 746     }
 747     foreach my $path_h (@path_h) {
 748         $name ||= $path_h;
 749     $module ||= do {
 750       $name =~ s/\.h$//;
 751       if ( $name !~ /::/ ) {
 752         $name =~ s#^.*/##;
 753         $name = "\u$name";
 754       }
 755       $name;
 756     };
 757
 758     if( $path_h =~ s#::#/#g && $opt_n ){
 759         warn "Nesting of headerfile ignored with -n\n";
 760     }
 761     $path_h .= ".h" unless $path_h =~ /\.h$/;
 762     my $fullpath = $path_h;
 763     $path_h =~ s/,.*$// if $opt_x;
 764     $fullpath{$path_h} = $fullpath;
 765
 766     # Minor trickery: we can't chdir() before we processed the headers
 767     # (so know the name of the extension), but the header may be in the
 768     # extension directory...
 769     my $tmp_path_h = $path_h;
 770     my $rel_path_h = $path_h;
 771     my @dirs = @paths;
 772     if (not -f $path_h) {
 773       my $found;
 774       for my $dir (@paths) {
 775         $found++, last
 776           if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
 777       }
 778       if ($found) {
 779         $rel_path_h = $path_h;
 780         $fullpath{$path_h} = $fullpath;
 781       } else {
 782         (my $epath = $module) =~ s,::,/,g;
 783         $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
 784         $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
 785         $path_h = $tmp_path_h;  # Used during -x
 786         push @dirs, $epath;
 787       }
 788     }
 789
 790     if (!$opt_c) {
 791       die "Can't find $tmp_path_h in @dirs\n"
 792         if ( ! $opt_f && ! -f "$rel_path_h" );
 793       # Scan the header file (we should deal with nested header files)
 794       # Record the names of simple #define constants into const_names
 795             # Function prototypes are processed below.
 796       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
 797     defines:
 798       while (<CH>) {
 799         if ($pre_sub_tri_graphs) {
 800             # Preprocess all tri-graphs
 801             # including things stuck in quoted string constants.
 802             s/\?\?=/#/g;                         # | ??=|  #|
 803             s/\?\?\!/|/g;                        # | ??!|  ||
 804             s/\?\?'/^/g;                         # | ??'|  ^|
 805             s/\?\?\(/[/g;                        # | ??(|  [|
 806             s/\?\?\)/]/g;                        # | ??)|  ]|
 807             s/\?\?\-/~/g;                        # | ??-|  ~|
 808             s/\?\?\//\\/g;                       # | ??/|  \|
 809             s/\?\?</{/g;                         # | ??<|  {|
 810             s/\?\?>/}/g;                         # | ??>|  }|
 811         }
 812         if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^"\s])(.*)/) {
 813             my $def = $1;
 814             my $rest = $2;
 815             $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
 816             $rest =~ s/^\s+//;
 817             $rest =~ s/\s+$//;
 818             # Cannot do: (-1) and ((LHANDLE)3) are OK:
 819             #print("Skip non-wordy $def => $rest\n"),
 820             #  next defines if $rest =~ /[^\w\$]/;
 821             if ($rest =~ /"/) {
 822               print("Skip stringy $def => $rest\n") if $opt_d;
 823               next defines;
 824             }
 825             print "Matched $_ ($def)\n" if $opt_d;
 826             $seen_define{$def} = $rest;
 827             $_ = $def;
 828             next if /^_.*_h_*$/i; # special case, but for what?
 829             if (defined $opt_p) {
 830               if (!/^$opt_p(\d)/) {
 831                 ++$prefix{$_} if s/^$opt_p//;
 832               }
 833               else {
 834                 warn "can't remove $opt_p prefix from '$_'!\n";
 835               }
 836             }
 837             $prefixless{$def} = $_;
 838             if (!$fmask or /$fmask/) {
 839                 print "... Passes mask of -M.\n" if $opt_d and $fmask;
 840                 $const_names{$_}++;
 841             }
 842           }
 843       }
 844       close(CH);
 845     }
 846     }
 847 }
 848
 849 # Save current directory so that C::Scan can use it
 850 my $cwd = File::Spec->rel2abs( File::Spec->curdir );
 851
 852 my ($ext, $nested, @modparts, $modfname, $modpname);
 853 # As Ilya suggested, use a name that contains - and then it can't clash with
 854 # the names of any packages. A directory 'fallback' will clash with any
 855 # new pragmata down the fallback:: tree, but that seems unlikely.
 856 my $constscfname = 'const-c.inc';
 857 my $constsxsfname = 'const-xs.inc';
 858 my $fallbackdirname = 'fallback';
 859
 860 $ext = chdir 'ext' ? 'ext/' : '';
 861
 862 if( $module =~ /::/ ){
 863         $nested = 1;
 864         @modparts = split(/::/,$module);
 865         $modfname = $modparts[-1];
 866         $modpname = join('/',@modparts);
 867 }
 868 else {
 869         $nested = 0;
 870         @modparts = ();
 871         $modfname = $modpname = $module;
 872 }
 873
 874
 875 if ($opt_O) {
 876         warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
 877 }
 878 else {
 879         die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
 880 }
 881 if( $nested ){
 882         my $modpath = "";
 883         foreach (@modparts){
 884                 -d "$modpath$_" || mkdir("$modpath$_", 0777);
 885                 $modpath .= "$_/";
 886         }
 887 }
 888 -d "$modpname"   || mkdir($modpname, 0777);
 889 chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
 890
 891 my %types_seen;
 892 my %std_types;
 893 my $fdecls = [];
 894 my $fdecls_parsed = [];
 895 my $typedef_rex;
 896 my %typedefs_pre;
 897 my %known_fnames;
 898 my %structs;
 899
 900 my @fnames;
 901 my @fnames_no_prefix;
 902 my %vdecl_hash;
 903 my @vdecls;
 904
 905 if( ! $opt_X ){  # use XS, unless it was disabled
 906   unless ($skip_ppport) {
 907     require Devel::PPPort;
 908     warn "Writing $ext$modpname/ppport.h\n";
 909     Devel::PPPort::WriteFile('ppport.h')
 910         || die "Can't create $ext$modpname/ppport.h: $!\n";
 911   }
 912   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
 913   if ($opt_x) {
 914     warn "Scanning typemaps...\n";
 915     get_typemap();
 916     my @td;
 917     my @good_td;
 918     my $addflags = $opt_F || '';
 919
 920     foreach my $filename (@path_h) {
 921       my $c;
 922       my $filter;
 923
 924       if ($fullpath{$filename} =~ /,/) {
 925         $filename = $`;
 926         $filter = $';
 927       }
 928       warn "Scanning $filename for functions...\n";
 929       my @styles = $Config{gccversion} ? qw(C++ C9X GNU) : qw(C++ C9X);
 930       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
 931         'add_cppflags' => $addflags, 'c_styles' => \@styles;
 932       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE", $cwd]);
 933
 934       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
 935       push(@$fdecls, @{$c->get('fdecls')});
 936
 937       push @td, @{$c->get('typedefs_maybe')};
 938       if ($opt_a) {
 939         my $structs = $c->get('typedef_structs');
 940         @structs{keys %$structs} = values %$structs;
 941       }
 942
 943       if ($opt_m) {
 944         %vdecl_hash = %{ $c->get('vdecl_hash') };
 945         @vdecls = sort keys %vdecl_hash;
 946         for (local $_ = 0; $_ < @vdecls; ++$_) {
 947           my $var = $vdecls[$_];
 948           my($type, $post) = @{ $vdecl_hash{$var} };
 949           if (defined $post) {
 950             warn "Can't handle variable '$type $var $post', skipping.\n";
 951             splice @vdecls, $_, 1;
 952             redo;
 953           }
 954           $type = normalize_type($type);
 955           $vdecl_hash{$var} = $type;
 956         }
 957       }
 958
 959       unless ($tmask_all) {
 960         warn "Scanning $filename for typedefs...\n";
 961         my $td = $c->get('typedef_hash');
 962         # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
 963         my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
 964         push @good_td, @f_good_td;
 965         @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
 966       }
 967     }
 968     { local $" = '|';
 969       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
 970     }
 971     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
 972     if ($fmask) {
 973       my @good;
 974       for my $i (0..$#$fdecls_parsed) {
 975         next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
 976         push @good, $i;
 977         print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
 978           if $opt_d;
 979       }
 980       $fdecls = [@$fdecls[@good]];
 981       $fdecls_parsed = [@$fdecls_parsed[@good]];
 982     }
 983     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
 984     # Sort declarations:
 985     {
 986       my %h = map( ($_->[1], $_), @$fdecls_parsed);
 987       $fdecls_parsed = [ @h{@fnames} ];
 988     }
 989     @fnames_no_prefix = @fnames;
 990     @fnames_no_prefix
 991       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix
 992          if defined $opt_p;
 993     # Remove macros which expand to typedefs
 994     print "Typedefs are @td.\n" if $opt_d;
 995     my %td = map {($_, $_)} @td;
 996     # Add some other possible but meaningless values for macros
 997     for my $k (qw(char double float int long short unsigned signed void)) {
 998       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
 999     }
1000     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
1001     my $n = 0;
1002     my %bad_macs;
1003     while (keys %td > $n) {
1004       $n = keys %td;
1005       my ($k, $v);
1006       while (($k, $v) = each %seen_define) {
1007         # print("found '$k'=>'$v'\n"),
1008         $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
1009       }
1010     }
1011     # Now %bad_macs contains names of bad macros
1012     for my $k (keys %bad_macs) {
1013       delete $const_names{$prefixless{$k}};
1014       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
1015     }
1016   }
1017 }
1018 my @const_names = sort keys %const_names;
1019
1020 open(PM, ">$modfname.pm") || die "Can't create $ext$modpname/$modfname.pm: $!\n";
1021
1022 $" = "\n\t";
1023 warn "Writing $ext$modpname/$modfname.pm\n";
1024
1025 print PM <<"END";
1026 package $module;
1027
1028 use $compat_version;
1029 END
1030
1031 print PM <<"END" unless $skip_strict;
1032 use strict;
1033 END
1034
1035 print PM "use warnings;\n" unless $skip_warnings or $compat_version < 5.006;
1036
1037 unless( $opt_X || $opt_c || $opt_A ){
1038         # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
1039         # will want Carp.
1040         print PM <<'END';
1041 use Carp;
1042 END
1043 }
1044
1045 print PM <<'END' unless $skip_exporter;
1046
1047 require Exporter;
1048 END
1049
1050 my $use_Dyna = (not $opt_X and $compat_version < 5.006);
1051 print PM <<"END" if $use_Dyna;  # use DynaLoader, unless XS was disabled
1052 require DynaLoader;
1053 END
1054
1055
1056 # Are we using AutoLoader or not?
1057 unless ($skip_autoloader) { # no autoloader whatsoever.
1058         unless ($opt_c) { # we're doing the AUTOLOAD
1059                 print PM "use AutoLoader;\n";
1060         }
1061         else {
1062                 print PM "use AutoLoader qw(AUTOLOAD);\n"
1063         }
1064 }
1065
1066 if ( $compat_version < 5.006 ) {
1067     my $vars = '$VERSION @ISA';
1068     $vars .= ' @EXPORT @EXPORT_OK %EXPORT_TAGS' unless $skip_exporter;
1069     $vars .= ' $AUTOLOAD' unless $opt_X || $opt_c || $opt_A;
1070     $vars .= ' $XS_VERSION' if $opt_B && !$opt_X;
1071     print PM "use vars qw($vars);";
1072 }
1073
1074 # Determine @ISA.
1075 my @modISA;
1076 push @modISA, 'Exporter'        unless $skip_exporter;
1077 push @modISA, 'DynaLoader'      if $use_Dyna;  # no XS
1078 my $myISA = "our \@ISA = qw(@modISA);";
1079 $myISA =~ s/^our // if $compat_version < 5.006;
1080
1081 print PM "\n$myISA\n\n";
1082
1083 my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
1084
1085 my $tmp='';
1086 $tmp .= <<"END" unless $skip_exporter;
1087 # Items to export into callers namespace by default. Note: do not export
1088 # names by default without a very good reason. Use EXPORT_OK instead.
1089 # Do not simply export all your public functions/methods/constants.
1090
1091 # This allows declaration       use $module ':all';
1092 # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
1093 # will save memory.
1094 our %EXPORT_TAGS = ( 'all' => [ qw(
1095         @exported_names
1096 ) ] );
1097
1098 our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
1099
1100 our \@EXPORT = qw(
1101         @const_names
1102 );
1103
1104 END
1105
1106 $tmp .= "our \$VERSION = '$TEMPLATE_VERSION';\n";
1107 if ($opt_B) {
1108     $tmp .= "our \$XS_VERSION = \$VERSION;\n" unless $opt_X;
1109     $tmp .= "\$VERSION = eval \$VERSION;  # see L<perlmodstyle>\n";
1110 }
1111 $tmp .= "\n";
1112
1113 $tmp =~ s/^our //mg if $compat_version < 5.006;
1114 print PM $tmp;
1115
1116 if (@vdecls) {
1117     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
1118 }
1119
1120
1121 print PM autoload ($module, $compat_version) unless $opt_c or $opt_X;
1122
1123 if( ! $opt_X ){ # print bootstrap, unless XS is disabled
1124   if ($use_Dyna) {
1125         $tmp = <<"END";
1126 bootstrap $module \$VERSION;
1127 END
1128   } else {
1129         $tmp = <<"END";
1130 require XSLoader;
1131 XSLoader::load('$module', \$VERSION);
1132 END
1133   }
1134   $tmp =~ s:\$VERSION:\$XS_VERSION:g if $opt_B;
1135   print PM $tmp;
1136 }
1137
1138 # tying the variables can happen only after bootstrap
1139 if (@vdecls) {
1140     printf PM <<END;
1141 {
1142 @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
1143 }
1144
1145 END
1146 }
1147
1148 my $after;
1149 if( $opt_P ){ # if POD is disabled
1150         $after = '__END__';
1151 }
1152 else {
1153         $after = '=cut';
1154 }
1155
1156 print PM <<"END";
1157
1158 # Preloaded methods go here.
1159 END
1160
1161 print PM <<"END" unless $opt_A;
1162
1163 # Autoload methods go after $after, and are processed by the autosplit program.
1164 END
1165
1166 print PM <<"END";
1167
1168 1;
1169 __END__
1170 END
1171
1172 my ($email,$author);
1173
1174 eval {
1175        my $username;
1176        ($username,$author) = (getpwuid($>))[0,6];
1177        if (defined $username && defined $author) {
1178            $author =~ s/,.*$//; # in case of sub fields
1179            my $domain = $Config{'mydomain'};
1180            $domain =~ s/^\.//;
1181            $email = "$username\@$domain";
1182        }
1183      };
1184
1185 $author ||= "A. U. Thor";
1186 $email  ||= 'a.u.thor@a.galaxy.far.far.away';
1187
1188 my $revhist = '';
1189 $revhist = <<EOT if $opt_C;
1190 #
1191 #=head1 HISTORY
1192 #
1193 #=over 8
1194 #
1195 #=item $TEMPLATE_VERSION
1196 #
1197 #Original version; created by h2xs $H2XS_VERSION with options
1198 #
1199 #  @ARGS
1200 #
1201 #=back
1202 #
1203 EOT
1204
1205 my $exp_doc = $skip_exporter ? '' : <<EOD;
1206 #
1207 #=head2 EXPORT
1208 #
1209 #None by default.
1210 #
1211 EOD
1212
1213 if (@const_names and not $opt_P) {
1214   $exp_doc .= <<EOD unless $skip_exporter;
1215 #=head2 Exportable constants
1216 #
1217 #  @{[join "\n  ", @const_names]}
1218 #
1219 EOD
1220 }
1221
1222 if (defined $fdecls and @$fdecls and not $opt_P) {
1223   $exp_doc .= <<EOD unless $skip_exporter;
1224 #=head2 Exportable functions
1225 #
1226 EOD
1227
1228 #  $exp_doc .= <<EOD if $opt_p;
1229 #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
1230 #
1231 #EOD
1232   $exp_doc .= <<EOD unless $skip_exporter;
1233 #  @{[join "\n  ", @known_fnames{@fnames}]}
1234 #
1235 EOD
1236 }
1237
1238 my $meth_doc = '';
1239
1240 if ($opt_x && $opt_a) {
1241   my($name, $struct);
1242   $meth_doc .= accessor_docs($name, $struct)
1243     while ($name, $struct) = each %structs;
1244 }
1245
1246 my $pod = <<"END" unless $opt_P;
1247 ## Below is stub documentation for your module. You'd better edit it!
1248 #
1249 #=head1 NAME
1250 #
1251 #$module - Perl extension for blah blah blah
1252 #
1253 #=head1 SYNOPSIS
1254 #
1255 #  use $module;
1256 #  blah blah blah
1257 #
1258 #=head1 ABSTRACT
1259 #
1260 #  This should be the abstract for $module.
1261 #  The abstract is used when making PPD (Perl Package Description) files.
1262 #  If you don't want an ABSTRACT you should also edit Makefile.PL to
1263 #  remove the ABSTRACT_FROM option.
1264 #
1265 #=head1 DESCRIPTION
1266 #
1267 #Stub documentation for $module, created by h2xs. It looks like the
1268 #author of the extension was negligent enough to leave the stub
1269 #unedited.
1270 #
1271 #Blah blah blah.
1272 $exp_doc$meth_doc$revhist
1273 #
1274 #=head1 SEE ALSO
1275 #
1276 #Mention other useful documentation such as the documentation of
1277 #related modules or operating system documentation (such as man pages
1278 #in UNIX), or any relevant external documentation such as RFCs or
1279 #standards.
1280 #
1281 #If you have a mailing list set up for your module, mention it here.
1282 #
1283 #If you have a web site set up for your module, mention it here.
1284 #
1285 #=head1 AUTHOR
1286 #
1287 #$author, E<lt>${email}E<gt>
1288 #
1289 #=head1 COPYRIGHT AND LICENSE
1290 #
1291 #Copyright ${\(1900 + (localtime) [5])} by $author
1292 #
1293 #This library is free software; you can redistribute it and/or modify
1294 #it under the same terms as Perl itself.
1295 #
1296 #=cut
1297 END
1298
1299 $pod =~ s/^\#//gm unless $opt_P;
1300 print PM $pod unless $opt_P;
1301
1302 close PM;
1303
1304
1305 if( ! $opt_X ){ # print XS, unless it is disabled
1306 warn "Writing $ext$modpname/$modfname.xs\n";
1307
1308 print XS <<"END";
1309 #include "EXTERN.h"
1310 #include "perl.h"
1311 #include "XSUB.h"
1312
1313 END
1314
1315 print XS <<"END" unless $skip_ppport;
1316 #include "ppport.h"
1317
1318 END
1319
1320 if( @path_h ){
1321     foreach my $path_h (@path_h_ini) {
1322         my($h) = $path_h;
1323         $h =~ s#^/usr/include/##;
1324         if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
1325         print XS qq{#include <$h>\n};
1326     }
1327     print XS "\n";
1328 }
1329
1330 print XS <<"END" if $opt_g;
1331
1332 /* Global Data */
1333
1334 #define MY_CXT_KEY "${module}::_guts" XS_VERSION
1335
1336 typedef struct {
1337     /* Put Global Data in here */
1338     int dummy;          /* you can access this elsewhere as MY_CXT.dummy */
1339 } my_cxt_t;
1340
1341 START_MY_CXT
1342
1343 END
1344
1345 my %pointer_typedefs;
1346 my %struct_typedefs;
1347
1348 sub td_is_pointer {
1349   my $type = shift;
1350   my $out = $pointer_typedefs{$type};
1351   return $out if defined $out;
1352   my $otype = $type;
1353   $out = ($type =~ /\*$/);
1354   # This converts only the guys which do not have trailing part in the typedef
1355   if (not $out
1356       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1357     $type = normalize_type($type);
1358     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
1359       if $opt_d;
1360     $out = td_is_pointer($type);
1361   }
1362   return ($pointer_typedefs{$otype} = $out);
1363 }
1364
1365 sub td_is_struct {
1366   my $type = shift;
1367   my $out = $struct_typedefs{$type};
1368   return $out if defined $out;
1369   my $otype = $type;
1370   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
1371   # This converts only the guys which do not have trailing part in the typedef
1372   if (not $out
1373       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1374     $type = normalize_type($type);
1375     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
1376       if $opt_d;
1377     $out = td_is_struct($type);
1378   }
1379   return ($struct_typedefs{$otype} = $out);
1380 }
1381
1382 print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
1383
1384 if( ! $opt_c ) {
1385   # We write the "sample" files used when this module is built by perl without
1386   # ExtUtils::Constant.
1387   # h2xs will later check that these are the same as those generated by the
1388   # code embedded into Makefile.PL
1389   unless (-d $fallbackdirname) {
1390     mkdir "$fallbackdirname" or die "Cannot mkdir $fallbackdirname: $!\n";
1391   }
1392   warn "Writing $ext$modpname/$fallbackdirname/$constscfname\n";
1393   warn "Writing $ext$modpname/$fallbackdirname/$constsxsfname\n";
1394   my $cfallback = File::Spec->catfile($fallbackdirname, $constscfname);
1395   my $xsfallback = File::Spec->catfile($fallbackdirname, $constsxsfname);
1396   WriteConstants ( C_FILE =>       $cfallback,
1397                    XS_FILE =>      $xsfallback,
1398                    DEFAULT_TYPE => $opt_t,
1399                    NAME =>         $module,
1400                    NAMES =>        \@const_names,
1401                  );
1402   print XS "#include \"$constscfname\"\n";
1403 }
1404
1405
1406 my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
1407
1408 # Now switch from C to XS by issuing the first MODULE declaration:
1409 print XS <<"END";
1410
1411 MODULE = $module                PACKAGE = $module               $prefix
1412
1413 END
1414
1415 # If a constant() function was #included then output a corresponding
1416 # XS declaration:
1417 print XS "INCLUDE: $constsxsfname\n" unless $opt_c;
1418
1419 print XS <<"END" if $opt_g;
1420
1421 BOOT:
1422 {
1423     MY_CXT_INIT;
1424     /* If any of the fields in the my_cxt_t struct need
1425        to be initialised, do it here.
1426      */
1427 }
1428
1429 END
1430
1431 foreach (sort keys %const_xsub) {
1432     print XS <<"END";
1433 char *
1434 $_()
1435
1436     CODE:
1437 #ifdef $_
1438         RETVAL = $_;
1439 #else
1440         croak("Your vendor has not defined the $module macro $_");
1441 #endif
1442
1443     OUTPUT:
1444         RETVAL
1445
1446 END
1447 }
1448
1449 my %seen_decl;
1450 my %typemap;
1451
1452 sub print_decl {
1453   my $fh = shift;
1454   my $decl = shift;
1455   my ($type, $name, $args) = @$decl;
1456   return if $seen_decl{$name}++; # Need to do the same for docs as well?
1457
1458   my @argnames = map {$_->[1]} @$args;
1459   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
1460   if ($opt_k) {
1461     s/^\s*const\b\s*// for @argtypes;
1462   }
1463   my @argarrays = map { $_->[4] || '' } @$args;
1464   my $numargs = @$args;
1465   if ($numargs and $argtypes[-1] eq '...') {
1466     $numargs--;
1467     $argnames[-1] = '...';
1468   }
1469   local $" = ', ';
1470   $type = normalize_type($type, 1);
1471
1472   print $fh <<"EOP";
1473
1474 $type
1475 $name(@argnames)
1476 EOP
1477
1478   for my $arg (0 .. $numargs - 1) {
1479     print $fh <<"EOP";
1480         $argtypes[$arg] $argnames[$arg]$argarrays[$arg]
1481 EOP
1482   }
1483 }
1484
1485 sub print_tievar_subs {
1486   my($fh, $name, $type) = @_;
1487   print $fh <<END;
1488 I32
1489 _get_$name(IV index, SV *sv) {
1490     dSP;
1491     PUSHMARK(SP);
1492     XPUSHs(sv);
1493     PUTBACK;
1494     (void)call_pv("$module\::_get_$name", G_DISCARD);
1495     return (I32)0;
1496 }
1497
1498 I32
1499 _set_$name(IV index, SV *sv) {
1500     dSP;
1501     PUSHMARK(SP);
1502     XPUSHs(sv);
1503     PUTBACK;
1504     (void)call_pv("$module\::_set_$name", G_DISCARD);
1505     return (I32)0;
1506 }
1507
1508 END
1509 }
1510
1511 sub print_tievar_xsubs {
1512   my($fh, $name, $type) = @_;
1513   print $fh <<END;
1514 void
1515 _tievar_$name(sv)
1516         SV* sv
1517     PREINIT:
1518         struct ufuncs uf;
1519     CODE:
1520         uf.uf_val = &_get_$name;
1521         uf.uf_set = &_set_$name;
1522         uf.uf_index = (IV)&_get_$name;
1523         sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
1524
1525 void
1526 _get_$name(THIS)
1527         $type THIS = NO_INIT
1528     CODE:
1529         THIS = $name;
1530     OUTPUT:
1531         SETMAGIC: DISABLE
1532         THIS
1533
1534 void
1535 _set_$name(THIS)
1536         $type THIS
1537     CODE:
1538         $name = THIS;
1539
1540 END
1541 }
1542
1543 sub print_accessors {
1544   my($fh, $name, $struct) = @_;
1545   return unless defined $struct && $name !~ /\s|_ANON/;
1546   $name = normalize_type($name);
1547   my $ptrname = normalize_type("$name *");
1548   print $fh <<"EOF";
1549
1550 MODULE = $module                PACKAGE = ${name}               $prefix
1551
1552 $name *
1553 _to_ptr(THIS)
1554         $name THIS = NO_INIT
1555     PROTOTYPE: \$
1556     CODE:
1557         if (sv_derived_from(ST(0), "$name")) {
1558             STRLEN len;
1559             char *s = SvPV((SV*)SvRV(ST(0)), len);
1560             if (len != sizeof(THIS))
1561                 croak("Size \%d of packed data != expected \%d",
1562                         len, sizeof(THIS));
1563             RETVAL = ($name *)s;
1564         }
1565         else
1566             croak("THIS is not of type $name");
1567     OUTPUT:
1568         RETVAL
1569
1570 $name
1571 new(CLASS)
1572         char *CLASS = NO_INIT
1573     PROTOTYPE: \$
1574     CODE:
1575         Zero((void*)&RETVAL, sizeof(RETVAL), char);
1576     OUTPUT:
1577         RETVAL
1578
1579 MODULE = $module                PACKAGE = ${name}Ptr            $prefix
1580
1581 EOF
1582   my @items = @$struct;
1583   while (@items) {
1584     my $item = shift @items;
1585     if ($item->[0] =~ /_ANON/) {
1586       if (defined $item->[2]) {
1587         push @items, map [
1588           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1589         ], @{ $structs{$item->[0]} };
1590       } else {
1591         push @items, @{ $structs{$item->[0]} };
1592       }
1593     } else {
1594       my $type = normalize_type($item->[0]);
1595       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
1596       print $fh <<"EOF";
1597 $ttype
1598 $item->[2](THIS, __value = NO_INIT)
1599         $ptrname THIS
1600         $type __value
1601     PROTOTYPE: \$;\$
1602     CODE:
1603         if (items > 1)
1604             THIS->$item->[-1] = __value;
1605         RETVAL = @{[
1606             $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
1607         ]};
1608     OUTPUT:
1609         RETVAL
1610
1611 EOF
1612     }
1613   }
1614 }
1615
1616 sub accessor_docs {
1617   my($name, $struct) = @_;
1618   return unless defined $struct && $name !~ /\s|_ANON/;
1619   $name = normalize_type($name);
1620   my $ptrname = $name . 'Ptr';
1621   my @items = @$struct;
1622   my @list;
1623   while (@items) {
1624     my $item = shift @items;
1625     if ($item->[0] =~ /_ANON/) {
1626       if (defined $item->[2]) {
1627         push @items, map [
1628           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1629         ], @{ $structs{$item->[0]} };
1630       } else {
1631         push @items, @{ $structs{$item->[0]} };
1632       }
1633     } else {
1634       push @list, $item->[2];
1635     }
1636   }
1637   my $methods = (join '(...)>, C<', @list) . '(...)';
1638
1639   my $pod = <<"EOF";
1640 #
1641 #=head2 Object and class methods for C<$name>/C<$ptrname>
1642 #
1643 #The principal Perl representation of a C object of type C<$name> is an
1644 #object of class C<$ptrname> which is a reference to an integer
1645 #representation of a C pointer.  To create such an object, one may use
1646 #a combination
1647 #
1648 #  my \$buffer = $name->new();
1649 #  my \$obj = \$buffer->_to_ptr();
1650 #
1651 #This exersizes the following two methods, and an additional class
1652 #C<$name>, the internal representation of which is a reference to a
1653 #packed string with the C structure.  Keep in mind that \$buffer should
1654 #better survive longer than \$obj.
1655 #
1656 #=over
1657 #
1658 #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
1659 #
1660 #Converts an object of type C<$name> to an object of type C<$ptrname>.
1661 #
1662 #=item C<$name-E<gt>new()>
1663 #
1664 #Creates an empty object of type C<$name>.  The corresponding packed
1665 #string is zeroed out.
1666 #
1667 #=item C<$methods>
1668 #
1669 #return the current value of the corresponding element if called
1670 #without additional arguments.  Set the element to the supplied value
1671 #(and return the new value) if called with an additional argument.
1672 #
1673 #Applicable to objects of type C<$ptrname>.
1674 #
1675 #=back
1676 #
1677 EOF
1678   $pod =~ s/^\#//gm;
1679   return $pod;
1680 }
1681
1682 # Should be called before any actual call to normalize_type().
1683 sub get_typemap {
1684   # We do not want to read ./typemap by obvios reasons.
1685   my @tm =  qw(../../../typemap ../../typemap ../typemap);
1686   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
1687   unshift @tm, $stdtypemap;
1688   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
1689
1690   # Start with useful default values
1691   $typemap{float} = 'T_NV';
1692
1693   foreach my $typemap (@tm) {
1694     next unless -e $typemap ;
1695     # skip directories, binary files etc.
1696     warn " Scanning $typemap\n";
1697     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
1698       unless -T $typemap ;
1699     open(TYPEMAP, $typemap)
1700       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
1701     my $mode = 'Typemap';
1702     while (<TYPEMAP>) {
1703       next if /^\s*\#/;
1704       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
1705       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
1706       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
1707       elsif ($mode eq 'Typemap') {
1708         next if /^\s*($|\#)/ ;
1709         my ($type, $image);
1710         if ( ($type, $image) =
1711              /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
1712              # This may reference undefined functions:
1713              and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
1714           $typemap{normalize_type($type)} = $image;
1715         }
1716       }
1717     }
1718     close(TYPEMAP) or die "Cannot close $typemap: $!";
1719   }
1720   %std_types = %types_seen;
1721   %types_seen = ();
1722 }
1723
1724
1725 sub normalize_type {            # Second arg: do not strip const's before \*
1726   my $type = shift;
1727   my $do_keep_deep_const = shift;
1728   # If $do_keep_deep_const this is heuristical only
1729   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
1730   my $ignore_mods
1731     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
1732   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
1733     $type =~ s/$ignore_mods//go;
1734   }
1735   else {
1736     $type =~ s/$ignore_mods//go;
1737   }
1738   $type =~ s/([^\s\w])/ $1 /g;
1739   $type =~ s/\s+$//;
1740   $type =~ s/^\s+//;
1741   $type =~ s/\s+/ /g;
1742   $type =~ s/\* (?=\*)/*/g;
1743   $type =~ s/\. \. \./.../g;
1744   $type =~ s/ ,/,/g;
1745   $types_seen{$type}++
1746     unless $type eq '...' or $type eq 'void' or $std_types{$type};
1747   $type;
1748 }
1749
1750 my $need_opaque;
1751
1752 sub assign_typemap_entry {
1753   my $type = shift;
1754   my $otype = $type;
1755   my $entry;
1756   if ($tmask and $type =~ /$tmask/) {
1757     print "Type $type matches -o mask\n" if $opt_d;
1758     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1759   }
1760   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1761     $type = normalize_type $type;
1762     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
1763     $entry = assign_typemap_entry($type);
1764   }
1765   # XXX good do better if our UV happens to be long long
1766   return "T_NV" if $type =~ /^(unsigned\s+)?long\s+(long|double)\z/;
1767   $entry ||= $typemap{$otype}
1768     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1769   $typemap{$otype} = $entry;
1770   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
1771   return $entry;
1772 }
1773
1774 for (@vdecls) {
1775   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
1776 }
1777
1778 if ($opt_x) {
1779   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
1780   if ($opt_a) {
1781     while (my($name, $struct) = each %structs) {
1782       print_accessors(\*XS, $name, $struct);
1783     }
1784   }
1785 }
1786
1787 close XS;
1788
1789 if (%types_seen) {
1790   my $type;
1791   warn "Writing $ext$modpname/typemap\n";
1792   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
1793
1794   for $type (sort keys %types_seen) {
1795     my $entry = assign_typemap_entry $type;
1796     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
1797   }
1798
1799   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
1800 #############################################################################
1801 INPUT
1802 T_OPAQUE_STRUCT
1803         if (sv_derived_from($arg, \"${ntype}\")) {
1804             STRLEN len;
1805             char  *s = SvPV((SV*)SvRV($arg), len);
1806
1807             if (len != sizeof($var))
1808                 croak(\"Size %d of packed data != expected %d\",
1809                         len, sizeof($var));
1810             $var = *($type *)s;
1811         }
1812         else
1813             croak(\"$var is not of type ${ntype}\")
1814 #############################################################################
1815 OUTPUT
1816 T_OPAQUE_STRUCT
1817         sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
1818 EOP
1819
1820   close TM or die "Cannot close typemap file for write: $!";
1821 }
1822
1823 } # if( ! $opt_X )
1824
1825 warn "Writing $ext$modpname/Makefile.PL\n";
1826 open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
1827
1828 my $prereq_pm;
1829
1830 if ( $compat_version < 5.00702 and $new_test )
1831 {
1832   $prereq_pm = q%'Test::More'  =>  0%;
1833 }
1834 else
1835 {
1836   $prereq_pm = '';
1837 }
1838
1839 print PL <<"END";
1840 use $compat_version;
1841 use ExtUtils::MakeMaker;
1842 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
1843 # the contents of the Makefile that is written.
1844 WriteMakefile(
1845     'NAME'              => '$module',
1846     'VERSION_FROM'      => '$modfname.pm', # finds \$VERSION
1847     'PREREQ_PM'         => {$prereq_pm}, # e.g., Module::Name => 1.1
1848     (\$] >= 5.005 ?    ## Add these new keywords supported since 5.005
1849       (ABSTRACT_FROM => '$modfname.pm', # retrieve abstract from module
1850        AUTHOR     => '$author <$email>') : ()),
1851 END
1852 if (!$opt_X) { # print C stuff, unless XS is disabled
1853   $opt_F = '' unless defined $opt_F;
1854   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
1855   my $Ihelp = ($I ? '-I. ' : '');
1856   my $Icomment = ($I ? '' : <<EOC);
1857         # Insert -I. if you add *.h files later:
1858 EOC
1859
1860   print PL <<END;
1861     'LIBS'              => ['$extralibs'], # e.g., '-lm'
1862     'DEFINE'            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
1863 $Icomment    'INC'              => '$I', # e.g., '${Ihelp}-I/usr/include/other'
1864 END
1865
1866   my $C = grep {$_ ne "$modfname.c"}
1867     (glob '*.c'), (glob '*.cc'), (glob '*.C');
1868   my $Cpre = ($C ? '' : '# ');
1869   my $Ccomment = ($C ? '' : <<EOC);
1870         # Un-comment this if you add C files to link with later:
1871 EOC
1872
1873   print PL <<END;
1874 $Ccomment    $Cpre\'OBJECT'             => '\$(O_FILES)', # link all the C files too
1875 END
1876 } # ' # Grr
1877 print PL ");\n";
1878 if (!$opt_c) {
1879   my $generate_code =
1880     WriteMakefileSnippet ( C_FILE =>       $constscfname,
1881                            XS_FILE =>      $constsxsfname,
1882                            DEFAULT_TYPE => $opt_t,
1883                            NAME =>         $module,
1884                            NAMES =>        \@const_names,
1885                  );
1886   print PL <<"END";
1887 if  (eval {require ExtUtils::Constant; 1}) {
1888   # If you edit these definitions to change the constants used by this module,
1889   # you will need to use the generated $constscfname and $constsxsfname
1890   # files to replace their "fallback" counterparts before distributing your
1891   # changes.
1892 $generate_code
1893 }
1894 else {
1895   use File::Copy;
1896   use File::Spec;
1897   foreach my \$file ('$constscfname', '$constsxsfname') {
1898     my \$fallback = File::Spec->catfile('$fallbackdirname', \$file);
1899     copy (\$fallback, \$file) or die "Can't copy \$fallback to \$file: \$!";
1900   }
1901 }
1902 END
1903
1904   eval $generate_code;
1905   if ($@) {
1906     warn <<"EOM";
1907 Attempting to test constant code in $ext$modpname/Makefile.PL:
1908 $generate_code
1909 __END__
1910 gave unexpected error $@
1911 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1912 using the perlbug script.
1913 EOM
1914   } else {
1915     my $fail;
1916
1917     foreach my $file ($constscfname, $constsxsfname) {
1918       my $fallback = File::Spec->catfile($fallbackdirname, $file);
1919       if (compare($file, $fallback)) {
1920         warn << "EOM";
1921 Files "$ext$modpname/$fallbackdirname/$file" and "$ext$modpname/$file" differ.
1922 EOM
1923         $fail++;
1924       }
1925     }
1926     if ($fail) {
1927       warn fill ('','', <<"EOM") . "\n";
1928 It appears that the code in $ext$modpname/Makefile.PL does not autogenerate
1929 the files $ext$modpname/$constscfname and $ext$modpname/$constsxsfname
1930 correctly.
1931
1932 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1933 using the perlbug script.
1934 EOM
1935     } else {
1936       unlink $constscfname, $constsxsfname;
1937     }
1938   }
1939 }
1940 close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
1941
1942 # Create a simple README since this is a CPAN requirement
1943 # and it doesnt hurt to have one
1944 warn "Writing $ext$modpname/README\n";
1945 open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
1946 my $thisyear = (gmtime)[5] + 1900;
1947 my $rmhead = "$modpname version $TEMPLATE_VERSION";
1948 my $rmheadeq = "=" x length($rmhead);
1949
1950 my $rm_prereq;
1951
1952 if ( $compat_version < 5.00702 and $new_test )
1953 {
1954    $rm_prereq = 'Test::More';
1955 }
1956 else
1957 {
1958    $rm_prereq = 'blah blah blah';
1959 }
1960
1961 print RM <<_RMEND_;
1962 $rmhead
1963 $rmheadeq
1964
1965 The README is used to introduce the module and provide instructions on
1966 how to install the module, any machine dependencies it may have (for
1967 example C compilers and installed libraries) and any other information
1968 that should be provided before the module is installed.
1969
1970 A README file is required for CPAN modules since CPAN extracts the
1971 README file from a module distribution so that people browsing the
1972 archive can use it get an idea of the modules uses. It is usually a
1973 good idea to provide version information here so that people can
1974 decide whether fixes for the module are worth downloading.
1975
1976 INSTALLATION
1977
1978 To install this module type the following:
1979
1980    perl Makefile.PL
1981    make
1982    make test
1983    make install
1984
1985 DEPENDENCIES
1986
1987 This module requires these other modules and libraries:
1988
1989   $rm_prereq
1990
1991 COPYRIGHT AND LICENCE
1992
1993 Put the correct copyright and licence information here.
1994
1995 Copyright (C) $thisyear $author
1996
1997 This library is free software; you can redistribute it and/or modify
1998 it under the same terms as Perl itself.
1999
2000 _RMEND_
2001 close(RM) || die "Can't close $ext$modpname/README: $!\n";
2002
2003 my $testdir  = "t";
2004 my $testfile = "$testdir/1.t";
2005 unless (-d "$testdir") {
2006   mkdir "$testdir" or die "Cannot mkdir $testdir: $!\n";
2007 }
2008 warn "Writing $ext$modpname/$testfile\n";
2009 my $tests = @const_names ? 2 : 1;
2010
2011 open EX, ">$testfile" or die "Can't create $ext$modpname/$testfile: $!\n";
2012
2013 print EX <<_END_;
2014 # Before `make install' is performed this script should be runnable with
2015 # `make test'. After `make install' it should work as `perl 1.t'
2016
2017 #########################
2018
2019 # change 'tests => $tests' to 'tests => last_test_to_print';
2020
2021 _END_
2022
2023 my $test_mod = 'Test::More';
2024
2025 if ( $old_test or ($compat_version < 5.007 and not $new_test ))
2026 {
2027   my $test_mod = 'Test';
2028
2029   print EX <<_END_;
2030 use Test;
2031 BEGIN { plan tests => $tests };
2032 use $module;
2033 ok(1); # If we made it this far, we're ok.
2034
2035 _END_
2036
2037    if (@const_names) {
2038      my $const_names = join " ", @const_names;
2039      print EX <<'_END_';
2040
2041 my $fail;
2042 foreach my $constname (qw(
2043 _END_
2044
2045      print EX wrap ("\t", "\t", $const_names);
2046      print EX (")) {\n");
2047
2048      print EX <<_END_;
2049   next if (eval "my \\\$a = \$constname; 1");
2050   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2051     print "# pass: \$\@";
2052   } else {
2053     print "# fail: \$\@";
2054     \$fail = 1;
2055   }
2056 }
2057 if (\$fail) {
2058   print "not ok 2\\n";
2059 } else {
2060   print "ok 2\\n";
2061 }
2062
2063 _END_
2064   }
2065 }
2066 else
2067 {
2068   print EX <<_END_;
2069 use Test::More tests => $tests;
2070 BEGIN { use_ok('$module') };
2071
2072 _END_
2073
2074    if (@const_names) {
2075      my $const_names = join " ", @const_names;
2076      print EX <<'_END_';
2077
2078 my $fail = 0;
2079 foreach my $constname (qw(
2080 _END_
2081
2082      print EX wrap ("\t", "\t", $const_names);
2083      print EX (")) {\n");
2084
2085      print EX <<_END_;
2086   next if (eval "my \\\$a = \$constname; 1");
2087   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2088     print "# pass: \$\@";
2089   } else {
2090     print "# fail: \$\@";
2091     \$fail = 1;
2092   }
2093
2094 }
2095
2096 ok( \$fail == 0 , 'Constants' );
2097 _END_
2098   }
2099 }
2100
2101 print EX <<_END_;
2102 #########################
2103
2104 # Insert your test code below, the $test_mod module is use()ed here so read
2105 # its man page ( perldoc $test_mod ) for help writing this test script.
2106
2107 _END_
2108
2109 close(EX) || die "Can't close $ext$modpname/$testfile: $!\n";
2110
2111 unless ($opt_C) {
2112   warn "Writing $ext$modpname/Changes\n";
2113   $" = ' ';
2114   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
2115   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
2116   print EX <<EOP;
2117 Revision history for Perl extension $module.
2118
2119 $TEMPLATE_VERSION  @{[scalar localtime]}
2120 \t- original version; created by h2xs $H2XS_VERSION with options
2121 \t\t@ARGS
2122
2123 EOP
2124   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
2125 }
2126
2127 warn "Writing $ext$modpname/MANIFEST\n";
2128 open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
2129 my @files = grep { -f } (<*>, <t/*>, <$fallbackdirname/*>);
2130 if (!@files) {
2131   eval {opendir(D,'.');};
2132   unless ($@) { @files = readdir(D); closedir(D); }
2133 }
2134 if (!@files) { @files = map {chomp && $_} `ls`; }
2135 if ($^O eq 'VMS') {
2136   foreach (@files) {
2137     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
2138     s%\.$%%;
2139     # Fix up for case-sensitive file systems
2140     s/$modfname/$modfname/i && next;
2141     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
2142     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
2143   }
2144 }
2145 print MANI join("\n",@files), "\n";
2146 close MANI;
2147 !NO!SUBS!
2148
2149 close OUT or die "Can't close $file: $!";
2150 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
2151 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
2152 chdir $origdir;