lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34)> or C<(re_eval 19)>.
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
 514
 515 BEGIN {
 516     require feature;
 517     $^V =~ /^v(\d+\.\d+)/;
 518     feature->import(":$1");
 519 }
 520
 521 # Debugger for Perl 5.00x; perl5db.pl patch level:
 522 $VERSION = '1.35';
 523
 524 $header = "perl5db.pl version $VERSION";
 525
 526 =head1 DEBUGGER ROUTINES
 527
 528 =head2 C<DB::eval()>
 529
 530 This function replaces straight C<eval()> inside the debugger; it simplifies
 531 the process of evaluating code in the user's context.
 532
 533 The code to be evaluated is passed via the package global variable
 534 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 535
 536 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 537 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 538 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 539 user's current package, grabbed when C<DB::DB> got control.  This causes the
 540 proper context to be used when the eval is actually done.  Afterward, we
 541 restore C<$trace>, C<$single>, and C<$^D>.
 542
 543 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 544 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 545 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 546 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 547 considered sane by the debugger. If there was an C<eval()> error, we print
 548 it on the debugger's output. If C<$onetimedump> is defined, we call
 549 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 550 'methods'. Setting it to something else causes the debugger to do the eval
 551 but not print the result - handy if you want to do something else with it
 552 (the "watch expressions" code does this to get the value of the watch
 553 expression but not show it unless it matters).
 554
 555 In any case, we then return the list of output from C<eval> to the caller,
 556 and unwinding restores the former version of C<$@> in C<@saved> as well
 557 (the localization of C<$saved[0]> goes away at the end of this scope).
 558
 559 =head3 Parameters and variables influencing execution of DB::eval()
 560
 561 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 562 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 563 The variables listed below influence C<DB::eval()>'s execution directly.
 564
 565 =over 4
 566
 567 =item C<$evalarg> - the thing to actually be eval'ed
 568
 569 =item C<$trace> - Current state of execution tracing
 570
 571 =item C<$single> - Current state of single-stepping
 572
 573 =item C<$onetimeDump> - what is to be displayed after the evaluation
 574
 575 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 576
 577 =back
 578
 579 The following variables are altered by C<DB::eval()> during its execution. They
 580 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 581
 582 =over 4
 583
 584 =item C<@res> - used to capture output from actual C<eval>.
 585
 586 =item C<$otrace> - saved value of C<$trace>.
 587
 588 =item C<$osingle> - saved value of C<$single>.
 589
 590 =item C<$od> - saved value of C<$^D>.
 591
 592 =item C<$saved[0]> - saved value of C<$@>.
 593
 594 =item $\ - for output of C<$@> if there is an evaluation error.
 595
 596 =back
 597
 598 =head3 The problem of lexicals
 599
 600 The context of C<DB::eval()> presents us with some problems. Obviously,
 601 we want to be 'sandboxed' away from the debugger's internals when we do
 602 the eval, but we need some way to control how punctuation variables and
 603 debugger globals are used.
 604
 605 We can't use local, because the code inside C<DB::eval> can see localized
 606 variables; and we can't use C<my> either for the same reason. The code
 607 in this routine compromises and uses C<my>.
 608
 609 After this routine is over, we don't have user code executing in the debugger's
 610 context, so we can use C<my> freely.
 611
 612 =cut
 613
 614 ############################################## Begin lexical danger zone
 615
 616 # 'my' variables used here could leak into (that is, be visible in)
 617 # the context that the code being evaluated is executing in. This means that
 618 # the code could modify the debugger's variables.
 619 #
 620 # Fiddling with the debugger's context could be Bad. We insulate things as
 621 # much as we can.
 622
 623 sub eval {
 624
 625     # 'my' would make it visible from user code
 626     #    but so does local! --tchrist
 627     # Remember: this localizes @DB::res, not @main::res.
 628     local @res;
 629     {
 630
 631         # Try to keep the user code from messing  with us. Save these so that
 632         # even if the eval'ed code changes them, we can put them back again.
 633         # Needed because the user could refer directly to the debugger's
 634         # package globals (and any 'my' variables in this containing scope)
 635         # inside the eval(), and we want to try to stay safe.
 636         local $otrace  = $trace;
 637         local $osingle = $single;
 638         local $od      = $^D;
 639
 640         # Untaint the incoming eval() argument.
 641         { ($evalarg) = $evalarg =~ /(.*)/s; }
 642
 643         # $usercontext built in DB::DB near the comment
 644         # "set up the context for DB::eval ..."
 645         # Evaluate and save any results.
 646         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 647
 648         # Restore those old values.
 649         $trace  = $otrace;
 650         $single = $osingle;
 651         $^D     = $od;
 652     }
 653
 654     # Save the current value of $@, and preserve it in the debugger's copy
 655     # of the saved precious globals.
 656     my $at = $@;
 657
 658     # Since we're only saving $@, we only have to localize the array element
 659     # that it will be stored in.
 660     local $saved[0];    # Preserve the old value of $@
 661     eval { &DB::save };
 662
 663     # Now see whether we need to report an error back to the user.
 664     if ($at) {
 665         local $\ = '';
 666         print $OUT $at;
 667     }
 668
 669     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 670     # are package globals.
 671     elsif ($onetimeDump) {
 672         if ( $onetimeDump eq 'dump' ) {
 673             local $option{dumpDepth} = $onetimedumpDepth
 674               if defined $onetimedumpDepth;
 675             dumpit( $OUT, \@res );
 676         }
 677         elsif ( $onetimeDump eq 'methods' ) {
 678             methods( $res[0] );
 679         }
 680     } ## end elsif ($onetimeDump)
 681     @res;
 682 } ## end sub eval
 683
 684 ############################################## End lexical danger zone
 685
 686 # After this point it is safe to introduce lexicals.
 687 # The code being debugged will be executing in its own context, and
 688 # can't see the inside of the debugger.
 689 #
 690 # However, one should not overdo it: leave as much control from outside as
 691 # possible. If you make something a lexical, it's not going to be addressable
 692 # from outside the debugger even if you know its name.
 693
 694 # This file is automatically included if you do perl -d.
 695 # It's probably not useful to include this yourself.
 696 #
 697 # Before venturing further into these twisty passages, it is
 698 # wise to read the perldebguts man page or risk the ire of dragons.
 699 #
 700 # (It should be noted that perldebguts will tell you a lot about
 701 # the underlying mechanics of how the debugger interfaces into the
 702 # Perl interpreter, but not a lot about the debugger itself. The new
 703 # comments in this code try to address this problem.)
 704
 705 # Note that no subroutine call is possible until &DB::sub is defined
 706 # (for subroutines defined outside of the package DB). In fact the same is
 707 # true if $deep is not defined.
 708
 709 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 710
 711 # modified Perl debugger, to be run from Emacs in perldb-mode
 712 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 713 # Johan Vromans -- upgrade to 4.0 pl 10
 714 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 715
 716 # (We have made efforts to  clarify the comments in the change log
 717 # in other places; some of them may seem somewhat obscure as they
 718 # were originally written, and explaining them away from the code
 719 # in question seems conterproductive.. -JM)
 720
 721 ########################################################################
 722 # Changes: 0.94
 723 #   + A lot of things changed after 0.94. First of all, core now informs
 724 #     debugger about entry into XSUBs, overloaded operators, tied operations,
 725 #     BEGIN and END. Handy with 'O f=2'.
 726 #   + This can make debugger a little bit too verbose, please be patient
 727 #     and report your problems promptly.
 728 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
 729 #   + Note that if DESTROY returns a reference to the object (or object),
 730 #     the deletion of data may be postponed until the next function call,
 731 #     due to the need to examine the return value.
 732 #
 733 # Changes: 0.95
 734 #   + 'v' command shows versions.
 735 #
 736 # Changes: 0.96
 737 #   + 'v' command shows version of readline.
 738 #     primitive completion works (dynamic variables, subs for 'b' and 'l',
 739 #     options). Can 'p %var'
 740 #   + Better help ('h <' now works). New commands <<, >>, {, {{.
 741 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
 742 #   + 'c sub' documented.
 743 #   + At last enough magic combined to stop after the end of debuggee.
 744 #   + !! should work now (thanks to Emacs bracket matching an extra
 745 #     ']' in a regexp is caught).
 746 #   + 'L', 'D' and 'A' span files now (as documented).
 747 #   + Breakpoints in 'require'd code are possible (used in 'R').
 748 #   +  Some additional words on internal work of debugger.
 749 #   + 'b load filename' implemented.
 750 #   + 'b postpone subr' implemented.
 751 #   + now only 'q' exits debugger (overwritable on $inhibit_exit).
 752 #   + When restarting debugger breakpoints/actions persist.
 753 #   + Buglet: When restarting debugger only one breakpoint/action per
 754 #             autoloaded function persists.
 755 #
 756 # Changes: 0.97: NonStop will not stop in at_exit().
 757 #   + Option AutoTrace implemented.
 758 #   + Trace printed differently if frames are printed too.
 759 #   + new 'inhibitExit' option.
 760 #   + printing of a very long statement interruptible.
 761 # Changes: 0.98: New command 'm' for printing possible methods
 762 #   + 'l -' is a synonym for '-'.
 763 #   + Cosmetic bugs in printing stack trace.
 764 #   +  'frame' & 8 to print "expanded args" in stack trace.
 765 #   + Can list/break in imported subs.
 766 #   + new 'maxTraceLen' option.
 767 #   + frame & 4 and frame & 8 granted.
 768 #   + new command 'm'
 769 #   + nonstoppable lines do not have ':' near the line number.
 770 #   + 'b compile subname' implemented.
 771 #   + Will not use $` any more.
 772 #   + '-' behaves sane now.
 773 # Changes: 0.99: Completion for 'f', 'm'.
 774 #   +  'm' will remove duplicate names instead of duplicate functions.
 775 #   + 'b load' strips trailing whitespace.
 776 #     completion ignores leading '|'; takes into account current package
 777 #     when completing a subroutine name (same for 'l').
 778 # Changes: 1.07: Many fixed by tchrist 13-March-2000
 779 #   BUG FIXES:
 780 #   + Added bare minimal security checks on perldb rc files, plus
 781 #     comments on what else is needed.
 782 #   + Fixed the ornaments that made "|h" completely unusable.
 783 #     They are not used in print_help if they will hurt.  Strip pod
 784 #     if we're paging to less.
 785 #   + Fixed mis-formatting of help messages caused by ornaments
 786 #     to restore Larry's original formatting.
 787 #   + Fixed many other formatting errors.  The code is still suboptimal,
 788 #     and needs a lot of work at restructuring.  It's also misindented
 789 #     in many places.
 790 #   + Fixed bug where trying to look at an option like your pager
 791 #     shows "1".
 792 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
 793 #     lose.  You should consider shell escapes not using their shell,
 794 #     or else not caring about detailed status.  This should really be
 795 #     unified into one place, too.
 796 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
 797 #     tricking Perl into thinking you weren't calling a debugger command!
 798 #   + Fixed bug where leading whitespace on commands hoses you.  (One
 799 #     suggests a leading semicolon or any other irrelevant non-whitespace
 800 #     to indicate literal Perl code.)
 801 #   + Fixed bugs that ate warnings due to wrong selected handle.
 802 #   + Fixed a precedence bug on signal stuff.
 803 #   + Fixed some unseemly wording.
 804 #   + Fixed bug in help command trying to call perl method code.
 805 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
 806 #   ENHANCEMENTS:
 807 #   + Added some comments.  This code is still nasty spaghetti.
 808 #   + Added message if you clear your pre/post command stacks which was
 809 #     very easy to do if you just typed a bare >, <, or {.  (A command
 810 #     without an argument should *never* be a destructive action; this
 811 #     API is fundamentally screwed up; likewise option setting, which
 812 #     is equally buggered.)
 813 #   + Added command stack dump on argument of "?" for >, <, or {.
 814 #   + Added a semi-built-in doc viewer command that calls man with the
 815 #     proper %Config::Config path (and thus gets caching, man -k, etc),
 816 #     or else perldoc on obstreperous platforms.
 817 #   + Added to and rearranged the help information.
 818 #   + Detected apparent misuse of { ... } to declare a block; this used
 819 #     to work but now is a command, and mysteriously gave no complaint.
 820 #
 821 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
 822 #   BUG FIX:
 823 #   + This patch to perl5db.pl cleans up formatting issues on the help
 824 #     summary (h h) screen in the debugger.  Mostly columnar alignment
 825 #     issues, plus converted the printed text to use all spaces, since
 826 #     tabs don't seem to help much here.
 827 #
 828 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
 829 #   Minor bugs corrected;
 830 #   + Support for auto-creation of new TTY window on startup, either
 831 #     unconditionally, or if started as a kid of another debugger session;
 832 #   + New 'O'ption CreateTTY
 833 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
 834 #                         1: on fork()
 835 #                         2: debugger is started inside debugger
 836 #                         4: on startup
 837 #   + Code to auto-create a new TTY window on OS/2 (currently one
 838 #     extra window per session - need named pipes to have more...);
 839 #   + Simplified interface for custom createTTY functions (with a backward
 840 #     compatibility hack); now returns the TTY name to use; return of ''
 841 #     means that the function reset the I/O handles itself;
 842 #   + Better message on the semantic of custom createTTY function;
 843 #   + Convert the existing code to create a TTY into a custom createTTY
 844 #     function;
 845 #   + Consistent support for TTY names of the form "TTYin,TTYout";
 846 #   + Switch line-tracing output too to the created TTY window;
 847 #   + make 'b fork' DWIM with CORE::GLOBAL::fork;
 848 #   + High-level debugger API cmd_*():
 849 #      cmd_b_load($filenamepart)            # b load filenamepart
 850 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
 851 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
 852 #      cmd_stop()                           # Control-C
 853 #      cmd_d($lineno)                       # d lineno (B)
 854 #      The cmd_*() API returns FALSE on failure; in this case it outputs
 855 #      the error message to the debugging output.
 856 #   + Low-level debugger API
 857 #      break_on_load($filename)             # b load filename
 858 #      @files = report_break_on_load()      # List files with load-breakpoints
 859 #      breakable_line_in_filename($name, $from [, $to])
 860 #                                           # First breakable line in the
 861 #                                           # range $from .. $to.  $to defaults
 862 #                                           # to $from, and may be less than
 863 #                                           # $to
 864 #      breakable_line($from [, $to])        # Same for the current file
 865 #      break_on_filename_line($name, $lineno [, $cond])
 866 #                                           # Set breakpoint,$cond defaults to
 867 #                                           # 1
 868 #      break_on_filename_line_range($name, $from, $to [, $cond])
 869 #                                           # As above, on the first
 870 #                                           # breakable line in range
 871 #      break_on_line($lineno [, $cond])     # As above, in the current file
 872 #      break_subroutine($sub [, $cond])     # break on the first breakable line
 873 #      ($name, $from, $to) = subroutine_filename_lines($sub)
 874 #                                           # The range of lines of the text
 875 #      The low-level API returns TRUE on success, and die()s on failure.
 876 #
 877 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 878 #   BUG FIXES:
 879 #   + Fixed warnings generated by "perl -dWe 42"
 880 #   + Corrected spelling errors
 881 #   + Squeezed Help (h) output into 80 columns
 882 #
 883 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
 884 #   + Made "x @INC" work like it used to
 885 #
 886 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
 887 #   + Fixed warnings generated by "O" (Show debugger options)
 888 #   + Fixed warnings generated by "p 42" (Print expression)
 889 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
 890 #   + Added windowSize option
 891 # Changes: 1.14: Oct  9, 2001 multiple
 892 #   + Clean up after itself on VMS (Charles Lane in 12385)
 893 #   + Adding "@ file" syntax (Peter Scott in 12014)
 894 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
 895 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
 896 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
 897 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
 898 #   + Updated 1.14 change log
 899 #   + Added *dbline explanatory comments
 900 #   + Mentioning perldebguts man page
 901 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
 902 #   + $onetimeDump improvements
 903 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
 904 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
 905 #   rationalised the following commands and added cmd_wrapper() to
 906 #   enable switching between old and frighteningly consistent new
 907 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
 908 #     a(add),       A(del)            # action expr   (added del by line)
 909 #   + b(add),       B(del)            # break  [line] (was b,D)
 910 #   + w(add),       W(del)            # watch  expr   (was W,W)
 911 #                                     # added del by expr
 912 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
 913 #   + m(methods),   M(modules)        # ...           (was m,v)
 914 #   + o(option)                       # lc            (was O)
 915 #   + v(view code), V(view Variables) # ...           (was w,V)
 916 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
 917 #   + fixed missing cmd_O bug
 918 # Changes: 1.19: Mar 29, 2002 Spider Boardman
 919 #   + Added missing local()s -- DB::DB is called recursively.
 920 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
 921 #   + pre'n'post commands no longer trashed with no args
 922 #   + watch val joined out of eval()
 923 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
 924 #   + Added comments and reformatted source. No bug fixes/enhancements.
 925 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
 926 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
 927 #   + Flush stdout/stderr before the debugger prompt is printed.
 928 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
 929 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
 930 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
 931 #   + Added command to save all debugger commands for sourcing later.
 932 #   + Added command to display parent inheritance tree of given class.
 933 #   + Fixed minor newline in history bug.
 934 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
 935 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
 936 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
 937 #   + unfork the 5.8.x and 5.9.x debuggers.
 938 #   + whitespace and assertions call cleanup across versions
 939 #   + H * deletes (resets) history
 940 #   + i now handles Class + blessed objects
 941 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
 942 #   + updated pod page references - clunky.
 943 #   + removed windowid restriction for forking into an xterm.
 944 #   + more whitespace again.
 945 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
 946 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
 947 #   + Added threads support (inc. e and E commands)
 948 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com>
 949 #   + Added macosx_get_fork_TTY support
 950 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
 951 #   + Added HistFile, HistSize
 952 # Changes: 1.31
 953 #   + Remove support for assertions and -A
 954 #   + stop NEXT::AUTOLOAD from emitting warnings under the debugger. RT #25053
 955 #   + "update for Mac OS X 10.5" [finding the tty device]
 956 #   + "What I needed to get the forked debugger to work" [on VMS]
 957 #   + [perl #57016] debugger: o warn=0 die=0 ignored
 958 #   + Note, but don't use, PERLDBf_SAVESRC
 959 #   + Fix #7013: lvalue subs not working inside debugger
 960 # Changes: 1.32: Jun 03, 2009 Jonathan Leto <jonathan@leto.net>
 961 #   + Fix bug where a key _< with undefined value was put into the symbol table
 962 #   +   when the $filename variable is not set
 963 # Changes: 1.33:
 964 #   + Debugger prints lines to the remote port when it forks and openes a new port (f633fd2)
 965 #   + The debugger now continues to use RemotePort when it's been configured to use it. (11653f7)
 966 #   + Stop using $ENV{LESS} for parameters not intended for less (d463cf2)
 967 #   + Configure has a path to less and perl5db.pl can use it (bf320d6)
 968 #   + Die with $@ instead of empty message (86755f4)
 969 #   + Remove extra/useless $@ check after eval { require PadWalker } (which is still checked) (dab8d6d)
 970 #   + Promote eval( "require ..." ) to eval { require ... } (4a49187)
 971 #   + Promote eval { require( ... )} || die to mere require( ... ) (999f23b)
 972 #   + Remove indirect object notation from debugger (bee4b46)
 973 #   + Document that @{$main::{'_<'.$filename}} lines are dualvar to (COP*). (7e17a74)
 974 #   + Remove MacOS classic support from the debugger. (2b894b7)
 975 ########################################################################
 976
 977 =head1 DEBUGGER INITIALIZATION
 978
 979 The debugger starts up in phases.
 980
 981 =head2 BASIC SETUP
 982
 983 First, it initializes the environment it wants to run in: turning off
 984 warnings during its own compilation, defining variables which it will need
 985 to avoid warnings later, setting itself up to not exit when the program
 986 terminates, and defaulting to printing return values for the C<r> command.
 987
 988 =cut
 989
 990 # Needed for the statement after exec():
 991 #
 992 # This BEGIN block is simply used to switch off warnings during debugger
 993 # compilation. Probably it would be better practice to fix the warnings,
 994 # but this is how it's done at the moment.
 995
 996 BEGIN {
 997     $ini_warn = $^W;
 998     $^W       = 0;
 999 }    # Switch compilation warnings off until another BEGIN.
