Porting/cmpVERSION.pl

   1 #!/usr/bin/perl -w
   2
   3 #
   4 # cmpVERSION - compare the current Perl source tree and a given tag
   5 # for modules that have identical version numbers but different contents.
   6 #
   7 # with -d option, output the diffs too
   8 # with -x option, exclude files from modules where blead is not upstream
   9 #
  10 # (after all, there are tools like core-cpan-diff that can already deal with
  11 # them)
  12 #
  13 # Original by slaven@rezic.de, modified by jhi and matt.w.johnson@gmail.com.
  14 # Adaptation to produce TAP by Abigail, folded back into this file by Nicholas
  15
  16 use strict;
  17 use 5.006;
  18
  19 use ExtUtils::MakeMaker;
  20 use File::Spec::Functions qw(devnull);
  21 use Getopt::Long;
  22
  23 my ($diffs, $exclude_upstream, $tag_to_compare, $tap);
  24 unless (GetOptions('diffs' => \$diffs,
  25                    'exclude|x' => \$exclude_upstream,
  26                    'tag=s' => \$tag_to_compare,
  27                    'tap' => \$tap,
  28                    ) && @ARGV == 0) {
  29     die "usage: $0 [ -d -x --tag TAG --tap]";
  30 }
  31
  32 die "$0: This does not look like a Perl directory\n"
  33     unless -f "perl.h" && -d "Porting";
  34 die "$0: 'This is a Perl directory but does not look like Git working directory\n"
  35     unless (-d ".git" || (exists $ENV{GIT_DIR} && -d $ENV{GIT_DIR}));
  36
  37 my $null = devnull();
  38
  39 unless (defined $tag_to_compare) {
  40     my $check = 'HEAD';
  41     while(1) {
  42         $check = `git describe --abbrev=0 $check 2>$null`;
  43         chomp $check;
  44         last unless $check =~ /-RC/;
  45         $check .= '~1';
  46     }
  47     $tag_to_compare = $check;
  48     # Thanks to David Golden for this suggestion.
  49
  50 }
  51
  52 unless (length $tag_to_compare) {
  53     die "$0: Git found, but no Git tags found\n"
  54         unless $tap;
  55     print "1..0 # SKIP: Git found, but no Git tags found\n";
  56     exit 0;
  57 }
  58
  59 my $tag_exists = `git --no-pager tag -l $tag_to_compare 2>$null`;
  60 chomp $tag_exists;
  61
  62 unless ($tag_exists eq $tag_to_compare) {
  63     die "$0: '$tag_to_compare' is not a known Git tag\n" unless $tap;
  64     print "1..0 # SKIP: '$tag_to_compare' is not a known Git tag\n";
  65     exit 0;
  66 }
  67
  68 my %upstream_files;
  69 if ($exclude_upstream) {
  70     unshift @INC, 'Porting';
  71     require Maintainers;
  72
  73     for my $m (grep {!defined $Maintainers::Modules{$_}{UPSTREAM}
  74                          or $Maintainers::Modules{$_}{UPSTREAM} ne 'blead'}
  75                keys %Maintainers::Modules) {
  76         $upstream_files{$_} = 1 for Maintainers::get_module_files($m);
  77     }
  78 }
  79
  80 # Files to skip from the check for one reason or another,
  81 # usually because they pull in their version from some other file.
  82 my %skip;
  83 @skip{
  84     'cpan/ExtUtils-MakeMaker/t/lib/MakeMaker/Test/Setup/BFD.pm', # just a test module
  85     'cpan/ExtUtils-MakeMaker/t/lib/MakeMaker/Test/Setup/XS.pm',  # just a test module
  86     'cpan/Math-BigInt/t/Math/BigFloat/Subclass.pm', # just a test module
  87     'cpan/Math-BigInt/t/Math/BigInt/BareCalc.pm',   # just a test module
  88     'cpan/Math-BigInt/t/Math/BigInt/Scalar.pm',     # just a test module
  89     'cpan/Math-BigInt/t/Math/BigInt/Subclass.pm',   # just a test module
  90     'cpan/Math-BigRat/t/Math/BigRat/Test.pm',       # just a test module
  91     'cpan/podlators/t/lib/Test/Podlators.pm',       # just a test module
  92     'cpan/podlators/t/lib/Test/RRA.pm',             # just a test module
  93     'cpan/podlators/t/lib/Test/RRA/Config.pm',      # just a test module
  94     'cpan/version/t/coretests.pm', # just a test module
  95     'dist/Attribute-Handlers/demo/MyClass.pm', # it's just demonstration code
  96     'dist/Exporter/lib/Exporter/Heavy.pm',
  97     'lib/Carp/Heavy.pm',
  98     'lib/Config.pm',            # no version number but contents will vary
  99     'win32/FindExt.pm',
 100 } = ();
 101
 102 # Files to skip just for particular version(s),
 103 # usually due to some # mix-up
 104
 105 my %skip_versions = (
 106            # 'some/sample/file.pm' => [ '1.23', '1.24' ],
 107           );
 108
 109 my $skip_dirs = qr|^t/lib|;
 110
 111 sub pm_file_from_xs {
 112     my $xs = shift;
 113
 114     foreach my $try (sub {
 115                          # First try a .pm at the same level as the .xs file
 116                          # with the same basename
 117                          return shift =~ s/\.xs\z//r;
 118                      },
 119                      sub {
 120                          # Try for a (different) .pm at the same level, based
 121                          # on the directory name:
 122                          my ($path) = shift =~ m!^(.*)/!;
 123                          my ($last) = $path =~ m!([^-/]+)\z!;
 124                          return "$path/$last";
 125                      },
 126                      sub {
 127                          # Try to work out the extension's full package, and
 128                          # look for a .pm in lib/ based on that:
 129                          my ($path) = shift =~ m!^(.*)/!;
 130                          my ($last) = $path =~ m!([^/]+)\z!;
 131                          $last = 'List-Util' if $last eq 'Scalar-List-Utils';
 132                          $last =~ tr !-!/!;
 133                          return "$path/lib/$last";
 134                      }) {
 135         # For all cases, first look to see if the .pm file is generated.
 136         my $base = $try->($xs);
 137         return "${base}_pm.PL" if -f "${base}_pm.PL";
 138         return "${base}.pm" if -f "${base}.pm";
 139     }
 140
 141     die "No idea which .pm file corresponds to '$xs', so aborting";
 142 }
 143
 144 # Key is the .pm file from which we check the version.
 145 # Value is a reference to an array of files to check for differences
 146 # The trivial case is a pure perl module, where the array holds one element,
 147 # the perl module's file. The "fun" comes with XS modules, and the real fun
 148 # with XS modules with more than one XS file, and "interesting" layouts.
 149
 150 my %module_diffs;
 151
 152 foreach (`git --no-pager diff --name-only $tag_to_compare --diff-filter=ACMRTUXB`) {
 153     chomp;
 154     next unless m/^(.*)\//;
 155     my $this_dir = $1;
 156     next if $this_dir =~ $skip_dirs || exists $skip{$_};
 157     next if exists $upstream_files{$_};
 158     if (/\.pm\z/ || m|^lib/.*\.pl\z| || /_pm\.PL\z/) {
 159         push @{$module_diffs{$_}}, $_;
 160     } elsif (/\.xs\z/ && !/\bt\b/) {
 161         push @{$module_diffs{pm_file_from_xs($_)}}, $_;
 162     }
 163 }
 164
 165 unless (%module_diffs) {
 166     print "1..1\nok 1 - No difference found\n" if $tap;
 167     exit;
 168 }
 169
 170 printf "1..%d\n" => scalar keys %module_diffs if $tap;
 171
 172 my $count;
 173 my $diff_cmd = "git --no-pager diff $tag_to_compare ";
 174 my $q = ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') ? '"' : "'";
 175 my (@diff);
 176
 177 foreach my $pm_file (sort keys %module_diffs) {
 178     # git has already told us that the files differ, so no need to grab each as
 179     # a blob from git, and do the comparison ourselves.
 180     my $pm_version = eval {MM->parse_version($pm_file)};
 181     my $orig_pm_content = get_file_from_git($pm_file, $tag_to_compare);
 182     my $orig_pm_version = eval {MM->parse_version(\$orig_pm_content)};
 183     ++$count;
 184
 185     if (!defined $orig_pm_version || $orig_pm_version eq 'undef') { # sigh
 186         print "ok $count - SKIP Can't parse \$VERSION in $pm_file\n"
 187           if $tap;
 188     } elsif (!defined $pm_version || $pm_version eq 'undef') {
 189         my $nok = "not ok $count - in $pm_file version was $orig_pm_version, now unparsable\n";
 190         print $nok if $tap;
 191         print STDERR "# $nok\n";
 192     } elsif ($pm_version ne $orig_pm_version) { # good
 193         print "ok $count - $pm_file\n" if $tap;
 194     } else {
 195         if ($tap) {
 196             foreach (sort @{$module_diffs{$pm_file}}) {
 197                 print "# $_" for `$diff_cmd $q$_$q`;
 198             }
 199             if (exists $skip_versions{$pm_file}
 200                 and grep $pm_version eq $_, @{$skip_versions{$pm_file}}) {
 201                 print "ok $count - SKIP $pm_file version $pm_version\n";
 202             } else {
 203                 my $nok = "not ok $count - $pm_file version $pm_version\n";
 204                 print $nok;
 205                 print STDERR "# $nok";
 206             }
 207         } else {
 208             push @diff, @{$module_diffs{$pm_file}};
 209             print "$pm_file version $pm_version\n";
 210         }
 211     }
 212 }
 213
 214 sub get_file_from_git {
 215     my ($file, $tag) = @_;
 216     local $/;
 217
 218     use open IN => ':raw';
 219     return scalar `git --no-pager show $tag:$file 2>$null`;
 220 }
 221
 222 if ($diffs) {
 223     for (sort @diff) {
 224         print "\n";
 225         system "$diff_cmd $q$_$q";
 226     }
 227 }