3 perlunifaq - Perl Unicode FAQ
7 This is a list of questions and answers about Unicode in Perl, intended to be
8 read after L<perlunitut>.
10 =head2 perlunitut isn't really a Unicode tutorial, is it?
12 No, and this isn't really a Unicode FAQ.
14 Perl has an abstracted interface for all supported character encodings, so this
15 is actually a generic C<Encode> tutorial and C<Encode> FAQ. But many people
16 think that Unicode is special and magical, and I didn't want to disappoint
17 them, so I decided to call the document a Unicode tutorial.
19 =head2 What character encodings does Perl support?
21 To find out which character encodings your Perl supports, run:
23 perl -MEncode -le "print for Encode->encodings(':all')"
25 =head2 Which version of perl should I use?
27 Well, if you can, upgrade to the most recent, but certainly C<5.8.1> or newer.
28 The tutorial and FAQ assume the latest release.
30 You should also check your modules, and upgrade them if necessary. For example,
31 HTML::Entities requires version >= 1.32 to function correctly, even though the
32 changelog is silent about this.
34 =head2 What about binary data, like images?
36 Well, apart from a bare C<binmode $fh>, you shouldn't treat them specially.
37 (The binmode is needed because otherwise Perl may convert line endings on Win32
40 Be careful, though, to never combine text strings with binary strings. If you
41 need text in a binary stream, encode your text strings first using the
42 appropriate encoding, then join them with binary strings. See also: "What if I
45 =head2 When should I decode or encode?
47 Whenever you're communicating text with anything that is external to your perl
48 process, like a database, a text file, a socket, or another program. Even if
49 the thing you're communicating with is also written in Perl.
51 =head2 What if I don't decode?
53 Whenever your encoded, binary string is used together with a text string, Perl
54 will assume that your binary string was encoded with ISO-8859-1, also known as
55 latin-1. If it wasn't latin-1, then your data is unpleasantly converted. For
56 example, if it was UTF-8, the individual bytes of multibyte characters are seen
57 as separate characters, and then again converted to UTF-8. Such double encoding
58 can be compared to double HTML encoding (C<&gt;>), or double URI encoding
61 This silent implicit decoding is known as "upgrading". That may sound
62 positive, but it's best to avoid it.
64 =head2 What if I don't encode?
66 It depends on what you output and how you output it.
68 =head3 Output via a filehandle
72 =item * If the string's characters are all code point 255 or lower, Perl
73 outputs bytes that match those code points. This is what happens with encoded
74 strings. It can also, though, happen with unencoded strings that happen to be
75 all code point 255 or lower.
77 =item * Otherwise, Perl outputs the string encoded as UTF-8. This only happens
78 with strings you neglected to encode. Since that should not happen, Perl also
79 throws a "wide character" warning in this case.
83 =head3 Other output mechanisms (e.g., C<exec>, C<chdir>, ..)
85 Your text string will be sent using the bytes in Perl's internal format.
87 Because the internal format is often UTF-8, these bugs are hard to spot,
88 because UTF-8 is usually the encoding you wanted! But don't be lazy, and don't
89 use the fact that Perl's internal format is UTF-8 to your advantage. Encode
90 explicitly to avoid weird bugs, and to show to maintenance programmers that you
93 =head2 Is there a way to automatically decode or encode?
95 If all data that comes from a certain handle is encoded in exactly the same
96 way, you can tell the PerlIO system to automatically decode everything, with
97 the C<encoding> layer. If you do this, you can't accidentally forget to decode
98 or encode anymore, on things that use the layered handle.
100 You can provide this layer when C<open>ing the file:
102 open my $fh, '>:encoding(UTF-8)', $filename; # auto encoding on write
103 open my $fh, '<:encoding(UTF-8)', $filename; # auto decoding on read
105 Or if you already have an open filehandle:
107 binmode $fh, ':encoding(UTF-8)';
109 Some database drivers for DBI can also automatically encode and decode, but
110 that is sometimes limited to the UTF-8 encoding.
112 =head2 What if I don't know which encoding was used?
114 Do whatever you can to find out, and if you have to: guess. (Don't forget to
115 document your guess with a comment.)
117 You could open the document in a web browser, and change the character set or
118 character encoding until you can visually confirm that all characters look the
121 There is no way to reliably detect the encoding automatically, so if people
122 keep sending you data without charset indication, you may have to educate them.
124 =head2 Can I use Unicode in my Perl sources?
126 Yes, you can! If your sources are UTF-8 encoded, you can indicate that with the
131 This doesn't do anything to your input, or to your output. It only influences
132 the way your sources are read. You can use Unicode in string literals, in
133 identifiers (but they still have to be "word characters" according to C<\w>),
134 and even in custom delimiters.
136 =head2 Data::Dumper doesn't restore the UTF8 flag; is it broken?
138 No, Data::Dumper's Unicode abilities are as they should be. There have been
139 some complaints that it should restore the UTF8 flag when the data is read
140 again with C<eval>. However, you should really not look at the flag, and
141 nothing indicates that Data::Dumper should break this rule.
143 Here's what happens: when Perl reads in a string literal, it sticks to 8 bit
144 encoding as long as it can. (But perhaps originally it was internally encoded
145 as UTF-8, when you dumped it.) When it has to give that up because other
146 characters are added to the text string, it silently upgrades the string to
149 If you properly encode your strings for output, none of this is of your
150 concern, and you can just C<eval> dumped data as always.
152 =head2 Why do regex character classes sometimes match only in the ASCII range?
154 Starting in Perl 5.14 (and partially in Perl 5.12), just put a
155 C<use feature 'unicode_strings'> near the beginning of your program.
156 Within its lexical scope you shouldn't have this problem. It also is
157 automatically enabled under C<use feature ':5.12'> or C<use v5.12> or
158 using C<-E> on the command line for Perl 5.12 or higher.
160 The rationale for requiring this is to not break older programs that
161 rely on the way things worked before Unicode came along. Those older
162 programs knew only about the ASCII character set, and so may not work
163 properly for additional characters. When a string is encoded in UTF-8,
164 Perl assumes that the program is prepared to deal with Unicode, but when
165 the string isn't, Perl assumes that only ASCII
166 is wanted, and so those characters that are not ASCII
167 characters aren't recognized as to what they would be in Unicode.
168 C<use feature 'unicode_strings'> tells Perl to treat all characters as
169 Unicode, whether the string is encoded in UTF-8 or not, thus avoiding
172 However, on earlier Perls, or if you pass strings to subroutines outside
173 the feature's scope, you can force Unicode rules by changing the
174 encoding to UTF-8 by doing C<utf8::upgrade($string)>. This can be used
175 safely on any string, as it checks and does not change strings that have
176 already been upgraded.
178 For a more detailed discussion, see L<Unicode::Semantics> on CPAN.
180 =head2 Why do some characters not uppercase or lowercase correctly?
182 See the answer to the previous question.
184 =head2 How can I determine if a string is a text string or a binary string?
186 You can't. Some use the UTF8 flag for this, but that's misuse, and makes well
187 behaved modules like Data::Dumper look bad. The flag is useless for this
188 purpose, because it's off when an 8 bit encoding (by default ISO-8859-1) is
189 used to store the string.
191 This is something you, the programmer, has to keep track of; sorry. You could
192 consider adopting a kind of "Hungarian notation" to help with this.
194 =head2 How do I convert from encoding FOO to encoding BAR?
196 By first converting the FOO-encoded byte string to a text string, and then the
197 text string to a BAR-encoded byte string:
199 my $text_string = decode('FOO', $foo_string);
200 my $bar_string = encode('BAR', $text_string);
202 or by skipping the text string part, and going directly from one binary
203 encoding to the other:
205 use Encode qw(from_to);
206 from_to($string, 'FOO', 'BAR'); # changes contents of $string
208 or by letting automatic decoding and encoding do all the work:
210 open my $foofh, '<:encoding(FOO)', 'example.foo.txt';
211 open my $barfh, '>:encoding(BAR)', 'example.bar.txt';
212 print { $barfh } $_ while <$foofh>;
214 =head2 What are C<decode_utf8> and C<encode_utf8>?
216 These are alternate syntaxes for C<decode('utf8', ...)> and C<encode('utf8',
217 ...)>. Do not use these functions for data exchange. Instead use
218 C<decode('UTF-8', ...)> and C<encode('UTF-8', ...)>; see
219 L</What's the difference between UTF-8 and utf8?> below.
221 =head2 What is a "wide character"?
223 This is a term used for characters occupying more than one byte.
225 The Perl warning "Wide character in ..." is caused by such a character.
226 With no specified encoding layer, Perl tries to
227 fit things into a single byte. When it can't, it
228 emits this warning (if warnings are enabled), and uses UTF-8 encoded data
231 To avoid this warning and to avoid having different output encodings in a single
232 stream, always specify an encoding explicitly, for example with a PerlIO layer:
234 binmode STDOUT, ":encoding(UTF-8)";
238 =head2 What is "the UTF8 flag"?
240 Please, unless you're hacking the internals, or debugging weirdness, don't
241 think about the UTF8 flag at all. That means that you very probably shouldn't
242 use C<is_utf8>, C<_utf8_on> or C<_utf8_off> at all.
244 The UTF8 flag, also called SvUTF8, is an internal flag that indicates that the
245 current internal representation is UTF-8. Without the flag, it is assumed to be
246 ISO-8859-1. Perl converts between these automatically. (Actually Perl usually
247 assumes the representation is ASCII; see L</Why do regex character classes
248 sometimes match only in the ASCII range?> above.)
250 One of Perl's internal formats happens to be UTF-8. Unfortunately, Perl can't
251 keep a secret, so everyone knows about this. That is the source of much
252 confusion. It's better to pretend that the internal format is some unknown
253 encoding, and that you always have to encode and decode explicitly.
255 =head2 What about the C<use bytes> pragma?
257 Don't use it. It makes no sense to deal with bytes in a text string, and it
258 makes no sense to deal with characters in a byte string. Do the proper
259 conversions (by decoding/encoding), and things will work out well: you get
260 character counts for decoded data, and byte counts for encoded data.
262 C<use bytes> is usually a failed attempt to do something useful. Just forget
265 =head2 What about the C<use encoding> pragma?
267 Don't use it. Unfortunately, it assumes that the programmer's environment and
268 that of the user will use the same encoding. It will use the same encoding for
269 the source code and for STDIN and STDOUT. When a program is copied to another
270 machine, the source code does not change, but the STDIO environment might.
272 If you need non-ASCII characters in your source code, make it a UTF-8 encoded
273 file and C<use utf8>.
275 If you need to set the encoding for STDIN, STDOUT, and STDERR, for example
276 based on the user's locale, C<use open>.
278 =head2 What is the difference between C<:encoding> and C<:utf8>?
280 Because UTF-8 is one of Perl's internal formats, you can often just skip the
281 encoding or decoding step, and manipulate the UTF8 flag directly.
283 Instead of C<:encoding(UTF-8)>, you can simply use C<:utf8>, which skips the
284 encoding step if the data was already represented as UTF8 internally. This is
285 widely accepted as good behavior when you're writing, but it can be dangerous
286 when reading, because it causes internal inconsistency when you have invalid
287 byte sequences. Using C<:utf8> for input can sometimes result in security
288 breaches, so please use C<:encoding(UTF-8)> instead.
290 Instead of C<decode> and C<encode>, you could use C<_utf8_on> and C<_utf8_off>,
291 but this is considered bad style. Especially C<_utf8_on> can be dangerous, for
292 the same reason that C<:utf8> can.
294 There are some shortcuts for oneliners;
295 see L<-C in perlrun|perlrun/-C [numberE<sol>list]>.
297 =head2 What's the difference between C<UTF-8> and C<utf8>?
299 C<UTF-8> is the official standard. C<utf8> is Perl's way of being liberal in
300 what it accepts. If you have to communicate with things that aren't so liberal,
301 you may want to consider using C<UTF-8>. If you have to communicate with things
302 that are too liberal, you may have to use C<utf8>. The full explanation is in
303 L<Encode/"UTF-8 vs. utf8 vs. UTF8">.
305 C<UTF-8> is internally known as C<utf-8-strict>. The tutorial uses UTF-8
306 consistently, even where utf8 is actually used internally, because the
307 distinction can be hard to make, and is mostly irrelevant.
309 For example, utf8 can be used for code points that don't exist in Unicode, like
310 9999999, but if you encode that to UTF-8, you get a substitution character (by
311 default; see L<Encode/"Handling Malformed Data"> for more ways of dealing with
314 Okay, if you insist: the "internal format" is utf8, not UTF-8. (When it's not
315 some other encoding.)
317 =head2 I lost track; what encoding is the internal format really?
319 It's good that you lost track, because you shouldn't depend on the internal
320 format being any specific encoding. But since you asked: by default, the
321 internal format is either ISO-8859-1 (latin-1), or utf8, depending on the
322 history of the string. On EBCDIC platforms, this may be different even.
324 Perl knows how it stored the string internally, and will use that knowledge
325 when you C<encode>. In other words: don't try to find out what the internal
326 encoding for a certain string is, but instead just encode it into the encoding
331 Juerd Waalboer <#####@juerd.nl>
335 L<perlunicode>, L<perluniintro>, L<Encode>