ext/DynaLoader/DynaLoader_pm.PL

   1 use Config;
   2
   3 sub to_string {
   4     my ($value) = @_;
   5     $value =~ s/\\/\\\\/g;
   6     $value =~ s/'/\\'/g;
   7     return "'$value'";
   8 }
   9
  10 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  11 open OUT, ">DynaLoader.pm" or die $!;
  12 print OUT <<'EOT';
  13
  14 # Generated from DynaLoader.pm.PL
  15
  16 package DynaLoader;
  17
  18 #   And Gandalf said: 'Many folk like to know beforehand what is to
  19 #   be set on the table; but those who have laboured to prepare the
  20 #   feast like to keep their secret; for wonder makes the words of
  21 #   praise louder.'
  22
  23 #   (Quote from Tolkien suggested by Anno Siegel.)
  24 #
  25 # See pod text at end of file for documentation.
  26 # See also ext/DynaLoader/README in source tree for other information.
  27 #
  28 # Tim.Bunce@ig.co.uk, August 1994
  29
  30 use vars qw($VERSION *AUTOLOAD);
  31
  32 $VERSION = 1.04;        # avoid typo warning
  33
  34 require AutoLoader;
  35 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  36
  37 use Config;
  38
  39 # The following require can't be removed during maintenance
  40 # releases, sadly, because of the risk of buggy code that does
  41 # require Carp; Carp::croak "..."; without brackets dying
  42 # if Carp hasn't been loaded in earlier compile time. :-(
  43 # We'll let those bugs get found on the development track.
  44 require Carp if $] < 5.00450;
  45
  46 # enable debug/trace messages from DynaLoader perl code
  47 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  48
  49 #
  50 # Flags to alter dl_load_file behaviour.  Assigned bits:
  51 #   0x01  make symbols available for linking later dl_load_file's.
  52 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
  53 #         (ignored under VMS; effect is built-in to image linking)
  54 #
  55 # This is called as a class method $module->dl_load_flags.  The
  56 # definition here will be inherited and result on "default" loading
  57 # behaviour unless a sub-class of DynaLoader defines its own version.
  58 #
  59
  60 sub dl_load_flags { 0x00 }
  61
  62 # ($dl_dlext, $dlsrc)
  63 #         = @Config::Config{'dlext', 'dlsrc'};
  64 EOT
  65
  66 print OUT "  (\$dl_dlext, \$dlsrc) = (",
  67           to_string($Config::Config{'dlext'}), ",",
  68           to_string($Config::Config{'dlsrc'}), ")\n;" ;
  69
  70 print OUT <<'EOT';
  71
  72 # Some systems need special handling to expand file specifications
  73 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
  74 # See dl_expandspec() for more details. Should be harmless but
  75 # inefficient to define on systems that don't need it.
  76 $Is_VMS    = $^O eq 'VMS';
  77 $do_expand = $Is_VMS;
  78 $Is_MacOS  = $^O eq 'MacOS';
  79
  80 @dl_require_symbols = ();       # names of symbols we need
  81 @dl_resolve_using   = ();       # names of files to link with
  82 @dl_library_path    = ();       # path to look for files
  83
  84 #XSLoader.pm may have added elements before we were required
  85 #@dl_librefs         = ();       # things we have loaded
  86 #@dl_modules         = ();       # Modules we have loaded
  87
  88 # This is a fix to support DLD's unfortunate desire to relink -lc
  89 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
  90
  91 EOT
  92
  93 my $cfg_dl_library_path = <<'EOT';
  94 push(@dl_library_path, split(' ', $Config::Config{libpth}));
  95 EOT
  96
  97 sub dquoted_comma_list {
  98     join(", ", map {qq("$_")} @_);
  99 }
 100
 101 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 102     eval $cfg_dl_library_path;
 103     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 104         my $dl_library_path = dquoted_comma_list(@dl_library_path);
 105         print OUT <<EOT;
 106 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
 107
 108 \@dl_library_path = ($dl_library_path);
 109
 110 EOT
 111     }
 112 }
 113 else {
 114     print OUT <<EOT;
 115 # Initialise \@dl_library_path with the 'standard' library path
 116 # for this platform as determined by Configure.
 117
 118 $cfg_dl_library_path
 119
 120 EOT
 121 }
 122
 123 my $ldlibpthname;
 124 my $ldlibpthname_defined;
 125 my $pthsep;
 126
 127 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 128     $ldlibpthname         = $Config::Config{ldlibpthname};
 129     $ldlibpthname_defined = defined $Config::Config{ldlibpthname} ? 1 : 0;
 130     $pthsep               = $Config::Config{path_sep};
 131 }
 132 else {
 133     $ldlibpthname         = q($Config::Config{ldlibpthname});
 134     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
 135     $pthsep               = q($Config::Config{path_sep});
 136     print OUT <<EOT;
 137 my \$ldlibpthname         = $ldlibpthname;
 138 my \$ldlibpthname_defined = $ldlibpthname_defined;
 139 my \$pthsep               = $pthsep;
 140
 141 EOT
 142 }
 143
 144 my $env_dl_library_path = <<'EOT';
 145 if ($ldlibpthname_defined &&
 146     exists $ENV{$ldlibpthname}) {
 147     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
 148 }
 149
 150 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 151
 152 if ($ldlibpthname_defined &&
 153     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
 154     exists $ENV{LD_LIBRARY_PATH}) {
 155     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
 156 }
 157 EOT
 158
 159 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 160     eval $env_dl_library_path;
 161 }
 162 else {
 163     print OUT <<EOT;
 164 # Add to \@dl_library_path any extra directories we can gather from environment
 165 # during runtime.
 166
 167 $env_dl_library_path
 168
 169 EOT
 170 }
 171
 172 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 173     my $dl_library_path = dquoted_comma_list(@dl_library_path);
 174     print OUT <<EOT;
 175 # The below \@dl_library_path has been expanded (%Config, %ENV)
 176 # in Perl build time.
 177
 178 \@dl_library_path = ($dl_library_path);
 179
 180 EOT
 181 }
 182
 183 print OUT <<'EOT';
 184 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 185 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 186 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 187                                 !defined(&dl_error);
 188
 189 if ($dl_debug) {
 190     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 191     print STDERR "DynaLoader not linked into this perl\n"
 192             unless defined(&boot_DynaLoader);
 193 }
 194
 195 1; # End of main code
 196
 197
 198 sub croak   { require Carp; Carp::croak(@_)   }
 199
 200 sub bootstrap_inherit {
 201     my $module = $_[0];
 202     local *isa = *{"$module\::ISA"};
 203     local @isa = (@isa, 'DynaLoader');
 204     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 205     bootstrap(@_);
 206 }
 207
 208 # The bootstrap function cannot be autoloaded (without complications)
 209 # so we define it here:
 210
 211 sub bootstrap {
 212     # use local vars to enable $module.bs script to edit values
 213     local(@args) = @_;
 214     local($module) = $args[0];
 215     local(@dirs, $file);
 216
 217     unless ($module) {
 218         require Carp;
 219         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 220     }
 221
 222     # A common error on platforms which don't support dynamic loading.
 223     # Since it's fatal and potentially confusing we give a detailed message.
 224     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 225         "  (You may need to build a new perl executable which either supports\n".
 226         "  dynamic loading or has the $module module statically linked into it.)\n")
 227         unless defined(&dl_load_file);
 228
 229     my @modparts = split(/::/,$module);
 230     my $modfname = $modparts[-1];
 231
 232     # Some systems have restrictions on files names for DLL's etc.
 233     # mod2fname returns appropriate file base name (typically truncated)
 234     # It may also edit @modparts if required.
 235     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 236
 237     my $modpname = join(($Is_MacOS ? ':' : '/'),@modparts);
 238
 239     print STDERR "DynaLoader::bootstrap for $module ",
 240                 ($Is_MacOS
 241                        ? "(:auto:$modpname:$modfname.$dl_dlext)\n" :
 242                        "(auto/$modpname/$modfname.$dl_dlext)\n")
 243         if $dl_debug;
 244
 245     foreach (@INC) {
 246         chop($_ = VMS::Filespec::unixpath($_)) if $Is_VMS;
 247         my $dir;
 248         if ($Is_MacOS) {
 249             $_ .= ":"  unless /:$/;
 250             $dir = "${_}auto:$modpname";
 251         } else {
 252             $dir = "$_/auto/$modpname";
 253         }
 254         next unless -d $dir; # skip over uninteresting directories
 255
 256         # check for common cases to avoid autoload of dl_findfile
 257         my $try = $Is_MacOS ? "$dir:$modfname.$dl_dlext" : "$dir/$modfname.$dl_dlext";
 258         last if $file = ($do_expand) ? dl_expandspec($try) : (-f $try && $try);
 259
 260         # no luck here, save dir for possible later dl_findfile search
 261         push @dirs, $dir;
 262     }
 263     # last resort, let dl_findfile have a go in all known locations
 264     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 265
 266     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 267         unless $file;   # wording similar to error from 'require'
 268
 269     $file = uc($file) if $Is_VMS && $Config::Config{d_vms_case_sensitive_symbols};
 270     my $bootname = "boot_$module";
 271     $bootname =~ s/\W/_/g;
 272     @dl_require_symbols = ($bootname);
 273
 274     # Execute optional '.bootstrap' perl script for this module.
 275     # The .bs file can be used to configure @dl_resolve_using etc to
 276     # match the needs of the individual module on this architecture.
 277     my $bs = $file;
 278     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 279     if (-s $bs) { # only read file if it's not empty
 280         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 281         eval { do $bs; };
 282         warn "$bs: $@\n" if $@;
 283     }
 284
 285     # Many dynamic extension loading problems will appear to come from
 286     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 287     # Often these errors are actually occurring in the initialisation
 288     # C code of the extension XS file. Perl reports the error as being
 289     # in this perl code simply because this was the last perl code
 290     # it executed.
 291
 292     my $libref = dl_load_file($file, $module->dl_load_flags) or
 293         croak("Can't load '$file' for module $module: ".dl_error());
 294
 295     push(@dl_librefs,$libref);  # record loaded object
 296
 297     my @unresolved = dl_undef_symbols();
 298     if (@unresolved) {
 299         require Carp;
 300         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 301     }
 302
 303     my $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 304          croak("Can't find '$bootname' symbol in $file\n");
 305
 306     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 307
 308     push(@dl_modules, $module); # record loaded module
 309
 310     # See comment block above
 311     &$xs(@args);
 312 }
 313
 314
 315 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 316 #    my($file) = @_;
 317 #    return $file if (!$do_expand && -f $file); # the common case
 318 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 319 #    return undef;
 320 #}
 321
 322
 323 # Let autosplit and the autoloader deal with these functions:
 324 __END__
 325
 326
 327 sub dl_findfile {
 328     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 329     # This function does not automatically consider the architecture
 330     # or the perl library auto directories.
 331     my (@args) = @_;
 332     my (@dirs,  $dir);   # which directories to search
 333     my (@found);         # full paths to real files we have found
 334 EOT
 335
 336 print OUT '    my $dl_ext= ' . to_string($Config::Config{'dlext'}) .
 337           "; # \$Config::Config{'dlext'} suffix for perl extensions\n";
 338 print OUT '    my $dl_so = ' . to_string($Config::Config{'so'}) .
 339           "; # \$Config::Config{'so'} suffix for shared libraries\n";
 340
 341 print OUT <<'EOT';
 342
 343     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 344
 345     # accumulate directories but process files as they appear
 346     arg: foreach(@args) {
 347         #  Special fast case: full filepath requires no search
 348         if ($Is_VMS && m%[:>/\]]% && -f $_) {
 349             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 350             last arg unless wantarray;
 351             next;
 352         }
 353         elsif ($Is_MacOS) {
 354             if (m/:/ && -f $_) {
 355                 push(@found,$_);
 356                 last arg unless wantarray;
 357             }
 358         }
 359         elsif (m:/: && -f $_ && !$do_expand) {
 360             push(@found,$_);
 361             last arg unless wantarray;
 362             next;
 363         }
 364
 365         # Deal with directories first:
 366         #  Using a -L prefix is the preferred option (faster and more robust)
 367         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 368
 369         if ($Is_MacOS) {
 370             #  Otherwise we try to try to spot directories by a heuristic
 371             #  (this is a more complicated issue than it first appears)
 372             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 373             #  Only files should get this far...
 374             my(@names, $name);    # what filenames to look for
 375             s/^-l//;
 376             push(@names, $_);
 377             foreach $dir (@dirs, @dl_library_path) {
 378                 next unless -d $dir;
 379                 $dir =~ s/^([^:]+)$/:$1/;
 380                 $dir =~ s/:$//;
 381                 foreach $name (@names) {
 382                     my($file) = "$dir:$name";
 383                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 384                     if (-f $file) {
 385                         push(@found, $file);
 386                         next arg; # no need to look any further
 387                     }
 388                 }
 389             }
 390             next;
 391         }
 392
 393         #  Otherwise we try to try to spot directories by a heuristic
 394         #  (this is a more complicated issue than it first appears)
 395         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 396
 397         # VMS: we may be using native VMS directory syntax instead of
 398         # Unix emulation, so check this as well
 399         if ($Is_VMS && /[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 400
 401         #  Only files should get this far...
 402         my(@names, $name);    # what filenames to look for
 403         if (m:-l: ) {          # convert -lname to appropriate library name
 404             s/-l//;
 405             push(@names,"lib$_.$dl_so");
 406             push(@names,"lib$_.a");
 407         } else {                # Umm, a bare name. Try various alternatives:
 408             # these should be ordered with the most likely first
 409             push(@names,"$_.$dl_ext")    unless m/\.$dl_ext$/o;
 410             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 411             push(@names,"lib$_.$dl_so")  unless m:/:;
 412             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 413             push(@names, $_);
 414         }
 415         foreach $dir (@dirs, @dl_library_path) {
 416             next unless -d $dir;
 417             chop($dir = VMS::Filespec::unixpath($dir)) if $Is_VMS;
 418             foreach $name (@names) {
 419                 my($file) = "$dir/$name";
 420                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 421                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 422                 #$file = _check_file($file);
 423                 if ($file) {
 424                     push(@found, $file);
 425                     next arg; # no need to look any further
 426                 }
 427             }
 428         }
 429     }
 430     if ($dl_debug) {
 431         foreach(@dirs) {
 432             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 433         }
 434         print STDERR "dl_findfile found: @found\n";
 435     }
 436     return $found[0] unless wantarray;
 437     @found;
 438 }
 439
 440
 441 sub dl_expandspec {
 442     my($spec) = @_;
 443     # Optional function invoked if DynaLoader.pm sets $do_expand.
 444     # Most systems do not require or use this function.
 445     # Some systems may implement it in the dl_*.xs file in which case
 446     # this autoload version will not be called but is harmless.
 447
 448     # This function is designed to deal with systems which treat some
 449     # 'filenames' in a special way. For example VMS 'Logical Names'
 450     # (something like unix environment variables - but different).
 451     # This function should recognise such names and expand them into
 452     # full file paths.
 453     # Must return undef if $spec is invalid or file does not exist.
 454
 455     my $file = $spec; # default output to input
 456
 457     if ($Is_VMS) { # dl_expandspec should be defined in dl_vms.xs
 458         require Carp;
 459         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 460     } else {
 461         return undef unless -f $file;
 462     }
 463     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 464     $file;
 465 }
 466
 467 sub dl_find_symbol_anywhere
 468 {
 469     my $sym = shift;
 470     my $libref;
 471     foreach $libref (@dl_librefs) {
 472         my $symref = dl_find_symbol($libref,$sym);
 473         return $symref if $symref;
 474     }
 475     return undef;
 476 }
 477
 478 =head1 NAME
 479
 480 DynaLoader - Dynamically load C libraries into Perl code
 481
 482 dl_error(), dl_findfile(), dl_expandspec(), dl_load_file(), dl_unload_file(), dl_find_symbol(), dl_find_symbol_anywhere(), dl_undef_symbols(), dl_install_xsub(), dl_load_flags(), bootstrap() - routines used by DynaLoader modules
 483
 484 =head1 SYNOPSIS
 485
 486     package YourPackage;
 487     require DynaLoader;
 488     @ISA = qw(... DynaLoader ...);
 489     bootstrap YourPackage;
 490
 491     # optional method for 'global' loading
 492     sub dl_load_flags { 0x01 }
 493
 494
 495 =head1 DESCRIPTION
 496
 497 This document defines a standard generic interface to the dynamic
 498 linking mechanisms available on many platforms.  Its primary purpose is
 499 to implement automatic dynamic loading of Perl modules.
 500
 501 This document serves as both a specification for anyone wishing to
 502 implement the DynaLoader for a new platform and as a guide for
 503 anyone wishing to use the DynaLoader directly in an application.
 504
 505 The DynaLoader is designed to be a very simple high-level
 506 interface that is sufficiently general to cover the requirements
 507 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 508
 509 It is also hoped that the interface will cover the needs of OS/2, NT
 510 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 511
 512 It must be stressed that the DynaLoader, by itself, is practically
 513 useless for accessing non-Perl libraries because it provides almost no
 514 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 515 library function or supplying arguments.  A C::DynaLib module
 516 is available from CPAN sites which performs that function for some
 517 common system types.
 518
 519 DynaLoader Interface Summary
 520
 521   @dl_library_path
 522   @dl_resolve_using
 523   @dl_require_symbols
 524   $dl_debug
 525   @dl_librefs
 526   @dl_modules
 527                                                   Implemented in:
 528   bootstrap($modulename)                               Perl
 529   @filepaths = dl_findfile(@names)                     Perl
 530   $flags = $modulename->dl_load_flags                  Perl
 531   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 532
 533   $libref  = dl_load_file($filename, $flags)           C
 534   $status  = dl_unload_file($libref)                   C
 535   $symref  = dl_find_symbol($libref, $symbol)          C
 536   @symbols = dl_undef_symbols()                        C
 537   dl_install_xsub($name, $symref [, $filename])        C
 538   $message = dl_error                                  C
 539
 540 =over 4
 541
 542 =item @dl_library_path
 543
 544 The standard/default list of directories in which dl_findfile() will
 545 search for libraries etc.  Directories are searched in order:
 546 $dl_library_path[0], [1], ... etc
 547
 548 @dl_library_path is initialised to hold the list of 'normal' directories
 549 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 550 ensure portability across a wide range of platforms.
 551
 552 @dl_library_path should also be initialised with any other directories
 553 that can be determined from the environment at runtime (such as
 554 LD_LIBRARY_PATH for SunOS).
 555
 556 After initialisation @dl_library_path can be manipulated by an
 557 application using push and unshift before calling dl_findfile().
 558 Unshift can be used to add directories to the front of the search order
 559 either to save search time or to override libraries with the same name
 560 in the 'normal' directories.
 561
 562 The load function that dl_load_file() calls may require an absolute
 563 pathname.  The dl_findfile() function and @dl_library_path can be
 564 used to search for and return the absolute pathname for the
 565 library/object that you wish to load.
 566
 567 =item @dl_resolve_using
 568
 569 A list of additional libraries or other shared objects which can be
 570 used to resolve any undefined symbols that might be generated by a
 571 later call to load_file().
 572
 573 This is only required on some platforms which do not handle dependent
 574 libraries automatically.  For example the Socket Perl extension
 575 library (F<auto/Socket/Socket.so>) contains references to many socket
 576 functions which need to be resolved when it's loaded.  Most platforms
 577 will automatically know where to find the 'dependent' library (e.g.,
 578 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 579 location of the dependent library explicitly.  Use @dl_resolve_using
 580 for this.
 581
 582 Example usage:
 583
 584     @dl_resolve_using = dl_findfile('-lsocket');
 585
 586 =item @dl_require_symbols
 587
 588 A list of one or more symbol names that are in the library/object file
 589 to be dynamically loaded.  This is only required on some platforms.
 590
 591 =item @dl_librefs
 592
 593 An array of the handles returned by successful calls to dl_load_file(),
 594 made by bootstrap, in the order in which they were loaded.
 595 Can be used with dl_find_symbol() to look for a symbol in any of
 596 the loaded files.
 597
 598 =item @dl_modules
 599
 600 An array of module (package) names that have been bootstrap'ed.
 601
 602 =item dl_error()
 603
 604 Syntax:
 605
 606     $message = dl_error();
 607
 608 Error message text from the last failed DynaLoader function.  Note
 609 that, similar to errno in unix, a successful function call does not
 610 reset this message.
 611
 612 Implementations should detect the error as soon as it occurs in any of
 613 the other functions and save the corresponding message for later
 614 retrieval.  This will avoid problems on some platforms (such as SunOS)
 615 where the error message is very temporary (e.g., dlerror()).
 616
 617 =item $dl_debug
 618
 619 Internal debugging messages are enabled when $dl_debug is set true.
 620 Currently setting $dl_debug only affects the Perl side of the
 621 DynaLoader.  These messages should help an application developer to
 622 resolve any DynaLoader usage problems.
 623
 624 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 625
 626 For the DynaLoader developer/porter there is a similar debugging
 627 variable added to the C code (see dlutils.c) and enabled if Perl was
 628 built with the B<-DDEBUGGING> flag.  This can also be set via the
 629 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 630 higher for more.
 631
 632 =item dl_findfile()
 633
 634 Syntax:
 635
 636     @filepaths = dl_findfile(@names)
 637
 638 Determine the full paths (including file suffix) of one or more
 639 loadable files given their generic names and optionally one or more
 640 directories.  Searches directories in @dl_library_path by default and
 641 returns an empty list if no files were found.
 642
 643 Names can be specified in a variety of platform independent forms.  Any
 644 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 645 an appropriate suffix for the platform.
 646
 647 If a name does not already have a suitable prefix and/or suffix then
 648 the corresponding file will be searched for by trying combinations of
 649 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 650 and "$name".
 651
 652 If any directories are included in @names they are searched before
 653 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 654 names are treated as filenames to be searched for.
 655
 656 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 657
 658 Example:
 659
 660     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 661
 662
 663 =item dl_expandspec()
 664
 665 Syntax:
 666
 667     $filepath = dl_expandspec($spec)
 668
 669 Some unusual systems, such as VMS, require special filename handling in
 670 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 671
 672 To support these systems a dl_expandspec() function can be implemented
 673 either in the F<dl_*.xs> file or code can be added to the autoloadable
 674 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 675 more information.
 676
 677 =item dl_load_file()
 678
 679 Syntax:
 680
 681     $libref = dl_load_file($filename, $flags)
 682
 683 Dynamically load $filename, which must be the path to a shared object
 684 or library.  An opaque 'library reference' is returned as a handle for
 685 the loaded object.  Returns undef on error.
 686
 687 The $flags argument to alters dl_load_file behaviour.
 688 Assigned bits:
 689
 690  0x01  make symbols available for linking later dl_load_file's.
 691        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 692        (ignored under VMS; this is a normal part of image linking)
 693
 694 (On systems that provide a handle for the loaded object such as SunOS
 695 and HPUX, $libref will be that handle.  On other systems $libref will
 696 typically be $filename or a pointer to a buffer containing $filename.
 697 The application should not examine or alter $libref in any way.)
 698
 699 This is the function that does the real work.  It should use the
 700 current values of @dl_require_symbols and @dl_resolve_using if required.
 701
 702     SunOS: dlopen($filename)
 703     HP-UX: shl_load($filename)
 704     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 705     NeXT:  rld_load($filename, @dl_resolve_using)
 706     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 707
 708 (The dlopen() function is also used by Solaris and some versions of
 709 Linux, and is a common choice when providing a "wrapper" on other
 710 mechanisms as is done in the OS/2 port.)
 711
 712 =item dl_unload_file()
 713
 714 Syntax:
 715
 716     $status = dl_unload_file($libref)
 717
 718 Dynamically unload $libref, which must be an opaque 'library reference' as
 719 returned from dl_load_file.  Returns one on success and zero on failure.
 720
 721 This function is optional and may not necessarily be provided on all platforms.
 722 If it is defined, it is called automatically when the interpreter exits for
 723 every shared object or library loaded by DynaLoader::bootstrap.  All such
 724 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 725 loads the libraries.  The files are unloaded in last-in, first-out order.
 726
 727 This unloading is usually necessary when embedding a shared-object perl (e.g.
 728 one configured with -Duseshrplib) within a larger application, and the perl
 729 interpreter is created and destroyed several times within the lifetime of the
 730 application.  In this case it is possible that the system dynamic linker will
 731 unload and then subsequently reload the shared libperl without relocating any
 732 references to it from any files DynaLoaded by the previous incarnation of the
 733 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 734 a now invalid 'ghost' of the libperl shared object, causing apparently random
 735 memory corruption and crashes.  This behaviour is most commonly seen when using
 736 Apache and mod_perl built with the APXS mechanism.
 737
 738     SunOS: dlclose($libref)
 739     HP-UX: ???
 740     Linux: ???
 741     NeXT:  ???
 742     VMS:   ???
 743
 744 (The dlclose() function is also used by Solaris and some versions of
 745 Linux, and is a common choice when providing a "wrapper" on other
 746 mechanisms as is done in the OS/2 port.)
 747
 748 =item dl_loadflags()
 749
 750 Syntax:
 751
 752     $flags = dl_loadflags $modulename;
 753
 754 Designed to be a method call, and to be overridden by a derived class
 755 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 756 DynaLoader itself returns 0, which produces standard behavior from
 757 dl_load_file().
 758
 759 =item dl_find_symbol()
 760
 761 Syntax:
 762
 763     $symref = dl_find_symbol($libref, $symbol)
 764
 765 Return the address of the symbol $symbol or C<undef> if not found.  If the
 766 target system has separate functions to search for symbols of different
 767 types then dl_find_symbol() should search for function symbols first and
 768 then other types.
 769
 770 The exact manner in which the address is returned in $symref is not
 771 currently defined.  The only initial requirement is that $symref can
 772 be passed to, and understood by, dl_install_xsub().
 773
 774     SunOS: dlsym($libref, $symbol)
 775     HP-UX: shl_findsym($libref, $symbol)
 776     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 777     NeXT:  rld_lookup("_$symbol")
 778     VMS:   lib$find_image_symbol($libref,$symbol)
 779
 780
 781 =item dl_find_symbol_anywhere()
 782
 783 Syntax:
 784
 785     $symref = dl_find_symbol_anywhere($symbol)
 786
 787 Applies dl_find_symbol() to the members of @dl_librefs and returns
 788 the first match found.
 789
 790 =item dl_undef_symbols()
 791
 792 Example
 793
 794     @symbols = dl_undef_symbols()
 795
 796 Return a list of symbol names which remain undefined after load_file().
 797 Returns C<()> if not known.  Don't worry if your platform does not provide
 798 a mechanism for this.  Most do not need it and hence do not provide it,
 799 they just return an empty list.
 800
 801
 802 =item dl_install_xsub()
 803
 804 Syntax:
 805
 806     dl_install_xsub($perl_name, $symref [, $filename])
 807
 808 Create a new Perl external subroutine named $perl_name using $symref as
 809 a pointer to the function which implements the routine.  This is simply
 810 a direct call to newXSUB().  Returns a reference to the installed
 811 function.
 812
 813 The $filename parameter is used by Perl to identify the source file for
 814 the function if required by die(), caller() or the debugger.  If
 815 $filename is not defined then "DynaLoader" will be used.
 816
 817
 818 =item bootstrap()
 819
 820 Syntax:
 821
 822 bootstrap($module)
 823
 824 This is the normal entry point for automatic dynamic loading in Perl.
 825
 826 It performs the following actions:
 827
 828 =over 8
 829
 830 =item *
 831
 832 locates an auto/$module directory by searching @INC
 833
 834 =item *
 835
 836 uses dl_findfile() to determine the filename to load
 837
 838 =item *
 839
 840 sets @dl_require_symbols to C<("boot_$module")>
 841
 842 =item *
 843
 844 executes an F<auto/$module/$module.bs> file if it exists
 845 (typically used to add to @dl_resolve_using any files which
 846 are required to load the module on the current platform)
 847
 848 =item *
 849
 850 calls dl_load_flags() to determine how to load the file.
 851
 852 =item *
 853
 854 calls dl_load_file() to load the file
 855
 856 =item *
 857
 858 calls dl_undef_symbols() and warns if any symbols are undefined
 859
 860 =item *
 861
 862 calls dl_find_symbol() for "boot_$module"
 863
 864 =item *
 865
 866 calls dl_install_xsub() to install it as "${module}::bootstrap"
 867
 868 =item *
 869
 870 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 871 it uses the function reference returned by dl_install_xsub for speed)
 872
 873 =back
 874
 875 =back
 876
 877
 878 =head1 AUTHOR
 879
 880 Tim Bunce, 11 August 1994.
 881
 882 This interface is based on the work and comments of (in no particular
 883 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 884 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 885
 886 Larry Wall designed the elegant inherited bootstrap mechanism and
 887 implemented the first Perl 5 dynamic loader using it.
 888
 889 Solaris global loading added by Nick Ing-Simmons with design/coding
 890 assistance from Tim Bunce, January 1996.
 891
 892 =cut
 893 EOT
 894
 895 close OUT or die $!;
 896