t/op/universal.t

   1 #!./perl
   2 #
   3 # check UNIVERSAL
   4 #
   5
   6 BEGIN {
   7     chdir 't' if -d 't';
   8     @INC = '../lib';
   9     $| = 1;
  10     require "./test.pl";
  11 }
  12
  13 plan tests => 129;
  14
  15 $a = {};
  16 bless $a, "Bob";
  17 ok $a->isa("Bob");
  18
  19 package Human;
  20 sub eat {}
  21
  22 package Female;
  23 @ISA=qw(Human);
  24
  25 package Alice;
  26 @ISA=qw(Bob Female);
  27 sub sing;
  28 sub drink { return "drinking " . $_[1]  }
  29 sub new { bless {} }
  30
  31 $Alice::VERSION = 2.718;
  32
  33 {
  34     package Cedric;
  35     our @ISA;
  36     use base qw(Human);
  37 }
  38
  39 {
  40     package Programmer;
  41     our $VERSION = 1.667;
  42
  43     sub write_perl { 1 }
  44 }
  45
  46 package main;
  47
  48
  49
  50 $a = new Alice;
  51
  52 ok $a->isa("Alice");
  53 ok $a->isa("main::Alice");    # check that alternate class names work
  54
  55 ok(("main::Alice"->new)->isa("Alice"));
  56
  57 ok $a->isa("Bob");
  58 ok $a->isa("main::Bob");
  59
  60 ok $a->isa("Female");
  61
  62 ok ! $a->isa("Female\0NOT REALLY!"), "->isa is nul-clean.";
  63
  64 ok $a->isa("Human");
  65
  66 ok ! $a->isa("Male");
  67
  68 ok ! $a->isa('Programmer');
  69
  70 ok $a->isa("HASH");
  71
  72 ok $a->can("eat");
  73 ok ! $a->can("eat\0Except not!"), "->can is nul-clean.";
  74 ok ! $a->can("sleep");
  75 ok my $ref = $a->can("drink");        # returns a coderef
  76 is $a->$ref("tea"), "drinking tea"; # ... which works
  77 ok $ref = $a->can("sing");
  78 eval { $a->$ref() };
  79 ok $@;                                # ... but not if no actual subroutine
  80
  81 ok (!Cedric->isa('Programmer'));
  82
  83 ok (Cedric->isa('Human'));
  84
  85 push(@Cedric::ISA,'Programmer');
  86
  87 ok (Cedric->isa('Programmer'));
  88
  89 {
  90     package Alice;
  91     base::->import('Programmer');
  92 }
  93
  94 ok $a->isa('Programmer');
  95 ok $a->isa("Female");
  96
  97 @Cedric::ISA = qw(Bob);
  98
  99 ok (!Cedric->isa('Programmer'));
 100
 101 my $b = 'abc';
 102 my @refs = qw(SCALAR SCALAR     LVALUE      GLOB ARRAY HASH CODE);
 103 my @vals = (  \$b,   \3.14, \substr($b,1,1), \*b,  [],  {}, sub {} );
 104 for ($p=0; $p < @refs; $p++) {
 105     for ($q=0; $q < @vals; $q++) {
 106         is UNIVERSAL::isa($vals[$p], $refs[$q]), ($p==$q or $p+$q==1);
 107     };
 108 };
 109
 110 ok ! UNIVERSAL::can(23, "can");
 111
 112 ok $a->can("VERSION");
 113
 114 ok $a->can("can");
 115 ok ! $a->can("export_tags");    # a method in Exporter
 116
 117 cmp_ok eval { $a->VERSION }, '==', 2.718;
 118
 119 ok ! (eval { $a->VERSION(2.719) });
 120 like $@, qr/^Alice version 2.719 required--this is only version 2.718 at /;
 121
 122 ok (eval { $a->VERSION(2.718) });
 123 is $@, '';
 124
 125 my $subs = join ' ', sort grep { defined &{"UNIVERSAL::$_"} } keys %UNIVERSAL::;
 126 ## The test for import here is *not* because we want to ensure that UNIVERSAL
 127 ## can always import; it is an historical accident that UNIVERSAL can import.
 128 if ('a' lt 'A') {
 129     is $subs, "can import isa DOES VERSION";
 130 } else {
 131     is $subs, "DOES VERSION can import isa";
 132 }
 133
 134 ok $a->isa("UNIVERSAL");
 135
 136 ok ! UNIVERSAL::isa([], "UNIVERSAL");
 137
 138 ok ! UNIVERSAL::can({}, "can");
 139
 140 ok UNIVERSAL::isa(Alice => "UNIVERSAL");
 141
 142 cmp_ok UNIVERSAL::can(Alice => "can"), '==', \&UNIVERSAL::can;
 143
 144 # now use UNIVERSAL.pm and see what changes
 145 eval "use UNIVERSAL";
 146
 147 ok $a->isa("UNIVERSAL");
 148
 149 my $sub2 = join ' ', sort grep { defined &{"UNIVERSAL::$_"} } keys %UNIVERSAL::;
 150 # XXX import being here is really a bug
 151 if ('a' lt 'A') {
 152     is $sub2, "can import isa DOES VERSION";
 153 } else {
 154     is $sub2, "DOES VERSION can import isa";
 155 }
 156
 157 eval 'sub UNIVERSAL::sleep {}';
 158 ok $a->can("sleep");
 159
 160 ok ! UNIVERSAL::can($b, "can");
 161
 162 ok ! $a->can("export_tags");    # a method in Exporter
 163
 164 ok ! UNIVERSAL::isa("\xff\xff\xff\0", 'HASH');
 165
 166 {
 167     package Pickup;
 168     use UNIVERSAL qw( isa can VERSION );
 169
 170     ::ok isa "Pickup", UNIVERSAL;
 171     ::cmp_ok can( "Pickup", "can" ), '==', \&UNIVERSAL::can;
 172     ::ok VERSION "UNIVERSAL" ;
 173 }
 174
 175 {
 176     # test isa() and can() on magic variables
 177     "Human" =~ /(.*)/;
 178     ok $1->isa("Human");
 179     ok $1->can("eat");
 180     package HumanTie;
 181     sub TIESCALAR { bless {} }
 182     sub FETCH { "Human" }
 183     tie my($x), "HumanTie";
 184     ::ok $x->isa("Human");
 185     ::ok $x->can("eat");
 186 }
 187
 188 # bugid 3284
 189 # a second call to isa('UNIVERSAL') when @ISA is null failed due to caching
 190
 191 @X::ISA=();
 192 my $x = {}; bless $x, 'X';
 193 ok $x->isa('UNIVERSAL');
 194 ok $x->isa('UNIVERSAL');
 195
 196
 197 # Check that the "historical accident" of UNIVERSAL having an import()
 198 # method doesn't effect anyone else.
 199 eval { Some::Package->import("bar") };
 200 is $@, '';
 201
 202
 203 # This segfaulted in a blead.
 204 fresh_perl_is('package Foo; Foo->VERSION;  print "ok"', 'ok');
 205
 206 # So did this.
 207 fresh_perl_is('$:; UNIVERSAL::isa(":","Unicode::String");print "ok"','ok');
 208
 209 package Foo;
 210
 211 sub DOES { 1 }
 212
 213 package Bar;
 214
 215 @Bar::ISA = 'Foo';
 216
 217 package Baz;
 218
 219 package main;
 220 ok( Foo->DOES( 'bar' ), 'DOES() should call DOES() on class' );
 221 ok( Bar->DOES( 'Bar' ), '... and should fall back to isa()' );
 222 ok( Bar->DOES( 'Foo' ), '... even when inherited' );
 223 ok( Baz->DOES( 'Baz' ), '... even without inheriting any other DOES()' );
 224 ok( ! Baz->DOES( 'Foo' ), '... returning true or false appropriately' );
 225
 226 ok( ! "T"->DOES( "T\0" ), 'DOES() is nul-clean' );
 227 ok( ! Baz->DOES( "Baz\0Boy howdy" ), 'DOES() is nul-clean' );
 228
 229 package Pig;
 230 package Bodine;
 231 Bodine->isa('Pig');
 232 *isa = \&UNIVERSAL::isa;
 233 eval { isa({}, 'HASH') };
 234 ::is($@, '', "*isa correctly found");
 235
 236 package main;
 237 eval { UNIVERSAL::DOES([], "foo") };
 238 like( $@, qr/Can't call method "DOES" on unblessed reference/,
 239     'DOES call error message says DOES, not isa' );
 240
 241 # Tests for can seem to be split between here and method.t
 242 # Add the verbatim perl code mentioned in the comments of
 243 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2001-05/msg01710.html
 244 # but never actually tested.
 245 is(UNIVERSAL->can("NoSuchPackage::foo"), undef);
 246
 247 @splatt::ISA = 'zlopp';
 248 ok (splatt->isa('zlopp'));
 249 ok (!splatt->isa('plop'));
 250
 251 # This should reset the ->isa lookup cache
 252 @splatt::ISA = 'plop';
 253 # And here is the new truth.
 254 ok (!splatt->isa('zlopp'));
 255 ok (splatt->isa('plop'));
 256
 257 use warnings "deprecated";
 258 {
 259     my $m;
 260     local $SIG{__WARN__} = sub { $m = $_[0] };
 261     eval "use UNIVERSAL 'can'";
 262     like($m, qr/^UNIVERSAL->import is deprecated/,
 263         "deprecation warning for UNIVERSAL->import('can')");
 264
 265           undef $m;
 266     eval "use UNIVERSAL";
 267     is($m, undef,
 268         "no deprecation warning for UNIVERSAL->import");
 269 }
 270
 271 # Test: [perl #66112]: change @ISA inside  sub isa
 272 {
 273     package RT66112::A;
 274
 275     package RT66112::B;
 276
 277     sub isa {
 278         my $self = shift;
 279         @ISA = qw/RT66112::A/;
 280         return $self->SUPER::isa(@_);
 281     }
 282
 283     package RT66112::C;
 284
 285     package RT66112::D;
 286
 287     sub isa {
 288         my $self = shift;
 289         @RT66112::E::ISA = qw/RT66112::A/;
 290         return $self->SUPER::isa(@_);
 291     }
 292
 293     package RT66112::E;
 294
 295     package main;
 296
 297     @RT66112::B::ISA = qw//;
 298     @RT66112::C::ISA = qw/RT66112::B/;
 299     @RT66112::T1::ISA = qw/RT66112::C/;
 300     ok(RT66112::T1->isa('RT66112::C'), "modify \@ISA in isa (RT66112::T1 isa RT66112::C)");
 301
 302     @RT66112::B::ISA = qw//;
 303     @RT66112::C::ISA = qw/RT66112::B/;
 304     @RT66112::T2::ISA = qw/RT66112::C/;
 305     ok(RT66112::T2->isa('RT66112::B'), "modify \@ISA in isa (RT66112::T2 isa RT66112::B)");
 306
 307     @RT66112::B::ISA = qw//;
 308     @RT66112::C::ISA = qw/RT66112::B/;
 309     @RT66112::T3::ISA = qw/RT66112::C/;
 310     ok(RT66112::T3->isa('RT66112::A'), "modify \@ISA in isa (RT66112::T3 isa RT66112::A)") or require mro, diag "@{mro::get_linear_isa('RT66112::T3')}";
 311
 312     @RT66112::E::ISA = qw/RT66112::D/;
 313     @RT66112::T4::ISA = qw/RT66112::E/;
 314     ok(RT66112::T4->isa('RT66112::E'), "modify \@ISA in isa (RT66112::T4 isa RT66112::E)");
 315
 316     @RT66112::E::ISA = qw/RT66112::D/;
 317     @RT66112::T5::ISA = qw/RT66112::E/;
 318     ok(! RT66112::T5->isa('RT66112::D'), "modify \@ISA in isa (RT66112::T5 not isa RT66112::D)");
 319
 320     @RT66112::E::ISA = qw/RT66112::D/;
 321     @RT66112::T6::ISA = qw/RT66112::E/;
 322     ok(RT66112::T6->isa('RT66112::A'), "modify \@ISA in isa (RT66112::T6 isa RT66112::A)");
 323 }