ext/Encode/Encode.pm

   1 package Encode;
   2 use strict;
   3
   4 our $VERSION = '0.02';
   5
   6 require DynaLoader;
   7 require Exporter;
   8
   9 our @ISA = qw(Exporter DynaLoader);
  10
  11 # Public, encouraged API is exported by default
  12 our @EXPORT = qw (
  13   encode
  14   decode
  15   encode_utf8
  16   decode_utf8
  17   find_encoding
  18   encodings
  19 );
  20
  21 our @EXPORT_OK =
  22     qw(
  23        define_encoding
  24        define_alias
  25        from_to
  26        is_utf8
  27        is_8bit
  28        is_16bit
  29        utf8_upgrade
  30        utf8_downgrade
  31        _utf8_on
  32        _utf8_off
  33       );
  34
  35 bootstrap Encode ();
  36
  37 # Documentation moved after __END__ for speed - NI-S
  38
  39 use Carp;
  40
  41 # Make a %encoding package variable to allow a certain amount of cheating
  42 our %encoding;
  43 my @alias;  # ordered matching list
  44 my %alias;  # cached known aliases
  45
  46                      # 0  1  2  3  4  5   6   7   8   9  10
  47 our @latin2iso_num = ( 0, 1, 2, 3, 4, 9, 10, 13, 14, 15, 16 );
  48
  49 our %winlatin2cp   = (
  50                       'Latin1'     => 1252,
  51                       'Latin2'     => 1250,
  52                       'Cyrillic'   => 1251,
  53                       'Baltic'     => 1257,
  54                       'Greek'      => 1253,
  55                       'Turkish'    => 1254,
  56                       'Hebrew'     => 1255,
  57                       'Arabic'     => 1256,
  58                       'Baltic'     => 1257,
  59                       'Vietnamese' => 1258,
  60                      );
  61
  62 sub encodings
  63 {
  64  my ($class) = @_;
  65  return keys %encoding;
  66 }
  67
  68 sub findAlias
  69 {
  70  my $class = shift;
  71  local $_ = shift;
  72  # print "# findAlias $_\n";
  73  unless (exists $alias{$_})
  74   {
  75    for (my $i=0; $i < @alias; $i += 2)
  76     {
  77      my $alias = $alias[$i];
  78      my $val   = $alias[$i+1];
  79      my $new;
  80      if (ref($alias) eq 'Regexp' && $_ =~ $alias)
  81       {
  82        $new = eval $val;
  83       }
  84      elsif (ref($alias) eq 'CODE')
  85       {
  86        $new = &{$alias}($val)
  87       }
  88      elsif (lc($_) eq lc($alias))
  89       {
  90        $new = $val;
  91       }
  92      if (defined($new))
  93       {
  94        next if $new eq $_; # avoid (direct) recursion on bugs
  95        my $enc = (ref($new)) ? $new : find_encoding($new);
  96        if ($enc)
  97         {
  98          $alias{$_} = $enc;
  99          last;
 100         }
 101       }
 102     }
 103   }
 104  return $alias{$_};
 105 }
 106
 107 sub define_alias
 108 {
 109  while (@_)
 110   {
 111    my ($alias,$name) = splice(@_,0,2);
 112    push(@alias, $alias => $name);
 113   }
 114 }
 115
 116 # Allow variants of iso-8859-1 etc.
 117 define_alias( qr/^iso[-_]?(\d+)[-_](\d+)$/i => '"iso-$1-$2"' );
 118
 119 # At least HP-UX has these.
 120 define_alias( qr/^iso8859(\d+)$/i => '"iso-8859-$1"' );
 121
 122 # More HP stuff.
 123 define_alias( qr/^(?:hp-)?(arabic|greek|hebrew|kana|roman|thai|turkish)8$/i => '"${1}8"' );
 124
 125 # The Official name of ASCII.
 126 define_alias( qr/^ANSI[-_]?X3\.4[-_]?1968$/i => '"ascii"' );
 127
 128 # This is a font issue, not an encoding issue.
 129 # (The currency symbol of the Latin 1 upper half
 130 #  has been redefined as the euro symbol.)
 131 define_alias( qr/^(.+)\@euro$/i => '"$1"' );
 132
 133 # Allow latin-1 style names as well
 134 define_alias( qr/^(?:iso[-_]?)?latin[-_]?(\d+)$/i => '"iso-8859-$latin2iso_num[$1]"' );
 135
 136 # Allow winlatin1 style names as well
 137 define_alias( qr/^win(latin[12]|cyrillic|baltic|greek|turkish|hebrew|arabic|baltic|vietnamese)$/i => '"cp$winlatin2cp{\u$1}"' );
 138
 139 # Common names for non-latin prefered MIME names
 140 define_alias( 'ascii'    => 'US-ascii',
 141               'cyrillic' => 'iso-8859-5',
 142               'arabic'   => 'iso-8859-6',
 143               'greek'    => 'iso-8859-7',
 144               'hebrew'   => 'iso-8859-8',
 145               'thai'     => 'iso-8859-11',
 146               'tis620'   => 'iso-8859-11',
 147             );
 148
 149 # At least AIX has IBM-NNN (surprisingly...) instead of cpNNN.
 150 define_alias( qr/^ibm[-_]?(\d\d\d\d?)$/i => '"cp$1"');
 151
 152 # Standardize on the dashed versions.
 153 define_alias( qr/^utf8$/i  => 'utf-8' );
 154 define_alias( qr/^koi8r$/i => 'koi8-r' );
 155 define_alias( qr/^koi8u$/i => 'koi8-u' );
 156
 157 # TODO: HP-UX '8' encodings arabic8 greek8 hebrew8 kana8 thai8 turkish8
 158 # TODO: HP-UX '15' encodings japanese15 korean15 roi15
 159 # TODO: Cyrillic encoding ISO-IR-111 (useful?)
 160 # TODO: Chinese encodings GB18030 GBK Big5-HSKCS EUC-TW
 161 # TODO: Armenian encoding ARMSCII-8
 162 # TODO: Hebrew encoding ISO-8859-8-1
 163 # TODO: Thai encoding TCVN
 164 # TODO: Korean encoding Johab
 165 # TODO: Vietnamese encodings VISCII VPS
 166 # TODO: Japanese encoding JIS (not the same as SJIS)
 167 # TODO: Mac Asian+African encodings: Arabic Armenian Bengali Burmese
 168 #       ChineseSimp ChineseTrad Devanagari Ethiopic ExtArabic
 169 #       Farsi Georgian Gujarati Gurmukhi Hebrew Japanese
 170 #       Kannada Khmer Korean Laotian Malayalam Mongolian
 171 #       Oriya Sinhalese Symbol Tamil Telugu Tibetan Vietnamese
 172 # TODO: what is the Japanese 'UJIS' encoding seen in some Linuxes?
 173
 174 # Map white space and _ to '-'
 175 define_alias( qr/^(\S+)[\s_]+(.*)$/i => '"$1-$2"' );
 176
 177 sub define_encoding
 178 {
 179  my $obj  = shift;
 180  my $name = shift;
 181  $encoding{$name} = $obj;
 182  my $lc = lc($name);
 183  define_alias($lc => $obj) unless $lc eq $name;
 184  while (@_)
 185   {
 186    my $alias = shift;
 187    define_alias($alias,$obj);
 188   }
 189  return $obj;
 190 }
 191
 192 sub getEncoding
 193 {
 194  my ($class,$name) = @_;
 195  my $enc;
 196  if (ref($name) && $name->can('new_sequence'))
 197   {
 198    return $name;
 199   }
 200  my $lc = lc $name;
 201  if (exists $encoding{$name})
 202   {
 203    return $encoding{$name};
 204   }
 205  if (exists $encoding{$lc})
 206   {
 207    return $encoding{$lc};
 208   }
 209
 210   my $oc = $class->findAlias($name);
 211   return $oc if defined $oc;
 212   return $class->findAlias($lc) if $lc ne $name;
 213
 214   return;
 215 }
 216
 217 sub find_encoding
 218 {
 219  my ($name) = @_;
 220  return __PACKAGE__->getEncoding($name);
 221 }
 222
 223 sub encode
 224 {
 225  my ($name,$string,$check) = @_;
 226  my $enc = find_encoding($name);
 227  croak("Unknown encoding '$name'") unless defined $enc;
 228  my $octets = $enc->encode($string,$check);
 229  return undef if ($check && length($string));
 230  return $octets;
 231 }
 232
 233 sub decode
 234 {
 235  my ($name,$octets,$check) = @_;
 236  my $enc = find_encoding($name);
 237  croak("Unknown encoding '$name'") unless defined $enc;
 238  my $string = $enc->decode($octets,$check);
 239  $_[1] = $octets if $check;
 240  return $string;
 241 }
 242
 243 sub from_to
 244 {
 245  my ($string,$from,$to,$check) = @_;
 246  my $f = find_encoding($from);
 247  croak("Unknown encoding '$from'") unless defined $f;
 248  my $t = find_encoding($to);
 249  croak("Unknown encoding '$to'") unless defined $t;
 250  my $uni = $f->decode($string,$check);
 251  return undef if ($check && length($string));
 252  $string = $t->encode($uni,$check);
 253  return undef if ($check && length($uni));
 254  return length($_[0] = $string);
 255 }
 256
 257 sub encode_utf8
 258 {
 259  my ($str) = @_;
 260  utf8::encode($str);
 261  return $str;
 262 }
 263
 264 sub decode_utf8
 265 {
 266  my ($str) = @_;
 267  return undef unless utf8::decode($str);
 268  return $str;
 269 }
 270
 271 package Encode::Encoding;
 272 # Base class for classes which implement encodings
 273
 274 sub Define
 275 {
 276  my $obj = shift;
 277  my $canonical = shift;
 278  $obj = bless { Name => $canonical },$obj unless ref $obj;
 279  # warn "$canonical => $obj\n";
 280  Encode::define_encoding($obj, $canonical, @_);
 281 }
 282
 283 sub name { shift->{'Name'} }
 284
 285 # Temporary legacy methods
 286 sub toUnicode    { shift->decode(@_) }
 287 sub fromUnicode  { shift->encode(@_) }
 288
 289 sub new_sequence { return $_[0] }
 290
 291 package Encode::XS;
 292 use base 'Encode::Encoding';
 293
 294 package Encode::Internal;
 295 use base 'Encode::Encoding';
 296
 297 # Dummy package that provides the encode interface but leaves data
 298 # as UTF-X encoded. It is here so that from_to() works.
 299
 300 __PACKAGE__->Define('Internal');
 301
 302 Encode::define_alias( 'Unicode' => 'Internal' ) if ord('A') == 65;
 303
 304 sub decode
 305 {
 306  my ($obj,$str,$chk) = @_;
 307  utf8::upgrade($str);
 308  $_[1] = '' if $chk;
 309  return $str;
 310 }
 311
 312 *encode = \&decode;
 313
 314 package Encoding::Unicode;
 315 use base 'Encode::Encoding';
 316
 317 __PACKAGE__->Define('Unicode') unless ord('A') == 65;
 318
 319 sub decode
 320 {
 321  my ($obj,$str,$chk) = @_;
 322  my $res = '';
 323  for (my $i = 0; $i < length($str); $i++)
 324   {
 325    $res .= chr(utf8::unicode_to_native(ord(substr($str,$i,1))));
 326   }
 327  $_[1] = '' if $chk;
 328  return $res;
 329 }
 330
 331 sub encode
 332 {
 333  my ($obj,$str,$chk) = @_;
 334  my $res = '';
 335  for (my $i = 0; $i < length($str); $i++)
 336   {
 337    $res .= chr(utf8::native_to_unicode(ord(substr($str,$i,1))));
 338   }
 339  $_[1] = '' if $chk;
 340  return $res;
 341 }
 342
 343
 344 package Encode::utf8;
 345 use base 'Encode::Encoding';
 346 # package to allow long-hand
 347 #   $octets = encode( utf8 => $string );
 348 #
 349
 350 __PACKAGE__->Define(qw(UTF-8 utf8));
 351
 352 sub decode
 353 {
 354  my ($obj,$octets,$chk) = @_;
 355  my $str = Encode::decode_utf8($octets);
 356  if (defined $str)
 357   {
 358    $_[1] = '' if $chk;
 359    return $str;
 360   }
 361  return undef;
 362 }
 363
 364 sub encode
 365 {
 366  my ($obj,$string,$chk) = @_;
 367  my $octets = Encode::encode_utf8($string);
 368  $_[1] = '' if $chk;
 369  return $octets;
 370 }
 371
 372 package Encode::iso10646_1;
 373 use base 'Encode::Encoding';
 374 # Encoding is 16-bit network order Unicode (no surogates)
 375 # Used for X font encodings
 376
 377 __PACKAGE__->Define(qw(UCS-2 iso-10646-1));
 378
 379 sub decode
 380 {
 381  my ($obj,$str,$chk) = @_;
 382  my $uni   = '';
 383  while (length($str))
 384   {
 385    my $code = unpack('n',substr($str,0,2,'')) & 0xffff;
 386    $uni .= chr($code);
 387   }
 388  $_[1] = $str if $chk;
 389  utf8::upgrade($uni);
 390  return $uni;
 391 }
 392
 393 sub encode
 394 {
 395  my ($obj,$uni,$chk) = @_;
 396  my $str   = '';
 397  while (length($uni))
 398   {
 399    my $ch = substr($uni,0,1,'');
 400    my $x  = ord($ch);
 401    unless ($x < 32768)
 402     {
 403      last if ($chk);
 404      $x = 0;
 405     }
 406    $str .= pack('n',$x);
 407   }
 408  $_[1] = $uni if $chk;
 409  return $str;
 410 }
 411
 412 package Encode::ucs_2le;
 413 use base 'Encode::Encoding';
 414
 415 __PACKAGE__->Define(qw(UCS-2le UCS-2LE ucs-2le));
 416
 417 sub decode
 418 {
 419  my ($obj,$str,$chk) = @_;
 420  my $uni   = '';
 421  while (length($str))
 422  {
 423   my $code = unpack('v',substr($str,0,2,'')) & 0xffff;
 424   $uni .= chr($code);
 425  }
 426  $_[1] = $str if $chk;
 427  utf8::upgrade($uni);
 428  return $uni;
 429 }
 430
 431 sub encode
 432 {
 433  my ($obj,$uni,$chk) = @_;
 434  my $str   = '';
 435  while (length($uni))
 436  {
 437   my $ch = substr($uni,0,1,'');
 438   my $x  = ord($ch);
 439   unless ($x < 32768)
 440   {
 441    last if ($chk);
 442    $x = 0;
 443   }
 444   $str .= pack('v',$x);
 445  }
 446  $_[1] = $uni if $chk;
 447  return $str;
 448 }
 449
 450 # switch back to Encode package in case we ever add AutoLoader
 451 package Encode;
 452
 453 1;
 454
 455 __END__
 456
 457 =head1 NAME
 458
 459 Encode - character encodings
 460
 461 =head1 SYNOPSIS
 462
 463     use Encode;
 464
 465 =head1 DESCRIPTION
 466
 467 The C<Encode> module provides the interfaces between Perl's strings
 468 and the rest of the system.  Perl strings are sequences of B<characters>.
 469
 470 The repertoire of characters that Perl can represent is at least that
 471 defined by the Unicode Consortium. On most platforms the ordinal
 472 values of the characters (as returned by C<ord(ch)>) is the "Unicode
 473 codepoint" for the character (the exceptions are those platforms where
 474 the legacy encoding is some variant of EBCDIC rather than a super-set
 475 of ASCII - see L<perlebcdic>).
 476
 477 Traditionaly computer data has been moved around in 8-bit chunks
 478 often called "bytes". These chunks are also known as "octets" in
 479 networking standards. Perl is widely used to manipulate data of
 480 many types - not only strings of characters representing human or
 481 computer languages but also "binary" data being the machines representation
 482 of numbers, pixels in an image - or just about anything.
 483
 484 When Perl is processing "binary data" the programmer wants Perl to process
 485 "sequences of bytes". This is not a problem for Perl - as a byte has 256
 486 possible values it easily fits in Perl's much larger "logical character".
 487
 488 =head2 TERMINOLOGY
 489
 490 =over 4
 491
 492 =item *
 493
 494 I<character>: a character in the range 0..(2**32-1) (or more).
 495 (What Perl's strings are made of.)
 496
 497 =item *
 498
 499 I<byte>: a character in the range 0..255
 500 (A special case of a Perl character.)
 501
 502 =item *
 503
 504 I<octet>: 8 bits of data, with ordinal values 0..255
 505 (Term for bytes passed to or from a non-Perl context, e.g. disk file.)
 506
 507 =back
 508
 509 The marker [INTERNAL] marks Internal Implementation Details, in
 510 general meant only for those who think they know what they are doing,
 511 and such details may change in future releases.
 512
 513 =head1 ENCODINGS
 514
 515 =head2 Characteristics of an Encoding
 516
 517 An encoding has a "repertoire" of characters that it can represent,
 518 and for each representable character there is at least one sequence of
 519 octets that represents it.
 520
 521 =head2 Types of Encodings
 522
 523 Encodings can be divided into the following types:
 524
 525 =over 4
 526
 527 =item * Fixed length 8-bit (or less) encodings.
 528
 529 Each character is a single octet so may have a repertoire of up to
 530 256 characters. ASCII and iso-8859-* are typical examples.
 531
 532 =item * Fixed length 16-bit encodings
 533
 534 Each character is two octets so may have a repertoire of up to
 535 65 536 characters.  Unicode's UCS-2 is an example.  Also used for
 536 encodings for East Asian languages.
 537
 538 =item * Fixed length 32-bit encodings.
 539
 540 Not really very "encoded" encodings. The Unicode code points
 541 are just represented as 4-octet integers. None the less because
 542 different architectures use different representations of integers
 543 (so called "endian") there at least two disctinct encodings.
 544
 545 =item * Multi-byte encodings
 546
 547 The number of octets needed to represent a character varies.
 548 UTF-8 is a particularly complex but regular case of a multi-byte
 549 encoding. Several East Asian countries use a multi-byte encoding
 550 where 1-octet is used to cover western roman characters and Asian
 551 characters get 2-octets.
 552 (UTF-16 is strictly a multi-byte encoding taking either 2 or 4 octets
 553 to represent a Unicode code point.)
 554
 555 =item * "Escape" encodings.
 556
 557 These encodings embed "escape sequences" into the octet sequence
 558 which describe how the following octets are to be interpreted.
 559 The iso-2022-* family is typical. Following the escape sequence
 560 octets are encoded by an "embedded" encoding (which will be one
 561 of the above types) until another escape sequence switches to
 562 a different "embedded" encoding.
 563
 564 These schemes are very flexible and can handle mixed languages but are
 565 very complex to process (and have state).  No escape encodings are
 566 implemented for Perl yet.
 567
 568 =back
 569
 570 =head2 Specifying Encodings
 571
 572 Encodings can be specified to the API described below in two ways:
 573
 574 =over 4
 575
 576 =item 1. By name
 577
 578 Encoding names are strings with characters taken from a restricted
 579 repertoire.  See L</"Encoding Names">.
 580
 581 =item 2. As an object
 582
 583 Encoding objects are returned by C<find_encoding($name)>.
 584
 585 =back
 586
 587 =head2 Encoding Names
 588
 589 Encoding names are case insensitive. White space in names is ignored.
 590 In addition an encoding may have aliases. Each encoding has one
 591 "canonical" name.  The "canonical" name is chosen from the names of
 592 the encoding by picking the first in the following sequence:
 593
 594 =over 4
 595
 596 =item * The MIME name as defined in IETF RFC-XXXX.
 597
 598 =item * The name in the IANA registry.
 599
 600 =item * The name used by the the organization that defined it.
 601
 602 =back
 603
 604 Because of all the alias issues, and because in the general case
 605 encodings have state C<Encode> uses the encoding object internally
 606 once an operation is in progress.
 607
 608 =head1 PERL ENCODING API
 609
 610 =head2 Generic Encoding Interface
 611
 612 =over 4
 613
 614 =item *
 615
 616         $bytes  = encode(ENCODING, $string[, CHECK])
 617
 618 Encodes string from Perl's internal form into I<ENCODING> and returns
 619 a sequence of octets.  For CHECK see L</"Handling Malformed Data">.
 620
 621 =item *
 622
 623         $string = decode(ENCODING, $bytes[, CHECK])
 624
 625 Decode sequence of octets assumed to be in I<ENCODING> into Perl's
 626 internal form and returns the resulting string.  For CHECK see
 627 L</"Handling Malformed Data">.
 628
 629 =item *
 630
 631         from_to($string, FROM_ENCODING, TO_ENCODING[, CHECK])
 632
 633 Convert B<in-place> the data between two encodings.  How did the data
 634 in $string originally get to be in FROM_ENCODING?  Either using
 635 encode() or through PerlIO: See L</"Encoding and IO">.  For CHECK
 636 see L</"Handling Malformed Data">.
 637
 638 For example to convert ISO 8859-1 data to UTF-8:
 639
 640         from_to($data, "iso-8859-1", "utf-8");
 641
 642 and to convert it back:
 643
 644         from_to($data, "utf-8", "iso-8859-1");
 645
 646 Note that because the conversion happens in place, the data to be
 647 converted cannot be a string constant, it must be a scalar variable.
 648
 649 =back
 650
 651 =head2 Handling Malformed Data
 652
 653 If CHECK is not set, C<undef> is returned.  If the data is supposed to
 654 be UTF-8, an optional lexical warning (category utf8) is given.  If
 655 CHECK is true but not a code reference, dies.
 656
 657 It would desirable to have a way to indicate that transform should use
 658 the encodings "replacement character" - no such mechanism is defined yet.
 659
 660 It is also planned to allow I<CHECK> to be a code reference.
 661
 662 This is not yet implemented as there are design issues with what its
 663 arguments should be and how it returns its results.
 664
 665 =over 4
 666
 667 =item Scheme 1
 668
 669 Passed remaining fragment of string being processed.
 670 Modifies it in place to remove bytes/characters it can understand
 671 and returns a string used to represent them.
 672 e.g.
 673
 674  sub fixup {
 675    my $ch = substr($_[0],0,1,'');
 676    return sprintf("\x{%02X}",ord($ch);
 677  }
 678
 679 This scheme is close to how underlying C code for Encode works, but gives
 680 the fixup routine very little context.
 681
 682 =item Scheme 2
 683
 684 Passed original string, and an index into it of the problem area, and
 685 output string so far.  Appends what it will to output string and
 686 returns new index into original string.  For example:
 687
 688  sub fixup {
 689    # my ($s,$i,$d) = @_;
 690    my $ch = substr($_[0],$_[1],1);
 691    $_[2] .= sprintf("\x{%02X}",ord($ch);
 692    return $_[1]+1;
 693  }
 694
 695 This scheme gives maximal control to the fixup routine but is more
 696 complicated to code, and may need internals of Encode to be tweaked to
 697 keep original string intact.
 698
 699 =item Other Schemes
 700
 701 Hybrids of above.
 702
 703 Multiple return values rather than in-place modifications.
 704
 705 Index into the string could be pos($str) allowing s/\G...//.
 706
 707 =back
 708
 709 =head2 UTF-8 / utf8
 710
 711 The Unicode consortium defines the UTF-8 standard as a way of encoding
 712 the entire Unicode repertiore as sequences of octets.  This encoding is
 713 expected to become very widespread. Perl can use this form internaly
 714 to represent strings, so conversions to and from this form are
 715 particularly efficient (as octets in memory do not have to change,
 716 just the meta-data that tells Perl how to treat them).
 717
 718 =over 4
 719
 720 =item *
 721
 722         $bytes = encode_utf8($string);
 723
 724 The characters that comprise string are encoded in Perl's superset of UTF-8
 725 and the resulting octets returned as a sequence of bytes. All possible
 726 characters have a UTF-8 representation so this function cannot fail.
 727
 728 =item *
 729
 730         $string = decode_utf8($bytes [,CHECK]);
 731
 732 The sequence of octets represented by $bytes is decoded from UTF-8
 733 into a sequence of logical characters. Not all sequences of octets
 734 form valid UTF-8 encodings, so it is possible for this call to fail.
 735 For CHECK see L</"Handling Malformed Data">.
 736
 737 =back
 738
 739 =head2 Other Encodings of Unicode
 740
 741 UTF-16 is similar to UCS-2, 16 bit or 2-byte chunks.  UCS-2 can only
 742 represent 0..0xFFFF, while UTF-16 has a I<surrogate pair> scheme which
 743 allows it to cover the whole Unicode range.
 744
 745 Surrogates are code points set aside to encode the 0x01000..0x10FFFF
 746 range of Unicode code points in pairs of 16-bit units.  The I<high
 747 surrogates> are the range 0xD800..0xDBFF, and the I<low surrogates>
 748 are the range 0xDC00..0xDFFFF.  The surrogate encoding is
 749
 750         $hi = ($uni - 0x10000) / 0x400 + 0xD800;
 751         $lo = ($uni - 0x10000) % 0x400 + 0xDC00;
 752
 753 and the decoding is
 754
 755         $uni = 0x10000 + ($hi - 0xD8000) * 0x400 + ($lo - 0xDC00);
 756
 757 Encode implements big-endian UCS-2 aliased to "iso-10646-1" as that
 758 happens to be the name used by that representation when used with X11
 759 fonts.
 760
 761 UTF-32 or UCS-4 is 32-bit or 4-byte chunks.  Perl's logical characters
 762 can be considered as being in this form without encoding. An encoding
 763 to transfer strings in this form (e.g. to write them to a file) would
 764 need to
 765
 766      pack('L*', unpack('U*', $string));  # native
 767   or
 768      pack('V*', unpack('U*', $string));  # little-endian
 769   or
 770      pack('N*', unpack('U*', $string));  # big-endian
 771
 772 depending on the endianness required.
 773
 774 No UTF-32 encodings are implemented yet.
 775
 776 Both UCS-2 and UCS-4 style encodings can have "byte order marks" by
 777 representing the code point 0xFFFE as the very first thing in a file.
 778
 779 =head2 Listing available encodings
 780
 781   use Encode qw(encodings);
 782   @list = encodings();
 783
 784 Returns a list of the canonical names of the available encodings.
 785
 786 =head2 Defining Aliases
 787
 788   use Encode qw(define_alias);
 789   define_alias( newName => ENCODING);
 790
 791 Allows newName to be used as am alias for ENCODING. ENCODING may be
 792 either the name of an encoding or and encoding object (as above).
 793
 794 Currently I<newName> can be specified in the following ways:
 795
 796 =over 4
 797
 798 =item As a simple string.
 799
 800 =item As a qr// compiled regular expression, e.g.:
 801
 802   define_alias( qr/^iso8859-(\d+)$/i => '"iso-8859-$1"' );
 803
 804 In this case if I<ENCODING> is not a reference it is C<eval>-ed to
 805 allow C<$1> etc. to be subsituted.  The example is one way to names as
 806 used in X11 font names to alias the MIME names for the iso-8859-*
 807 family.
 808
 809 =item As a code reference, e.g.:
 810
 811   define_alias( sub { return /^iso8859-(\d+)$/i ? "iso-8859-$1" : undef } , '');
 812
 813 In this case C<$_> will be set to the name that is being looked up and
 814 I<ENCODING> is passed to the sub as its first argument.  The example
 815 is another way to names as used in X11 font names to alias the MIME
 816 names for the iso-8859-* family.
 817
 818 =back
 819
 820 =head2 Defining Encodings
 821
 822     use Encode qw(define_alias);
 823     define_encoding( $object, 'canonicalName' [,alias...]);
 824
 825 Causes I<canonicalName> to be associated with I<$object>.  The object
 826 should provide the interface described in L</"IMPLEMENTATION CLASSES">
 827 below.  If more than two arguments are provided then additional
 828 arguments are taken as aliases for I<$object> as for C<define_alias>.
 829
 830 =head1 Encoding and IO
 831
 832 It is very common to want to do encoding transformations when
 833 reading or writing files, network connections, pipes etc.
 834 If Perl is configured to use the new 'perlio' IO system then
 835 C<Encode> provides a "layer" (See L<perliol>) which can transform
 836 data as it is read or written.
 837
 838 Here is how the blind poet would modernise the encoding:
 839
 840     use Encode;
 841     open(my $iliad,'<:encoding(iso-8859-7)','iliad.greek');
 842     open(my $utf8,'>:utf8','iliad.utf8');
 843     my @epic = <$iliad>;
 844     print $utf8 @epic;
 845     close($utf8);
 846     close($illiad);
 847
 848 In addition the new IO system can also be configured to read/write
 849 UTF-8 encoded characters (as noted above this is efficient):
 850
 851     open(my $fh,'>:utf8','anything');
 852     print $fh "Any \x{0021} string \N{SMILEY FACE}\n";
 853
 854 Either of the above forms of "layer" specifications can be made the default
 855 for a lexical scope with the C<use open ...> pragma. See L<open>.
 856
 857 Once a handle is open is layers can be altered using C<binmode>.
 858
 859 Without any such configuration, or if Perl itself is built using
 860 system's own IO, then write operations assume that file handle accepts
 861 only I<bytes> and will C<die> if a character larger than 255 is
 862 written to the handle. When reading, each octet from the handle
 863 becomes a byte-in-a-character. Note that this default is the same
 864 behaviour as bytes-only languages (including Perl before v5.6) would
 865 have, and is sufficient to handle native 8-bit encodings
 866 e.g. iso-8859-1, EBCDIC etc. and any legacy mechanisms for handling
 867 other encodings and binary data.
 868
 869 In other cases it is the programs responsibility to transform
 870 characters into bytes using the API above before doing writes, and to
 871 transform the bytes read from a handle into characters before doing
 872 "character operations" (e.g. C<lc>, C</\W+/>, ...).
 873
 874 You can also use PerlIO to convert larger amounts of data you don't
 875 want to bring into memory.  For example to convert between ISO 8859-1
 876 (Latin 1) and UTF-8 (or UTF-EBCDIC in EBCDIC machines):
 877
 878     open(F, "<:encoding(iso-8859-1)", "data.txt") or die $!;
 879     open(G, ">:utf8",                 "data.utf") or die $!;
 880     while (<F>) { print G }
 881
 882     # Could also do "print G <F>" but that would pull
 883     # the whole file into memory just to write it out again.
 884
 885 More examples:
 886
 887     open(my $f, "<:encoding(cp1252)")
 888     open(my $g, ">:encoding(iso-8859-2)")
 889     open(my $h, ">:encoding(latin9)")       # iso-8859-15
 890
 891 See L<PerlIO> for more information.
 892
 893 See also L<encoding> for how to change the default encoding of the
 894 data in your script.
 895
 896 =head1 Encoding How to ...
 897
 898 To do:
 899
 900 =over 4
 901
 902 =item * IO with mixed content (faking iso-2020-*)
 903
 904 =item * MIME's Content-Length:
 905
 906 =item * UTF-8 strings in binary data.
 907
 908 =item * Perl/Encode wrappers on non-Unicode XS modules.
 909
 910 =back
 911
 912 =head1 Messing with Perl's Internals
 913
 914 The following API uses parts of Perl's internals in the current
 915 implementation.  As such they are efficient, but may change.
 916
 917 =over 4
 918
 919 =item * is_utf8(STRING [, CHECK])
 920
 921 [INTERNAL] Test whether the UTF-8 flag is turned on in the STRING.
 922 If CHECK is true, also checks the data in STRING for being well-formed
 923 UTF-8.  Returns true if successful, false otherwise.
 924
 925 =item * valid_utf8(STRING)
 926
 927 [INTERNAL] Test whether STRING is in a consistent state.  Will return
 928 true if string is held as bytes, or is well-formed UTF-8 and has the
 929 UTF-8 flag on.  Main reason for this routine is to allow Perl's
 930 testsuite to check that operations have left strings in a consistent
 931 state.
 932
 933 =item *
 934
 935         _utf8_on(STRING)
 936
 937 [INTERNAL] Turn on the UTF-8 flag in STRING.  The data in STRING is
 938 B<not> checked for being well-formed UTF-8.  Do not use unless you
 939 B<know> that the STRING is well-formed UTF-8.  Returns the previous
 940 state of the UTF-8 flag (so please don't test the return value as
 941 I<not> success or failure), or C<undef> if STRING is not a string.
 942
 943 =item *
 944
 945         _utf8_off(STRING)
 946
 947 [INTERNAL] Turn off the UTF-8 flag in STRING.  Do not use frivolously.
 948 Returns the previous state of the UTF-8 flag (so please don't test the
 949 return value as I<not> success or failure), or C<undef> if STRING is
 950 not a string.
 951
 952 =back
 953
 954 =head1 IMPLEMENTATION CLASSES
 955
 956 As mentioned above encodings are (in the current implementation at least)
 957 defined by objects. The mapping of encoding name to object is via the
 958 C<%encodings> hash.
 959
 960 The values of the hash can currently be either strings or objects.
 961 The string form may go away in the future. The string form occurs
 962 when C<encodings()> has scanned C<@INC> for loadable encodings but has
 963 not actually loaded the encoding in question. This is because the
 964 current "loading" process is all Perl and a bit slow.
 965
 966 Once an encoding is loaded then value of the hash is object which
 967 implements the encoding. The object should provide the following
 968 interface:
 969
 970 =over 4
 971
 972 =item -E<gt>name
 973
 974 Should return the string representing the canonical name of the encoding.
 975
 976 =item -E<gt>new_sequence
 977
 978 This is a placeholder for encodings with state. It should return an
 979 object which implements this interface, all current implementations
 980 return the original object.
 981
 982 =item -E<gt>encode($string,$check)
 983
 984 Should return the octet sequence representing I<$string>. If I<$check>
 985 is true it should modify I<$string> in place to remove the converted
 986 part (i.e.  the whole string unless there is an error).  If an error
 987 occurs it should return the octet sequence for the fragment of string
 988 that has been converted, and modify $string in-place to remove the
 989 converted part leaving it starting with the problem fragment.
 990
 991 If check is is false then C<encode> should make a "best effort" to
 992 convert the string - for example by using a replacement character.
 993
 994 =item -E<gt>decode($octets,$check)
 995
 996 Should return the string that I<$octets> represents. If I<$check> is
 997 true it should modify I<$octets> in place to remove the converted part
 998 (i.e.  the whole sequence unless there is an error).  If an error
 999 occurs it should return the fragment of string that has been
1000 converted, and modify $octets in-place to remove the converted part
1001 leaving it starting with the problem fragment.
1002
1003 If check is is false then C<decode> should make a "best effort" to
1004 convert the string - for example by using Unicode's "\x{FFFD}" as a
1005 replacement character.
1006
1007 =back
1008
1009 It should be noted that the check behaviour is different from the
1010 outer public API. The logic is that the "unchecked" case is useful
1011 when encoding is part of a stream which may be reporting errors
1012 (e.g. STDERR).  In such cases it is desirable to get everything
1013 through somehow without causing additional errors which obscure the
1014 original one. Also the encoding is best placed to know what the
1015 correct replacement character is, so if that is the desired behaviour
1016 then letting low level code do it is the most efficient.
1017
1018 In contrast if check is true, the scheme above allows the encoding to
1019 do as much as it can and tell layer above how much that was. What is
1020 lacking at present is a mechanism to report what went wrong. The most
1021 likely interface will be an additional method call to the object, or
1022 perhaps (to avoid forcing per-stream objects on otherwise stateless
1023 encodings) and additional parameter.
1024
1025 It is also highly desirable that encoding classes inherit from
1026 C<Encode::Encoding> as a base class. This allows that class to define
1027 additional behaviour for all encoding objects. For example built in
1028 Unicode, UCS-2 and UTF-8 classes use :
1029
1030   package Encode::MyEncoding;
1031   use base qw(Encode::Encoding);
1032
1033   __PACKAGE__->Define(qw(myCanonical myAlias));
1034
1035 To create an object with bless {Name => ...},$class, and call
1036 define_encoding.  They inherit their C<name> method from
1037 C<Encode::Encoding>.
1038
1039 =head2 Compiled Encodings
1040
1041 F<Encode.xs> provides a class C<Encode::XS> which provides the
1042 interface described above. It calls a generic octet-sequence to
1043 octet-sequence "engine" that is driven by tables (defined in
1044 F<encengine.c>). The same engine is used for both encode and
1045 decode. C<Encode:XS>'s C<encode> forces Perl's characters to their
1046 UTF-8 form and then treats them as just another multibyte
1047 encoding. C<Encode:XS>'s C<decode> transforms the sequence and then
1048 turns the UTF-8-ness flag as that is the form that the tables are
1049 defined to produce. For details of the engine see the comments in
1050 F<encengine.c>.
1051
1052 The tables are produced by the Perl script F<compile> (the name needs
1053 to change so we can eventually install it somewhere). F<compile> can
1054 currently read two formats:
1055
1056 =over 4
1057
1058 =item *.enc
1059
1060 This is a coined format used by Tcl. It is documented in
1061 Encode/EncodeFormat.pod.
1062
1063 =item *.ucm
1064
1065 This is the semi-standard format used by IBM's ICU package.
1066
1067 =back
1068
1069 F<compile> can write the following forms:
1070
1071 =over 4
1072
1073 =item *.ucm
1074
1075 See above - the F<Encode/*.ucm> files provided with the distribution have
1076 been created from the original Tcl .enc files using this approach.
1077
1078 =item *.c
1079
1080 Produces tables as C data structures - this is used to build in encodings
1081 into F<Encode.so>/F<Encode.dll>.
1082
1083 =item *.xs
1084
1085 In theory this allows encodings to be stand-alone loadable Perl
1086 extensions.  The process has not yet been tested. The plan is to use
1087 this approach for large East Asian encodings.
1088
1089 =back
1090
1091 The set of encodings built-in to F<Encode.so>/F<Encode.dll> is
1092 determined by F<Makefile.PL>.  The current set is as follows:
1093
1094 =over 4
1095
1096 =item ascii and iso-8859-*
1097
1098 That is all the common 8-bit "western" encodings.
1099
1100 =item IBM-1047 and two other variants of EBCDIC.
1101
1102 These are the same variants that are supported by EBCDIC Perl as
1103 "native" encodings.  They are included to prove "reversibility" of
1104 some constructs in EBCDIC Perl.
1105
1106 =item symbol and dingbats as used by Tk on X11.
1107
1108 (The reason Encode got started was to support Perl/Tk.)
1109
1110 =back
1111
1112 That set is rather ad hoc and has been driven by the needs of the
1113 tests rather than the needs of typical applications. It is likely
1114 to be rationalized.
1115
1116 =head1 SEE ALSO
1117
1118 L<perlunicode>, L<perlebcdic>, L<perlfunc/open>, L<PerlIO>, L<encoding>
1119
1120 =cut
1121