lib/Term/Cap.t

   1 #!./perl
   2
   3 my $file;
   4
   5 BEGIN {
   6         $file = $0;
   7         chdir 't' if -d 't';
   8
   9         if ( $ENV{PERL_CORE} ) {
  10            @INC = '../lib';
  11         }
  12 }
  13
  14 END {
  15         # let VMS whack all versions
  16         1 while unlink('tcout');
  17 }
  18
  19 use Test::More;
  20
  21 # these names are hardcoded in Term::Cap
  22 my $files = join '',
  23     grep { -f $_ }
  24         ( $ENV{HOME} . '/.termcap', # we assume pretty UNIXy system anyway
  25           '/etc/termcap',
  26           '/usr/share/misc/termcap' );
  27 unless( $files || $^O eq 'VMS') {
  28     plan skip_all => 'no termcap available to test';
  29 }
  30 else {
  31     plan tests => 44;
  32 }
  33
  34 use_ok( 'Term::Cap' );
  35
  36 local (*TCOUT, *OUT);
  37 my $out = tie *OUT, 'TieOut';
  38 my $writable = 1;
  39
  40 if (open(TCOUT, ">tcout")) {
  41         print TCOUT <DATA>;
  42         close TCOUT;
  43 } else {
  44         $writable = 0;
  45 }
  46
  47 # termcap_path -- the names are hardcoded in Term::Cap
  48 $ENV{TERMCAP} = '';
  49 my $path = join '', Term::Cap::termcap_path();
  50 is( $path, $files, 'termcap_path() should find default files' );
  51
  52 SKIP: {
  53         # this is ugly, but -f $0 really *ought* to work
  54         skip("-f $file fails, some tests difficult now", 2) unless -f $file;
  55
  56         $ENV{TERMCAP} = $ENV{TERMPATH} = $file;
  57         ok( grep($file, Term::Cap::termcap_path()),
  58                 'termcap_path() should find file from $ENV{TERMCAP}' );
  59
  60         $ENV{TERMCAP} = '/';
  61         ok( grep($file, Term::Cap::termcap_path()),
  62                 'termcap_path() should find file from $ENV{TERMPATH}' );
  63 }
  64
  65 # make a Term::Cap "object"
  66 my $t = {
  67         PADDING => 1,
  68         _pc => 'pc',
  69 };
  70 bless($t, 'Term::Cap' );
  71
  72 # see if Tpad() works
  73 is( $t->Tpad(), undef, 'Tpad() should return undef with no arguments' );
  74 is( $t->Tpad('x'), 'x', 'Tpad() should return strings verbatim with no match' );
  75 is( $t->Tpad( '1*a', 2 ), 'apcpc', 'Tpad() should pad paddable strings' );
  76
  77 $t->{PADDING} = 2;
  78 is( $t->Tpad( '1*a', 3, *OUT ), 'apcpc', 'Tpad() should perform pad math' );
  79 is( $out->read(), 'apcpc', 'Tpad() should write to filehandle when passed' );
  80
  81 is( $t->Tputs('PADDING'), 2, 'Tputs() should return existing value' );
  82 is( $t->Tputs('pc', 2), 'pc', 'Tputs() should delegate to Tpad()' );
  83 $t->Tputs('pc', 1, *OUT);
  84 is( $t->{pc}, 'pc', 'Tputs() should cache pc value when asked' );
  85 is( $out->read(), 'pc', 'Tputs() should write to filehandle when passed' );
  86
  87 eval { $t->Trequire( 'pc' ) };
  88 is( $@, '', 'Trequire() should finds existing cap' );
  89 eval { $t->Trequire( 'nonsense' ) };
  90 like( $@, qr/support: \(nonsense\)/,
  91         'Trequire() should croak with unsupported cap' );
  92
  93 my $warn;
  94 local $SIG{__WARN__} = sub {
  95         $warn = $_[0];
  96 };
  97
  98 # test the first few features by forcing Tgetent() to croak (line 156)
  99 undef $ENV{TERM};
 100 my $vals = {};
 101 eval { local $^W = 1; $t = Term::Cap->Tgetent($vals) };
 102 like( $@, qr/TERM not set/, 'Tgetent() should croaks without TERM' );
 103 like( $warn, qr/OSPEED was not set/, 'Tgetent() should set default OSPEED' );
 104
 105 is( $vals->{PADDING}, 10000/9600, 'Default OSPEED implies default PADDING' );
 106
 107 $warn = 'xxxx';
 108 eval { local $^W = 0; $t = Term::Cap->Tgetent($vals) };
 109 is($warn,'xxxx',"Tgetent() doesn't carp() without warnings on");
 110
 111 # check values for very slow speeds
 112 $vals->{OSPEED} = 1;
 113 $warn = '';
 114 eval { $t = Term::Cap->Tgetent($vals) };
 115 is( $warn, '', 'Tgetent() should not work if OSPEED is provided' );
 116 is( $vals->{PADDING}, 200, 'Tgetent() should set slow PADDING when needed' );
 117
 118
 119 SKIP: {
 120         skip('Tgetent() bad termcap test, since using a fixed termcap',1)
 121               if $^O eq 'VMS';
 122         # now see if lines 177 or 180 will fail
 123         $ENV{TERM} = 'foo';
 124         $ENV{TERMPATH} = '!';
 125         $ENV{TERMCAP} = '';
 126         eval { $t = Term::Cap->Tgetent($vals) };
 127         isn't( $@, '', 'Tgetent() should catch bad termcap file' );
 128 }
 129
 130 SKIP: {
 131         skip( "Can't write 'tcout' file for tests", 9 ) unless $writable;
 132
 133         # it won't find the termtype in this fake file, so it should croak
 134         $vals->{TERM} = 'quux';
 135         $ENV{TERMPATH} = 'tcout';
 136         eval { $t = Term::Cap->Tgetent($vals) };
 137         like( $@, qr/failed termcap/, 'Tgetent() should die with bad termcap' );
 138
 139         # it shouldn't try to read one file more than 32(!) times
 140         # see __END__ for a really awful termcap example
 141         $ENV{TERMPATH} = join(' ', ('tcout') x 33);
 142         $vals->{TERM} = 'bar';
 143         eval { $t = Term::Cap->Tgetent($vals) };
 144         like( $@, qr/failed termcap loop/, 'Tgetent() should catch deep recursion');
 145
 146         # now let it read a fake termcap file, and see if it sets properties
 147         $ENV{TERMPATH} = 'tcout';
 148         $vals->{TERM} = 'baz';
 149         $t = Term::Cap->Tgetent($vals);
 150         is( $t->{_f1}, 1, 'Tgetent() should set a single field correctly' );
 151         is( $t->{_f2}, 1, 'Tgetent() should set another field on the same line' );
 152         is( $t->{_no}, '', 'Tgetent() should set a blank field correctly' );
 153         is( $t->{_k1}, 'v1', 'Tgetent() should set a key value pair correctly' );
 154         like( $t->{_k2}, qr/v2\\\n2/, 'Tgetent() should set and translate pairs' );
 155
 156         # and it should have set these two fields
 157         is( $t->{_pc}, "\0", 'should set _pc field correctly' );
 158         is( $t->{_bc}, "\b", 'should set _bc field correctly' );
 159 }
 160
 161 # Tgoto has comments on the expected formats
 162 $t->{_test} = "a%d";
 163 is( $t->Tgoto('test', '', 1, *OUT), 'a1', 'Tgoto() should handle %d code' );
 164 is( $out->read(), 'a1', 'Tgoto() should print to filehandle if passed' );
 165
 166 $t->{_test} = "a%.";
 167 like( $t->Tgoto('test', '', 1), qr/^a\x01/, 'Tgoto() should handle %.' );
 168 like( $t->Tgoto('test', '', 0), qr/\x61\x01\x08/,
 169         'Tgoto() should handle %. and magic' );
 170
 171 $t->{_test} = 'a%+';
 172 like( $t->Tgoto('test', '', 1), qr/a\x01/, 'Tgoto() should handle %+' );
 173 $t->{_test} = 'a%+a';
 174 is( $t->Tgoto('test', '', 1), 'ab', 'Tgoto() should handle %+char' );
 175 $t->{_test} .= 'a' x 99;
 176 like( $t->Tgoto('test', '', 1), qr/ba{98}/,
 177         'Tgoto() should substr()s %+ if needed' );
 178
 179 $t->{_test} = '%ra%d';
 180 is( $t->Tgoto('test', 1, ''), 'a1', 'Tgoto() should swaps params with %r' );
 181
 182 $t->{_test} = 'a%>11bc';
 183 is( $t->Tgoto('test', '', 1), 'abc', 'Tgoto() should unpack args with %>' );
 184
 185 $t->{_test} = 'a%21';
 186 is( $t->Tgoto('test'), 'a001', 'Tgoto() should format with %2' );
 187
 188 $t->{_test} = 'a%31';
 189 is( $t->Tgoto('test'), 'a0001', 'Tgoto() should also formats with %3' );
 190
 191 $t->{_test} = '%ia%21';
 192 is( $t->Tgoto('test', '', 1), 'a021', 'Tgoto() should increment args with %i' );
 193
 194 $t->{_test} = '%z';
 195 is( $t->Tgoto('test'), 'OOPS', 'Tgoto() should catch invalid args' );
 196
 197 # and this is pretty standard
 198 package TieOut;
 199
 200 sub TIEHANDLE {
 201         bless( \(my $self), $_[0] );
 202 }
 203
 204 sub PRINT {
 205         my $self = shift;
 206         $$self .= join('', @_);
 207 }
 208
 209 sub read {
 210         my $self = shift;
 211         substr( $$self, 0, length($$self), '' );
 212 }
 213
 214 __END__
 215 bar: :tc=bar: \
 216 baz: \
 217 :f1: :f2: \
 218 :no@ \
 219 :k1#v1\
 220 :k2=v2\\n2