t/op/pack.t

   1 #!./perl -w
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';
   7 }
   8
   9 plan tests => 5852;
  10
  11 use strict;
  12 use warnings;
  13 use Config;
  14
  15 my $Is_EBCDIC = (defined $Config{ebcdic} && $Config{ebcdic} eq 'define');
  16 my $Perl = which_perl();
  17
  18 sub encode_list {
  19   my @result = map {_qq($_)} @_;
  20   if (@result == 1) {
  21     return @result;
  22   }
  23   return '(' . join (', ', @result) . ')';
  24 }
  25
  26
  27 sub list_eq ($$) {
  28   my ($l, $r) = @_;
  29   return 0 unless @$l == @$r;
  30   for my $i (0..$#$l) {
  31     if (defined $l->[$i]) {
  32       return 0 unless defined ($r->[$i]) && $l->[$i] eq $r->[$i];
  33     } else {
  34       return 0 if defined $r->[$i]
  35     }
  36   }
  37   return 1;
  38 }
  39
  40 ##############################################################################
  41 #
  42 # Here starteth the tests
  43 #
  44
  45 {
  46     my $format = "c2 x5 C C x s d i l a6";
  47     # Need the expression in here to force ary[5] to be numeric.  This avoids
  48     # test2 failing because ary2 goes str->numeric->str and ary doesn't.
  49     my @ary = (1,-100,127,128,32767,987.654321098 / 100.0,12345,123456,
  50                "abcdef");
  51     my $foo = pack($format,@ary);
  52     my @ary2 = unpack($format,$foo);
  53
  54     is($#ary, $#ary2);
  55
  56     my $out1=join(':',@ary);
  57     my $out2=join(':',@ary2);
  58     # Using long double NVs may introduce greater accuracy than wanted.
  59     $out1 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
  60     $out2 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
  61     is($out1, $out2);
  62
  63     like($foo, qr/def/);
  64 }
  65 # How about counting bits?
  66
  67 {
  68     my $x;
  69     is( ($x = unpack("%32B*", "\001\002\004\010\020\040\100\200\377")), 16 );
  70
  71     is( ($x = unpack("%32b69", "\001\002\004\010\020\040\100\200\017")), 12 );
  72
  73     is( ($x = unpack("%32B69", "\001\002\004\010\020\040\100\200\017")), 9 );
  74 }
  75
  76 {
  77     my $sum = 129; # ASCII
  78     $sum = 103 if $Is_EBCDIC;
  79
  80     my $x;
  81     is( ($x = unpack("%32B*", "Now is the time for all good blurfl")), $sum );
  82
  83     my $foo;
  84     open(BIN, $Perl) || die "Can't open $Perl: $!\n";
  85     sysread BIN, $foo, 8192;
  86     close BIN;
  87
  88     $sum = unpack("%32b*", $foo);
  89     my $longway = unpack("b*", $foo);
  90     is( $sum, $longway =~ tr/1/1/ );
  91 }
  92
  93 {
  94   my $x;
  95   is( ($x = unpack("I",pack("I", 0xFFFFFFFF))), 0xFFFFFFFF );
  96 }
  97
  98 {
  99     # check 'w'
 100     my @x = (5,130,256,560,32000,3097152,268435455,1073741844, 2**33,
 101              '4503599627365785','23728385234614992549757750638446');
 102     my $x = pack('w*', @x);
 103     my $y = pack 'H*', '0581028200843081fa0081bd8440ffffff7f8480808014A0808'.
 104                        '0800087ffffffffffdb19caefe8e1eeeea0c2e1e3e8ede1ee6e';
 105
 106     is($x, $y);
 107
 108     my @y = unpack('w*', $y);
 109     my $a;
 110     while ($a = pop @x) {
 111         my $b = pop @y;
 112         is($a, $b);
 113     }
 114
 115     @y = unpack('w2', $x);
 116
 117     is(scalar(@y), 2);
 118     is($y[1], 130);
 119     $x = pack('w*', 5000000000); $y = '';
 120     eval {
 121     use Math::BigInt;
 122     $y = pack('w*', Math::BigInt::->new(5000000000));
 123     };
 124     is($x, $y);
 125
 126     $x = pack 'w', ~0;
 127     $y = pack 'w', (~0).'';
 128     is($x, $y);
 129     is(unpack ('w',$x), ~0);
 130     is(unpack ('w',$y), ~0);
 131
 132     $x = pack 'w', ~0 - 1;
 133     $y = pack 'w', (~0) - 2;
 134
 135     if (~0 - 1 == (~0) - 2) {
 136         is($x, $y, "NV arithmetic");
 137     } else {
 138         isnt($x, $y, "IV/NV arithmetic");
 139     }
 140     cmp_ok(unpack ('w',$x), '==', ~0 - 1);
 141     cmp_ok(unpack ('w',$y), '==', ~0 - 2);
 142
 143     # These should spot that pack 'w' is using NV, not double, on platforms
 144     # where IVs are smaller than doubles, and harmlessly pass elsewhere.
 145     # (tests for change 16861)
 146     my $x0 = 2**54+3;
 147     my $y0 = 2**54-2;
 148
 149     $x = pack 'w', $x0;
 150     $y = pack 'w', $y0;
 151
 152     if ($x0 == $y0) {
 153         is($x, $y, "NV arithmetic");
 154     } else {
 155         isnt($x, $y, "IV/NV arithmetic");
 156     }
 157     cmp_ok(unpack ('w',$x), '==', $x0);
 158     cmp_ok(unpack ('w',$y), '==', $y0);
 159 }
 160
 161
 162 {
 163   print "# test exceptions\n";
 164   my $x;
 165   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff};
 166   like($@, qr/^Unterminated compressed integer/);
 167
 168   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff};
 169   like($@, qr/^Unterminated compressed integer/);
 170
 171   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff};
 172   like($@, qr/^Unterminated compressed integer/);
 173
 174   eval { $x = pack 'w', -1 };
 175   like ($@, qr/^Cannot compress negative numbers/);
 176
 177   eval { $x = pack 'w', '1'x(1 + length ~0) . 'e0' };
 178   like ($@, qr/^Can only compress unsigned integers/);
 179
 180  SKIP: {
 181     # Is this a stupid thing to do on VMS, VOS and other unusual platforms?
 182
 183     skip("-- the IEEE infinity model is unavailable in this configuration.", 1)
 184        if (($^O eq 'VMS') && !defined($Config{useieee}));
 185
 186     skip("-- $^O has serious fp indigestion on w-packed infinities", 1)
 187        if (($^O eq 'mpeix') || ($^O eq 'ultrix'));
 188
 189     my $inf = eval '2**10000';
 190
 191     skip("Couldn't generate infinity - got error '$@'", 1)
 192       unless defined $inf and $inf == $inf / 2 and $inf + 1 == $inf;
 193
 194     local our $TODO;
 195     $TODO = "VOS needs a fix for posix-1022 to pass this test."
 196       if ($^O eq 'vos');
 197
 198     eval { $x = pack 'w', $inf };
 199     like ($@, qr/^Cannot compress integer/, "Cannot compress integer");
 200   }
 201
 202  SKIP: {
 203
 204     skip("-- the full range of an IEEE double may not be available in this configuration.", 3)
 205        if (($^O eq 'VMS') && !defined($Config{useieee}));
 206
 207     skip("-- $^O does not like 2**1023", 3)
 208        if (($^O eq 'ultrix'));
 209
 210     # This should be about the biggest thing possible on an IEEE double
 211     my $big = eval '2**1023';
 212
 213     skip("Couldn't generate 2**1023 - got error '$@'", 3)
 214       unless defined $big and $big != $big / 2;
 215
 216     eval { $x = pack 'w', $big };
 217     is ($@, '', "Should be able to pack 'w', $big # 2**1023");
 218
 219     my $y = eval {unpack 'w', $x};
 220     is ($@, '',
 221         "Should be able to unpack 'w' the result of pack 'w', $big # 2**1023");
 222
 223     # I'm getting about 1e-16 on FreeBSD
 224     my $quotient = int (100 * ($y - $big) / $big);
 225     ok($quotient < 2 && $quotient > -2,
 226        "Round trip pack, unpack 'w' of $big is withing 1% ($quotient%)");
 227   }
 228
 229 }
 230
 231 print "# test the 'p' template\n";
 232
 233 # literals
 234 is(unpack("p",pack("p","foo")), "foo");
 235
 236 # scalars
 237 is(unpack("p",pack("p",239)), 239);
 238
 239 # temps
 240 sub foo { my $a = "a"; return $a . $a++ . $a++ }
 241 {
 242   use warnings;
 243   my $warning;
 244   local $SIG{__WARN__} = sub {
 245       $warning = $_[0];
 246   };
 247   my $junk = pack("p", &foo);
 248
 249   like($warning, qr/temporary val/);
 250 }
 251
 252 # undef should give null pointer
 253 like(pack("p", undef), qr/^\0+/);
 254
 255 # Check for optimizer bug (e.g.  Digital Unix GEM cc with -O4 on DU V4.0B gives
 256 #                                4294967295 instead of -1)
 257 #                                see #ifdef __osf__ in pp.c pp_unpack
 258 is((unpack("i",pack("i",-1))), -1);
 259
 260 print "# test the pack lengths of s S i I l L n N v V\n";
 261
 262 my @lengths = qw(s 2 S 2 i -4 I -4 l 4 L 4 n 2 N 4 v 2 V 4);
 263 while (my ($format, $expect) = splice @lengths, 0, 2) {
 264   my $len = length(pack($format, 0));
 265   if ($expect > 0) {
 266     is($expect, $len, "format '$format'");
 267   } else {
 268     $expect = -$expect;
 269     ok ($len >= $expect, "format '$format'") ||
 270       print "# format '$format' has length $len, expected >= $expect\n";
 271   }
 272 }
 273
 274
 275 print "# test unpack-pack lengths\n";
 276
 277 my @templates = qw(c C i I s S l L n N v V f d q Q);
 278
 279 foreach my $t (@templates) {
 280     SKIP: {
 281         my @t = eval { unpack("$t*", pack("$t*", 12, 34)) };
 282
 283         # quads not supported everywhere
 284         skip "Quads not supported", 4 if $@ =~ /Invalid type/;
 285         is( $@, '' );
 286
 287         is(scalar @t, 2);
 288
 289         SKIP: {
 290             skip "$t not expected to work for some reason", 2 if $t =~ /[nv]/i;
 291
 292             is($t[0], 12);
 293             is($t[1], 34);
 294         }
 295     }
 296 }
 297
 298 {
 299     # uuencode/decode
 300
 301     # Note that first uuencoding known 'text' data and then checking the
 302     # binary values of the uuencoded version would not be portable between
 303     # character sets.  Uuencoding is meant for encoding binary data, not
 304     # text data.
 305
 306     my $in = pack 'C*', 0 .. 255;
 307
 308     # just to be anal, we do some random tr/`/ /
 309     my $uu = <<'EOUU';
 310 M` $"`P0%!@<("0H+# T.#Q`1$A,4%187&!D:&QP='A\@(2(C)"4F)R@I*BLL
 311 M+2XO,#$R,S0U-C<X.3H[/#T^/T!!0D-$149'2$E*2TQ-3D]045)35%565UA9
 312 M6EM<75Y?8&%B8V1E9F=H:6IK;&UN;W!Q<G-T=79W>'EZ>WQ]?G^`@8*#A(6&
 313 MAXB)BHN,C8Z/D)&2DY25EI>8F9J;G)V>GZ"AHJ.DI::GJ*FJJZRMKJ^PL;*S
 314 MM+6VM[BYNKN\O;Z_P,'"P\3%QL?(R<K+S,W.S]#1TM/4U=;7V-G:V]S=WM_@
 315 ?X>+CY.7FY^CIZNOL[>[O\/'R\_3U]O?X^?K[_/W^_P `
 316 EOUU
 317
 318     $_ = $uu;
 319     tr/ /`/;
 320
 321     is(pack('u', $in), $_);
 322
 323     is(unpack('u', $uu), $in);
 324
 325     $in = "\x1f\x8b\x08\x08\x58\xdc\xc4\x35\x02\x03\x4a\x41\x50\x55\x00\xf3\x2a\x2d\x2e\x51\x48\xcc\xcb\x2f\xc9\x48\x2d\x52\x08\x48\x2d\xca\x51\x28\x2d\x4d\xce\x4f\x49\x2d\xe2\x02\x00\x64\x66\x60\x5c\x1a\x00\x00\x00";
 326     $uu = <<'EOUU';
 327 M'XL("%C<Q#4"`TI!4%4`\RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>("`&1F
 328 &8%P:````
 329 EOUU
 330
 331     is(unpack('u', $uu), $in);
 332
 333 # This is identical to the above except that backquotes have been
 334 # changed to spaces
 335
 336     $uu = <<'EOUU';
 337 M'XL("%C<Q#4" TI!4%4 \RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>(" &1F
 338 &8%P:
 339 EOUU
 340
 341     # ' # Grr
 342     is(unpack('u', $uu), $in);
 343
 344 }
 345
 346 # test the ascii template types (A, a, Z)
 347
 348 foreach (
 349 ['p', 'A*',  "foo\0bar\0 ", "foo\0bar\0 "],
 350 ['p', 'A11', "foo\0bar\0 ", "foo\0bar\0   "],
 351 ['u', 'A*',  "foo\0bar \0", "foo\0bar"],
 352 ['u', 'A8',  "foo\0bar \0", "foo\0bar"],
 353 ['p', 'a*',  "foo\0bar\0 ", "foo\0bar\0 "],
 354 ['p', 'a11', "foo\0bar\0 ", "foo\0bar\0 \0\0"],
 355 ['u', 'a*',  "foo\0bar \0", "foo\0bar \0"],
 356 ['u', 'a8',  "foo\0bar \0", "foo\0bar "],
 357 ['p', 'Z*',  "foo\0bar\0 ", "foo\0bar\0 \0"],
 358 ['p', 'Z11', "foo\0bar\0 ", "foo\0bar\0 \0\0"],
 359 ['p', 'Z3',  "foo",         "fo\0"],
 360 ['u', 'Z*',  "foo\0bar \0", "foo"],
 361 ['u', 'Z8',  "foo\0bar \0", "foo"],
 362 )
 363 {
 364     my ($what, $template, $in, $out) = @$_;
 365     my $got = $what eq 'u' ? (unpack $template, $in) : (pack $template, $in);
 366     unless (is($got, $out)) {
 367         my $un = $what eq 'u' ? 'un' : '';
 368         print "# ${un}pack ('$template', "._qq($in).') gave '._qq($out).
 369             ' not '._qq($got)."\n";
 370     }
 371 }
 372
 373 print "# packing native shorts/ints/longs\n";
 374
 375 is(length(pack("s!", 0)), $Config{shortsize});
 376 is(length(pack("i!", 0)), $Config{intsize});
 377 is(length(pack("l!", 0)), $Config{longsize});
 378 ok(length(pack("s!", 0)) <= length(pack("i!", 0)));
 379 ok(length(pack("i!", 0)) <= length(pack("l!", 0)));
 380 is(length(pack("i!", 0)), length(pack("i", 0)));
 381
 382 sub numbers {
 383   my $format = shift;
 384   return numbers_with_total ($format, undef, @_);
 385 }
 386
 387 sub numbers_with_total {
 388   my $format = shift;
 389   my $total = shift;
 390   if (!defined $total) {
 391     foreach (@_) {
 392       $total += $_;
 393     }
 394   }
 395   print "# numbers test for $format\n";
 396   foreach (@_) {
 397     SKIP: {
 398         my $out = eval {unpack($format, pack($format, $_))};
 399         skip "cannot pack '$format' on this perl", 2 if
 400           $@ =~ /Invalid type '$format'/;
 401
 402         is($@, '');
 403         is($out, $_);
 404     }
 405   }
 406
 407   my $skip_if_longer_than = ~0; # "Infinity"
 408   if (~0 - 1 == ~0) {
 409     # If we're running with -DNO_PERLPRESERVE_IVUV and NVs don't preserve all
 410     # UVs (in which case ~0 is NV, ~0-1 will be the same NV) then we can't
 411     # correctly in perl calculate UV totals for long checksums, as pp_unpack
 412     # is using UV maths, and we've only got NVs.
 413     $skip_if_longer_than = $Config{nv_preserves_uv_bits};
 414   }
 415
 416   foreach ('', 1, 2, 3, 15, 16, 17, 31, 32, 33, 53, 54, 63, 64, 65) {
 417     SKIP: {
 418       my $sum = eval {unpack "%$_$format*", pack "$format*", @_};
 419       skip "cannot pack '$format' on this perl", 3
 420         if $@ =~ /Invalid type '$format'/;
 421
 422       is($@, '');
 423       ok(defined $sum);
 424
 425       my $len = $_; # Copy, so that we can reassign ''
 426       $len = 16 unless length $len;
 427
 428       SKIP: {
 429         skip "cannot test checksums over $skip_if_longer_than bits", 1
 430           if $len > $skip_if_longer_than;
 431
 432         # Our problem with testing this portably is that the checksum code in
 433         # pp_unpack is able to cast signed to unsigned, and do modulo 2**n
 434         # arithmetic in unsigned ints, which perl has no operators to do.
 435         # (use integer; does signed ints, which won't wrap on UTS, which is just
 436         # fine with ANSI, but not with most people's assumptions.
 437         # This is why we need to supply the totals for 'Q' as there's no way in
 438         # perl to calculate them, short of unpack '%0Q' (is that documented?)
 439         # ** returns NVs; make sure it's IV.
 440         my $max = 1 + 2 * (int (2 ** ($len-1))-1); # The max possible checksum
 441         my $max_p1 = $max + 1;
 442         my ($max_is_integer, $max_p1_is_integer);
 443         $max_p1_is_integer = 1 unless $max_p1 + 1 == $max_p1;
 444         $max_is_integer = 1 if $max - 1 < ~0;
 445
 446         my $calc_sum;
 447         if (ref $total) {
 448             $calc_sum = &$total($len);
 449         } else {
 450             $calc_sum = $total;
 451             # Shift into range by some multiple of the total
 452             my $mult = $max_p1 ? int ($total / $max_p1) : undef;
 453             # Need this to make sure that -1 + (~0+1) is ~0 (ie still integer)
 454             $calc_sum = $total - $mult;
 455             $calc_sum -= $mult * $max;
 456             if ($calc_sum < 0) {
 457                 $calc_sum += 1;
 458                 $calc_sum += $max;
 459             }
 460         }
 461         if ($calc_sum == $calc_sum - 1 && $calc_sum == $max_p1) {
 462             # we're into floating point (either by getting out of the range of
 463             # UV arithmetic, or because we're doing a floating point checksum)
 464             # and our calculation of the checksum has become rounded up to
 465             # max_checksum + 1
 466             $calc_sum = 0;
 467         }
 468
 469         if ($calc_sum == $sum) { # HAS to be ==, not eq (so no is()).
 470             ok ("unpack '%$_$format' gave $sum");
 471         } else {
 472             my $delta = 1.000001;
 473             if ($format =~ tr /dDfF//
 474                 && ($calc_sum <= $sum * $delta && $calc_sum >= $sum / $delta)) {
 475                 pass ("unpack '%$_$format' gave $sum, expected $calc_sum");
 476             } else {
 477                 my $text = ref $total ? &$total($len) : $total;
 478                 fail;
 479                 print "# For list (" . join (", ", @_) . ") (total $text)"
 480                     . " packed with $format unpack '%$_$format' gave $sum,"
 481                     . " expected $calc_sum\n";
 482             }
 483         }
 484       }
 485     }
 486   }
 487 }
 488
 489 numbers ('c', -128, -1, 0, 1, 127);
 490 numbers ('C', 0, 1, 127, 128, 255);
 491 numbers ('s', -32768, -1, 0, 1, 32767);
 492 numbers ('S', 0, 1, 32767, 32768, 65535);
 493 numbers ('i', -2147483648, -1, 0, 1, 2147483647);
 494 numbers ('I', 0, 1, 2147483647, 2147483648, 4294967295);
 495 numbers ('l', -2147483648, -1, 0, 1, 2147483647);
 496 numbers ('L', 0, 1, 2147483647, 2147483648, 4294967295);
 497 numbers ('s!', -32768, -1, 0, 1, 32767);
 498 numbers ('S!', 0, 1, 32767, 32768, 65535);
 499 numbers ('i!', -2147483648, -1, 0, 1, 2147483647);
 500 numbers ('I!', 0, 1, 2147483647, 2147483648, 4294967295);
 501 numbers ('l!', -2147483648, -1, 0, 1, 2147483647);
 502 numbers ('L!', 0, 1, 2147483647, 2147483648, 4294967295);
 503 numbers ('n', 0, 1, 32767, 32768, 65535);
 504 numbers ('v', 0, 1, 32767, 32768, 65535);
 505 numbers ('N', 0, 1, 2147483647, 2147483648, 4294967295);
 506 numbers ('V', 0, 1, 2147483647, 2147483648, 4294967295);
 507 # All these should have exact binary representations:
 508 numbers ('f', -1, 0, 0.5, 42, 2**34);
 509 numbers ('d', -(2**34), -1, 0, 1, 2**34);
 510 ## These don't, but 'd' is NV.  XXX wrong, it's double
 511 #numbers ('d', -1, 0, 1, 1-exp(-1), -exp(1));
 512
 513 numbers_with_total ('q', -1,
 514                     -9223372036854775808, -1, 0, 1,9223372036854775807);
 515 # This total is icky, but the true total is 2**65-1, and need a way to generate
 516 # the epxected checksum on any system including those where NVs can preserve
 517 # 65 bits. (long double is 128 bits on sparc, so they certainly can)
 518 # or where rounding is down not up on binary conversion (crays)
 519 numbers_with_total ('Q', sub {
 520                       my $len = shift;
 521                       $len = 65 if $len > 65; # unmasked total is 2**65-1 here
 522                       my $total = 1 + 2 * (int (2**($len - 1)) - 1);
 523                       return 0 if $total == $total - 1; # Overflowed integers
 524                       return $total; # NVs still accurate to nearest integer
 525                     },
 526                     0, 1,9223372036854775807, 9223372036854775808,
 527                     18446744073709551615);
 528
 529 print "# pack nvNV byteorders\n";
 530
 531 is(pack("n", 0xdead), "\xde\xad");
 532 is(pack("v", 0xdead), "\xad\xde");
 533 is(pack("N", 0xdeadbeef), "\xde\xad\xbe\xef");
 534 is(pack("V", 0xdeadbeef), "\xef\xbe\xad\xde");
 535
 536 {
 537   # /
 538
 539   my ($x, $y, $z);
 540   eval { ($x) = unpack '/a*','hello' };
 541   like($@, qr!'/' must follow a numeric type!);
 542   undef $x;
 543   eval { $x = unpack '/a*','hello' };
 544   like($@, qr!'/' must follow a numeric type!);
 545
 546   undef $x;
 547   eval { ($z,$x,$y) = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
 548   is($@, '');
 549   is($z, 'ok');
 550   is($x, 'yes');
 551   is($y, 'z');
 552   undef $z;
 553   eval { $z = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
 554   is($@, '');
 555   is($z, 'ok');
 556
 557
 558   undef $x;
 559   eval { ($x) = pack '/a*','hello' };
 560   like($@,  qr!Invalid type '/'!);
 561   undef $x;
 562   eval { $x = pack '/a*','hello' };
 563   like($@,  qr!Invalid type '/'!);
 564
 565   $z = pack 'n/a* N/Z* w/A*','string','hi there ','etc';
 566   my $expect = "\000\006string\0\0\0\012hi there \000\003etc";
 567   is($z, $expect);
 568
 569   undef $x;
 570   $expect = 'hello world';
 571   eval { ($x) = unpack ("w/a", chr (11) . "hello world!")};
 572   is($x, $expect);
 573   is($@, '');
 574
 575   undef $x;
 576   # Doing this in scalar context used to fail.
 577   eval { $x = unpack ("w/a", chr (11) . "hello world!")};
 578   is($@, '');
 579   is($x, $expect);
 580
 581   foreach (
 582            ['a/a*/a*', '212ab345678901234567','ab3456789012'],
 583            ['a/a*/a*', '3012ab345678901234567', 'ab3456789012'],
 584            ['a/a*/b*', '212ab', $Is_EBCDIC ? '100000010100' : '100001100100'],
 585   )
 586   {
 587     my ($pat, $in, $expect) = @$_;
 588     undef $x;
 589     eval { ($x) = unpack $pat, $in };
 590     is($@, '');
 591     is($x, $expect) ||
 592       printf "# list unpack ('$pat', '$in') gave %s, expected '$expect'\n",
 593              encode_list ($x);
 594
 595     undef $x;
 596     eval { $x = unpack $pat, $in };
 597     is($@, '');
 598     is($x, $expect) ||
 599       printf "# scalar unpack ('$pat', '$in') gave %s, expected '$expect'\n",
 600              encode_list ($x);
 601   }
 602
 603   # / with #
 604
 605   my $pattern = <<'EOU';
 606  a3/A                   # Count in ASCII
 607  C/a*                   # Count in a C char
 608  C/Z                    # Count in a C char but skip after \0
 609 EOU
 610
 611   $x = $y = $z =undef;
 612   eval { ($z,$x,$y) = unpack $pattern, "003ok \003yes\004z\000abc" };
 613   is($@, '');
 614   is($z, 'ok');
 615   is($x, 'yes');
 616   is($y, 'z');
 617   undef $x;
 618   eval { $z = unpack $pattern, "003ok \003yes\004z\000abc" };
 619   is($@, '');
 620   is($z, 'ok');
 621
 622   $pattern = <<'EOP';
 623   n/a*                  # Count as network short
 624   w/A*                  # Count a  BER integer
 625 EOP
 626   $expect = "\000\006string\003etc";
 627   $z = pack $pattern,'string','etc';
 628   is($z, $expect);
 629 }
 630
 631
 632 SKIP: {
 633     skip("(EBCDIC and) version strings are bad idea", 2) if $Is_EBCDIC;
 634
 635     is("1.20.300.4000", sprintf "%vd", pack("U*",1,20,300,4000));
 636     is("1.20.300.4000", sprintf "%vd", pack("  U*",1,20,300,4000));
 637 }
 638 isnt(v1.20.300.4000, sprintf "%vd", pack("C0U*",1,20,300,4000));
 639
 640 my $rslt = $Is_EBCDIC ? "156 67" : "199 162";
 641 is(join(" ", unpack("C*", chr(0x1e2))), $rslt);
 642
 643 # does pack U create Unicode?
 644 is(ord(pack('U', 300)), 300);
 645
 646 # does unpack U deref Unicode?
 647 is((unpack('U', chr(300)))[0], 300);
 648
 649 # is unpack U the reverse of pack U for Unicode string?
 650 is("@{[unpack('U*', pack('U*', 100, 200, 300))]}", "100 200 300");
 651
 652 # is unpack U the reverse of pack U for byte string?
 653 is("@{[unpack('U*', pack('U*', 100, 200))]}", "100 200");
 654
 655
 656 SKIP: {
 657     skip "Not for EBCDIC", 4 if $Is_EBCDIC;
 658
 659     # does unpack C unravel pack U?
 660     is("@{[unpack('C*', pack('U*', 100, 200))]}", "100 195 136");
 661
 662     # does pack U0C create Unicode?
 663     is("@{[pack('U0C*', 100, 195, 136)]}", v100.v200);
 664
 665     # does pack C0U create characters?
 666     is("@{[pack('C0U*', 100, 200)]}", pack("C*", 100, 195, 136));
 667
 668     # does unpack U0U on byte data warn?
 669     {
 670         local $SIG{__WARN__} = sub { $@ = "@_" };
 671         my @null = unpack('U0U', chr(255));
 672         like($@, /^Malformed UTF-8 character /);
 673     }
 674 }
 675
 676 {
 677   my $p = pack 'i*', -2147483648, ~0, 0, 1, 2147483647;
 678   my (@a);
 679   # bug - % had to be at the start of the pattern, no leading whitespace or
 680   # comments. %i! didn't work at all.
 681   foreach my $pat ('%32i*', ' %32i*', "# Muhahahaha\n%32i*", '%32i*  ',
 682                    '%32i!*', ' %32i!*', "\n#\n#\n\r \t\f%32i!*", '%32i!*#') {
 683     @a = unpack $pat, $p;
 684     is($a[0], 0xFFFFFFFF) || print "# $pat\n";
 685     @a = scalar unpack $pat, $p;
 686     is($a[0], 0xFFFFFFFF) || print "# $pat\n";
 687   }
 688
 689
 690   $p = pack 'I*', 42, 12;
 691   # Multiline patterns in scalar context failed.
 692   foreach my $pat ('I', <<EOPOEMSNIPPET, 'I#I', 'I # I', 'I # !!!') {
 693 # On the Ning Nang Nong
 694 # Where the Cows go Bong!
 695 # And the Monkeys all say Boo!
 696 I
 697 EOPOEMSNIPPET
 698     @a = unpack $pat, $p;
 699     is(scalar @a, 1);
 700     is($a[0], 42);
 701     @a = scalar unpack $pat, $p;
 702     is(scalar @a, 1);
 703     is($a[0], 42);
 704   }
 705
 706   # shorts (of all flavours) didn't calculate checksums > 32 bits with floating
 707   # point, so a pathologically long pattern would wrap at 32 bits.
 708   my $pat = "\xff\xff"x65538; # Start with it long, to save any copying.
 709   foreach (4,3,2,1,0) {
 710     my $len = 65534 + $_;
 711     is(unpack ("%33n$len", $pat), 65535 * $len);
 712   }
 713 }
 714
 715
 716 # pack x X @
 717 foreach (
 718          ['x', "N", "\0"],
 719          ['x4', "N", "\0"x4],
 720          ['xX', "N", ""],
 721          ['xXa*', "Nick", "Nick"],
 722          ['a5Xa5', "cameL", "llama", "camellama"],
 723          ['@4', 'N', "\0"x4],
 724          ['a*@8a*', 'Camel', 'Dromedary', "Camel\0\0\0Dromedary"],
 725          ['a*@4a', 'Perl rules', '!', 'Perl!'],
 726 )
 727 {
 728   my ($template, @in) = @$_;
 729   my $out = pop @in;
 730   my $got = eval {pack $template, @in};
 731   is($@, '');
 732   is($out, $got) ||
 733     printf "# pack ('$template', %s) gave %s expected %s\n",
 734            encode_list (@in), encode_list ($got), encode_list ($out);
 735 }
 736
 737 # unpack x X @
 738 foreach (
 739          ['x', "N"],
 740          ['xX', "N"],
 741          ['xXa*', "Nick", "Nick"],
 742          ['a5Xa5', "camellama", "camel", "llama"],
 743          ['@3', "ice"],
 744          ['@2a2', "water", "te"],
 745          ['a*@1a3', "steam", "steam", "tea"],
 746 )
 747 {
 748   my ($template, $in, @out) = @$_;
 749   my @got = eval {unpack $template, $in};
 750   is($@, '');
 751   ok (list_eq (\@got, \@out)) ||
 752     printf "# list unpack ('$template', %s) gave %s expected %s\n",
 753            _qq($in), encode_list (@got), encode_list (@out);
 754
 755   my $got = eval {unpack $template, $in};
 756   is($@, '');
 757   @out ? is( $got, $out[0] ) # 1 or more items; should get first
 758        : ok( !defined $got ) # 0 items; should get undef
 759     or printf "# scalar unpack ('$template', %s) gave %s expected %s\n",
 760               _qq($in), encode_list ($got), encode_list ($out[0]);
 761 }
 762
 763 {
 764     my $t = 'Z*Z*';
 765     my ($u, $v) = qw(foo xyzzy);
 766     my $p = pack($t, $u, $v);
 767     my @u = unpack($t, $p);
 768     is(scalar @u, 2);
 769     is($u[0], $u);
 770     is($u[1], $v);
 771 }
 772
 773 {
 774     is((unpack("w/a*", "\x02abc"))[0], "ab");
 775
 776     # "w/a*" should be seen as one unit
 777
 778     is(scalar unpack("w/a*", "\x02abc"), "ab");
 779 }
 780
 781 {
 782     # from Wolfgang Laun: fix in change #13163
 783
 784     my $s = 'ABC' x 10;
 785     my $t = '*';
 786     my $x = ord($t);
 787     my $buf = pack( 'Z*/A* C',  $s, $x );
 788     my $y;
 789
 790     my $h = $buf;
 791     $h =~ s/[^[:print:]]/./g;
 792     ( $s, $y ) = unpack( "Z*/A* C", $buf );
 793     is($h, "30.ABCABCABCABCABCABCABCABCABCABC$t");
 794     is(length $buf, 34);
 795     is($s, "ABCABCABCABCABCABCABCABCABCABC");
 796     is($y, $x);
 797 }
 798
 799 {
 800     # from Wolfgang Laun: fix in change #13288
 801
 802     eval { my $t=unpack("P*", "abc") };
 803     like($@, qr/'P' must have an explicit size/);
 804 }
 805
 806 {   # Grouping constructs
 807     my (@a, @b);
 808     @a = unpack '(SL)',   pack 'SLSLSL', 67..90;
 809     is("@a", "67 68");
 810     @a = unpack '(SL)3',   pack 'SLSLSL', 67..90;
 811     @b = (67..72);
 812     is("@a", "@b");
 813     @a = unpack '(SL)3',   pack 'SLSLSLSL', 67..90;
 814     is("@a", "@b");
 815     @a = unpack '(SL)[3]', pack 'SLSLSLSL', 67..90;
 816     is("@a", "@b");
 817     @a = unpack '(SL)[2] SL', pack 'SLSLSLSL', 67..90;
 818     is("@a", "@b");
 819     @a = unpack 'A/(SL)',  pack 'ASLSLSLSL', 3, 67..90;
 820     is("@a", "@b");
 821     @a = unpack 'A/(SL)SL',  pack 'ASLSLSLSL', 2, 67..90;
 822     is("@a", "@b");
 823     @a = unpack '(SL)*',   pack 'SLSLSLSL', 67..90;
 824     @b = (67..74);
 825     is("@a", "@b");
 826     @a = unpack '(SL)*SL',   pack 'SLSLSLSL', 67..90;
 827     is("@a", "@b");
 828     eval { @a = unpack '(*SL)',   '' };
 829     like($@, qr/\(\)-group starts with a count/);
 830     eval { @a = unpack '(3SL)',   '' };
 831     like($@, qr/\(\)-group starts with a count/);
 832     eval { @a = unpack '([3]SL)',   '' };
 833     like($@, qr/\(\)-group starts with a count/);
 834     eval { @a = pack '(*SL)' };
 835     like($@, qr/\(\)-group starts with a count/);
 836     @a = unpack '(SL)3 SL',   pack '(SL)4', 67..74;
 837     is("@a", "@b");
 838     @a = unpack '(SL)3 SL',   pack '(SL)[4]', 67..74;
 839     is("@a", "@b");
 840     @a = unpack '(SL)3 SL',   pack '(SL)*', 67..74;
 841     is("@a", "@b");
 842 }
 843
 844 {  # more on grouping (W.Laun)
 845   use warnings;
 846   my $warning;
 847   local $SIG{__WARN__} = sub {
 848       $warning = $_[0];
 849   };
 850   # @ absolute within ()-group
 851   my $badc = pack( '(a)*', unpack( '(@1a @0a @2)*', 'abcd' ) );
 852   is( $badc, 'badc' );
 853   my @b = ( 1, 2, 3 );
 854   my $buf = pack( '(@1c)((@2C)@3c)', @b );
 855   is( $buf, "\0\1\0\0\2\3" );
 856   my @a = unpack( '(@1c)((@2c)@3c)', $buf );
 857   is( "@a", "@b" );
 858
 859   # various unpack count/code scenarios
 860   my @Env = ( a => 'AAA', b => 'BBB' );
 861   my $env = pack( 'S(S/A*S/A*)*', @Env/2, @Env );
 862
 863   # unpack full length - ok
 864   my @pup = unpack( 'S/(S/A* S/A*)', $env );
 865   is( "@pup", "@Env" );
 866
 867   # warn when count/code goes beyond end of string
 868   # \0002 \0001 a \0003 AAA \0001 b \0003 BBB
 869   #     2     4 5     7  10    1213
 870   eval { @pup = unpack( 'S/(S/A* S/A*)', substr( $env, 0, 13 ) ) };
 871   like( $@, qr{length/code after end of string} );
 872
 873   # postfix repeat count
 874   $env = pack( '(S/A* S/A*)' . @Env/2, @Env );
 875
 876   # warn when count/code goes beyond end of string
 877   # \0001 a \0003 AAA \0001  b \0003 BBB
 878   #     2 3c    5   8    10 11    13  16
 879   eval { @pup = unpack( '(S/A* S/A*)' . @Env/2, substr( $env, 0, 11 ) ) };
 880   like( $@, qr{length/code after end of string} );
 881
 882   # catch stack overflow/segfault
 883   eval { $_ = pack( ('(' x 105) . 'A' . (')' x 105) ); };
 884   like( $@, qr{Too deeply nested \(\)-groups} );
 885 }
 886
 887 { # syntax checks (W.Laun)
 888   use warnings;
 889   my @warning;
 890   local $SIG{__WARN__} = sub {
 891       push( @warning, $_[0] );
 892   };
 893   eval { my $s = pack( 'Ax![4c]A', 1..5 ); };
 894   like( $@, qr{Malformed integer in \[\]} );
 895
 896   eval { my $buf = pack( '(c/*a*)', 'AAA', 'BB' ); };
 897   like( $@, qr{'/' does not take a repeat count} );
 898
 899   eval { my @inf = unpack( 'c/1a', "\x03AAA\x02BB" ); };
 900   like( $@, qr{'/' does not take a repeat count} );
 901
 902   eval { my @inf = unpack( 'c/*a', "\x03AAA\x02BB" ); };
 903   like( $@, qr{'/' does not take a repeat count} );
 904
 905   # white space where possible
 906   my @Env = ( a => 'AAA', b => 'BBB' );
 907   my $env = pack( ' S ( S / A*   S / A* )* ', @Env/2, @Env );
 908   my @pup = unpack( ' S / ( S / A*   S / A* ) ', $env );
 909   is( "@pup", "@Env" );
 910
 911   # white space in 4 wrong places
 912   for my $temp (  'A ![4]', 'A [4]', 'A *', 'A 4' ){
 913       eval { my $s = pack( $temp, 'B' ); };
 914       like( $@, qr{Invalid type } );
 915   }
 916
 917   # warning for commas
 918   @warning = ();
 919   my $x = pack( 'I,A', 4, 'X' );
 920   like( $warning[0], qr{Invalid type ','} );
 921
 922   # comma warning only once
 923   @warning = ();
 924   $x = pack( 'C(C,C)C,C', 65..71  );
 925   like( scalar @warning, 1 );
 926
 927   # forbidden code in []
 928   eval { my $x = pack( 'A[@4]', 'XXXX' ); };
 929   like( $@, qr{Within \[\]-length '\@' not allowed} );
 930
 931   # @ repeat default 1
 932   my $s = pack( 'AA@A', 'A', 'B', 'C' );
 933   my @c = unpack( 'AA@A', $s );
 934   is( $s, 'AC' );
 935   is( "@c", "A C C" );
 936
 937   # no unpack code after /
 938   eval { my @a = unpack( "C/", "\3" ); };
 939   like( $@, qr{Code missing after '/'} );
 940
 941 }
 942
 943 {  # Repeat count [SUBEXPR]
 944    my @codes = qw( x A Z a c C B b H h s v n S i I l V N L p P f F d
 945                    s! S! i! I! l! L! j J);
 946    my $G;
 947    if (eval { pack 'q', 1 } ) {
 948      push @codes, qw(q Q);
 949    } else {
 950      push @codes, qw(c C);      # Keep the count the same
 951    }
 952    if (eval { pack 'D', 1 } ) {
 953      push @codes, 'D';
 954    } else {
 955      push @codes, 'd';  # Keep the count the same
 956    }
 957
 958    my %val;
 959    @val{@codes} = map { / [Xx]  (?{ undef })
 960                         | [AZa] (?{ 'something' })
 961                         | C     (?{ 214 })
 962                         | c     (?{ 114 })
 963                         | [Bb]  (?{ '101' })
 964                         | [Hh]  (?{ 'b8' })
 965                         | [svnSiIlVNLqQjJ]  (?{ 10111 })
 966                         | [FfDd]  (?{ 1.36514538e67 })
 967                         | [pP]  (?{ "try this buffer" })
 968                         /x; $^R } @codes;
 969    my @end = (0x12345678, 0x23456781, 0x35465768, 0x15263748);
 970    my $end = "N4";
 971
 972    for my $type (@codes) {
 973      my @list = $val{$type};
 974      @list = () unless defined $list[0];
 975      for my $count ('', '3', '[11]') {
 976        my $c = 1;
 977        $c = $1 if $count =~ /(\d+)/;
 978        my @list1 = @list;
 979        @list1 = (@list1) x $c unless $type =~ /[XxAaZBbHhP]/;
 980        for my $groupend ('', ')2', ')[8]') {
 981            my $groupbegin = ($groupend ? '(' : '');
 982            $c = 1;
 983            $c = $1 if $groupend =~ /(\d+)/;
 984            my @list2 = (@list1) x $c;
 985
 986            my $junk1 = "$groupbegin $type$count $groupend";
 987            # print "# junk1=$junk1\n";
 988            my $p = pack $junk1, @list2;
 989            my $half = int( (length $p)/2 );
 990            for my $move ('', "X$half", "X!$half", 'x1', 'x!8', "x$half") {
 991              my $junk = "$junk1 $move";
 992              # print "# junk='$junk', list=(@list2)\n";
 993              $p = pack "$junk $end", @list2, @end;
 994              my @l = unpack "x[$junk] $end", $p;
 995              is(scalar @l, scalar @end);
 996              is("@l", "@end", "skipping x[$junk]");
 997            }
 998        }
 999      }
1000    }
1001 }
1002
1003 # / is recognized after spaces in scalar context
1004 # XXXX no spaces are allowed in pack...  In pack only before the slash...
1005 is(scalar unpack('A /A Z20', pack 'A/A* Z20', 'bcde', 'xxxxx'), 'bcde');
1006 is(scalar unpack('A /A /A Z20', '3004bcde'), 'bcde');
1007
1008 { # X! and x!
1009   my $t = 'C[3]  x!8 C[2]';
1010   my @a = (0x73..0x77);
1011   my $p = pack($t, @a);
1012   is($p, "\x73\x74\x75\0\0\0\0\0\x76\x77");
1013   my @b = unpack $t, $p;
1014   is(scalar @b, scalar @a);
1015   is("@b", "@a", 'x!8');
1016   $t = 'x[5] C[6] X!8 C[2]';
1017   @a = (0x73..0x7a);
1018   $p = pack($t, @a);
1019   is($p, "\0\0\0\0\0\x73\x74\x75\x79\x7a");
1020   @b = unpack $t, $p;
1021   @a = (0x73..0x75, 0x79, 0x7a, 0x79, 0x7a);
1022   is(scalar @b, scalar @a);
1023   is("@b", "@a");
1024 }
1025
1026 { # struct {char c1; double d; char cc[2];}
1027   my $t = 'C x![d] d C[2]';
1028   my @a = (173, 1.283476517e-45, 42, 215);
1029   my $p = pack $t, @a;
1030   ok( length $p);
1031   my @b = unpack "$t X[$t] $t", $p;     # Extract, step back, extract again
1032   is(scalar @b, 2 * scalar @a);
1033   $b = "@b";
1034   $b =~ s/(?:17000+|16999+)\d+(e-45) /17$1 /gi; # stringification is gamble
1035   is($b, "@a @a");
1036
1037   my $warning;
1038   local $SIG{__WARN__} = sub {
1039       $warning = $_[0];
1040   };
1041   @b = unpack "x[C] x[$t] X[$t] X[C] $t", "$p\0";
1042
1043   is($warning, undef);
1044   is(scalar @b, scalar @a);
1045   $b = "@b";
1046   $b =~ s/(?:17000+|16999+)\d+(e-45) /17$1 /gi; # stringification is gamble
1047   is($b, "@a");
1048 }
1049
1050 is(length(pack("j", 0)), $Config{ivsize});
1051 is(length(pack("J", 0)), $Config{uvsize});
1052 is(length(pack("F", 0)), $Config{nvsize});
1053
1054 numbers ('j', -2147483648, -1, 0, 1, 2147483647);
1055 numbers ('J', 0, 1, 2147483647, 2147483648, 4294967295);
1056 numbers ('F', -(2**34), -1, 0, 1, 2**34);
1057 SKIP: {
1058     my $t = eval { unpack("D*", pack("D", 12.34)) };
1059
1060     skip "Long doubles not in use", 56 if $@ =~ /Invalid type/;
1061
1062     is(length(pack("D", 0)), $Config{longdblsize});
1063     numbers ('D', -(2**34), -1, 0, 1, 2**34);
1064 }
1065
1066 # Maybe this knowledge needs to be "global" for all of pack.t
1067 # Or a "can checksum" which would effectively be all the number types"
1068 my %cant_checksum = map {$_=> 1} qw(A Z u w);
1069 # not a b B h H
1070 foreach my $template (qw(A Z c C s S i I l L n N v V q Q j J f d F D u U w)) {
1071   SKIP: {
1072     my $packed = eval {pack "${template}4", 1, 4, 9, 16};
1073     if ($@) {
1074       die unless $@ =~ /Invalid type '$template'/;
1075       skip ("$template not supported on this perl",
1076             $cant_checksum{$template} ? 4 : 8);
1077     }
1078     my @unpack4 = unpack "${template}4", $packed;
1079     my @unpack = unpack "${template}*", $packed;
1080     my @unpack1 = unpack "${template}", $packed;
1081     my @unpack1s = scalar unpack "${template}", $packed;
1082     my @unpack4s = scalar unpack "${template}4", $packed;
1083     my @unpacks = scalar unpack "${template}*", $packed;
1084
1085     my @tests = ( ["${template}4 vs ${template}*", \@unpack4, \@unpack],
1086                   ["scalar ${template} ${template}", \@unpack1s, \@unpack1],
1087                   ["scalar ${template}4 vs ${template}", \@unpack4s, \@unpack1],
1088                   ["scalar ${template}* vs ${template}", \@unpacks, \@unpack1],
1089                 );
1090
1091     unless ($cant_checksum{$template}) {
1092       my @unpack4_c = unpack "\%${template}4", $packed;
1093       my @unpack_c = unpack "\%${template}*", $packed;
1094       my @unpack1_c = unpack "\%${template}", $packed;
1095       my @unpack1s_c = scalar unpack "\%${template}", $packed;
1096       my @unpack4s_c = scalar unpack "\%${template}4", $packed;
1097       my @unpacks_c = scalar unpack "\%${template}*", $packed;
1098
1099       push @tests,
1100         ( ["% ${template}4 vs ${template}*", \@unpack4_c, \@unpack_c],
1101           ["% scalar ${template} ${template}", \@unpack1s_c, \@unpack1_c],
1102           ["% scalar ${template}4 vs ${template}*", \@unpack4s_c, \@unpack_c],
1103           ["% scalar ${template}* vs ${template}*", \@unpacks_c, \@unpack_c],
1104         );
1105     }
1106     foreach my $test (@tests) {
1107       ok (list_eq ($test->[1], $test->[2]), $test->[0]) ||
1108         printf "# unpack gave %s expected %s\n",
1109           encode_list (@{$test->[1]}), encode_list (@{$test->[2]});
1110     }
1111   }
1112 }
1113
1114 ok(pack('u2', 'AA'), "[perl #8026]"); # used to hang and eat RAM in perl 5.7.2
1115
1116 $_ = pack('c', 65); # 'A' would not be EBCDIC-friendly
1117 is(unpack('c'), 65, "one-arg unpack (change #18751)"); # defaulting to $_
1118
1119 {
1120     my $a = "X\t01234567\n" x 100;
1121     my @a = unpack("(a1 c/a)*", $a);
1122     is(scalar @a, 200,       "[perl #15288]");
1123     is($a[-1], "01234567\n", "[perl #15288]");
1124     is($a[-2], "X",          "[perl #15288]");
1125 }