t/op/regexp.t

   1 #!./perl
   2
   3 # The tests are in a separate file 't/op/re_tests'.
   4 # Each line in that file is a separate test.
   5 # There are five columns, separated by tabs.
   6 #
   7 # Column 1 contains the pattern, optionally enclosed in C<''>.
   8 # Modifiers can be put after the closing C<'>.
   9 #
  10 # Column 2 contains the string to be matched.
  11 #
  12 # Column 3 contains the expected result:
  13 #       y       expect a match
  14 #       n       expect no match
  15 #       c       expect an error
  16 #       B       test exposes a known bug in Perl, should be skipped
  17 #       b       test exposes a known bug in Perl, should be skipped if noamp
  18 #
  19 # Columns 4 and 5 are used only if column 3 contains C<y> or C<c>.
  20 #
  21 # Column 4 contains a string, usually C<$&>.
  22 #
  23 # Column 5 contains the expected result of double-quote
  24 # interpolating that string after the match, or start of error message.
  25 #
  26 # Column 6, if present, contains a reason why the test is skipped.
  27 # This is printed with "skipped", for harness to pick up.
  28 #
  29 # \n in the tests are interpolated, as are variables of the form ${\w+}.
  30 #
  31 # If you want to add a regular expression test that can't be expressed
  32 # in this format, don't add it here: put it in op/pat.t instead.
  33
  34 BEGIN {
  35     chdir 't' if -d 't';
  36     @INC = '../lib';
  37 }
  38
  39 use re 'asciirange'; # ranges are computed in ASCII
  40
  41 $iters = shift || 1;            # Poor man performance suite, 10000 is OK.
  42
  43 open(TESTS,'op/re_tests') || open(TESTS,'t/op/re_tests') ||
  44         die "Can't open re_tests";
  45
  46 while (<TESTS>) { }
  47 $numtests = $.;
  48 seek(TESTS,0,0);
  49 $. = 0;
  50
  51 $bang = sprintf "\\%03o", ord "!"; # \41 would not be portable.
  52 $ffff  = chr(0xff) x 2;
  53 $nulnul = "\0" x 2;
  54
  55 $| = 1;
  56 print "1..$numtests\n# $iters iterations\n";
  57 TEST:
  58 while (<TESTS>) {
  59     chomp;
  60     s/\\n/\n/g;
  61     ($pat, $subject, $result, $repl, $expect, $reason) = split(/\t/,$_,6);
  62     $input = join(':',$pat,$subject,$result,$repl,$expect);
  63     infty_subst(\$pat);
  64     infty_subst(\$expect);
  65     $pat = "'$pat'" unless $pat =~ /^[:']/;
  66     $pat =~ s/(\$\{\w+\})/$1/eeg;
  67     $pat =~ s/\\n/\n/g;
  68     $subject =~ s/(\$\{\w+\})/$1/eeg;
  69     $subject =~ s/\\n/\n/g;
  70     $expect =~ s/(\$\{\w+\})/$1/eeg;
  71     $expect =~ s/\\n/\n/g;
  72     $expect = $repl = '-' if $skip_amp and $input =~ /\$[&\`\']/;
  73     $skip = ($skip_amp ? ($result =~ s/B//i) : ($result =~ s/B//));
  74     # Certain tests don't work with utf8 (the re_test should be in UTF8)
  75     $skip = 1, $reason = 'utf8'
  76       if ($^H &= ~0x00000008) && $pat =~ /\[:\^(alnum|print|word|ascii|xdigit):\]/;
  77     $result =~ s/B//i unless $skip;
  78     for $study ('', 'study \$subject') {
  79         $c = $iters;
  80         eval "$study; \$match = (\$subject =~ m$pat) while \$c--; \$got = \"$repl\";";
  81         chomp( $err = $@ );
  82         if ($result eq 'c') {
  83             if ($err !~ m!^\Q$expect!) { print "not ok $. (compile) $input => `$err'\n"; next TEST }
  84             last;  # no need to study a syntax error
  85         }
  86         elsif ( $skip ) {
  87             print "ok $. # skipped", length($reason) ? " $reason" : '', "\n";
  88             next TEST;
  89         }
  90         elsif ($@) {
  91             print "not ok $. $input => error `$err'\n"; next TEST;
  92         }
  93         elsif ($result eq 'n') {
  94             if ($match) { print "not ok $. ($study) $input => false positive\n"; next TEST }
  95         }
  96         else {
  97             if (!$match || $got ne $expect) {
  98                 print "not ok $. ($study) $input => `$got', match=$match\n";
  99                 next TEST;
 100             }
 101         }
 102     }
 103     print "ok $.\n";
 104 }
 105
 106 close(TESTS);
 107
 108 sub infty_subst                             # Special-case substitution
 109 {                                           #  of $reg_infty and friends
 110     my $tp = shift;
 111     $$tp =~ s/,\$reg_infty_m}/,$reg_infty_m}/o;
 112     $$tp =~ s/,\$reg_infty_p}/,$reg_infty_p}/o;
 113     $$tp =~ s/,\$reg_infty}/,$reg_infty}/o;
 114 }