win32/config_sh.PL

   1 use FindExt;
   2 # take a semicolon separated path list and turn it into a quoted
   3 # list of paths that Text::Parsewords will grok
   4 sub mungepath {
   5     my $p = shift;
   6     # remove leading/trailing semis/spaces
   7     $p =~ s/^[ ;]+//;
   8     $p =~ s/[ ;]+$//;
   9     $p =~ s/'/"/g;
  10     my @p = map { $_ = "\"$_\"" if /\s/ and !/^".*"$/; $_ } split /;/, $p;
  11     return join(' ', @p);
  12 }
  13
  14 # generate an array of option strings from command-line args
  15 # or an option file
  16 #    -- added by BKS, 10-17-1999 to fix command-line overflow problems
  17 sub loadopts {
  18     if ($ARGV[0] =~ /--cfgsh-option-file/) {
  19         shift @ARGV;
  20         my $optfile = shift @ARGV;
  21         local (*F);
  22         open OPTF, $optfile or die "Can't open $optfile: $!\n";
  23         my @opts;
  24         chomp(my $line = <OPTF>);
  25         my @vars = split(/\t+~\t+/, $line);
  26         for (@vars) {
  27             push(@opts, $_) unless (/^\s*$/);
  28         }
  29         close OPTF;
  30         return \@opts;
  31     }
  32     else {
  33         return \@ARGV;
  34     }
  35 }
  36
  37 my %opt;
  38
  39 my $optref = loadopts();
  40 while (@{$optref} && $optref->[0] =~ /^([\w_]+)=(.*)$/) {
  41     $opt{$1}=$2;
  42     shift(@{$optref});
  43 }
  44
  45 FindExt::scan_ext("../cpan");
  46 FindExt::scan_ext("../dist");
  47 FindExt::scan_ext("../ext");
  48 FindExt::set_static_extensions(split ' ', $opt{'static_ext'});
  49
  50 $opt{'nonxs_ext'}        = join(' ',FindExt::nonxs_ext()) || ' ';
  51 $opt{'static_ext'}       = join(' ',FindExt::static_ext()) || ' ';
  52 $opt{'dynamic_ext'}      = join(' ',FindExt::dynamic_ext()) || ' ';
  53 $opt{'extensions'}       = join(' ',FindExt::extensions()) || ' ';
  54 $opt{'known_extensions'} = join(' ',FindExt::known_extensions()) || ' ';
  55
  56 my $pl_h = '../patchlevel.h';
  57
  58 if (-e $pl_h) {
  59     open PL, "<$pl_h" or die "Can't open $pl_h: $!";
  60     while (<PL>) {
  61         if (/^#\s*define\s+(PERL_\w+)\s+([\d.]+)/) {
  62             $opt{$1} = $2;
  63         }
  64     }
  65     close PL;
  66 }
  67 else {
  68     die "Can't find $pl_h: $!";
  69 }
  70
  71 my $patch_file = '../.patch';
  72
  73 if (-e $patch_file) {
  74     open my $fh, "<", $patch_file or die "Can't open $patch_file: $!";
  75     chomp($opt{PERL_PATCHLEVEL} = <$fh>);
  76     close $fh;
  77 }
  78
  79 $opt{VERSION} = "$opt{PERL_REVISION}.$opt{PERL_VERSION}.$opt{PERL_SUBVERSION}";
  80 $opt{INST_VER} =~ s|~VERSION~|$opt{VERSION}|g;
  81 $opt{'version_patchlevel_string'} = "version $opt{PERL_VERSION} subversion $opt{PERL_SUBVERSION}";
  82 $opt{'version_patchlevel_string'} .= " patch $opt{PERL_PATCHLEVEL}" if exists $opt{PERL_PATCHLEVEL};
  83
  84 my $ver = `ver 2>nul`;
  85 if ($ver =~ /Version (\d+\.\d+)/) {
  86     $opt{'osvers'} = $1;
  87 }
  88 else {
  89     $opt{'osvers'} = '4.0';
  90 }
  91
  92 if (exists $opt{cc}) {
  93     # cl version detection borrowed from Test::Smoke's configsmoke.pl
  94     if ($opt{cc} eq 'cl') {
  95         my $output = `cl --version 2>&1`;
  96         $opt{ccversion} = $output =~ /^.*Version\s+([\d.]+)/ ? $1 : '?';
  97     }
  98     elsif ($opt{cc} =~ /\bgcc\b/) {
  99         chomp($opt{gccversion} = `$opt{cc} -dumpversion`);
 100     }
 101 }
 102
 103 $opt{'cf_by'} = $ENV{USERNAME} unless $opt{'cf_by'};
 104 $opt{'cf_email'} = $opt{'cf_by'} . '@' . (gethostbyname('localhost'))[0]
 105         unless $opt{'cf_email'};
 106 $opt{'usemymalloc'} = 'y' if $opt{'d_mymalloc'} eq 'define';
 107
 108 $opt{libpth} = mungepath($opt{libpth}) if exists $opt{libpth};
 109 $opt{incpath} = mungepath($opt{incpath}) if exists $opt{incpath};
 110
 111 # some functions are not available on Win9x
 112 unless (defined $ENV{SYSTEMROOT}) { # SystemRoot has been introduced by WinNT
 113     $opt{d_flock} = 'undef';
 114     $opt{d_link} = 'undef';
 115 }
 116
 117 # change the lseeksize and lseektype from their canned default values (which
 118 # are set-up for a non-uselargefiles build) if we are building with
 119 # uselargefiles.
 120 if ($opt{uselargefiles} eq 'define') {
 121     $opt{lseeksize} = 8;
 122     if ($opt{cc} eq 'cl') {
 123         $opt{lseektype} = '__int64';
 124     }
 125     elsif ($opt{cc} =~ /\bgcc\b/) {
 126         $opt{lseektype} = 'long long';
 127     }
 128 }
 129
 130 # change the s{GM|LOCAL}TIME_{min|max} for VS2005 (aka VC 8) and
 131 # VS2008 (aka VC 9) or higher (presuming that later versions will have
 132 # at least the range of that).
 133 if ($opt{cc} eq 'cl' and $opt{ccversion} =~ /^(\d+)/) {
 134     my $ccversion = $1;
 135     if ($ccversion >= 14) {
 136         $opt{sGMTIME_max} = 32535291599;
 137         $opt{sLOCALTIME_max} = 32535244799;
 138     }
 139 }
 140
 141 if ($opt{useithreads} eq 'define' && $opt{ccflags} =~ /-DPERL_IMPLICIT_SYS\b/) {
 142     $opt{d_pseudofork} = 'define';
 143 }
 144
 145 while (<>) {
 146     s/~([\w_]+)~/$opt{$1}/g;
 147     if (/^([\w_]+)=(.*)$/) {
 148         my($k,$v) = ($1,$2);
 149         # this depends on cf_time being empty in the template (or we'll
 150         # get a loop)
 151         if ($k eq 'cf_time') {
 152             $_ = "$k='" . localtime(time) . "'\n" if $v =~ /^\s*'\s*'/;
 153         }
 154         elsif (exists $opt{$k}) {
 155             $_ = "$k='$opt{$k}'\n";
 156         }
 157     }
 158     print;
 159 }