pod/perlrecharclass.pod

   1 =head1 NAME
   2 X<character class>
   3
   4 perlrecharclass - Perl Regular Expression Character Classes
   5
   6 =head1 DESCRIPTION
   7
   8 The top level documentation about Perl regular expressions
   9 is found in L<perlre>.
  10
  11 This manual page discusses the syntax and use of character
  12 classes in Perl regular expressions.
  13
  14 A character class is a way of denoting a set of characters
  15 in such a way that one character of the set is matched.
  16 It's important to remember that: matching a character class
  17 consumes exactly one character in the source string. (The source
  18 string is the string the regular expression is matched against.)
  19
  20 There are three types of character classes in Perl regular
  21 expressions: the dot, backslash sequences, and the form enclosed in square
  22 brackets.  Keep in mind, though, that often the term "character class" is used
  23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
  24
  25 =head2 The dot
  26
  27 The dot (or period), C<.> is probably the most used, and certainly
  28 the most well-known character class. By default, a dot matches any
  29 character, except for the newline. That default can be changed to
  30 add matching the newline by using the I<single line> modifier: either
  31 for the entire regular expression with the C</s> modifier, or
  32 locally with C<(?s)>.  (The C<\N> backslash sequence, described
  33 below, matches any character except newline without regard to the
  34 I<single line> modifier.)
  35
  36 Here are some examples:
  37
  38  "a"  =~  /./       # Match
  39  "."  =~  /./       # Match
  40  ""   =~  /./       # No match (dot has to match a character)
  41  "\n" =~  /./       # No match (dot does not match a newline)
  42  "\n" =~  /./s      # Match (global 'single line' modifier)
  43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
  44  "ab" =~  /^.$/     # No match (dot matches one character)
  45
  46 =head2 Backslash sequences
  47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
  48 X<\N> X<\v> X<\V> X<\h> X<\H>
  49 X<word> X<whitespace>
  50
  51 A backslash sequence is a sequence of characters, the first one of which is a
  52 backslash.  Perl ascribes special meaning to many such sequences, and some of
  53 these are character classes.  That is, they match a single character each,
  54 provided that the character belongs to the specific set of characters defined
  55 by the sequence.
  56
  57 Here's a list of the backslash sequences that are character classes.  They
  58 are discussed in more detail below.  (For the backslash sequences that aren't
  59 character classes, see L<perlrebackslash>.)
  60
  61  \d             Match a decimal digit character.
  62  \D             Match a non-decimal-digit character.
  63  \w             Match a "word" character.
  64  \W             Match a non-"word" character.
  65  \s             Match a whitespace character.
  66  \S             Match a non-whitespace character.
  67  \h             Match a horizontal whitespace character.
  68  \H             Match a character that isn't horizontal whitespace.
  69  \v             Match a vertical whitespace character.
  70  \V             Match a character that isn't vertical whitespace.
  71  \N             Match a character that isn't a newline.
  72  \pP, \p{Prop}  Match a character that has the given Unicode property.
  73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
  74
  75 =head3 \N
  76
  77 C<\N>, available starting in v5.12, like the dot, matches any
  78 character that is not a newline. The difference is that C<\N> is not influenced
  79 by the I<single line> regular expression modifier (see L</The dot> above).  Note
  80 that the form C<\N{...}> may mean something completely different.  When the
  81 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
  82 character that many times.  For example, C<\N{3}> means to match 3
  83 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
  84 is not a legal quantifier, it is presumed to be a named character.  See
  85 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
  86 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
  87 names are respectively C<COLON>, C<4F>, and C<F4>.
  88
  89 =head3 Digits
  90
  91 C<\d> matches a single character considered to be a decimal I<digit>.
  92 If the C</a> regular expression modifier is in effect, it matches [0-9].
  93 Otherwise, it
  94 matches anything that is matched by C<\p{Digit}>, which includes [0-9].
  95 (An unlikely possible exception is that under locale matching rules, the
  96 current locale might not have [0-9] matched by C<\d>, and/or might match
  97 other characters whose code point is less than 256.  Such a locale
  98 definition would be in violation of the C language standard, but Perl
  99 doesn't currently assume anything in regard to this.)
 100
 101 What this means is that unless the C</a> modifier is in effect C<\d> not
 102 only matches the digits '0' - '9', but also Arabic, Devanagari, and
 103 digits from other languages.  This may cause some confusion, and some
 104 security issues.
 105
 106 Some digits that C<\d> matches look like some of the [0-9] ones, but
 107 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
 108 very much like an ASCII DIGIT EIGHT (U+0038).  An application that
 109 is expecting only the ASCII digits might be misled, or if the match is
 110 C<\d+>, the matched string might contain a mixture of digits from
 111 different writing systems that look like they signify a number different
 112 than they actually do.  L<Unicode::UCD/num()> can
 113 be used to safely
 114 calculate the value, returning C<undef> if the input string contains
 115 such a mixture.
 116
 117 What C<\p{Digit}> means (and hence C<\d> except under the C</a>
 118 modifier) is C<\p{General_Category=Decimal_Number}>, or synonymously,
 119 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this
 120 is the same set of characters matched by C<\p{Numeric_Type=Decimal}>.
 121 But Unicode also has a different property with a similar name,
 122 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
 123 characters.  These characters are things such as C<CIRCLED DIGIT ONE>
 124 or subscripts, or are from writing systems that lack all ten digits.
 125
 126 The design intent is for C<\d> to exactly match the set of characters
 127 that can safely be used with "normal" big-endian positional decimal
 128 syntax, where, for example 123 means one 'hundred', plus two 'tens',
 129 plus three 'ones'.  This positional notation does not necessarily apply
 130 to characters that match the other type of "digit",
 131 C<\p{Numeric_Type=Digit}>, and so C<\d> doesn't match them.
 132
 133 The Tamil digits (U+0BE6 - U+0BEF) can also legally be
 134 used in old-style Tamil numbers in which they would appear no more than
 135 one in a row, separated by characters that mean "times 10", "times 100",
 136 etc.  (See L<http://www.unicode.org/notes/tn21>.)
 137
 138 Any character not matched by C<\d> is matched by C<\D>.
 139
 140 =head3 Word characters
 141
 142 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
 143 decimal digit); or a connecting punctuation character, such as an
 144 underscore ("_"); or a "mark" character (like some sort of accent) that
 145 attaches to one of those.  It does not match a whole word.  To match a
 146 whole word, use C<\w+>.  This isn't the same thing as matching an
 147 English word, but in the ASCII range it is the same as a string of
 148 Perl-identifier characters.
 149
 150 =over
 151
 152 =item If the C</a> modifier is in effect ...
 153
 154 C<\w> matches the 63 characters [a-zA-Z0-9_].
 155
 156 =item otherwise ...
 157
 158 =over
 159
 160 =item For code points above 255 ...
 161
 162 C<\w> matches the same as C<\p{Word}> matches in this range.  That is,
 163 it matches Thai letters, Greek letters, etc.  This includes connector
 164 punctuation (like the underscore) which connect two words together, or
 165 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
 166 are generally used to add auxiliary markings to letters.
 167
 168 =item For code points below 256 ...
 169
 170 =over
 171
 172 =item if locale rules are in effect ...
 173
 174 C<\w> matches the platform's native underscore character plus whatever
 175 the locale considers to be alphanumeric.
 176
 177 =item if Unicode rules are in effect ...
 178
 179 C<\w> matches exactly what C<\p{Word}> matches.
 180
 181 =item otherwise ...
 182
 183 C<\w> matches [a-zA-Z0-9_].
 184
 185 =back
 186
 187 =back
 188
 189 =back
 190
 191 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
 192
 193 There are a number of security issues with the full Unicode list of word
 194 characters.  See L<http://unicode.org/reports/tr36>.
 195
 196 Also, for a somewhat finer-grained set of characters that are in programming
 197 language identifiers beyond the ASCII range, you may wish to instead use the
 198 more customized L</Unicode Properties>, C<\p{ID_Start}>,
 199 C<\p{ID_Continue}>, C<\p{XID_Start}>, and C<\p{XID_Continue}>.  See
 200 L<http://unicode.org/reports/tr31>.
 201
 202 Any character not matched by C<\w> is matched by C<\W>.
 203
 204 =head3 Whitespace
 205
 206 C<\s> matches any single character considered whitespace.
 207
 208 =over
 209
 210 =item If the C</a> modifier is in effect ...
 211
 212 In all Perl versions, C<\s> matches the 5 characters [\t\n\f\r ]; that
 213 is, the horizontal tab,
 214 the newline, the form feed, the carriage return, and the space.
 215 Starting in Perl v5.18, experimentally, it also matches the vertical tab, C<\cK>.
 216 See note C<[1]> below for a discussion of this.
 217
 218 =item otherwise ...
 219
 220 =over
 221
 222 =item For code points above 255 ...
 223
 224 C<\s> matches exactly the code points above 255 shown with an "s" column
 225 in the table below.
 226
 227 =item For code points below 256 ...
 228
 229 =over
 230
 231 =item if locale rules are in effect ...
 232
 233 C<\s> matches whatever the locale considers to be whitespace.
 234
 235 =item if Unicode rules are in effect ...
 236
 237 C<\s> matches exactly the characters shown with an "s" column in the
 238 table below.
 239
 240 =item otherwise ...
 241
 242 C<\s> matches [\t\n\f\r\cK ] and, starting, experimentally in Perl
 243 v5.18, the vertical tab, C<\cK>.
 244 (See note C<[1]> below for a discussion of this.)
 245 Note that this list doesn't include the non-breaking space.
 246
 247 =back
 248
 249 =back
 250
 251 =back
 252
 253 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
 254
 255 Any character not matched by C<\s> is matched by C<\S>.
 256
 257 C<\h> matches any character considered horizontal whitespace;
 258 this includes the platform's space and tab characters and several others
 259 listed in the table below.  C<\H> matches any character
 260 not considered horizontal whitespace.  They use the platform's native
 261 character set, and do not consider any locale that may otherwise be in
 262 use.
 263
 264 C<\v> matches any character considered vertical whitespace;
 265 this includes the platform's carriage return and line feed characters (newline)
 266 plus several other characters, all listed in the table below.
 267 C<\V> matches any character not considered vertical whitespace.
 268 They use the platform's native character set, and do not consider any
 269 locale that may otherwise be in use.
 270
 271 C<\R> matches anything that can be considered a newline under Unicode
 272 rules. It's not a character class, as it can match a multi-character
 273 sequence. Therefore, it cannot be used inside a bracketed character
 274 class; use C<\v> instead (vertical whitespace).  It uses the platform's
 275 native character set, and does not consider any locale that may
 276 otherwise be in use.
 277 Details are discussed in L<perlrebackslash>.
 278
 279 Note that unlike C<\s> (and C<\d> and C<\w>), C<\h> and C<\v> always match
 280 the same characters, without regard to other factors, such as the active
 281 locale or whether the source string is in UTF-8 format.
 282
 283 One might think that C<\s> is equivalent to C<[\h\v]>. This is indeed true
 284 starting in Perl v5.18, but prior to that, the sole difference was that the
 285 vertical tab (C<"\cK">) was not matched by C<\s>.
 286
 287 The following table is a complete listing of characters matched by
 288 C<\s>, C<\h> and C<\v> as of Unicode 6.3.
 289
 290 The first column gives the Unicode code point of the character (in hex format),
 291 the second column gives the (Unicode) name. The third column indicates
 292 by which class(es) the character is matched (assuming no locale is in
 293 effect that changes the C<\s> matching).
 294
 295  0x0009        CHARACTER TABULATION   h s
 296  0x000a              LINE FEED (LF)    vs
 297  0x000b             LINE TABULATION    vs  [1]
 298  0x000c              FORM FEED (FF)    vs
 299  0x000d        CARRIAGE RETURN (CR)    vs
 300  0x0020                       SPACE   h s
 301  0x0085             NEXT LINE (NEL)    vs  [2]
 302  0x00a0              NO-BREAK SPACE   h s  [2]
 303  0x1680            OGHAM SPACE MARK   h s
 304  0x2000                     EN QUAD   h s
 305  0x2001                     EM QUAD   h s
 306  0x2002                    EN SPACE   h s
 307  0x2003                    EM SPACE   h s
 308  0x2004          THREE-PER-EM SPACE   h s
 309  0x2005           FOUR-PER-EM SPACE   h s
 310  0x2006            SIX-PER-EM SPACE   h s
 311  0x2007                FIGURE SPACE   h s
 312  0x2008           PUNCTUATION SPACE   h s
 313  0x2009                  THIN SPACE   h s
 314  0x200a                  HAIR SPACE   h s
 315  0x2028              LINE SEPARATOR    vs
 316  0x2029         PARAGRAPH SEPARATOR    vs
 317  0x202f       NARROW NO-BREAK SPACE   h s
 318  0x205f   MEDIUM MATHEMATICAL SPACE   h s
 319  0x3000           IDEOGRAPHIC SPACE   h s
 320
 321 =over 4
 322
 323 =item [1]
 324
 325 Prior to Perl v5.18, C<\s> did not match the vertical tab.  The change
 326 in v5.18 is considered an experiment, which means it could be backed out
 327 in v5.20 or v5.22 if experience indicates that it breaks too much
 328 existing code.  If this change adversely affects you, send email to
 329 C<perlbug@perl.org>; if it affects you positively, email
 330 C<perlthanks@perl.org>.  In the meantime, C<[^\S\cK]> (obscurely)
 331 matches what C<\s> traditionally did.
 332
 333 =item [2]
 334
 335 NEXT LINE and NO-BREAK SPACE may or may not match C<\s> depending
 336 on the rules in effect.  See
 337 L<the beginning of this section|/Whitespace>.
 338
 339 =back
 340
 341 =head3 Unicode Properties
 342
 343 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
 344 Unicode properties.  One letter property names can be used in the C<\pP> form,
 345 with the property name following the C<\p>, otherwise, braces are required.
 346 When using braces, there is a single form, which is just the property name
 347 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
 348 which means to match if the property "name" for the character has that particular
 349 "value".
 350 For instance, a match for a number can be written as C</\pN/> or as
 351 C</\p{Number}/>, or as C</\p{Number=True}/>.
 352 Lowercase letters are matched by the property I<Lowercase_Letter> which
 353 has the short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
 354 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
 355 (the underscores are optional).
 356 C</\pLl/> is valid, but means something different.
 357 It matches a two character string: a letter (Unicode property C<\pL>),
 358 followed by a lowercase C<l>.
 359
 360 If locale rules are not in effect, the use of
 361 a Unicode property will force the regular expression into using Unicode
 362 rules, if it isn't already.
 363
 364 Note that almost all properties are immune to case-insensitive matching.
 365 That is, adding a C</i> regular expression modifier does not change what
 366 they match.  There are two sets that are affected.  The first set is
 367 C<Uppercase_Letter>,
 368 C<Lowercase_Letter>,
 369 and C<Titlecase_Letter>,
 370 all of which match C<Cased_Letter> under C</i> matching.
 371 The second set is
 372 C<Uppercase>,
 373 C<Lowercase>,
 374 and C<Titlecase>,
 375 all of which match C<Cased> under C</i> matching.
 376 (The difference between these sets is that some things, such as Roman
 377 numerals, come in both upper and lower case, so they are C<Cased>, but
 378 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
 379 actually C<Letter_Number>s.)
 380 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
 381 of which under C</i> match C<PosixAlpha>.
 382
 383 For more details on Unicode properties, see L<perlunicode/Unicode
 384 Character Properties>; for a
 385 complete list of possible properties, see
 386 L<perluniprops/Properties accessible through \p{} and \P{}>,
 387 which notes all forms that have C</i> differences.
 388 It is also possible to define your own properties. This is discussed in
 389 L<perlunicode/User-Defined Character Properties>.
 390
 391 Unicode properties are defined (surprise!) only on Unicode code points.
 392 A warning is raised and all matches fail on non-Unicode code points
 393 (those above the legal Unicode maximum of 0x10FFFF).  This can be
 394 somewhat surprising,
 395
 396  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}      # Fails.
 397  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}     # Also fails!
 398
 399 Even though these two matches might be thought of as complements, they
 400 are so only on Unicode code points.
 401
 402 =head4 Examples
 403
 404  "a"  =~  /\w/      # Match, "a" is a 'word' character.
 405  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
 406  "a"  =~  /\d/      # No match, "a" isn't a digit.
 407  "7"  =~  /\d/      # Match, "7" is a digit.
 408  " "  =~  /\s/      # Match, a space is whitespace.
 409  "a"  =~  /\D/      # Match, "a" is a non-digit.
 410  "7"  =~  /\D/      # No match, "7" is not a non-digit.
 411  " "  =~  /\S/      # No match, a space is not non-whitespace.
 412
 413  " "  =~  /\h/      # Match, space is horizontal whitespace.
 414  " "  =~  /\v/      # No match, space is not vertical whitespace.
 415  "\r" =~  /\v/      # Match, a return is vertical whitespace.
 416
 417  "a"  =~  /\pL/     # Match, "a" is a letter.
 418  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
 419
 420  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
 421                            # 'THAI CHARACTER SO SO', and that's in
 422                            # Thai Unicode class.
 423  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
 424
 425 It is worth emphasizing that C<\d>, C<\w>, etc, match single characters, not
 426 complete numbers or words. To match a number (that consists of digits),
 427 use C<\d+>; to match a word, use C<\w+>.  But be aware of the security
 428 considerations in doing so, as mentioned above.
 429
 430 =head2 Bracketed Character Classes
 431
 432 The third form of character class you can use in Perl regular expressions
 433 is the bracketed character class.  In its simplest form, it lists the characters
 434 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
 435 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
 436 character classes, exactly one character is matched.* To match
 437 a longer string consisting of characters mentioned in the character
 438 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
 439 instance, C<[aeiou]+> matches one or more lowercase English vowels.
 440
 441 Repeating a character in a character class has no
 442 effect; it's considered to be in the set only once.
 443
 444 Examples:
 445
 446  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
 447  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
 448  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
 449                            # a single character.
 450  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
 451
 452  -------
 453
 454 * There is an exception to a bracketed character class matching a
 455 single character only.  When the class is to match caselessly under C</i>
 456 matching rules, and a character that is explicitly mentioned inside the
 457 class matches a
 458 multiple-character sequence caselessly under Unicode rules, the class
 459 (when not L<inverted|/Negation>) will also match that sequence.  For
 460 example, Unicode says that the letter C<LATIN SMALL LETTER SHARP S>
 461 should match the sequence C<ss> under C</i> rules.  Thus,
 462
 463  'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i             # Matches
 464  'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i    # Matches
 465
 466 For this to happen, the character must be explicitly specified, and not
 467 be part of a multi-character range (not even as one of its endpoints).
 468 (L</Character Ranges> will be explained shortly.)  Therefore,
 469
 470  'ss' =~ /\A[\0-\x{ff}]\z/i        # Doesn't match
 471  'ss' =~ /\A[\0-\N{LATIN SMALL LETTER SHARP S}]\z/i    # No match
 472  'ss' =~ /\A[\xDF-\xDF]\z/i    # Matches on ASCII platforms, since \XDF
 473                                # is LATIN SMALL LETTER SHARP S, and the
 474                                # range is just a single element
 475
 476 Note that it isn't a good idea to specify these types of ranges anyway.
 477
 478 =head3 Special Characters Inside a Bracketed Character Class
 479
 480 Most characters that are meta characters in regular expressions (that
 481 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
 482 their special meaning and can be used inside a character class without
 483 the need to escape them. For instance, C<[()]> matches either an opening
 484 parenthesis, or a closing parenthesis, and the parens inside the character
 485 class don't group or capture.
 486
 487 Characters that may carry a special meaning inside a character class are:
 488 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
 489 escaped with a backslash, although this is sometimes not needed, in which
 490 case the backslash may be omitted.
 491
 492 The sequence C<\b> is special inside a bracketed character class. While
 493 outside the character class, C<\b> is an assertion indicating a point
 494 that does not have either two word characters or two non-word characters
 495 on either side, inside a bracketed character class, C<\b> matches a
 496 backspace character.
 497
 498 The sequences
 499 C<\a>,
 500 C<\c>,
 501 C<\e>,
 502 C<\f>,
 503 C<\n>,
 504 C<\N{I<NAME>}>,
 505 C<\N{U+I<hex char>}>,
 506 C<\r>,
 507 C<\t>,
 508 and
 509 C<\x>
 510 are also special and have the same meanings as they do outside a
 511 bracketed character class.  (However, inside a bracketed character
 512 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
 513 one in the sequence is used, with a warning.)
 514
 515 Also, a backslash followed by two or three octal digits is considered an octal
 516 number.
 517
 518 A C<[> is not special inside a character class, unless it's the start of a
 519 POSIX character class (see L</POSIX Character Classes> below). It normally does
 520 not need escaping.
 521
 522 A C<]> is normally either the end of a POSIX character class (see
 523 L</POSIX Character Classes> below), or it signals the end of the bracketed
 524 character class.  If you want to include a C<]> in the set of characters, you
 525 must generally escape it.
 526
 527 However, if the C<]> is the I<first> (or the second if the first
 528 character is a caret) character of a bracketed character class, it
 529 does not denote the end of the class (as you cannot have an empty class)
 530 and is considered part of the set of characters that can be matched without
 531 escaping.
 532
 533 Examples:
 534
 535  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
 536  "\cH" =~ /[\b]/      #  Match, \b inside in a character class.
 537                       #  is equivalent to a backspace.
 538  "]"   =~ /[][]/      #  Match, as the character class contains.
 539                       #  both [ and ].
 540  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
 541                       #  containing just ], and the character class is
 542                       #  followed by a ].
 543
 544 =head3 Character Ranges
 545
 546 It is not uncommon to want to match a range of characters. Luckily, instead
 547 of listing all characters in the range, one may use the hyphen (C<->).
 548 If inside a bracketed character class you have two characters separated
 549 by a hyphen, it's treated as if all characters between the two were in
 550 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
 551 matches any lowercase letter from the first half of the ASCII alphabet.
 552
 553 Note that the two characters on either side of the hyphen are not
 554 necessarily both letters or both digits. Any character is possible,
 555 although not advisable.  C<['-?]> contains a range of characters, but
 556 most people will not know which characters that means.  Furthermore,
 557 such ranges may lead to portability problems if the code has to run on
 558 a platform that uses a different character set, such as EBCDIC.
 559
 560 If a hyphen in a character class cannot syntactically be part of a range, for
 561 instance because it is the first or the last character of the character class,
 562 or if it immediately follows a range, the hyphen isn't special, and so is
 563 considered a character to be matched literally.  If you want a hyphen in
 564 your set of characters to be matched and its position in the class is such
 565 that it could be considered part of a range, you must escape that hyphen
 566 with a backslash.
 567
 568 Examples:
 569
 570  [a-z]       #  Matches a character that is a lower case ASCII letter.
 571  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
 572              #  the letter 'z'.
 573  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
 574  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
 575              #  hyphen ('-'), or the letter 'm'.
 576  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
 577              #  (But not on an EBCDIC platform).
 578
 579
 580 =head3 Negation
 581
 582 It is also possible to instead list the characters you do not want to
 583 match. You can do so by using a caret (C<^>) as the first character in the
 584 character class. For instance, C<[^a-z]> matches any character that is not a
 585 lowercase ASCII letter, which therefore includes more than a million
 586 Unicode code points.  The class is said to be "negated" or "inverted".
 587
 588 This syntax make the caret a special character inside a bracketed character
 589 class, but only if it is the first character of the class. So if you want
 590 the caret as one of the characters to match, either escape the caret or
 591 else don't list it first.
 592
 593 In inverted bracketed character classes, Perl ignores the Unicode rules
 594 that normally say that certain characters should match a sequence of
 595 multiple characters under caseless C</i> matching.  Following those
 596 rules could lead to highly confusing situations:
 597
 598  "ss" =~ /^[^\xDF]+$/ui;   # Matches!
 599
 600 This should match any sequences of characters that aren't C<\xDF> nor
 601 what C<\xDF> matches under C</i>.  C<"s"> isn't C<\xDF>, but Unicode
 602 says that C<"ss"> is what C<\xDF> matches under C</i>.  So which one
 603 "wins"? Do you fail the match because the string has C<ss> or accept it
 604 because it has an C<s> followed by another C<s>?  Perl has chosen the
 605 latter.
 606
 607 Examples:
 608
 609  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
 610  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
 611  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
 612  "^"  =~  /[x^]/       #  Match, caret is not special here.
 613
 614 =head3 Backslash Sequences
 615
 616 You can put any backslash sequence character class (with the exception of
 617 C<\N> and C<\R>) inside a bracketed character class, and it will act just
 618 as if you had put all characters matched by the backslash sequence inside the
 619 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
 620 of the lowercase letters between 'a' and 'f' inclusive.
 621
 622 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
 623 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
 624 for the same reason that a dot C<.> inside a bracketed character class loses
 625 its special meaning: it matches nearly anything, which generally isn't what you
 626 want to happen.
 627
 628
 629 Examples:
 630
 631  /[\p{Thai}\d]/     # Matches a character that is either a Thai
 632                     # character, or a digit.
 633  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
 634                     # character, nor a parenthesis.
 635
 636 Backslash sequence character classes cannot form one of the endpoints
 637 of a range.  Thus, you can't say:
 638
 639  /[\p{Thai}-\d]/     # Wrong!
 640
 641 =head3 POSIX Character Classes
 642 X<character class> X<\p> X<\p{}>
 643 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
 644 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
 645
 646 POSIX character classes have the form C<[:class:]>, where I<class> is
 647 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
 648 I<inside> bracketed character classes, and are a convenient and descriptive
 649 way of listing a group of characters.
 650
 651 Be careful about the syntax,
 652
 653  # Correct:
 654  $string =~ /[[:alpha:]]/
 655
 656  # Incorrect (will warn):
 657  $string =~ /[:alpha:]/
 658
 659 The latter pattern would be a character class consisting of a colon,
 660 and the letters C<a>, C<l>, C<p> and C<h>.
 661 POSIX character classes can be part of a larger bracketed character class.
 662 For example,
 663
 664  [01[:alpha:]%]
 665
 666 is valid and matches '0', '1', any alphabetic character, and the percent sign.
 667
 668 Perl recognizes the following POSIX character classes:
 669
 670  alpha  Any alphabetical character ("[A-Za-z]").
 671  alnum  Any alphanumeric character ("[A-Za-z0-9]").
 672  ascii  Any character in the ASCII character set.
 673  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
 674  cntrl  Any control character.  See Note [2] below.
 675  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
 676  graph  Any printable character, excluding a space.  See Note [3] below.
 677  lower  Any lowercase character ("[a-z]").
 678  print  Any printable character, including a space.  See Note [4] below.
 679  punct  Any graphical character excluding "word" characters.  Note [5].
 680  space  Any whitespace character. "\s" including the vertical tab
 681         ("\cK").
 682  upper  Any uppercase character ("[A-Z]").
 683  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
 684  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
 685
 686 Most POSIX character classes have two Unicode-style C<\p> property
 687 counterparts.  (They are not official Unicode properties, but Perl extensions
 688 derived from official Unicode properties.)  The table below shows the relation
 689 between POSIX character classes and these counterparts.
 690
 691 One counterpart, in the column labelled "ASCII-range Unicode" in
 692 the table, matches only characters in the ASCII character set.
 693
 694 The other counterpart, in the column labelled "Full-range Unicode", matches any
 695 appropriate characters in the full Unicode character set.  For example,
 696 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
 697 character in the entire Unicode character set considered alphabetic.
 698 An entry in the column labelled "backslash sequence" is a (short)
 699 equivalent.
 700
 701  [[:...:]]      ASCII-range          Full-range  backslash  Note
 702                  Unicode              Unicode     sequence
 703  -----------------------------------------------------
 704    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
 705    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
 706    ascii      \p{ASCII}
 707    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
 708                                    or \p{HorizSpace}        [1]
 709    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
 710    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
 711    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
 712    lower      \p{PosixLower}       \p{XPosixLower}
 713    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
 714    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
 715               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
 716    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
 717    upper      \p{PosixUpper}       \p{XPosixUpper}
 718    word       \p{PosixWord}        \p{XPosixWord}   \w
 719    xdigit     \p{PosixXDigit}      \p{XPosixXDigit}
 720
 721 =over 4
 722
 723 =item [1]
 724
 725 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
 726
 727 =item [2]
 728
 729 Control characters don't produce output as such, but instead usually control
 730 the terminal somehow: for example, newline and backspace are control characters.
 731 In the ASCII range, characters whose code points are between 0 and 31 inclusive,
 732 plus 127 (C<DEL>) are control characters.
 733
 734 =item [3]
 735
 736 Any character that is I<graphical>, that is, visible. This class consists
 737 of all alphanumeric characters and all punctuation characters.
 738
 739 =item [4]
 740
 741 All printable characters, which is the set of all graphical characters
 742 plus those whitespace characters which are not also controls.
 743
 744 =item [5]
 745
 746 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
 747 non-controls, non-alphanumeric, non-space characters:
 748 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
 749 it could alter the behavior of C<[[:punct:]]>).
 750
 751 The similarly named property, C<\p{Punct}>, matches a somewhat different
 752 set in the ASCII range, namely
 753 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing the nine
 754 characters C<[$+E<lt>=E<gt>^`|~]>.
 755 This is because Unicode splits what POSIX considers to be punctuation into two
 756 categories, Punctuation and Symbols.
 757
 758 C<\p{XPosixPunct}> and (under Unicode rules) C<[[:punct:]]>, match what
 759 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
 760 matches.  This is different than strictly matching according to
 761 C<\p{Punct}>.  Another way to say it is that
 762 if Unicode rules are in effect, C<[[:punct:]]> matches all characters
 763 that Unicode considers punctuation, plus all ASCII-range characters that
 764 Unicode considers symbols.
 765
 766 =item [6]
 767
 768 C<\p{SpacePerl}> and C<\p{Space}> match identically starting with Perl
 769 v5.18.  In earlier versions, these differ only in that in non-locale
 770 matching, C<\p{SpacePerl}> does not match the vertical tab, C<\cK>.
 771 Same for the two ASCII-only range forms.
 772
 773 =back
 774
 775 There are various other synonyms that can be used besides the names
 776 listed in the table.  For example, C<\p{PosixAlpha}> can be written as
 777 C<\p{Alpha}>.  All are listed in
 778 L<perluniprops/Properties accessible through \p{} and \P{}>,
 779 plus all characters matched by each ASCII-range property.
 780
 781 Both the C<\p> counterparts always assume Unicode rules are in effect.
 782 On ASCII platforms, this means they assume that the code points from 128
 783 to 255 are Latin-1, and that means that using them under locale rules is
 784 unwise unless the locale is guaranteed to be Latin-1 or UTF-8.  In contrast, the
 785 POSIX character classes are useful under locale rules.  They are
 786 affected by the actual rules in effect, as follows:
 787
 788 =over
 789
 790 =item If the C</a> modifier, is in effect ...
 791
 792 Each of the POSIX classes matches exactly the same as their ASCII-range
 793 counterparts.
 794
 795 =item otherwise ...
 796
 797 =over
 798
 799 =item For code points above 255 ...
 800
 801 The POSIX class matches the same as its Full-range counterpart.
 802
 803 =item For code points below 256 ...
 804
 805 =over
 806
 807 =item if locale rules are in effect ...
 808
 809 The POSIX class matches according to the locale, except that
 810 C<word> uses the platform's native underscore character, no matter what
 811 the locale is.
 812
 813 =item if Unicode rules are in effect ...
 814
 815 The POSIX class matches the same as the Full-range counterpart.
 816
 817 =item otherwise ...
 818
 819 The POSIX class matches the same as the ASCII range counterpart.
 820
 821 =back
 822
 823 =back
 824
 825 =back
 826
 827 Which rules apply are determined as described in
 828 L<perlre/Which character set modifier is in effect?>.
 829
 830 It is proposed to change this behavior in a future release of Perl so that
 831 whether or not Unicode rules are in effect would not change the
 832 behavior:  Outside of locale, the POSIX classes
 833 would behave like their ASCII-range counterparts.  If you wish to
 834 comment on this proposal, send email to C<perl5-porters@perl.org>.
 835
 836 =head4 Negation of POSIX character classes
 837 X<character class, negation>
 838
 839 A Perl extension to the POSIX character class is the ability to
 840 negate it. This is done by prefixing the class name with a caret (C<^>).
 841 Some examples:
 842
 843      POSIX         ASCII-range     Full-range  backslash
 844                     Unicode         Unicode    sequence
 845  -----------------------------------------------------
 846  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
 847  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
 848                 \P{PerlSpace}   \P{XPerlSpace}    \S
 849  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
 850
 851 The backslash sequence can mean either ASCII- or Full-range Unicode,
 852 depending on various factors as described in L<perlre/Which character set modifier is in effect?>.
 853
 854 =head4 [= =] and [. .]
 855
 856 Perl recognizes the POSIX character classes C<[=class=]> and
 857 C<[.class.]>, but does not (yet?) support them.  Any attempt to use
 858 either construct raises an exception.
 859
 860 =head4 Examples
 861
 862  /[[:digit:]]/            # Matches a character that is a digit.
 863  /[01[:lower:]]/          # Matches a character that is either a
 864                           # lowercase letter, or '0' or '1'.
 865  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
 866                           # except the letters 'a' to 'f' and 'A' to
 867                           # 'F'.  This is because the main character
 868                           # class is composed of two POSIX character
 869                           # classes that are ORed together, one that
 870                           # matches any digit, and the other that
 871                           # matches anything that isn't a hex digit.
 872                           # The OR adds the digits, leaving only the
 873                           # letters 'a' to 'f' and 'A' to 'F' excluded.
 874
 875 =head3 Extended Bracketed Character Classes
 876 X<character class>
 877 X<set operations>
 878
 879 This is a fancy bracketed character class that can be used for more
 880 readable and less error-prone classes, and to perform set operations,
 881 such as intersection. An example is
 882
 883  /(?[ \p{Thai} & \p{Digit} ])/
 884
 885 This will match all the digit characters that are in the Thai script.
 886
 887 This is an experimental feature available starting in 5.18, and is
 888 subject to change as we gain field experience with it.  Any attempt to
 889 use it will raise a warning, unless disabled via
 890
 891  no warnings "experimental::regex_sets";
 892
 893 Comments on this feature are welcome; send email to
 894 C<perl5-porters@perl.org>.
 895
 896 We can extend the example above:
 897
 898  /(?[ ( \p{Thai} + \p{Lao} ) & \p{Digit} ])/
 899
 900 This matches digits that are in either the Thai or Laotian scripts.
 901
 902 Notice the white space in these examples.  This construct always has
 903 the C<E<sol>x> modifier turned on.
 904
 905 The available binary operators are:
 906
 907  &    intersection
 908  +    union
 909  |    another name for '+', hence means union
 910  -    subtraction (the result matches the set consisting of those
 911       code points matched by the first operand, excluding any that
 912       are also matched by the second operand)
 913  ^    symmetric difference (the union minus the intersection).  This
 914       is like an exclusive or, in that the result is the set of code
 915       points that are matched by either, but not both, of the
 916       operands.
 917
 918 There is one unary operator:
 919
 920  !    complement
 921
 922 All the binary operators left associate, and are of equal precedence.
 923 The unary operator right associates, and has higher precedence.  Use
 924 parentheses to override the default associations.  Some feedback we've
 925 received indicates a desire for intersection to have higher precedence
 926 than union.  This is something that feedback from the field may cause us
 927 to change in future releases; you may want to parenthesize copiously to
 928 avoid such changes affecting your code, until this feature is no longer
 929 considered experimental.
 930
 931 The main restriction is that everything is a metacharacter.  Thus,
 932 you cannot refer to single characters by doing something like this:
 933
 934  /(?[ a + b ])/ # Syntax error!
 935
 936 The easiest way to specify an individual typable character is to enclose
 937 it in brackets:
 938
 939  /(?[ [a] + [b] ])/
 940
 941 (This is the same thing as C<[ab]>.)  You could also have said the
 942 equivalent:
 943
 944  /(?[[ a b ]])/
 945
 946 (You can, of course, specify single characters by using, C<\x{...}>,
 947 C<\N{...}>, etc.)
 948
 949 This last example shows the use of this construct to specify an ordinary
 950 bracketed character class without additional set operations.  Note the
 951 white space within it; C<E<sol>x> is turned on even within bracketed
 952 character classes, except you can't have comments inside them.  Hence,
 953
 954  (?[ [#] ])
 955
 956 matches the literal character "#".  To specify a literal white space character,
 957 you can escape it with a backslash, like:
 958
 959  /(?[ [ a e i o u \  ] ])/
 960
 961 This matches the English vowels plus the SPACE character.
 962 All the other escapes accepted by normal bracketed character classes are
 963 accepted here as well; but unrecognized escapes that generate warnings
 964 in normal classes are fatal errors here.
 965
 966 All warnings from these class elements are fatal, as well as some
 967 practices that don't currently warn.  For example you cannot say
 968
 969  /(?[ [ \xF ] ])/     # Syntax error!
 970
 971 You have to have two hex digits after a braceless C<\x> (use a leading
 972 zero to make two).  These restrictions are to lower the incidence of
 973 typos causing the class to not match what you thought it would.
 974
 975 The final difference between regular bracketed character classes and
 976 these, is that it is not possible to get these to match a
 977 multi-character fold.  Thus,
 978
 979  /(?[ [\xDF] ])/iu
 980
 981 does not match the string C<ss>.
 982
 983 You don't have to enclose POSIX class names inside double brackets,
 984 hence both of the following work:
 985
 986  /(?[ [:word:] - [:lower:] ])/
 987  /(?[ [[:word:]] - [[:lower:]] ])/
 988
 989 Any contained POSIX character classes, including things like C<\w> and C<\D>
 990 respect the C<E<sol>a> (and C<E<sol>aa>) modifiers.
 991
 992 C<< (?[ ]) >> is a regex-compile-time construct.  Any attempt to use
 993 something which isn't knowable at the time the containing regular
 994 expression is compiled is a fatal error.  In practice, this means
 995 just three limitations:
 996
 997 =over 4
 998
 999 =item 1
1000
1001 This construct cannot be used within the scope of
1002 C<use locale> (or the C<E<sol>l> regex modifier).
1003
1004 =item 2
1005
1006 Any
1007 L<user-defined property|perlunicode/"User-Defined Character Properties">
1008 used must be already defined by the time the regular expression is
1009 compiled (but note that this construct can be used instead of such
1010 properties).
1011
1012 =item 3
1013
1014 A regular expression that otherwise would compile
1015 using C<E<sol>d> rules, and which uses this construct will instead
1016 use C<E<sol>u>.  Thus this construct tells Perl that you don't want
1017 C<E<sol>d> rules for the entire regular expression containing it.
1018
1019 =back
1020
1021 The C<E<sol>x> processing within this class is an extended form.
1022 Besides the characters that are considered white space in normal C</x>
1023 processing, there are 5 others, recommended by the Unicode standard:
1024
1025  U+0085 NEXT LINE
1026  U+200E LEFT-TO-RIGHT MARK
1027  U+200F RIGHT-TO-LEFT MARK
1028  U+2028 LINE SEPARATOR
1029  U+2029 PARAGRAPH SEPARATOR
1030
1031 Note that skipping white space applies only to the interior of this
1032 construct.  There must not be any space between any of the characters
1033 that form the initial C<(?[>.  Nor may there be space between the
1034 closing C<])> characters.
1035
1036 Just as in all regular expressions, the pattern can be built up by
1037 including variables that are interpolated at regex compilation time.
1038 Care must be taken to ensure that you are getting what you expect.  For
1039 example:
1040
1041  my $thai_or_lao = '\p{Thai} + \p{Lao}';
1042  ...
1043  qr/(?[ \p{Digit} & $thai_or_lao ])/;
1044
1045 compiles to
1046
1047  qr/(?[ \p{Digit} & \p{Thai} + \p{Lao} ])/;
1048
1049 But this does not have the effect that someone reading the code would
1050 likely expect, as the intersection applies just to C<\p{Thai}>,
1051 excluding the Laotian.  Pitfalls like this can be avoided by
1052 parenthesizing the component pieces:
1053
1054  my $thai_or_lao = '( \p{Thai} + \p{Lao} )';
1055
1056 But any modifiers will still apply to all the components:
1057
1058  my $lower = '\p{Lower} + \p{Digit}';
1059  qr/(?[ \p{Greek} & $lower ])/i;
1060
1061 matches upper case things.  You can avoid surprises by making the
1062 components into instances of this construct by compiling them:
1063
1064  my $thai_or_lao = qr/(?[ \p{Thai} + \p{Lao} ])/;
1065  my $lower = qr/(?[ \p{Lower} + \p{Digit} ])/;
1066
1067 When these are embedded in another pattern, what they match does not
1068 change, regardless of parenthesization or what modifiers are in effect
1069 in that outer pattern.
1070
1071 Due to the way that Perl parses things, your parentheses and brackets
1072 may need to be balanced, even including comments.  If you run into any
1073 examples, please send them to C<perlbug@perl.org>, so that we can have a
1074 concrete example for this man page.
1075
1076 We may change it so that things that remain legal uses in normal bracketed
1077 character classes might become illegal within this experimental
1078 construct.  One proposal, for example, is to forbid adjacent uses of the
1079 same character, as in C<(?[ [aa] ])>.  The motivation for such a change
1080 is that this usage is likely a typo, as the second "a" adds nothing.