ext/DynaLoader/DynaLoader_pm.PL

   1 use Config;
   2
   3 sub to_string {
   4     my ($value) = @_;
   5     $value =~ s/\\/\\\\/g;
   6     $value =~ s/'/\\'/g;
   7     return "'$value'";
   8 }
   9
  10 #
  11 # subroutine expand_os_specific expands $^O-specific preprocessing information
  12 # so that it will not be re-calculated at runtime in Dynaloader.pm
  13 #
  14 # Syntax of preprocessor should be kept extremely simple:
  15 #  - directives are in double angle brackets <<...>>
  16 #  - <<=string>> will be just evaluated
  17 #  - for $^O-specific there are two forms:
  18 #   <<$^O-eq-osname>>
  19 #   <<$^O-ne-osname>>
  20 #  this directive should be closed with respectively
  21 #   <</$^O-eq-osname>>
  22 #   <</$^O-ne-osname>>
  23 #  construct <<|$^O-ne-osname>> means #else
  24 #  nested <<$^O...>>-constructs are allowed but nested values must be for
  25 #   different OS-names!
  26 #
  27 #  -- added by VKON, 03-10-2004 to separate $^O-specific between OSes
  28 #     (so that Win32 never checks for $^O eq 'VMS' for example)
  29 #
  30 # The $^O tests test both for $^O and for $Config{osname}.
  31 # The latter is better for some for cross-compilation setups.
  32 #
  33 sub expand_os_specific {
  34     my $s = shift;
  35     for ($s) {
  36         s/<<=(.*?)>>/$1/gee;
  37         s/<<\$\^O-(eq|ne)-(\w+)>>(.*?)<<\/\$\^O-\1-\2>>/
  38           my ($op, $os, $expr) = ($1,$2,$3);
  39           if ($op ne 'eq' and $op ne 'ne') {die "wrong eq-ne arg in $&"};
  40           if ($expr =~ m[^(.*?)<<\|\$\^O-$op-$os>>(.*?)$]s) {
  41               # #if;#else;#endif
  42               my ($if,$el) = ($1,$2);
  43               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
  44                   $if
  45               }
  46               else {
  47                   $el
  48               }
  49           }
  50           else {
  51               # #if;#endif
  52               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
  53                   $expr
  54               }
  55               else {
  56                   ""
  57               }
  58           }
  59         /ges;
  60         if (/<<(=|\$\^O-)/) {die "bad <<\$^O-eq/ne-osname>> expression.".
  61             " Unclosed brackets?";
  62         }
  63     }
  64     $s;
  65 }
  66
  67 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  68 open OUT, ">DynaLoader.pm" or die $!;
  69 print OUT <<'EOT';
  70
  71 # Generated from DynaLoader.pm.PL
  72
  73 package DynaLoader;
  74
  75 #   And Gandalf said: 'Many folk like to know beforehand what is to
  76 #   be set on the table; but those who have laboured to prepare the
  77 #   feast like to keep their secret; for wonder makes the words of
  78 #   praise louder.'
  79
  80 #   (Quote from Tolkien suggested by Anno Siegel.)
  81 #
  82 # See pod text at end of file for documentation.
  83 # See also ext/DynaLoader/README in source tree for other information.
  84 #
  85 # Tim.Bunce@ig.co.uk, August 1994
  86
  87 $VERSION = '1.07';
  88
  89 require AutoLoader;
  90 *AUTOLOAD = \&AutoLoader::AUTOLOAD;
  91
  92 use Config;
  93
  94 # enable debug/trace messages from DynaLoader perl code
  95 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
  96
  97 #
  98 # Flags to alter dl_load_file behaviour.  Assigned bits:
  99 #   0x01  make symbols available for linking later dl_load_file's.
 100 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 101 #         (ignored under VMS; effect is built-in to image linking)
 102 #
 103 # This is called as a class method $module->dl_load_flags.  The
 104 # definition here will be inherited and result on "default" loading
 105 # behaviour unless a sub-class of DynaLoader defines its own version.
 106 #
 107
 108 sub dl_load_flags { 0x00 }
 109
 110 # ($dl_dlext, $dlsrc)
 111 #         = @Config::Config{'dlext', 'dlsrc'};
 112 EOT
 113
 114 $dl_dlext = $Config::Config{'dlext'};
 115 $dl_so = $Config::Config{'so'};
 116 print OUT "  (\$dl_dlext, \$dlsrc) = ('$dl_dlext', ",
 117           to_string($Config::Config{'dlsrc'}), ")\n;";
 118
 119 print OUT expand_os_specific(<<'EOT');
 120
 121 <<$^O-eq-VMS>>
 122 # Some systems need special handling to expand file specifications
 123 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
 124 # See dl_expandspec() for more details. Should be harmless but
 125 # inefficient to define on systems that don't need it.
 126 $Is_VMS    = $^O eq 'VMS';
 127 <</$^O-eq-VMS>>
 128 $do_expand = <<$^O-eq-VMS>>1<<|$^O-eq-VMS>>0<</$^O-eq-VMS>>;
 129
 130 <<$^O-eq-MacOS>>
 131 my $Mac_FS;
 132 $Mac_FS = eval { require Mac::FileSpec::Unixish };
 133 <</$^O-eq-MacOS>>
 134
 135 @dl_require_symbols = ();       # names of symbols we need
 136 @dl_resolve_using   = ();       # names of files to link with
 137 @dl_library_path    = ();       # path to look for files
 138
 139 #XSLoader.pm may have added elements before we were required
 140 #@dl_shared_objects  = ();       # shared objects for symbols we have
 141 #@dl_librefs         = ();       # things we have loaded
 142 #@dl_modules         = ();       # Modules we have loaded
 143
 144 # This is a fix to support DLD's unfortunate desire to relink -lc
 145 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
 146
 147 EOT
 148
 149 my $cfg_dl_library_path = <<'EOT';
 150 push(@dl_library_path, split(' ', $Config::Config{libpth}));
 151 EOT
 152
 153 sub dquoted_comma_list {
 154     join(", ", map {'"'.quotemeta($_).'"'} @_);
 155 }
 156
 157 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 158     eval $cfg_dl_library_path;
 159     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 160         my $dl_library_path = dquoted_comma_list(@dl_library_path);
 161         print OUT <<EOT;
 162 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
 163
 164 \@dl_library_path = ($dl_library_path);
 165
 166 EOT
 167     }
 168 }
 169 else {
 170     print OUT <<EOT;
 171 # Initialise \@dl_library_path with the 'standard' library path
 172 # for this platform as determined by Configure.
 173
 174 $cfg_dl_library_path
 175
 176 EOT
 177 }
 178
 179 my $ldlibpthname;
 180 my $ldlibpthname_defined;
 181 my $pthsep;
 182
 183 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 184     $ldlibpthname         = to_string($Config::Config{ldlibpthname});
 185     $ldlibpthname_defined = to_string(defined $Config::Config{ldlibpthname} ? 1 : 0);
 186     $pthsep               = to_string($Config::Config{path_sep});
 187 }
 188 else {
 189     $ldlibpthname         = q($Config::Config{ldlibpthname});
 190     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
 191     $pthsep               = q($Config::Config{path_sep});
 192 }
 193 print OUT <<EOT;
 194 my \$ldlibpthname         = $ldlibpthname;
 195 my \$ldlibpthname_defined = $ldlibpthname_defined;
 196 my \$pthsep               = $pthsep;
 197
 198 EOT
 199
 200 my $env_dl_library_path = <<'EOT';
 201 if ($ldlibpthname_defined &&
 202     exists $ENV{$ldlibpthname}) {
 203     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
 204 }
 205
 206 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 207
 208 if ($ldlibpthname_defined &&
 209     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
 210     exists $ENV{LD_LIBRARY_PATH}) {
 211     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
 212 }
 213 EOT
 214
 215 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 216     eval $env_dl_library_path;
 217 }
 218 else {
 219     print OUT <<EOT;
 220 # Add to \@dl_library_path any extra directories we can gather from environment
 221 # during runtime.
 222
 223 $env_dl_library_path
 224
 225 EOT
 226 }
 227
 228 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 229     my $dl_library_path = dquoted_comma_list(@dl_library_path);
 230     print OUT <<EOT;
 231 # The below \@dl_library_path has been expanded (%Config, %ENV)
 232 # in Perl build time.
 233
 234 \@dl_library_path = ($dl_library_path);
 235
 236 EOT
 237 }
 238
 239
 240 # following long string contains $^O-specific stuff, which is factored out
 241 print OUT expand_os_specific(<<'EOT');
 242 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 243 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 244 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 245                                 !defined(&dl_error);
 246
 247 if ($dl_debug) {
 248     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 249     print STDERR "DynaLoader not linked into this perl\n"
 250             unless defined(&boot_DynaLoader);
 251 }
 252
 253 1; # End of main code
 254
 255
 256 sub croak   { require Carp; Carp::croak(@_)   }
 257
 258 sub bootstrap_inherit {
 259     my $module = $_[0];
 260     local *isa = *{"$module\::ISA"};
 261     local @isa = (@isa, 'DynaLoader');
 262     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 263     bootstrap(@_);
 264 }
 265
 266 # The bootstrap function cannot be autoloaded (without complications)
 267 # so we define it here:
 268
 269 sub bootstrap {
 270     # use local vars to enable $module.bs script to edit values
 271     local(@args) = @_;
 272     local($module) = $args[0];
 273     local(@dirs, $file);
 274
 275     unless ($module) {
 276         require Carp;
 277         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 278     }
 279
 280     # A common error on platforms which don't support dynamic loading.
 281     # Since it's fatal and potentially confusing we give a detailed message.
 282     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 283         "  (You may need to build a new perl executable which either supports\n".
 284         "  dynamic loading or has the $module module statically linked into it.)\n")
 285         unless defined(&dl_load_file);
 286
 287
 288     <<$^O-eq-os2>>
 289     # Can dynaload, but cannot dynaload Perl modules...
 290     die 'Dynaloaded Perl modules are not available in this build of Perl' if $OS2::is_static;
 291
 292     <</$^O-eq-os2>>
 293     my @modparts = split(/::/,$module);
 294     my $modfname = $modparts[-1];
 295
 296     # Some systems have restrictions on files names for DLL's etc.
 297     # mod2fname returns appropriate file base name (typically truncated)
 298     # It may also edit @modparts if required.
 299     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 300
 301     <<$^O-eq-NetWare>>
 302     # Truncate the module name to 8.3 format for NetWare
 303         if ((length($modfname) > 8)) {
 304                 $modfname = substr($modfname, 0, 8);
 305         }
 306     <</$^O-eq-NetWare>>
 307
 308     my $modpname = join(<<$^O-eq-MacOS>>':'<<|$^O-eq-MacOS>>'/'<</$^O-eq-MacOS>>,@modparts);
 309
 310     print STDERR "DynaLoader::bootstrap for $module ",
 311                        <<$^O-eq-MacOS>> "(:auto:$modpname:$modfname.<<=$dl_dlext>>)\n"
 312                        <<|$^O-eq-MacOS>>"(auto/$modpname/$modfname.<<=$dl_dlext>>)\n"<</$^O-eq-MacOS>>
 313         if $dl_debug;
 314
 315     foreach (@INC) {
 316         <<$^O-eq-VMS>>chop($_ = VMS::Filespec::unixpath($_));<</$^O-eq-VMS>>
 317         <<$^O-eq-MacOS>>
 318             my $path = $_;
 319             if ($Mac_FS && ! -d $path) {
 320                 $path = Mac::FileSpec::Unixish::nativize($path);
 321             }
 322             $path .= ":"  unless /:$/;
 323             my $dir = "${path}auto:$modpname";
 324         <<|$^O-eq-MacOS>>
 325             my $dir = "$_/auto/$modpname";
 326         <</$^O-eq-MacOS>>
 327
 328         next unless -d $dir; # skip over uninteresting directories
 329
 330         # check for common cases to avoid autoload of dl_findfile
 331         my $try = <<$^O-eq-MacOS>> "$dir:$modfname.<<=$dl_dlext>>" <<|$^O-eq-MacOS>> "$dir/$modfname.<<=$dl_dlext>>"<</$^O-eq-MacOS>>;
 332         last if $file = <<$^O-eq-VMS>>($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
 333         <<|$^O-eq-VMS>>(-f $try) && $try;
 334         <</$^O-eq-VMS>>
 335
 336         # no luck here, save dir for possible later dl_findfile search
 337         push @dirs, $dir;
 338     }
 339     # last resort, let dl_findfile have a go in all known locations
 340     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 341
 342     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 343         unless $file;   # wording similar to error from 'require'
 344
 345     <<$^O-eq-VMS>>$file = uc($file) if $Config::Config{d_vms_case_sensitive_symbols};<</$^O-eq-VMS>>
 346     my $bootname = "boot_$module";
 347     $bootname =~ s/\W/_/g;
 348     @dl_require_symbols = ($bootname);
 349
 350     # Execute optional '.bootstrap' perl script for this module.
 351     # The .bs file can be used to configure @dl_resolve_using etc to
 352     # match the needs of the individual module on this architecture.
 353     my $bs = $file;
 354     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 355     if (-s $bs) { # only read file if it's not empty
 356         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 357         eval { do $bs; };
 358         warn "$bs: $@\n" if $@;
 359     }
 360
 361     my $boot_symbol_ref;
 362
 363     <<$^O-eq-darwin>>
 364     if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
 365         goto boot; #extension library has already been loaded, e.g. darwin
 366     }
 367     <</$^O-eq-darwin>>
 368
 369     # Many dynamic extension loading problems will appear to come from
 370     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 371     # Often these errors are actually occurring in the initialisation
 372     # C code of the extension XS file. Perl reports the error as being
 373     # in this perl code simply because this was the last perl code
 374     # it executed.
 375
 376     my $libref = dl_load_file($file, $module->dl_load_flags) or
 377         croak("Can't load '$file' for module $module: ".dl_error());
 378
 379     push(@dl_librefs,$libref);  # record loaded object
 380
 381     my @unresolved = dl_undef_symbols();
 382     if (@unresolved) {
 383         require Carp;
 384         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 385     }
 386
 387     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 388          croak("Can't find '$bootname' symbol in $file\n");
 389
 390     push(@dl_modules, $module); # record loaded module
 391
 392   boot:
 393     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 394
 395     # See comment block above
 396
 397         push(@dl_shared_objects, $file); # record files loaded
 398
 399     &$xs(@args);
 400 }
 401
 402
 403 #sub _check_file {   # private utility to handle dl_expandspec vs -f tests
 404 #    my($file) = @_;
 405 #    return $file if (!$do_expand && -f $file); # the common case
 406 #    return $file if ( $do_expand && ($file=dl_expandspec($file)));
 407 #    return undef;
 408 #}
 409
 410
 411 # Let autosplit and the autoloader deal with these functions:
 412 __END__
 413
 414
 415 sub dl_findfile {
 416     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
 417     # This function does not automatically consider the architecture
 418     # or the perl library auto directories.
 419     my (@args) = @_;
 420     my (@dirs,  $dir);   # which directories to search
 421     my (@found);         # full paths to real files we have found
 422     #my $dl_ext= <<=to_string($Config::Config{'dlext'})>>; # $Config::Config{'dlext'} suffix for perl extensions
 423     #my $dl_so = <<=to_string($Config::Config{'so'})>>; # $Config::Config{'so'} suffix for shared libraries
 424
 425     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 426
 427     # accumulate directories but process files as they appear
 428     arg: foreach(@args) {
 429         #  Special fast case: full filepath requires no search
 430         <<$^O-eq-VMS>>
 431         if (m%[:>/\]]% && -f $_) {
 432             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 433             last arg unless wantarray;
 434             next;
 435         }
 436         <</$^O-eq-VMS>>
 437         <<$^O-eq-MacOS>>
 438             if (m/:/ && -f $_) {
 439                 push(@found,$_);
 440                 last arg unless wantarray;
 441             }
 442         <</$^O-eq-MacOS>>
 443         <<$^O-ne-VMS>>
 444         if (m:/: && -f $_) {
 445             push(@found,$_);
 446             last arg unless wantarray;
 447             next;
 448         }
 449         <</$^O-ne-VMS>>
 450
 451         # Deal with directories first:
 452         #  Using a -L prefix is the preferred option (faster and more robust)
 453         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 454
 455         <<$^O-eq-MacOS>>
 456             #  Otherwise we try to try to spot directories by a heuristic
 457             #  (this is a more complicated issue than it first appears)
 458             if (m/:/ && -d $_) {   push(@dirs, $_); next; }
 459             #  Only files should get this far...
 460             my(@names, $name);    # what filenames to look for
 461             s/^-l//;
 462             push(@names, $_);
 463             foreach $dir (@dirs, @dl_library_path) {
 464                 next unless -d $dir;
 465                 $dir =~ s/^([^:]+)$/:$1/;
 466                 $dir =~ s/:$//;
 467                 foreach $name (@names) {
 468                     my($file) = "$dir:$name";
 469                     print STDERR " checking in $dir for $name\n" if $dl_debug;
 470                     if (-f $file) {
 471                         push(@found, $file);
 472                         next arg; # no need to look any further
 473                     }
 474                 }
 475             }
 476             next;
 477         <</$^O-eq-MacOS>>
 478
 479         #  Otherwise we try to try to spot directories by a heuristic
 480         #  (this is a more complicated issue than it first appears)
 481         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 482
 483         <<$^O-eq-VMS>>
 484         # VMS: we may be using native VMS directory syntax instead of
 485         # Unix emulation, so check this as well
 486         if (/[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 487         <</$^O-eq-VMS>>
 488
 489         #  Only files should get this far...
 490         my(@names, $name);    # what filenames to look for
 491         if (m:-l: ) {          # convert -lname to appropriate library name
 492             s/-l//;
 493             push(@names,"lib$_.<<=to_string($Config::Config{'so'})>>");
 494             push(@names,"lib$_.a");
 495         } else {                # Umm, a bare name. Try various alternatives:
 496             # these should be ordered with the most likely first
 497             push(@names,"$_.<<=$dl_dlext>>")    unless m/\.<<=$dl_dlext>>$/o;
 498             push(@names,"$_.<<=$dl_so>>")     unless m/\.<<=$dl_so>>$/o;
 499             push(@names,"lib$_.<<=$dl_so>>")  unless m:/:;
 500             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
 501             push(@names, $_);
 502         }
 503         my $dirsep = '/';
 504         <<$^O-eq-symbian>>
 505         $dirsep = '\\';
 506         if ($0 =~ /^([a-z]):/i) {
 507             my $drive = $1;
 508             @dirs = map { "$drive:$_" } @dirs;
 509             @dl_library_path = map { "$drive:$_" } @dl_library_path;
 510         }
 511         <</$^O-eq-symbian>>
 512         foreach $dir (@dirs, @dl_library_path) {
 513             next unless -d $dir;
 514             <<$^O-eq-VMS>>
 515             chop($dir = VMS::Filespec::unixpath($dir));
 516             <</$^O-eq-VMS>>
 517             foreach $name (@names) {
 518                 my($file) = "$dir$dirsep$name";
 519                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 520                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 521                 #$file = _check_file($file);
 522                 if ($file) {
 523                     push(@found, $file);
 524                     next arg; # no need to look any further
 525                 }
 526             }
 527         }
 528     }
 529     if ($dl_debug) {
 530         foreach(@dirs) {
 531             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 532         }
 533         print STDERR "dl_findfile found: @found\n";
 534     }
 535     return $found[0] unless wantarray;
 536     @found;
 537 }
 538
 539
 540 sub dl_expandspec {
 541     my($spec) = @_;
 542     # Optional function invoked if DynaLoader.pm sets $do_expand.
 543     # Most systems do not require or use this function.
 544     # Some systems may implement it in the dl_*.xs file in which case
 545     # this autoload version will not be called but is harmless.
 546
 547     # This function is designed to deal with systems which treat some
 548     # 'filenames' in a special way. For example VMS 'Logical Names'
 549     # (something like unix environment variables - but different).
 550     # This function should recognise such names and expand them into
 551     # full file paths.
 552     # Must return undef if $spec is invalid or file does not exist.
 553
 554     my $file = $spec; # default output to input
 555
 556     <<$^O-eq-VMS>>
 557         # dl_expandspec should be defined in dl_vms.xs
 558         require Carp;
 559         Carp::croak("dl_expandspec: should be defined in XS file!\n");
 560     <<|$^O-eq-VMS>>
 561         return undef unless -f $file;
 562     <</$^O-eq-VMS>>
 563     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 564     $file;
 565 }
 566
 567 sub dl_find_symbol_anywhere
 568 {
 569     my $sym = shift;
 570     my $libref;
 571     foreach $libref (@dl_librefs) {
 572         my $symref = dl_find_symbol($libref,$sym);
 573         return $symref if $symref;
 574     }
 575     return undef;
 576 }
 577
 578 =head1 NAME
 579
 580 DynaLoader - Dynamically load C libraries into Perl code
 581
 582 =head1 SYNOPSIS
 583
 584     package YourPackage;
 585     require DynaLoader;
 586     @ISA = qw(... DynaLoader ...);
 587     bootstrap YourPackage;
 588
 589     # optional method for 'global' loading
 590     sub dl_load_flags { 0x01 }
 591
 592
 593 =head1 DESCRIPTION
 594
 595 This document defines a standard generic interface to the dynamic
 596 linking mechanisms available on many platforms.  Its primary purpose is
 597 to implement automatic dynamic loading of Perl modules.
 598
 599 This document serves as both a specification for anyone wishing to
 600 implement the DynaLoader for a new platform and as a guide for
 601 anyone wishing to use the DynaLoader directly in an application.
 602
 603 The DynaLoader is designed to be a very simple high-level
 604 interface that is sufficiently general to cover the requirements
 605 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
 606
 607 It is also hoped that the interface will cover the needs of OS/2, NT
 608 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 609
 610 It must be stressed that the DynaLoader, by itself, is practically
 611 useless for accessing non-Perl libraries because it provides almost no
 612 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 613 library function or supplying arguments.  A C::DynaLib module
 614 is available from CPAN sites which performs that function for some
 615 common system types.  And since the year 2000, there's also Inline::C,
 616 a module that allows you to write Perl subroutines in C.  Also available
 617 from your local CPAN site.
 618
 619 DynaLoader Interface Summary
 620
 621   @dl_library_path
 622   @dl_resolve_using
 623   @dl_require_symbols
 624   $dl_debug
 625   @dl_librefs
 626   @dl_modules
 627   @dl_shared_objects
 628                                                   Implemented in:
 629   bootstrap($modulename)                               Perl
 630   @filepaths = dl_findfile(@names)                     Perl
 631   $flags = $modulename->dl_load_flags                  Perl
 632   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 633
 634   $libref  = dl_load_file($filename, $flags)           C
 635   $status  = dl_unload_file($libref)                   C
 636   $symref  = dl_find_symbol($libref, $symbol)          C
 637   @symbols = dl_undef_symbols()                        C
 638   dl_install_xsub($name, $symref [, $filename])        C
 639   $message = dl_error                                  C
 640
 641 =over 4
 642
 643 =item @dl_library_path
 644
 645 The standard/default list of directories in which dl_findfile() will
 646 search for libraries etc.  Directories are searched in order:
 647 $dl_library_path[0], [1], ... etc
 648
 649 @dl_library_path is initialised to hold the list of 'normal' directories
 650 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 651 ensure portability across a wide range of platforms.
 652
 653 @dl_library_path should also be initialised with any other directories
 654 that can be determined from the environment at runtime (such as
 655 LD_LIBRARY_PATH for SunOS).
 656
 657 After initialisation @dl_library_path can be manipulated by an
 658 application using push and unshift before calling dl_findfile().
 659 Unshift can be used to add directories to the front of the search order
 660 either to save search time or to override libraries with the same name
 661 in the 'normal' directories.
 662
 663 The load function that dl_load_file() calls may require an absolute
 664 pathname.  The dl_findfile() function and @dl_library_path can be
 665 used to search for and return the absolute pathname for the
 666 library/object that you wish to load.
 667
 668 =item @dl_resolve_using
 669
 670 A list of additional libraries or other shared objects which can be
 671 used to resolve any undefined symbols that might be generated by a
 672 later call to load_file().
 673
 674 This is only required on some platforms which do not handle dependent
 675 libraries automatically.  For example the Socket Perl extension
 676 library (F<auto/Socket/Socket.so>) contains references to many socket
 677 functions which need to be resolved when it's loaded.  Most platforms
 678 will automatically know where to find the 'dependent' library (e.g.,
 679 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 680 location of the dependent library explicitly.  Use @dl_resolve_using
 681 for this.
 682
 683 Example usage:
 684
 685     @dl_resolve_using = dl_findfile('-lsocket');
 686
 687 =item @dl_require_symbols
 688
 689 A list of one or more symbol names that are in the library/object file
 690 to be dynamically loaded.  This is only required on some platforms.
 691
 692 =item @dl_librefs
 693
 694 An array of the handles returned by successful calls to dl_load_file(),
 695 made by bootstrap, in the order in which they were loaded.
 696 Can be used with dl_find_symbol() to look for a symbol in any of
 697 the loaded files.
 698
 699 =item @dl_modules
 700
 701 An array of module (package) names that have been bootstrap'ed.
 702
 703 =item @dl_shared_objects
 704
 705 An array of file names for the shared objects that were loaded.
 706
 707 =item dl_error()
 708
 709 Syntax:
 710
 711     $message = dl_error();
 712
 713 Error message text from the last failed DynaLoader function.  Note
 714 that, similar to errno in unix, a successful function call does not
 715 reset this message.
 716
 717 Implementations should detect the error as soon as it occurs in any of
 718 the other functions and save the corresponding message for later
 719 retrieval.  This will avoid problems on some platforms (such as SunOS)
 720 where the error message is very temporary (e.g., dlerror()).
 721
 722 =item $dl_debug
 723
 724 Internal debugging messages are enabled when $dl_debug is set true.
 725 Currently setting $dl_debug only affects the Perl side of the
 726 DynaLoader.  These messages should help an application developer to
 727 resolve any DynaLoader usage problems.
 728
 729 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 730
 731 For the DynaLoader developer/porter there is a similar debugging
 732 variable added to the C code (see dlutils.c) and enabled if Perl was
 733 built with the B<-DDEBUGGING> flag.  This can also be set via the
 734 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 735 higher for more.
 736
 737 =item dl_findfile()
 738
 739 Syntax:
 740
 741     @filepaths = dl_findfile(@names)
 742
 743 Determine the full paths (including file suffix) of one or more
 744 loadable files given their generic names and optionally one or more
 745 directories.  Searches directories in @dl_library_path by default and
 746 returns an empty list if no files were found.
 747
 748 Names can be specified in a variety of platform independent forms.  Any
 749 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 750 an appropriate suffix for the platform.
 751
 752 If a name does not already have a suitable prefix and/or suffix then
 753 the corresponding file will be searched for by trying combinations of
 754 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 755 and "$name".
 756
 757 If any directories are included in @names they are searched before
 758 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 759 names are treated as filenames to be searched for.
 760
 761 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 762
 763 Example:
 764
 765     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 766
 767
 768 =item dl_expandspec()
 769
 770 Syntax:
 771
 772     $filepath = dl_expandspec($spec)
 773
 774 Some unusual systems, such as VMS, require special filename handling in
 775 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 776
 777 To support these systems a dl_expandspec() function can be implemented
 778 either in the F<dl_*.xs> file or code can be added to the autoloadable
 779 dl_expandspec() function in F<DynaLoader.pm>.  See F<DynaLoader.pm> for
 780 more information.
 781
 782 =item dl_load_file()
 783
 784 Syntax:
 785
 786     $libref = dl_load_file($filename, $flags)
 787
 788 Dynamically load $filename, which must be the path to a shared object
 789 or library.  An opaque 'library reference' is returned as a handle for
 790 the loaded object.  Returns undef on error.
 791
 792 The $flags argument to alters dl_load_file behaviour.
 793 Assigned bits:
 794
 795  0x01  make symbols available for linking later dl_load_file's.
 796        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 797        (ignored under VMS; this is a normal part of image linking)
 798
 799 (On systems that provide a handle for the loaded object such as SunOS
 800 and HPUX, $libref will be that handle.  On other systems $libref will
 801 typically be $filename or a pointer to a buffer containing $filename.
 802 The application should not examine or alter $libref in any way.)
 803
 804 This is the function that does the real work.  It should use the
 805 current values of @dl_require_symbols and @dl_resolve_using if required.
 806
 807     SunOS: dlopen($filename)
 808     HP-UX: shl_load($filename)
 809     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 810     NeXT:  rld_load($filename, @dl_resolve_using)
 811     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 812
 813 (The dlopen() function is also used by Solaris and some versions of
 814 Linux, and is a common choice when providing a "wrapper" on other
 815 mechanisms as is done in the OS/2 port.)
 816
 817 =item dl_unload_file()
 818
 819 Syntax:
 820
 821     $status = dl_unload_file($libref)
 822
 823 Dynamically unload $libref, which must be an opaque 'library reference' as
 824 returned from dl_load_file.  Returns one on success and zero on failure.
 825
 826 This function is optional and may not necessarily be provided on all platforms.
 827 If it is defined, it is called automatically when the interpreter exits for
 828 every shared object or library loaded by DynaLoader::bootstrap.  All such
 829 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 830 loads the libraries.  The files are unloaded in last-in, first-out order.
 831
 832 This unloading is usually necessary when embedding a shared-object perl (e.g.
 833 one configured with -Duseshrplib) within a larger application, and the perl
 834 interpreter is created and destroyed several times within the lifetime of the
 835 application.  In this case it is possible that the system dynamic linker will
 836 unload and then subsequently reload the shared libperl without relocating any
 837 references to it from any files DynaLoaded by the previous incarnation of the
 838 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 839 a now invalid 'ghost' of the libperl shared object, causing apparently random
 840 memory corruption and crashes.  This behaviour is most commonly seen when using
 841 Apache and mod_perl built with the APXS mechanism.
 842
 843     SunOS: dlclose($libref)
 844     HP-UX: ???
 845     Linux: ???
 846     NeXT:  ???
 847     VMS:   ???
 848
 849 (The dlclose() function is also used by Solaris and some versions of
 850 Linux, and is a common choice when providing a "wrapper" on other
 851 mechanisms as is done in the OS/2 port.)
 852
 853 =item dl_load_flags()
 854
 855 Syntax:
 856
 857     $flags = dl_load_flags $modulename;
 858
 859 Designed to be a method call, and to be overridden by a derived class
 860 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 861 DynaLoader itself returns 0, which produces standard behavior from
 862 dl_load_file().
 863
 864 =item dl_find_symbol()
 865
 866 Syntax:
 867
 868     $symref = dl_find_symbol($libref, $symbol)
 869
 870 Return the address of the symbol $symbol or C<undef> if not found.  If the
 871 target system has separate functions to search for symbols of different
 872 types then dl_find_symbol() should search for function symbols first and
 873 then other types.
 874
 875 The exact manner in which the address is returned in $symref is not
 876 currently defined.  The only initial requirement is that $symref can
 877 be passed to, and understood by, dl_install_xsub().
 878
 879     SunOS: dlsym($libref, $symbol)
 880     HP-UX: shl_findsym($libref, $symbol)
 881     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 882     NeXT:  rld_lookup("_$symbol")
 883     VMS:   lib$find_image_symbol($libref,$symbol)
 884
 885
 886 =item dl_find_symbol_anywhere()
 887
 888 Syntax:
 889
 890     $symref = dl_find_symbol_anywhere($symbol)
 891
 892 Applies dl_find_symbol() to the members of @dl_librefs and returns
 893 the first match found.
 894
 895 =item dl_undef_symbols()
 896
 897 Example
 898
 899     @symbols = dl_undef_symbols()
 900
 901 Return a list of symbol names which remain undefined after load_file().
 902 Returns C<()> if not known.  Don't worry if your platform does not provide
 903 a mechanism for this.  Most do not need it and hence do not provide it,
 904 they just return an empty list.
 905
 906
 907 =item dl_install_xsub()
 908
 909 Syntax:
 910
 911     dl_install_xsub($perl_name, $symref [, $filename])
 912
 913 Create a new Perl external subroutine named $perl_name using $symref as
 914 a pointer to the function which implements the routine.  This is simply
 915 a direct call to newXSUB().  Returns a reference to the installed
 916 function.
 917
 918 The $filename parameter is used by Perl to identify the source file for
 919 the function if required by die(), caller() or the debugger.  If
 920 $filename is not defined then "DynaLoader" will be used.
 921
 922
 923 =item bootstrap()
 924
 925 Syntax:
 926
 927 bootstrap($module)
 928
 929 This is the normal entry point for automatic dynamic loading in Perl.
 930
 931 It performs the following actions:
 932
 933 =over 8
 934
 935 =item *
 936
 937 locates an auto/$module directory by searching @INC
 938
 939 =item *
 940
 941 uses dl_findfile() to determine the filename to load
 942
 943 =item *
 944
 945 sets @dl_require_symbols to C<("boot_$module")>
 946
 947 =item *
 948
 949 executes an F<auto/$module/$module.bs> file if it exists
 950 (typically used to add to @dl_resolve_using any files which
 951 are required to load the module on the current platform)
 952
 953 =item *
 954
 955 calls dl_load_flags() to determine how to load the file.
 956
 957 =item *
 958
 959 calls dl_load_file() to load the file
 960
 961 =item *
 962
 963 calls dl_undef_symbols() and warns if any symbols are undefined
 964
 965 =item *
 966
 967 calls dl_find_symbol() for "boot_$module"
 968
 969 =item *
 970
 971 calls dl_install_xsub() to install it as "${module}::bootstrap"
 972
 973 =item *
 974
 975 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 976 it uses the function reference returned by dl_install_xsub for speed)
 977
 978 =back
 979
 980 =back
 981
 982
 983 =head1 AUTHOR
 984
 985 Tim Bunce, 11 August 1994.
 986
 987 This interface is based on the work and comments of (in no particular
 988 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 989 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 990
 991 Larry Wall designed the elegant inherited bootstrap mechanism and
 992 implemented the first Perl 5 dynamic loader using it.
 993
 994 Solaris global loading added by Nick Ing-Simmons with design/coding
 995 assistance from Tim Bunce, January 1996.
 996
 997 =cut
 998 EOT
 999
1000 close OUT or die $!;
1001