t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # "not absolute" is the the default, as it saves some fakery within TestInit
  27 # which can peturb tests, and takes CPU. Working with the upstream author of
  28 # any of these, to figure out how to remove them from this list, considered
  29 # "a good thing".
  30 my %abs = (
  31            '../cpan/Archive-Extract' => 1,
  32            '../cpan/Archive-Tar' => 1,
  33            '../cpan/AutoLoader' => 1,
  34            '../cpan/CPAN' => 1,
  35            '../cpan/Class-ISA' => 1,
  36            '../cpan/Devel-PPPort' => 1,
  37            '../cpan/Encode' => 1,
  38            '../cpan/ExtUtils-Constant' => 1,
  39            '../cpan/ExtUtils-MakeMaker' => 1,
  40            '../cpan/File-Fetch' => 1,
  41            '../cpan/IPC-Cmd' => 1,
  42            '../cpan/IPC-SysV' => 1,
  43            '../cpan/Locale-Codes' => 1,
  44            '../cpan/Log-Message' => 1,
  45            '../cpan/Math-Complex' => 1,
  46            '../cpan/Module-Build' => 1,
  47            '../cpan/Module-Load' => 1,
  48            '../cpan/Module-Load-Conditional' => 1,
  49            '../cpan/Object-Accessor' => 1,
  50            '../cpan/Package-Constants' => 1,
  51            '../cpan/Parse-CPAN-Meta' => 1,
  52            '../cpan/Pod-Simple' => 1,
  53            '../cpan/Term-UI' => 1,
  54            '../cpan/Test-Simple' => 1,
  55            '../cpan/Tie-File' => 1,
  56            '../cpan/podlators' => 1,
  57            '../dist/Cwd' => 1,
  58            '../dist/ExtUtils-Command' => 1,
  59            '../dist/ExtUtils-Install' => 1,
  60            '../dist/ExtUtils-Manifest' => 1,
  61            '../dist/ExtUtils-ParseXS' => 1,
  62           );
  63
  64 my %temp_no_core =
  65     ('../cpan/B-Debug' => 1,
  66      '../cpan/Compress-Raw-Bzip2' => 1,
  67      '../cpan/Compress-Raw-Zlib' => 1,
  68      '../cpan/Devel-PPPort' => 1,
  69      '../cpan/Getopt-Long' => 1,
  70      '../cpan/IO-Compress' => 1,
  71      '../cpan/MIME-Base64' => 1,
  72      '../cpan/parent' => 1,
  73      '../cpan/Parse-CPAN-Meta' => 1,
  74      '../cpan/Pod-Simple' => 1,
  75      '../cpan/podlators' => 1,
  76      '../cpan/Test-Simple' => 1,
  77      '../cpan/Tie-RefHash' => 1,
  78      '../cpan/Time-HiRes' => 1,
  79      '../cpan/Unicode-Collate' => 1,
  80      '../cpan/Unicode-Normalize' => 1,
  81     );
  82
  83 # delete env vars that may influence the results
  84 # but allow override via *_TEST env var if wanted
  85 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  86 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
  87     my $override = $ENV{"${envname}_TEST"};
  88     if (defined $override) {
  89         warn "$0: $envname=$override\n";
  90         $ENV{$envname} = $override;
  91     }
  92     else {
  93         delete $ENV{$envname};
  94     }
  95 }
  96
  97 if ($::do_nothing) {
  98     return 1;
  99 }
 100
 101 # Location to put the Valgrind log.
 102 our $Valgrind_Log;
 103
 104 $| = 1;
 105
 106 # for testing TEST only
 107 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 108 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 109
 110 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 111 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 112 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 113
 114 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 115 # can't rely on require working.
 116 {
 117     my @argv = ();
 118     foreach my $idx (0..$#ARGV) {
 119         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 120         $::benchmark = 1 if $1 eq 'benchmark';
 121         $::core    = 1 if $1 eq 'core';
 122         $::verbose = 1 if $1 eq 'v';
 123         $::torture = 1 if $1 eq 'torture';
 124         $::with_utf8 = 1 if $1 eq 'utf8';
 125         $::with_utf16 = 1 if $1 eq 'utf16';
 126         $::taintwarn = 1 if $1 eq 'taintwarn';
 127         if ($1 =~ /^deparse(,.+)?$/) {
 128             $::deparse = 1;
 129             $::deparse_opts = $1;
 130         }
 131     }
 132     @ARGV = @argv;
 133 }
 134
 135 $ENV{PERL_CORE_MINITEST} = 1 unless defined &DynaLoader::boot_DynaLoader;
 136
 137 chdir 't' if -f 't/TEST';
 138 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 139     @INC = '../lib';
 140 }
 141
 142 die "You need to run \"make test\" first to set things up.\n"
 143   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 144
 145 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 146     unless (-x 'perl.third') {
 147         unless (-x '../perl.third') {
 148             die "You need to run \"make perl.third first.\n";
 149         }
 150         else {
 151             print "Symlinking ../perl.third as perl.third...\n";
 152             die "Failed to symlink: $!\n"
 153                 unless symlink("../perl.third", "perl.third");
 154             die "Symlinked but no executable perl.third: $!\n"
 155                 unless -x 'perl.third';
 156         }
 157     }
 158 }
 159
 160 # check leakage for embedders
 161 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 162
 163 $ENV{EMXSHELL} = 'sh';        # For OS/2
 164
 165 if ($show_elapsed_time) { require Time::HiRes }
 166
 167 my %skip = (
 168             '.' => 1,
 169             '..' => 1,
 170             'CVS' => 1,
 171             'RCS' => 1,
 172             'SCCS' => 1,
 173             '.svn' => 1,
 174            );
 175
 176 # Roll your own File::Find!
 177 sub _find_tests {
 178     my($dir) = @_;
 179     opendir DIR, $dir or die "Trouble opening $dir: $!";
 180     foreach my $f (sort { $a cmp $b } readdir DIR) {
 181         next if $skip{$f};
 182
 183         my $fullpath = "$dir/$f";
 184
 185         if (-d $fullpath) {
 186             _find_tests($fullpath);
 187         } elsif ($f =~ /\.t$/) {
 188             push @ARGV, $fullpath;
 189         }
 190     }
 191 }
 192
 193
 194 # Scan the text of the test program to find switches and special options
 195 # we might need to apply.
 196 sub _scan_test {
 197     my($test, $type) = @_;
 198
 199     open(my $script, "<", $test) or die "Can't read $test.\n";
 200     my $first_line = <$script>;
 201
 202     $first_line =~ tr/\0//d if $::with_utf16;
 203
 204     my $switch = "";
 205     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 206         $switch = "-$1";
 207     } else {
 208         if ($::taintwarn) {
 209             # not all tests are expected to pass with this option
 210             $switch = '-t';
 211         } else {
 212             $switch = '';
 213         }
 214     }
 215
 216     my $file_opts = "";
 217     if ($type eq 'deparse') {
 218         # Look for #line directives which change the filename
 219         while (<$script>) {
 220             $file_opts = $file_opts . ",-f$3$4"
 221               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 222         }
 223     }
 224
 225     close $script;
 226
 227     my $perl = './perl';
 228     my $lib  = '../lib';
 229     my $run_dir;
 230     my $return_dir;
 231
 232     $test =~ /^(.+)\/[^\/]+/;
 233     my $dir = $1;
 234     my $testswitch = $dir_to_switch{$dir};
 235     if (!defined $testswitch) {
 236         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 237             $run_dir = $1;
 238             $return_dir = '../../t';
 239             $lib = '../../lib';
 240             $perl = '../../t/perl';
 241             $testswitch = "-I../.. -MTestInit=U2T";
 242             if ($2 eq 'cpan' || $2 eq 'dist') {
 243                 if($abs{$run_dir}) {
 244                     $testswitch = $testswitch . ',A';
 245                 }
 246                 if ($temp_no_core{$run_dir}) {
 247                     $testswitch = $testswitch . ',NC';
 248                 }
 249             }
 250         } elsif ($test =~ m!^\.\./lib!) {
 251             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 252         } else {
 253             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 254         }
 255     }
 256
 257     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 258
 259     my %options = (
 260         perl => $perl,
 261         lib => $lib,
 262         test => $test,
 263         run_dir => $run_dir,
 264         return_dir => $return_dir,
 265         testswitch => $testswitch,
 266         utf8 => $utf8,
 267         file => $file_opts,
 268         switch => $switch,
 269     );
 270
 271     return \%options;
 272 }
 273
 274 sub _cmd {
 275     my($options, $type) = @_;
 276
 277     my $test = $options->{test};
 278
 279     my $cmd;
 280     if ($type eq 'deparse') {
 281         my $perl = "$options->{perl} $options->{testswitch}";
 282         my $lib = $options->{lib};
 283
 284         $cmd = (
 285           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 286           "-l$::deparse_opts$options->{file} ".
 287           "$test > $test.dp ".
 288           "&& $perl $options->{switch} -I$lib $test.dp"
 289         );
 290     }
 291     elsif ($type eq 'perl') {
 292         my $perl = $options->{perl};
 293         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 294
 295         if ($ENV{PERL_VALGRIND}) {
 296             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 297             my $valgrind = $ENV{VALGRIND} // 'valgrind';
 298             my $vg_opts = $ENV{VG_OPTS}
 299               //  "--suppressions=$perl_supp --leak-check=yes "
 300                 . "--leak-resolution=high --show-reachable=yes "
 301                   . "--num-callers=50 --track-origins=yes";
 302             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
 303             $redir = "3>$Valgrind_Log";
 304             if ($options->{run_dir}) {
 305                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 306             }
 307         }
 308
 309         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 310         $cmd = $perl . _quote_args($args) . " $test $redir";
 311     }
 312
 313     return $cmd;
 314 }
 315
 316 sub _before_fork {
 317     my ($options) = @_;
 318
 319     if ($options->{run_dir}) {
 320         my $run_dir = $options->{run_dir};
 321         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 322     }
 323
 324     return;
 325 }
 326
 327 sub _after_fork {
 328     my ($options) = @_;
 329
 330     if ($options->{return_dir}) {
 331         my $return_dir = $options->{return_dir};
 332         chdir $return_dir
 333            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 334     }
 335
 336     return;
 337 }
 338
 339 sub _run_test {
 340     my ($test, $type) = @_;
 341
 342     my $options = _scan_test($test, $type);
 343     # $test might have changed if we're in ext/Foo, so don't use it anymore
 344     # from now on. Use $options->{test} instead.
 345
 346     _before_fork($options);
 347
 348     my $cmd = _cmd($options, $type);
 349
 350     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 351
 352     _after_fork($options);
 353
 354     # Our environment may force us to use UTF-8, but we can't be sure that
 355     # anything we're reading from will be generating (well formed) UTF-8
 356     # This may not be the best way - possibly we should unset ${^OPEN} up
 357     # top?
 358     binmode $results;
 359
 360     return $results;
 361 }
 362
 363 sub _quote_args {
 364     my ($args) = @_;
 365     my $argstring = '';
 366
 367     foreach (split(/\s+/,$args)) {
 368        # In VMS protect with doublequotes because otherwise
 369        # DCL will lowercase -- unless already doublequoted.
 370        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 371        $argstring = $argstring . ' ' . $_;
 372     }
 373     return $argstring;
 374 }
 375
 376 sub _populate_hash {
 377     return unless defined $_[0];
 378     return map {$_, 1} split /\s+/, $_[0];
 379 }
 380
 381 sub _tests_from_manifest {
 382     my ($extensions, $known_extensions) = @_;
 383     my %skip;
 384     my %extensions = _populate_hash($extensions);
 385     my %known_extensions = _populate_hash($known_extensions);
 386
 387     foreach (keys %known_extensions) {
 388         $skip{$_} = 1 unless $extensions{$_};
 389     }
 390
 391     my @results;
 392     my $mani = '../MANIFEST';
 393     if (open(MANI, $mani)) {
 394         while (<MANI>) {
 395             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 396                 my $t = $1;
 397                 my $extension = $2;
 398                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 399                     if (defined $extension) {
 400                         $extension =~ s!/t(:?/\S+)*$!!;
 401                         # XXX Do I want to warn that I'm skipping these?
 402                         next if $skip{$extension};
 403                         my $flat_extension = $extension;
 404                         $flat_extension =~ s!-!/!g;
 405                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 406                     }
 407                     my $path = "../$t";
 408                     push @results, $path;
 409                     $::path_to_name{$path} = $t;
 410                 }
 411             }
 412         }
 413         close MANI;
 414     } else {
 415         warn "$0: cannot open $mani: $!\n";
 416     }
 417     return @results;
 418 }
 419
 420 unless (@ARGV) {
 421     # base first, as TEST bails out if that can't run
 422     # then comp, to validate that require works
 423     # then run, to validate that -M works
 424     # then we know we can -MTestInit for everything else, making life simpler
 425     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 426         _find_tests($dir);
 427     }
 428     _find_tests("lib") unless $::core;
 429     # Config.pm may be broken for make minitest. And this is only a refinement
 430     # for skipping tests on non-default builds, so it is allowed to fail.
 431     # What we want to to is make a list of extensions which we did not build.
 432     my $configsh = '../config.sh';
 433     my ($extensions, $known_extensions);
 434     if (-f $configsh) {
 435         open FH, $configsh or die "Can't open $configsh: $!";
 436         while (<FH>) {
 437             if (/^extensions=['"](.*)['"]$/) {
 438                 $extensions = $1;
 439             }
 440             elsif (/^known_extensions=['"](.*)['"]$/) {
 441                 $known_extensions = $1;
 442             }
 443         }
 444         if (!defined $known_extensions) {
 445             warn "No known_extensions line found in $configsh";
 446         }
 447         if (!defined $extensions) {
 448             warn "No extensions line found in $configsh";
 449         }
 450     }
 451     # The "complex" constructions of list return from a subroutine, and push of
 452     # a list, might fail if perl is really hosed, but they aren't needed for
 453     # make minitest, and the building of extensions will likely also fail if
 454     # something is that badly wrong.
 455     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 456     unless ($::core) {
 457         _find_tests('x2p');
 458         _find_tests('porting');
 459         _find_tests('japh') if $::torture;
 460         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 461     }
 462 }
 463
 464 if ($::deparse) {
 465     _testprogs('deparse', '',   @ARGV);
 466 }
 467 elsif ($::with_utf16) {
 468     for my $e (0, 1) {
 469         for my $b (0, 1) {
 470             print STDERR "# ENDIAN $e BOM $b\n";
 471             my @UARGV;
 472             for my $a (@ARGV) {
 473                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 474                 my $f = $e ? "v" : "n";
 475                 push @UARGV, $u;
 476                 unlink($u);
 477                 if (open(A, $a)) {
 478                     if (open(U, ">$u")) {
 479                         print U pack("$f", 0xFEFF) if $b;
 480                         while (<A>) {
 481                             print U pack("$f*", unpack("C*", $_));
 482                         }
 483                         close(U);
 484                     }
 485                     close(A);
 486                 }
 487             }
 488             _testprogs('perl', '', @UARGV);
 489             unlink(@UARGV);
 490         }
 491     }
 492 }
 493 else {
 494     _testprogs('perl',    '',   @ARGV);
 495 }
 496
 497 sub _testprogs {
 498     my ($type, $args, @tests) = @_;
 499
 500     print <<'EOT' if ($type eq 'deparse');
 501 ------------------------------------------------------------------------------
 502 TESTING DEPARSER
 503 ------------------------------------------------------------------------------
 504 EOT
 505
 506     $::bad_files = 0;
 507
 508     foreach my $t (@tests) {
 509       unless (exists $::path_to_name{$t}) {
 510         my $tname = "t/$t";
 511         $::path_to_name{$t} = $tname;
 512       }
 513     }
 514     my $maxlen = 0;
 515     foreach (@::path_to_name{@tests}) {
 516         s/\.\w+\z/./;
 517         my $len = length ;
 518         $maxlen = $len if $len > $maxlen;
 519     }
 520     # + 3 : we want three dots between the test name and the "ok"
 521     my $dotdotdot = $maxlen + 3 ;
 522     my $valgrind = 0;
 523     my $total_files = @tests;
 524     my $good_files = 0;
 525     my $tested_files  = 0;
 526     my $totmax = 0;
 527     my %failed_tests;
 528
 529     while (my $test = shift @tests) {
 530         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
 531
 532         if ($test =~ /^$/) {
 533             next;
 534         }
 535         if ($type eq 'deparse') {
 536             if ($test eq "comp/redef.t") {
 537                 # Redefinition happens at compile time
 538                 next;
 539             }
 540             elsif ($test =~ m{lib/Switch/t/}) {
 541                 # B::Deparse doesn't support source filtering
 542                 next;
 543             }
 544         }
 545         my $te = $::path_to_name{$test} . '.'
 546                     x ($dotdotdot - length($::path_to_name{$test}));
 547
 548         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 549             print $te;
 550             $te = '';
 551         }
 552
 553         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 554         my $results = _run_test($test, $type);
 555
 556         my $failure;
 557         my $next = 0;
 558         my $seen_leader = 0;
 559         my $seen_ok = 0;
 560         my $trailing_leader = 0;
 561         my $max;
 562         my %todo;
 563         while (<$results>) {
 564             next if /^\s*$/; # skip blank lines
 565             if (/^1..$/ && ($^O eq 'VMS')) {
 566                 # VMS pipe bug inserts blank lines.
 567                 my $l2 = <RESULTS>;
 568                 if ($l2 =~ /^\s*$/) {
 569                     $l2 = <RESULTS>;
 570                 }
 571                 $_ = '1..' . $l2;
 572             }
 573             if ($::verbose) {
 574                 print $_;
 575             }
 576             unless (/^\#/) {
 577                 if ($trailing_leader) {
 578                     # shouldn't be anything following a postfix 1..n
 579                     $failure = 'FAILED--extra output after trailing 1..n';
 580                     last;
 581                 }
 582                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 583                     if ($seen_leader) {
 584                         $failure = 'FAILED--seen duplicate leader';
 585                         last;
 586                     }
 587                     $max = $1;
 588                     %todo = map { $_ => 1 } split / /, $3 if $3;
 589                     $totmax = $totmax + $max;
 590                     $tested_files = $tested_files + 1;
 591                     if ($seen_ok) {
 592                         # 1..n appears at end of file
 593                         $trailing_leader = 1;
 594                         if ($next != $max) {
 595                             $failure = "FAILED--expected $max tests, saw $next";
 596                             last;
 597                         }
 598                     }
 599                     else {
 600                         $next = 0;
 601                     }
 602                     $seen_leader = 1;
 603                 }
 604                 else {
 605                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 606                         unless ($seen_leader) {
 607                             unless ($seen_ok) {
 608                                 $next = 0;
 609                             }
 610                         }
 611                         $seen_ok = 1;
 612                         $next = $next + 1;
 613                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 614                         $num = $next unless $num;
 615
 616                         if ($num == $next) {
 617
 618                             # SKIP is essentially the same as TODO for t/TEST
 619                             # this still conforms to TAP:
 620                             # http://search.cpan.org/dist/TAP/TAP.pm
 621                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 622                             $istodo = 1 if $todo{$num};
 623
 624                             if( $not && !$istodo ) {
 625                                 $failure = "FAILED at test $num";
 626                                 last;
 627                             }
 628                         }
 629                         else {
 630                             $failure ="FAILED--expected test $next, saw test $num";
 631                             last;
 632                         }
 633                     }
 634                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 635                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 636                     }
 637                     else {
 638                         # module tests are allowed extra output,
 639                         # because Test::Harness allows it
 640                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 641                         $failure = "FAILED--unexpected output at test $next";
 642                         last;
 643                     }
 644                 }
 645             }
 646         }
 647         close $results;
 648
 649         if (not defined $failure) {
 650             $failure = 'FAILED--no leader found' unless $seen_leader;
 651         }
 652
 653         if ($ENV{PERL_VALGRIND}) {
 654             my @valgrind;
 655             if (-e $Valgrind_Log) {
 656                 if (open(V, $Valgrind_Log)) {
 657                     @valgrind = <V>;
 658                     close V;
 659                 } else {
 660                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 661                 }
 662             }
 663             if ($ENV{VG_OPTS} =~ /cachegrind/) {
 664                 if (rename $Valgrind_Log, "$test.valgrind") {
 665                     $valgrind = $valgrind + 1;
 666                 } else {
 667                     warn "$0: Failed to create '$test.valgrind': $!\n";
 668                 }
 669             }
 670             elsif (@valgrind) {
 671                 my $leaks = 0;
 672                 my $errors = 0;
 673                 for my $i (0..$#valgrind) {
 674                     local $_ = $valgrind[$i];
 675                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 676                         $errors = $errors + $1;   # there may be multiple error summaries
 677                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 678                         for my $off (1 .. 4) {
 679                             if ($valgrind[$i+$off] =~
 680                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 681                                 $leaks = $leaks + $1;
 682                             }
 683                         }
 684                     }
 685                 }
 686                 if ($errors or $leaks) {
 687                     if (rename $Valgrind_Log, "$test.valgrind") {
 688                         $valgrind = $valgrind + 1;
 689                     } else {
 690                         warn "$0: Failed to create '$test.valgrind': $!\n";
 691                     }
 692                 }
 693             } else {
 694                 warn "No valgrind output?\n";
 695             }
 696             if (-e $Valgrind_Log) {
 697                 unlink $Valgrind_Log
 698                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 699             }
 700         }
 701         if ($type eq 'deparse') {
 702             unlink "./$test.dp";
 703         }
 704         if ($ENV{PERL_3LOG}) {
 705             my $tpp = $test;
 706             $tpp =~ s:^\.\./::;
 707             $tpp =~ s:/:_:g;
 708             $tpp =~ s:\.t$:.3log:;
 709             rename("perl.3log", $tpp) ||
 710                 die "rename: perl3.log to $tpp: $!\n";
 711         }
 712         if (not defined $failure and $next != $max) {
 713             $failure="FAILED--expected $max tests, saw $next";
 714         }
 715
 716         if( !defined $failure  # don't mask a test failure
 717             and $? )
 718         {
 719             $failure = "FAILED--non-zero wait status: $?";
 720         }
 721
 722         if (defined $failure) {
 723             print "${te}$failure\n";
 724             $::bad_files = $::bad_files + 1;
 725             if ($test =~ /^base/) {
 726                 die "Failed a basic test ($test) -- cannot continue.\n";
 727             }
 728             $failed_tests{$test} = 1;
 729         }
 730         else {
 731             if ($max) {
 732                 my $elapsed;
 733                 if ( $show_elapsed_time ) {
 734                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
 735                 }
 736                 else {
 737                     $elapsed = "";
 738                 }
 739                 print "${te}ok$elapsed\n";
 740                 $good_files = $good_files + 1;
 741             }
 742             else {
 743                 print "${te}skipped\n";
 744                 $tested_files = $tested_files - 1;
 745             }
 746         }
 747     } # while tests
 748
 749     if ($::bad_files == 0) {
 750         if ($good_files) {
 751             print "All tests successful.\n";
 752             # XXX add mention of 'perlbug -ok' ?
 753         }
 754         else {
 755             die "FAILED--no tests were run for some reason.\n";
 756         }
 757     }
 758     else {
 759         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 760         my $s = $::bad_files == 1 ? "" : "s";
 761         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 762         for my $test ( sort keys %failed_tests ) {
 763             print "\t$test\n";
 764         }
 765         warn <<'SHRDLU_1';
 766 ### Since not all tests were successful, you may want to run some of
 767 ### them individually and examine any diagnostic messages they produce.
 768 ### See the INSTALL document's section on "make test".
 769 SHRDLU_1
 770         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 771 ### You have a good chance to get more information by running
 772 ###   ./perl harness
 773 ### in the 't' directory since most (>=80%) of the tests succeeded.
 774 SHRDLU_2
 775         if (eval {require Config; import Config; 1}) {
 776             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 777                 warn <<SHRDLU_3;
 778 ### You may have to set your dynamic library search path,
 779 ### $p, to point to the build directory:
 780 SHRDLU_3
 781                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 782                     warn <<SHRDLU_4a;
 783 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 784 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 785 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 786 SHRDLU_4a
 787                 } else {
 788                     warn <<SHRDLU_4b;
 789 ###   setenv $p `pwd`; cd t; ./perl harness
 790 ###   $p=`pwd`; export $p; cd t; ./perl harness
 791 ###   export $p=`pwd`; cd t; ./perl harness
 792 SHRDLU_4b
 793                 }
 794                 warn <<SHRDLU_5;
 795 ### for csh-style shells, like tcsh; or for traditional/modern
 796 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 797 SHRDLU_5
 798             }
 799         }
 800     }
 801     my ($user,$sys,$cuser,$csys) = times;
 802     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
 803         $user,$sys,$cuser,$csys,$tested_files,$totmax);
 804     if ($ENV{PERL_VALGRIND}) {
 805         my $s = $valgrind == 1 ? '' : 's';
 806         print "$valgrind valgrind report$s created.\n", ;
 807     }
 808 }
 809 exit ($::bad_files != 0);
 810
 811 # ex: set ts=8 sts=4 sw=4 noet: