This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perldelta for fd2709db56
[perl5.git] / pod / perlrecharclass.pod
1 =head1 NAME
2 X<character class>
3
4 perlrecharclass - Perl Regular Expression Character Classes
5
6 =head1 DESCRIPTION
7
8 The top level documentation about Perl regular expressions
9 is found in L<perlre>.
10
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
13
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
19
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets.  Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
24
25 =head2 The dot
26
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. That default can be changed to
30 add matching the newline by using the I<single line> modifier: either
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>.  (The C<L</\N>> backslash sequence, described
33 below, matches any character except newline without regard to the
34 I<single line> modifier.)
35
36 Here are some examples:
37
38  "a"  =~  /./       # Match
39  "."  =~  /./       # Match
40  ""   =~  /./       # No match (dot has to match a character)
41  "\n" =~  /./       # No match (dot does not match a newline)
42  "\n" =~  /./s      # Match (global 'single line' modifier)
43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
44  "ab" =~  /^.$/     # No match (dot matches one character)
45
46 =head2 Backslash sequences
47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
48 X<\N> X<\v> X<\V> X<\h> X<\H>
49 X<word> X<whitespace>
50
51 A backslash sequence is a sequence of characters, the first one of which is a
52 backslash.  Perl ascribes special meaning to many such sequences, and some of
53 these are character classes.  That is, they match a single character each,
54 provided that the character belongs to the specific set of characters defined
55 by the sequence.
56
57 Here's a list of the backslash sequences that are character classes.  They
58 are discussed in more detail below.  (For the backslash sequences that aren't
59 character classes, see L<perlrebackslash>.)
60
61  \d             Match a decimal digit character.
62  \D             Match a non-decimal-digit character.
63  \w             Match a "word" character.
64  \W             Match a non-"word" character.
65  \s             Match a whitespace character.
66  \S             Match a non-whitespace character.
67  \h             Match a horizontal whitespace character.
68  \H             Match a character that isn't horizontal whitespace.
69  \v             Match a vertical whitespace character.
70  \V             Match a character that isn't vertical whitespace.
71  \N             Match a character that isn't a newline.
72  \pP, \p{Prop}  Match a character that has the given Unicode property.
73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
74
75 =head3 \N
76
77 C<\N>, available starting in v5.12, like the dot, matches any
78 character that is not a newline. The difference is that C<\N> is not influenced
79 by the I<single line> regular expression modifier (see L</The dot> above).  Note
80 that the form C<\N{...}> may mean something completely different.  When the
81 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
82 character that many times.  For example, C<\N{3}> means to match 3
83 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
84 is not a legal quantifier, it is presumed to be a named character.  See
85 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
86 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
87 names are respectively C<COLON>, C<4F>, and C<F4>.
88
89 =head3 Digits
90
91 C<\d> matches a single character considered to be a decimal I<digit>.
92 If the C</a> regular expression modifier is in effect, it matches [0-9].
93 Otherwise, it
94 matches anything that is matched by C<\p{Digit}>, which includes [0-9].
95 (An unlikely possible exception is that under locale matching rules, the
96 current locale might not have C<[0-9]> matched by C<\d>, and/or might match
97 other characters whose code point is less than 256.  The only such locale
98 definitions that are legal would be to match C<[0-9]> plus another set of
99 10 consecutive digit characters;  anything else would be in violation of
100 the C language standard, but Perl doesn't currently assume anything in
101 regard to this.)
102
103 What this means is that unless the C</a> modifier is in effect C<\d> not
104 only matches the digits '0' - '9', but also Arabic, Devanagari, and
105 digits from other languages.  This may cause some confusion, and some
106 security issues.
107
108 Some digits that C<\d> matches look like some of the [0-9] ones, but
109 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
110 very much like an ASCII DIGIT EIGHT (U+0038).  An application that
111 is expecting only the ASCII digits might be misled, or if the match is
112 C<\d+>, the matched string might contain a mixture of digits from
113 different writing systems that look like they signify a number different
114 than they actually do.  L<Unicode::UCD/num()> can
115 be used to safely
116 calculate the value, returning C<undef> if the input string contains
117 such a mixture.
118
119 What C<\p{Digit}> means (and hence C<\d> except under the C</a>
120 modifier) is C<\p{General_Category=Decimal_Number}>, or synonymously,
121 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this
122 is the same set of characters matched by C<\p{Numeric_Type=Decimal}>.
123 But Unicode also has a different property with a similar name,
124 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
125 characters.  These characters are things such as C<CIRCLED DIGIT ONE>
126 or subscripts, or are from writing systems that lack all ten digits.
127
128 The design intent is for C<\d> to exactly match the set of characters
129 that can safely be used with "normal" big-endian positional decimal
130 syntax, where, for example 123 means one 'hundred', plus two 'tens',
131 plus three 'ones'.  This positional notation does not necessarily apply
132 to characters that match the other type of "digit",
133 C<\p{Numeric_Type=Digit}>, and so C<\d> doesn't match them.
134
135 The Tamil digits (U+0BE6 - U+0BEF) can also legally be
136 used in old-style Tamil numbers in which they would appear no more than
137 one in a row, separated by characters that mean "times 10", "times 100",
138 etc.  (See L<http://www.unicode.org/notes/tn21>.)
139
140 Any character not matched by C<\d> is matched by C<\D>.
141
142 =head3 Word characters
143
144 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
145 decimal digit); or a connecting punctuation character, such as an
146 underscore ("_"); or a "mark" character (like some sort of accent) that
147 attaches to one of those.  It does not match a whole word.  To match a
148 whole word, use C<\w+>.  This isn't the same thing as matching an
149 English word, but in the ASCII range it is the same as a string of
150 Perl-identifier characters.
151
152 =over
153
154 =item If the C</a> modifier is in effect ...
155
156 C<\w> matches the 63 characters [a-zA-Z0-9_].
157
158 =item otherwise ...
159
160 =over
161
162 =item For code points above 255 ...
163
164 C<\w> matches the same as C<\p{Word}> matches in this range.  That is,
165 it matches Thai letters, Greek letters, etc.  This includes connector
166 punctuation (like the underscore) which connect two words together, or
167 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
168 are generally used to add auxiliary markings to letters.
169
170 =item For code points below 256 ...
171
172 =over
173
174 =item if locale rules are in effect ...
175
176 C<\w> matches the platform's native underscore character plus whatever
177 the locale considers to be alphanumeric.
178
179 =item if Unicode rules are in effect ...
180
181 C<\w> matches exactly what C<\p{Word}> matches.
182
183 =item otherwise ...
184
185 C<\w> matches [a-zA-Z0-9_].
186
187 =back
188
189 =back
190
191 =back
192
193 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
194
195 There are a number of security issues with the full Unicode list of word
196 characters.  See L<http://unicode.org/reports/tr36>.
197
198 Also, for a somewhat finer-grained set of characters that are in programming
199 language identifiers beyond the ASCII range, you may wish to instead use the
200 more customized L</Unicode Properties>, C<\p{ID_Start}>,
201 C<\p{ID_Continue}>, C<\p{XID_Start}>, and C<\p{XID_Continue}>.  See
202 L<http://unicode.org/reports/tr31>.
203
204 Any character not matched by C<\w> is matched by C<\W>.
205
206 =head3 Whitespace
207
208 C<\s> matches any single character considered whitespace.
209
210 =over
211
212 =item If the C</a> modifier is in effect ...
213
214 In all Perl versions, C<\s> matches the 5 characters [\t\n\f\r ]; that
215 is, the horizontal tab,
216 the newline, the form feed, the carriage return, and the space.
217 Starting in Perl v5.18, experimentally, it also matches the vertical tab, C<\cK>.
218 See note C<[1]> below for a discussion of this.
219
220 =item otherwise ...
221
222 =over
223
224 =item For code points above 255 ...
225
226 C<\s> matches exactly the code points above 255 shown with an "s" column
227 in the table below.
228
229 =item For code points below 256 ...
230
231 =over
232
233 =item if locale rules are in effect ...
234
235 C<\s> matches whatever the locale considers to be whitespace.
236
237 =item if Unicode rules are in effect ...
238
239 C<\s> matches exactly the characters shown with an "s" column in the
240 table below.
241
242 =item otherwise ...
243
244 C<\s> matches [\t\n\f\r ] and, starting, experimentally in Perl
245 v5.18, the vertical tab, C<\cK>.
246 (See note C<[1]> below for a discussion of this.)
247 Note that this list doesn't include the non-breaking space.
248
249 =back
250
251 =back
252
253 =back
254
255 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
256
257 Any character not matched by C<\s> is matched by C<\S>.
258
259 C<\h> matches any character considered horizontal whitespace;
260 this includes the platform's space and tab characters and several others
261 listed in the table below.  C<\H> matches any character
262 not considered horizontal whitespace.  They use the platform's native
263 character set, and do not consider any locale that may otherwise be in
264 use.
265
266 C<\v> matches any character considered vertical whitespace;
267 this includes the platform's carriage return and line feed characters (newline)
268 plus several other characters, all listed in the table below.
269 C<\V> matches any character not considered vertical whitespace.
270 They use the platform's native character set, and do not consider any
271 locale that may otherwise be in use.
272
273 C<\R> matches anything that can be considered a newline under Unicode
274 rules. It's not a character class, as it can match a multi-character
275 sequence. Therefore, it cannot be used inside a bracketed character
276 class; use C<\v> instead (vertical whitespace).  It uses the platform's
277 native character set, and does not consider any locale that may
278 otherwise be in use.
279 Details are discussed in L<perlrebackslash>.
280
281 Note that unlike C<\s> (and C<\d> and C<\w>), C<\h> and C<\v> always match
282 the same characters, without regard to other factors, such as the active
283 locale or whether the source string is in UTF-8 format.
284
285 One might think that C<\s> is equivalent to C<[\h\v]>. This is indeed true
286 starting in Perl v5.18, but prior to that, the sole difference was that the
287 vertical tab (C<"\cK">) was not matched by C<\s>.
288
289 The following table is a complete listing of characters matched by
290 C<\s>, C<\h> and C<\v> as of Unicode 6.3.
291
292 The first column gives the Unicode code point of the character (in hex format),
293 the second column gives the (Unicode) name. The third column indicates
294 by which class(es) the character is matched (assuming no locale is in
295 effect that changes the C<\s> matching).
296
297  0x0009        CHARACTER TABULATION   h s
298  0x000a              LINE FEED (LF)    vs
299  0x000b             LINE TABULATION    vs  [1]
300  0x000c              FORM FEED (FF)    vs
301  0x000d        CARRIAGE RETURN (CR)    vs
302  0x0020                       SPACE   h s
303  0x0085             NEXT LINE (NEL)    vs  [2]
304  0x00a0              NO-BREAK SPACE   h s  [2]
305  0x1680            OGHAM SPACE MARK   h s
306  0x2000                     EN QUAD   h s
307  0x2001                     EM QUAD   h s
308  0x2002                    EN SPACE   h s
309  0x2003                    EM SPACE   h s
310  0x2004          THREE-PER-EM SPACE   h s
311  0x2005           FOUR-PER-EM SPACE   h s
312  0x2006            SIX-PER-EM SPACE   h s
313  0x2007                FIGURE SPACE   h s
314  0x2008           PUNCTUATION SPACE   h s
315  0x2009                  THIN SPACE   h s
316  0x200a                  HAIR SPACE   h s
317  0x2028              LINE SEPARATOR    vs
318  0x2029         PARAGRAPH SEPARATOR    vs
319  0x202f       NARROW NO-BREAK SPACE   h s
320  0x205f   MEDIUM MATHEMATICAL SPACE   h s
321  0x3000           IDEOGRAPHIC SPACE   h s
322
323 =over 4
324
325 =item [1]
326
327 Prior to Perl v5.18, C<\s> did not match the vertical tab.  The change
328 in v5.18 is considered an experiment, which means it could be backed out
329 in v5.22 if experience indicates that it breaks too much
330 existing code.  If this change adversely affects you, send email to
331 C<perlbug@perl.org>; if it affects you positively, email
332 C<perlthanks@perl.org>.  In the meantime, C<[^\S\cK]> (obscurely)
333 matches what C<\s> traditionally did.
334
335 =item [2]
336
337 NEXT LINE and NO-BREAK SPACE may or may not match C<\s> depending
338 on the rules in effect.  See
339 L<the beginning of this section|/Whitespace>.
340
341 =back
342
343 =head3 Unicode Properties
344
345 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
346 Unicode properties.  One letter property names can be used in the C<\pP> form,
347 with the property name following the C<\p>, otherwise, braces are required.
348 When using braces, there is a single form, which is just the property name
349 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
350 which means to match if the property "name" for the character has that particular
351 "value".
352 For instance, a match for a number can be written as C</\pN/> or as
353 C</\p{Number}/>, or as C</\p{Number=True}/>.
354 Lowercase letters are matched by the property I<Lowercase_Letter> which
355 has the short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
356 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
357 (the underscores are optional).
358 C</\pLl/> is valid, but means something different.
359 It matches a two character string: a letter (Unicode property C<\pL>),
360 followed by a lowercase C<l>.
361
362 If locale rules are not in effect, the use of
363 a Unicode property will force the regular expression into using Unicode
364 rules, if it isn't already.
365
366 Note that almost all properties are immune to case-insensitive matching.
367 That is, adding a C</i> regular expression modifier does not change what
368 they match.  There are two sets that are affected.  The first set is
369 C<Uppercase_Letter>,
370 C<Lowercase_Letter>,
371 and C<Titlecase_Letter>,
372 all of which match C<Cased_Letter> under C</i> matching.
373 The second set is
374 C<Uppercase>,
375 C<Lowercase>,
376 and C<Titlecase>,
377 all of which match C<Cased> under C</i> matching.
378 (The difference between these sets is that some things, such as Roman
379 numerals, come in both upper and lower case, so they are C<Cased>, but
380 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
381 actually C<Letter_Number>s.)
382 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
383 of which under C</i> match C<PosixAlpha>.
384
385 For more details on Unicode properties, see L<perlunicode/Unicode
386 Character Properties>; for a
387 complete list of possible properties, see
388 L<perluniprops/Properties accessible through \p{} and \P{}>,
389 which notes all forms that have C</i> differences.
390 It is also possible to define your own properties. This is discussed in
391 L<perlunicode/User-Defined Character Properties>.
392
393 Unicode properties are defined (surprise!) only on Unicode code points.
394 Starting in v5.20, when matching against C<\p> and C<\P>, Perl treats
395 non-Unicode code points (those above the legal Unicode maximum of
396 0x10FFFF) as if they were typical unassigned Unicode code points.
397
398 Prior to v5.20, Perl raised a warning and made all matches fail on
399 non-Unicode code points.  This could be somewhat surprising:
400
401  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}     # Fails on Perls < v5.20.
402  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}    # Also fails on Perls
403                                                # < v5.20
404
405 Even though these two matches might be thought of as complements, until
406 v5.20 they were so only on Unicode code points.
407
408 =head4 Examples
409
410  "a"  =~  /\w/      # Match, "a" is a 'word' character.
411  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
412  "a"  =~  /\d/      # No match, "a" isn't a digit.
413  "7"  =~  /\d/      # Match, "7" is a digit.
414  " "  =~  /\s/      # Match, a space is whitespace.
415  "a"  =~  /\D/      # Match, "a" is a non-digit.
416  "7"  =~  /\D/      # No match, "7" is not a non-digit.
417  " "  =~  /\S/      # No match, a space is not non-whitespace.
418
419  " "  =~  /\h/      # Match, space is horizontal whitespace.
420  " "  =~  /\v/      # No match, space is not vertical whitespace.
421  "\r" =~  /\v/      # Match, a return is vertical whitespace.
422
423  "a"  =~  /\pL/     # Match, "a" is a letter.
424  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
425
426  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
427                            # 'THAI CHARACTER SO SO', and that's in
428                            # Thai Unicode class.
429  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
430
431 It is worth emphasizing that C<\d>, C<\w>, etc, match single characters, not
432 complete numbers or words. To match a number (that consists of digits),
433 use C<\d+>; to match a word, use C<\w+>.  But be aware of the security
434 considerations in doing so, as mentioned above.
435
436 =head2 Bracketed Character Classes
437
438 The third form of character class you can use in Perl regular expressions
439 is the bracketed character class.  In its simplest form, it lists the characters
440 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
441 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
442 character classes, exactly one character is matched.* To match
443 a longer string consisting of characters mentioned in the character
444 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
445 instance, C<[aeiou]+> matches one or more lowercase English vowels.
446
447 Repeating a character in a character class has no
448 effect; it's considered to be in the set only once.
449
450 Examples:
451
452  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
453  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
454  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
455                            # a single character.
456  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
457
458  -------
459
460 * There are two exceptions to a bracketed character class matching a
461 single character only.  Each requires special handling by Perl to make
462 things work:
463
464 =over
465
466 =item *
467
468 When the class is to match caselessly under C</i> matching rules, and a
469 character that is explicitly mentioned inside the class matches a
470 multiple-character sequence caselessly under Unicode rules, the class
471 will also match that sequence.  For example, Unicode says that the
472 letter C<LATIN SMALL LETTER SHARP S> should match the sequence C<ss>
473 under C</i> rules.  Thus,
474
475  'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i             # Matches
476  'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i    # Matches
477
478 For this to happen, the class must not be inverted (see L</Negation>)
479 and the character must be explicitly specified, and not be part of a
480 multi-character range (not even as one of its endpoints).  (L</Character
481 Ranges> will be explained shortly.) Therefore,
482
483  'ss' =~ /\A[\0-\x{ff}]\z/ui       # Doesn't match
484  'ss' =~ /\A[\0-\N{LATIN SMALL LETTER SHARP S}]\z/ui   # No match
485  'ss' =~ /\A[\xDF-\xDF]\z/ui   # Matches on ASCII platforms, since
486                                # \XDF is LATIN SMALL LETTER SHARP S,
487                                # and the range is just a single
488                                # element
489
490 Note that it isn't a good idea to specify these types of ranges anyway.
491
492 =item *
493
494 Some names known to C<\N{...}> refer to a sequence of multiple characters,
495 instead of the usual single character.  When one of these is included in
496 the class, the entire sequence is matched.  For example,
497
498   "\N{TAMIL LETTER KA}\N{TAMIL VOWEL SIGN AU}"
499                               =~ / ^ [\N{TAMIL SYLLABLE KAU}]  $ /x;
500
501 matches, because C<\N{TAMIL SYLLABLE KAU}> is a named sequence
502 consisting of the two characters matched against.  Like the other
503 instance where a bracketed class can match multiple characters, and for
504 similar reasons, the class must not be inverted, and the named sequence
505 may not appear in a range, even one where it is both endpoints.  If
506 these happen, it is a fatal error if the character class is within an
507 extended L<C<(?[...])>|/Extended Bracketed Character Classes>
508 class; and only the first code point is used (with
509 a C<regexp>-type warning raised) otherwise.
510
511 =back
512
513 =head3 Special Characters Inside a Bracketed Character Class
514
515 Most characters that are meta characters in regular expressions (that
516 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
517 their special meaning and can be used inside a character class without
518 the need to escape them. For instance, C<[()]> matches either an opening
519 parenthesis, or a closing parenthesis, and the parens inside the character
520 class don't group or capture.
521
522 Characters that may carry a special meaning inside a character class are:
523 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
524 escaped with a backslash, although this is sometimes not needed, in which
525 case the backslash may be omitted.
526
527 The sequence C<\b> is special inside a bracketed character class. While
528 outside the character class, C<\b> is an assertion indicating a point
529 that does not have either two word characters or two non-word characters
530 on either side, inside a bracketed character class, C<\b> matches a
531 backspace character.
532
533 The sequences
534 C<\a>,
535 C<\c>,
536 C<\e>,
537 C<\f>,
538 C<\n>,
539 C<\N{I<NAME>}>,
540 C<\N{U+I<hex char>}>,
541 C<\r>,
542 C<\t>,
543 and
544 C<\x>
545 are also special and have the same meanings as they do outside a
546 bracketed character class.
547
548 Also, a backslash followed by two or three octal digits is considered an octal
549 number.
550
551 A C<[> is not special inside a character class, unless it's the start of a
552 POSIX character class (see L</POSIX Character Classes> below). It normally does
553 not need escaping.
554
555 A C<]> is normally either the end of a POSIX character class (see
556 L</POSIX Character Classes> below), or it signals the end of the bracketed
557 character class.  If you want to include a C<]> in the set of characters, you
558 must generally escape it.
559
560 However, if the C<]> is the I<first> (or the second if the first
561 character is a caret) character of a bracketed character class, it
562 does not denote the end of the class (as you cannot have an empty class)
563 and is considered part of the set of characters that can be matched without
564 escaping.
565
566 Examples:
567
568  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
569  "\cH" =~ /[\b]/      #  Match, \b inside in a character class.
570                       #  is equivalent to a backspace.
571  "]"   =~ /[][]/      #  Match, as the character class contains.
572                       #  both [ and ].
573  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
574                       #  containing just ], and the character class is
575                       #  followed by a ].
576
577 =head3 Character Ranges
578
579 It is not uncommon to want to match a range of characters. Luckily, instead
580 of listing all characters in the range, one may use the hyphen (C<->).
581 If inside a bracketed character class you have two characters separated
582 by a hyphen, it's treated as if all characters between the two were in
583 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
584 matches any lowercase letter from the first half of the ASCII alphabet.
585
586 Note that the two characters on either side of the hyphen are not
587 necessarily both letters or both digits. Any character is possible,
588 although not advisable.  C<['-?]> contains a range of characters, but
589 most people will not know which characters that means.  Furthermore,
590 such ranges may lead to portability problems if the code has to run on
591 a platform that uses a different character set, such as EBCDIC.
592
593 If a hyphen in a character class cannot syntactically be part of a range, for
594 instance because it is the first or the last character of the character class,
595 or if it immediately follows a range, the hyphen isn't special, and so is
596 considered a character to be matched literally.  If you want a hyphen in
597 your set of characters to be matched and its position in the class is such
598 that it could be considered part of a range, you must escape that hyphen
599 with a backslash.
600
601 Examples:
602
603  [a-z]       #  Matches a character that is a lower case ASCII letter.
604  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
605              #  the letter 'z'.
606  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
607  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
608              #  hyphen ('-'), or the letter 'm'.
609  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
610              #  (But not on an EBCDIC platform).
611
612 Perl guarantees that the ranges C<A-Z>, C<a-z>, C<0-9>, and any
613 subranges of these match what an English-only speaker would expect them
614 to match.  That is, C<[A-Z]> matches the 26 ASCII uppercase letters;
615 C<[a-z]> matches the 26 lowercase letters; and C<[0-9]> matches the 10
616 digits.  Subranges, like C<[h-k]>, match correspondingly, in this case
617 just the four letters C<"h">, C<"i">, C<"j">, and C<"k">.  This is the
618 natural behavior on ASCII platforms where the code points (ordinal
619 values) for C<"h"> through C<"k"> are consecutive integers (0x68 through
620 0x6B).  But special handling to achieve this may be needed on platforms
621 with a non-ASCII native character set.  For example, on EBCDIC
622 platforms, the code point for C<"h"> is 0x88, C<"i"> is 0x89, C<"j"> is
623 0x91, and C<"k"> is 0x92.   Perl specially treats C<[h-k]> to exclude the
624 seven code points in the gap: 0x8A through 0x90.  This special handling is
625 only invoked when the range is a subrange of one of the ASCII uppercase,
626 lowercase, and digit ranges, AND each end of the range is expressed
627 either as a literal, like C<"A">, or as a named character (C<\N{...}>,
628 including the C<\N{U+...> form).
629
630 EBCDIC Examples:
631
632  [i-j]               #  Matches either "i" or "j"
633  [i-\N{LATIN SMALL LETTER J}]  # Same
634  [i-\N{U+6A}]        #  Same
635  [\N{U+69}-\N{U+6A}] #  Same
636  [\x{89}-\x{91}]     #  Matches 0x89 ("i"), 0x8A .. 0x90, 0x91 ("j")
637  [i-\x{91}]          #  Same
638  [\x{89}-j]          #  Same
639  [i-J]               #  Matches, 0x89 ("i") .. 0xC1 ("J"); special
640                      #  handling doesn't apply because range is mixed
641                      #  case
642
643 =head3 Negation
644
645 It is also possible to instead list the characters you do not want to
646 match. You can do so by using a caret (C<^>) as the first character in the
647 character class. For instance, C<[^a-z]> matches any character that is not a
648 lowercase ASCII letter, which therefore includes more than a million
649 Unicode code points.  The class is said to be "negated" or "inverted".
650
651 This syntax make the caret a special character inside a bracketed character
652 class, but only if it is the first character of the class. So if you want
653 the caret as one of the characters to match, either escape the caret or
654 else don't list it first.
655
656 In inverted bracketed character classes, Perl ignores the Unicode rules
657 that normally say that named sequence, and certain characters should
658 match a sequence of multiple characters use under caseless C</i>
659 matching.  Following those rules could lead to highly confusing
660 situations:
661
662  "ss" =~ /^[^\xDF]+$/ui;   # Matches!
663
664 This should match any sequences of characters that aren't C<\xDF> nor
665 what C<\xDF> matches under C</i>.  C<"s"> isn't C<\xDF>, but Unicode
666 says that C<"ss"> is what C<\xDF> matches under C</i>.  So which one
667 "wins"? Do you fail the match because the string has C<ss> or accept it
668 because it has an C<s> followed by another C<s>?  Perl has chosen the
669 latter.  (See note in L</Bracketed Character Classes> above.)
670
671 Examples:
672
673  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
674  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
675  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
676  "^"  =~  /[x^]/       #  Match, caret is not special here.
677
678 =head3 Backslash Sequences
679
680 You can put any backslash sequence character class (with the exception of
681 C<\N> and C<\R>) inside a bracketed character class, and it will act just
682 as if you had put all characters matched by the backslash sequence inside the
683 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
684 of the lowercase letters between 'a' and 'f' inclusive.
685
686 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
687 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
688 for the same reason that a dot C<.> inside a bracketed character class loses
689 its special meaning: it matches nearly anything, which generally isn't what you
690 want to happen.
691
692
693 Examples:
694
695  /[\p{Thai}\d]/     # Matches a character that is either a Thai
696                     # character, or a digit.
697  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
698                     # character, nor a parenthesis.
699
700 Backslash sequence character classes cannot form one of the endpoints
701 of a range.  Thus, you can't say:
702
703  /[\p{Thai}-\d]/     # Wrong!
704
705 =head3 POSIX Character Classes
706 X<character class> X<\p> X<\p{}>
707 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
708 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
709
710 POSIX character classes have the form C<[:class:]>, where I<class> is the
711 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
712 I<inside> bracketed character classes, and are a convenient and descriptive
713 way of listing a group of characters.
714
715 Be careful about the syntax,
716
717  # Correct:
718  $string =~ /[[:alpha:]]/
719
720  # Incorrect (will warn):
721  $string =~ /[:alpha:]/
722
723 The latter pattern would be a character class consisting of a colon,
724 and the letters C<a>, C<l>, C<p> and C<h>.
725
726 POSIX character classes can be part of a larger bracketed character class.
727 For example,
728
729  [01[:alpha:]%]
730
731 is valid and matches '0', '1', any alphabetic character, and the percent sign.
732
733 Perl recognizes the following POSIX character classes:
734
735  alpha  Any alphabetical character ("[A-Za-z]").
736  alnum  Any alphanumeric character ("[A-Za-z0-9]").
737  ascii  Any character in the ASCII character set.
738  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
739  cntrl  Any control character.  See Note [2] below.
740  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
741  graph  Any printable character, excluding a space.  See Note [3] below.
742  lower  Any lowercase character ("[a-z]").
743  print  Any printable character, including a space.  See Note [4] below.
744  punct  Any graphical character excluding "word" characters.  Note [5].
745  space  Any whitespace character. "\s" including the vertical tab
746         ("\cK").
747  upper  Any uppercase character ("[A-Z]").
748  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
749  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
750
751 Most POSIX character classes have two Unicode-style C<\p> property
752 counterparts.  (They are not official Unicode properties, but Perl extensions
753 derived from official Unicode properties.)  The table below shows the relation
754 between POSIX character classes and these counterparts.
755
756 One counterpart, in the column labelled "ASCII-range Unicode" in
757 the table, matches only characters in the ASCII character set.
758
759 The other counterpart, in the column labelled "Full-range Unicode", matches any
760 appropriate characters in the full Unicode character set.  For example,
761 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
762 character in the entire Unicode character set considered alphabetic.
763 An entry in the column labelled "backslash sequence" is a (short)
764 equivalent.
765
766  [[:...:]]      ASCII-range          Full-range  backslash  Note
767                  Unicode              Unicode     sequence
768  -----------------------------------------------------
769    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
770    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
771    ascii      \p{ASCII}
772    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
773                                    or \p{HorizSpace}        [1]
774    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
775    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
776    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
777    lower      \p{PosixLower}       \p{XPosixLower}
778    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
779    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
780               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
781    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
782    upper      \p{PosixUpper}       \p{XPosixUpper}
783    word       \p{PosixWord}        \p{XPosixWord}   \w
784    xdigit     \p{PosixXDigit}      \p{XPosixXDigit}
785
786 =over 4
787
788 =item [1]
789
790 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
791
792 =item [2]
793
794 Control characters don't produce output as such, but instead usually control
795 the terminal somehow: for example, newline and backspace are control characters.
796 In the ASCII range, characters whose code points are between 0 and 31 inclusive,
797 plus 127 (C<DEL>) are control characters.
798
799 =item [3]
800
801 Any character that is I<graphical>, that is, visible. This class consists
802 of all alphanumeric characters and all punctuation characters.
803
804 =item [4]
805
806 All printable characters, which is the set of all graphical characters
807 plus those whitespace characters which are not also controls.
808
809 =item [5]
810
811 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
812 non-controls, non-alphanumeric, non-space characters:
813 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
814 it could alter the behavior of C<[[:punct:]]>).
815
816 The similarly named property, C<\p{Punct}>, matches a somewhat different
817 set in the ASCII range, namely
818 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing the nine
819 characters C<[$+E<lt>=E<gt>^`|~]>.
820 This is because Unicode splits what POSIX considers to be punctuation into two
821 categories, Punctuation and Symbols.
822
823 C<\p{XPosixPunct}> and (under Unicode rules) C<[[:punct:]]>, match what
824 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
825 matches.  This is different than strictly matching according to
826 C<\p{Punct}>.  Another way to say it is that
827 if Unicode rules are in effect, C<[[:punct:]]> matches all characters
828 that Unicode considers punctuation, plus all ASCII-range characters that
829 Unicode considers symbols.
830
831 =item [6]
832
833 C<\p{XPerlSpace}> and C<\p{Space}> match identically starting with Perl
834 v5.18.  In earlier versions, these differ only in that in non-locale
835 matching, C<\p{XPerlSpace}> does not match the vertical tab, C<\cK>.
836 Same for the two ASCII-only range forms.
837
838 =back
839
840 There are various other synonyms that can be used besides the names
841 listed in the table.  For example, C<\p{PosixAlpha}> can be written as
842 C<\p{Alpha}>.  All are listed in
843 L<perluniprops/Properties accessible through \p{} and \P{}>.
844
845 Both the C<\p> counterparts always assume Unicode rules are in effect.
846 On ASCII platforms, this means they assume that the code points from 128
847 to 255 are Latin-1, and that means that using them under locale rules is
848 unwise unless the locale is guaranteed to be Latin-1 or UTF-8.  In contrast, the
849 POSIX character classes are useful under locale rules.  They are
850 affected by the actual rules in effect, as follows:
851
852 =over
853
854 =item If the C</a> modifier, is in effect ...
855
856 Each of the POSIX classes matches exactly the same as their ASCII-range
857 counterparts.
858
859 =item otherwise ...
860
861 =over
862
863 =item For code points above 255 ...
864
865 The POSIX class matches the same as its Full-range counterpart.
866
867 =item For code points below 256 ...
868
869 =over
870
871 =item if locale rules are in effect ...
872
873 The POSIX class matches according to the locale, except:
874
875 =over
876
877 =item C<word>
878
879 also includes the platform's native underscore character, no matter what
880 the locale is.
881
882 =item C<ascii>
883
884 on platforms that don't have the POSIX C<ascii> extension, this matches
885 just the platform's native ASCII-range characters.
886
887 =item C<blank>
888
889 on platforms that don't have the POSIX C<blank> extension, this matches
890 just the platform's native tab and space characters.
891
892 =back
893
894 =item if Unicode rules are in effect ...
895
896 The POSIX class matches the same as the Full-range counterpart.
897
898 =item otherwise ...
899
900 The POSIX class matches the same as the ASCII range counterpart.
901
902 =back
903
904 =back
905
906 =back
907
908 Which rules apply are determined as described in
909 L<perlre/Which character set modifier is in effect?>.
910
911 It is proposed to change this behavior in a future release of Perl so that
912 whether or not Unicode rules are in effect would not change the
913 behavior:  Outside of locale, the POSIX classes
914 would behave like their ASCII-range counterparts.  If you wish to
915 comment on this proposal, send email to C<perl5-porters@perl.org>.
916
917 =head4 Negation of POSIX character classes
918 X<character class, negation>
919
920 A Perl extension to the POSIX character class is the ability to
921 negate it. This is done by prefixing the class name with a caret (C<^>).
922 Some examples:
923
924      POSIX         ASCII-range     Full-range  backslash
925                     Unicode         Unicode    sequence
926  -----------------------------------------------------
927  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
928  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
929                 \P{PerlSpace}   \P{XPerlSpace}    \S
930  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
931
932 The backslash sequence can mean either ASCII- or Full-range Unicode,
933 depending on various factors as described in L<perlre/Which character set modifier is in effect?>.
934
935 =head4 [= =] and [. .]
936
937 Perl recognizes the POSIX character classes C<[=class=]> and
938 C<[.class.]>, but does not (yet?) support them.  Any attempt to use
939 either construct raises an exception.
940
941 =head4 Examples
942
943  /[[:digit:]]/            # Matches a character that is a digit.
944  /[01[:lower:]]/          # Matches a character that is either a
945                           # lowercase letter, or '0' or '1'.
946  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
947                           # except the letters 'a' to 'f' and 'A' to
948                           # 'F'.  This is because the main character
949                           # class is composed of two POSIX character
950                           # classes that are ORed together, one that
951                           # matches any digit, and the other that
952                           # matches anything that isn't a hex digit.
953                           # The OR adds the digits, leaving only the
954                           # letters 'a' to 'f' and 'A' to 'F' excluded.
955
956 =head3 Extended Bracketed Character Classes
957 X<character class>
958 X<set operations>
959
960 This is a fancy bracketed character class that can be used for more
961 readable and less error-prone classes, and to perform set operations,
962 such as intersection. An example is
963
964  /(?[ \p{Thai} & \p{Digit} ])/
965
966 This will match all the digit characters that are in the Thai script.
967
968 This is an experimental feature available starting in 5.18, and is
969 subject to change as we gain field experience with it.  Any attempt to
970 use it will raise a warning, unless disabled via
971
972  no warnings "experimental::regex_sets";
973
974 Comments on this feature are welcome; send email to
975 C<perl5-porters@perl.org>.
976
977 We can extend the example above:
978
979  /(?[ ( \p{Thai} + \p{Lao} ) & \p{Digit} ])/
980
981 This matches digits that are in either the Thai or Laotian scripts.
982
983 Notice the white space in these examples.  This construct always has
984 the C<E<sol>x> modifier turned on within it.
985
986 The available binary operators are:
987
988  &    intersection
989  +    union
990  |    another name for '+', hence means union
991  -    subtraction (the result matches the set consisting of those
992       code points matched by the first operand, excluding any that
993       are also matched by the second operand)
994  ^    symmetric difference (the union minus the intersection).  This
995       is like an exclusive or, in that the result is the set of code
996       points that are matched by either, but not both, of the
997       operands.
998
999 There is one unary operator:
1000
1001  !    complement
1002
1003 All the binary operators left associate, and are of equal precedence.
1004 The unary operator right associates, and has higher precedence.  Use
1005 parentheses to override the default associations.  Some feedback we've
1006 received indicates a desire for intersection to have higher precedence
1007 than union.  This is something that feedback from the field may cause us
1008 to change in future releases; you may want to parenthesize copiously to
1009 avoid such changes affecting your code, until this feature is no longer
1010 considered experimental.
1011
1012 The main restriction is that everything is a metacharacter.  Thus,
1013 you cannot refer to single characters by doing something like this:
1014
1015  /(?[ a + b ])/ # Syntax error!
1016
1017 The easiest way to specify an individual typable character is to enclose
1018 it in brackets:
1019
1020  /(?[ [a] + [b] ])/
1021
1022 (This is the same thing as C<[ab]>.)  You could also have said the
1023 equivalent:
1024
1025  /(?[[ a b ]])/
1026
1027 (You can, of course, specify single characters by using, C<\x{...}>,
1028 C<\N{...}>, etc.)
1029
1030 This last example shows the use of this construct to specify an ordinary
1031 bracketed character class without additional set operations.  Note the
1032 white space within it; C<E<sol>x> is turned on even within bracketed
1033 character classes, except you can't have comments inside them.  Hence,
1034
1035  (?[ [#] ])
1036
1037 matches the literal character "#".  To specify a literal white space character,
1038 you can escape it with a backslash, like:
1039
1040  /(?[ [ a e i o u \  ] ])/
1041
1042 This matches the English vowels plus the SPACE character.
1043 All the other escapes accepted by normal bracketed character classes are
1044 accepted here as well; but unrecognized escapes that generate warnings
1045 in normal classes are fatal errors here.
1046
1047 All warnings from these class elements are fatal, as well as some
1048 practices that don't currently warn.  For example you cannot say
1049
1050  /(?[ [ \xF ] ])/     # Syntax error!
1051
1052 You have to have two hex digits after a braceless C<\x> (use a leading
1053 zero to make two).  These restrictions are to lower the incidence of
1054 typos causing the class to not match what you thought it would.
1055
1056 If a regular bracketed character class contains a C<\p{}> or C<\P{}> and
1057 is matched against a non-Unicode code point, a warning may be
1058 raised, as the result is not Unicode-defined.  No such warning will come
1059 when using this extended form.
1060
1061 The final difference between regular bracketed character classes and
1062 these, is that it is not possible to get these to match a
1063 multi-character fold.  Thus,
1064
1065  /(?[ [\xDF] ])/iu
1066
1067 does not match the string C<ss>.
1068
1069 You don't have to enclose POSIX class names inside double brackets,
1070 hence both of the following work:
1071
1072  /(?[ [:word:] - [:lower:] ])/
1073  /(?[ [[:word:]] - [[:lower:]] ])/
1074
1075 Any contained POSIX character classes, including things like C<\w> and C<\D>
1076 respect the C<E<sol>a> (and C<E<sol>aa>) modifiers.
1077
1078 C<< (?[ ]) >> is a regex-compile-time construct.  Any attempt to use
1079 something which isn't knowable at the time the containing regular
1080 expression is compiled is a fatal error.  In practice, this means
1081 just three limitations:
1082
1083 =over 4
1084
1085 =item 1
1086
1087 This construct cannot be used within the scope of
1088 C<use locale> (or the C<E<sol>l> regex modifier).
1089
1090 =item 2
1091
1092 Any
1093 L<user-defined property|perlunicode/"User-Defined Character Properties">
1094 used must be already defined by the time the regular expression is
1095 compiled (but note that this construct can be used instead of such
1096 properties).
1097
1098 =item 3
1099
1100 A regular expression that otherwise would compile
1101 using C<E<sol>d> rules, and which uses this construct will instead
1102 use C<E<sol>u>.  Thus this construct tells Perl that you don't want
1103 C<E<sol>d> rules for the entire regular expression containing it.
1104
1105 =back
1106
1107 Note that skipping white space applies only to the interior of this
1108 construct.  There must not be any space between any of the characters
1109 that form the initial C<(?[>.  Nor may there be space between the
1110 closing C<])> characters.
1111
1112 Just as in all regular expressions, the pattern can be built up by
1113 including variables that are interpolated at regex compilation time.
1114 Care must be taken to ensure that you are getting what you expect.  For
1115 example:
1116
1117  my $thai_or_lao = '\p{Thai} + \p{Lao}';
1118  ...
1119  qr/(?[ \p{Digit} & $thai_or_lao ])/;
1120
1121 compiles to
1122
1123  qr/(?[ \p{Digit} & \p{Thai} + \p{Lao} ])/;
1124
1125 But this does not have the effect that someone reading the code would
1126 likely expect, as the intersection applies just to C<\p{Thai}>,
1127 excluding the Laotian.  Pitfalls like this can be avoided by
1128 parenthesizing the component pieces:
1129
1130  my $thai_or_lao = '( \p{Thai} + \p{Lao} )';
1131
1132 But any modifiers will still apply to all the components:
1133
1134  my $lower = '\p{Lower} + \p{Digit}';
1135  qr/(?[ \p{Greek} & $lower ])/i;
1136
1137 matches upper case things.  You can avoid surprises by making the
1138 components into instances of this construct by compiling them:
1139
1140  my $thai_or_lao = qr/(?[ \p{Thai} + \p{Lao} ])/;
1141  my $lower = qr/(?[ \p{Lower} + \p{Digit} ])/;
1142
1143 When these are embedded in another pattern, what they match does not
1144 change, regardless of parenthesization or what modifiers are in effect
1145 in that outer pattern.
1146
1147 Due to the way that Perl parses things, your parentheses and brackets
1148 may need to be balanced, even including comments.  If you run into any
1149 examples, please send them to C<perlbug@perl.org>, so that we can have a
1150 concrete example for this man page.
1151
1152 We may change it so that things that remain legal uses in normal bracketed
1153 character classes might become illegal within this experimental
1154 construct.  One proposal, for example, is to forbid adjacent uses of the
1155 same character, as in C<(?[ [aa] ])>.  The motivation for such a change
1156 is that this usage is likely a typo, as the second "a" adds nothing.