2 X<reference> X<pointer> X<data structure> X<structure> X<struct>
4 perlref - Perl references and nested data structures
8 This is complete documentation about all aspects of references.
9 For a shorter, tutorial introduction to just the essential features,
14 Before release 5 of Perl it was difficult to represent complex data
15 structures, because all references had to be symbolic--and even then
16 it was difficult to refer to a variable instead of a symbol table entry.
17 Perl now not only makes it easier to use symbolic references to variables,
18 but also lets you have "hard" references to any piece of data or code.
19 Any scalar may hold a hard reference. Because arrays and hashes contain
20 scalars, you can now easily build arrays of arrays, arrays of hashes,
21 hashes of arrays, arrays of hashes of functions, and so on.
23 Hard references are smart--they keep track of reference counts for you,
24 automatically freeing the thing referred to when its reference count goes
25 to zero. (Reference counts for values in self-referential or
26 cyclic data structures may not go to zero without a little help; see
27 L</"Circular References"> for a detailed explanation.)
28 If that thing happens to be an object, the object is destructed. See
29 L<perlobj> for more about objects. (In a sense, everything in Perl is an
30 object, but we usually reserve the word for references to objects that
31 have been officially "blessed" into a class package.)
33 Symbolic references are names of variables or other objects, just as a
34 symbolic link in a Unix filesystem contains merely the name of a file.
35 The C<*glob> notation is something of a symbolic reference. (Symbolic
36 references are sometimes called "soft references", but please don't call
37 them that; references are confusing enough without useless synonyms.)
38 X<reference, symbolic> X<reference, soft>
39 X<symbolic reference> X<soft reference>
41 In contrast, hard references are more like hard links in a Unix file
42 system: They are used to access an underlying object without concern for
43 what its (other) name is. When the word "reference" is used without an
44 adjective, as in the following paragraph, it is usually talking about a
46 X<reference, hard> X<hard reference>
48 References are easy to use in Perl. There is just one overriding
49 principle: in general, Perl does no implicit referencing or dereferencing.
50 When a scalar is holding a reference, it always behaves as a simple scalar.
51 It doesn't magically start being an array or hash or subroutine; you have to
52 tell it explicitly to do so, by dereferencing it.
54 =head2 Making References
55 X<reference, creation> X<referencing>
57 References can be created in several ways.
59 =head3 Backslash Operator
62 By using the backslash operator on a variable, subroutine, or value.
63 (This works much like the & (address-of) operator in C.)
64 This typically creates I<another> reference to a variable, because
65 there's already a reference to the variable in the symbol table. But
66 the symbol table reference might go away, and you'll still have the
67 reference that the backslash returned. Here are some examples:
75 It isn't possible to create a true reference to an IO handle (filehandle
76 or dirhandle) using the backslash operator. The most you can get is a
77 reference to a typeglob, which is actually a complete symbol table entry.
78 But see the explanation of the C<*foo{THING}> syntax below. However,
79 you can still use type globs and globrefs as though they were IO handles.
81 =head3 Square Brackets
82 X<array, anonymous> X<[> X<[]> X<square bracket>
83 X<bracket, square> X<arrayref> X<array reference> X<reference, array>
85 A reference to an anonymous array can be created using square
88 $arrayref = [1, 2, ['a', 'b', 'c']];
90 Here we've created a reference to an anonymous array of three elements
91 whose final element is itself a reference to another anonymous array of three
92 elements. (The multidimensional syntax described later can be used to
93 access this. For example, after the above, C<< $arrayref->[2][1] >> would have
96 Taking a reference to an enumerated list is not the same
97 as using square brackets--instead it's the same as creating
100 @list = (\$a, \@b, \%c);
101 @list = \($a, @b, %c); # same thing!
103 As a special case, C<\(@foo)> returns a list of references to the contents
104 of C<@foo>, not a reference to C<@foo> itself. Likewise for C<%foo>,
105 except that the key references are to copies (since the keys are just
106 strings rather than full-fledged scalars).
108 =head3 Curly Brackets
109 X<hash, anonymous> X<{> X<{}> X<curly bracket>
110 X<bracket, curly> X<brace> X<hashref> X<hash reference> X<reference, hash>
112 A reference to an anonymous hash can be created using curly
120 Anonymous hash and array composers like these can be intermixed freely to
121 produce as complicated a structure as you want. The multidimensional
122 syntax described below works for these too. The values above are
123 literals, but variables and expressions would work just as well, because
124 assignment operators in Perl (even within local() or my()) are executable
125 statements, not compile-time declarations.
127 Because curly brackets (braces) are used for several other things
128 including BLOCKs, you may occasionally have to disambiguate braces at the
129 beginning of a statement by putting a C<+> or a C<return> in front so
130 that Perl realizes the opening brace isn't starting a BLOCK. The economy and
131 mnemonic value of using curlies is deemed worth this occasional extra
134 For example, if you wanted a function to make a new hash and return a
135 reference to it, you have these options:
137 sub hashem { { @_ } } # silently wrong
138 sub hashem { +{ @_ } } # ok
139 sub hashem { return { @_ } } # ok
141 On the other hand, if you want the other meaning, you can do this:
143 sub showem { { @_ } } # ambiguous (currently ok,
145 sub showem { {; @_ } } # ok
146 sub showem { { return @_ } } # ok
148 The leading C<+{> and C<{;> always serve to disambiguate
149 the expression to mean either the HASH reference, or the BLOCK.
151 =head3 Anonymous Subroutines
152 X<subroutine, anonymous> X<subroutine, reference> X<reference, subroutine>
153 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
155 A reference to an anonymous subroutine can be created by using
156 C<sub> without a subname:
158 $coderef = sub { print "Boink!\n" };
160 Note the semicolon. Except for the code
161 inside not being immediately executed, a C<sub {}> is not so much a
162 declaration as it is an operator, like C<do{}> or C<eval{}>. (However, no
163 matter how many times you execute that particular line (unless you're in an
164 C<eval("...")>), $coderef will still have a reference to the I<same>
165 anonymous subroutine.)
167 Anonymous subroutines act as closures with respect to my() variables,
168 that is, variables lexically visible within the current scope. Closure
169 is a notion out of the Lisp world that says if you define an anonymous
170 function in a particular lexical context, it pretends to run in that
171 context even when it's called outside the context.
173 In human terms, it's a funny way of passing arguments to a subroutine when
174 you define it as well as when you call it. It's useful for setting up
175 little bits of code to run later, such as callbacks. You can even
176 do object-oriented stuff with it, though Perl already provides a different
177 mechanism to do that--see L<perlobj>.
179 You might also think of closure as a way to write a subroutine
180 template without using eval(). Here's a small example of how
185 return sub { my $y = shift; print "$x, $y!\n"; };
187 $h = newprint("Howdy");
188 $g = newprint("Greetings");
198 Greetings, earthlings!
200 Note particularly that $x continues to refer to the value passed
201 into newprint() I<despite> "my $x" having gone out of scope by the
202 time the anonymous subroutine runs. That's what a closure is all
205 This applies only to lexical variables, by the way. Dynamic variables
206 continue to work as they have always worked. Closure is not something
207 that most Perl programmers need trouble themselves about to begin with.
210 X<constructor> X<new>
212 References are often returned by special subroutines called constructors. Perl
213 objects are just references to a special type of object that happens to know
214 which package it's associated with. Constructors are just special subroutines
215 that know how to create that association. They do so by starting with an
216 ordinary reference, and it remains an ordinary reference even while it's also
217 being an object. Constructors are often named C<new()>. You I<can> call them
220 $objref = new Doggie( Tail => 'short', Ears => 'long' );
222 But that can produce ambiguous syntax in certain cases, so it's often
223 better to use the direct method invocation approach:
225 $objref = Doggie->new(Tail => 'short', Ears => 'long');
228 $terminal = Term::Cap->Tgetent( { OSPEED => 9600 });
231 $main = MainWindow->new();
232 $menubar = $main->Frame(-relief => "raised",
235 =head3 Autovivification
238 References of the appropriate type can spring into existence if you
239 dereference them in a context that assumes they exist. Because we haven't
240 talked about dereferencing yet, we can't show you any examples yet.
242 =head3 Typeglob Slots
245 A reference can be created by using a special syntax, lovingly known as
246 the *foo{THING} syntax. *foo{THING} returns a reference to the THING
247 slot in *foo (which is the symbol table entry which holds everything
250 $scalarref = *foo{SCALAR};
251 $arrayref = *ARGV{ARRAY};
252 $hashref = *ENV{HASH};
253 $coderef = *handler{CODE};
255 $globref = *foo{GLOB};
256 $formatref = *foo{FORMAT};
257 $globname = *foo{NAME}; # "foo"
258 $pkgname = *foo{PACKAGE}; # "main"
260 Most of these are self-explanatory, but C<*foo{IO}>
261 deserves special attention. It returns
262 the IO handle, used for file handles (L<perlfunc/open>), sockets
263 (L<perlfunc/socket> and L<perlfunc/socketpair>), and directory
264 handles (L<perlfunc/opendir>). For compatibility with previous
265 versions of Perl, C<*foo{FILEHANDLE}> is a synonym for C<*foo{IO}>, though it
266 is discouraged, to encourage a consistent use of one name: IO. On perls
267 between v5.8 and v5.22, it will issue a deprecation warning, but this
268 deprecation has since been rescinded.
270 C<*foo{THING}> returns undef if that particular THING hasn't been used yet,
271 except in the case of scalars. C<*foo{SCALAR}> returns a reference to an
272 anonymous scalar if $foo hasn't been used yet. This might change in a
275 C<*foo{NAME}> and C<*foo{PACKAGE}> are the exception, in that they return
276 strings, rather than references. These return the package and name of the
277 typeglob itself, rather than one that has been assigned to it. So, after
278 C<*foo=*Foo::bar>, C<*foo> will become "*Foo::bar" when used as a string,
279 but C<*foo{PACKAGE}> and C<*foo{NAME}> will continue to produce "main" and
282 C<*foo{IO}> is an alternative to the C<*HANDLE> mechanism given in
283 L<perldata/"Typeglobs and Filehandles"> for passing filehandles
284 into or out of subroutines, or storing into larger data structures.
285 Its disadvantage is that it won't create a new filehandle for you.
286 Its advantage is that you have less risk of clobbering more than
287 you want to with a typeglob assignment. (It still conflates file
288 and directory handles, though.) However, if you assign the incoming
289 value to a scalar instead of a typeglob as we do in the examples
290 below, there's no risk of that happening.
292 splutter(*STDOUT); # pass the whole glob
293 splutter(*STDOUT{IO}); # pass both file and dir handles
297 print $fh "her um well a hmmm\n";
300 $rec = get_rec(*STDIN); # pass the whole glob
301 $rec = get_rec(*STDIN{IO}); # pass both file and dir handles
308 =head2 Using References
309 X<reference, use> X<dereferencing> X<dereference>
311 That's it for creating references. By now you're probably dying to
312 know how to use references to get back to your long-lost data. There
313 are several basic methods.
317 Anywhere you'd put an identifier (or chain of identifiers) as part
318 of a variable or subroutine name, you can replace the identifier with
319 a simple scalar variable containing a reference of the correct type:
322 push(@$arrayref, $filename);
323 $$arrayref[0] = "January";
324 $$hashref{"KEY"} = "VALUE";
326 print $globref "output\n";
328 It's important to understand that we are specifically I<not> dereferencing
329 C<$arrayref[0]> or C<$hashref{"KEY"}> there. The dereference of the
330 scalar variable happens I<before> it does any key lookups. Anything more
331 complicated than a simple scalar variable must use methods 2 or 3 below.
332 However, a "simple scalar" includes an identifier that itself uses method
333 1 recursively. Therefore, the following prints "howdy".
335 $refrefref = \\\"howdy";
340 Anywhere you'd put an identifier (or chain of identifiers) as part of a
341 variable or subroutine name, you can replace the identifier with a
342 BLOCK returning a reference of the correct type. In other words, the
343 previous examples could be written like this:
345 $bar = ${$scalarref};
346 push(@{$arrayref}, $filename);
347 ${$arrayref}[0] = "January";
348 ${$hashref}{"KEY"} = "VALUE";
350 $globref->print("output\n"); # iff IO::Handle is loaded
352 Admittedly, it's a little silly to use the curlies in this case, but
353 the BLOCK can contain any arbitrary expression, in particular,
354 subscripted expressions:
356 &{ $dispatch{$index} }(1,2,3); # call correct routine
358 Because of being able to omit the curlies for the simple case of C<$$x>,
359 people often make the mistake of viewing the dereferencing symbols as
360 proper operators, and wonder about their precedence. If they were,
361 though, you could use parentheses instead of braces. That's not the case.
362 Consider the difference below; case 0 is a short-hand version of case 1,
365 $$hashref{"KEY"} = "VALUE"; # CASE 0
366 ${$hashref}{"KEY"} = "VALUE"; # CASE 1
367 ${$hashref{"KEY"}} = "VALUE"; # CASE 2
368 ${$hashref->{"KEY"}} = "VALUE"; # CASE 3
370 Case 2 is also deceptive in that you're accessing a variable
371 called %hashref, not dereferencing through $hashref to the hash
372 it's presumably referencing. That would be case 3.
374 =head3 Arrow Notation
376 Subroutine calls and lookups of individual array elements arise often
377 enough that it gets cumbersome to use method 2. As a form of
378 syntactic sugar, the examples for method 2 may be written:
380 $arrayref->[0] = "January"; # Array element
381 $hashref->{"KEY"} = "VALUE"; # Hash element
382 $coderef->(1,2,3); # Subroutine call
384 The left side of the arrow can be any expression returning a reference,
385 including a previous dereference. Note that C<$array[$x]> is I<not> the
386 same thing as C<< $array->[$x] >> here:
388 $array[$x]->{"foo"}->[0] = "January";
390 This is one of the cases we mentioned earlier in which references could
391 spring into existence when in an lvalue context. Before this
392 statement, C<$array[$x]> may have been undefined. If so, it's
393 automatically defined with a hash reference so that we can look up
394 C<{"foo"}> in it. Likewise C<< $array[$x]->{"foo"} >> will automatically get
395 defined with an array reference so that we can look up C<[0]> in it.
396 This process is called I<autovivification>.
398 One more thing here. The arrow is optional I<between> brackets
399 subscripts, so you can shrink the above down to
401 $array[$x]{"foo"}[0] = "January";
403 Which, in the degenerate case of using only ordinary arrays, gives you
404 multidimensional arrays just like C's:
406 $score[$x][$y][$z] += 42;
408 Well, okay, not entirely like C's arrays, actually. C doesn't know how
409 to grow its arrays on demand. Perl does.
413 If a reference happens to be a reference to an object, then there are
414 probably methods to access the things referred to, and you should probably
415 stick to those methods unless you're in the class package that defines the
416 object's methods. In other words, be nice, and don't violate the object's
417 encapsulation without a very good reason. Perl does not enforce
418 encapsulation. We are not totalitarians here. We do expect some basic
421 =head3 Miscellaneous Usage
423 Using a string or number as a reference produces a symbolic reference,
424 as explained above. Using a reference as a number produces an
425 integer representing its storage location in memory. The only
426 useful thing to be done with this is to compare two references
427 numerically to see whether they refer to the same location.
428 X<reference, numeric context>
430 if ($ref1 == $ref2) { # cheap numeric compare of references
431 print "refs 1 and 2 refer to the same thing\n";
434 Using a reference as a string produces both its referent's type,
435 including any package blessing as described in L<perlobj>, as well
436 as the numeric address expressed in hex. The ref() operator returns
437 just the type of thing the reference is pointing to, without the
438 address. See L<perlfunc/ref> for details and examples of its use.
439 X<reference, string context>
441 The bless() operator may be used to associate the object a reference
442 points to with a package functioning as an object class. See L<perlobj>.
444 A typeglob may be dereferenced the same way a reference can, because
445 the dereference syntax always indicates the type of reference desired.
446 So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable.
448 Here's a trick for interpolating a subroutine call into a string:
450 print "My sub returned @{[mysub(1,2,3)]} that time.\n";
452 The way it works is that when the C<@{...}> is seen in the double-quoted
453 string, it's evaluated as a block. The block creates a reference to an
454 anonymous array containing the results of the call to C<mysub(1,2,3)>. So
455 the whole block returns a reference to an array, which is then
456 dereferenced by C<@{...}> and stuck into the double-quoted string. This
457 chicanery is also useful for arbitrary expressions:
459 print "That yields @{[$n + 5]} widgets\n";
461 Similarly, an expression that returns a reference to a scalar can be
462 dereferenced via C<${...}>. Thus, the above expression may be written
465 print "That yields ${\($n + 5)} widgets\n";
467 =head2 Circular References
468 X<circular reference> X<reference, circular>
470 It is possible to create a "circular reference" in Perl, which can lead
471 to memory leaks. A circular reference occurs when two references
472 contain a reference to each other, like this:
475 my $bar = { foo => $foo };
478 You can also create a circular reference with a single variable:
483 In this case, the reference count for the variables will never reach 0,
484 and the references will never be garbage-collected. This can lead to
487 Because objects in Perl are implemented as references, it's possible to
488 have circular references with objects as well. Imagine a TreeNode class
489 where each node references its parent and child nodes. Any node with a
490 parent will be part of a circular reference.
492 You can break circular references by creating a "weak reference". A
493 weak reference does not increment the reference count for a variable,
494 which means that the object can go out of scope and be destroyed. You
495 can weaken a reference with the C<weaken> function exported by the
496 L<Scalar::Util> module, or available as C<builtin::weaken> directly in
497 Perl version 5.35.7 or later.
499 Here's how we can make the first example safer:
501 use Scalar::Util 'weaken';
504 my $bar = { foo => $foo };
509 The reference from C<$foo> to C<$bar> has been weakened. When the
510 C<$bar> variable goes out of scope, it will be garbage-collected. The
511 next time you look at the value of the C<< $foo->{bar} >> key, it will
514 This action at a distance can be confusing, so you should be careful
515 with your use of weaken. You should weaken the reference in the
516 variable that will go out of scope I<first>. That way, the longer-lived
517 variable will contain the expected reference until it goes out of
520 =head2 Symbolic references
521 X<reference, symbolic> X<reference, soft>
522 X<symbolic reference> X<soft reference>
524 We said that references spring into existence as necessary if they are
525 undefined, but we didn't say what happens if a value used as a
526 reference is already defined, but I<isn't> a hard reference. If you
527 use it as a reference, it'll be treated as a symbolic
528 reference. That is, the value of the scalar is taken to be the I<name>
529 of a variable, rather than a direct link to a (possibly) anonymous
532 People frequently expect it to work like this. So it does.
535 $$name = 1; # Sets $foo
536 ${$name} = 2; # Sets $foo
537 ${$name x 2} = 3; # Sets $foofoo
538 $name->[0] = 4; # Sets $foo[0]
539 @$name = (); # Clears @foo
540 &$name(); # Calls &foo()
542 ${"${pack}::$name"} = 5; # Sets $THAT::foo without eval
544 This is powerful, and slightly dangerous, in that it's possible
545 to intend (with the utmost sincerity) to use a hard reference, and
546 accidentally use a symbolic reference instead. To protect against
551 and then only hard references will be allowed for the rest of the enclosing
552 block. An inner block may countermand that with
556 Only package variables (globals, even if localized) are visible to
557 symbolic references. Lexical variables (declared with my()) aren't in
558 a symbol table, and thus are invisible to this mechanism. For example:
567 This will still print 10, not 20. Remember that local() affects package
568 variables, which are all "global" to the package.
570 =head2 Not-so-symbolic references
572 Brackets around a symbolic reference can simply
573 serve to isolate an identifier or variable name from the rest of an
574 expression, just as they always have within a string. For example,
579 has always meant to print "pop on over", even though push is
580 a reserved word. This is generalized to work the same
581 without the enclosing double quotes, so that
583 print ${push} . "over";
587 print ${ push } . "over";
589 will have the same effect. This
590 construct is I<not> considered to be a symbolic reference when you're
594 ${ bareword }; # Okay, means $bareword.
595 ${ "bareword" }; # Error, symbolic reference.
597 Similarly, because of all the subscripting that is done using single words,
598 the same rule applies to any bareword that is used for subscripting a hash.
599 So now, instead of writing
601 $hash{ "aaa" }{ "bbb" }{ "ccc" }
605 $hash{ aaa }{ bbb }{ ccc }
607 and not worry about whether the subscripts are reserved words. In the
608 rare event that you do wish to do something like
612 you can force interpretation as a reserved word by adding anything that
613 makes it more than a bareword:
619 The C<use warnings> pragma or the B<-w> switch will warn you if it
620 interprets a reserved word as a string.
621 But it will no longer warn you about using lowercase words, because the
622 string is effectively quoted.
624 =head2 Pseudo-hashes: Using an array as a hash
625 X<pseudo-hash> X<pseudo hash> X<pseudohash>
627 Pseudo-hashes have been removed from Perl. The 'fields' pragma
630 =head2 Function Templates
631 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
632 X<subroutine, nested> X<sub, nested> X<subroutine, local> X<sub, local>
634 As explained above, an anonymous function with access to the lexical
635 variables visible when that function was compiled, creates a closure. It
636 retains access to those variables even though it doesn't get run until
637 later, such as in a signal handler or a Tk callback.
639 Using a closure as a function template allows us to generate many functions
640 that act similarly. Suppose you wanted functions named after the colors
641 that generated HTML font changes for the various colors:
643 print "Be ", red("careful"), "with that ", green("light");
645 The red() and green() functions would be similar. To create these,
646 we'll assign a closure to a typeglob of the name of the function we're
649 @colors = qw(red blue green yellow orange purple violet);
650 for my $name (@colors) {
651 no strict 'refs'; # allow symbol table manipulation
652 *$name = *{uc $name} = sub { "<FONT COLOR='$name'>@_</FONT>" };
655 Now all those different functions appear to exist independently. You can
656 call red(), RED(), blue(), BLUE(), green(), etc. This technique saves on
657 both compile time and memory use, and is less error-prone as well, since
658 syntax checks happen at compile time. It's critical that any variables in
659 the anonymous subroutine be lexicals in order to create a proper closure.
660 That's the reasons for the C<my> on the loop iteration variable.
662 This is one of the only places where giving a prototype to a closure makes
663 much sense. If you wanted to impose scalar context on the arguments of
664 these functions (probably not a wise idea for this particular example),
665 you could have written it this way instead:
667 *$name = sub ($) { "<FONT COLOR='$name'>$_[0]</FONT>" };
669 However, since prototype checking happens at compile time, the assignment
670 above happens too late to be of much use. You could address this by
671 putting the whole loop of assignments within a BEGIN block, forcing it
672 to occur during compilation.
674 Access to lexicals that change over time--like those in the C<for> loop
675 above, basically aliases to elements from the surrounding lexical scopes--
676 only works with anonymous subs, not with named subroutines. Generally
677 said, named subroutines do not nest properly and should only be declared
678 in the main package scope.
680 This is because named subroutines are created at compile time so their
681 lexical variables get assigned to the parent lexicals from the first
682 execution of the parent block. If a parent scope is entered a second
683 time, its lexicals are created again, while the nested subs still
684 reference the old ones.
686 Anonymous subroutines get to capture each time you execute the C<sub>
687 operator, as they are created on the fly. If you are accustomed to using
688 nested subroutines in other programming languages with their own private
689 variables, you'll have to work at it a bit in Perl. The intuitive coding
690 of this type of thing incurs mysterious warnings about "will not stay
691 shared" due to the reasons explained above.
692 For example, this won't work:
696 sub inner { return $x * 19 } # WRONG
700 A work-around is the following:
704 local *inner = sub { return $x * 19 };
708 Now inner() can only be called from within outer(), because of the
709 temporary assignments of the anonymous subroutine. But when it does,
710 it has normal access to the lexical variable $x from the scope of
711 outer() at the time outer is invoked.
713 This has the interesting effect of creating a function local to another
714 function, something not normally supported in Perl.
716 =head2 Postfix Dereference Syntax
718 Beginning in v5.20.0, a postfix syntax for using references is
719 available. It behaves as described in L</Using References>, but instead
720 of a prefixed sigil, a postfixed sigil-and-star is used.
725 @b = $r->@*; # equivalent to @$r or @{ $r }
727 $r = [ 1, [ 2, 3 ], 4 ];
728 $r->[1]->@*; # equivalent to @{ $r->[1] }
730 In Perl 5.20 and 5.22, this syntax must be enabled with C<use feature
731 'postderef'>. As of Perl 5.24, no feature declarations are required to make
734 Postfix dereference should work in all circumstances where block
735 (circumfix) dereference worked, and should be entirely equivalent. This
736 syntax allows dereferencing to be written and read entirely
737 left-to-right. The following equivalencies are defined:
739 $sref->$*; # same as ${ $sref }
740 $aref->@*; # same as @{ $aref }
741 $aref->$#*; # same as $#{ $aref }
742 $href->%*; # same as %{ $href }
743 $cref->&*; # same as &{ $cref }
744 $gref->**; # same as *{ $gref }
746 Note especially that C<< $cref->&* >> is I<not> equivalent to C<<
747 $cref->() >>, and can serve different purposes.
749 Glob elements can be extracted through the postfix dereferencing feature:
751 $gref->*{SCALAR}; # same as *{ $gref }{SCALAR}
753 Postfix array and scalar dereferencing I<can> be used in interpolating
754 strings (double quotes or the C<qq> operator), but only if the
755 C<postderef_qq> feature is enabled.
757 =head2 Postfix Reference Slicing
759 Value slices of arrays and hashes may also be taken with postfix
760 dereferencing notation, with the following equivalencies:
762 $aref->@[ ... ]; # same as @$aref[ ... ]
763 $href->@{ ... }; # same as @$href{ ... }
765 Postfix key/value pair slicing, added in 5.20.0 and documented in
766 L<the KeyE<sol>Value Hash Slices section of perldata|perldata/"Key/Value Hash
767 Slices">, also behaves as expected:
769 $aref->%[ ... ]; # same as %$aref[ ... ]
770 $href->%{ ... }; # same as %$href{ ... }
772 As with postfix array, postfix value slice dereferencing I<can> be used
773 in interpolating strings (double quotes or the C<qq> operator), but only
774 if the C<postderef_qq> L<feature> is enabled.
776 =head2 Assigning to References
778 Beginning in v5.22.0, the referencing operator can be assigned to. It
779 performs an aliasing operation, so that the variable name referenced on the
780 left-hand side becomes an alias for the thing referenced on the right-hand
783 \$a = \$b; # $a and $b now point to the same scalar
784 \&foo = \&bar; # foo() now means bar()
786 This syntax must be enabled with C<use feature 'refaliasing'>. It is
787 experimental, and will warn by default unless C<no warnings
788 'experimental::refaliasing'> is in effect.
790 These forms may be assigned to, and cause the right-hand side to be
791 evaluated in scalar context:
800 \state $scalar # or @array, etc.
802 \local $scalar # etc.
803 \local our $scalar # etc.
806 \local $some_array[$index]
807 \local $some_hash{$key}
808 condition ? \$this : \$that[0] # etc.
810 Slicing operations and parentheses cause
811 the right-hand side to be evaluated in
818 (\@hash{'foo','bar'})
819 \(@hash{'foo','bar'})
829 (\$foo, \@bar, \%baz)
831 Each element on the right-hand side must be a reference to a datum of the
832 right type. Parentheses immediately surrounding an array (and possibly
833 also C<my>/C<state>/C<our>/C<local>) will make each element of the array an
834 alias to the corresponding scalar referenced on the right-hand side:
836 \(@a) = \(@b); # @a and @b now have the same elements
837 \my(@a) = \(@b); # likewise
838 \(my @a) = \(@b); # likewise
839 push @a, 3; # but now @a has an extra element that @b lacks
840 \(@a) = (\$a, \$b, \$c); # @a now contains $a, $b, and $c
842 Combining that form with C<local> and putting parentheses immediately
843 around a hash are forbidden (because it is not clear what they should do):
845 \local(@array) = foo(); # WRONG
846 \(%hash) = bar(); # WRONG
848 Assignment to references and non-references may be combined in lists and
849 conditional ternary expressions, as long as the values on the right-hand
850 side are the right type for each element on the left, though this may make
853 (my $tom, \my $dick, \my @harry) = (\1, \2, [1..3]);
855 # $dick is now 2 (read-only)
858 my $type = ref $thingy;
859 ($type ? $type eq 'ARRAY' ? \@foo : \$bar : $baz) = $thingy;
861 The C<foreach> loop can also take a reference constructor for its loop
862 variable, though the syntax is limited to one of the following, with an
863 optional C<my>, C<state>, or C<our> after the backslash:
870 No parentheses are permitted. This feature is particularly useful for
871 arrays-of-arrays, or arrays-of-hashes:
873 foreach \my @a (@array_of_arrays) {
874 frobnicate($a[0], $a[-1]);
877 foreach \my %h (@array_of_hashes) {
878 $h{gelastic}++ if $h{type} eq 'funny';
881 B<CAVEAT:> Aliasing does not work correctly with closures. If you try to
882 alias lexical variables from an inner subroutine or C<eval>, the aliasing
883 will only be visible within that inner sub, and will not affect the outer
884 subroutine where the variables are declared. This bizarre behavior is
887 =head2 Declaring a Reference to a Variable
889 Beginning in v5.26.0, the referencing operator can come after C<my>,
890 C<state>, C<our>, or C<local>. This syntax must be enabled with C<use
891 feature 'declared_refs'>. It is experimental, and will warn by default
892 unless C<no warnings 'experimental::refaliasing'> is in effect.
894 This feature makes these:
904 It is intended mainly for use in assignments to references (see
905 L</Assigning to References>, above). It also allows the backslash to be
906 used on just some items in a list of declared variables:
908 my ($foo, \@bar, \%baz); # equivalent to: my $foo, \my(@bar, %baz);
910 =head1 WARNING: Don't use references as hash keys
911 X<reference, string context> X<reference, use as hash key>
913 You may not (usefully) use a reference as the key to a hash. It will be
914 converted into a string:
918 If you try to dereference the key, it won't do a hard dereference, and
919 you won't accomplish what you're attempting. You might want to do something
925 And then at least you can use the values(), which will be
926 real refs, instead of the keys(), which won't.
928 The standard Tie::RefHash module provides a convenient workaround to this.
932 Besides the obvious documents, source code can be instructive.
933 Some pathological examples of the use of references can be found
934 in the F<t/op/ref.t> regression test in the Perl source directory.
936 See also L<perldsc> and L<perllol> for how to use references to create
937 complex data structures, and L<perlootut> and L<perlobj>
938 for how to use them to create objects.