t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still current
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # "not absolute" is the default, as it saves some fakery within TestInit
  27 # which can perturb tests, and takes CPU. Working with the upstream author of
  28 # any of these, to figure out how to remove them from this list, considered
  29 # "a good thing".
  30 my %abs = (
  31            '../cpan/Archive-Tar' => 1,
  32            '../cpan/AutoLoader' => 1,
  33            '../cpan/CPAN' => 1,
  34            '../cpan/Class-ISA' => 1,
  35            '../cpan/Devel-PPPort' => 1,
  36            '../cpan/Encode' => 1,
  37            '../cpan/ExtUtils-Constant' => 1,
  38            '../cpan/ExtUtils-MakeMaker' => 1,
  39            '../cpan/File-Fetch' => 1,
  40            '../cpan/IPC-Cmd' => 1,
  41            '../cpan/IPC-SysV' => 1,
  42            '../cpan/Locale-Codes' => 1,
  43            '../cpan/Module-Build' => 1,
  44            '../cpan/Module-Load' => 1,
  45            '../cpan/Module-Load-Conditional' => 1,
  46            '../cpan/Package-Constants' => 1,
  47            '../cpan/Parse-CPAN-Meta' => 1,
  48            '../cpan/Pod-Simple' => 1,
  49            '../cpan/Test-Simple' => 1,
  50            '../cpan/podlators' => 1,
  51            '../dist/Cwd' => 1,
  52            '../dist/ExtUtils-Command' => 1,
  53            '../dist/ExtUtils-Install' => 1,
  54            '../dist/ExtUtils-Manifest' => 1,
  55            '../dist/ExtUtils-ParseXS' => 1,
  56            '../dist/Tie-File' => 1,
  57           );
  58
  59 my %temp_no_core =
  60     ('../cpan/B-Debug' => 1,
  61      '../cpan/Compress-Raw-Bzip2' => 1,
  62      '../cpan/Compress-Raw-Zlib' => 1,
  63      '../cpan/Devel-PPPort' => 1,
  64      '../cpan/Getopt-Long' => 1,
  65      '../cpan/IO-Compress' => 1,
  66      '../cpan/MIME-Base64' => 1,
  67      '../cpan/parent' => 1,
  68      '../cpan/Parse-CPAN-Meta' => 1,
  69      '../cpan/Pod-Simple' => 1,
  70      '../cpan/podlators' => 1,
  71      '../cpan/Test-Simple' => 1,
  72      '../cpan/Tie-RefHash' => 1,
  73      '../cpan/Unicode-Collate' => 1,
  74      '../cpan/Unicode-Normalize' => 1,
  75     );
  76
  77 # delete env vars that may influence the results
  78 # but allow override via *_TEST env var if wanted
  79 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  80 my @bad_env_vars = qw(
  81     PERL5LIB PERLLIB PERL5OPT
  82     PERL_YAML_BACKEND PERL_JSON_BACKEND
  83 );
  84
  85 for my $envname (@bad_env_vars) {
  86     my $override = $ENV{"${envname}_TEST"};
  87     if (defined $override) {
  88         warn "$0: $envname=$override\n";
  89         $ENV{$envname} = $override;
  90     }
  91     else {
  92         delete $ENV{$envname};
  93     }
  94 }
  95
  96 # Location to put the Valgrind log.
  97 our $Valgrind_Log;
  98
  99 my %skip = (
 100             '.' => 1,
 101             '..' => 1,
 102             'CVS' => 1,
 103             'RCS' => 1,
 104             'SCCS' => 1,
 105             '.svn' => 1,
 106            );
 107
 108
 109 if ($::do_nothing) {
 110     return 1;
 111 }
 112
 113 $| = 1;
 114
 115 # for testing TEST only
 116 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 117 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 118
 119 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 120 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 121 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 122
 123 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 124 # can't rely on require working.
 125 {
 126     my @argv = ();
 127     foreach my $idx (0..$#ARGV) {
 128         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 129         $::benchmark = 1 if $1 eq 'benchmark';
 130         $::core    = 1 if $1 eq 'core';
 131         $::verbose = 1 if $1 eq 'v';
 132         $::torture = 1 if $1 eq 'torture';
 133         $::with_utf8 = 1 if $1 eq 'utf8';
 134         $::with_utf16 = 1 if $1 eq 'utf16';
 135         $::taintwarn = 1 if $1 eq 'taintwarn';
 136         if ($1 =~ /^deparse(,.+)?$/) {
 137             $::deparse = 1;
 138             $::deparse_opts = $1;
 139         }
 140     }
 141     @ARGV = @argv;
 142 }
 143
 144 chdir 't' if -f 't/TEST';
 145 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 146     @INC = '../lib';
 147 }
 148
 149 die "You need to run \"make test\" first to set things up.\n"
 150   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 151
 152 # check leakage for embedders
 153 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 154 # check existence of all symbols
 155 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
 156
 157 $ENV{EMXSHELL} = 'sh';        # For OS/2
 158
 159 if ($show_elapsed_time) { require Time::HiRes }
 160 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 161
 162 # Roll your own File::Find!
 163 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
 164 sub _find_files {
 165     my($patt, @dirs) = @_;
 166     for my $dir (@dirs) {
 167         opendir DIR, $dir or die "Trouble opening $dir: $!";
 168         foreach my $f (sort { $a cmp $b } readdir DIR) {
 169             next if $skip{$f};
 170
 171             my $fullpath = "$dir/$f";
 172
 173             if (-d $fullpath) {
 174                 _find_files($patt, $fullpath);
 175             } elsif ($f =~ /$patt/) {
 176                 push @found, $fullpath;
 177             }
 178         }
 179     }
 180     @found;
 181 }
 182
 183
 184 # Scan the text of the test program to find switches and special options
 185 # we might need to apply.
 186 sub _scan_test {
 187     my($test, $type) = @_;
 188
 189     open(my $script, "<", $test) or die "Can't read $test.\n";
 190     my $first_line = <$script>;
 191
 192     $first_line =~ tr/\0//d if $::with_utf16;
 193
 194     my $switch = "";
 195     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 196         $switch = "-$1";
 197     } else {
 198         if ($::taintwarn) {
 199             # not all tests are expected to pass with this option
 200             $switch = '-t';
 201         } else {
 202             $switch = '';
 203         }
 204     }
 205
 206     my $file_opts = "";
 207     if ($type eq 'deparse') {
 208         # Look for #line directives which change the filename
 209         while (<$script>) {
 210             $file_opts = $file_opts . ",-f$3$4"
 211               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 212         }
 213     }
 214
 215     close $script;
 216
 217     my $perl = './perl';
 218     my $lib  = '../lib';
 219     my $run_dir;
 220     my $return_dir;
 221
 222     $test =~ /^(.+)\/[^\/]+/;
 223     my $dir = $1;
 224     my $testswitch = $dir_to_switch{$dir};
 225     if (!defined $testswitch) {
 226         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 227             $run_dir = $1;
 228             $return_dir = '../../t';
 229             $lib = '../../lib';
 230             $perl = '../../t/perl';
 231             $testswitch = "-I../.. -MTestInit=U2T";
 232             if ($2 eq 'cpan' || $2 eq 'dist') {
 233                 if($abs{$run_dir}) {
 234                     $testswitch = $testswitch . ',A';
 235                 }
 236                 if ($temp_no_core{$run_dir}) {
 237                     $testswitch = $testswitch . ',NC';
 238                 }
 239             }
 240         } elsif ($test =~ m!^\.\./lib!) {
 241             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 242         } else {
 243             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 244         }
 245     }
 246
 247     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 248
 249     my %options = (
 250         perl => $perl,
 251         lib => $lib,
 252         test => $test,
 253         run_dir => $run_dir,
 254         return_dir => $return_dir,
 255         testswitch => $testswitch,
 256         utf8 => $utf8,
 257         file => $file_opts,
 258         switch => $switch,
 259     );
 260
 261     return \%options;
 262 }
 263
 264 sub _cmd {
 265     my($options, $type) = @_;
 266
 267     my $test = $options->{test};
 268
 269     my $cmd;
 270     if ($type eq 'deparse') {
 271         my $perl = "$options->{perl} $options->{testswitch}";
 272         my $lib = $options->{lib};
 273
 274         $cmd = (
 275           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 276           "-l$::deparse_opts$options->{file} ".
 277           "$test > $test.dp ".
 278           "&& $perl $options->{switch} -I$lib $test.dp"
 279         );
 280     }
 281     elsif ($type eq 'perl') {
 282         my $perl = $options->{perl};
 283         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 284
 285         if ($ENV{PERL_VALGRIND}) {
 286             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 287             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 288             if ($options->{run_dir}) {
 289                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 290             }
 291             my $vg_opts = $ENV{VG_OPTS}
 292                //   "--log-file=$Valgrind_Log "
 293                   . "--suppressions=$perl_supp --leak-check=yes "
 294                   . "--leak-resolution=high --show-reachable=yes "
 295                   . "--num-callers=50 --track-origins=yes";
 296             # Force logging if not asked for (so cachegrind reporting works below)
 297             if ($vg_opts !~ /--log-file/) {
 298                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
 299             }
 300             $perl = "$valgrind_exe $vg_opts $perl";
 301         }
 302
 303         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 304         $cmd = $perl . _quote_args($args) . " $test $redir";
 305     }
 306     return $cmd;
 307 }
 308
 309 sub _before_fork {
 310     my ($options) = @_;
 311
 312     if ($options->{run_dir}) {
 313         my $run_dir = $options->{run_dir};
 314         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 315     }
 316
 317     # Remove previous valgrind output otherwise it will interfere
 318     my $test = $options->{test};
 319
 320     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 321
 322     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
 323         unlink $Valgrind_Log
 324             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 325     }
 326
 327     return;
 328 }
 329
 330 sub _after_fork {
 331     my ($options) = @_;
 332
 333     if ($options->{return_dir}) {
 334         my $return_dir = $options->{return_dir};
 335         chdir $return_dir
 336            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 337     }
 338
 339     return;
 340 }
 341
 342 sub _run_test {
 343     my ($test, $type) = @_;
 344
 345     my $options = _scan_test($test, $type);
 346     # $test might have changed if we're in ext/Foo, so don't use it anymore
 347     # from now on. Use $options->{test} instead.
 348
 349     _before_fork($options);
 350
 351     my $cmd = _cmd($options, $type);
 352
 353     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 354
 355     _after_fork($options);
 356
 357     # Our environment may force us to use UTF-8, but we can't be sure that
 358     # anything we're reading from will be generating (well formed) UTF-8
 359     # This may not be the best way - possibly we should unset ${^OPEN} up
 360     # top?
 361     binmode $results;
 362
 363     return $results;
 364 }
 365
 366 sub _quote_args {
 367     my ($args) = @_;
 368     my $argstring = '';
 369
 370     foreach (split(/\s+/,$args)) {
 371        # In VMS protect with doublequotes because otherwise
 372        # DCL will lowercase -- unless already doublequoted.
 373        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 374        $argstring = $argstring . ' ' . $_;
 375     }
 376     return $argstring;
 377 }
 378
 379 sub _populate_hash {
 380     return unless defined $_[0];
 381     return map {$_, 1} split /\s+/, $_[0];
 382 }
 383
 384 sub _tests_from_manifest {
 385     my ($extensions, $known_extensions) = @_;
 386     my %skip;
 387     my %extensions = _populate_hash($extensions);
 388     my %known_extensions = _populate_hash($known_extensions);
 389
 390     foreach (keys %known_extensions) {
 391         $skip{$_} = 1 unless $extensions{$_};
 392     }
 393
 394     my @results;
 395     my $mani = '../MANIFEST';
 396     if (open(MANI, $mani)) {
 397         while (<MANI>) {
 398             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 399                 my $t = $1;
 400                 my $extension = $2;
 401                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 402                     if (defined $extension) {
 403                         $extension =~ s!/t(:?/\S+)*$!!;
 404                         # XXX Do I want to warn that I'm skipping these?
 405                         next if $skip{$extension};
 406                         my $flat_extension = $extension;
 407                         $flat_extension =~ s!-!/!g;
 408                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 409                     }
 410                     my $path = "../$t";
 411                     push @results, $path;
 412                     $::path_to_name{$path} = $t;
 413                 }
 414             }
 415         }
 416         close MANI;
 417     } else {
 418         warn "$0: cannot open $mani: $!\n";
 419     }
 420     return @results;
 421 }
 422
 423 unless (@ARGV) {
 424     # base first, as TEST bails out if that can't run
 425     # then comp, to validate that require works
 426     # then run, to validate that -M works
 427     # then we know we can -MTestInit for everything else, making life simpler
 428     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro)) {
 429         _find_tests($dir);
 430     }
 431     unless ($::core) {
 432         _find_tests('porting');
 433         _find_tests("lib");
 434     }
 435     # Config.pm may be broken for make minitest. And this is only a refinement
 436     # for skipping tests on non-default builds, so it is allowed to fail.
 437     # What we want to to is make a list of extensions which we did not build.
 438     my $configsh = '../config.sh';
 439     my ($extensions, $known_extensions);
 440     if (-f $configsh) {
 441         open FH, $configsh or die "Can't open $configsh: $!";
 442         while (<FH>) {
 443             if (/^extensions=['"](.*)['"]$/) {
 444                 $extensions = $1;
 445             }
 446             elsif (/^known_extensions=['"](.*)['"]$/) {
 447                 $known_extensions = $1;
 448             }
 449         }
 450         if (!defined $known_extensions) {
 451             warn "No known_extensions line found in $configsh";
 452         }
 453         if (!defined $extensions) {
 454             warn "No extensions line found in $configsh";
 455         }
 456     }
 457     # The "complex" constructions of list return from a subroutine, and push of
 458     # a list, might fail if perl is really hosed, but they aren't needed for
 459     # make minitest, and the building of extensions will likely also fail if
 460     # something is that badly wrong.
 461     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 462     unless ($::core) {
 463         _find_tests('x2p');
 464         _find_tests('japh') if $::torture;
 465         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 466         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
 467     }
 468 }
 469
 470 if ($::deparse) {
 471     _testprogs('deparse', '',   @ARGV);
 472 }
 473 elsif ($::with_utf16) {
 474     for my $e (0, 1) {
 475         for my $b (0, 1) {
 476             print STDERR "# ENDIAN $e BOM $b\n";
 477             my @UARGV;
 478             for my $a (@ARGV) {
 479                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 480                 my $f = $e ? "v" : "n";
 481                 push @UARGV, $u;
 482                 unlink($u);
 483                 if (open(A, $a)) {
 484                     if (open(U, ">$u")) {
 485                         print U pack("$f", 0xFEFF) if $b;
 486                         while (<A>) {
 487                             print U pack("$f*", unpack("C*", $_));
 488                         }
 489                         close(U);
 490                     }
 491                     close(A);
 492                 }
 493             }
 494             _testprogs('perl', '', @UARGV);
 495             unlink(@UARGV);
 496         }
 497     }
 498 }
 499 else {
 500     _testprogs('perl',    '',   @ARGV);
 501 }
 502
 503 sub _testprogs {
 504     my ($type, $args, @tests) = @_;
 505
 506     print <<'EOT' if ($type eq 'deparse');
 507 ------------------------------------------------------------------------------
 508 TESTING DEPARSER
 509 ------------------------------------------------------------------------------
 510 EOT
 511
 512     $::bad_files = 0;
 513
 514     foreach my $t (@tests) {
 515       unless (exists $::path_to_name{$t}) {
 516         my $tname = "t/$t";
 517         $::path_to_name{$t} = $tname;
 518       }
 519     }
 520     my $maxlen = 0;
 521     foreach (@::path_to_name{@tests}) {
 522         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 523         my $len = length ;
 524         $maxlen = $len if $len > $maxlen;
 525     }
 526     # + 3 : we want three dots between the test name and the "ok"
 527     my $dotdotdot = $maxlen + 3 ;
 528     my $grind_ct = 0;           # count of non-empty valgrind reports
 529     my $total_files = @tests;
 530     my $good_files = 0;
 531     my $tested_files  = 0;
 532     my $totmax = 0;
 533     my %failed_tests;
 534     my $toolnm;         # valgrind, cachegrind, perf
 535
 536     while (my $test = shift @tests) {
 537         my ($test_start_time, @starttimes) = 0;
 538         if ($show_elapsed_time) {
 539             $test_start_time = Time::HiRes::time();
 540             # times() reports usage by TEST, but we want usage of each
 541             # testprog it calls, so record accumulated times now,
 542             # subtract them out afterwards.  Ideally, we'd take times
 543             # in BEGIN/END blocks (giving better visibility of self vs
 544             # children of each testprog), but that would require some
 545             # IPC to send results back here, or a completely different
 546             # collection scheme (Storable isn't tuned for incremental use)
 547             @starttimes = times;
 548         }
 549         if ($test =~ /^$/) {
 550             next;
 551         }
 552         if ($type eq 'deparse') {
 553             if ($test eq "comp/redef.t") {
 554                 # Redefinition happens at compile time
 555                 next;
 556             }
 557             elsif ($test =~ m{lib/Switch/t/}) {
 558                 # B::Deparse doesn't support source filtering
 559                 next;
 560             }
 561         }
 562         my $te = $::path_to_name{$test} . '.'
 563                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 564
 565         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 566             print $te;
 567             $te = '';
 568         }
 569
 570         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 571
 572         my $results = _run_test($test, $type);
 573
 574         my $failure;
 575         my $next = 0;
 576         my $seen_leader = 0;
 577         my $seen_ok = 0;
 578         my $trailing_leader = 0;
 579         my $max;
 580         my %todo;
 581         while (<$results>) {
 582             next if /^\s*$/; # skip blank lines
 583             if (/^1..$/ && ($^O eq 'VMS')) {
 584                 # VMS pipe bug inserts blank lines.
 585                 my $l2 = <$results>;
 586                 if ($l2 =~ /^\s*$/) {
 587                     $l2 = <$results>;
 588                 }
 589                 $_ = '1..' . $l2;
 590             }
 591             if ($::verbose) {
 592                 print $_;
 593             }
 594             unless (/^\#/) {
 595                 if ($trailing_leader) {
 596                     # shouldn't be anything following a postfix 1..n
 597                     $failure = 'FAILED--extra output after trailing 1..n';
 598                     last;
 599                 }
 600                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 601                     if ($seen_leader) {
 602                         $failure = 'FAILED--seen duplicate leader';
 603                         last;
 604                     }
 605                     $max = $1;
 606                     %todo = map { $_ => 1 } split / /, $3 if $3;
 607                     $totmax = $totmax + $max;
 608                     $tested_files = $tested_files + 1;
 609                     if ($seen_ok) {
 610                         # 1..n appears at end of file
 611                         $trailing_leader = 1;
 612                         if ($next != $max) {
 613                             $failure = "FAILED--expected $max tests, saw $next";
 614                             last;
 615                         }
 616                     }
 617                     else {
 618                         $next = 0;
 619                     }
 620                     $seen_leader = 1;
 621                 }
 622                 else {
 623                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 624                         unless ($seen_leader) {
 625                             unless ($seen_ok) {
 626                                 $next = 0;
 627                             }
 628                         }
 629                         $seen_ok = 1;
 630                         $next = $next + 1;
 631                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 632                         $num = $next unless $num;
 633
 634                         if ($num == $next) {
 635
 636                             # SKIP is essentially the same as TODO for t/TEST
 637                             # this still conforms to TAP:
 638                             # http://testanything.org/wiki/index.php/TAP_specification
 639                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 640                             $istodo = 1 if $todo{$num};
 641
 642                             if( $not && !$istodo ) {
 643                                 $failure = "FAILED at test $num";
 644                                 last;
 645                             }
 646                         }
 647                         else {
 648                             $failure ="FAILED--expected test $next, saw test $num";
 649                             last;
 650                         }
 651                     }
 652                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 653                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 654                     }
 655                     else {
 656                         # module tests are allowed extra output,
 657                         # because Test::Harness allows it
 658                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 659                         $failure = "FAILED--unexpected output at test $next";
 660                         last;
 661                     }
 662                 }
 663             }
 664         }
 665         close $results;
 666
 667         if (not defined $failure) {
 668             $failure = 'FAILED--no leader found' unless $seen_leader;
 669         }
 670
 671         _check_valgrind(\$toolnm, \$grind_ct, \$test);
 672
 673         if ($type eq 'deparse') {
 674             unlink "./$test.dp";
 675         }
 676         if (not defined $failure and $next != $max) {
 677             $failure="FAILED--expected $max tests, saw $next";
 678         }
 679
 680         if( !defined $failure  # don't mask a test failure
 681             and $? )
 682         {
 683             $failure = "FAILED--non-zero wait status: $?";
 684         }
 685
 686         if (defined $failure) {
 687             print "${te}$failure\n";
 688             $::bad_files = $::bad_files + 1;
 689             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
 690                 # Die if running under minitest (no DynaLoader).  Otherwise
 691                 # keep going, as  we know that Perl basically works, or we
 692                 # would not have been able to actually compile it all the way.
 693                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
 694             }
 695             $failed_tests{$test} = 1;
 696         }
 697         else {
 698             if ($max) {
 699                 my ($elapsed, $etms) = ("", 0);
 700                 if ( $show_elapsed_time ) {
 701                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 702                     $elapsed = sprintf(" %8.0f ms", $etms);
 703
 704                     my (@endtimes) = times;
 705                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 706                     splice @endtimes, 0, 2;    # drop self/harness times
 707                     $_ *= 1000 for @endtimes;  # and scale to ms
 708                     $timings{$test} = [$etms,@endtimes];
 709                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 710                 }
 711                 print "${te}ok$elapsed\n";
 712                 $good_files = $good_files + 1;
 713             }
 714             else {
 715                 print "${te}skipped\n";
 716                 $tested_files = $tested_files - 1;
 717             }
 718         }
 719     } # while tests
 720
 721     if ($::bad_files == 0) {
 722         if ($good_files) {
 723             print "All tests successful.\n";
 724             # XXX add mention of 'perlbug -ok' ?
 725         }
 726         else {
 727             die "FAILED--no tests were run for some reason.\n";
 728         }
 729     }
 730     else {
 731         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 732         my $s = $::bad_files == 1 ? "" : "s";
 733         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 734         for my $test ( sort keys %failed_tests ) {
 735             print "\t$test\n";
 736         }
 737         warn <<'SHRDLU_1';
 738 ### Since not all tests were successful, you may want to run some of
 739 ### them individually and examine any diagnostic messages they produce.
 740 ### See the INSTALL document's section on "make test".
 741 SHRDLU_1
 742         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 743 ### You have a good chance to get more information by running
 744 ###   ./perl harness
 745 ### in the 't' directory since most (>=80%) of the tests succeeded.
 746 SHRDLU_2
 747         if (eval {require Config; import Config; 1}) {
 748             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 749                 warn <<SHRDLU_3;
 750 ### You may have to set your dynamic library search path,
 751 ### $p, to point to the build directory:
 752 SHRDLU_3
 753                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 754                     warn <<SHRDLU_4a;
 755 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 756 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 757 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 758 SHRDLU_4a
 759                 } else {
 760                     warn <<SHRDLU_4b;
 761 ###   setenv $p `pwd`; cd t; ./perl harness
 762 ###   $p=`pwd`; export $p; cd t; ./perl harness
 763 ###   export $p=`pwd`; cd t; ./perl harness
 764 SHRDLU_4b
 765                 }
 766                 warn <<SHRDLU_5;
 767 ### for csh-style shells, like tcsh; or for traditional/modern
 768 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 769 SHRDLU_5
 770             }
 771         }
 772     }
 773     my ($user,$sys,$cuser,$csys) = times;
 774     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 775                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 776     print "$tot\n";
 777     if ($good_files) {
 778         if (-d $show_elapsed_time) {
 779             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 780             # storable file there.  NB: the test cds to ./t/, so
 781             # relative path must account for that, ie ../../perf
 782             # points to dir next to source tree.
 783             require Storable;
 784             my @dt = localtime;
 785             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 786             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 787             Storable::store({ perf => \%timings,
 788                               gather_conf_platform_info(),
 789                               total => $tot,
 790                             }, $fn);
 791             print "wrote storable file: $fn\n";
 792         }
 793     }
 794
 795     _cleanup_valgrind(\$toolnm, \$grind_ct);
 796 }
 797 exit ($::bad_files != 0);
 798
 799 # Collect platform, config data that should allow comparing
 800 # performance data between different machines.  With enough data,
 801 # and/or clever statistical analysis, it should be possible to
 802 # determine the effect of config choices, more memory, etc
 803
 804 sub gather_conf_platform_info {
 805     # currently rather quick & dirty, and subject to change
 806     # for both content and format.
 807     require Config;
 808     my (%conf, @platform) = ();
 809     $conf{$_} = $Config::Config{$_} for
 810         grep /cc|git|config_arg\d+/, keys %Config::Config;
 811     if (-f '/proc/cpuinfo') {
 812         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 813         @platform = grep /name|cpu/, <$fh>;
 814         chomp $_ for @platform;
 815     }
 816     unshift @platform, $^O;
 817
 818     return (
 819         conf => \%conf,
 820         platform => {cpu => \@platform,
 821                      mem => [ grep s/\s+/ /,
 822                               grep chomp, `free` ],
 823                      load => [ grep chomp, `uptime` ],
 824         },
 825         host => (grep chomp, `hostname -f`),
 826         version => '0.03', # bump for conf, platform, or data collection changes
 827         );
 828 }
 829
 830 sub _check_valgrind {
 831     return unless $ENV{PERL_VALGRIND};
 832
 833     my ($toolnm, $grind_ct, $test) = @_;
 834
 835     $$toolnm = $ENV{VALGRIND};
 836     $$toolnm =~ s|.*/||;  # keep basename
 837     my @valgrind;       # gets content of file
 838     if (-e $Valgrind_Log) {
 839         if (open(V, $Valgrind_Log)) {
 840             @valgrind = <V>;
 841             close V;
 842         } else {
 843             warn "$0: Failed to open '$Valgrind_Log': $!\n";
 844         }
 845     }
 846     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
 847         $$toolnm = $1;
 848         if ($$toolnm eq 'perf') {
 849             # append perfs subcommand, not just stat
 850             my ($sub) = split /\s/, $ENV{VG_OPTS};
 851             $$toolnm .= "-$sub";
 852         }
 853         if (rename $Valgrind_Log, "$$test.$$toolnm") {
 854             $$grind_ct++;
 855         } else {
 856             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
 857         }
 858     }
 859     elsif (@valgrind) {
 860         my $leaks = 0;
 861         my $errors = 0;
 862         for my $i (0..$#valgrind) {
 863             local $_ = $valgrind[$i];
 864             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 865                 $errors = $errors + $1;   # there may be multiple error summaries
 866             } elsif (/^==\d+== LEAK SUMMARY:/) {
 867                 for my $off (1 .. 4) {
 868                     if ($valgrind[$i+$off] =~
 869                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 870                             $leaks = $leaks + $1;
 871                     }
 872                 }
 873             }
 874         }
 875         if ($errors or $leaks) {
 876             if (rename $Valgrind_Log, "$$test.valgrind") {
 877                 $$grind_ct = $$grind_ct + 1;
 878             } else {
 879                 warn "$0: Failed to create '$$test.valgrind': $!\n";
 880             }
 881         }
 882     } else {
 883         # Quiet wasn't asked for? Something may be amiss
 884         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
 885             warn "No valgrind output?\n";
 886         }
 887     }
 888     if (-e $Valgrind_Log) {
 889         unlink $Valgrind_Log
 890             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 891     }
 892 }
 893
 894 sub _cleanup_valgrind {
 895     return unless $ENV{PERL_VALGRIND};
 896
 897     my ($toolnm, $grind_ct) = @_;
 898     my $s = $$grind_ct == 1 ? '' : 's';
 899     print "$$grind_ct valgrind report$s created.\n", ;
 900     if ($$toolnm eq 'cachegrind') {
 901         # cachegrind leaves a lot of cachegrind.out.$pid litter
 902         # around the tree, find and delete them
 903         unlink _find_files('cachegrind.out.\d+$',
 904                      qw ( ../t ../cpan ../ext ../dist/ ));
 905     }
 906 }
 907
 908 # ex: set ts=8 sts=4 sw=4 noet: