t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still current
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17 # Measure the elapsed wallclock time.
  18 my $t0 = time();
  19
  20 # If we're doing deparse tests, ignore failures for these
  21 my $deparse_failures;
  22
  23 # And skip even running these
  24 my $deparse_skips;
  25
  26 # directories with special sets of test switches
  27 my %dir_to_switch =
  28     (base => '',
  29      comp => '',
  30      run => '',
  31      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  32      );
  33
  34 # "not absolute" is the default, as it saves some fakery within TestInit
  35 # which can perturb tests, and takes CPU. Working with the upstream author of
  36 # any of these, to figure out how to remove them from this list, considered
  37 # "a good thing".
  38 my %abs = (
  39            '../cpan/Archive-Tar' => 1,
  40            '../cpan/AutoLoader' => 1,
  41            '../cpan/CPAN' => 1,
  42            '../cpan/Devel-PPPort' => 1,
  43            '../cpan/Encode' => 1,
  44            '../cpan/ExtUtils-Command' => 1,
  45            '../cpan/ExtUtils-Constant' => 1,
  46            '../cpan/ExtUtils-Install' => 1,
  47            '../cpan/ExtUtils-MakeMaker' => 1,
  48            '../cpan/ExtUtils-Manifest' => 1,
  49            '../cpan/File-Fetch' => 1,
  50            '../cpan/IPC-Cmd' => 1,
  51            '../cpan/IPC-SysV' => 1,
  52            '../cpan/Locale-Codes' => 1,
  53            '../cpan/Module-Load' => 1,
  54            '../cpan/Module-Load-Conditional' => 1,
  55            '../cpan/Parse-CPAN-Meta' => 1,
  56            '../cpan/Pod-Simple' => 1,
  57            '../cpan/Test-Simple' => 1,
  58            '../cpan/podlators' => 1,
  59            '../dist/Cwd' => 1,
  60            '../dist/ExtUtils-ParseXS' => 1,
  61            '../dist/Tie-File' => 1,
  62           );
  63
  64 my %temp_no_core =
  65     ('../cpan/B-Debug' => 1,
  66      '../cpan/Compress-Raw-Bzip2' => 1,
  67      '../cpan/Compress-Raw-Zlib' => 1,
  68      '../cpan/Devel-PPPort' => 1,
  69      '../cpan/Getopt-Long' => 1,
  70      '../cpan/IO-Compress' => 1,
  71      '../cpan/MIME-Base64' => 1,
  72      '../cpan/parent' => 1,
  73      '../cpan/Parse-CPAN-Meta' => 1,
  74      '../cpan/Pod-Simple' => 1,
  75      '../cpan/podlators' => 1,
  76      '../cpan/Test-Simple' => 1,
  77      '../cpan/Tie-RefHash' => 1,
  78      '../cpan/Unicode-Collate' => 1,
  79      '../cpan/Unicode-Normalize' => 1,
  80     );
  81
  82 # delete env vars that may influence the results
  83 # but allow override via *_TEST env var if wanted
  84 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  85 my @bad_env_vars = qw(
  86     PERL5LIB PERLLIB PERL5OPT
  87     PERL_YAML_BACKEND PERL_JSON_BACKEND
  88 );
  89
  90 for my $envname (@bad_env_vars) {
  91     my $override = $ENV{"${envname}_TEST"};
  92     if (defined $override) {
  93         warn "$0: $envname=$override\n";
  94         $ENV{$envname} = $override;
  95     }
  96     else {
  97         delete $ENV{$envname};
  98     }
  99 }
 100
 101 # Location to put the Valgrind log.
 102 our $Valgrind_Log;
 103
 104 my %skip = (
 105             '.' => 1,
 106             '..' => 1,
 107             'CVS' => 1,
 108             'RCS' => 1,
 109             'SCCS' => 1,
 110             '.svn' => 1,
 111            );
 112
 113
 114 if ($::do_nothing) {
 115     return 1;
 116 }
 117
 118 $| = 1;
 119
 120 # for testing TEST only
 121 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 122 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 123
 124 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 125 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 126
 127 # String eval to avoid loading File::Glob on non-miniperl.
 128 # (Windows only uses this script for miniperl.)
 129 @ARGV = eval 'map glob, @ARGV' if $^O eq 'MSWin32';
 130
 131 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 132
 133 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 134 # can't rely on require working.
 135 {
 136     my @argv = ();
 137     foreach my $idx (0..$#ARGV) {
 138         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 139         $::benchmark = 1 if $1 eq 'benchmark';
 140         $::core    = 1 if $1 eq 'core';
 141         $::verbose = 1 if $1 eq 'v';
 142         $::torture = 1 if $1 eq 'torture';
 143         $::with_utf8 = 1 if $1 eq 'utf8';
 144         $::with_utf16 = 1 if $1 eq 'utf16';
 145         $::taintwarn = 1 if $1 eq 'taintwarn';
 146         if ($1 =~ /^deparse(,.+)?$/) {
 147             $::deparse = 1;
 148             $::deparse_opts = $1;
 149             _process_deparse_config();
 150         }
 151     }
 152     @ARGV = @argv;
 153 }
 154
 155 chdir 't' if -f 't/TEST';
 156 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 157     @INC = '../lib';
 158 }
 159
 160 die "You need to run \"make test\" first to set things up.\n"
 161   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 162
 163 # check leakage for embedders
 164 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 165 # check existence of all symbols
 166 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
 167
 168 $ENV{EMXSHELL} = 'sh';        # For OS/2
 169
 170 if ($show_elapsed_time) { require Time::HiRes }
 171 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 172
 173 # Roll your own File::Find!
 174 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
 175 sub _find_files {
 176     my($patt, @dirs) = @_;
 177     for my $dir (@dirs) {
 178         opendir DIR, $dir or die "Trouble opening $dir: $!";
 179         foreach my $f (sort { $a cmp $b } readdir DIR) {
 180             next if $skip{$f};
 181
 182             my $fullpath = "$dir/$f";
 183
 184             if (-d $fullpath) {
 185                 _find_files($patt, $fullpath);
 186             } elsif ($f =~ /$patt/) {
 187                 push @found, $fullpath;
 188             }
 189         }
 190     }
 191     @found;
 192 }
 193
 194
 195 # Scan the text of the test program to find switches and special options
 196 # we might need to apply.
 197 sub _scan_test {
 198     my($test, $type) = @_;
 199
 200     open(my $script, "<", $test) or die "Can't read $test.\n";
 201     my $first_line = <$script>;
 202
 203     $first_line =~ tr/\0//d if $::with_utf16;
 204
 205     my $switch = "";
 206     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 207         $switch = "-$1";
 208     } else {
 209         if ($::taintwarn) {
 210             # not all tests are expected to pass with this option
 211             $switch = '-t';
 212         } else {
 213             $switch = '';
 214         }
 215     }
 216
 217     my $file_opts = "";
 218     if ($type eq 'deparse') {
 219         # Look for #line directives which change the filename
 220         while (<$script>) {
 221             $file_opts = $file_opts . ",-f$3$4"
 222               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 223         }
 224     }
 225
 226     close $script;
 227
 228     my $perl = $^O eq 'MSWin32' ? '.\perl' : './perl';
 229     my $lib  = '../lib';
 230     my $run_dir;
 231     my $return_dir;
 232
 233     $test =~ /^(.+)\/[^\/]+/;
 234     my $dir = $1;
 235     my $testswitch = $dir_to_switch{$dir};
 236     if (!defined $testswitch) {
 237         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 238             $run_dir = $1;
 239             $return_dir = '../../t';
 240             $lib = '../../lib';
 241             $perl = '../../t/perl';
 242             $testswitch = "-I../.. -MTestInit=U2T";
 243             if ($2 eq 'cpan' || $2 eq 'dist') {
 244                 if($abs{$run_dir}) {
 245                     $testswitch = $testswitch . ',A';
 246                 }
 247                 if ($temp_no_core{$run_dir}) {
 248                     $testswitch = $testswitch . ',NC';
 249                 }
 250             }
 251         } elsif ($test =~ m!^\.\./lib!) {
 252             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 253         } else {
 254             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 255         }
 256     }
 257
 258     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 259
 260     my %options = (
 261         perl => $perl,
 262         lib => $lib,
 263         test => $test,
 264         run_dir => $run_dir,
 265         return_dir => $return_dir,
 266         testswitch => $testswitch,
 267         utf8 => $utf8,
 268         file => $file_opts,
 269         switch => $switch,
 270     );
 271
 272     return \%options;
 273 }
 274
 275 sub _cmd {
 276     my($options, $type) = @_;
 277
 278     my $test = $options->{test};
 279
 280     my $cmd;
 281     if ($type eq 'deparse') {
 282         my $perl = "$options->{perl} $options->{testswitch}";
 283         my $lib = $options->{lib};
 284
 285         $cmd = (
 286           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 287           "-l$::deparse_opts$options->{file} ".
 288           "$test > $test.dp ".
 289           "&& $perl $options->{switch} -I$lib $test.dp"
 290         );
 291     }
 292     elsif ($type eq 'perl') {
 293         my $perl = $options->{perl};
 294         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 295
 296         if ($ENV{PERL_VALGRIND}) {
 297             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 298             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 299             if ($options->{run_dir}) {
 300                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 301             }
 302             my $vg_opts = $ENV{VG_OPTS}
 303                //   "--log-file=$Valgrind_Log "
 304                   . "--suppressions=$perl_supp --leak-check=yes "
 305                   . "--leak-resolution=high --show-reachable=yes "
 306                   . "--num-callers=50 --track-origins=yes";
 307             # Force logging if not asked for (so cachegrind reporting works below)
 308             if ($vg_opts !~ /--log-file/) {
 309                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
 310             }
 311             $perl = "$valgrind_exe $vg_opts $perl";
 312         }
 313
 314         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 315         $cmd = $perl . _quote_args($args) . " $test $redir";
 316     }
 317     return $cmd;
 318 }
 319
 320 sub _before_fork {
 321     my ($options) = @_;
 322
 323     if ($options->{run_dir}) {
 324         my $run_dir = $options->{run_dir};
 325         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 326     }
 327
 328     # Remove previous valgrind output otherwise it will interfere
 329     my $test = $options->{test};
 330
 331     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 332
 333     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
 334         unlink $Valgrind_Log
 335             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 336     }
 337
 338     return;
 339 }
 340
 341 sub _after_fork {
 342     my ($options) = @_;
 343
 344     if ($options->{return_dir}) {
 345         my $return_dir = $options->{return_dir};
 346         chdir $return_dir
 347            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 348     }
 349
 350     return;
 351 }
 352
 353 sub _run_test {
 354     my ($test, $type) = @_;
 355
 356     my $options = _scan_test($test, $type);
 357     # $test might have changed if we're in ext/Foo, so don't use it anymore
 358     # from now on. Use $options->{test} instead.
 359
 360     _before_fork($options);
 361
 362     my $cmd = _cmd($options, $type);
 363
 364     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 365
 366     _after_fork($options);
 367
 368     # Our environment may force us to use UTF-8, but we can't be sure that
 369     # anything we're reading from will be generating (well formed) UTF-8
 370     # This may not be the best way - possibly we should unset ${^OPEN} up
 371     # top?
 372     binmode $results;
 373
 374     return $results;
 375 }
 376
 377 sub _quote_args {
 378     my ($args) = @_;
 379     my $argstring = '';
 380
 381     foreach (split(/\s+/,$args)) {
 382        # In VMS protect with doublequotes because otherwise
 383        # DCL will lowercase -- unless already doublequoted.
 384        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 385        $argstring = $argstring . ' ' . $_;
 386     }
 387     return $argstring;
 388 }
 389
 390 sub _populate_hash {
 391     return unless defined $_[0];
 392     return map {$_, 1} split /\s+/, $_[0];
 393 }
 394
 395 sub _tests_from_manifest {
 396     my ($extensions, $known_extensions) = @_;
 397     my %skip;
 398     my %extensions = _populate_hash($extensions);
 399     my %known_extensions = _populate_hash($known_extensions);
 400
 401     foreach (keys %known_extensions) {
 402         $skip{$_} = 1 unless $extensions{$_};
 403     }
 404
 405     my @results;
 406     my $mani = '../MANIFEST';
 407     if (open(MANI, $mani)) {
 408         while (<MANI>) {
 409             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 410                 my $t = $1;
 411                 my $extension = $2;
 412
 413                 # XXX Generates way too many error lines currently.  Skip for
 414                 # v5.22
 415                 next if $t =~ /^cpan/ && ord("A") != 65;
 416
 417                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 418                     if (defined $extension) {
 419                         $extension =~ s!/t(:?/\S+)*$!!;
 420                         # XXX Do I want to warn that I'm skipping these?
 421                         next if $skip{$extension};
 422                         my $flat_extension = $extension;
 423                         $flat_extension =~ s!-!/!g;
 424                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 425                     }
 426                     my $path = "../$t";
 427                     push @results, $path;
 428                     $::path_to_name{$path} = $t;
 429                 }
 430             }
 431         }
 432         close MANI;
 433     } else {
 434         warn "$0: cannot open $mani: $!\n";
 435     }
 436     return @results;
 437 }
 438
 439 unless (@ARGV) {
 440     # base first, as TEST bails out if that can't run
 441     # then comp, to validate that require works
 442     # then run, to validate that -M works
 443     # then we know we can -MTestInit for everything else, making life simpler
 444     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro perf)) {
 445         _find_tests($dir);
 446     }
 447     unless ($::core) {
 448         _find_tests('porting');
 449         _find_tests("lib");
 450     }
 451     # Config.pm may be broken for make minitest. And this is only a refinement
 452     # for skipping tests on non-default builds, so it is allowed to fail.
 453     # What we want to to is make a list of extensions which we did not build.
 454     my $configsh = '../config.sh';
 455     my ($extensions, $known_extensions);
 456     if (-f $configsh) {
 457         open FH, $configsh or die "Can't open $configsh: $!";
 458         while (<FH>) {
 459             if (/^extensions=['"](.*)['"]$/) {
 460                 $extensions = $1;
 461             }
 462             elsif (/^known_extensions=['"](.*)['"]$/) {
 463                 $known_extensions = $1;
 464             }
 465         }
 466         if (!defined $known_extensions) {
 467             warn "No known_extensions line found in $configsh";
 468         }
 469         if (!defined $extensions) {
 470             warn "No extensions line found in $configsh";
 471         }
 472     }
 473     # The "complex" constructions of list return from a subroutine, and push of
 474     # a list, might fail if perl is really hosed, but they aren't needed for
 475     # make minitest, and the building of extensions will likely also fail if
 476     # something is that badly wrong.
 477     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 478     unless ($::core) {
 479         _find_tests('japh') if $::torture;
 480         _find_tests('benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 481         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
 482     }
 483 }
 484
 485 if ($::deparse) {
 486     _testprogs('deparse', '',   @ARGV);
 487 }
 488 elsif ($::with_utf16) {
 489     for my $e (0, 1) {
 490         for my $b (0, 1) {
 491             print STDERR "# ENDIAN $e BOM $b\n";
 492             my @UARGV;
 493             for my $a (@ARGV) {
 494                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 495                 my $f = $e ? "v" : "n";
 496                 push @UARGV, $u;
 497                 unlink($u);
 498                 if (open(A, $a)) {
 499                     if (open(U, ">$u")) {
 500                         print U pack("$f", 0xFEFF) if $b;
 501                         while (<A>) {
 502                             print U pack("$f*", unpack("C*", $_));
 503                         }
 504                         close(U);
 505                     }
 506                     close(A);
 507                 }
 508             }
 509             _testprogs('perl', '', @UARGV);
 510             unlink(@UARGV);
 511         }
 512     }
 513 }
 514 else {
 515     _testprogs('perl',    '',   @ARGV);
 516 }
 517
 518 sub _testprogs {
 519     my ($type, $args, @tests) = @_;
 520
 521     print <<'EOT' if ($type eq 'deparse');
 522 ------------------------------------------------------------------------------
 523 TESTING DEPARSER
 524 ------------------------------------------------------------------------------
 525 EOT
 526
 527     $::bad_files = 0;
 528
 529     foreach my $t (@tests) {
 530       unless (exists $::path_to_name{$t}) {
 531         my $tname = "t/$t";
 532         $::path_to_name{$t} = $tname;
 533       }
 534     }
 535     my $maxlen = 0;
 536     foreach (@::path_to_name{@tests}) {
 537         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 538         my $len = length ;
 539         $maxlen = $len if $len > $maxlen;
 540     }
 541     # + 3 : we want three dots between the test name and the "ok"
 542     my $dotdotdot = $maxlen + 3 ;
 543     my $grind_ct = 0;           # count of non-empty valgrind reports
 544     my $total_files = @tests;
 545     my $good_files = 0;
 546     my $tested_files  = 0;
 547     my $totmax = 0;
 548     my %failed_tests;
 549     my $toolnm;         # valgrind, cachegrind, perf
 550
 551     while (my $test = shift @tests) {
 552         my ($test_start_time, @starttimes) = 0;
 553         if ($show_elapsed_time) {
 554             $test_start_time = Time::HiRes::time();
 555             # times() reports usage by TEST, but we want usage of each
 556             # testprog it calls, so record accumulated times now,
 557             # subtract them out afterwards.  Ideally, we'd take times
 558             # in BEGIN/END blocks (giving better visibility of self vs
 559             # children of each testprog), but that would require some
 560             # IPC to send results back here, or a completely different
 561             # collection scheme (Storable isn't tuned for incremental use)
 562             @starttimes = times;
 563         }
 564         if ($test =~ /^$/) {
 565             next;
 566         }
 567         if ($type eq 'deparse' && $test =~ $deparse_skips) {
 568             next;
 569         }
 570         my $te = $::path_to_name{$test} . '.'
 571                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 572
 573         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 574             print $te;
 575             $te = '';
 576         }
 577
 578         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 579
 580         my $results = _run_test($test, $type);
 581
 582         my $failure;
 583         my $next = 0;
 584         my $seen_leader = 0;
 585         my $seen_ok = 0;
 586         my $trailing_leader = 0;
 587         my $max;
 588         my %todo;
 589         while (<$results>) {
 590             next if /^\s*$/; # skip blank lines
 591             if (/^1..$/ && ($^O eq 'VMS')) {
 592                 # VMS pipe bug inserts blank lines.
 593                 my $l2 = <$results>;
 594                 if ($l2 =~ /^\s*$/) {
 595                     $l2 = <$results>;
 596                 }
 597                 $_ = '1..' . $l2;
 598             }
 599             if ($::verbose) {
 600                 print $_;
 601             }
 602             unless (/^\#/) {
 603                 if ($trailing_leader) {
 604                     # shouldn't be anything following a postfix 1..n
 605                     $failure = 'FAILED--extra output after trailing 1..n';
 606                     last;
 607                 }
 608                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 609                     if ($seen_leader) {
 610                         $failure = 'FAILED--seen duplicate leader';
 611                         last;
 612                     }
 613                     $max = $1;
 614                     %todo = map { $_ => 1 } split / /, $3 if $3;
 615                     $totmax = $totmax + $max;
 616                     $tested_files = $tested_files + 1;
 617                     if ($seen_ok) {
 618                         # 1..n appears at end of file
 619                         $trailing_leader = 1;
 620                         if ($next != $max) {
 621                             $failure = "FAILED--expected $max tests, saw $next";
 622                             last;
 623                         }
 624                     }
 625                     else {
 626                         $next = 0;
 627                     }
 628                     $seen_leader = 1;
 629                 }
 630                 else {
 631                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 632                         unless ($seen_leader) {
 633                             unless ($seen_ok) {
 634                                 $next = 0;
 635                             }
 636                         }
 637                         $seen_ok = 1;
 638                         $next = $next + 1;
 639                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 640                         $num = $next unless $num;
 641
 642                         if ($num == $next) {
 643
 644                             # SKIP is essentially the same as TODO for t/TEST
 645                             # this still conforms to TAP:
 646                             # http://testanything.org/wiki/index.php/TAP_specification
 647                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 648                             $istodo = 1 if $todo{$num};
 649
 650                             if( $not && !$istodo ) {
 651                                 $failure = "FAILED at test $num";
 652                                 last;
 653                             }
 654                         }
 655                         else {
 656                             $failure ="FAILED--expected test $next, saw test $num";
 657                             last;
 658                         }
 659                     }
 660                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 661                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 662                     }
 663                     else {
 664                         # module tests are allowed extra output,
 665                         # because Test::Harness allows it
 666                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 667                         $failure = "FAILED--unexpected output at test $next";
 668                         last;
 669                     }
 670                 }
 671             }
 672         }
 673         my  @junk = <$results>;  # dump remaining output to prevent SIGPIPE
 674                                  # (so far happens only on os390)
 675         close $results;
 676         undef @junk;
 677
 678         if (not defined $failure) {
 679             $failure = 'FAILED--no leader found' unless $seen_leader;
 680         }
 681
 682         _check_valgrind(\$toolnm, \$grind_ct, \$test);
 683
 684         if ($type eq 'deparse' && !$ENV{KEEP_DEPARSE_FILES}) {
 685             unlink "./$test.dp";
 686         }
 687         if (not defined $failure and $next != $max) {
 688             $failure="FAILED--expected $max tests, saw $next";
 689         }
 690
 691         if( !defined $failure  # don't mask a test failure
 692             and $? )
 693         {
 694             $failure = "FAILED--non-zero wait status: $?";
 695         }
 696
 697         # Deparse? Should it have passed or failed?
 698         if ($type eq 'deparse' && $test =~ $deparse_failures) {
 699             if (!$failure) {
 700                 # Wait, it didn't fail? Great news! Tell someone!
 701                 $failure = "FAILED--all tests passed but test should have failed";
 702             } else {
 703                 # Bah, still failing. Mask it.
 704                 print "${te}skipped\n";
 705                 $tested_files = $tested_files - 1;
 706                 next;
 707             }
 708         }
 709
 710         if (defined $failure) {
 711             print "${te}$failure\n";
 712             $::bad_files = $::bad_files + 1;
 713             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
 714                 # Die if running under minitest (no DynaLoader).  Otherwise
 715                 # keep going, as  we know that Perl basically works, or we
 716                 # would not have been able to actually compile it all the way.
 717                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
 718             }
 719             $failed_tests{$test} = 1;
 720         }
 721         else {
 722             if ($max) {
 723                 my ($elapsed, $etms) = ("", 0);
 724                 if ( $show_elapsed_time ) {
 725                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 726                     $elapsed = sprintf(" %8.0f ms", $etms);
 727
 728                     my (@endtimes) = times;
 729                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 730                     splice @endtimes, 0, 2;    # drop self/harness times
 731                     $_ *= 1000 for @endtimes;  # and scale to ms
 732                     $timings{$test} = [$etms,@endtimes];
 733                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 734                 }
 735                 print "${te}ok$elapsed\n";
 736                 $good_files = $good_files + 1;
 737             }
 738             else {
 739                 print "${te}skipped\n";
 740                 $tested_files = $tested_files - 1;
 741             }
 742         }
 743     } # while tests
 744
 745     if ($::bad_files == 0) {
 746         if ($good_files) {
 747             print "All tests successful.\n";
 748             # XXX add mention of 'perlbug -ok' ?
 749         }
 750         else {
 751             die "FAILED--no tests were run for some reason.\n";
 752         }
 753     }
 754     else {
 755         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 756         my $s = $::bad_files == 1 ? "" : "s";
 757         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 758         for my $test ( sort keys %failed_tests ) {
 759             print "\t$test\n";
 760         }
 761         warn <<'SHRDLU_1';
 762 ### Since not all tests were successful, you may want to run some of
 763 ### them individually and examine any diagnostic messages they produce.
 764 ### See the INSTALL document's section on "make test".
 765 SHRDLU_1
 766         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 767 ### You have a good chance to get more information by running
 768 ###   ./perl harness
 769 ### in the 't' directory since most (>=80%) of the tests succeeded.
 770 SHRDLU_2
 771         if (eval {require Config; import Config; 1}) {
 772             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 773                 warn <<SHRDLU_3;
 774 ### You may have to set your dynamic library search path,
 775 ### $p, to point to the build directory:
 776 SHRDLU_3
 777                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 778                     warn <<SHRDLU_4a;
 779 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 780 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 781 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 782 SHRDLU_4a
 783                 } else {
 784                     warn <<SHRDLU_4b;
 785 ###   setenv $p `pwd`; cd t; ./perl harness
 786 ###   $p=`pwd`; export $p; cd t; ./perl harness
 787 ###   export $p=`pwd`; cd t; ./perl harness
 788 SHRDLU_4b
 789                 }
 790                 warn <<SHRDLU_5;
 791 ### for csh-style shells, like tcsh; or for traditional/modern
 792 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 793 SHRDLU_5
 794             }
 795         }
 796     }
 797     printf "Elapsed: %d sec\n", time() - $t0;
 798     my ($user,$sys,$cuser,$csys) = times;
 799     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 800                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 801     print "$tot\n";
 802     if ($good_files) {
 803         if (-d $show_elapsed_time) {
 804             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 805             # storable file there.  NB: the test cds to ./t/, so
 806             # relative path must account for that, ie ../../perf
 807             # points to dir next to source tree.
 808             require Storable;
 809             my @dt = localtime;
 810             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 811             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 812             Storable::store({ perf => \%timings,
 813                               gather_conf_platform_info(),
 814                               total => $tot,
 815                             }, $fn);
 816             print "wrote storable file: $fn\n";
 817         }
 818     }
 819
 820     _cleanup_valgrind(\$toolnm, \$grind_ct);
 821 }
 822 exit ($::bad_files != 0);
 823
 824 # Collect platform, config data that should allow comparing
 825 # performance data between different machines.  With enough data,
 826 # and/or clever statistical analysis, it should be possible to
 827 # determine the effect of config choices, more memory, etc
 828
 829 sub gather_conf_platform_info {
 830     # currently rather quick & dirty, and subject to change
 831     # for both content and format.
 832     require Config;
 833     my (%conf, @platform) = ();
 834     $conf{$_} = $Config::Config{$_} for
 835         grep /cc|git|config_arg\d+/, keys %Config::Config;
 836     if (-f '/proc/cpuinfo') {
 837         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 838         @platform = grep /name|cpu/, <$fh>;
 839         chomp $_ for @platform;
 840     }
 841     unshift @platform, $^O;
 842
 843     return (
 844         conf => \%conf,
 845         platform => {cpu => \@platform,
 846                      mem => [ grep s/\s+/ /,
 847                               grep chomp, `free` ],
 848                      load => [ grep chomp, `uptime` ],
 849         },
 850         host => (grep chomp, `hostname -f`),
 851         version => '0.03', # bump for conf, platform, or data collection changes
 852         );
 853 }
 854
 855 sub _check_valgrind {
 856     return unless $ENV{PERL_VALGRIND};
 857
 858     my ($toolnm, $grind_ct, $test) = @_;
 859
 860     $$toolnm = $ENV{VALGRIND};
 861     $$toolnm =~ s|.*/||;  # keep basename
 862     my @valgrind;       # gets content of file
 863     if (-e $Valgrind_Log) {
 864         if (open(V, $Valgrind_Log)) {
 865             @valgrind = <V>;
 866             close V;
 867         } else {
 868             warn "$0: Failed to open '$Valgrind_Log': $!\n";
 869         }
 870     }
 871     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
 872         $$toolnm = $1;
 873         if ($$toolnm eq 'perf') {
 874             # append perfs subcommand, not just stat
 875             my ($sub) = split /\s/, $ENV{VG_OPTS};
 876             $$toolnm .= "-$sub";
 877         }
 878         if (rename $Valgrind_Log, "$$test.$$toolnm") {
 879             $$grind_ct++;
 880         } else {
 881             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
 882         }
 883     }
 884     elsif (@valgrind) {
 885         my $leaks = 0;
 886         my $errors = 0;
 887         for my $i (0..$#valgrind) {
 888             local $_ = $valgrind[$i];
 889             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 890                 $errors = $errors + $1;   # there may be multiple error summaries
 891             } elsif (/^==\d+== LEAK SUMMARY:/) {
 892                 for my $off (1 .. 4) {
 893                     if ($valgrind[$i+$off] =~
 894                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 895                             $leaks = $leaks + $1;
 896                     }
 897                 }
 898             }
 899         }
 900         if ($errors or $leaks) {
 901             if (rename $Valgrind_Log, "$$test.valgrind") {
 902                 $$grind_ct = $$grind_ct + 1;
 903             } else {
 904                 warn "$0: Failed to create '$$test.valgrind': $!\n";
 905             }
 906         }
 907     } else {
 908         # Quiet wasn't asked for? Something may be amiss
 909         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
 910             warn "No valgrind output?\n";
 911         }
 912     }
 913     if (-e $Valgrind_Log) {
 914         unlink $Valgrind_Log
 915             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 916     }
 917 }
 918
 919 sub _cleanup_valgrind {
 920     return unless $ENV{PERL_VALGRIND};
 921
 922     my ($toolnm, $grind_ct) = @_;
 923     my $s = $$grind_ct == 1 ? '' : 's';
 924     print "$$grind_ct valgrind report$s created.\n", ;
 925     if ($$toolnm eq 'cachegrind') {
 926         # cachegrind leaves a lot of cachegrind.out.$pid litter
 927         # around the tree, find and delete them
 928         unlink _find_files('cachegrind.out.\d+$',
 929                      qw ( ../t ../cpan ../ext ../dist/ ));
 930     }
 931 }
 932
 933 # Generate regexps of known bad filenames / skips from Porting/deparse-skips.txt
 934 my $in;
 935
 936 sub _process_deparse_config {
 937     my @deparse_failures;
 938     my @deparse_skips;
 939
 940     my $f = '../Porting/deparse-skips.txt';
 941
 942     my $skips;
 943     if (!open($skips, '<', $f)) {
 944         warn "Failed to find $f: $!\n";
 945         return;
 946     }
 947
 948     while(<$skips>) {
 949         if (/__DEPARSE_FAILURES__/) {
 950             $in = \@deparse_failures; next;
 951         } elsif (/__DEPARSE_SKIPS__/) {
 952             $in = \@deparse_skips; next;
 953         } elsif (!$in) {
 954             next;
 955         }
 956
 957         s/#.*$//; # Kill comments
 958         s/\s+$//; # And trailing whitespace
 959
 960         next unless $_;
 961
 962         push @$in, $_;
 963     }
 964
 965     for my $f (@deparse_failures, @deparse_skips) {
 966         if ($f =~ m|/$|) { # Dir? Skip everything below it
 967             $f = qr/\Q$f\E.*/;
 968         } else {
 969             $f = qr/\Q$f\E/;
 970         }
 971     }
 972
 973     $deparse_failures = join('|', @deparse_failures);
 974     $deparse_failures = qr/^(?:$deparse_failures)$/;
 975
 976     $deparse_skips = join('|', @deparse_skips);
 977     $deparse_skips = qr/^(?:$deparse_skips)$/;
 978 }
 979
 980 # ex: set ts=8 sts=4 sw=4 noet: