t/op/stash.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = qw(../lib);
   6 }
   7
   8 BEGIN { require "./test.pl"; }
   9
  10 plan( tests => 55 );
  11
  12 # Used to segfault (bug #15479)
  13 fresh_perl_like(
  14     '%:: = ""',
  15     qr/Odd number of elements in hash assignment at - line 1\./,
  16     { switches => [ '-w' ] },
  17     'delete $::{STDERR} and print a warning',
  18 );
  19
  20 # Used to segfault
  21 fresh_perl_is(
  22     'BEGIN { $::{"X::"} = 2 }',
  23     '',
  24     { switches => [ '-w' ] },
  25     q(Insert a non-GV in a stash, under warnings 'once'),
  26 );
  27
  28 {
  29     no warnings 'deprecated';
  30     ok( defined %oedipa::maas::, q(stashes happen to be defined if not used) );
  31     ok( defined %{"oedipa::maas::"}, q(- work with hard refs too) );
  32
  33     ok( defined %tyrone::slothrop::, q(stashes are defined if seen at compile time) );
  34     ok( defined %{"tyrone::slothrop::"}, q(- work with hard refs too) );
  35
  36     ok( defined %bongo::shaftsbury::, q(stashes are defined if a var is seen at compile time) );
  37     ok( defined %{"bongo::shaftsbury::"}, q(- work with hard refs too) );
  38 }
  39
  40 package tyrone::slothrop;
  41 $bongo::shaftsbury::scalar = 1;
  42
  43 package main;
  44
  45 # Used to warn
  46 # Unbalanced string table refcount: (1) for "A::" during global destruction.
  47 # for ithreads.
  48 {
  49     local $ENV{PERL_DESTRUCT_LEVEL} = 2;
  50     fresh_perl_is(
  51                   'package A; sub a { // }; %::=""',
  52                   '',
  53                   '',
  54                   );
  55 }
  56
  57 # now tests in eval
  58
  59 ok( eval  { no warnings 'deprecated'; defined %achtfaden:: },   'works in eval{}' );
  60 ok( eval q{ no warnings 'deprecated'; defined %schoenmaker:: }, 'works in eval("")' );
  61
  62 # now tests with strictures
  63
  64 {
  65     use strict;
  66     no warnings 'deprecated';
  67     ok( defined %pig::, q(referencing a non-existent stash doesn't produce stricture errors) );
  68     ok( !exists $pig::{bodine}, q(referencing a non-existent stash element doesn't produce stricture errors) );
  69 }
  70
  71 SKIP: {
  72     eval { require B; 1 } or skip "no B", 29;
  73
  74     *b = \&B::svref_2object;
  75     my $CVf_ANON = B::CVf_ANON();
  76
  77     my $sub = do {
  78         package one;
  79         \&{"one"};
  80     };
  81     delete $one::{one};
  82     my $gv = b($sub)->GV;
  83
  84     isa_ok( $gv, "B::GV", "deleted stash entry leaves CV with valid GV");
  85     is( b($sub)->CvFLAGS & $CVf_ANON, $CVf_ANON, "...and CVf_ANON set");
  86     is( eval { $gv->NAME }, "__ANON__", "...and an __ANON__ name");
  87     is( eval { $gv->STASH->NAME }, "one", "...but leaves stash intact");
  88
  89     $sub = do {
  90         package two;
  91         \&{"two"};
  92     };
  93     %two:: = ();
  94     $gv = b($sub)->GV;
  95
  96     isa_ok( $gv, "B::GV", "cleared stash leaves CV with valid GV");
  97     is( b($sub)->CvFLAGS & $CVf_ANON, $CVf_ANON, "...and CVf_ANON set");
  98     is( eval { $gv->NAME }, "__ANON__", "...and an __ANON__ name");
  99     is( eval { $gv->STASH->NAME }, "two", "...but leaves stash intact");
 100
 101     $sub = do {
 102         package three;
 103         \&{"three"};
 104     };
 105     undef %three::;
 106     $gv = b($sub)->GV;
 107
 108     isa_ok( $gv, "B::GV", "undefed stash leaves CV with valid GV");
 109     is( b($sub)->CvFLAGS & $CVf_ANON, $CVf_ANON, "...and CVf_ANON set");
 110     is( eval { $gv->NAME }, "__ANON__", "...and an __ANON__ name");
 111     is( eval { $gv->STASH->NAME }, "__ANON__", "...and an __ANON__ stash");
 112
 113     my $sub = do {
 114         package four;
 115         sub { 1 };
 116     };
 117     %four:: = ();
 118
 119     my $gv = B::svref_2object($sub)->GV;
 120     ok($gv->isa(q/B::GV/), "cleared stash leaves anon CV with valid GV");
 121
 122     my $st = eval { $gv->STASH->NAME };
 123     is($st, q/four/, "...but leaves the stash intact");
 124
 125     my $sub = do {
 126         package five;
 127         sub { 1 };
 128     };
 129     undef %five::;
 130
 131     $gv = B::svref_2object($sub)->GV;
 132     ok($gv->isa(q/B::GV/), "undefed stash leaves anon CV with valid GV");
 133
 134     $st = eval { $gv->STASH->NAME };
 135     { local $TODO = 'STASHES not anonymized';
 136         is($st, q/__ANON__/, "...and an __ANON__ stash");
 137     }
 138
 139     my $sub = do {
 140         package six;
 141         \&{"six"}
 142     };
 143     my $stash_glob = delete $::{"six::"};
 144     # Now free the GV while the stash still exists (though detached)
 145     delete $$stash_glob{"six"};
 146     $gv = B::svref_2object($sub)->GV;
 147     ok($gv->isa(q/B::GV/),
 148        'anonymised CV whose stash is detached still has a GV');
 149     is $gv->STASH->NAME, '__ANON__',
 150      'CV anonymised when its stash is detached becomes __ANON__::__ANON__';
 151
 152     # CvSTASH should be null on a named sub if the stash has been deleted
 153     {
 154         package FOO;
 155         sub foo {}
 156         my $rfoo = \&foo;
 157         package main;
 158         delete $::{'FOO::'};
 159         my $cv = B::svref_2object($rfoo);
 160         # (is there a better way of testing for NULL ?)
 161         my $stash = $cv->STASH;
 162         like($stash, qr/B::SPECIAL/, "NULL CvSTASH on named sub");
 163     }
 164
 165     # on glob reassignment, orphaned CV should have anon CvGV
 166
 167     {
 168         my $r;
 169         eval q[
 170             package FOO2;
 171             sub f{};
 172             $r = \&f;
 173             *f = sub {};
 174         ];
 175         delete $FOO2::{f};
 176         my $cv = B::svref_2object($r);
 177         my $gv = $cv->GV;
 178         ok($gv->isa(q/B::GV/), "orphaned CV has valid GV");
 179         is($gv->NAME, '__ANON__', "orphaned CV has anon GV");
 180     }
 181
 182     # deleting __ANON__ glob shouldn't break things
 183
 184     {
 185         package FOO3;
 186         sub named {};
 187         my $anon = sub {};
 188         my $named = eval q[\&named];
 189         package main;
 190         delete $FOO3::{named}; # make named anonymous
 191
 192         delete $FOO3::{__ANON__}; # whoops!
 193         my ($cv,$gv);
 194         $cv = B::svref_2object($named);
 195         $gv = $cv->GV;
 196         ok($gv->isa(q/B::GV/), "ex-named CV has valid GV");
 197         is($gv->NAME, '__ANON__', "ex-named CV has anon GV");
 198
 199         $cv = B::svref_2object($anon);
 200         $gv = $cv->GV;
 201         ok($gv->isa(q/B::GV/), "anon CV has valid GV");
 202         is($gv->NAME, '__ANON__', "anon CV has anon GV");
 203     }
 204
 205     {
 206         my $r;
 207         {
 208             package bloop;
 209
 210             BEGIN {
 211                 $r = \&main::whack;
 212             }
 213         }
 214
 215         my $br = B::svref_2object($r);
 216         is ($br->STASH->NAME, 'bloop',
 217             'stub records the package it was compiled in');
 218         # Arguably this shouldn't quite be here, but it's easy to add it
 219         # here, and tricky to figure out a different good place for it.
 220         like ($br->FILE, qr/stash/i,
 221               'stub records the file it was compiled in');
 222
 223         # We need to take this reference "late", after the subroutine is
 224         # defined.
 225         $br = B::svref_2object(eval 'sub whack {}; \&whack');
 226         die $@ if $@;
 227
 228         is ($br->STASH->NAME, 'main',
 229             'definition overrides the package it was compiled in');
 230         like ($br->FILE, qr/eval/,
 231               'definition overrides the file it was compiled in');
 232     }
 233 }
 234
 235 # [perl #58530]
 236 fresh_perl_is(
 237     'sub foo { 1 }; use overload q/""/ => \&foo;' .
 238         'delete $main::{foo}; bless []',
 239     "",
 240     {},
 241     "no segfault with overload/deleted stash entry [#58530]",
 242 );
 243
 244 # make sure having a sub called __ANON__ doesn't confuse perl.
 245
 246 {
 247     my $c;
 248     sub __ANON__ { $c = (caller(0))[3]; }
 249     __ANON__();
 250     is ($c, 'main::__ANON__', '__ANON__ sub called ok');
 251 }
 252
 253
 254 # Stashes that are effectively renamed
 255 {
 256     package rile;
 257
 258     use Config;
 259
 260     my $obj  = bless [];
 261     my $globref = \*tat;
 262
 263     # effectively rename a stash
 264     *slin:: = *rile::; *rile:: = *zor::;
 265
 266     ::is *$globref, "*rile::tat",
 267      'globs stringify the same way when stashes are moved';
 268     ::is ref $obj, "rile",
 269      'ref() returns the same thing when an object’s stash is moved';
 270     ::like "$obj", qr "^rile=ARRAY\(0x[\da-f]+\)\z",
 271      'objects stringify the same way when their stashes are moved';
 272     {
 273         local $::TODO =  $Config{useithreads} ? "fails under threads" : undef;
 274         ::is eval '__PACKAGE__', 'rile',
 275          '__PACKAGE__ returns the same when the current stash is moved';
 276     }
 277
 278     # Now detach it completely from the symtab, making it effect-
 279     # ively anonymous
 280     my $life_raft = \%slin::;
 281     *slin:: = *zor::;
 282
 283     ::is *$globref, "*rile::tat",
 284      'globs stringify the same way when stashes are detached';
 285     ::is ref $obj, "rile",
 286      'ref() returns the same thing when an object’s stash is detached';
 287     ::like "$obj", qr "^rile=ARRAY\(0x[\da-f]+\)\z",
 288      'objects stringify the same way when their stashes are detached';
 289     {
 290         local $::TODO =  $Config{useithreads} ? "fails under threads" : undef;
 291         ::is eval '__PACKAGE__', 'rile',
 292          '__PACKAGE__ returns the same when the current stash is detached';
 293     }
 294 }
 295
 296 # Setting the name during undef %stash:: should have no effect.
 297 {
 298     my $glob = \*Phoo::glob;
 299     sub o::DESTROY { eval '++$Phoo::bar' }
 300     no strict 'refs';
 301     ${"Phoo::thing1"} = bless [], "o";
 302     undef %Phoo::;
 303     is "$$glob", "*__ANON__::glob",
 304       "setting stash name during undef has no effect";
 305 }
 306
 307 # [perl #88134] incorrect package structure
 308 {
 309     package Bear::;
 310     sub baz{1}
 311     package main;
 312     ok eval { Bear::::baz() },
 313      'packages ending with :: are self-consistent';
 314 }
 315
 316 # [perl #88138] ' not equivalent to :: before a null
 317 ${"a'\0b"} = "c";
 318 is ${"a::\0b"}, "c", "' is equivalent to :: before a null";