pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The sequence of statements is executed just once, unlike in B<sed>
   9 and B<awk> scripts, where the sequence of statements is executed
  10 for each input line.  While this means that you must explicitly
  11 loop over the lines of your input file (or files), it also means
  12 you have much more control over which files and which lines you look at.
  13 (Actually, I'm lying--it is possible to do an implicit loop with
  14 either the B<-n> or B<-p> switch.  It's just not the mandatory
  15 default like it is in B<sed> and B<awk>.)
  16
  17 Perl is, for the most part, a free-form language.  (The only exception
  18 to this is format declarations, for obvious reasons.)  Text from a
  19 C<"#"> character until the end of the line is a comment, and is
  20 ignored.  If you attempt to use C</* */> C-style comments, it will be
  21 interpreted either as division or pattern matching, depending on the
  22 context, and C++ C<//> comments just look like a null regular
  23 expression, so don't do that.
  24
  25 =head2 Declarations
  26
  27 The only things you need to declare in Perl are report formats
  28 and subroutines--and even undefined subroutines can be handled
  29 through AUTOLOAD.  A variable holds the undefined value (C<undef>)
  30 until it has been assigned a defined value, which is anything
  31 other than C<undef>.  When used as a number, C<undef> is treated
  32 as C<0>; when used as a string, it is treated the empty string,
  33 C<"">; and when used as a reference that isn't being assigned
  34 to, it is treated as an error.  If you enable warnings, you'll
  35 be notified of an uninitialized value whenever you treat C<undef>
  36 as a string or a number.  Well, usually.  Boolean ("don't-care")
  37 contexts and operators such as C<++>, C<-->, C<+=>, C<-=>, and
  38 C<.=> are always exempt from such warnings.
  39
  40 A declaration can be put anywhere a statement can, but has no effect on
  41 the execution of the primary sequence of statements--declarations all
  42 take effect at compile time.  Typically all the declarations are put at
  43 the beginning or the end of the script.  However, if you're using
  44 lexically-scoped private variables created with C<my()>, you'll
  45 have to make sure
  46 your format or subroutine definition is within the same block scope
  47 as the my if you expect to be able to access those private variables.
  48
  49 Declaring a subroutine allows a subroutine name to be used as if it were a
  50 list operator from that point forward in the program.  You can declare a
  51 subroutine without defining it by saying C<sub name>, thus:
  52
  53     sub myname;
  54     $me = myname $0             or die "can't get myname";
  55
  56 Note that myname() functions as a list operator, not as a unary operator;
  57 so be careful to use C<or> instead of C<||> in this case.  However, if
  58 you were to declare the subroutine as C<sub myname ($)>, then
  59 C<myname> would function as a unary operator, so either C<or> or
  60 C<||> would work.
  61
  62 Subroutines declarations can also be loaded up with the C<require> statement
  63 or both loaded and imported into your namespace with a C<use> statement.
  64 See L<perlmod> for details on this.
  65
  66 A statement sequence may contain declarations of lexically-scoped
  67 variables, but apart from declaring a variable name, the declaration acts
  68 like an ordinary statement, and is elaborated within the sequence of
  69 statements as if it were an ordinary statement.  That means it actually
  70 has both compile-time and run-time effects.
  71
  72 =head2 Simple statements
  73
  74 The only kind of simple statement is an expression evaluated for its
  75 side effects.  Every simple statement must be terminated with a
  76 semicolon, unless it is the final statement in a block, in which case
  77 the semicolon is optional.  (A semicolon is still encouraged there if the
  78 block takes up more than one line, because you may eventually add another line.)
  79 Note that there are some operators like C<eval {}> and C<do {}> that look
  80 like compound statements, but aren't (they're just TERMs in an expression),
  81 and thus need an explicit termination if used as the last item in a statement.
  82
  83 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  84 just before the terminating semicolon (or block ending).  The possible
  85 modifiers are:
  86
  87     if EXPR
  88     unless EXPR
  89     while EXPR
  90     until EXPR
  91     foreach EXPR
  92
  93 The C<if> and C<unless> modifiers have the expected semantics,
  94 presuming you're a speaker of English.  The C<foreach> modifier is an
  95 iterator:  For each value in EXPR, it aliases C<$_> to the value and
  96 executes the statement.  The C<while> and C<until> modifiers have the
  97 usual "C<while> loop" semantics (conditional evaluated first), except
  98 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
  99 statement), in which case the block executes once before the
 100 conditional is evaluated.  This is so that you can write loops like:
 101
 102     do {
 103         $line = <STDIN>;
 104         ...
 105     } until $line  eq ".\n";
 106
 107 See L<perlfunc/do>.  Note also that the loop control statements described
 108 later will I<NOT> work in this construct, because modifiers don't take
 109 loop labels.  Sorry.  You can always put another block inside of it
 110 (for C<next>) or around it (for C<last>) to do that sort of thing.
 111 For C<next>, just double the braces:
 112
 113     do {{
 114         next if $x == $y;
 115         # do something here
 116     }} until $x++ > $z;
 117
 118 For C<last>, you have to be more elaborate:
 119
 120     LOOP: {
 121             do {
 122                 last if $x = $y**2;
 123                 # do something here
 124             } while $x++ <= $z;
 125     }
 126
 127 =head2 Compound statements
 128
 129 In Perl, a sequence of statements that defines a scope is called a block.
 130 Sometimes a block is delimited by the file containing it (in the case
 131 of a required file, or the program as a whole), and sometimes a block
 132 is delimited by the extent of a string (in the case of an eval).
 133
 134 But generally, a block is delimited by curly brackets, also known as braces.
 135 We will call this syntactic construct a BLOCK.
 136
 137 The following compound statements may be used to control flow:
 138
 139     if (EXPR) BLOCK
 140     if (EXPR) BLOCK else BLOCK
 141     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 142     LABEL while (EXPR) BLOCK
 143     LABEL while (EXPR) BLOCK continue BLOCK
 144     LABEL for (EXPR; EXPR; EXPR) BLOCK
 145     LABEL foreach VAR (LIST) BLOCK
 146     LABEL foreach VAR (LIST) BLOCK continue BLOCK
 147     LABEL BLOCK continue BLOCK
 148
 149 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 150 not statements.  This means that the curly brackets are I<required>--no
 151 dangling statements allowed.  If you want to write conditionals without
 152 curly brackets there are several other ways to do it.  The following
 153 all do the same thing:
 154
 155     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 156     die "Can't open $FOO: $!" unless open(FOO);
 157     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 158     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 159                         # a bit exotic, that last one
 160
 161 The C<if> statement is straightforward.  Because BLOCKs are always
 162 bounded by curly brackets, there is never any ambiguity about which
 163 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 164 the sense of the test is reversed.
 165
 166 The C<while> statement executes the block as long as the expression is
 167 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
 168 The LABEL is optional, and if present, consists of an identifier followed
 169 by a colon.  The LABEL identifies the loop for the loop control
 170 statements C<next>, C<last>, and C<redo>.
 171 If the LABEL is omitted, the loop control statement
 172 refers to the innermost enclosing loop.  This may include dynamically
 173 looking back your call-stack at run time to find the LABEL.  Such
 174 desperate behavior triggers a warning if you use the C<use warnings>
 175 pragma or the B<-w> flag.
 176 Unlike a C<foreach> statement, a C<while> statement never implicitly
 177 localises any variables.
 178
 179 If there is a C<continue> BLOCK, it is always executed just before the
 180 conditional is about to be evaluated again, just like the third part of a
 181 C<for> loop in C.  Thus it can be used to increment a loop variable, even
 182 when the loop has been continued via the C<next> statement (which is
 183 similar to the C C<continue> statement).
 184
 185 =head2 Loop Control
 186
 187 The C<next> command is like the C<continue> statement in C; it starts
 188 the next iteration of the loop:
 189
 190     LINE: while (<STDIN>) {
 191         next LINE if /^#/;      # discard comments
 192         ...
 193     }
 194
 195 The C<last> command is like the C<break> statement in C (as used in
 196 loops); it immediately exits the loop in question.  The
 197 C<continue> block, if any, is not executed:
 198
 199     LINE: while (<STDIN>) {
 200         last LINE if /^$/;      # exit when done with header
 201         ...
 202     }
 203
 204 The C<redo> command restarts the loop block without evaluating the
 205 conditional again.  The C<continue> block, if any, is I<not> executed.
 206 This command is normally used by programs that want to lie to themselves
 207 about what was just input.
 208
 209 For example, when processing a file like F</etc/termcap>.
 210 If your input lines might end in backslashes to indicate continuation, you
 211 want to skip ahead and get the next record.
 212
 213     while (<>) {
 214         chomp;
 215         if (s/\\$//) {
 216             $_ .= <>;
 217             redo unless eof();
 218         }
 219         # now process $_
 220     }
 221
 222 which is Perl short-hand for the more explicitly written version:
 223
 224     LINE: while (defined($line = <ARGV>)) {
 225         chomp($line);
 226         if ($line =~ s/\\$//) {
 227             $line .= <ARGV>;
 228             redo LINE unless eof(); # not eof(ARGV)!
 229         }
 230         # now process $line
 231     }
 232
 233 Note that if there were a C<continue> block on the above code, it would get
 234 executed even on discarded lines.  This is often used to reset line counters
 235 or C<?pat?> one-time matches.
 236
 237     # inspired by :1,$g/fred/s//WILMA/
 238     while (<>) {
 239         ?(fred)?    && s//WILMA $1 WILMA/;
 240         ?(barney)?  && s//BETTY $1 BETTY/;
 241         ?(homer)?   && s//MARGE $1 MARGE/;
 242     } continue {
 243         print "$ARGV $.: $_";
 244         close ARGV  if eof();           # reset $.
 245         reset       if eof();           # reset ?pat?
 246     }
 247
 248 If the word C<while> is replaced by the word C<until>, the sense of the
 249 test is reversed, but the conditional is still tested before the first
 250 iteration.
 251
 252 The loop control statements don't work in an C<if> or C<unless>, since
 253 they aren't loops.  You can double the braces to make them such, though.
 254
 255     if (/pattern/) {{
 256         next if /fred/;
 257         next if /barney/;
 258         # so something here
 259     }}
 260
 261 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 262 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 263
 264 =head2 For Loops
 265
 266 Perl's C-style C<for> loop works like the corresponding C<while> loop;
 267 that means that this:
 268
 269     for ($i = 1; $i < 10; $i++) {
 270         ...
 271     }
 272
 273 is the same as this:
 274
 275     $i = 1;
 276     while ($i < 10) {
 277         ...
 278     } continue {
 279         $i++;
 280     }
 281
 282 There is one minor difference: if variables are declared with C<my>
 283 in the initialization section of the C<for>, the lexical scope of
 284 those variables is exactly the C<for> loop (the body of the loop
 285 and the control sections).
 286
 287 Besides the normal array index looping, C<for> can lend itself
 288 to many other interesting applications.  Here's one that avoids the
 289 problem you get into if you explicitly test for end-of-file on
 290 an interactive file descriptor causing your program to appear to
 291 hang.
 292
 293     $on_a_tty = -t STDIN && -t STDOUT;
 294     sub prompt { print "yes? " if $on_a_tty }
 295     for ( prompt(); <STDIN>; prompt() ) {
 296         # do something
 297     }
 298
 299 =head2 Foreach Loops
 300
 301 The C<foreach> loop iterates over a normal list value and sets the
 302 variable VAR to be each element of the list in turn.  If the variable
 303 is preceded with the keyword C<my>, then it is lexically scoped, and
 304 is therefore visible only within the loop.  Otherwise, the variable is
 305 implicitly local to the loop and regains its former value upon exiting
 306 the loop.  If the variable was previously declared with C<my>, it uses
 307 that variable instead of the global one, but it's still localized to
 308 the loop.
 309
 310 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 311 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 312 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 313 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 314
 315 If any element of LIST is an lvalue, you can modify it by modifying
 316 VAR inside the loop.  Conversely, if any element of LIST is NOT an
 317 lvalue, any attempt to modify that element will fail.  In other words,
 318 the C<foreach> loop index variable is an implicit alias for each item
 319 in the list that you're looping over.
 320
 321 If any part of LIST is an array, C<foreach> will get very confused if
 322 you add or remove elements within the loop body, for example with
 323 C<splice>.   So don't do that.
 324
 325 C<foreach> probably won't do what you expect if VAR is a tied or other
 326 special variable.   Don't do that either.
 327
 328 Examples:
 329
 330     for (@ary) { s/foo/bar/ }
 331
 332     for my $elem (@elements) {
 333         $elem *= 2;
 334     }
 335
 336     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 337         print $count, "\n"; sleep(1);
 338     }
 339
 340     for (1..15) { print "Merry Christmas\n"; }
 341
 342     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 343         print "Item: $item\n";
 344     }
 345
 346 Here's how a C programmer might code up a particular algorithm in Perl:
 347
 348     for (my $i = 0; $i < @ary1; $i++) {
 349         for (my $j = 0; $j < @ary2; $j++) {
 350             if ($ary1[$i] > $ary2[$j]) {
 351                 last; # can't go to outer :-(
 352             }
 353             $ary1[$i] += $ary2[$j];
 354         }
 355         # this is where that last takes me
 356     }
 357
 358 Whereas here's how a Perl programmer more comfortable with the idiom might
 359 do it:
 360
 361     OUTER: for my $wid (@ary1) {
 362     INNER:   for my $jet (@ary2) {
 363                 next OUTER if $wid > $jet;
 364                 $wid += $jet;
 365              }
 366           }
 367
 368 See how much easier this is?  It's cleaner, safer, and faster.  It's
 369 cleaner because it's less noisy.  It's safer because if code gets added
 370 between the inner and outer loops later on, the new code won't be
 371 accidentally executed.  The C<next> explicitly iterates the other loop
 372 rather than merely terminating the inner one.  And it's faster because
 373 Perl executes a C<foreach> statement more rapidly than it would the
 374 equivalent C<for> loop.
 375
 376 =head2 Basic BLOCKs and Switch Statements
 377
 378 A BLOCK by itself (labeled or not) is semantically equivalent to a
 379 loop that executes once.  Thus you can use any of the loop control
 380 statements in it to leave or restart the block.  (Note that this is
 381 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 382 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 383 block is optional.
 384
 385 The BLOCK construct is particularly nice for doing case
 386 structures.
 387
 388     SWITCH: {
 389         if (/^abc/) { $abc = 1; last SWITCH; }
 390         if (/^def/) { $def = 1; last SWITCH; }
 391         if (/^xyz/) { $xyz = 1; last SWITCH; }
 392         $nothing = 1;
 393     }
 394
 395 There is no official C<switch> statement in Perl, because there are
 396 already several ways to write the equivalent.
 397
 398 However, starting from Perl 5.8 to get switch and case one can use
 399 the Switch extension and say:
 400
 401         use Switch;
 402
 403 after which one has switch and case.  It is not as fast as it could be
 404 because it's not really part of the language (it's done using source
 405 filters) but it is available, and it's very flexible.
 406
 407 In addition to the above BLOCK construct, you could write
 408
 409     SWITCH: {
 410         $abc = 1, last SWITCH  if /^abc/;
 411         $def = 1, last SWITCH  if /^def/;
 412         $xyz = 1, last SWITCH  if /^xyz/;
 413         $nothing = 1;
 414     }
 415
 416 (That's actually not as strange as it looks once you realize that you can
 417 use loop control "operators" within an expression,  That's just the normal
 418 C comma operator.)
 419
 420 or
 421
 422     SWITCH: {
 423         /^abc/ && do { $abc = 1; last SWITCH; };
 424         /^def/ && do { $def = 1; last SWITCH; };
 425         /^xyz/ && do { $xyz = 1; last SWITCH; };
 426         $nothing = 1;
 427     }
 428
 429 or formatted so it stands out more as a "proper" C<switch> statement:
 430
 431     SWITCH: {
 432         /^abc/      && do {
 433                             $abc = 1;
 434                             last SWITCH;
 435                        };
 436
 437         /^def/      && do {
 438                             $def = 1;
 439                             last SWITCH;
 440                        };
 441
 442         /^xyz/      && do {
 443                             $xyz = 1;
 444                             last SWITCH;
 445                         };
 446         $nothing = 1;
 447     }
 448
 449 or
 450
 451     SWITCH: {
 452         /^abc/ and $abc = 1, last SWITCH;
 453         /^def/ and $def = 1, last SWITCH;
 454         /^xyz/ and $xyz = 1, last SWITCH;
 455         $nothing = 1;
 456     }
 457
 458 or even, horrors,
 459
 460     if (/^abc/)
 461         { $abc = 1 }
 462     elsif (/^def/)
 463         { $def = 1 }
 464     elsif (/^xyz/)
 465         { $xyz = 1 }
 466     else
 467         { $nothing = 1 }
 468
 469 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 470 a temporary assignment to C<$_> for convenient matching:
 471
 472     SWITCH: for ($where) {
 473                 /In Card Names/     && do { push @flags, '-e'; last; };
 474                 /Anywhere/          && do { push @flags, '-h'; last; };
 475                 /In Rulings/        && do {                    last; };
 476                 die "unknown value for form variable where: `$where'";
 477             }
 478
 479 Another interesting approach to a switch statement is arrange
 480 for a C<do> block to return the proper value:
 481
 482     $amode = do {
 483         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 484         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 485         elsif  ($flag & O_RDWR)   {
 486             if ($flag & O_CREAT)  { "w+" }
 487             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 488         }
 489     };
 490
 491 Or
 492
 493         print do {
 494             ($flags & O_WRONLY) ? "write-only"          :
 495             ($flags & O_RDWR)   ? "read-write"          :
 496                                   "read-only";
 497         };
 498
 499 Or if you are certainly that all the C<&&> clauses are true, you can use
 500 something like this, which "switches" on the value of the
 501 C<HTTP_USER_AGENT> environment variable.
 502
 503     #!/usr/bin/perl
 504     # pick out jargon file page based on browser
 505     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 506     for ($ENV{HTTP_USER_AGENT}) {
 507         $page  =    /Mac/            && 'm/Macintrash.html'
 508                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 509                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 510                  || /Linux/          && 'l/Linux.html'
 511                  || /HP-UX/          && 'h/HP-SUX.html'
 512                  || /SunOS/          && 's/ScumOS.html'
 513                  ||                     'a/AppendixB.html';
 514     }
 515     print "Location: $dir/$page\015\012\015\012";
 516
 517 That kind of switch statement only works when you know the C<&&> clauses
 518 will be true.  If you don't, the previous C<?:> example should be used.
 519
 520 You might also consider writing a hash of subroutine references
 521 instead of synthesizing a C<switch> statement.
 522
 523 =head2 Goto
 524
 525 Although not for the faint of heart, Perl does support a C<goto>
 526 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 527 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 528 a C<goto>; it's just the name of the loop.
 529
 530 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 531 execution there.  It may not be used to go into any construct that
 532 requires initialization, such as a subroutine or a C<foreach> loop.  It
 533 also can't be used to go into a construct that is optimized away.  It
 534 can be used to go almost anywhere else within the dynamic scope,
 535 including out of subroutines, but it's usually better to use some other
 536 construct such as C<last> or C<die>.  The author of Perl has never felt the
 537 need to use this form of C<goto> (in Perl, that is--C is another matter).
 538
 539 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 540 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 541 necessarily recommended if you're optimizing for maintainability:
 542
 543     goto(("FOO", "BAR", "GLARCH")[$i]);
 544
 545 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 546 named subroutine for the currently running subroutine.  This is used by
 547 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 548 pretend that the other subroutine had been called in the first place
 549 (except that any modifications to C<@_> in the current subroutine are
 550 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 551 will be able to tell that this routine was called first.
 552
 553 In almost all cases like this, it's usually a far, far better idea to use the
 554 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 555 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 556 C<eval{}> and die() for exception processing can also be a prudent approach.
 557
 558 =head2 PODs: Embedded Documentation
 559
 560 Perl has a mechanism for intermixing documentation with source code.
 561 While it's expecting the beginning of a new statement, if the compiler
 562 encounters a line that begins with an equal sign and a word, like this
 563
 564     =head1 Here There Be Pods!
 565
 566 Then that text and all remaining text up through and including a line
 567 beginning with C<=cut> will be ignored.  The format of the intervening
 568 text is described in L<perlpod>.
 569
 570 This allows you to intermix your source code
 571 and your documentation text freely, as in
 572
 573     =item snazzle($)
 574
 575     The snazzle() function will behave in the most spectacular
 576     form that you can possibly imagine, not even excepting
 577     cybernetic pyrotechnics.
 578
 579     =cut back to the compiler, nuff of this pod stuff!
 580
 581     sub snazzle($) {
 582         my $thingie = shift;
 583         .........
 584     }
 585
 586 Note that pod translators should look at only paragraphs beginning
 587 with a pod directive (it makes parsing easier), whereas the compiler
 588 actually knows to look for pod escapes even in the middle of a
 589 paragraph.  This means that the following secret stuff will be
 590 ignored by both the compiler and the translators.
 591
 592     $a=3;
 593     =secret stuff
 594      warn "Neither POD nor CODE!?"
 595     =cut back
 596     print "got $a\n";
 597
 598 You probably shouldn't rely upon the C<warn()> being podded out forever.
 599 Not all pod translators are well-behaved in this regard, and perhaps
 600 the compiler will become pickier.
 601
 602 One may also use pod directives to quickly comment out a section
 603 of code.
 604
 605 =head2 Plain Old Comments (Not!)
 606
 607 Much like the C preprocessor, Perl can process line directives.  Using
 608 this, one can control Perl's idea of filenames and line numbers in
 609 error or warning messages (especially for strings that are processed
 610 with C<eval()>).  The syntax for this mechanism is the same as for most
 611 C preprocessors: it matches the regular expression
 612 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]+)")?\s*$/> with C<$1> being the line
 613 number for the next line, and C<$2> being the optional filename
 614 (specified within quotes).
 615
 616 There is a fairly obvious gotcha included with the line directive:
 617 Debuggers and profilers will only show the last source line to appear
 618 at a particular line number in a given file.  Care should be taken not
 619 to cause line number collisions in code you'd like to debug later.
 620
 621 Here are some examples that you should be able to type into your command
 622 shell:
 623
 624     % perl
 625     # line 200 "bzzzt"
 626     # the `#' on the previous line must be the first char on line
 627     die 'foo';
 628     __END__
 629     foo at bzzzt line 201.
 630
 631     % perl
 632     # line 200 "bzzzt"
 633     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 634     __END__
 635     foo at - line 2001.
 636
 637     % perl
 638     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 639     __END__
 640     foo at foo bar line 200.
 641
 642     % perl
 643     # line 345 "goop"
 644     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 645     print $@;
 646     __END__
 647     foo at goop line 345.
 648
 649 =cut