t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still current
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17 # Measure the elapsed wallclock time.
  18 my $t0 = time();
  19
  20 # If we're doing deparse tests, ignore failures for these
  21 my $deparse_failures;
  22
  23 # And skip even running these
  24 my $deparse_skips;
  25
  26 # directories with special sets of test switches
  27 my %dir_to_switch =
  28     (base => '',
  29      comp => '',
  30      run => '',
  31      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  32      );
  33
  34 # "not absolute" is the default, as it saves some fakery within TestInit
  35 # which can perturb tests, and takes CPU. Working with the upstream author of
  36 # any of these, to figure out how to remove them from this list, considered
  37 # "a good thing".
  38 my %abs = (
  39            '../cpan/Archive-Tar' => 1,
  40            '../cpan/AutoLoader' => 1,
  41            '../cpan/CPAN' => 1,
  42            '../cpan/Devel-PPPort' => 1,
  43            '../cpan/Encode' => 1,
  44            '../cpan/ExtUtils-Command' => 1,
  45            '../cpan/ExtUtils-Constant' => 1,
  46            '../cpan/ExtUtils-Install' => 1,
  47            '../cpan/ExtUtils-MakeMaker' => 1,
  48            '../cpan/ExtUtils-Manifest' => 1,
  49            '../cpan/File-Fetch' => 1,
  50            '../cpan/IPC-Cmd' => 1,
  51            '../cpan/IPC-SysV' => 1,
  52            '../cpan/Locale-Codes' => 1,
  53            '../cpan/Module-Load' => 1,
  54            '../cpan/Module-Load-Conditional' => 1,
  55            '../cpan/Parse-CPAN-Meta' => 1,
  56            '../cpan/Pod-Simple' => 1,
  57            '../cpan/Test-Simple' => 1,
  58            '../cpan/podlators' => 1,
  59            '../dist/Cwd' => 1,
  60            '../dist/ExtUtils-ParseXS' => 1,
  61            '../dist/Tie-File' => 1,
  62           );
  63
  64 my %temp_no_core =
  65     ('../cpan/B-Debug' => 1,
  66      '../cpan/Compress-Raw-Bzip2' => 1,
  67      '../cpan/Compress-Raw-Zlib' => 1,
  68      '../cpan/Devel-PPPort' => 1,
  69      '../cpan/Getopt-Long' => 1,
  70      '../cpan/IO-Compress' => 1,
  71      '../cpan/MIME-Base64' => 1,
  72      '../cpan/parent' => 1,
  73      '../cpan/Parse-CPAN-Meta' => 1,
  74      '../cpan/Pod-Simple' => 1,
  75      '../cpan/podlators' => 1,
  76      '../cpan/Test-Simple' => 1,
  77      '../cpan/Tie-RefHash' => 1,
  78      '../cpan/Unicode-Collate' => 1,
  79      '../cpan/Unicode-Normalize' => 1,
  80     );
  81
  82 # delete env vars that may influence the results
  83 # but allow override via *_TEST env var if wanted
  84 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  85 my @bad_env_vars = qw(
  86     PERL5LIB PERLLIB PERL5OPT
  87     PERL_YAML_BACKEND PERL_JSON_BACKEND
  88 );
  89
  90 for my $envname (@bad_env_vars) {
  91     my $override = $ENV{"${envname}_TEST"};
  92     if (defined $override) {
  93         warn "$0: $envname=$override\n";
  94         $ENV{$envname} = $override;
  95     }
  96     else {
  97         delete $ENV{$envname};
  98     }
  99 }
 100
 101 # Location to put the Valgrind log.
 102 our $Valgrind_Log;
 103
 104 my %skip = (
 105             '.' => 1,
 106             '..' => 1,
 107             'CVS' => 1,
 108             'RCS' => 1,
 109             'SCCS' => 1,
 110             '.svn' => 1,
 111            );
 112
 113
 114 if ($::do_nothing) {
 115     return 1;
 116 }
 117
 118 $| = 1;
 119
 120 # for testing TEST only
 121 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 122 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 123
 124 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 125 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 126 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 127
 128 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 129 # can't rely on require working.
 130 {
 131     my @argv = ();
 132     foreach my $idx (0..$#ARGV) {
 133         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 134         $::benchmark = 1 if $1 eq 'benchmark';
 135         $::core    = 1 if $1 eq 'core';
 136         $::verbose = 1 if $1 eq 'v';
 137         $::torture = 1 if $1 eq 'torture';
 138         $::with_utf8 = 1 if $1 eq 'utf8';
 139         $::with_utf16 = 1 if $1 eq 'utf16';
 140         $::taintwarn = 1 if $1 eq 'taintwarn';
 141         if ($1 =~ /^deparse(,.+)?$/) {
 142             $::deparse = 1;
 143             $::deparse_opts = $1;
 144             _process_deparse_config();
 145         }
 146     }
 147     @ARGV = @argv;
 148 }
 149
 150 chdir 't' if -f 't/TEST';
 151 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 152     @INC = '../lib';
 153 }
 154
 155 die "You need to run \"make test\" first to set things up.\n"
 156   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 157
 158 # check leakage for embedders
 159 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 160 # check existence of all symbols
 161 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
 162
 163 $ENV{EMXSHELL} = 'sh';        # For OS/2
 164
 165 if ($show_elapsed_time) { require Time::HiRes }
 166 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 167
 168 # Roll your own File::Find!
 169 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
 170 sub _find_files {
 171     my($patt, @dirs) = @_;
 172     for my $dir (@dirs) {
 173         opendir DIR, $dir or die "Trouble opening $dir: $!";
 174         foreach my $f (sort { $a cmp $b } readdir DIR) {
 175             next if $skip{$f};
 176
 177             my $fullpath = "$dir/$f";
 178
 179             if (-d $fullpath) {
 180                 _find_files($patt, $fullpath);
 181             } elsif ($f =~ /$patt/) {
 182                 push @found, $fullpath;
 183             }
 184         }
 185     }
 186     @found;
 187 }
 188
 189
 190 # Scan the text of the test program to find switches and special options
 191 # we might need to apply.
 192 sub _scan_test {
 193     my($test, $type) = @_;
 194
 195     open(my $script, "<", $test) or die "Can't read $test.\n";
 196     my $first_line = <$script>;
 197
 198     $first_line =~ tr/\0//d if $::with_utf16;
 199
 200     my $switch = "";
 201     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 202         $switch = "-$1";
 203     } else {
 204         if ($::taintwarn) {
 205             # not all tests are expected to pass with this option
 206             $switch = '-t';
 207         } else {
 208             $switch = '';
 209         }
 210     }
 211
 212     my $file_opts = "";
 213     if ($type eq 'deparse') {
 214         # Look for #line directives which change the filename
 215         while (<$script>) {
 216             $file_opts = $file_opts . ",-f$3$4"
 217               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 218         }
 219     }
 220
 221     close $script;
 222
 223     my $perl = './perl';
 224     my $lib  = '../lib';
 225     my $run_dir;
 226     my $return_dir;
 227
 228     $test =~ /^(.+)\/[^\/]+/;
 229     my $dir = $1;
 230     my $testswitch = $dir_to_switch{$dir};
 231     if (!defined $testswitch) {
 232         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 233             $run_dir = $1;
 234             $return_dir = '../../t';
 235             $lib = '../../lib';
 236             $perl = '../../t/perl';
 237             $testswitch = "-I../.. -MTestInit=U2T";
 238             if ($2 eq 'cpan' || $2 eq 'dist') {
 239                 if($abs{$run_dir}) {
 240                     $testswitch = $testswitch . ',A';
 241                 }
 242                 if ($temp_no_core{$run_dir}) {
 243                     $testswitch = $testswitch . ',NC';
 244                 }
 245             }
 246         } elsif ($test =~ m!^\.\./lib!) {
 247             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 248         } else {
 249             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 250         }
 251     }
 252
 253     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 254
 255     my %options = (
 256         perl => $perl,
 257         lib => $lib,
 258         test => $test,
 259         run_dir => $run_dir,
 260         return_dir => $return_dir,
 261         testswitch => $testswitch,
 262         utf8 => $utf8,
 263         file => $file_opts,
 264         switch => $switch,
 265     );
 266
 267     return \%options;
 268 }
 269
 270 sub _cmd {
 271     my($options, $type) = @_;
 272
 273     my $test = $options->{test};
 274
 275     my $cmd;
 276     if ($type eq 'deparse') {
 277         my $perl = "$options->{perl} $options->{testswitch}";
 278         my $lib = $options->{lib};
 279
 280         $cmd = (
 281           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 282           "-l$::deparse_opts$options->{file} ".
 283           "$test > $test.dp ".
 284           "&& $perl $options->{switch} -I$lib $test.dp"
 285         );
 286     }
 287     elsif ($type eq 'perl') {
 288         my $perl = $options->{perl};
 289         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 290
 291         if ($ENV{PERL_VALGRIND}) {
 292             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 293             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 294             if ($options->{run_dir}) {
 295                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 296             }
 297             my $vg_opts = $ENV{VG_OPTS}
 298                //   "--log-file=$Valgrind_Log "
 299                   . "--suppressions=$perl_supp --leak-check=yes "
 300                   . "--leak-resolution=high --show-reachable=yes "
 301                   . "--num-callers=50 --track-origins=yes";
 302             # Force logging if not asked for (so cachegrind reporting works below)
 303             if ($vg_opts !~ /--log-file/) {
 304                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
 305             }
 306             $perl = "$valgrind_exe $vg_opts $perl";
 307         }
 308
 309         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 310         $cmd = $perl . _quote_args($args) . " $test $redir";
 311     }
 312     return $cmd;
 313 }
 314
 315 sub _before_fork {
 316     my ($options) = @_;
 317
 318     if ($options->{run_dir}) {
 319         my $run_dir = $options->{run_dir};
 320         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 321     }
 322
 323     # Remove previous valgrind output otherwise it will interfere
 324     my $test = $options->{test};
 325
 326     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 327
 328     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
 329         unlink $Valgrind_Log
 330             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 331     }
 332
 333     return;
 334 }
 335
 336 sub _after_fork {
 337     my ($options) = @_;
 338
 339     if ($options->{return_dir}) {
 340         my $return_dir = $options->{return_dir};
 341         chdir $return_dir
 342            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 343     }
 344
 345     return;
 346 }
 347
 348 sub _run_test {
 349     my ($test, $type) = @_;
 350
 351     my $options = _scan_test($test, $type);
 352     # $test might have changed if we're in ext/Foo, so don't use it anymore
 353     # from now on. Use $options->{test} instead.
 354
 355     _before_fork($options);
 356
 357     my $cmd = _cmd($options, $type);
 358
 359     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 360
 361     _after_fork($options);
 362
 363     # Our environment may force us to use UTF-8, but we can't be sure that
 364     # anything we're reading from will be generating (well formed) UTF-8
 365     # This may not be the best way - possibly we should unset ${^OPEN} up
 366     # top?
 367     binmode $results;
 368
 369     return $results;
 370 }
 371
 372 sub _quote_args {
 373     my ($args) = @_;
 374     my $argstring = '';
 375
 376     foreach (split(/\s+/,$args)) {
 377        # In VMS protect with doublequotes because otherwise
 378        # DCL will lowercase -- unless already doublequoted.
 379        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 380        $argstring = $argstring . ' ' . $_;
 381     }
 382     return $argstring;
 383 }
 384
 385 sub _populate_hash {
 386     return unless defined $_[0];
 387     return map {$_, 1} split /\s+/, $_[0];
 388 }
 389
 390 sub _tests_from_manifest {
 391     my ($extensions, $known_extensions) = @_;
 392     my %skip;
 393     my %extensions = _populate_hash($extensions);
 394     my %known_extensions = _populate_hash($known_extensions);
 395
 396     foreach (keys %known_extensions) {
 397         $skip{$_} = 1 unless $extensions{$_};
 398     }
 399
 400     my @results;
 401     my $mani = '../MANIFEST';
 402     if (open(MANI, $mani)) {
 403         while (<MANI>) {
 404             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 405                 my $t = $1;
 406                 my $extension = $2;
 407                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 408                     if (defined $extension) {
 409                         $extension =~ s!/t(:?/\S+)*$!!;
 410                         # XXX Do I want to warn that I'm skipping these?
 411                         next if $skip{$extension};
 412                         my $flat_extension = $extension;
 413                         $flat_extension =~ s!-!/!g;
 414                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 415                     }
 416                     my $path = "../$t";
 417                     push @results, $path;
 418                     $::path_to_name{$path} = $t;
 419                 }
 420             }
 421         }
 422         close MANI;
 423     } else {
 424         warn "$0: cannot open $mani: $!\n";
 425     }
 426     return @results;
 427 }
 428
 429 unless (@ARGV) {
 430     # base first, as TEST bails out if that can't run
 431     # then comp, to validate that require works
 432     # then run, to validate that -M works
 433     # then we know we can -MTestInit for everything else, making life simpler
 434     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro perf)) {
 435         _find_tests($dir);
 436     }
 437     unless ($::core) {
 438         _find_tests('porting');
 439         _find_tests("lib");
 440     }
 441     # Config.pm may be broken for make minitest. And this is only a refinement
 442     # for skipping tests on non-default builds, so it is allowed to fail.
 443     # What we want to to is make a list of extensions which we did not build.
 444     my $configsh = '../config.sh';
 445     my ($extensions, $known_extensions);
 446     if (-f $configsh) {
 447         open FH, $configsh or die "Can't open $configsh: $!";
 448         while (<FH>) {
 449             if (/^extensions=['"](.*)['"]$/) {
 450                 $extensions = $1;
 451             }
 452             elsif (/^known_extensions=['"](.*)['"]$/) {
 453                 $known_extensions = $1;
 454             }
 455         }
 456         if (!defined $known_extensions) {
 457             warn "No known_extensions line found in $configsh";
 458         }
 459         if (!defined $extensions) {
 460             warn "No extensions line found in $configsh";
 461         }
 462     }
 463     # The "complex" constructions of list return from a subroutine, and push of
 464     # a list, might fail if perl is really hosed, but they aren't needed for
 465     # make minitest, and the building of extensions will likely also fail if
 466     # something is that badly wrong.
 467     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 468     unless ($::core) {
 469         _find_tests('japh') if $::torture;
 470         _find_tests('benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 471         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
 472     }
 473 }
 474
 475 if ($::deparse) {
 476     _testprogs('deparse', '',   @ARGV);
 477 }
 478 elsif ($::with_utf16) {
 479     for my $e (0, 1) {
 480         for my $b (0, 1) {
 481             print STDERR "# ENDIAN $e BOM $b\n";
 482             my @UARGV;
 483             for my $a (@ARGV) {
 484                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 485                 my $f = $e ? "v" : "n";
 486                 push @UARGV, $u;
 487                 unlink($u);
 488                 if (open(A, $a)) {
 489                     if (open(U, ">$u")) {
 490                         print U pack("$f", 0xFEFF) if $b;
 491                         while (<A>) {
 492                             print U pack("$f*", unpack("C*", $_));
 493                         }
 494                         close(U);
 495                     }
 496                     close(A);
 497                 }
 498             }
 499             _testprogs('perl', '', @UARGV);
 500             unlink(@UARGV);
 501         }
 502     }
 503 }
 504 else {
 505     _testprogs('perl',    '',   @ARGV);
 506 }
 507
 508 sub _testprogs {
 509     my ($type, $args, @tests) = @_;
 510
 511     print <<'EOT' if ($type eq 'deparse');
 512 ------------------------------------------------------------------------------
 513 TESTING DEPARSER
 514 ------------------------------------------------------------------------------
 515 EOT
 516
 517     $::bad_files = 0;
 518
 519     foreach my $t (@tests) {
 520       unless (exists $::path_to_name{$t}) {
 521         my $tname = "t/$t";
 522         $::path_to_name{$t} = $tname;
 523       }
 524     }
 525     my $maxlen = 0;
 526     foreach (@::path_to_name{@tests}) {
 527         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 528         my $len = length ;
 529         $maxlen = $len if $len > $maxlen;
 530     }
 531     # + 3 : we want three dots between the test name and the "ok"
 532     my $dotdotdot = $maxlen + 3 ;
 533     my $grind_ct = 0;           # count of non-empty valgrind reports
 534     my $total_files = @tests;
 535     my $good_files = 0;
 536     my $tested_files  = 0;
 537     my $totmax = 0;
 538     my %failed_tests;
 539     my $toolnm;         # valgrind, cachegrind, perf
 540
 541     while (my $test = shift @tests) {
 542         my ($test_start_time, @starttimes) = 0;
 543         if ($show_elapsed_time) {
 544             $test_start_time = Time::HiRes::time();
 545             # times() reports usage by TEST, but we want usage of each
 546             # testprog it calls, so record accumulated times now,
 547             # subtract them out afterwards.  Ideally, we'd take times
 548             # in BEGIN/END blocks (giving better visibility of self vs
 549             # children of each testprog), but that would require some
 550             # IPC to send results back here, or a completely different
 551             # collection scheme (Storable isn't tuned for incremental use)
 552             @starttimes = times;
 553         }
 554         if ($test =~ /^$/) {
 555             next;
 556         }
 557         if ($type eq 'deparse' && $test =~ $deparse_skips) {
 558             next;
 559         }
 560         my $te = $::path_to_name{$test} . '.'
 561                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 562
 563         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 564             print $te;
 565             $te = '';
 566         }
 567
 568         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 569
 570         my $results = _run_test($test, $type);
 571
 572         my $failure;
 573         my $next = 0;
 574         my $seen_leader = 0;
 575         my $seen_ok = 0;
 576         my $trailing_leader = 0;
 577         my $max;
 578         my %todo;
 579         while (<$results>) {
 580             next if /^\s*$/; # skip blank lines
 581             if (/^1..$/ && ($^O eq 'VMS')) {
 582                 # VMS pipe bug inserts blank lines.
 583                 my $l2 = <$results>;
 584                 if ($l2 =~ /^\s*$/) {
 585                     $l2 = <$results>;
 586                 }
 587                 $_ = '1..' . $l2;
 588             }
 589             if ($::verbose) {
 590                 print $_;
 591             }
 592             unless (/^\#/) {
 593                 if ($trailing_leader) {
 594                     # shouldn't be anything following a postfix 1..n
 595                     $failure = 'FAILED--extra output after trailing 1..n';
 596                     last;
 597                 }
 598                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 599                     if ($seen_leader) {
 600                         $failure = 'FAILED--seen duplicate leader';
 601                         last;
 602                     }
 603                     $max = $1;
 604                     %todo = map { $_ => 1 } split / /, $3 if $3;
 605                     $totmax = $totmax + $max;
 606                     $tested_files = $tested_files + 1;
 607                     if ($seen_ok) {
 608                         # 1..n appears at end of file
 609                         $trailing_leader = 1;
 610                         if ($next != $max) {
 611                             $failure = "FAILED--expected $max tests, saw $next";
 612                             last;
 613                         }
 614                     }
 615                     else {
 616                         $next = 0;
 617                     }
 618                     $seen_leader = 1;
 619                 }
 620                 else {
 621                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 622                         unless ($seen_leader) {
 623                             unless ($seen_ok) {
 624                                 $next = 0;
 625                             }
 626                         }
 627                         $seen_ok = 1;
 628                         $next = $next + 1;
 629                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 630                         $num = $next unless $num;
 631
 632                         if ($num == $next) {
 633
 634                             # SKIP is essentially the same as TODO for t/TEST
 635                             # this still conforms to TAP:
 636                             # http://testanything.org/wiki/index.php/TAP_specification
 637                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 638                             $istodo = 1 if $todo{$num};
 639
 640                             if( $not && !$istodo ) {
 641                                 $failure = "FAILED at test $num";
 642                                 last;
 643                             }
 644                         }
 645                         else {
 646                             $failure ="FAILED--expected test $next, saw test $num";
 647                             last;
 648                         }
 649                     }
 650                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 651                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 652                     }
 653                     else {
 654                         # module tests are allowed extra output,
 655                         # because Test::Harness allows it
 656                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 657                         $failure = "FAILED--unexpected output at test $next";
 658                         last;
 659                     }
 660                 }
 661             }
 662         }
 663         close $results;
 664
 665         if (not defined $failure) {
 666             $failure = 'FAILED--no leader found' unless $seen_leader;
 667         }
 668
 669         _check_valgrind(\$toolnm, \$grind_ct, \$test);
 670
 671         if ($type eq 'deparse' && !$ENV{KEEP_DEPARSE_FILES}) {
 672             unlink "./$test.dp";
 673         }
 674         if (not defined $failure and $next != $max) {
 675             $failure="FAILED--expected $max tests, saw $next";
 676         }
 677
 678         if( !defined $failure  # don't mask a test failure
 679             and $? )
 680         {
 681             $failure = "FAILED--non-zero wait status: $?";
 682         }
 683
 684         # Deparse? Should it have passed or failed?
 685         if ($type eq 'deparse' && $test =~ $deparse_failures) {
 686             if (!$failure) {
 687                 # Wait, it didn't fail? Great news! Tell someone!
 688                 $failure = "FAILED--all tests passed but test should have failed";
 689             } else {
 690                 # Bah, still failing. Mask it.
 691                 print "${te}skipped\n";
 692                 $tested_files = $tested_files - 1;
 693                 next;
 694             }
 695         }
 696
 697         if (defined $failure) {
 698             print "${te}$failure\n";
 699             $::bad_files = $::bad_files + 1;
 700             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
 701                 # Die if running under minitest (no DynaLoader).  Otherwise
 702                 # keep going, as  we know that Perl basically works, or we
 703                 # would not have been able to actually compile it all the way.
 704                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
 705             }
 706             $failed_tests{$test} = 1;
 707         }
 708         else {
 709             if ($max) {
 710                 my ($elapsed, $etms) = ("", 0);
 711                 if ( $show_elapsed_time ) {
 712                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 713                     $elapsed = sprintf(" %8.0f ms", $etms);
 714
 715                     my (@endtimes) = times;
 716                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 717                     splice @endtimes, 0, 2;    # drop self/harness times
 718                     $_ *= 1000 for @endtimes;  # and scale to ms
 719                     $timings{$test} = [$etms,@endtimes];
 720                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 721                 }
 722                 print "${te}ok$elapsed\n";
 723                 $good_files = $good_files + 1;
 724             }
 725             else {
 726                 print "${te}skipped\n";
 727                 $tested_files = $tested_files - 1;
 728             }
 729         }
 730     } # while tests
 731
 732     if ($::bad_files == 0) {
 733         if ($good_files) {
 734             print "All tests successful.\n";
 735             # XXX add mention of 'perlbug -ok' ?
 736         }
 737         else {
 738             die "FAILED--no tests were run for some reason.\n";
 739         }
 740     }
 741     else {
 742         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 743         my $s = $::bad_files == 1 ? "" : "s";
 744         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 745         for my $test ( sort keys %failed_tests ) {
 746             print "\t$test\n";
 747         }
 748         warn <<'SHRDLU_1';
 749 ### Since not all tests were successful, you may want to run some of
 750 ### them individually and examine any diagnostic messages they produce.
 751 ### See the INSTALL document's section on "make test".
 752 SHRDLU_1
 753         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 754 ### You have a good chance to get more information by running
 755 ###   ./perl harness
 756 ### in the 't' directory since most (>=80%) of the tests succeeded.
 757 SHRDLU_2
 758         if (eval {require Config; import Config; 1}) {
 759             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 760                 warn <<SHRDLU_3;
 761 ### You may have to set your dynamic library search path,
 762 ### $p, to point to the build directory:
 763 SHRDLU_3
 764                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 765                     warn <<SHRDLU_4a;
 766 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 767 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 768 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 769 SHRDLU_4a
 770                 } else {
 771                     warn <<SHRDLU_4b;
 772 ###   setenv $p `pwd`; cd t; ./perl harness
 773 ###   $p=`pwd`; export $p; cd t; ./perl harness
 774 ###   export $p=`pwd`; cd t; ./perl harness
 775 SHRDLU_4b
 776                 }
 777                 warn <<SHRDLU_5;
 778 ### for csh-style shells, like tcsh; or for traditional/modern
 779 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 780 SHRDLU_5
 781             }
 782         }
 783     }
 784     printf "Elapsed: %d sec\n", time() - $t0;
 785     my ($user,$sys,$cuser,$csys) = times;
 786     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 787                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 788     print "$tot\n";
 789     if ($good_files) {
 790         if (-d $show_elapsed_time) {
 791             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 792             # storable file there.  NB: the test cds to ./t/, so
 793             # relative path must account for that, ie ../../perf
 794             # points to dir next to source tree.
 795             require Storable;
 796             my @dt = localtime;
 797             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 798             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 799             Storable::store({ perf => \%timings,
 800                               gather_conf_platform_info(),
 801                               total => $tot,
 802                             }, $fn);
 803             print "wrote storable file: $fn\n";
 804         }
 805     }
 806
 807     _cleanup_valgrind(\$toolnm, \$grind_ct);
 808 }
 809 exit ($::bad_files != 0);
 810
 811 # Collect platform, config data that should allow comparing
 812 # performance data between different machines.  With enough data,
 813 # and/or clever statistical analysis, it should be possible to
 814 # determine the effect of config choices, more memory, etc
 815
 816 sub gather_conf_platform_info {
 817     # currently rather quick & dirty, and subject to change
 818     # for both content and format.
 819     require Config;
 820     my (%conf, @platform) = ();
 821     $conf{$_} = $Config::Config{$_} for
 822         grep /cc|git|config_arg\d+/, keys %Config::Config;
 823     if (-f '/proc/cpuinfo') {
 824         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 825         @platform = grep /name|cpu/, <$fh>;
 826         chomp $_ for @platform;
 827     }
 828     unshift @platform, $^O;
 829
 830     return (
 831         conf => \%conf,
 832         platform => {cpu => \@platform,
 833                      mem => [ grep s/\s+/ /,
 834                               grep chomp, `free` ],
 835                      load => [ grep chomp, `uptime` ],
 836         },
 837         host => (grep chomp, `hostname -f`),
 838         version => '0.03', # bump for conf, platform, or data collection changes
 839         );
 840 }
 841
 842 sub _check_valgrind {
 843     return unless $ENV{PERL_VALGRIND};
 844
 845     my ($toolnm, $grind_ct, $test) = @_;
 846
 847     $$toolnm = $ENV{VALGRIND};
 848     $$toolnm =~ s|.*/||;  # keep basename
 849     my @valgrind;       # gets content of file
 850     if (-e $Valgrind_Log) {
 851         if (open(V, $Valgrind_Log)) {
 852             @valgrind = <V>;
 853             close V;
 854         } else {
 855             warn "$0: Failed to open '$Valgrind_Log': $!\n";
 856         }
 857     }
 858     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
 859         $$toolnm = $1;
 860         if ($$toolnm eq 'perf') {
 861             # append perfs subcommand, not just stat
 862             my ($sub) = split /\s/, $ENV{VG_OPTS};
 863             $$toolnm .= "-$sub";
 864         }
 865         if (rename $Valgrind_Log, "$$test.$$toolnm") {
 866             $$grind_ct++;
 867         } else {
 868             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
 869         }
 870     }
 871     elsif (@valgrind) {
 872         my $leaks = 0;
 873         my $errors = 0;
 874         for my $i (0..$#valgrind) {
 875             local $_ = $valgrind[$i];
 876             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 877                 $errors = $errors + $1;   # there may be multiple error summaries
 878             } elsif (/^==\d+== LEAK SUMMARY:/) {
 879                 for my $off (1 .. 4) {
 880                     if ($valgrind[$i+$off] =~
 881                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 882                             $leaks = $leaks + $1;
 883                     }
 884                 }
 885             }
 886         }
 887         if ($errors or $leaks) {
 888             if (rename $Valgrind_Log, "$$test.valgrind") {
 889                 $$grind_ct = $$grind_ct + 1;
 890             } else {
 891                 warn "$0: Failed to create '$$test.valgrind': $!\n";
 892             }
 893         }
 894     } else {
 895         # Quiet wasn't asked for? Something may be amiss
 896         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
 897             warn "No valgrind output?\n";
 898         }
 899     }
 900     if (-e $Valgrind_Log) {
 901         unlink $Valgrind_Log
 902             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 903     }
 904 }
 905
 906 sub _cleanup_valgrind {
 907     return unless $ENV{PERL_VALGRIND};
 908
 909     my ($toolnm, $grind_ct) = @_;
 910     my $s = $$grind_ct == 1 ? '' : 's';
 911     print "$$grind_ct valgrind report$s created.\n", ;
 912     if ($$toolnm eq 'cachegrind') {
 913         # cachegrind leaves a lot of cachegrind.out.$pid litter
 914         # around the tree, find and delete them
 915         unlink _find_files('cachegrind.out.\d+$',
 916                      qw ( ../t ../cpan ../ext ../dist/ ));
 917     }
 918 }
 919
 920 # Generate regexps of known bad filenames / skips from Porting/deparse-skips.txt
 921 my $in;
 922
 923 sub _process_deparse_config {
 924     my @deparse_failures;
 925     my @deparse_skips;
 926
 927     my $f = '../Porting/deparse-skips.txt';
 928
 929     my $skips;
 930     if (!open($skips, '<', $f)) {
 931         warn "Failed to find $f: $!\n";
 932         return;
 933     }
 934
 935     while(<$skips>) {
 936         if (/__DEPARSE_FAILURES__/) {
 937             $in = \@deparse_failures; next;
 938         } elsif (/__DEPARSE_SKIPS__/) {
 939             $in = \@deparse_skips; next;
 940         } elsif (!$in) {
 941             next;
 942         }
 943
 944         s/#.*$//; # Kill comments
 945         s/\s+$//; # And trailing whitespace
 946
 947         next unless $_;
 948
 949         push @$in, $_;
 950     }
 951
 952     for my $f (@deparse_failures, @deparse_skips) {
 953         if ($f =~ m|/$|) { # Dir? Skip everything below it
 954             $f = qr/\Q$f\E.*/;
 955         } else {
 956             $f = qr/\Q$f\E/;
 957         }
 958     }
 959
 960     $deparse_failures = join('|', @deparse_failures);
 961     $deparse_failures = qr/^(?:$deparse_failures)$/;
 962
 963     $deparse_skips = join('|', @deparse_skips);
 964     $deparse_skips = qr/^(?:$deparse_skips)$/;
 965 }
 966
 967 # ex: set ts=8 sts=4 sw=4 noet: