lib/utf8.pm

   1 package utf8;
   2
   3 $utf8::hint_bits = 0x00800000;
   4
   5 our $VERSION = '1.20';
   6
   7 sub import {
   8     $^H |= $utf8::hint_bits;
   9 }
  10
  11 sub unimport {
  12     $^H &= ~$utf8::hint_bits;
  13 }
  14
  15 sub AUTOLOAD {
  16     require "utf8_heavy.pl";
  17     goto &$AUTOLOAD if defined &$AUTOLOAD;
  18     require Carp;
  19     Carp::croak("Undefined subroutine $AUTOLOAD called");
  20 }
  21
  22 1;
  23 __END__
  24
  25 =head1 NAME
  26
  27 utf8 - Perl pragma to enable/disable UTF-8 (or UTF-EBCDIC) in source code
  28
  29 =head1 SYNOPSIS
  30
  31  use utf8;
  32  no utf8;
  33
  34  # Convert the internal representation of a Perl scalar to/from UTF-8.
  35
  36  $num_octets = utf8::upgrade($string);
  37  $success    = utf8::downgrade($string[, $fail_ok]);
  38
  39  # Change each character of a Perl scalar to/from a series of
  40  # characters that represent the UTF-8 bytes of each original character.
  41
  42  utf8::encode($string);  # "\x{100}"  becomes "\xc4\x80"
  43  utf8::decode($string);  # "\xc4\x80" becomes "\x{100}"
  44
  45  # Convert a code point from the platform native character set to
  46  # Unicode, and vice-versa.
  47  $unicode = utf8::native_to_unicode(ord('A')); # returns 65 on both
  48                                                # ASCII and EBCDIC
  49                                                # platforms
  50  $native = utf8::unicode_to_native(65);        # returns 65 on ASCII
  51                                                # platforms; 193 on
  52                                                # EBCDIC
  53
  54  $flag = utf8::is_utf8($string); # since Perl 5.8.1
  55  $flag = utf8::valid($string);
  56
  57 =head1 DESCRIPTION
  58
  59 The C<use utf8> pragma tells the Perl parser to allow UTF-8 in the
  60 program text in the current lexical scope.  The C<no utf8> pragma tells Perl
  61 to switch back to treating the source text as literal bytes in the current
  62 lexical scope.  (On EBCDIC platforms, technically it is allowing UTF-EBCDIC,
  63 and not UTF-8, but this distinction is academic, so in this document the term
  64 UTF-8 is used to mean both).
  65
  66 B<Do not use this pragma for anything else than telling Perl that your
  67 script is written in UTF-8.> The utility functions described below are
  68 directly usable without C<use utf8;>.
  69
  70 Because it is not possible to reliably tell UTF-8 from native 8 bit
  71 encodings, you need either a Byte Order Mark at the beginning of your
  72 source code, or C<use utf8;>, to instruct perl.
  73
  74 When UTF-8 becomes the standard source format, this pragma will
  75 effectively become a no-op.
  76
  77 See also the effects of the C<-C> switch and its cousin, the
  78 C<PERL_UNICODE> environment variable, in L<perlrun>.
  79
  80 Enabling the C<utf8> pragma has the following effect:
  81
  82 =over 4
  83
  84 =item *
  85
  86 Bytes in the source text that are not in the ASCII character set will be
  87 treated as being part of a literal UTF-8 sequence.  This includes most
  88 literals such as identifier names, string constants, and constant
  89 regular expression patterns.
  90
  91 =back
  92
  93 Note that if you have non-ASCII, non-UTF-8 bytes in your script (for example
  94 embedded Latin-1 in your string literals), C<use utf8> will be unhappy.  If
  95 you want to have such bytes under C<use utf8>, you can disable this pragma
  96 until the end the block (or file, if at top level) by C<no utf8;>.
  97
  98 =head2 Utility functions
  99
 100 The following functions are defined in the C<utf8::> package by the
 101 Perl core.  You do not need to say C<use utf8> to use these and in fact
 102 you should not say that unless you really want to have UTF-8 source code.
 103
 104 =over 4
 105
 106 =item * C<$num_octets = utf8::upgrade($string)>
 107
 108 (Since Perl v5.8.0)
 109 Converts in-place the internal representation of the string from an octet
 110 sequence in the native encoding (Latin-1 or EBCDIC) to UTF-8. The
 111 logical character sequence itself is unchanged.  If I<$string> is already
 112 upgraded, then this is a no-op. Returns the
 113 number of octets necessary to represent the string as UTF-8.
 114
 115 If your code needs to be compatible with versions of perl without
 116 C<use feature 'unicode_strings';>, you can force Unicode semantics on
 117 a given string:
 118
 119   # force unicode semantics for $string without the
 120   # "unicode_strings" feature
 121   utf8::upgrade($string);
 122
 123 For example:
 124
 125   # without explicit or implicit use feature 'unicode_strings'
 126   my $x = "\xDF";    # LATIN SMALL LETTER SHARP S
 127   $x =~ /ss/i;       # won't match
 128   my $y = uc($x);    # won't convert
 129   utf8::upgrade($x);
 130   $x =~ /ss/i;       # matches
 131   my $z = uc($x);    # converts to "SS"
 132
 133 B<Note that this function does not handle arbitrary encodings>;
 134 use L<Encode> instead.
 135
 136 =item * C<$success = utf8::downgrade($string[, $fail_ok])>
 137
 138 (Since Perl v5.8.0)
 139 Converts in-place the internal representation of the string from
 140 UTF-8 to the equivalent octet sequence in the native encoding (Latin-1
 141 or EBCDIC). The logical character sequence itself is unchanged. If
 142 I<$string> is already stored as native 8 bit, then this is a no-op.  Can
 143 be used to
 144 make sure that the UTF-8 flag is off, e.g. when you want to make sure
 145 that the substr() or length() function works with the usually faster
 146 byte algorithm.
 147
 148 Fails if the original UTF-8 sequence cannot be represented in the
 149 native 8 bit encoding. On failure dies or, if the value of I<$fail_ok> is
 150 true, returns false.
 151
 152 Returns true on success.
 153
 154 If your code expects an octet sequence this can be used to validate
 155 that you've received one:
 156
 157   # throw an exception if not representable as octets
 158   utf8::downgrade($string)
 159
 160   # or do your own error handling
 161   utf8::downgrade($string, 1) or die "string must be octets";
 162
 163 B<Note that this function does not handle arbitrary encodings>;
 164 use L<Encode> instead.
 165
 166 =item * C<utf8::encode($string)>
 167
 168 (Since Perl v5.8.0)
 169 Converts in-place the character sequence to the corresponding octet
 170 sequence in UTF-8. That is, every (possibly wide) character gets
 171 replaced with a sequence of one or more characters that represent the
 172 individual UTF-8 bytes of the character.  The UTF8 flag is turned off.
 173 Returns nothing.
 174
 175  my $x = "\x{100}"; # $x contains one character, with ord 0x100
 176  utf8::encode($x);  # $x contains two characters, with ords (on
 177                     # ASCII platforms) 0xc4 and 0x80.  On EBCDIC
 178                     # 1047, this would instead be 0x8C and 0x41.
 179
 180 Similar to:
 181
 182   use Encode;
 183   $x = Encode::encode("utf8", $x);
 184
 185 B<Note that this function does not handle arbitrary encodings>;
 186 use L<Encode> instead.
 187
 188 =item * C<$success = utf8::decode($string)>
 189
 190 (Since Perl v5.8.0)
 191 Attempts to convert in-place the octet sequence encoded as UTF-8 to the
 192 corresponding character sequence. That is, it replaces each sequence of
 193 characters in the string whose ords represent a valid UTF-8 byte
 194 sequence, with the corresponding single character.  The UTF-8 flag is
 195 turned on only if the source string contains multiple-byte UTF-8
 196 characters.  If I<$string> is invalid as UTF-8, returns false;
 197 otherwise returns true.
 198
 199  my $x = "\xc4\x80"; # $x contains two characters, with ords
 200                      # 0xc4 and 0x80
 201  utf8::decode($x);   # On ASCII platforms, $x contains one char,
 202                      # with ord 0x100.   Since these bytes aren't
 203                      # legal UTF-EBCDIC, on EBCDIC platforms, $x is
 204                      # unchanged and the function returns FALSE.
 205
 206 B<Note that this function does not handle arbitrary encodings>;
 207 use L<Encode> instead.
 208
 209 =item * C<$unicode = utf8::native_to_unicode($code_point)>
 210
 211 (Since Perl v5.8.0)
 212 This takes an unsigned integer (which represents the ordinal number of a
 213 character (or a code point) on the platform the program is being run on) and
 214 returns its Unicode equivalent value.  Since ASCII platforms natively use the
 215 Unicode code points, this function returns its input on them.  On EBCDIC
 216 platforms it converts from EBCDIC to Unicode.
 217
 218 A meaningless value will currently be returned if the input is not an unsigned
 219 integer.
 220
 221 Since Perl v5.22.0, calls to this function are optimized out on ASCII
 222 platforms, so there is no performance hit in using it there.
 223
 224 =item * C<$native = utf8::unicode_to_native($code_point)>
 225
 226 (Since Perl v5.8.0)
 227 This is the inverse of C<utf8::native_to_unicode()>, converting the other
 228 direction.  Again, on ASCII platforms, this returns its input, but on EBCDIC
 229 platforms it will find the native platform code point, given any Unicode one.
 230
 231 A meaningless value will currently be returned if the input is not an unsigned
 232 integer.
 233
 234 Since Perl v5.22.0, calls to this function are optimized out on ASCII
 235 platforms, so there is no performance hit in using it there.
 236
 237 =item * C<$flag = utf8::is_utf8($string)>
 238
 239 (Since Perl 5.8.1)  Test whether I<$string> is marked internally as encoded in
 240 UTF-8.  Functionally the same as C<Encode::is_utf8($string)>.
 241
 242 Typically only necessary for debugging and testing, if you need to
 243 dump the internals of an SV, L<Devel::Peek's|Devel::Peek> Dump()
 244 provides more detail in a compact form.
 245
 246 If you still think you need this outside of debugging, testing or
 247 dealing with filenames, you should probably read L<perlunitut> and
 248 L<perlunifaq/What is "the UTF8 flag"?>.
 249
 250 Don't use this flag as a marker to distinguish character and binary
 251 data, that should be decided for each variable when you write your
 252 code.
 253
 254 To force unicode semantics in code portable to perl 5.8 and 5.10, call
 255 C<utf8::upgrade($string)> unconditionally.
 256
 257 =item * C<$flag = utf8::valid($string)>
 258
 259 [INTERNAL] Test whether I<$string> is in a consistent state regarding
 260 UTF-8.  Will return true if it is well-formed UTF-8 and has the UTF-8 flag
 261 on B<or> if I<$string> is held as bytes (both these states are 'consistent').
 262 Main reason for this routine is to allow Perl's test suite to check
 263 that operations have left strings in a consistent state.
 264
 265 =back
 266
 267 C<utf8::encode> is like C<utf8::upgrade>, but the UTF8 flag is
 268 cleared.  See L<perlunicode>, and the C API
 269 functions C<L<sv_utf8_upgrade|perlapi/sv_utf8_upgrade>>,
 270 C<L<perlapi/sv_utf8_downgrade>>, C<L<perlapi/sv_utf8_encode>>,
 271 and C<L<perlapi/sv_utf8_decode>>, which are wrapped by the Perl functions
 272 C<utf8::upgrade>, C<utf8::downgrade>, C<utf8::encode> and
 273 C<utf8::decode>.  Also, the functions C<utf8::is_utf8>, C<utf8::valid>,
 274 C<utf8::encode>, C<utf8::decode>, C<utf8::upgrade>, and C<utf8::downgrade> are
 275 actually internal, and thus always available, without a C<require utf8>
 276 statement.
 277
 278 =head1 BUGS
 279
 280 Some filesystems may not support UTF-8 file names, or they may be supported
 281 incompatibly with Perl.  Therefore UTF-8 names that are visible to the
 282 filesystem, such as module names may not work.
 283
 284 =head1 SEE ALSO
 285
 286 L<perlunitut>, L<perluniintro>, L<perlrun>, L<bytes>, L<perlunicode>
 287
 288 =cut