t/test.pl

   1 #
   2 # t/test.pl - most of Test::More functionality without the fuss, plus
   3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
   4 # on non ASCII-ish platforms need to be skipped
   5
   6
   7 # NOTE:
   8 #
   9 # Increment ($x++) has a certain amount of cleverness for things like
  10 #
  11 #   $x = 'zz';
  12 #   $x++; # $x eq 'aaa';
  13 #
  14 # stands more chance of breaking than just a simple
  15 #
  16 #   $x = $x + 1
  17 #
  18 # In this file, we use the latter "Baby Perl" approach, and increment
  19 # will be worked over by t/op/inc.t
  20
  21 $Level = 1;
  22 my $test = 1;
  23 my $planned;
  24 my $noplan;
  25 my $Perl;       # Safer version of $^X set by which_perl()
  26
  27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
  28 $::IS_ASCII  = ord 'A' ==  65;
  29 $::IS_EBCDIC = ord 'A' == 193;
  30
  31 $TODO = 0;
  32 $NO_ENDING = 0;
  33 $Tests_Are_Passing = 1;
  34
  35 # Use this instead of print to avoid interference while testing globals.
  36 sub _print {
  37     local($\, $", $,) = (undef, ' ', '');
  38     print STDOUT @_;
  39 }
  40
  41 sub _print_stderr {
  42     local($\, $", $,) = (undef, ' ', '');
  43     print STDERR @_;
  44 }
  45
  46 sub plan {
  47     my $n;
  48     if (@_ == 1) {
  49         $n = shift;
  50         if ($n eq 'no_plan') {
  51           undef $n;
  52           $noplan = 1;
  53         }
  54     } else {
  55         my %plan = @_;
  56         $n = $plan{tests};
  57     }
  58     _print "1..$n\n" unless $noplan;
  59     $planned = $n;
  60 }
  61
  62
  63 # Set the plan at the end.  See Test::More::done_testing.
  64 sub done_testing {
  65     my $n = $test - 1;
  66     $n = shift if @_;
  67
  68     _print "1..$n\n";
  69     $planned = $n;
  70 }
  71
  72
  73 END {
  74     my $ran = $test - 1;
  75     if (!$NO_ENDING) {
  76         if (defined $planned && $planned != $ran) {
  77             _print_stderr
  78                 "# Looks like you planned $planned tests but ran $ran.\n";
  79         } elsif ($noplan) {
  80             _print "1..$ran\n";
  81         }
  82     }
  83 }
  84
  85 sub _diag {
  86     return unless @_;
  87     my @mess = _comment(@_);
  88     $TODO ? _print(@mess) : _print_stderr(@mess);
  89 }
  90
  91 # Use this instead of "print STDERR" when outputting failure diagnostic
  92 # messages
  93 sub diag {
  94     _diag(@_);
  95 }
  96
  97 # Use this instead of "print" when outputting informational messages
  98 sub note {
  99     return unless @_;
 100     _print( _comment(@_) );
 101 }
 102
 103 sub is_miniperl {
 104     return !defined &DynaLoader::boot_DynaLoader;
 105 }
 106
 107 sub _comment {
 108     return map { /^#/ ? "$_\n" : "# $_\n" }
 109            map { split /\n/ } @_;
 110 }
 111
 112 sub _have_dynamic_extension {
 113     my $extension = shift;
 114     unless (eval {require Config; 1}) {
 115         warn "test.pl had problems loading Config: $@";
 116         return 1;
 117     }
 118     $extension =~ s!::!/!g;
 119     return 1 if ($Config::Config{extensions} =~ /\b$extension\b/);
 120 }
 121
 122 sub skip_all {
 123     if (@_) {
 124         _print "1..0 # Skip @_\n";
 125     } else {
 126         _print "1..0\n";
 127     }
 128     exit(0);
 129 }
 130
 131 sub skip_all_if_miniperl {
 132     skip_all(@_) if is_miniperl();
 133 }
 134
 135 sub skip_all_without_dynamic_extension {
 136     my ($extension) = @_;
 137     skip_all("no dynamic loading on miniperl, no $extension") if is_miniperl();
 138     return if &_have_dynamic_extension;
 139     skip_all("$extension was not built");
 140 }
 141
 142 sub skip_all_without_perlio {
 143     skip_all('no PerlIO') unless PerlIO::Layer->find('perlio');
 144 }
 145
 146 sub skip_all_without_config {
 147     unless (eval {require Config; 1}) {
 148         warn "test.pl had problems loading Config: $@";
 149         return;
 150     }
 151     foreach (@_) {
 152         next if $Config::Config{$_};
 153         my $key = $_; # Need to copy, before trying to modify.
 154         $key =~ s/^use//;
 155         $key =~ s/^d_//;
 156         skip_all("no $key");
 157     }
 158 }
 159
 160 sub find_git_or_skip {
 161     my ($source_dir, $reason);
 162     if (-d '.git') {
 163         $source_dir = '.';
 164     } elsif (-l 'MANIFEST' && -l 'AUTHORS') {
 165         my $where = readlink 'MANIFEST';
 166         die "Can't readling MANIFEST: $!" unless defined $where;
 167         die "Confusing symlink target for MANIFEST, '$where'"
 168             unless $where =~ s!/MANIFEST\z!!;
 169         if (-d "$where/.git") {
 170             # Looks like we are in a symlink tree
 171             if (exists $ENV{GIT_DIR}) {
 172                 diag("Found source tree at $where, but \$ENV{GIT_DIR} is $ENV{GIT_DIR}. Not changing it");
 173             } else {
 174                 note("Found source tree at $where, setting \$ENV{GIT_DIR}");
 175                 $ENV{GIT_DIR} = "$where/.git";
 176             }
 177             $source_dir = $where;
 178         }
 179     } elsif (exists $ENV{GIT_DIR}) {
 180         my $commit = '8d063cd8450e59ea1c611a2f4f5a21059a2804f1';
 181         my $out = `git rev-parse --verify --quiet '$commit^{commit}'`;
 182         chomp $out;
 183         if($out eq $commit) {
 184             $source_dir = '.'
 185         }
 186     }
 187     if ($source_dir) {
 188         my $version_string = `git --version`;
 189         if (defined $version_string
 190               && $version_string =~ /\Agit version (\d+\.\d+\.\d+)(.*)/) {
 191             return $source_dir if eval "v$1 ge v1.5.0";
 192             # If you have earlier than 1.5.0 and it works, change this test
 193             $reason = "in git checkout, but git version '$1$2' too old";
 194         } else {
 195             $reason = "in git checkout, but cannot run git";
 196         }
 197     } else {
 198         $reason = 'not being run from a git checkout';
 199     }
 200     skip_all($reason) if $_[0] && $_[0] eq 'all';
 201     skip($reason, @_);
 202 }
 203
 204 sub BAIL_OUT {
 205     my ($reason) = @_;
 206     _print("Bail out!  $reason\n");
 207     exit 255;
 208 }
 209
 210 sub _ok {
 211     my ($pass, $where, $name, @mess) = @_;
 212     # Do not try to microoptimize by factoring out the "not ".
 213     # VMS will avenge.
 214     my $out;
 215     if ($name) {
 216         # escape out '#' or it will interfere with '# skip' and such
 217         $name =~ s/#/\\#/g;
 218         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
 219     } else {
 220         $out = $pass ? "ok $test" : "not ok $test";
 221     }
 222
 223     if ($TODO) {
 224         $out = $out . " # TODO $TODO";
 225     } else {
 226         $Tests_Are_Passing = 0 unless $pass;
 227     }
 228
 229     _print "$out\n";
 230
 231     if ($pass) {
 232         note @mess; # Ensure that the message is properly escaped.
 233     }
 234     else {
 235         my $msg = "# Failed test $test - ";
 236         $msg.= "$name " if $name;
 237         $msg .= "$where\n";
 238         _diag $msg;
 239         _diag @mess;
 240     }
 241
 242     $test = $test + 1; # don't use ++
 243
 244     return $pass;
 245 }
 246
 247 sub _where {
 248     my @caller = caller($Level);
 249     return "at $caller[1] line $caller[2]";
 250 }
 251
 252 # DON'T use this for matches. Use like() instead.
 253 sub ok ($@) {
 254     my ($pass, $name, @mess) = @_;
 255     _ok($pass, _where(), $name, @mess);
 256 }
 257
 258 sub _q {
 259     my $x = shift;
 260     return 'undef' unless defined $x;
 261     my $q = $x;
 262     $q =~ s/\\/\\\\/g;
 263     $q =~ s/'/\\'/g;
 264     return "'$q'";
 265 }
 266
 267 sub _qq {
 268     my $x = shift;
 269     return defined $x ? '"' . display ($x) . '"' : 'undef';
 270 };
 271
 272 # keys are the codes \n etc map to, values are 2 char strings such as \n
 273 my %backslash_escape;
 274 foreach my $x (split //, 'nrtfa\\\'"') {
 275     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
 276 }
 277 # A way to display scalars containing control characters and Unicode.
 278 # Trying to avoid setting $_, or relying on local $_ to work.
 279 sub display {
 280     my @result;
 281     foreach my $x (@_) {
 282         if (defined $x and not ref $x) {
 283             my $y = '';
 284             foreach my $c (unpack("U*", $x)) {
 285                 if ($c > 255) {
 286                     $y = $y . sprintf "\\x{%x}", $c;
 287                 } elsif ($backslash_escape{$c}) {
 288                     $y = $y . $backslash_escape{$c};
 289                 } else {
 290                     my $z = chr $c; # Maybe we can get away with a literal...
 291                     if ($z =~ /[[:^print:]]/) {
 292
 293                         # Use octal for characters traditionally expressed as
 294                         # such: the low controls, which on EBCDIC aren't
 295                         # necessarily the same ones as on ASCII platforms, but
 296                         # are small ordinals, nonetheless
 297                         if ($c <= 037) {
 298                             $z = sprintf "\\%03o", $c;
 299                         } else {
 300                             $z = sprintf "\\x{%x}", $c;
 301                         }
 302                     }
 303                     $y = $y . $z;
 304                 }
 305             }
 306             $x = $y;
 307         }
 308         return $x unless wantarray;
 309         push @result, $x;
 310     }
 311     return @result;
 312 }
 313
 314 sub is ($$@) {
 315     my ($got, $expected, $name, @mess) = @_;
 316
 317     my $pass;
 318     if( !defined $got || !defined $expected ) {
 319         # undef only matches undef
 320         $pass = !defined $got && !defined $expected;
 321     }
 322     else {
 323         $pass = $got eq $expected;
 324     }
 325
 326     unless ($pass) {
 327         unshift(@mess, "#      got "._qq($got)."\n",
 328                        "# expected "._qq($expected)."\n");
 329     }
 330     _ok($pass, _where(), $name, @mess);
 331 }
 332
 333 sub isnt ($$@) {
 334     my ($got, $isnt, $name, @mess) = @_;
 335
 336     my $pass;
 337     if( !defined $got || !defined $isnt ) {
 338         # undef only matches undef
 339         $pass = defined $got || defined $isnt;
 340     }
 341     else {
 342         $pass = $got ne $isnt;
 343     }
 344
 345     unless( $pass ) {
 346         unshift(@mess, "# it should not be "._qq($got)."\n",
 347                        "# but it is.\n");
 348     }
 349     _ok($pass, _where(), $name, @mess);
 350 }
 351
 352 sub cmp_ok ($$$@) {
 353     my($got, $type, $expected, $name, @mess) = @_;
 354
 355     my $pass;
 356     {
 357         local $^W = 0;
 358         local($@,$!);   # don't interfere with $@
 359                         # eval() sometimes resets $!
 360         $pass = eval "\$got $type \$expected";
 361     }
 362     unless ($pass) {
 363         # It seems Irix long doubles can have 2147483648 and 2147483648
 364         # that stringify to the same thing but are actually numerically
 365         # different. Display the numbers if $type isn't a string operator,
 366         # and the numbers are stringwise the same.
 367         # (all string operators have alphabetic names, so tr/a-z// is true)
 368         # This will also show numbers for some unneeded cases, but will
 369         # definitely be helpful for things such as == and <= that fail
 370         if ($got eq $expected and $type !~ tr/a-z//) {
 371             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 372         }
 373         unshift(@mess, "#      got "._qq($got)."\n",
 374                        "# expected $type "._qq($expected)."\n");
 375     }
 376     _ok($pass, _where(), $name, @mess);
 377 }
 378
 379 # Check that $got is within $range of $expected
 380 # if $range is 0, then check it's exact
 381 # else if $expected is 0, then $range is an absolute value
 382 # otherwise $range is a fractional error.
 383 # Here $range must be numeric, >= 0
 384 # Non numeric ranges might be a useful future extension. (eg %)
 385 sub within ($$$@) {
 386     my ($got, $expected, $range, $name, @mess) = @_;
 387     my $pass;
 388     if (!defined $got or !defined $expected or !defined $range) {
 389         # This is a fail, but doesn't need extra diagnostics
 390     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
 391         # This is a fail
 392         unshift @mess, "# got, expected and range must be numeric\n";
 393     } elsif ($range < 0) {
 394         # This is also a fail
 395         unshift @mess, "# range must not be negative\n";
 396     } elsif ($range == 0) {
 397         # Within 0 is ==
 398         $pass = $got == $expected;
 399     } elsif ($expected == 0) {
 400         # If expected is 0, treat range as absolute
 401         $pass = ($got <= $range) && ($got >= - $range);
 402     } else {
 403         my $diff = $got - $expected;
 404         $pass = abs ($diff / $expected) < $range;
 405     }
 406     unless ($pass) {
 407         if ($got eq $expected) {
 408             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
 409         }
 410         unshift@mess, "#      got "._qq($got)."\n",
 411                       "# expected "._qq($expected)." (within "._qq($range).")\n";
 412     }
 413     _ok($pass, _where(), $name, @mess);
 414 }
 415
 416 # Note: this isn't quite as fancy as Test::More::like().
 417
 418 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
 419 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
 420
 421 sub like_yn ($$$@) {
 422     my ($flip, undef, $expected, $name, @mess) = @_;
 423     my $pass;
 424     $pass = $_[1] =~ /$expected/ if !$flip;
 425     $pass = $_[1] !~ /$expected/ if $flip;
 426     unless ($pass) {
 427         unshift(@mess, "#      got '$_[1]'\n",
 428                 $flip
 429                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
 430     }
 431     local $Level = $Level + 1;
 432     _ok($pass, _where(), $name, @mess);
 433 }
 434
 435 sub pass {
 436     _ok(1, '', @_);
 437 }
 438
 439 sub fail {
 440     _ok(0, _where(), @_);
 441 }
 442
 443 sub curr_test {
 444     $test = shift if @_;
 445     return $test;
 446 }
 447
 448 sub next_test {
 449   my $retval = $test;
 450   $test = $test + 1; # don't use ++
 451   $retval;
 452 }
 453
 454 # Note: can't pass multipart messages since we try to
 455 # be compatible with Test::More::skip().
 456 sub skip {
 457     my $why = shift;
 458     my $n    = @_ ? shift : 1;
 459     for (1..$n) {
 460         _print "ok $test # skip $why\n";
 461         $test = $test + 1;
 462     }
 463     local $^W = 0;
 464     last SKIP;
 465 }
 466
 467 sub skip_if_miniperl {
 468     skip(@_) if is_miniperl();
 469 }
 470
 471 sub skip_without_dynamic_extension {
 472     my ($extension) = @_;
 473     skip("no dynamic loading on miniperl, no $extension") if is_miniperl();
 474     return if &_have_dynamic_extension;
 475     skip("$extension was not built");
 476 }
 477
 478 sub todo_skip {
 479     my $why = shift;
 480     my $n   = @_ ? shift : 1;
 481
 482     for (1..$n) {
 483         _print "not ok $test # TODO & SKIP $why\n";
 484         $test = $test + 1;
 485     }
 486     local $^W = 0;
 487     last TODO;
 488 }
 489
 490 sub eq_array {
 491     my ($ra, $rb) = @_;
 492     return 0 unless $#$ra == $#$rb;
 493     for my $i (0..$#$ra) {
 494         next     if !defined $ra->[$i] && !defined $rb->[$i];
 495         return 0 if !defined $ra->[$i];
 496         return 0 if !defined $rb->[$i];
 497         return 0 unless $ra->[$i] eq $rb->[$i];
 498     }
 499     return 1;
 500 }
 501
 502 sub eq_hash {
 503   my ($orig, $suspect) = @_;
 504   my $fail;
 505   while (my ($key, $value) = each %$suspect) {
 506     # Force a hash recompute if this perl's internals can cache the hash key.
 507     $key = "" . $key;
 508     if (exists $orig->{$key}) {
 509       if (
 510         defined $orig->{$key} != defined $value
 511         || (defined $value && $orig->{$key} ne $value)
 512       ) {
 513         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
 514                      " now ", _qq($value), "\n";
 515         $fail = 1;
 516       }
 517     } else {
 518       _print "# key ", _qq($key), " is ", _qq($value),
 519                    ", not in original.\n";
 520       $fail = 1;
 521     }
 522   }
 523   foreach (keys %$orig) {
 524     # Force a hash recompute if this perl's internals can cache the hash key.
 525     $_ = "" . $_;
 526     next if (exists $suspect->{$_});
 527     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
 528     $fail = 1;
 529   }
 530   !$fail;
 531 }
 532
 533 # We only provide a subset of the Test::More functionality.
 534 sub require_ok ($) {
 535     my ($require) = @_;
 536     if ($require =~ tr/[A-Za-z0-9:.]//c) {
 537         fail("Invalid character in \"$require\", passed to require_ok");
 538     } else {
 539         eval <<REQUIRE_OK;
 540 require $require;
 541 REQUIRE_OK
 542         is($@, '', _where(), "require $require");
 543     }
 544 }
 545
 546 sub use_ok ($) {
 547     my ($use) = @_;
 548     if ($use =~ tr/[A-Za-z0-9:.]//c) {
 549         fail("Invalid character in \"$use\", passed to use");
 550     } else {
 551         eval <<USE_OK;
 552 use $use;
 553 USE_OK
 554         is($@, '', _where(), "use $use");
 555     }
 556 }
 557
 558 # runperl - Runs a separate perl interpreter and returns its output.
 559 # Arguments :
 560 #   switches => [ command-line switches ]
 561 #   nolib    => 1 # don't use -I../lib (included by default)
 562 #   non_portable => Don't warn if a one liner contains quotes
 563 #   prog     => one-liner (avoid quotes)
 564 #   progs    => [ multi-liner (avoid quotes) ]
 565 #   progfile => perl script
 566 #   stdin    => string to feed the stdin (or undef to redirect from /dev/null)
 567 #   stderr   => If 'devnull' suppresses stderr, if other TRUE value redirect
 568 #               stderr to stdout
 569 #   args     => [ command-line arguments to the perl program ]
 570 #   verbose  => print the command line
 571
 572 my $is_mswin    = $^O eq 'MSWin32';
 573 my $is_netware  = $^O eq 'NetWare';
 574 my $is_vms      = $^O eq 'VMS';
 575 my $is_cygwin   = $^O eq 'cygwin';
 576
 577 sub _quote_args {
 578     my ($runperl, $args) = @_;
 579
 580     foreach (@$args) {
 581         # In VMS protect with doublequotes because otherwise
 582         # DCL will lowercase -- unless already doublequoted.
 583        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
 584        $runperl = $runperl . ' ' . $_;
 585     }
 586     return $runperl;
 587 }
 588
 589 sub _create_runperl { # Create the string to qx in runperl().
 590     my %args = @_;
 591     my $runperl = which_perl();
 592     if ($runperl =~ m/\s/) {
 593         $runperl = qq{"$runperl"};
 594     }
 595     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
 596     if ($ENV{PERL_RUNPERL_DEBUG}) {
 597         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
 598     }
 599     unless ($args{nolib}) {
 600         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
 601     }
 602     if ($args{switches}) {
 603         local $Level = 2;
 604         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
 605             unless ref $args{switches} eq "ARRAY";
 606         $runperl = _quote_args($runperl, $args{switches});
 607     }
 608     if (defined $args{prog}) {
 609         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
 610             if defined $args{progs};
 611         $args{progs} = [$args{prog}]
 612     }
 613     if (defined $args{progs}) {
 614         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
 615             unless ref $args{progs} eq "ARRAY";
 616         foreach my $prog (@{$args{progs}}) {
 617             if (!$args{non_portable}) {
 618                 if ($prog =~ tr/'"//) {
 619                     warn "quotes in prog >>$prog<< are not portable";
 620                 }
 621                 if ($prog =~ /^([<>|]|2>)/) {
 622                     warn "Initial $1 in prog >>$prog<< is not portable";
 623                 }
 624                 if ($prog =~ /&\z/) {
 625                     warn "Trailing & in prog >>$prog<< is not portable";
 626                 }
 627             }
 628             if ($is_mswin || $is_netware || $is_vms) {
 629                 $runperl = $runperl . qq ( -e "$prog" );
 630             }
 631             else {
 632                 $runperl = $runperl . qq ( -e '$prog' );
 633             }
 634         }
 635     } elsif (defined $args{progfile}) {
 636         $runperl = $runperl . qq( "$args{progfile}");
 637     } else {
 638         # You probably didn't want to be sucking in from the upstream stdin
 639         die "test.pl:runperl(): none of prog, progs, progfile, args, "
 640             . " switches or stdin specified"
 641             unless defined $args{args} or defined $args{switches}
 642                 or defined $args{stdin};
 643     }
 644     if (defined $args{stdin}) {
 645         # so we don't try to put literal newlines and crs onto the
 646         # command line.
 647         $args{stdin} =~ s/\n/\\n/g;
 648         $args{stdin} =~ s/\r/\\r/g;
 649
 650         if ($is_mswin || $is_netware || $is_vms) {
 651             $runperl = qq{$Perl -e "print qq(} .
 652                 $args{stdin} . q{)" | } . $runperl;
 653         }
 654         else {
 655             $runperl = qq{$Perl -e 'print qq(} .
 656                 $args{stdin} . q{)' | } . $runperl;
 657         }
 658     } elsif (exists $args{stdin}) {
 659         # Using the pipe construction above can cause fun on systems which use
 660         # ksh as /bin/sh, as ksh does pipes differently (with one less process)
 661         # With sh, for the command line 'perl -e 'print qq()' | perl -e ...'
 662         # the sh process forks two children, which use exec to start the two
 663         # perl processes. The parent shell process persists for the duration of
 664         # the pipeline, and the second perl process starts with no children.
 665         # With ksh (and zsh), the shell saves a process by forking a child for
 666         # just the first perl process, and execing itself to start the second.
 667         # This means that the second perl process starts with one child which
 668         # it didn't create. This causes "fun" when if the tests assume that
 669         # wait (or waitpid) will only return information about processes
 670         # started within the test.
 671         # They also cause fun on VMS, where the pipe implementation returns
 672         # the exit code of the process at the front of the pipeline, not the
 673         # end. This messes up any test using OPTION FATAL.
 674         # Hence it's useful to have a way to make STDIN be at eof without
 675         # needing a pipeline, so that the fork tests have a sane environment
 676         # without these surprises.
 677
 678         # /dev/null appears to be surprisingly portable.
 679         $runperl = $runperl . ($is_mswin ? ' <nul' : ' </dev/null');
 680     }
 681     if (defined $args{args}) {
 682         $runperl = _quote_args($runperl, $args{args});
 683     }
 684     if (exists $args{stderr} && $args{stderr} eq 'devnull') {
 685         $runperl = $runperl . ($is_mswin ? ' 2>nul' : ' 2>/dev/null');
 686     }
 687     elsif ($args{stderr}) {
 688         $runperl = $runperl . ' 2>&1';
 689     }
 690     if ($args{verbose}) {
 691         my $runperldisplay = $runperl;
 692         $runperldisplay =~ s/\n/\n\#/g;
 693         _print_stderr "# $runperldisplay\n";
 694     }
 695     return $runperl;
 696 }
 697
 698 sub runperl {
 699     die "test.pl:runperl() does not take a hashref"
 700         if ref $_[0] and ref $_[0] eq 'HASH';
 701     my $runperl = &_create_runperl;
 702     my $result;
 703
 704     my $tainted = ${^TAINT};
 705     my %args = @_;
 706     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
 707
 708     if ($tainted) {
 709         # We will assume that if you're running under -T, you really mean to
 710         # run a fresh perl, so we'll brute force launder everything for you
 711         my $sep;
 712
 713         if (! eval {require Config; 1}) {
 714             warn "test.pl had problems loading Config: $@";
 715             $sep = ':';
 716         } else {
 717             $sep = $Config::Config{path_sep};
 718         }
 719
 720         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
 721         local @ENV{@keys} = ();
 722         # Untaint, plus take out . and empty string:
 723         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
 724         $ENV{PATH} =~ /(.*)/s;
 725         local $ENV{PATH} =
 726             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
 727                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
 728                     split quotemeta ($sep), $1;
 729         if ($is_cygwin) {   # Must have /bin under Cygwin
 730             if (length $ENV{PATH}) {
 731                 $ENV{PATH} = $ENV{PATH} . $sep;
 732             }
 733             $ENV{PATH} = $ENV{PATH} . '/bin';
 734         }
 735         $runperl =~ /(.*)/s;
 736         $runperl = $1;
 737
 738         $result = `$runperl`;
 739     } else {
 740         $result = `$runperl`;
 741     }
 742     $result =~ s/\n\n/\n/g if $is_vms; # XXX pipes sometimes double these
 743     return $result;
 744 }
 745
 746 # Nice alias
 747 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
 748
 749 sub DIE {
 750     _print_stderr "# @_\n";
 751     exit 1;
 752 }
 753
 754 # A somewhat safer version of the sometimes wrong $^X.
 755 sub which_perl {
 756     unless (defined $Perl) {
 757         $Perl = $^X;
 758
 759         # VMS should have 'perl' aliased properly
 760         return $Perl if $is_vms;
 761
 762         my $exe;
 763         if (! eval {require Config; 1}) {
 764             warn "test.pl had problems loading Config: $@";
 765             $exe = '';
 766         } else {
 767             $exe = $Config::Config{_exe};
 768         }
 769        $exe = '' unless defined $exe;
 770
 771         # This doesn't absolutize the path: beware of future chdirs().
 772         # We could do File::Spec->abs2rel() but that does getcwd()s,
 773         # which is a bit heavyweight to do here.
 774
 775         if ($Perl =~ /^perl\Q$exe\E$/i) {
 776             my $perl = "perl$exe";
 777             if (! eval {require File::Spec; 1}) {
 778                 warn "test.pl had problems loading File::Spec: $@";
 779                 $Perl = "./$perl";
 780             } else {
 781                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
 782             }
 783         }
 784
 785         # Build up the name of the executable file from the name of
 786         # the command.
 787
 788         if ($Perl !~ /\Q$exe\E$/i) {
 789             $Perl = $Perl . $exe;
 790         }
 791
 792         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
 793
 794         # For subcommands to use.
 795         $ENV{PERLEXE} = $Perl;
 796     }
 797     return $Perl;
 798 }
 799
 800 sub unlink_all {
 801     my $count = 0;
 802     foreach my $file (@_) {
 803         1 while unlink $file;
 804         if( -f $file ){
 805             _print_stderr "# Couldn't unlink '$file': $!\n";
 806         }else{
 807             ++$count;
 808         }
 809     }
 810     $count;
 811 }
 812
 813 # _num_to_alpha - Returns a string of letters representing a positive integer.
 814 # Arguments :
 815 #   number to convert
 816 #   maximum number of letters
 817
 818 # returns undef if the number is negative
 819 # returns undef if the number of letters is greater than the maximum wanted
 820
 821 # _num_to_alpha( 0) eq 'A';
 822 # _num_to_alpha( 1) eq 'B';
 823 # _num_to_alpha(25) eq 'Z';
 824 # _num_to_alpha(26) eq 'AA';
 825 # _num_to_alpha(27) eq 'AB';
 826
 827 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
 828
 829 # Avoid ++ -- ranges split negative numbers
 830 sub _num_to_alpha{
 831     my($num,$max_char) = @_;
 832     return unless $num >= 0;
 833     my $alpha = '';
 834     my $char_count = 0;
 835     $max_char = 0 if $max_char < 0;
 836
 837     while( 1 ){
 838         $alpha = $letters[ $num % 26 ] . $alpha;
 839         $num = int( $num / 26 );
 840         last if $num == 0;
 841         $num = $num - 1;
 842
 843         # char limit
 844         next unless $max_char;
 845         $char_count = $char_count + 1;
 846         return if $char_count == $max_char;
 847     }
 848     return $alpha;
 849 }
 850
 851 my %tmpfiles;
 852 END { unlink_all keys %tmpfiles }
 853
 854 # A regexp that matches the tempfile names
 855 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
 856
 857 # Avoid ++, avoid ranges, avoid split //
 858 my $tempfile_count = 0;
 859 sub tempfile {
 860     while(1){
 861         my $try = "tmp$$";
 862         my $alpha = _num_to_alpha($tempfile_count,2);
 863         last unless defined $alpha;
 864         $try = $try . $alpha;
 865         $tempfile_count = $tempfile_count + 1;
 866
 867         # Need to note all the file names we allocated, as a second request may
 868         # come before the first is created.
 869         if (!$tmpfiles{$try} && !-e $try) {
 870             # We have a winner
 871             $tmpfiles{$try} = 1;
 872             return $try;
 873         }
 874     }
 875     die "Can't find temporary file name starting \"tmp$$\"";
 876 }
 877
 878 # register_tempfile - Adds a list of files to be removed at the end of the current test file
 879 # Arguments :
 880 #   a list of files to be removed later
 881
 882 # returns a count of how many file names were actually added
 883
 884 # Reuses %tmpfiles so that tempfile() will also skip any files added here
 885 # even if the file doesn't exist yet.
 886
 887 sub register_tempfile {
 888     my $count = 0;
 889     for( @_ ){
 890         if( $tmpfiles{$_} ){
 891             _print_stderr "# Temporary file '$_' already added\n";
 892         }else{
 893             $tmpfiles{$_} = 1;
 894             $count = $count + 1;
 895         }
 896     }
 897     return $count;
 898 }
 899
 900 # This is the temporary file for _fresh_perl
 901 my $tmpfile = tempfile();
 902
 903 sub _fresh_perl {
 904     my($prog, $action, $expect, $runperl_args, $name) = @_;
 905
 906     # Given the choice of the mis-parsable {}
 907     # (we want an anon hash, but a borked lexer might think that it's a block)
 908     # or relying on taking a reference to a lexical
 909     # (\ might be mis-parsed, and the reference counting on the pad may go
 910     #  awry)
 911     # it feels like the least-worse thing is to assume that auto-vivification
 912     # works. At least, this is only going to be a run-time failure, so won't
 913     # affect tests using this file but not this function.
 914     $runperl_args->{progfile} ||= $tmpfile;
 915     $runperl_args->{stderr}     = 1 unless exists $runperl_args->{stderr};
 916
 917     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
 918     print TEST $prog;
 919     close TEST or die "Cannot close $tmpfile: $!";
 920
 921     my $results = runperl(%$runperl_args);
 922     my $status = $?;
 923
 924     # Clean up the results into something a bit more predictable.
 925     $results  =~ s/\n+$//;
 926     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
 927     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
 928
 929     # bison says 'parse error' instead of 'syntax error',
 930     # various yaccs may or may not capitalize 'syntax'.
 931     $results =~ s/^(syntax|parse) error/syntax error/mig;
 932
 933     if ($is_vms) {
 934         # some tests will trigger VMS messages that won't be expected
 935         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
 936
 937         # pipes double these sometimes
 938         $results =~ s/\n\n/\n/g;
 939     }
 940
 941     # Use the first line of the program as a name if none was given
 942     unless( $name ) {
 943         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
 944         $name = $name . '...' if length $first_line > length $name;
 945     }
 946
 947     # Historically this was implemented using a closure, but then that means
 948     # that the tests for closures avoid using this code. Given that there
 949     # are exactly two callers, doing exactly two things, the simpler approach
 950     # feels like a better trade off.
 951     my $pass;
 952     if ($action eq 'eq') {
 953         $pass = is($results, $expect, $name);
 954     } elsif ($action eq '=~') {
 955         $pass = like($results, $expect, $name);
 956     } else {
 957         die "_fresh_perl can't process action '$action'";
 958     }
 959
 960     unless ($pass) {
 961         _diag "# PROG: \n$prog\n";
 962         _diag "# STATUS: $status\n";
 963     }
 964
 965     return $pass;
 966 }
 967
 968 #
 969 # fresh_perl_is
 970 #
 971 # Combination of run_perl() and is().
 972 #
 973
 974 sub fresh_perl_is {
 975     my($prog, $expected, $runperl_args, $name) = @_;
 976
 977     # _fresh_perl() is going to clip the trailing newlines off the result.
 978     # This will make it so the test author doesn't have to know that.
 979     $expected =~ s/\n+$//;
 980
 981     local $Level = 2;
 982     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
 983 }
 984
 985 #
 986 # fresh_perl_like
 987 #
 988 # Combination of run_perl() and like().
 989 #
 990
 991 sub fresh_perl_like {
 992     my($prog, $expected, $runperl_args, $name) = @_;
 993     local $Level = 2;
 994     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
 995 }
 996
 997 # Many tests use the same format in __DATA__ or external files to specify a
 998 # sequence of (fresh) tests to run, extra files they may temporarily need, and
 999 # what the expected output is.  Putting it here allows common code to serve
1000 # these multiple tests.
1001 #
1002 # Each program is source code to run followed by an "EXPECT" line, followed
1003 # by the expected output.
1004 #
1005 # The code to run may begin with a command line switch such as -w or -0777
1006 # (alphanumerics only), and may contain (note the '# ' on each):
1007 #   # TODO reason for todo
1008 #   # SKIP reason for skip
1009 #   # SKIP ?code to test if this should be skipped
1010 #   # NAME name of the test (as with ok($ok, $name))
1011 #
1012 # The expected output may contain:
1013 #   OPTION list of options
1014 #   OPTIONS list of options
1015 #
1016 # The possible options for OPTION may be:
1017 #   regex - the expected output is a regular expression
1018 #   random - all lines match but in any order
1019 #   fatal - the code will fail fatally (croak, die)
1020 #
1021 # If the actual output contains a line "SKIPPED" the test will be
1022 # skipped.
1023 #
1024 # If the actual output contains a line "PREFIX", any output starting with that
1025 # line will be ignored when comparing with the expected output
1026 #
1027 # If the global variable $FATAL is true then OPTION fatal is the
1028 # default.
1029
1030 sub _setup_one_file {
1031     my $fh = shift;
1032     # Store the filename as a program that started at line 0.
1033     # Real files count lines starting at line 1.
1034     my @these = (0, shift);
1035     my ($lineno, $current);
1036     while (<$fh>) {
1037         if ($_ eq "########\n") {
1038             if (defined $current) {
1039                 push @these, $lineno, $current;
1040             }
1041             undef $current;
1042         } else {
1043             if (!defined $current) {
1044                 $lineno = $.;
1045             }
1046             $current .= $_;
1047         }
1048     }
1049     if (defined $current) {
1050         push @these, $lineno, $current;
1051     }
1052     ((scalar @these) / 2 - 1, @these);
1053 }
1054
1055 sub setup_multiple_progs {
1056     my ($tests, @prgs);
1057     foreach my $file (@_) {
1058         next if $file =~ /(?:~|\.orig|,v)$/;
1059         next if $file =~ /perlio$/ && !PerlIO::Layer->find('perlio');
1060         next if -d $file;
1061
1062         open my $fh, '<', $file or die "Cannot open $file: $!\n" ;
1063         my $found;
1064         while (<$fh>) {
1065             if (/^__END__/) {
1066                 ++$found;
1067                 last;
1068             }
1069         }
1070         # This is an internal error, and should never happen. All bar one of
1071         # the files had an __END__ marker to signal the end of their preamble,
1072         # although for some it wasn't technically necessary as they have no
1073         # tests. It might be possible to process files without an __END__ by
1074         # seeking back to the start and treating the whole file as tests, but
1075         # it's simpler and more reliable just to make the rule that all files
1076         # must have __END__ in. This should never fail - a file without an
1077         # __END__ should not have been checked in, because the regression tests
1078         # would not have passed.
1079         die "Could not find '__END__' in $file"
1080             unless $found;
1081
1082         my ($t, @p) = _setup_one_file($fh, $file);
1083         $tests += $t;
1084         push @prgs, @p;
1085
1086         close $fh
1087             or die "Cannot close $file: $!\n";
1088     }
1089     return ($tests, @prgs);
1090 }
1091
1092 sub run_multiple_progs {
1093     my $up = shift;
1094     my @prgs;
1095     if ($up) {
1096         # The tests in lib run in a temporary subdirectory of t, and always
1097         # pass in a list of "programs" to run
1098         @prgs = @_;
1099     } else {
1100         # The tests below t run in t and pass in a file handle. In theory we
1101         # can pass (caller)[1] as the second argument to report errors with
1102         # the filename of our caller, as the handle is always DATA. However,
1103         # line numbers in DATA count from the __END__ token, so will be wrong.
1104         # Which is more confusing than not providing line numbers. So, for now,
1105         # don't provide line numbers. No obvious clean solution - one hack
1106         # would be to seek DATA back to the start and read to the __END__ token,
1107         # but that feels almost like we should just open $0 instead.
1108
1109         # Not going to rely on undef in list assignment.
1110         my $dummy;
1111         ($dummy, @prgs) = _setup_one_file(shift);
1112     }
1113
1114     my $tmpfile = tempfile();
1115
1116     my ($file, $line);
1117   PROGRAM:
1118     while (defined ($line = shift @prgs)) {
1119         $_ = shift @prgs;
1120         unless ($line) {
1121             $file = $_;
1122             if (defined $file) {
1123                 print "# From $file\n";
1124             }
1125             next;
1126         }
1127         my $switch = "";
1128         my @temps ;
1129         my @temp_path;
1130         if (s/^(\s*-\w+)//) {
1131             $switch = $1;
1132         }
1133         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
1134
1135         my %reason;
1136         foreach my $what (qw(skip todo)) {
1137             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
1138             # If the SKIP reason starts ? then it's taken as a code snippet to
1139             # evaluate. This provides the flexibility to have conditional SKIPs
1140             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
1141                 my $temp = eval $reason{$what};
1142                 if ($@) {
1143                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
1144                 }
1145                 $reason{$what} = $temp;
1146             }
1147         }
1148
1149         my $name = '';
1150         if ($prog =~ s/^#\s*NAME\s+(.+)\n//m) {
1151             $name = $1;
1152         }
1153
1154         if ($reason{skip}) {
1155         SKIP:
1156           {
1157             skip($name ? "$name - $reason{skip}" : $reason{skip}, 1);
1158           }
1159           next PROGRAM;
1160         }
1161
1162         if ($prog =~ /--FILE--/) {
1163             my @files = split(/\n?--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
1164             shift @files ;
1165             die "Internal error: test $_ didn't split into pairs, got " .
1166                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
1167                     if @files % 2;
1168             while (@files > 2) {
1169                 my $filename = shift @files;
1170                 my $code = shift @files;
1171                 push @temps, $filename;
1172                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
1173                     require File::Path;
1174                     File::Path::mkpath($1);
1175                     push(@temp_path, $1);
1176                 }
1177                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
1178                 print $fh $code;
1179                 close $fh or die "Cannot close $filename: $!\n";
1180             }
1181             shift @files;
1182             $prog = shift @files;
1183         }
1184
1185         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
1186         print $fh q{
1187         BEGIN {
1188             open STDERR, '>&', STDOUT
1189               or die "Can't dup STDOUT->STDERR: $!;";
1190         }
1191         };
1192         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
1193         print $fh $prog,"\n";
1194         close $fh or die "Cannot close $tmpfile: $!";
1195         my $results = runperl( stderr => 1, progfile => $tmpfile,
1196                                stdin => undef, $up
1197                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
1198                                : (switches => [$switch])
1199                                 );
1200         my $status = $?;
1201         $results =~ s/\n+$//;
1202         # allow expected output to be written as if $prog is on STDIN
1203         $results =~ s/$::tempfile_regexp/-/g;
1204         if ($^O eq 'VMS') {
1205             # some tests will trigger VMS messages that won't be expected
1206             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
1207
1208             # pipes double these sometimes
1209             $results =~ s/\n\n/\n/g;
1210         }
1211         # bison says 'parse error' instead of 'syntax error',
1212         # various yaccs may or may not capitalize 'syntax'.
1213         $results =~ s/^(syntax|parse) error/syntax error/mig;
1214         # allow all tests to run when there are leaks
1215         $results =~ s/Scalars leaked: \d+\n//g;
1216
1217         $expected =~ s/\n+$//;
1218         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
1219         # any special options? (OPTIONS foo bar zap)
1220         my $option_regex = 0;
1221         my $option_random = 0;
1222         my $fatal = $FATAL;
1223         if ($expected =~ s/^OPTIONS? (.+)\n//) {
1224             foreach my $option (split(' ', $1)) {
1225                 if ($option eq 'regex') { # allow regular expressions
1226                     $option_regex = 1;
1227                 }
1228                 elsif ($option eq 'random') { # all lines match, but in any order
1229                     $option_random = 1;
1230                 }
1231                 elsif ($option eq 'fatal') { # perl should fail
1232                     $fatal = 1;
1233                 }
1234                 else {
1235                     die "$0: Unknown OPTION '$option'\n";
1236                 }
1237             }
1238         }
1239         die "$0: can't have OPTION regex and random\n"
1240             if $option_regex + $option_random > 1;
1241         my $ok = 0;
1242         if ($results =~ s/^SKIPPED\n//) {
1243             print "$results\n" ;
1244             $ok = 1;
1245         }
1246         else {
1247             if ($option_random) {
1248                 my @got = sort split "\n", $results;
1249                 my @expected = sort split "\n", $expected;
1250
1251                 $ok = "@got" eq "@expected";
1252             }
1253             elsif ($option_regex) {
1254                 $ok = $results =~ /^$expected/;
1255             }
1256             elsif ($prefix) {
1257                 $ok = $results =~ /^\Q$expected/;
1258             }
1259             else {
1260                 $ok = $results eq $expected;
1261             }
1262
1263             if ($ok && $fatal && !($status >> 8)) {
1264                 $ok = 0;
1265             }
1266         }
1267
1268         local $::TODO = $reason{todo};
1269
1270         unless ($ok) {
1271             my $err_line = "PROG: $switch\n$prog\n" .
1272                            "EXPECTED:\n$expected\n";
1273             $err_line   .= "EXIT STATUS: != 0\n" if $fatal;
1274             $err_line   .= "GOT:\n$results\n";
1275             $err_line   .= "EXIT STATUS: " . ($status >> 8) . "\n" if $fatal;
1276             if ($::TODO) {
1277                 $err_line =~ s/^/# /mg;
1278                 print $err_line;  # Harness can't filter it out from STDERR.
1279             }
1280             else {
1281                 print STDERR $err_line;
1282             }
1283         }
1284
1285         if (defined $file) {
1286             _ok($ok, "at $file line $line", $name);
1287         } else {
1288             # We don't have file and line number data for the test, so report
1289             # errors as coming from our caller.
1290             local $Level = $Level + 1;
1291             ok($ok, $name);
1292         }
1293
1294         foreach (@temps) {
1295             unlink $_ if $_;
1296         }
1297         foreach (@temp_path) {
1298             File::Path::rmtree $_ if -d $_;
1299         }
1300     }
1301 }
1302
1303 sub can_ok ($@) {
1304     my($proto, @methods) = @_;
1305     my $class = ref $proto || $proto;
1306
1307     unless( @methods ) {
1308         return _ok( 0, _where(), "$class->can(...)" );
1309     }
1310
1311     my @nok = ();
1312     foreach my $method (@methods) {
1313         local($!, $@);  # don't interfere with caller's $@
1314                         # eval sometimes resets $!
1315         eval { $proto->can($method) } || push @nok, $method;
1316     }
1317
1318     my $name;
1319     $name = @methods == 1 ? "$class->can('$methods[0]')"
1320                           : "$class->can(...)";
1321
1322     _ok( !@nok, _where(), $name );
1323 }
1324
1325
1326 # Call $class->new( @$args ); and run the result through object_ok.
1327 # See Test::More::new_ok
1328 sub new_ok {
1329     my($class, $args, $obj_name) = @_;
1330     $args ||= [];
1331     $object_name = "The object" unless defined $obj_name;
1332
1333     local $Level = $Level + 1;
1334
1335     my $obj;
1336     my $ok = eval { $obj = $class->new(@$args); 1 };
1337     my $error = $@;
1338
1339     if($ok) {
1340         object_ok($obj, $class, $object_name);
1341     }
1342     else {
1343         ok( 0, "new() died" );
1344         diag("Error was:  $@");
1345     }
1346
1347     return $obj;
1348
1349 }
1350
1351
1352 sub isa_ok ($$;$) {
1353     my($object, $class, $obj_name) = @_;
1354
1355     my $diag;
1356     $obj_name = 'The object' unless defined $obj_name;
1357     my $name = "$obj_name isa $class";
1358     if( !defined $object ) {
1359         $diag = "$obj_name isn't defined";
1360     }
1361     else {
1362         my $whatami = ref $object ? 'object' : 'class';
1363
1364         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1365         local($@, $!);  # eval sometimes resets $!
1366         my $rslt = eval { $object->isa($class) };
1367         my $error = $@;  # in case something else blows away $@
1368
1369         if( $error ) {
1370             if( $error =~ /^Can't call method "isa" on unblessed reference/ ) {
1371                 # It's an unblessed reference
1372                 $obj_name = 'The reference' unless defined $obj_name;
1373                 if( !UNIVERSAL::isa($object, $class) ) {
1374                     my $ref = ref $object;
1375                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1376                 }
1377             }
1378             elsif( $error =~ /Can't call method "isa" without a package/ ) {
1379                 # It's something that can't even be a class
1380                 $obj_name = 'The thing' unless defined $obj_name;
1381                 $diag = "$obj_name isn't a class or reference";
1382             }
1383             else {
1384                 die <<WHOA;
1385 WHOA! I tried to call ->isa on your object and got some weird error.
1386 This should never happen.  Please contact the author immediately.
1387 Here's the error.
1388 $@
1389 WHOA
1390             }
1391         }
1392         elsif( !$rslt ) {
1393             $obj_name = "The $whatami" unless defined $obj_name;
1394             my $ref = ref $object;
1395             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1396         }
1397     }
1398
1399     _ok( !$diag, _where(), $name );
1400 }
1401
1402
1403 sub class_ok {
1404     my($class, $isa, $class_name) = @_;
1405
1406     # Written so as to count as one test
1407     local $Level = $Level + 1;
1408     if( ref $class ) {
1409         ok( 0, "$class is a refrence, not a class name" );
1410     }
1411     else {
1412         isa_ok($class, $isa, $class_name);
1413     }
1414 }
1415
1416
1417 sub object_ok {
1418     my($obj, $isa, $obj_name) = @_;
1419
1420     local $Level = $Level + 1;
1421     if( !ref $obj ) {
1422         ok( 0, "$obj is not a reference" );
1423     }
1424     else {
1425         isa_ok($obj, $isa, $obj_name);
1426     }
1427 }
1428
1429
1430 # Purposefully avoiding a closure.
1431 sub __capture {
1432     push @::__capture, join "", @_;
1433 }
1434
1435 sub capture_warnings {
1436     my $code = shift;
1437
1438     local @::__capture;
1439     local $SIG {__WARN__} = \&__capture;
1440     &$code;
1441     return @::__capture;
1442 }
1443
1444 # This will generate a variable number of tests.
1445 # Use done_testing() instead of a fixed plan.
1446 sub warnings_like {
1447     my ($code, $expect, $name) = @_;
1448     local $Level = $Level + 1;
1449
1450     my @w = capture_warnings($code);
1451
1452     cmp_ok(scalar @w, '==', scalar @$expect, $name);
1453     foreach my $e (@$expect) {
1454         if (ref $e) {
1455             like(shift @w, $e, $name);
1456         } else {
1457             is(shift @w, $e, $name);
1458         }
1459     }
1460     if (@w) {
1461         diag("Saw these additional warnings:");
1462         diag($_) foreach @w;
1463     }
1464 }
1465
1466 sub _fail_excess_warnings {
1467     my($expect, $got, $name) = @_;
1468     local $Level = $Level + 1;
1469     # This will fail, and produce diagnostics
1470     is($expect, scalar @$got, $name);
1471     diag("Saw these warnings:");
1472     diag($_) foreach @$got;
1473 }
1474
1475 sub warning_is {
1476     my ($code, $expect, $name) = @_;
1477     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1478         if ref $expect;
1479     local $Level = $Level + 1;
1480     my @w = capture_warnings($code);
1481     if (@w > 1) {
1482         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1483     } else {
1484         is($w[0], $expect, $name);
1485     }
1486 }
1487
1488 sub warning_like {
1489     my ($code, $expect, $name) = @_;
1490     die sprintf "Expect must be a regexp object"
1491         unless ref $expect eq 'Regexp';
1492     local $Level = $Level + 1;
1493     my @w = capture_warnings($code);
1494     if (@w > 1) {
1495         _fail_excess_warnings(0 + defined $expect, \@w, $name);
1496     } else {
1497         like($w[0], $expect, $name);
1498     }
1499 }
1500
1501 # Set a watchdog to timeout the entire test file
1502 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1503 #        _AFTER_ the 'threads' module is loaded.
1504 sub watchdog ($;$)
1505 {
1506     my $timeout = shift;
1507     my $method  = shift || "";
1508     my $timeout_msg = 'Test process timed out - terminating';
1509
1510     # Valgrind slows perl way down so give it more time before dying.
1511     $timeout *= 10 if $ENV{PERL_VALGRIND};
1512
1513     my $pid_to_kill = $$;   # PID for this process
1514
1515     if ($method eq "alarm") {
1516         goto WATCHDOG_VIA_ALARM;
1517     }
1518
1519     # shut up use only once warning
1520     my $threads_on = $threads::threads && $threads::threads;
1521
1522     # Don't use a watchdog process if 'threads' is loaded -
1523     #   use a watchdog thread instead
1524     if (!$threads_on || $method eq "process") {
1525
1526         # On Windows and VMS, try launching a watchdog process
1527         #   using system(1, ...) (see perlport.pod)
1528         if ($is_mswin || $is_vms) {
1529             # On Windows, try to get the 'real' PID
1530             if ($is_mswin) {
1531                 eval { require Win32; };
1532                 if (defined(&Win32::GetCurrentProcessId)) {
1533                     $pid_to_kill = Win32::GetCurrentProcessId();
1534                 }
1535             }
1536
1537             # If we still have a fake PID, we can't use this method at all
1538             return if ($pid_to_kill <= 0);
1539
1540             # Launch watchdog process
1541             my $watchdog;
1542             eval {
1543                 local $SIG{'__WARN__'} = sub {
1544                     _diag("Watchdog warning: $_[0]");
1545                 };
1546                 my $sig = $is_vms ? 'TERM' : 'KILL';
1547                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1548                                                     "warn qq/# $timeout_msg" . '\n/;' .
1549                                                     "kill($sig, $pid_to_kill);");
1550                 $watchdog = system(1, $cmd);
1551             };
1552             if ($@ || ($watchdog <= 0)) {
1553                 _diag('Failed to start watchdog');
1554                 _diag($@) if $@;
1555                 undef($watchdog);
1556                 return;
1557             }
1558
1559             # Add END block to parent to terminate and
1560             #   clean up watchdog process
1561             # Win32 watchdog is launched by cmd.exe shell, so use process group
1562             # kill, otherwise the watchdog is never killed and harness waits
1563             # every time for the timeout, #121395
1564             eval( $is_mswin ?
1565             "END { local \$! = 0; local \$? = 0;
1566                         wait() if kill('-KILL', $watchdog); };"
1567             : "END { local \$! = 0; local \$? = 0;
1568                         wait() if kill('KILL', $watchdog); };");
1569             return;
1570         }
1571
1572         # Try using fork() to generate a watchdog process
1573         my $watchdog;
1574         eval { $watchdog = fork() };
1575         if (defined($watchdog)) {
1576             if ($watchdog) {   # Parent process
1577                 # Add END block to parent to terminate and
1578                 #   clean up watchdog process
1579                 eval "END { local \$! = 0; local \$? = 0;
1580                             wait() if kill('KILL', $watchdog); };";
1581                 return;
1582             }
1583
1584             ### Watchdog process code
1585
1586             # Load POSIX if available
1587             eval { require POSIX; };
1588
1589             # Execute the timeout
1590             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1591             sleep(2);
1592
1593             # Kill test process if still running
1594             if (kill(0, $pid_to_kill)) {
1595                 _diag($timeout_msg);
1596                 kill('KILL', $pid_to_kill);
1597                 if ($is_cygwin) {
1598                     # sometimes the above isn't enough on cygwin
1599                     sleep 1; # wait a little, it might have worked after all
1600                     system("/bin/kill -f $pid_to_kill");
1601                 }
1602             }
1603
1604             # Don't execute END block (added at beginning of this file)
1605             $NO_ENDING = 1;
1606
1607             # Terminate ourself (i.e., the watchdog)
1608             POSIX::_exit(1) if (defined(&POSIX::_exit));
1609             exit(1);
1610         }
1611
1612         # fork() failed - fall through and try using a thread
1613     }
1614
1615     # Use a watchdog thread because either 'threads' is loaded,
1616     #   or fork() failed
1617     if (eval {require threads; 1}) {
1618         'threads'->create(sub {
1619                 # Load POSIX if available
1620                 eval { require POSIX; };
1621
1622                 # Execute the timeout
1623                 my $time_left = $timeout;
1624                 do {
1625                     $time_left = $time_left - sleep($time_left);
1626                 } while ($time_left > 0);
1627
1628                 # Kill the parent (and ourself)
1629                 select(STDERR); $| = 1;
1630                 _diag($timeout_msg);
1631                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1632                 my $sig = $is_vms ? 'TERM' : 'KILL';
1633                 kill($sig, $pid_to_kill);
1634             })->detach();
1635         return;
1636     }
1637
1638     # If everything above fails, then just use an alarm timeout
1639 WATCHDOG_VIA_ALARM:
1640     if (eval { alarm($timeout); 1; }) {
1641         # Load POSIX if available
1642         eval { require POSIX; };
1643
1644         # Alarm handler will do the actual 'killing'
1645         $SIG{'ALRM'} = sub {
1646             select(STDERR); $| = 1;
1647             _diag($timeout_msg);
1648             POSIX::_exit(1) if (defined(&POSIX::_exit));
1649             my $sig = $is_vms ? 'TERM' : 'KILL';
1650             kill($sig, $pid_to_kill);
1651         };
1652     }
1653 }
1654
1655 # The following 2 functions allow tests to work on both EBCDIC and
1656 # ASCII-ish platforms.  They convert string scalars between the native
1657 # character set and the set of 256 characters which is usually called
1658 # Latin1.
1659
1660 sub native_to_latin1($) {
1661     my $string = shift;
1662
1663     return $string if ord('^') == 94;   # ASCII, Latin1
1664     my $output = "";
1665     for my $i (0 .. length($string) - 1) {
1666         $output .= chr(ord_native_to_latin1(ord(substr($string, $i, 1))));
1667     }
1668     # Preserve utf8ness of input onto the output, even if it didn't need to be
1669     # utf8
1670     utf8::upgrade($output) if utf8::is_utf8($string);
1671
1672     return $output;
1673 }
1674
1675 sub latin1_to_native($) {
1676     my $string = shift;
1677
1678     return $string if ord('^') == 94;   # ASCII, Latin1
1679     my $output = "";
1680     for my $i (0 .. length($string) - 1) {
1681         $output .= chr(ord_latin1_to_native(ord(substr($string, $i, 1))));
1682     }
1683     # Preserve utf8ness of input onto the output, even if it didn't need to be
1684     # utf8
1685     utf8::upgrade($output) if utf8::is_utf8($string);
1686
1687     return $output;
1688 }
1689
1690 sub ord_latin1_to_native {
1691     # given an input code point, return the platform's native
1692     # equivalent value.  Anything above latin1 is itself.
1693
1694     my $ord = shift;
1695     return $ord if ord('^') == 94;   # ASCII, Latin1
1696     return utf8::unicode_to_native($ord);
1697 }
1698
1699 sub ord_native_to_latin1 {
1700     # given an input platform code point, return the latin1 equivalent value.
1701     # Anything above latin1 is itself.
1702
1703     my $ord = shift;
1704     return $ord if ord('^') == 94;   # ASCII, Latin1
1705     return utf8::native_to_unicode($ord);
1706 }
1707
1708 1;