lib/lib.pm

   1 package lib;
   2
   3 use 5.005_64;
   4 use Config;
   5
   6 my $archname = defined($Config{'archname'}) ? $Config{'archname'} : '';
   7 my $ver = defined($Config{'version'}) ? $Config{'version'} : '';
   8 my @inc_version_list = defined($Config{'inc_version_list'}) ?
   9    reverse split / /, $Config{'inc_version_list'} : ();
  10
  11 our @ORIG_INC = @INC;   # take a handy copy of 'original' value
  12 our $VERSION = '0.5564';
  13
  14 sub import {
  15     shift;
  16
  17     my %names;
  18     foreach (reverse @_) {
  19         if ($_ eq '') {
  20             require Carp;
  21             Carp::carp("Empty compile time value given to use lib");
  22         }
  23         if (-e && ! -d _) {
  24             require Carp;
  25             Carp::carp("Parameter to use lib must be directory, not file");
  26         }
  27         unshift(@INC, $_);
  28         # Add any previous version directories we found at configure time
  29         foreach my $incver (@inc_version_list)
  30         {
  31             unshift(@INC, "$_/$incver") if -d "$_/$incver";
  32         }
  33         # Put a corresponding archlib directory infront of $_ if it
  34         # looks like $_ has an archlib directory below it.
  35         unshift(@INC, "$_/$ver") if -d "$_/$ver";
  36         unshift(@INC, "$_/$ver/$archname") if -d "$_/$ver/$archname";
  37     }
  38
  39     # remove trailing duplicates
  40     @INC = grep { ++$names{$_} == 1 } @INC;
  41     return;
  42 }
  43
  44
  45 sub unimport {
  46     shift;
  47
  48     my %names;
  49     foreach (@_) {
  50         ++$names{$_};
  51         ++$names{"$_/$archname"} if -d "$_/$archname/auto";
  52     }
  53
  54     # Remove ALL instances of each named directory.
  55     @INC = grep { !exists $names{$_} } @INC;
  56     return;
  57 }
  58
  59 1;
  60 __END__
  61
  62 =head1 NAME
  63
  64 lib - manipulate @INC at compile time
  65
  66 =head1 SYNOPSIS
  67
  68     use lib LIST;
  69
  70     no lib LIST;
  71
  72 =head1 DESCRIPTION
  73
  74 This is a small simple module which simplifies the manipulation of @INC
  75 at compile time.
  76
  77 It is typically used to add extra directories to perl's search path so
  78 that later C<use> or C<require> statements will find modules which are
  79 not located on perl's default search path.
  80
  81 =head2 Adding directories to @INC
  82
  83 The parameters to C<use lib> are added to the start of the perl search
  84 path. Saying
  85
  86     use lib LIST;
  87
  88 is I<almost> the same as saying
  89
  90     BEGIN { unshift(@INC, LIST) }
  91
  92 For each directory in LIST (called $dir here) the lib module also
  93 checks to see if a directory called $dir/$archname/auto exists.
  94 If so the $dir/$archname directory is assumed to be a corresponding
  95 architecture specific directory and is added to @INC in front of $dir.
  96
  97 To avoid memory leaks, all trailing duplicate entries in @INC are
  98 removed.
  99
 100 =head2 Deleting directories from @INC
 101
 102 You should normally only add directories to @INC.  If you need to
 103 delete directories from @INC take care to only delete those which you
 104 added yourself or which you are certain are not needed by other modules
 105 in your script.  Other modules may have added directories which they
 106 need for correct operation.
 107
 108 The C<no lib> statement deletes all instances of each named directory
 109 from @INC.
 110
 111 For each directory in LIST (called $dir here) the lib module also
 112 checks to see if a directory called $dir/$archname/auto exists.
 113 If so the $dir/$archname directory is assumed to be a corresponding
 114 architecture specific directory and is also deleted from @INC.
 115
 116 =head2 Restoring original @INC
 117
 118 When the lib module is first loaded it records the current value of @INC
 119 in an array C<@lib::ORIG_INC>. To restore @INC to that value you
 120 can say
 121
 122     @INC = @lib::ORIG_INC;
 123
 124
 125 =head1 SEE ALSO
 126
 127 FindBin - optional module which deals with paths relative to the source file.
 128
 129 =head1 AUTHOR
 130
 131 Tim Bunce, 2nd June 1995.
 132
 133 =cut