1000
1001 local ($^W) = 0;    # Switch run-time warnings off during init.
1002
1003 =head2 THREADS SUPPORT
1004
1005 If we are running under a threaded Perl, we require threads and threads::shared
1006 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
1007 threaded debugger control.  C<-dt> can also be used to set this.
1008
1009 Each new thread will be announced and the debugger prompt will always inform
1010 you of each new thread created.  It will also indicate the thread id in which
1011 we are currently running within the prompt like this:
1012
1013         [tid] DB<$i>
1014
1015 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
1016 command prompt.  The prompt will show: C<[0]> when running under threads, but
1017 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
1018
1019 While running under threads, when you set or delete a breakpoint (etc.), this
1020 will apply to all threads, not just the currently running one.  When you are
1021 in a currently executing thread, you will stay there until it completes.  With
1022 the current implementation it is not currently possible to hop from one thread
1023 to another.
1024
1025 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1026
1027 Note that threading support was built into the debugger as of Perl version
1028 C<5.8.6> and debugger version C<1.2.8>.
1029
1030 =cut
1031
1032 BEGIN {
1033   # ensure we can share our non-threaded variables or no-op
1034   if ($ENV{PERL5DB_THREADED}) {
1035         require threads;
1036         require threads::shared;
1037         import threads::shared qw(share);
1038         $DBGR;
1039         share(\$DBGR);
1040         lock($DBGR);
1041         print "Threads support enabled\n";
1042   } else {
1043         *lock  = sub(*) {};
1044         *share = sub(*) {};
1045   }
1046 }
1047
1048 # This would probably be better done with "use vars", but that wasn't around
1049 # when this code was originally written. (Neither was "use strict".) And on
1050 # the principle of not fiddling with something that was working, this was
1051 # left alone.
1052 warn(               # Do not ;-)
1053     # These variables control the execution of 'dumpvar.pl'.
1054     $dumpvar::hashDepth,
1055     $dumpvar::arrayDepth,
1056     $dumpvar::dumpDBFiles,
1057     $dumpvar::dumpPackages,
1058     $dumpvar::quoteHighBit,
1059     $dumpvar::printUndef,
1060     $dumpvar::globPrint,
1061     $dumpvar::usageOnly,
1062
1063     # used to save @ARGV and extract any debugger-related flags.
1064     @ARGS,
1065
1066     # used to control die() reporting in diesignal()
1067     $Carp::CarpLevel,
1068
1069     # used to prevent multiple entries to diesignal()
1070     # (if for instance diesignal() itself dies)
1071     $panic,
1072
1073     # used to prevent the debugger from running nonstop
1074     # after a restart
1075     $second_time,
1076   )
1077   if 0;
1078
1079 # without threads, $filename is not defined until DB::DB is called
1080 foreach my $k (keys (%INC)) {
1081         &share(\$main::{'_<'.$filename}) if defined $filename;
1082 };
1083
1084 # Command-line + PERLLIB:
1085 # Save the contents of @INC before they are modified elsewhere.
1086 @ini_INC = @INC;
1087
1088 # This was an attempt to clear out the previous values of various
1089 # trapped errors. Apparently it didn't help. XXX More info needed!
1090 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1091
1092 # We set these variables to safe values. We don't want to blindly turn
1093 # off warnings, because other packages may still want them.
1094 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1095                                    # (local $^W cannot help - other packages!).
1096
1097 # Default to not exiting when program finishes; print the return
1098 # value when the 'r' command is used to return from a subroutine.
1099 $inhibit_exit = $option{PrintRet} = 1;
1100
1101 # Default to 1 so the prompt will display the first line.
1102 $trace_to_depth = 1;
1103
1104 =head1 OPTION PROCESSING
1105
1106 The debugger's options are actually spread out over the debugger itself and
1107 C<dumpvar.pl>; some of these are variables to be set, while others are
1108 subs to be called with a value. To try to make this a little easier to
1109 manage, the debugger uses a few data structures to define what options
1110 are legal and how they are to be processed.
1111
1112 First, the C<@options> array defines the I<names> of all the options that
1113 are to be accepted.
1114
1115 =cut
1116
1117 @options = qw(
1118   CommandSet   HistFile      HistSize
1119   hashDepth    arrayDepth    dumpDepth
1120   DumpDBFiles  DumpPackages  DumpReused
1121   compactDump  veryCompact   quote
1122   HighBit      undefPrint    globPrint
1123   PrintRet     UsageOnly     frame
1124   AutoTrace    TTY           noTTY
1125   ReadLine     NonStop       LineInfo
1126   maxTraceLen  recallCommand ShellBang
1127   pager        tkRunning     ornaments
1128   signalLevel  warnLevel     dieLevel
1129   inhibit_exit ImmediateStop bareStringify
1130   CreateTTY    RemotePort    windowSize
1131   DollarCaretP
1132 );
1133
1134 @RememberOnROptions = qw(DollarCaretP);
1135
1136 =pod
1137
1138 Second, C<optionVars> lists the variables that each option uses to save its
1139 state.
1140
1141 =cut
1142
1143 %optionVars = (
1144     hashDepth     => \$dumpvar::hashDepth,
1145     arrayDepth    => \$dumpvar::arrayDepth,
1146     CommandSet    => \$CommandSet,
1147     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1148     DumpPackages  => \$dumpvar::dumpPackages,
1149     DumpReused    => \$dumpvar::dumpReused,
1150     HighBit       => \$dumpvar::quoteHighBit,
1151     undefPrint    => \$dumpvar::printUndef,
1152     globPrint     => \$dumpvar::globPrint,
1153     UsageOnly     => \$dumpvar::usageOnly,
1154     CreateTTY     => \$CreateTTY,
1155     bareStringify => \$dumpvar::bareStringify,
1156     frame         => \$frame,
1157     AutoTrace     => \$trace,
1158     inhibit_exit  => \$inhibit_exit,
1159     maxTraceLen   => \$maxtrace,
1160     ImmediateStop => \$ImmediateStop,
1161     RemotePort    => \$remoteport,
1162     windowSize    => \$window,
1163     HistFile      => \$histfile,
1164     HistSize      => \$histsize,
1165 );
1166
1167 =pod
1168
1169 Third, C<%optionAction> defines the subroutine to be called to process each
1170 option.
1171
1172 =cut
1173
1174 %optionAction = (
1175     compactDump   => \&dumpvar::compactDump,
1176     veryCompact   => \&dumpvar::veryCompact,
1177     quote         => \&dumpvar::quote,
1178     TTY           => \&TTY,
1179     noTTY         => \&noTTY,
1180     ReadLine      => \&ReadLine,
1181     NonStop       => \&NonStop,
1182     LineInfo      => \&LineInfo,
1183     recallCommand => \&recallCommand,
1184     ShellBang     => \&shellBang,
1185     pager         => \&pager,
1186     signalLevel   => \&signalLevel,
1187     warnLevel     => \&warnLevel,
1188     dieLevel      => \&dieLevel,
1189     tkRunning     => \&tkRunning,
1190     ornaments     => \&ornaments,
1191     RemotePort    => \&RemotePort,
1192     DollarCaretP  => \&DollarCaretP,
1193 );
1194
1195 =pod
1196
1197 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1198 option is used.
1199
1200 =cut
1201
1202 # Note that this list is not complete: several options not listed here
1203 # actually require that dumpvar.pl be loaded for them to work, but are
1204 # not in the table. A subsequent patch will correct this problem; for
1205 # the moment, we're just recommenting, and we are NOT going to change
1206 # function.
1207 %optionRequire = (
1208     compactDump => 'dumpvar.pl',
1209     veryCompact => 'dumpvar.pl',
1210     quote       => 'dumpvar.pl',
1211 );
1212
1213 =pod
1214
1215 There are a number of initialization-related variables which can be set
1216 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1217 variable. These are:
1218
1219 =over 4
1220
1221 =item C<$rl> - readline control XXX needs more explanation
1222
1223 =item C<$warnLevel> - whether or not debugger takes over warning handling
1224
1225 =item C<$dieLevel> - whether or not debugger takes over die handling
1226
1227 =item C<$signalLevel> - whether or not debugger takes over signal handling
1228
1229 =item C<$pre> - preprompt actions (array reference)
1230
1231 =item C<$post> - postprompt actions (array reference)
1232
1233 =item C<$pretype>
1234
1235 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1236
1237 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1238
1239 =back
1240
1241 =cut
1242
1243 # These guys may be defined in $ENV{PERL5DB} :
1244 $rl          = 1     unless defined $rl;
1245 $warnLevel   = 1     unless defined $warnLevel;
1246 $dieLevel    = 1     unless defined $dieLevel;
1247 $signalLevel = 1     unless defined $signalLevel;
1248 $pre         = []    unless defined $pre;
1249 $post        = []    unless defined $post;
1250 $pretype     = []    unless defined $pretype;
1251 $CreateTTY   = 3     unless defined $CreateTTY;
1252 $CommandSet  = '580' unless defined $CommandSet;
1253
1254 share($rl);
1255 share($warnLevel);
1256 share($dieLevel);
1257 share($signalLevel);
1258 share($pre);
1259 share($post);
1260 share($pretype);
1261 share($rl);
1262 share($CreateTTY);
1263 share($CommandSet);
1264
1265 =pod
1266
1267 The default C<die>, C<warn>, and C<signal> handlers are set up.
1268
1269 =cut
1270
1271 warnLevel($warnLevel);
1272 dieLevel($dieLevel);
1273 signalLevel($signalLevel);
1274
1275 =pod
1276
1277 The pager to be used is needed next. We try to get it from the
1278 environment first.  If it's not defined there, we try to find it in
1279 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1280 then call the C<pager()> function to save the pager name.
1281
1282 =cut
1283
1284 # This routine makes sure $pager is set up so that '|' can use it.
1285 pager(
1286
1287     # If PAGER is defined in the environment, use it.
1288     defined $ENV{PAGER}
1289     ? $ENV{PAGER}
1290
1291       # If not, see if Config.pm defines it.
1292     : eval { require Config }
1293       && defined $Config::Config{pager}
1294     ? $Config::Config{pager}
1295
1296       # If not, fall back to 'more'.
1297     : 'more'
1298   )
1299   unless defined $pager;
1300
1301 =pod
1302
1303 We set up the command to be used to access the man pages, the command
1304 recall character (C<!> unless otherwise defined) and the shell escape
1305 character (C<!> unless otherwise defined). Yes, these do conflict, and
1306 neither works in the debugger at the moment.
1307
1308 =cut
1309
1310 setman();
1311
1312 # Set up defaults for command recall and shell escape (note:
1313 # these currently don't work in linemode debugging).
1314 &recallCommand("!") unless defined $prc;
1315 &shellBang("!")     unless defined $psh;
1316
1317 =pod
1318
1319 We then set up the gigantic string containing the debugger help.
1320 We also set the limit on the number of arguments we'll display during a
1321 trace.
1322
1323 =cut
1324
1325 sethelp();
1326
1327 # If we didn't get a default for the length of eval/stack trace args,
1328 # set it here.
1329 $maxtrace = 400 unless defined $maxtrace;
1330
1331 =head2 SETTING UP THE DEBUGGER GREETING
1332
1333 The debugger I<greeting> helps to inform the user how many debuggers are
1334 running, and whether the current debugger is the primary or a child.
1335
1336 If we are the primary, we just hang onto our pid so we'll have it when
1337 or if we start a child debugger. If we are a child, we'll set things up
1338 so we'll have a unique greeting and so the parent will give us our own
1339 TTY later.
1340
1341 We save the current contents of the C<PERLDB_PIDS> environment variable
1342 because we mess around with it. We'll also need to hang onto it because
1343 we'll need it if we restart.
1344
1345 Child debuggers make a label out of the current PID structure recorded in
1346 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1347 yet so the parent will give them one later via C<resetterm()>.
1348
1349 =cut
1350
1351 # Save the current contents of the environment; we're about to
1352 # much with it. We'll need this if we have to restart.
1353 $ini_pids = $ENV{PERLDB_PIDS};
1354
1355 if ( defined $ENV{PERLDB_PIDS} ) {
1356
1357     # We're a child. Make us a label out of the current PID structure
1358     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1359     # a term yet so the parent will give us one later via resetterm().
1360
1361     my $env_pids = $ENV{PERLDB_PIDS};
1362     $pids = "[$env_pids]";
1363
1364     # Unless we are on OpenVMS, all programs under the DCL shell run under
1365     # the same PID.
1366
1367     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1368         $term_pid         = $$;
1369     }
1370     else {
1371         $ENV{PERLDB_PIDS} .= "->$$";
1372         $term_pid = -1;
1373     }
1374
1375 } ## end if (defined $ENV{PERLDB_PIDS...
1376 else {
1377
1378     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1379     # child debugger, and mark us as the parent, so we'll know to set up
1380     # more TTY's is we have to.
1381     $ENV{PERLDB_PIDS} = "$$";
1382     $pids             = "[pid=$$]";
1383     $term_pid         = $$;
1384 }
1385
1386 $pidprompt = '';
1387
1388 # Sets up $emacs as a synonym for $slave_editor.
1389 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1390
1391 =head2 READING THE RC FILE
1392
1393 The debugger will read a file of initialization options if supplied. If
1394 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1395
1396 =cut
1397
1398 # As noted, this test really doesn't check accurately that the debugger
1399 # is running at a terminal or not.
1400
1401 my $dev_tty = '/dev/tty';
1402    $dev_tty = 'TT:' if ($^O eq 'VMS');
1403 if ( -e $dev_tty ) {                      # this is the wrong metric!
1404     $rcfile = ".perldb";
1405 }
1406 else {
1407     $rcfile = "perldb.ini";
1408 }
1409
1410 =pod
1411
1412 The debugger does a safety test of the file to be read. It must be owned
1413 either by the current user or root, and must only be writable by the owner.
1414
1415 =cut
1416
1417 # This wraps a safety test around "do" to read and evaluate the init file.
1418 #
1419 # This isn't really safe, because there's a race
1420 # between checking and opening.  The solution is to
1421 # open and fstat the handle, but then you have to read and
1422 # eval the contents.  But then the silly thing gets
1423 # your lexical scope, which is unfortunate at best.
1424 sub safe_do {
1425     my $file = shift;
1426
1427     # Just exactly what part of the word "CORE::" don't you understand?
1428     local $SIG{__WARN__};
1429     local $SIG{__DIE__};
1430
1431     unless ( is_safe_file($file) ) {
1432         CORE::warn <<EO_GRIPE;
1433 perldb: Must not source insecure rcfile $file.
1434         You or the superuser must be the owner, and it must not
1435         be writable by anyone but its owner.
1436 EO_GRIPE
1437         return;
1438     } ## end unless (is_safe_file($file...
1439
1440     do $file;
1441     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1442 } ## end sub safe_do
1443
1444 # This is the safety test itself.
1445 #
1446 # Verifies that owner is either real user or superuser and that no
1447 # one but owner may write to it.  This function is of limited use
1448 # when called on a path instead of upon a handle, because there are
1449 # no guarantees that filename (by dirent) whose file (by ino) is
1450 # eventually accessed is the same as the one tested.
1451 # Assumes that the file's existence is not in doubt.
1452 sub is_safe_file {
1453     my $path = shift;
1454     stat($path) || return;    # mysteriously vaporized
1455     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1456
1457     return 0 if $uid != 0 && $uid != $<;
1458     return 0 if $mode & 022;
1459     return 1;
1460 } ## end sub is_safe_file
1461
1462 # If the rcfile (whichever one we decided was the right one to read)
1463 # exists, we safely do it.
1464 if ( -f $rcfile ) {
1465     safe_do("./$rcfile");
1466 }
1467
1468 # If there isn't one here, try the user's home directory.
1469 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1470     safe_do("$ENV{HOME}/$rcfile");
1471 }
1472
1473 # Else try the login directory.
1474 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1475     safe_do("$ENV{LOGDIR}/$rcfile");
1476 }
1477
1478 # If the PERLDB_OPTS variable has options in it, parse those out next.
1479 if ( defined $ENV{PERLDB_OPTS} ) {
1480     parse_options( $ENV{PERLDB_OPTS} );
1481 }
1482
1483 =pod
1484
1485 The last thing we do during initialization is determine which subroutine is
1486 to be used to obtain a new terminal when a new debugger is started. Right now,
1487 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1488 (darwin).
1489
1490 =cut
1491
1492 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1493 # Works if you're running an xterm or xterm-like window, or you're on
1494 # OS/2, or on Mac OS X. This may need some expansion.
1495
1496 if (not defined &get_fork_TTY)       # only if no routine exists
1497 {
1498     if ( defined $remoteport ) {
1499                                                  # Expect an inetd-like server
1500         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1501     }
1502     elsif (defined $ENV{TERM}                    # If we know what kind
1503                                                  # of terminal this is,
1504         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1505         and defined $ENV{DISPLAY}                # and what display it's on,
1506       )
1507     {
1508         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1509     }
1510     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1511         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1512     }
1513     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1514             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1515             and $ENV{TERM_PROGRAM}
1516                 eq 'Apple_Terminal'              # Terminal.app
1517             )
1518     {
1519         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1520     }
1521 } ## end if (not defined &get_fork_TTY...
1522
1523 # untaint $^O, which may have been tainted by the last statement.
1524 # see bug [perl #24674]
1525 $^O =~ m/^(.*)\z/;
1526 $^O = $1;
1527
1528 # Here begin the unreadable code.  It needs fixing.
1529
1530 =head2 RESTART PROCESSING
1531
1532 This section handles the restart command. When the C<R> command is invoked, it
1533 tries to capture all of the state it can into environment variables, and
1534 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1535 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1536 the R command stuffed into the environment variables.
1537
1538   PERLDB_RESTART   - flag only, contains no restart data itself.
1539   PERLDB_HIST      - command history, if it's available
1540   PERLDB_ON_LOAD   - breakpoints set by the rc file
1541   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1542   PERLDB_VISITED   - files that had breakpoints
1543   PERLDB_FILE_...  - breakpoints for a file
1544   PERLDB_OPT       - active options
1545   PERLDB_INC       - the original @INC
1546   PERLDB_PRETYPE   - preprompt debugger actions
1547   PERLDB_PRE       - preprompt Perl code
1548   PERLDB_POST      - post-prompt Perl code
1549   PERLDB_TYPEAHEAD - typeahead captured by readline()
1550
1551 We chug through all these variables and plug the values saved in them
1552 back into the appropriate spots in the debugger.
1553
1554 =cut
1555
1556 if ( exists $ENV{PERLDB_RESTART} ) {
1557
1558     # We're restarting, so we don't need the flag that says to restart anymore.
1559     delete $ENV{PERLDB_RESTART};
1560
1561     # $restart = 1;
1562     @hist          = get_list('PERLDB_HIST');
1563     %break_on_load = get_list("PERLDB_ON_LOAD");
1564     %postponed     = get_list("PERLDB_POSTPONE");
1565
1566         share(@hist);
1567         share(@truehist);
1568         share(%break_on_load);
1569         share(%postponed);
1570
1571     # restore breakpoints/actions
1572     my @had_breakpoints = get_list("PERLDB_VISITED");
1573     for my $file_idx ( 0 .. $#had_breakpoints ) {
1574         my $filename = $had_breakpoints[$file_idx];
1575         my %pf = get_list("PERLDB_FILE_$file_idx");
1576         $postponed_file{ $filename } = \%pf if %pf;
1577         my @lines = sort {$a <=> $b} keys(%pf);
1578         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1579         for my $line_idx (0 .. $#lines) {
1580             _set_breakpoint_enabled_status(
1581                 $filename,
1582                 $lines[$line_idx],
1583                 ($enabled_statuses[$line_idx] ? 1 : ''),
1584             );
1585         }
1586     }
1587
1588     # restore options
1589     my %opt = get_list("PERLDB_OPT");
1590     my ( $opt, $val );
1591     while ( ( $opt, $val ) = each %opt ) {
1592         $val =~ s/[\\\']/\\$1/g;
1593         parse_options("$opt'$val'");
1594     }
1595
1596     # restore original @INC
1597     @INC     = get_list("PERLDB_INC");
1598     @ini_INC = @INC;
1599
1600     # return pre/postprompt actions and typeahead buffer
1601     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1602     $pre       = [ get_list("PERLDB_PRE") ];
1603     $post      = [ get_list("PERLDB_POST") ];
1604     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1605 } ## end if (exists $ENV{PERLDB_RESTART...
1606
1607 =head2 SETTING UP THE TERMINAL
1608
1609 Now, we'll decide how the debugger is going to interact with the user.
1610 If there's no TTY, we set the debugger to run non-stop; there's not going
1611 to be anyone there to enter commands.
1612
1613 =cut
1614
1615 if ($notty) {
1616     $runnonstop = 1;
1617         share($runnonstop);
1618 }
1619
1620 =pod
1621
1622 If there is a TTY, we have to determine who it belongs to before we can
1623 proceed. If this is a slave editor or graphical debugger (denoted by
1624 the first command-line switch being '-emacs'), we shift this off and
1625 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1626
1627 =cut
1628
1629 else {
1630
1631     # Is Perl being run from a slave editor or graphical debugger?
1632     # If so, don't use readline, and set $slave_editor = 1.
1633     $slave_editor =
1634       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1635     $rl = 0, shift(@main::ARGV) if $slave_editor;
1636
1637     #require Term::ReadLine;
1638
1639 =pod
1640
1641 We then determine what the console should be on various systems:
1642
1643 =over 4
1644
1645 =item * Cygwin - We use C<stdin> instead of a separate device.
1646
1647 =cut
1648
1649     if ( $^O eq 'cygwin' ) {
1650
1651         # /dev/tty is binary. use stdin for textmode
1652         undef $console;
1653     }
1654
1655 =item * Unix - use C</dev/tty>.
1656
1657 =cut
1658
1659     elsif ( -e "/dev/tty" ) {
1660         $console = "/dev/tty";
1661     }
1662
1663 =item * Windows or MSDOS - use C<con>.
1664
1665 =cut
1666
1667     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1668         $console = "con";
1669     }
1670
1671 =item * VMS - use C<sys$command>.
1672
1673 =cut
1674
1675     else {
1676
1677         # everything else is ...
1678         $console = "sys\$command";
1679     }
1680
1681 =pod
1682
1683 =back
1684
1685 Several other systems don't use a specific console. We C<undef $console>
1686 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1687 with a slave editor, Epoc).
1688
1689 =cut
1690
1691     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1692
1693         # /dev/tty is binary. use stdin for textmode
1694         $console = undef;
1695     }
1696
1697     if ( $^O eq 'NetWare' ) {
1698
1699         # /dev/tty is binary. use stdin for textmode
1700         $console = undef;
1701     }
1702
1703     # In OS/2, we need to use STDIN to get textmode too, even though
1704     # it pretty much looks like Unix otherwise.
1705     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1706     {    # In OS/2
1707         $console = undef;
1708     }
1709
1710     # EPOC also falls into the 'got to use STDIN' camp.
1711     if ( $^O eq 'epoc' ) {
1712         $console = undef;
1713     }
1714
1715 =pod
1716
1717 If there is a TTY hanging around from a parent, we use that as the console.
1718
1719 =cut
1720
1721     $console = $tty if defined $tty;
1722
1723 =head2 SOCKET HANDLING
1724
1725 The debugger is capable of opening a socket and carrying out a debugging
1726 session over the socket.
1727
1728 If C<RemotePort> was defined in the options, the debugger assumes that it
1729 should try to start a debugging session on that port. It builds the socket
1730 and then tries to connect the input and output filehandles to it.
1731
1732 =cut
1733
1734     # Handle socket stuff.
1735
1736     if ( defined $remoteport ) {
1737
1738         # If RemotePort was defined in the options, connect input and output
1739         # to the socket.
1740         $IN = $OUT = connect_remoteport();
1741     } ## end if (defined $remoteport)
1742
1743 =pod
1744
1745 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1746 this is probably a situation where multiple debuggers are running (for example,
1747 a backticked command that starts up another debugger). We create a new IN and
1748 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1749 and if we can.
1750
1751 =cut
1752
1753     # Non-socket.
1754     else {
1755
1756         # Two debuggers running (probably a system or a backtick that invokes
1757         # the debugger itself under the running one). create a new IN and OUT
1758         # filehandle, and do the necessary mojo to create a new tty if we
1759         # know how, and we can.
1760         create_IN_OUT(4) if $CreateTTY & 4;
1761         if ($console) {
1762
1763             # If we have a console, check to see if there are separate ins and
1764             # outs to open. (They are assumed identical if not.)
1765
1766             my ( $i, $o ) = split /,/, $console;
1767             $o = $i unless defined $o;
1768
1769             # read/write on in, or just read, or read on STDIN.
1770             open( IN,      "+<$i" )
1771               || open( IN, "<$i" )
1772               || open( IN, "<&STDIN" );
1773
1774             # read/write/create/clobber out, or write/create/clobber out,
1775             # or merge with STDERR, or merge with STDOUT.
1776                  open( OUT, "+>$o" )
1777               || open( OUT, ">$o" )
1778               || open( OUT, ">&STDERR" )
1779               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1780
1781         } ## end if ($console)
1782         elsif ( not defined $console ) {
1783
1784             # No console. Open STDIN.
1785             open( IN, "<&STDIN" );
1786
1787             # merge with STDERR, or with STDOUT.
1788             open( OUT,      ">&STDERR" )
1789               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1790             $console = 'STDIN/OUT';
1791         } ## end elsif (not defined $console)
1792
1793         # Keep copies of the filehandles so that when the pager runs, it
1794         # can close standard input without clobbering ours.
1795         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1796     } ## end elsif (from if(defined $remoteport))
1797
1798     # Unbuffer DB::OUT. We need to see responses right away.
1799     my $previous = select($OUT);
1800     $| = 1;                                  # for DB::OUT
1801     select($previous);
1802
1803     # Line info goes to debugger output unless pointed elsewhere.
1804     # Pointing elsewhere makes it possible for slave editors to
1805     # keep track of file and position. We have both a filehandle
1806     # and a I/O description to keep track of.
1807     $LINEINFO = $OUT     unless defined $LINEINFO;
1808     $lineinfo = $console unless defined $lineinfo;
1809         # share($LINEINFO); # <- unable to share globs
1810         share($lineinfo);   #
1811
1812 =pod
1813
1814 To finish initialization, we show the debugger greeting,
1815 and then call the C<afterinit()> subroutine if there is one.
1816
1817 =cut
1818
1819     # Show the debugger greeting.
1820     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1821     unless ($runnonstop) {
1822         local $\ = '';
1823         local $, = '';
1824         if ( $term_pid eq '-1' ) {
1825             print $OUT "\nDaughter DB session started...\n";
1826         }
1827         else {
1828             print $OUT "\nLoading DB routines from $header\n";
1829             print $OUT (
1830                 "Editor support ",
1831                 $slave_editor ? "enabled" : "available", ".\n"
1832             );
1833             print $OUT
1834 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1835         } ## end else [ if ($term_pid eq '-1')
1836     } ## end unless ($runnonstop)
1837 } ## end else [ if ($notty)
1838
1839 # XXX This looks like a bug to me.
1840 # Why copy to @ARGS and then futz with @args?
1841 @ARGS = @ARGV;
1842 for (@args) {
1843     # Make sure backslashes before single quotes are stripped out, and
1844     # keep args unless they are numeric (XXX why?)
1845     # s/\'/\\\'/g;                      # removed while not justified understandably
1846     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1847 }
1848
1849 # If there was an afterinit() sub defined, call it. It will get
1850 # executed in our scope, so it can fiddle with debugger globals.
1851 if ( defined &afterinit ) {    # May be defined in $rcfile
1852     &afterinit();
1853 }
1854
1855 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1856 $I_m_init = 1;
1857
1858 ############################################################ Subroutines
1859
1860 =head1 SUBROUTINES
1861
1862 =head2 DB
1863
1864 This gigantic subroutine is the heart of the debugger. Called before every
1865 statement, its job is to determine if a breakpoint has been reached, and
1866 stop if so; read commands from the user, parse them, and execute
1867 them, and then send execution off to the next statement.
1868
1869 Note that the order in which the commands are processed is very important;
1870 some commands earlier in the loop will actually alter the C<$cmd> variable
1871 to create other commands to be executed later. This is all highly I<optimized>
1872 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1873 see what's happening in any given command.
1874
1875 =cut
1876
1877 sub DB {
1878
1879     # lock the debugger and get the thread id for the prompt
1880         lock($DBGR);
1881         my $tid;
1882         if ($ENV{PERL5DB_THREADED}) {
1883                 $tid = eval { "[".threads->tid."]" };
1884         }
1885
1886     # Check for whether we should be running continuously or not.
1887     # _After_ the perl program is compiled, $single is set to 1:
1888     if ( $single and not $second_time++ ) {
1889
1890         # Options say run non-stop. Run until we get an interrupt.
1891         if ($runnonstop) {    # Disable until signal
1892                 # If there's any call stack in place, turn off single
1893                 # stepping into subs throughout the stack.
1894             for ( $i = 0 ; $i <= $stack_depth ; ) {
1895                 $stack[ $i++ ] &= ~1;
1896             }
1897
1898             # And we are now no longer in single-step mode.
1899             $single = 0;
1900
1901             # If we simply returned at this point, we wouldn't get
1902             # the trace info. Fall on through.
1903             # return;
1904         } ## end if ($runnonstop)
1905
1906         elsif ($ImmediateStop) {
1907
1908             # We are supposed to stop here; XXX probably a break.
1909             $ImmediateStop = 0;    # We've processed it; turn it off
1910             $signal        = 1;    # Simulate an interrupt to force
1911                                    # us into the command loop
1912         }
1913     } ## end if ($single and not $second_time...
1914
1915     # If we're in single-step mode, or an interrupt (real or fake)
1916     # has occurred, turn off non-stop mode.
1917     $runnonstop = 0 if $single or $signal;
1918
1919     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1920     # The code being debugged may have altered them.
1921     &save;
1922
1923     # Since DB::DB gets called after every line, we can use caller() to
1924     # figure out where we last were executing. Sneaky, eh? This works because
1925     # caller is returning all the extra information when called from the
1926     # debugger.
1927     local ( $package, $filename, $line ) = caller;
1928     local $filename_ini = $filename;
1929
1930     # set up the context for DB::eval, so it can properly execute
1931     # code on behalf of the user. We add the package in so that the
1932     # code is eval'ed in the proper package (not in the debugger!).
1933     local $usercontext =
1934       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1935
1936     # Create an alias to the active file magical array to simplify
1937     # the code here.
1938     local (*dbline) = $main::{ '_<' . $filename };
1939
1940     # Last line in the program.
1941     local $max = $#dbline;
1942
1943     # if we have something here, see if we should break.
1944     if ( $dbline{$line}
1945         && _is_breakpoint_enabled($filename, $line)
1946         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1947     {
1948
1949         # Stop if the stop criterion says to just stop.
1950         if ( $stop eq '1' ) {
1951             $signal |= 1;
1952         }
1953
1954         # It's a conditional stop; eval it in the user's context and
1955         # see if we should stop. If so, remove the one-time sigil.
1956         elsif ($stop) {
1957             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1958             &eval;
1959             # If the breakpoint is temporary, then delete its enabled status.
1960             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1961                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1962             }
1963         }
1964     } ## end if ($dbline{$line} && ...
1965
1966     # Preserve the current stop-or-not, and see if any of the W
1967     # (watch expressions) has changed.
1968     my $was_signal = $signal;
1969
1970     # If we have any watch expressions ...
1971     if ( $trace & 2 ) {
1972         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1973             $evalarg = $to_watch[$n];
1974             local $onetimeDump;    # Tell DB::eval() to not output results
1975
1976             # Fix context DB::eval() wants to return an array, but
1977             # we need a scalar here.
1978             my ($val) = join( "', '", &eval );
1979             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1980
1981             # Did it change?
1982             if ( $val ne $old_watch[$n] ) {
1983
1984                 # Yep! Show the difference, and fake an interrupt.
1985                 $signal = 1;
1986                 print $OUT <<EOP;
1987 Watchpoint $n:\t$to_watch[$n] changed:
1988     old value:\t$old_watch[$n]
1989     new value:\t$val
1990 EOP
1991                 $old_watch[$n] = $val;
1992             } ## end if ($val ne $old_watch...
1993         } ## end for (my $n = 0 ; $n <= ...
1994     } ## end if ($trace & 2)
1995
1996 =head2 C<watchfunction()>
1997
1998 C<watchfunction()> is a function that can be defined by the user; it is a
1999 function which will be run on each entry to C<DB::DB>; it gets the
2000 current package, filename, and line as its parameters.
2001
2002 The watchfunction can do anything it likes; it is executing in the
2003 debugger's context, so it has access to all of the debugger's internal
2004 data structures and functions.
2005
2006 C<watchfunction()> can control the debugger's actions. Any of the following
2007 will cause the debugger to return control to the user's program after
2008 C<watchfunction()> executes:
2009
2010 =over 4
2011
2012 =item *
2013
2014 Returning a false value from the C<watchfunction()> itself.
2015
2016 =item *
2017
2018 Altering C<$single> to a false value.
2019
2020 =item *
2021
2022 Altering C<$signal> to a false value.
2023
2024 =item *
2025
2026 Turning off the C<4> bit in C<$trace> (this also disables the
2027 check for C<watchfunction()>. This can be done with
2028
2029     $trace &= ~4;
2030
2031 =back
2032
2033 =cut
2034
2035     # If there's a user-defined DB::watchfunction, call it with the
2036     # current package, filename, and line. The function executes in
2037     # the DB:: package.
2038     if ( $trace & 4 ) {    # User-installed watch
2039         return
2040           if watchfunction( $package, $filename, $line )
2041           and not $single
2042           and not $was_signal
2043           and not( $trace & ~4 );
2044     } ## end if ($trace & 4)
2045
2046     # Pick up any alteration to $signal in the watchfunction, and
2047     # turn off the signal now.
2048     $was_signal = $signal;
2049     $signal     = 0;
2050
2051 =head2 GETTING READY TO EXECUTE COMMANDS
2052
2053 The debugger decides to take control if single-step mode is on, the
2054 C<t> command was entered, or the user generated a signal. If the program
2055 has fallen off the end, we set things up so that entering further commands
2056 won't cause trouble, and we say that the program is over.
2057
2058 =cut
2059
2060     # Check to see if we should grab control ($single true,
2061     # trace set appropriately, or we got a signal).
2062     if ( $single || ( $trace & 1 ) || $was_signal ) {
2063
2064         # Yes, grab control.
2065         if ($slave_editor) {
2066
2067             # Tell the editor to update its position.
2068             $position = "\032\032$filename:$line:0\n";
2069             print_lineinfo($position);
2070         }
2071
2072 =pod
2073
2074 Special check: if we're in package C<DB::fake>, we've gone through the
2075 C<END> block at least once. We set up everything so that we can continue
2076 to enter commands and have a valid context to be in.
2077
2078 =cut
2079
2080         elsif ( $package eq 'DB::fake' ) {
2081
2082             # Fallen off the end already.
2083             $term || &setterm;
2084             print_help(<<EOP);
2085 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2086   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2087   B<h q>, B<h R> or B<h o> to get additional info.
2088 EOP
2089
2090             # Set the DB::eval context appropriately.
2091             $package     = 'main';
2092             $usercontext =
2093                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2094               . "package $package;";    # this won't let them modify, alas
2095         } ## end elsif ($package eq 'DB::fake')
2096
2097 =pod
2098
2099 If the program hasn't finished executing, we scan forward to the
2100 next executable line, print that out, build the prompt from the file and line
2101 number information, and print that.
2102
2103 =cut
2104
2105         else {
2106
2107             # Still somewhere in the midst of execution. Set up the
2108             #  debugger prompt.
2109             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2110                                  # Perl 5 ones (sorry, we don't print Klingon
2111                                  #module names)
2112
2113             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2114             $prefix .= "$sub($filename:";
2115             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2116
2117             # Break up the prompt if it's really long.
2118             if ( length($prefix) > 30 ) {
2119                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2120                 $prefix   = "";
2121                 $infix    = ":\t";
2122             }
2123             else {
2124                 $infix    = "):\t";
2125                 $position = "$prefix$line$infix$dbline[$line]$after";
2126             }
2127
2128             # Print current line info, indenting if necessary.
2129             if ($frame) {
2130                 print_lineinfo( ' ' x $stack_depth,
2131                     "$line:\t$dbline[$line]$after" );
2132             }
2133             else {
2134                 depth_print_lineinfo($position);
2135             }
2136
2137             # Scan forward, stopping at either the end or the next
2138             # unbreakable line.
2139             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2140             {    #{ vi
2141
2142                 # Drop out on null statements, block closers, and comments.
2143                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2144
2145                 # Drop out if the user interrupted us.
2146                 last if $signal;
2147
2148                 # Append a newline if the line doesn't have one. Can happen
2149                 # in eval'ed text, for instance.
2150                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2151
2152                 # Next executable line.
2153                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2154                 $position .= $incr_pos;
2155                 if ($frame) {
2156
2157                     # Print it indented if tracing is on.
2158                     print_lineinfo( ' ' x $stack_depth,
2159                         "$i:\t$dbline[$i]$after" );
2160                 }
2161                 else {
2162                     depth_print_lineinfo($incr_pos);
2163                 }
2164             } ## end for ($i = $line + 1 ; $i...
2165         } ## end else [ if ($slave_editor)
2166     } ## end if ($single || ($trace...
2167
2168 =pod
2169
2170 If there's an action to be executed for the line we stopped at, execute it.
2171 If there are any preprompt actions, execute those as well.
2172
2173 =cut
2174
2175     # If there's an action, do it now.
2176     $evalarg = $action, &eval if $action;
2177
2178     # Are we nested another level (e.g., did we evaluate a function
2179     # that had a breakpoint in it at the debugger prompt)?
2180     if ( $single || $was_signal ) {
2181
2182         # Yes, go down a level.
2183         local $level = $level + 1;
2184
2185         # Do any pre-prompt actions.
2186         foreach $evalarg (@$pre) {
2187             &eval;
2188         }
2189
2190         # Complain about too much recursion if we passed the limit.
2191         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2192           if $single & 4;
2193
2194         # The line we're currently on. Set $incr to -1 to stay here
2195         # until we get a command that tells us to advance.
2196         $start = $line;
2197         $incr  = -1;      # for backward motion.
2198
2199         # Tack preprompt debugger actions ahead of any actual input.
2200         @typeahead = ( @$pretype, @typeahead );
2201
2202 =head2 WHERE ARE WE?
2203
2204 XXX Relocate this section?
2205
2206 The debugger normally shows the line corresponding to the current line of
2207 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2208 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2209
2210 C<$incr> controls by how many lines the I<current> line should move forward
2211 after a command is executed. If set to -1, this indicates that the I<current>
2212 line shouldn't change.
2213
2214 C<$start> is the I<current> line. It is used for things like knowing where to
2215 move forwards or backwards from when doing an C<L> or C<-> command.
2216
2217 C<$max> tells the debugger where the last line of the current file is. It's
2218 used to terminate loops most often.
2219
2220 =head2 THE COMMAND LOOP
2221
2222 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2223 in two parts:
2224
2225 =over 4
2226
2227 =item *
2228
2229 The outer part of the loop, starting at the C<CMD> label. This loop
2230 reads a command and then executes it.
2231
2232 =item *
2233
2234 The inner part of the loop, starting at the C<PIPE> label. This part
2235 is wholly contained inside the C<CMD> block and only executes a command.
2236 Used to handle commands running inside a pager.
2237
2238 =back
2239
2240 So why have two labels to restart the loop? Because sometimes, it's easier to
2241 have a command I<generate> another command and then re-execute the loop to do
2242 the new command. This is faster, but perhaps a bit more convoluted.
2243
2244 =cut
2245
2246         # The big command dispatch loop. It keeps running until the
2247         # user yields up control again.
2248         #
2249         # If we have a terminal for input, and we get something back
2250         # from readline(), keep on processing.
2251       CMD:
2252         while (
2253
2254             # We have a terminal, or can get one ...
2255             ( $term || &setterm ),
2256
2257             # ... and it belogs to this PID or we get one for this PID ...
2258             ( $term_pid == $$ or resetterm(1) ),
2259
2260             # ... and we got a line of command input ...
2261             defined(
2262                 $cmd = &readline(
2263                         "$pidprompt $tid DB"
2264                       . ( '<' x $level )
2265                       . ( $#hist + 1 )
2266                       . ( '>' x $level ) . " "
2267                 )
2268             )
2269           )
2270         {
2271
2272                         share($cmd);
2273             # ... try to execute the input as debugger commands.
2274
2275             # Don't stop running.
2276             $single = 0;
2277
2278             # No signal is active.
2279             $signal = 0;
2280
2281             # Handle continued commands (ending with \):
2282             $cmd =~ s/\\$/\n/ && do {
2283                 $cmd .= &readline("  cont: ");
2284                 redo CMD;
2285             };
2286
2287 =head4 The null command
2288
2289 A newline entered by itself means I<re-execute the last command>. We grab the
2290 command out of C<$laststep> (where it was recorded previously), and copy it
2291 back into C<$cmd> to be executed below. If there wasn't any previous command,
2292 we'll do nothing below (no command will match). If there was, we also save it
2293 in the command history and fall through to allow the command parsing to pick
2294 it up.
2295
2296 =cut
2297
2298             # Empty input means repeat the last command.
2299             $cmd =~ /^$/ && ( $cmd = $laststep );
2300             chomp($cmd);    # get rid of the annoying extra newline
2301             push( @hist, $cmd ) if length($cmd) > 1;
2302             push( @truehist, $cmd );
2303                         share(@hist);
2304                         share(@truehist);
2305
2306             # This is a restart point for commands that didn't arrive
2307             # via direct user input. It allows us to 'redo PIPE' to
2308             # re-execute command processing without reading a new command.
2309           PIPE: {
2310                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2311                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2312                 ($i) = split( /\s+/, $cmd );
2313
2314 =head3 COMMAND ALIASES
2315
2316 The debugger can create aliases for commands (these are stored in the
2317 C<%alias> hash). Before a command is executed, the command loop looks it up
2318 in the alias hash and substitutes the contents of the alias for the command,
2319 completely replacing it.
2320
2321 =cut
2322
2323                 # See if there's an alias for the command, and set it up if so.
2324                 if ( $alias{$i} ) {
2325
2326                     # Squelch signal handling; we want to keep control here
2327                     # if something goes loco during the alias eval.
2328                     local $SIG{__DIE__};
2329                     local $SIG{__WARN__};
2330
2331                     # This is a command, so we eval it in the DEBUGGER's
2332                     # scope! Otherwise, we can't see the special debugger
2333                     # variables, or get to the debugger's subs. (Well, we
2334                     # _could_, but why make it even more complicated?)
2335                     eval "\$cmd =~ $alias{$i}";
2336                     if ($@) {
2337                         local $\ = '';
2338                         print $OUT "Couldn't evaluate '$i' alias: $@";
2339                         next CMD;
2340                     }
2341                 } ## end if ($alias{$i})
2342
2343 =head3 MAIN-LINE COMMANDS
2344
2345 All of these commands work up to and after the program being debugged has
2346 terminated.
2347
2348 =head4 C<q> - quit
2349
2350 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2351 try to execute further, cleaning any restart-related stuff out of the
2352 environment, and executing with the last value of C<$?>.
2353
2354 =cut
2355
2356                 $cmd =~ /^q$/ && do {
2357                     $fall_off_end = 1;
2358                     clean_ENV();
2359                     exit $?;
2360                 };
2361
2362 =head4 C<t> - trace [n]
2363
2364 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2365 If level is specified, set C<$trace_to_depth>.
2366
2367 =cut
2368
2369                 $cmd =~ /^t(?:\s+(\d+))?$/ && do {
2370                     my $levels = $1;
2371                     $trace ^= 1;
2372                     local $\ = '';
2373                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2374                     print $OUT "Trace = "
2375                       . ( ( $trace & 1 )
2376                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2377                       : "off" ) . "\n";
2378                     next CMD;
2379                 };
2380
2381 =head4 C<S> - list subroutines matching/not matching a pattern
2382
2383 Walks through C<%sub>, checking to see whether or not to print the name.
2384
2385 =cut
2386
2387                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2388
2389                     $Srev     = defined $2;     # Reverse scan?
2390                     $Spatt    = $3;             # The pattern (if any) to use.
2391                     $Snocheck = !defined $1;    # No args - print all subs.
2392
2393                     # Need to make these sane here.
2394                     local $\ = '';
2395                     local $, = '';
2396
2397                     # Search through the debugger's magical hash of subs.
2398                     # If $nocheck is true, just print the sub name.
2399                     # Otherwise, check it against the pattern. We then use
2400                     # the XOR trick to reverse the condition as required.
2401                     foreach $subname ( sort( keys %sub ) ) {
2402                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2403                             print $OUT $subname, "\n";
2404                         }
2405                     }
2406                     next CMD;
2407                 };
2408
2409 =head4 C<X> - list variables in current package
2410
2411 Since the C<V> command actually processes this, just change this to the
2412 appropriate C<V> command and fall through.
2413
2414 =cut
2415
2416                 $cmd =~ s/^X\b/V $package/;
2417
2418 =head4 C<V> - list variables
2419
2420 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2421
2422 =cut
2423
2424                 # Bare V commands get the currently-being-debugged package
2425                 # added.
2426                 $cmd =~ /^V$/ && do {
2427                     $cmd = "V $package";
2428                 };
2429
2430                 # V - show variables in package.
2431                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2432
2433                     # Save the currently selected filehandle and
2434                     # force output to debugger's filehandle (dumpvar
2435                     # just does "print" for output).
2436                     local ($savout) = select($OUT);
2437
2438                     # Grab package name and variables to dump.
2439                     $packname = $1;
2440                     @vars     = split( ' ', $2 );
2441
2442                     # If main::dumpvar isn't here, get it.
2443                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2444                     if ( defined &main::dumpvar ) {
2445
2446                         # We got it. Turn off subroutine entry/exit messages
2447                         # for the moment, along with return values.
2448                         local $frame = 0;
2449                         local $doret = -2;
2450
2451                         # must detect sigpipe failures  - not catching
2452                         # then will cause the debugger to die.
2453                         eval {
2454                             &main::dumpvar(
2455                                 $packname,
2456                                 defined $option{dumpDepth}
2457                                 ? $option{dumpDepth}
2458                                 : -1,    # assume -1 unless specified
2459                                 @vars
2460                             );
2461                         };
2462
2463                         # The die doesn't need to include the $@, because
2464                         # it will automatically get propagated for us.
2465                         if ($@) {
2466                             die unless $@ =~ /dumpvar print failed/;
2467                         }
2468                     } ## end if (defined &main::dumpvar)
2469                     else {
2470
2471                         # Couldn't load dumpvar.
2472                         print $OUT "dumpvar.pl not available.\n";
2473                     }
2474
2475                     # Restore the output filehandle, and go round again.
2476                     select($savout);
2477                     next CMD;
2478                 };
2479
2480 =head4 C<x> - evaluate and print an expression
2481
2482 Hands the expression off to C<DB::eval>, setting it up to print the value
2483 via C<dumpvar.pl> instead of just printing it directly.
2484
2485 =cut
2486
2487                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2488                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2489
2490                     # handle special  "x 3 blah" syntax XXX propagate
2491                     # doc back to special variables.
2492                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2493                         $onetimedumpDepth = $1;
2494                     }
2495                 };
2496
2497 =head4 C<m> - print methods
2498
2499 Just uses C<DB::methods> to determine what methods are available.
2500
2501 =cut
2502
2503                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2504                     methods($1);
2505                     next CMD;
2506                 };
2507
2508                 # m expr - set up DB::eval to do the work
2509                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2510                     $onetimeDump = 'methods';   #  method output gets used there
2511                 };
2512
2513 =head4 C<f> - switch files
2514
2515 =cut
2516
2517                 $cmd =~ /^f\b\s*(.*)/ && do {
2518                     $file = $1;
2519                     $file =~ s/\s+$//;
2520
2521                     # help for no arguments (old-style was return from sub).
2522                     if ( !$file ) {
2523                         print $OUT
2524                           "The old f command is now the r command.\n";    # hint
2525                         print $OUT "The new f command switches filenames.\n";
2526                         next CMD;
2527                     } ## end if (!$file)
2528
2529                     # if not in magic file list, try a close match.
2530                     if ( !defined $main::{ '_<' . $file } ) {
2531                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2532                             {
2533                                 $try = substr( $try, 2 );
2534                                 print $OUT "Choosing $try matching '$file':\n";
2535                                 $file = $try;
2536                             }
2537                         } ## end if (($try) = grep(m#^_<.*$file#...
2538                     } ## end if (!defined $main::{ ...
2539
2540                     # If not successfully switched now, we failed.
2541                     if ( !defined $main::{ '_<' . $file } ) {
2542                         print $OUT "No file matching '$file' is loaded.\n";
2543                         next CMD;
2544                     }
2545
2546                     # We switched, so switch the debugger internals around.
2547                     elsif ( $file ne $filename ) {
2548                         *dbline   = $main::{ '_<' . $file };
2549                         $max      = $#dbline;
2550                         $filename = $file;
2551                         $start    = 1;
2552                         $cmd      = "l";
2553                     } ## end elsif ($file ne $filename)
2554
2555                     # We didn't switch; say we didn't.
2556                     else {
2557                         print $OUT "Already in $file.\n";
2558                         next CMD;
2559                     }
2560                 };
2561
2562 =head4 C<.> - return to last-executed line.
2563
2564 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2565 and then we look up the line in the magical C<%dbline> hash.
2566
2567 =cut
2568
2569                 # . command.
2570                 $cmd =~ /^\.$/ && do {
2571                     $incr = -1;    # stay at current line
2572
2573                     # Reset everything to the old location.
2574                     $start    = $line;
2575                     $filename = $filename_ini;
2576                     *dbline   = $main::{ '_<' . $filename };
2577                     $max      = $#dbline;
2578
2579                     # Now where are we?
2580                     print_lineinfo($position);
2581                     next CMD;
2582                 };
2583
2584 =head4 C<-> - back one window
2585
2586 We change C<$start> to be one window back; if we go back past the first line,
2587 we set it to be the first line. We ser C<$incr> to put us back at the
2588 currently-executing line, and then put a C<l $start +> (list one window from
2589 C<$start>) in C<$cmd> to be executed later.
2590
2591 =cut
2592
2593                 # - - back a window.
2594                 $cmd =~ /^-$/ && do {
2595
2596                     # back up by a window; go to 1 if back too far.
2597                     $start -= $incr + $window + 1;
2598                     $start = 1 if $start <= 0;
2599                     $incr  = $window - 1;
2600
2601                     # Generate and execute a "l +" command (handled below).
2602                     $cmd = 'l ' . ($start) . '+';
2603                 };
2604
2605 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2606
2607 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2608 problems, most notably that the default case of several commands destroying
2609 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2610 retain the old commands for those who were used to using them or who preferred
2611 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2612 deal with them instead of processing them in-line.
2613
2614 =cut
2615
2616                 # All of these commands were remapped in perl 5.8.0;
2617                 # we send them off to the secondary dispatcher (see below).
2618                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2619                     &cmd_wrapper( $1, $2, $line );
2620                     next CMD;
2621                 };
2622
2623 =head4 C<y> - List lexicals in higher scope
2624
2625 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2626 above the current one and then displays then using C<dumpvar.pl>.
2627
2628 =cut
2629
2630                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2631
2632                     # See if we've got the necessary support.
2633                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2634                       or &warn(
2635                         $@ =~ /locate/
2636                         ? "PadWalker module not found - please install\n"
2637                         : $@
2638                       )
2639                       and next CMD;
2640
2641                     # Load up dumpvar if we don't have it. If we can, that is.
2642                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2643                     defined &main::dumpvar
2644                       or print $OUT "dumpvar.pl not available.\n"
2645                       and next CMD;
2646
2647                     # Got all the modules we need. Find them and print them.
2648                     my @vars = split( ' ', $2 || '' );
2649
2650                     # Find the pad.
2651                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2652
2653                     # Oops. Can't find it.
2654                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2655
2656                     # Show the desired vars with dumplex().
2657                     my $savout = select($OUT);
2658
2659                     # Have dumplex dump the lexicals.
2660                     dumpvar::dumplex( $_, $h->{$_},
2661                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2662                         @vars )
2663                       for sort keys %$h;
2664                     select($savout);
2665                     next CMD;
2666                 };
2667
2668 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2669
2670 All of the commands below this point don't work after the program being
2671 debugged has ended. All of them check to see if the program has ended; this
2672 allows the commands to be relocated without worrying about a 'line of
2673 demarcation' above which commands can be entered anytime, and below which
2674 they can't.
2675
2676 =head4 C<n> - single step, but don't trace down into subs
2677
2678 Done by setting C<$single> to 2, which forces subs to execute straight through
2679 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2680 so a null command knows what to re-execute.
2681
2682 =cut
2683
2684                 # n - next
2685                 $cmd =~ /^n$/ && do {
2686                     end_report(), next CMD if $finished and $level <= 1;
2687
2688                     # Single step, but don't enter subs.
2689                     $single = 2;
2690
2691                     # Save for empty command (repeat last).
2692                     $laststep = $cmd;
2693                     last CMD;
2694                 };
2695
2696 =head4 C<s> - single-step, entering subs
2697
2698 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2699 subs. Also saves C<s> as C<$lastcmd>.
2700
2701 =cut
2702
2703                 # s - single step.
2704                 $cmd =~ /^s$/ && do {
2705
2706                     # Get out and restart the command loop if program
2707                     # has finished.
2708                     end_report(), next CMD if $finished and $level <= 1;
2709
2710                     # Single step should enter subs.
2711                     $single = 1;
2712
2713                     # Save for empty command (repeat last).
2714                     $laststep = $cmd;
2715                     last CMD;
2716                 };
2717
2718 =head4 C<c> - run continuously, setting an optional breakpoint
2719
2720 Most of the code for this command is taken up with locating the optional
2721 breakpoint, which is either a subroutine name or a line number. We set
2722 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2723 in this and all call levels above this one.
2724
2725 =cut
2726
2727                 # c - start continuous execution.
2728                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2729
2730                     # Hey, show's over. The debugged program finished
2731                     # executing already.
2732                     end_report(), next CMD if $finished and $level <= 1;
2733
2734                     # Capture the place to put a one-time break.
2735                     $subname = $i = $1;
2736
2737                     #  Probably not needed, since we finish an interactive
2738                     #  sub-session anyway...
2739                     # local $filename = $filename;
2740                     # local *dbline = *dbline; # XXX Would this work?!
2741                     #
2742                     # The above question wonders if localizing the alias
2743                     # to the magic array works or not. Since it's commented
2744                     # out, we'll just leave that to speculation for now.
2745
2746                     # If the "subname" isn't all digits, we'll assume it
2747                     # is a subroutine name, and try to find it.
2748                     if ( $subname =~ /\D/ ) {    # subroutine name
2749                             # Qualify it to the current package unless it's
2750                             # already qualified.
2751                         $subname = $package . "::" . $subname
2752                           unless $subname =~ /::/;
2753
2754                         # find_sub will return "file:line_number" corresponding
2755                         # to where the subroutine is defined; we call find_sub,
2756                         # break up the return value, and assign it in one
2757                         # operation.
2758                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2759
2760                         # Force the line number to be numeric.
2761                         $i += 0;
2762
2763                         # If we got a line number, we found the sub.
2764                         if ($i) {
2765
2766                             # Switch all the debugger's internals around so
2767                             # we're actually working with that file.
2768                             $filename = $file;
2769                             *dbline   = $main::{ '_<' . $filename };
2770
2771                             # Mark that there's a breakpoint in this file.
2772                             $had_breakpoints{$filename} |= 1;
2773
2774                             # Scan forward to the first executable line
2775                             # after the 'sub whatever' line.
2776                             $max = $#dbline;
2777                             ++$i while $dbline[$i] == 0 && $i < $max;
2778                         } ## end if ($i)
2779
2780                         # We didn't find a sub by that name.
2781                         else {
2782                             print $OUT "Subroutine $subname not found.\n";
2783                             next CMD;
2784                         }
2785                     } ## end if ($subname =~ /\D/)
2786
2787                     # At this point, either the subname was all digits (an
2788                     # absolute line-break request) or we've scanned through
2789                     # the code following the definition of the sub, looking
2790                     # for an executable, which we may or may not have found.
2791                     #
2792                     # If $i (which we set $subname from) is non-zero, we
2793                     # got a request to break at some line somewhere. On
2794                     # one hand, if there wasn't any real subroutine name
2795                     # involved, this will be a request to break in the current
2796                     # file at the specified line, so we have to check to make
2797                     # sure that the line specified really is breakable.
2798                     #
2799                     # On the other hand, if there was a subname supplied, the
2800                     # preceding block has moved us to the proper file and
2801                     # location within that file, and then scanned forward
2802                     # looking for the next executable line. We have to make
2803                     # sure that one was found.
2804                     #
2805                     # On the gripping hand, we can't do anything unless the
2806                     # current value of $i points to a valid breakable line.
2807                     # Check that.
2808                     if ($i) {
2809
2810                         # Breakable?
2811                         if ( $dbline[$i] == 0 ) {
2812                             print $OUT "Line $i not breakable.\n";
2813                             next CMD;
2814                         }
2815
2816                         # Yes. Set up the one-time-break sigil.
2817                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2818                         _enable_breakpoint_temp_enabled_status($filename, $i);
2819                     } ## end if ($i)
2820
2821                     # Turn off stack tracing from here up.
2822                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2823                         $stack[ $i++ ] &= ~1;
2824                     }
2825                     last CMD;
2826                 };
2827
2828 =head4 C<r> - return from a subroutine
2829
2830 For C<r> to work properly, the debugger has to stop execution again
2831 immediately after the return is executed. This is done by forcing
2832 single-stepping to be on in the call level above the current one. If
2833 we are printing return values when a C<r> is executed, set C<$doret>
2834 appropriately, and force us out of the command loop.
2835
2836 =cut
2837
2838                 # r - return from the current subroutine.
2839                 $cmd =~ /^r$/ && do {
2840
2841                     # Can't do anything if the program's over.
2842                     end_report(), next CMD if $finished and $level <= 1;
2843
2844                     # Turn on stack trace.
2845                     $stack[$stack_depth] |= 1;
2846
2847                     # Print return value unless the stack is empty.
2848                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2849                     last CMD;
2850                 };
2851
2852 =head4 C<T> - stack trace
2853
2854 Just calls C<DB::print_trace>.
2855
2856 =cut
2857
2858                 $cmd =~ /^T$/ && do {
2859                     print_trace( $OUT, 1 );    # skip DB
2860                     next CMD;
2861                 };
2862
2863 =head4 C<w> - List window around current line.
2864
2865 Just calls C<DB::cmd_w>.
2866
2867 =cut
2868
2869                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2870
2871 =head4 C<W> - watch-expression processing.
2872
2873 Just calls C<DB::cmd_W>.
2874
2875 =cut
2876
2877                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2878
2879 =head4 C</> - search forward for a string in the source
2880
2881 We take the argument and treat it as a pattern. If it turns out to be a
2882 bad one, we return the error we got from trying to C<eval> it and exit.
2883 If not, we create some code to do the search and C<eval> it so it can't
2884 mess us up.
2885
2886 =cut
2887
2888                 $cmd =~ /^\/(.*)$/ && do {
2889
2890                     # The pattern as a string.
2891                     $inpat = $1;
2892
2893                     # Remove the final slash.
2894                     $inpat =~ s:([^\\])/$:$1:;
2895
2896                     # If the pattern isn't null ...
2897                     if ( $inpat ne "" ) {
2898
2899                         # Turn of warn and die procesing for a bit.
2900                         local $SIG{__DIE__};
2901                         local $SIG{__WARN__};
2902
2903                         # Create the pattern.
2904                         eval '$inpat =~ m' . "\a$inpat\a";
2905                         if ( $@ ne "" ) {
2906
2907                             # Oops. Bad pattern. No biscuit.
2908                             # Print the eval error and go back for more
2909                             # commands.
2910                             print $OUT "$@";
2911                             next CMD;
2912                         }
2913                         $pat = $inpat;
2914                     } ## end if ($inpat ne "")
2915
2916                     # Set up to stop on wrap-around.
2917                     $end = $start;
2918
2919                     # Don't move off the current line.
2920                     $incr = -1;
2921
2922                     # Done in eval so nothing breaks if the pattern
2923                     # does something weird.
2924                     eval '
2925                         for (;;) {
2926                             # Move ahead one line.
2927                             ++$start;
2928
2929                             # Wrap if we pass the last line.
2930                             $start = 1 if ($start > $max);
2931
2932                             # Stop if we have gotten back to this line again,
2933                             last if ($start == $end);
2934
2935                             # A hit! (Note, though, that we are doing
2936                             # case-insensitive matching. Maybe a qr//
2937                             # expression would be better, so the user could
2938                             # do case-sensitive matching if desired.
2939                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2940                                 if ($slave_editor) {
2941                                     # Handle proper escaping in the slave.
2942                                     print $OUT "\032\032$filename:$start:0\n";
2943                                 }
2944                                 else {
2945                                     # Just print the line normally.
2946                                     print $OUT "$start:\t",$dbline[$start],"\n";
2947                                 }
2948                                 # And quit since we found something.
2949                                 last;
2950                             }
2951                          } ';
2952
2953                     # If we wrapped, there never was a match.
2954                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2955                     next CMD;
2956                 };
2957
2958 =head4 C<?> - search backward for a string in the source
2959
2960 Same as for C</>, except the loop runs backwards.
2961
2962 =cut
2963
2964                 # ? - backward pattern search.
2965                 $cmd =~ /^\?(.*)$/ && do {
2966
2967                     # Get the pattern, remove trailing question mark.
2968                     $inpat = $1;
2969                     $inpat =~ s:([^\\])\?$:$1:;
2970
2971                     # If we've got one ...
2972                     if ( $inpat ne "" ) {
2973
2974                         # Turn off die & warn handlers.
2975                         local $SIG{__DIE__};
2976                         local $SIG{__WARN__};
2977                         eval '$inpat =~ m' . "\a$inpat\a";
2978
2979                         if ( $@ ne "" ) {
2980
2981                             # Ouch. Not good. Print the error.
2982                             print $OUT $@;
2983                             next CMD;
2984                         }
2985                         $pat = $inpat;
2986                     } ## end if ($inpat ne "")
2987
2988                     # Where we are now is where to stop after wraparound.
2989                     $end = $start;
2990
2991                     # Don't move away from this line.
2992                     $incr = -1;
2993
2994                     # Search inside the eval to prevent pattern badness
2995                     # from killing us.
2996                     eval '
2997                         for (;;) {
2998                             # Back up a line.
2999                             --$start;
3000
3001                             # Wrap if we pass the first line.
3002
3003                             $start = $max if ($start <= 0);
3004
3005                             # Quit if we get back where we started,
3006                             last if ($start == $end);
3007
3008                             # Match?
3009                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
3010                                 if ($slave_editor) {
3011                                     # Yep, follow slave editor requirements.
3012                                     print $OUT "\032\032$filename:$start:0\n";
3013                                 }
3014                                 else {
3015                                     # Yep, just print normally.
3016                                     print $OUT "$start:\t",$dbline[$start],"\n";
3017                                 }
3018
3019                                 # Found, so done.
3020                                 last;
3021                             }
3022                         } ';
3023
3024                     # Say we failed if the loop never found anything,
3025                     print $OUT "?$pat?: not found\n" if ( $start == $end );
3026                     next CMD;
3027                 };
3028
3029 =head4 C<$rc> - Recall command
3030
3031 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3032 that the terminal supports history). It find the the command required, puts it
3033 into C<$cmd>, and redoes the loop to execute it.
3034
3035 =cut
3036
3037                 # $rc - recall command.
3038                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3039
3040                     # No arguments, take one thing off history.
3041                     pop(@hist) if length($cmd) > 1;
3042
3043                     # Relative (- found)?
3044                     #  Y - index back from most recent (by 1 if bare minus)
3045                     #  N - go to that particular command slot or the last
3046                     #      thing if nothing following.
3047                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3048
3049                     # Pick out the command desired.
3050                     $cmd = $hist[$i];
3051
3052                     # Print the command to be executed and restart the loop
3053                     # with that command in the buffer.
3054                     print $OUT $cmd, "\n";
3055                     redo CMD;
3056                 };
3057
3058 =head4 C<$sh$sh> - C<system()> command
3059
3060 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3061 C<STDOUT> from getting messed up.
3062
3063 =cut
3064
3065                 # $sh$sh - run a shell command (if it's all ASCII).
3066                 # Can't run shell commands with Unicode in the debugger, hmm.
3067                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3068
3069                     # System it.
3070                     &system($1);
3071                     next CMD;
3072                 };
3073
3074 =head4 C<$rc I<pattern> $rc> - Search command history
3075
3076 Another command to manipulate C<@hist>: this one searches it with a pattern.
3077 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3078
3079 =cut
3080
3081                 # $rc pattern $rc - find a command in the history.
3082                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3083
3084                     # Create the pattern to use.
3085                     $pat = "^$1";
3086
3087                     # Toss off last entry if length is >1 (and it always is).
3088                     pop(@hist) if length($cmd) > 1;
3089
3090                     # Look backward through the history.
3091                     for ( $i = $#hist ; $i ; --$i ) {
3092
3093                         # Stop if we find it.
3094                         last if $hist[$i] =~ /$pat/;
3095                     }
3096
3097                     if ( !$i ) {
3098
3099                         # Never found it.
3100                         print $OUT "No such command!\n\n";
3101                         next CMD;
3102                     }
3103
3104                     # Found it. Put it in the buffer, print it, and process it.
3105                     $cmd = $hist[$i];
3106                     print $OUT $cmd, "\n";
3107                     redo CMD;
3108                 };
3109
3110 =head4 C<$sh> - Invoke a shell
3111
3112 Uses C<DB::system> to invoke a shell.
3113
3114 =cut
3115
3116                 # $sh - start a shell.
3117                 $cmd =~ /^$sh$/ && do {
3118
3119                     # Run the user's shell. If none defined, run Bourne.
3120                     # We resume execution when the shell terminates.
3121                     &system( $ENV{SHELL} || "/bin/sh" );
3122                     next CMD;
3123                 };
3124
3125 =head4 C<$sh I<command>> - Force execution of a command in a shell
3126
3127 Like the above, but the command is passed to the shell. Again, we use
3128 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3129
3130 =cut
3131
3132                 # $sh command - start a shell and run a command in it.
3133                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3134
3135                     # XXX: using csh or tcsh destroys sigint retvals!
3136                     #&system($1);  # use this instead
3137
3138                     # use the user's shell, or Bourne if none defined.
3139                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3140                     next CMD;
3141                 };
3142
3143 =head4 C<H> - display commands in history
3144
3145 Prints the contents of C<@hist> (if any).
3146
3147 =cut
3148
3149                 $cmd =~ /^H\b\s*\*/ && do {
3150                     @hist = @truehist = ();
3151                     print $OUT "History cleansed\n";
3152                     next CMD;
3153                 };
3154
3155                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3156
3157                     # Anything other than negative numbers is ignored by
3158                     # the (incorrect) pattern, so this test does nothing.
3159                     $end = $2 ? ( $#hist - $2 ) : 0;
3160
3161                     # Set to the minimum if less than zero.
3162                     $hist = 0 if $hist < 0;
3163
3164                     # Start at the end of the array.
3165                     # Stay in while we're still above the ending value.
3166                     # Tick back by one each time around the loop.
3167                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3168
3169                         # Print the command  unless it has no arguments.
3170                         print $OUT "$i: ", $hist[$i], "\n"
3171                           unless $hist[$i] =~ /^.?$/;
3172                     }
3173                     next CMD;
3174                 };
3175
3176 =head4 C<man, doc, perldoc> - look up documentation
3177
3178 Just calls C<runman()> to print the appropriate document.
3179
3180 =cut
3181
3182                 # man, perldoc, doc - show manual pages.
3183                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3184                     runman($1);
3185                     next CMD;
3186                 };
3187
3188 =head4 C<p> - print
3189
3190 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3191 the bottom of the loop.
3192
3193 =cut
3194
3195                 # p - print (no args): print $_.
3196                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3197
3198                 # p - print the given expression.
3199                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3200
3201 =head4 C<=> - define command alias
3202
3203 Manipulates C<%alias> to add or list command aliases.
3204
3205 =cut
3206
3207                 # = - set up a command alias.
3208                 $cmd =~ s/^=\s*// && do {
3209                     my @keys;
3210                     if ( length $cmd == 0 ) {
3211
3212                         # No args, get current aliases.
3213                         @keys = sort keys %alias;
3214                     }
3215                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3216
3217                         # Creating a new alias. $k is alias name, $v is
3218                         # alias value.
3219
3220                         # can't use $_ or kill //g state
3221                         for my $x ( $k, $v ) {
3222
3223                             # Escape "alarm" characters.
3224                             $x =~ s/\a/\\a/g;
3225                         }
3226
3227                         # Substitute key for value, using alarm chars
3228                         # as separators (which is why we escaped them in
3229                         # the command).
3230                         $alias{$k} = "s\a$k\a$v\a";
3231
3232                         # Turn off standard warn and die behavior.
3233                         local $SIG{__DIE__};
3234                         local $SIG{__WARN__};
3235
3236                         # Is it valid Perl?
3237                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3238
3239                             # Nope. Bad alias. Say so and get out.
3240                             print $OUT "Can't alias $k to $v: $@\n";
3241                             delete $alias{$k};
3242                             next CMD;
3243                         }
3244
3245                         # We'll only list the new one.
3246                         @keys = ($k);
3247                     } ## end elsif (my ($k, $v) = ($cmd...
3248
3249                     # The argument is the alias to list.
3250                     else {
3251                         @keys = ($cmd);
3252                     }
3253
3254                     # List aliases.
3255                     for my $k (@keys) {
3256
3257                         # Messy metaquoting: Trim the substitution code off.
3258                         # We use control-G as the delimiter because it's not
3259                         # likely to appear in the alias.
3260                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3261
3262                             # Print the alias.
3263                             print $OUT "$k\t= $1\n";
3264                         }
3265                         elsif ( defined $alias{$k} ) {
3266
3267                             # Couldn't trim it off; just print the alias code.
3268                             print $OUT "$k\t$alias{$k}\n";
3269                         }
3270                         else {
3271
3272                             # No such, dude.
3273                             print "No alias for $k\n";
3274                         }
3275                     } ## end for my $k (@keys)
3276                     next CMD;
3277                 };
3278
3279 =head4 C<source> - read commands from a file.
3280
3281 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3282 pick it up.
3283
3284 =cut
3285
3286                 # source - read commands from a file (or pipe!) and execute.
3287                 $cmd =~ /^source\s+(.*\S)/ && do {
3288                     if ( open my $fh, $1 ) {
3289
3290                         # Opened OK; stick it in the list of file handles.
3291                         push @cmdfhs, $fh;
3292                     }
3293                     else {
3294
3295                         # Couldn't open it.
3296                         &warn("Can't execute '$1': $!\n");
3297                     }
3298                     next CMD;
3299                 };
3300
3301                 $cmd =~ /^(enable|disable)\s+(\S+)\s*$/ && do {
3302                     my ($cmd, $position) = ($1, $2);
3303
3304                     my ($fn, $line_num);
3305                     if ($position =~ m{\A\d+\z})
3306                     {
3307                         $fn = $filename;
3308                         $line_num = $position;
3309                     }
3310                     elsif ($position =~ m{\A(.*):(\d+)\z})
3311                     {
3312                         ($fn, $line_num) = ($1, $2);
3313                     }
3314                     else
3315                     {
3316                         &warn("Wrong spec for enable/disable argument.\n");
3317                     }
3318
3319                     if (defined($fn)) {
3320                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3321                             _set_breakpoint_enabled_status($fn, $line_num,
3322                                 ($cmd eq 'enable' ? 1 : '')
3323                             );
3324                         }
3325                         else {
3326                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3327                         }
3328                     }
3329
3330                     next CMD;
3331                 };
3332
3333 =head4 C<save> - send current history to a file
3334
3335 Takes the complete history, (not the shrunken version you see with C<H>),
3336 and saves it to the given filename, so it can be replayed using C<source>.
3337
3338 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3339
3340 =cut
3341
3342                 # save source - write commands to a file for later use
3343                 $cmd =~ /^save\s*(.*)$/ && do {
3344                     my $file = $1 || '.perl5dbrc';    # default?
3345                     if ( open my $fh, "> $file" ) {
3346
3347                        # chomp to remove extraneous newlines from source'd files
3348                         chomp( my @truelist =
3349                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3350                               @truehist );
3351                         print $fh join( "\n", @truelist );
3352                         print "commands saved in $file\n";
3353                     }
3354                     else {
3355                         &warn("Can't save debugger commands in '$1': $!\n");
3356                     }
3357                     next CMD;
3358                 };
3359
3360 =head4 C<R> - restart
3361
3362 Restart the debugger session.
3363
3364 =head4 C<rerun> - rerun the current session
3365
3366 Return to any given position in the B<true>-history list
3367
3368 =cut
3369
3370                 # R - restart execution.
3371                 # rerun - controlled restart execution.
3372                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3373                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3374
3375                     # Close all non-system fds for a clean restart.  A more
3376                     # correct method would be to close all fds that were not
3377                     # open when the process started, but this seems to be
3378                     # hard.  See "debugger 'R'estart and open database
3379                     # connections" on p5p.
3380
3381                     my $max_fd = 1024; # default if POSIX can't be loaded
3382                     if (eval { require POSIX }) {
3383                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3384                     }
3385
3386                     if (defined $max_fd) {
3387                         foreach ($^F+1 .. $max_fd-1) {
3388                             next unless open FD_TO_CLOSE, "<&=$_";
3389                             close(FD_TO_CLOSE);
3390                         }
3391                     }
3392
3393                     # And run Perl again.  We use exec() to keep the
3394                     # PID stable (and that way $ini_pids is still valid).
3395                     exec(@args) || print $OUT "exec failed: $!\n";
3396
3397                     last CMD;
3398                 };
3399
3400 =head4 C<|, ||> - pipe output through the pager.
3401
3402 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3403 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3404 pipe to the pager (restoring the output filehandles if this fails). If this
3405 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3406 set C<$signal>, sending us back into the debugger.
3407
3408 We then trim off the pipe symbols and C<redo> the command loop at the
3409 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3410 reading another.
3411
3412 =cut
3413
3414                 # || - run command in the pager, with output to DB::OUT.
3415                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3416                     if ( $pager =~ /^\|/ ) {
3417
3418                         # Default pager is into a pipe. Redirect I/O.
3419                         open( SAVEOUT, ">&STDOUT" )
3420                           || &warn("Can't save STDOUT");
3421                         open( STDOUT, ">&OUT" )
3422                           || &warn("Can't redirect STDOUT");
3423                     } ## end if ($pager =~ /^\|/)
3424                     else {
3425
3426                         # Not into a pipe. STDOUT is safe.
3427                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3428                     }
3429
3430                     # Fix up environment to record we have less if so.
3431                     fix_less();
3432
3433                     unless ( $piped = open( OUT, $pager ) ) {
3434
3435                         # Couldn't open pipe to pager.
3436                         &warn("Can't pipe output to '$pager'");
3437                         if ( $pager =~ /^\|/ ) {
3438
3439                             # Redirect I/O back again.
3440                             open( OUT, ">&STDOUT" )    # XXX: lost message
3441                               || &warn("Can't restore DB::OUT");
3442                             open( STDOUT, ">&SAVEOUT" )
3443                               || &warn("Can't restore STDOUT");
3444                             close(SAVEOUT);
3445                         } ## end if ($pager =~ /^\|/)
3446                         else {
3447
3448                             # Redirect I/O. STDOUT already safe.
3449                             open( OUT, ">&STDOUT" )    # XXX: lost message
3450                               || &warn("Can't restore DB::OUT");
3451                         }
3452                         next CMD;
3453                     } ## end unless ($piped = open(OUT,...
3454
3455                     # Set up broken-pipe handler if necessary.
3456                     $SIG{PIPE} = \&DB::catch
3457                       if $pager =~ /^\|/
3458                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3459
3460                     # Save current filehandle, unbuffer out, and put it back.
3461                     $selected = select(OUT);
3462                     $|        = 1;
3463
3464                     # Don't put it back if pager was a pipe.
3465                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3466
3467                     # Trim off the pipe symbols and run the command now.
3468                     $cmd =~ s/^\|+\s*//;
3469                     redo PIPE;
3470                 };
3471
3472 =head3 END OF COMMAND PARSING
3473
3474 Anything left in C<$cmd> at this point is a Perl expression that we want to
3475 evaluate. We'll always evaluate in the user's context, and fully qualify
3476 any variables we might want to address in the C<DB> package.
3477
3478 =cut
3479
3480                 # t - turn trace on.
3481                 $cmd =~ s/^t\s+(\d+)?/\$DB::trace |= 1;\n/ && do {
3482                     $trace_to_depth = $1 ? $stack_depth||0 + $1 : 1E9;
3483                 };
3484
3485                 # s - single-step. Remember the last command was 's'.
3486                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3487
3488                 # n - single-step, but not into subs. Remember last command
3489                 # was 'n'.
3490                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3491
3492             }    # PIPE:
3493
3494             # Make sure the flag that says "the debugger's running" is
3495             # still on, to make sure we get control again.
3496             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3497
3498             # Run *our* eval that executes in the caller's context.
3499             &eval;
3500
3501             # Turn off the one-time-dump stuff now.
3502             if ($onetimeDump) {
3503                 $onetimeDump      = undef;
3504                 $onetimedumpDepth = undef;
3505             }
3506             elsif ( $term_pid == $$ ) {
3507                 eval {          # May run under miniperl, when not available...
3508                     STDOUT->flush();
3509                     STDERR->flush();
3510                 };
3511
3512                 # XXX If this is the master pid, print a newline.
3513                 print $OUT "\n";
3514             }
3515         } ## end while (($term || &setterm...
3516
3517 =head3 POST-COMMAND PROCESSING
3518
3519 After each command, we check to see if the command output was piped anywhere.
3520 If so, we go through the necessary code to unhook the pipe and go back to
3521 our standard filehandles for input and output.
3522
3523 =cut
3524
3525         continue {    # CMD:
3526
3527             # At the end of every command:
3528             if ($piped) {
3529
3530                 # Unhook the pipe mechanism now.
3531                 if ( $pager =~ /^\|/ ) {
3532
3533                     # No error from the child.
3534                     $? = 0;
3535
3536                     # we cannot warn here: the handle is missing --tchrist
3537                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3538
3539                     # most of the $? crud was coping with broken cshisms
3540                     # $? is explicitly set to 0, so this never runs.
3541                     if ($?) {
3542                         print SAVEOUT "Pager '$pager' failed: ";
3543                         if ( $? == -1 ) {
3544                             print SAVEOUT "shell returned -1\n";
3545                         }
3546                         elsif ( $? >> 8 ) {
3547                             print SAVEOUT ( $? & 127 )
3548                               ? " (SIG#" . ( $? & 127 ) . ")"
3549                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3550                         }
3551                         else {
3552                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3553                         }
3554                     } ## end if ($?)
3555
3556                     # Reopen filehandle for our output (if we can) and
3557                     # restore STDOUT (if we can).
3558                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3559                     open( STDOUT, ">&SAVEOUT" )
3560                       || &warn("Can't restore STDOUT");
3561
3562                     # Turn off pipe exception handler if necessary.
3563                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3564
3565                     # Will stop ignoring SIGPIPE if done like nohup(1)
3566                     # does SIGINT but Perl doesn't give us a choice.
3567                 } ## end if ($pager =~ /^\|/)
3568                 else {
3569
3570                     # Non-piped "pager". Just restore STDOUT.
3571                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3572                 }
3573
3574                 # Close filehandle pager was using, restore the normal one
3575                 # if necessary,
3576                 close(SAVEOUT);
3577                 select($selected), $selected = "" unless $selected eq "";
3578
3579                 # No pipes now.
3580                 $piped = "";
3581             } ## end if ($piped)
3582         }    # CMD:
3583
3584 =head3 COMMAND LOOP TERMINATION
3585
3586 When commands have finished executing, we come here. If the user closed the
3587 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3588 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3589 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3590 The interpreter will then execute the next line and then return control to us
3591 again.
3592
3593 =cut
3594
3595         # No more commands? Quit.
3596         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3597
3598         # Evaluate post-prompt commands.
3599         foreach $evalarg (@$post) {
3600             &eval;
3601         }
3602     }    # if ($single || $signal)
3603
3604     # Put the user's globals back where you found them.
3605     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3606     ();
3607 } ## end sub DB
3608
3609 # The following code may be executed now:
3610 # BEGIN {warn 4}
3611
3612 =head2 sub
3613
3614 C<sub> is called whenever a subroutine call happens in the program being
3615 debugged. The variable C<$DB::sub> contains the name of the subroutine
3616 being called.
3617
3618 The core function of this subroutine is to actually call the sub in the proper
3619 context, capturing its output. This of course causes C<DB::DB> to get called
3620 again, repeating until the subroutine ends and returns control to C<DB::sub>
3621 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3622 return value, and returns its captured copy of the return value as its own
3623 return value. The value then feeds back into the program being debugged as if
3624 C<DB::sub> hadn't been there at all.
3625
3626 C<sub> does all the work of printing the subroutine entry and exit messages
3627 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3628 and also prints the return value if needed (for the C<r> command and if
3629 the 16 bit is set in C<$frame>).
3630
3631 It also tracks the subroutine call depth by saving the current setting of
3632 C<$single> in the C<@stack> package global; if this exceeds the value in
3633 C<$deep>, C<sub> automatically turns on printing of the current depth by
3634 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3635 of stop/don't stop on entry to subs set as it currently is set.
3636
3637 =head3 C<caller()> support
3638
3639 If C<caller()> is called from the package C<DB>, it provides some
3640 additional data, in the following order:
3641
3642 =over 4
3643
3644 =item * C<$package>
3645
3646 The package name the sub was in
3647
3648 =item * C<$filename>
3649
3650 The filename it was defined in
3651
3652 =item * C<$line>
3653
3654 The line number it was defined on
3655
3656 =item * C<$subroutine>
3657
3658 The subroutine name; C<(eval)> if an C<eval>().
3659
3660 =item * C<$hasargs>
3661
3662 1 if it has arguments, 0 if not
3663
3664 =item * C<$wantarray>
3665
3666 1 if array context, 0 if scalar context
3667
3668 =item * C<$evaltext>
3669
3670 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3671
3672 =item * C<$is_require>
3673
3674 frame was created by a C<use> or C<require> statement
3675
3676 =item * C<$hints>
3677
3678 pragma information; subject to change between versions
3679
3680 =item * C<$bitmask>
3681
3682 pragma information; subject to change between versions
3683
3684 =item * C<@DB::args>
3685
3686 arguments with which the subroutine was invoked
3687
3688 =back
3689
3690 =cut
3691
3692 sub sub {
3693         # Do not use a regex in this subroutine -> results in corrupted memory
3694         # See: [perl #66110]
3695
3696         # lock ourselves under threads
3697         lock($DBGR);
3698
3699     # Whether or not the autoloader was running, a scalar to put the
3700     # sub's return value in (if needed), and an array to put the sub's
3701     # return value in (if needed).
3702     my ( $al, $ret, @ret ) = "";
3703         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3704                 print "creating new thread\n";
3705         }
3706
3707     # If the last ten characters are '::AUTOLOAD', note we've traced
3708     # into AUTOLOAD for $sub.
3709     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3710         $al = " for $$sub" if defined $$sub;
3711     }
3712
3713     # We stack the stack pointer and then increment it to protect us
3714     # from a situation that might unwind a whole bunch of call frames
3715     # at once. Localizing the stack pointer means that it will automatically
3716     # unwind the same amount when multiple stack frames are unwound.
3717     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3718
3719     # Expand @stack.
3720     $#stack = $stack_depth;
3721
3722     # Save current single-step setting.
3723     $stack[-1] = $single;
3724
3725     # Turn off all flags except single-stepping.
3726     $single &= 1;
3727
3728     # If we've gotten really deeply recursed, turn on the flag that will
3729     # make us stop with the 'deep recursion' message.
3730     $single |= 4 if $stack_depth == $deep;
3731
3732     # If frame messages are on ...
3733     (
3734         $frame & 4    # Extended frame entry message
3735         ? (
3736             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3737
3738             # Why -1? But it works! :-(
3739             # Because print_trace will call add 1 to it and then call
3740             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3741             # in dump_trace.
3742             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3743           )
3744         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3745
3746           # standard frame entry message
3747       )
3748       if $frame;
3749
3750     # Determine the sub's return type, and capture appropriately.
3751     if (wantarray) {
3752
3753         # Called in array context. call sub and capture output.
3754         # DB::DB will recursively get control again if appropriate; we'll come
3755         # back here when the sub is finished.
3756         @ret = &$sub;
3757
3758         # Pop the single-step value back off the stack.
3759         $single |= $stack[ $stack_depth-- ];
3760
3761         # Check for exit trace messages...
3762         (
3763             $frame & 4    # Extended exit message
3764             ? (
3765                 print_lineinfo( ' ' x $stack_depth, "out " ),
3766                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3767               )
3768             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3769
3770               # Standard exit message
3771           )
3772           if $frame & 2;
3773
3774         # Print the return info if we need to.
3775         if ( $doret eq $stack_depth or $frame & 16 ) {
3776
3777             # Turn off output record separator.
3778             local $\ = '';
3779             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3780
3781             # Indent if we're printing because of $frame tracing.
3782             print $fh ' ' x $stack_depth if $frame & 16;
3783
3784             # Print the return value.
3785             print $fh "list context return from $sub:\n";
3786             dumpit( $fh, \@ret );
3787
3788             # And don't print it again.
3789             $doret = -2;
3790         } ## end if ($doret eq $stack_depth...
3791             # And we have to return the return value now.
3792         @ret;
3793     } ## end if (wantarray)
3794
3795     # Scalar context.
3796     else {
3797         if ( defined wantarray ) {
3798
3799             # Save the value if it's wanted at all.
3800             $ret = &$sub;
3801         }
3802         else {
3803
3804             # Void return, explicitly.
3805             &$sub;
3806             undef $ret;
3807         }
3808
3809         # Pop the single-step value off the stack.
3810         $single |= $stack[ $stack_depth-- ];
3811
3812         # If we're doing exit messages...
3813         (
3814             $frame & 4    # Extended messages
3815             ? (
3816                 print_lineinfo( ' ' x $stack_depth, "out " ),
3817                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3818               )
3819             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3820
3821               # Standard messages
3822           )
3823           if $frame & 2;
3824
3825         # If we are supposed to show the return value... same as before.
3826         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3827             local $\ = '';
3828             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3829             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3830             print $fh (
3831                 defined wantarray
3832                 ? "scalar context return from $sub: "
3833                 : "void context return from $sub\n"
3834             );
3835             dumpit( $fh, $ret ) if defined wantarray;
3836             $doret = -2;
3837         } ## end if ($doret eq $stack_depth...
3838
3839         # Return the appropriate scalar value.
3840         $ret;
3841     } ## end else [ if (wantarray)
3842 } ## end sub sub
3843
3844 sub lsub : lvalue {
3845
3846         # lock ourselves under threads
3847         lock($DBGR);
3848
3849     # Whether or not the autoloader was running, a scalar to put the
3850     # sub's return value in (if needed), and an array to put the sub's
3851     # return value in (if needed).
3852     my ( $al, $ret, @ret ) = "";
3853         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3854                 print "creating new thread\n";
3855         }
3856
3857     # If the last ten characters are C'::AUTOLOAD', note we've traced
3858     # into AUTOLOAD for $sub.
3859     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3860         $al = " for $$sub";
3861     }
3862
3863     # We stack the stack pointer and then increment it to protect us
3864     # from a situation that might unwind a whole bunch of call frames
3865     # at once. Localizing the stack pointer means that it will automatically
3866     # unwind the same amount when multiple stack frames are unwound.
3867     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3868
3869     # Expand @stack.
3870     $#stack = $stack_depth;
3871
3872     # Save current single-step setting.
3873     $stack[-1] = $single;
3874
3875     # Turn off all flags except single-stepping.
3876     $single &= 1;
3877
3878     # If we've gotten really deeply recursed, turn on the flag that will
3879     # make us stop with the 'deep recursion' message.
3880     $single |= 4 if $stack_depth == $deep;
3881
3882     # If frame messages are on ...
3883     (
3884         $frame & 4    # Extended frame entry message
3885         ? (
3886             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3887
3888             # Why -1? But it works! :-(
3889             # Because print_trace will call add 1 to it and then call
3890             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3891             # in dump_trace.
3892             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3893           )
3894         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3895
3896           # standard frame entry message
3897       )
3898       if $frame;
3899
3900     # Pop the single-step value back off the stack.
3901     $single |= $stack[ $stack_depth-- ];
3902
3903     # call the original lvalue sub.
3904     &$sub;
3905 }
3906
3907 # Abstracting common code from multiple places elsewhere:
3908 sub depth_print_lineinfo {
3909     print_lineinfo( @_ ) if $stack_depth < $trace_to_depth;
3910 }
3911
3912 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3913
3914 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3915 Most of the changes were to systematize the command structure and to eliminate
3916 commands that threw away user input without checking.
3917
3918 The following sections describe the code added to make it easy to support
3919 multiple command sets with conflicting command names. This section is a start
3920 at unifying all command processing to make it simpler to develop commands.
3921
3922 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3923 number, and C<$dbline> (the current line) as arguments.
3924
3925 Support functions in this section which have multiple modes of failure C<die>
3926 on error; the rest simply return a false value.
3927
3928 The user-interface functions (all of the C<cmd_*> functions) just output
3929 error messages.
3930
3931 =head2 C<%set>
3932
3933 The C<%set> hash defines the mapping from command letter to subroutine
3934 name suffix.
3935
3936 C<%set> is a two-level hash, indexed by set name and then by command name.
3937 Note that trying to set the CommandSet to C<foobar> simply results in the
3938 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3939
3940 =cut
3941
3942 ### The API section
3943
3944 my %set = (    #
3945     'pre580' => {
3946         'a' => 'pre580_a',
3947         'A' => 'pre580_null',
3948         'b' => 'pre580_b',
3949         'B' => 'pre580_null',
3950         'd' => 'pre580_null',
3951         'D' => 'pre580_D',
3952         'h' => 'pre580_h',
3953         'M' => 'pre580_null',
3954         'O' => 'o',
3955         'o' => 'pre580_null',
3956         'v' => 'M',
3957         'w' => 'v',
3958         'W' => 'pre580_W',
3959     },
3960     'pre590' => {
3961         '<'  => 'pre590_prepost',
3962         '<<' => 'pre590_prepost',
3963         '>'  => 'pre590_prepost',
3964         '>>' => 'pre590_prepost',
3965         '{'  => 'pre590_prepost',
3966         '{{' => 'pre590_prepost',
3967     },
3968 );
3969
3970 my %breakpoints_data;
3971
3972 sub _has_breakpoint_data_ref {
3973     my ($filename, $line) = @_;
3974
3975     return (
3976         exists( $breakpoints_data{$filename} )
3977             and
3978         exists( $breakpoints_data{$filename}{$line} )
3979     );
3980 }
3981
3982 sub _get_breakpoint_data_ref {
3983     my ($filename, $line) = @_;
3984
3985     return ($breakpoints_data{$filename}{$line} ||= +{});
3986 }
3987
3988 sub _delete_breakpoint_data_ref {
3989     my ($filename, $line) = @_;
3990
3991     delete($breakpoints_data{$filename}{$line});
3992     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3993         delete($breakpoints_data{$filename});
3994     }
3995
3996     return;
3997 }
3998
3999 sub _set_breakpoint_enabled_status {
4000     my ($filename, $line, $status) = @_;
4001
4002     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4003         ($status ? 1 : '')
4004         ;
4005
4006     return;
4007 }
4008
4009 sub _enable_breakpoint_temp_enabled_status {
4010     my ($filename, $line) = @_;
4011
4012     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4013
4014     return;
4015 }
4016
4017 sub _cancel_breakpoint_temp_enabled_status {
4018     my ($filename, $line) = @_;
4019
4020     my $ref = _get_breakpoint_data_ref($filename, $line);
4021
4022     delete ($ref->{'temp_enabled'});
4023
4024     if (! %$ref) {
4025         _delete_breakpoint_data_ref($filename, $line);
4026     }
4027
4028     return;
4029 }
4030
4031 sub _is_breakpoint_enabled {
4032     my ($filename, $line) = @_;
4033
4034     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4035     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4036 }
4037
4038 =head2 C<cmd_wrapper()> (API)
4039
4040 C<cmd_wrapper()> allows the debugger to switch command sets
4041 depending on the value of the C<CommandSet> option.
4042
4043 It tries to look up the command in the C<%set> package-level I<lexical>
4044 (which means external entities can't fiddle with it) and create the name of
4045 the sub to call based on the value found in the hash (if it's there). I<All>
4046 of the commands to be handled in a set have to be added to C<%set>; if they
4047 aren't found, the 5.8.0 equivalent is called (if there is one).
4048
4049 This code uses symbolic references.
4050
4051 =cut
4052
4053 sub cmd_wrapper {
4054     my $cmd      = shift;
4055     my $line     = shift;
4056     my $dblineno = shift;
4057
4058     # Assemble the command subroutine's name by looking up the
4059     # command set and command name in %set. If we can't find it,
4060     # default to the older version of the command.
4061     my $call = 'cmd_'
4062       . ( $set{$CommandSet}{$cmd}
4063           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4064
4065     # Call the command subroutine, call it by name.
4066     return &$call( $cmd, $line, $dblineno );
4067 } ## end sub cmd_wrapper
4068
4069 =head3 C<cmd_a> (command)
4070
4071 The C<a> command handles pre-execution actions. These are associated with a
4072 particular line, so they're stored in C<%dbline>. We default to the current
4073 line if none is specified.
4074
4075 =cut
4076
4077 sub cmd_a {
4078     my $cmd    = shift;
4079     my $line   = shift || '';    # [.|line] expr
4080     my $dbline = shift;
4081
4082     # If it's dot (here), or not all digits,  use the current line.
4083     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4084
4085     # Should be a line number followed by an expression.
4086     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4087         my ( $lineno, $expr ) = ( $1, $2 );
4088
4089         # If we have an expression ...
4090         if ( length $expr ) {
4091
4092             # ... but the line isn't breakable, complain.
4093             if ( $dbline[$lineno] == 0 ) {
4094                 print $OUT
4095                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4096             }
4097             else {
4098
4099                 # It's executable. Record that the line has an action.
4100                 $had_breakpoints{$filename} |= 2;
4101
4102                 # Remove any action, temp breakpoint, etc.
4103                 $dbline{$lineno} =~ s/\0[^\0]*//;
4104
4105                 # Add the action to the line.
4106                 $dbline{$lineno} .= "\0" . action($expr);
4107             }
4108         } ## end if (length $expr)
4109     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4110     else {
4111
4112         # Syntax wrong.
4113         print $OUT
4114           "Adding an action requires an optional lineno and an expression\n"
4115           ;    # hint
4116     }
4117 } ## end sub cmd_a
4118
4119 =head3 C<cmd_A> (command)
4120
4121 Delete actions. Similar to above, except the delete code is in a separate
4122 subroutine, C<delete_action>.
4123
4124 =cut
4125
4126 sub cmd_A {
4127     my $cmd    = shift;
4128     my $line   = shift || '';
4129     my $dbline = shift;
4130
4131     # Dot is this line.
4132     $line =~ s/^\./$dbline/;
4133
4134     # Call delete_action with a null param to delete them all.
4135     # The '1' forces the eval to be true. It'll be false only
4136     # if delete_action blows up for some reason, in which case
4137     # we print $@ and get out.
4138     if ( $line eq '*' ) {
4139         eval { &delete_action(); 1 } or print $OUT $@ and return;
4140     }
4141
4142     # There's a real line  number. Pass it to delete_action.
4143     # Error trapping is as above.
4144     elsif ( $line =~ /^(\S.*)/ ) {
4145         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4146     }
4147
4148     # Swing and a miss. Bad syntax.
4149     else {
4150         print $OUT
4151           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4152     }
4153 } ## end sub cmd_A
4154
4155 =head3 C<delete_action> (API)
4156
4157 C<delete_action> accepts either a line number or C<undef>. If a line number
4158 is specified, we check for the line being executable (if it's not, it
4159 couldn't have had an  action). If it is, we just take the action off (this
4160 will get any kind of an action, including breakpoints).
4161
4162 =cut
4163
4164 sub delete_action {
4165     my $i = shift;
4166     if ( defined($i) ) {
4167
4168         # Can there be one?
4169         die "Line $i has no action .\n" if $dbline[$i] == 0;
4170
4171         # Nuke whatever's there.
4172         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4173         delete $dbline{$i} if $dbline{$i} eq '';
4174     }
4175     else {
4176         print $OUT "Deleting all actions...\n";
4177         for my $file ( keys %had_breakpoints ) {
4178             local *dbline = $main::{ '_<' . $file };
4179             my $max = $#dbline;
4180             my $was;
4181             for ( $i = 1 ; $i <= $max ; $i++ ) {
4182                 if ( defined $dbline{$i} ) {
4183                     $dbline{$i} =~ s/\0[^\0]*//;
4184                     delete $dbline{$i} if $dbline{$i} eq '';
4185                 }
4186                 unless ( $had_breakpoints{$file} &= ~2 ) {
4187                     delete $had_breakpoints{$file};
4188                 }
4189             } ## end for ($i = 1 ; $i <= $max...
4190         } ## end for my $file (keys %had_breakpoints)
4191     } ## end else [ if (defined($i))
4192 } ## end sub delete_action
4193
4194 =head3 C<cmd_b> (command)
4195
4196 Set breakpoints. Since breakpoints can be set in so many places, in so many
4197 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4198 we try to parse the command type, and then shuttle it off to an appropriate
4199 subroutine to actually do the work of setting the breakpoint in the right
4200 place.
4201
4202 =cut
4203
4204 sub cmd_b {
4205     my $cmd    = shift;
4206     my $line   = shift;    # [.|line] [cond]
4207     my $dbline = shift;
4208
4209     # Make . the current line number if it's there..
4210     $line =~ s/^\.\b/$dbline/;
4211
4212     # No line number, no condition. Simple break on current line.
4213     if ( $line =~ /^\s*$/ ) {
4214         &cmd_b_line( $dbline, 1 );
4215     }
4216
4217     # Break on load for a file.
4218     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4219         my $file = $1;
4220         $file =~ s/\s+$//;
4221         &cmd_b_load($file);
4222     }
4223
4224     # b compile|postpone <some sub> [<condition>]
4225     # The interpreter actually traps this one for us; we just put the
4226     # necessary condition in the %postponed hash.
4227     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4228
4229         # Capture the condition if there is one. Make it true if none.
4230         my $cond = length $3 ? $3 : '1';
4231
4232         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4233         # if it was 'compile'.
4234         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4235
4236         # De-Perl4-ify the name - ' separators to ::.
4237         $subname =~ s/\'/::/g;
4238
4239         # Qualify it into the current package unless it's already qualified.
4240         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4241
4242         # Add main if it starts with ::.
4243         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4244
4245         # Save the break type for this sub.
4246         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4247     } ## end elsif ($line =~ ...
4248     # b <filename>:<line> [<condition>]
4249     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4250         my ($filename, $line_num, $cond) = ($1, $2, $3);
4251         cmd_b_filename_line(
4252             $filename,
4253             $line_num,
4254             (length($cond) ? $cond : '1'),
4255         );
4256     }
4257     # b <sub name> [<condition>]
4258     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4259
4260         #
4261         $subname = $1;
4262         $cond = length $2 ? $2 : '1';
4263         &cmd_b_sub( $subname, $cond );
4264     }
4265
4266     # b <line> [<condition>].
4267     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4268
4269         # Capture the line. If none, it's the current line.
4270         $line = $1 || $dbline;
4271
4272         # If there's no condition, make it '1'.
4273         $cond = length $2 ? $2 : '1';
4274
4275         # Break on line.
4276         &cmd_b_line( $line, $cond );
4277     }
4278
4279     # Line didn't make sense.
4280     else {
4281         print "confused by line($line)?\n";
4282     }
4283 } ## end sub cmd_b
4284
4285 =head3 C<break_on_load> (API)
4286
4287 We want to break when this file is loaded. Mark this file in the
4288 C<%break_on_load> hash, and note that it has a breakpoint in
4289 C<%had_breakpoints>.
4290
4291 =cut
4292
4293 sub break_on_load {
4294     my $file = shift;
4295     $break_on_load{$file} = 1;
4296     $had_breakpoints{$file} |= 1;
4297 }
4298
4299 =head3 C<report_break_on_load> (API)
4300
4301 Gives us an array of filenames that are set to break on load. Note that
4302 only files with break-on-load are in here, so simply showing the keys
4303 suffices.
4304
4305 =cut
4306
4307 sub report_break_on_load {
4308     sort keys %break_on_load;
4309 }
4310
4311 =head3 C<cmd_b_load> (command)
4312
4313 We take the file passed in and try to find it in C<%INC> (which maps modules
4314 to files they came from). We mark those files for break-on-load via
4315 C<break_on_load> and then report that it was done.
4316
4317 =cut
4318
4319 sub cmd_b_load {
4320     my $file = shift;
4321     my @files;
4322
4323     # This is a block because that way we can use a redo inside it
4324     # even without there being any looping structure at all outside it.
4325     {
4326
4327         # Save short name and full path if found.
4328         push @files, $file;
4329         push @files, $::INC{$file} if $::INC{$file};
4330
4331         # Tack on .pm and do it again unless there was a '.' in the name
4332         # already.
4333         $file .= '.pm', redo unless $file =~ /\./;
4334     }
4335
4336     # Do the real work here.
4337     break_on_load($_) for @files;
4338
4339     # All the files that have break-on-load breakpoints.
4340     @files = report_break_on_load;
4341
4342     # Normalize for the purposes of our printing this.
4343     local $\ = '';
4344     local $" = ' ';
4345     print $OUT "Will stop on load of '@files'.\n";
4346 } ## end sub cmd_b_load
4347
4348 =head3 C<$filename_error> (API package global)
4349
4350 Several of the functions we need to implement in the API need to work both
4351 on the current file and on other files. We don't want to duplicate code, so
4352 C<$filename_error> is used to contain the name of the file that's being
4353 worked on (if it's not the current one).
4354
4355 We can now build functions in pairs: the basic function works on the current
4356 file, and uses C<$filename_error> as part of its error message. Since this is
4357 initialized to C<"">, no filename will appear when we are working on the
4358 current file.
4359
4360 The second function is a wrapper which does the following:
4361
4362 =over 4
4363
4364 =item *
4365
4366 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4367
4368 =item *
4369
4370 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4371
4372 =item *
4373
4374 Calls the first function.
4375
4376 The first function works on the I<current> file (i.e., the one we changed to),
4377 and prints C<$filename_error> in the error message (the name of the other file)
4378 if it needs to. When the functions return, C<*dbline> is restored to point
4379 to the actual current file (the one we're executing in) and
4380 C<$filename_error> is restored to C<"">. This restores everything to
4381 the way it was before the second function was called at all.
4382
4383 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4384 details.
4385
4386 =back
4387
4388 =cut
4389
4390 $filename_error = '';
4391
4392 =head3 breakable_line(from, to) (API)
4393
4394 The subroutine decides whether or not a line in the current file is breakable.
4395 It walks through C<@dbline> within the range of lines specified, looking for
4396 the first line that is breakable.
4397
4398 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4399 first line I<after> C<$to> that's breakable, if there is one.
4400
4401 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4402 first line I<before> C<$to> that's breakable, if there is one.
4403
4404 =cut
4405
4406 sub breakable_line {
4407
4408     my ( $from, $to ) = @_;
4409
4410     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4411     my $i = $from;
4412
4413     # If there are at least 2 arguments, we're trying to search a range.
4414     if ( @_ >= 2 ) {
4415
4416         # $delta is positive for a forward search, negative for a backward one.
4417         my $delta = $from < $to ? +1 : -1;
4418
4419         # Keep us from running off the ends of the file.
4420         my $limit = $delta > 0 ? $#dbline : 1;
4421
4422         # Clever test. If you're a mathematician, it's obvious why this
4423         # test works. If not:
4424         # If $delta is positive (going forward), $limit will be $#dbline.
4425         #    If $to is less than $limit, ($limit - $to) will be positive, times
4426         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4427         #    as the stopping point.
4428         #
4429         #    If $to is greater than $limit, ($limit - $to) is negative,
4430         #    times $delta of 1 (positive), so the result is < 0 and we should
4431         #    use $limit ($#dbline) as the stopping point.
4432         #
4433         # If $delta is negative (going backward), $limit will be 1.
4434         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4435         #    (negative) so the result is > 0, and we use $to as the stopping
4436         #    point.
4437         #
4438         #    If $to is less than zero, ($limit - $to) will be positive,
4439         #    times $delta of -1 (negative), so the result is not > 0, and
4440         #    we use $limit (1) as the stopping point.
4441         #
4442         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4443         #    (negative), still giving zero; the result is not > 0, and
4444         #    we use $limit (1) as the stopping point.
4445         #
4446         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4447         #    (negative), giving a positive (>0) value, so we'll set $limit to
4448         #    $to.
4449
4450         $limit = $to if ( $limit - $to ) * $delta > 0;
4451
4452         # The real search loop.
4453         # $i starts at $from (the point we want to start searching from).
4454         # We move through @dbline in the appropriate direction (determined
4455         # by $delta: either -1 (back) or +1 (ahead).
4456         # We stay in as long as we haven't hit an executable line
4457         # ($dbline[$i] == 0 means not executable) and we haven't reached
4458         # the limit yet (test similar to the above).
4459         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4460
4461     } ## end if (@_ >= 2)
4462
4463     # If $i points to a line that is executable, return that.
4464     return $i unless $dbline[$i] == 0;
4465
4466     # Format the message and print it: no breakable lines in range.
4467     my ( $pl, $upto ) = ( '', '' );
4468     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4469
4470     # If there's a filename in filename_error, we'll see it.
4471     # If not, not.
4472     die "Line$pl $from$upto$filename_error not breakable\n";
4473 } ## end sub breakable_line
4474
4475 =head3 breakable_line_in_filename(file, from, to) (API)
4476
4477 Like C<breakable_line>, but look in another file.
4478
4479 =cut
4480
4481 sub breakable_line_in_filename {
4482
4483     # Capture the file name.
4484     my ($f) = shift;
4485
4486     # Swap the magic line array over there temporarily.
4487     local *dbline = $main::{ '_<' . $f };
4488
4489     # If there's an error, it's in this other file.
4490     local $filename_error = " of '$f'";
4491
4492     # Find the breakable line.
4493     breakable_line(@_);
4494
4495     # *dbline and $filename_error get restored when this block ends.
4496
4497 } ## end sub breakable_line_in_filename
4498
4499 =head3 break_on_line(lineno, [condition]) (API)
4500
4501 Adds a breakpoint with the specified condition (or 1 if no condition was
4502 specified) to the specified line. Dies if it can't.
4503
4504 =cut
4505
4506 sub break_on_line {
4507     my ( $i, $cond ) = @_;
4508
4509     # Always true if no condition supplied.
4510     $cond = 1 unless @_ >= 2;
4511
4512     my $inii  = $i;
4513     my $after = '';
4514     my $pl    = '';
4515
4516     # Woops, not a breakable line. $filename_error allows us to say
4517     # if it was in a different file.
4518     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4519
4520     # Mark this file as having breakpoints in it.
4521     $had_breakpoints{$filename} |= 1;
4522
4523     # If there is an action or condition here already ...
4524     if ( $dbline{$i} ) {
4525
4526         # ... swap this condition for the existing one.
4527         $dbline{$i} =~ s/^[^\0]*/$cond/;
4528     }
4529     else {
4530
4531         # Nothing here - just add the condition.
4532         $dbline{$i} = $cond;
4533
4534         _set_breakpoint_enabled_status($filename, $i, 1);
4535     }
4536 } ## end sub break_on_line
4537
4538 =head3 cmd_b_line(line, [condition]) (command)
4539
4540 Wrapper for C<break_on_line>. Prints the failure message if it
4541 doesn't work.
4542
4543 =cut
4544
4545 sub cmd_b_line {
4546     eval { break_on_line(@_); 1 } or do {
4547         local $\ = '';
4548         print $OUT $@ and return;
4549     };
4550 } ## end sub cmd_b_line
4551
4552 =head3 cmd_b_filename_line(line, [condition]) (command)
4553
4554 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4555 doesn't work.
4556
4557 =cut
4558
4559 sub cmd_b_filename_line {
4560     eval { break_on_filename_line(@_); 1 } or do {
4561         local $\ = '';
4562         print $OUT $@ and return;
4563     };
4564 }
4565
4566 =head3 break_on_filename_line(file, line, [condition]) (API)
4567
4568 Switches to the file specified and then calls C<break_on_line> to set
4569 the breakpoint.
4570
4571 =cut
4572
4573 sub break_on_filename_line {
4574     my ( $f, $i, $cond ) = @_;
4575
4576     # Always true if condition left off.
4577     $cond = 1 unless @_ >= 3;
4578
4579     # Switch the magical hash temporarily.
4580     local *dbline = $main::{ '_<' . $f };
4581
4582     # Localize the variables that break_on_line uses to make its message.
4583     local $filename_error = " of '$f'";
4584     local $filename       = $f;
4585
4586     # Add the breakpoint.
4587     break_on_line( $i, $cond );
4588 } ## end sub break_on_filename_line
4589
4590 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4591
4592 Switch to another file, search the range of lines specified for an
4593 executable one, and put a breakpoint on the first one you find.
4594
4595 =cut
4596
4597 sub break_on_filename_line_range {
4598     my ( $f, $from, $to, $cond ) = @_;
4599
4600     # Find a breakable line if there is one.
4601     my $i = breakable_line_in_filename( $f, $from, $to );
4602
4603     # Always true if missing.
4604     $cond = 1 unless @_ >= 3;
4605
4606     # Add the breakpoint.
4607     break_on_filename_line( $f, $i, $cond );
4608 } ## end sub break_on_filename_line_range
4609
4610 =head3 subroutine_filename_lines(subname, [condition]) (API)
4611
4612 Search for a subroutine within a given file. The condition is ignored.
4613 Uses C<find_sub> to locate the desired subroutine.
4614
4615 =cut
4616
4617 sub subroutine_filename_lines {
4618     my ( $subname, $cond ) = @_;
4619
4620     # Returned value from find_sub() is fullpathname:startline-endline.
4621     # The match creates the list (fullpathname, start, end). Falling off
4622     # the end of the subroutine returns this implicitly.
4623     find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/;
4624 } ## end sub subroutine_filename_lines
4625
4626 =head3 break_subroutine(subname) (API)
4627
4628 Places a break on the first line possible in the specified subroutine. Uses
4629 C<subroutine_filename_lines> to find the subroutine, and
4630 C<break_on_filename_line_range> to place the break.
4631
4632 =cut
4633
4634 sub break_subroutine {
4635     my $subname = shift;
4636
4637     # Get filename, start, and end.
4638     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4639       or die "Subroutine $subname not found.\n";
4640
4641     # Null condition changes to '1' (always true).
4642     $cond = 1 unless @_ >= 2;
4643
4644     # Put a break the first place possible in the range of lines
4645     # that make up this subroutine.
4646     break_on_filename_line_range( $file, $s, $e, @_ );
4647 } ## end sub break_subroutine
4648
4649 =head3 cmd_b_sub(subname, [condition]) (command)
4650
4651 We take the incoming subroutine name and fully-qualify it as best we can.
4652
4653 =over 4
4654
4655 =item 1. If it's already fully-qualified, leave it alone.
4656
4657 =item 2. Try putting it in the current package.
4658
4659 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4660
4661 =item 4. If it starts with '::', put it in 'main::'.
4662
4663 =back
4664
4665 After all this cleanup, we call C<break_subroutine> to try to set the
4666 breakpoint.
4667
4668 =cut
4669
4670 sub cmd_b_sub {
4671     my ( $subname, $cond ) = @_;
4672
4673     # Add always-true condition if we have none.
4674     $cond = 1 unless @_ >= 2;
4675
4676     # If the subname isn't a code reference, qualify it so that
4677     # break_subroutine() will work right.
4678     unless ( ref $subname eq 'CODE' ) {
4679
4680         # Not Perl4.
4681         $subname =~ s/\'/::/g;
4682         my $s = $subname;
4683
4684         # Put it in this package unless it's already qualified.
4685         $subname = "${'package'}::" . $subname
4686           unless $subname =~ /::/;
4687
4688         # Requalify it into CORE::GLOBAL if qualifying it into this
4689         # package resulted in its not being defined, but only do so
4690         # if it really is in CORE::GLOBAL.
4691         $subname = "CORE::GLOBAL::$s"
4692           if not defined &$subname
4693           and $s !~ /::/
4694           and defined &{"CORE::GLOBAL::$s"};
4695
4696         # Put it in package 'main' if it has a leading ::.
4697         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4698
4699     } ## end unless (ref $subname eq 'CODE')
4700
4701     # Try to set the breakpoint.
4702     eval { break_subroutine( $subname, $cond ); 1 } or do {
4703         local $\ = '';
4704         print $OUT $@ and return;
4705       }
4706 } ## end sub cmd_b_sub
4707
4708 =head3 C<cmd_B> - delete breakpoint(s) (command)
4709
4710 The command mostly parses the command line and tries to turn the argument
4711 into a line spec. If it can't, it uses the current line. It then calls
4712 C<delete_breakpoint> to actually do the work.
4713
4714 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4715 thereby deleting all the breakpoints.
4716
4717 =cut
4718
4719 sub cmd_B {
4720     my $cmd = shift;
4721
4722     # No line spec? Use dbline.
4723     # If there is one, use it if it's non-zero, or wipe it out if it is.
4724     my $line   = ( $_[0] =~ /^\./ ) ? $dbline : shift || '';
4725     my $dbline = shift;
4726
4727     # If the line was dot, make the line the current one.
4728     $line =~ s/^\./$dbline/;
4729
4730     # If it's * we're deleting all the breakpoints.
4731     if ( $line eq '*' ) {
4732         eval { &delete_breakpoint(); 1 } or print $OUT $@ and return;
4733     }
4734
4735     # If there is a line spec, delete the breakpoint on that line.
4736     elsif ( $line =~ /^(\S.*)/ ) {
4737         eval { &delete_breakpoint( $line || $dbline ); 1 } or do {
4738             local $\ = '';
4739             print $OUT $@ and return;
4740         };
4741     } ## end elsif ($line =~ /^(\S.*)/)
4742
4743     # No line spec.
4744     else {
4745         print $OUT
4746           "Deleting a breakpoint requires a line number, or '*' for all\n"
4747           ;    # hint
4748     }
4749 } ## end sub cmd_B
4750
4751 =head3 delete_breakpoint([line]) (API)
4752
4753 This actually does the work of deleting either a single breakpoint, or all
4754 of them.
4755
4756 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4757 just drop out with a message saying so. If it is, we remove the condition
4758 part of the 'condition\0action' that says there's a breakpoint here. If,
4759 after we've done that, there's nothing left, we delete the corresponding
4760 line in C<%dbline> to signal that no action needs to be taken for this line.
4761
4762 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4763 which lists all currently-loaded files which have breakpoints. We then look
4764 at each line in each of these files, temporarily switching the C<%dbline>
4765 and C<@dbline> structures to point to the files in question, and do what
4766 we did in the single line case: delete the condition in C<@dbline>, and
4767 delete the key in C<%dbline> if nothing's left.
4768
4769 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4770 C<%break_on_load>, because these structures contain breakpoints for files
4771 and code that haven't been loaded yet. We can just kill these off because there
4772 are no magical debugger structures associated with them.
4773
4774 =cut
4775
4776 sub delete_breakpoint {
4777     my $i = shift;
4778
4779     my $fn = $filename;
4780
4781     # If we got a line, delete just that one.
4782     if ( defined($i) ) {
4783
4784         # Woops. This line wasn't breakable at all.
4785         die "Line $i not breakable.\n" if $dbline[$i] == 0;
4786
4787         # Kill the condition, but leave any action.
4788         $dbline{$i} =~ s/^[^\0]*//;
4789
4790         # Remove the entry entirely if there's no action left.
4791         if ($dbline{$i} eq '') {
4792             delete $dbline{$i};
4793             _delete_breakpoint_data_ref($fn, $i);
4794         }
4795     }
4796
4797     # No line; delete them all.
4798     else {
4799         print $OUT "Deleting all breakpoints...\n";
4800
4801         # %had_breakpoints lists every file that had at least one
4802         # breakpoint in it.
4803         for my $file ( keys %had_breakpoints ) {
4804
4805             # Switch to the desired file temporarily.
4806             local *dbline = $main::{ '_<' . $file };
4807
4808             my $max = $#dbline;
4809             my $was;
4810
4811             # For all lines in this file ...
4812             for ( $i = 1 ; $i <= $max ; $i++ ) {
4813
4814                 # If there's a breakpoint or action on this line ...
4815                 if ( defined $dbline{$i} ) {
4816
4817                     # ... remove the breakpoint.
4818                     $dbline{$i} =~ s/^[^\0]+//;
4819                     if ( $dbline{$i} =~ s/^\0?$// ) {
4820
4821                         # Remove the entry altogether if no action is there.
4822                         delete $dbline{$i};
4823                         _delete_breakpoint_data_ref($file, $i);
4824                     }
4825                 } ## end if (defined $dbline{$i...
4826             } ## end for ($i = 1 ; $i <= $max...
4827
4828             # If, after we turn off the "there were breakpoints in this file"
4829             # bit, the entry in %had_breakpoints for this file is zero,
4830             # we should remove this file from the hash.
4831             if ( not $had_breakpoints{$file} &= ~1 ) {
4832                 delete $had_breakpoints{$file};
4833             }
4834         } ## end for my $file (keys %had_breakpoints)
4835
4836         # Kill off all the other breakpoints that are waiting for files that
4837         # haven't been loaded yet.
4838         undef %postponed;
4839         undef %postponed_file;
4840         undef %break_on_load;
4841     } ## end else [ if (defined($i))
4842 } ## end sub delete_breakpoint
4843
4844 =head3 cmd_stop (command)
4845
4846 This is meant to be part of the new command API, but it isn't called or used
4847 anywhere else in the debugger. XXX It is probably meant for use in development
4848 of new commands.
4849
4850 =cut
4851
4852 sub cmd_stop {    # As on ^C, but not signal-safy.
4853     $signal = 1;
4854 }
4855
4856 =head3 C<cmd_e> - threads
4857
4858 Display the current thread id:
4859
4860         e
4861
4862 This could be how (when implemented) to send commands to this thread id (e cmd)
4863 or that thread id (e tid cmd).
4864
4865 =cut
4866
4867 sub cmd_e {
4868     my $cmd  = shift;
4869     my $line = shift;
4870         unless (exists($INC{'threads.pm'})) {
4871                 print "threads not loaded($ENV{PERL5DB_THREADED})
4872                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4873         } else {
4874                 my $tid = threads->tid;
4875                 print "thread id: $tid\n";
4876         }
4877 } ## end sub cmd_e
4878
4879 =head3 C<cmd_E> - list of thread ids
4880
4881 Display the list of available thread ids:
4882
4883         E
4884
4885 This could be used (when implemented) to send commands to all threads (E cmd).
4886
4887 =cut
4888
4889 sub cmd_E {
4890     my $cmd  = shift;
4891     my $line = shift;
4892         unless (exists($INC{'threads.pm'})) {
4893                 print "threads not loaded($ENV{PERL5DB_THREADED})
4894                 please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4895         } else {
4896                 my $tid = threads->tid;
4897                 print "thread ids: ".join(', ',
4898                         map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
4899                 )."\n";
4900         }
4901 } ## end sub cmd_E
4902
4903 =head3 C<cmd_h> - help command (command)
4904
4905 Does the work of either
4906
4907 =over 4
4908
4909 =item *
4910
4911 Showing all the debugger help
4912
4913 =item *
4914
4915 Showing help for a specific command
4916
4917 =back
4918
4919 =cut
4920
4921 sub cmd_h {
4922     my $cmd = shift;
4923
4924     # If we have no operand, assume null.
4925     my $line = shift || '';
4926
4927     # 'h h'. Print the long-format help.
4928     if ( $line =~ /^h\s*/ ) {
4929         print_help($help);
4930     }
4931
4932     # 'h <something>'. Search for the command and print only its help.
4933     elsif ( $line =~ /^(\S.*)$/ ) {
4934
4935         # support long commands; otherwise bogus errors
4936         # happen when you ask for h on <CR> for example
4937         my $asked = $1;    # the command requested
4938                            # (for proper error message)
4939
4940         my $qasked = quotemeta($asked);    # for searching; we don't
4941                                            # want to use it as a pattern.
4942                                            # XXX: finds CR but not <CR>
4943
4944         # Search the help string for the command.
4945         if (
4946             $help =~ /^                    # Start of a line
4947                       <?                   # Optional '<'
4948                       (?:[IB]<)            # Optional markup
4949                       $qasked              # The requested command
4950                      /mx
4951           )
4952         {
4953
4954             # It's there; pull it out and print it.
4955             while (
4956                 $help =~ /^
4957                               (<?            # Optional '<'
4958                                  (?:[IB]<)   # Optional markup
4959                                  $qasked     # The command
4960                                  ([\s\S]*?)  # Description line(s)
4961                               \n)            # End of last description line
4962                               (?!\s)         # Next line not starting with
4963                                              # whitespace
4964                              /mgx
4965               )
4966             {
4967                 print_help($1);
4968             }
4969         }
4970
4971         # Not found; not a debugger command.
4972         else {
4973             print_help("B<$asked> is not a debugger command.\n");
4974         }
4975     } ## end elsif ($line =~ /^(\S.*)$/)
4976
4977     # 'h' - print the summary help.
4978     else {
4979         print_help($summary);
4980     }
4981 } ## end sub cmd_h
4982
4983 =head3 C<cmd_i> - inheritance display
4984
4985 Display the (nested) parentage of the module or object given.
4986
4987 =cut
4988
4989 sub cmd_i {
4990     my $cmd  = shift;
4991     my $line = shift;
4992     foreach my $isa ( split( /\s+/, $line ) ) {
4993         $evalarg = $isa;
4994         ($isa) = &eval;
4995         no strict 'refs';
4996         print join(
4997             ', ',
4998             map {
4999                 "$_"
5000                   . (
5001                     defined( ${"$_\::VERSION"} )
5002                     ? ' ' . ${"$_\::VERSION"}
5003                     : undef )
5004               } @{mro::get_linear_isa(ref($isa) || $isa)}
5005         );
5006         print "\n";
5007     }
5008 } ## end sub cmd_i
5009
5010 =head3 C<cmd_l> - list lines (command)
5011
5012 Most of the command is taken up with transforming all the different line
5013 specification syntaxes into 'start-stop'. After that is done, the command
5014 runs a loop over C<@dbline> for the specified range of lines. It handles
5015 the printing of each line and any markers (C<==E<gt>> for current line,
5016 C<b> for break on this line, C<a> for action on this line, C<:> for this
5017 line breakable).
5018
5019 We save the last line listed in the C<$start> global for further listing
5020 later.
5021
5022 =cut
5023
5024 sub cmd_l {
5025     my $current_line = $line;
5026     my $cmd  = shift;
5027     my $line = shift;
5028
5029     # If this is '-something', delete any spaces after the dash.
5030     $line =~ s/^-\s*$/-/;
5031
5032     # If the line is '$something', assume this is a scalar containing a
5033     # line number.
5034     if ( $line =~ /^(\$.*)/s ) {
5035
5036         # Set up for DB::eval() - evaluate in *user* context.
5037         $evalarg = $1;
5038         # $evalarg = $2;
5039         my ($s) = &eval;
5040
5041         # Ooops. Bad scalar.
5042         print( $OUT "Error: $@\n" ), next CMD if $@;
5043
5044         # Good scalar. If it's a reference, find what it points to.
5045         $s = CvGV_name($s);
5046         print( $OUT "Interpreted as: $1 $s\n" );
5047         $line = "$1 $s";
5048
5049         # Call self recursively to really do the command.
5050         &cmd_l( 'l', $s );
5051     } ## end if ($line =~ /^(\$.*)/s)
5052
5053     # l name. Try to find a sub by that name.
5054     elsif ( $line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s ) {
5055         my $s = $subname = $1;
5056
5057         # De-Perl4.
5058         $subname =~ s/\'/::/;
5059
5060         # Put it in this package unless it starts with ::.
5061         $subname = $package . "::" . $subname unless $subname =~ /::/;
5062
5063         # Put it in CORE::GLOBAL if t doesn't start with :: and
5064         # it doesn't live in this package and it lives in CORE::GLOBAL.
5065         $subname = "CORE::GLOBAL::$s"
5066           if not defined &$subname
5067           and $s !~ /::/
5068           and defined &{"CORE::GLOBAL::$s"};
5069
5070         # Put leading '::' names into 'main::'.
5071         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5072
5073         # Get name:start-stop from find_sub, and break this up at
5074         # colons.
5075         @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5076
5077         # Pull off start-stop.
5078         $subrange = pop @pieces;
5079
5080         # If the name contained colons, the split broke it up.
5081         # Put it back together.
5082         $file = join( ':', @pieces );
5083
5084         # If we're not in that file, switch over to it.
5085         if ( $file ne $filename ) {
5086             print $OUT "Switching to file '$file'.\n"
5087               unless $slave_editor;
5088
5089             # Switch debugger's magic structures.
5090             *dbline   = $main::{ '_<' . $file };
5091             $max      = $#dbline;
5092             $filename = $file;
5093         } ## end if ($file ne $filename)
5094
5095         # Subrange is 'start-stop'. If this is less than a window full,
5096         # swap it to 'start+', which will list a window from the start point.
5097         if ($subrange) {
5098             if ( eval($subrange) < -$window ) {
5099                 $subrange =~ s/-.*/+/;
5100             }
5101
5102             # Call self recursively to list the range.
5103             $line = $subrange;
5104             &cmd_l( 'l', $subrange );
5105         } ## end if ($subrange)
5106
5107         # Couldn't find it.
5108         else {
5109             print $OUT "Subroutine $subname not found.\n";
5110         }
5111     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5112
5113     # Bare 'l' command.
5114     elsif ( $line =~ /^\s*$/ ) {
5115
5116         # Compute new range to list.
5117         $incr = $window - 1;
5118         $line = $start . '-' . ( $start + $incr );
5119
5120         # Recurse to do it.
5121         &cmd_l( 'l', $line );
5122     }
5123
5124     # l [start]+number_of_lines
5125     elsif ( $line =~ /^(\d*)\+(\d*)$/ ) {
5126
5127         # Don't reset start for 'l +nnn'.
5128         $start = $1 if $1;
5129
5130         # Increment for list. Use window size if not specified.
5131         # (Allows 'l +' to work.)
5132         $incr = $2;
5133         $incr = $window - 1 unless $incr;
5134
5135         # Create a line range we'll understand, and recurse to do it.
5136         $line = $start . '-' . ( $start + $incr );
5137         &cmd_l( 'l', $line );
5138     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5139
5140     # l start-stop or l start,stop
5141     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5142
5143         # Determine end point; use end of file if not specified.
5144         $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5145
5146         # Go on to the end, and then stop.
5147         $end = $max if $end > $max;
5148
5149         # Determine start line.
5150         $i    = $2;
5151         $i    = $line if $i eq '.';
5152         $i    = 1 if $i < 1;
5153         $incr = $end - $i;
5154
5155         # If we're running under a slave editor, force it to show the lines.
5156         if ($slave_editor) {
5157             print $OUT "\032\032$filename:$i:0\n";
5158             $i = $end;
5159         }
5160
5161         # We're doing it ourselves. We want to show the line and special
5162         # markers for:
5163         # - the current line in execution
5164         # - whether a line is breakable or not
5165         # - whether a line has a break or not
5166         # - whether a line has an action or not
5167         else {
5168             for ( ; $i <= $end ; $i++ ) {
5169
5170                 # Check for breakpoints and actions.
5171                 my ( $stop, $action );
5172                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5173                   if $dbline{$i};
5174
5175                 # ==> if this is the current line in execution,
5176                 # : if it's breakable.
5177                 $arrow =
5178                   ( $i == $current_line and $filename eq $filename_ini )
5179                   ? '==>'
5180                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5181
5182                 # Add break and action indicators.
5183                 $arrow .= 'b' if $stop;
5184                 $arrow .= 'a' if $action;
5185
5186                 # Print the line.
5187                 print $OUT "$i$arrow\t", $dbline[$i];
5188
5189                 # Move on to the next line. Drop out on an interrupt.
5190                 $i++, last if $signal;
5191             } ## end for (; $i <= $end ; $i++)
5192
5193             # Line the prompt up; print a newline if the last line listed
5194             # didn't have a newline.
5195             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5196         } ## end else [ if ($slave_editor)
5197
5198         # Save the point we last listed to in case another relative 'l'
5199         # command is desired. Don't let it run off the end.
5200         $start = $i;
5201         $start = $max if $start > $max;
5202     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5203 } ## end sub cmd_l
5204
5205 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5206
5207 To list breakpoints, the command has to look determine where all of them are
5208 first. It starts a C<%had_breakpoints>, which tells us what all files have
5209 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5210 magic source and breakpoint data structures) to the file, and then look
5211 through C<%dbline> for lines with breakpoints and/or actions, listing them
5212 out. We look through C<%postponed> not-yet-compiled subroutines that have
5213 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5214 that have breakpoints.
5215
5216 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5217
5218 =cut
5219
5220 sub cmd_L {
5221     my $cmd = shift;
5222
5223     # If no argument, list everything. Pre-5.8.0 version always lists
5224     # everything
5225     my $arg = shift || 'abw';
5226     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5227
5228     # See what is wanted.
5229     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5230     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5231     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5232
5233     # Breaks and actions are found together, so we look in the same place
5234     # for both.
5235     if ( $break_wanted or $action_wanted ) {
5236
5237         # Look in all the files with breakpoints...
5238         for my $file ( keys %had_breakpoints ) {
5239
5240             # Temporary switch to this file.
5241             local *dbline = $main::{ '_<' . $file };
5242
5243             # Set up to look through the whole file.
5244             my $max = $#dbline;
5245             my $was;    # Flag: did we print something
5246                         # in this file?
5247
5248             # For each line in the file ...
5249             for ( $i = 1 ; $i <= $max ; $i++ ) {
5250
5251                 # We've got something on this line.
5252                 if ( defined $dbline{$i} ) {
5253
5254                     # Print the header if we haven't.
5255                     print $OUT "$file:\n" unless $was++;
5256
5257                     # Print the line.
5258                     print $OUT " $i:\t", $dbline[$i];
5259
5260                     # Pull out the condition and the action.
5261                     ( $stop, $action ) = split( /\0/, $dbline{$i} );
5262
5263                     # Print the break if there is one and it's wanted.
5264                     print $OUT "   break if (", $stop, ")\n"
5265                       if $stop
5266                       and $break_wanted;
5267
5268                     # Print the action if there is one and it's wanted.
5269                     print $OUT "   action:  ", $action, "\n"
5270                       if $action
5271                       and $action_wanted;
5272
5273                     # Quit if the user hit interrupt.
5274                     last if $signal;
5275                 } ## end if (defined $dbline{$i...
5276             } ## end for ($i = 1 ; $i <= $max...
5277         } ## end for my $file (keys %had_breakpoints)
5278     } ## end if ($break_wanted or $action_wanted)
5279
5280     # Look for breaks in not-yet-compiled subs:
5281     if ( %postponed and $break_wanted ) {
5282         print $OUT "Postponed breakpoints in subroutines:\n";
5283         my $subname;
5284         for $subname ( keys %postponed ) {
5285             print $OUT " $subname\t$postponed{$subname}\n";
5286             last if $signal;
5287         }
5288     } ## end if (%postponed and $break_wanted)
5289
5290     # Find files that have not-yet-loaded breaks:
5291     my @have = map {    # Combined keys
5292         keys %{ $postponed_file{$_} }
5293     } keys %postponed_file;
5294
5295     # If there are any, list them.
5296     if ( @have and ( $break_wanted or $action_wanted ) ) {
5297         print $OUT "Postponed breakpoints in files:\n";
5298         my ( $file, $line );
5299
5300         for $file ( keys %postponed_file ) {
5301             my $db = $postponed_file{$file};
5302             print $OUT " $file:\n";
5303             for $line ( sort { $a <=> $b } keys %$db ) {
5304                 print $OUT "  $line:\n";
5305                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5306                 print $OUT "    break if (", $stop, ")\n"
5307                   if $stop
5308                   and $break_wanted;
5309                 print $OUT "    action:  ", $action, "\n"
5310                   if $action
5311                   and $action_wanted;
5312                 last if $signal;
5313             } ## end for $line (sort { $a <=>...
5314             last if $signal;
5315         } ## end for $file (keys %postponed_file)
5316     } ## end if (@have and ($break_wanted...
5317     if ( %break_on_load and $break_wanted ) {
5318         print $OUT "Breakpoints on load:\n";
5319         my $file;
5320         for $file ( keys %break_on_load ) {
5321             print $OUT " $file\n";
5322             last if $signal;
5323         }
5324     } ## end if (%break_on_load and...
5325     if ($watch_wanted) {
5326         if ( $trace & 2 ) {
5327             print $OUT "Watch-expressions:\n" if @to_watch;
5328             for my $expr (@to_watch) {
5329                 print $OUT " $expr\n";
5330                 last if $signal;
5331             }
5332         } ## end if ($trace & 2)
5333     } ## end if ($watch_wanted)
5334 } ## end sub cmd_L
5335
5336 =head3 C<cmd_M> - list modules (command)
5337
5338 Just call C<list_modules>.
5339
5340 =cut
5341
5342 sub cmd_M {
5343     &list_modules();
5344 }
5345
5346 =head3 C<cmd_o> - options (command)
5347
5348 If this is just C<o> by itself, we list the current settings via
5349 C<dump_option>. If there's a nonblank value following it, we pass that on to
5350 C<parse_options> for processing.
5351
5352 =cut
5353
5354 sub cmd_o {
5355     my $cmd = shift;
5356     my $opt = shift || '';    # opt[=val]
5357
5358     # Nonblank. Try to parse and process.
5359     if ( $opt =~ /^(\S.*)/ ) {
5360         &parse_options($1);
5361     }
5362
5363     # Blank. List the current option settings.
5364     else {
5365         for (@options) {
5366             &dump_option($_);
5367         }
5368     }
5369 } ## end sub cmd_o
5370
5371 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5372
5373 Advises the user that the O command has been renamed.
5374
5375 =cut
5376
5377 sub cmd_O {
5378     print $OUT "The old O command is now the o command.\n";             # hint
5379     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5380     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5381 }
5382
5383 =head3 C<cmd_v> - view window (command)
5384
5385 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5386 move back a few lines to list the selected line in context. Uses C<cmd_l>
5387 to do the actual listing after figuring out the range of line to request.
5388
5389 =cut
5390
5391 sub cmd_v {
5392     my $cmd  = shift;
5393     my $line = shift;
5394
5395     # Extract the line to list around. (Astute readers will have noted that
5396     # this pattern will match whether or not a numeric line is specified,
5397     # which means that we'll always enter this loop (though a non-numeric
5398     # argument results in no action at all)).
5399     if ( $line =~ /^(\d*)$/ ) {
5400
5401         # Total number of lines to list (a windowful).
5402         $incr = $window - 1;
5403
5404         # Set the start to the argument given (if there was one).
5405         $start = $1 if $1;
5406
5407         # Back up by the context amount.
5408         $start -= $preview;
5409
5410         # Put together a linespec that cmd_l will like.
5411         $line = $start . '-' . ( $start + $incr );
5412
5413         # List the lines.
5414         &cmd_l( 'l', $line );
5415     } ## end if ($line =~ /^(\d*)$/)
5416 } ## end sub cmd_v
5417
5418 =head3 C<cmd_w> - add a watch expression (command)
5419
5420 The 5.8 version of this command adds a watch expression if one is specified;
5421 it does nothing if entered with no operands.
5422
5423 We extract the expression, save it, evaluate it in the user's context, and
5424 save the value. We'll re-evaluate it each time the debugger passes a line,
5425 and will stop (see the code at the top of the command loop) if the value
5426 of any of the expressions changes.
5427
5428 =cut
5429
5430 sub cmd_w {
5431     my $cmd = shift;
5432
5433     # Null expression if no arguments.
5434     my $expr = shift || '';
5435
5436     # If expression is not null ...
5437     if ( $expr =~ /^(\S.*)/ ) {
5438
5439         # ... save it.
5440         push @to_watch, $expr;
5441
5442         # Parameterize DB::eval and call it to get the expression's value
5443         # in the user's context. This version can handle expressions which
5444         # return a list value.
5445         $evalarg = $expr;
5446         my ($val) = join( ' ', &eval );
5447         $val = ( defined $val ) ? "'$val'" : 'undef';
5448
5449         # Save the current value of the expression.
5450         push @old_watch, $val;
5451
5452         # We are now watching expressions.
5453         $trace |= 2;
5454     } ## end if ($expr =~ /^(\S.*)/)
5455
5456     # You have to give one to get one.
5457     else {
5458         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5459     }
5460 } ## end sub cmd_w
5461
5462 =head3 C<cmd_W> - delete watch expressions (command)
5463
5464 This command accepts either a watch expression to be removed from the list
5465 of watch expressions, or C<*> to delete them all.
5466
5467 If C<*> is specified, we simply empty the watch expression list and the
5468 watch expression value list. We also turn off the bit that says we've got
5469 watch expressions.
5470
5471 If an expression (or partial expression) is specified, we pattern-match
5472 through the expressions and remove the ones that match. We also discard
5473 the corresponding values. If no watch expressions are left, we turn off
5474 the I<watching expressions> bit.
5475
5476 =cut
5477
5478 sub cmd_W {
5479     my $cmd  = shift;
5480     my $expr = shift || '';
5481
5482     # Delete them all.
5483     if ( $expr eq '*' ) {
5484
5485         # Not watching now.
5486         $trace &= ~2;
5487
5488         print $OUT "Deleting all watch expressions ...\n";
5489
5490         # And all gone.
5491         @to_watch = @old_watch = ();
5492     }
5493
5494     # Delete one of them.
5495     elsif ( $expr =~ /^(\S.*)/ ) {
5496
5497         # Where we are in the list.
5498         my $i_cnt = 0;
5499
5500         # For each expression ...
5501         foreach (@to_watch) {
5502             my $val = $to_watch[$i_cnt];
5503
5504             # Does this one match the command argument?
5505             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5506                                       # Yes. Turn it off, and its value too.
5507                 splice( @to_watch,  $i_cnt, 1 );
5508                 splice( @old_watch, $i_cnt, 1 );
5509             }
5510             $i_cnt++;
5511         } ## end foreach (@to_watch)
5512
5513         # We don't bother to turn watching off because
5514         #  a) we don't want to stop calling watchfunction() it it exists
5515         #  b) foreach over a null list doesn't do anything anyway
5516
5517     } ## end elsif ($expr =~ /^(\S.*)/)
5518
5519     # No command arguments entered.
5520     else {
5521         print $OUT
5522           "Deleting a watch-expression requires an expression, or '*' for all\n"
5523           ;    # hint
5524     }
5525 } ## end sub cmd_W
5526
5527 ### END of the API section
5528
5529 =head1 SUPPORT ROUTINES
5530
5531 These are general support routines that are used in a number of places
5532 throughout the debugger.
5533
5534 =head2 save
5535
5536 save() saves the user's versions of globals that would mess us up in C<@saved>,
5537 and installs the versions we like better.
5538
5539 =cut
5540
5541 sub save {
5542
5543     # Save eval failure, command failure, extended OS error, output field
5544     # separator, input record separator, output record separator and
5545     # the warning setting.
5546     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5547
5548     $,  = "";      # output field separator is null string
5549     $/  = "\n";    # input record separator is newline
5550     $\  = "";      # output record separator is null string
5551     $^W = 0;       # warnings are off
5552 } ## end sub save
5553
5554 =head2 C<print_lineinfo> - show where we are now
5555
5556 print_lineinfo prints whatever it is that it is handed; it prints it to the
5557 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5558 us to feed line information to a slave editor without messing up the
5559 debugger output.
5560
5561 =cut
5562
5563 sub print_lineinfo {
5564
5565     # Make the terminal sensible if we're not the primary debugger.
5566     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5567     local $\ = '';
5568     local $, = '';
5569     print $LINEINFO @_;
5570 } ## end sub print_lineinfo
5571
5572 =head2 C<postponed_sub>
5573
5574 Handles setting postponed breakpoints in subroutines once they're compiled.
5575 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5576 range for the subroutine, then mark the file as having a breakpoint,
5577 temporarily switch the C<*dbline> glob over to the source file, and then
5578 search the given range of lines to find a breakable line. If we find one,
5579 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5580
5581 =cut
5582
5583 # The following takes its argument via $evalarg to preserve current @_
5584
5585 sub postponed_sub {
5586
5587     # Get the subroutine name.
5588     my $subname = shift;
5589
5590     # If this is a 'break +<n> if <condition>' ...
5591     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5592
5593         # If there's no offset, use '+0'.
5594         my $offset = $1 || 0;
5595
5596         # find_sub's value is 'fullpath-filename:start-stop'. It's
5597         # possible that the filename might have colons in it too.
5598         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5599         if ($i) {
5600
5601             # We got the start line. Add the offset '+<n>' from
5602             # $postponed{subname}.
5603             $i += $offset;
5604
5605             # Switch to the file this sub is in, temporarily.
5606             local *dbline = $main::{ '_<' . $file };
5607
5608             # No warnings, please.
5609             local $^W = 0;    # != 0 is magical below
5610
5611             # This file's got a breakpoint in it.
5612             $had_breakpoints{$file} |= 1;
5613
5614             # Last line in file.
5615             my $max = $#dbline;
5616
5617             # Search forward until we hit a breakable line or get to
5618             # the end of the file.
5619             ++$i until $dbline[$i] != 0 or $i >= $max;
5620
5621             # Copy the breakpoint in and delete it from %postponed.
5622             $dbline{$i} = delete $postponed{$subname};
5623         } ## end if ($i)
5624
5625         # find_sub didn't find the sub.
5626         else {
5627             local $\ = '';
5628             print $OUT "Subroutine $subname not found.\n";
5629         }
5630         return;
5631     } ## end if ($postponed{$subname...
5632     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5633
5634     #print $OUT "In postponed_sub for '$subname'.\n";
5635 } ## end sub postponed_sub
5636
5637 =head2 C<postponed>
5638
5639 Called after each required file is compiled, but before it is executed;
5640 also called if the name of a just-compiled subroutine is a key of
5641 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5642 etc.) into the just-compiled code.
5643
5644 If this is a C<require>'d file, the incoming parameter is the glob
5645 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5646
5647 If it's a subroutine, the incoming parameter is the subroutine name.
5648
5649 =cut
5650
5651 sub postponed {
5652
5653     # If there's a break, process it.
5654     if ($ImmediateStop) {
5655
5656         # Right, we've stopped. Turn it off.
5657         $ImmediateStop = 0;
5658
5659         # Enter the command loop when DB::DB gets called.
5660         $signal = 1;
5661     }
5662
5663     # If this is a subroutine, let postponed_sub() deal with it.
5664     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5665
5666     # Not a subroutine. Deal with the file.
5667     local *dbline = shift;
5668     my $filename = $dbline;
5669     $filename =~ s/^_<//;
5670     local $\ = '';
5671     $signal = 1, print $OUT "'$filename' loaded...\n"
5672       if $break_on_load{$filename};
5673     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5674
5675     # Do we have any breakpoints to put in this file?
5676     return unless $postponed_file{$filename};
5677
5678     # Yes. Mark this file as having breakpoints.
5679     $had_breakpoints{$filename} |= 1;
5680
5681     # "Cannot be done: insufficient magic" - we can't just put the
5682     # breakpoints saved in %postponed_file into %dbline by assigning
5683     # the whole hash; we have to do it one item at a time for the
5684     # breakpoints to be set properly.
5685     #%dbline = %{$postponed_file{$filename}};
5686
5687     # Set the breakpoints, one at a time.
5688     my $key;
5689
5690     for $key ( keys %{ $postponed_file{$filename} } ) {
5691
5692         # Stash the saved breakpoint into the current file's magic line array.
5693         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5694     }
5695
5696     # This file's been compiled; discard the stored breakpoints.
5697     delete $postponed_file{$filename};
5698
5699 } ## end sub postponed
5700
5701 =head2 C<dumpit>
5702
5703 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5704
5705 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5706 a reference to a variable (the thing to be dumped) as its input.
5707
5708 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5709 the currently-selected filehandle, thank you very much). The current
5710 values of the package globals C<$single> and C<$trace> are backed up in
5711 lexicals, and they are turned off (this keeps the debugger from trying
5712 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5713 preserve its current value and it is set to zero to prevent entry/exit
5714 messages from printing, and C<$doret> is localized as well and set to -2 to
5715 prevent return values from being shown.
5716
5717 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5718 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5719 installed version in C<@INC>, yours will be used instead. Possible security
5720 problem?).
5721
5722 It then checks to see if the subroutine C<main::dumpValue> is now defined
5723 (it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5724 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5725 is called, and picks up the variable to be dumped from the parameter list.
5726
5727 It checks the package global C<%options> to see if there's a C<dumpDepth>
5728 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5729 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5730 structure: -1 means dump everything.
5731
5732 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5733 warning.
5734
5735 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5736 and we then return to the caller.
5737
5738 =cut
5739
5740 sub dumpit {
5741
5742     # Save the current output filehandle and switch to the one
5743     # passed in as the first parameter.
5744     local ($savout) = select(shift);
5745
5746     # Save current settings of $single and $trace, and then turn them off.
5747     my $osingle = $single;
5748     my $otrace  = $trace;
5749     $single = $trace = 0;
5750
5751     # XXX Okay, what do $frame and $doret do, again?
5752     local $frame = 0;
5753     local $doret = -2;
5754
5755     # Load dumpvar.pl unless we've already got the sub we need from it.
5756     unless ( defined &main::dumpValue ) {
5757         do 'dumpvar.pl' or die $@;
5758     }
5759
5760     # If the load succeeded (or we already had dumpvalue()), go ahead
5761     # and dump things.
5762     if ( defined &main::dumpValue ) {
5763         local $\ = '';
5764         local $, = '';
5765         local $" = ' ';
5766         my $v = shift;
5767         my $maxdepth = shift || $option{dumpDepth};
5768         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5769         &main::dumpValue( $v, $maxdepth );
5770     } ## end if (defined &main::dumpValue)
5771
5772     # Oops, couldn't load dumpvar.pl.
5773     else {
5774         local $\ = '';
5775         print $OUT "dumpvar.pl not available.\n";
5776     }
5777
5778     # Reset $single and $trace to their old values.
5779     $single = $osingle;
5780     $trace  = $otrace;
5781
5782     # Restore the old filehandle.
5783     select($savout);
5784 } ## end sub dumpit
5785
5786 =head2 C<print_trace>
5787
5788 C<print_trace>'s job is to print a stack trace. It does this via the
5789 C<dump_trace> routine, which actually does all the ferreting-out of the
5790 stack trace data. C<print_trace> takes care of formatting it nicely and
5791 printing it to the proper filehandle.
5792
5793 Parameters:
5794
5795 =over 4
5796
5797 =item *
5798
5799 The filehandle to print to.
5800
5801 =item *
5802
5803 How many frames to skip before starting trace.
5804
5805 =item *
5806
5807 How many frames to print.
5808
5809 =item *
5810
5811 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5812
5813 =back
5814
5815 The original comment below seems to be noting that the traceback may not be
5816 correct if this routine is called in a tied method.
5817
5818 =cut
5819
5820 # Tied method do not create a context, so may get wrong message:
5821
5822 sub print_trace {
5823     local $\ = '';
5824     my $fh = shift;
5825
5826     # If this is going to a slave editor, but we're not the primary
5827     # debugger, reset it first.
5828     resetterm(1)
5829       if $fh        eq $LINEINFO    # slave editor
5830       and $LINEINFO eq $OUT         # normal output
5831       and $term_pid != $$;          # not the primary
5832
5833     # Collect the actual trace information to be formatted.
5834     # This is an array of hashes of subroutine call info.
5835     my @sub = dump_trace( $_[0] + 1, $_[1] );
5836
5837     # Grab the "short report" flag from @_.
5838     my $short = $_[2];              # Print short report, next one for sub name
5839
5840     # Run through the traceback info, format it, and print it.
5841     my $s;
5842     for ( $i = 0 ; $i <= $#sub ; $i++ ) {
5843
5844         # Drop out if the user has lost interest and hit control-C.
5845         last if $signal;
5846
5847         # Set the separator so arrys print nice.
5848         local $" = ', ';
5849
5850         # Grab and stringify the arguments if they are there.
5851         my $args =
5852           defined $sub[$i]{args}
5853           ? "(@{ $sub[$i]{args} })"
5854           : '';
5855
5856         # Shorten them up if $maxtrace says they're too long.
5857         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5858           if length $args > $maxtrace;
5859
5860         # Get the file name.
5861         my $file = $sub[$i]{file};
5862
5863         # Put in a filename header if short is off.
5864         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5865
5866         # Get the actual sub's name, and shorten to $maxtrace's requirement.
5867         $s = $sub[$i]{sub};
5868         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
5869
5870         # Short report uses trimmed file and sub names.
5871         if ($short) {
5872             my $sub = @_ >= 4 ? $_[3] : $s;
5873             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
5874         } ## end if ($short)
5875
5876         # Non-short report includes full names.
5877         else {
5878             print $fh "$sub[$i]{context} = $s$args"
5879               . " called from $file"
5880               . " line $sub[$i]{line}\n";
5881         }
5882     } ## end for ($i = 0 ; $i <= $#sub...
5883 } ## end sub print_trace
5884
5885 =head2 dump_trace(skip[,count])
5886
5887 Actually collect the traceback information available via C<caller()>. It does
5888 some filtering and cleanup of the data, but mostly it just collects it to
5889 make C<print_trace()>'s job easier.
5890
5891 C<skip> defines the number of stack frames to be skipped, working backwards
5892 from the most current. C<count> determines the total number of frames to
5893 be returned; all of them (well, the first 10^9) are returned if C<count>
5894 is omitted.
5895
5896 This routine returns a list of hashes, from most-recent to least-recent
5897 stack frame. Each has the following keys and values:
5898
5899 =over 4
5900
5901 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
5902
5903 =item * C<sub> - subroutine name, or C<eval> information
5904
5905 =item * C<args> - undef, or a reference to an array of arguments
5906
5907 =item * C<file> - the file in which this item was defined (if any)
5908
5909 =item * C<line> - the line on which it was defined
5910
5911 =back
5912
5913 =cut
5914
5915 sub dump_trace {
5916
5917     # How many levels to skip.
5918     my $skip = shift;
5919
5920     # How many levels to show. (1e9 is a cheap way of saying "all of them";
5921     # it's unlikely that we'll have more than a billion stack frames. If you
5922     # do, you've got an awfully big machine...)
5923     my $count = shift || 1e9;
5924
5925     # We increment skip because caller(1) is the first level *back* from
5926     # the current one.  Add $skip to the count of frames so we have a
5927     # simple stop criterion, counting from $skip to $count+$skip.
5928     $skip++;
5929     $count += $skip;
5930
5931     # These variables are used to capture output from caller();
5932     my ( $p, $file, $line, $sub, $h, $context );
5933
5934     my ( $e, $r, @a, @sub, $args );
5935
5936     # XXX Okay... why'd we do that?
5937     my $nothard = not $frame & 8;
5938     local $frame = 0;
5939
5940     # Do not want to trace this.
5941     my $otrace = $trace;
5942     $trace = 0;
5943
5944     # Start out at the skip count.
5945     # If we haven't reached the number of frames requested, and caller() is
5946     # still returning something, stay in the loop. (If we pass the requested
5947     # number of stack frames, or we run out - caller() returns nothing - we
5948     # quit.
5949     # Up the stack frame index to go back one more level each time.
5950     for (
5951         $i = $skip ;
5952         $i < $count
5953         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
5954         $i++
5955       )
5956     {
5957
5958         # Go through the arguments and save them for later.
5959         @a = ();
5960         for $arg (@args) {
5961             my $type;
5962             if ( not defined $arg ) {    # undefined parameter
5963                 push @a, "undef";
5964             }
5965
5966             elsif ( $nothard and tied $arg ) {    # tied parameter
5967                 push @a, "tied";
5968             }
5969             elsif ( $nothard and $type = ref $arg ) {    # reference
5970                 push @a, "ref($type)";
5971             }
5972             else {                                       # can be stringified
5973                 local $_ =
5974                   "$arg";    # Safe to stringify now - should not call f().
5975
5976                 # Backslash any single-quotes or backslashes.
5977                 s/([\'\\])/\\$1/g;
5978
5979                 # Single-quote it unless it's a number or a colon-separated
5980                 # name.
5981                 s/(.*)/'$1'/s
5982                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
5983
5984                 # Turn high-bit characters into meta-whatever.
5985                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
5986
5987                 # Turn control characters into ^-whatever.
5988                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
5989
5990                 push( @a, $_ );
5991             } ## end else [ if (not defined $arg)
5992         } ## end for $arg (@args)
5993
5994         # If context is true, this is array (@)context.
5995         # If context is false, this is scalar ($) context.
5996         # If neither, context isn't defined. (This is apparently a 'can't
5997         # happen' trap.)
5998         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
5999
6000         # if the sub has args ($h true), make an anonymous array of the
6001         # dumped args.
6002         $args = $h ? [@a] : undef;
6003
6004         # remove trailing newline-whitespace-semicolon-end of line sequence
6005         # from the eval text, if any.
6006         $e =~ s/\n\s*\;\s*\Z// if $e;
6007
6008         # Escape backslashed single-quotes again if necessary.
6009         $e =~ s/([\\\'])/\\$1/g if $e;
6010
6011         # if the require flag is true, the eval text is from a require.
6012         if ($r) {
6013             $sub = "require '$e'";
6014         }
6015
6016         # if it's false, the eval text is really from an eval.
6017         elsif ( defined $r ) {
6018             $sub = "eval '$e'";
6019         }
6020
6021         # If the sub is '(eval)', this is a block eval, meaning we don't
6022         # know what the eval'ed text actually was.
6023         elsif ( $sub eq '(eval)' ) {
6024             $sub = "eval {...}";
6025         }
6026
6027         # Stick the collected information into @sub as an anonymous hash.
6028         push(
6029             @sub,
6030             {
6031                 context => $context,
6032                 sub     => $sub,
6033                 args    => $args,
6034                 file    => $file,
6035                 line    => $line
6036             }
6037         );
6038
6039         # Stop processing frames if the user hit control-C.
6040         last if $signal;
6041     } ## end for ($i = $skip ; $i < ...
6042
6043     # Restore the trace value again.
6044     $trace = $otrace;
6045     @sub;
6046 } ## end sub dump_trace
6047
6048 =head2 C<action()>
6049
6050 C<action()> takes input provided as the argument to an add-action command,
6051 either pre- or post-, and makes sure it's a complete command. It doesn't do
6052 any fancy parsing; it just keeps reading input until it gets a string
6053 without a trailing backslash.
6054
6055 =cut
6056
6057 sub action {
6058     my $action = shift;
6059
6060     while ( $action =~ s/\\$// ) {
6061
6062         # We have a backslash on the end. Read more.
6063         $action .= &gets;
6064     } ## end while ($action =~ s/\\$//)
6065
6066     # Return the assembled action.
6067     $action;
6068 } ## end sub action
6069
6070 =head2 unbalanced
6071
6072 This routine mostly just packages up a regular expression to be used
6073 to check that the thing it's being matched against has properly-matched
6074 curly braces.
6075
6076 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6077 speeds things up by only creating the qr//'ed expression once; if it's
6078 already defined, we don't try to define it again. A speed hack.
6079
6080 =cut
6081
6082 sub unbalanced {
6083
6084     # I hate using globals!
6085     $balanced_brace_re ||= qr{
6086         ^ \{
6087              (?:
6088                  (?> [^{}] + )              # Non-parens without backtracking
6089                 |
6090                  (??{ $balanced_brace_re }) # Group with matching parens
6091               ) *
6092           \} $
6093    }x;
6094     return $_[0] !~ m/$balanced_brace_re/;
6095 } ## end sub unbalanced
6096
6097 =head2 C<gets()>
6098
6099 C<gets()> is a primitive (very primitive) routine to read continuations.
6100 It was devised for reading continuations for actions.
6101 it just reads more input with C<readline()> and returns it.
6102
6103 =cut
6104
6105 sub gets {
6106     &readline("cont: ");
6107 }
6108
6109 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6110
6111 The C<system()> function assumes that it can just go ahead and use STDIN and
6112 STDOUT, but under the debugger, we want it to use the debugger's input and
6113 outout filehandles.
6114
6115 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6116 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6117 and then puts everything back again.
6118
6119 =cut
6120
6121 sub system {
6122
6123     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6124     # some non-Unix systems can do system() but have problems with fork().
6125     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6126     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6127     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6128     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6129
6130     # XXX: using csh or tcsh destroys sigint retvals!
6131     system(@_);
6132     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6133     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6134     close(SAVEIN);
6135     close(SAVEOUT);
6136
6137     # most of the $? crud was coping with broken cshisms
6138     if ( $? >> 8 ) {
6139         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6140     }
6141     elsif ($?) {
6142         &warn(
6143             "(Command died of SIG#",
6144             ( $? & 127 ),
6145             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6146             ")", "\n"
6147         );
6148     } ## end elsif ($?)
6149
6150     return $?;
6151
6152 } ## end sub system
6153
6154 =head1 TTY MANAGEMENT
6155
6156 The subs here do some of the terminal management for multiple debuggers.
6157
6158 =head2 setterm
6159
6160 Top-level function called when we want to set up a new terminal for use
6161 by the debugger.
6162
6163 If the C<noTTY> debugger option was set, we'll either use the terminal
6164 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6165 to find one. If we're a forked debugger, we call C<resetterm> to try to
6166 get a whole new terminal if we can.
6167
6168 In either case, we set up the terminal next. If the C<ReadLine> option was
6169 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6170 the appropriate attributes. We then
6171
6172 =cut
6173
6174 sub setterm {
6175
6176     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6177     local $frame = 0;
6178     local $doret = -2;
6179     require Term::ReadLine;
6180
6181     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6182     if ($notty) {
6183         if ($tty) {
6184             my ( $i, $o ) = split $tty, /,/;
6185             $o = $i unless defined $o;
6186             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6187             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6188             $IN  = \*IN;
6189             $OUT = \*OUT;
6190             my $sel = select($OUT);
6191             $| = 1;
6192             select($sel);
6193         } ## end if ($tty)
6194
6195         # We don't have a TTY - try to find one via Term::Rendezvous.
6196         else {
6197             require Term::Rendezvous;
6198
6199             # See if we have anything to pass to Term::Rendezvous.
6200             # Use $HOME/.perldbtty$$ if not.
6201             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6202
6203             # Rendezvous and get the filehandles.
6204             my $term_rv = Term::Rendezvous->new( $rv );
6205             $IN  = $term_rv->IN;
6206             $OUT = $term_rv->OUT;
6207         } ## end else [ if ($tty)
6208     } ## end if ($notty)
6209
6210     # We're a daughter debugger. Try to fork off another TTY.
6211     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6212         resetterm(2);
6213     }
6214
6215     # If we shouldn't use Term::ReadLine, don't.
6216     if ( !$rl ) {
6217         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6218     }
6219
6220     # We're using Term::ReadLine. Get all the attributes for this terminal.
6221     else {
6222         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6223
6224         $rl_attribs = $term->Attribs;
6225         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6226           if defined $rl_attribs->{basic_word_break_characters}
6227           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6228         $rl_attribs->{special_prefixes} = '$@&%';
6229         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6230         $rl_attribs->{completion_function} = \&db_complete;
6231     } ## end else [ if (!$rl)
6232
6233     # Set up the LINEINFO filehandle.
6234     $LINEINFO = $OUT     unless defined $LINEINFO;
6235     $lineinfo = $console unless defined $lineinfo;
6236
6237     $term->MinLine(2);
6238
6239     &load_hist();
6240
6241     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6242         $term->SetHistory(@hist);
6243     }
6244
6245     # XXX Ornaments are turned on unconditionally, which is not
6246     # always a good thing.
6247     ornaments($ornaments) if defined $ornaments;
6248     $term_pid = $$;
6249 } ## end sub setterm
6250
6251 sub load_hist {
6252     $histfile //= option_val("HistFile", undef);
6253     return unless defined $histfile;
6254     open my $fh, "<", $histfile or return;
6255     local $/ = "\n";
6256     @hist = ();
6257     while (<$fh>) {
6258         chomp;
6259         push @hist, $_;
6260     }
6261     close $fh;
6262 }
6263
6264 sub save_hist {
6265     return unless defined $histfile;
6266     eval { require File::Path } or return;
6267     eval { require File::Basename } or return;
6268     File::Path::mkpath(File::Basename::dirname($histfile));
6269     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6270     $histsize //= option_val("HistSize",100);
6271     my @copy = grep { $_ ne '?' } @hist;
6272     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6273     for ($start .. $#copy) {
6274         print $fh "$copy[$_]\n";
6275     }
6276     close $fh or die "Could not write '$histfile': $!";
6277 }
6278
6279 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6280
6281 When the process being debugged forks, or the process invokes a command
6282 via C<system()> which starts a new debugger, we need to be able to get a new
6283 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6284 fight over the terminal, and you can never quite be sure who's going to get the
6285 input you're typing.
6286
6287 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6288 is tasked with doing all the necessary operating system mojo to get a new
6289 TTY (and probably another window) and to direct the new debugger to read and
6290 write there.
6291
6292 The debugger provides C<get_fork_TTY> functions which work for TCP
6293 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6294 supported. You are encouraged to write C<get_fork_TTY> functions which
6295 work for I<your> platform and contribute them.
6296
6297 =head3 C<socket_get_fork_TTY>
6298
6299 =cut
6300
6301 sub connect_remoteport {
6302     require IO::Socket;
6303
6304     my $socket = IO::Socket::INET->new(
6305         Timeout  => '10',
6306         PeerAddr => $remoteport,
6307         Proto    => 'tcp',
6308     );
6309     if ( ! $socket ) {
6310         die "Unable to connect to remote host: $remoteport\n";
6311     }
6312     return $socket;
6313 }
6314
6315 sub socket_get_fork_TTY {
6316     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6317
6318     # Do I need to worry about setting $term?
6319
6320     reset_IN_OUT( $IN, $OUT );
6321     return '';
6322 }
6323
6324 =head3 C<xterm_get_fork_TTY>
6325
6326 This function provides the C<get_fork_TTY> function for X11. If a
6327 program running under the debugger forks, a new <xterm> window is opened and
6328 the subsidiary debugger is directed there.
6329
6330 The C<open()> call is of particular note here. We have the new C<xterm>
6331 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6332 command (which prints the device name of the TTY we'll want to use for input
6333 and output to STDOUT, then C<sleep> for a very long time, routing this output
6334 to file number 3. This way we can simply read from the <XT> filehandle (which
6335 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6336
6337 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6338 properly set up.
6339
6340 =cut
6341
6342 sub xterm_get_fork_TTY {
6343     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6344     open XT,
6345 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6346  sleep 10000000' |];
6347
6348     # Get the output from 'tty' and clean it up a little.
6349     my $tty = <XT>;
6350     chomp $tty;
6351
6352     $pidprompt = '';    # Shown anyway in titlebar
6353
6354     # We need $term defined or we can not switch to the newly created xterm
6355     if ($tty ne '' && !defined $term) {
6356         require Term::ReadLine;
6357         if ( !$rl ) {
6358             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6359         }
6360         else {
6361             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6362         }
6363     }
6364     # There's our new TTY.
6365     return $tty;
6366 } ## end sub xterm_get_fork_TTY
6367
6368 =head3 C<os2_get_fork_TTY>
6369
6370 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6371
6372 =cut
6373
6374 # This example function resets $IN, $OUT itself
6375 my $c_pipe = 0;
6376 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6377     local $\  = '';
6378     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6379     my %opt = ( title => "Daughter Perl debugger $pids $name",
6380                 ($rl ? (read_by_key => 1) : ()) );
6381     require OS2::Process;
6382     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6383       or return;
6384     $pidprompt = '';    # Shown anyway in titlebar
6385     reset_IN_OUT($in, $out);
6386     $tty = '*reset*';
6387     return '';          # Indicate that reset_IN_OUT is called
6388 } ## end sub os2_get_fork_TTY
6389
6390 =head3 C<macosx_get_fork_TTY>
6391
6392 The Mac OS X version uses AppleScript to tell Terminal.app to create
6393 a new window.
6394
6395 =cut
6396
6397 # Notes about Terminal.app's AppleScript support,
6398 # (aka things that might break in future OS versions).
6399 #
6400 # The "do script" command doesn't return a reference to the new window
6401 # it creates, but since it appears frontmost and windows are enumerated
6402 # front to back, we can use "first window" === "window 1".
6403 #
6404 # Since "do script" is implemented by supplying the argument (plus a
6405 # return character) as terminal input, there's a potential race condition
6406 # where the debugger could beat the shell to reading the command.
6407 # To prevent this, we wait for the screen to clear before proceeding.
6408 #
6409 # 10.3 and 10.4:
6410 # There's no direct accessor for the tty device name, so we fiddle
6411 # with the window title options until it says what we want.
6412 #
6413 # 10.5:
6414 # There _is_ a direct accessor for the tty device name, _and_ there's
6415 # a new possible component of the window title (the name of the settings
6416 # set).  A separate version is needed.
6417
6418 my @script_versions=
6419
6420     ([237, <<'__LEOPARD__'],
6421 tell application "Terminal"
6422     do script "clear;exec sleep 100000"
6423     tell first tab of first window
6424         copy tty to thetty
6425         set custom title to "forked perl debugger"
6426         set title displays custom title to true
6427         repeat while (length of first paragraph of (get contents)) > 0
6428             delay 0.1
6429         end repeat
6430     end tell
6431 end tell
6432 thetty
6433 __LEOPARD__
6434
6435      [100, <<'__JAGUAR_TIGER__'],
6436 tell application "Terminal"
6437     do script "clear;exec sleep 100000"
6438     tell first window
6439         set title displays shell path to false
6440         set title displays window size to false
6441         set title displays file name to false
6442         set title displays device name to true
6443         set title displays custom title to true
6444         set custom title to ""
6445         copy "/dev/" & name to thetty
6446         set custom title to "forked perl debugger"
6447         repeat while (length of first paragraph of (get contents)) > 0
6448             delay 0.1
6449         end repeat
6450     end tell
6451 end tell
6452 thetty
6453 __JAGUAR_TIGER__
6454
6455 );
6456
6457 sub macosx_get_fork_TTY
6458 {
6459     my($version,$script,$pipe,$tty);
6460
6461     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6462     foreach my $entry (@script_versions) {
6463         if ($version>=$entry->[0]) {
6464             $script=$entry->[1];
6465             last;
6466         }
6467     }
6468     return unless defined($script);
6469     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6470     $tty=readline($pipe);
6471     close($pipe);
6472     return unless defined($tty) && $tty =~ m(^/dev/);
6473     chomp $tty;
6474     return $tty;
6475 }
6476
6477 =head2 C<create_IN_OUT($flags)>
6478
6479 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6480 try to diagnose why.
6481
6482 Flags are:
6483
6484 =over 4
6485
6486 =item * 1 - Don't know how to create a new TTY.
6487
6488 =item * 2 - Debugger has forked, but we can't get a new TTY.
6489
6490 =item * 4 - standard debugger startup is happening.
6491
6492 =back
6493
6494 =cut
6495
6496 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6497
6498     # If we know how to get a new TTY, do it! $in will have
6499     # the TTY name if get_fork_TTY works.
6500     my $in = &get_fork_TTY if defined &get_fork_TTY;
6501
6502     # It used to be that
6503     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6504
6505     if ( not defined $in ) {
6506         my $why = shift;
6507
6508         # We don't know how.
6509         print_help(<<EOP) if $why == 1;
6510 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6511 EOP
6512
6513         # Forked debugger.
6514         print_help(<<EOP) if $why == 2;
6515 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6516   This may be an asynchronous session, so the parent debugger may be active.
6517 EOP
6518
6519         # Note that both debuggers are fighting over the same input.
6520         print_help(<<EOP) if $why != 4;
6521   Since two debuggers fight for the same TTY, input is severely entangled.
6522
6523 EOP
6524         print_help(<<EOP);
6525   I know how to switch the output to a different window in xterms, OS/2
6526   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6527   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6528   B<DB::get_fork_TTY()> returning this.
6529
6530   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6531   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6532
6533 EOP
6534     } ## end if (not defined $in)
6535     elsif ( $in ne '' ) {
6536         TTY($in);
6537     }
6538     else {
6539         $console = '';    # Indicate no need to open-from-the-console
6540     }
6541     undef $fork_TTY;
6542 } ## end sub create_IN_OUT
6543
6544 =head2 C<resetterm>
6545
6546 Handles rejiggering the prompt when we've forked off a new debugger.
6547
6548 If the new debugger happened because of a C<system()> that invoked a
6549 program under the debugger, the arrow between the old pid and the new
6550 in the prompt has I<two> dashes instead of one.
6551
6552 We take the current list of pids and add this one to the end. If there
6553 isn't any list yet, we make one up out of the initial pid associated with
6554 the terminal and our new pid, sticking an arrow (either one-dashed or
6555 two dashed) in between them.
6556
6557 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6558 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6559 and try to do that.
6560
6561 =cut
6562
6563 sub resetterm {    # We forked, so we need a different TTY
6564
6565     # Needs to be passed to create_IN_OUT() as well.
6566     my $in = shift;
6567
6568     # resetterm(2): got in here because of a system() starting a debugger.
6569     # resetterm(1): just forked.
6570     my $systemed = $in > 1 ? '-' : '';
6571
6572     # If there's already a list of pids, add this to the end.
6573     if ($pids) {
6574         $pids =~ s/\]/$systemed->$$]/;
6575     }
6576
6577     # No pid list. Time to make one.
6578     else {
6579         $pids = "[$term_pid->$$]";
6580     }
6581
6582     # The prompt we're going to be using for this debugger.
6583     $pidprompt = $pids;
6584
6585     # We now 0wnz this terminal.
6586     $term_pid = $$;
6587
6588     # Just return if we're not supposed to try to create a new TTY.
6589     return unless $CreateTTY & $in;
6590
6591     # Try to create a new IN/OUT pair.
6592     create_IN_OUT($in);
6593 } ## end sub resetterm
6594
6595 =head2 C<readline>
6596
6597 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6598 the next line, print a message saying we got it, add it to the terminal
6599 history (if possible), and return it.
6600
6601 If there's nothing in the typeahead buffer, check the command filehandle stack.
6602 If there are any filehandles there, read from the last one, and return the line
6603 if we got one. If not, we pop the filehandle off and close it, and try the
6604 next one up the stack.
6605
6606 If we've emptied the filehandle stack, we check to see if we've got a socket
6607 open, and we read that and return it if we do. If we don't, we just call the
6608 core C<readline()> and return its value.
6609
6610 =cut
6611
6612 sub readline {
6613
6614     # Localize to prevent it from being smashed in the program being debugged.
6615     local $.;
6616
6617     # Pull a line out of the typeahead if there's stuff there.
6618     if (@typeahead) {
6619
6620         # How many lines left.
6621         my $left = @typeahead;
6622
6623         # Get the next line.
6624         my $got = shift @typeahead;
6625
6626         # Print a message saying we got input from the typeahead.
6627         local $\ = '';
6628         print $OUT "auto(-$left)", shift, $got, "\n";
6629
6630         # Add it to the terminal history (if possible).
6631         $term->AddHistory($got)
6632           if length($got) > 1
6633           and defined $term->Features->{addHistory};
6634         return $got;
6635     } ## end if (@typeahead)
6636
6637     # We really need to read some input. Turn off entry/exit trace and
6638     # return value printing.
6639     local $frame = 0;
6640     local $doret = -2;
6641
6642     # If there are stacked filehandles to read from ...
6643     while (@cmdfhs) {
6644
6645         # Read from the last one in the stack.
6646         my $line = CORE::readline( $cmdfhs[-1] );
6647
6648         # If we got a line ...
6649         defined $line
6650           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6651           : close pop @cmdfhs;                            # Pop and close
6652     } ## end while (@cmdfhs)
6653
6654     # Nothing on the filehandle stack. Socket?
6655     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6656
6657         # Send anything we have to send.
6658         $OUT->write( join( '', @_ ) );
6659
6660         # Receive anything there is to receive.
6661         $stuff;
6662         my $stuff = '';
6663         my $buf;
6664         do {
6665             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6666                                             # XXX Don't know. You tell me.
6667         } while length $buf and ($stuff .= $buf) !~ /\n/;
6668
6669         # What we got.
6670         $stuff;
6671     } ## end if (ref $OUT and UNIVERSAL::isa...
6672
6673     # No socket. Just read from the terminal.
6674     else {
6675         $term->readline(@_);
6676     }
6677 } ## end sub readline
6678
6679 =head1 OPTIONS SUPPORT ROUTINES
6680
6681 These routines handle listing and setting option values.
6682
6683 =head2 C<dump_option> - list the current value of an option setting
6684
6685 This routine uses C<option_val> to look up the value for an option.
6686 It cleans up escaped single-quotes and then displays the option and
6687 its value.
6688
6689 =cut
6690
6691 sub dump_option {
6692     my ( $opt, $val ) = @_;
6693     $val = option_val( $opt, 'N/A' );
6694     $val =~ s/([\\\'])/\\$1/g;
6695     printf $OUT "%20s = '%s'\n", $opt, $val;
6696 } ## end sub dump_option
6697
6698 sub options2remember {
6699     foreach my $k (@RememberOnROptions) {
6700         $option{$k} = option_val( $k, 'N/A' );
6701     }
6702     return %option;
6703 }
6704
6705 =head2 C<option_val> - find the current value of an option
6706
6707 This can't just be a simple hash lookup because of the indirect way that
6708 the option values are stored. Some are retrieved by calling a subroutine,
6709 some are just variables.
6710
6711 You must supply a default value to be used in case the option isn't set.
6712
6713 =cut
6714
6715 sub option_val {
6716     my ( $opt, $default ) = @_;
6717     my $val;
6718
6719     # Does this option exist, and is it a variable?
6720     # If so, retrieve the value via the value in %optionVars.
6721     if (    defined $optionVars{$opt}
6722         and defined ${ $optionVars{$opt} } )
6723     {
6724         $val = ${ $optionVars{$opt} };
6725     }
6726
6727     # Does this option exist, and it's a subroutine?
6728     # If so, call the subroutine via the ref in %optionAction
6729     # and capture the value.
6730     elsif ( defined $optionAction{$opt}
6731         and defined &{ $optionAction{$opt} } )
6732     {
6733         $val = &{ $optionAction{$opt} }();
6734     }
6735
6736     # If there's an action or variable for the supplied option,
6737     # but no value was set, use the default.
6738     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6739         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6740     {
6741         $val = $default;
6742     }
6743
6744     # Otherwise, do the simple hash lookup.
6745     else {
6746         $val = $option{$opt};
6747     }
6748
6749     # If the value isn't defined, use the default.
6750     # Then return whatever the value is.
6751     $val = $default unless defined $val;
6752     $val;
6753 } ## end sub option_val
6754
6755 =head2 C<parse_options>
6756
6757 Handles the parsing and execution of option setting/displaying commands.
6758
6759 An option entered by itself is assumed to be I<set me to 1> (the default value)
6760 if the option is a boolean one. If not, the user is prompted to enter a valid
6761 value or to query the current value (via C<option? >).
6762
6763 If C<option=value> is entered, we try to extract a quoted string from the
6764 value (if it is quoted). If it's not, we just use the whole value as-is.
6765
6766 We load any modules required to service this option, and then we set it: if
6767 it just gets stuck in a variable, we do that; if there's a subroutine to
6768 handle setting the option, we call that.
6769
6770 Finally, if we're running in interactive mode, we display the effect of the
6771 user's command back to the terminal, skipping this if we're setting things
6772 during initialization.
6773
6774 =cut
6775
6776 sub parse_options {
6777     local ($_) = @_;
6778     local $\ = '';
6779
6780     # These options need a value. Don't allow them to be clobbered by accident.
6781     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6782       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6783       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6784     };
6785
6786     while (length) {
6787         my $val_defaulted;
6788
6789         # Clean off excess leading whitespace.
6790         s/^\s+// && next;
6791
6792         # Options are always all word characters, followed by a non-word
6793         # separator.
6794         s/^(\w+)(\W?)// or print( $OUT "Invalid option '$_'\n" ), last;
6795         my ( $opt, $sep ) = ( $1, $2 );
6796
6797         # Make sure that such an option exists.
6798         my $matches = grep( /^\Q$opt/ && ( $option = $_ ), @options )
6799           || grep( /^\Q$opt/i && ( $option = $_ ), @options );
6800
6801         print( $OUT "Unknown option '$opt'\n" ), next unless $matches;
6802         print( $OUT "Ambiguous option '$opt'\n" ), next if $matches > 1;
6803         my $val;
6804
6805         # '?' as separator means query, but must have whitespace after it.
6806         if ( "?" eq $sep ) {
6807             print( $OUT "Option query '$opt?' followed by non-space '$_'\n" ),
6808               last
6809               if /^\S/;
6810
6811             #&dump_option($opt);
6812         } ## end if ("?" eq $sep)
6813
6814         # Separator is whitespace (or just a carriage return).
6815         # They're going for a default, which we assume is 1.
6816         elsif ( $sep !~ /\S/ ) {
6817             $val_defaulted = 1;
6818             $val           = "1";   #  this is an evil default; make 'em set it!
6819         }
6820
6821         # Separator is =. Trying to set a value.
6822         elsif ( $sep eq "=" ) {
6823
6824             # If quoted, extract a quoted string.
6825             if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6826                 my $quote = $1;
6827                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6828             }
6829
6830             # Not quoted. Use the whole thing. Warn about 'option='.
6831             else {
6832                 s/^(\S*)//;
6833                 $val = $1;
6834                 print OUT qq(Option better cleared using $opt=""\n)
6835                   unless length $val;
6836             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6837
6838         } ## end elsif ($sep eq "=")
6839
6840         # "Quoted" with [], <>, or {}.
6841         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6842             my ($end) =
6843               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
6844             s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
6845               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
6846             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
6847         } ## end else [ if ("?" eq $sep)
6848
6849         # Exclude non-booleans from getting set to 1 by default.
6850         if ( $opt_needs_val{$option} && $val_defaulted ) {
6851             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
6852             print $OUT
6853 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
6854             next;
6855         } ## end if ($opt_needs_val{$option...
6856
6857         # Save the option value.
6858         $option{$option} = $val if defined $val;
6859
6860         # Load any module that this option requires.
6861         eval qq{
6862                 local \$frame = 0;
6863                 local \$doret = -2;
6864                 require '$optionRequire{$option}';
6865                 1;
6866                } || die $@   # XXX: shouldn't happen
6867           if defined $optionRequire{$option}
6868           && defined $val;
6869
6870         # Set it.
6871         # Stick it in the proper variable if it goes in a variable.
6872         ${ $optionVars{$option} } = $val
6873           if defined $optionVars{$option}
6874           && defined $val;
6875
6876         # Call the appropriate sub if it gets set via sub.
6877         &{ $optionAction{$option} }($val)
6878           if defined $optionAction{$option}
6879           && defined &{ $optionAction{$option} }
6880           && defined $val;
6881
6882         # Not initialization - echo the value we set it to.
6883         dump_option($option) unless $OUT eq \*STDERR;
6884     } ## end while (length)
6885 } ## end sub parse_options
6886
6887 =head1 RESTART SUPPORT
6888
6889 These routines are used to store (and restore) lists of items in environment
6890 variables during a restart.
6891
6892 =head2 set_list
6893
6894 Set_list packages up items to be stored in a set of environment variables
6895 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
6896 the values). Values outside the standard ASCII charset are stored by encoding
6897 then as hexadecimal values.
6898
6899 =cut
6900
6901 sub set_list {
6902     my ( $stem, @list ) = @_;
6903     my $val;
6904
6905     # VAR_n: how many we have. Scalar assignment gets the number of items.
6906     $ENV{"${stem}_n"} = @list;
6907
6908     # Grab each item in the list, escape the backslashes, encode the non-ASCII
6909     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
6910     for $i ( 0 .. $#list ) {
6911         $val = $list[$i];
6912         $val =~ s/\\/\\\\/g;
6913         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
6914         $ENV{"${stem}_$i"} = $val;
6915     } ## end for $i (0 .. $#list)
6916 } ## end sub set_list
6917
6918 =head2 get_list
6919
6920 Reverse the set_list operation: grab VAR_n to see how many we should be getting
6921 back, and then pull VAR_0, VAR_1. etc. back out.
6922
6923 =cut
6924
6925 sub get_list {
6926     my $stem = shift;
6927     my @list;
6928     my $n = delete $ENV{"${stem}_n"};
6929     my $val;
6930     for $i ( 0 .. $n - 1 ) {
6931         $val = delete $ENV{"${stem}_$i"};
6932         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
6933         push @list, $val;
6934     }
6935     @list;
6936 } ## end sub get_list
6937
6938 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
6939
6940 =head2 catch()
6941
6942 The C<catch()> subroutine is the essence of fast and low-impact. We simply
6943 set an already-existing global scalar variable to a constant value. This
6944 avoids allocating any memory possibly in the middle of something that will
6945 get all confused if we do, particularly under I<unsafe signals>.
6946
6947 =cut
6948
6949 sub catch {
6950     $signal = 1;
6951     return;    # Put nothing on the stack - malloc/free land!
6952 }
6953
6954 =head2 C<warn()>
6955
6956 C<warn> emits a warning, by joining together its arguments and printing
6957 them, with couple of fillips.
6958
6959 If the composited message I<doesn't> end with a newline, we automatically
6960 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
6961 to be set to the filehandle to be used to output warnings; it makes no
6962 assumptions about what filehandles are available.
6963
6964 =cut
6965
6966 sub warn {
6967     my ($msg) = join( "", @_ );
6968     $msg .= ": $!\n" unless $msg =~ /\n$/;
6969     local $\ = '';
6970     print $OUT $msg;
6971 } ## end sub warn
6972
6973 =head1 INITIALIZATION TTY SUPPORT
6974
6975 =head2 C<reset_IN_OUT>
6976
6977 This routine handles restoring the debugger's input and output filehandles
6978 after we've tried and failed to move them elsewhere.  In addition, it assigns
6979 the debugger's output filehandle to $LINEINFO if it was already open there.
6980
6981 =cut
6982
6983 sub reset_IN_OUT {
6984     my $switch_li = $LINEINFO eq $OUT;
6985
6986     # If there's a term and it's able to get a new tty, try to get one.
6987     if ( $term and $term->Features->{newTTY} ) {
6988         ( $IN, $OUT ) = ( shift, shift );
6989         $term->newTTY( $IN, $OUT );
6990     }
6991
6992     # This term can't get a new tty now. Better luck later.
6993     elsif ($term) {
6994         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
6995     }
6996
6997     # Set the filehndles up as they were.
6998     else {
6999         ( $IN, $OUT ) = ( shift, shift );
7000     }
7001
7002     # Unbuffer the output filehandle.
7003     my $o = select $OUT;
7004     $| = 1;
7005     select $o;
7006
7007     # Point LINEINFO to the same output filehandle if it was there before.
7008     $LINEINFO = $OUT if $switch_li;
7009 } ## end sub reset_IN_OUT
7010
7011 =head1 OPTION SUPPORT ROUTINES
7012
7013 The following routines are used to process some of the more complicated
7014 debugger options.
7015
7016 =head2 C<TTY>
7017
7018 Sets the input and output filehandles to the specified files or pipes.
7019 If the terminal supports switching, we go ahead and do it. If not, and
7020 there's already a terminal in place, we save the information to take effect
7021 on restart.
7022
7023 If there's no terminal yet (for instance, during debugger initialization),
7024 we go ahead and set C<$console> and C<$tty> to the file indicated.
7025
7026 =cut
7027
7028 sub TTY {
7029
7030     if ( @_ and $term and $term->Features->{newTTY} ) {
7031
7032         # This terminal supports switching to a new TTY.
7033         # Can be a list of two files, or on string containing both names,
7034         # comma-separated.
7035         # XXX Should this perhaps be an assignment from @_?
7036         my ( $in, $out ) = shift;
7037         if ( $in =~ /,/ ) {
7038
7039             # Split list apart if supplied.
7040             ( $in, $out ) = split /,/, $in, 2;
7041         }
7042         else {
7043
7044             # Use the same file for both input and output.
7045             $out = $in;
7046         }
7047
7048         # Open file onto the debugger's filehandles, if you can.
7049         open IN,  $in     or die "cannot open '$in' for read: $!";
7050         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7051
7052         # Swap to the new filehandles.
7053         reset_IN_OUT( \*IN, \*OUT );
7054
7055         # Save the setting for later.
7056         return $tty = $in;
7057     } ## end if (@_ and $term and $term...
7058
7059     # Terminal doesn't support new TTY, or doesn't support readline.
7060     # Can't do it now, try restarting.
7061     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
7062
7063     # Useful if done through PERLDB_OPTS:
7064     $console = $tty = shift if @_;
7065
7066     # Return whatever the TTY is.
7067     $tty or $console;
7068 } ## end sub TTY
7069
7070 =head2 C<noTTY>
7071
7072 Sets the C<$notty> global, controlling whether or not the debugger tries to
7073 get a terminal to read from. If called after a terminal is already in place,
7074 we save the value to use it if we're restarted.
7075
7076 =cut
7077
7078 sub noTTY {
7079     if ($term) {
7080         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7081     }
7082     $notty = shift if @_;
7083     $notty;
7084 } ## end sub noTTY
7085
7086 =head2 C<ReadLine>
7087
7088 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7089 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7090 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7091 the value in case a restart is done so we can change it then.
7092
7093 =cut
7094
7095 sub ReadLine {
7096     if ($term) {
7097         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7098     }
7099     $rl = shift if @_;
7100     $rl;
7101 } ## end sub ReadLine
7102
7103 =head2 C<RemotePort>
7104
7105 Sets the port that the debugger will try to connect to when starting up.
7106 If the terminal's already been set up, we can't do it, but we remember the
7107 setting in case the user does a restart.
7108
7109 =cut
7110
7111 sub RemotePort {
7112     if ($term) {
7113         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7114     }
7115     $remoteport = shift if @_;
7116     $remoteport;
7117 } ## end sub RemotePort
7118
7119 =head2 C<tkRunning>
7120
7121 Checks with the terminal to see if C<Tk> is running, and returns true or
7122 false. Returns false if the current terminal doesn't support C<readline>.
7123
7124 =cut
7125
7126 sub tkRunning {
7127     if ( ${ $term->Features }{tkRunning} ) {
7128         return $term->tkRunning(@_);
7129     }
7130     else {
7131         local $\ = '';
7132         print $OUT "tkRunning not supported by current ReadLine package.\n";
7133         0;
7134     }
7135 } ## end sub tkRunning
7136
7137 =head2 C<NonStop>
7138
7139 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7140 debugger remembers the setting in case you restart, though.
7141
7142 =cut
7143
7144 sub NonStop {
7145     if ($term) {
7146         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7147           if @_;
7148     }
7149     $runnonstop = shift if @_;
7150     $runnonstop;
7151 } ## end sub NonStop
7152
7153 sub DollarCaretP {
7154     if ($term) {
7155         &warn("Some flag changes could not take effect until next 'R'!\n")
7156           if @_;
7157     }
7158     $^P = parse_DollarCaretP_flags(shift) if @_;
7159     expand_DollarCaretP_flags($^P);
7160 }
7161
7162 =head2 C<pager>
7163
7164 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7165 there already.
7166
7167 =cut
7168
7169 sub pager {
7170     if (@_) {
7171         $pager = shift;
7172         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7173     }
7174     $pager;
7175 } ## end sub pager
7176
7177 =head2 C<shellBang>
7178
7179 Sets the shell escape command, and generates a printable copy to be used
7180 in the help.
7181
7182 =cut
7183
7184 sub shellBang {
7185
7186     # If we got an argument, meta-quote it, and add '\b' if it
7187     # ends in a word character.
7188     if (@_) {
7189         $sh = quotemeta shift;
7190         $sh .= "\\b" if $sh =~ /\w$/;
7191     }
7192
7193     # Generate the printable version for the help:
7194     $psh = $sh;    # copy it
7195     $psh =~ s/\\b$//;        # Take off trailing \b if any
7196     $psh =~ s/\\(.)/$1/g;    # De-escape
7197     $psh;                    # return the printable version
7198 } ## end sub shellBang
7199
7200 =head2 C<ornaments>
7201
7202 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7203 was passed as the argument. (This means you can't override the terminal's
7204 ornaments.)
7205
7206 =cut
7207
7208 sub ornaments {
7209     if ( defined $term ) {
7210
7211         # We don't want to show warning backtraces, but we do want die() ones.
7212         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7213
7214         # No ornaments if the terminal doesn't support them.
7215         return '' unless $term->Features->{ornaments};
7216         eval { $term->ornaments(@_) } || '';
7217     }
7218
7219     # Use what was passed in if we can't determine it ourselves.
7220     else {
7221         $ornaments = shift;
7222     }
7223 } ## end sub ornaments
7224
7225 =head2 C<recallCommand>
7226
7227 Sets the recall command, and builds a printable version which will appear in
7228 the help text.
7229
7230 =cut
7231
7232 sub recallCommand {
7233
7234     # If there is input, metaquote it. Add '\b' if it ends with a word
7235     # character.
7236     if (@_) {
7237         $rc = quotemeta shift;
7238         $rc .= "\\b" if $rc =~ /\w$/;
7239     }
7240
7241     # Build it into a printable version.
7242     $prc = $rc;    # Copy it
7243     $prc =~ s/\\b$//;        # Remove trailing \b
7244     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7245     $prc;                    # Return the printable version
7246 } ## end sub recallCommand
7247
7248 =head2 C<LineInfo> - where the line number information goes
7249
7250 Called with no arguments, returns the file or pipe that line info should go to.
7251
7252 Called with an argument (a file or a pipe), it opens that onto the
7253 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7254 file or pipe again to the caller.
7255
7256 =cut
7257
7258 sub LineInfo {
7259     return $lineinfo unless @_;
7260     $lineinfo = shift;
7261
7262     #  If this is a valid "thing to be opened for output", tack a
7263     # '>' onto the front.
7264     my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7265
7266     # If this is a pipe, the stream points to a slave editor.
7267     $slave_editor = ( $stream =~ /^\|/ );
7268
7269     # Open it up and unbuffer it.
7270     open( LINEINFO, "$stream" ) || &warn("Cannot open '$stream' for write");
7271     $LINEINFO = \*LINEINFO;
7272     my $save = select($LINEINFO);
7273     $| = 1;
7274     select($save);
7275
7276     # Hand the file or pipe back again.
7277     $lineinfo;
7278 } ## end sub LineInfo
7279
7280 =head1 COMMAND SUPPORT ROUTINES
7281
7282 These subroutines provide functionality for various commands.
7283
7284 =head2 C<list_modules>
7285
7286 For the C<M> command: list modules loaded and their versions.
7287 Essentially just runs through the keys in %INC, picks each package's
7288 C<$VERSION> variable, gets the file name, and formats the information
7289 for output.
7290
7291 =cut
7292
7293 sub list_modules {    # versions
7294     my %version;
7295     my $file;
7296
7297     # keys are the "as-loaded" name, values are the fully-qualified path
7298     # to the file itself.
7299     for ( keys %INC ) {
7300         $file = $_;                                # get the module name
7301         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7302         s,/,::,g;                                  # change '/' to '::'
7303         s/^perl5db$/DB/;                           # Special case: debugger
7304                                                    # moves to package DB
7305         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7306
7307         # If the package has a $VERSION package global (as all good packages
7308         # should!) decode it and save as partial message.
7309         if ( defined ${ $_ . '::VERSION' } ) {
7310             $version{$file} = "${ $_ . '::VERSION' } from ";
7311         }
7312
7313         # Finish up the message with the file the package came from.
7314         $version{$file} .= $INC{$file};
7315     } ## end for (keys %INC)
7316
7317     # Hey, dumpit() formats a hash nicely, so why not use it?
7318     dumpit( $OUT, \%version );
7319 } ## end sub list_modules
7320
7321 =head2 C<sethelp()>
7322
7323 Sets up the monster string used to format and print the help.
7324
7325 =head3 HELP MESSAGE FORMAT
7326
7327 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7328 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7329 easy to parse and portable, but which still allows the help to be a little
7330 nicer than just plain text.
7331
7332 Essentially, you define the command name (usually marked up with C<< B<> >>
7333 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7334 newline. The descriptive text can also be marked up in the same way. If you
7335 need to continue the descriptive text to another line, start that line with
7336 just tabs and then enter the marked-up text.
7337
7338 If you are modifying the help text, I<be careful>. The help-string parser is
7339 not very sophisticated, and if you don't follow these rules it will mangle the
7340 help beyond hope until you fix the string.
7341
7342 =cut
7343
7344 sub sethelp {
7345
7346     # XXX: make sure there are tabs between the command and explanation,
7347     #      or print_help will screw up your formatting if you have
7348     #      eeevil ornaments enabled.  This is an insane mess.
7349
7350     $help = "
7351 Help is currently only available for the new 5.8 command set.
7352 No help is available for the old command set.
7353 We assume you know what you're doing if you switch to it.
7354
7355 B<T>        Stack trace.
7356 B<s> [I<expr>]    Single step [in I<expr>].
7357 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7358 <B<CR>>        Repeat last B<n> or B<s> command.
7359 B<r>        Return from current subroutine.
7360 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7361         at the specified position.
7362 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7363 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7364 B<l> I<line>        List single I<line>.
7365 B<l> I<subname>    List first window of lines from subroutine.
7366 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7367 B<l>        List next window of lines.
7368 B<->        List previous window of lines.
7369 B<v> [I<line>]    View window around I<line>.
7370 B<.>        Return to the executed line.
7371 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7372         I<filename> may be either the full name of the file, or a regular
7373         expression matching the full file name:
7374         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7375         Evals (with saved bodies) are considered to be filenames:
7376         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7377         (in the order of execution).
7378 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7379 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7380 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7381 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7382 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7383 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7384 B<b>        Sets breakpoint on current line)
7385 B<b> [I<line>] [I<condition>]
7386         Set breakpoint; I<line> defaults to the current execution line;
7387         I<condition> breaks if it evaluates to true, defaults to '1'.
7388 B<b> I<subname> [I<condition>]
7389         Set breakpoint at first line of subroutine.
7390 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7391 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7392 B<b> B<postpone> I<subname> [I<condition>]
7393         Set breakpoint at first line of subroutine after
7394         it is compiled.
7395 B<b> B<compile> I<subname>
7396         Stop after the subroutine is compiled.
7397 B<B> [I<line>]    Delete the breakpoint for I<line>.
7398 B<B> I<*>             Delete all breakpoints.
7399 B<a> [I<line>] I<command>
7400         Set an action to be done before the I<line> is executed;
7401         I<line> defaults to the current execution line.
7402         Sequence is: check for breakpoint/watchpoint, print line
7403         if necessary, do action, prompt user if necessary,
7404         execute line.
7405 B<a>        Does nothing
7406 B<A> [I<line>]    Delete the action for I<line>.
7407 B<A> I<*>             Delete all actions.
7408 B<w> I<expr>        Add a global watch-expression.
7409 B<w>             Does nothing
7410 B<W> I<expr>        Delete a global watch-expression.
7411 B<W> I<*>             Delete all watch-expressions.
7412 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7413         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7414 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7415 B<x> I<expr>        Evals expression in list context, dumps the result.
7416 B<m> I<expr>        Evals expression in list context, prints methods callable
7417         on the first element of the result.
7418 B<m> I<class>        Prints methods callable via the given class.
7419 B<M>        Show versions of loaded modules.
7420 B<i> I<class>       Prints nested parents of given class.
7421 B<e>         Display current thread id.
7422 B<E>         Display all thread ids the current one will be identified: <n>.
7423 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7424
7425 B<<> ?            List Perl commands to run before each prompt.
7426 B<<> I<expr>        Define Perl command to run before each prompt.
7427 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7428 B<< *>                Delete the list of perl commands to run before each prompt.
7429 B<>> ?            List Perl commands to run after each prompt.
7430 B<>> I<expr>        Define Perl command to run after each prompt.
7431 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7432 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7433 B<{> I<db_command>    Define debugger command to run before each prompt.
7434 B<{> ?            List debugger commands to run before each prompt.
7435 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7436 B<{ *>             Delete the list of debugger commands to run before each prompt.
7437 B<$prc> I<number>    Redo a previous command (default previous command).
7438 B<$prc> I<-number>    Redo number'th-to-last command.
7439 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7440         See 'B<O> I<recallCommand>' too.
7441 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7442       . (
7443         $rc eq $sh
7444         ? ""
7445         : "
7446 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7447       ) . "
7448         See 'B<O> I<shellBang>' too.
7449 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7450 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7451 B<rerun>           Rerun session to current position.
7452 B<rerun> I<n>         Rerun session to numbered command.
7453 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7454 B<H> I<-number>    Display last number commands (default all).
7455 B<H> I<*>          Delete complete history.
7456 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7457 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7458 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7459 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7460 I<command>        Execute as a perl statement in current package.
7461 B<R>        Pure-man-restart of debugger, some of debugger state
7462         and command-line options may be lost.
7463         Currently the following settings are preserved:
7464         history, breakpoints and actions, debugger B<O>ptions
7465         and the following command-line options: I<-w>, I<-I>, I<-e>.
7466
7467 B<o> [I<opt>] ...    Set boolean option to true
7468 B<o> [I<opt>B<?>]    Query options
7469 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7470         Set options.  Use quotes if spaces in value.
7471     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7472     I<pager>            program for output of \"|cmd\";
7473     I<tkRunning>            run Tk while prompting (with ReadLine);
7474     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7475     I<inhibit_exit>        Allows stepping off the end of the script.
7476     I<ImmediateStop>        Debugger should stop as early as possible.
7477     I<RemotePort>            Remote hostname:port for remote debugging
7478   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7479     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7480     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7481     I<globPrint>             whether to print contents of globs;
7482     I<DumpDBFiles>         dump arrays holding debugged files;
7483     I<DumpPackages>         dump symbol tables of packages;
7484     I<DumpReused>             dump contents of \"reused\" addresses;
7485     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7486     I<bareStringify>         Do not print the overload-stringified value;
7487   Other options include:
7488     I<PrintRet>        affects printing of return value after B<r> command,
7489     I<frame>        affects printing messages on subroutine entry/exit.
7490     I<AutoTrace>    affects printing messages on possible breaking points.
7491     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7492     I<ornaments>     affects screen appearance of the command line.
7493     I<CreateTTY>     bits control attempts to create a new TTY on events:
7494             1: on fork()    2: debugger is started inside debugger
7495             4: on startup
7496     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7497     You can put additional initialization options I<TTY>, I<noTTY>,
7498     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7499     B<R> after you set them).
7500
7501 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7502 B<h>        Summary of debugger commands.
7503 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7504 B<h h>        Long help for debugger commands
7505 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7506         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7507         Set B<\$DB::doccmd> to change viewer.
7508
7509 Type '|h h' for a paged display if this was too hard to read.
7510
7511 ";    # Fix balance of vi % matching: }}}}
7512
7513     #  note: tabs in the following section are not-so-helpful
7514     $summary = <<"END_SUM";
7515 I<List/search source lines:>               I<Control script execution:>
7516   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7517   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7518   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7519   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7520   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7521   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7522 I<Debugger controls:>                        B<L>           List break/watch/actions
7523   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7524   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7525   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7526   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7527   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7528   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7529   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7530   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7531   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7532 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7533   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7534   B<p> I<expr>         Print expression (uses script's current package).
7535   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7536   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7537   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7538   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7539   B<e>     Display thread id     B<E> Display all thread ids.
7540 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7541 END_SUM
7542
7543     # ')}}; # Fix balance of vi % matching
7544
7545     # and this is really numb...
7546     $pre580_help = "
7547 B<T>        Stack trace.
7548 B<s> [I<expr>]    Single step [in I<expr>].
7549 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7550 B<CR>>        Repeat last B<n> or B<s> command.
7551 B<r>        Return from current subroutine.
7552 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7553         at the specified position.
7554 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7555 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7556 B<l> I<line>        List single I<line>.
7557 B<l> I<subname>    List first window of lines from subroutine.
7558 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7559 B<l>        List next window of lines.
7560 B<->        List previous window of lines.
7561 B<w> [I<line>]    List window around I<line>.
7562 B<.>        Return to the executed line.
7563 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7564         I<filename> may be either the full name of the file, or a regular
7565         expression matching the full file name:
7566         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7567         Evals (with saved bodies) are considered to be filenames:
7568         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7569         (in the order of execution).
7570 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7571 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7572 B<L>        List all breakpoints and actions.
7573 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7574 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7575 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7576 B<b> [I<line>] [I<condition>]
7577         Set breakpoint; I<line> defaults to the current execution line;
7578         I<condition> breaks if it evaluates to true, defaults to '1'.
7579 B<b> I<subname> [I<condition>]
7580         Set breakpoint at first line of subroutine.
7581 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7582 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7583 B<b> B<postpone> I<subname> [I<condition>]
7584         Set breakpoint at first line of subroutine after
7585         it is compiled.
7586 B<b> B<compile> I<subname>
7587         Stop after the subroutine is compiled.
7588 B<d> [I<line>]    Delete the breakpoint for I<line>.
7589 B<D>        Delete all breakpoints.
7590 B<a> [I<line>] I<command>
7591         Set an action to be done before the I<line> is executed;
7592         I<line> defaults to the current execution line.
7593         Sequence is: check for breakpoint/watchpoint, print line
7594         if necessary, do action, prompt user if necessary,
7595         execute line.
7596 B<a> [I<line>]    Delete the action for I<line>.
7597 B<A>        Delete all actions.
7598 B<W> I<expr>        Add a global watch-expression.
7599 B<W>        Delete all watch-expressions.
7600 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7601         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7602 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7603 B<x> I<expr>        Evals expression in list context, dumps the result.
7604 B<m> I<expr>        Evals expression in list context, prints methods callable
7605         on the first element of the result.
7606 B<m> I<class>        Prints methods callable via the given class.
7607
7608 B<<> ?            List Perl commands to run before each prompt.
7609 B<<> I<expr>        Define Perl command to run before each prompt.
7610 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7611 B<>> ?            List Perl commands to run after each prompt.
7612 B<>> I<expr>        Define Perl command to run after each prompt.
7613 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7614 B<{> I<db_command>    Define debugger command to run before each prompt.
7615 B<{> ?            List debugger commands to run before each prompt.
7616 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7617 B<$prc> I<number>    Redo a previous command (default previous command).
7618 B<$prc> I<-number>    Redo number'th-to-last command.
7619 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7620         See 'B<O> I<recallCommand>' too.
7621 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7622       . (
7623         $rc eq $sh
7624         ? ""
7625         : "
7626 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7627       ) . "
7628         See 'B<O> I<shellBang>' too.
7629 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7630 B<H> I<-number>    Display last number commands (default all).
7631 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7632 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7633 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7634 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7635 I<command>        Execute as a perl statement in current package.
7636 B<v>        Show versions of loaded modules.
7637 B<R>        Pure-man-restart of debugger, some of debugger state
7638         and command-line options may be lost.
7639         Currently the following settings are preserved:
7640         history, breakpoints and actions, debugger B<O>ptions
7641         and the following command-line options: I<-w>, I<-I>, I<-e>.
7642
7643 B<O> [I<opt>] ...    Set boolean option to true
7644 B<O> [I<opt>B<?>]    Query options
7645 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7646         Set options.  Use quotes if spaces in value.
7647     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7648     I<pager>            program for output of \"|cmd\";
7649     I<tkRunning>            run Tk while prompting (with ReadLine);
7650     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7651     I<inhibit_exit>        Allows stepping off the end of the script.
7652     I<ImmediateStop>        Debugger should stop as early as possible.
7653     I<RemotePort>            Remote hostname:port for remote debugging
7654   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7655     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7656     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7657     I<globPrint>             whether to print contents of globs;
7658     I<DumpDBFiles>         dump arrays holding debugged files;
7659     I<DumpPackages>         dump symbol tables of packages;
7660     I<DumpReused>             dump contents of \"reused\" addresses;
7661     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7662     I<bareStringify>         Do not print the overload-stringified value;
7663   Other options include:
7664     I<PrintRet>        affects printing of return value after B<r> command,
7665     I<frame>        affects printing messages on subroutine entry/exit.
7666     I<AutoTrace>    affects printing messages on possible breaking points.
7667     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7668     I<ornaments>     affects screen appearance of the command line.
7669     I<CreateTTY>     bits control attempts to create a new TTY on events:
7670             1: on fork()    2: debugger is started inside debugger
7671             4: on startup
7672     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7673     You can put additional initialization options I<TTY>, I<noTTY>,
7674     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7675     B<R> after you set them).
7676
7677 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7678 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7679 B<h h>        Summary of debugger commands.
7680 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7681         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7682         Set B<\$DB::doccmd> to change viewer.
7683
7684 Type '|h' for a paged display if this was too hard to read.
7685
7686 ";    # Fix balance of vi % matching: }}}}
7687
7688     #  note: tabs in the following section are not-so-helpful
7689     $pre580_summary = <<"END_SUM";
7690 I<List/search source lines:>               I<Control script execution:>
7691   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7692   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7693   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7694   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7695   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7696   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7697 I<Debugger controls:>                        B<L>           List break/watch/actions
7698   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7699   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7700   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7701   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7702   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7703   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7704   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7705   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7706 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7707   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7708   B<p> I<expr>         Print expression (uses script's current package).
7709   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7710   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7711   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7712   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7713 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7714 END_SUM
7715
7716     # ')}}; # Fix balance of vi % matching
7717
7718 } ## end sub sethelp
7719
7720 =head2 C<print_help()>
7721
7722 Most of what C<print_help> does is just text formatting. It finds the
7723 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7724 terminal control characters to simulate them (courtesy of
7725 C<Term::ReadLine::TermCap>).
7726
7727 =cut
7728
7729 sub print_help {
7730     local $_ = shift;
7731
7732     # Restore proper alignment destroyed by eeevil I<> and B<>
7733     # ornaments: A pox on both their houses!
7734     #
7735     # A help command will have everything up to and including
7736     # the first tab sequence padded into a field 16 (or if indented 20)
7737     # wide.  If it's wider than that, an extra space will be added.
7738     s{
7739         ^                       # only matters at start of line
7740           ( \040{4} | \t )*     # some subcommands are indented
7741           ( < ?                 # so <CR> works
7742             [BI] < [^\t\n] + )  # find an eeevil ornament
7743           ( \t+ )               # original separation, discarded
7744           ( .* )                # this will now start (no earlier) than
7745                                 # column 16
7746     } {
7747         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7748         my $clean = $command;
7749         $clean =~ s/[BI]<([^>]*)>/$1/g;
7750
7751         # replace with this whole string:
7752         ($leadwhite ? " " x 4 : "")
7753       . $command
7754       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7755       . $text;
7756
7757     }mgex;
7758
7759     s{                          # handle bold ornaments
7760        B < ( [^>] + | > ) >
7761     } {
7762           $Term::ReadLine::TermCap::rl_term_set[2]
7763         . $1
7764         . $Term::ReadLine::TermCap::rl_term_set[3]
7765     }gex;
7766
7767     s{                         # handle italic ornaments
7768        I < ( [^>] + | > ) >
7769     } {
7770           $Term::ReadLine::TermCap::rl_term_set[0]
7771         . $1
7772         . $Term::ReadLine::TermCap::rl_term_set[1]
7773     }gex;
7774
7775     local $\ = '';
7776     print $OUT $_;
7777 } ## end sub print_help
7778
7779 =head2 C<fix_less>
7780
7781 This routine does a lot of gyrations to be sure that the pager is C<less>.
7782 It checks for C<less> masquerading as C<more> and records the result in
7783 C<$fixed_less> so we don't have to go through doing the stats again.
7784
7785 =cut
7786
7787 sub fix_less {
7788
7789     # We already know if this is set.
7790     return if $fixed_less;
7791
7792     # Pager is less for sure.
7793     my $is_less = $pager =~ /\bless\b/;
7794     if ( $pager =~ /\bmore\b/ ) {
7795
7796         # Nope, set to more. See what's out there.
7797         my @st_more = stat('/usr/bin/more');
7798         my @st_less = stat('/usr/bin/less');
7799
7800         # is it really less, pretending to be more?
7801              $is_less = @st_more
7802           && @st_less
7803           && $st_more[0] == $st_less[0]
7804           && $st_more[1] == $st_less[1];
7805     } ## end if ($pager =~ /\bmore\b/)
7806
7807     # changes environment!
7808     # 'r' added so we don't do (slow) stats again.
7809     $fixed_less = 1 if $is_less;
7810 } ## end sub fix_less
7811
7812 =head1 DIE AND WARN MANAGEMENT
7813
7814 =head2 C<diesignal>
7815
7816 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7817 to debug a debugger problem.
7818
7819 It does its best to report the error that occurred, and then forces the
7820 program, debugger, and everything to die.
7821
7822 =cut
7823
7824 sub diesignal {
7825
7826     # No entry/exit messages.
7827     local $frame = 0;
7828
7829     # No return value prints.
7830     local $doret = -2;
7831
7832     # set the abort signal handling to the default (just terminate).
7833     $SIG{'ABRT'} = 'DEFAULT';
7834
7835     # If we enter the signal handler recursively, kill myself with an
7836     # abort signal (so we just terminate).
7837     kill 'ABRT', $$ if $panic++;
7838
7839     # If we can show detailed info, do so.
7840     if ( defined &Carp::longmess ) {
7841
7842         # Don't recursively enter the warn handler, since we're carping.
7843         local $SIG{__WARN__} = '';
7844
7845         # Skip two levels before reporting traceback: we're skipping
7846         # mydie and confess.
7847         local $Carp::CarpLevel = 2;    # mydie + confess
7848
7849         # Tell us all about it.
7850         &warn( Carp::longmess("Signal @_") );
7851     }
7852
7853     # No Carp. Tell us about the signal as best we can.
7854     else {
7855         local $\ = '';
7856         print $DB::OUT "Got signal @_\n";
7857     }
7858
7859     # Drop dead.
7860     kill 'ABRT', $$;
7861 } ## end sub diesignal
7862
7863 =head2 C<dbwarn>
7864
7865 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
7866 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
7867
7868 =cut
7869
7870 sub dbwarn {
7871
7872     # No entry/exit trace.
7873     local $frame = 0;
7874
7875     # No return value printing.
7876     local $doret = -2;
7877
7878     # Turn off warn and die handling to prevent recursive entries to this
7879     # routine.
7880     local $SIG{__WARN__} = '';
7881     local $SIG{__DIE__}  = '';
7882
7883     # Load Carp if we can. If $^S is false (current thing being compiled isn't
7884     # done yet), we may not be able to do a require.
7885     eval { require Carp }
7886       if defined $^S;    # If error/warning during compilation,
7887                          # require may be broken.
7888
7889     # Use the core warn() unless Carp loaded OK.
7890     CORE::warn( @_,
7891         "\nCannot print stack trace, load with -MCarp option to see stack" ),
7892       return
7893       unless defined &Carp::longmess;
7894
7895     # Save the current values of $single and $trace, and then turn them off.
7896     my ( $mysingle, $mytrace ) = ( $single, $trace );
7897     $single = 0;
7898     $trace  = 0;
7899
7900     # We can call Carp::longmess without its being "debugged" (which we
7901     # don't want - we just want to use it!). Capture this for later.
7902     my $mess = Carp::longmess(@_);
7903
7904     # Restore $single and $trace to their original values.
7905     ( $single, $trace ) = ( $mysingle, $mytrace );
7906
7907     # Use the debugger's own special way of printing warnings to print
7908     # the stack trace message.
7909     &warn($mess);
7910 } ## end sub dbwarn
7911
7912 =head2 C<dbdie>
7913
7914 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
7915 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
7916 single stepping and tracing during the call to C<Carp::longmess> to avoid
7917 debugging it - we just want to use it.
7918
7919 If C<dieLevel> is zero, we let the program being debugged handle the
7920 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
7921 the debugger takes over all exception handling, printing a backtrace and
7922 displaying the exception via its C<dbwarn()> routine.
7923
7924 =cut
7925
7926 sub dbdie {
7927     local $frame         = 0;
7928     local $doret         = -2;
7929     local $SIG{__DIE__}  = '';
7930     local $SIG{__WARN__} = '';
7931     my $i      = 0;
7932     my $ineval = 0;
7933     my $sub;
7934     if ( $dieLevel > 2 ) {
7935         local $SIG{__WARN__} = \&dbwarn;
7936         &warn(@_);    # Yell no matter what
7937         return;
7938     }
7939     if ( $dieLevel < 2 ) {
7940         die @_ if $^S;    # in eval propagate
7941     }
7942
7943     # The code used to check $^S to see if compilation of the current thing
7944     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
7945     eval { require Carp };
7946
7947     die( @_,
7948         "\nCannot print stack trace, load with -MCarp option to see stack" )
7949       unless defined &Carp::longmess;
7950
7951     # We do not want to debug this chunk (automatic disabling works
7952     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
7953     # get the stack trace from Carp::longmess (if possible), restore $signal
7954     # and $trace, and then die with the stack trace.
7955     my ( $mysingle, $mytrace ) = ( $single, $trace );
7956     $single = 0;
7957     $trace  = 0;
7958     my $mess = "@_";
7959     {
7960
7961         package Carp;    # Do not include us in the list
7962         eval { $mess = Carp::longmess(@_); };
7963     }
7964     ( $single, $trace ) = ( $mysingle, $mytrace );
7965     die $mess;
7966 } ## end sub dbdie
7967
7968 =head2 C<warnlevel()>
7969
7970 Set the C<$DB::warnLevel> variable that stores the value of the
7971 C<warnLevel> option. Calling C<warnLevel()> with a positive value
7972 results in the debugger taking over all warning handlers. Setting
7973 C<warnLevel> to zero leaves any warning handlers set up by the program
7974 being debugged in place.
7975
7976 =cut
7977
7978 sub warnLevel {
7979     if (@_) {
7980         $prevwarn = $SIG{__WARN__} unless $warnLevel;
7981         $warnLevel = shift;
7982         if ($warnLevel) {
7983             $SIG{__WARN__} = \&DB::dbwarn;
7984         }
7985         elsif ($prevwarn) {
7986             $SIG{__WARN__} = $prevwarn;
7987         } else {
7988             undef $SIG{__WARN__};
7989         }
7990     } ## end if (@_)
7991     $warnLevel;
7992 } ## end sub warnLevel
7993
7994 =head2 C<dielevel>
7995
7996 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
7997 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
7998 zero lets you use your own C<die()> handler.
7999
8000 =cut
8001
8002 sub dieLevel {
8003     local $\ = '';
8004     if (@_) {
8005         $prevdie = $SIG{__DIE__} unless $dieLevel;
8006         $dieLevel = shift;
8007         if ($dieLevel) {
8008
8009             # Always set it to dbdie() for non-zero values.
8010             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8011
8012             # No longer exists, so don't try  to use it.
8013             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8014
8015             # If we've finished initialization, mention that stack dumps
8016             # are enabled, If dieLevel is 1, we won't stack dump if we die
8017             # in an eval().
8018             print $OUT "Stack dump during die enabled",
8019               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8020               if $I_m_init;
8021
8022             # XXX This is probably obsolete, given that diehard() is gone.
8023             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8024         } ## end if ($dieLevel)
8025
8026         # Put the old one back if there was one.
8027         elsif ($prevdie) {
8028             $SIG{__DIE__} = $prevdie;
8029             print $OUT "Default die handler restored.\n";
8030         } else {
8031             undef $SIG{__DIE__};
8032             print $OUT "Die handler removed.\n";
8033         }
8034     } ## end if (@_)
8035     $dieLevel;
8036 } ## end sub dieLevel
8037
8038 =head2 C<signalLevel>
8039
8040 Number three in a series: set C<signalLevel> to zero to keep your own
8041 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8042 takes over and handles them with C<DB::diesignal()>.
8043
8044 =cut
8045
8046 sub signalLevel {
8047     if (@_) {
8048         $prevsegv = $SIG{SEGV} unless $signalLevel;
8049         $prevbus  = $SIG{BUS}  unless $signalLevel;
8050         $signalLevel = shift;
8051         if ($signalLevel) {
8052             $SIG{SEGV} = \&DB::diesignal;
8053             $SIG{BUS}  = \&DB::diesignal;
8054         }
8055         else {
8056             $SIG{SEGV} = $prevsegv;
8057             $SIG{BUS}  = $prevbus;
8058         }
8059     } ## end if (@_)
8060     $signalLevel;
8061 } ## end sub signalLevel
8062
8063 =head1 SUBROUTINE DECODING SUPPORT
8064
8065 These subroutines are used during the C<x> and C<X> commands to try to
8066 produce as much information as possible about a code reference. They use
8067 L<Devel::Peek> to try to find the glob in which this code reference lives
8068 (if it does) - this allows us to actually code references which correspond
8069 to named subroutines (including those aliased via glob assignment).
8070
8071 =head2 C<CvGV_name()>
8072
8073 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8074 via that routine. If this fails, return the reference again (when the
8075 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8076
8077 =cut
8078
8079 sub CvGV_name {
8080     my $in   = shift;
8081     my $name = CvGV_name_or_bust($in);
8082     defined $name ? $name : $in;
8083 }
8084
8085 =head2 C<CvGV_name_or_bust> I<coderef>
8086
8087 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8088 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8089 find a glob for this ref.
8090
8091 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8092
8093 =cut
8094
8095 sub CvGV_name_or_bust {
8096     my $in = shift;
8097     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8098     return unless ref $in;
8099     $in = \&$in;            # Hard reference...
8100     eval { require Devel::Peek; 1 } or return;
8101     my $gv = Devel::Peek::CvGV($in) or return;
8102     *$gv{PACKAGE} . '::' . *$gv{NAME};
8103 } ## end sub CvGV_name_or_bust
8104
8105 =head2 C<find_sub>
8106
8107 A utility routine used in various places; finds the file where a subroutine
8108 was defined, and returns that filename and a line-number range.
8109
8110 Tries to use C<@sub> first; if it can't find it there, it tries building a
8111 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8112 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8113 this way, it brute-force searches C<%sub>, checking for identical references.
8114
8115 =cut
8116
8117 sub find_sub {
8118     my $subr = shift;
8119     $sub{$subr} or do {
8120         return unless defined &$subr;
8121         my $name = CvGV_name_or_bust($subr);
8122         my $data;
8123         $data = $sub{$name} if defined $name;
8124         return $data if defined $data;
8125
8126         # Old stupid way...
8127         $subr = \&$subr;    # Hard reference
8128         my $s;
8129         for ( keys %sub ) {
8130             $s = $_, last if $subr eq \&$_;
8131         }
8132         $sub{$s} if $s;
8133       } ## end do
8134 } ## end sub find_sub
8135
8136 =head2 C<methods>
8137
8138 A subroutine that uses the utility function C<methods_via> to find all the
8139 methods in the class corresponding to the current reference and in
8140 C<UNIVERSAL>.
8141
8142 =cut
8143
8144 sub methods {
8145
8146     # Figure out the class - either this is the class or it's a reference
8147     # to something blessed into that class.
8148     my $class = shift;
8149     $class = ref $class if ref $class;
8150
8151     local %seen;
8152
8153     # Show the methods that this class has.
8154     methods_via( $class, '', 1 );
8155
8156     # Show the methods that UNIVERSAL has.
8157     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8158 } ## end sub methods
8159
8160 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8161
8162 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8163 all the parent class methods. C<$class> is the name of the next class to
8164 try; C<$prefix> is the message prefix, which gets built up as we go up the
8165 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8166 higher in the C<@ISA> tree, 0 if we should stop.
8167
8168 =cut
8169
8170 sub methods_via {
8171
8172     # If we've processed this class already, just quit.
8173     my $class = shift;
8174     return if $seen{$class}++;
8175
8176     # This is a package that is contributing the methods we're about to print.
8177     my $prefix  = shift;
8178     my $prepend = $prefix ? "via $prefix: " : '';
8179     my @to_print;
8180
8181     # Extract from all the symbols in this class.
8182     while (my ($name, $glob) = each %{"${class}::"}) {
8183         # references directly in the symbol table are Proxy Constant
8184         # Subroutines, and are by their very nature defined
8185         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8186         # to a subroutine reference, which can be tested by defined.
8187         # $glob might also be the value -1  (from sub foo;)
8188         # or (say) '$$' (from sub foo ($$);)
8189         # \$glob will be SCALAR in both cases.
8190         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8191             && !$seen{$name}++) {
8192             push @to_print, "$prepend$name\n";
8193         }
8194     }
8195
8196     {
8197         local $\ = '';
8198         local $, = '';
8199         print $DB::OUT $_ foreach sort @to_print;
8200     }
8201
8202     # If the $crawl_upward argument is false, just quit here.
8203     return unless shift;
8204
8205     # $crawl_upward true: keep going up the tree.
8206     # Find all the classes this one is a subclass of.
8207     for $name ( @{"${class}::ISA"} ) {
8208
8209         # Set up the new prefix.
8210         $prepend = $prefix ? $prefix . " -> $name" : $name;
8211
8212         # Crawl up the tree and keep trying to crawl up.
8213         methods_via( $name, $prepend, 1 );
8214     }
8215 } ## end sub methods_via
8216
8217 =head2 C<setman> - figure out which command to use to show documentation
8218
8219 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8220
8221 =cut
8222
8223 sub setman {
8224     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8225       ? "man"         # O Happy Day!
8226       : "perldoc";    # Alas, poor unfortunates
8227 } ## end sub setman
8228
8229 =head2 C<runman> - run the appropriate command to show documentation
8230
8231 Accepts a man page name; runs the appropriate command to display it (set up
8232 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8233 program's STDIN and STDOUT.
8234
8235 =cut
8236
8237 sub runman {
8238     my $page = shift;
8239     unless ($page) {
8240         &system("$doccmd $doccmd");
8241         return;
8242     }
8243
8244     # this way user can override, like with $doccmd="man -Mwhatever"
8245     # or even just "man " to disable the path check.
8246     unless ( $doccmd eq 'man' ) {
8247         &system("$doccmd $page");
8248         return;
8249     }
8250
8251     $page = 'perl' if lc($page) eq 'help';
8252
8253     require Config;
8254     my $man1dir = $Config::Config{'man1dir'};
8255     my $man3dir = $Config::Config{'man3dir'};
8256     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8257     my $manpath = '';
8258     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8259     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8260     chop $manpath if $manpath;
8261
8262     # harmless if missing, I figure
8263     my $oldpath = $ENV{MANPATH};
8264     $ENV{MANPATH} = $manpath if $manpath;
8265     my $nopathopt = $^O =~ /dunno what goes here/;
8266     if (
8267         CORE::system(
8268             $doccmd,
8269
8270             # I just *know* there are men without -M
8271             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8272             split ' ', $page
8273         )
8274       )
8275     {
8276         unless ( $page =~ /^perl\w/ ) {
8277 # do it this way because its easier to slurp in to keep up to date - clunky though.
8278 my @pods = qw(
8279     5004delta
8280     5005delta
8281     561delta
8282     56delta
8283     570delta
8284     571delta
8285     572delta
8286     573delta
8287     58delta
8288     581delta
8289     582delta
8290     583delta
8291     584delta
8292     590delta
8293     591delta
8294     592delta
8295     aix
8296     amiga
8297     apio
8298     api
8299     artistic
8300     beos
8301     book
8302     boot
8303     bot
8304     bs2000
8305     call
8306     ce
8307     cheat
8308     clib
8309     cn
8310     compile
8311     cygwin
8312     data
8313     dbmfilter
8314     debguts
8315     debtut
8316     debug
8317     delta
8318     dgux
8319     diag
8320     doc
8321     dos
8322     dsc
8323     ebcdic
8324     embed
8325     epoc
8326     faq1
8327     faq2
8328     faq3
8329     faq4
8330     faq5
8331     faq6
8332     faq7
8333     faq8
8334     faq9
8335     faq
8336     filter
8337     fork
8338     form
8339     freebsd
8340     func
8341     gpl
8342     guts
8343     hack
8344     hist
8345     hpux
8346     hurd
8347     intern
8348     intro
8349     iol
8350     ipc
8351     irix
8352     jp
8353     ko
8354     lexwarn
8355     locale
8356     lol
8357     macos
8358     macosx
8359     modinstall
8360     modlib
8361     mod
8362     modstyle
8363     mpeix
8364     netware
8365     newmod
8366     number
8367     obj
8368     opentut
8369     op
8370     os2
8371     os390
8372     os400
8373     packtut
8374     plan9
8375     pod
8376     podspec
8377     port
8378     qnx
8379     ref
8380     reftut
8381     re
8382     requick
8383     reref
8384     retut
8385     run
8386     sec
8387     solaris
8388     style
8389     sub
8390     syn
8391     thrtut
8392     tie
8393     toc
8394     todo
8395     tooc
8396     toot
8397     trap
8398     tru64
8399     tw
8400     unicode
8401     uniintro
8402     util
8403     uts
8404     var
8405     vmesa
8406     vms
8407     vos
8408     win32
8409     xs
8410     xstut
8411 );
8412             if (grep { $page eq $_ } @pods) {
8413                 $page =~ s/^/perl/;
8414                 CORE::system( $doccmd,
8415                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8416                     $page );
8417             } ## end if (grep { $page eq $_...
8418         } ## end unless ($page =~ /^perl\w/)
8419     } ## end if (CORE::system($doccmd...
8420     if ( defined $oldpath ) {
8421         $ENV{MANPATH} = $manpath;
8422     }
8423     else {
8424         delete $ENV{MANPATH};
8425     }
8426 } ## end sub runman
8427
8428 #use Carp;                          # This did break, left for debugging
8429
8430 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8431
8432 Because of the way the debugger interface to the Perl core is designed, any
8433 debugger package globals that C<DB::sub()> requires have to be defined before
8434 any subroutines can be called. These are defined in the second C<BEGIN> block.
8435
8436 This block sets things up so that (basically) the world is sane
8437 before the debugger starts executing. We set up various variables that the
8438 debugger has to have set up before the Perl core starts running:
8439
8440 =over 4
8441
8442 =item *
8443
8444 The debugger's own filehandles (copies of STD and STDOUT for now).
8445
8446 =item *
8447
8448 Characters for shell escapes, the recall command, and the history command.
8449
8450 =item *
8451
8452 The maximum recursion depth.
8453
8454 =item *
8455
8456 The size of a C<w> command's window.
8457
8458 =item *
8459
8460 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8461
8462 =item *
8463
8464 The fact that we're not in a sub at all right now.
8465
8466 =item *
8467
8468 The default SIGINT handler for the debugger.
8469
8470 =item *
8471
8472 The appropriate value of the flag in C<$^D> that says the debugger is running
8473
8474 =item *
8475
8476 The current debugger recursion level
8477
8478 =item *
8479
8480 The list of postponed items and the C<$single> stack (XXX define this)
8481
8482 =item *
8483
8484 That we want no return values and no subroutine entry/exit trace.
8485
8486 =back
8487
8488 =cut
8489
8490 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8491
8492 BEGIN {    # This does not compile, alas. (XXX eh?)
8493     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8494     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8495
8496     # Define characters used by command parsing.
8497     $sh       = '!';      # Shell escape (does not work)
8498     $rc       = ',';      # Recall command (does not work)
8499     @hist     = ('?');    # Show history (does not work)
8500     @truehist = ();       # Can be saved for replay (per session)
8501
8502     # This defines the point at which you get the 'deep recursion'
8503     # warning. It MUST be defined or the debugger will not load.
8504     $deep = 100;
8505
8506     # Number of lines around the current one that are shown in the
8507     # 'w' command.
8508     $window = 10;
8509
8510     # How much before-the-current-line context the 'v' command should
8511     # use in calculating the start of the window it will display.
8512     $preview = 3;
8513
8514     # We're not in any sub yet, but we need this to be a defined value.
8515     $sub = '';
8516
8517     # Set up the debugger's interrupt handler. It simply sets a flag
8518     # ($signal) that DB::DB() will check before each command is executed.
8519     $SIG{INT} = \&DB::catch;
8520
8521     # The following lines supposedly, if uncommented, allow the debugger to
8522     # debug itself. Perhaps we can try that someday.
8523     # This may be enabled to debug debugger:
8524     #$warnLevel = 1 unless defined $warnLevel;
8525     #$dieLevel = 1 unless defined $dieLevel;
8526     #$signalLevel = 1 unless defined $signalLevel;
8527
8528     # This is the flag that says "a debugger is running, please call
8529     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8530     # execute anything in the user's context, because we always want to
8531     # get control back.
8532     $db_stop = 0;          # Compiler warning ...
8533     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8534
8535     # This variable records how many levels we're nested in debugging. Used
8536     # Used in the debugger prompt, and in determining whether it's all over or
8537     # not.
8538     $level = 0;            # Level of recursive debugging
8539
8540     # "Triggers bug (?) in perl if we postpone this until runtime."
8541     # XXX No details on this yet, or whether we should fix the bug instead
8542     # of work around it. Stay tuned.
8543     @postponed = @stack = (0);
8544
8545     # Used to track the current stack depth using the auto-stacked-variable
8546     # trick.
8547     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8548
8549     # Don't print return values on exiting a subroutine.
8550     $doret = -2;
8551
8552     # No extry/exit tracing.
8553     $frame = 0;
8554
8555 } ## end BEGIN
8556
8557 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8558
8559 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8560
8561 =head2 db_complete
8562
8563 C<readline> support - adds command completion to basic C<readline>.
8564
8565 Returns a list of possible completions to C<readline> when invoked. C<readline>
8566 will print the longest common substring following the text already entered.
8567
8568 If there is only a single possible completion, C<readline> will use it in full.
8569
8570 This code uses C<map> and C<grep> heavily to create lists of possible
8571 completion. Think LISP in this section.
8572
8573 =cut
8574
8575 sub db_complete {
8576
8577     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8578     # $text is the text to be completed.
8579     # $line is the incoming line typed by the user.
8580     # $start is the start of the text to be completed in the incoming line.
8581     my ( $text, $line, $start ) = @_;
8582
8583     # Save the initial text.
8584     # The search pattern is current package, ::, extract the next qualifier
8585     # Prefix and pack are set to undef.
8586     my ( $itext, $search, $prefix, $pack ) =
8587       ( $text, "^\Q${'package'}::\E([^:]+)\$" );
8588
8589 =head3 C<b postpone|compile>
8590
8591 =over 4
8592
8593 =item *
8594
8595 Find all the subroutines that might match in this package
8596
8597 =item *
8598
8599 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8600
8601 =item *
8602
8603 Include all the rest of the subs that are known
8604
8605 =item *
8606
8607 C<grep> out the ones that match the text we have so far
8608
8609 =item *
8610
8611 Return this as the list of possible completions
8612
8613 =back
8614
8615 =cut
8616
8617     return sort grep /^\Q$text/, ( keys %sub ),
8618       qw(postpone load compile),    # subroutines
8619       ( map { /$search/ ? ($1) : () } keys %sub )
8620       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8621
8622 =head3 C<b load>
8623
8624 Get all the possible files from C<@INC> as it currently stands and
8625 select the ones that match the text so far.
8626
8627 =cut
8628
8629     return sort grep /^\Q$text/, values %INC    # files
8630       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8631
8632 =head3  C<V> (list variable) and C<m> (list modules)
8633
8634 There are two entry points for these commands:
8635
8636 =head4 Unqualified package names
8637
8638 Get the top-level packages and grab everything that matches the text
8639 so far. For each match, recursively complete the partial packages to
8640 get all possible matching packages. Return this sorted list.
8641
8642 =cut
8643
8644     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8645       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8646       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8647
8648 =head4 Qualified package names
8649
8650 Take a partially-qualified package and find all subpackages for it
8651 by getting all the subpackages for the package so far, matching all
8652 the subpackages against the text, and discarding all of them which
8653 start with 'main::'. Return this list.
8654
8655 =cut
8656
8657     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8658       grep !/^main::/, grep /^\Q$text/,
8659       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () } keys %{ $prefix . '::' }
8660       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8661       and $text =~ /^(.*[^:])::?(\w*)$/
8662       and $prefix = $1;
8663
8664 =head3 C<f> - switch files
8665
8666 Here, we want to get a fully-qualified filename for the C<f> command.
8667 Possibilities are:
8668
8669 =over 4
8670
8671 =item 1. The original source file itself
8672
8673 =item 2. A file from C<@INC>
8674
8675 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8676
8677 =back
8678
8679 =cut
8680
8681     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8682            # We might possibly want to switch to an eval (which has a "filename"
8683            # like '(eval 9)'), so we may need to clean up the completion text
8684            # before proceeding.
8685         $prefix = length($1) - length($text);
8686         $text   = $1;
8687
8688 =pod
8689
8690 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8691 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8692 out of C<%main::>, add the initial source file, and extract the ones that
8693 match the completion text so far.
8694
8695 =cut
8696
8697         return sort
8698           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8699           $0;
8700     } ## end if ($line =~ /^\|*f\s+(.*)/)
8701
8702 =head3 Subroutine name completion
8703
8704 We look through all of the defined subs (the keys of C<%sub>) and
8705 return both all the possible matches to the subroutine name plus
8706 all the matches qualified to the current package.
8707
8708 =cut
8709
8710     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8711         $text = substr $text, 1;
8712         $prefix = "&";
8713         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8714           (
8715             map { /$search/ ? ($1) : () }
8716               keys %sub
8717           );
8718     } ## end if ((substr $text, 0, ...
8719
8720 =head3  Scalar, array, and hash completion: partially qualified package
8721
8722 Much like the above, except we have to do a little more cleanup:
8723
8724 =cut
8725
8726     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8727
8728 =pod
8729
8730 =over 4
8731
8732 =item *
8733
8734 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8735
8736 =cut
8737
8738         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8739
8740 =pod
8741
8742 =item *
8743
8744 Figure out the prefix vs. what needs completing.
8745
8746 =cut
8747
8748         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8749         $text   = $2;
8750
8751 =pod
8752
8753 =item *
8754
8755 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8756
8757 =cut
8758
8759         my @out = map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8760           keys %$pack;
8761
8762 =pod
8763
8764 =item *
8765
8766 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8767
8768 =cut
8769
8770         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8771             return db_complete( $out[0], $line, $start );
8772         }
8773
8774         # Return the list of possibles.
8775         return sort @out;
8776
8777     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8778
8779 =pod
8780
8781 =back
8782
8783 =head3 Symbol completion: current package or package C<main>.
8784
8785 =cut
8786
8787     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8788 =pod
8789
8790 =over 4
8791
8792 =item *
8793
8794 If it's C<main>, delete main to just get C<::> leading.
8795
8796 =cut
8797
8798         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8799
8800 =pod
8801
8802 =item *
8803
8804 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
8805
8806 =cut
8807
8808         $prefix = substr $text, 0, 1;
8809         $text   = substr $text, 1;
8810
8811         my @out;
8812
8813 =pod
8814
8815 =item *
8816
8817 We look for the lexical scope above DB::DB and auto-complete lexical variables
8818 if PadWalker could be loaded.
8819
8820 =cut
8821
8822         if (not $text =~ /::/ and eval { require PadWalker } ) {
8823             my $level = 1;
8824             while (1) {
8825                 my @info = caller($level);
8826                 $level++;
8827                 $level = -1, last
8828                   if not @info;
8829                 last if $info[3] eq 'DB::DB';
8830             }
8831             if ($level > 0) {
8832                 my $lexicals = PadWalker::peek_my($level);
8833                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
8834             }
8835         }
8836
8837 =pod
8838
8839 =item *
8840
8841 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
8842
8843 =cut
8844
8845         push @out, map "$prefix$_", grep /^\Q$text/,
8846           ( grep /^_?[a-zA-Z]/, keys %$pack ),
8847           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
8848
8849 =item *
8850
8851 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
8852
8853 =back
8854
8855 =cut
8856
8857         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8858             return db_complete( $out[0], $line, $start );
8859         }
8860
8861         # Return the list of possibles.
8862         return sort @out;
8863     } ## end if ($text =~ /^[\$@%]/)
8864
8865 =head3 Options
8866
8867 We use C<option_val()> to look up the current value of the option. If there's
8868 only a single value, we complete the command in such a way that it is a
8869 complete command for setting the option in question. If there are multiple
8870 possible values, we generate a command consisting of the option plus a trailing
8871 question mark, which, if executed, will list the current value of the option.
8872
8873 =cut
8874
8875     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
8876     {    # Options after space
8877            # We look for the text to be matched in the list of possible options,
8878            # and fetch the current value.
8879         my @out = grep /^\Q$text/, @options;
8880         my $val = option_val( $out[0], undef );
8881
8882         # Set up a 'query option's value' command.
8883         my $out = '? ';
8884         if ( not defined $val or $val =~ /[\n\r]/ ) {
8885
8886             # There's really nothing else we can do.
8887         }
8888
8889         # We have a value. Create a proper option-setting command.
8890         elsif ( $val =~ /\s/ ) {
8891
8892             # XXX This may be an extraneous variable.
8893             my $found;
8894
8895             # We'll want to quote the string (because of the embedded
8896             # whtespace), but we want to make sure we don't end up with
8897             # mismatched quote characters. We try several possibilities.
8898             foreach $l ( split //, qq/\"\'\#\|/ ) {
8899
8900                 # If we didn't find this quote character in the value,
8901                 # quote it using this quote character.
8902                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
8903             }
8904         } ## end elsif ($val =~ /\s/)
8905
8906         # Don't need any quotes.
8907         else {
8908             $out = "=$val ";
8909         }
8910
8911         # If there were multiple possible values, return '? ', which
8912         # makes the command into a query command. If there was just one,
8913         # have readline append that.
8914         $rl_attribs->{completer_terminator_character} =
8915           ( @out == 1 ? $out : '? ' );
8916
8917         # Return list of possibilities.
8918         return sort @out;
8919     } ## end if ((substr $line, 0, ...
8920
8921 =head3 Filename completion
8922
8923 For entering filenames. We simply call C<readline>'s C<filename_list()>
8924 method with the completion text to get the possible completions.
8925
8926 =cut
8927
8928     return $term->filename_list($text);    # filenames
8929
8930 } ## end sub db_complete
8931
8932 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
8933
8934 Functions that possibly ought to be somewhere else.
8935
8936 =head2 end_report
8937
8938 Say we're done.
8939
8940 =cut
8941
8942 sub end_report {
8943     local $\ = '';
8944     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
8945 }
8946
8947 =head2 clean_ENV
8948
8949 If we have $ini_pids, save it in the environment; else remove it from the
8950 environment. Used by the C<R> (restart) command.
8951
8952 =cut
8953
8954 sub clean_ENV {
8955     if ( defined($ini_pids) ) {
8956         $ENV{PERLDB_PIDS} = $ini_pids;
8957     }
8958     else {
8959         delete( $ENV{PERLDB_PIDS} );
8960     }
8961 } ## end sub clean_ENV
8962
8963 # PERLDBf_... flag names from perl.h
8964 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
8965
8966 BEGIN {
8967     %DollarCaretP_flags = (
8968         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
8969         PERLDBf_LINE      => 0x02,     # Keep line #
8970         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
8971         PERLDBf_INTER     => 0x08,     # Preserve more data
8972         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
8973         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
8974         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
8975         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
8976         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
8977         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
8978         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
8979         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
8980     );
8981     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
8982     # doesn't need to set it. It's provided for the benefit of profilers and
8983     # other code analysers.
8984
8985     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
8986 }
8987
8988 sub parse_DollarCaretP_flags {
8989     my $flags = shift;
8990     $flags =~ s/^\s+//;
8991     $flags =~ s/\s+$//;
8992     my $acu = 0;
8993     foreach my $f ( split /\s*\|\s*/, $flags ) {
8994         my $value;
8995         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
8996             $value = hex $1;
8997         }
8998         elsif ( $f =~ /^(\d+)$/ ) {
8999             $value = int $1;
9000         }
9001         elsif ( $f =~ /^DEFAULT$/i ) {
9002             $value = $DollarCaretP_flags{PERLDB_ALL};
9003         }
9004         else {
9005             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9006             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9007             unless ( defined $value ) {
9008                 print $OUT (
9009                     "Unrecognized \$^P flag '$f'!\n",
9010                     "Acceptable flags are: "
9011                       . join( ', ', sort keys %DollarCaretP_flags ),
9012                     ", and hexadecimal and decimal numbers.\n"
9013                 );
9014                 return undef;
9015             }
9016         }
9017         $acu |= $value;
9018     }
9019     $acu;
9020 }
9021
9022 sub expand_DollarCaretP_flags {
9023     my $DollarCaretP = shift;
9024     my @bits         = (
9025         map {
9026             my $n = ( 1 << $_ );
9027             ( $DollarCaretP & $n )
9028               ? ( $DollarCaretP_flags_r{$n}
9029                   || sprintf( '0x%x', $n ) )
9030               : ()
9031           } 0 .. 31
9032     );
9033     return @bits ? join( '|', @bits ) : 0;
9034 }
9035
9036 =over 4
9037
9038 =item rerun
9039
9040 Rerun the current session to:
9041
9042     rerun        current position
9043
9044     rerun 4      command number 4
9045
9046     rerun -4     current command minus 4 (go back 4 steps)
9047
9048 Whether this always makes sense, in the current context is unknowable, and is
9049 in part left as a useful exercise for the reader.  This sub returns the
9050 appropriate arguments to rerun the current session.
9051
9052 =cut
9053
9054 sub rerun {
9055     my $i = shift;
9056     my @args;
9057     pop(@truehist);                      # strim
9058     unless (defined $truehist[$i]) {
9059         print "Unable to return to non-existent command: $i\n";
9060     } else {
9061         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9062         my @temp = @truehist;            # store
9063         push(@DB::typeahead, @truehist); # saved
9064         @truehist = @hist = ();          # flush
9065         @args = &restart();              # setup
9066         &get_list("PERLDB_HIST");        # clean
9067         &set_list("PERLDB_HIST", @temp); # reset
9068     }
9069     return @args;
9070 }
9071
9072 =item restart
9073
9074 Restarting the debugger is a complex operation that occurs in several phases.
9075 First, we try to reconstruct the command line that was used to invoke Perl
9076 and the debugger.
9077
9078 =cut
9079
9080 sub restart {
9081     # I may not be able to resurrect you, but here goes ...
9082     print $OUT
9083 "Warning: some settings and command-line options may be lost!\n";
9084     my ( @script, @flags, $cl );
9085
9086     # If warn was on before, turn it on again.
9087     push @flags, '-w' if $ini_warn;
9088
9089     # Rebuild the -I flags that were on the initial
9090     # command line.
9091     for (@ini_INC) {
9092         push @flags, '-I', $_;
9093     }
9094
9095     # Turn on taint if it was on before.
9096     push @flags, '-T' if ${^TAINT};
9097
9098     # Arrange for setting the old INC:
9099     # Save the current @init_INC in the environment.
9100     set_list( "PERLDB_INC", @ini_INC );
9101
9102     # If this was a perl one-liner, go to the "file"
9103     # corresponding to the one-liner read all the lines
9104     # out of it (except for the first one, which is going
9105     # to be added back on again when 'perl -d' runs: that's
9106     # the 'require perl5db.pl;' line), and add them back on
9107     # to the command line to be executed.
9108     if ( $0 eq '-e' ) {
9109         for ( 1 .. $#{'::_<-e'} ) {  # The first line is PERL5DB
9110             chomp( $cl = ${'::_<-e'}[$_] );
9111             push @script, '-e', $cl;
9112         }
9113     } ## end if ($0 eq '-e')
9114
9115     # Otherwise we just reuse the original name we had
9116     # before.
9117     else {
9118         @script = $0;
9119     }
9120
9121 =pod
9122
9123 After the command line  has been reconstructed, the next step is to save
9124 the debugger's status in environment variables. The C<DB::set_list> routine
9125 is used to save aggregate variables (both hashes and arrays); scalars are
9126 just popped into environment variables directly.
9127
9128 =cut
9129
9130     # If the terminal supported history, grab it and
9131     # save that in the environment.
9132     set_list( "PERLDB_HIST",
9133           $term->Features->{getHistory}
9134         ? $term->GetHistory
9135         : @hist );
9136
9137     # Find all the files that were visited during this
9138     # session (i.e., the debugger had magic hashes
9139     # corresponding to them) and stick them in the environment.
9140     my @had_breakpoints = keys %had_breakpoints;
9141     set_list( "PERLDB_VISITED", @had_breakpoints );
9142
9143     # Save the debugger options we chose.
9144     set_list( "PERLDB_OPT", %option );
9145     # set_list( "PERLDB_OPT", options2remember() );
9146
9147     # Save the break-on-loads.
9148     set_list( "PERLDB_ON_LOAD", %break_on_load );
9149
9150 =pod
9151
9152 The most complex part of this is the saving of all of the breakpoints. They
9153 can live in an awful lot of places, and we have to go through all of them,
9154 find the breakpoints, and then save them in the appropriate environment
9155 variable via C<DB::set_list>.
9156
9157 =cut
9158
9159     # Go through all the breakpoints and make sure they're
9160     # still valid.
9161     my @hard;
9162     for ( 0 .. $#had_breakpoints ) {
9163
9164         # We were in this file.
9165         my $file = $had_breakpoints[$_];
9166
9167         # Grab that file's magic line hash.
9168         *dbline = $main::{ '_<' . $file };
9169
9170         # Skip out if it doesn't exist, or if the breakpoint
9171         # is in a postponed file (we'll do postponed ones
9172         # later).
9173         next unless %dbline or $postponed_file{$file};
9174
9175         # In an eval. This is a little harder, so we'll
9176         # do more processing on that below.
9177         ( push @hard, $file ), next
9178           if $file =~ /^\(\w*eval/;
9179
9180         # XXX I have no idea what this is doing. Yet.
9181         my @add;
9182         @add = %{ $postponed_file{$file} }
9183           if $postponed_file{$file};
9184
9185         # Save the list of all the breakpoints for this file.
9186         set_list( "PERLDB_FILE_$_", %dbline, @add );
9187
9188         # Serialize the extra data %breakpoints_data hash.
9189         # That's a bug fix.
9190         set_list( "PERLDB_FILE_ENABLED_$_",
9191             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9192             sort { $a <=> $b } keys(%dbline)
9193         )
9194     } ## end for (0 .. $#had_breakpoints)
9195
9196     # The breakpoint was inside an eval. This is a little
9197     # more difficult. XXX and I don't understand it.
9198     for (@hard) {
9199         # Get over to the eval in question.
9200         *dbline = $main::{ '_<' . $_ };
9201         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9202         for $sub ( keys %sub ) {
9203             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9204             $subs{$sub} = [ $1, $2 ];
9205         }
9206         unless (%subs) {
9207             print $OUT
9208               "No subroutines in $_, ignoring breakpoints.\n";
9209             next;
9210         }
9211       LINES: for $line ( keys %dbline ) {
9212
9213             # One breakpoint per sub only:
9214             my ( $offset, $sub, $found );
9215           SUBS: for $sub ( keys %subs ) {
9216                 if (
9217                     $subs{$sub}->[1] >=
9218                     $line    # Not after the subroutine
9219                     and (
9220                         not defined $offset    # Not caught
9221                         or $offset < 0
9222                     )
9223                   )
9224                 {                              # or badly caught
9225                     $found  = $sub;
9226                     $offset = $line - $subs{$sub}->[0];
9227                     $offset = "+$offset", last SUBS
9228                       if $offset >= 0;
9229                 } ## end if ($subs{$sub}->[1] >=...
9230             } ## end for $sub (keys %subs)
9231             if ( defined $offset ) {
9232                 $postponed{$found} =
9233                   "break $offset if $dbline{$line}";
9234             }
9235             else {
9236                 print $OUT
9237 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9238             }
9239         } ## end for $line (keys %dbline)
9240     } ## end for (@hard)
9241
9242     # Save the other things that don't need to be
9243     # processed.
9244     set_list( "PERLDB_POSTPONE",  %postponed );
9245     set_list( "PERLDB_PRETYPE",   @$pretype );
9246     set_list( "PERLDB_PRE",       @$pre );
9247     set_list( "PERLDB_POST",      @$post );
9248     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9249
9250     # We are officially restarting.
9251     $ENV{PERLDB_RESTART} = 1;
9252
9253     # We are junking all child debuggers.
9254     delete $ENV{PERLDB_PIDS};    # Restore ini state
9255
9256     # Set this back to the initial pid.
9257     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9258
9259 =pod
9260
9261 After all the debugger status has been saved, we take the command we built up
9262 and then return it, so we can C<exec()> it. The debugger will spot the
9263 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9264 from the environment.
9265
9266 =cut
9267
9268     # And run Perl again. Add the "-d" flag, all the
9269     # flags we built up, the script (whether a one-liner
9270     # or a file), add on the -emacs flag for a slave editor,
9271     # and then the old arguments.
9272
9273     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9274
9275 };  # end restart
9276
9277 =back
9278
9279 =head1 END PROCESSING - THE C<END> BLOCK
9280
9281 Come here at the very end of processing. We want to go into a
9282 loop where we allow the user to enter commands and interact with the
9283 debugger, but we don't want anything else to execute.
9284
9285 First we set the C<$finished> variable, so that some commands that
9286 shouldn't be run after the end of program quit working.
9287
9288 We then figure out whether we're truly done (as in the user entered a C<q>
9289 command, or we finished execution while running nonstop). If we aren't,
9290 we set C<$single> to 1 (causing the debugger to get control again).
9291
9292 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9293 message and returns control to the debugger. Repeat.
9294
9295 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9296 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9297 break, run to completion.).
9298
9299 =cut
9300
9301 END {
9302     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9303     $fall_off_end = 1 unless $inhibit_exit;
9304
9305     # Do not stop in at_exit() and destructors on exit:
9306     if ($fall_off_end or $runnonstop) {
9307         &save_hist();
9308     } else {
9309         $DB::single = 1;
9310         DB::fake::at_exit();
9311     }
9312 } ## end END
9313
9314 =head1 PRE-5.8 COMMANDS
9315
9316 Some of the commands changed function quite a bit in the 5.8 command
9317 realignment, so much so that the old code had to be replaced completely.
9318 Because we wanted to retain the option of being able to go back to the
9319 former command set, we moved the old code off to this section.
9320
9321 There's an awful lot of duplicated code here. We've duplicated the
9322 comments to keep things clear.
9323
9324 =head2 Null command
9325
9326 Does nothing. Used to I<turn off> commands.
9327
9328 =cut
9329
9330 sub cmd_pre580_null {
9331
9332     # do nothing...
9333 }
9334
9335 =head2 Old C<a> command.
9336
9337 This version added actions if you supplied them, and deleted them
9338 if you didn't.
9339
9340 =cut
9341
9342 sub cmd_pre580_a {
9343     my $xcmd = shift;
9344     my $cmd  = shift;
9345
9346     # Argument supplied. Add the action.
9347     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9348
9349         # If the line isn't there, use the current line.
9350         $i = $1 || $line;
9351         $j = $2;
9352
9353         # If there is an action ...
9354         if ( length $j ) {
9355
9356             # ... but the line isn't breakable, skip it.
9357             if ( $dbline[$i] == 0 ) {
9358                 print $OUT "Line $i may not have an action.\n";
9359             }
9360             else {
9361
9362                 # ... and the line is breakable:
9363                 # Mark that there's an action in this file.
9364                 $had_breakpoints{$filename} |= 2;
9365
9366                 # Delete any current action.
9367                 $dbline{$i} =~ s/\0[^\0]*//;
9368
9369                 # Add the new action, continuing the line as needed.
9370                 $dbline{$i} .= "\0" . action($j);
9371             }
9372         } ## end if (length $j)
9373
9374         # No action supplied.
9375         else {
9376
9377             # Delete the action.
9378             $dbline{$i} =~ s/\0[^\0]*//;
9379
9380             # Mark as having no break or action if nothing's left.
9381             delete $dbline{$i} if $dbline{$i} eq '';
9382         }
9383     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9384 } ## end sub cmd_pre580_a
9385
9386 =head2 Old C<b> command
9387
9388 Add breakpoints.
9389
9390 =cut
9391
9392 sub cmd_pre580_b {
9393     my $xcmd   = shift;
9394     my $cmd    = shift;
9395     my $dbline = shift;
9396
9397     # Break on load.
9398     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9399         my $file = $1;
9400         $file =~ s/\s+$//;
9401         &cmd_b_load($file);
9402     }
9403
9404     # b compile|postpone <some sub> [<condition>]
9405     # The interpreter actually traps this one for us; we just put the
9406     # necessary condition in the %postponed hash.
9407     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9408
9409         # Capture the condition if there is one. Make it true if none.
9410         my $cond = length $3 ? $3 : '1';
9411
9412         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9413         # if it was 'compile'.
9414         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9415
9416         # De-Perl4-ify the name - ' separators to ::.
9417         $subname =~ s/\'/::/g;
9418
9419         # Qualify it into the current package unless it's already qualified.
9420         $subname = "${'package'}::" . $subname
9421           unless $subname =~ /::/;
9422
9423         # Add main if it starts with ::.
9424         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9425
9426         # Save the break type for this sub.
9427         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9428     } ## end elsif ($cmd =~ ...
9429
9430     # b <sub name> [<condition>]
9431     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9432         my $subname = $1;
9433         my $cond = length $2 ? $2 : '1';
9434         &cmd_b_sub( $subname, $cond );
9435     }
9436     # b <line> [<condition>].
9437     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9438         my $i = $1 || $dbline;
9439         my $cond = length $2 ? $2 : '1';
9440         &cmd_b_line( $i, $cond );
9441     }
9442 } ## end sub cmd_pre580_b
9443
9444 =head2 Old C<D> command.
9445
9446 Delete all breakpoints unconditionally.
9447
9448 =cut
9449
9450 sub cmd_pre580_D {
9451     my $xcmd = shift;
9452     my $cmd  = shift;
9453     if ( $cmd =~ /^\s*$/ ) {
9454         print $OUT "Deleting all breakpoints...\n";
9455
9456         # %had_breakpoints lists every file that had at least one
9457         # breakpoint in it.
9458         my $file;
9459         for $file ( keys %had_breakpoints ) {
9460
9461             # Switch to the desired file temporarily.
9462             local *dbline = $main::{ '_<' . $file };
9463
9464             my $max = $#dbline;
9465             my $was;
9466
9467             # For all lines in this file ...
9468             for ( $i = 1 ; $i <= $max ; $i++ ) {
9469
9470                 # If there's a breakpoint or action on this line ...
9471                 if ( defined $dbline{$i} ) {
9472
9473                     # ... remove the breakpoint.
9474                     $dbline{$i} =~ s/^[^\0]+//;
9475                     if ( $dbline{$i} =~ s/^\0?$// ) {
9476
9477                         # Remove the entry altogether if no action is there.
9478                         delete $dbline{$i};
9479                     }
9480                 } ## end if (defined $dbline{$i...
9481             } ## end for ($i = 1 ; $i <= $max...
9482
9483             # If, after we turn off the "there were breakpoints in this file"
9484             # bit, the entry in %had_breakpoints for this file is zero,
9485             # we should remove this file from the hash.
9486             if ( not $had_breakpoints{$file} &= ~1 ) {
9487                 delete $had_breakpoints{$file};
9488             }
9489         } ## end for $file (keys %had_breakpoints)
9490
9491         # Kill off all the other breakpoints that are waiting for files that
9492         # haven't been loaded yet.
9493         undef %postponed;
9494         undef %postponed_file;
9495         undef %break_on_load;
9496     } ## end if ($cmd =~ /^\s*$/)
9497 } ## end sub cmd_pre580_D
9498
9499 =head2 Old C<h> command
9500
9501 Print help. Defaults to printing the long-form help; the 5.8 version
9502 prints the summary by default.
9503
9504 =cut
9505
9506 sub cmd_pre580_h {
9507     my $xcmd = shift;
9508     my $cmd  = shift;
9509
9510     # Print the *right* help, long format.
9511     if ( $cmd =~ /^\s*$/ ) {
9512         print_help($pre580_help);
9513     }
9514
9515     # 'h h' - explicitly-requested summary.
9516     elsif ( $cmd =~ /^h\s*/ ) {
9517         print_help($pre580_summary);
9518     }
9519
9520     # Find and print a command's help.
9521     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9522         my $asked  = $1;                   # for proper errmsg
9523         my $qasked = quotemeta($asked);    # for searching
9524                                            # XXX: finds CR but not <CR>
9525         if (
9526             $pre580_help =~ /^
9527                               <?           # Optional '<'
9528                               (?:[IB]<)    # Optional markup
9529                               $qasked      # The command name
9530                             /mx
9531           )
9532         {
9533
9534             while (
9535                 $pre580_help =~ /^
9536                                   (             # The command help:
9537                                    <?           # Optional '<'
9538                                    (?:[IB]<)    # Optional markup
9539                                    $qasked      # The command name
9540                                    ([\s\S]*?)   # Lines starting with tabs
9541                                    \n           # Final newline
9542                                   )
9543                                   (?!\s)/mgx
9544               )    # Line not starting with space
9545                    # (Next command's help)
9546             {
9547                 print_help($1);
9548             }
9549         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9550
9551         # Help not found.
9552         else {
9553             print_help("B<$asked> is not a debugger command.\n");
9554         }
9555     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9556 } ## end sub cmd_pre580_h
9557
9558 =head2 Old C<W> command
9559
9560 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9561
9562 =cut
9563
9564 sub cmd_pre580_W {
9565     my $xcmd = shift;
9566     my $cmd  = shift;
9567
9568     # Delete all watch expressions.
9569     if ( $cmd =~ /^$/ ) {
9570
9571         # No watching is going on.
9572         $trace &= ~2;
9573
9574         # Kill all the watch expressions and values.
9575         @to_watch = @old_watch = ();
9576     }
9577
9578     # Add a watch expression.
9579     elsif ( $cmd =~ /^(.*)/s ) {
9580
9581         # add it to the list to be watched.
9582         push @to_watch, $1;
9583
9584         # Get the current value of the expression.
9585         # Doesn't handle expressions returning list values!
9586         $evalarg = $1;
9587         my ($val) = &eval;
9588         $val = ( defined $val ) ? "'$val'" : 'undef';
9589
9590         # Save it.
9591         push @old_watch, $val;
9592
9593         # We're watching stuff.
9594         $trace |= 2;
9595
9596     } ## end elsif ($cmd =~ /^(.*)/s)
9597 } ## end sub cmd_pre580_W
9598
9599 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9600
9601 The debugger used to have a bunch of nearly-identical code to handle
9602 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9603 C<cmd_prepost> unify all this into one set of code to handle the
9604 appropriate actions.
9605
9606 =head2 C<cmd_pre590_prepost>
9607
9608 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9609 do something destructive. In pre 5.8 debuggers, the default action was to
9610 delete all the actions.
9611
9612 =cut
9613
9614 sub cmd_pre590_prepost {
9615     my $cmd    = shift;
9616     my $line   = shift || '*';
9617     my $dbline = shift;
9618
9619     return &cmd_prepost( $cmd, $line, $dbline );
9620 } ## end sub cmd_pre590_prepost
9621
9622 =head2 C<cmd_prepost>
9623
9624 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9625 Since the lists of actions are all held in arrays that are pointed to by
9626 references anyway, all we have to do is pick the right array reference and
9627 then use generic code to all, delete, or list actions.
9628
9629 =cut
9630
9631 sub cmd_prepost {
9632     my $cmd = shift;
9633
9634     # No action supplied defaults to 'list'.
9635     my $line = shift || '?';
9636
9637     # Figure out what to put in the prompt.
9638     my $which = '';
9639
9640     # Make sure we have some array or another to address later.
9641     # This means that if ssome reason the tests fail, we won't be
9642     # trying to stash actions or delete them from the wrong place.
9643     my $aref = [];
9644
9645     # < - Perl code to run before prompt.
9646     if ( $cmd =~ /^\</o ) {
9647         $which = 'pre-perl';
9648         $aref  = $pre;
9649     }
9650
9651     # > - Perl code to run after prompt.
9652     elsif ( $cmd =~ /^\>/o ) {
9653         $which = 'post-perl';
9654         $aref  = $post;
9655     }
9656
9657     # { - first check for properly-balanced braces.
9658     elsif ( $cmd =~ /^\{/o ) {
9659         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9660             print $OUT
9661 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9662         }
9663
9664         # Properly balanced. Pre-prompt debugger actions.
9665         else {
9666             $which = 'pre-debugger';
9667             $aref  = $pretype;
9668         }
9669     } ## end elsif ( $cmd =~ /^\{/o )
9670
9671     # Did we find something that makes sense?
9672     unless ($which) {
9673         print $OUT "Confused by command: $cmd\n";
9674     }
9675
9676     # Yes.
9677     else {
9678
9679         # List actions.
9680         if ( $line =~ /^\s*\?\s*$/o ) {
9681             unless (@$aref) {
9682
9683                 # Nothing there. Complain.
9684                 print $OUT "No $which actions.\n";
9685             }
9686             else {
9687
9688                 # List the actions in the selected list.
9689                 print $OUT "$which commands:\n";
9690                 foreach my $action (@$aref) {
9691                     print $OUT "\t$cmd -- $action\n";
9692                 }
9693             } ## end else
9694         } ## end if ( $line =~ /^\s*\?\s*$/o)
9695
9696         # Might be a delete.
9697         else {
9698             if ( length($cmd) == 1 ) {
9699                 if ( $line =~ /^\s*\*\s*$/o ) {
9700
9701                     # It's a delete. Get rid of the old actions in the
9702                     # selected list..
9703                     @$aref = ();
9704                     print $OUT "All $cmd actions cleared.\n";
9705                 }
9706                 else {
9707
9708                     # Replace all the actions. (This is a <, >, or {).
9709                     @$aref = action($line);
9710                 }
9711             } ## end if ( length($cmd) == 1)
9712             elsif ( length($cmd) == 2 ) {
9713
9714                 # Add the action to the line. (This is a <<, >>, or {{).
9715                 push @$aref, action($line);
9716             }
9717             else {
9718
9719                 # <<<, >>>>, {{{{{{ ... something not a command.
9720                 print $OUT
9721                   "Confused by strange length of $which command($cmd)...\n";
9722             }
9723         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9724     } ## end else
9725 } ## end sub cmd_prepost
9726
9727 =head1 C<DB::fake>
9728
9729 Contains the C<at_exit> routine that the debugger uses to issue the
9730 C<Debugged program terminated ...> message after the program completes. See
9731 the C<END> block documentation for more details.
9732
9733 =cut
9734
9735 package DB::fake;
9736
9737 sub at_exit {
9738     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9739 }
9740
9741 package DB;    # Do not trace this 1; below!
9742
9743 1;
9744
9745