pod/pod2text.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 $origdir = cwd;
  17 chdir dirname($0);
  18 $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 # pod2text -- Convert POD data to formatted ASCII text.
  39 #
  40 # Copyright 1999, 2000 by Russ Allbery <rra@stanford.edu>
  41 #
  42 # This program is free software; you can redistribute it and/or modify it
  43 # under the same terms as Perl itself.
  44 #
  45 # The driver script for Pod::Text, Pod::Text::Termcap, and Pod::Text::Color,
  46 # invoked by perldoc -t among other things.
  47
  48 require 5.004;
  49
  50 use Getopt::Long qw(GetOptions);
  51 use Pod::Text ();
  52 use Pod::Usage qw(pod2usage);
  53
  54 use strict;
  55
  56 # Take an initial pass through our options, looking for one of the form
  57 # -<number>.  We turn that into -w <number> for compatibility with the
  58 # original pod2text script.
  59 for (my $i = 0; $i < @ARGV; $i++) {
  60     last if $ARGV[$i] =~ /^--$/;
  61     if ($ARGV[$i] =~ /^-(\d+)$/) {
  62         splice (@ARGV, $i++, 1, '-w', $1);
  63     }
  64 }
  65
  66 # Insert -- into @ARGV before any single dash argument to hide it from
  67 # Getopt::Long; we want to interpret it as meaning stdin (which Pod::Parser
  68 # does correctly).
  69 my $stdin;
  70 @ARGV = map { $_ eq '-' && !$stdin++ ? ('--', $_) : $_ } @ARGV;
  71
  72 # Parse our options.  Use the same names as Pod::Text for simplicity, and
  73 # default to sentence boundaries turned off for compatibility.
  74 my %options;
  75 $options{sentence} = 0;
  76 Getopt::Long::config ('bundling');
  77 GetOptions (\%options, 'alt|a', 'color|c', 'help|h', 'indent|i=i',
  78             'loose|l', 'quotes|q=s', 'sentence|s', 'termcap|t',
  79             'width|w=i') or exit 1;
  80 pod2usage (1) if $options{help};
  81
  82 # Figure out what formatter we're going to use.  -c overrides -t.
  83 my $formatter = 'Pod::Text';
  84 if ($options{color}) {
  85     $formatter = 'Pod::Text::Color';
  86     eval { require Term::ANSIColor };
  87     if ($@) { die "-c (--color) requires Term::ANSIColor be installed\n" }
  88     require Pod::Text::Color;
  89 } elsif ($options{termcap}) {
  90     $formatter = 'Pod::Text::Termcap';
  91     require Pod::Text::Termcap;
  92 }
  93 delete @options{'color', 'termcap'};
  94
  95 # Initialize and run the formatter.
  96 my $parser = $formatter->new (%options);
  97 $parser->parse_from_file (@ARGV);
  98
  99 __END__
 100
 101 =head1 NAME
 102
 103 pod2text - Convert POD data to formatted ASCII text
 104
 105 =head1 SYNOPSIS
 106
 107 pod2text [B<-aclst>] [B<-i> I<indent>] [B<-q> I<quotes>] [B<-w> I<width>]
 108 [I<input> [I<output>]]
 109
 110 pod2text B<-h>
 111
 112 =head1 DESCRIPTION
 113
 114 B<pod2text> is a front-end for Pod::Text and its subclasses.  It uses them
 115 to generate formatted ASCII text from POD source.  It can optionally use
 116 either termcap sequences or ANSI color escape sequences to format the text.
 117
 118 I<input> is the file to read for POD source (the POD can be embedded in
 119 code).  If I<input> isn't given, it defaults to STDIN.  I<output>, if given,
 120 is the file to which to write the formatted output.  If I<output> isn't
 121 given, the formatted output is written to STDOUT.
 122
 123 =head1 OPTIONS
 124
 125 =over 4
 126
 127 =item B<-a>, B<--alt>
 128
 129 Use an alternate output format that, among other things, uses a different
 130 heading style and marks C<=item> entries with a colon in the left margin.
 131
 132 =item B<-c>, B<--color>
 133
 134 Format the output with ANSI color escape sequences.  Using this option
 135 requires that Term::ANSIColor be installed on your system.
 136
 137 =item B<-i> I<indent>, B<--indent=>I<indent>
 138
 139 Set the number of spaces to indent regular text, and the default indentation
 140 for C<=over> blocks.  Defaults to 4 spaces if this option isn't given.
 141
 142 =item B<-h>, B<--help>
 143
 144 Print out usage information and exit.
 145
 146 =item B<-l>, B<--loose>
 147
 148 Print a blank line after a C<=head1> heading.  Normally, no blank line is
 149 printed after C<=head1>, although one is still printed after C<=head2>,
 150 because this is the expected formatting for manual pages; if you're
 151 formatting arbitrary text documents, using this option is recommended.
 152
 153 =item B<-q> I<quotes>, B<--quotes>=I<quotes>
 154
 155 Sets the quote marks used to surround CE<lt>> text to I<quotes>.  If
 156 I<quotes> is a single character, it is used as both the left and right
 157 quote; if I<quotes> is two characters, the first character is used as the
 158 left quote and the second as the right quoted; and if I<quotes> is four
 159 characters, the first two are used as the left quote and the second two as
 160 the right quote.
 161
 162 I<quotes> may also be set to the special value C<none>, in which case no
 163 quote marks are added around CE<lt>> text.
 164
 165 =item B<-s>, B<--sentence>
 166
 167 Assume each sentence ends with two spaces and try to preserve that spacing.
 168 Without this option, all consecutive whitespace in non-verbatim paragraphs
 169 is compressed into a single space.
 170
 171 =item B<-t>, B<--termcap>
 172
 173 Try to determine the width of the screen and the bold and underline
 174 sequences for the terminal from termcap, and use that information in
 175 formatting the output.  Output will be wrapped at two columns less than the
 176 width of your terminal device.  Using this option requires that your system
 177 have a termcap file somewhere where Term::Cap can find it and requires that
 178 your system support termios.  With this option, the output of B<pod2text>
 179 will contain terminal control sequences for your current terminal type.
 180
 181 =item B<-w>, B<--width=>I<width>, B<->I<width>
 182
 183 The column at which to wrap text on the right-hand side.  Defaults to 76,
 184 unless B<-t> is given, in which case it's two columns less than the width of
 185 your terminal device.
 186
 187 =back
 188
 189 =head1 DIAGNOSTICS
 190
 191 If B<pod2text> fails with errors, see L<Pod::Text> and L<Pod::Parser> for
 192 information about what those errors might mean.  Internally, it can also
 193 produce the following diagnostics:
 194
 195 =over 4
 196
 197 =item -c (--color) requires Term::ANSIColor be installed
 198
 199 (F) B<-c> or B<--color> were given, but Term::ANSIColor could not be
 200 loaded.
 201
 202 =item Unknown option: %s
 203
 204 (F) An unknown command line option was given.
 205
 206 =back
 207
 208 In addition, other L<Getopt::Long|Getopt::Long> error messages may result
 209 from invalid command-line options.
 210
 211 =head1 ENVIRONMENT
 212
 213 =over 4
 214
 215 =item COLUMNS
 216
 217 If B<-t> is given, B<pod2text> will take the current width of your screen
 218 from this environment variable, if available.  It overrides terminal width
 219 information in TERMCAP.
 220
 221 =item TERMCAP
 222
 223 If B<-t> is given, B<pod2text> will use the contents of this environment
 224 variable if available to determine the correct formatting sequences for your
 225 current terminal device.
 226
 227 =back
 228
 229 =head1 SEE ALSO
 230
 231 L<Pod::Text|Pod::Text>, L<Pod::Text::Color|Pod::Text::Color>,
 232 L<Pod::Text::Termcap|Pod::Text::Termcap>, L<Pod::Parser|Pod::Parser>
 233
 234 =head1 AUTHOR
 235
 236 Russ Allbery E<lt>rra@stanford.eduE<gt>.
 237
 238 =cut
 239 !NO!SUBS!
 240
 241 close OUT or die "Can't close $file: $!";
 242 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 243 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 244 chdir $origdir;