t/run/switches.t

   1 #!./perl -w
   2
   3 # Tests for the command-line switches:
   4 # -0, -c, -l, -s, -m, -M, -V, -v, -h, -i, -E and all unknown
   5 # Some switches have their own tests, see MANIFEST.
   6
   7 BEGIN {
   8     chdir 't' if -d 't';
   9     @INC = '../lib';
  10 }
  11
  12 BEGIN { require "./test.pl"; }
  13
  14 plan(tests => 71);
  15
  16 use Config;
  17
  18 # due to a bug in VMS's piping which makes it impossible for runperl()
  19 # to emulate echo -n (ie. stdin always winds up with a newline), these
  20 # tests almost totally fail.
  21 $TODO = "runperl() unable to emulate echo -n due to pipe bug" if $^O eq 'VMS';
  22
  23 my $r;
  24 my @tmpfiles = ();
  25 END { unlink @tmpfiles }
  26
  27 # Tests for -0
  28
  29 $r = runperl(
  30     switches    => [ '-0', ],
  31     stdin       => 'foo\0bar\0baz\0',
  32     prog        => 'print qq(<$_>) while <>',
  33 );
  34 is( $r, "<foo\0><bar\0><baz\0>", "-0" );
  35
  36 $r = runperl(
  37     switches    => [ '-l', '-0', '-p' ],
  38     stdin       => 'foo\0bar\0baz\0',
  39     prog        => '1',
  40 );
  41 is( $r, "foo\nbar\nbaz\n", "-0 after a -l" );
  42
  43 $r = runperl(
  44     switches    => [ '-0', '-l', '-p' ],
  45     stdin       => 'foo\0bar\0baz\0',
  46     prog        => '1',
  47 );
  48 is( $r, "foo\0bar\0baz\0", "-0 before a -l" );
  49
  50 $r = runperl(
  51     switches    => [ sprintf("-0%o", ord 'x') ],
  52     stdin       => 'fooxbarxbazx',
  53     prog        => 'print qq(<$_>) while <>',
  54 );
  55 is( $r, "<foox><barx><bazx>", "-0 with octal number" );
  56
  57 $r = runperl(
  58     switches    => [ '-00', '-p' ],
  59     stdin       => 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
  60     prog        => 's/\n/-/g;$_.=q(/)',
  61 );
  62 is( $r, 'abc-def--/ghi-jkl-mno--/pq-/', '-00 (paragraph mode)' );
  63
  64 $r = runperl(
  65     switches    => [ '-0777', '-p' ],
  66     stdin       => 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
  67     prog        => 's/\n/-/g;$_.=q(/)',
  68 );
  69 is( $r, 'abc-def--ghi-jkl-mno--pq-/', '-0777 (slurp mode)' );
  70
  71 $r = runperl(
  72     switches    => [ '-066' ],
  73     prog        => 'BEGIN { print qq{($/)} } print qq{[$/]}',
  74 );
  75 is( $r, "(\066)[\066]", '$/ set at compile-time' );
  76
  77 # Tests for -c
  78
  79 my $filename = tempfile();
  80 SKIP: {
  81     local $TODO = '';   # this one works on VMS
  82
  83     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
  84     print $f <<'SWTEST';
  85 BEGIN { print "block 1\n"; }
  86 CHECK { print "block 2\n"; }
  87 INIT  { print "block 3\n"; }
  88         print "block 4\n";
  89 END   { print "block 5\n"; }
  90 SWTEST
  91     close $f or die "Could not close: $!";
  92     $r = runperl(
  93         switches        => [ '-c' ],
  94         progfile        => $filename,
  95         stderr          => 1,
  96     );
  97     # Because of the stderr redirection, we can't tell reliably the order
  98     # in which the output is given
  99     ok(
 100         $r =~ /$filename syntax OK/
 101         && $r =~ /\bblock 1\b/
 102         && $r =~ /\bblock 2\b/
 103         && $r !~ /\bblock 3\b/
 104         && $r !~ /\bblock 4\b/
 105         && $r !~ /\bblock 5\b/,
 106         '-c'
 107     );
 108 }
 109
 110 # Tests for -l
 111
 112 $r = runperl(
 113     switches    => [ sprintf("-l%o", ord 'x') ],
 114     prog        => 'print for qw/foo bar/'
 115 );
 116 is( $r, 'fooxbarx', '-l with octal number' );
 117
 118 # Tests for -s
 119
 120 $r = runperl(
 121     switches    => [ '-s' ],
 122     prog        => 'for (qw/abc def ghi/) {print defined $$_ ? $$_ : q(-)}',
 123     args        => [ '--', '-abc=2', '-def', ],
 124 );
 125 is( $r, '21-', '-s switch parsing' );
 126
 127 $filename = tempfile();
 128 SKIP: {
 129     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
 130     print $f <<'SWTEST';
 131 #!perl -s
 132 BEGIN { print $x,$y; exit }
 133 SWTEST
 134     close $f or die "Could not close: $!";
 135     $r = runperl(
 136         progfile    => $filename,
 137         args        => [ '-x=foo -y' ],
 138     );
 139     is( $r, 'foo1', '-s on the shebang line' );
 140 }
 141
 142 # Bug ID 20011106.084
 143 $filename = tempfile();
 144 SKIP: {
 145     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
 146     print $f <<'SWTEST';
 147 #!perl -sn
 148 BEGIN { print $x; exit }
 149 SWTEST
 150     close $f or die "Could not close: $!";
 151     $r = runperl(
 152         progfile    => $filename,
 153         args        => [ '-x=foo' ],
 154     );
 155     is( $r, 'foo', '-sn on the shebang line' );
 156 }
 157
 158 # Tests for -m and -M
 159
 160 my $package = tempfile();
 161 $filename = "$package.pm";
 162 SKIP: {
 163     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!",4 );
 164     print $f <<"SWTESTPM";
 165 package $package;
 166 sub import { print map "<\$_>", \@_ }
 167 1;
 168 SWTESTPM
 169     close $f or die "Could not close: $!";
 170     $r = runperl(
 171         switches    => [ "-M$package" ],
 172         prog        => '1',
 173     );
 174     is( $r, "<$package>", '-M' );
 175     $r = runperl(
 176         switches    => [ "-M$package=foo" ],
 177         prog        => '1',
 178     );
 179     is( $r, "<$package><foo>", '-M with import parameter' );
 180     $r = runperl(
 181         switches    => [ "-m$package" ],
 182         prog        => '1',
 183     );
 184
 185     {
 186         local $TODO = '';  # this one works on VMS
 187         is( $r, '', '-m' );
 188     }
 189     $r = runperl(
 190         switches    => [ "-m$package=foo,bar" ],
 191         prog        => '1',
 192     );
 193     is( $r, "<$package><foo><bar>", '-m with import parameters' );
 194     push @tmpfiles, $filename;
 195
 196   {
 197     local $TODO = '';  # these work on VMS
 198
 199     is( runperl( switches => [ '-MTie::Hash' ], stderr => 1, prog => 1 ),
 200           '', "-MFoo::Bar allowed" );
 201
 202     like( runperl( switches => [ "-M:$package" ], stderr => 1,
 203                    prog => 'die "oops"' ),
 204           qr/Invalid module name [\w:]+ with -M option\b/,
 205           "-M:Foo not allowed" );
 206
 207     like( runperl( switches => [ '-mA:B:C' ], stderr => 1,
 208                    prog => 'die "oops"' ),
 209           qr/Invalid module name [\w:]+ with -m option\b/,
 210           "-mFoo:Bar not allowed" );
 211
 212     like( runperl( switches => [ '-m-A:B:C' ], stderr => 1,
 213                    prog => 'die "oops"' ),
 214           qr/Invalid module name [\w:]+ with -m option\b/,
 215           "-m-Foo:Bar not allowed" );
 216
 217     like( runperl( switches => [ '-m-' ], stderr => 1,
 218                    prog => 'die "oops"' ),
 219           qr/Module name required with -m option\b/,
 220           "-m- not allowed" );
 221
 222     like( runperl( switches => [ '-M-=' ], stderr => 1,
 223                    prog => 'die "oops"' ),
 224           qr/Module name required with -M option\b/,
 225           "-M- not allowed" );
 226   }  # disable TODO on VMS
 227 }
 228
 229 # Tests for -V
 230
 231 {
 232     local $TODO = '';   # these ones should work on VMS
 233
 234     # basic perl -V should generate significant output.
 235     # we don't test actual format too much since it could change
 236     like( runperl( switches => ['-V'] ), qr/(\n.*){20}/,
 237           '-V generates 20+ lines' );
 238
 239     like( runperl( switches => ['-V'] ),
 240           qr/\ASummary of my perl5 .*configuration:/,
 241           '-V looks okay' );
 242
 243     # lookup a known config var
 244     chomp( $r=runperl( switches => ['-V:osname'] ) );
 245     is( $r, "osname='$^O';", 'perl -V:osname');
 246
 247     # lookup a nonexistent var
 248     chomp( $r=runperl( switches => ['-V:this_var_makes_switches_test_fail'] ) );
 249     is( $r, "this_var_makes_switches_test_fail='UNKNOWN';",
 250         'perl -V:unknown var');
 251
 252     # regexp lookup
 253     # platforms that don't like this quoting can either skip this test
 254     # or fix test.pl _quote_args
 255     $r = runperl( switches => ['"-V:i\D+size"'] );
 256     # should be unlike( $r, qr/^$|not found|UNKNOWN/ );
 257     like( $r, qr/^(?!.*(not found|UNKNOWN))./, 'perl -V:re got a result' );
 258
 259     # make sure each line we got matches the re
 260     ok( !( grep !/^i\D+size=/, split /^/, $r ), '-V:re correct' );
 261 }
 262
 263 # Tests for -v
 264
 265 {
 266     local $TODO = '';   # these ones should work on VMS
 267     # there are definitely known build configs where this test will fail
 268     # DG/UX comes to mind. Maybe we should remove these special cases?
 269     my $v = sprintf "%vd", $^V;
 270     my $ver = $Config{PERL_VERSION};
 271     my $rel = $Config{PERL_SUBVERSION};
 272     like( runperl( switches => ['-v'] ),
 273           qr/This is perl 5, version \Q$ver\E, subversion \Q$rel\E \(v\Q$v\E(?:[-*\w]+| \([^)]+\))?\) built for \Q$Config{archname}\E.+Copyright.+Larry Wall.+Artistic License.+GNU General Public License/s,
 274           '-v looks okay' );
 275
 276 }
 277
 278 # Tests for -h
 279
 280 {
 281     local $TODO = '';   # these ones should work on VMS
 282
 283     like( runperl( switches => ['-h'] ),
 284           qr/Usage: .+(?i:perl(?:$Config{_exe})?).+switches.+programfile.+arguments/,
 285           '-h looks okay' );
 286
 287 }
 288
 289 # Tests for switches which do not exist
 290
 291 foreach my $switch (split //, "ABbGgHJjKkLNOoPQqRrYyZz123456789_")
 292 {
 293     local $TODO = '';   # these ones should work on VMS
 294
 295     like( runperl( switches => ["-$switch"], stderr => 1,
 296                    prog => 'die "oops"' ),
 297           qr/\QUnrecognized switch: -$switch  (-h will show valid options)./,
 298           "-$switch correctly unknown" );
 299
 300 }
 301
 302 # Tests for -i
 303
 304 {
 305     local $TODO = '';   # these ones should work on VMS
 306
 307     sub do_i_unlink { 1 while unlink("file", "file.bak") }
 308
 309     open(FILE, ">file") or die "$0: Failed to create 'file': $!";
 310     print FILE <<__EOF__;
 311 foo yada dada
 312 bada foo bing
 313 king kong foo
 314 __EOF__
 315     close FILE;
 316
 317     END { do_i_unlink() }
 318
 319     runperl( switches => ['-pi.bak'], prog => 's/foo/bar/', args => ['file'] );
 320
 321     open(FILE, "file") or die "$0: Failed to open 'file': $!";
 322     chomp(my @file = <FILE>);
 323     close FILE;
 324
 325     open(BAK, "file.bak") or die "$0: Failed to open 'file': $!";
 326     chomp(my @bak = <BAK>);
 327     close BAK;
 328
 329     is(join(":", @file),
 330        "bar yada dada:bada bar bing:king kong bar",
 331        "-i new file");
 332     is(join(":", @bak),
 333        "foo yada dada:bada foo bing:king kong foo",
 334        "-i backup file");
 335 }
 336
 337 # Tests for -E
 338
 339 $TODO = '';  # the -E tests work on VMS
 340
 341 $r = runperl(
 342     switches    => [ '-E', '"say q(Hello, world!)"']
 343 );
 344 is( $r, "Hello, world!\n", "-E say" );
 345
 346
 347 $r = runperl(
 348     switches    => [ '-E', '"undef ~~ undef and say q(Hello, world!)"']
 349 );
 350 is( $r, "Hello, world!\n", "-E ~~" );
 351
 352 $r = runperl(
 353     switches    => [ '-E', '"given(undef) {when(undef) { say q(Hello, world!)"}}']
 354 );
 355 is( $r, "Hello, world!\n", "-E given" );
 356
 357 $r = runperl(
 358     switches    => [ '-nE', q("} END { say q/affe/") ],
 359     stdin       => 'zomtek',
 360 );
 361 is( $r, "affe\n", '-E works outside of the block created by -n' );
 362
 363 $r = runperl(
 364     switches    => [ '-E', q("*{'bar'} = sub{}; print 'Hello, world!',qq|\n|;")]
 365 );
 366 is( $r, "Hello, world!\n", "-E does not enable strictures" );
 367
 368 # RT #30660
 369
 370 $filename = tempfile();
 371 SKIP: {
 372     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
 373     print $f <<'SWTEST';
 374 #!perl -w    -iok
 375 print "$^I\n";
 376 SWTEST
 377     close $f or die "Could not close: $!";
 378     $r = runperl(
 379         progfile    => $filename,
 380     );
 381     like( $r, qr/ok/, 'Spaces on the #! line (#30660)' );
 382 }