lib/Cwd.pm

   1 package Cwd;
   2 use 5.006;
   3
   4 =head1 NAME
   5
   6 Cwd - get pathname of current working directory
   7
   8 =head1 SYNOPSIS
   9
  10     use Cwd;
  11     my $dir = getcwd;
  12
  13     use Cwd 'abs_path';
  14     my $abs_path = abs_path($file);
  15
  16 =head1 DESCRIPTION
  17
  18 This module provides functions for determining the pathname of the
  19 current working directory.  It is recommended that getcwd (or another
  20 *cwd() function) be used in I<all> code to ensure portability.
  21
  22 By default, it exports the functions cwd(), getcwd(), fastcwd(), and
  23 fastgetcwd() into the caller's namespace.
  24
  25
  26 =head2 getcwd and friends
  27
  28 Each of these functions are called without arguments and return the
  29 absolute path of the current working directory.
  30
  31 =over 4
  32
  33 =item getcwd
  34
  35     my $cwd = getcwd();
  36
  37 Returns the current working directory.
  38
  39 Re-implements the getcwd(3) (or getwd(3)) functions in Perl.
  40
  41 =item cwd
  42
  43     my $cwd = cwd();
  44
  45 The cwd() is the most natural form for the current architecture. For
  46 most systems it is identical to `pwd` (but without the trailing line
  47 terminator).
  48
  49 Unfortunately, cwd() tends to break if called under taint mode.
  50
  51 =item fastcwd
  52
  53     my $cwd = fastcwd();
  54
  55 A more dangerous version of getcwd(), but potentially faster.
  56
  57 It might conceivably chdir() you out of a directory that it can't
  58 chdir() you back into.  If fastcwd encounters a problem it will return
  59 undef but will probably leave you in a different directory.  For a
  60 measure of extra security, if everything appears to have worked, the
  61 fastcwd() function will check that it leaves you in the same directory
  62 that it started in. If it has changed it will C<die> with the message
  63 "Unstable directory path, current directory changed
  64 unexpectedly". That should never happen.
  65
  66 =item fastgetcwd
  67
  68   my $cwd = fastgetcwd();
  69
  70 The fastgetcwd() function is provided as a synonym for cwd().
  71
  72 =back
  73
  74
  75 =head2 abs_path and friends
  76
  77 These functions are exported only on request.  They each take a single
  78 argument and return the absolute pathname for it.
  79
  80 =over 4
  81
  82 =item abs_path
  83
  84   my $abs_path = abs_path($file);
  85
  86 Uses the same algorithm as getcwd().  Symbolic links and relative-path
  87 components ("." and "..") are resolved to return the canonical
  88 pathname, just like realpath(3).
  89
  90 =item realpath
  91
  92   my $abs_path = realpath($file);
  93
  94 A synonym for abs_path().
  95
  96 =item fast_abs_path
  97
  98   my $abs_path = fast_abs_path($file);
  99
 100 A more dangerous, but potentially faster version of abs_path.
 101
 102 =back
 103
 104 =head2 $ENV{PWD}
 105
 106 If you ask to override your chdir() built-in function,
 107
 108   use Cwd qw(chdir);
 109
 110 then your PWD environment variable will be kept up to date.  Note that
 111 it will only be kept up to date if all packages which use chdir import
 112 it from Cwd.
 113
 114
 115 =head1 NOTES
 116
 117 =over 4
 118
 119 =item *
 120
 121 Since the path seperators are different on some operating systems ('/'
 122 on Unix, ':' on MacPerl, etc...) we recommend you use the File::Spec
 123 modules wherever portability is a concern.
 124
 125 =item *
 126
 127 Actually, on Mac OS, the C<getcwd()>, C<fastgetcwd()> and C<fastcwd()>
 128 functions  are all aliases for the C<cwd()> function, which, on Mac OS,
 129 calls `pwd`. Likewise, the C<abs_path()> function is an alias for
 130 C<fast_abs_path()>.
 131
 132 =back
 133
 134 =head1 SEE ALSO
 135
 136 L<File::chdir>
 137
 138 =cut
 139
 140 use strict;
 141
 142 use Carp;
 143
 144 our $VERSION = '2.06';
 145
 146 use base qw/ Exporter /;
 147 our @EXPORT = qw(cwd getcwd fastcwd fastgetcwd);
 148 our @EXPORT_OK = qw(chdir abs_path fast_abs_path realpath fast_realpath);
 149
 150 # sys_cwd may keep the builtin command
 151
 152 # All the functionality of this module may provided by builtins,
 153 # there is no sense to process the rest of the file.
 154 # The best choice may be to have this in BEGIN, but how to return from BEGIN?
 155
 156 if ($^O eq 'os2' && defined &sys_cwd && defined &sys_abspath) {
 157     local $^W = 0;
 158     *cwd                = \&sys_cwd;
 159     *getcwd             = \&cwd;
 160     *fastgetcwd         = \&cwd;
 161     *fastcwd            = \&cwd;
 162     *abs_path           = \&sys_abspath;
 163     *fast_abs_path      = \&abs_path;
 164     *realpath           = \&abs_path;
 165     *fast_realpath      = \&abs_path;
 166     return 1;
 167 }
 168
 169 eval {
 170     require XSLoader;
 171     undef *Cwd::fastcwd; # avoid redefinition warning
 172     XSLoader::load('Cwd');
 173 };
 174
 175
 176 # Find the pwd command in the expected locations.  We assume these
 177 # are safe.  This prevents _backtick_pwd() consulting $ENV{PATH}
 178 # so everything works under taint mode.
 179 my $pwd_cmd;
 180 foreach my $try (qw(/bin/pwd /usr/bin/pwd)) {
 181     if( -x $try ) {
 182         $pwd_cmd = $try;
 183         last;
 184     }
 185 }
 186 $pwd_cmd ||= 'pwd';
 187
 188 # The 'natural and safe form' for UNIX (pwd may be setuid root)
 189 sub _backtick_pwd {
 190     my $cwd = `$pwd_cmd`;
 191     # Belt-and-suspenders in case someone said "undef $/".
 192     local $/ = "\n";
 193     # `pwd` may fail e.g. if the disk is full
 194     chomp($cwd) if defined $cwd;
 195     $cwd;
 196 }
 197
 198 # Since some ports may predefine cwd internally (e.g., NT)
 199 # we take care not to override an existing definition for cwd().
 200
 201 unless(defined &cwd) {
 202     # The pwd command is not available in some chroot(2)'ed environments
 203     if( $^O eq 'MacOS' || (defined $ENV{PATH} &&
 204                            grep { -x "$_/pwd" } split(':', $ENV{PATH})) )
 205     {
 206         *cwd = \&_backtick_pwd;
 207     }
 208     else {
 209         *cwd = \&getcwd;
 210     }
 211 }
 212
 213 # set a reasonable (and very safe) default for fastgetcwd, in case it
 214 # isn't redefined later (20001212 rspier)
 215 *fastgetcwd = \&cwd;
 216
 217 # By Brandon S. Allbery
 218 #
 219 # Usage: $cwd = getcwd();
 220
 221 sub getcwd
 222 {
 223     abs_path('.');
 224 }
 225
 226
 227 # By John Bazik
 228 #
 229 # Usage: $cwd = &fastcwd;
 230 #
 231 # This is a faster version of getcwd.  It's also more dangerous because
 232 # you might chdir out of a directory that you can't chdir back into.
 233
 234 sub fastcwd {
 235     my($odev, $oino, $cdev, $cino, $tdev, $tino);
 236     my(@path, $path);
 237     local(*DIR);
 238
 239     my($orig_cdev, $orig_cino) = stat('.');
 240     ($cdev, $cino) = ($orig_cdev, $orig_cino);
 241     for (;;) {
 242         my $direntry;
 243         ($odev, $oino) = ($cdev, $cino);
 244         CORE::chdir('..') || return undef;
 245         ($cdev, $cino) = stat('.');
 246         last if $odev == $cdev && $oino == $cino;
 247         opendir(DIR, '.') || return undef;
 248         for (;;) {
 249             $direntry = readdir(DIR);
 250             last unless defined $direntry;
 251             next if $direntry eq '.';
 252             next if $direntry eq '..';
 253
 254             ($tdev, $tino) = lstat($direntry);
 255             last unless $tdev != $odev || $tino != $oino;
 256         }
 257         closedir(DIR);
 258         return undef unless defined $direntry; # should never happen
 259         unshift(@path, $direntry);
 260     }
 261     $path = '/' . join('/', @path);
 262     if ($^O eq 'apollo') { $path = "/".$path; }
 263     # At this point $path may be tainted (if tainting) and chdir would fail.
 264     # To be more useful we untaint it then check that we landed where we started.
 265     $path = $1 if $path =~ /^(.*)\z/s;  # untaint
 266     CORE::chdir($path) || return undef;
 267     ($cdev, $cino) = stat('.');
 268     die "Unstable directory path, current directory changed unexpectedly"
 269         if $cdev != $orig_cdev || $cino != $orig_cino;
 270     $path;
 271 }
 272
 273
 274 # Keeps track of current working directory in PWD environment var
 275 # Usage:
 276 #       use Cwd 'chdir';
 277 #       chdir $newdir;
 278
 279 my $chdir_init = 0;
 280
 281 sub chdir_init {
 282     if ($ENV{'PWD'} and $^O ne 'os2' and $^O ne 'dos' and $^O ne 'MSWin32') {
 283         my($dd,$di) = stat('.');
 284         my($pd,$pi) = stat($ENV{'PWD'});
 285         if (!defined $dd or !defined $pd or $di != $pi or $dd != $pd) {
 286             $ENV{'PWD'} = cwd();
 287         }
 288     }
 289     else {
 290         my $wd = cwd();
 291         $wd = Win32::GetFullPathName($wd) if $^O eq 'MSWin32';
 292         $ENV{'PWD'} = $wd;
 293     }
 294     # Strip an automounter prefix (where /tmp_mnt/foo/bar == /foo/bar)
 295     if ($^O ne 'MSWin32' and $ENV{'PWD'} =~ m|(/[^/]+(/[^/]+/[^/]+))(.*)|s) {
 296         my($pd,$pi) = stat($2);
 297         my($dd,$di) = stat($1);
 298         if (defined $pd and defined $dd and $di == $pi and $dd == $pd) {
 299             $ENV{'PWD'}="$2$3";
 300         }
 301     }
 302     $chdir_init = 1;
 303 }
 304
 305 sub chdir {
 306     my $newdir = @_ ? shift : '';       # allow for no arg (chdir to HOME dir)
 307     $newdir =~ s|///*|/|g unless $^O eq 'MSWin32';
 308     chdir_init() unless $chdir_init;
 309     my $newpwd;
 310     if ($^O eq 'MSWin32') {
 311         # get the full path name *before* the chdir()
 312         $newpwd = Win32::GetFullPathName($newdir);
 313     }
 314
 315     return 0 unless CORE::chdir $newdir;
 316
 317     if ($^O eq 'VMS') {
 318         return $ENV{'PWD'} = $ENV{'DEFAULT'}
 319     }
 320     elsif ($^O eq 'MacOS') {
 321         return $ENV{'PWD'} = cwd();
 322     }
 323     elsif ($^O eq 'MSWin32') {
 324         $ENV{'PWD'} = $newpwd;
 325         return 1;
 326     }
 327
 328     if ($newdir =~ m#^/#s) {
 329         $ENV{'PWD'} = $newdir;
 330     } else {
 331         my @curdir = split(m#/#,$ENV{'PWD'});
 332         @curdir = ('') unless @curdir;
 333         my $component;
 334         foreach $component (split(m#/#, $newdir)) {
 335             next if $component eq '.';
 336             pop(@curdir),next if $component eq '..';
 337             push(@curdir,$component);
 338         }
 339         $ENV{'PWD'} = join('/',@curdir) || '/';
 340     }
 341     1;
 342 }
 343
 344
 345 # In case the XS version doesn't load.
 346 *abs_path = \&_perl_abs_path unless defined &abs_path;
 347 sub _perl_abs_path
 348 {
 349     my $start = @_ ? shift : '.';
 350     my($dotdots, $cwd, @pst, @cst, $dir, @tst);
 351
 352     unless (@cst = stat( $start ))
 353     {
 354         carp "stat($start): $!";
 355         return '';
 356     }
 357     $cwd = '';
 358     $dotdots = $start;
 359     do
 360     {
 361         $dotdots .= '/..';
 362         @pst = @cst;
 363         unless (opendir(PARENT, $dotdots))
 364         {
 365             carp "opendir($dotdots): $!";
 366             return '';
 367         }
 368         unless (@cst = stat($dotdots))
 369         {
 370             carp "stat($dotdots): $!";
 371             closedir(PARENT);
 372             return '';
 373         }
 374         if ($pst[0] == $cst[0] && $pst[1] == $cst[1])
 375         {
 376             $dir = undef;
 377         }
 378         else
 379         {
 380             do
 381             {
 382                 unless (defined ($dir = readdir(PARENT)))
 383                 {
 384                     carp "readdir($dotdots): $!";
 385                     closedir(PARENT);
 386                     return '';
 387                 }
 388                 $tst[0] = $pst[0]+1 unless (@tst = lstat("$dotdots/$dir"))
 389             }
 390             while ($dir eq '.' || $dir eq '..' || $tst[0] != $pst[0] ||
 391                    $tst[1] != $pst[1]);
 392         }
 393         $cwd = (defined $dir ? "$dir" : "" ) . "/$cwd" ;
 394         closedir(PARENT);
 395     } while (defined $dir);
 396     chop($cwd) unless $cwd eq '/'; # drop the trailing /
 397     $cwd;
 398 }
 399
 400
 401 # added function alias for those of us more
 402 # used to the libc function.  --tchrist 27-Jan-00
 403 *realpath = \&abs_path;
 404
 405 sub fast_abs_path {
 406     my $cwd = getcwd();
 407     require File::Spec;
 408     my $path = @_ ? shift : File::Spec->curdir;
 409     CORE::chdir($path) || croak "Cannot chdir to $path:$!";
 410     my $realpath = getcwd();
 411     CORE::chdir($cwd)  || croak "Cannot chdir back to $cwd:$!";
 412     $realpath;
 413 }
 414
 415 # added function alias to follow principle of least surprise
 416 # based on previous aliasing.  --tchrist 27-Jan-00
 417 *fast_realpath = \&fast_abs_path;
 418
 419
 420 # --- PORTING SECTION ---
 421
 422 # VMS: $ENV{'DEFAULT'} points to default directory at all times
 423 # 06-Mar-1996  Charles Bailey  bailey@newman.upenn.edu
 424 # Note: Use of Cwd::chdir() causes the logical name PWD to be defined
 425 #   in the process logical name table as the default device and directory
 426 #   seen by Perl. This may not be the same as the default device
 427 #   and directory seen by DCL after Perl exits, since the effects
 428 #   the CRTL chdir() function persist only until Perl exits.
 429
 430 sub _vms_cwd {
 431     return $ENV{'DEFAULT'};
 432 }
 433
 434 sub _vms_abs_path {
 435     return $ENV{'DEFAULT'} unless @_;
 436     my $path = VMS::Filespec::pathify($_[0]);
 437     croak("Invalid path name $_[0]") unless defined $path;
 438     return VMS::Filespec::rmsexpand($path);
 439 }
 440
 441 sub _os2_cwd {
 442     $ENV{'PWD'} = `cmd /c cd`;
 443     chop $ENV{'PWD'};
 444     $ENV{'PWD'} =~ s:\\:/:g ;
 445     return $ENV{'PWD'};
 446 }
 447
 448 sub _win32_cwd {
 449     $ENV{'PWD'} = Win32::GetCwd();
 450     $ENV{'PWD'} =~ s:\\:/:g ;
 451     return $ENV{'PWD'};
 452 }
 453
 454 *_NT_cwd = \&_win32_cwd if (!defined &_NT_cwd &&
 455                             defined &Win32::GetCwd);
 456
 457 *_NT_cwd = \&_os2_cwd unless defined &_NT_cwd;
 458
 459 sub _dos_cwd {
 460     if (!defined &Dos::GetCwd) {
 461         $ENV{'PWD'} = `command /c cd`;
 462         chop $ENV{'PWD'};
 463         $ENV{'PWD'} =~ s:\\:/:g ;
 464     } else {
 465         $ENV{'PWD'} = Dos::GetCwd();
 466     }
 467     return $ENV{'PWD'};
 468 }
 469
 470 sub _qnx_cwd {
 471         local $ENV{PATH} = '';
 472         local $ENV{CDPATH} = '';
 473         local $ENV{ENV} = '';
 474     $ENV{'PWD'} = `/usr/bin/fullpath -t`;
 475     chop $ENV{'PWD'};
 476     return $ENV{'PWD'};
 477 }
 478
 479 sub _qnx_abs_path {
 480         local $ENV{PATH} = '';
 481         local $ENV{CDPATH} = '';
 482         local $ENV{ENV} = '';
 483     my $path = @_ ? shift : '.';
 484     my $realpath=`/usr/bin/fullpath -t $path`;
 485     chop $realpath;
 486     return $realpath;
 487 }
 488
 489 sub _epoc_cwd {
 490     $ENV{'PWD'} = EPOC::getcwd();
 491     return $ENV{'PWD'};
 492 }
 493
 494 {
 495     no warnings;        # assignments trigger 'subroutine redefined' warning
 496
 497     if ($^O eq 'VMS') {
 498         *cwd            = \&_vms_cwd;
 499         *getcwd         = \&_vms_cwd;
 500         *fastcwd        = \&_vms_cwd;
 501         *fastgetcwd     = \&_vms_cwd;
 502         *abs_path       = \&_vms_abs_path;
 503         *fast_abs_path  = \&_vms_abs_path;
 504     }
 505     elsif ($^O eq 'NT' or $^O eq 'MSWin32') {
 506         # We assume that &_NT_cwd is defined as an XSUB or in the core.
 507         *cwd            = \&_NT_cwd;
 508         *getcwd         = \&_NT_cwd;
 509         *fastcwd        = \&_NT_cwd;
 510         *fastgetcwd     = \&_NT_cwd;
 511         *abs_path       = \&fast_abs_path;
 512         *realpath   = \&fast_abs_path;
 513     }
 514     elsif ($^O eq 'os2') {
 515         # sys_cwd may keep the builtin command
 516         *cwd            = defined &sys_cwd ? \&sys_cwd : \&_os2_cwd;
 517         *getcwd         = \&cwd;
 518         *fastgetcwd     = \&cwd;
 519         *fastcwd        = \&cwd;
 520         *abs_path       = \&fast_abs_path;
 521     }
 522     elsif ($^O eq 'dos') {
 523         *cwd            = \&_dos_cwd;
 524         *getcwd         = \&_dos_cwd;
 525         *fastgetcwd     = \&_dos_cwd;
 526         *fastcwd        = \&_dos_cwd;
 527         *abs_path       = \&fast_abs_path;
 528     }
 529     elsif ($^O =~ m/^(?:qnx|nto)$/ ) {
 530         *cwd            = \&_qnx_cwd;
 531         *getcwd         = \&_qnx_cwd;
 532         *fastgetcwd     = \&_qnx_cwd;
 533         *fastcwd        = \&_qnx_cwd;
 534         *abs_path       = \&_qnx_abs_path;
 535         *fast_abs_path  = \&_qnx_abs_path;
 536     }
 537     elsif ($^O eq 'cygwin') {
 538         *getcwd = \&cwd;
 539         *fastgetcwd     = \&cwd;
 540         *fastcwd        = \&cwd;
 541         *abs_path       = \&fast_abs_path;
 542     }
 543     elsif ($^O eq 'epoc') {
 544         *cwd            = \&_epoc_cwd;
 545         *getcwd         = \&_epoc_cwd;
 546         *fastgetcwd     = \&_epoc_cwd;
 547         *fastcwd        = \&_epoc_cwd;
 548         *abs_path       = \&fast_abs_path;
 549     }
 550     elsif ($^O eq 'MacOS') {
 551         *getcwd     = \&cwd;
 552         *fastgetcwd = \&cwd;
 553         *fastcwd    = \&cwd;
 554         *abs_path   = \&fast_abs_path;
 555     }
 556 }
 557
 558
 559 1;