utils/h2ph.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(basename dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13 # Wanted:  $archlibexp
  14
  15 # This forces PL files to create target in same directory as PL file.
  16 # This is so that make depend always knows where to find PL derivatives.
  17 $origdir = cwd;
  18 chdir dirname($0);
  19 $file = basename($0, '.PL');
  20 $file .= '.com' if $^O eq 'VMS';
  21
  22 open OUT,">$file" or die "Can't create $file: $!";
  23
  24 print "Extracting $file (with variable substitutions)\n";
  25
  26 # In this section, perl variables will be expanded during extraction.
  27 # You can use $Config{...} to use Configure variables.
  28
  29 print OUT <<"!GROK!THIS!";
  30 $Config{startperl}
  31     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  32         if \$running_under_some_shell;
  33 !GROK!THIS!
  34
  35 # In the following, perl variables are not expanded during extraction.
  36
  37 print OUT <<'!NO!SUBS!';
  38
  39 use strict;
  40
  41 use Config;
  42 use File::Path qw(mkpath);
  43 use Getopt::Std;
  44
  45 # Make sure read permissions for all are set:
  46 if (defined umask && (umask() & 0444)) {
  47     umask (umask() & ~0444);
  48 }
  49
  50 getopts('Dd:rlhaQe');
  51 use vars qw($opt_D $opt_d $opt_r $opt_l $opt_h $opt_a $opt_Q $opt_e);
  52 die "-r and -a options are mutually exclusive\n" if ($opt_r and $opt_a);
  53 my @inc_dirs = inc_dirs() if $opt_a;
  54
  55 my $Exit = 0;
  56
  57 my $Dest_dir = $opt_d || $Config{installsitearch};
  58 die "Destination directory $Dest_dir doesn't exist or isn't a directory\n"
  59     unless -d $Dest_dir;
  60
  61 my @isatype = qw(
  62         char    uchar   u_char
  63         short   ushort  u_short
  64         int     uint    u_int
  65         long    ulong   u_long
  66         FILE    key_t   caddr_t
  67         float   double  size_t
  68 );
  69
  70 my %isatype;
  71 @isatype{@isatype} = (1) x @isatype;
  72 my $inif = 0;
  73 my %Is_converted;
  74 my %bad_file = ();
  75
  76 @ARGV = ('-') unless @ARGV;
  77
  78 build_preamble_if_necessary();
  79
  80 sub reindent($) {
  81     my($text) = shift;
  82     $text =~ s/\n/\n    /g;
  83     $text =~ s/        /\t/g;
  84     $text;
  85 }
  86
  87 my ($t, $tab, %curargs, $new, $eval_index, $dir, $name, $args, $outfile);
  88 my ($incl, $incl_type, $incl_quote, $next);
  89 while (defined (my $file = next_file())) {
  90     if (-l $file and -d $file) {
  91         link_if_possible($file) if ($opt_l);
  92         next;
  93     }
  94
  95     # Recover from header files with unbalanced cpp directives
  96     $t = '';
  97     $tab = 0;
  98
  99     # $eval_index goes into ``#line'' directives, to help locate syntax errors:
 100     $eval_index = 1;
 101
 102     if ($file eq '-') {
 103         open(IN, "-");
 104         open(OUT, ">-");
 105     } else {
 106         ($outfile = $file) =~ s/\.h$/.ph/ || next;
 107         print "$file -> $outfile\n" unless $opt_Q;
 108         if ($file =~ m|^(.*)/|) {
 109             $dir = $1;
 110             mkpath "$Dest_dir/$dir";
 111         }
 112
 113         if ($opt_a) { # automagic mode:  locate header file in @inc_dirs
 114             foreach (@inc_dirs) {
 115                 chdir $_;
 116                 last if -f $file;
 117             }
 118         }
 119
 120         open(IN,"$file") || (($Exit = 1),(warn "Can't open $file: $!\n"),next);
 121         open(OUT,">$Dest_dir/$outfile") || die "Can't create $outfile: $!\n";
 122     }
 123
 124     print OUT
 125         "require '_h2ph_pre.ph';\n\n",
 126         "no warnings qw(redefine misc);\n\n";
 127
 128     while (defined (local $_ = next_line($file))) {
 129         if (s/^\s*\#\s*//) {
 130             if (s/^define\s+(\w+)//) {
 131                 $name = $1;
 132                 $new = '';
 133                 s/\s+$//;
 134                 s/\(\w+\s*\(\*\)\s*\(\w*\)\)\s*(-?\d+)/$1/; # (int (*)(foo_t))0
 135                 if (s/^\(([\w,\s]*)\)//) {
 136                     $args = $1;
 137                     my $proto = '() ';
 138                     if ($args ne '') {
 139                         $proto = '';
 140                         foreach my $arg (split(/,\s*/,$args)) {
 141                             $arg =~ s/^\s*([^\s].*[^\s])\s*$/$1/;
 142                             $curargs{$arg} = 1;
 143                         }
 144                         $args =~ s/\b(\w)/\$$1/g;
 145                         $args = "my($args) = \@_;\n$t    ";
 146                     }
 147                     s/^\s+//;
 148                     expr();
 149                     $new =~ s/(["\\])/\\$1/g;       #"]);
 150                     EMIT($proto);
 151                 } else {
 152                     s/^\s+//;
 153                     expr();
 154                     $new = 1 if $new eq '';
 155                     $new = reindent($new);
 156                     $args = reindent($args);
 157                     if ($t ne '') {
 158                         $new =~ s/(['\\])/\\$1/g;        #']);
 159
 160                         if ($opt_h) {
 161                             print OUT $t,"eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 162                             $eval_index++;
 163                         } else {
 164                             print OUT $t,"eval 'sub $name () {",$new,";}' unless defined(\&$name);\n";
 165                         }
 166                     } else {
 167                         # Shunt around such directives as `#define FOO FOO':
 168                         next if " \&$name" eq $new;
 169
 170                       print OUT $t,"unless(defined(\&$name)) {\n    sub $name () {\t",$new,";}\n}\n";
 171                     }
 172                 }
 173             } elsif (/^(include|import|include_next)\s*([<\"])(.*)[>\"]/) {
 174                 $incl_type = $1;
 175                 $incl_quote = $2;
 176                 $incl = $3;
 177                 if (($incl_type eq 'include_next') ||
 178                     ($opt_e && exists($bad_file{$incl}))) {
 179                     $incl =~ s/\.h$/.ph/;
 180                 print OUT ($t,
 181                            "eval {\n");
 182                 $tab += 4;
 183                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 184                     print OUT ($t, "my(\@REM);\n");
 185                     if ($incl_type eq 'include_next') {
 186                 print OUT ($t,
 187                            "my(\%INCD) = map { \$INC{\$_} => 1 } ",
 188                                    "(grep { \$_ eq \"$incl\" } ",
 189                                    "keys(\%INC));\n");
 190                 print OUT ($t,
 191                                    "\@REM = map { \"\$_/$incl\" } ",
 192                            "(grep { not exists(\$INCD{\"\$_/$incl\"})",
 193                                    " and -f \"\$_/$incl\" } \@INC);\n");
 194                     } else {
 195                         print OUT ($t,
 196                                    "\@REM = map { \"\$_/$incl\" } ",
 197                                    "(grep {-r \"\$_/$incl\" } \@INC);\n");
 198                     }
 199                 print OUT ($t,
 200                            "require \"\$REM[0]\" if \@REM;\n");
 201                 $tab -= 4;
 202                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 203                 print OUT ($t,
 204                            "};\n");
 205                 print OUT ($t,
 206                            "warn(\$\@) if \$\@;\n");
 207                 } else {
 208                     $incl =~ s/\.h$/.ph/;
 209                     # copy the prefix in the quote syntax (#include "x.h") case
 210                     if ($incl !~ m|/| && $incl_quote eq q{"} && $file =~ m|^(.*)/|) {
 211                         $incl = "$1/$incl";
 212                     }
 213                     print OUT $t,"require '$incl';\n";
 214                 }
 215             } elsif (/^ifdef\s+(\w+)/) {
 216                 print OUT $t,"if(defined(&$1)) {\n";
 217                 $tab += 4;
 218                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 219             } elsif (/^ifndef\s+(\w+)/) {
 220                 print OUT $t,"unless(defined(&$1)) {\n";
 221                 $tab += 4;
 222                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 223             } elsif (s/^if\s+//) {
 224                 $new = '';
 225                 $inif = 1;
 226                 expr();
 227                 $inif = 0;
 228                 print OUT $t,"if($new) {\n";
 229                 $tab += 4;
 230                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 231             } elsif (s/^elif\s+//) {
 232                 $new = '';
 233                 $inif = 1;
 234                 expr();
 235                 $inif = 0;
 236                 $tab -= 4;
 237                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 238                 print OUT $t,"}\n elsif($new) {\n";
 239                 $tab += 4;
 240                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 241             } elsif (/^else/) {
 242                 $tab -= 4;
 243                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 244                 print OUT $t,"} else {\n";
 245                 $tab += 4;
 246                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 247             } elsif (/^endif/) {
 248                 $tab -= 4;
 249                 $t = "\t" x ($tab / 8) . ' ' x ($tab % 8);
 250                 print OUT $t,"}\n";
 251             } elsif(/^undef\s+(\w+)/) {
 252                 print OUT $t, "undef(&$1) if defined(&$1);\n";
 253             } elsif(/^error\s+(".*")/) {
 254                 print OUT $t, "die($1);\n";
 255             } elsif(/^error\s+(.*)/) {
 256                 print OUT $t, "die(\"", quotemeta($1), "\");\n";
 257             } elsif(/^warning\s+(.*)/) {
 258                 print OUT $t, "warn(\"", quotemeta($1), "\");\n";
 259             } elsif(/^ident\s+(.*)/) {
 260                 print OUT $t, "# $1\n";
 261             }
 262         } elsif (/^\s*(typedef\s*)?enum\s*(\s+[a-zA-Z_]\w*\s*)?/) { # { for vi
 263             until(/\{[^}]*\}.*;/ || /;/) {
 264                 last unless defined ($next = next_line($file));
 265                 chomp $next;
 266                 # drop "#define FOO FOO" in enums
 267                 $next =~ s/^\s*#\s*define\s+(\w+)\s+\1\s*$//;
 268                 # #defines in enums (aliases)
 269                 $next =~ s/^\s*#\s*define\s+(\w+)\s+(\w+)\s*$/$1 = $2,/;
 270                 $_ .= $next;
 271                 print OUT "# $next\n" if $opt_D;
 272             }
 273             s/#\s*if.*?#\s*endif//g; # drop #ifdefs
 274             s@/\*.*?\*/@@g;
 275             s/\s+/ /g;
 276             next unless /^\s?(typedef\s?)?enum\s?([a-zA-Z_]\w*)?\s?\{(.*)\}\s?([a-zA-Z_]\w*)?\s?;/;
 277             (my $enum_subs = $3) =~ s/\s//g;
 278             my @enum_subs = split(/,/, $enum_subs);
 279             my $enum_val = -1;
 280             foreach my $enum (@enum_subs) {
 281                 my ($enum_name, $enum_value) = $enum =~ /^([a-zA-Z_]\w*)(=.+)?$/;
 282                 $enum_name or next;
 283                 $enum_value =~ s/^=//;
 284                 $enum_val = (length($enum_value) ? $enum_value : $enum_val + 1);
 285                 if ($opt_h) {
 286                     print OUT ($t,
 287                                "eval(\"\\n#line $eval_index $outfile\\n",
 288                                "sub $enum_name () \{ $enum_val; \}\") ",
 289                                "unless defined(\&$enum_name);\n");
 290                     ++ $eval_index;
 291                 } else {
 292                     print OUT ($t,
 293                                "eval(\"sub $enum_name () \{ $enum_val; \}\") ",
 294                                "unless defined(\&$enum_name);\n");
 295                 }
 296             }
 297         } elsif (/^(?:__extension__\s+)?(?:extern|static)\s+(?:__)?inline(?:__)?\s+/
 298             and !/;\s*$/ and !/{\s*}\s*$/)
 299         { # { for vi
 300             # This is a hack to parse the inline functions in the glibc headers.
 301             # Warning: massive kludge ahead. We suppose inline functions
 302             # are mainly constructed like macros.
 303             while (1) {
 304                 last unless defined ($next = next_line($file));
 305                 chomp $next;
 306                 undef $_, last if $next =~ /__THROW\s*;/
 307                                or $next =~ /^(__extension__|extern|static)\b/;
 308                 $_ .= " $next";
 309                 print OUT "# $next\n" if $opt_D;
 310                 last if $next =~ /^}|^{.*}\s*$/;
 311             }
 312             next if not defined; # because it's only a prototype
 313             s/\b(__extension__|extern|static|(?:__)?inline(?:__)?)\b//g;
 314             # violently drop #ifdefs
 315             s/#\s*if.*?#\s*endif//g
 316                 and print OUT "# some #ifdef were dropped here -- fill in the blanks\n";
 317             if (s/^(?:\w|\s|\*)*\s(\w+)\s*//) {
 318                 $name = $1;
 319             } else {
 320                 warn "name not found"; next; # shouldn't occur...
 321             }
 322             my @args;
 323             if (s/^\(([^()]*)\)\s*(\w+\s*)*//) {
 324                 for my $arg (split /,/, $1) {
 325                     if ($arg =~ /(\w+)\s*$/) {
 326                         $curargs{$1} = 1;
 327                         push @args, $1;
 328                     }
 329                 }
 330             }
 331             $args = (
 332                 @args
 333                 ? "my(" . (join ',', map "\$$_", @args) . ") = \@_;\n$t    "
 334                 : ""
 335             );
 336             my $proto = @args ? '' : '() ';
 337             $new = '';
 338             s/\breturn\b//g; # "return" doesn't occur in macros usually...
 339             expr();
 340             # try to find and perlify local C variables
 341             our @local_variables = (); # needs to be a our(): (?{...}) bug workaround
 342             {
 343                 use re "eval";
 344                 my $typelist = join '|', keys %isatype;
 345                 $new =~ s['
 346                   (?:(?:__)?const(?:__)?\s+)?
 347                   (?:(?:un)?signed\s+)?
 348                   (?:long\s+)?
 349                   (?:$typelist)\s+
 350                   (\w+)
 351                   (?{ push @local_variables, $1 })
 352                   ']
 353                  [my \$$1]gx;
 354                 $new =~ s['
 355                   (?:(?:__)?const(?:__)?\s+)?
 356                   (?:(?:un)?signed\s+)?
 357                   (?:long\s+)?
 358                   (?:$typelist)\s+
 359                   ' \s+ &(\w+) \s* ;
 360                   (?{ push @local_variables, $1 })
 361                   ]
 362                  [my \$$1;]gx;
 363              }
 364             $new =~ s/&$_\b/\$$_/g for @local_variables;
 365             $new =~ s/(["\\])/\\$1/g;       #"]);
 366             # now that's almost like a macro (we hope)
 367             EMIT($proto);
 368         }
 369     }
 370     $Is_converted{$file} = 1;
 371     if ($opt_e && exists($bad_file{$file})) {
 372         unlink($Dest_dir . '/' . $outfile);
 373         $next = '';
 374     } else {
 375         print OUT "1;\n";
 376         queue_includes_from($file) if $opt_a;
 377     }
 378 }
 379
 380 if ($opt_e && (scalar(keys %bad_file) > 0)) {
 381     warn "Was unable to convert the following files:\n";
 382     warn "\t" . join("\n\t",sort(keys %bad_file)) . "\n";
 383 }
 384
 385 exit $Exit;
 386
 387 sub EMIT {
 388     my $proto = shift;
 389
 390     $new = reindent($new);
 391     $args = reindent($args);
 392     if ($t ne '') {
 393     $new =~ s/(['\\])/\\$1/g;   #']);
 394     if ($opt_h) {
 395         print OUT $t,
 396                     "eval \"\\n#line $eval_index $outfile\\n\" . 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 397                     $eval_index++;
 398     } else {
 399         print OUT $t,
 400                     "eval 'sub $name $proto\{\n$t    ${args}eval q($new);\n$t}' unless defined(\&$name);\n";
 401     }
 402     } else {
 403               print OUT "unless(defined(\&$name)) {\n    sub $name $proto\{\n\t${args}eval q($new);\n    }\n}\n";
 404     }
 405     %curargs = ();
 406     return;
 407 }
 408
 409 sub expr {
 410     if (/\b__asm__\b/) {        # freak out
 411         $new = '"(assembly code)"';
 412         return
 413     }
 414     my $joined_args;
 415     if(keys(%curargs)) {
 416         $joined_args = join('|', keys(%curargs));
 417     }
 418     while ($_ ne '') {
 419         s/^\&\&// && do { $new .= " &&"; next;}; # handle && operator
 420         s/^\&([\(a-z\)]+)/$1/i; # hack for things that take the address of
 421         s/^(\s+)//              && do {$new .= ' '; next;};
 422         s/^0X([0-9A-F]+)[UL]*//i
 423             && do {my $hex = $1;
 424                    $hex =~ s/^0+//;
 425                    if (length $hex > 8 && !$Config{use64bitint}) {
 426                        # Croak if nv_preserves_uv_bits < 64 ?
 427                        $new .=         hex(substr($hex, -8)) +
 428                                2**32 * hex(substr($hex,  0, -8));
 429                        # The above will produce "erroneous" code
 430                        # if the hex constant was e.g. inside UINT64_C
 431                        # macro, but then again, h2ph is an approximation.
 432                    } else {
 433                        $new .= lc("0x$hex");
 434                    }
 435                    next;};
 436         s/^(-?\d+\.\d+E[-+]?\d+)[FL]?//i        && do {$new .= $1; next;};
 437         s/^(\d+)\s*[LU]*//i     && do {$new .= $1; next;};
 438         s/^("(\\"|[^"])*")//    && do {$new .= $1; next;};
 439         s/^'((\\"|[^"])*)'//    && do {
 440             if ($curargs{$1}) {
 441                 $new .= "ord('\$$1')";
 442             } else {
 443                 $new .= "ord('$1')";
 444             }
 445             next;
 446         };
 447         # replace "sizeof(foo)" with "{foo}"
 448         # also, remove * (C dereference operator) to avoid perl syntax
 449         # problems.  Where the %sizeof array comes from is anyone's
 450         # guess (c2ph?), but this at least avoids fatal syntax errors.
 451         # Behavior is undefined if sizeof() delimiters are unbalanced.
 452         # This code was modified to able to handle constructs like this:
 453         #   sizeof(*(p)), which appear in the HP-UX 10.01 header files.
 454         s/^sizeof\s*\(// && do {
 455             $new .= '$sizeof';
 456             my $lvl = 1;  # already saw one open paren
 457             # tack { on the front, and skip it in the loop
 458             $_ = "{" . "$_";
 459             my $index = 1;
 460             # find balanced closing paren
 461             while ($index <= length($_) && $lvl > 0) {
 462                 $lvl++ if substr($_, $index, 1) eq "(";
 463                 $lvl-- if substr($_, $index, 1) eq ")";
 464                 $index++;
 465             }
 466             # tack } on the end, replacing )
 467             substr($_, $index - 1, 1) = "}";
 468             # remove pesky * operators within the sizeof argument
 469             substr($_, 0, $index - 1) =~ s/\*//g;
 470             next;
 471         };
 472         # Eliminate typedefs
 473         /\(([\w\s]+)[\*\s]*\)\s*[\w\(]/ && do {
 474             my $doit = 1;
 475             foreach (split /\s+/, $1) {  # Make sure all the words are types,
 476                 unless($isatype{$_} or $_ eq 'struct' or $_ eq 'union'){
 477                     $doit = 0;
 478                     last;
 479                 }
 480             }
 481             if( $doit ){
 482                 s/\([\w\s]+[\*\s]*\)// && next;      # then eliminate them.
 483             }
 484         };
 485         # struct/union member, including arrays:
 486         s/^([_A-Z]\w*(\[[^\]]+\])?((\.|->)[_A-Z]\w*(\[[^\]]+\])?)+)//i && do {
 487             my $id = $1;
 488             $id =~ s/(\.|(->))([^\.\-]*)/->\{$3\}/g;
 489             $id =~ s/\b([^\$])($joined_args)/$1\$$2/g if length($joined_args);
 490             while($id =~ /\[\s*([^\$\&\d\]]+)\]/) {
 491                 my($index) = $1;
 492                 $index =~ s/\s//g;
 493                 if(exists($curargs{$index})) {
 494                     $index = "\$$index";
 495                 } else {
 496                     $index = "&$index";
 497                 }
 498                 $id =~ s/\[\s*([^\$\&\d\]]+)\]/[$index]/;
 499             }
 500             $new .= " (\$$id)";
 501         };
 502         s/^([_a-zA-Z]\w*)//     && do {
 503             my $id = $1;
 504             if ($id eq 'struct' || $id eq 'union') {
 505                 s/^\s+(\w+)//;
 506                 $id .= ' ' . $1;
 507                 $isatype{$id} = 1;
 508             } elsif ($id =~ /^((un)?signed)|(long)|(short)$/) {
 509                 while (s/^\s+(\w+)//) { $id .= ' ' . $1; }
 510                 $isatype{$id} = 1;
 511             }
 512             if ($curargs{$id}) {
 513                 $new .= "\$$id";
 514                 $new .= '->' if /^[\[\{]/;
 515             } elsif ($id eq 'defined') {
 516                 $new .= 'defined';
 517             } elsif (/^\s*\(/) {
 518                 s/^\s*\((\w),/("$1",/ if $id =~ /^_IO[WR]*$/i;  # cheat
 519                 $new .= " &$id";
 520             } elsif ($isatype{$id}) {
 521                 if ($new =~ /\{\s*$/) {
 522                     $new .= "'$id'";
 523                 } elsif ($new =~ /\(\s*$/ && /^[\s*]*\)/) {
 524                     $new =~ s/\(\s*$//;
 525                     s/^[\s*]*\)//;
 526                 } else {
 527                     $new .= q(').$id.q(');
 528                 }
 529             } else {
 530                 if ($inif) {
 531                     if ($new =~ /defined\s*$/) {
 532                         $new .= '(&' . $id . ')';
 533                     } elsif ($new =~ /defined\s*\($/) {
 534                         $new .= '&' . $id;
 535                     } else {
 536                         $new .= '(defined(&' . $id . ') ? &' . $id . ' : undef)';
 537                     }
 538                 } elsif (/^\[/) {
 539                     $new .= " \$$id";
 540                 } else {
 541                     $new .= ' &' . $id;
 542                 }
 543             }
 544             next;
 545         };
 546         s/^(.)// && do { if ($1 ne '#') { $new .= $1; } next;};
 547     }
 548 }
 549
 550
 551 sub next_line
 552 {
 553     my $file = shift;
 554     my ($in, $out);
 555     my $pre_sub_tri_graphs = 1;
 556
 557     READ: while (not eof IN) {
 558         $in  .= <IN>;
 559         chomp $in;
 560         next unless length $in;
 561
 562         while (length $in) {
 563             if ($pre_sub_tri_graphs) {
 564                 # Preprocess all tri-graphs
 565                 # including things stuck in quoted string constants.
 566                 $in =~ s/\?\?=/#/g;                         # | ??=|  #|
 567                 $in =~ s/\?\?\!/|/g;                        # | ??!|  ||
 568                 $in =~ s/\?\?'/^/g;                         # | ??'|  ^|
 569                 $in =~ s/\?\?\(/[/g;                        # | ??(|  [|
 570                 $in =~ s/\?\?\)/]/g;                        # | ??)|  ]|
 571                 $in =~ s/\?\?\-/~/g;                        # | ??-|  ~|
 572                 $in =~ s/\?\?\//\\/g;                       # | ??/|  \|
 573                 $in =~ s/\?\?</{/g;                         # | ??<|  {|
 574                 $in =~ s/\?\?>/}/g;                         # | ??>|  }|
 575             }
 576             if ($in =~ /^\#ifdef __LANGUAGE_PASCAL__/) {
 577                 # Tru64 disassembler.h evilness: mixed C and Pascal.
 578                 while (<IN>) {
 579                     last if /^\#endif/;
 580                 }
 581                 $in = "";
 582                 next READ;
 583             }
 584             if ($in =~ /^extern inline / && # Inlined assembler.
 585                 $^O eq 'linux' && $file =~ m!(?:^|/)asm/[^/]+\.h$!) {
 586                 while (<IN>) {
 587                     last if /^}/;
 588                 }
 589                 $in = "";
 590                 next READ;
 591             }
 592             if ($in =~ s/\\$//) {                           # \-newline
 593                 $out    .= ' ';
 594                 next READ;
 595             } elsif ($in =~ s/^([^"'\\\/]+)//) {            # Passthrough
 596                 $out    .= $1;
 597             } elsif ($in =~ s/^(\\.)//) {                   # \...
 598                 $out    .= $1;
 599             } elsif ($in =~ /^'/) {                         # '...
 600                 if ($in =~ s/^('(\\.|[^'\\])*')//) {
 601                     $out    .= $1;
 602                 } else {
 603                     next READ;
 604                 }
 605             } elsif ($in =~ /^"/) {                         # "...
 606                 if ($in =~ s/^("(\\.|[^"\\])*")//) {
 607                     $out    .= $1;
 608                 } else {
 609                     next READ;
 610                 }
 611             } elsif ($in =~ s/^\/\/.*//) {                  # //...
 612                 # fall through
 613             } elsif ($in =~ m/^\/\*/) {                     # /*...
 614                 # C comment removal adapted from perlfaq6:
 615                 if ($in =~ s/^\/\*[^*]*\*+([^\/*][^*]*\*+)*\///) {
 616                     $out    .= ' ';
 617                 } else {                                    # Incomplete /* */
 618                     next READ;
 619                 }
 620             } elsif ($in =~ s/^(\/)//) {                    # /...
 621                 $out    .= $1;
 622             } elsif ($in =~ s/^([^\'\"\\\/]+)//) {
 623                 $out    .= $1;
 624             } elsif ($^O eq 'linux' &&
 625                      $file =~ m!(?:^|/)linux/byteorder/pdp_endian\.h$! &&
 626                      $in   =~ s!\'T KNOW!!) {
 627                 $out    =~ s!I DON$!I_DO_NOT_KNOW!;
 628             } else {
 629                 if ($opt_e) {
 630                     warn "Cannot parse $file:\n$in\n";
 631                     $bad_file{$file} = 1;
 632                     $in = '';
 633                     $out = undef;
 634                     last READ;
 635                 } else {
 636                 die "Cannot parse:\n$in\n";
 637                 }
 638             }
 639         }
 640
 641         last READ if $out =~ /\S/;
 642     }
 643
 644     return $out;
 645 }
 646
 647
 648 # Handle recursive subdirectories without getting a grotesquely big stack.
 649 # Could this be implemented using File::Find?
 650 sub next_file
 651 {
 652     my $file;
 653
 654     while (@ARGV) {
 655         $file = shift @ARGV;
 656
 657         if ($file eq '-' or -f $file or -l $file) {
 658             return $file;
 659         } elsif (-d $file) {
 660             if ($opt_r) {
 661                 expand_glob($file);
 662             } else {
 663                 print STDERR "Skipping directory `$file'\n";
 664             }
 665         } elsif ($opt_a) {
 666             return $file;
 667         } else {
 668             print STDERR "Skipping `$file':  not a file or directory\n";
 669         }
 670     }
 671
 672     return undef;
 673 }
 674
 675
 676 # Put all the files in $directory into @ARGV for processing.
 677 sub expand_glob
 678 {
 679     my ($directory)  = @_;
 680
 681     $directory =~ s:/$::;
 682
 683     opendir DIR, $directory;
 684         foreach (readdir DIR) {
 685             next if ($_ eq '.' or $_ eq '..');
 686
 687             # expand_glob() is going to be called until $ARGV[0] isn't a
 688             # directory; so push directories, and unshift everything else.
 689             if (-d "$directory/$_") { push    @ARGV, "$directory/$_" }
 690             else                    { unshift @ARGV, "$directory/$_" }
 691         }
 692     closedir DIR;
 693 }
 694
 695
 696 # Given $file, a symbolic link to a directory in the C include directory,
 697 # make an equivalent symbolic link in $Dest_dir, if we can figure out how.
 698 # Otherwise, just duplicate the file or directory.
 699 sub link_if_possible
 700 {
 701     my ($dirlink)  = @_;
 702     my $target  = eval 'readlink($dirlink)';
 703
 704     if ($target =~ m:^\.\./: or $target =~ m:^/:) {
 705         # The target of a parent or absolute link could leave the $Dest_dir
 706         # hierarchy, so let's put all of the contents of $dirlink (actually,
 707         # the contents of $target) into @ARGV; as a side effect down the
 708         # line, $dirlink will get created as an _actual_ directory.
 709         expand_glob($dirlink);
 710     } else {
 711         if (-l "$Dest_dir/$dirlink") {
 712             unlink "$Dest_dir/$dirlink" or
 713                 print STDERR "Could not remove link $Dest_dir/$dirlink:  $!\n";
 714         }
 715
 716         if (eval 'symlink($target, "$Dest_dir/$dirlink")') {
 717             print "Linking $target -> $Dest_dir/$dirlink\n";
 718
 719             # Make sure that the link _links_ to something:
 720             if (! -e "$Dest_dir/$target") {
 721                 mkpath("$Dest_dir/$target", 0755) or
 722                     print STDERR "Could not create $Dest_dir/$target/\n";
 723             }
 724         } else {
 725             print STDERR "Could not symlink $target -> $Dest_dir/$dirlink:  $!\n";
 726         }
 727     }
 728 }
 729
 730
 731 # Push all #included files in $file onto our stack, except for STDIN
 732 # and files we've already processed.
 733 sub queue_includes_from
 734 {
 735     my ($file)    = @_;
 736     my $line;
 737
 738     return if ($file eq "-");
 739
 740     open HEADER, $file or return;
 741         while (defined($line = <HEADER>)) {
 742             while (/\\$/) { # Handle continuation lines
 743                 chop $line;
 744                 $line .= <HEADER>;
 745             }
 746
 747             if ($line =~ /^#\s*include\s+([<"])(.*?)[>"]/) {
 748                 my ($delimiter, $new_file) = ($1, $2);
 749                 # copy the prefix in the quote syntax (#include "x.h") case
 750                 if ($delimiter eq q{"} && $file =~ m|^(.*)/|) {
 751                     $new_file = "$1/$new_file";
 752                 }
 753                 push(@ARGV, $new_file) unless $Is_converted{$new_file};
 754             }
 755         }
 756     close HEADER;
 757 }
 758
 759
 760 # Determine include directories; $Config{usrinc} should be enough for (all
 761 # non-GCC?) C compilers, but gcc uses additional include directories.
 762 sub inc_dirs
 763 {
 764     my $from_gcc   = `LC_ALL=C $Config{cc} -v -E - < /dev/null 2>&1 | awk '/^#include/, /^End of search list/' | grep '^ '`;
 765     length($from_gcc) ? (split(' ', $from_gcc), $Config{usrinc}) : ($Config{usrinc});
 766 }
 767
 768
 769 # Create "_h2ph_pre.ph", if it doesn't exist or was built by a different
 770 # version of h2ph.
 771 sub build_preamble_if_necessary
 772 {
 773     # Increment $VERSION every time this function is modified:
 774     my $VERSION     = 3;
 775     my $preamble    = "$Dest_dir/_h2ph_pre.ph";
 776
 777     # Can we skip building the preamble file?
 778     if (-r $preamble) {
 779         # Extract version number from first line of preamble:
 780         open  PREAMBLE, $preamble or die "Cannot open $preamble:  $!";
 781             my $line = <PREAMBLE>;
 782             $line =~ /(\b\d+\b)/;
 783         close PREAMBLE            or die "Cannot close $preamble:  $!";
 784
 785         # Don't build preamble if a compatible preamble exists:
 786         return if $1 == $VERSION;
 787     }
 788
 789     my (%define) = _extract_cc_defines();
 790
 791     open  PREAMBLE, ">$preamble" or die "Cannot open $preamble:  $!";
 792         print PREAMBLE "# This file was created by h2ph version $VERSION\n";
 793
 794         foreach (sort keys %define) {
 795             if ($opt_D) {
 796                 print PREAMBLE "# $_=$define{$_}\n";
 797             }
 798             if ($define{$_} =~ /^\((.*)\)$/) {
 799                 # parenthesized value:  d=(v)
 800                 $define{$_} = $1;
 801             }
 802             if (/^(\w+)\((\w)\)$/) {
 803                 my($macro, $arg) = ($1, $2);
 804                 my $def = $define{$_};
 805                 $def =~ s/$arg/\$\{$arg\}/g;
 806                 print PREAMBLE <<DEFINE;
 807 unless (defined &$macro) { sub $macro(\$) { my (\$$arg) = \@_; \"$def\" } }
 808
 809 DEFINE
 810             } elsif
 811                 ($define{$_} =~ /^([+-]?(\d+)?\.\d+([eE][+-]?\d+)?)[FL]?$/) {
 812                 # float:
 813                 print PREAMBLE
 814                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
 815             } elsif ($define{$_} =~ /^([+-]?\d+)U?L{0,2}$/i) {
 816                 # integer:
 817                 print PREAMBLE
 818                     "unless (defined &$_) { sub $_() { $1 } }\n\n";
 819             } elsif ($define{$_} =~ /^\w+$/) {
 820                 my $def = $define{$_};
 821                 if ($isatype{$def}) {
 822                   print PREAMBLE
 823                     "unless (defined &$_) { sub $_() { \"$def\" } }\n\n";
 824                 } else {
 825                   print PREAMBLE
 826                     "unless (defined &$_) { sub $_() { &$def } }\n\n";
 827                 }
 828             } else {
 829                 print PREAMBLE
 830                     "unless (defined &$_) { sub $_() { \"",
 831                     quotemeta($define{$_}), "\" } }\n\n";
 832             }
 833         }
 834         print PREAMBLE "\n1;\n";  # avoid 'did not return a true value' when empty
 835     close PREAMBLE               or die "Cannot close $preamble:  $!";
 836 }
 837
 838
 839 # %Config contains information on macros that are pre-defined by the
 840 # system's compiler.  We need this information to make the .ph files
 841 # function with perl as the .h files do with cc.
 842 sub _extract_cc_defines
 843 {
 844     my %define;
 845     my $allsymbols  = join " ",
 846         @Config{'ccsymbols', 'cppsymbols', 'cppccsymbols'};
 847
 848     # Split compiler pre-definitions into `key=value' pairs:
 849     while ($allsymbols =~ /([^\s]+)=((\\\s|[^\s])+)/g) {
 850         $define{$1} = $2;
 851         if ($opt_D) {
 852             print STDERR "$_:  $1 -> $2\n";
 853         }
 854     }
 855
 856     return %define;
 857 }
 858
 859
 860 1;
 861
 862 ##############################################################################
 863 __END__
 864
 865 =head1 NAME
 866
 867 h2ph - convert .h C header files to .ph Perl header files
 868
 869 =head1 SYNOPSIS
 870
 871 B<h2ph [-d destination directory] [-r | -a] [-l] [headerfiles]>
 872
 873 =head1 DESCRIPTION
 874
 875 I<h2ph>
 876 converts any C header files specified to the corresponding Perl header file
 877 format.
 878 It is most easily run while in /usr/include:
 879
 880         cd /usr/include; h2ph * sys/*
 881
 882 or
 883
 884         cd /usr/include; h2ph * sys/* arpa/* netinet/*
 885
 886 or
 887
 888         cd /usr/include; h2ph -r -l .
 889
 890 The output files are placed in the hierarchy rooted at Perl's
 891 architecture dependent library directory.  You can specify a different
 892 hierarchy with a B<-d> switch.
 893
 894 If run with no arguments, filters standard input to standard output.
 895
 896 =head1 OPTIONS
 897
 898 =over 4
 899
 900 =item -d destination_dir
 901
 902 Put the resulting B<.ph> files beneath B<destination_dir>, instead of
 903 beneath the default Perl library location (C<$Config{'installsitearch'}>).
 904
 905 =item -r
 906
 907 Run recursively; if any of B<headerfiles> are directories, then run I<h2ph>
 908 on all files in those directories (and their subdirectories, etc.).  B<-r>
 909 and B<-a> are mutually exclusive.
 910
 911 =item -a
 912
 913 Run automagically; convert B<headerfiles>, as well as any B<.h> files
 914 which they include.  This option will search for B<.h> files in all
 915 directories which your C compiler ordinarily uses.  B<-a> and B<-r> are
 916 mutually exclusive.
 917
 918 =item -l
 919
 920 Symbolic links will be replicated in the destination directory.  If B<-l>
 921 is not specified, then links are skipped over.
 922
 923 =item -h
 924
 925 Put ``hints'' in the .ph files which will help in locating problems with
 926 I<h2ph>.  In those cases when you B<require> a B<.ph> file containing syntax
 927 errors, instead of the cryptic
 928
 929         [ some error condition ] at (eval mmm) line nnn
 930
 931 you will see the slightly more helpful
 932
 933         [ some error condition ] at filename.ph line nnn
 934
 935 However, the B<.ph> files almost double in size when built using B<-h>.
 936
 937 =item -D
 938
 939 Include the code from the B<.h> file as a comment in the B<.ph> file.
 940 This is primarily used for debugging I<h2ph>.
 941
 942 =item -Q
 943
 944 ``Quiet'' mode; don't print out the names of the files being converted.
 945
 946 =back
 947
 948 =head1 ENVIRONMENT
 949
 950 No environment variables are used.
 951
 952 =head1 FILES
 953
 954  /usr/include/*.h
 955  /usr/include/sys/*.h
 956
 957 etc.
 958
 959 =head1 AUTHOR
 960
 961 Larry Wall
 962
 963 =head1 SEE ALSO
 964
 965 perl(1)
 966
 967 =head1 DIAGNOSTICS
 968
 969 The usual warnings if it can't read or write the files involved.
 970
 971 =head1 BUGS
 972
 973 Doesn't construct the %sizeof array for you.
 974
 975 It doesn't handle all C constructs, but it does attempt to isolate
 976 definitions inside evals so that you can get at the definitions
 977 that it can translate.
 978
 979 It's only intended as a rough tool.
 980 You may need to dicker with the files produced.
 981
 982 You have to run this program by hand; it's not run as part of the Perl
 983 installation.
 984
 985 Doesn't handle complicated expressions built piecemeal, a la:
 986
 987     enum {
 988         FIRST_VALUE,
 989         SECOND_VALUE,
 990     #ifdef ABC
 991         THIRD_VALUE
 992     #endif
 993     };
 994
 995 Doesn't necessarily locate all of your C compiler's internally-defined
 996 symbols.
 997
 998 =cut
 999
1000 !NO!SUBS!
1001
1002 close OUT or die "Can't close $file: $!";
1003 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1004 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1005 chdir $origdir;