t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss
   3
   4
   5 # NOTE:
   6 #
   7 # Do not rely on features found only in more modern Perls here, as some CPAN
   8 # distributions copy this file and must operate on older Perls. Similarly, keep
   9 # things, simple as this may be run under fairly broken circumstances. For
  10 # example, increment ($x++) has a certain amount of cleverness for things like
  11 #
  12 #   $x = 'zz';
  13 #   $x++; # $x eq 'aaa';
  14 #
  15 # This stands more chance of breaking than just a simple
  16 #
  17 #   $x = $x + 1
  18 #
  19 # In this file, we use the latter "Baby Perl" approach, and increment
  20 # will be worked over by t/op/inc.t
  21
  22 $| = 1;
  23 our $Level = 1;
  24 my $test = 1;
  25 my $planned;
  26 my $noplan;
  27 my $Perl;       # Safer version of $^X set by which_perl()
  28
  29 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
  30 $::IS_ASCII  = ord 'A' ==  65;
  31 $::IS_EBCDIC = ord 'A' == 193;
  32
  33 # This is 'our' to enable harness to account for TODO-ed tests in
  34 # overall grade of PASS or FAIL
  35 our $TODO = 0;
  36 our $NO_ENDING = 0;
  37 our $Tests_Are_Passing = 1;
  38
  39 # Use this instead of print to avoid interference while testing globals.
  40 sub _print {
  41     local($\, $", $,) = (undef, ' ', '');
  42     print STDOUT @_;
  43 }
  44
  45 sub _print_stderr {
  46     local($\, $", $,) = (undef, ' ', '');
  47     print STDERR @_;
  48 }
  49
  50 sub plan {
  51     my $n;
  52     if (@_ == 1) {
  53         $n = shift;
  54         if ($n eq 'no_plan') {
  55           undef $n;
  56           $noplan = 1;
  57         }
  58     } else {
  59         my %plan = @_;
  60         $plan{skip_all} and skip_all($plan{skip_all});
  61         $n = $plan{tests};
  62     }
  63     _print "1..$n\n" unless $noplan;
  64     $planned = $n;
  65 }
  66
  67
  68 # Set the plan at the end.  See Test::More::done_testing.
  69 sub done_testing {
  70     my $n = $test - 1;
  71     $n = shift if @_;
  72
  73     _print "1..$n\n";
  74     $planned = $n;
  75 }
  76
  77
  78 END {
  79     my $ran = $test - 1;
  80     if (!$NO_ENDING) {
  81         if (defined $planned && $planned != $ran) {
  82             _print_stderr
  83                 "# Looks like you planned $planned tests but ran $ran.\n";
  84         } elsif ($noplan) {
  85             _print "1..$ran\n";
  86         }
  87     }
  88 }
  89
  90 sub _diag {
  91     return unless @_;
  92     my @mess = _comment(@_);
  93     $TODO ? _print(@mess) : _print_stderr(@mess);
  94 }
  95
  96 # Use this instead of "print STDERR" when outputting failure diagnostic
  97 # messages
  98 sub diag {
  99     _diag(@_);
 100 }
 101
 102 # Use this instead of "print" when outputting informational messages
 103 sub note {
 104     return unless @_;
 105     _print( _comment(@_) );
 106 }
 107
 108 sub is_miniperl {
 109     return !defined &DynaLoader::boot_DynaLoader;
 110 }
 111
 112 sub set_up_inc {
 113     # Don’t clobber @INC under miniperl
 114     @INC = () unless is_miniperl;
 115     unshift @INC, @_;
 116 }
 117
 118 sub _comment {
 119     return map { /^#/ ? "$_\n" : "# $_\n" }
 120            map { split /\n/ } @_;
 121 }
 122
 123 sub _have_dynamic_extension {
 124     my $extension = shift;
 125     unless (eval {require Config; 1}) {
 126         warn "test.pl had problems loading Config: $@";
 127         return 1;
 128     }
 129     $extension =~ s!::!/!g;
 130     return 1 if ($Config::Config{extensions} =~ /\b$extension\b/);
 131 }
 132
 133 sub skip_all {
 134     if (@_) {
 135         _print "1..0 # Skip @_\n";
 136     } else {
 137         _print "1..0\n";
 138     }
 139     exit(0);
 140 }
 141
 142 sub skip_all_if_miniperl {
 143     skip_all(@_) if is_miniperl();
 144 }
 145
 146 sub skip_all_without_dynamic_extension {
 147     my ($extension) = @_;
 148     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
 149     return if &_have_dynamic_extension;
 150     skip_all("$extension was not built");
 151 }
 152
 153 sub skip_all_without_perlio {
 154     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
 155 }
 156
 157 sub skip_all_without_config {
 158     unless (eval {require Config; 1}) {
 159         warn "test.pl had problems loading Config: $@";
 160         return;
 161     }
 162     foreach (@_) {
 163         next if $Config::Config{$_};
 164         my $key = $_; # Need to copy, before trying to modify.
 165         $key =~ s/^use//;
 166         $key =~ s/^d_//;
 167         skip_all("no $key");
 168     }
 169 }
 170
 171 sub skip_all_without_unicode_tables { # (but only under miniperl)
 172     if (is_miniperl()) {
 173         skip_all_if_miniperl("Unicode tables not built yet")
 174             unless eval 'require "unicore/UCD.pl"';
 175     }
 176 }
 177
 178 sub find_git_or_skip {
 179     my ($source_dir, $reason);
 180
 181     if ( $ENV{CONTINUOUS_INTEGRATION} && $ENV{WORKSPACE} ) {
 182         $source_dir = $ENV{WORKSPACE};
 183         if ( -d "${source_dir}/.git" ) {
 184             $ENV{GIT_DIR} = "${source_dir}/.git";
 185             return $source_dir;
 186         }
 187     }
 188
 189     if (-d '.git') {
 190         $source_dir = '.';
 191     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
 192         my $where = readlink 'MANIFEST';
 193         die "Can't readlink MANIFEST: $!" unless defined $where;
 194         die "Confusing symlink target for MANIFEST, '$where'"
 195             unless $where =~ s!/MANIFEST\z!!;
 196         if (-d "$where/.git") {
 197             # Looks like we are in a symlink tree
 198             if (exists $ENV{GIT_DIR}) {
 199                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
 200             } else {
 201                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
 202                 $ENV{GIT_DIR} = "$where/.git";
 203             }
 204             $source_dir = $where;
 205         }
 206     } elsif (exists $ENV{GIT_DIR} || -f '.git') {
 207         my $commit = '8d063cd8450e59ea1c611a2f4f5a21059a2804f1';
 208         my $out = `git rev-parse --verify --quiet '$commit^{commit}'`;
 209         chomp $out;
 210         if($out eq $commit) {
 211             $source_dir = '.'
 212         }
 213     }
 214     if ($ENV{'PERL_BUILD_PACKAGING'}) {
 215         $reason = 'PERL_BUILD_PACKAGING is set';
 216     } elsif ($source_dir) {
 217         my $version_string = `git --version`;
 218         if (defined $version_string
 219               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
 220             return $source_dir if eval "v$1 ge v1.5.0";
 221             # If you have earlier than 1.5.0 and it works, change this test
 222             $reason = "in git checkout, but git version '$1$2' too old";
 223         } else {
 224             $reason = "in git checkout, but cannot run git";
 225         }
 226     } else {
 227         $reason = 'not being run from a git checkout';
 228     }
 229     skip_all($reason) if $_[0] && $_[0] eq 'all';
 230     skip($reason, @_);
 231 }
 232
 233 sub BAIL_OUT {
 234     my ($reason) = @_;
 235     _print("Bail out!  $reason\n");
 236     exit 255;
 237 }
 238
 239 sub _ok {
 240     my ($pass, $where, $name, @mess) = @_;
 241     # Do not try to microoptimize by factoring out the "not ".
 242     # VMS will avenge.
 243     my $out;
 244     if ($name) {
 245         # escape out '#' or it will interfere with '# skip' and such
 246         $name =~ s/#/\\#/g;
 247         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
 248     } else {
 249         $out = $pass ? "ok $test" : "not ok $test";
 250     }
 251
 252     if ($TODO) {
 253         $out = $out . " # TODO $TODO";
 254     } else {
 255         $Tests_Are_Passing = 0 unless $pass;
 256     }
 257
 258     _print "$out\n";
 259
 260     if ($pass) {
 261         note @mess; # Ensure that the message is properly escaped.
 262     }
 263     else {
 264         my $msg = "# Failed test $test - ";
 265         $msg.= "$name " if $name;
 266         $msg .= "$where\n";
 267         _diag $msg;
 268         _diag @mess;
 269     }
 270
 271     $test = $test + 1; # don't use ++
 272
 273     return $pass;
 274 }
 275
 276 sub _where {
 277     my @caller = caller($Level);
 278     return "at $caller[1] line $caller[2]";
 279 }
 280
 281 # DON'T use this for matches. Use like() instead.
 282 sub ok ($@) {
 283     my ($pass, $name, @mess) = @_;
 284     _ok($pass, _where(), $name, @mess);
 285 }
 286
 287 sub _q {
 288     my $x = shift;
 289     return 'undef' unless defined $x;
 290     my $q = $x;
 291     $q =~ s/\\/\\\\/g;
 292     $q =~ s/'/\\'/g;
 293     return "'$q'";
 294 }
 295
 296 sub _qq {
 297     my $x = shift;
 298     return defined $x ? '"' . display ($x) . '"' : 'undef';
 299 };
 300
 301 # Support pre-5.10 Perls, for the benefit of CPAN dists that copy this file.
 302 # Note that chr(90) exists in both ASCII ("Z") and EBCDIC ("!").
 303 my $chars_template = defined(eval { pack "W*", 90 }) ? "W*" : "U*";
 304 eval 'sub re::is_regexp { ref($_[0]) eq "Regexp" }'
 305     if !defined &re::is_regexp;
 306
 307 # keys are the codes \n etc map to, values are 2 char strings such as \n
 308 my %backslash_escape;
 309 foreach my $x (split //, 'enrtfa\\\'"') {
 310     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 311 }
 312 # A way to display scalars containing control characters and Unicode.
 313 # Trying to avoid setting $_, or relying on local $_ to work.
 314 sub display {
 315     my @result;
 316     foreach my $x (@_) {
 317         if (defined $x and not ref $x) {
 318             my $y = '';
 319             foreach my $c (unpack($chars_template, $x)) {
 320                 if ($c > 255) {
 321                     $y = $y . sprintf "\\x{%x}", $c;
 322                 } elsif ($backslash_escape{$c}) {
 323                     $y = $y . $backslash_escape{$c};
 324                 } elsif ($c < ord " ") {
 325                     # Use octal for characters with small ordinals that are
 326                     # traditionally expressed as octal: the controls below
 327                     # space, which on EBCDIC are almost all the controls, but
 328                     # on ASCII don't include DEL nor the C1 controls.
 329                     $y = $y . sprintf "\\%03o", $c;
 330                 } elsif (chr $c =~ /[[:print:]]/a) {
 331                     $y = $y . chr $c;
 332                 }
 333                 else {
 334                     $y = $y . sprintf "\\x%02X", $c;
 335                 }
 336             }
 337             $x = $y;
 338         }
 339         return $x unless wantarray;
 340         push @result, $x;
 341     }
 342     return @result;
 343 }
 344
 345 sub is ($$@) {
 346     my ($got, $expected, $name, @mess) = @_;
 347
 348     my $pass;
 349     if( !defined $got || !defined $expected ) {
 350         # undef only matches undef
 351         $pass = !defined $got && !defined $expected;
 352     }
 353     else {
 354         $pass = $got eq $expected;
 355     }
 356
 357     unless ($pass) {
 358         unshift(@mess, "#      got "._qq($got)."\n",
 359                        "# expected "._qq($expected)."\n");
 360     }
 361     _ok($pass, _where(), $name, @mess);
 362 }
 363
 364 sub isnt ($$@) {
 365     my ($got, $isnt, $name, @mess) = @_;
 366
 367     my $pass;
 368     if( !defined $got || !defined $isnt ) {
 369         # undef only matches undef
 370         $pass = defined $got || defined $isnt;
 371     }
 372     else {
 373         $pass = $got ne $isnt;
 374     }
 375
 376     unless( $pass ) {
 377         unshift(@mess, "# it should not be "._qq($got)."\n",
 378                        "# but it is.\n");
 379     }
 380     _ok($pass, _where(), $name, @mess);
 381 }
 382
 383 sub cmp_ok ($$$@) {
 384     my($got, $type, $expected, $name, @mess) = @_;
 385
 386     my $pass;
 387     {
 388         local $^W = 0;
 389         local($@,$!);   # don't interfere with $@
 390                         # eval() sometimes resets $!
 391         $pass = eval "\$got $type \$expected";
 392     }
 393     unless ($pass) {
 394         # It seems Irix long doubles can have 2147483648 and 2147483648
 395         # that stringify to the same thing but are actually numerically
 396         # different. Display the numbers if $type isn't a string operator,
 397         # and the numbers are stringwise the same.
 398         # (all string operators have alphabetic names, so tr/a-z// is true)
 399         # This will also show numbers for some unneeded cases, but will
 400         # definitely be helpful for things such as == and <= that fail
 401         if ($got eq $expected and $type !~ tr/a-z//) {
 402             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 403         }
 404         unshift(@mess, "#      got "._qq($got)."\n",
 405                        "# expected $type "._qq($expected)."\n");
 406     }
 407     _ok($pass, _where(), $name, @mess);
 408 }
 409
 410 # Check that $got is within $range of $expected
 411 # if $range is 0, then check it's exact
 412 # else if $expected is 0, then $range is an absolute value
 413 # otherwise $range is a fractional error.
 414 # Here $range must be numeric, >= 0
 415 # Non numeric ranges might be a useful future extension. (eg %)
 416 sub within ($$$@) {
 417     my ($got, $expected, $range, $name, @mess) = @_;
 418     my $pass;
 419     if (!defined $got or !defined $expected or !defined $range) {
 420         # This is a fail, but doesn't need extra diagnostics
 421     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 422         # This is a fail
 423         unshift @mess, "# got, expected and range must be numeric\n";
 424     } elsif ($range < 0) {
 425         # This is also a fail
 426         unshift @mess, "# range must not be negative\n";
 427     } elsif ($range == 0) {
 428         # Within 0 is ==
 429         $pass = $got == $expected;
 430     } elsif ($expected == 0) {
 431         # If expected is 0, treat range as absolute
 432         $pass = ($got <= $range) && ($got >= - $range);
 433     } else {
 434         my $diff = $got - $expected;
 435         $pass = abs ($diff / $expected) < $range;
 436     }
 437     unless ($pass) {
 438         if ($got eq $expected) {
 439             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 440         }
 441         unshift@mess, "#      got "._qq($got)."\n",
 442                       "# expected "._qq($expected)." (within "._qq($range).")\n";
 443     }
 444     _ok($pass, _where(), $name, @mess);
 445 }
 446
 447 # Note: this isn't quite as fancy as Test::More::like().
 448
 449 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
 450 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
 451
 452 sub like_yn ($$$@) {
 453     my ($flip, undef, $expected, $name, @mess) = @_;
 454
 455     # We just accept like(..., qr/.../), not like(..., '...'), and
 456     # definitely not like(..., '/.../') like
 457     # Test::Builder::maybe_regex() does.
 458     unless (re::is_regexp($expected)) {
 459         die "PANIC: The value '$expected' isn't a regexp. The like() function needs a qr// pattern, not a string";
 460     }
 461
 462     my $pass;
 463     $pass = $_[1] =~ /$expected/ if !$flip;
 464     $pass = $_[1] !~ /$expected/ if $flip;
 465     my $display_got = $_[1];
 466     $display_got = display($display_got);
 467     my $display_expected = $expected;
 468     $display_expected = display($display_expected);
 469     unless ($pass) {
 470         unshift(@mess, "#      got '$display_got'\n",
 471                 $flip
 472                 ? "# expected !~ /$display_expected/\n"
 473                 : "# expected /$display_expected/\n");
 474     }
 475     local $Level = $Level + 1;
 476     _ok($pass, _where(), $name, @mess);
 477 }
 478
 479 sub pass {
 480     _ok(1, '', @_);
 481 }
 482
 483 sub fail {
 484     _ok(0, _where(), @_);
 485 }
 486
 487 sub curr_test {
 488     $test = shift if @_;
 489     return $test;
 490 }
 491
 492 sub next_test {
 493   my $retval = $test;
 494   $test = $test + 1; # don't use ++
 495   $retval;
 496 }
 497
 498 # Note: can't pass multipart messages since we try to
 499 # be compatible with Test::More::skip().
 500 sub skip {
 501     my $why = shift;
 502     my $n   = @_ ? shift : 1;
 503     my $bad_swap;
 504     my $both_zero;
 505     {
 506       local $^W = 0;
 507       $bad_swap = $why > 0 && $n == 0;
 508       $both_zero = $why == 0 && $n == 0;
 509     }
 510     if ($bad_swap || $both_zero || @_) {
 511       my $arg = "'$why', '$n'";
 512       if (@_) {
 513         $arg .= join(", ", '', map { qq['$_'] } @_);
 514       }
 515       die qq[$0: expected skip(why, count), got skip($arg)\n];
 516     }
 517     for (1..$n) {
 518         _print "ok $test # skip $why\n";
 519         $test = $test + 1;
 520     }
 521     local $^W = 0;
 522     last SKIP;
 523 }
 524
 525 sub skip_if_miniperl {
 526     skip(@_) if is_miniperl();
 527 }
 528
 529 sub skip_without_dynamic_extension {
 530     my $extension = shift;
 531     skip("no dynamic loading on miniperl, no extension $extension", @_)
 532         if is_miniperl();
 533     return if &_have_dynamic_extension($extension);
 534     skip("extension $extension was not built", @_);
 535 }
 536
 537 sub todo_skip {
 538     my $why = shift;
 539     my $n   = @_ ? shift : 1;
 540
 541     for (1..$n) {
 542         _print "not ok $test # TODO & SKIP $why\n";
 543         $test = $test + 1;
 544     }
 545     local $^W = 0;
 546     last TODO;
 547 }
 548
 549 sub eq_array {
 550     my ($ra, $rb) = @_;
 551     return 0 unless $#$ra == $#$rb;
 552     for my $i (0..$#$ra) {
 553         next     if !defined $ra->[$i] && !defined $rb->[$i];
 554         return 0 if !defined $ra->[$i];
 555         return 0 if !defined $rb->[$i];
 556         return 0 unless $ra->[$i] eq $rb->[$i];
 557     }
 558     return 1;
 559 }
 560
 561 sub eq_hash {
 562   my ($orig, $suspect) = @_;
 563   my $fail;
 564   while (my ($key, $value) = each %$suspect) {
 565     # Force a hash recompute if this perl's internals can cache the hash key.
 566     $key = "" . $key;
 567     if (exists $orig->{$key}) {
 568       if (
 569         defined $orig->{$key} != defined $value
 570         || (defined $value && $orig->{$key} ne $value)
 571       ) {
 572         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
 573                      " now ", _qq($value), "\n";
 574         $fail = 1;
 575       }
 576     } else {
 577       _print "# key ", _qq($key), " is ", _qq($value),
 578                    ", not in original.\n";
 579       $fail = 1;
 580     }
 581   }
 582   foreach (keys %$orig) {
 583     # Force a hash recompute if this perl's internals can cache the hash key.
 584     $_ = "" . $_;
 585     next if (exists $suspect->{$_});
 586     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 587     $fail = 1;
 588   }
 589   !$fail;
 590 }
 591
 592 # We only provide a subset of the Test::More functionality.
 593 sub require_ok ($) {
 594     my ($require) = @_;
 595     if ($require =~ tr/[A-Za-z0-9:.]//c) {
 596         fail("Invalid character in \"$require\", passed to require_ok");
 597     } else {
 598         eval <<REQUIRE_OK;
 599 require $require;
 600 REQUIRE_OK
 601         is($@, '', _where(), "require $require");
 602     }
 603 }
 604
 605 sub use_ok ($) {
 606     my ($use) = @_;
 607     if ($use =~ tr/[A-Za-z0-9:.]//c) {
 608         fail("Invalid character in \"$use\", passed to use");
 609     } else {
 610         eval <<USE_OK;
 611 use $use;
 612 USE_OK
 613         is($@, '', _where(), "use $use");
 614     }
 615 }
 616
 617 # runperl, run_perl - Runs a separate perl interpreter and returns its output.
 618 # Arguments :
 619 #   switches => [ command-line switches ]
 620 #   nolib    => 1 # don't use -I../lib (included by default)
 621 #   non_portable => Don't warn if a one liner contains quotes
 622 #   prog     => one-liner (avoid quotes)
 623 #   progs    => [ multi-liner (avoid quotes) ]
 624 #   progfile => perl script
 625 #   stdin    => string to feed the stdin (or undef to redirect from /dev/null)
 626 #   stderr   => If 'devnull' suppresses stderr, if other TRUE value redirect
 627 #               stderr to stdout
 628 #   args     => [ command-line arguments to the perl program ]
 629 #   verbose  => print the command line
 630
 631 my $is_mswin    = $^O eq 'MSWin32';
 632 my $is_vms      = $^O eq 'VMS';
 633 my $is_cygwin   = $^O eq 'cygwin';
 634
 635 sub _quote_args {
 636     my ($runperl, $args) = @_;
 637
 638     foreach (@$args) {
 639         # In VMS protect with doublequotes because otherwise
 640         # DCL will lowercase -- unless already doublequoted.
 641        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 642        $runperl = $runperl . ' ' . $_;
 643     }
 644     return $runperl;
 645 }
 646
 647 sub _create_runperl { # Create the string to qx in runperl().
 648     my %args = @_;
 649     my $runperl = which_perl();
 650     if ($runperl =~ m/\s/) {
 651         $runperl = qq{"$runperl"};
 652     }
 653     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
 654     if ($ENV{PERL_RUNPERL_DEBUG}) {
 655         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
 656     }
 657     unless ($args{nolib}) {
 658         $runperl = $runperl . ' "-I../lib" "-I." '; # doublequotes because of VMS
 659     }
 660     if ($args{switches}) {
 661         local $Level = 2;
 662         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
 663             unless ref $args{switches} eq "ARRAY";
 664         $runperl = _quote_args($runperl, $args{switches});
 665     }
 666     if (defined $args{prog}) {
 667         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
 668             if defined $args{progs};
 669         $args{progs} = [split /\n/, $args{prog}, -1]
 670     }
 671     if (defined $args{progs}) {
 672         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
 673             unless ref $args{progs} eq "ARRAY";
 674         foreach my $prog (@{$args{progs}}) {
 675             if (!$args{non_portable}) {
 676                 if ($prog =~ tr/'"//) {
 677                     warn "quotes in prog >>$prog<< are not portable";
 678                 }
 679                 if ($prog =~ /^([<>|]|2>)/) {
 680                     warn "Initial $1 in prog >>$prog<< is not portable";
 681                 }
 682                 if ($prog =~ /&\z/) {
 683                     warn "Trailing & in prog >>$prog<< is not portable";
 684                 }
 685             }
 686             if ($is_mswin || $is_vms) {
 687                 $runperl = $runperl . qq ( -e "$prog" );
 688             }
 689             else {
 690                 $runperl = $runperl . qq ( -e '$prog' );
 691             }
 692         }
 693     } elsif (defined $args{progfile}) {
 694         $runperl = $runperl . qq( "$args{progfile}");
 695     } else {
 696         # You probably didn't want to be sucking in from the upstream stdin
 697         die "test.pl:runperl(): none of prog, progs, progfile, args, "
 698             . " switches or stdin specified"
 699             unless defined $args{args} or defined $args{switches}
 700                 or defined $args{stdin};
 701     }
 702     if (defined $args{stdin}) {
 703         # so we don't try to put literal newlines and crs onto the
 704         # command line.
 705         $args{stdin} =~ s/\n/\\n/g;
 706         $args{stdin} =~ s/\r/\\r/g;
 707
 708         if ($is_mswin || $is_vms) {
 709             $runperl = qq{$Perl -e "print qq(} .
 710                 $args{stdin} . q{)" | } . $runperl;
 711         }
 712         else {
 713             $runperl = qq{$Perl -e 'print qq(} .
 714                 $args{stdin} . q{)' | } . $runperl;
 715         }
 716     } elsif (exists $args{stdin}) {
 717         # Using the pipe construction above can cause fun on systems which use
 718         # ksh as /bin/sh, as ksh does pipes differently (with one less process)
 719         # With sh, for the command line 'perl -e 'print qq()' | perl -e ...'
 720         # the sh process forks two children, which use exec to start the two
 721         # perl processes. The parent shell process persists for the duration of
 722         # the pipeline, and the second perl process starts with no children.
 723         # With ksh (and zsh), the shell saves a process by forking a child for
 724         # just the first perl process, and execing itself to start the second.
 725         # This means that the second perl process starts with one child which
 726         # it didn't create. This causes "fun" when if the tests assume that
 727         # wait (or waitpid) will only return information about processes
 728         # started within the test.
 729         # They also cause fun on VMS, where the pipe implementation returns
 730         # the exit code of the process at the front of the pipeline, not the
 731         # end. This messes up any test using OPTION FATAL.
 732         # Hence it's useful to have a way to make STDIN be at eof without
 733         # needing a pipeline, so that the fork tests have a sane environment
 734         # without these surprises.
 735
 736         # /dev/null appears to be surprisingly portable.
 737         $runperl = $runperl . ($is_mswin ? ' <nul' : ' </dev/null');
 738     }
 739     if (defined $args{args}) {
 740         $runperl = _quote_args($runperl, $args{args});
 741     }
 742     if (exists $args{stderr} && $args{stderr} eq 'devnull') {
 743         $runperl = $runperl . ($is_mswin ? ' 2>nul' : ' 2>/dev/null');
 744     }
 745     elsif ($args{stderr}) {
 746         $runperl = $runperl . ' 2>&1';
 747     }
 748     if ($args{verbose}) {
 749         my $runperldisplay = $runperl;
 750         $runperldisplay =~ s/\n/\n\#/g;
 751         _print_stderr "# $runperldisplay\n";
 752     }
 753     return $runperl;
 754 }
 755
 756 # usage:
 757 #  $ENV{PATH} =~ /(.*)/s;
 758 #  local $ENV{PATH} = untaint_path($1);
 759 sub untaint_path {
 760     my $path = shift;
 761     my $sep;
 762
 763     if (! eval {require Config; 1}) {
 764         warn "test.pl had problems loading Config: $@";
 765         $sep = ':';
 766     } else {
 767         $sep = $Config::Config{path_sep};
 768     }
 769
 770     $path =
 771         join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
 772               ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
 773         split quotemeta ($sep), $1;
 774     if ($is_cygwin) {   # Must have /bin under Cygwin
 775         if (length $path) {
 776             $path = $path . $sep;
 777         }
 778         $path = $path . '/bin';
 779     }
 780
 781     $path;
 782 }
 783
 784 # sub run_perl {} is alias to below
 785 # Since this uses backticks to run, it is subject to the rules of the shell.
 786 # Locale settings may pose a problem, depending on the program being run.
 787 sub runperl {
 788     die "test.pl:runperl() does not take a hashref"
 789         if ref $_[0] and ref $_[0] eq 'HASH';
 790     my $runperl = &_create_runperl;
 791     my $result;
 792
 793     my $tainted = ${^TAINT};
 794     my %args = @_;
 795     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
 796
 797     if ($tainted) {
 798         # We will assume that if you're running under -T, you really mean to
 799         # run a fresh perl, so we'll brute force launder everything for you
 800         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
 801         local @ENV{@keys} = ();
 802         # Untaint, plus take out . and empty string:
 803         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
 804         $ENV{PATH} =~ /(.*)/s;
 805         local $ENV{PATH} = untaint_path($1);
 806         $runperl =~ /(.*)/s;
 807         $runperl = $1;
 808
 809         $result = `$runperl`;
 810     } else {
 811         $result = `$runperl`;
 812     }
 813     $result =~ s/\n\n/\n/g if $is_vms; # XXX pipes sometimes double these
 814     return $result;
 815 }
 816
 817 # Nice alias
 818 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
 819
 820 sub DIE {
 821     _print_stderr "# @_\n";
 822     exit 1;
 823 }
 824
 825 # A somewhat safer version of the sometimes wrong $^X.
 826 sub which_perl {
 827     unless (defined $Perl) {
 828         $Perl = $^X;
 829
 830         # VMS should have 'perl' aliased properly
 831         return $Perl if $is_vms;
 832
 833         my $exe;
 834         if (! eval {require Config; 1}) {
 835             warn "test.pl had problems loading Config: $@";
 836             $exe = '';
 837         } else {
 838             $exe = $Config::Config{_exe};
 839         }
 840        $exe = '' unless defined $exe;
 841
 842         # This doesn't absolutize the path: beware of future chdirs().
 843         # We could do File::Spec->abs2rel() but that does getcwd()s,
 844         # which is a bit heavyweight to do here.
 845
 846         if ($Perl =~ /^perl\Q$exe\E$/i) {
 847             my $perl = "perl$exe";
 848             if (! eval {require File::Spec; 1}) {
 849                 warn "test.pl had problems loading File::Spec: $@";
 850                 $Perl = "./$perl";
 851             } else {
 852                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 853             }
 854         }
 855
 856         # Build up the name of the executable file from the name of
 857         # the command.
 858
 859         if ($Perl !~ /\Q$exe\E$/i) {
 860             $Perl = $Perl . $exe;
 861         }
 862
 863         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 864
 865         # For subcommands to use.
 866         $ENV{PERLEXE} = $Perl;
 867     }
 868     return $Perl;
 869 }
 870
 871 sub unlink_all {
 872     my $count = 0;
 873     foreach my $file (@_) {
 874         1 while unlink $file;
 875         if( -f $file ){
 876             _print_stderr "# Couldn't unlink '$file': $!\n";
 877         }else{
 878             $count = $count + 1; # don't use ++
 879         }
 880     }
 881     $count;
 882 }
 883
 884 # _num_to_alpha - Returns a string of letters representing a positive integer.
 885 # Arguments :
 886 #   number to convert
 887 #   maximum number of letters
 888
 889 # returns undef if the number is negative
 890 # returns undef if the number of letters is greater than the maximum wanted
 891
 892 # _num_to_alpha( 0) eq 'A';
 893 # _num_to_alpha( 1) eq 'B';
 894 # _num_to_alpha(25) eq 'Z';
 895 # _num_to_alpha(26) eq 'AA';
 896 # _num_to_alpha(27) eq 'AB';
 897
 898 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
 899
 900 # Avoid ++ -- ranges split negative numbers
 901 sub _num_to_alpha {
 902     my($num,$max_char) = @_;
 903     return unless $num >= 0;
 904     my $alpha = '';
 905     my $char_count = 0;
 906     $max_char = 0 if !defined($max_char) or $max_char < 0;
 907
 908     while( 1 ){
 909         $alpha = $letters[ $num % 26 ] . $alpha;
 910         $num = int( $num / 26 );
 911         last if $num == 0;
 912         $num = $num - 1;
 913
 914         # char limit
 915         next unless $max_char;
 916         $char_count = $char_count + 1;
 917         return if $char_count == $max_char;
 918     }
 919     return $alpha;
 920 }
 921
 922 my %tmpfiles;
 923 sub unlink_tempfiles {
 924     unlink_all keys %tmpfiles;
 925     %tempfiles = ();
 926 }
 927
 928 END { unlink_tempfiles(); }
 929
 930
 931 # NOTE: tempfile() may be used as a module names in our tests
 932 # so the result must be restricted to only legal characters for a module
 933 # name.
 934
 935 # A regexp that matches the tempfile names
 936 $::tempfile_regexp = 'tmp_[A-Z]+_[A-Z]+';
 937
 938 # Avoid ++, avoid ranges, avoid split //
 939 my $tempfile_count = 0;
 940 my $max_file_chars = 3;
 941 sub tempfile {
 942     # if you change the format returned by tempfile() you MUST change
 943     # the $::tempfile_regex define above.
 944     my $try_prefix = (-d "t" ? "t/" : "")."tmp_"._num_to_alpha($$);
 945     while (1) {
 946         my $alpha = _num_to_alpha($tempfile_count,$max_file_chars);
 947         last unless defined $alpha;
 948         my $try = $try_prefix . "_" . $alpha;
 949         $tempfile_count = $tempfile_count + 1;
 950
 951         # Need to note all the file names we allocated, as a second request
 952         # may come before the first is created. Also we are avoiding ++ here
 953         # so we aren't using the normal idiom for this kind of test.
 954         if (!$tmpfiles{$try} && !-e $try) {
 955             # We have a winner
 956             $tmpfiles{$try} = 1;
 957             return $try;
 958         }
 959     }
 960     die sprintf
 961         'panic: Too many tempfile()s with prefix "%s", limit of %d reached',
 962         $try_prefix, 26 ** $max_file_chars;
 963 }
 964
 965 # register_tempfile - Adds a list of files to be removed at the end of the current test file
 966 # Arguments :
 967 #   a list of files to be removed later
 968
 969 # returns a count of how many file names were actually added
 970
 971 # Reuses %tmpfiles so that tempfile() will also skip any files added here
 972 # even if the file doesn't exist yet.
 973
 974 sub register_tempfile {
 975     my $count = 0;
 976     for( @_ ){
 977         if( $tmpfiles{$_} ){
 978             _print_stderr "# Temporary file '$_' already added\n";
 979         }else{
 980             $tmpfiles{$_} = 1;
 981             $count = $count + 1;
 982         }
 983     }
 984     return $count;
 985 }
 986
 987 # This is the temporary file for fresh_perl
 988 my $tmpfile = tempfile();
 989
 990 sub fresh_perl {
 991     my($prog, $runperl_args) = @_;
 992
 993     # Run 'runperl' with the complete perl program contained in '$prog', and
 994     # arguments in the hash referred to by '$runperl_args'.  The results are
 995     # returned, with $? set to the exit code.  Unless overridden, stderr is
 996     # redirected to stdout.
 997     #
 998     # Placing the program in a file bypasses various sh vagaries
 999
1000     die sprintf "Second argument to fresh_perl_.* must be hashref of args to fresh_perl (or {})"
1001         unless !(defined $runperl_args) || ref($runperl_args) eq 'HASH';
1002
1003     # Given the choice of the mis-parsable {}
1004     # (we want an anon hash, but a borked lexer might think that it's a block)
1005     # or relying on taking a reference to a lexical
1006     # (\ might be mis-parsed, and the reference counting on the pad may go
1007     #  awry)
1008     # it feels like the least-worse thing is to assume that auto-vivification
1009     # works. At least, this is only going to be a run-time failure, so won't
1010     # affect tests using this file but not this function.
1011     $runperl_args->{progfile} ||= $tmpfile;
1012     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
1013
1014     open TEST, '>', $tmpfile or die "Cannot open $tmpfile: $!";
1015     binmode TEST, ':utf8' if $runperl_args->{wide_chars};
1016     print TEST $prog;
1017     close TEST or die "Cannot close $tmpfile: $!";
1018
1019     my $results = runperl(%$runperl_args);
1020     my $status = $?;    # Not necessary to save this, but it makes it clear to
1021                         # future maintainers.
1022
1023     # Clean up the results into something a bit more predictable.
1024     $results  =~ s/\n+$//;
1025     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
1026     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
1027
1028     # bison says 'parse error' instead of 'syntax error',
1029     # various yaccs may or may not capitalize 'syntax'.
1030     $results =~ s/^(syntax|parse) error/syntax error/mig;
1031
1032     if ($is_vms) {
1033         # some tests will trigger VMS messages that won't be expected
1034         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1035
1036         # pipes double these sometimes
1037         $results =~ s/\n\n/\n/g;
1038     }
1039
1040     $? = $status;
1041     return $results;
1042 }
1043
1044
1045 sub _fresh_perl {
1046     my($prog, $action, $expect, $runperl_args, $name) = @_;
1047
1048     my $results = fresh_perl($prog, $runperl_args);
1049     my $status = $?;
1050
1051     # Use the first line of the program as a name if none was given
1052     unless( $name ) {
1053         (my $first_line, $name) = $prog =~ /^((.{1,50}).*)/;
1054         $name = $name . '...' if length $first_line > length $name;
1055     }
1056
1057     # Historically this was implemented using a closure, but then that means
1058     # that the tests for closures avoid using this code. Given that there
1059     # are exactly two callers, doing exactly two things, the simpler approach
1060     # feels like a better trade off.
1061     my $pass;
1062     if ($action eq 'eq') {
1063         $pass = is($results, $expect, $name);
1064     } elsif ($action eq '=~') {
1065         $pass = like($results, $expect, $name);
1066     } else {
1067         die "_fresh_perl can't process action '$action'";
1068     }
1069
1070     unless ($pass) {
1071         _diag "# PROG: \n$prog\n";
1072         _diag "# STATUS: $status\n";
1073     }
1074
1075     return $pass;
1076 }
1077
1078 #
1079 # fresh_perl_is
1080 #
1081 # Combination of run_perl() and is().
1082 #
1083
1084 sub fresh_perl_is {
1085     my($prog, $expected, $runperl_args, $name) = @_;
1086
1087     # _fresh_perl() is going to clip the trailing newlines off the result.
1088     # This will make it so the test author doesn't have to know that.
1089     $expected =~ s/\n+$//;
1090
1091     local $Level = 2;
1092     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
1093 }
1094
1095 #
1096 # fresh_perl_like
1097 #
1098 # Combination of run_perl() and like().
1099 #
1100
1101 sub fresh_perl_like {
1102     my($prog, $expected, $runperl_args, $name) = @_;
1103     local $Level = 2;
1104     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
1105 }
1106
1107 # Many tests use the same format in __DATA__ or external files to specify a
1108 # sequence of (fresh) tests to run, extra files they may temporarily need, and
1109 # what the expected output is.  Putting it here allows common code to serve
1110 # these multiple tests.
1111 #
1112 # Each program is source code to run followed by an "EXPECT" line, followed
1113 # by the expected output.
1114 #
1115 # The first line of the code to run may be a command line switch such as -wE
1116 # or -0777 (alphanumerics only; only one cluster, beginning with a minus is
1117 # allowed).  Later lines may contain (note the '# ' on each):
1118 #   # TODO reason for todo
1119 #   # SKIP reason for skip
1120 #   # SKIP ?code to test if this should be skipped
1121 #   # NAME name of the test (as with ok($ok, $name))
1122 #
1123 # The expected output may contain:
1124 #   OPTION list of options
1125 #   OPTIONS list of options
1126 #
1127 # The possible options for OPTION may be:
1128 #   regex - the expected output is a regular expression
1129 #   random - all lines match but in any order
1130 #   fatal - the code will fail fatally (croak, die)
1131 #   nonfatal - the code is not expected to fail fatally
1132 #
1133 # If the actual output contains a line "SKIPPED" the test will be
1134 # skipped.
1135 #
1136 # If the actual output contains a line "PREFIX", any output starting with that
1137 # line will be ignored when comparing with the expected output
1138 #
1139 # If the global variable $FATAL is true then OPTION fatal is the
1140 # default.
1141
1142 our $FATAL;
1143 sub _setup_one_file {
1144     my $fh = shift;
1145     # Store the filename as a program that started at line 0.
1146     # Real files count lines starting at line 1.
1147     my @these = (0, shift);
1148     my ($lineno, $current);
1149     while (<$fh>) {
1150         if ($_ eq "########\n") {
1151             if (defined $current) {
1152                 push @these, $lineno, $current;
1153             }
1154             undef $current;
1155         } else {
1156             if (!defined $current) {
1157                 $lineno = $.;
1158             }
1159             $current .= $_;
1160         }
1161     }
1162     if (defined $current) {
1163         push @these, $lineno, $current;
1164     }
1165     ((scalar @these) / 2 - 1, @these);
1166 }
1167
1168 sub setup_multiple_progs {
1169     my ($tests, @prgs);
1170     foreach my $file (@_) {
1171         next if $file =~ /(?:~|\.orig|,v)$/;
1172         next if $file =~ /perlio$/ && !PerlIO::Layer->find('perlio');
1173         next if -d $file;
1174
1175         open my $fh, '<', $file or die "Cannot open $file: $!\n" ;
1176         my $found;
1177         while (<$fh>) {
1178             if (/^__END__/) {
1179                 $found = $found + 1; # don't use ++
1180                 last;
1181             }
1182         }
1183         # This is an internal error, and should never happen. All bar one of
1184         # the files had an __END__ marker to signal the end of their preamble,
1185         # although for some it wasn't technically necessary as they have no
1186         # tests. It might be possible to process files without an __END__ by
1187         # seeking back to the start and treating the whole file as tests, but
1188         # it's simpler and more reliable just to make the rule that all files
1189         # must have __END__ in. This should never fail - a file without an
1190         # __END__ should not have been checked in, because the regression tests
1191         # would not have passed.
1192         die "Could not find '__END__' in $file"
1193             unless $found;
1194
1195         my ($t, @p) = _setup_one_file($fh, $file);
1196         $tests += $t;
1197         push @prgs, @p;
1198
1199         close $fh
1200             or die "Cannot close $file: $!\n";
1201     }
1202     return ($tests, @prgs);
1203 }
1204
1205 sub run_multiple_progs {
1206     my $up = shift;
1207     my @prgs;
1208     if ($up) {
1209         # The tests in lib run in a temporary subdirectory of t, and always
1210         # pass in a list of "programs" to run
1211         @prgs = @_;
1212     } else {
1213         # The tests below t run in t and pass in a file handle. In theory we
1214         # can pass (caller)[1] as the second argument to report errors with
1215         # the filename of our caller, as the handle is always DATA. However,
1216         # line numbers in DATA count from the __END__ token, so will be wrong.
1217         # Which is more confusing than not providing line numbers. So, for now,
1218         # don't provide line numbers. No obvious clean solution - one hack
1219         # would be to seek DATA back to the start and read to the __END__ token,
1220         # but that feels almost like we should just open $0 instead.
1221
1222         # Not going to rely on undef in list assignment.
1223         my $dummy;
1224         ($dummy, @prgs) = _setup_one_file(shift);
1225     }
1226
1227     my $tmpfile = tempfile();
1228
1229     my $count_failures = 0;
1230     my ($file, $line);
1231   PROGRAM:
1232     while (defined ($line = shift @prgs)) {
1233         $_ = shift @prgs;
1234         unless ($line) {
1235             $file = $_;
1236             if (defined $file) {
1237                 print "# From $file\n";
1238             }
1239             next;
1240         }
1241         my $switch = "";
1242         my @temps ;
1243         my @temp_path;
1244         if (s/^(\s*-\w+)//) {
1245             $switch = $1;
1246         }
1247         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
1248
1249         my %reason;
1250         foreach my $what (qw(skip todo)) {
1251             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
1252             # If the SKIP reason starts ? then it's taken as a code snippet to
1253             # evaluate. This provides the flexibility to have conditional SKIPs
1254             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
1255                 my $temp = eval $reason{$what};
1256                 if ($@) {
1257                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
1258                 }
1259                 $reason{$what} = $temp;
1260             }
1261         }
1262
1263     my $name = '';
1264     if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
1265         $name = $1;
1266     } elsif (defined $file) {
1267         $name = "test from $file at line $line";
1268     }
1269
1270         if ($reason{skip}) {
1271         SKIP:
1272           {
1273             skip($name ? "$name - $reason{skip}" : $reason{skip}, 1);
1274           }
1275           next PROGRAM;
1276         }
1277
1278         if ($prog =~ /--FILE--/) {
1279             my @files = split(/\n?--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
1280             shift @files ;
1281             die "Internal error: test $_ didn't split into pairs, got " .
1282                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
1283                     if @files % 2;
1284             while (@files > 2) {
1285                 my $filename = shift @files;
1286                 my $code = shift @files;
1287                 push @temps, $filename;
1288                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
1289                     require File::Path;
1290                     File::Path::mkpath($1);
1291                     push(@temp_path, $1);
1292                 }
1293                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
1294                 print $fh $code;
1295                 close $fh or die "Cannot close $filename: $!\n";
1296             }
1297             shift @files;
1298             $prog = shift @files;
1299         }
1300
1301         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
1302         print $fh q{
1303         BEGIN {
1304             push @INC, '.';
1305             open STDERR, '>&', STDOUT
1306               or die "Can't dup STDOUT->STDERR: $!;";
1307         }
1308         };
1309         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
1310         print $fh $prog,"\n";
1311         close $fh or die "Cannot close $tmpfile: $!";
1312         my $results = runperl( stderr => 1, progfile => $tmpfile,
1313                                stdin => undef, $up
1314                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1315                                : (switches => [$switch])
1316                                 );
1317         my $status = $?;
1318         $results =~ s/\n+$//;
1319         # allow expected output to be written as if $prog is on STDIN
1320         $results =~ s/$::tempfile_regexp/-/g;
1321         if ($^O eq 'VMS') {
1322             # some tests will trigger VMS messages that won't be expected
1323             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1324
1325             # pipes double these sometimes
1326             $results =~ s/\n\n/\n/g;
1327         }
1328         # bison says 'parse error' instead of 'syntax error',
1329         # various yaccs may or may not capitalize 'syntax'.
1330         $results =~ s/^(syntax|parse) error/syntax error/mig;
1331         # allow all tests to run when there are leaks
1332         $results =~ s/Scalars leaked: \d+\n//g;
1333
1334         $expected =~ s/\n+$//;
1335         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1336         # any special options? (OPTIONS foo bar zap)
1337         my $option_regex = 0;
1338         my $option_random = 0;
1339         my $fatal = $FATAL;
1340         if ($expected =~ s/^OPTIONS? (.+)(?:\n|\Z)//) {
1341             foreach my $option (split(' ', $1)) {
1342                 if ($option eq 'regex') { # allow regular expressions
1343                     $option_regex = 1;
1344                 }
1345                 elsif ($option eq 'random') { # all lines match, but in any order
1346                     $option_random = 1;
1347                 }
1348                 elsif ($option eq 'fatal') { # perl should fail
1349                     $fatal = 1;
1350                 }
1351                 elsif ($option eq 'nonfatal') {
1352                     # used to turn off default fatal
1353                     $fatal = 0;
1354                 }
1355                 else {
1356                     die "$0: Unknown OPTION '$option'\n";
1357                 }
1358             }
1359         }
1360         die "$0: can't have OPTION regex and random\n"
1361             if $option_regex + $option_random > 1;
1362         my $ok = 0;
1363         if ($results =~ s/^SKIPPED\n//) {
1364             print "$results\n" ;
1365             $ok = 1;
1366         }
1367         else {
1368             if ($option_random) {
1369                 my @got = sort split "\n", $results;
1370                 my @expected = sort split "\n", $expected;
1371
1372                 $ok = "@got" eq "@expected";
1373             }
1374             elsif ($option_regex) {
1375                 $ok = $results =~ /^$expected/;
1376             }
1377             elsif ($prefix) {
1378                 $ok = $results =~ /^\Q$expected/;
1379             }
1380             else {
1381                 $ok = $results eq $expected;
1382             }
1383
1384             if ($ok && $fatal && !($status >> 8)) {
1385                 $ok = 0;
1386             }
1387         }
1388
1389         local $::TODO = $reason{todo};
1390
1391         unless ($ok) {
1392         my $err_line = '';
1393         $err_line   .= "FILE: $file ; line $line\n" if defined $file;
1394         $err_line   .= "PROG: $switch\n$prog\n" .
1395                                    "EXPECTED:\n$expected\n";
1396         $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1397         $err_line   .= "GOT:\n$results\n";
1398         $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1399         if ($::TODO) {
1400             $err_line =~ s/^/# /mg;
1401             print $err_line;  # Harness can't filter it out from STDERR.
1402         }
1403         else {
1404             print STDERR $err_line;
1405             ++$count_failures;
1406             die "PERL_TEST_ABORT_FIRST_FAILURE set Test Failure"
1407                 if $ENV{PERL_TEST_ABORT_FIRST_FAILURE};
1408         }
1409     }
1410
1411         if (defined $file) {
1412             _ok($ok, "at $file line $line", $name);
1413         } else {
1414             # We don't have file and line number data for the test, so report
1415             # errors as coming from our caller.
1416             local $Level = $Level + 1;
1417             ok($ok, $name);
1418         }
1419
1420         foreach (@temps) {
1421             unlink $_ if $_;
1422         }
1423         foreach (@temp_path) {
1424             File::Path::rmtree $_ if -d $_;
1425         }
1426     }
1427
1428     if ( $count_failures ) {
1429         print STDERR <<'EOS';
1430 #
1431 # Note: 'run_multiple_progs' run has one or more failures
1432 #        you can consider setting the environment variable
1433 #        PERL_TEST_ABORT_FIRST_FAILURE=1 before running the test
1434 #        to stop on the first error.
1435 #
1436 EOS
1437     }
1438
1439
1440     return;
1441 }
1442
1443 sub can_ok ($@) {
1444     my($proto, @methods) = @_;
1445     my $class = ref $proto || $proto;
1446
1447     unless( @methods ) {
1448         return _ok( 0, _where(), "$class->can(...)" );
1449     }
1450
1451     my @nok = ();
1452     foreach my $method (@methods) {
1453         local($!, $@);  # don't interfere with caller's $@
1454                         # eval sometimes resets $!
1455         eval { $proto->can($method) } || push @nok, $method;
1456     }
1457
1458     my $name;
1459     $name = @methods == 1 ? "$class->can('$methods[0]')"
1460                           : "$class->can(...)";
1461
1462     _ok( !@nok, _where(), $name );
1463 }
1464
1465
1466 # Call $class->new( @$args ); and run the result through object_ok.
1467 # See Test::More::new_ok
1468 sub new_ok {
1469     my($class, $args, $obj_name) = @_;
1470     $args ||= [];
1471     $obj_name = "The object" unless defined $obj_name;
1472
1473     local $Level = $Level + 1;
1474
1475     my $obj;
1476     my $ok = eval { $obj = $class->new(@$args); 1 };
1477     my $error = $@;
1478
1479     if($ok) {
1480         object_ok($obj, $class, $obj_name);
1481     }
1482     else {
1483         ok( 0, "new() died" );
1484         diag("Error was:  $@");
1485     }
1486
1487     return $obj;
1488
1489 }
1490
1491
1492 sub isa_ok ($$;$) {
1493     my($object, $class, $obj_name) = @_;
1494
1495     my $diag;
1496     $obj_name = 'The object' unless defined $obj_name;
1497     my $name = "$obj_name isa $class";
1498     if( !defined $object ) {
1499         $diag = "$obj_name isn't defined";
1500     }
1501     else {
1502         my $whatami = ref $object ? 'object' : 'class';
1503
1504         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1505         local($@, $!);  # eval sometimes resets $!
1506         my $rslt = eval { $object->isa($class) };
1507         my $error = $@;  # in case something else blows away $@
1508
1509         if( $error ) {
1510             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1511                 # It's an unblessed reference
1512                 $obj_name = 'The reference' unless defined $obj_name;
1513                 if( !UNIVERSAL::isa($object, $class) ) {
1514                     my $ref = ref $object;
1515                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1516                 }
1517             }
1518             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1519                 # It's something that can't even be a class
1520                 $obj_name = 'The thing' unless defined $obj_name;
1521                 $diag = "$obj_name isn't a class or reference";
1522             }
1523             else {
1524                 die <<WHOA;
1525 WHOA! I tried to call ->isa on your object and got some weird error.
1526 This should never happen.  Please contact the author immediately.
1527 Here's the error.
1528 $@
1529 WHOA
1530             }
1531         }
1532         elsif( !$rslt ) {
1533             $obj_name = "The $whatami" unless defined $obj_name;
1534             my $ref = ref $object;
1535             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1536         }
1537     }
1538
1539     _ok( !$diag, _where(), $name );
1540 }
1541
1542
1543 sub class_ok {
1544     my($class, $isa, $class_name) = @_;
1545
1546     # Written so as to count as one test
1547     local $Level = $Level + 1;
1548     if( ref $class ) {
1549         ok( 0, "$class is a reference, not a class name" );
1550     }
1551     else {
1552         isa_ok($class, $isa, $class_name);
1553     }
1554 }
1555
1556
1557 sub object_ok {
1558     my($obj, $isa, $obj_name) = @_;
1559
1560     local $Level = $Level + 1;
1561     if( !ref $obj ) {
1562         ok( 0, "$obj is not a reference" );
1563     }
1564     else {
1565         isa_ok($obj, $isa, $obj_name);
1566     }
1567 }
1568
1569
1570 # Purposefully avoiding a closure.
1571 sub __capture {
1572     push @::__capture, join "", @_;
1573 }
1574
1575 sub capture_warnings {
1576     my $code = shift;
1577
1578     local @::__capture;
1579     local $SIG {__WARN__} = \&__capture;
1580     local $Level = 1;
1581     &$code;
1582     return @::__capture;
1583 }
1584
1585 # This will generate a variable number of tests.
1586 # Use done_testing() instead of a fixed plan.
1587 sub warnings_like {
1588     my ($code, $expect, $name) = @_;
1589     local $Level = $Level + 1;
1590
1591     my @w = capture_warnings($code);
1592
1593     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1594     foreach my $e (@$expect) {
1595         if (ref $e) {
1596             like(shift @w, $e, $name);
1597         } else {
1598             is(shift @w, $e, $name);
1599         }
1600     }
1601     if (@w) {
1602         diag("Saw these additional warnings:");
1603         diag($_) foreach @w;
1604     }
1605 }
1606
1607 sub _fail_excess_warnings {
1608     my($expect, $got, $name) = @_;
1609     local $Level = $Level + 1;
1610     # This will fail, and produce diagnostics
1611     is($expect, scalar @$got, $name);
1612     diag("Saw these warnings:");
1613     diag($_) foreach @$got;
1614 }
1615
1616 sub warning_is {
1617     my ($code, $expect, $name) = @_;
1618     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1619         if ref $expect;
1620     local $Level = $Level + 1;
1621     my @w = capture_warnings($code);
1622     if (@w > 1) {
1623         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1624     } else {
1625         is($w[0], $expect, $name);
1626     }
1627 }
1628
1629 sub warning_like {
1630     my ($code, $expect, $name) = @_;
1631     die sprintf "Expect must be a regexp object"
1632         unless ref $expect eq 'Regexp';
1633     local $Level = $Level + 1;
1634     my @w = capture_warnings($code);
1635     if (@w > 1) {
1636         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1637     } else {
1638         like($w[0], $expect, $name);
1639     }
1640 }
1641
1642 # Set a watchdog to timeout the entire test file
1643 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1644 #        _AFTER_ the 'threads' module is loaded.
1645 sub watchdog ($;$)
1646 {
1647     my $timeout = shift;
1648     my $method  = shift || "";
1649     my $timeout_msg = 'Test process timed out - terminating';
1650
1651     # Valgrind slows perl way down so give it more time before dying.
1652     $timeout *= 10 if $ENV{PERL_VALGRIND};
1653
1654     my $pid_to_kill = $$;   # PID for this process
1655
1656     if ($method eq "alarm") {
1657         goto WATCHDOG_VIA_ALARM;
1658     }
1659
1660     # shut up use only once warning
1661     my $threads_on = $threads::threads && $threads::threads;
1662
1663     # Don't use a watchdog process if 'threads' is loaded -
1664     #   use a watchdog thread instead
1665     if (!$threads_on || $method eq "process") {
1666
1667         # On Windows and VMS, try launching a watchdog process
1668         #   using system(1, ...) (see perlport.pod)
1669         if ($is_mswin || $is_vms) {
1670             # On Windows, try to get the 'real' PID
1671             if ($is_mswin) {
1672                 eval { require Win32; };
1673                 if (defined(&Win32::GetCurrentProcessId)) {
1674                     $pid_to_kill = Win32::GetCurrentProcessId();
1675                 }
1676             }
1677
1678             # If we still have a fake PID, we can't use this method at all
1679             return if ($pid_to_kill <= 0);
1680
1681             # Launch watchdog process
1682             my $watchdog;
1683             eval {
1684                 local $SIG{'__WARN__'} = sub {
1685                     _diag("Watchdog warning: $_[0]");
1686                 };
1687                 my $sig = $is_vms ? 'TERM' : 'KILL';
1688                 my $prog = "sleep($timeout);" .
1689                            "warn qq/# $timeout_msg" . '\n/;' .
1690                            "kill(q/$sig/, $pid_to_kill);";
1691
1692                 # If we're in taint mode PATH will be tainted
1693                 $ENV{PATH} =~ /(.*)/s;
1694                 local $ENV{PATH} = untaint_path($1);
1695
1696                 # On Windows use the indirect object plus LIST form to guarantee
1697                 # that perl is launched directly rather than via the shell (see
1698                 # perlfunc.pod), and ensure that the LIST has multiple elements
1699                 # since the indirect object plus COMMANDSTRING form seems to
1700                 # hang (see perl #121283). Don't do this on VMS, which doesn't
1701                 # support the LIST form at all.
1702                 if ($is_mswin) {
1703                     my $runperl = which_perl();
1704                     $runperl =~ /(.*)/;
1705                     $runperl = $1;
1706                     if ($runperl =~ m/\s/) {
1707                         $runperl = qq{"$runperl"};
1708                     }
1709                     $watchdog = system({ $runperl } 1, $runperl, '-e', $prog);
1710                 }
1711                 else {
1712                     my $cmd = _create_runperl(prog => $prog);
1713                     $watchdog = system(1, $cmd);
1714                 }
1715             };
1716             if ($@ || ($watchdog <= 0)) {
1717                 _diag('Failed to start watchdog');
1718                 _diag($@) if $@;
1719                 undef($watchdog);
1720                 return;
1721             }
1722
1723             # Add END block to parent to terminate and
1724             #   clean up watchdog process
1725             eval("END { local \$! = 0; local \$? = 0;
1726                         wait() if kill('KILL', $watchdog); };");
1727             return;
1728         }
1729
1730         # Try using fork() to generate a watchdog process
1731         my $watchdog;
1732         eval { $watchdog = fork() };
1733         if (defined($watchdog)) {
1734             if ($watchdog) {   # Parent process
1735                 # Add END block to parent to terminate and
1736                 #   clean up watchdog process
1737                 eval "END { local \$! = 0; local \$? = 0;
1738                             wait() if kill('KILL', $watchdog); };";
1739                 return;
1740             }
1741
1742             ### Watchdog process code
1743
1744             # Load POSIX if available
1745             eval { require POSIX; };
1746
1747             # Execute the timeout
1748             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1749             sleep(2);
1750
1751             # Kill test process if still running
1752             if (kill(0, $pid_to_kill)) {
1753                 _diag($timeout_msg);
1754                 kill('KILL', $pid_to_kill);
1755                 if ($is_cygwin) {
1756                     # sometimes the above isn't enough on cygwin
1757                     sleep 1; # wait a little, it might have worked after all
1758                     system("/bin/kill -f $pid_to_kill") if kill(0, $pid_to_kill);
1759                 }
1760             }
1761
1762             # Don't execute END block (added at beginning of this file)
1763             $NO_ENDING = 1;
1764
1765             # Terminate ourself (i.e., the watchdog)
1766             POSIX::_exit(1) if (defined(&POSIX::_exit));
1767             exit(1);
1768         }
1769
1770         # fork() failed - fall through and try using a thread
1771     }
1772
1773     # Use a watchdog thread because either 'threads' is loaded,
1774     #   or fork() failed
1775     if (eval {require threads; 1}) {
1776         'threads'->create(sub {
1777                 # Load POSIX if available
1778                 eval { require POSIX; };
1779
1780                 # Execute the timeout
1781                 my $time_left = $timeout;
1782                 do {
1783                     $time_left = $time_left - sleep($time_left);
1784                 } while ($time_left > 0);
1785
1786                 # Kill the parent (and ourself)
1787                 select(STDERR); $| = 1;
1788                 _diag($timeout_msg);
1789                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1790                 my $sig = $is_vms ? 'TERM' : 'KILL';
1791                 kill($sig, $pid_to_kill);
1792             })->detach();
1793         return;
1794     }
1795
1796     # If everything above fails, then just use an alarm timeout
1797 WATCHDOG_VIA_ALARM:
1798     if (eval { alarm($timeout); 1; }) {
1799         # Load POSIX if available
1800         eval { require POSIX; };
1801
1802         # Alarm handler will do the actual 'killing'
1803         $SIG{'ALRM'} = sub {
1804             select(STDERR); $| = 1;
1805             _diag($timeout_msg);
1806             POSIX::_exit(1) if (defined(&POSIX::_exit));
1807             my $sig = $is_vms ? 'TERM' : 'KILL';
1808             kill($sig, $pid_to_kill);
1809         };
1810     }
1811 }
1812
1813 # Orphaned Docker or Linux containers do not necessarily attach to PID 1. They might attach to 0 instead.
1814 sub is_linux_container {
1815
1816     if ($^O eq 'linux' && open my $fh, '<', '/proc/1/cgroup') {
1817         while(<$fh>) {
1818             if (m{^\d+:pids:(.*)} && $1 ne '/init.scope') {
1819                 return 1;
1820             }
1821         }
1822     }
1823
1824     return 0;
1825 }
1826
1827 1;