ext/re/re.pm

   1 package re;
   2
   3 # pragma for controlling the regex engine
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION     = "0.10";
   8 our @ISA         = qw(Exporter);
   9 our @EXPORT_OK   = ('regmust',
  10                     qw(is_regexp regexp_pattern
  11                        regname regnames regnames_count));
  12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
  13
  14 my %bitmask = (
  15     taint   => 0x00100000, # HINT_RE_TAINT
  16     eval    => 0x00200000, # HINT_RE_EVAL
  17 );
  18
  19 sub setcolor {
  20  eval {                         # Ignore errors
  21   require Term::Cap;
  22
  23   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
  24   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
  25   my @props = split /,/, $props;
  26   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
  27
  28   $colors =~ s/\0//g;
  29   $ENV{PERL_RE_COLORS} = $colors;
  30  };
  31  if ($@) {
  32     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
  33  }
  34
  35 }
  36
  37 my %flags = (
  38     COMPILE         => 0x0000FF,
  39     PARSE           => 0x000001,
  40     OPTIMISE        => 0x000002,
  41     TRIEC           => 0x000004,
  42     DUMP            => 0x000008,
  43     FLAGS           => 0x000010,
  44
  45     EXECUTE         => 0x00FF00,
  46     INTUIT          => 0x000100,
  47     MATCH           => 0x000200,
  48     TRIEE           => 0x000400,
  49
  50     EXTRA           => 0xFF0000,
  51     TRIEM           => 0x010000,
  52     OFFSETS         => 0x020000,
  53     OFFSETSDBG      => 0x040000,
  54     STATE           => 0x080000,
  55     OPTIMISEM       => 0x100000,
  56     STACK           => 0x280000,
  57     BUFFERS         => 0x400000,
  58     GPOS            => 0x800000,
  59 );
  60 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
  61 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
  62 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
  63 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
  64 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
  65 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
  66
  67 if (defined &DynaLoader::boot_DynaLoader) {
  68     require XSLoader;
  69     XSLoader::load( __PACKAGE__, $VERSION);
  70 }
  71 # else we're miniperl
  72 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
  73 # uses re 'taint'.
  74
  75 sub _load_unload {
  76     my ($on)= @_;
  77     if ($on) {
  78         # We call install() every time, as if we didn't, we wouldn't
  79         # "see" any changes to the color environment var since
  80         # the last time it was called.
  81
  82         # install() returns an integer, which if casted properly
  83         # in C resolves to a structure containing the regex
  84         # hooks. Setting it to a random integer will guarantee
  85         # segfaults.
  86         $^H{regcomp} = install();
  87     } else {
  88         delete $^H{regcomp};
  89     }
  90 }
  91
  92 sub bits {
  93     my $on = shift;
  94     my $bits = 0;
  95     unless (@_) {
  96         require Carp;
  97         Carp::carp("Useless use of \"re\" pragma");
  98     }
  99     foreach my $idx (0..$#_){
 100         my $s=$_[$idx];
 101         if ($s eq 'Debug' or $s eq 'Debugcolor') {
 102             setcolor() if $s =~/color/i;
 103             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
 104             for my $idx ($idx+1..$#_) {
 105                 if ($flags{$_[$idx]}) {
 106                     if ($on) {
 107                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
 108                     } else {
 109                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
 110                     }
 111                 } else {
 112                     require Carp;
 113                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
 114                                join(", ",sort keys %flags ) );
 115                 }
 116             }
 117             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
 118             last;
 119         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
 120             setcolor() if $s =~/color/i;
 121             _load_unload($on);
 122             last;
 123         } elsif (exists $bitmask{$s}) {
 124             $bits |= $bitmask{$s};
 125         } elsif ($EXPORT_OK{$s}) {
 126             require Exporter;
 127             re->export_to_level(2, 're', $s);
 128         } else {
 129             require Carp;
 130             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
 131                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
 132                        ")");
 133         }
 134     }
 135     $bits;
 136 }
 137
 138 sub import {
 139     shift;
 140     $^H |= bits(1, @_);
 141 }
 142
 143 sub unimport {
 144     shift;
 145     $^H &= ~ bits(0, @_);
 146 }
 147
 148 1;
 149
 150 __END__
 151
 152 =head1 NAME
 153
 154 re - Perl pragma to alter regular expression behaviour
 155
 156 =head1 SYNOPSIS
 157
 158     use re 'taint';
 159     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
 160
 161     $pat = '(?{ $foo = 1 })';
 162     use re 'eval';
 163     /foo${pat}bar/;                # won't fail (when not under -T switch)
 164
 165     {
 166         no re 'taint';             # the default
 167         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
 168
 169         no re 'eval';              # the default
 170         /foo${pat}bar/;            # disallowed (with or without -T switch)
 171     }
 172
 173     use re 'debug';                # output debugging info during
 174     /^(.*)$/s;                     #     compile and run time
 175
 176
 177     use re 'debugcolor';           # same as 'debug', but with colored output
 178     ...
 179
 180     use re qw(Debug All);          # Finer tuned debugging options.
 181     use re qw(Debug More);
 182     no re qw(Debug ALL);           # Turn of all re debugging in this scope
 183
 184     use re qw(is_regexp regexp_pattern); # import utility functions
 185     my ($pat,$mods)=regexp_pattern(qr/foo/i);
 186     if (is_regexp($obj)) {
 187         print "Got regexp: ",
 188             scalar regexp_pattern($obj); # just as perl would stringify it
 189     }                                    # but no hassle with blessed re's.
 190
 191 (We use $^X in these examples because it's tainted by default.)
 192
 193 =head1 DESCRIPTION
 194
 195 =head2 'taint' mode
 196
 197 When C<use re 'taint'> is in effect, and a tainted string is the target
 198 of a regex, the regex memories (or values returned by the m// operator
 199 in list context) are tainted.  This feature is useful when regex operations
 200 on tainted data aren't meant to extract safe substrings, but to perform
 201 other transformations.
 202
 203 =head2 'eval' mode
 204
 205 When C<use re 'eval'> is in effect, a regex is allowed to contain
 206 C<(?{ ... })> zero-width assertions even if regular expression contains
 207 variable interpolation.  That is normally disallowed, since it is a
 208 potential security risk.  Note that this pragma is ignored when the regular
 209 expression is obtained from tainted data, i.e.  evaluation is always
 210 disallowed with tainted regular expressions.  See L<perlre/(?{ code })>.
 211
 212 For the purpose of this pragma, interpolation of precompiled regular
 213 expressions (i.e., the result of C<qr//>) is I<not> considered variable
 214 interpolation.  Thus:
 215
 216     /foo${pat}bar/
 217
 218 I<is> allowed if $pat is a precompiled regular expression, even
 219 if $pat contains C<(?{ ... })> assertions.
 220
 221 =head2 'debug' mode
 222
 223 When C<use re 'debug'> is in effect, perl emits debugging messages when
 224 compiling and using regular expressions.  The output is the same as that
 225 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
 226 B<-Dr> switch. It may be quite voluminous depending on the complexity
 227 of the match.  Using C<debugcolor> instead of C<debug> enables a
 228 form of output that can be used to get a colorful display on terminals
 229 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
 230 comma-separated list of C<termcap> properties to use for highlighting
 231 strings on/off, pre-point part on/off.
 232 See L<perldebug/"Debugging regular expressions"> for additional info.
 233
 234 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 235 lexically scoped, as the other directives are.  However they have both
 236 compile-time and run-time effects.
 237
 238 See L<perlmodlib/Pragmatic Modules>.
 239
 240 =head2 'Debug' mode
 241
 242 Similarly C<use re 'Debug'> produces debugging output, the difference
 243 being that it allows the fine tuning of what debugging output will be
 244 emitted. Options are divided into three groups, those related to
 245 compilation, those related to execution and those related to special
 246 purposes. The options are as follows:
 247
 248 =over 4
 249
 250 =item Compile related options
 251
 252 =over 4
 253
 254 =item COMPILE
 255
 256 Turns on all compile related debug options.
 257
 258 =item PARSE
 259
 260 Turns on debug output related to the process of parsing the pattern.
 261
 262 =item OPTIMISE
 263
 264 Enables output related to the optimisation phase of compilation.
 265
 266 =item TRIEC
 267
 268 Detailed info about trie compilation.
 269
 270 =item DUMP
 271
 272 Dump the final program out after it is compiled and optimised.
 273
 274 =back
 275
 276 =item Execute related options
 277
 278 =over 4
 279
 280 =item EXECUTE
 281
 282 Turns on all execute related debug options.
 283
 284 =item MATCH
 285
 286 Turns on debugging of the main matching loop.
 287
 288 =item TRIEE
 289
 290 Extra debugging of how tries execute.
 291
 292 =item INTUIT
 293
 294 Enable debugging of start point optimisations.
 295
 296 =back
 297
 298 =item Extra debugging options
 299
 300 =over 4
 301
 302 =item EXTRA
 303
 304 Turns on all "extra" debugging options.
 305
 306 =item BUFFERS
 307
 308 Enable debugging the capture buffer storage during match. Warning,
 309 this can potentially produce extremely large output.
 310
 311 =item TRIEM
 312
 313 Enable enhanced TRIE debugging. Enhances both TRIEE
 314 and TRIEC.
 315
 316 =item STATE
 317
 318 Enable debugging of states in the engine.
 319
 320 =item STACK
 321
 322 Enable debugging of the recursion stack in the engine. Enabling
 323 or disabling this option automatically does the same for debugging
 324 states as well. This output from this can be quite large.
 325
 326 =item OPTIMISEM
 327
 328 Enable enhanced optimisation debugging and start point optimisations.
 329 Probably not useful except when debugging the regex engine itself.
 330
 331 =item OFFSETS
 332
 333 Dump offset information. This can be used to see how regops correlate
 334 to the pattern. Output format is
 335
 336    NODENUM:POSITION[LENGTH]
 337
 338 Where 1 is the position of the first char in the string. Note that position
 339 can be 0, or larger than the actual length of the pattern, likewise length
 340 can be zero.
 341
 342 =item OFFSETSDBG
 343
 344 Enable debugging of offsets information. This emits copious
 345 amounts of trace information and doesn't mesh well with other
 346 debug options.
 347
 348 Almost definitely only useful to people hacking
 349 on the offsets part of the debug engine.
 350
 351 =back
 352
 353 =item Other useful flags
 354
 355 These are useful shortcuts to save on the typing.
 356
 357 =over 4
 358
 359 =item ALL
 360
 361 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS
 362
 363 =item All
 364
 365 Enable DUMP and all execute options. Equivalent to:
 366
 367   use re 'debug';
 368
 369 =item MORE
 370
 371 =item More
 372
 373 Enable TRIEM and all execute compile and execute options.
 374
 375 =back
 376
 377 =back
 378
 379 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 380 lexically scoped, as the other directives are.  However they have both
 381 compile-time and run-time effects.
 382
 383 =head2 Exportable Functions
 384
 385 As of perl 5.9.5 're' debug contains a number of utility functions that
 386 may be optionally exported into the caller's namespace. They are listed
 387 below.
 388
 389 =over 4
 390
 391 =item is_regexp($ref)
 392
 393 Returns true if the argument is a compiled regular expression as returned
 394 by C<qr//>, false if it is not.
 395
 396 This function will not be confused by overloading or blessing. In
 397 internals terms, this extracts the regexp pointer out of the
 398 PERL_MAGIC_qr structure so it it cannot be fooled.
 399
 400 =item regexp_pattern($ref)
 401
 402 If the argument is a compiled regular expression as returned by C<qr//>,
 403 then this function returns the pattern.
 404
 405 In list context it returns a two element list, the first element
 406 containing the pattern and the second containing the modifiers used when
 407 the pattern was compiled.
 408
 409   my ($pat, $mods) = regexp_pattern($ref);
 410
 411 In scalar context it returns the same as perl would when strigifying a raw
 412 C<qr//> with the same pattern inside.  If the argument is not a compiled
 413 reference then this routine returns false but defined in scalar context,
 414 and the empty list in list context. Thus the following
 415
 416     if (regexp_pattern($ref) eq '(?i-xsm:foo)')
 417
 418 will be warning free regardless of what $ref actually is.
 419
 420 Like C<is_regexp> this function will not be confused by overloading
 421 or blessing of the object.
 422
 423 =item regmust($ref)
 424
 425 If the argument is a compiled regular expression as returned by C<qr//>,
 426 then this function returns what the optimiser consiers to be the longest
 427 anchored fixed string and longest floating fixed string in the pattern.
 428
 429 A I<fixed string> is defined as being a substring that must appear for the
 430 pattern to match. An I<anchored fixed string> is a fixed string that must
 431 appear at a particular offset from the beginning of the match. A I<floating
 432 fixed string> is defined as a fixed string that can appear at any point in
 433 a range of positions relative to the start of the match. For example,
 434
 435     my $qr = qr/here .* there/x;
 436     my ($anchored, $floating) = regmust($qr);
 437     print "anchored:'$anchored'\nfloating:'$floating'\n";
 438
 439 results in
 440
 441     anchored:'here'
 442     floating:'there'
 443
 444 Because the C<here> is before the C<.*> in the pattern, its position
 445 can be determined exactly. That's not true, however, for the C<there>;
 446 it could appear at any point after where the anchored string appeared.
 447 Perl uses both for its optimisations, prefering the longer, or, if they are
 448 equal, the floating.
 449
 450 B<NOTE:> This may not necessarily be the definitive longest anchored and
 451 floating string. This will be what the optimiser of the Perl that you
 452 are using thinks is the longest. If you believe that the result is wrong
 453 please report it via the L<perlbug> utility.
 454
 455 =item regname($name,$all)
 456
 457 Returns the contents of a named buffer of the last successful match. If
 458 $all is true, then returns an array ref containing one entry per buffer,
 459 otherwise returns the first defined buffer.
 460
 461 =item regnames($all)
 462
 463 Returns a list of all of the named buffers defined in the last successful
 464 match. If $all is true, then it returns all names defined, if not it returns
 465 only names which were involved in the match.
 466
 467 =item regnames_count()
 468
 469 Returns the number of distinct names defined in the pattern used
 470 for the last successful match.
 471
 472 B<Note:> this result is always the actual number of distinct
 473 named buffers defined, it may not actually match that which is
 474 returned by C<regnames()> and related routines when those routines
 475 have not been called with the $all parameter set.
 476
 477 =back
 478
 479 =head1 SEE ALSO
 480
 481 L<perlmodlib/Pragmatic Modules>.
 482
 483 =cut